lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => \&count,
   7         'bool'   => sub { 1; },
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use base qw/DBIx::Class/;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/result_class _source_handle/);
  17
  18 =head1 NAME
  19
  20 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  21
  22 =head1 SYNOPSIS
  23
  24   my $rs   = $schema->resultset('User')->search(registered => 1);
  25   my @rows = $schema->resultset('CD')->search(year => 2005);
  26
  27 =head1 DESCRIPTION
  28
  29 The resultset is also known as an iterator. It is responsible for handling
  30 queries that may return an arbitrary number of rows, e.g. via L</search>
  31 or a C<has_many> relationship.
  32
  33 In the examples below, the following table classes are used:
  34
  35   package MyApp::Schema::Artist;
  36   use base qw/DBIx::Class/;
  37   __PACKAGE__->load_components(qw/Core/);
  38   __PACKAGE__->table('artist');
  39   __PACKAGE__->add_columns(qw/artistid name/);
  40   __PACKAGE__->set_primary_key('artistid');
  41   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  42   1;
  43
  44   package MyApp::Schema::CD;
  45   use base qw/DBIx::Class/;
  46   __PACKAGE__->load_components(qw/Core/);
  47   __PACKAGE__->table('cd');
  48   __PACKAGE__->add_columns(qw/cdid artist title year/);
  49   __PACKAGE__->set_primary_key('cdid');
  50   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  51   1;
  52
  53 =head1 METHODS
  54
  55 =head2 new
  56
  57 =over 4
  58
  59 =item Arguments: $source, \%$attrs
  60
  61 =item Return Value: $rs
  62
  63 =back
  64
  65 The resultset constructor. Takes a source object (usually a
  66 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  67 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  68 executed as needed by the other methods.
  69
  70 Generally you won't need to construct a resultset manually.  You'll
  71 automatically get one from e.g. a L</search> called in scalar context:
  72
  73   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  74
  75 IMPORTANT: If called on an object, proxies to new_result instead so
  76
  77   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  78
  79 will return a CD object, not a ResultSet.
  80
  81 =cut
  82
  83 sub new {
  84   my $class = shift;
  85   return $class->new_result(@_) if ref $class;
  86
  87   my ($source, $attrs) = @_;
  88   $source = $source->handle
  89     unless $source->isa('DBIx::Class::ResultSourceHandle');
  90   $attrs = { %{$attrs||{}} };
  91
  92   if ($attrs->{page}) {
  93     $attrs->{rows} ||= 10;
  94   }
  95
  96   $attrs->{alias} ||= 'me';
  97
  98   my $self = {
  99     _source_handle => $source,
 100     result_class => $attrs->{result_class} || $source->resolve->result_class,
 101     cond => $attrs->{where},
 102     count => undef,
 103     pager => undef,
 104     attrs => $attrs
 105   };
 106
 107   bless $self, $class;
 108
 109   return $self;
 110 }
 111
 112 =head2 search
 113
 114 =over 4
 115
 116 =item Arguments: $cond, \%attrs?
 117
 118 =item Return Value: $resultset (scalar context), @row_objs (list context)
 119
 120 =back
 121
 122   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 123   my $new_rs = $cd_rs->search({ year => 2005 });
 124
 125   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 126                  # year = 2005 OR year = 2004
 127
 128 If you need to pass in additional attributes but no additional condition,
 129 call it as C<search(undef, \%attrs)>.
 130
 131   # "SELECT name, artistid FROM $artist_table"
 132   my @all_artists = $schema->resultset('Artist')->search(undef, {
 133     columns => [qw/name artistid/],
 134   });
 135
 136 For a list of attributes that can be passed to C<search>, see
 137 L</ATTRIBUTES>. For more examples of using this function, see
 138 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 139 documentation for the first argument, see L<SQL::Abstract>.
 140
 141 =cut
 142
 143 sub search {
 144   my $self = shift;
 145   my $rs = $self->search_rs( @_ );
 146   return (wantarray ? $rs->all : $rs);
 147 }
 148
 149 =head2 search_rs
 150
 151 =over 4
 152
 153 =item Arguments: $cond, \%attrs?
 154
 155 =item Return Value: $resultset
 156
 157 =back
 158
 159 This method does the same exact thing as search() except it will
 160 always return a resultset, even in list context.
 161
 162 =cut
 163
 164 sub search_rs {
 165   my $self = shift;
 166
 167   my $rows;
 168
 169   unless (@_) {                 # no search, effectively just a clone
 170     $rows = $self->get_cache;
 171   }
 172
 173   my $attrs = {};
 174   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 175   my $our_attrs = { %{$self->{attrs}} };
 176   my $having = delete $our_attrs->{having};
 177   my $where = delete $our_attrs->{where};
 178
 179   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 180
 181   # merge new attrs into inherited
 182   foreach my $key (qw/join prefetch/) {
 183     next unless exists $attrs->{$key};
 184     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 185   }
 186
 187   my $cond = (@_
 188     ? (
 189         (@_ == 1 || ref $_[0] eq "HASH")
 190           ? (
 191               (ref $_[0] eq 'HASH')
 192                 ? (
 193                     (keys %{ $_[0] }  > 0)
 194                       ? shift
 195                       : undef
 196                    )
 197                 :  shift
 198              )
 199           : (
 200               (@_ % 2)
 201                 ? $self->throw_exception("Odd number of arguments to search")
 202                 : {@_}
 203              )
 204       )
 205     : undef
 206   );
 207
 208   if (defined $where) {
 209     $new_attrs->{where} = (
 210       defined $new_attrs->{where}
 211         ? { '-and' => [
 212               map {
 213                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 214               } $where, $new_attrs->{where}
 215             ]
 216           }
 217         : $where);
 218   }
 219
 220   if (defined $cond) {
 221     $new_attrs->{where} = (
 222       defined $new_attrs->{where}
 223         ? { '-and' => [
 224               map {
 225                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 226               } $cond, $new_attrs->{where}
 227             ]
 228           }
 229         : $cond);
 230   }
 231
 232   if (defined $having) {
 233     $new_attrs->{having} = (
 234       defined $new_attrs->{having}
 235         ? { '-and' => [
 236               map {
 237                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 238               } $having, $new_attrs->{having}
 239             ]
 240           }
 241         : $having);
 242   }
 243
 244   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 245   if ($rows) {
 246     $rs->set_cache($rows);
 247   }
 248   return $rs;
 249 }
 250
 251 =head2 search_literal
 252
 253 =over 4
 254
 255 =item Arguments: $sql_fragment, @bind_values
 256
 257 =item Return Value: $resultset (scalar context), @row_objs (list context)
 258
 259 =back
 260
 261   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 262   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 263
 264 Pass a literal chunk of SQL to be added to the conditional part of the
 265 resultset query.
 266
 267 =cut
 268
 269 sub search_literal {
 270   my ($self, $cond, @vals) = @_;
 271   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 272   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 273   return $self->search(\$cond, $attrs);
 274 }
 275
 276 =head2 find
 277
 278 =over 4
 279
 280 =item Arguments: @values | \%cols, \%attrs?
 281
 282 =item Return Value: $row_object
 283
 284 =back
 285
 286 Finds a row based on its primary key or unique constraint. For example, to find
 287 a row by its primary key:
 288
 289   my $cd = $schema->resultset('CD')->find(5);
 290
 291 You can also find a row by a specific unique constraint using the C<key>
 292 attribute. For example:
 293
 294   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 295     key => 'cd_artist_title'
 296   });
 297
 298 Additionally, you can specify the columns explicitly by name:
 299
 300   my $cd = $schema->resultset('CD')->find(
 301     {
 302       artist => 'Massive Attack',
 303       title  => 'Mezzanine',
 304     },
 305     { key => 'cd_artist_title' }
 306   );
 307
 308 If the C<key> is specified as C<primary>, it searches only on the primary key.
 309
 310 If no C<key> is specified, it searches on all unique constraints defined on the
 311 source, including the primary key.
 312
 313 If your table does not have a primary key, you B<must> provide a value for the
 314 C<key> attribute matching one of the unique constraints on the source.
 315
 316 See also L</find_or_create> and L</update_or_create>. For information on how to
 317 declare unique constraints, see
 318 L<DBIx::Class::ResultSource/add_unique_constraint>.
 319
 320 =cut
 321
 322 sub find {
 323   my $self = shift;
 324   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 325
 326   # Default to the primary key, but allow a specific key
 327   my @cols = exists $attrs->{key}
 328     ? $self->result_source->unique_constraint_columns($attrs->{key})
 329     : $self->result_source->primary_columns;
 330   $self->throw_exception(
 331     "Can't find unless a primary key is defined or unique constraint is specified"
 332   ) unless @cols;
 333
 334   # Parse out a hashref from input
 335   my $input_query;
 336   if (ref $_[0] eq 'HASH') {
 337     $input_query = { %{$_[0]} };
 338   }
 339   elsif (@_ == @cols) {
 340     $input_query = {};
 341     @{$input_query}{@cols} = @_;
 342   }
 343   else {
 344     # Compatibility: Allow e.g. find(id => $value)
 345     carp "Find by key => value deprecated; please use a hashref instead";
 346     $input_query = {@_};
 347   }
 348
 349   my (%related, $info);
 350
 351   KEY: foreach my $key (keys %$input_query) {
 352     if (ref($input_query->{$key})
 353         && ($info = $self->result_source->relationship_info($key))) {
 354       my $val = delete $input_query->{$key};
 355       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 356       my $rel_q = $self->result_source->resolve_condition(
 357                     $info->{cond}, $val, $key
 358                   );
 359       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 360       @related{keys %$rel_q} = values %$rel_q;
 361     }
 362   }
 363   if (my @keys = keys %related) {
 364     @{$input_query}{@keys} = values %related;
 365   }
 366
 367   my @unique_queries = $self->_unique_queries($input_query, $attrs);
 368
 369   # Build the final query: Default to the disjunction of the unique queries,
 370   # but allow the input query in case the ResultSet defines the query or the
 371   # user is abusing find
 372   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 373   my $query = @unique_queries
 374     ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 375     : $self->_add_alias($input_query, $alias);
 376
 377   # Run the query
 378   if (keys %$attrs) {
 379     my $rs = $self->search($query, $attrs);
 380     return keys %{$rs->_resolved_attrs->{collapse}} ? $rs->next : $rs->single;
 381   }
 382   else {
 383     return keys %{$self->_resolved_attrs->{collapse}}
 384       ? $self->search($query)->next
 385       : $self->single($query);
 386   }
 387 }
 388
 389 # _add_alias
 390 #
 391 # Add the specified alias to the specified query hash. A copy is made so the
 392 # original query is not modified.
 393
 394 sub _add_alias {
 395   my ($self, $query, $alias) = @_;
 396
 397   my %aliased = %$query;
 398   foreach my $col (grep { ! m/\./ } keys %aliased) {
 399     $aliased{"$alias.$col"} = delete $aliased{$col};
 400   }
 401
 402   return \%aliased;
 403 }
 404
 405 # _unique_queries
 406 #
 407 # Build a list of queries which satisfy unique constraints.
 408
 409 sub _unique_queries {
 410   my ($self, $query, $attrs) = @_;
 411
 412   my @constraint_names = exists $attrs->{key}
 413     ? ($attrs->{key})
 414     : $self->result_source->unique_constraint_names;
 415
 416   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 417   my $num_where = scalar keys %$where;
 418
 419   my @unique_queries;
 420   foreach my $name (@constraint_names) {
 421     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 422     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 423
 424     my $num_cols = scalar @unique_cols;
 425     my $num_query = scalar keys %$unique_query;
 426
 427     my $total = $num_query + $num_where;
 428     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 429       # The query is either unique on its own or is unique in combination with
 430       # the existing where clause
 431       push @unique_queries, $unique_query;
 432     }
 433   }
 434
 435   return @unique_queries;
 436 }
 437
 438 # _build_unique_query
 439 #
 440 # Constrain the specified query hash based on the specified column names.
 441
 442 sub _build_unique_query {
 443   my ($self, $query, $unique_cols) = @_;
 444
 445   return {
 446     map  { $_ => $query->{$_} }
 447     grep { exists $query->{$_} }
 448       @$unique_cols
 449   };
 450 }
 451
 452 =head2 search_related
 453
 454 =over 4
 455
 456 =item Arguments: $rel, $cond, \%attrs?
 457
 458 =item Return Value: $new_resultset
 459
 460 =back
 461
 462   $new_rs = $cd_rs->search_related('artist', {
 463     name => 'Emo-R-Us',
 464   });
 465
 466 Searches the specified relationship, optionally specifying a condition and
 467 attributes for matching records. See L</ATTRIBUTES> for more information.
 468
 469 =cut
 470
 471 sub search_related {
 472   return shift->related_resultset(shift)->search(@_);
 473 }
 474
 475 =head2 cursor
 476
 477 =over 4
 478
 479 =item Arguments: none
 480
 481 =item Return Value: $cursor
 482
 483 =back
 484
 485 Returns a storage-driven cursor to the given resultset. See
 486 L<DBIx::Class::Cursor> for more information.
 487
 488 =cut
 489
 490 sub cursor {
 491   my ($self) = @_;
 492
 493   my $attrs = { %{$self->_resolved_attrs} };
 494   return $self->{cursor}
 495     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 496           $attrs->{where},$attrs);
 497 }
 498
 499 =head2 single
 500
 501 =over 4
 502
 503 =item Arguments: $cond?
 504
 505 =item Return Value: $row_object?
 506
 507 =back
 508
 509   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 510
 511 Inflates the first result without creating a cursor if the resultset has
 512 any records in it; if not returns nothing. Used by L</find> as an optimisation.
 513
 514 Can optionally take an additional condition *only* - this is a fast-code-path
 515 method; if you need to add extra joins or similar call ->search and then
 516 ->single without a condition on the $rs returned from that.
 517
 518 =cut
 519
 520 sub single {
 521   my ($self, $where) = @_;
 522   my $attrs = { %{$self->_resolved_attrs} };
 523   if ($where) {
 524     if (defined $attrs->{where}) {
 525       $attrs->{where} = {
 526         '-and' =>
 527             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 528                $where, delete $attrs->{where} ]
 529       };
 530     } else {
 531       $attrs->{where} = $where;
 532     }
 533   }
 534
 535 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 536 #  unless ($self->_is_unique_query($attrs->{where})) {
 537 #    carp "Query not guaranteed to return a single row"
 538 #      . "; please declare your unique constraints or use search instead";
 539 #  }
 540
 541   my @data = $self->result_source->storage->select_single(
 542     $attrs->{from}, $attrs->{select},
 543     $attrs->{where}, $attrs
 544   );
 545
 546   return (@data ? ($self->_construct_object(@data))[0] : undef);
 547 }
 548
 549 # _is_unique_query
 550 #
 551 # Try to determine if the specified query is guaranteed to be unique, based on
 552 # the declared unique constraints.
 553
 554 sub _is_unique_query {
 555   my ($self, $query) = @_;
 556
 557   my $collapsed = $self->_collapse_query($query);
 558   my $alias = $self->{attrs}{alias};
 559
 560   foreach my $name ($self->result_source->unique_constraint_names) {
 561     my @unique_cols = map {
 562       "$alias.$_"
 563     } $self->result_source->unique_constraint_columns($name);
 564
 565     # Count the values for each unique column
 566     my %seen = map { $_ => 0 } @unique_cols;
 567
 568     foreach my $key (keys %$collapsed) {
 569       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 570       next unless exists $seen{$aliased};  # Additional constraints are okay
 571       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 572     }
 573
 574     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 575     return 1 unless grep { $_ != 1 } values %seen;
 576   }
 577
 578   return 0;
 579 }
 580
 581 # _collapse_query
 582 #
 583 # Recursively collapse the query, accumulating values for each column.
 584
 585 sub _collapse_query {
 586   my ($self, $query, $collapsed) = @_;
 587
 588   $collapsed ||= {};
 589
 590   if (ref $query eq 'ARRAY') {
 591     foreach my $subquery (@$query) {
 592       next unless ref $subquery;  # -or
 593 #      warn "ARRAY: " . Dumper $subquery;
 594       $collapsed = $self->_collapse_query($subquery, $collapsed);
 595     }
 596   }
 597   elsif (ref $query eq 'HASH') {
 598     if (keys %$query and (keys %$query)[0] eq '-and') {
 599       foreach my $subquery (@{$query->{-and}}) {
 600 #        warn "HASH: " . Dumper $subquery;
 601         $collapsed = $self->_collapse_query($subquery, $collapsed);
 602       }
 603     }
 604     else {
 605 #      warn "LEAF: " . Dumper $query;
 606       foreach my $col (keys %$query) {
 607         my $value = $query->{$col};
 608         $collapsed->{$col}{$value}++;
 609       }
 610     }
 611   }
 612
 613   return $collapsed;
 614 }
 615
 616 =head2 get_column
 617
 618 =over 4
 619
 620 =item Arguments: $cond?
 621
 622 =item Return Value: $resultsetcolumn
 623
 624 =back
 625
 626   my $max_length = $rs->get_column('length')->max;
 627
 628 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 629
 630 =cut
 631
 632 sub get_column {
 633   my ($self, $column) = @_;
 634   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 635   return $new;
 636 }
 637
 638 =head2 search_like
 639
 640 =over 4
 641
 642 =item Arguments: $cond, \%attrs?
 643
 644 =item Return Value: $resultset (scalar context), @row_objs (list context)
 645
 646 =back
 647
 648   # WHERE title LIKE '%blue%'
 649   $cd_rs = $rs->search_like({ title => '%blue%'});
 650
 651 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 652 that this is simply a convenience method. You most likely want to use
 653 L</search> with specific operators.
 654
 655 For more information, see L<DBIx::Class::Manual::Cookbook>.
 656
 657 =cut
 658
 659 sub search_like {
 660   my $class = shift;
 661   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 662   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 663   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 664   return $class->search($query, { %$attrs });
 665 }
 666
 667 =head2 slice
 668
 669 =over 4
 670
 671 =item Arguments: $first, $last
 672
 673 =item Return Value: $resultset (scalar context), @row_objs (list context)
 674
 675 =back
 676
 677 Returns a resultset or object list representing a subset of elements from the
 678 resultset slice is called on. Indexes are from 0, i.e., to get the first
 679 three records, call:
 680
 681   my ($one, $two, $three) = $rs->slice(0, 2);
 682
 683 =cut
 684
 685 sub slice {
 686   my ($self, $min, $max) = @_;
 687   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 688   $attrs->{offset} = $self->{attrs}{offset} || 0;
 689   $attrs->{offset} += $min;
 690   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 691   return $self->search(undef(), $attrs);
 692   #my $slice = (ref $self)->new($self->result_source, $attrs);
 693   #return (wantarray ? $slice->all : $slice);
 694 }
 695
 696 =head2 next
 697
 698 =over 4
 699
 700 =item Arguments: none
 701
 702 =item Return Value: $result?
 703
 704 =back
 705
 706 Returns the next element in the resultset (C<undef> is there is none).
 707
 708 Can be used to efficiently iterate over records in the resultset:
 709
 710   my $rs = $schema->resultset('CD')->search;
 711   while (my $cd = $rs->next) {
 712     print $cd->title;
 713   }
 714
 715 Note that you need to store the resultset object, and call C<next> on it.
 716 Calling C<< resultset('Table')->next >> repeatedly will always return the
 717 first record from the resultset.
 718
 719 =cut
 720
 721 sub next {
 722   my ($self) = @_;
 723   if (my $cache = $self->get_cache) {
 724     $self->{all_cache_position} ||= 0;
 725     return $cache->[$self->{all_cache_position}++];
 726   }
 727   if ($self->{attrs}{cache}) {
 728     $self->{all_cache_position} = 1;
 729     return ($self->all)[0];
 730   }
 731   if ($self->{stashed_objects}) {
 732     my $obj = shift(@{$self->{stashed_objects}});
 733     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 734     return $obj;
 735   }
 736   my @row = (
 737     exists $self->{stashed_row}
 738       ? @{delete $self->{stashed_row}}
 739       : $self->cursor->next
 740   );
 741   return undef unless (@row);
 742   my ($row, @more) = $self->_construct_object(@row);
 743   $self->{stashed_objects} = \@more if @more;
 744   return $row;
 745 }
 746
 747 sub _construct_object {
 748   my ($self, @row) = @_;
 749   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 750   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 751   @new = $self->{_attrs}{record_filter}->(@new)
 752     if exists $self->{_attrs}{record_filter};
 753   return @new;
 754 }
 755
 756 sub _collapse_result {
 757   my ($self, $as_proto, $row) = @_;
 758
 759   my @copy = @$row;
 760
 761   # 'foo'         => [ undef, 'foo' ]
 762   # 'foo.bar'     => [ 'foo', 'bar' ]
 763   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 764
 765   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 766
 767   my %collapse = %{$self->{_attrs}{collapse}||{}};
 768
 769   my @pri_index;
 770
 771   # if we're doing collapsing (has_many prefetch) we need to grab records
 772   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 773   # we know we don't have to bother.
 774
 775   # the reason for not using the collapse stuff directly is because if you
 776   # had for e.g. two artists in a row with no cds, the collapse info for
 777   # both would be NULL (undef) so you'd lose the second artist
 778
 779   # store just the index so we can check the array positions from the row
 780   # without having to contruct the full hash
 781
 782   if (keys %collapse) {
 783     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 784     foreach my $i (0 .. $#construct_as) {
 785       next if defined($construct_as[$i][0]); # only self table
 786       if (delete $pri{$construct_as[$i][1]}) {
 787         push(@pri_index, $i);
 788       }
 789       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 790     }
 791   }
 792
 793   # no need to do an if, it'll be empty if @pri_index is empty anyway
 794
 795   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 796
 797   my @const_rows;
 798
 799   do { # no need to check anything at the front, we always want the first row
 800
 801     my %const;
 802
 803     foreach my $this_as (@construct_as) {
 804       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 805     }
 806
 807     push(@const_rows, \%const);
 808
 809   } until ( # no pri_index => no collapse => drop straight out
 810       !@pri_index
 811     or
 812       do { # get another row, stash it, drop out if different PK
 813
 814         @copy = $self->cursor->next;
 815         $self->{stashed_row} = \@copy;
 816
 817         # last thing in do block, counts as true if anything doesn't match
 818
 819         # check xor defined first for NULL vs. NOT NULL then if one is
 820         # defined the other must be so check string equality
 821
 822         grep {
 823           (defined $pri_vals{$_} ^ defined $copy[$_])
 824           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 825         } @pri_index;
 826       }
 827   );
 828
 829   my $alias = $self->{attrs}{alias};
 830   my $info = [];
 831
 832   my %collapse_pos;
 833
 834   my @const_keys;
 835
 836   foreach my $const (@const_rows) {
 837     scalar @const_keys or do {
 838       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 839     };
 840     foreach my $key (@const_keys) {
 841       if (length $key) {
 842         my $target = $info;
 843         my @parts = split(/\./, $key);
 844         my $cur = '';
 845         my $data = $const->{$key};
 846         foreach my $p (@parts) {
 847           $target = $target->[1]->{$p} ||= [];
 848           $cur .= ".${p}";
 849           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 850             # collapsing at this point and on final part
 851             my $pos = $collapse_pos{$cur};
 852             CK: foreach my $ck (@ckey) {
 853               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 854                 $collapse_pos{$cur} = $data;
 855                 delete @collapse_pos{ # clear all positioning for sub-entries
 856                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 857                 };
 858                 push(@$target, []);
 859                 last CK;
 860               }
 861             }
 862           }
 863           if (exists $collapse{$cur}) {
 864             $target = $target->[-1];
 865           }
 866         }
 867         $target->[0] = $data;
 868       } else {
 869         $info->[0] = $const->{$key};
 870       }
 871     }
 872   }
 873
 874   return $info;
 875 }
 876
 877 =head2 result_source
 878
 879 =over 4
 880
 881 =item Arguments: $result_source?
 882
 883 =item Return Value: $result_source
 884
 885 =back
 886
 887 An accessor for the primary ResultSource object from which this ResultSet
 888 is derived.
 889
 890 =head2 result_class
 891
 892 =over 4
 893
 894 =item Arguments: $result_class?
 895
 896 =item Return Value: $result_class
 897
 898 =back
 899
 900 An accessor for the class to use when creating row objects. Defaults to
 901 C<< result_source->result_class >> - which in most cases is the name of the
 902 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 903
 904 =cut
 905
 906
 907 =head2 count
 908
 909 =over 4
 910
 911 =item Arguments: $cond, \%attrs??
 912
 913 =item Return Value: $count
 914
 915 =back
 916
 917 Performs an SQL C<COUNT> with the same query as the resultset was built
 918 with to find the number of elements. If passed arguments, does a search
 919 on the resultset and counts the results of that.
 920
 921 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 922 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 923 not support C<DISTINCT> with multiple columns. If you are using such a
 924 database, you should only use columns from the main table in your C<group_by>
 925 clause.
 926
 927 =cut
 928
 929 sub count {
 930   my $self = shift;
 931   return $self->search(@_)->count if @_ and defined $_[0];
 932   return scalar @{ $self->get_cache } if $self->get_cache;
 933   my $count = $self->_count;
 934   return 0 unless $count;
 935
 936   # need to take offset from resolved attrs
 937
 938   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
 939   $count = $self->{attrs}{rows} if
 940     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 941   $count = 0 if ($count < 0);
 942   return $count;
 943 }
 944
 945 sub _count { # Separated out so pager can get the full count
 946   my $self = shift;
 947   my $select = { count => '*' };
 948
 949   my $attrs = { %{$self->_resolved_attrs} };
 950   if (my $group_by = delete $attrs->{group_by}) {
 951     delete $attrs->{having};
 952     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 953     # todo: try CONCAT for multi-column pk
 954     my @pk = $self->result_source->primary_columns;
 955     if (@pk == 1) {
 956       my $alias = $attrs->{alias};
 957       foreach my $column (@distinct) {
 958         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
 959           @distinct = ($column);
 960           last;
 961         }
 962       }
 963     }
 964
 965     $select = { count => { distinct => \@distinct } };
 966   }
 967
 968   $attrs->{select} = $select;
 969   $attrs->{as} = [qw/count/];
 970
 971   # offset, order by and page are not needed to count. record_filter is cdbi
 972   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 973
 974   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
 975   my ($count) = $tmp_rs->cursor->next;
 976   return $count;
 977 }
 978
 979 =head2 count_literal
 980
 981 =over 4
 982
 983 =item Arguments: $sql_fragment, @bind_values
 984
 985 =item Return Value: $count
 986
 987 =back
 988
 989 Counts the results in a literal query. Equivalent to calling L</search_literal>
 990 with the passed arguments, then L</count>.
 991
 992 =cut
 993
 994 sub count_literal { shift->search_literal(@_)->count; }
 995
 996 =head2 all
 997
 998 =over 4
 999
1000 =item Arguments: none
1001
1002 =item Return Value: @objects
1003
1004 =back
1005
1006 Returns all elements in the resultset. Called implicitly if the resultset
1007 is returned in list context.
1008
1009 =cut
1010
1011 sub all {
1012   my ($self) = @_;
1013   return @{ $self->get_cache } if $self->get_cache;
1014
1015   my @obj;
1016
1017   # TODO: don't call resolve here
1018   if (keys %{$self->_resolved_attrs->{collapse}}) {
1019 #  if ($self->{attrs}{prefetch}) {
1020       # Using $self->cursor->all is really just an optimisation.
1021       # If we're collapsing has_many prefetches it probably makes
1022       # very little difference, and this is cleaner than hacking
1023       # _construct_object to survive the approach
1024     my @row = $self->cursor->next;
1025     while (@row) {
1026       push(@obj, $self->_construct_object(@row));
1027       @row = (exists $self->{stashed_row}
1028                ? @{delete $self->{stashed_row}}
1029                : $self->cursor->next);
1030     }
1031   } else {
1032     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1033   }
1034
1035   $self->set_cache(\@obj) if $self->{attrs}{cache};
1036   return @obj;
1037 }
1038
1039 =head2 reset
1040
1041 =over 4
1042
1043 =item Arguments: none
1044
1045 =item Return Value: $self
1046
1047 =back
1048
1049 Resets the resultset's cursor, so you can iterate through the elements again.
1050
1051 =cut
1052
1053 sub reset {
1054   my ($self) = @_;
1055   delete $self->{_attrs} if exists $self->{_attrs};
1056   $self->{all_cache_position} = 0;
1057   $self->cursor->reset;
1058   return $self;
1059 }
1060
1061 =head2 first
1062
1063 =over 4
1064
1065 =item Arguments: none
1066
1067 =item Return Value: $object?
1068
1069 =back
1070
1071 Resets the resultset and returns an object for the first result (if the
1072 resultset returns anything).
1073
1074 =cut
1075
1076 sub first {
1077   return $_[0]->reset->next;
1078 }
1079
1080 # _cond_for_update_delete
1081 #
1082 # update/delete require the condition to be modified to handle
1083 # the differing SQL syntax available.  This transforms the $self->{cond}
1084 # appropriately, returning the new condition.
1085
1086 sub _cond_for_update_delete {
1087   my ($self, $full_cond) = @_;
1088   my $cond = {};
1089
1090   $full_cond ||= $self->{cond};
1091   # No-op. No condition, we're updating/deleting everything
1092   return $cond unless ref $full_cond;
1093
1094   if (ref $full_cond eq 'ARRAY') {
1095     $cond = [
1096       map {
1097         my %hash;
1098         foreach my $key (keys %{$_}) {
1099           $key =~ /([^.]+)$/;
1100           $hash{$1} = $_->{$key};
1101         }
1102         \%hash;
1103       } @{$full_cond}
1104     ];
1105   }
1106   elsif (ref $full_cond eq 'HASH') {
1107     if ((keys %{$full_cond})[0] eq '-and') {
1108       $cond->{-and} = [];
1109
1110       my @cond = @{$full_cond->{-and}};
1111       for (my $i = 0; $i < @cond; $i++) {
1112         my $entry = $cond[$i];
1113
1114         my $hash;
1115         if (ref $entry eq 'HASH') {
1116           $hash = $self->_cond_for_update_delete($entry);
1117         }
1118         else {
1119           $entry =~ /([^.]+)$/;
1120           $hash->{$1} = $cond[++$i];
1121         }
1122
1123         push @{$cond->{-and}}, $hash;
1124       }
1125     }
1126     else {
1127       foreach my $key (keys %{$full_cond}) {
1128         $key =~ /([^.]+)$/;
1129         $cond->{$1} = $full_cond->{$key};
1130       }
1131     }
1132   }
1133   else {
1134     $self->throw_exception(
1135       "Can't update/delete on resultset with condition unless hash or array"
1136     );
1137   }
1138
1139   return $cond;
1140 }
1141
1142
1143 =head2 update
1144
1145 =over 4
1146
1147 =item Arguments: \%values
1148
1149 =item Return Value: $storage_rv
1150
1151 =back
1152
1153 Sets the specified columns in the resultset to the supplied values in a
1154 single query. Return value will be true if the update succeeded or false
1155 if no records were updated; exact type of success value is storage-dependent.
1156
1157 =cut
1158
1159 sub update {
1160   my ($self, $values) = @_;
1161   $self->throw_exception("Values for update must be a hash")
1162     unless ref $values eq 'HASH';
1163
1164   my $cond = $self->_cond_for_update_delete;
1165
1166   return $self->result_source->storage->update(
1167     $self->result_source, $values, $cond
1168   );
1169 }
1170
1171 =head2 update_all
1172
1173 =over 4
1174
1175 =item Arguments: \%values
1176
1177 =item Return Value: 1
1178
1179 =back
1180
1181 Fetches all objects and updates them one at a time. Note that C<update_all>
1182 will run DBIC cascade triggers, while L</update> will not.
1183
1184 =cut
1185
1186 sub update_all {
1187   my ($self, $values) = @_;
1188   $self->throw_exception("Values for update must be a hash")
1189     unless ref $values eq 'HASH';
1190   foreach my $obj ($self->all) {
1191     $obj->set_columns($values)->update;
1192   }
1193   return 1;
1194 }
1195
1196 =head2 delete
1197
1198 =over 4
1199
1200 =item Arguments: none
1201
1202 =item Return Value: 1
1203
1204 =back
1205
1206 Deletes the contents of the resultset from its result source. Note that this
1207 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1208 to run. See also L<DBIx::Class::Row/delete>.
1209
1210 =cut
1211
1212 sub delete {
1213   my ($self) = @_;
1214
1215   my $cond = $self->_cond_for_update_delete;
1216
1217   $self->result_source->storage->delete($self->result_source, $cond);
1218   return 1;
1219 }
1220
1221 =head2 delete_all
1222
1223 =over 4
1224
1225 =item Arguments: none
1226
1227 =item Return Value: 1
1228
1229 =back
1230
1231 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1232 will run DBIC cascade triggers, while L</delete> will not.
1233
1234 =cut
1235
1236 sub delete_all {
1237   my ($self) = @_;
1238   $_->delete for $self->all;
1239   return 1;
1240 }
1241
1242 =head2 populate
1243
1244 =over 4
1245
1246 =item Arguments: \@data;
1247
1248 =back
1249
1250 Pass an arrayref of hashrefs. Each hashref should be a structure suitable for
1251 submitting to a $resultset->create(...) method.
1252
1253 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1254 to insert the data, as this is a faster method.
1255
1256 Otherwise, each set of data is inserted into the database using
1257 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1258 objects is returned.
1259
1260 Example:  Assuming an Artist Class that has many CDs Classes relating:
1261
1262   my $Artist_rs = $schema->resultset("Artist");
1263
1264   ## Void Context Example
1265   $Artist_rs->populate([
1266      { artistid => 4, name => 'Manufactured Crap', cds => [
1267         { title => 'My First CD', year => 2006 },
1268         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1269       ],
1270      },
1271      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1272         { title => 'My parents sold me to a record company' ,year => 2005 },
1273         { title => 'Why Am I So Ugly?', year => 2006 },
1274         { title => 'I Got Surgery and am now Popular', year => 2007 }
1275       ],
1276      },
1277   ]);
1278
1279   ## Array Context Example
1280   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1281     { name => "Artist One"},
1282     { name => "Artist Two"},
1283     { name => "Artist Three", cds=> [
1284     { title => "First CD", year => 2007},
1285     { title => "Second CD", year => 2008},
1286   ]}
1287   ]);
1288
1289   print $ArtistOne->name; ## response is 'Artist One'
1290   print $ArtistThree->cds->count ## reponse is '2'
1291
1292 Please note an important effect on your data when choosing between void and
1293 wantarray context. Since void context goes straight to C<insert_bulk> in
1294 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1295 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1296 create primary keys for you, you will find that your PKs are empty.  In this
1297 case you will have to use the wantarray context in order to create those
1298 values.
1299
1300 =cut
1301
1302 sub populate {
1303   my ($self, $data) = @_;
1304
1305   if(defined wantarray) {
1306     my @created;
1307     foreach my $item (@$data) {
1308       push(@created, $self->create($item));
1309     }
1310     return @created;
1311   } else {
1312     my ($first, @rest) = @$data;
1313
1314     my @names = grep {!ref $first->{$_}} keys %$first;
1315     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1316     my @pks = $self->result_source->primary_columns;
1317
1318     ## do the belongs_to relationships
1319     foreach my $index (0..$#$data) {
1320       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1321         my @ret = $self->populate($data);
1322         return;
1323       }
1324
1325       foreach my $rel (@rels) {
1326         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1327         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1328         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1329         my $related = $result->result_source->resolve_condition(
1330           $result->result_source->relationship_info($reverse)->{cond},
1331           $self,
1332           $result,
1333         );
1334
1335         delete $data->[$index]->{$rel};
1336         $data->[$index] = {%{$data->[$index]}, %$related};
1337
1338         push @names, keys %$related if $index == 0;
1339       }
1340     }
1341
1342     ## do bulk insert on current row
1343     my @values = map { [ @$_{@names} ] } @$data;
1344
1345     $self->result_source->storage->insert_bulk(
1346       $self->result_source,
1347       \@names,
1348       \@values,
1349     );
1350
1351     ## do the has_many relationships
1352     foreach my $item (@$data) {
1353
1354       foreach my $rel (@rels) {
1355         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1356
1357         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1358      || $self->throw_exception('Cannot find the relating object.');
1359
1360         my $child = $parent->$rel;
1361
1362         my $related = $child->result_source->resolve_condition(
1363           $parent->result_source->relationship_info($rel)->{cond},
1364           $child,
1365           $parent,
1366         );
1367
1368         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1369         my @populate = map { {%$_, %$related} } @rows_to_add;
1370
1371         $child->populate( \@populate );
1372       }
1373     }
1374   }
1375 }
1376
1377 =head2 pager
1378
1379 =over 4
1380
1381 =item Arguments: none
1382
1383 =item Return Value: $pager
1384
1385 =back
1386
1387 Return Value a L<Data::Page> object for the current resultset. Only makes
1388 sense for queries with a C<page> attribute.
1389
1390 =cut
1391
1392 sub pager {
1393   my ($self) = @_;
1394   my $attrs = $self->{attrs};
1395   $self->throw_exception("Can't create pager for non-paged rs")
1396     unless $self->{attrs}{page};
1397   $attrs->{rows} ||= 10;
1398   return $self->{pager} ||= Data::Page->new(
1399     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1400 }
1401
1402 =head2 page
1403
1404 =over 4
1405
1406 =item Arguments: $page_number
1407
1408 =item Return Value: $rs
1409
1410 =back
1411
1412 Returns a resultset for the $page_number page of the resultset on which page
1413 is called, where each page contains a number of rows equal to the 'rows'
1414 attribute set on the resultset (10 by default).
1415
1416 =cut
1417
1418 sub page {
1419   my ($self, $page) = @_;
1420   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1421 }
1422
1423 =head2 new_result
1424
1425 =over 4
1426
1427 =item Arguments: \%vals
1428
1429 =item Return Value: $object
1430
1431 =back
1432
1433 Creates a new row object in the resultset's result class and returns
1434 it. The row is not inserted into the database at this point, call
1435 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1436 will tell you whether the row object has been inserted or not.
1437
1438 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1439
1440 =cut
1441
1442 sub new_result {
1443   my ($self, $values) = @_;
1444   $self->throw_exception( "new_result needs a hash" )
1445     unless (ref $values eq 'HASH');
1446   $self->throw_exception(
1447     "Can't abstract implicit construct, condition not a hash"
1448   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1449
1450   my $alias = $self->{attrs}{alias};
1451   my $collapsed_cond = $self->{cond} ? $self->_collapse_cond($self->{cond}) : {};
1452
1453   # precendence must be given to passed values over values inherited from the cond,
1454   # so the order here is important.
1455   my %new = (
1456     %{ $self->_remove_alias($collapsed_cond, $alias) },
1457     %{ $self->_remove_alias($values, $alias) },
1458     -source_handle => $self->_source_handle,
1459     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1460   );
1461
1462   return $self->result_class->new(\%new);
1463 }
1464
1465 # _collapse_cond
1466 #
1467 # Recursively collapse the condition.
1468
1469 sub _collapse_cond {
1470   my ($self, $cond, $collapsed) = @_;
1471
1472   $collapsed ||= {};
1473
1474   if (ref $cond eq 'ARRAY') {
1475     foreach my $subcond (@$cond) {
1476       next unless ref $subcond;  # -or
1477 #      warn "ARRAY: " . Dumper $subcond;
1478       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1479     }
1480   }
1481   elsif (ref $cond eq 'HASH') {
1482     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1483       foreach my $subcond (@{$cond->{-and}}) {
1484 #        warn "HASH: " . Dumper $subcond;
1485         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1486       }
1487     }
1488     else {
1489 #      warn "LEAF: " . Dumper $cond;
1490       foreach my $col (keys %$cond) {
1491         my $value = $cond->{$col};
1492         $collapsed->{$col} = $value;
1493       }
1494     }
1495   }
1496
1497   return $collapsed;
1498 }
1499
1500 # _remove_alias
1501 #
1502 # Remove the specified alias from the specified query hash. A copy is made so
1503 # the original query is not modified.
1504
1505 sub _remove_alias {
1506   my ($self, $query, $alias) = @_;
1507
1508   my %orig = %{ $query || {} };
1509   my %unaliased;
1510
1511   foreach my $key (keys %orig) {
1512     if ($key !~ /\./) {
1513       $unaliased{$key} = $orig{$key};
1514       next;
1515     }
1516     $unaliased{$1} = $orig{$key}
1517       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1518   }
1519
1520   return \%unaliased;
1521 }
1522
1523 =head2 find_or_new
1524
1525 =over 4
1526
1527 =item Arguments: \%vals, \%attrs?
1528
1529 =item Return Value: $object
1530
1531 =back
1532
1533 Find an existing record from this resultset. If none exists, instantiate a new
1534 result object and return it. The object will not be saved into your storage
1535 until you call L<DBIx::Class::Row/insert> on it.
1536
1537 If you want objects to be saved immediately, use L</find_or_create> instead.
1538
1539 =cut
1540
1541 sub find_or_new {
1542   my $self     = shift;
1543   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1544   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1545   my $exists   = $self->find($hash, $attrs);
1546   return defined $exists ? $exists : $self->new_result($hash);
1547 }
1548
1549 =head2 create
1550
1551 =over 4
1552
1553 =item Arguments: \%vals
1554
1555 =item Return Value: $object
1556
1557 =back
1558
1559 Attempt to create a single new row or a row with multiple related rows
1560 in the table represented by the resultset (and related tables). This
1561 will not check for duplicate rows before inserting, use
1562 L</find_or_create> to do that.
1563
1564 To create one row for this resultset, pass a hashref of key/value
1565 pairs representing the columns of the table and the values you wish to
1566 store. If the appropriate relationships are set up, foreign key fields
1567 can also be passed an object representing the foreign row, and the
1568 value will be set to it's primary key.
1569
1570 To create related objects, pass a hashref for the value if the related
1571 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1572 and use the name of the relationship as the key. (NOT the name of the field,
1573 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1574 of hashrefs containing the data for each of the rows to create in the foreign
1575 tables, again using the relationship name as the key.
1576
1577 Instead of hashrefs of plain related data (key/value pairs), you may
1578 also pass new or inserted objects. New objects (not inserted yet, see
1579 L</new>), will be inserted into their appropriate tables.
1580
1581 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1582
1583 Example of creating a new row.
1584
1585   $person_rs->create({
1586     name=>"Some Person",
1587         email=>"somebody@someplace.com"
1588   });
1589
1590 Example of creating a new row and also creating rows in a related C<has_many>
1591 or C<has_one> resultset.  Note Arrayref.
1592
1593   $artist_rs->create(
1594      { artistid => 4, name => 'Manufactured Crap', cds => [
1595         { title => 'My First CD', year => 2006 },
1596         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1597       ],
1598      },
1599   );
1600
1601 Example of creating a new row and also creating a row in a related
1602 C<belongs_to>resultset. Note Hashref.
1603
1604   $cd_rs->create({
1605     title=>"Music for Silly Walks",
1606         year=>2000,
1607         artist => {
1608           name=>"Silly Musician",
1609         }
1610   });
1611
1612 =cut
1613
1614 sub create {
1615   my ($self, $attrs) = @_;
1616   $self->throw_exception( "create needs a hashref" )
1617     unless ref $attrs eq 'HASH';
1618   return $self->new_result($attrs)->insert;
1619 }
1620
1621 =head2 find_or_create
1622
1623 =over 4
1624
1625 =item Arguments: \%vals, \%attrs?
1626
1627 =item Return Value: $object
1628
1629 =back
1630
1631   $class->find_or_create({ key => $val, ... });
1632
1633 Tries to find a record based on its primary key or unique constraint; if none
1634 is found, creates one and returns that instead.
1635
1636   my $cd = $schema->resultset('CD')->find_or_create({
1637     cdid   => 5,
1638     artist => 'Massive Attack',
1639     title  => 'Mezzanine',
1640     year   => 2005,
1641   });
1642
1643 Also takes an optional C<key> attribute, to search by a specific key or unique
1644 constraint. For example:
1645
1646   my $cd = $schema->resultset('CD')->find_or_create(
1647     {
1648       artist => 'Massive Attack',
1649       title  => 'Mezzanine',
1650     },
1651     { key => 'cd_artist_title' }
1652   );
1653
1654 See also L</find> and L</update_or_create>. For information on how to declare
1655 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1656
1657 =cut
1658
1659 sub find_or_create {
1660   my $self     = shift;
1661   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1662   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1663   my $exists   = $self->find($hash, $attrs);
1664   return defined $exists ? $exists : $self->create($hash);
1665 }
1666
1667 =head2 update_or_create
1668
1669 =over 4
1670
1671 =item Arguments: \%col_values, { key => $unique_constraint }?
1672
1673 =item Return Value: $object
1674
1675 =back
1676
1677   $class->update_or_create({ col => $val, ... });
1678
1679 First, searches for an existing row matching one of the unique constraints
1680 (including the primary key) on the source of this resultset. If a row is
1681 found, updates it with the other given column values. Otherwise, creates a new
1682 row.
1683
1684 Takes an optional C<key> attribute to search on a specific unique constraint.
1685 For example:
1686
1687   # In your application
1688   my $cd = $schema->resultset('CD')->update_or_create(
1689     {
1690       artist => 'Massive Attack',
1691       title  => 'Mezzanine',
1692       year   => 1998,
1693     },
1694     { key => 'cd_artist_title' }
1695   );
1696
1697 If no C<key> is specified, it searches on all unique constraints defined on the
1698 source, including the primary key.
1699
1700 If the C<key> is specified as C<primary>, it searches only on the primary key.
1701
1702 See also L</find> and L</find_or_create>. For information on how to declare
1703 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1704
1705 =cut
1706
1707 sub update_or_create {
1708   my $self = shift;
1709   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1710   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1711
1712   my $row = $self->find($cond, $attrs);
1713   if (defined $row) {
1714     $row->update($cond);
1715     return $row;
1716   }
1717
1718   return $self->create($cond);
1719 }
1720
1721 =head2 get_cache
1722
1723 =over 4
1724
1725 =item Arguments: none
1726
1727 =item Return Value: \@cache_objects?
1728
1729 =back
1730
1731 Gets the contents of the cache for the resultset, if the cache is set.
1732
1733 =cut
1734
1735 sub get_cache {
1736   shift->{all_cache};
1737 }
1738
1739 =head2 set_cache
1740
1741 =over 4
1742
1743 =item Arguments: \@cache_objects
1744
1745 =item Return Value: \@cache_objects
1746
1747 =back
1748
1749 Sets the contents of the cache for the resultset. Expects an arrayref
1750 of objects of the same class as those produced by the resultset. Note that
1751 if the cache is set the resultset will return the cached objects rather
1752 than re-querying the database even if the cache attr is not set.
1753
1754 =cut
1755
1756 sub set_cache {
1757   my ( $self, $data ) = @_;
1758   $self->throw_exception("set_cache requires an arrayref")
1759       if defined($data) && (ref $data ne 'ARRAY');
1760   $self->{all_cache} = $data;
1761 }
1762
1763 =head2 clear_cache
1764
1765 =over 4
1766
1767 =item Arguments: none
1768
1769 =item Return Value: []
1770
1771 =back
1772
1773 Clears the cache for the resultset.
1774
1775 =cut
1776
1777 sub clear_cache {
1778   shift->set_cache(undef);
1779 }
1780
1781 =head2 related_resultset
1782
1783 =over 4
1784
1785 =item Arguments: $relationship_name
1786
1787 =item Return Value: $resultset
1788
1789 =back
1790
1791 Returns a related resultset for the supplied relationship name.
1792
1793   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1794
1795 =cut
1796
1797 sub related_resultset {
1798   my ($self, $rel) = @_;
1799
1800   $self->{related_resultsets} ||= {};
1801   return $self->{related_resultsets}{$rel} ||= do {
1802     my $rel_obj = $self->result_source->relationship_info($rel);
1803
1804     $self->throw_exception(
1805       "search_related: result source '" . $self->result_source->source_name .
1806         "' has no such relationship $rel")
1807       unless $rel_obj;
1808
1809     my ($from,$seen) = $self->_resolve_from($rel);
1810
1811     my $join_count = $seen->{$rel};
1812     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
1813
1814     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
1815     my %attrs = %{$self->{attrs}||{}};
1816     delete @attrs{qw(result_class alias)};
1817
1818     my $new_cache;
1819
1820     if (my $cache = $self->get_cache) {
1821       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
1822         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
1823                         @$cache ];
1824       }
1825     }
1826
1827     my $rel_source = $self->result_source->related_source($rel);
1828
1829     my $new = do {
1830
1831       # The reason we do this now instead of passing the alias to the
1832       # search_rs below is that if you wrap/overload resultset on the
1833       # source you need to know what alias it's -going- to have for things
1834       # to work sanely (e.g. RestrictWithObject wants to be able to add
1835       # extra query restrictions, and these may need to be $alias.)
1836
1837       my $attrs = $rel_source->resultset_attributes;
1838       local $attrs->{alias} = $alias;
1839
1840       $rel_source->resultset
1841                  ->search_rs(
1842                      undef, {
1843                        %attrs,
1844                        join => undef,
1845                        prefetch => undef,
1846                        select => undef,
1847                        as => undef,
1848                        where => $self->{cond},
1849                        seen_join => $seen,
1850                        from => $from,
1851                    });
1852     };
1853     $new->set_cache($new_cache) if $new_cache;
1854     $new;
1855   };
1856 }
1857
1858 sub _resolve_from {
1859   my ($self, $extra_join) = @_;
1860   my $source = $self->result_source;
1861   my $attrs = $self->{attrs};
1862
1863   my $from = $attrs->{from}
1864     || [ { $attrs->{alias} => $source->from } ];
1865
1866   my $seen = { %{$attrs->{seen_join}||{}} };
1867
1868   my $join = ($attrs->{join}
1869                ? [ $attrs->{join}, $extra_join ]
1870                : $extra_join);
1871
1872   # we need to take the prefetch the attrs into account before we
1873   # ->resolve_join as otherwise they get lost - captainL
1874   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
1875
1876   $from = [
1877     @$from,
1878     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
1879   ];
1880
1881   return ($from,$seen);
1882 }
1883
1884 sub _resolved_attrs {
1885   my $self = shift;
1886   return $self->{_attrs} if $self->{_attrs};
1887
1888   my $attrs = { %{$self->{attrs}||{}} };
1889   my $source = $self->result_source;
1890   my $alias = $attrs->{alias};
1891
1892   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
1893   if ($attrs->{columns}) {
1894     delete $attrs->{as};
1895   } elsif (!$attrs->{select}) {
1896     $attrs->{columns} = [ $source->columns ];
1897   }
1898
1899   $attrs->{select} =
1900     ($attrs->{select}
1901       ? (ref $attrs->{select} eq 'ARRAY'
1902           ? [ @{$attrs->{select}} ]
1903           : [ $attrs->{select} ])
1904       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
1905     );
1906   $attrs->{as} =
1907     ($attrs->{as}
1908       ? (ref $attrs->{as} eq 'ARRAY'
1909           ? [ @{$attrs->{as}} ]
1910           : [ $attrs->{as} ])
1911       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
1912     );
1913
1914   my $adds;
1915   if ($adds = delete $attrs->{include_columns}) {
1916     $adds = [$adds] unless ref $adds eq 'ARRAY';
1917     push(@{$attrs->{select}}, @$adds);
1918     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
1919   }
1920   if ($adds = delete $attrs->{'+select'}) {
1921     $adds = [$adds] unless ref $adds eq 'ARRAY';
1922     push(@{$attrs->{select}},
1923            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
1924   }
1925   if (my $adds = delete $attrs->{'+as'}) {
1926     $adds = [$adds] unless ref $adds eq 'ARRAY';
1927     push(@{$attrs->{as}}, @$adds);
1928   }
1929
1930   $attrs->{from} ||= [ { 'me' => $source->from } ];
1931
1932   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
1933     my $join = delete $attrs->{join} || {};
1934
1935     if (defined $attrs->{prefetch}) {
1936       $join = $self->_merge_attr(
1937         $join, $attrs->{prefetch}
1938       );
1939
1940     }
1941
1942     $attrs->{from} =   # have to copy here to avoid corrupting the original
1943       [
1944         @{$attrs->{from}},
1945         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
1946       ];
1947
1948   }
1949
1950   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
1951   if ($attrs->{order_by}) {
1952     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
1953                            ? [ @{$attrs->{order_by}} ]
1954                            : [ $attrs->{order_by} ]);
1955   } else {
1956     $attrs->{order_by} = [];
1957   }
1958
1959   my $collapse = $attrs->{collapse} || {};
1960   if (my $prefetch = delete $attrs->{prefetch}) {
1961     $prefetch = $self->_merge_attr({}, $prefetch);
1962     my @pre_order;
1963     my $seen = $attrs->{seen_join} || {};
1964     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
1965       # bring joins back to level of current class
1966       my @prefetch = $source->resolve_prefetch(
1967         $p, $alias, $seen, \@pre_order, $collapse
1968       );
1969       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
1970       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
1971     }
1972     push(@{$attrs->{order_by}}, @pre_order);
1973   }
1974   $attrs->{collapse} = $collapse;
1975
1976   if ($attrs->{page}) {
1977     $attrs->{offset} ||= 0;
1978     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
1979   }
1980
1981   return $self->{_attrs} = $attrs;
1982 }
1983
1984 sub _rollout_attr {
1985   my ($self, $attr) = @_;
1986
1987   if (ref $attr eq 'HASH') {
1988     return $self->_rollout_hash($attr);
1989   } elsif (ref $attr eq 'ARRAY') {
1990     return $self->_rollout_array($attr);
1991   } else {
1992     return [$attr];
1993   }
1994 }
1995
1996 sub _rollout_array {
1997   my ($self, $attr) = @_;
1998
1999   my @rolled_array;
2000   foreach my $element (@{$attr}) {
2001     if (ref $element eq 'HASH') {
2002       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2003     } elsif (ref $element eq 'ARRAY') {
2004       #  XXX - should probably recurse here
2005       push( @rolled_array, @{$self->_rollout_array($element)} );
2006     } else {
2007       push( @rolled_array, $element );
2008     }
2009   }
2010   return \@rolled_array;
2011 }
2012
2013 sub _rollout_hash {
2014   my ($self, $attr) = @_;
2015
2016   my @rolled_array;
2017   foreach my $key (keys %{$attr}) {
2018     push( @rolled_array, { $key => $attr->{$key} } );
2019   }
2020   return \@rolled_array;
2021 }
2022
2023 sub _calculate_score {
2024   my ($self, $a, $b) = @_;
2025
2026   if (ref $b eq 'HASH') {
2027     my ($b_key) = keys %{$b};
2028     if (ref $a eq 'HASH') {
2029       my ($a_key) = keys %{$a};
2030       if ($a_key eq $b_key) {
2031         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2032       } else {
2033         return 0;
2034       }
2035     } else {
2036       return ($a eq $b_key) ? 1 : 0;
2037     }
2038   } else {
2039     if (ref $a eq 'HASH') {
2040       my ($a_key) = keys %{$a};
2041       return ($b eq $a_key) ? 1 : 0;
2042     } else {
2043       return ($b eq $a) ? 1 : 0;
2044     }
2045   }
2046 }
2047
2048 sub _merge_attr {
2049   my ($self, $a, $b) = @_;
2050
2051   return $b unless defined($a);
2052   return $a unless defined($b);
2053
2054   $a = $self->_rollout_attr($a);
2055   $b = $self->_rollout_attr($b);
2056
2057   my $seen_keys;
2058   foreach my $b_element ( @{$b} ) {
2059     # find best candidate from $a to merge $b_element into
2060     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2061     foreach my $a_element ( @{$a} ) {
2062       my $score = $self->_calculate_score( $a_element, $b_element );
2063       if ($score > $best_candidate->{score}) {
2064         $best_candidate->{position} = $position;
2065         $best_candidate->{score} = $score;
2066       }
2067       $position++;
2068     }
2069     my ($b_key) = ( ref $b_element eq 'HASH' ) ? keys %{$b_element} : ($b_element);
2070     if ($best_candidate->{score} == 0 || exists $seen_keys->{$b_key}) {
2071       push( @{$a}, $b_element );
2072     } else {
2073       $seen_keys->{$b_key} = 1; # don't merge the same key twice
2074       my $a_best = $a->[$best_candidate->{position}];
2075       # merge a_best and b_element together and replace original with merged
2076       if (ref $a_best ne 'HASH') {
2077         $a->[$best_candidate->{position}] = $b_element;
2078       } elsif (ref $b_element eq 'HASH') {
2079         my ($key) = keys %{$a_best};
2080         $a->[$best_candidate->{position}] = { $key => $self->_merge_attr($a_best->{$key}, $b_element->{$key}) };
2081       }
2082     }
2083   }
2084
2085   return $a;
2086 }
2087
2088 sub result_source {
2089     my $self = shift;
2090
2091     if (@_) {
2092         $self->_source_handle($_[0]->handle);
2093     } else {
2094         $self->_source_handle->resolve;
2095     }
2096 }
2097
2098 =head2 throw_exception
2099
2100 See L<DBIx::Class::Schema/throw_exception> for details.
2101
2102 =cut
2103
2104 sub throw_exception {
2105   my $self=shift;
2106   $self->_source_handle->schema->throw_exception(@_);
2107 }
2108
2109 # XXX: FIXME: Attributes docs need clearing up
2110
2111 =head1 ATTRIBUTES
2112
2113 The resultset takes various attributes that modify its behavior. Here's an
2114 overview of them:
2115
2116 =head2 order_by
2117
2118 =over 4
2119
2120 =item Value: ($order_by | \@order_by)
2121
2122 =back
2123
2124 Which column(s) to order the results by. This is currently passed
2125 through directly to SQL, so you can give e.g. C<year DESC> for a
2126 descending order on the column `year'.
2127
2128 Please note that if you have C<quote_char> enabled (see
2129 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
2130 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
2131 so you will need to manually quote things as appropriate.)
2132
2133 =head2 columns
2134
2135 =over 4
2136
2137 =item Value: \@columns
2138
2139 =back
2140
2141 Shortcut to request a particular set of columns to be retrieved.  Adds
2142 C<me.> onto the start of any column without a C<.> in it and sets C<select>
2143 from that, then auto-populates C<as> from C<select> as normal. (You may also
2144 use the C<cols> attribute, as in earlier versions of DBIC.)
2145
2146 =head2 include_columns
2147
2148 =over 4
2149
2150 =item Value: \@columns
2151
2152 =back
2153
2154 Shortcut to include additional columns in the returned results - for example
2155
2156   $schema->resultset('CD')->search(undef, {
2157     include_columns => ['artist.name'],
2158     join => ['artist']
2159   });
2160
2161 would return all CDs and include a 'name' column to the information
2162 passed to object inflation. Note that the 'artist' is the name of the
2163 column (or relationship) accessor, and 'name' is the name of the column
2164 accessor in the related table.
2165
2166 =head2 select
2167
2168 =over 4
2169
2170 =item Value: \@select_columns
2171
2172 =back
2173
2174 Indicates which columns should be selected from the storage. You can use
2175 column names, or in the case of RDBMS back ends, function or stored procedure
2176 names:
2177
2178   $rs = $schema->resultset('Employee')->search(undef, {
2179     select => [
2180       'name',
2181       { count => 'employeeid' },
2182       { sum => 'salary' }
2183     ]
2184   });
2185
2186 When you use function/stored procedure names and do not supply an C<as>
2187 attribute, the column names returned are storage-dependent. E.g. MySQL would
2188 return a column named C<count(employeeid)> in the above example.
2189
2190 =head2 +select
2191
2192 =over 4
2193
2194 Indicates additional columns to be selected from storage.  Works the same as
2195 L<select> but adds columns to the selection.
2196
2197 =back
2198
2199 =head2 +as
2200
2201 =over 4
2202
2203 Indicates additional column names for those added via L<+select>.
2204
2205 =back
2206
2207 =head2 as
2208
2209 =over 4
2210
2211 =item Value: \@inflation_names
2212
2213 =back
2214
2215 Indicates column names for object inflation. That is, C<as>
2216 indicates the name that the column can be accessed as via the
2217 C<get_column> method (or via the object accessor, B<if one already
2218 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2219
2220 The C<as> attribute is used in conjunction with C<select>,
2221 usually when C<select> contains one or more function or stored
2222 procedure names:
2223
2224   $rs = $schema->resultset('Employee')->search(undef, {
2225     select => [
2226       'name',
2227       { count => 'employeeid' }
2228     ],
2229     as => ['name', 'employee_count'],
2230   });
2231
2232   my $employee = $rs->first(); # get the first Employee
2233
2234 If the object against which the search is performed already has an accessor
2235 matching a column name specified in C<as>, the value can be retrieved using
2236 the accessor as normal:
2237
2238   my $name = $employee->name();
2239
2240 If on the other hand an accessor does not exist in the object, you need to
2241 use C<get_column> instead:
2242
2243   my $employee_count = $employee->get_column('employee_count');
2244
2245 You can create your own accessors if required - see
2246 L<DBIx::Class::Manual::Cookbook> for details.
2247
2248 Please note: This will NOT insert an C<AS employee_count> into the SQL
2249 statement produced, it is used for internal access only. Thus
2250 attempting to use the accessor in an C<order_by> clause or similar
2251 will fail miserably.
2252
2253 To get around this limitation, you can supply literal SQL to your
2254 C<select> attibute that contains the C<AS alias> text, eg:
2255
2256   select => [\'myfield AS alias']
2257
2258 =head2 join
2259
2260 =over 4
2261
2262 =item Value: ($rel_name | \@rel_names | \%rel_names)
2263
2264 =back
2265
2266 Contains a list of relationships that should be joined for this query.  For
2267 example:
2268
2269   # Get CDs by Nine Inch Nails
2270   my $rs = $schema->resultset('CD')->search(
2271     { 'artist.name' => 'Nine Inch Nails' },
2272     { join => 'artist' }
2273   );
2274
2275 Can also contain a hash reference to refer to the other relation's relations.
2276 For example:
2277
2278   package MyApp::Schema::Track;
2279   use base qw/DBIx::Class/;
2280   __PACKAGE__->table('track');
2281   __PACKAGE__->add_columns(qw/trackid cd position title/);
2282   __PACKAGE__->set_primary_key('trackid');
2283   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2284   1;
2285
2286   # In your application
2287   my $rs = $schema->resultset('Artist')->search(
2288     { 'track.title' => 'Teardrop' },
2289     {
2290       join     => { cd => 'track' },
2291       order_by => 'artist.name',
2292     }
2293   );
2294
2295 You need to use the relationship (not the table) name in  conditions,
2296 because they are aliased as such. The current table is aliased as "me", so
2297 you need to use me.column_name in order to avoid ambiguity. For example:
2298
2299   # Get CDs from 1984 with a 'Foo' track
2300   my $rs = $schema->resultset('CD')->search(
2301     {
2302       'me.year' => 1984,
2303       'tracks.name' => 'Foo'
2304     },
2305     { join => 'tracks' }
2306   );
2307
2308 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2309 similarly for a third time). For e.g.
2310
2311   my $rs = $schema->resultset('Artist')->search({
2312     'cds.title'   => 'Down to Earth',
2313     'cds_2.title' => 'Popular',
2314   }, {
2315     join => [ qw/cds cds/ ],
2316   });
2317
2318 will return a set of all artists that have both a cd with title 'Down
2319 to Earth' and a cd with title 'Popular'.
2320
2321 If you want to fetch related objects from other tables as well, see C<prefetch>
2322 below.
2323
2324 =head2 prefetch
2325
2326 =over 4
2327
2328 =item Value: ($rel_name | \@rel_names | \%rel_names)
2329
2330 =back
2331
2332 Contains one or more relationships that should be fetched along with
2333 the main query (when they are accessed afterwards the data will
2334 already be available, without extra queries to the database).  This is
2335 useful for when you know you will need the related objects, because it
2336 saves at least one query:
2337
2338   my $rs = $schema->resultset('Tag')->search(
2339     undef,
2340     {
2341       prefetch => {
2342         cd => 'artist'
2343       }
2344     }
2345   );
2346
2347 The initial search results in SQL like the following:
2348
2349   SELECT tag.*, cd.*, artist.* FROM tag
2350   JOIN cd ON tag.cd = cd.cdid
2351   JOIN artist ON cd.artist = artist.artistid
2352
2353 L<DBIx::Class> has no need to go back to the database when we access the
2354 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2355 case.
2356
2357 Simple prefetches will be joined automatically, so there is no need
2358 for a C<join> attribute in the above search. If you're prefetching to
2359 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
2360 specify the join as well.
2361
2362 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2363 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2364 with an accessor type of 'single' or 'filter').
2365
2366 =head2 page
2367
2368 =over 4
2369
2370 =item Value: $page
2371
2372 =back
2373
2374 Makes the resultset paged and specifies the page to retrieve. Effectively
2375 identical to creating a non-pages resultset and then calling ->page($page)
2376 on it.
2377
2378 If L<rows> attribute is not specified it defualts to 10 rows per page.
2379
2380 =head2 rows
2381
2382 =over 4
2383
2384 =item Value: $rows
2385
2386 =back
2387
2388 Specifes the maximum number of rows for direct retrieval or the number of
2389 rows per page if the page attribute or method is used.
2390
2391 =head2 offset
2392
2393 =over 4
2394
2395 =item Value: $offset
2396
2397 =back
2398
2399 Specifies the (zero-based) row number for the  first row to be returned, or the
2400 of the first row of the first page if paging is used.
2401
2402 =head2 group_by
2403
2404 =over 4
2405
2406 =item Value: \@columns
2407
2408 =back
2409
2410 A arrayref of columns to group by. Can include columns of joined tables.
2411
2412   group_by => [qw/ column1 column2 ... /]
2413
2414 =head2 having
2415
2416 =over 4
2417
2418 =item Value: $condition
2419
2420 =back
2421
2422 HAVING is a select statement attribute that is applied between GROUP BY and
2423 ORDER BY. It is applied to the after the grouping calculations have been
2424 done.
2425
2426   having => { 'count(employee)' => { '>=', 100 } }
2427
2428 =head2 distinct
2429
2430 =over 4
2431
2432 =item Value: (0 | 1)
2433
2434 =back
2435
2436 Set to 1 to group by all columns.
2437
2438 =head2 where
2439
2440 =over 4
2441
2442 Adds to the WHERE clause.
2443
2444   # only return rows WHERE deleted IS NULL for all searches
2445   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2446
2447 Can be overridden by passing C<{ where => undef }> as an attribute
2448 to a resulset.
2449
2450 =back
2451
2452 =head2 cache
2453
2454 Set to 1 to cache search results. This prevents extra SQL queries if you
2455 revisit rows in your ResultSet:
2456
2457   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2458
2459   while( my $artist = $resultset->next ) {
2460     ... do stuff ...
2461   }
2462
2463   $rs->first; # without cache, this would issue a query
2464
2465 By default, searches are not cached.
2466
2467 For more examples of using these attributes, see
2468 L<DBIx::Class::Manual::Cookbook>.
2469
2470 =head2 from
2471
2472 =over 4
2473
2474 =item Value: \@from_clause
2475
2476 =back
2477
2478 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2479 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2480 clauses.
2481
2482 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2483
2484 C<join> will usually do what you need and it is strongly recommended that you
2485 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2486 And we really do mean "cannot", not just tried and failed. Attempting to use
2487 this because you're having problems with C<join> is like trying to use x86
2488 ASM because you've got a syntax error in your C. Trust us on this.
2489
2490 Now, if you're still really, really sure you need to use this (and if you're
2491 not 100% sure, ask the mailing list first), here's an explanation of how this
2492 works.
2493
2494 The syntax is as follows -
2495
2496   [
2497     { <alias1> => <table1> },
2498     [
2499       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2500       [], # nested JOIN (optional)
2501       { <table1.column1> => <table2.column2>, ... (more conditions) },
2502     ],
2503     # More of the above [ ] may follow for additional joins
2504   ]
2505
2506   <table1> <alias1>
2507   JOIN
2508     <table2> <alias2>
2509     [JOIN ...]
2510   ON <table1.column1> = <table2.column2>
2511   <more joins may follow>
2512
2513 An easy way to follow the examples below is to remember the following:
2514
2515     Anything inside "[]" is a JOIN
2516     Anything inside "{}" is a condition for the enclosing JOIN
2517
2518 The following examples utilize a "person" table in a family tree application.
2519 In order to express parent->child relationships, this table is self-joined:
2520
2521     # Person->belongs_to('father' => 'Person');
2522     # Person->belongs_to('mother' => 'Person');
2523
2524 C<from> can be used to nest joins. Here we return all children with a father,
2525 then search against all mothers of those children:
2526
2527   $rs = $schema->resultset('Person')->search(
2528       undef,
2529       {
2530           alias => 'mother', # alias columns in accordance with "from"
2531           from => [
2532               { mother => 'person' },
2533               [
2534                   [
2535                       { child => 'person' },
2536                       [
2537                           { father => 'person' },
2538                           { 'father.person_id' => 'child.father_id' }
2539                       ]
2540                   ],
2541                   { 'mother.person_id' => 'child.mother_id' }
2542               ],
2543           ]
2544       },
2545   );
2546
2547   # Equivalent SQL:
2548   # SELECT mother.* FROM person mother
2549   # JOIN (
2550   #   person child
2551   #   JOIN person father
2552   #   ON ( father.person_id = child.father_id )
2553   # )
2554   # ON ( mother.person_id = child.mother_id )
2555
2556 The type of any join can be controlled manually. To search against only people
2557 with a father in the person table, we could explicitly use C<INNER JOIN>:
2558
2559     $rs = $schema->resultset('Person')->search(
2560         undef,
2561         {
2562             alias => 'child', # alias columns in accordance with "from"
2563             from => [
2564                 { child => 'person' },
2565                 [
2566                     { father => 'person', -join_type => 'inner' },
2567                     { 'father.id' => 'child.father_id' }
2568                 ],
2569             ]
2570         },
2571     );
2572
2573     # Equivalent SQL:
2574     # SELECT child.* FROM person child
2575     # INNER JOIN person father ON child.father_id = father.id
2576
2577 =cut
2578
2579 1;