lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use base qw/DBIx::Class/;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/result_class _source_handle/);
  17
  18 =head1 NAME
  19
  20 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  21
  22 =head1 SYNOPSIS
  23
  24   my $rs   = $schema->resultset('User')->search(registered => 1);
  25   my @rows = $schema->resultset('CD')->search(year => 2005);
  26
  27 =head1 DESCRIPTION
  28
  29 The resultset is also known as an iterator. It is responsible for handling
  30 queries that may return an arbitrary number of rows, e.g. via L</search>
  31 or a C<has_many> relationship.
  32
  33 In the examples below, the following table classes are used:
  34
  35   package MyApp::Schema::Artist;
  36   use base qw/DBIx::Class/;
  37   __PACKAGE__->load_components(qw/Core/);
  38   __PACKAGE__->table('artist');
  39   __PACKAGE__->add_columns(qw/artistid name/);
  40   __PACKAGE__->set_primary_key('artistid');
  41   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  42   1;
  43
  44   package MyApp::Schema::CD;
  45   use base qw/DBIx::Class/;
  46   __PACKAGE__->load_components(qw/Core/);
  47   __PACKAGE__->table('cd');
  48   __PACKAGE__->add_columns(qw/cdid artist title year/);
  49   __PACKAGE__->set_primary_key('cdid');
  50   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  51   1;
  52
  53 =head1 OVERLOADING
  54
  55 If a resultset is used as a number it returns the C<count()>.  However, if it is used as a boolean it is always true.  So if you want to check if a result set has any results use C<if $rs != 0>.  C<if $rs> will always be true.
  56
  57 =head1 METHODS
  58
  59 =head2 new
  60
  61 =over 4
  62
  63 =item Arguments: $source, \%$attrs
  64
  65 =item Return Value: $rs
  66
  67 =back
  68
  69 The resultset constructor. Takes a source object (usually a
  70 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  71 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  72 executed as needed by the other methods.
  73
  74 Generally you won't need to construct a resultset manually.  You'll
  75 automatically get one from e.g. a L</search> called in scalar context:
  76
  77   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  78
  79 IMPORTANT: If called on an object, proxies to new_result instead so
  80
  81   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  82
  83 will return a CD object, not a ResultSet.
  84
  85 =cut
  86
  87 sub new {
  88   my $class = shift;
  89   return $class->new_result(@_) if ref $class;
  90
  91   my ($source, $attrs) = @_;
  92   $source = $source->handle
  93     unless $source->isa('DBIx::Class::ResultSourceHandle');
  94   $attrs = { %{$attrs||{}} };
  95
  96   if ($attrs->{page}) {
  97     $attrs->{rows} ||= 10;
  98   }
  99
 100   $attrs->{alias} ||= 'me';
 101
 102   my $self = {
 103     _source_handle => $source,
 104     result_class => $attrs->{result_class} || $source->resolve->result_class,
 105     cond => $attrs->{where},
 106     count => undef,
 107     pager => undef,
 108     attrs => $attrs
 109   };
 110
 111   bless $self, $class;
 112
 113   return $self;
 114 }
 115
 116 =head2 search
 117
 118 =over 4
 119
 120 =item Arguments: $cond, \%attrs?
 121
 122 =item Return Value: $resultset (scalar context), @row_objs (list context)
 123
 124 =back
 125
 126   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 127   my $new_rs = $cd_rs->search({ year => 2005 });
 128
 129   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 130                  # year = 2005 OR year = 2004
 131
 132 If you need to pass in additional attributes but no additional condition,
 133 call it as C<search(undef, \%attrs)>.
 134
 135   # "SELECT name, artistid FROM $artist_table"
 136   my @all_artists = $schema->resultset('Artist')->search(undef, {
 137     columns => [qw/name artistid/],
 138   });
 139
 140 For a list of attributes that can be passed to C<search>, see
 141 L</ATTRIBUTES>. For more examples of using this function, see
 142 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 143 documentation for the first argument, see L<SQL::Abstract>.
 144
 145 =cut
 146
 147 sub search {
 148   my $self = shift;
 149   my $rs = $self->search_rs( @_ );
 150   return (wantarray ? $rs->all : $rs);
 151 }
 152
 153 =head2 search_rs
 154
 155 =over 4
 156
 157 =item Arguments: $cond, \%attrs?
 158
 159 =item Return Value: $resultset
 160
 161 =back
 162
 163 This method does the same exact thing as search() except it will
 164 always return a resultset, even in list context.
 165
 166 =cut
 167
 168 sub search_rs {
 169   my $self = shift;
 170
 171   my $rows;
 172
 173   unless (@_) {                 # no search, effectively just a clone
 174     $rows = $self->get_cache;
 175   }
 176
 177   my $attrs = {};
 178   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 179   my $our_attrs = { %{$self->{attrs}} };
 180   my $having = delete $our_attrs->{having};
 181   my $where = delete $our_attrs->{where};
 182
 183   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 184
 185   # merge new attrs into inherited
 186   foreach my $key (qw/join prefetch/) {
 187     next unless exists $attrs->{$key};
 188     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 189   }
 190
 191   my $cond = (@_
 192     ? (
 193         (@_ == 1 || ref $_[0] eq "HASH")
 194           ? (
 195               (ref $_[0] eq 'HASH')
 196                 ? (
 197                     (keys %{ $_[0] }  > 0)
 198                       ? shift
 199                       : undef
 200                    )
 201                 :  shift
 202              )
 203           : (
 204               (@_ % 2)
 205                 ? $self->throw_exception("Odd number of arguments to search")
 206                 : {@_}
 207              )
 208       )
 209     : undef
 210   );
 211
 212   if (defined $where) {
 213     $new_attrs->{where} = (
 214       defined $new_attrs->{where}
 215         ? { '-and' => [
 216               map {
 217                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 218               } $where, $new_attrs->{where}
 219             ]
 220           }
 221         : $where);
 222   }
 223
 224   if (defined $cond) {
 225     $new_attrs->{where} = (
 226       defined $new_attrs->{where}
 227         ? { '-and' => [
 228               map {
 229                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 230               } $cond, $new_attrs->{where}
 231             ]
 232           }
 233         : $cond);
 234   }
 235
 236   if (defined $having) {
 237     $new_attrs->{having} = (
 238       defined $new_attrs->{having}
 239         ? { '-and' => [
 240               map {
 241                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 242               } $having, $new_attrs->{having}
 243             ]
 244           }
 245         : $having);
 246   }
 247
 248   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 249   if ($rows) {
 250     $rs->set_cache($rows);
 251   }
 252   return $rs;
 253 }
 254
 255 =head2 search_literal
 256
 257 =over 4
 258
 259 =item Arguments: $sql_fragment, @bind_values
 260
 261 =item Return Value: $resultset (scalar context), @row_objs (list context)
 262
 263 =back
 264
 265   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 266   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 267
 268 Pass a literal chunk of SQL to be added to the conditional part of the
 269 resultset query.
 270
 271 =cut
 272
 273 sub search_literal {
 274   my ($self, $cond, @vals) = @_;
 275   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 276   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 277   return $self->search(\$cond, $attrs);
 278 }
 279
 280 =head2 find
 281
 282 =over 4
 283
 284 =item Arguments: @values | \%cols, \%attrs?
 285
 286 =item Return Value: $row_object
 287
 288 =back
 289
 290 Finds a row based on its primary key or unique constraint. For example, to find
 291 a row by its primary key:
 292
 293   my $cd = $schema->resultset('CD')->find(5);
 294
 295 You can also find a row by a specific unique constraint using the C<key>
 296 attribute. For example:
 297
 298   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 299     key => 'cd_artist_title'
 300   });
 301
 302 Additionally, you can specify the columns explicitly by name:
 303
 304   my $cd = $schema->resultset('CD')->find(
 305     {
 306       artist => 'Massive Attack',
 307       title  => 'Mezzanine',
 308     },
 309     { key => 'cd_artist_title' }
 310   );
 311
 312 If the C<key> is specified as C<primary>, it searches only on the primary key.
 313
 314 If no C<key> is specified, it searches on all unique constraints defined on the
 315 source, including the primary key.
 316
 317 If your table does not have a primary key, you B<must> provide a value for the
 318 C<key> attribute matching one of the unique constraints on the source.
 319
 320 See also L</find_or_create> and L</update_or_create>. For information on how to
 321 declare unique constraints, see
 322 L<DBIx::Class::ResultSource/add_unique_constraint>.
 323
 324 =cut
 325
 326 sub find {
 327   my $self = shift;
 328   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 329
 330   # Default to the primary key, but allow a specific key
 331   my @cols = exists $attrs->{key}
 332     ? $self->result_source->unique_constraint_columns($attrs->{key})
 333     : $self->result_source->primary_columns;
 334   $self->throw_exception(
 335     "Can't find unless a primary key is defined or unique constraint is specified"
 336   ) unless @cols;
 337
 338   # Parse out a hashref from input
 339   my $input_query;
 340   if (ref $_[0] eq 'HASH') {
 341     $input_query = { %{$_[0]} };
 342   }
 343   elsif (@_ == @cols) {
 344     $input_query = {};
 345     @{$input_query}{@cols} = @_;
 346   }
 347   else {
 348     # Compatibility: Allow e.g. find(id => $value)
 349     carp "Find by key => value deprecated; please use a hashref instead";
 350     $input_query = {@_};
 351   }
 352
 353   my (%related, $info);
 354
 355   KEY: foreach my $key (keys %$input_query) {
 356     if (ref($input_query->{$key})
 357         && ($info = $self->result_source->relationship_info($key))) {
 358       my $val = delete $input_query->{$key};
 359       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 360       my $rel_q = $self->result_source->resolve_condition(
 361                     $info->{cond}, $val, $key
 362                   );
 363       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 364       @related{keys %$rel_q} = values %$rel_q;
 365     }
 366   }
 367   if (my @keys = keys %related) {
 368     @{$input_query}{@keys} = values %related;
 369   }
 370
 371   my @unique_queries = $self->_unique_queries($input_query, $attrs);
 372
 373   # Build the final query: Default to the disjunction of the unique queries,
 374   # but allow the input query in case the ResultSet defines the query or the
 375   # user is abusing find
 376   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 377   my $query = @unique_queries
 378     ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 379     : $self->_add_alias($input_query, $alias);
 380
 381   # Run the query
 382   if (keys %$attrs) {
 383     my $rs = $self->search($query, $attrs);
 384     return keys %{$rs->_resolved_attrs->{collapse}} ? $rs->next : $rs->single;
 385   }
 386   else {
 387     return keys %{$self->_resolved_attrs->{collapse}}
 388       ? $self->search($query)->next
 389       : $self->single($query);
 390   }
 391 }
 392
 393 # _add_alias
 394 #
 395 # Add the specified alias to the specified query hash. A copy is made so the
 396 # original query is not modified.
 397
 398 sub _add_alias {
 399   my ($self, $query, $alias) = @_;
 400
 401   my %aliased = %$query;
 402   foreach my $col (grep { ! m/\./ } keys %aliased) {
 403     $aliased{"$alias.$col"} = delete $aliased{$col};
 404   }
 405
 406   return \%aliased;
 407 }
 408
 409 # _unique_queries
 410 #
 411 # Build a list of queries which satisfy unique constraints.
 412
 413 sub _unique_queries {
 414   my ($self, $query, $attrs) = @_;
 415
 416   my @constraint_names = exists $attrs->{key}
 417     ? ($attrs->{key})
 418     : $self->result_source->unique_constraint_names;
 419
 420   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 421   my $num_where = scalar keys %$where;
 422
 423   my @unique_queries;
 424   foreach my $name (@constraint_names) {
 425     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 426     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 427
 428     my $num_cols = scalar @unique_cols;
 429     my $num_query = scalar keys %$unique_query;
 430
 431     my $total = $num_query + $num_where;
 432     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 433       # The query is either unique on its own or is unique in combination with
 434       # the existing where clause
 435       push @unique_queries, $unique_query;
 436     }
 437   }
 438
 439   return @unique_queries;
 440 }
 441
 442 # _build_unique_query
 443 #
 444 # Constrain the specified query hash based on the specified column names.
 445
 446 sub _build_unique_query {
 447   my ($self, $query, $unique_cols) = @_;
 448
 449   return {
 450     map  { $_ => $query->{$_} }
 451     grep { exists $query->{$_} }
 452       @$unique_cols
 453   };
 454 }
 455
 456 =head2 search_related
 457
 458 =over 4
 459
 460 =item Arguments: $rel, $cond, \%attrs?
 461
 462 =item Return Value: $new_resultset
 463
 464 =back
 465
 466   $new_rs = $cd_rs->search_related('artist', {
 467     name => 'Emo-R-Us',
 468   });
 469
 470 Searches the specified relationship, optionally specifying a condition and
 471 attributes for matching records. See L</ATTRIBUTES> for more information.
 472
 473 =cut
 474
 475 sub search_related {
 476   return shift->related_resultset(shift)->search(@_);
 477 }
 478
 479 =head2 cursor
 480
 481 =over 4
 482
 483 =item Arguments: none
 484
 485 =item Return Value: $cursor
 486
 487 =back
 488
 489 Returns a storage-driven cursor to the given resultset. See
 490 L<DBIx::Class::Cursor> for more information.
 491
 492 =cut
 493
 494 sub cursor {
 495   my ($self) = @_;
 496
 497   my $attrs = { %{$self->_resolved_attrs} };
 498   return $self->{cursor}
 499     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 500           $attrs->{where},$attrs);
 501 }
 502
 503 =head2 single
 504
 505 =over 4
 506
 507 =item Arguments: $cond?
 508
 509 =item Return Value: $row_object?
 510
 511 =back
 512
 513   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 514
 515 Inflates the first result without creating a cursor if the resultset has
 516 any records in it; if not returns nothing. Used by L</find> as an optimisation.
 517
 518 Can optionally take an additional condition *only* - this is a fast-code-path
 519 method; if you need to add extra joins or similar call ->search and then
 520 ->single without a condition on the $rs returned from that.
 521
 522 =cut
 523
 524 sub single {
 525   my ($self, $where) = @_;
 526   my $attrs = { %{$self->_resolved_attrs} };
 527   if ($where) {
 528     if (defined $attrs->{where}) {
 529       $attrs->{where} = {
 530         '-and' =>
 531             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 532                $where, delete $attrs->{where} ]
 533       };
 534     } else {
 535       $attrs->{where} = $where;
 536     }
 537   }
 538
 539 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 540 #  unless ($self->_is_unique_query($attrs->{where})) {
 541 #    carp "Query not guaranteed to return a single row"
 542 #      . "; please declare your unique constraints or use search instead";
 543 #  }
 544
 545   my @data = $self->result_source->storage->select_single(
 546     $attrs->{from}, $attrs->{select},
 547     $attrs->{where}, $attrs
 548   );
 549
 550   return (@data ? ($self->_construct_object(@data))[0] : undef);
 551 }
 552
 553 # _is_unique_query
 554 #
 555 # Try to determine if the specified query is guaranteed to be unique, based on
 556 # the declared unique constraints.
 557
 558 sub _is_unique_query {
 559   my ($self, $query) = @_;
 560
 561   my $collapsed = $self->_collapse_query($query);
 562   my $alias = $self->{attrs}{alias};
 563
 564   foreach my $name ($self->result_source->unique_constraint_names) {
 565     my @unique_cols = map {
 566       "$alias.$_"
 567     } $self->result_source->unique_constraint_columns($name);
 568
 569     # Count the values for each unique column
 570     my %seen = map { $_ => 0 } @unique_cols;
 571
 572     foreach my $key (keys %$collapsed) {
 573       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 574       next unless exists $seen{$aliased};  # Additional constraints are okay
 575       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 576     }
 577
 578     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 579     return 1 unless grep { $_ != 1 } values %seen;
 580   }
 581
 582   return 0;
 583 }
 584
 585 # _collapse_query
 586 #
 587 # Recursively collapse the query, accumulating values for each column.
 588
 589 sub _collapse_query {
 590   my ($self, $query, $collapsed) = @_;
 591
 592   $collapsed ||= {};
 593
 594   if (ref $query eq 'ARRAY') {
 595     foreach my $subquery (@$query) {
 596       next unless ref $subquery;  # -or
 597 #      warn "ARRAY: " . Dumper $subquery;
 598       $collapsed = $self->_collapse_query($subquery, $collapsed);
 599     }
 600   }
 601   elsif (ref $query eq 'HASH') {
 602     if (keys %$query and (keys %$query)[0] eq '-and') {
 603       foreach my $subquery (@{$query->{-and}}) {
 604 #        warn "HASH: " . Dumper $subquery;
 605         $collapsed = $self->_collapse_query($subquery, $collapsed);
 606       }
 607     }
 608     else {
 609 #      warn "LEAF: " . Dumper $query;
 610       foreach my $col (keys %$query) {
 611         my $value = $query->{$col};
 612         $collapsed->{$col}{$value}++;
 613       }
 614     }
 615   }
 616
 617   return $collapsed;
 618 }
 619
 620 =head2 get_column
 621
 622 =over 4
 623
 624 =item Arguments: $cond?
 625
 626 =item Return Value: $resultsetcolumn
 627
 628 =back
 629
 630   my $max_length = $rs->get_column('length')->max;
 631
 632 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 633
 634 =cut
 635
 636 sub get_column {
 637   my ($self, $column) = @_;
 638   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 639   return $new;
 640 }
 641
 642 =head2 search_like
 643
 644 =over 4
 645
 646 =item Arguments: $cond, \%attrs?
 647
 648 =item Return Value: $resultset (scalar context), @row_objs (list context)
 649
 650 =back
 651
 652   # WHERE title LIKE '%blue%'
 653   $cd_rs = $rs->search_like({ title => '%blue%'});
 654
 655 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 656 that this is simply a convenience method. You most likely want to use
 657 L</search> with specific operators.
 658
 659 For more information, see L<DBIx::Class::Manual::Cookbook>.
 660
 661 =cut
 662
 663 sub search_like {
 664   my $class = shift;
 665   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 666   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 667   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 668   return $class->search($query, { %$attrs });
 669 }
 670
 671 =head2 slice
 672
 673 =over 4
 674
 675 =item Arguments: $first, $last
 676
 677 =item Return Value: $resultset (scalar context), @row_objs (list context)
 678
 679 =back
 680
 681 Returns a resultset or object list representing a subset of elements from the
 682 resultset slice is called on. Indexes are from 0, i.e., to get the first
 683 three records, call:
 684
 685   my ($one, $two, $three) = $rs->slice(0, 2);
 686
 687 =cut
 688
 689 sub slice {
 690   my ($self, $min, $max) = @_;
 691   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 692   $attrs->{offset} = $self->{attrs}{offset} || 0;
 693   $attrs->{offset} += $min;
 694   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 695   return $self->search(undef(), $attrs);
 696   #my $slice = (ref $self)->new($self->result_source, $attrs);
 697   #return (wantarray ? $slice->all : $slice);
 698 }
 699
 700 =head2 next
 701
 702 =over 4
 703
 704 =item Arguments: none
 705
 706 =item Return Value: $result?
 707
 708 =back
 709
 710 Returns the next element in the resultset (C<undef> is there is none).
 711
 712 Can be used to efficiently iterate over records in the resultset:
 713
 714   my $rs = $schema->resultset('CD')->search;
 715   while (my $cd = $rs->next) {
 716     print $cd->title;
 717   }
 718
 719 Note that you need to store the resultset object, and call C<next> on it.
 720 Calling C<< resultset('Table')->next >> repeatedly will always return the
 721 first record from the resultset.
 722
 723 =cut
 724
 725 sub next {
 726   my ($self) = @_;
 727   if (my $cache = $self->get_cache) {
 728     $self->{all_cache_position} ||= 0;
 729     return $cache->[$self->{all_cache_position}++];
 730   }
 731   if ($self->{attrs}{cache}) {
 732     $self->{all_cache_position} = 1;
 733     return ($self->all)[0];
 734   }
 735   if ($self->{stashed_objects}) {
 736     my $obj = shift(@{$self->{stashed_objects}});
 737     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 738     return $obj;
 739   }
 740   my @row = (
 741     exists $self->{stashed_row}
 742       ? @{delete $self->{stashed_row}}
 743       : $self->cursor->next
 744   );
 745   return undef unless (@row);
 746   my ($row, @more) = $self->_construct_object(@row);
 747   $self->{stashed_objects} = \@more if @more;
 748   return $row;
 749 }
 750
 751 sub _construct_object {
 752   my ($self, @row) = @_;
 753   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 754   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 755   @new = $self->{_attrs}{record_filter}->(@new)
 756     if exists $self->{_attrs}{record_filter};
 757   return @new;
 758 }
 759
 760 sub _collapse_result {
 761   my ($self, $as_proto, $row) = @_;
 762
 763   my @copy = @$row;
 764
 765   # 'foo'         => [ undef, 'foo' ]
 766   # 'foo.bar'     => [ 'foo', 'bar' ]
 767   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 768
 769   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 770
 771   my %collapse = %{$self->{_attrs}{collapse}||{}};
 772
 773   my @pri_index;
 774
 775   # if we're doing collapsing (has_many prefetch) we need to grab records
 776   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 777   # we know we don't have to bother.
 778
 779   # the reason for not using the collapse stuff directly is because if you
 780   # had for e.g. two artists in a row with no cds, the collapse info for
 781   # both would be NULL (undef) so you'd lose the second artist
 782
 783   # store just the index so we can check the array positions from the row
 784   # without having to contruct the full hash
 785
 786   if (keys %collapse) {
 787     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 788     foreach my $i (0 .. $#construct_as) {
 789       next if defined($construct_as[$i][0]); # only self table
 790       if (delete $pri{$construct_as[$i][1]}) {
 791         push(@pri_index, $i);
 792       }
 793       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 794     }
 795   }
 796
 797   # no need to do an if, it'll be empty if @pri_index is empty anyway
 798
 799   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 800
 801   my @const_rows;
 802
 803   do { # no need to check anything at the front, we always want the first row
 804
 805     my %const;
 806
 807     foreach my $this_as (@construct_as) {
 808       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 809     }
 810
 811     push(@const_rows, \%const);
 812
 813   } until ( # no pri_index => no collapse => drop straight out
 814       !@pri_index
 815     or
 816       do { # get another row, stash it, drop out if different PK
 817
 818         @copy = $self->cursor->next;
 819         $self->{stashed_row} = \@copy;
 820
 821         # last thing in do block, counts as true if anything doesn't match
 822
 823         # check xor defined first for NULL vs. NOT NULL then if one is
 824         # defined the other must be so check string equality
 825
 826         grep {
 827           (defined $pri_vals{$_} ^ defined $copy[$_])
 828           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 829         } @pri_index;
 830       }
 831   );
 832
 833   my $alias = $self->{attrs}{alias};
 834   my $info = [];
 835
 836   my %collapse_pos;
 837
 838   my @const_keys;
 839
 840   foreach my $const (@const_rows) {
 841     scalar @const_keys or do {
 842       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 843     };
 844     foreach my $key (@const_keys) {
 845       if (length $key) {
 846         my $target = $info;
 847         my @parts = split(/\./, $key);
 848         my $cur = '';
 849         my $data = $const->{$key};
 850         foreach my $p (@parts) {
 851           $target = $target->[1]->{$p} ||= [];
 852           $cur .= ".${p}";
 853           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 854             # collapsing at this point and on final part
 855             my $pos = $collapse_pos{$cur};
 856             CK: foreach my $ck (@ckey) {
 857               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 858                 $collapse_pos{$cur} = $data;
 859                 delete @collapse_pos{ # clear all positioning for sub-entries
 860                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 861                 };
 862                 push(@$target, []);
 863                 last CK;
 864               }
 865             }
 866           }
 867           if (exists $collapse{$cur}) {
 868             $target = $target->[-1];
 869           }
 870         }
 871         $target->[0] = $data;
 872       } else {
 873         $info->[0] = $const->{$key};
 874       }
 875     }
 876   }
 877
 878   return $info;
 879 }
 880
 881 =head2 result_source
 882
 883 =over 4
 884
 885 =item Arguments: $result_source?
 886
 887 =item Return Value: $result_source
 888
 889 =back
 890
 891 An accessor for the primary ResultSource object from which this ResultSet
 892 is derived.
 893
 894 =head2 result_class
 895
 896 =over 4
 897
 898 =item Arguments: $result_class?
 899
 900 =item Return Value: $result_class
 901
 902 =back
 903
 904 An accessor for the class to use when creating row objects. Defaults to
 905 C<< result_source->result_class >> - which in most cases is the name of the
 906 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 907
 908 =cut
 909
 910
 911 =head2 count
 912
 913 =over 4
 914
 915 =item Arguments: $cond, \%attrs??
 916
 917 =item Return Value: $count
 918
 919 =back
 920
 921 Performs an SQL C<COUNT> with the same query as the resultset was built
 922 with to find the number of elements. If passed arguments, does a search
 923 on the resultset and counts the results of that.
 924
 925 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 926 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 927 not support C<DISTINCT> with multiple columns. If you are using such a
 928 database, you should only use columns from the main table in your C<group_by>
 929 clause.
 930
 931 =cut
 932
 933 sub count {
 934   my $self = shift;
 935   return $self->search(@_)->count if @_ and defined $_[0];
 936   return scalar @{ $self->get_cache } if $self->get_cache;
 937   my $count = $self->_count;
 938   return 0 unless $count;
 939
 940   # need to take offset from resolved attrs
 941
 942   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
 943   $count = $self->{attrs}{rows} if
 944     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 945   $count = 0 if ($count < 0);
 946   return $count;
 947 }
 948
 949 sub _count { # Separated out so pager can get the full count
 950   my $self = shift;
 951   my $select = { count => '*' };
 952
 953   my $attrs = { %{$self->_resolved_attrs} };
 954   if (my $group_by = delete $attrs->{group_by}) {
 955     delete $attrs->{having};
 956     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 957     # todo: try CONCAT for multi-column pk
 958     my @pk = $self->result_source->primary_columns;
 959     if (@pk == 1) {
 960       my $alias = $attrs->{alias};
 961       foreach my $column (@distinct) {
 962         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
 963           @distinct = ($column);
 964           last;
 965         }
 966       }
 967     }
 968
 969     $select = { count => { distinct => \@distinct } };
 970   }
 971
 972   $attrs->{select} = $select;
 973   $attrs->{as} = [qw/count/];
 974
 975   # offset, order by and page are not needed to count. record_filter is cdbi
 976   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 977
 978   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
 979   my ($count) = $tmp_rs->cursor->next;
 980   return $count;
 981 }
 982
 983 sub _bool {
 984   return 1;
 985 }
 986
 987 =head2 count_literal
 988
 989 =over 4
 990
 991 =item Arguments: $sql_fragment, @bind_values
 992
 993 =item Return Value: $count
 994
 995 =back
 996
 997 Counts the results in a literal query. Equivalent to calling L</search_literal>
 998 with the passed arguments, then L</count>.
 999
1000 =cut
1001
1002 sub count_literal { shift->search_literal(@_)->count; }
1003
1004 =head2 all
1005
1006 =over 4
1007
1008 =item Arguments: none
1009
1010 =item Return Value: @objects
1011
1012 =back
1013
1014 Returns all elements in the resultset. Called implicitly if the resultset
1015 is returned in list context.
1016
1017 =cut
1018
1019 sub all {
1020   my ($self) = @_;
1021   return @{ $self->get_cache } if $self->get_cache;
1022
1023   my @obj;
1024
1025   # TODO: don't call resolve here
1026   if (keys %{$self->_resolved_attrs->{collapse}}) {
1027 #  if ($self->{attrs}{prefetch}) {
1028       # Using $self->cursor->all is really just an optimisation.
1029       # If we're collapsing has_many prefetches it probably makes
1030       # very little difference, and this is cleaner than hacking
1031       # _construct_object to survive the approach
1032     my @row = $self->cursor->next;
1033     while (@row) {
1034       push(@obj, $self->_construct_object(@row));
1035       @row = (exists $self->{stashed_row}
1036                ? @{delete $self->{stashed_row}}
1037                : $self->cursor->next);
1038     }
1039   } else {
1040     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1041   }
1042
1043   $self->set_cache(\@obj) if $self->{attrs}{cache};
1044   return @obj;
1045 }
1046
1047 =head2 reset
1048
1049 =over 4
1050
1051 =item Arguments: none
1052
1053 =item Return Value: $self
1054
1055 =back
1056
1057 Resets the resultset's cursor, so you can iterate through the elements again.
1058
1059 =cut
1060
1061 sub reset {
1062   my ($self) = @_;
1063   delete $self->{_attrs} if exists $self->{_attrs};
1064   $self->{all_cache_position} = 0;
1065   $self->cursor->reset;
1066   return $self;
1067 }
1068
1069 =head2 first
1070
1071 =over 4
1072
1073 =item Arguments: none
1074
1075 =item Return Value: $object?
1076
1077 =back
1078
1079 Resets the resultset and returns an object for the first result (if the
1080 resultset returns anything).
1081
1082 =cut
1083
1084 sub first {
1085   return $_[0]->reset->next;
1086 }
1087
1088 # _cond_for_update_delete
1089 #
1090 # update/delete require the condition to be modified to handle
1091 # the differing SQL syntax available.  This transforms the $self->{cond}
1092 # appropriately, returning the new condition.
1093
1094 sub _cond_for_update_delete {
1095   my ($self, $full_cond) = @_;
1096   my $cond = {};
1097
1098   $full_cond ||= $self->{cond};
1099   # No-op. No condition, we're updating/deleting everything
1100   return $cond unless ref $full_cond;
1101
1102   if (ref $full_cond eq 'ARRAY') {
1103     $cond = [
1104       map {
1105         my %hash;
1106         foreach my $key (keys %{$_}) {
1107           $key =~ /([^.]+)$/;
1108           $hash{$1} = $_->{$key};
1109         }
1110         \%hash;
1111       } @{$full_cond}
1112     ];
1113   }
1114   elsif (ref $full_cond eq 'HASH') {
1115     if ((keys %{$full_cond})[0] eq '-and') {
1116       $cond->{-and} = [];
1117
1118       my @cond = @{$full_cond->{-and}};
1119       for (my $i = 0; $i < @cond; $i++) {
1120         my $entry = $cond[$i];
1121
1122         my $hash;
1123         if (ref $entry eq 'HASH') {
1124           $hash = $self->_cond_for_update_delete($entry);
1125         }
1126         else {
1127           $entry =~ /([^.]+)$/;
1128           $hash->{$1} = $cond[++$i];
1129         }
1130
1131         push @{$cond->{-and}}, $hash;
1132       }
1133     }
1134     else {
1135       foreach my $key (keys %{$full_cond}) {
1136         $key =~ /([^.]+)$/;
1137         $cond->{$1} = $full_cond->{$key};
1138       }
1139     }
1140   }
1141   else {
1142     $self->throw_exception(
1143       "Can't update/delete on resultset with condition unless hash or array"
1144     );
1145   }
1146
1147   return $cond;
1148 }
1149
1150
1151 =head2 update
1152
1153 =over 4
1154
1155 =item Arguments: \%values
1156
1157 =item Return Value: $storage_rv
1158
1159 =back
1160
1161 Sets the specified columns in the resultset to the supplied values in a
1162 single query. Return value will be true if the update succeeded or false
1163 if no records were updated; exact type of success value is storage-dependent.
1164
1165 =cut
1166
1167 sub update {
1168   my ($self, $values) = @_;
1169   $self->throw_exception("Values for update must be a hash")
1170     unless ref $values eq 'HASH';
1171
1172   my $cond = $self->_cond_for_update_delete;
1173
1174   return $self->result_source->storage->update(
1175     $self->result_source, $values, $cond
1176   );
1177 }
1178
1179 =head2 update_all
1180
1181 =over 4
1182
1183 =item Arguments: \%values
1184
1185 =item Return Value: 1
1186
1187 =back
1188
1189 Fetches all objects and updates them one at a time. Note that C<update_all>
1190 will run DBIC cascade triggers, while L</update> will not.
1191
1192 =cut
1193
1194 sub update_all {
1195   my ($self, $values) = @_;
1196   $self->throw_exception("Values for update must be a hash")
1197     unless ref $values eq 'HASH';
1198   foreach my $obj ($self->all) {
1199     $obj->set_columns($values)->update;
1200   }
1201   return 1;
1202 }
1203
1204 =head2 delete
1205
1206 =over 4
1207
1208 =item Arguments: none
1209
1210 =item Return Value: 1
1211
1212 =back
1213
1214 Deletes the contents of the resultset from its result source. Note that this
1215 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1216 to run. See also L<DBIx::Class::Row/delete>.
1217
1218 =cut
1219
1220 sub delete {
1221   my ($self) = @_;
1222
1223   my $cond = $self->_cond_for_update_delete;
1224
1225   $self->result_source->storage->delete($self->result_source, $cond);
1226   return 1;
1227 }
1228
1229 =head2 delete_all
1230
1231 =over 4
1232
1233 =item Arguments: none
1234
1235 =item Return Value: 1
1236
1237 =back
1238
1239 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1240 will run DBIC cascade triggers, while L</delete> will not.
1241
1242 =cut
1243
1244 sub delete_all {
1245   my ($self) = @_;
1246   $_->delete for $self->all;
1247   return 1;
1248 }
1249
1250 =head2 populate
1251
1252 =over 4
1253
1254 =item Arguments: \@data;
1255
1256 =back
1257
1258 Pass an arrayref of hashrefs. Each hashref should be a structure suitable for
1259 submitting to a $resultset->create(...) method.
1260
1261 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1262 to insert the data, as this is a faster method.
1263
1264 Otherwise, each set of data is inserted into the database using
1265 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1266 objects is returned.
1267
1268 Example:  Assuming an Artist Class that has many CDs Classes relating:
1269
1270   my $Artist_rs = $schema->resultset("Artist");
1271
1272   ## Void Context Example
1273   $Artist_rs->populate([
1274      { artistid => 4, name => 'Manufactured Crap', cds => [
1275         { title => 'My First CD', year => 2006 },
1276         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1277       ],
1278      },
1279      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1280         { title => 'My parents sold me to a record company' ,year => 2005 },
1281         { title => 'Why Am I So Ugly?', year => 2006 },
1282         { title => 'I Got Surgery and am now Popular', year => 2007 }
1283       ],
1284      },
1285   ]);
1286
1287   ## Array Context Example
1288   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1289     { name => "Artist One"},
1290     { name => "Artist Two"},
1291     { name => "Artist Three", cds=> [
1292     { title => "First CD", year => 2007},
1293     { title => "Second CD", year => 2008},
1294   ]}
1295   ]);
1296
1297   print $ArtistOne->name; ## response is 'Artist One'
1298   print $ArtistThree->cds->count ## reponse is '2'
1299
1300 Please note an important effect on your data when choosing between void and
1301 wantarray context. Since void context goes straight to C<insert_bulk> in
1302 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1303 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1304 create primary keys for you, you will find that your PKs are empty.  In this
1305 case you will have to use the wantarray context in order to create those
1306 values.
1307
1308 =cut
1309
1310 sub populate {
1311   my ($self, $data) = @_;
1312
1313   if(defined wantarray) {
1314     my @created;
1315     foreach my $item (@$data) {
1316       push(@created, $self->create($item));
1317     }
1318     return @created;
1319   } else {
1320     my ($first, @rest) = @$data;
1321
1322     my @names = grep {!ref $first->{$_}} keys %$first;
1323     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1324     my @pks = $self->result_source->primary_columns;
1325
1326     ## do the belongs_to relationships
1327     foreach my $index (0..$#$data) {
1328       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1329         my @ret = $self->populate($data);
1330         return;
1331       }
1332
1333       foreach my $rel (@rels) {
1334         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1335         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1336         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1337         my $related = $result->result_source->resolve_condition(
1338           $result->result_source->relationship_info($reverse)->{cond},
1339           $self,
1340           $result,
1341         );
1342
1343         delete $data->[$index]->{$rel};
1344         $data->[$index] = {%{$data->[$index]}, %$related};
1345
1346         push @names, keys %$related if $index == 0;
1347       }
1348     }
1349
1350     ## do bulk insert on current row
1351     my @values = map { [ @$_{@names} ] } @$data;
1352
1353     $self->result_source->storage->insert_bulk(
1354       $self->result_source,
1355       \@names,
1356       \@values,
1357     );
1358
1359     ## do the has_many relationships
1360     foreach my $item (@$data) {
1361
1362       foreach my $rel (@rels) {
1363         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1364
1365         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1366      || $self->throw_exception('Cannot find the relating object.');
1367
1368         my $child = $parent->$rel;
1369
1370         my $related = $child->result_source->resolve_condition(
1371           $parent->result_source->relationship_info($rel)->{cond},
1372           $child,
1373           $parent,
1374         );
1375
1376         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1377         my @populate = map { {%$_, %$related} } @rows_to_add;
1378
1379         $child->populate( \@populate );
1380       }
1381     }
1382   }
1383 }
1384
1385 =head2 pager
1386
1387 =over 4
1388
1389 =item Arguments: none
1390
1391 =item Return Value: $pager
1392
1393 =back
1394
1395 Return Value a L<Data::Page> object for the current resultset. Only makes
1396 sense for queries with a C<page> attribute.
1397
1398 =cut
1399
1400 sub pager {
1401   my ($self) = @_;
1402   my $attrs = $self->{attrs};
1403   $self->throw_exception("Can't create pager for non-paged rs")
1404     unless $self->{attrs}{page};
1405   $attrs->{rows} ||= 10;
1406   return $self->{pager} ||= Data::Page->new(
1407     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1408 }
1409
1410 =head2 page
1411
1412 =over 4
1413
1414 =item Arguments: $page_number
1415
1416 =item Return Value: $rs
1417
1418 =back
1419
1420 Returns a resultset for the $page_number page of the resultset on which page
1421 is called, where each page contains a number of rows equal to the 'rows'
1422 attribute set on the resultset (10 by default).
1423
1424 =cut
1425
1426 sub page {
1427   my ($self, $page) = @_;
1428   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1429 }
1430
1431 =head2 new_result
1432
1433 =over 4
1434
1435 =item Arguments: \%vals
1436
1437 =item Return Value: $object
1438
1439 =back
1440
1441 Creates a new row object in the resultset's result class and returns
1442 it. The row is not inserted into the database at this point, call
1443 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1444 will tell you whether the row object has been inserted or not.
1445
1446 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1447
1448 =cut
1449
1450 sub new_result {
1451   my ($self, $values) = @_;
1452   $self->throw_exception( "new_result needs a hash" )
1453     unless (ref $values eq 'HASH');
1454   $self->throw_exception(
1455     "Can't abstract implicit construct, condition not a hash"
1456   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1457
1458   my $alias = $self->{attrs}{alias};
1459   my $collapsed_cond = $self->{cond} ? $self->_collapse_cond($self->{cond}) : {};
1460   my %new = (
1461     %{ $self->_remove_alias($values, $alias) },
1462     %{ $self->_remove_alias($collapsed_cond, $alias) },
1463     -source_handle => $self->_source_handle,
1464     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1465   );
1466
1467   return $self->result_class->new(\%new);
1468 }
1469
1470 # _collapse_cond
1471 #
1472 # Recursively collapse the condition.
1473
1474 sub _collapse_cond {
1475   my ($self, $cond, $collapsed) = @_;
1476
1477   $collapsed ||= {};
1478
1479   if (ref $cond eq 'ARRAY') {
1480     foreach my $subcond (@$cond) {
1481       next unless ref $subcond;  # -or
1482 #      warn "ARRAY: " . Dumper $subcond;
1483       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1484     }
1485   }
1486   elsif (ref $cond eq 'HASH') {
1487     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1488       foreach my $subcond (@{$cond->{-and}}) {
1489 #        warn "HASH: " . Dumper $subcond;
1490         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1491       }
1492     }
1493     else {
1494 #      warn "LEAF: " . Dumper $cond;
1495       foreach my $col (keys %$cond) {
1496         my $value = $cond->{$col};
1497         $collapsed->{$col} = $value;
1498       }
1499     }
1500   }
1501
1502   return $collapsed;
1503 }
1504
1505 # _remove_alias
1506 #
1507 # Remove the specified alias from the specified query hash. A copy is made so
1508 # the original query is not modified.
1509
1510 sub _remove_alias {
1511   my ($self, $query, $alias) = @_;
1512
1513   my %orig = %{ $query || {} };
1514   my %unaliased;
1515
1516   foreach my $key (keys %orig) {
1517     if ($key !~ /\./) {
1518       $unaliased{$key} = $orig{$key};
1519       next;
1520     }
1521     $unaliased{$1} = $orig{$key}
1522       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1523   }
1524
1525   return \%unaliased;
1526 }
1527
1528 =head2 find_or_new
1529
1530 =over 4
1531
1532 =item Arguments: \%vals, \%attrs?
1533
1534 =item Return Value: $object
1535
1536 =back
1537
1538 Find an existing record from this resultset. If none exists, instantiate a new
1539 result object and return it. The object will not be saved into your storage
1540 until you call L<DBIx::Class::Row/insert> on it.
1541
1542 If you want objects to be saved immediately, use L</find_or_create> instead.
1543
1544 =cut
1545
1546 sub find_or_new {
1547   my $self     = shift;
1548   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1549   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1550   my $exists   = $self->find($hash, $attrs);
1551   return defined $exists ? $exists : $self->new_result($hash);
1552 }
1553
1554 =head2 create
1555
1556 =over 4
1557
1558 =item Arguments: \%vals
1559
1560 =item Return Value: $object
1561
1562 =back
1563
1564 Attempt to create a single new row or a row with multiple related rows
1565 in the table represented by the resultset (and related tables). This
1566 will not check for duplicate rows before inserting, use
1567 L</find_or_create> to do that.
1568
1569 To create one row for this resultset, pass a hashref of key/value
1570 pairs representing the columns of the table and the values you wish to
1571 store. If the appropriate relationships are set up, foreign key fields
1572 can also be passed an object representing the foreign row, and the
1573 value will be set to it's primary key.
1574
1575 To create related objects, pass a hashref for the value if the related
1576 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1577 and use the name of the relationship as the key. (NOT the name of the field,
1578 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1579 of hashrefs containing the data for each of the rows to create in the foreign
1580 tables, again using the relationship name as the key.
1581
1582 Instead of hashrefs of plain related data (key/value pairs), you may
1583 also pass new or inserted objects. New objects (not inserted yet, see
1584 L</new>), will be inserted into their appropriate tables.
1585
1586 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1587
1588 Example of creating a new row.
1589
1590   $person_rs->create({
1591     name=>"Some Person",
1592         email=>"somebody@someplace.com"
1593   });
1594
1595 Example of creating a new row and also creating rows in a related C<has_many>
1596 or C<has_one> resultset.  Note Arrayref.
1597
1598   $artist_rs->create(
1599      { artistid => 4, name => 'Manufactured Crap', cds => [
1600         { title => 'My First CD', year => 2006 },
1601         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1602       ],
1603      },
1604   );
1605
1606 Example of creating a new row and also creating a row in a related
1607 C<belongs_to>resultset. Note Hashref.
1608
1609   $cd_rs->create({
1610     title=>"Music for Silly Walks",
1611         year=>2000,
1612         artist => {
1613           name=>"Silly Musician",
1614         }
1615   });
1616
1617 =cut
1618
1619 sub create {
1620   my ($self, $attrs) = @_;
1621   $self->throw_exception( "create needs a hashref" )
1622     unless ref $attrs eq 'HASH';
1623   return $self->new_result($attrs)->insert;
1624 }
1625
1626 =head2 find_or_create
1627
1628 =over 4
1629
1630 =item Arguments: \%vals, \%attrs?
1631
1632 =item Return Value: $object
1633
1634 =back
1635
1636   $class->find_or_create({ key => $val, ... });
1637
1638 Tries to find a record based on its primary key or unique constraint; if none
1639 is found, creates one and returns that instead.
1640
1641   my $cd = $schema->resultset('CD')->find_or_create({
1642     cdid   => 5,
1643     artist => 'Massive Attack',
1644     title  => 'Mezzanine',
1645     year   => 2005,
1646   });
1647
1648 Also takes an optional C<key> attribute, to search by a specific key or unique
1649 constraint. For example:
1650
1651   my $cd = $schema->resultset('CD')->find_or_create(
1652     {
1653       artist => 'Massive Attack',
1654       title  => 'Mezzanine',
1655     },
1656     { key => 'cd_artist_title' }
1657   );
1658
1659 See also L</find> and L</update_or_create>. For information on how to declare
1660 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1661
1662 =cut
1663
1664 sub find_or_create {
1665   my $self     = shift;
1666   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1667   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1668   my $exists   = $self->find($hash, $attrs);
1669   return defined $exists ? $exists : $self->create($hash);
1670 }
1671
1672 =head2 update_or_create
1673
1674 =over 4
1675
1676 =item Arguments: \%col_values, { key => $unique_constraint }?
1677
1678 =item Return Value: $object
1679
1680 =back
1681
1682   $class->update_or_create({ col => $val, ... });
1683
1684 First, searches for an existing row matching one of the unique constraints
1685 (including the primary key) on the source of this resultset. If a row is
1686 found, updates it with the other given column values. Otherwise, creates a new
1687 row.
1688
1689 Takes an optional C<key> attribute to search on a specific unique constraint.
1690 For example:
1691
1692   # In your application
1693   my $cd = $schema->resultset('CD')->update_or_create(
1694     {
1695       artist => 'Massive Attack',
1696       title  => 'Mezzanine',
1697       year   => 1998,
1698     },
1699     { key => 'cd_artist_title' }
1700   );
1701
1702 If no C<key> is specified, it searches on all unique constraints defined on the
1703 source, including the primary key.
1704
1705 If the C<key> is specified as C<primary>, it searches only on the primary key.
1706
1707 See also L</find> and L</find_or_create>. For information on how to declare
1708 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1709
1710 =cut
1711
1712 sub update_or_create {
1713   my $self = shift;
1714   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1715   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1716
1717   my $row = $self->find($cond, $attrs);
1718   if (defined $row) {
1719     $row->update($cond);
1720     return $row;
1721   }
1722
1723   return $self->create($cond);
1724 }
1725
1726 =head2 get_cache
1727
1728 =over 4
1729
1730 =item Arguments: none
1731
1732 =item Return Value: \@cache_objects?
1733
1734 =back
1735
1736 Gets the contents of the cache for the resultset, if the cache is set.
1737
1738 =cut
1739
1740 sub get_cache {
1741   shift->{all_cache};
1742 }
1743
1744 =head2 set_cache
1745
1746 =over 4
1747
1748 =item Arguments: \@cache_objects
1749
1750 =item Return Value: \@cache_objects
1751
1752 =back
1753
1754 Sets the contents of the cache for the resultset. Expects an arrayref
1755 of objects of the same class as those produced by the resultset. Note that
1756 if the cache is set the resultset will return the cached objects rather
1757 than re-querying the database even if the cache attr is not set.
1758
1759 =cut
1760
1761 sub set_cache {
1762   my ( $self, $data ) = @_;
1763   $self->throw_exception("set_cache requires an arrayref")
1764       if defined($data) && (ref $data ne 'ARRAY');
1765   $self->{all_cache} = $data;
1766 }
1767
1768 =head2 clear_cache
1769
1770 =over 4
1771
1772 =item Arguments: none
1773
1774 =item Return Value: []
1775
1776 =back
1777
1778 Clears the cache for the resultset.
1779
1780 =cut
1781
1782 sub clear_cache {
1783   shift->set_cache(undef);
1784 }
1785
1786 =head2 related_resultset
1787
1788 =over 4
1789
1790 =item Arguments: $relationship_name
1791
1792 =item Return Value: $resultset
1793
1794 =back
1795
1796 Returns a related resultset for the supplied relationship name.
1797
1798   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1799
1800 =cut
1801
1802 sub related_resultset {
1803   my ($self, $rel) = @_;
1804
1805   $self->{related_resultsets} ||= {};
1806   return $self->{related_resultsets}{$rel} ||= do {
1807     my $rel_obj = $self->result_source->relationship_info($rel);
1808
1809     $self->throw_exception(
1810       "search_related: result source '" . $self->result_source->source_name .
1811         "' has no such relationship $rel")
1812       unless $rel_obj;
1813
1814     my ($from,$seen) = $self->_resolve_from($rel);
1815
1816     my $join_count = $seen->{$rel};
1817     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
1818
1819     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
1820     my %attrs = %{$self->{attrs}||{}};
1821     delete @attrs{qw(result_class alias)};
1822
1823     my $new_cache;
1824
1825     if (my $cache = $self->get_cache) {
1826       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
1827         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
1828                         @$cache ];
1829       }
1830     }
1831
1832     my $rel_source = $self->result_source->related_source($rel);
1833
1834     my $new = do {
1835
1836       # The reason we do this now instead of passing the alias to the
1837       # search_rs below is that if you wrap/overload resultset on the
1838       # source you need to know what alias it's -going- to have for things
1839       # to work sanely (e.g. RestrictWithObject wants to be able to add
1840       # extra query restrictions, and these may need to be $alias.)
1841
1842       my $attrs = $rel_source->resultset_attributes;
1843       local $attrs->{alias} = $alias;
1844
1845       $rel_source->resultset
1846                  ->search_rs(
1847                      undef, {
1848                        %attrs,
1849                        join => undef,
1850                        prefetch => undef,
1851                        select => undef,
1852                        as => undef,
1853                        where => $self->{cond},
1854                        seen_join => $seen,
1855                        from => $from,
1856                    });
1857     };
1858     $new->set_cache($new_cache) if $new_cache;
1859     $new;
1860   };
1861 }
1862
1863 sub _resolve_from {
1864   my ($self, $extra_join) = @_;
1865   my $source = $self->result_source;
1866   my $attrs = $self->{attrs};
1867
1868   my $from = $attrs->{from}
1869     || [ { $attrs->{alias} => $source->from } ];
1870
1871   my $seen = { %{$attrs->{seen_join}||{}} };
1872
1873   my $join = ($attrs->{join}
1874                ? [ $attrs->{join}, $extra_join ]
1875                : $extra_join);
1876
1877   # we need to take the prefetch the attrs into account before we
1878   # ->resolve_join as otherwise they get lost - captainL
1879   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
1880
1881   $from = [
1882     @$from,
1883     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
1884   ];
1885
1886   return ($from,$seen);
1887 }
1888
1889 sub _resolved_attrs {
1890   my $self = shift;
1891   return $self->{_attrs} if $self->{_attrs};
1892
1893   my $attrs = { %{$self->{attrs}||{}} };
1894   my $source = $self->result_source;
1895   my $alias = $attrs->{alias};
1896
1897   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
1898   if ($attrs->{columns}) {
1899     delete $attrs->{as};
1900   } elsif (!$attrs->{select}) {
1901     $attrs->{columns} = [ $source->columns ];
1902   }
1903
1904   $attrs->{select} =
1905     ($attrs->{select}
1906       ? (ref $attrs->{select} eq 'ARRAY'
1907           ? [ @{$attrs->{select}} ]
1908           : [ $attrs->{select} ])
1909       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
1910     );
1911   $attrs->{as} =
1912     ($attrs->{as}
1913       ? (ref $attrs->{as} eq 'ARRAY'
1914           ? [ @{$attrs->{as}} ]
1915           : [ $attrs->{as} ])
1916       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
1917     );
1918
1919   my $adds;
1920   if ($adds = delete $attrs->{include_columns}) {
1921     $adds = [$adds] unless ref $adds eq 'ARRAY';
1922     push(@{$attrs->{select}}, @$adds);
1923     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
1924   }
1925   if ($adds = delete $attrs->{'+select'}) {
1926     $adds = [$adds] unless ref $adds eq 'ARRAY';
1927     push(@{$attrs->{select}},
1928            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
1929   }
1930   if (my $adds = delete $attrs->{'+as'}) {
1931     $adds = [$adds] unless ref $adds eq 'ARRAY';
1932     push(@{$attrs->{as}}, @$adds);
1933   }
1934
1935   $attrs->{from} ||= [ { 'me' => $source->from } ];
1936
1937   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
1938     my $join = delete $attrs->{join} || {};
1939
1940     if (defined $attrs->{prefetch}) {
1941       $join = $self->_merge_attr(
1942         $join, $attrs->{prefetch}
1943       );
1944
1945     }
1946
1947     $attrs->{from} =   # have to copy here to avoid corrupting the original
1948       [
1949         @{$attrs->{from}},
1950         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
1951       ];
1952
1953   }
1954
1955   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
1956   if ($attrs->{order_by}) {
1957     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
1958                            ? [ @{$attrs->{order_by}} ]
1959                            : [ $attrs->{order_by} ]);
1960   } else {
1961     $attrs->{order_by} = [];
1962   }
1963
1964   my $collapse = $attrs->{collapse} || {};
1965   if (my $prefetch = delete $attrs->{prefetch}) {
1966     $prefetch = $self->_merge_attr({}, $prefetch);
1967     my @pre_order;
1968     my $seen = $attrs->{seen_join} || {};
1969     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
1970       # bring joins back to level of current class
1971       my @prefetch = $source->resolve_prefetch(
1972         $p, $alias, $seen, \@pre_order, $collapse
1973       );
1974       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
1975       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
1976     }
1977     push(@{$attrs->{order_by}}, @pre_order);
1978   }
1979   $attrs->{collapse} = $collapse;
1980
1981   if ($attrs->{page}) {
1982     $attrs->{offset} ||= 0;
1983     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
1984   }
1985
1986   return $self->{_attrs} = $attrs;
1987 }
1988
1989 sub _rollout_attr {
1990   my ($self, $attr) = @_;
1991
1992   if (ref $attr eq 'HASH') {
1993     return $self->_rollout_hash($attr);
1994   } elsif (ref $attr eq 'ARRAY') {
1995     return $self->_rollout_array($attr);
1996   } else {
1997     return [$attr];
1998   }
1999 }
2000
2001 sub _rollout_array {
2002   my ($self, $attr) = @_;
2003
2004   my @rolled_array;
2005   foreach my $element (@{$attr}) {
2006     if (ref $element eq 'HASH') {
2007       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2008     } elsif (ref $element eq 'ARRAY') {
2009       #  XXX - should probably recurse here
2010       push( @rolled_array, @{$self->_rollout_array($element)} );
2011     } else {
2012       push( @rolled_array, $element );
2013     }
2014   }
2015   return \@rolled_array;
2016 }
2017
2018 sub _rollout_hash {
2019   my ($self, $attr) = @_;
2020
2021   my @rolled_array;
2022   foreach my $key (keys %{$attr}) {
2023     push( @rolled_array, { $key => $attr->{$key} } );
2024   }
2025   return \@rolled_array;
2026 }
2027
2028 sub _calculate_score {
2029   my ($self, $a, $b) = @_;
2030
2031   if (ref $b eq 'HASH') {
2032     my ($b_key) = keys %{$b};
2033     if (ref $a eq 'HASH') {
2034       my ($a_key) = keys %{$a};
2035       if ($a_key eq $b_key) {
2036         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2037       } else {
2038         return 0;
2039       }
2040     } else {
2041       return ($a eq $b_key) ? 1 : 0;
2042     }
2043   } else {
2044     if (ref $a eq 'HASH') {
2045       my ($a_key) = keys %{$a};
2046       return ($b eq $a_key) ? 1 : 0;
2047     } else {
2048       return ($b eq $a) ? 1 : 0;
2049     }
2050   }
2051 }
2052
2053 sub _merge_attr {
2054   my ($self, $a, $b) = @_;
2055
2056   return $b unless defined($a);
2057   return $a unless defined($b);
2058
2059   $a = $self->_rollout_attr($a);
2060   $b = $self->_rollout_attr($b);
2061
2062   my $seen_keys;
2063   foreach my $b_element ( @{$b} ) {
2064     # find best candidate from $a to merge $b_element into
2065     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2066     foreach my $a_element ( @{$a} ) {
2067       my $score = $self->_calculate_score( $a_element, $b_element );
2068       if ($score > $best_candidate->{score}) {
2069         $best_candidate->{position} = $position;
2070         $best_candidate->{score} = $score;
2071       }
2072       $position++;
2073     }
2074     my ($b_key) = ( ref $b_element eq 'HASH' ) ? keys %{$b_element} : ($b_element);
2075     if ($best_candidate->{score} == 0 || exists $seen_keys->{$b_key}) {
2076       push( @{$a}, $b_element );
2077     } else {
2078       $seen_keys->{$b_key} = 1; # don't merge the same key twice
2079       my $a_best = $a->[$best_candidate->{position}];
2080       # merge a_best and b_element together and replace original with merged
2081       if (ref $a_best ne 'HASH') {
2082         $a->[$best_candidate->{position}] = $b_element;
2083       } elsif (ref $b_element eq 'HASH') {
2084         my ($key) = keys %{$a_best};
2085         $a->[$best_candidate->{position}] = { $key => $self->_merge_attr($a_best->{$key}, $b_element->{$key}) };
2086       }
2087     }
2088   }
2089
2090   return $a;
2091 }
2092
2093 sub result_source {
2094     my $self = shift;
2095
2096     if (@_) {
2097         $self->_source_handle($_[0]->handle);
2098     } else {
2099         $self->_source_handle->resolve;
2100     }
2101 }
2102
2103 =head2 throw_exception
2104
2105 See L<DBIx::Class::Schema/throw_exception> for details.
2106
2107 =cut
2108
2109 sub throw_exception {
2110   my $self=shift;
2111   $self->_source_handle->schema->throw_exception(@_);
2112 }
2113
2114 # XXX: FIXME: Attributes docs need clearing up
2115
2116 =head1 ATTRIBUTES
2117
2118 The resultset takes various attributes that modify its behavior. Here's an
2119 overview of them:
2120
2121 =head2 order_by
2122
2123 =over 4
2124
2125 =item Value: ($order_by | \@order_by)
2126
2127 =back
2128
2129 Which column(s) to order the results by. This is currently passed
2130 through directly to SQL, so you can give e.g. C<year DESC> for a
2131 descending order on the column `year'.
2132
2133 Please note that if you have C<quote_char> enabled (see
2134 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
2135 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
2136 so you will need to manually quote things as appropriate.)
2137
2138 =head2 columns
2139
2140 =over 4
2141
2142 =item Value: \@columns
2143
2144 =back
2145
2146 Shortcut to request a particular set of columns to be retrieved.  Adds
2147 C<me.> onto the start of any column without a C<.> in it and sets C<select>
2148 from that, then auto-populates C<as> from C<select> as normal. (You may also
2149 use the C<cols> attribute, as in earlier versions of DBIC.)
2150
2151 =head2 include_columns
2152
2153 =over 4
2154
2155 =item Value: \@columns
2156
2157 =back
2158
2159 Shortcut to include additional columns in the returned results - for example
2160
2161   $schema->resultset('CD')->search(undef, {
2162     include_columns => ['artist.name'],
2163     join => ['artist']
2164   });
2165
2166 would return all CDs and include a 'name' column to the information
2167 passed to object inflation. Note that the 'artist' is the name of the
2168 column (or relationship) accessor, and 'name' is the name of the column
2169 accessor in the related table.
2170
2171 =head2 select
2172
2173 =over 4
2174
2175 =item Value: \@select_columns
2176
2177 =back
2178
2179 Indicates which columns should be selected from the storage. You can use
2180 column names, or in the case of RDBMS back ends, function or stored procedure
2181 names:
2182
2183   $rs = $schema->resultset('Employee')->search(undef, {
2184     select => [
2185       'name',
2186       { count => 'employeeid' },
2187       { sum => 'salary' }
2188     ]
2189   });
2190
2191 When you use function/stored procedure names and do not supply an C<as>
2192 attribute, the column names returned are storage-dependent. E.g. MySQL would
2193 return a column named C<count(employeeid)> in the above example.
2194
2195 =head2 +select
2196
2197 =over 4
2198
2199 Indicates additional columns to be selected from storage.  Works the same as
2200 L<select> but adds columns to the selection.
2201
2202 =back
2203
2204 =head2 +as
2205
2206 =over 4
2207
2208 Indicates additional column names for those added via L<+select>.
2209
2210 =back
2211
2212 =head2 as
2213
2214 =over 4
2215
2216 =item Value: \@inflation_names
2217
2218 =back
2219
2220 Indicates column names for object inflation. That is, c< as >
2221 indicates the name that the column can be accessed as via the
2222 C<get_column> method (or via the object accessor, B<if one already
2223 exists>).  It has nothing to do with the SQL code C< SELECT foo AS bar
2224 >.
2225
2226 The C<as> attribute is used in conjunction with C<select>,
2227 usually when C<select> contains one or more function or stored
2228 procedure names:
2229
2230   $rs = $schema->resultset('Employee')->search(undef, {
2231     select => [
2232       'name',
2233       { count => 'employeeid' }
2234     ],
2235     as => ['name', 'employee_count'],
2236   });
2237
2238   my $employee = $rs->first(); # get the first Employee
2239
2240 If the object against which the search is performed already has an accessor
2241 matching a column name specified in C<as>, the value can be retrieved using
2242 the accessor as normal:
2243
2244   my $name = $employee->name();
2245
2246 If on the other hand an accessor does not exist in the object, you need to
2247 use C<get_column> instead:
2248
2249   my $employee_count = $employee->get_column('employee_count');
2250
2251 You can create your own accessors if required - see
2252 L<DBIx::Class::Manual::Cookbook> for details.
2253
2254 Please note: This will NOT insert an C<AS employee_count> into the SQL
2255 statement produced, it is used for internal access only. Thus
2256 attempting to use the accessor in an C<order_by> clause or similar
2257 will fail miserably.
2258
2259 To get around this limitation, you can supply literal SQL to your
2260 C<select> attibute that contains the C<AS alias> text, eg:
2261
2262   select => [\'myfield AS alias']
2263
2264 =head2 join
2265
2266 =over 4
2267
2268 =item Value: ($rel_name | \@rel_names | \%rel_names)
2269
2270 =back
2271
2272 Contains a list of relationships that should be joined for this query.  For
2273 example:
2274
2275   # Get CDs by Nine Inch Nails
2276   my $rs = $schema->resultset('CD')->search(
2277     { 'artist.name' => 'Nine Inch Nails' },
2278     { join => 'artist' }
2279   );
2280
2281 Can also contain a hash reference to refer to the other relation's relations.
2282 For example:
2283
2284   package MyApp::Schema::Track;
2285   use base qw/DBIx::Class/;
2286   __PACKAGE__->table('track');
2287   __PACKAGE__->add_columns(qw/trackid cd position title/);
2288   __PACKAGE__->set_primary_key('trackid');
2289   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2290   1;
2291
2292   # In your application
2293   my $rs = $schema->resultset('Artist')->search(
2294     { 'track.title' => 'Teardrop' },
2295     {
2296       join     => { cd => 'track' },
2297       order_by => 'artist.name',
2298     }
2299   );
2300
2301 You need to use the relationship (not the table) name in  conditions,
2302 because they are aliased as such. The current table is aliased as "me", so
2303 you need to use me.column_name in order to avoid ambiguity. For example:
2304
2305   # Get CDs from 1984 with a 'Foo' track
2306   my $rs = $schema->resultset('CD')->search(
2307     {
2308       'me.year' => 1984,
2309       'tracks.name' => 'Foo'
2310     },
2311     { join => 'tracks' }
2312   );
2313
2314 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2315 similarly for a third time). For e.g.
2316
2317   my $rs = $schema->resultset('Artist')->search({
2318     'cds.title'   => 'Down to Earth',
2319     'cds_2.title' => 'Popular',
2320   }, {
2321     join => [ qw/cds cds/ ],
2322   });
2323
2324 will return a set of all artists that have both a cd with title 'Down
2325 to Earth' and a cd with title 'Popular'.
2326
2327 If you want to fetch related objects from other tables as well, see C<prefetch>
2328 below.
2329
2330 =head2 prefetch
2331
2332 =over 4
2333
2334 =item Value: ($rel_name | \@rel_names | \%rel_names)
2335
2336 =back
2337
2338 Contains one or more relationships that should be fetched along with
2339 the main query (when they are accessed afterwards the data will
2340 already be available, without extra queries to the database).  This is
2341 useful for when you know you will need the related objects, because it
2342 saves at least one query:
2343
2344   my $rs = $schema->resultset('Tag')->search(
2345     undef,
2346     {
2347       prefetch => {
2348         cd => 'artist'
2349       }
2350     }
2351   );
2352
2353 The initial search results in SQL like the following:
2354
2355   SELECT tag.*, cd.*, artist.* FROM tag
2356   JOIN cd ON tag.cd = cd.cdid
2357   JOIN artist ON cd.artist = artist.artistid
2358
2359 L<DBIx::Class> has no need to go back to the database when we access the
2360 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2361 case.
2362
2363 Simple prefetches will be joined automatically, so there is no need
2364 for a C<join> attribute in the above search. If you're prefetching to
2365 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
2366 specify the join as well.
2367
2368 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2369 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2370 with an accessor type of 'single' or 'filter').
2371
2372 =head2 page
2373
2374 =over 4
2375
2376 =item Value: $page
2377
2378 =back
2379
2380 Makes the resultset paged and specifies the page to retrieve. Effectively
2381 identical to creating a non-pages resultset and then calling ->page($page)
2382 on it.
2383
2384 If L<rows> attribute is not specified it defualts to 10 rows per page.
2385
2386 =head2 rows
2387
2388 =over 4
2389
2390 =item Value: $rows
2391
2392 =back
2393
2394 Specifes the maximum number of rows for direct retrieval or the number of
2395 rows per page if the page attribute or method is used.
2396
2397 =head2 offset
2398
2399 =over 4
2400
2401 =item Value: $offset
2402
2403 =back
2404
2405 Specifies the (zero-based) row number for the  first row to be returned, or the
2406 of the first row of the first page if paging is used.
2407
2408 =head2 group_by
2409
2410 =over 4
2411
2412 =item Value: \@columns
2413
2414 =back
2415
2416 A arrayref of columns to group by. Can include columns of joined tables.
2417
2418   group_by => [qw/ column1 column2 ... /]
2419
2420 =head2 having
2421
2422 =over 4
2423
2424 =item Value: $condition
2425
2426 =back
2427
2428 HAVING is a select statement attribute that is applied between GROUP BY and
2429 ORDER BY. It is applied to the after the grouping calculations have been
2430 done.
2431
2432   having => { 'count(employee)' => { '>=', 100 } }
2433
2434 =head2 distinct
2435
2436 =over 4
2437
2438 =item Value: (0 | 1)
2439
2440 =back
2441
2442 Set to 1 to group by all columns.
2443
2444 =head2 where
2445
2446 =over 4
2447
2448 Adds to the WHERE clause.
2449
2450   # only return rows WHERE deleted IS NULL for all searches
2451   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2452
2453 Can be overridden by passing C<{ where => undef }> as an attribute
2454 to a resulset.
2455
2456 =back
2457
2458 =head2 cache
2459
2460 Set to 1 to cache search results. This prevents extra SQL queries if you
2461 revisit rows in your ResultSet:
2462
2463   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2464
2465   while( my $artist = $resultset->next ) {
2466     ... do stuff ...
2467   }
2468
2469   $rs->first; # without cache, this would issue a query
2470
2471 By default, searches are not cached.
2472
2473 For more examples of using these attributes, see
2474 L<DBIx::Class::Manual::Cookbook>.
2475
2476 =head2 from
2477
2478 =over 4
2479
2480 =item Value: \@from_clause
2481
2482 =back
2483
2484 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2485 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2486 clauses.
2487
2488 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2489
2490 C<join> will usually do what you need and it is strongly recommended that you
2491 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2492 And we really do mean "cannot", not just tried and failed. Attempting to use
2493 this because you're having problems with C<join> is like trying to use x86
2494 ASM because you've got a syntax error in your C. Trust us on this.
2495
2496 Now, if you're still really, really sure you need to use this (and if you're
2497 not 100% sure, ask the mailing list first), here's an explanation of how this
2498 works.
2499
2500 The syntax is as follows -
2501
2502   [
2503     { <alias1> => <table1> },
2504     [
2505       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2506       [], # nested JOIN (optional)
2507       { <table1.column1> => <table2.column2>, ... (more conditions) },
2508     ],
2509     # More of the above [ ] may follow for additional joins
2510   ]
2511
2512   <table1> <alias1>
2513   JOIN
2514     <table2> <alias2>
2515     [JOIN ...]
2516   ON <table1.column1> = <table2.column2>
2517   <more joins may follow>
2518
2519 An easy way to follow the examples below is to remember the following:
2520
2521     Anything inside "[]" is a JOIN
2522     Anything inside "{}" is a condition for the enclosing JOIN
2523
2524 The following examples utilize a "person" table in a family tree application.
2525 In order to express parent->child relationships, this table is self-joined:
2526
2527     # Person->belongs_to('father' => 'Person');
2528     # Person->belongs_to('mother' => 'Person');
2529
2530 C<from> can be used to nest joins. Here we return all children with a father,
2531 then search against all mothers of those children:
2532
2533   $rs = $schema->resultset('Person')->search(
2534       undef,
2535       {
2536           alias => 'mother', # alias columns in accordance with "from"
2537           from => [
2538               { mother => 'person' },
2539               [
2540                   [
2541                       { child => 'person' },
2542                       [
2543                           { father => 'person' },
2544                           { 'father.person_id' => 'child.father_id' }
2545                       ]
2546                   ],
2547                   { 'mother.person_id' => 'child.mother_id' }
2548               ],
2549           ]
2550       },
2551   );
2552
2553   # Equivalent SQL:
2554   # SELECT mother.* FROM person mother
2555   # JOIN (
2556   #   person child
2557   #   JOIN person father
2558   #   ON ( father.person_id = child.father_id )
2559   # )
2560   # ON ( mother.person_id = child.mother_id )
2561
2562 The type of any join can be controlled manually. To search against only people
2563 with a father in the person table, we could explicitly use C<INNER JOIN>:
2564
2565     $rs = $schema->resultset('Person')->search(
2566         undef,
2567         {
2568             alias => 'child', # alias columns in accordance with "from"
2569             from => [
2570                 { child => 'person' },
2571                 [
2572                     { father => 'person', -join_type => 'inner' },
2573                     { 'father.id' => 'child.father_id' }
2574                 ],
2575             ]
2576         },
2577     );
2578
2579     # Equivalent SQL:
2580     # SELECT child.* FROM person child
2581     # INNER JOIN person father ON child.father_id = father.id
2582
2583 =cut
2584
2585 1;