lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11
  12 # not importing first() as it will clash with our own method
  13 use List::Util ();
  14
  15 BEGIN {
  16   # De-duplication in _merge_attr() is disabled, but left in for reference
  17   # (the merger is used for other things that ought not to be de-duped)
  18   *__HM_DEDUP = sub () { 0 };
  19 }
  20
  21 use namespace::clean;
  22
  23 use overload
  24         '0+'     => "count",
  25         'bool'   => "_bool",
  26         fallback => 1;
  27
  28 # this is real - CDBICompat overrides it with insanity
  29 # yes, prototype won't matter, but that's for now ;)
  30 sub _bool () { 1 }
  31
  32 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  33
  34 =head1 NAME
  35
  36 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  37
  38 =head1 SYNOPSIS
  39
  40   my $users_rs = $schema->resultset('User');
  41   while( $user = $users_rs->next) {
  42     print $user->username;
  43   }
  44
  45   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  46   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  47
  48 =head1 DESCRIPTION
  49
  50 A ResultSet is an object which stores a set of conditions representing
  51 a query. It is the backbone of DBIx::Class (i.e. the really
  52 important/useful bit).
  53
  54 No SQL is executed on the database when a ResultSet is created, it
  55 just stores all the conditions needed to create the query.
  56
  57 A basic ResultSet representing the data of an entire table is returned
  58 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  59 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  60
  61   my $users_rs = $schema->resultset('User');
  62
  63 A new ResultSet is returned from calling L</search> on an existing
  64 ResultSet. The new one will contain all the conditions of the
  65 original, plus any new conditions added in the C<search> call.
  66
  67 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  68 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  69 represents.
  70
  71 The query that the ResultSet represents is B<only> executed against
  72 the database when these methods are called:
  73 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  74
  75 If a resultset is used in a numeric context it returns the L</count>.
  76 However, if it is used in a boolean context it is B<always> true.  So if
  77 you want to check if a resultset has any results, you must use C<if $rs
  78 != 0>.
  79
  80 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  81
  82 If you want to make your custom ResultSet classes with L<Moose>, use a template
  83 similar to:
  84
  85     package MyApp::Schema::ResultSet::User;
  86
  87     use Moose;
  88     use namespace::autoclean;
  89     use MooseX::NonMoose;
  90     extends 'DBIx::Class::ResultSet';
  91
  92     sub BUILDARGS { $_[2] }
  93
  94     ...your code...
  95
  96     __PACKAGE__->meta->make_immutable;
  97
  98     1;
  99
 100 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 101 clash with the regular ResultSet constructor. Alternatively, you can use:
 102
 103     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 104
 105 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 106 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 107
 108 =head1 EXAMPLES
 109
 110 =head2 Chaining resultsets
 111
 112 Let's say you've got a query that needs to be run to return some data
 113 to the user. But, you have an authorization system in place that
 114 prevents certain users from seeing certain information. So, you want
 115 to construct the basic query in one method, but add constraints to it in
 116 another.
 117
 118   sub get_data {
 119     my $self = shift;
 120     my $request = $self->get_request; # Get a request object somehow.
 121     my $schema = $self->result_source->schema;
 122
 123     my $cd_rs = $schema->resultset('CD')->search({
 124       title => $request->param('title'),
 125       year => $request->param('year'),
 126     });
 127
 128     $cd_rs = $self->apply_security_policy( $cd_rs );
 129
 130     return $cd_rs->all();
 131   }
 132
 133   sub apply_security_policy {
 134     my $self = shift;
 135     my ($rs) = @_;
 136
 137     return $rs->search({
 138       subversive => 0,
 139     });
 140   }
 141
 142 =head3 Resolving conditions and attributes
 143
 144 When a resultset is chained from another resultset (e.g.:
 145 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 146 and attributes with the same keys need resolving.
 147
 148 If any of L</columns>, L</select>, L</as> are present, they reset the
 149 original selection, and start the selection "clean".
 150
 151 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 152 are merged into the existing ones from the original resultset.
 153
 154 The L</where> and L</having> attributes, and any search conditions, are
 155 merged with an SQL C<AND> to the existing condition from the original
 156 resultset.
 157
 158 All other attributes are overridden by any new ones supplied in the
 159 search attributes.
 160
 161 =head2 Multiple queries
 162
 163 Since a resultset just defines a query, you can do all sorts of
 164 things with it with the same object.
 165
 166   # Don't hit the DB yet.
 167   my $cd_rs = $schema->resultset('CD')->search({
 168     title => 'something',
 169     year => 2009,
 170   });
 171
 172   # Each of these hits the DB individually.
 173   my $count = $cd_rs->count;
 174   my $most_recent = $cd_rs->get_column('date_released')->max();
 175   my @records = $cd_rs->all;
 176
 177 And it's not just limited to SELECT statements.
 178
 179   $cd_rs->delete();
 180
 181 This is even cooler:
 182
 183   $cd_rs->create({ artist => 'Fred' });
 184
 185 Which is the same as:
 186
 187   $schema->resultset('CD')->create({
 188     title => 'something',
 189     year => 2009,
 190     artist => 'Fred'
 191   });
 192
 193 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 194
 195 =head1 METHODS
 196
 197 =head2 new
 198
 199 =over 4
 200
 201 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 202
 203 =item Return Value: L<$resultset|/search>
 204
 205 =back
 206
 207 The resultset constructor. Takes a source object (usually a
 208 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 209 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 210 executed as needed by the other methods.
 211
 212 Generally you never construct a resultset manually. Instead you get one
 213 from e.g. a
 214 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 215 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 216 scalar context):
 217
 218   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 219
 220 =over
 221
 222 =item WARNING
 223
 224 If called on an object, proxies to L</new_result> instead, so
 225
 226   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 227
 228 will return a CD object, not a ResultSet, and is equivalent to:
 229
 230   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 231
 232 Please also keep in mind that many internals call L</new_result> directly,
 233 so overloading this method with the idea of intercepting new result object
 234 creation B<will not work>. See also warning pertaining to L</create>.
 235
 236 =back
 237
 238 =cut
 239
 240 sub new {
 241   my $class = shift;
 242   return $class->new_result(@_) if ref $class;
 243
 244   my ($source, $attrs) = @_;
 245   $source = $source->resolve
 246     if $source->isa('DBIx::Class::ResultSourceHandle');
 247
 248   $attrs = { %{$attrs||{}} };
 249   delete @{$attrs}{qw(_sqlmaker_select_args _related_results_construction)};
 250
 251   if ($attrs->{page}) {
 252     $attrs->{rows} ||= 10;
 253   }
 254
 255   $attrs->{alias} ||= 'me';
 256
 257   my $self = bless {
 258     result_source => $source,
 259     cond => $attrs->{where},
 260     pager => undef,
 261     attrs => $attrs,
 262   }, $class;
 263
 264   # if there is a dark selector, this means we are already in a
 265   # chain and the cleanup/sanification was taken care of by
 266   # _search_rs already
 267   $self->_normalize_selection($attrs)
 268     unless $attrs->{_dark_selector};
 269
 270   $self->result_class(
 271     $attrs->{result_class} || $source->result_class
 272   );
 273
 274   $self;
 275 }
 276
 277 =head2 search
 278
 279 =over 4
 280
 281 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 282
 283 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 284
 285 =back
 286
 287   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 288   my $new_rs = $cd_rs->search({ year => 2005 });
 289
 290   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 291                  # year = 2005 OR year = 2004
 292
 293 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 294 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 295 To avoid that, use L</search_rs>.
 296
 297 If you need to pass in additional attributes but no additional condition,
 298 call it as C<search(undef, \%attrs)>.
 299
 300   # "SELECT name, artistid FROM $artist_table"
 301   my @all_artists = $schema->resultset('Artist')->search(undef, {
 302     columns => [qw/name artistid/],
 303   });
 304
 305 For a list of attributes that can be passed to C<search>, see
 306 L</ATTRIBUTES>. For more examples of using this function, see
 307 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 308 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 309 and its extension L<DBIx::Class::SQLMaker>.
 310
 311 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 312
 313 =head3 CAVEAT
 314
 315 Note that L</search> does not process/deflate any of the values passed in the
 316 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 317 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 318 manually that any value passed to this method will stringify to something the
 319 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 320 objects, for more info see:
 321 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 322
 323 =cut
 324
 325 sub search {
 326   my $self = shift;
 327   my $rs = $self->search_rs( @_ );
 328
 329   if (wantarray) {
 330     return $rs->all;
 331   }
 332   elsif (defined wantarray) {
 333     return $rs;
 334   }
 335   else {
 336     # we can be called by a relationship helper, which in
 337     # turn may be called in void context due to some braindead
 338     # overload or whatever else the user decided to be clever
 339     # at this particular day. Thus limit the exception to
 340     # external code calls only
 341     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 342       if (caller)[0] !~ /^\QDBIx::Class::/;
 343
 344     return ();
 345   }
 346 }
 347
 348 =head2 search_rs
 349
 350 =over 4
 351
 352 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 353
 354 =item Return Value: L<$resultset|/search>
 355
 356 =back
 357
 358 This method does the same exact thing as search() except it will
 359 always return a resultset, even in list context.
 360
 361 =cut
 362
 363 sub search_rs {
 364   my $self = shift;
 365
 366   my $rsrc = $self->result_source;
 367   my ($call_cond, $call_attrs);
 368
 369   # Special-case handling for (undef, undef) or (undef)
 370   # Note that (foo => undef) is valid deprecated syntax
 371   @_ = () if not scalar grep { defined $_ } @_;
 372
 373   # just a cond
 374   if (@_ == 1) {
 375     $call_cond = shift;
 376   }
 377   # fish out attrs in the ($condref, $attr) case
 378   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 379     ($call_cond, $call_attrs) = @_;
 380   }
 381   elsif (@_ % 2) {
 382     $self->throw_exception('Odd number of arguments to search')
 383   }
 384   # legacy search
 385   elsif (@_) {
 386     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 387       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 388
 389     for my $i (0 .. $#_) {
 390       next if $i % 2;
 391       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 392         if (! defined $_[$i] or ref $_[$i] ne '');
 393     }
 394
 395     $call_cond = { @_ };
 396   }
 397
 398   # see if we can keep the cache (no $rs changes)
 399   my $cache;
 400   my %safe = (alias => 1, cache => 1);
 401   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 402     ! defined $call_cond
 403       or
 404     ref $call_cond eq 'HASH' && ! keys %$call_cond
 405       or
 406     ref $call_cond eq 'ARRAY' && ! @$call_cond
 407   )) {
 408     $cache = $self->get_cache;
 409   }
 410
 411   my $old_attrs = { %{$self->{attrs}} };
 412   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 413
 414   my $new_attrs = { %$old_attrs };
 415
 416   # take care of call attrs (only if anything is changing)
 417   if ($call_attrs and keys %$call_attrs) {
 418
 419     # copy for _normalize_selection
 420     $call_attrs = { %$call_attrs };
 421
 422     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 423
 424     # reset the current selector list if new selectors are supplied
 425     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 426       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 427     }
 428
 429     # Normalize the new selector list (operates on the passed-in attr structure)
 430     # Need to do it on every chain instead of only once on _resolved_attrs, in
 431     # order to allow detection of empty vs partial 'as'
 432     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 433       if $old_attrs->{_dark_selector};
 434     $self->_normalize_selection ($call_attrs);
 435
 436     # start with blind overwriting merge, exclude selector attrs
 437     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 438     delete @{$new_attrs}{@selector_attrs};
 439
 440     for (@selector_attrs) {
 441       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 442         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 443     }
 444
 445     # older deprecated name, use only if {columns} is not there
 446     if (my $c = delete $new_attrs->{cols}) {
 447       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 448       if ($new_attrs->{columns}) {
 449         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 450       }
 451       else {
 452         $new_attrs->{columns} = $c;
 453       }
 454     }
 455
 456
 457     # join/prefetch use their own crazy merging heuristics
 458     foreach my $key (qw/join prefetch/) {
 459       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 460         if exists $call_attrs->{$key};
 461     }
 462
 463     # stack binds together
 464     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 465   }
 466
 467
 468   for ($old_where, $call_cond) {
 469     if (defined $_) {
 470       $new_attrs->{where} = $self->_stack_cond (
 471         $_, $new_attrs->{where}
 472       );
 473     }
 474   }
 475
 476   if (defined $old_having) {
 477     $new_attrs->{having} = $self->_stack_cond (
 478       $old_having, $new_attrs->{having}
 479     )
 480   }
 481
 482   my $rs = (ref $self)->new($rsrc, $new_attrs);
 483
 484   $rs->set_cache($cache) if ($cache);
 485
 486   return $rs;
 487 }
 488
 489 my $dark_sel_dumper;
 490 sub _normalize_selection {
 491   my ($self, $attrs) = @_;
 492
 493   # legacy syntax
 494   if ( exists $attrs->{include_columns} ) {
 495     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 496     $attrs->{'+columns'} = $self->_merge_attr(
 497       $attrs->{'+columns'}, delete $attrs->{include_columns}
 498     );
 499   }
 500
 501   # columns are always placed first, however
 502
 503   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 504   # delay the decision on whether to use a default select list ($rsrc->columns)
 505   # allowing stuff like the remove_columns helper to work
 506   #
 507   # select/as +select/+as pairs need special handling - the amount of select/as
 508   # elements in each pair does *not* have to be equal (think multicolumn
 509   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 510   # supplied at all) - try to infer the alias, either from the -as parameter
 511   # of the selector spec, or use the parameter whole if it looks like a column
 512   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 513   # is ok as well), but make sure no more additions to the 'as' chain take place
 514   for my $pref ('', '+') {
 515
 516     my ($sel, $as) = map {
 517       my $key = "${pref}${_}";
 518
 519       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 520         ? @{$attrs->{$key}}
 521         : $attrs->{$key} || ()
 522       ];
 523       delete $attrs->{$key};
 524       $val;
 525     } qw/select as/;
 526
 527     if (! @$as and ! @$sel ) {
 528       next;
 529     }
 530     elsif (@$as and ! @$sel) {
 531       $self->throw_exception(
 532         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 533       );
 534     }
 535     elsif( ! @$as ) {
 536       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 537       # if any @$as has been supplied we assume the user knows what (s)he is doing
 538       # and blindly keep stacking up pieces
 539       unless ($attrs->{_dark_selector}) {
 540         SELECTOR:
 541         for (@$sel) {
 542           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 543             push @$as, $_->{-as};
 544           }
 545           # assume any plain no-space, no-parenthesis string to be a column spec
 546           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 547           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 548             push @$as, $_;
 549           }
 550           # if all else fails - raise a flag that no more aliasing will be allowed
 551           else {
 552             $attrs->{_dark_selector} = {
 553               plus_stage => $pref,
 554               string => ($dark_sel_dumper ||= do {
 555                   require Data::Dumper::Concise;
 556                   Data::Dumper::Concise::DumperObject()->Indent(0);
 557                 })->Values([$_])->Dump
 558               ,
 559             };
 560             last SELECTOR;
 561           }
 562         }
 563       }
 564     }
 565     elsif (@$as < @$sel) {
 566       $self->throw_exception(
 567         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 568       );
 569     }
 570     elsif ($pref and $attrs->{_dark_selector}) {
 571       $self->throw_exception(
 572         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 573       );
 574     }
 575
 576
 577     # merge result
 578     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 579     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 580   }
 581 }
 582
 583 sub _stack_cond {
 584   my ($self, $left, $right) = @_;
 585
 586   # collapse single element top-level conditions
 587   # (single pass only, unlikely to need recursion)
 588   for ($left, $right) {
 589     if (ref $_ eq 'ARRAY') {
 590       if (@$_ == 0) {
 591         $_ = undef;
 592       }
 593       elsif (@$_ == 1) {
 594         $_ = $_->[0];
 595       }
 596     }
 597     elsif (ref $_ eq 'HASH') {
 598       my ($first, $more) = keys %$_;
 599
 600       # empty hash
 601       if (! defined $first) {
 602         $_ = undef;
 603       }
 604       # one element hash
 605       elsif (! defined $more) {
 606         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 607           $_ = $_->{'-and'};
 608         }
 609         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 610           $_ = $_->{'-or'};
 611         }
 612       }
 613     }
 614   }
 615
 616   # merge hashes with weeding out of duplicates (simple cases only)
 617   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 618
 619     # shallow copy to destroy
 620     $right = { %$right };
 621     for (grep { exists $right->{$_} } keys %$left) {
 622       # the use of eq_deeply here is justified - the rhs of an
 623       # expression can contain a lot of twisted weird stuff
 624       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 625     }
 626
 627     $right = undef unless keys %$right;
 628   }
 629
 630
 631   if (defined $left xor defined $right) {
 632     return defined $left ? $left : $right;
 633   }
 634   elsif (! defined $left) {
 635     return undef;
 636   }
 637   else {
 638     return { -and => [ $left, $right ] };
 639   }
 640 }
 641
 642 =head2 search_literal
 643
 644 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 645 should only be used in that context. C<search_literal> is a convenience
 646 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 647 want to ensure columns are bound correctly, use L</search>.
 648
 649 See L<DBIx::Class::Manual::Cookbook/Searching> and
 650 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 651 require C<search_literal>.
 652
 653 =over 4
 654
 655 =item Arguments: $sql_fragment, @standalone_bind_values
 656
 657 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 658
 659 =back
 660
 661   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 662   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 663
 664 Pass a literal chunk of SQL to be added to the conditional part of the
 665 resultset query.
 666
 667 Example of how to use C<search> instead of C<search_literal>
 668
 669   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 670   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 671
 672 =cut
 673
 674 sub search_literal {
 675   my ($self, $sql, @bind) = @_;
 676   my $attr;
 677   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 678     $attr = pop @bind;
 679   }
 680   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 681 }
 682
 683 =head2 find
 684
 685 =over 4
 686
 687 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 688
 689 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 690
 691 =back
 692
 693 Finds and returns a single row based on supplied criteria. Takes either a
 694 hashref with the same format as L</create> (including inference of foreign
 695 keys from related objects), or a list of primary key values in the same
 696 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 697 declaration on the L</result_source>.
 698
 699 In either case an attempt is made to combine conditions already existing on
 700 the resultset with the condition passed to this method.
 701
 702 To aid with preparing the correct query for the storage you may supply the
 703 C<key> attribute, which is the name of a
 704 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 705 unique constraint corresponding to the
 706 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 707 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 708 to construct a query that satisfies the named unique constraint fully (
 709 non-NULL values for each column member of the constraint) an exception is
 710 thrown.
 711
 712 If no C<key> is specified, the search is carried over all unique constraints
 713 which are fully defined by the available condition.
 714
 715 If no such constraint is found, C<find> currently defaults to a simple
 716 C<< search->(\%column_values) >> which may or may not do what you expect.
 717 Note that this fallback behavior may be deprecated in further versions. If
 718 you need to search with arbitrary conditions - use L</search>. If the query
 719 resulting from this fallback produces more than one row, a warning to the
 720 effect is issued, though only the first row is constructed and returned as
 721 C<$result_object>.
 722
 723 In addition to C<key>, L</find> recognizes and applies standard
 724 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 725
 726 Note that if you have extra concerns about the correctness of the resulting
 727 query you need to specify the C<key> attribute and supply the entire condition
 728 as an argument to find (since it is not always possible to perform the
 729 combination of the resultset condition with the supplied one, especially if
 730 the resultset condition contains literal sql).
 731
 732 For example, to find a row by its primary key:
 733
 734   my $cd = $schema->resultset('CD')->find(5);
 735
 736 You can also find a row by a specific unique constraint:
 737
 738   my $cd = $schema->resultset('CD')->find(
 739     {
 740       artist => 'Massive Attack',
 741       title  => 'Mezzanine',
 742     },
 743     { key => 'cd_artist_title' }
 744   );
 745
 746 See also L</find_or_create> and L</update_or_create>.
 747
 748 =cut
 749
 750 sub find {
 751   my $self = shift;
 752   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 753
 754   my $rsrc = $self->result_source;
 755
 756   my $constraint_name;
 757   if (exists $attrs->{key}) {
 758     $constraint_name = defined $attrs->{key}
 759       ? $attrs->{key}
 760       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 761     ;
 762   }
 763
 764   # Parse out the condition from input
 765   my $call_cond;
 766
 767   if (ref $_[0] eq 'HASH') {
 768     $call_cond = { %{$_[0]} };
 769   }
 770   else {
 771     # if only values are supplied we need to default to 'primary'
 772     $constraint_name = 'primary' unless defined $constraint_name;
 773
 774     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 775
 776     $self->throw_exception(
 777       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 778     ) unless @c_cols;
 779
 780     $self->throw_exception (
 781       'find() expects either a column/value hashref, or a list of values '
 782     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 783     ) unless @c_cols == @_;
 784
 785     $call_cond = {};
 786     @{$call_cond}{@c_cols} = @_;
 787   }
 788
 789   my %related;
 790   for my $key (keys %$call_cond) {
 791     if (
 792       my $keyref = ref($call_cond->{$key})
 793         and
 794       my $relinfo = $rsrc->relationship_info($key)
 795     ) {
 796       my $val = delete $call_cond->{$key};
 797
 798       next if $keyref eq 'ARRAY'; # has_many for multi_create
 799
 800       my $rel_q = $rsrc->_resolve_condition(
 801         $relinfo->{cond}, $val, $key, $key
 802       );
 803       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 804       @related{keys %$rel_q} = values %$rel_q;
 805     }
 806   }
 807
 808   # relationship conditions take precedence (?)
 809   @{$call_cond}{keys %related} = values %related;
 810
 811   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 812   my $final_cond;
 813   if (defined $constraint_name) {
 814     $final_cond = $self->_qualify_cond_columns (
 815
 816       $self->_build_unique_cond (
 817         $constraint_name,
 818         $call_cond,
 819       ),
 820
 821       $alias,
 822     );
 823   }
 824   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 825     # This means that we got here after a merger of relationship conditions
 826     # in ::Relationship::Base::search_related (the row method), and furthermore
 827     # the relationship is of the 'single' type. This means that the condition
 828     # provided by the relationship (already attached to $self) is sufficient,
 829     # as there can be only one row in the database that would satisfy the
 830     # relationship
 831   }
 832   else {
 833     # no key was specified - fall down to heuristics mode:
 834     # run through all unique queries registered on the resultset, and
 835     # 'OR' all qualifying queries together
 836     my (@unique_queries, %seen_column_combinations);
 837     for my $c_name ($rsrc->unique_constraint_names) {
 838       next if $seen_column_combinations{
 839         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 840       }++;
 841
 842       push @unique_queries, try {
 843         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 844       } || ();
 845     }
 846
 847     $final_cond = @unique_queries
 848       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 849       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 850     ;
 851   }
 852
 853   # Run the query, passing the result_class since it should propagate for find
 854   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 855   if ($rs->_resolved_attrs->{collapse}) {
 856     my $row = $rs->next;
 857     carp "Query returned more than one row" if $rs->next;
 858     return $row;
 859   }
 860   else {
 861     return $rs->single;
 862   }
 863 }
 864
 865 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 866 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 867 #
 868 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 869 # condition. It is provided for overrides until a saner way forward is devised
 870 #
 871 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 872 # the road. Please adjust your tests accordingly to catch this situation early
 873 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 874 #
 875 # The method will not be removed without an adequately complete replacement
 876 # for strict-mode enforcement
 877 sub _non_unique_find_fallback {
 878   my ($self, $cond, $attrs) = @_;
 879
 880   return $self->_qualify_cond_columns(
 881     $cond,
 882     exists $attrs->{alias}
 883       ? $attrs->{alias}
 884       : $self->{attrs}{alias}
 885   );
 886 }
 887
 888
 889 sub _qualify_cond_columns {
 890   my ($self, $cond, $alias) = @_;
 891
 892   my %aliased = %$cond;
 893   for (keys %aliased) {
 894     $aliased{"$alias.$_"} = delete $aliased{$_}
 895       if $_ !~ /\./;
 896   }
 897
 898   return \%aliased;
 899 }
 900
 901 sub _build_unique_cond {
 902   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 903
 904   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 905
 906   # combination may fail if $self->{cond} is non-trivial
 907   my ($final_cond) = try {
 908     $self->_merge_with_rscond ($extra_cond)
 909   } catch {
 910     +{ %$extra_cond }
 911   };
 912
 913   # trim out everything not in $columns
 914   $final_cond = { map {
 915     exists $final_cond->{$_}
 916       ? ( $_ => $final_cond->{$_} )
 917       : ()
 918   } @c_cols };
 919
 920   if (my @missing = grep
 921     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 922     (@c_cols)
 923   ) {
 924     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 925       $constraint_name,
 926       join (', ', map { "'$_'" } @missing),
 927     ) );
 928   }
 929
 930   if (
 931     !$croak_on_null
 932       and
 933     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 934       and
 935     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 936   ) {
 937     carp_unique ( sprintf (
 938       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 939     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 940     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 941       $constraint_name,
 942       join (', ', map { "'$_'" } @undefs),
 943     ));
 944   }
 945
 946   return $final_cond;
 947 }
 948
 949 =head2 search_related
 950
 951 =over 4
 952
 953 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 954
 955 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 956
 957 =back
 958
 959   $new_rs = $cd_rs->search_related('artist', {
 960     name => 'Emo-R-Us',
 961   });
 962
 963 Searches the specified relationship, optionally specifying a condition and
 964 attributes for matching records. See L</ATTRIBUTES> for more information.
 965
 966 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 967 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 968
 969 See also L</search_related_rs>.
 970
 971 =cut
 972
 973 sub search_related {
 974   return shift->related_resultset(shift)->search(@_);
 975 }
 976
 977 =head2 search_related_rs
 978
 979 This method works exactly the same as search_related, except that
 980 it guarantees a resultset, even in list context.
 981
 982 =cut
 983
 984 sub search_related_rs {
 985   return shift->related_resultset(shift)->search_rs(@_);
 986 }
 987
 988 =head2 cursor
 989
 990 =over 4
 991
 992 =item Arguments: none
 993
 994 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 995
 996 =back
 997
 998 Returns a storage-driven cursor to the given resultset. See
 999 L<DBIx::Class::Cursor> for more information.
1000
1001 =cut
1002
1003 sub cursor {
1004   my $self = shift;
1005
1006   return $self->{cursor} ||= do {
1007     my $attrs = $self->_resolved_attrs;
1008     $self->result_source->storage->select(
1009       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1010     );
1011   };
1012 }
1013
1014 =head2 single
1015
1016 =over 4
1017
1018 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1019
1020 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1021
1022 =back
1023
1024   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1025
1026 Inflates the first result without creating a cursor if the resultset has
1027 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1028 of L</search>.
1029
1030 While this method can take an optional search condition (just like L</search>)
1031 being a fast-code-path it does not recognize search attributes. If you need to
1032 add extra joins or similar, call L</search> and then chain-call L</single> on the
1033 L<DBIx::Class::ResultSet> returned.
1034
1035 =over
1036
1037 =item B<Note>
1038
1039 As of 0.08100, this method enforces the assumption that the preceding
1040 query returns only one row. If more than one row is returned, you will receive
1041 a warning:
1042
1043   Query returned more than one row
1044
1045 In this case, you should be using L</next> or L</find> instead, or if you really
1046 know what you are doing, use the L</rows> attribute to explicitly limit the size
1047 of the resultset.
1048
1049 This method will also throw an exception if it is called on a resultset prefetching
1050 has_many, as such a prefetch implies fetching multiple rows from the database in
1051 order to assemble the resulting object.
1052
1053 =back
1054
1055 =cut
1056
1057 sub single {
1058   my ($self, $where) = @_;
1059   if(@_ > 2) {
1060       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1061   }
1062
1063   my $attrs = { %{$self->_resolved_attrs} };
1064
1065   $self->throw_exception(
1066     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1067   ) if $attrs->{collapse};
1068
1069   if ($where) {
1070     if (defined $attrs->{where}) {
1071       $attrs->{where} = {
1072         '-and' =>
1073             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1074                $where, delete $attrs->{where} ]
1075       };
1076     } else {
1077       $attrs->{where} = $where;
1078     }
1079   }
1080
1081   my $data = [ $self->result_source->storage->select_single(
1082     $attrs->{from}, $attrs->{select},
1083     $attrs->{where}, $attrs
1084   )];
1085
1086   return undef unless @$data;
1087   $self->{_stashed_rows} = [ $data ];
1088   $self->_construct_results->[0];
1089 }
1090
1091
1092 # _collapse_query
1093 #
1094 # Recursively collapse the query, accumulating values for each column.
1095
1096 sub _collapse_query {
1097   my ($self, $query, $collapsed) = @_;
1098
1099   $collapsed ||= {};
1100
1101   if (ref $query eq 'ARRAY') {
1102     foreach my $subquery (@$query) {
1103       next unless ref $subquery;  # -or
1104       $collapsed = $self->_collapse_query($subquery, $collapsed);
1105     }
1106   }
1107   elsif (ref $query eq 'HASH') {
1108     if (keys %$query and (keys %$query)[0] eq '-and') {
1109       foreach my $subquery (@{$query->{-and}}) {
1110         $collapsed = $self->_collapse_query($subquery, $collapsed);
1111       }
1112     }
1113     else {
1114       foreach my $col (keys %$query) {
1115         my $value = $query->{$col};
1116         $collapsed->{$col}{$value}++;
1117       }
1118     }
1119   }
1120
1121   return $collapsed;
1122 }
1123
1124 =head2 get_column
1125
1126 =over 4
1127
1128 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1129
1130 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1131
1132 =back
1133
1134   my $max_length = $rs->get_column('length')->max;
1135
1136 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1137
1138 =cut
1139
1140 sub get_column {
1141   my ($self, $column) = @_;
1142   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1143   return $new;
1144 }
1145
1146 =head2 search_like
1147
1148 =over 4
1149
1150 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1151
1152 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1153
1154 =back
1155
1156   # WHERE title LIKE '%blue%'
1157   $cd_rs = $rs->search_like({ title => '%blue%'});
1158
1159 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1160 that this is simply a convenience method retained for ex Class::DBI users.
1161 You most likely want to use L</search> with specific operators.
1162
1163 For more information, see L<DBIx::Class::Manual::Cookbook>.
1164
1165 This method is deprecated and will be removed in 0.09. Use L</search()>
1166 instead. An example conversion is:
1167
1168   ->search_like({ foo => 'bar' });
1169
1170   # Becomes
1171
1172   ->search({ foo => { like => 'bar' } });
1173
1174 =cut
1175
1176 sub search_like {
1177   my $class = shift;
1178   carp_unique (
1179     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1180    .' Instead use ->search({ x => { -like => "y%" } })'
1181    .' (note the outer pair of {}s - they are important!)'
1182   );
1183   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1184   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1185   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1186   return $class->search($query, { %$attrs });
1187 }
1188
1189 =head2 slice
1190
1191 =over 4
1192
1193 =item Arguments: $first, $last
1194
1195 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1196
1197 =back
1198
1199 Returns a resultset or object list representing a subset of elements from the
1200 resultset slice is called on. Indexes are from 0, i.e., to get the first
1201 three records, call:
1202
1203   my ($one, $two, $three) = $rs->slice(0, 2);
1204
1205 =cut
1206
1207 sub slice {
1208   my ($self, $min, $max) = @_;
1209   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1210   $attrs->{offset} = $self->{attrs}{offset} || 0;
1211   $attrs->{offset} += $min;
1212   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1213   return $self->search(undef, $attrs);
1214   #my $slice = (ref $self)->new($self->result_source, $attrs);
1215   #return (wantarray ? $slice->all : $slice);
1216 }
1217
1218 =head2 next
1219
1220 =over 4
1221
1222 =item Arguments: none
1223
1224 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1225
1226 =back
1227
1228 Returns the next element in the resultset (C<undef> is there is none).
1229
1230 Can be used to efficiently iterate over records in the resultset:
1231
1232   my $rs = $schema->resultset('CD')->search;
1233   while (my $cd = $rs->next) {
1234     print $cd->title;
1235   }
1236
1237 Note that you need to store the resultset object, and call C<next> on it.
1238 Calling C<< resultset('Table')->next >> repeatedly will always return the
1239 first record from the resultset.
1240
1241 =cut
1242
1243 sub next {
1244   my ($self) = @_;
1245
1246   if (my $cache = $self->get_cache) {
1247     $self->{all_cache_position} ||= 0;
1248     return $cache->[$self->{all_cache_position}++];
1249   }
1250
1251   if ($self->{attrs}{cache}) {
1252     delete $self->{pager};
1253     $self->{all_cache_position} = 1;
1254     return ($self->all)[0];
1255   }
1256
1257   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1258
1259   $self->{_stashed_results} = $self->_construct_results
1260     or return undef;
1261
1262   return shift @{$self->{_stashed_results}};
1263 }
1264
1265 # Constructs as many results as it can in one pass while respecting
1266 # cursor laziness. Several modes of operation:
1267 #
1268 # * Always builds everything present in @{$self->{_stashed_rows}}
1269 # * If called with $fetch_all true - pulls everything off the cursor and
1270 #   builds all result structures (or objects) in one pass
1271 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1272 #   and if the resultset is ordered properly by the left side:
1273 #   * Fetches stuff off the cursor until the "master object" changes,
1274 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1275 #   OR
1276 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1277 #     was requested (there is no other way to collapse except for an
1278 #     eager cursor)
1279 # * If no collapse is requested - just get the next row, construct and
1280 #   return
1281 sub _construct_results {
1282   my ($self, $fetch_all) = @_;
1283
1284   my $rsrc = $self->result_source;
1285   my $attrs = $self->_resolved_attrs;
1286
1287   if (
1288     ! $fetch_all
1289       and
1290     ! $attrs->{order_by}
1291       and
1292     $attrs->{collapse}
1293       and
1294     my @pcols = $rsrc->primary_columns
1295   ) {
1296     # default order for collapsing unless the user asked for something
1297     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1298     $attrs->{_ordered_for_collapse} = 1;
1299     $attrs->{_order_is_artificial} = 1;
1300   }
1301
1302   # this will be used as both initial raw-row collector AND as a RV of
1303   # _construct_results. Not regrowing the array twice matters a lot...
1304   # a surprising amount actually
1305   my $rows = delete $self->{_stashed_rows};
1306
1307   my $cursor; # we may not need one at all
1308
1309   my $did_fetch_all = $fetch_all;
1310
1311   if ($fetch_all) {
1312     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1313     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1314   }
1315   elsif( $attrs->{collapse} ) {
1316
1317     # a cursor will need to be closed over in case of collapse
1318     $cursor = $self->cursor;
1319
1320     $attrs->{_ordered_for_collapse} = (
1321       (
1322         $attrs->{order_by}
1323           and
1324         $rsrc->schema
1325               ->storage
1326                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1327       ) ? 1 : 0
1328     ) unless defined $attrs->{_ordered_for_collapse};
1329
1330     if (! $attrs->{_ordered_for_collapse}) {
1331       $did_fetch_all = 1;
1332
1333       # instead of looping over ->next, use ->all in stealth mode
1334       # *without* calling a ->reset afterwards
1335       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1336       if (! $cursor->{_done}) {
1337         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1338         $cursor->{_done} = 1;
1339       }
1340     }
1341   }
1342
1343   if (! $did_fetch_all and ! @{$rows||[]} ) {
1344     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1345     $cursor ||= $self->cursor;
1346     if (scalar (my @r = $cursor->next) ) {
1347       $rows = [ \@r ];
1348     }
1349   }
1350
1351   return undef unless @{$rows||[]};
1352
1353   # sanity check - people are too clever for their own good
1354   if ($attrs->{collapse} and my $aliastypes = $attrs->{_sqlmaker_select_args}[3]{_aliastypes} ) {
1355
1356     my $multiplied_selectors;
1357     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1358       if (
1359         $aliastypes->{multiplying}{$sel_alias}
1360           or
1361         scalar grep { $aliastypes->{multiplying}{(values %$_)[0]} } @{ $aliastypes->{selecting}{$sel_alias}{-parents} }
1362       ) {
1363         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1364       }
1365     }
1366
1367     for my $i (0 .. $#{$attrs->{as}} ) {
1368       my $sel = $attrs->{select}[$i];
1369
1370       if (ref $sel eq 'SCALAR') {
1371         $sel = $$sel;
1372       }
1373       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1374         $sel = $$sel->[0];
1375       }
1376
1377       $self->throw_exception(
1378         'Result collapse not possible - selection from a has_many source redirected to the main object'
1379       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1380     }
1381   }
1382
1383   # hotspot - skip the setter
1384   my $res_class = $self->_result_class;
1385
1386   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1387     $res_class->can ('inflate_result')
1388       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1389   };
1390
1391   my $infmap = $attrs->{as};
1392
1393   $self->{_result_inflator}{is_core_row} = ( (
1394     $inflator_cref
1395       ==
1396     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1397   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1398
1399   $self->{_result_inflator}{is_hri} = ( (
1400     ! $self->{_result_inflator}{is_core_row}
1401       and
1402     $inflator_cref == (
1403       require DBIx::Class::ResultClass::HashRefInflator
1404         &&
1405       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1406     )
1407   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1408
1409
1410   if (! $attrs->{_related_results_construction}) {
1411     # construct a much simpler array->hash folder for the one-table cases right here
1412     if ($self->{_result_inflator}{is_hri}) {
1413       for my $r (@$rows) {
1414         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1415       }
1416     }
1417     # FIXME SUBOPTIMAL this is a very very very hot spot
1418     # while rather optimal we can *still* do much better, by
1419     # building a smarter Row::inflate_result(), and
1420     # switch to feeding it data via a much leaner interface
1421     #
1422     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1423     # this particular resultset size
1424     elsif (@$rows < 60) {
1425       for my $r (@$rows) {
1426         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1427       }
1428     }
1429     else {
1430       eval sprintf (
1431         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1432         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1433       );
1434     }
1435   }
1436   else {
1437     my $parser_type =
1438         $self->{_result_inflator}{is_hri}       ? 'hri'
1439       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1440       :                                           'classic_nonpruning'
1441     ;
1442
1443     # $args and $attrs to _mk_row_parser are separated to delineate what is
1444     # core collapser stuff and what is dbic $rs specific
1445     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1446       eval => 1,
1447       inflate_map => $infmap,
1448       collapse => $attrs->{collapse},
1449       premultiplied => $attrs->{_main_source_premultiplied},
1450       hri_style => $self->{_result_inflator}{is_hri},
1451       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1452     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1453
1454     # column_info metadata historically hasn't been too reliable.
1455     # We need to start fixing this somehow (the collapse resolver
1456     # can't work without it). Add an explicit check for the *main*
1457     # result, hopefully this will gradually weed out such errors
1458     #
1459     # FIXME - this is a temporary kludge that reduces performance
1460     # It is however necessary for the time being
1461     my ($unrolled_non_null_cols_to_check, $err);
1462
1463     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1464
1465       $err =
1466         'Collapse aborted due to invalid ResultSource metadata - the following '
1467       . 'selections are declared non-nullable but NULLs were retrieved: '
1468       ;
1469
1470       my @violating_idx;
1471       COL: for my $i (@$check_non_null_cols) {
1472         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1473       }
1474
1475       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1476         if @violating_idx;
1477
1478       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1479     }
1480
1481     my $next_cref =
1482       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1483     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1484 sub {
1485   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1486   my @r = $cursor->next or return;
1487   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1488     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1489   }
1490   \@r
1491 }
1492 EOS
1493     : sub {
1494         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1495         my @r = $cursor->next or return;
1496         \@r
1497       }
1498     ;
1499
1500     $self->{_row_parser}{$parser_type}{cref}->(
1501       $rows,
1502       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1503     );
1504
1505     # Special-case multi-object HRI - there is no $inflator_cref pass
1506     unless ($self->{_result_inflator}{is_hri}) {
1507       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1508     }
1509   }
1510
1511   # The @$rows check seems odd at first - why wouldn't we want to warn
1512   # regardless? The issue is things like find() etc, where the user
1513   # *knows* only one result will come back. In these cases the ->all
1514   # is not a pessimization, but rather something we actually want
1515   carp_unique(
1516     'Unable to properly collapse has_many results in iterator mode due '
1517   . 'to order criteria - performed an eager cursor slurp underneath. '
1518   . 'Consider using ->all() instead'
1519   ) if ( ! $fetch_all and @$rows > 1 );
1520
1521   return $rows;
1522 }
1523
1524 =head2 result_source
1525
1526 =over 4
1527
1528 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1529
1530 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1531
1532 =back
1533
1534 An accessor for the primary ResultSource object from which this ResultSet
1535 is derived.
1536
1537 =head2 result_class
1538
1539 =over 4
1540
1541 =item Arguments: $result_class?
1542
1543 =item Return Value: $result_class
1544
1545 =back
1546
1547 An accessor for the class to use when creating result objects. Defaults to
1548 C<< result_source->result_class >> - which in most cases is the name of the
1549 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1550
1551 Note that changing the result_class will also remove any components
1552 that were originally loaded in the source class via
1553 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1554 in the original source class will not run.
1555
1556 =cut
1557
1558 sub result_class {
1559   my ($self, $result_class) = @_;
1560   if ($result_class) {
1561
1562     # don't fire this for an object
1563     $self->ensure_class_loaded($result_class)
1564       unless ref($result_class);
1565
1566     if ($self->get_cache) {
1567       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1568     }
1569     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1570     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1571       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1572     }
1573
1574     $self->_result_class($result_class);
1575
1576     delete $self->{_result_inflator};
1577   }
1578   $self->_result_class;
1579 }
1580
1581 =head2 count
1582
1583 =over 4
1584
1585 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1586
1587 =item Return Value: $count
1588
1589 =back
1590
1591 Performs an SQL C<COUNT> with the same query as the resultset was built
1592 with to find the number of elements. Passing arguments is equivalent to
1593 C<< $rs->search ($cond, \%attrs)->count >>
1594
1595 =cut
1596
1597 sub count {
1598   my $self = shift;
1599   return $self->search(@_)->count if @_ and defined $_[0];
1600   return scalar @{ $self->get_cache } if $self->get_cache;
1601
1602   my $attrs = { %{ $self->_resolved_attrs } };
1603
1604   # this is a little optimization - it is faster to do the limit
1605   # adjustments in software, instead of a subquery
1606   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1607
1608   my $crs;
1609   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1610     $crs = $self->_count_subq_rs ($attrs);
1611   }
1612   else {
1613     $crs = $self->_count_rs ($attrs);
1614   }
1615   my $count = $crs->next;
1616
1617   $count -= $offset if $offset;
1618   $count = $rows if $rows and $rows < $count;
1619   $count = 0 if ($count < 0);
1620
1621   return $count;
1622 }
1623
1624 =head2 count_rs
1625
1626 =over 4
1627
1628 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1629
1630 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1631
1632 =back
1633
1634 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1635 This can be very handy for subqueries:
1636
1637   ->search( { amount => $some_rs->count_rs->as_query } )
1638
1639 As with regular resultsets the SQL query will be executed only after
1640 the resultset is accessed via L</next> or L</all>. That would return
1641 the same single value obtainable via L</count>.
1642
1643 =cut
1644
1645 sub count_rs {
1646   my $self = shift;
1647   return $self->search(@_)->count_rs if @_;
1648
1649   # this may look like a lack of abstraction (count() does about the same)
1650   # but in fact an _rs *must* use a subquery for the limits, as the
1651   # software based limiting can not be ported if this $rs is to be used
1652   # in a subquery itself (i.e. ->as_query)
1653   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1654     return $self->_count_subq_rs($self->{_attrs});
1655   }
1656   else {
1657     return $self->_count_rs($self->{_attrs});
1658   }
1659 }
1660
1661 #
1662 # returns a ResultSetColumn object tied to the count query
1663 #
1664 sub _count_rs {
1665   my ($self, $attrs) = @_;
1666
1667   my $rsrc = $self->result_source;
1668
1669   my $tmp_attrs = { %$attrs };
1670   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1671   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1672
1673   # overwrite the selector (supplied by the storage)
1674   $rsrc->resultset_class->new($rsrc, {
1675     %$tmp_attrs,
1676     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1677     as => 'count',
1678   })->get_column ('count');
1679 }
1680
1681 #
1682 # same as above but uses a subquery
1683 #
1684 sub _count_subq_rs {
1685   my ($self, $attrs) = @_;
1686
1687   my $rsrc = $self->result_source;
1688
1689   my $sub_attrs = { %$attrs };
1690   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1691   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1692
1693   # if we multi-prefetch we group_by something unique, as this is what we would
1694   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1695   if ( $attrs->{collapse}  ) {
1696     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1697       $rsrc->_identifying_column_set || $self->throw_exception(
1698         'Unable to construct a unique group_by criteria properly collapsing the '
1699       . 'has_many prefetch before count()'
1700       );
1701     } ]
1702   }
1703
1704   # Calculate subquery selector
1705   if (my $g = $sub_attrs->{group_by}) {
1706
1707     my $sql_maker = $rsrc->storage->sql_maker;
1708
1709     # necessary as the group_by may refer to aliased functions
1710     my $sel_index;
1711     for my $sel (@{$attrs->{select}}) {
1712       $sel_index->{$sel->{-as}} = $sel
1713         if (ref $sel eq 'HASH' and $sel->{-as});
1714     }
1715
1716     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1717     # also look for named aggregates referred in the having clause
1718     # having often contains scalarrefs - thus parse it out entirely
1719     my @parts = @$g;
1720     if ($attrs->{having}) {
1721       local $sql_maker->{having_bind};
1722       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1723       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1724       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1725         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1726         # if we don't unset it we screw up retarded but unfortunately working
1727         # 'MAX(foo.bar)' => { '>', 3 }
1728         $sql_maker->{name_sep} = '';
1729       }
1730
1731       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1732
1733       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1734       my %seen_having;
1735
1736       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1737       # and if all fails for an utterly naive quoted scalar-with-function
1738       while ($having_sql =~ /
1739         $rquote $sep $lquote (.+?) $rquote
1740           |
1741         [\s,] \w+ \. (\w+) [\s,]
1742           |
1743         [\s,] $lquote (.+?) $rquote [\s,]
1744       /gx) {
1745         my $part = $1 || $2 || $3;  # one of them matched if we got here
1746         unless ($seen_having{$part}++) {
1747           push @parts, $part;
1748         }
1749       }
1750     }
1751
1752     for (@parts) {
1753       my $colpiece = $sel_index->{$_} || $_;
1754
1755       # unqualify join-based group_by's. Arcane but possible query
1756       # also horrible horrible hack to alias a column (not a func.)
1757       # (probably need to introduce SQLA syntax)
1758       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1759         my $as = $colpiece;
1760         $as =~ s/\./__/;
1761         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1762       }
1763       push @{$sub_attrs->{select}}, $colpiece;
1764     }
1765   }
1766   else {
1767     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1768     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1769   }
1770
1771   return $rsrc->resultset_class
1772                ->new ($rsrc, $sub_attrs)
1773                 ->as_subselect_rs
1774                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1775                   ->get_column ('count');
1776 }
1777
1778
1779 =head2 count_literal
1780
1781 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1782 should only be used in that context. See L</search_literal> for further info.
1783
1784 =over 4
1785
1786 =item Arguments: $sql_fragment, @standalone_bind_values
1787
1788 =item Return Value: $count
1789
1790 =back
1791
1792 Counts the results in a literal query. Equivalent to calling L</search_literal>
1793 with the passed arguments, then L</count>.
1794
1795 =cut
1796
1797 sub count_literal { shift->search_literal(@_)->count; }
1798
1799 =head2 all
1800
1801 =over 4
1802
1803 =item Arguments: none
1804
1805 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1806
1807 =back
1808
1809 Returns all elements in the resultset.
1810
1811 =cut
1812
1813 sub all {
1814   my $self = shift;
1815   if(@_) {
1816     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1817   }
1818
1819   delete @{$self}{qw/_stashed_rows _stashed_results/};
1820
1821   if (my $c = $self->get_cache) {
1822     return @$c;
1823   }
1824
1825   $self->cursor->reset;
1826
1827   my $objs = $self->_construct_results('fetch_all') || [];
1828
1829   $self->set_cache($objs) if $self->{attrs}{cache};
1830
1831   return @$objs;
1832 }
1833
1834 =head2 reset
1835
1836 =over 4
1837
1838 =item Arguments: none
1839
1840 =item Return Value: $self
1841
1842 =back
1843
1844 Resets the resultset's cursor, so you can iterate through the elements again.
1845 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1846 another query.
1847
1848 =cut
1849
1850 sub reset {
1851   my ($self) = @_;
1852
1853   delete @{$self}{qw/_stashed_rows _stashed_results/};
1854   $self->{all_cache_position} = 0;
1855   $self->cursor->reset;
1856   return $self;
1857 }
1858
1859 =head2 first
1860
1861 =over 4
1862
1863 =item Arguments: none
1864
1865 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1866
1867 =back
1868
1869 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1870 an object for the first result (or C<undef> if the resultset is empty).
1871
1872 =cut
1873
1874 sub first {
1875   return $_[0]->reset->next;
1876 }
1877
1878
1879 # _rs_update_delete
1880 #
1881 # Determines whether and what type of subquery is required for the $rs operation.
1882 # If grouping is necessary either supplies its own, or verifies the current one
1883 # After all is done delegates to the proper storage method.
1884
1885 sub _rs_update_delete {
1886   my ($self, $op, $values) = @_;
1887
1888   my $rsrc = $self->result_source;
1889   my $storage = $rsrc->schema->storage;
1890
1891   my $attrs = { %{$self->_resolved_attrs} };
1892
1893   my $join_classifications;
1894   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1895
1896   # do we need a subquery for any reason?
1897   my $needs_subq = (
1898     defined $existing_group_by
1899       or
1900     # if {from} is unparseable wrap a subq
1901     ref($attrs->{from}) ne 'ARRAY'
1902       or
1903     # limits call for a subq
1904     $self->_has_resolved_attr(qw/rows offset/)
1905   );
1906
1907   # simplify the joinmap, so we can further decide if a subq is necessary
1908   if (!$needs_subq and @{$attrs->{from}} > 1) {
1909
1910     ($attrs->{from}, $join_classifications) =
1911       $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1912
1913     # any non-pruneable non-local restricting joins imply subq
1914     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1915   }
1916
1917   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1918   $needs_subq ||= (
1919     (ref $attrs->{from}[0]) ne 'HASH'
1920       or
1921     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1922   );
1923
1924   my ($cond, $guard);
1925   # do we need anything like a subquery?
1926   if (! $needs_subq) {
1927     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1928     # a condition containing 'me' or other table prefixes will not work
1929     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1930     if ($self->{cond}) {
1931       $cond = do {
1932         my $sqla = $rsrc->storage->sql_maker;
1933         local $sqla->{_dequalify_idents} = 1;
1934         \[ $sqla->_recurse_where($self->{cond}) ];
1935       };
1936     }
1937   }
1938   else {
1939     # we got this far - means it is time to wrap a subquery
1940     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1941       sprintf(
1942         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1943         $op,
1944         $rsrc->source_name,
1945       )
1946     );
1947
1948     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1949     delete $attrs->{$_} for qw/select as collapse/;
1950     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1951
1952     # this will be consumed by the pruner waaaaay down the stack
1953     $attrs->{_force_prune_multiplying_joins} = 1;
1954
1955     my $subrs = (ref $self)->new($rsrc, $attrs);
1956
1957     if (@$idcols == 1) {
1958       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1959     }
1960     elsif ($storage->_use_multicolumn_in) {
1961       # no syntax for calling this properly yet
1962       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1963       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1964         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1965         $subrs->as_query
1966       ),
1967     }
1968     else {
1969       # if all else fails - get all primary keys and operate over a ORed set
1970       # wrap in a transaction for consistency
1971       # this is where the group_by/multiplication starts to matter
1972       if (
1973         $existing_group_by
1974           or
1975         keys %{ $join_classifications->{multiplying} || {} }
1976       ) {
1977         # make sure if there is a supplied group_by it matches the columns compiled above
1978         # perfectly. Anything else can not be sanely executed on most databases so croak
1979         # right then and there
1980         if ($existing_group_by) {
1981           my @current_group_by = map
1982             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1983             @$existing_group_by
1984           ;
1985
1986           if (
1987             join ("\x00", sort @current_group_by)
1988               ne
1989             join ("\x00", sort @{$attrs->{columns}} )
1990           ) {
1991             $self->throw_exception (
1992               "You have just attempted a $op operation on a resultset which does group_by"
1993               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1994               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1995               . ' kind of queries. Please retry the operation with a modified group_by or'
1996               . ' without using one at all.'
1997             );
1998           }
1999         }
2000
2001         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2002       }
2003
2004       $guard = $storage->txn_scope_guard;
2005
2006       $cond = [];
2007       for my $row ($subrs->cursor->all) {
2008         push @$cond, { map
2009           { $idcols->[$_] => $row->[$_] }
2010           (0 .. $#$idcols)
2011         };
2012       }
2013     }
2014   }
2015
2016   my $res = $storage->$op (
2017     $rsrc,
2018     $op eq 'update' ? $values : (),
2019     $cond,
2020   );
2021
2022   $guard->commit if $guard;
2023
2024   return $res;
2025 }
2026
2027 =head2 update
2028
2029 =over 4
2030
2031 =item Arguments: \%values
2032
2033 =item Return Value: $underlying_storage_rv
2034
2035 =back
2036
2037 Sets the specified columns in the resultset to the supplied values in a
2038 single query. Note that this will not run any accessor/set_column/update
2039 triggers, nor will it update any result object instances derived from this
2040 resultset (this includes the contents of the L<resultset cache|/set_cache>
2041 if any). See L</update_all> if you need to execute any on-update
2042 triggers or cascades defined either by you or a
2043 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2044
2045 The return value is a pass through of what the underlying
2046 storage backend returned, and may vary. See L<DBI/execute> for the most
2047 common case.
2048
2049 =head3 CAVEAT
2050
2051 Note that L</update> does not process/deflate any of the values passed in.
2052 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2053 ensure manually that any value passed to this method will stringify to
2054 something the RDBMS knows how to deal with. A notable example is the
2055 handling of L<DateTime> objects, for more info see:
2056 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2057
2058 =cut
2059
2060 sub update {
2061   my ($self, $values) = @_;
2062   $self->throw_exception('Values for update must be a hash')
2063     unless ref $values eq 'HASH';
2064
2065   return $self->_rs_update_delete ('update', $values);
2066 }
2067
2068 =head2 update_all
2069
2070 =over 4
2071
2072 =item Arguments: \%values
2073
2074 =item Return Value: 1
2075
2076 =back
2077
2078 Fetches all objects and updates them one at a time via
2079 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2080 triggers, while L</update> will not.
2081
2082 =cut
2083
2084 sub update_all {
2085   my ($self, $values) = @_;
2086   $self->throw_exception('Values for update_all must be a hash')
2087     unless ref $values eq 'HASH';
2088
2089   my $guard = $self->result_source->schema->txn_scope_guard;
2090   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2091   $guard->commit;
2092   return 1;
2093 }
2094
2095 =head2 delete
2096
2097 =over 4
2098
2099 =item Arguments: none
2100
2101 =item Return Value: $underlying_storage_rv
2102
2103 =back
2104
2105 Deletes the rows matching this resultset in a single query. Note that this
2106 will not run any delete triggers, nor will it alter the
2107 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2108 derived from this resultset (this includes the contents of the
2109 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2110 execute any on-delete triggers or cascades defined either by you or a
2111 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2112
2113 The return value is a pass through of what the underlying storage backend
2114 returned, and may vary. See L<DBI/execute> for the most common case.
2115
2116 =cut
2117
2118 sub delete {
2119   my $self = shift;
2120   $self->throw_exception('delete does not accept any arguments')
2121     if @_;
2122
2123   return $self->_rs_update_delete ('delete');
2124 }
2125
2126 =head2 delete_all
2127
2128 =over 4
2129
2130 =item Arguments: none
2131
2132 =item Return Value: 1
2133
2134 =back
2135
2136 Fetches all objects and deletes them one at a time via
2137 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2138 triggers, while L</delete> will not.
2139
2140 =cut
2141
2142 sub delete_all {
2143   my $self = shift;
2144   $self->throw_exception('delete_all does not accept any arguments')
2145     if @_;
2146
2147   my $guard = $self->result_source->schema->txn_scope_guard;
2148   $_->delete for $self->all;
2149   $guard->commit;
2150   return 1;
2151 }
2152
2153 =head2 populate
2154
2155 =over 4
2156
2157 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2158
2159 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2160
2161 =back
2162
2163 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2164 arrayrefs.
2165
2166 =over
2167
2168 =item NOTE
2169
2170 The context of this method call has an important effect on what is
2171 submitted to storage. In void context data is fed directly to fastpath
2172 insertion routines provided by the underlying storage (most often
2173 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2174 L<insert|DBIx::Class::Row/insert> calls on the
2175 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2176 augmentation of these methods provided by components. For example if you
2177 are using something like L<DBIx::Class::UUIDColumns> to create primary
2178 keys for you, you will find that your PKs are empty.  In this case you
2179 will have to explicitly force scalar or list context in order to create
2180 those values.
2181
2182 =back
2183
2184 In non-void (scalar or list) context, this method is simply a wrapper
2185 for L</create>. Depending on list or scalar context either a list of
2186 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2187 containing these objects is returned.
2188
2189 When supplying data in "arrayref of arrayrefs" invocation style, the
2190 first element should be a list of column names and each subsequent
2191 element should be a data value in the earlier specified column order.
2192 For example:
2193
2194   $schema->resultset("Artist")->populate([
2195     [ qw( artistid name ) ],
2196     [ 100, 'A Formally Unknown Singer' ],
2197     [ 101, 'A singer that jumped the shark two albums ago' ],
2198     [ 102, 'An actually cool singer' ],
2199   ]);
2200
2201 For the arrayref of hashrefs style each hashref should be a structure
2202 suitable for passing to L</create>. Multi-create is also permitted with
2203 this syntax.
2204
2205   $schema->resultset("Artist")->populate([
2206      { artistid => 4, name => 'Manufactured Crap', cds => [
2207         { title => 'My First CD', year => 2006 },
2208         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2209       ],
2210      },
2211      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2212         { title => 'My parents sold me to a record company', year => 2005 },
2213         { title => 'Why Am I So Ugly?', year => 2006 },
2214         { title => 'I Got Surgery and am now Popular', year => 2007 }
2215       ],
2216      },
2217   ]);
2218
2219 If you attempt a void-context multi-create as in the example above (each
2220 Artist also has the related list of CDs), and B<do not> supply the
2221 necessary autoinc foreign key information, this method will proxy to the
2222 less efficient L</create>, and then throw the Result objects away. In this
2223 case there are obviously no benefits to using this method over L</create>.
2224
2225 =cut
2226
2227 sub populate {
2228   my $self = shift;
2229
2230   # cruft placed in standalone method
2231   my $data = $self->_normalize_populate_args(@_);
2232
2233   return unless @$data;
2234
2235   if(defined wantarray) {
2236     my @created = map { $self->create($_) } @$data;
2237     return wantarray ? @created : \@created;
2238   }
2239   else {
2240     my $first = $data->[0];
2241
2242     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2243     # it relationship data
2244     my (@rels, @columns);
2245     my $rsrc = $self->result_source;
2246     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2247     for (keys %$first) {
2248       my $ref = ref $first->{$_};
2249       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2250         ? push @rels, $_
2251         : push @columns, $_
2252       ;
2253     }
2254
2255     my @pks = $rsrc->primary_columns;
2256
2257     ## do the belongs_to relationships
2258     foreach my $index (0..$#$data) {
2259
2260       # delegate to create() for any dataset without primary keys with specified relationships
2261       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2262         for my $r (@rels) {
2263           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2264             my @ret = $self->populate($data);
2265             return;
2266           }
2267         }
2268       }
2269
2270       foreach my $rel (@rels) {
2271         next unless ref $data->[$index]->{$rel} eq "HASH";
2272         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2273         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2274         my $related = $result->result_source->_resolve_condition(
2275           $reverse_relinfo->{cond},
2276           $self,
2277           $result,
2278           $rel,
2279         );
2280
2281         delete $data->[$index]->{$rel};
2282         $data->[$index] = {%{$data->[$index]}, %$related};
2283
2284         push @columns, keys %$related if $index == 0;
2285       }
2286     }
2287
2288     ## inherit the data locked in the conditions of the resultset
2289     my ($rs_data) = $self->_merge_with_rscond({});
2290     delete @{$rs_data}{@columns};
2291
2292     ## do bulk insert on current row
2293     $rsrc->storage->insert_bulk(
2294       $rsrc,
2295       [@columns, keys %$rs_data],
2296       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2297     );
2298
2299     ## do the has_many relationships
2300     foreach my $item (@$data) {
2301
2302       my $main_row;
2303
2304       foreach my $rel (@rels) {
2305         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2306
2307         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2308
2309         my $child = $main_row->$rel;
2310
2311         my $related = $child->result_source->_resolve_condition(
2312           $rels->{$rel}{cond},
2313           $child,
2314           $main_row,
2315           $rel,
2316         );
2317
2318         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2319         my @populate = map { {%$_, %$related} } @rows_to_add;
2320
2321         $child->populate( \@populate );
2322       }
2323     }
2324   }
2325 }
2326
2327
2328 # populate() arguments went over several incarnations
2329 # What we ultimately support is AoH
2330 sub _normalize_populate_args {
2331   my ($self, $arg) = @_;
2332
2333   if (ref $arg eq 'ARRAY') {
2334     if (!@$arg) {
2335       return [];
2336     }
2337     elsif (ref $arg->[0] eq 'HASH') {
2338       return $arg;
2339     }
2340     elsif (ref $arg->[0] eq 'ARRAY') {
2341       my @ret;
2342       my @colnames = @{$arg->[0]};
2343       foreach my $values (@{$arg}[1 .. $#$arg]) {
2344         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2345       }
2346       return \@ret;
2347     }
2348   }
2349
2350   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2351 }
2352
2353 =head2 pager
2354
2355 =over 4
2356
2357 =item Arguments: none
2358
2359 =item Return Value: L<$pager|Data::Page>
2360
2361 =back
2362
2363 Returns a L<Data::Page> object for the current resultset. Only makes
2364 sense for queries with a C<page> attribute.
2365
2366 To get the full count of entries for a paged resultset, call
2367 C<total_entries> on the L<Data::Page> object.
2368
2369 =cut
2370
2371 sub pager {
2372   my ($self) = @_;
2373
2374   return $self->{pager} if $self->{pager};
2375
2376   my $attrs = $self->{attrs};
2377   if (!defined $attrs->{page}) {
2378     $self->throw_exception("Can't create pager for non-paged rs");
2379   }
2380   elsif ($attrs->{page} <= 0) {
2381     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2382   }
2383   $attrs->{rows} ||= 10;
2384
2385   # throw away the paging flags and re-run the count (possibly
2386   # with a subselect) to get the real total count
2387   my $count_attrs = { %$attrs };
2388   delete @{$count_attrs}{qw/rows offset page pager/};
2389
2390   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2391
2392   require DBIx::Class::ResultSet::Pager;
2393   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2394     sub { $total_rs->count },  #lazy-get the total
2395     $attrs->{rows},
2396     $self->{attrs}{page},
2397   );
2398 }
2399
2400 =head2 page
2401
2402 =over 4
2403
2404 =item Arguments: $page_number
2405
2406 =item Return Value: L<$resultset|/search>
2407
2408 =back
2409
2410 Returns a resultset for the $page_number page of the resultset on which page
2411 is called, where each page contains a number of rows equal to the 'rows'
2412 attribute set on the resultset (10 by default).
2413
2414 =cut
2415
2416 sub page {
2417   my ($self, $page) = @_;
2418   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2419 }
2420
2421 =head2 new_result
2422
2423 =over 4
2424
2425 =item Arguments: \%col_data
2426
2427 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2428
2429 =back
2430
2431 Creates a new result object in the resultset's result class and returns
2432 it. The row is not inserted into the database at this point, call
2433 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2434 will tell you whether the result object has been inserted or not.
2435
2436 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2437
2438 =cut
2439
2440 sub new_result {
2441   my ($self, $values) = @_;
2442
2443   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2444     if @_ > 2;
2445
2446   $self->throw_exception( "new_result expects a hashref" )
2447     unless (ref $values eq 'HASH');
2448
2449   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2450
2451   my $new = $self->result_class->new({
2452     %$merged_cond,
2453     ( @$cols_from_relations
2454       ? (-cols_from_relations => $cols_from_relations)
2455       : ()
2456     ),
2457     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2458   });
2459
2460   if (
2461     reftype($new) eq 'HASH'
2462       and
2463     ! keys %$new
2464       and
2465     blessed($new)
2466   ) {
2467     carp_unique (sprintf (
2468       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2469       $self->result_class,
2470     ));
2471   }
2472
2473   $new;
2474 }
2475
2476 # _merge_with_rscond
2477 #
2478 # Takes a simple hash of K/V data and returns its copy merged with the
2479 # condition already present on the resultset. Additionally returns an
2480 # arrayref of value/condition names, which were inferred from related
2481 # objects (this is needed for in-memory related objects)
2482 sub _merge_with_rscond {
2483   my ($self, $data) = @_;
2484
2485   my (%new_data, @cols_from_relations);
2486
2487   my $alias = $self->{attrs}{alias};
2488
2489   if (! defined $self->{cond}) {
2490     # just massage $data below
2491   }
2492   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2493     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2494     @cols_from_relations = keys %new_data;
2495   }
2496   elsif (ref $self->{cond} ne 'HASH') {
2497     $self->throw_exception(
2498       "Can't abstract implicit construct, resultset condition not a hash"
2499     );
2500   }
2501   else {
2502     # precedence must be given to passed values over values inherited from
2503     # the cond, so the order here is important.
2504     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2505     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2506
2507     while ( my($col, $value) = each %implied ) {
2508       my $vref = ref $value;
2509       if (
2510         $vref eq 'HASH'
2511           and
2512         keys(%$value) == 1
2513           and
2514         (keys %$value)[0] eq '='
2515       ) {
2516         $new_data{$col} = $value->{'='};
2517       }
2518       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2519         $new_data{$col} = $value;
2520       }
2521     }
2522   }
2523
2524   %new_data = (
2525     %new_data,
2526     %{ $self->_remove_alias($data, $alias) },
2527   );
2528
2529   return (\%new_data, \@cols_from_relations);
2530 }
2531
2532 # _has_resolved_attr
2533 #
2534 # determines if the resultset defines at least one
2535 # of the attributes supplied
2536 #
2537 # used to determine if a subquery is necessary
2538 #
2539 # supports some virtual attributes:
2540 #   -join
2541 #     This will scan for any joins being present on the resultset.
2542 #     It is not a mere key-search but a deep inspection of {from}
2543 #
2544
2545 sub _has_resolved_attr {
2546   my ($self, @attr_names) = @_;
2547
2548   my $attrs = $self->_resolved_attrs;
2549
2550   my %extra_checks;
2551
2552   for my $n (@attr_names) {
2553     if (grep { $n eq $_ } (qw/-join/) ) {
2554       $extra_checks{$n}++;
2555       next;
2556     }
2557
2558     my $attr =  $attrs->{$n};
2559
2560     next if not defined $attr;
2561
2562     if (ref $attr eq 'HASH') {
2563       return 1 if keys %$attr;
2564     }
2565     elsif (ref $attr eq 'ARRAY') {
2566       return 1 if @$attr;
2567     }
2568     else {
2569       return 1 if $attr;
2570     }
2571   }
2572
2573   # a resolved join is expressed as a multi-level from
2574   return 1 if (
2575     $extra_checks{-join}
2576       and
2577     ref $attrs->{from} eq 'ARRAY'
2578       and
2579     @{$attrs->{from}} > 1
2580   );
2581
2582   return 0;
2583 }
2584
2585 # _collapse_cond
2586 #
2587 # Recursively collapse the condition.
2588
2589 sub _collapse_cond {
2590   my ($self, $cond, $collapsed) = @_;
2591
2592   $collapsed ||= {};
2593
2594   if (ref $cond eq 'ARRAY') {
2595     foreach my $subcond (@$cond) {
2596       next unless ref $subcond;  # -or
2597       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2598     }
2599   }
2600   elsif (ref $cond eq 'HASH') {
2601     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2602       foreach my $subcond (@{$cond->{-and}}) {
2603         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2604       }
2605     }
2606     else {
2607       foreach my $col (keys %$cond) {
2608         my $value = $cond->{$col};
2609         $collapsed->{$col} = $value;
2610       }
2611     }
2612   }
2613
2614   return $collapsed;
2615 }
2616
2617 # _remove_alias
2618 #
2619 # Remove the specified alias from the specified query hash. A copy is made so
2620 # the original query is not modified.
2621
2622 sub _remove_alias {
2623   my ($self, $query, $alias) = @_;
2624
2625   my %orig = %{ $query || {} };
2626   my %unaliased;
2627
2628   foreach my $key (keys %orig) {
2629     if ($key !~ /\./) {
2630       $unaliased{$key} = $orig{$key};
2631       next;
2632     }
2633     $unaliased{$1} = $orig{$key}
2634       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2635   }
2636
2637   return \%unaliased;
2638 }
2639
2640 =head2 as_query
2641
2642 =over 4
2643
2644 =item Arguments: none
2645
2646 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2647
2648 =back
2649
2650 Returns the SQL query and bind vars associated with the invocant.
2651
2652 This is generally used as the RHS for a subquery.
2653
2654 =cut
2655
2656 sub as_query {
2657   my $self = shift;
2658
2659   my $attrs = { %{ $self->_resolved_attrs } };
2660
2661   my $aq = $self->result_source->storage->_select_args_to_query (
2662     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2663   );
2664
2665   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
2666
2667   $aq;
2668 }
2669
2670 =head2 find_or_new
2671
2672 =over 4
2673
2674 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2675
2676 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2677
2678 =back
2679
2680   my $artist = $schema->resultset('Artist')->find_or_new(
2681     { artist => 'fred' }, { key => 'artists' });
2682
2683   $cd->cd_to_producer->find_or_new({ producer => $producer },
2684                                    { key => 'primary' });
2685
2686 Find an existing record from this resultset using L</find>. if none exists,
2687 instantiate a new result object and return it. The object will not be saved
2688 into your storage until you call L<DBIx::Class::Row/insert> on it.
2689
2690 You most likely want this method when looking for existing rows using a unique
2691 constraint that is not the primary key, or looking for related rows.
2692
2693 If you want objects to be saved immediately, use L</find_or_create> instead.
2694
2695 B<Note>: Make sure to read the documentation of L</find> and understand the
2696 significance of the C<key> attribute, as its lack may skew your search, and
2697 subsequently result in spurious new objects.
2698
2699 B<Note>: Take care when using C<find_or_new> with a table having
2700 columns with default values that you intend to be automatically
2701 supplied by the database (e.g. an auto_increment primary key column).
2702 In normal usage, the value of such columns should NOT be included at
2703 all in the call to C<find_or_new>, even when set to C<undef>.
2704
2705 =cut
2706
2707 sub find_or_new {
2708   my $self     = shift;
2709   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2710   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2711   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2712     return $row;
2713   }
2714   return $self->new_result($hash);
2715 }
2716
2717 =head2 create
2718
2719 =over 4
2720
2721 =item Arguments: \%col_data
2722
2723 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2724
2725 =back
2726
2727 Attempt to create a single new row or a row with multiple related rows
2728 in the table represented by the resultset (and related tables). This
2729 will not check for duplicate rows before inserting, use
2730 L</find_or_create> to do that.
2731
2732 To create one row for this resultset, pass a hashref of key/value
2733 pairs representing the columns of the table and the values you wish to
2734 store. If the appropriate relationships are set up, foreign key fields
2735 can also be passed an object representing the foreign row, and the
2736 value will be set to its primary key.
2737
2738 To create related objects, pass a hashref of related-object column values
2739 B<keyed on the relationship name>. If the relationship is of type C<multi>
2740 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2741 The process will correctly identify columns holding foreign keys, and will
2742 transparently populate them from the keys of the corresponding relation.
2743 This can be applied recursively, and will work correctly for a structure
2744 with an arbitrary depth and width, as long as the relationships actually
2745 exists and the correct column data has been supplied.
2746
2747 Instead of hashrefs of plain related data (key/value pairs), you may
2748 also pass new or inserted objects. New objects (not inserted yet, see
2749 L</new_result>), will be inserted into their appropriate tables.
2750
2751 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2752
2753 Example of creating a new row.
2754
2755   $person_rs->create({
2756     name=>"Some Person",
2757     email=>"somebody@someplace.com"
2758   });
2759
2760 Example of creating a new row and also creating rows in a related C<has_many>
2761 or C<has_one> resultset.  Note Arrayref.
2762
2763   $artist_rs->create(
2764      { artistid => 4, name => 'Manufactured Crap', cds => [
2765         { title => 'My First CD', year => 2006 },
2766         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2767       ],
2768      },
2769   );
2770
2771 Example of creating a new row and also creating a row in a related
2772 C<belongs_to> resultset. Note Hashref.
2773
2774   $cd_rs->create({
2775     title=>"Music for Silly Walks",
2776     year=>2000,
2777     artist => {
2778       name=>"Silly Musician",
2779     }
2780   });
2781
2782 =over
2783
2784 =item WARNING
2785
2786 When subclassing ResultSet never attempt to override this method. Since
2787 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2788 lot of the internals simply never call it, so your override will be
2789 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2790 or L<DBIx::Class::Row/insert> depending on how early in the
2791 L</create> process you need to intervene. See also warning pertaining to
2792 L</new>.
2793
2794 =back
2795
2796 =cut
2797
2798 sub create {
2799   my ($self, $col_data) = @_;
2800   $self->throw_exception( "create needs a hashref" )
2801     unless ref $col_data eq 'HASH';
2802   return $self->new_result($col_data)->insert;
2803 }
2804
2805 =head2 find_or_create
2806
2807 =over 4
2808
2809 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2810
2811 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2812
2813 =back
2814
2815   $cd->cd_to_producer->find_or_create({ producer => $producer },
2816                                       { key => 'primary' });
2817
2818 Tries to find a record based on its primary key or unique constraints; if none
2819 is found, creates one and returns that instead.
2820
2821   my $cd = $schema->resultset('CD')->find_or_create({
2822     cdid   => 5,
2823     artist => 'Massive Attack',
2824     title  => 'Mezzanine',
2825     year   => 2005,
2826   });
2827
2828 Also takes an optional C<key> attribute, to search by a specific key or unique
2829 constraint. For example:
2830
2831   my $cd = $schema->resultset('CD')->find_or_create(
2832     {
2833       artist => 'Massive Attack',
2834       title  => 'Mezzanine',
2835     },
2836     { key => 'cd_artist_title' }
2837   );
2838
2839 B<Note>: Make sure to read the documentation of L</find> and understand the
2840 significance of the C<key> attribute, as its lack may skew your search, and
2841 subsequently result in spurious row creation.
2842
2843 B<Note>: Because find_or_create() reads from the database and then
2844 possibly inserts based on the result, this method is subject to a race
2845 condition. Another process could create a record in the table after
2846 the find has completed and before the create has started. To avoid
2847 this problem, use find_or_create() inside a transaction.
2848
2849 B<Note>: Take care when using C<find_or_create> with a table having
2850 columns with default values that you intend to be automatically
2851 supplied by the database (e.g. an auto_increment primary key column).
2852 In normal usage, the value of such columns should NOT be included at
2853 all in the call to C<find_or_create>, even when set to C<undef>.
2854
2855 See also L</find> and L</update_or_create>. For information on how to declare
2856 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2857
2858 If you need to know if an existing row was found or a new one created use
2859 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2860 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2861 database!
2862
2863   my $cd = $schema->resultset('CD')->find_or_new({
2864     cdid   => 5,
2865     artist => 'Massive Attack',
2866     title  => 'Mezzanine',
2867     year   => 2005,
2868   });
2869
2870   if( !$cd->in_storage ) {
2871       # do some stuff
2872       $cd->insert;
2873   }
2874
2875 =cut
2876
2877 sub find_or_create {
2878   my $self     = shift;
2879   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2880   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2881   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2882     return $row;
2883   }
2884   return $self->create($hash);
2885 }
2886
2887 =head2 update_or_create
2888
2889 =over 4
2890
2891 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2892
2893 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2894
2895 =back
2896
2897   $resultset->update_or_create({ col => $val, ... });
2898
2899 Like L</find_or_create>, but if a row is found it is immediately updated via
2900 C<< $found_row->update (\%col_data) >>.
2901
2902
2903 Takes an optional C<key> attribute to search on a specific unique constraint.
2904 For example:
2905
2906   # In your application
2907   my $cd = $schema->resultset('CD')->update_or_create(
2908     {
2909       artist => 'Massive Attack',
2910       title  => 'Mezzanine',
2911       year   => 1998,
2912     },
2913     { key => 'cd_artist_title' }
2914   );
2915
2916   $cd->cd_to_producer->update_or_create({
2917     producer => $producer,
2918     name => 'harry',
2919   }, {
2920     key => 'primary',
2921   });
2922
2923 B<Note>: Make sure to read the documentation of L</find> and understand the
2924 significance of the C<key> attribute, as its lack may skew your search, and
2925 subsequently result in spurious row creation.
2926
2927 B<Note>: Take care when using C<update_or_create> with a table having
2928 columns with default values that you intend to be automatically
2929 supplied by the database (e.g. an auto_increment primary key column).
2930 In normal usage, the value of such columns should NOT be included at
2931 all in the call to C<update_or_create>, even when set to C<undef>.
2932
2933 See also L</find> and L</find_or_create>. For information on how to declare
2934 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2935
2936 If you need to know if an existing row was updated or a new one created use
2937 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2938 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2939 database!
2940
2941 =cut
2942
2943 sub update_or_create {
2944   my $self = shift;
2945   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2946   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2947
2948   my $row = $self->find($cond, $attrs);
2949   if (defined $row) {
2950     $row->update($cond);
2951     return $row;
2952   }
2953
2954   return $self->create($cond);
2955 }
2956
2957 =head2 update_or_new
2958
2959 =over 4
2960
2961 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2962
2963 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2964
2965 =back
2966
2967   $resultset->update_or_new({ col => $val, ... });
2968
2969 Like L</find_or_new> but if a row is found it is immediately updated via
2970 C<< $found_row->update (\%col_data) >>.
2971
2972 For example:
2973
2974   # In your application
2975   my $cd = $schema->resultset('CD')->update_or_new(
2976     {
2977       artist => 'Massive Attack',
2978       title  => 'Mezzanine',
2979       year   => 1998,
2980     },
2981     { key => 'cd_artist_title' }
2982   );
2983
2984   if ($cd->in_storage) {
2985       # the cd was updated
2986   }
2987   else {
2988       # the cd is not yet in the database, let's insert it
2989       $cd->insert;
2990   }
2991
2992 B<Note>: Make sure to read the documentation of L</find> and understand the
2993 significance of the C<key> attribute, as its lack may skew your search, and
2994 subsequently result in spurious new objects.
2995
2996 B<Note>: Take care when using C<update_or_new> with a table having
2997 columns with default values that you intend to be automatically
2998 supplied by the database (e.g. an auto_increment primary key column).
2999 In normal usage, the value of such columns should NOT be included at
3000 all in the call to C<update_or_new>, even when set to C<undef>.
3001
3002 See also L</find>, L</find_or_create> and L</find_or_new>.
3003
3004 =cut
3005
3006 sub update_or_new {
3007     my $self  = shift;
3008     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3009     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3010
3011     my $row = $self->find( $cond, $attrs );
3012     if ( defined $row ) {
3013         $row->update($cond);
3014         return $row;
3015     }
3016
3017     return $self->new_result($cond);
3018 }
3019
3020 =head2 get_cache
3021
3022 =over 4
3023
3024 =item Arguments: none
3025
3026 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3027
3028 =back
3029
3030 Gets the contents of the cache for the resultset, if the cache is set.
3031
3032 The cache is populated either by using the L</prefetch> attribute to
3033 L</search> or by calling L</set_cache>.
3034
3035 =cut
3036
3037 sub get_cache {
3038   shift->{all_cache};
3039 }
3040
3041 =head2 set_cache
3042
3043 =over 4
3044
3045 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3046
3047 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3048
3049 =back
3050
3051 Sets the contents of the cache for the resultset. Expects an arrayref
3052 of objects of the same class as those produced by the resultset. Note that
3053 if the cache is set, the resultset will return the cached objects rather
3054 than re-querying the database even if the cache attr is not set.
3055
3056 The contents of the cache can also be populated by using the
3057 L</prefetch> attribute to L</search>.
3058
3059 =cut
3060
3061 sub set_cache {
3062   my ( $self, $data ) = @_;
3063   $self->throw_exception("set_cache requires an arrayref")
3064       if defined($data) && (ref $data ne 'ARRAY');
3065   $self->{all_cache} = $data;
3066 }
3067
3068 =head2 clear_cache
3069
3070 =over 4
3071
3072 =item Arguments: none
3073
3074 =item Return Value: undef
3075
3076 =back
3077
3078 Clears the cache for the resultset.
3079
3080 =cut
3081
3082 sub clear_cache {
3083   shift->set_cache(undef);
3084 }
3085
3086 =head2 is_paged
3087
3088 =over 4
3089
3090 =item Arguments: none
3091
3092 =item Return Value: true, if the resultset has been paginated
3093
3094 =back
3095
3096 =cut
3097
3098 sub is_paged {
3099   my ($self) = @_;
3100   return !!$self->{attrs}{page};
3101 }
3102
3103 =head2 is_ordered
3104
3105 =over 4
3106
3107 =item Arguments: none
3108
3109 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3110
3111 =back
3112
3113 =cut
3114
3115 sub is_ordered {
3116   my ($self) = @_;
3117   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3118 }
3119
3120 =head2 related_resultset
3121
3122 =over 4
3123
3124 =item Arguments: $rel_name
3125
3126 =item Return Value: L<$resultset|/search>
3127
3128 =back
3129
3130 Returns a related resultset for the supplied relationship name.
3131
3132   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3133
3134 =cut
3135
3136 sub related_resultset {
3137   my ($self, $rel) = @_;
3138
3139   return $self->{related_resultsets}{$rel}
3140     if defined $self->{related_resultsets}{$rel};
3141
3142   return $self->{related_resultsets}{$rel} = do {
3143     my $rsrc = $self->result_source;
3144     my $rel_info = $rsrc->relationship_info($rel);
3145
3146     $self->throw_exception(
3147       "search_related: result source '" . $rsrc->source_name .
3148         "' has no such relationship $rel")
3149       unless $rel_info;
3150
3151     my $attrs = $self->_chain_relationship($rel);
3152
3153     my $join_count = $attrs->{seen_join}{$rel};
3154
3155     my $alias = $self->result_source->storage
3156         ->relname_to_table_alias($rel, $join_count);
3157
3158     # since this is search_related, and we already slid the select window inwards
3159     # (the select/as attrs were deleted in the beginning), we need to flip all
3160     # left joins to inner, so we get the expected results
3161     # read the comment on top of the actual function to see what this does
3162     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3163
3164
3165     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3166     delete @{$attrs}{qw(result_class alias)};
3167
3168     my $rel_source = $rsrc->related_source($rel);
3169
3170     my $new = do {
3171
3172       # The reason we do this now instead of passing the alias to the
3173       # search_rs below is that if you wrap/overload resultset on the
3174       # source you need to know what alias it's -going- to have for things
3175       # to work sanely (e.g. RestrictWithObject wants to be able to add
3176       # extra query restrictions, and these may need to be $alias.)
3177
3178       my $rel_attrs = $rel_source->resultset_attributes;
3179       local $rel_attrs->{alias} = $alias;
3180
3181       $rel_source->resultset
3182                  ->search_rs(
3183                      undef, {
3184                        %$attrs,
3185                        where => $attrs->{where},
3186                    });
3187     };
3188
3189     if (my $cache = $self->get_cache) {
3190       my @related_cache = map
3191         { @{$_->related_resultset($rel)->get_cache||[]} }
3192         @$cache
3193       ;
3194
3195       $new->set_cache(\@related_cache) if @related_cache;
3196     }
3197
3198     $new;
3199   };
3200 }
3201
3202 =head2 current_source_alias
3203
3204 =over 4
3205
3206 =item Arguments: none
3207
3208 =item Return Value: $source_alias
3209
3210 =back
3211
3212 Returns the current table alias for the result source this resultset is built
3213 on, that will be used in the SQL query. Usually it is C<me>.
3214
3215 Currently the source alias that refers to the result set returned by a
3216 L</search>/L</find> family method depends on how you got to the resultset: it's
3217 C<me> by default, but eg. L</search_related> aliases it to the related result
3218 source name (and keeps C<me> referring to the original result set). The long
3219 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3220 (and make this method unnecessary).
3221
3222 Thus it's currently necessary to use this method in predefined queries (see
3223 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3224 source alias of the current result set:
3225
3226   # in a result set class
3227   sub modified_by {
3228     my ($self, $user) = @_;
3229
3230     my $me = $self->current_source_alias;
3231
3232     return $self->search({
3233       "$me.modified" => $user->id,
3234     });
3235   }
3236
3237 =cut
3238
3239 sub current_source_alias {
3240   return (shift->{attrs} || {})->{alias} || 'me';
3241 }
3242
3243 =head2 as_subselect_rs
3244
3245 =over 4
3246
3247 =item Arguments: none
3248
3249 =item Return Value: L<$resultset|/search>
3250
3251 =back
3252
3253 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3254 "virtual view" by including it as a subquery within the from clause.  From this
3255 point on, any joined tables are inaccessible to ->search on the resultset (as if
3256 it were simply where-filtered without joins).  For example:
3257
3258  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3259
3260  # 'x' now pollutes the query namespace
3261
3262  # So the following works as expected
3263  my $ok_rs = $rs->search({'x.other' => 1});
3264
3265  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3266  # def) we look for one row with contradictory terms and join in another table
3267  # (aliased 'x_2') which we never use
3268  my $broken_rs = $rs->search({'x.name' => 'def'});
3269
3270  my $rs2 = $rs->as_subselect_rs;
3271
3272  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3273  my $not_joined_rs = $rs2->search({'x.other' => 1});
3274
3275  # works as expected: finds a 'table' row related to two x rows (abc and def)
3276  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3277
3278 Another example of when one might use this would be to select a subset of
3279 columns in a group by clause:
3280
3281  my $rs = $schema->resultset('Bar')->search(undef, {
3282    group_by => [qw{ id foo_id baz_id }],
3283  })->as_subselect_rs->search(undef, {
3284    columns => [qw{ id foo_id }]
3285  });
3286
3287 In the above example normally columns would have to be equal to the group by,
3288 but because we isolated the group by into a subselect the above works.
3289
3290 =cut
3291
3292 sub as_subselect_rs {
3293   my $self = shift;
3294
3295   my $attrs = $self->_resolved_attrs;
3296
3297   my $fresh_rs = (ref $self)->new (
3298     $self->result_source
3299   );
3300
3301   # these pieces will be locked in the subquery
3302   delete $fresh_rs->{cond};
3303   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3304
3305   return $fresh_rs->search( {}, {
3306     from => [{
3307       $attrs->{alias} => $self->as_query,
3308       -alias  => $attrs->{alias},
3309       -rsrc   => $self->result_source,
3310     }],
3311     alias => $attrs->{alias},
3312   });
3313 }
3314
3315 # This code is called by search_related, and makes sure there
3316 # is clear separation between the joins before, during, and
3317 # after the relationship. This information is needed later
3318 # in order to properly resolve prefetch aliases (any alias
3319 # with a relation_chain_depth less than the depth of the
3320 # current prefetch is not considered)
3321 #
3322 # The increments happen twice per join. An even number means a
3323 # relationship specified via a search_related, whereas an odd
3324 # number indicates a join/prefetch added via attributes
3325 #
3326 # Also this code will wrap the current resultset (the one we
3327 # chain to) in a subselect IFF it contains limiting attributes
3328 sub _chain_relationship {
3329   my ($self, $rel) = @_;
3330   my $source = $self->result_source;
3331   my $attrs = { %{$self->{attrs}||{}} };
3332
3333   # we need to take the prefetch the attrs into account before we
3334   # ->_resolve_join as otherwise they get lost - captainL
3335   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3336
3337   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3338
3339   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3340
3341   my $from;
3342   my @force_subq_attrs = qw/offset rows group_by having/;
3343
3344   if (
3345     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3346       ||
3347     $self->_has_resolved_attr (@force_subq_attrs)
3348   ) {
3349     # Nuke the prefetch (if any) before the new $rs attrs
3350     # are resolved (prefetch is useless - we are wrapping
3351     # a subquery anyway).
3352     my $rs_copy = $self->search;
3353     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3354       $rs_copy->{attrs}{join},
3355       delete $rs_copy->{attrs}{prefetch},
3356     );
3357
3358     $from = [{
3359       -rsrc   => $source,
3360       -alias  => $attrs->{alias},
3361       $attrs->{alias} => $rs_copy->as_query,
3362     }];
3363     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3364     $seen->{-relation_chain_depth} = 0;
3365   }
3366   elsif ($attrs->{from}) {  #shallow copy suffices
3367     $from = [ @{$attrs->{from}} ];
3368   }
3369   else {
3370     $from = [{
3371       -rsrc  => $source,
3372       -alias => $attrs->{alias},
3373       $attrs->{alias} => $source->from,
3374     }];
3375   }
3376
3377   my $jpath = ($seen->{-relation_chain_depth})
3378     ? $from->[-1][0]{-join_path}
3379     : [];
3380
3381   my @requested_joins = $source->_resolve_join(
3382     $join,
3383     $attrs->{alias},
3384     $seen,
3385     $jpath,
3386   );
3387
3388   push @$from, @requested_joins;
3389
3390   $seen->{-relation_chain_depth}++;
3391
3392   # if $self already had a join/prefetch specified on it, the requested
3393   # $rel might very well be already included. What we do in this case
3394   # is effectively a no-op (except that we bump up the chain_depth on
3395   # the join in question so we could tell it *is* the search_related)
3396   my $already_joined;
3397
3398   # we consider the last one thus reverse
3399   for my $j (reverse @requested_joins) {
3400     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3401     if ($rel eq $last_j) {
3402       $j->[0]{-relation_chain_depth}++;
3403       $already_joined++;
3404       last;
3405     }
3406   }
3407
3408   unless ($already_joined) {
3409     push @$from, $source->_resolve_join(
3410       $rel,
3411       $attrs->{alias},
3412       $seen,
3413       $jpath,
3414     );
3415   }
3416
3417   $seen->{-relation_chain_depth}++;
3418
3419   return {%$attrs, from => $from, seen_join => $seen};
3420 }
3421
3422 sub _resolved_attrs {
3423   my $self = shift;
3424   return $self->{_attrs} if $self->{_attrs};
3425
3426   my $attrs  = { %{ $self->{attrs} || {} } };
3427   my $source = $self->result_source;
3428   my $alias  = $attrs->{alias};
3429
3430   # default selection list
3431   $attrs->{columns} = [ $source->columns ]
3432     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3433
3434   # merge selectors together
3435   for (qw/columns select as/) {
3436     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3437       if $attrs->{$_} or $attrs->{"+$_"};
3438   }
3439
3440   # disassemble columns
3441   my (@sel, @as);
3442   if (my $cols = delete $attrs->{columns}) {
3443     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3444       if (ref $c eq 'HASH') {
3445         for my $as (sort keys %$c) {
3446           push @sel, $c->{$as};
3447           push @as, $as;
3448         }
3449       }
3450       else {
3451         push @sel, $c;
3452         push @as, $c;
3453       }
3454     }
3455   }
3456
3457   # when trying to weed off duplicates later do not go past this point -
3458   # everything added from here on is unbalanced "anyone's guess" stuff
3459   my $dedup_stop_idx = $#as;
3460
3461   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3462     if $attrs->{as};
3463   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3464     if $attrs->{select};
3465
3466   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3467   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3468
3469   # disqualify all $alias.col as-bits (inflate-map mandated)
3470   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3471
3472   # de-duplicate the result (remove *identical* select/as pairs)
3473   # and also die on duplicate {as} pointing to different {select}s
3474   # not using a c-style for as the condition is prone to shrinkage
3475   my $seen;
3476   my $i = 0;
3477   while ($i <= $dedup_stop_idx) {
3478     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3479       splice @sel, $i, 1;
3480       splice @as, $i, 1;
3481       $dedup_stop_idx--;
3482     }
3483     elsif ($seen->{$as[$i]}++) {
3484       $self->throw_exception(
3485         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3486       );
3487     }
3488     else {
3489       $i++;
3490     }
3491   }
3492
3493   $attrs->{select} = \@sel;
3494   $attrs->{as} = \@as;
3495
3496   $attrs->{from} ||= [{
3497     -rsrc   => $source,
3498     -alias  => $self->{attrs}{alias},
3499     $self->{attrs}{alias} => $source->from,
3500   }];
3501
3502   if ( $attrs->{join} || $attrs->{prefetch} ) {
3503
3504     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3505       if ref $attrs->{from} ne 'ARRAY';
3506
3507     my $join = (delete $attrs->{join}) || {};
3508
3509     if ( defined $attrs->{prefetch} ) {
3510       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3511     }
3512
3513     $attrs->{from} =    # have to copy here to avoid corrupting the original
3514       [
3515         @{ $attrs->{from} },
3516         $source->_resolve_join(
3517           $join,
3518           $alias,
3519           { %{ $attrs->{seen_join} || {} } },
3520           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3521             ? $attrs->{from}[-1][0]{-join_path}
3522             : []
3523           ,
3524         )
3525       ];
3526   }
3527
3528   if ( defined $attrs->{order_by} ) {
3529     $attrs->{order_by} = (
3530       ref( $attrs->{order_by} ) eq 'ARRAY'
3531       ? [ @{ $attrs->{order_by} } ]
3532       : [ $attrs->{order_by} || () ]
3533     );
3534   }
3535
3536   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3537     $attrs->{group_by} = [ $attrs->{group_by} ];
3538   }
3539
3540   # generate the distinct induced group_by early, as prefetch will be carried via a
3541   # subquery (since a group_by is present)
3542   if (delete $attrs->{distinct}) {
3543     if ($attrs->{group_by}) {
3544       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3545     }
3546     else {
3547       $attrs->{_grouped_by_distinct} = 1;
3548       # distinct affects only the main selection part, not what prefetch may
3549       # add below.
3550       $attrs->{group_by} = $source->storage->_group_over_selection($attrs);
3551     }
3552   }
3553
3554   # generate selections based on the prefetch helper
3555   my $prefetch;
3556   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3557     if defined $attrs->{prefetch};
3558
3559   if ($prefetch) {
3560
3561     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3562       if $attrs->{_dark_selector};
3563
3564     $attrs->{collapse} = 1;
3565
3566     # this is a separate structure (we don't look in {from} directly)
3567     # as the resolver needs to shift things off the lists to work
3568     # properly (identical-prefetches on different branches)
3569     my $join_map = {};
3570     if (ref $attrs->{from} eq 'ARRAY') {
3571
3572       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3573
3574       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3575         next unless $j->[0]{-alias};
3576         next unless $j->[0]{-join_path};
3577         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3578
3579         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3580
3581         my $p = $join_map;
3582         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3583         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3584       }
3585     }
3586
3587     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3588
3589     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3590     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3591   }
3592
3593   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3594     $attrs->{_related_results_construction} = 1;
3595   }
3596
3597   # run through the resulting joinstructure (starting from our current slot)
3598   # and unset collapse if proven unnecessary
3599   #
3600   # also while we are at it find out if the current root source has
3601   # been premultiplied by previous related_source chaining
3602   #
3603   # this allows to predict whether a root object with all other relation
3604   # data set to NULL is in fact unique
3605   if ($attrs->{collapse}) {
3606
3607     if (ref $attrs->{from} eq 'ARRAY') {
3608
3609       if (@{$attrs->{from}} == 1) {
3610         # no joins - no collapse
3611         $attrs->{collapse} = 0;
3612       }
3613       else {
3614         # find where our table-spec starts
3615         my @fromlist = @{$attrs->{from}};
3616         while (@fromlist) {
3617           my $t = shift @fromlist;
3618
3619           my $is_multi;
3620           # me vs join from-spec distinction - a ref means non-root
3621           if (ref $t eq 'ARRAY') {
3622             $t = $t->[0];
3623             $is_multi ||= ! $t->{-is_single};
3624           }
3625           last if ($t->{-alias} && $t->{-alias} eq $alias);
3626           $attrs->{_main_source_premultiplied} ||= $is_multi;
3627         }
3628
3629         # no non-singles remaining, nor any premultiplication - nothing to collapse
3630         if (
3631           ! $attrs->{_main_source_premultiplied}
3632             and
3633           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3634         ) {
3635           $attrs->{collapse} = 0;
3636         }
3637       }
3638     }
3639
3640     else {
3641       # if we can not analyze the from - err on the side of safety
3642       $attrs->{_main_source_premultiplied} = 1;
3643     }
3644   }
3645
3646   # if both page and offset are specified, produce a combined offset
3647   # even though it doesn't make much sense, this is what pre 081xx has
3648   # been doing
3649   if (my $page = delete $attrs->{page}) {
3650     $attrs->{offset} =
3651       ($attrs->{rows} * ($page - 1))
3652             +
3653       ($attrs->{offset} || 0)
3654     ;
3655   }
3656
3657   return $self->{_attrs} = $attrs;
3658 }
3659
3660 sub _rollout_attr {
3661   my ($self, $attr) = @_;
3662
3663   if (ref $attr eq 'HASH') {
3664     return $self->_rollout_hash($attr);
3665   } elsif (ref $attr eq 'ARRAY') {
3666     return $self->_rollout_array($attr);
3667   } else {
3668     return [$attr];
3669   }
3670 }
3671
3672 sub _rollout_array {
3673   my ($self, $attr) = @_;
3674
3675   my @rolled_array;
3676   foreach my $element (@{$attr}) {
3677     if (ref $element eq 'HASH') {
3678       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3679     } elsif (ref $element eq 'ARRAY') {
3680       #  XXX - should probably recurse here
3681       push( @rolled_array, @{$self->_rollout_array($element)} );
3682     } else {
3683       push( @rolled_array, $element );
3684     }
3685   }
3686   return \@rolled_array;
3687 }
3688
3689 sub _rollout_hash {
3690   my ($self, $attr) = @_;
3691
3692   my @rolled_array;
3693   foreach my $key (keys %{$attr}) {
3694     push( @rolled_array, { $key => $attr->{$key} } );
3695   }
3696   return \@rolled_array;
3697 }
3698
3699 sub _calculate_score {
3700   my ($self, $a, $b) = @_;
3701
3702   if (defined $a xor defined $b) {
3703     return 0;
3704   }
3705   elsif (not defined $a) {
3706     return 1;
3707   }
3708
3709   if (ref $b eq 'HASH') {
3710     my ($b_key) = keys %{$b};
3711     if (ref $a eq 'HASH') {
3712       my ($a_key) = keys %{$a};
3713       if ($a_key eq $b_key) {
3714         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3715       } else {
3716         return 0;
3717       }
3718     } else {
3719       return ($a eq $b_key) ? 1 : 0;
3720     }
3721   } else {
3722     if (ref $a eq 'HASH') {
3723       my ($a_key) = keys %{$a};
3724       return ($b eq $a_key) ? 1 : 0;
3725     } else {
3726       return ($b eq $a) ? 1 : 0;
3727     }
3728   }
3729 }
3730
3731 sub _merge_joinpref_attr {
3732   my ($self, $orig, $import) = @_;
3733
3734   return $import unless defined($orig);
3735   return $orig unless defined($import);
3736
3737   $orig = $self->_rollout_attr($orig);
3738   $import = $self->_rollout_attr($import);
3739
3740   my $seen_keys;
3741   foreach my $import_element ( @{$import} ) {
3742     # find best candidate from $orig to merge $b_element into
3743     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3744     foreach my $orig_element ( @{$orig} ) {
3745       my $score = $self->_calculate_score( $orig_element, $import_element );
3746       if ($score > $best_candidate->{score}) {
3747         $best_candidate->{position} = $position;
3748         $best_candidate->{score} = $score;
3749       }
3750       $position++;
3751     }
3752     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3753     $import_key = '' if not defined $import_key;
3754
3755     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3756       push( @{$orig}, $import_element );
3757     } else {
3758       my $orig_best = $orig->[$best_candidate->{position}];
3759       # merge orig_best and b_element together and replace original with merged
3760       if (ref $orig_best ne 'HASH') {
3761         $orig->[$best_candidate->{position}] = $import_element;
3762       } elsif (ref $import_element eq 'HASH') {
3763         my ($key) = keys %{$orig_best};
3764         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3765       }
3766     }
3767     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3768   }
3769
3770   return @$orig ? $orig : ();
3771 }
3772
3773 {
3774   my $hm;
3775
3776   sub _merge_attr {
3777     $hm ||= do {
3778       require Hash::Merge;
3779       my $hm = Hash::Merge->new;
3780
3781       $hm->specify_behavior({
3782         SCALAR => {
3783           SCALAR => sub {
3784             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3785
3786             if ($defl xor $defr) {
3787               return [ $defl ? $_[0] : $_[1] ];
3788             }
3789             elsif (! $defl) {
3790               return [];
3791             }
3792             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3793               return [ $_[0] ];
3794             }
3795             else {
3796               return [$_[0], $_[1]];
3797             }
3798           },
3799           ARRAY => sub {
3800             return $_[1] if !defined $_[0];
3801             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3802             return [$_[0], @{$_[1]}]
3803           },
3804           HASH  => sub {
3805             return [] if !defined $_[0] and !keys %{$_[1]};
3806             return [ $_[1] ] if !defined $_[0];
3807             return [ $_[0] ] if !keys %{$_[1]};
3808             return [$_[0], $_[1]]
3809           },
3810         },
3811         ARRAY => {
3812           SCALAR => sub {
3813             return $_[0] if !defined $_[1];
3814             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3815             return [@{$_[0]}, $_[1]]
3816           },
3817           ARRAY => sub {
3818             my @ret = @{$_[0]} or return $_[1];
3819             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3820             my %idx = map { $_ => 1 } @ret;
3821             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3822             \@ret;
3823           },
3824           HASH => sub {
3825             return [ $_[1] ] if ! @{$_[0]};
3826             return $_[0] if !keys %{$_[1]};
3827             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3828             return [ @{$_[0]}, $_[1] ];
3829           },
3830         },
3831         HASH => {
3832           SCALAR => sub {
3833             return [] if !keys %{$_[0]} and !defined $_[1];
3834             return [ $_[0] ] if !defined $_[1];
3835             return [ $_[1] ] if !keys %{$_[0]};
3836             return [$_[0], $_[1]]
3837           },
3838           ARRAY => sub {
3839             return [] if !keys %{$_[0]} and !@{$_[1]};
3840             return [ $_[0] ] if !@{$_[1]};
3841             return $_[1] if !keys %{$_[0]};
3842             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3843             return [ $_[0], @{$_[1]} ];
3844           },
3845           HASH => sub {
3846             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3847             return [ $_[0] ] if !keys %{$_[1]};
3848             return [ $_[1] ] if !keys %{$_[0]};
3849             return [ $_[0] ] if $_[0] eq $_[1];
3850             return [ $_[0], $_[1] ];
3851           },
3852         }
3853       } => 'DBIC_RS_ATTR_MERGER');
3854       $hm;
3855     };
3856
3857     return $hm->merge ($_[1], $_[2]);
3858   }
3859 }
3860
3861 sub STORABLE_freeze {
3862   my ($self, $cloning) = @_;
3863   my $to_serialize = { %$self };
3864
3865   # A cursor in progress can't be serialized (and would make little sense anyway)
3866   # the parser can be regenerated (and can't be serialized)
3867   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3868
3869   # nor is it sensical to store a not-yet-fired-count pager
3870   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3871     delete $to_serialize->{pager};
3872   }
3873
3874   Storable::nfreeze($to_serialize);
3875 }
3876
3877 # need this hook for symmetry
3878 sub STORABLE_thaw {
3879   my ($self, $cloning, $serialized) = @_;
3880
3881   %$self = %{ Storable::thaw($serialized) };
3882
3883   $self;
3884 }
3885
3886
3887 =head2 throw_exception
3888
3889 See L<DBIx::Class::Schema/throw_exception> for details.
3890
3891 =cut
3892
3893 sub throw_exception {
3894   my $self=shift;
3895
3896   if (ref $self and my $rsrc = $self->result_source) {
3897     $rsrc->throw_exception(@_)
3898   }
3899   else {
3900     DBIx::Class::Exception->throw(@_);
3901   }
3902 }
3903
3904 1;
3905
3906 __END__
3907
3908 # XXX: FIXME: Attributes docs need clearing up
3909
3910 =head1 ATTRIBUTES
3911
3912 Attributes are used to refine a ResultSet in various ways when
3913 searching for data. They can be passed to any method which takes an
3914 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3915 L</count>.
3916
3917 Default attributes can be set on the result class using
3918 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3919 the CAVEATS on that feature before using it!)
3920
3921 These are in no particular order:
3922
3923 =head2 order_by
3924
3925 =over 4
3926
3927 =item Value: ( $order_by | \@order_by | \%order_by )
3928
3929 =back
3930
3931 Which column(s) to order the results by.
3932
3933 [The full list of suitable values is documented in
3934 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3935 common options.]
3936
3937 If a single column name, or an arrayref of names is supplied, the
3938 argument is passed through directly to SQL. The hashref syntax allows
3939 for connection-agnostic specification of ordering direction:
3940
3941  For descending order:
3942
3943   order_by => { -desc => [qw/col1 col2 col3/] }
3944
3945  For explicit ascending order:
3946
3947   order_by => { -asc => 'col' }
3948
3949 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3950 supported, although you are strongly encouraged to use the hashref
3951 syntax as outlined above.
3952
3953 =head2 columns
3954
3955 =over 4
3956
3957 =item Value: \@columns | \%columns | $column
3958
3959 =back
3960
3961 Shortcut to request a particular set of columns to be retrieved. Each
3962 column spec may be a string (a table column name), or a hash (in which
3963 case the key is the C<as> value, and the value is used as the C<select>
3964 expression). Adds C<me.> onto the start of any column without a C<.> in
3965 it and sets C<select> from that, then auto-populates C<as> from
3966 C<select> as normal. (You may also use the C<cols> attribute, as in
3967 earlier versions of DBIC, but this is deprecated.)
3968
3969 Essentially C<columns> does the same as L</select> and L</as>.
3970
3971     columns => [ 'foo', { bar => 'baz' } ]
3972
3973 is the same as
3974
3975     select => [qw/foo baz/],
3976     as => [qw/foo bar/]
3977
3978 =head2 +columns
3979
3980 =over 4
3981
3982 =item Value: \@columns
3983
3984 =back
3985
3986 Indicates additional columns to be selected from storage. Works the same as
3987 L</columns> but adds columns to the selection. (You may also use the
3988 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3989 deprecated). For example:-
3990
3991   $schema->resultset('CD')->search(undef, {
3992     '+columns' => ['artist.name'],
3993     join => ['artist']
3994   });
3995
3996 would return all CDs and include a 'name' column to the information
3997 passed to object inflation. Note that the 'artist' is the name of the
3998 column (or relationship) accessor, and 'name' is the name of the column
3999 accessor in the related table.
4000
4001 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
4002 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
4003 unary plus operator before it.
4004
4005 =head2 include_columns
4006
4007 =over 4
4008
4009 =item Value: \@columns
4010
4011 =back
4012
4013 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
4014
4015 =head2 select
4016
4017 =over 4
4018
4019 =item Value: \@select_columns
4020
4021 =back
4022
4023 Indicates which columns should be selected from the storage. You can use
4024 column names, or in the case of RDBMS back ends, function or stored procedure
4025 names:
4026
4027   $rs = $schema->resultset('Employee')->search(undef, {
4028     select => [
4029       'name',
4030       { count => 'employeeid' },
4031       { max => { length => 'name' }, -as => 'longest_name' }
4032     ]
4033   });
4034
4035   # Equivalent SQL
4036   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4037
4038 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4039 use L</select>, to instruct DBIx::Class how to store the result of the column.
4040 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4041 identifier aliasing. You can however alias a function, so you can use it in
4042 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4043 attribute> supplied as shown in the example above.
4044
4045 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4046 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4047 unary plus operator before it.
4048
4049 =head2 +select
4050
4051 =over 4
4052
4053 Indicates additional columns to be selected from storage.  Works the same as
4054 L</select> but adds columns to the default selection, instead of specifying
4055 an explicit list.
4056
4057 =back
4058
4059 =head2 as
4060
4061 =over 4
4062
4063 =item Value: \@inflation_names
4064
4065 =back
4066
4067 Indicates column names for object inflation. That is L</as> indicates the
4068 slot name in which the column value will be stored within the
4069 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4070 identifier by the C<get_column> method (or via the object accessor B<if one
4071 with the same name already exists>) as shown below. The L</as> attribute has
4072 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4073
4074   $rs = $schema->resultset('Employee')->search(undef, {
4075     select => [
4076       'name',
4077       { count => 'employeeid' },
4078       { max => { length => 'name' }, -as => 'longest_name' }
4079     ],
4080     as => [qw/
4081       name
4082       employee_count
4083       max_name_length
4084     /],
4085   });
4086
4087 If the object against which the search is performed already has an accessor
4088 matching a column name specified in C<as>, the value can be retrieved using
4089 the accessor as normal:
4090
4091   my $name = $employee->name();
4092
4093 If on the other hand an accessor does not exist in the object, you need to
4094 use C<get_column> instead:
4095
4096   my $employee_count = $employee->get_column('employee_count');
4097
4098 You can create your own accessors if required - see
4099 L<DBIx::Class::Manual::Cookbook> for details.
4100
4101 =head2 +as
4102
4103 =over 4
4104
4105 Indicates additional column names for those added via L</+select>. See L</as>.
4106
4107 =back
4108
4109 =head2 join
4110
4111 =over 4
4112
4113 =item Value: ($rel_name | \@rel_names | \%rel_names)
4114
4115 =back
4116
4117 Contains a list of relationships that should be joined for this query.  For
4118 example:
4119
4120   # Get CDs by Nine Inch Nails
4121   my $rs = $schema->resultset('CD')->search(
4122     { 'artist.name' => 'Nine Inch Nails' },
4123     { join => 'artist' }
4124   );
4125
4126 Can also contain a hash reference to refer to the other relation's relations.
4127 For example:
4128
4129   package MyApp::Schema::Track;
4130   use base qw/DBIx::Class/;
4131   __PACKAGE__->table('track');
4132   __PACKAGE__->add_columns(qw/trackid cd position title/);
4133   __PACKAGE__->set_primary_key('trackid');
4134   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4135   1;
4136
4137   # In your application
4138   my $rs = $schema->resultset('Artist')->search(
4139     { 'track.title' => 'Teardrop' },
4140     {
4141       join     => { cd => 'track' },
4142       order_by => 'artist.name',
4143     }
4144   );
4145
4146 You need to use the relationship (not the table) name in  conditions,
4147 because they are aliased as such. The current table is aliased as "me", so
4148 you need to use me.column_name in order to avoid ambiguity. For example:
4149
4150   # Get CDs from 1984 with a 'Foo' track
4151   my $rs = $schema->resultset('CD')->search(
4152     {
4153       'me.year' => 1984,
4154       'tracks.name' => 'Foo'
4155     },
4156     { join => 'tracks' }
4157   );
4158
4159 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4160 similarly for a third time). For e.g.
4161
4162   my $rs = $schema->resultset('Artist')->search({
4163     'cds.title'   => 'Down to Earth',
4164     'cds_2.title' => 'Popular',
4165   }, {
4166     join => [ qw/cds cds/ ],
4167   });
4168
4169 will return a set of all artists that have both a cd with title 'Down
4170 to Earth' and a cd with title 'Popular'.
4171
4172 If you want to fetch related objects from other tables as well, see L</prefetch>
4173 below.
4174
4175  NOTE: An internal join-chain pruner will discard certain joins while
4176  constructing the actual SQL query, as long as the joins in question do not
4177  affect the retrieved result. This for example includes 1:1 left joins
4178  that are not part of the restriction specification (WHERE/HAVING) nor are
4179  a part of the query selection.
4180
4181 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4182
4183 =head2 collapse
4184
4185 =over 4
4186
4187 =item Value: (0 | 1)
4188
4189 =back
4190
4191 When set to a true value, indicates that any rows fetched from joined has_many
4192 relationships are to be aggregated into the corresponding "parent" object. For
4193 example, the resultset:
4194
4195   my $rs = $schema->resultset('CD')->search({}, {
4196     '+columns' => [ qw/ tracks.title tracks.position / ],
4197     join => 'tracks',
4198     collapse => 1,
4199   });
4200
4201 While executing the following query:
4202
4203   SELECT me.*, tracks.title, tracks.position
4204     FROM cd me
4205     LEFT JOIN track tracks
4206       ON tracks.cdid = me.cdid
4207
4208 Will return only as many objects as there are rows in the CD source, even
4209 though the result of the query may span many rows. Each of these CD objects
4210 will in turn have multiple "Track" objects hidden behind the has_many
4211 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4212 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4213 product"), with each CD object containing exactly one of all fetched Track data.
4214
4215 When a collapse is requested on a non-ordered resultset, an order by some
4216 unique part of the main source (the left-most table) is inserted automatically.
4217 This is done so that the resultset is allowed to be "lazy" - calling
4218 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4219 object with all of its related data.
4220
4221 If an L</order_by> is already declared, and orders the resultset in a way that
4222 makes collapsing as described above impossible (e.g. C<< ORDER BY
4223 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4224 switch to "eager" mode and slurp the entire resultset before constructing the
4225 first object returned by L</next>.
4226
4227 Setting this attribute on a resultset that does not join any has_many
4228 relations is a no-op.
4229
4230 For a more in-depth discussion, see L</PREFETCHING>.
4231
4232 =head2 prefetch
4233
4234 =over 4
4235
4236 =item Value: ($rel_name | \@rel_names | \%rel_names)
4237
4238 =back
4239
4240 This attribute is a shorthand for specifying a L</join> spec, adding all
4241 columns from the joined related sources as L</+columns> and setting
4242 L</collapse> to a true value. For example, the following two queries are
4243 equivalent:
4244
4245   my $rs = $schema->resultset('Artist')->search({}, {
4246     prefetch => { cds => ['genre', 'tracks' ] },
4247   });
4248
4249 and
4250
4251   my $rs = $schema->resultset('Artist')->search({}, {
4252     join => { cds => ['genre', 'tracks' ] },
4253     collapse => 1,
4254     '+columns' => [
4255       (map
4256         { +{ "cds.$_" => "cds.$_" } }
4257         $schema->source('Artist')->related_source('cds')->columns
4258       ),
4259       (map
4260         { +{ "cds.genre.$_" => "genre.$_" } }
4261         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4262       ),
4263       (map
4264         { +{ "cds.tracks.$_" => "tracks.$_" } }
4265         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4266       ),
4267     ],
4268   });
4269
4270 Both producing the following SQL:
4271
4272   SELECT  me.artistid, me.name, me.rank, me.charfield,
4273           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4274           genre.genreid, genre.name,
4275           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4276     FROM artist me
4277     LEFT JOIN cd cds
4278       ON cds.artist = me.artistid
4279     LEFT JOIN genre genre
4280       ON genre.genreid = cds.genreid
4281     LEFT JOIN track tracks
4282       ON tracks.cd = cds.cdid
4283   ORDER BY me.artistid
4284
4285 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4286 the arguments are properly merged and generally do the right thing. For
4287 example, you may want to do the following:
4288
4289   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4290     { 'genre.genreid' => undef },
4291     {
4292       join => { cds => 'genre' },
4293       prefetch => 'cds',
4294     }
4295   );
4296
4297 Which generates the following SQL:
4298
4299   SELECT  me.artistid, me.name, me.rank, me.charfield,
4300           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4301     FROM artist me
4302     LEFT JOIN cd cds
4303       ON cds.artist = me.artistid
4304     LEFT JOIN genre genre
4305       ON genre.genreid = cds.genreid
4306   WHERE genre.genreid IS NULL
4307   ORDER BY me.artistid
4308
4309 For a more in-depth discussion, see L</PREFETCHING>.
4310
4311 =head2 alias
4312
4313 =over 4
4314
4315 =item Value: $source_alias
4316
4317 =back
4318
4319 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4320 nested search queries (sub-SELECTs) might need specific aliases set to
4321 reference inner queries.  For example:
4322
4323    my $q = $rs
4324       ->related_resultset('CDs')
4325       ->related_resultset('Tracks')
4326       ->search({
4327          'track.id' => { -ident => 'none_search.id' },
4328       })
4329       ->as_query;
4330
4331    my $ids = $self->search({
4332       -not_exists => $q,
4333    }, {
4334       alias    => 'none_search',
4335       group_by => 'none_search.id',
4336    })->get_column('id')->as_query;
4337
4338    $self->search({ id => { -in => $ids } })
4339
4340 This attribute is directly tied to L</current_source_alias>.
4341
4342 =head2 page
4343
4344 =over 4
4345
4346 =item Value: $page
4347
4348 =back
4349
4350 Makes the resultset paged and specifies the page to retrieve. Effectively
4351 identical to creating a non-pages resultset and then calling ->page($page)
4352 on it.
4353
4354 If L</rows> attribute is not specified it defaults to 10 rows per page.
4355
4356 When you have a paged resultset, L</count> will only return the number
4357 of rows in the page. To get the total, use the L</pager> and call
4358 C<total_entries> on it.
4359
4360 =head2 rows
4361
4362 =over 4
4363
4364 =item Value: $rows
4365
4366 =back
4367
4368 Specifies the maximum number of rows for direct retrieval or the number of
4369 rows per page if the page attribute or method is used.
4370
4371 =head2 offset
4372
4373 =over 4
4374
4375 =item Value: $offset
4376
4377 =back
4378
4379 Specifies the (zero-based) row number for the  first row to be returned, or the
4380 of the first row of the first page if paging is used.
4381
4382 =head2 software_limit
4383
4384 =over 4
4385
4386 =item Value: (0 | 1)
4387
4388 =back
4389
4390 When combined with L</rows> and/or L</offset> the generated SQL will not
4391 include any limit dialect stanzas. Instead the entire result will be selected
4392 as if no limits were specified, and DBIC will perform the limit locally, by
4393 artificially advancing and finishing the resulting L</cursor>.
4394
4395 This is the recommended way of performing resultset limiting when no sane RDBMS
4396 implementation is available (e.g.
4397 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4398 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4399
4400 =head2 group_by
4401
4402 =over 4
4403
4404 =item Value: \@columns
4405
4406 =back
4407
4408 A arrayref of columns to group by. Can include columns of joined tables.
4409
4410   group_by => [qw/ column1 column2 ... /]
4411
4412 =head2 having
4413
4414 =over 4
4415
4416 =item Value: $condition
4417
4418 =back
4419
4420 HAVING is a select statement attribute that is applied between GROUP BY and
4421 ORDER BY. It is applied to the after the grouping calculations have been
4422 done.
4423
4424   having => { 'count_employee' => { '>=', 100 } }
4425
4426 or with an in-place function in which case literal SQL is required:
4427
4428   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4429
4430 =head2 distinct
4431
4432 =over 4
4433
4434 =item Value: (0 | 1)
4435
4436 =back
4437
4438 Set to 1 to group by all columns. If the resultset already has a group_by
4439 attribute, this setting is ignored and an appropriate warning is issued.
4440
4441 =head2 where
4442
4443 =over 4
4444
4445 Adds to the WHERE clause.
4446
4447   # only return rows WHERE deleted IS NULL for all searches
4448   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4449
4450 Can be overridden by passing C<< { where => undef } >> as an attribute
4451 to a resultset.
4452
4453 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4454
4455 =back
4456
4457 =head2 cache
4458
4459 Set to 1 to cache search results. This prevents extra SQL queries if you
4460 revisit rows in your ResultSet:
4461
4462   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4463
4464   while( my $artist = $resultset->next ) {
4465     ... do stuff ...
4466   }
4467
4468   $rs->first; # without cache, this would issue a query
4469
4470 By default, searches are not cached.
4471
4472 For more examples of using these attributes, see
4473 L<DBIx::Class::Manual::Cookbook>.
4474
4475 =head2 for
4476
4477 =over 4
4478
4479 =item Value: ( 'update' | 'shared' | \$scalar )
4480
4481 =back
4482
4483 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4484 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4485 query.
4486
4487 =head1 PREFETCHING
4488
4489 DBIx::Class supports arbitrary related data prefetching from multiple related
4490 sources. Any combination of relationship types and column sets are supported.
4491 If L<collapsing|/collapse> is requested, there is an additional requirement of
4492 selecting enough data to make every individual object uniquely identifiable.
4493
4494 Here are some more involved examples, based on the following relationship map:
4495
4496   # Assuming:
4497   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4498   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4499   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4500
4501   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4502
4503   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4504
4505
4506
4507   my $rs = $schema->resultset('Tag')->search(
4508     undef,
4509     {
4510       prefetch => {
4511         cd => 'artist'
4512       }
4513     }
4514   );
4515
4516 The initial search results in SQL like the following:
4517
4518   SELECT tag.*, cd.*, artist.* FROM tag
4519   JOIN cd ON tag.cd = cd.cdid
4520   JOIN artist ON cd.artist = artist.artistid
4521
4522 L<DBIx::Class> has no need to go back to the database when we access the
4523 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4524 case.
4525
4526 Simple prefetches will be joined automatically, so there is no need
4527 for a C<join> attribute in the above search.
4528
4529 The L</prefetch> attribute can be used with any of the relationship types
4530 and multiple prefetches can be specified together. Below is a more complex
4531 example that prefetches a CD's artist, its liner notes (if present),
4532 the cover image, the tracks on that CD, and the guests on those
4533 tracks.
4534
4535   my $rs = $schema->resultset('CD')->search(
4536     undef,
4537     {
4538       prefetch => [
4539         { artist => 'record_label'},  # belongs_to => belongs_to
4540         'liner_note',                 # might_have
4541         'cover_image',                # has_one
4542         { tracks => 'guests' },       # has_many => has_many
4543       ]
4544     }
4545   );
4546
4547 This will produce SQL like the following:
4548
4549   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4550          tracks.*, guests.*
4551     FROM cd me
4552     JOIN artist artist
4553       ON artist.artistid = me.artistid
4554     JOIN record_label record_label
4555       ON record_label.labelid = artist.labelid
4556     LEFT JOIN track tracks
4557       ON tracks.cdid = me.cdid
4558     LEFT JOIN guest guests
4559       ON guests.trackid = track.trackid
4560     LEFT JOIN liner_notes liner_note
4561       ON liner_note.cdid = me.cdid
4562     JOIN cd_artwork cover_image
4563       ON cover_image.cdid = me.cdid
4564   ORDER BY tracks.cd
4565
4566 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4567 C<tracks>, and C<guests> of the CD will all be available through the
4568 relationship accessors without the need for additional queries to the
4569 database.
4570
4571 =head3 CAVEATS
4572
4573 Prefetch does a lot of deep magic. As such, it may not behave exactly
4574 as you might expect.
4575
4576 =over 4
4577
4578 =item *
4579
4580 Prefetch uses the L</cache> to populate the prefetched relationships. This
4581 may or may not be what you want.
4582
4583 =item *
4584
4585 If you specify a condition on a prefetched relationship, ONLY those
4586 rows that match the prefetched condition will be fetched into that relationship.
4587 This means that adding prefetch to a search() B<may alter> what is returned by
4588 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4589
4590   my $artist_rs = $schema->resultset('Artist')->search({
4591       'cds.year' => 2008,
4592   }, {
4593       join => 'cds',
4594   });
4595
4596   my $count = $artist_rs->first->cds->count;
4597
4598   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4599
4600   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4601
4602   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4603
4604 That cmp_ok() may or may not pass depending on the datasets involved. In other
4605 words the C<WHERE> condition would apply to the entire dataset, just like
4606 it would in regular SQL. If you want to add a condition only to the "right side"
4607 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4608 condition|DBIx::Class::Relationship::Base/condition>
4609
4610 =back
4611
4612 =head1 DBIC BIND VALUES
4613
4614 Because DBIC may need more information to bind values than just the column name
4615 and value itself, it uses a special format for both passing and receiving bind
4616 values.  Each bind value should be composed of an arrayref of
4617 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4618
4619 =over 4
4620
4621 =item dbd_attrs
4622
4623 If present (in any form), this is what is being passed directly to bind_param.
4624 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4625 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4626
4627 If this is specified, all other bind options described below are ignored.
4628
4629 =item sqlt_datatype
4630
4631 If present, this is used to infer the actual bind attribute by passing to
4632 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4633 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4634
4635 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4636 currently drivers are expected to "Do the Right Thing" when given a common
4637 datatype name.  (Not ideal, but that's what we got at this point.)
4638
4639 =item sqlt_size
4640
4641 Currently used to correctly allocate buffers for bind_param_inout().
4642 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4643 or to a sensible value based on the "data_type".
4644
4645 =item dbic_colname
4646
4647 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4648 explicitly specified they are never overridden).  Also used by some weird DBDs,
4649 where the column name should be available at bind_param time (e.g. Oracle).
4650
4651 =back
4652
4653 For backwards compatibility and convenience, the following shortcuts are
4654 supported:
4655
4656   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4657   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4658   [ undef,   $val ] === [ {}, $val ]
4659   $val              === [ {}, $val ]
4660
4661 =head1 AUTHOR AND CONTRIBUTORS
4662
4663 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4664
4665 =head1 LICENSE
4666
4667 You may distribute this code under the same terms as Perl itself.
4668