lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util 'fail_on_internal_wantarray';
  10 use Try::Tiny;
  11 use Data::Dumper::Concise ();
  12 use Data::Query::Constants;
  13 use Data::Query::ExprHelpers;
  14 # not importing first() as it will clash with our own method
  15 use List::Util ();
  16
  17 BEGIN {
  18   # De-duplication in _merge_attr() is disabled, but left in for reference
  19   # (the merger is used for other things that ought not to be de-duped)
  20   *__HM_DEDUP = sub () { 0 };
  21 }
  22
  23 use namespace::clean;
  24
  25 use overload
  26         '0+'     => "count",
  27         'bool'   => "_bool",
  28         fallback => 1;
  29
  30 # this is real - CDBICompat overrides it with insanity
  31 # yes, prototype won't matter, but that's for now ;)
  32 sub _bool () { 1 }
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  35
  36 =head1 NAME
  37
  38 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  39
  40 =head1 SYNOPSIS
  41
  42   my $users_rs = $schema->resultset('User');
  43   while( $user = $users_rs->next) {
  44     print $user->username;
  45   }
  46
  47   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  48   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  49
  50 =head1 DESCRIPTION
  51
  52 A ResultSet is an object which stores a set of conditions representing
  53 a query. It is the backbone of DBIx::Class (i.e. the really
  54 important/useful bit).
  55
  56 No SQL is executed on the database when a ResultSet is created, it
  57 just stores all the conditions needed to create the query.
  58
  59 A basic ResultSet representing the data of an entire table is returned
  60 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  61 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  62
  63   my $users_rs = $schema->resultset('User');
  64
  65 A new ResultSet is returned from calling L</search> on an existing
  66 ResultSet. The new one will contain all the conditions of the
  67 original, plus any new conditions added in the C<search> call.
  68
  69 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  70 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  71 represents.
  72
  73 The query that the ResultSet represents is B<only> executed against
  74 the database when these methods are called:
  75 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  76
  77 If a resultset is used in a numeric context it returns the L</count>.
  78 However, if it is used in a boolean context it is B<always> true.  So if
  79 you want to check if a resultset has any results, you must use C<if $rs
  80 != 0>.
  81
  82 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  83
  84 If you want to make your custom ResultSet classes with L<Moose>, use a template
  85 similar to:
  86
  87     package MyApp::Schema::ResultSet::User;
  88
  89     use Moose;
  90     use namespace::autoclean;
  91     use MooseX::NonMoose;
  92     extends 'DBIx::Class::ResultSet';
  93
  94     sub BUILDARGS { $_[2] }
  95
  96     ...your code...
  97
  98     __PACKAGE__->meta->make_immutable;
  99
 100     1;
 101
 102 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 103 clash with the regular ResultSet constructor. Alternatively, you can use:
 104
 105     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 106
 107 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 108 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 109
 110 =head1 EXAMPLES
 111
 112 =head2 Chaining resultsets
 113
 114 Let's say you've got a query that needs to be run to return some data
 115 to the user. But, you have an authorization system in place that
 116 prevents certain users from seeing certain information. So, you want
 117 to construct the basic query in one method, but add constraints to it in
 118 another.
 119
 120   sub get_data {
 121     my $self = shift;
 122     my $request = $self->get_request; # Get a request object somehow.
 123     my $schema = $self->result_source->schema;
 124
 125     my $cd_rs = $schema->resultset('CD')->search({
 126       title => $request->param('title'),
 127       year => $request->param('year'),
 128     });
 129
 130     $cd_rs = $self->apply_security_policy( $cd_rs );
 131
 132     return $cd_rs->all();
 133   }
 134
 135   sub apply_security_policy {
 136     my $self = shift;
 137     my ($rs) = @_;
 138
 139     return $rs->search({
 140       subversive => 0,
 141     });
 142   }
 143
 144 =head3 Resolving conditions and attributes
 145
 146 When a resultset is chained from another resultset (e.g.:
 147 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 148 and attributes with the same keys need resolving.
 149
 150 If any of L</columns>, L</select>, L</as> are present, they reset the
 151 original selection, and start the selection "clean".
 152
 153 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 154 are merged into the existing ones from the original resultset.
 155
 156 The L</where> and L</having> attributes, and any search conditions, are
 157 merged with an SQL C<AND> to the existing condition from the original
 158 resultset.
 159
 160 All other attributes are overridden by any new ones supplied in the
 161 search attributes.
 162
 163 =head2 Multiple queries
 164
 165 Since a resultset just defines a query, you can do all sorts of
 166 things with it with the same object.
 167
 168   # Don't hit the DB yet.
 169   my $cd_rs = $schema->resultset('CD')->search({
 170     title => 'something',
 171     year => 2009,
 172   });
 173
 174   # Each of these hits the DB individually.
 175   my $count = $cd_rs->count;
 176   my $most_recent = $cd_rs->get_column('date_released')->max();
 177   my @records = $cd_rs->all;
 178
 179 And it's not just limited to SELECT statements.
 180
 181   $cd_rs->delete();
 182
 183 This is even cooler:
 184
 185   $cd_rs->create({ artist => 'Fred' });
 186
 187 Which is the same as:
 188
 189   $schema->resultset('CD')->create({
 190     title => 'something',
 191     year => 2009,
 192     artist => 'Fred'
 193   });
 194
 195 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 196
 197 =head1 METHODS
 198
 199 =head2 new
 200
 201 =over 4
 202
 203 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 204
 205 =item Return Value: L<$resultset|/search>
 206
 207 =back
 208
 209 The resultset constructor. Takes a source object (usually a
 210 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 211 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 212 executed as needed by the other methods.
 213
 214 Generally you never construct a resultset manually. Instead you get one
 215 from e.g. a
 216 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 217 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 218 scalar context):
 219
 220   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 221
 222 =over
 223
 224 =item WARNING
 225
 226 If called on an object, proxies to L</new_result> instead, so
 227
 228   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 229
 230 will return a CD object, not a ResultSet, and is equivalent to:
 231
 232   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 233
 234 Please also keep in mind that many internals call L</new_result> directly,
 235 so overloading this method with the idea of intercepting new result object
 236 creation B<will not work>. See also warning pertaining to L</create>.
 237
 238 =back
 239
 240 =cut
 241
 242 sub new {
 243   my $class = shift;
 244   return $class->new_result(@_) if ref $class;
 245
 246   my ($source, $attrs) = @_;
 247   $source = $source->resolve
 248     if $source->isa('DBIx::Class::ResultSourceHandle');
 249
 250   $attrs = { %{$attrs||{}} };
 251   delete @{$attrs}{qw(_sqlmaker_select_args _related_results_construction)};
 252
 253   if ($attrs->{page}) {
 254     $attrs->{rows} ||= 10;
 255   }
 256
 257   $attrs->{alias} ||= 'me';
 258
 259   my $self = bless {
 260     result_source => $source,
 261     cond => $attrs->{where},
 262     pager => undef,
 263     attrs => $attrs,
 264   }, $class;
 265
 266   # if there is a dark selector, this means we are already in a
 267   # chain and the cleanup/sanification was taken care of by
 268   # _search_rs already
 269   $self->_normalize_selection($attrs)
 270     unless $attrs->{_dark_selector};
 271
 272   $self->result_class(
 273     $attrs->{result_class} || $source->result_class
 274   );
 275
 276   $self;
 277 }
 278
 279 =head2 search
 280
 281 =over 4
 282
 283 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 284
 285 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 286
 287 =back
 288
 289   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 290   my $new_rs = $cd_rs->search({ year => 2005 });
 291
 292   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 293                  # year = 2005 OR year = 2004
 294
 295 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 296 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 297 To avoid that, use L</search_rs>.
 298
 299 If you need to pass in additional attributes but no additional condition,
 300 call it as C<search(undef, \%attrs)>.
 301
 302   # "SELECT name, artistid FROM $artist_table"
 303   my @all_artists = $schema->resultset('Artist')->search(undef, {
 304     columns => [qw/name artistid/],
 305   });
 306
 307 For a list of attributes that can be passed to C<search>, see
 308 L</ATTRIBUTES>. For more examples of using this function, see
 309 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 310 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 311 and its extension L<DBIx::Class::SQLMaker>.
 312
 313 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 314
 315 =head3 CAVEAT
 316
 317 Note that L</search> does not process/deflate any of the values passed in the
 318 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 319 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 320 manually that any value passed to this method will stringify to something the
 321 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 322 objects, for more info see:
 323 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 324
 325 =cut
 326
 327 sub search {
 328   my $self = shift;
 329   my $rs = $self->search_rs( @_ );
 330
 331   if (wantarray) {
 332     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray($rs);
 333     return $rs->all;
 334   }
 335   elsif (defined wantarray) {
 336     return $rs;
 337   }
 338   else {
 339     # we can be called by a relationship helper, which in
 340     # turn may be called in void context due to some braindead
 341     # overload or whatever else the user decided to be clever
 342     # at this particular day. Thus limit the exception to
 343     # external code calls only
 344     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 345       if (caller)[0] !~ /^\QDBIx::Class::/;
 346
 347     return ();
 348   }
 349 }
 350
 351 =head2 search_rs
 352
 353 =over 4
 354
 355 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 356
 357 =item Return Value: L<$resultset|/search>
 358
 359 =back
 360
 361 This method does the same exact thing as search() except it will
 362 always return a resultset, even in list context.
 363
 364 =cut
 365
 366 sub search_rs {
 367   my $self = shift;
 368
 369   my $rsrc = $self->result_source;
 370   my ($call_cond, $call_attrs);
 371
 372   # Special-case handling for (undef, undef) or (undef)
 373   # Note that (foo => undef) is valid deprecated syntax
 374   @_ = () if not scalar grep { defined $_ } @_;
 375
 376   # just a cond
 377   if (@_ == 1) {
 378     $call_cond = shift;
 379   }
 380   # fish out attrs in the ($condref, $attr) case
 381   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 382     ($call_cond, $call_attrs) = @_;
 383   }
 384   elsif (@_ % 2) {
 385     $self->throw_exception('Odd number of arguments to search')
 386   }
 387   # legacy search
 388   elsif (@_) {
 389     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 390       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 391
 392     for my $i (0 .. $#_) {
 393       next if $i % 2;
 394       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 395         if (! defined $_[$i] or ref $_[$i] ne '');
 396     }
 397
 398     $call_cond = { @_ };
 399   }
 400
 401   if (blessed($call_cond) and $call_cond->isa('Data::Query::ExprBuilder')) {
 402     $call_cond = \$call_cond->{expr};
 403   }
 404
 405   # see if we can keep the cache (no $rs changes)
 406   my $cache;
 407   my %safe = (alias => 1, cache => 1);
 408   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 409     ! defined $call_cond
 410       or
 411     ref $call_cond eq 'HASH' && ! keys %$call_cond
 412       or
 413     ref $call_cond eq 'ARRAY' && ! @$call_cond
 414   )) {
 415     $cache = $self->get_cache;
 416   }
 417
 418   my $old_attrs = { %{$self->{attrs}} };
 419   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 420
 421   my $new_attrs = { %$old_attrs };
 422
 423   # take care of call attrs (only if anything is changing)
 424   if ($call_attrs and keys %$call_attrs) {
 425
 426     # copy for _normalize_selection
 427     $call_attrs = { %$call_attrs };
 428
 429     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 430
 431     # reset the current selector list if new selectors are supplied
 432     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 433       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 434     }
 435
 436     # Normalize the new selector list (operates on the passed-in attr structure)
 437     # Need to do it on every chain instead of only once on _resolved_attrs, in
 438     # order to allow detection of empty vs partial 'as'
 439     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 440       if $old_attrs->{_dark_selector};
 441     $self->_normalize_selection ($call_attrs);
 442
 443     # start with blind overwriting merge, exclude selector attrs
 444     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 445     delete @{$new_attrs}{@selector_attrs};
 446
 447     for (@selector_attrs) {
 448       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 449         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 450     }
 451
 452     # older deprecated name, use only if {columns} is not there
 453     if (my $c = delete $new_attrs->{cols}) {
 454       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 455       if ($new_attrs->{columns}) {
 456         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 457       }
 458       else {
 459         $new_attrs->{columns} = $c;
 460       }
 461     }
 462
 463
 464     # join/prefetch use their own crazy merging heuristics
 465     foreach my $key (qw/join prefetch/) {
 466       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 467         if exists $call_attrs->{$key};
 468     }
 469
 470     # stack binds together
 471     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 472   }
 473
 474
 475   for ($old_where, $call_cond) {
 476     if (defined $_) {
 477       $new_attrs->{where} = $self->_stack_cond (
 478         $_, $new_attrs->{where}
 479       );
 480     }
 481   }
 482
 483   if (defined $old_having) {
 484     $new_attrs->{having} = $self->_stack_cond (
 485       $old_having, $new_attrs->{having}
 486     )
 487   }
 488
 489   my $rs = (ref $self)->new($rsrc, $new_attrs);
 490
 491   $rs->set_cache($cache) if ($cache);
 492
 493   return $rs;
 494 }
 495
 496 my $dark_sel_dumper;
 497 sub _normalize_selection {
 498   my ($self, $attrs) = @_;
 499
 500   # legacy syntax
 501   if ( exists $attrs->{include_columns} ) {
 502     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 503     $attrs->{'+columns'} = $self->_merge_attr(
 504       $attrs->{'+columns'}, delete $attrs->{include_columns}
 505     );
 506   }
 507
 508   # columns are always placed first, however
 509
 510   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 511   # delay the decision on whether to use a default select list ($rsrc->columns)
 512   # allowing stuff like the remove_columns helper to work
 513   #
 514   # select/as +select/+as pairs need special handling - the amount of select/as
 515   # elements in each pair does *not* have to be equal (think multicolumn
 516   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 517   # supplied at all) - try to infer the alias, either from the -as parameter
 518   # of the selector spec, or use the parameter whole if it looks like a column
 519   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 520   # is ok as well), but make sure no more additions to the 'as' chain take place
 521   for my $pref ('', '+') {
 522
 523     my ($sel, $as) = map {
 524       my $key = "${pref}${_}";
 525
 526       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 527         ? @{$attrs->{$key}}
 528         : $attrs->{$key} || ()
 529       ];
 530       delete $attrs->{$key};
 531       $val;
 532     } qw/select as/;
 533
 534     if (! @$as and ! @$sel ) {
 535       next;
 536     }
 537     elsif (@$as and ! @$sel) {
 538       $self->throw_exception(
 539         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 540       );
 541     }
 542     elsif( ! @$as ) {
 543       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 544       # if any @$as has been supplied we assume the user knows what (s)he is doing
 545       # and blindly keep stacking up pieces
 546       unless ($attrs->{_dark_selector}) {
 547         SELECTOR:
 548         for (@$sel) {
 549           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 550             push @$as, $_->{-as};
 551           }
 552           # assume any plain no-space, no-parenthesis string to be a column spec
 553           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 554           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 555             push @$as, $_;
 556           }
 557           # if all else fails - raise a flag that no more aliasing will be allowed
 558           else {
 559             $attrs->{_dark_selector} = {
 560               plus_stage => $pref,
 561               string => ($dark_sel_dumper ||= do {
 562                   require Data::Dumper::Concise;
 563                   Data::Dumper::Concise::DumperObject()->Indent(0);
 564                 })->Values([$_])->Dump
 565               ,
 566             };
 567             last SELECTOR;
 568           }
 569         }
 570       }
 571     }
 572     elsif (@$as < @$sel) {
 573       $self->throw_exception(
 574         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 575       );
 576     }
 577     elsif ($pref and $attrs->{_dark_selector}) {
 578       $self->throw_exception(
 579         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 580       );
 581     }
 582
 583
 584     # merge result
 585     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 586     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 587   }
 588 }
 589
 590 sub _stack_cond {
 591   my ($self, $left, $right) = @_;
 592
 593   my $source = $self->result_source;
 594
 595   my $converter = $source->schema->storage->sql_maker->converter;
 596
 597   my @top = map $source->_extract_top_level_conditions(
 598     $converter->_expr_to_dq($_)
 599   ), grep defined, $left, $right;
 600
 601   return undef unless @top;
 602
 603   my %seen;
 604
 605   my @uniq = grep { !$seen{Data::Dumper::Concise::Dumper($_)}++ } @top;
 606
 607   return \Operator({ 'SQL.Naive' => 'AND' }, \@uniq);
 608 }
 609
 610 =head2 search_literal
 611
 612 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 613 should only be used in that context. C<search_literal> is a convenience
 614 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 615 want to ensure columns are bound correctly, use L</search>.
 616
 617 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 618 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 619 require C<search_literal>.
 620
 621 =over 4
 622
 623 =item Arguments: $sql_fragment, @standalone_bind_values
 624
 625 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 626
 627 =back
 628
 629   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 630   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 631
 632 Pass a literal chunk of SQL to be added to the conditional part of the
 633 resultset query.
 634
 635 Example of how to use C<search> instead of C<search_literal>
 636
 637   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 638   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 639
 640 =cut
 641
 642 sub search_literal {
 643   my ($self, $sql, @bind) = @_;
 644   my $attr;
 645   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 646     $attr = pop @bind;
 647   }
 648   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 649 }
 650
 651 =head2 find
 652
 653 =over 4
 654
 655 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 656
 657 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 658
 659 =back
 660
 661 Finds and returns a single row based on supplied criteria. Takes either a
 662 hashref with the same format as L</create> (including inference of foreign
 663 keys from related objects), or a list of primary key values in the same
 664 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 665 declaration on the L</result_source>.
 666
 667 In either case an attempt is made to combine conditions already existing on
 668 the resultset with the condition passed to this method.
 669
 670 To aid with preparing the correct query for the storage you may supply the
 671 C<key> attribute, which is the name of a
 672 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 673 unique constraint corresponding to the
 674 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 675 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 676 to construct a query that satisfies the named unique constraint fully (
 677 non-NULL values for each column member of the constraint) an exception is
 678 thrown.
 679
 680 If no C<key> is specified, the search is carried over all unique constraints
 681 which are fully defined by the available condition.
 682
 683 If no such constraint is found, C<find> currently defaults to a simple
 684 C<< search->(\%column_values) >> which may or may not do what you expect.
 685 Note that this fallback behavior may be deprecated in further versions. If
 686 you need to search with arbitrary conditions - use L</search>. If the query
 687 resulting from this fallback produces more than one row, a warning to the
 688 effect is issued, though only the first row is constructed and returned as
 689 C<$result_object>.
 690
 691 In addition to C<key>, L</find> recognizes and applies standard
 692 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 693
 694 Note that if you have extra concerns about the correctness of the resulting
 695 query you need to specify the C<key> attribute and supply the entire condition
 696 as an argument to find (since it is not always possible to perform the
 697 combination of the resultset condition with the supplied one, especially if
 698 the resultset condition contains literal sql).
 699
 700 For example, to find a row by its primary key:
 701
 702   my $cd = $schema->resultset('CD')->find(5);
 703
 704 You can also find a row by a specific unique constraint:
 705
 706   my $cd = $schema->resultset('CD')->find(
 707     {
 708       artist => 'Massive Attack',
 709       title  => 'Mezzanine',
 710     },
 711     { key => 'cd_artist_title' }
 712   );
 713
 714 See also L</find_or_create> and L</update_or_create>.
 715
 716 =cut
 717
 718 sub find {
 719   my $self = shift;
 720   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 721
 722   my $rsrc = $self->result_source;
 723
 724   my $constraint_name;
 725   if (exists $attrs->{key}) {
 726     $constraint_name = defined $attrs->{key}
 727       ? $attrs->{key}
 728       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 729     ;
 730   }
 731
 732   # Parse out the condition from input
 733   my $call_cond;
 734
 735   if (ref $_[0] eq 'HASH') {
 736     $call_cond = { %{$_[0]} };
 737   }
 738   else {
 739     # if only values are supplied we need to default to 'primary'
 740     $constraint_name = 'primary' unless defined $constraint_name;
 741
 742     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 743
 744     $self->throw_exception(
 745       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 746     ) unless @c_cols;
 747
 748     $self->throw_exception (
 749       'find() expects either a column/value hashref, or a list of values '
 750     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 751     ) unless @c_cols == @_;
 752
 753     $call_cond = {};
 754     @{$call_cond}{@c_cols} = @_;
 755   }
 756
 757   my %related;
 758   for my $key (keys %$call_cond) {
 759     if (
 760       my $keyref = ref($call_cond->{$key})
 761         and
 762       my $relinfo = $rsrc->relationship_info($key)
 763     ) {
 764       my $val = delete $call_cond->{$key};
 765
 766       next if $keyref eq 'ARRAY'; # has_many for multi_create
 767
 768       my $rel_q = $rsrc->_resolve_condition(
 769         $relinfo->{cond}, $val, $key, $key
 770       );
 771       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 772       @related{keys %$rel_q} = values %$rel_q;
 773     }
 774   }
 775
 776   # relationship conditions take precedence (?)
 777   @{$call_cond}{keys %related} = values %related;
 778
 779   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 780   my $final_cond;
 781   if (defined $constraint_name) {
 782     $final_cond = $self->_qualify_cond_columns (
 783
 784       $self->_build_unique_cond (
 785         $constraint_name,
 786         $call_cond,
 787       ),
 788
 789       $alias,
 790     );
 791   }
 792   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 793     # This means that we got here after a merger of relationship conditions
 794     # in ::Relationship::Base::search_related (the row method), and furthermore
 795     # the relationship is of the 'single' type. This means that the condition
 796     # provided by the relationship (already attached to $self) is sufficient,
 797     # as there can be only one row in the database that would satisfy the
 798     # relationship
 799   }
 800   else {
 801     # no key was specified - fall down to heuristics mode:
 802     # run through all unique queries registered on the resultset, and
 803     # 'OR' all qualifying queries together
 804     my (@unique_queries, %seen_column_combinations);
 805     for my $c_name ($rsrc->unique_constraint_names) {
 806       next if $seen_column_combinations{
 807         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 808       }++;
 809
 810       push @unique_queries, try {
 811         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 812       } || ();
 813     }
 814
 815     $final_cond = @unique_queries
 816       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 817       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 818     ;
 819   }
 820
 821   # Run the query, passing the result_class since it should propagate for find
 822   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 823   if ($rs->_resolved_attrs->{collapse}) {
 824     my $row = $rs->next;
 825     carp "Query returned more than one row" if $rs->next;
 826     return $row;
 827   }
 828   else {
 829     return $rs->single;
 830   }
 831 }
 832
 833 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 834 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 835 #
 836 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 837 # condition. It is provided for overrides until a saner way forward is devised
 838 #
 839 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 840 # the road. Please adjust your tests accordingly to catch this situation early
 841 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 842 #
 843 # The method will not be removed without an adequately complete replacement
 844 # for strict-mode enforcement
 845 sub _non_unique_find_fallback {
 846   my ($self, $cond, $attrs) = @_;
 847
 848   return $self->_qualify_cond_columns(
 849     $cond,
 850     exists $attrs->{alias}
 851       ? $attrs->{alias}
 852       : $self->{attrs}{alias}
 853   );
 854 }
 855
 856
 857 sub _qualify_cond_columns {
 858   my ($self, $cond, $alias) = @_;
 859
 860   my %aliased = %$cond;
 861   for (keys %aliased) {
 862     $aliased{"$alias.$_"} = delete $aliased{$_}
 863       if $_ !~ /\./;
 864   }
 865
 866   return \%aliased;
 867 }
 868
 869 sub _build_unique_cond {
 870   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 871
 872   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 873
 874   # combination may fail if $self->{cond} is non-trivial
 875   my ($final_cond) = try {
 876     $self->_merge_with_rscond ($extra_cond)
 877   } catch {
 878     +{ %$extra_cond }
 879   };
 880
 881   # trim out everything not in $columns
 882   $final_cond = { map {
 883     exists $final_cond->{$_}
 884       ? ( $_ => $final_cond->{$_} )
 885       : ()
 886   } @c_cols };
 887
 888   if (my @missing = grep
 889     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 890     (@c_cols)
 891   ) {
 892     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 893       $constraint_name,
 894       join (', ', map { "'$_'" } @missing),
 895     ) );
 896   }
 897
 898   if (
 899     !$croak_on_null
 900       and
 901     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 902       and
 903     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 904   ) {
 905     carp_unique ( sprintf (
 906       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 907     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 908     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 909       $constraint_name,
 910       join (', ', map { "'$_'" } @undefs),
 911     ));
 912   }
 913
 914   return $final_cond;
 915 }
 916
 917 =head2 search_related
 918
 919 =over 4
 920
 921 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 922
 923 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 924
 925 =back
 926
 927   $new_rs = $cd_rs->search_related('artist', {
 928     name => 'Emo-R-Us',
 929   });
 930
 931 Searches the specified relationship, optionally specifying a condition and
 932 attributes for matching records. See L</ATTRIBUTES> for more information.
 933
 934 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 935 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 936
 937 See also L</search_related_rs>.
 938
 939 =cut
 940
 941 sub search_related {
 942   return shift->related_resultset(shift)->search(@_);
 943 }
 944
 945 =head2 search_related_rs
 946
 947 This method works exactly the same as search_related, except that
 948 it guarantees a resultset, even in list context.
 949
 950 =cut
 951
 952 sub search_related_rs {
 953   return shift->related_resultset(shift)->search_rs(@_);
 954 }
 955
 956 =head2 cursor
 957
 958 =over 4
 959
 960 =item Arguments: none
 961
 962 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 963
 964 =back
 965
 966 Returns a storage-driven cursor to the given resultset. See
 967 L<DBIx::Class::Cursor> for more information.
 968
 969 =cut
 970
 971 sub cursor {
 972   my $self = shift;
 973
 974   return $self->{cursor} ||= do {
 975     my $attrs = $self->_resolved_attrs;
 976     $self->result_source->storage->select(
 977       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
 978     );
 979   };
 980 }
 981
 982 =head2 single
 983
 984 =over 4
 985
 986 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
 987
 988 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 989
 990 =back
 991
 992   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 993
 994 Inflates the first result without creating a cursor if the resultset has
 995 any records in it; if not returns C<undef>. Used by L</find> as a lean version
 996 of L</search>.
 997
 998 While this method can take an optional search condition (just like L</search>)
 999 being a fast-code-path it does not recognize search attributes. If you need to
1000 add extra joins or similar, call L</search> and then chain-call L</single> on the
1001 L<DBIx::Class::ResultSet> returned.
1002
1003 =over
1004
1005 =item B<Note>
1006
1007 As of 0.08100, this method enforces the assumption that the preceding
1008 query returns only one row. If more than one row is returned, you will receive
1009 a warning:
1010
1011   Query returned more than one row
1012
1013 In this case, you should be using L</next> or L</find> instead, or if you really
1014 know what you are doing, use the L</rows> attribute to explicitly limit the size
1015 of the resultset.
1016
1017 This method will also throw an exception if it is called on a resultset prefetching
1018 has_many, as such a prefetch implies fetching multiple rows from the database in
1019 order to assemble the resulting object.
1020
1021 =back
1022
1023 =cut
1024
1025 sub single {
1026   my ($self, $where) = @_;
1027   if(@_ > 2) {
1028       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1029   }
1030
1031   my $attrs = { %{$self->_resolved_attrs} };
1032
1033   $self->throw_exception(
1034     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1035   ) if $attrs->{collapse};
1036
1037   if ($where) {
1038     if (defined $attrs->{where}) {
1039       $attrs->{where} = {
1040         '-and' =>
1041             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1042                $where, delete $attrs->{where} ]
1043       };
1044     } else {
1045       $attrs->{where} = $where;
1046     }
1047   }
1048
1049   my $data = [ $self->result_source->storage->select_single(
1050     $attrs->{from}, $attrs->{select},
1051     $attrs->{where}, $attrs
1052   )];
1053
1054   return undef unless @$data;
1055   $self->{_stashed_rows} = [ $data ];
1056   $self->_construct_results->[0];
1057 }
1058
1059
1060 # _collapse_query
1061 #
1062 # Recursively collapse the query, accumulating values for each column.
1063
1064 sub _collapse_query {
1065   my ($self, $query, $collapsed) = @_;
1066
1067   $collapsed ||= {};
1068
1069   if (ref $query eq 'ARRAY') {
1070     foreach my $subquery (@$query) {
1071       next unless ref $subquery;  # -or
1072       $collapsed = $self->_collapse_query($subquery, $collapsed);
1073     }
1074   }
1075   elsif (ref $query eq 'HASH') {
1076     if (keys %$query and (keys %$query)[0] eq '-and') {
1077       foreach my $subquery (@{$query->{-and}}) {
1078         $collapsed = $self->_collapse_query($subquery, $collapsed);
1079       }
1080     }
1081     else {
1082       foreach my $col (keys %$query) {
1083         my $value = $query->{$col};
1084         $collapsed->{$col}{$value}++;
1085       }
1086     }
1087   }
1088
1089   return $collapsed;
1090 }
1091
1092 =head2 get_column
1093
1094 =over 4
1095
1096 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1097
1098 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1099
1100 =back
1101
1102   my $max_length = $rs->get_column('length')->max;
1103
1104 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1105
1106 =cut
1107
1108 sub get_column {
1109   my ($self, $column) = @_;
1110   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1111   return $new;
1112 }
1113
1114 =head2 search_like
1115
1116 =over 4
1117
1118 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1119
1120 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1121
1122 =back
1123
1124   # WHERE title LIKE '%blue%'
1125   $cd_rs = $rs->search_like({ title => '%blue%'});
1126
1127 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1128 that this is simply a convenience method retained for ex Class::DBI users.
1129 You most likely want to use L</search> with specific operators.
1130
1131 For more information, see L<DBIx::Class::Manual::Cookbook>.
1132
1133 This method is deprecated and will be removed in 0.09. Use L</search()>
1134 instead. An example conversion is:
1135
1136   ->search_like({ foo => 'bar' });
1137
1138   # Becomes
1139
1140   ->search({ foo => { like => 'bar' } });
1141
1142 =cut
1143
1144 sub search_like {
1145   my $class = shift;
1146   carp_unique (
1147     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1148    .' Instead use ->search({ x => { -like => "y%" } })'
1149    .' (note the outer pair of {}s - they are important!)'
1150   );
1151   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1152   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1153   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1154   return $class->search($query, { %$attrs });
1155 }
1156
1157 =head2 slice
1158
1159 =over 4
1160
1161 =item Arguments: $first, $last
1162
1163 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1164
1165 =back
1166
1167 Returns a resultset or object list representing a subset of elements from the
1168 resultset slice is called on. Indexes are from 0, i.e., to get the first
1169 three records, call:
1170
1171   my ($one, $two, $three) = $rs->slice(0, 2);
1172
1173 =cut
1174
1175 sub slice {
1176   my ($self, $min, $max) = @_;
1177   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1178   $attrs->{offset} = $self->{attrs}{offset} || 0;
1179   $attrs->{offset} += $min;
1180   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1181   return $self->search(undef, $attrs);
1182 }
1183
1184 =head2 next
1185
1186 =over 4
1187
1188 =item Arguments: none
1189
1190 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1191
1192 =back
1193
1194 Returns the next element in the resultset (C<undef> is there is none).
1195
1196 Can be used to efficiently iterate over records in the resultset:
1197
1198   my $rs = $schema->resultset('CD')->search;
1199   while (my $cd = $rs->next) {
1200     print $cd->title;
1201   }
1202
1203 Note that you need to store the resultset object, and call C<next> on it.
1204 Calling C<< resultset('Table')->next >> repeatedly will always return the
1205 first record from the resultset.
1206
1207 =cut
1208
1209 sub next {
1210   my ($self) = @_;
1211
1212   if (my $cache = $self->get_cache) {
1213     $self->{all_cache_position} ||= 0;
1214     return $cache->[$self->{all_cache_position}++];
1215   }
1216
1217   if ($self->{attrs}{cache}) {
1218     delete $self->{pager};
1219     $self->{all_cache_position} = 1;
1220     return ($self->all)[0];
1221   }
1222
1223   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1224
1225   $self->{_stashed_results} = $self->_construct_results
1226     or return undef;
1227
1228   return shift @{$self->{_stashed_results}};
1229 }
1230
1231 # Constructs as many results as it can in one pass while respecting
1232 # cursor laziness. Several modes of operation:
1233 #
1234 # * Always builds everything present in @{$self->{_stashed_rows}}
1235 # * If called with $fetch_all true - pulls everything off the cursor and
1236 #   builds all result structures (or objects) in one pass
1237 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1238 #   and if the resultset is ordered properly by the left side:
1239 #   * Fetches stuff off the cursor until the "master object" changes,
1240 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1241 #   OR
1242 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1243 #     was requested (there is no other way to collapse except for an
1244 #     eager cursor)
1245 # * If no collapse is requested - just get the next row, construct and
1246 #   return
1247 sub _construct_results {
1248   my ($self, $fetch_all) = @_;
1249
1250   my $rsrc = $self->result_source;
1251   my $attrs = $self->_resolved_attrs;
1252
1253   if (
1254     ! $fetch_all
1255       and
1256     ! $attrs->{order_by}
1257       and
1258     $attrs->{collapse}
1259       and
1260     my @pcols = $rsrc->primary_columns
1261   ) {
1262     # default order for collapsing unless the user asked for something
1263     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1264     $attrs->{_ordered_for_collapse} = 1;
1265     $attrs->{_order_is_artificial} = 1;
1266   }
1267
1268   # this will be used as both initial raw-row collector AND as a RV of
1269   # _construct_results. Not regrowing the array twice matters a lot...
1270   # a surprising amount actually
1271   my $rows = delete $self->{_stashed_rows};
1272
1273   my $cursor; # we may not need one at all
1274
1275   my $did_fetch_all = $fetch_all;
1276
1277   if ($fetch_all) {
1278     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1279     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1280   }
1281   elsif( $attrs->{collapse} ) {
1282
1283     # a cursor will need to be closed over in case of collapse
1284     $cursor = $self->cursor;
1285
1286     $attrs->{_ordered_for_collapse} = (
1287       (
1288         $attrs->{order_by}
1289           and
1290         $rsrc->schema
1291               ->storage
1292                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1293       ) ? 1 : 0
1294     ) unless defined $attrs->{_ordered_for_collapse};
1295
1296     if (! $attrs->{_ordered_for_collapse}) {
1297       $did_fetch_all = 1;
1298
1299       # instead of looping over ->next, use ->all in stealth mode
1300       # *without* calling a ->reset afterwards
1301       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1302       if (! $cursor->{_done}) {
1303         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1304         $cursor->{_done} = 1;
1305       }
1306     }
1307   }
1308
1309   if (! $did_fetch_all and ! @{$rows||[]} ) {
1310     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1311     $cursor ||= $self->cursor;
1312     if (scalar (my @r = $cursor->next) ) {
1313       $rows = [ \@r ];
1314     }
1315   }
1316
1317   return undef unless @{$rows||[]};
1318
1319   # sanity check - people are too clever for their own good
1320   if ($attrs->{collapse} and my $aliastypes = $attrs->{_sqlmaker_select_args}[3]{_aliastypes} ) {
1321
1322     my $multiplied_selectors;
1323     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1324       if (
1325         $aliastypes->{multiplying}{$sel_alias}
1326           or
1327         $aliastypes->{premultiplied}{$sel_alias}
1328       ) {
1329         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1330       }
1331     }
1332
1333     for my $i (0 .. $#{$attrs->{as}} ) {
1334       my $sel = $attrs->{select}[$i];
1335
1336       if (ref $sel eq 'SCALAR') {
1337         $sel = $$sel;
1338       }
1339       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1340         $sel = $$sel->[0];
1341       }
1342
1343       $self->throw_exception(
1344         'Result collapse not possible - selection from a has_many source redirected to the main object'
1345       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1346     }
1347   }
1348
1349   # hotspot - skip the setter
1350   my $res_class = $self->_result_class;
1351
1352   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1353     $res_class->can ('inflate_result')
1354       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1355   };
1356
1357   my $infmap = $attrs->{as};
1358
1359   $self->{_result_inflator}{is_core_row} = ( (
1360     $inflator_cref
1361       ==
1362     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1363   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1364
1365   $self->{_result_inflator}{is_hri} = ( (
1366     ! $self->{_result_inflator}{is_core_row}
1367       and
1368     $inflator_cref == (
1369       require DBIx::Class::ResultClass::HashRefInflator
1370         &&
1371       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1372     )
1373   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1374
1375
1376   if (! $attrs->{_related_results_construction}) {
1377     # construct a much simpler array->hash folder for the one-table cases right here
1378     if ($self->{_result_inflator}{is_hri}) {
1379       for my $r (@$rows) {
1380         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1381       }
1382     }
1383     # FIXME SUBOPTIMAL this is a very very very hot spot
1384     # while rather optimal we can *still* do much better, by
1385     # building a smarter Row::inflate_result(), and
1386     # switch to feeding it data via a much leaner interface
1387     #
1388     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1389     # this particular resultset size
1390     elsif (@$rows < 60) {
1391       for my $r (@$rows) {
1392         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1393       }
1394     }
1395     else {
1396       eval sprintf (
1397         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1398         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1399       );
1400     }
1401   }
1402   else {
1403     my $parser_type =
1404         $self->{_result_inflator}{is_hri}       ? 'hri'
1405       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1406       :                                           'classic_nonpruning'
1407     ;
1408
1409     # $args and $attrs to _mk_row_parser are separated to delineate what is
1410     # core collapser stuff and what is dbic $rs specific
1411     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1412       eval => 1,
1413       inflate_map => $infmap,
1414       collapse => $attrs->{collapse},
1415       premultiplied => $attrs->{_main_source_premultiplied},
1416       hri_style => $self->{_result_inflator}{is_hri},
1417       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1418     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1419
1420     # column_info metadata historically hasn't been too reliable.
1421     # We need to start fixing this somehow (the collapse resolver
1422     # can't work without it). Add an explicit check for the *main*
1423     # result, hopefully this will gradually weed out such errors
1424     #
1425     # FIXME - this is a temporary kludge that reduces performance
1426     # It is however necessary for the time being
1427     my ($unrolled_non_null_cols_to_check, $err);
1428
1429     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1430
1431       $err =
1432         'Collapse aborted due to invalid ResultSource metadata - the following '
1433       . 'selections are declared non-nullable but NULLs were retrieved: '
1434       ;
1435
1436       my @violating_idx;
1437       COL: for my $i (@$check_non_null_cols) {
1438         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1439       }
1440
1441       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1442         if @violating_idx;
1443
1444       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1445     }
1446
1447     my $next_cref =
1448       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1449     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1450 sub {
1451   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1452   my @r = $cursor->next or return;
1453   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1454     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1455   }
1456   \@r
1457 }
1458 EOS
1459     : sub {
1460         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1461         my @r = $cursor->next or return;
1462         \@r
1463       }
1464     ;
1465
1466     $self->{_row_parser}{$parser_type}{cref}->(
1467       $rows,
1468       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1469     );
1470
1471     # Special-case multi-object HRI - there is no $inflator_cref pass
1472     unless ($self->{_result_inflator}{is_hri}) {
1473       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1474     }
1475   }
1476
1477   # The @$rows check seems odd at first - why wouldn't we want to warn
1478   # regardless? The issue is things like find() etc, where the user
1479   # *knows* only one result will come back. In these cases the ->all
1480   # is not a pessimization, but rather something we actually want
1481   carp_unique(
1482     'Unable to properly collapse has_many results in iterator mode due '
1483   . 'to order criteria - performed an eager cursor slurp underneath. '
1484   . 'Consider using ->all() instead'
1485   ) if ( ! $fetch_all and @$rows > 1 );
1486
1487   return $rows;
1488 }
1489
1490 =head2 result_source
1491
1492 =over 4
1493
1494 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1495
1496 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1497
1498 =back
1499
1500 An accessor for the primary ResultSource object from which this ResultSet
1501 is derived.
1502
1503 =head2 result_class
1504
1505 =over 4
1506
1507 =item Arguments: $result_class?
1508
1509 =item Return Value: $result_class
1510
1511 =back
1512
1513 An accessor for the class to use when creating result objects. Defaults to
1514 C<< result_source->result_class >> - which in most cases is the name of the
1515 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1516
1517 Note that changing the result_class will also remove any components
1518 that were originally loaded in the source class via
1519 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1520 in the original source class will not run.
1521
1522 =cut
1523
1524 sub result_class {
1525   my ($self, $result_class) = @_;
1526   if ($result_class) {
1527
1528     # don't fire this for an object
1529     $self->ensure_class_loaded($result_class)
1530       unless ref($result_class);
1531
1532     if ($self->get_cache) {
1533       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1534     }
1535     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1536     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1537       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1538     }
1539
1540     $self->_result_class($result_class);
1541
1542     delete $self->{_result_inflator};
1543   }
1544   $self->_result_class;
1545 }
1546
1547 =head2 count
1548
1549 =over 4
1550
1551 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1552
1553 =item Return Value: $count
1554
1555 =back
1556
1557 Performs an SQL C<COUNT> with the same query as the resultset was built
1558 with to find the number of elements. Passing arguments is equivalent to
1559 C<< $rs->search ($cond, \%attrs)->count >>
1560
1561 =cut
1562
1563 sub count {
1564   my $self = shift;
1565   return $self->search(@_)->count if @_ and defined $_[0];
1566   return scalar @{ $self->get_cache } if $self->get_cache;
1567
1568   my $attrs = { %{ $self->_resolved_attrs } };
1569
1570   # this is a little optimization - it is faster to do the limit
1571   # adjustments in software, instead of a subquery
1572   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1573
1574   my $crs;
1575   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1576     $crs = $self->_count_subq_rs ($attrs);
1577   }
1578   else {
1579     $crs = $self->_count_rs ($attrs);
1580   }
1581   my $count = $crs->next;
1582
1583   $count -= $offset if $offset;
1584   $count = $rows if $rows and $rows < $count;
1585   $count = 0 if ($count < 0);
1586
1587   return $count;
1588 }
1589
1590 =head2 count_rs
1591
1592 =over 4
1593
1594 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1595
1596 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1597
1598 =back
1599
1600 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1601 This can be very handy for subqueries:
1602
1603   ->search( { amount => $some_rs->count_rs->as_query } )
1604
1605 As with regular resultsets the SQL query will be executed only after
1606 the resultset is accessed via L</next> or L</all>. That would return
1607 the same single value obtainable via L</count>.
1608
1609 =cut
1610
1611 sub count_rs {
1612   my $self = shift;
1613   return $self->search(@_)->count_rs if @_;
1614
1615   # this may look like a lack of abstraction (count() does about the same)
1616   # but in fact an _rs *must* use a subquery for the limits, as the
1617   # software based limiting can not be ported if this $rs is to be used
1618   # in a subquery itself (i.e. ->as_query)
1619   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1620     return $self->_count_subq_rs($self->{_attrs});
1621   }
1622   else {
1623     return $self->_count_rs($self->{_attrs});
1624   }
1625 }
1626
1627 #
1628 # returns a ResultSetColumn object tied to the count query
1629 #
1630 sub _count_rs {
1631   my ($self, $attrs) = @_;
1632
1633   my $rsrc = $self->result_source;
1634
1635   my $tmp_attrs = { %$attrs };
1636   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1637   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1638
1639   # overwrite the selector (supplied by the storage)
1640   $rsrc->resultset_class->new($rsrc, {
1641     %$tmp_attrs,
1642     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1643     as => 'count',
1644   })->get_column ('count');
1645 }
1646
1647 #
1648 # same as above but uses a subquery
1649 #
1650 sub _count_subq_rs {
1651   my ($self, $attrs) = @_;
1652
1653   my $rsrc = $self->result_source;
1654
1655   my $sub_attrs = { %$attrs };
1656   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1657   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1658
1659   # if we multi-prefetch we group_by something unique, as this is what we would
1660   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1661   if ( $attrs->{collapse}  ) {
1662     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1663       $rsrc->_identifying_column_set || $self->throw_exception(
1664         'Unable to construct a unique group_by criteria properly collapsing the '
1665       . 'has_many prefetch before count()'
1666       );
1667     } ]
1668   }
1669
1670   # Calculate subquery selector
1671   if (my $g = $sub_attrs->{group_by}) {
1672
1673     my $sql_maker = $rsrc->storage->sql_maker;
1674
1675     # necessary as the group_by may refer to aliased functions
1676     my $sel_index;
1677     for my $sel (@{$attrs->{select}}) {
1678       $sel_index->{$sel->{-as}} = $sel
1679         if (ref $sel eq 'HASH' and $sel->{-as});
1680     }
1681
1682     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1683     # also look for named aggregates referred in the having clause
1684     # having often contains scalarrefs - thus parse it out entirely
1685     my @parts = @$g;
1686     if ($attrs->{having}) {
1687       local $sql_maker->{having_bind};
1688       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1689       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1690       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1691         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1692         # if we don't unset it we screw up retarded but unfortunately working
1693         # 'MAX(foo.bar)' => { '>', 3 }
1694         $sql_maker->{name_sep} = '';
1695       }
1696
1697       $sql_maker->clear_renderer;
1698       $sql_maker->clear_converter;
1699
1700       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1701
1702       my $having_sql = $sql_maker->_render_sqla(where => $attrs->{having});
1703
1704       $sql_maker->clear_renderer;
1705       $sql_maker->clear_converter;
1706
1707       my %seen_having;
1708
1709       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1710       # and if all fails for an utterly naive quoted scalar-with-function
1711       while ($having_sql =~ /
1712         (?: $rquote $sep)? $lquote (.+?) $rquote
1713           |
1714         [\s,] \w+ \. (\w+) [\s,]
1715           |
1716         [\s,] $lquote (.+?) $rquote [\s,]
1717       /gx) {
1718         my $part = $1 || $2 || $3;  # one of them matched if we got here
1719         unless ($seen_having{$part}++) {
1720           push @parts, $part;
1721         }
1722       }
1723     }
1724
1725     for (@parts) {
1726       my $colpiece = $sel_index->{$_} || $_;
1727
1728       # unqualify join-based group_by's. Arcane but possible query
1729       # also horrible horrible hack to alias a column (not a func.)
1730       # (probably need to introduce SQLA syntax)
1731       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1732         my $as = $colpiece;
1733         $as =~ s/\./__/;
1734         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1735       }
1736       push @{$sub_attrs->{select}}, $colpiece;
1737     }
1738   }
1739   else {
1740     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1741     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1742   }
1743
1744   return $rsrc->resultset_class
1745                ->new ($rsrc, $sub_attrs)
1746                 ->as_subselect_rs
1747                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1748                   ->get_column ('count');
1749 }
1750
1751
1752 =head2 count_literal
1753
1754 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1755 should only be used in that context. See L</search_literal> for further info.
1756
1757 =over 4
1758
1759 =item Arguments: $sql_fragment, @standalone_bind_values
1760
1761 =item Return Value: $count
1762
1763 =back
1764
1765 Counts the results in a literal query. Equivalent to calling L</search_literal>
1766 with the passed arguments, then L</count>.
1767
1768 =cut
1769
1770 sub count_literal { shift->search_literal(@_)->count; }
1771
1772 =head2 all
1773
1774 =over 4
1775
1776 =item Arguments: none
1777
1778 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1779
1780 =back
1781
1782 Returns all elements in the resultset.
1783
1784 =cut
1785
1786 sub all {
1787   my $self = shift;
1788   if(@_) {
1789     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1790   }
1791
1792   delete @{$self}{qw/_stashed_rows _stashed_results/};
1793
1794   if (my $c = $self->get_cache) {
1795     return @$c;
1796   }
1797
1798   $self->cursor->reset;
1799
1800   my $objs = $self->_construct_results('fetch_all') || [];
1801
1802   $self->set_cache($objs) if $self->{attrs}{cache};
1803
1804   return @$objs;
1805 }
1806
1807 =head2 reset
1808
1809 =over 4
1810
1811 =item Arguments: none
1812
1813 =item Return Value: $self
1814
1815 =back
1816
1817 Resets the resultset's cursor, so you can iterate through the elements again.
1818 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1819 another query.
1820
1821 =cut
1822
1823 sub reset {
1824   my ($self) = @_;
1825
1826   delete @{$self}{qw/_stashed_rows _stashed_results/};
1827   $self->{all_cache_position} = 0;
1828   $self->cursor->reset;
1829   return $self;
1830 }
1831
1832 =head2 first
1833
1834 =over 4
1835
1836 =item Arguments: none
1837
1838 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1839
1840 =back
1841
1842 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1843 an object for the first result (or C<undef> if the resultset is empty).
1844
1845 =cut
1846
1847 sub first {
1848   return $_[0]->reset->next;
1849 }
1850
1851
1852 # _rs_update_delete
1853 #
1854 # Determines whether and what type of subquery is required for the $rs operation.
1855 # If grouping is necessary either supplies its own, or verifies the current one
1856 # After all is done delegates to the proper storage method.
1857
1858 sub _rs_update_delete {
1859   my ($self, $op, $values) = @_;
1860
1861   my $rsrc = $self->result_source;
1862   my $storage = $rsrc->schema->storage;
1863
1864   my $attrs = { %{$self->_resolved_attrs} };
1865
1866   my $join_classifications;
1867   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1868
1869   # do we need a subquery for any reason?
1870   my $needs_subq = (
1871     defined $existing_group_by
1872       or
1873     # if {from} is unparseable wrap a subq
1874     ref($attrs->{from}) ne 'ARRAY'
1875       or
1876     # limits call for a subq
1877     $self->_has_resolved_attr(qw/rows offset/)
1878   );
1879
1880   # simplify the joinmap, so we can further decide if a subq is necessary
1881   if (!$needs_subq and @{$attrs->{from}} > 1) {
1882
1883     ($attrs->{from}, $join_classifications) =
1884       $storage->_prune_unused_joins ($attrs);
1885
1886     # any non-pruneable non-local restricting joins imply subq
1887     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1888   }
1889
1890   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1891   $needs_subq ||= (
1892     (ref $attrs->{from}[0]) ne 'HASH'
1893       or
1894     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1895   );
1896
1897   my ($cond, $guard);
1898   # do we need anything like a subquery?
1899   if (! $needs_subq) {
1900     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1901     # a condition containing 'me' or other table prefixes will not work
1902     # at all - so we convert the WHERE to a dq tree now, dequalify all
1903     # identifiers found therein via a scan across the tree, and then use
1904     # \{} style to pass the result onwards for use in the final query
1905     if ($self->{cond}) {
1906       $cond = do {
1907         my $converter = $rsrc->storage->sql_maker->converter;
1908         scan_dq_nodes({
1909           DQ_IDENTIFIER ,=> sub { $_ = [ $_->[-1] ] for $_[0]->{elements} }
1910         }, my $where_dq = $converter->_where_to_dq($self->{cond}));
1911         \$where_dq;
1912       };
1913     }
1914   }
1915   else {
1916     # we got this far - means it is time to wrap a subquery
1917     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1918       sprintf(
1919         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1920         $op,
1921         $rsrc->source_name,
1922       )
1923     );
1924
1925     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1926     delete $attrs->{$_} for qw/select as collapse/;
1927     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1928
1929     # this will be consumed by the pruner waaaaay down the stack
1930     $attrs->{_force_prune_multiplying_joins} = 1;
1931
1932     my $subrs = (ref $self)->new($rsrc, $attrs);
1933
1934     if (@$idcols == 1) {
1935       $cond = { $idcols->[0] => { -in => \$subrs->_as_select_dq } };
1936     }
1937     elsif ($storage->_use_multicolumn_in) {
1938       # no syntax for calling this properly yet
1939       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1940       my $left = $storage->sql_maker->_render_sqla(select_select => $idcols);
1941       $left =~ s/^SELECT //i;
1942       my $right = $storage->sql_maker
1943                           ->converter
1944                           ->_literal_to_dq(${$subrs->as_query});
1945       $cond = \Operator(
1946         { 'SQL.Naive' => 'in' },
1947         [ Literal(SQL => "( $left )"), $right ],
1948       ),
1949     }
1950     else {
1951       # if all else fails - get all primary keys and operate over a ORed set
1952       # wrap in a transaction for consistency
1953       # this is where the group_by/multiplication starts to matter
1954       if (
1955         $existing_group_by
1956           or
1957         # we do not need to check pre-multipliers, since if the premulti is there, its
1958         # parent (who is multi) will be there too
1959         keys %{ $join_classifications->{multiplying} || {} }
1960       ) {
1961         # make sure if there is a supplied group_by it matches the columns compiled above
1962         # perfectly. Anything else can not be sanely executed on most databases so croak
1963         # right then and there
1964         if ($existing_group_by) {
1965           my @current_group_by = map
1966             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1967             @$existing_group_by
1968           ;
1969
1970           if (
1971             join ("\x00", sort @current_group_by)
1972               ne
1973             join ("\x00", sort @{$attrs->{columns}} )
1974           ) {
1975             $self->throw_exception (
1976               "You have just attempted a $op operation on a resultset which does group_by"
1977               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1978               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1979               . ' kind of queries. Please retry the operation with a modified group_by or'
1980               . ' without using one at all.'
1981             );
1982           }
1983         }
1984
1985         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1986       }
1987
1988       $guard = $storage->txn_scope_guard;
1989
1990       $cond = [];
1991       for my $row ($subrs->cursor->all) {
1992         push @$cond, { map
1993           { $idcols->[$_] => $row->[$_] }
1994           (0 .. $#$idcols)
1995         };
1996       }
1997     }
1998   }
1999
2000   my $res = $storage->$op (
2001     $rsrc,
2002     $op eq 'update' ? $values : (),
2003     $cond,
2004   );
2005
2006   $guard->commit if $guard;
2007
2008   return $res;
2009 }
2010
2011 =head2 update
2012
2013 =over 4
2014
2015 =item Arguments: \%values
2016
2017 =item Return Value: $underlying_storage_rv
2018
2019 =back
2020
2021 Sets the specified columns in the resultset to the supplied values in a
2022 single query. Note that this will not run any accessor/set_column/update
2023 triggers, nor will it update any result object instances derived from this
2024 resultset (this includes the contents of the L<resultset cache|/set_cache>
2025 if any). See L</update_all> if you need to execute any on-update
2026 triggers or cascades defined either by you or a
2027 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2028
2029 The return value is a pass through of what the underlying
2030 storage backend returned, and may vary. See L<DBI/execute> for the most
2031 common case.
2032
2033 =head3 CAVEAT
2034
2035 Note that L</update> does not process/deflate any of the values passed in.
2036 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2037 ensure manually that any value passed to this method will stringify to
2038 something the RDBMS knows how to deal with. A notable example is the
2039 handling of L<DateTime> objects, for more info see:
2040 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2041
2042 =cut
2043
2044 sub update {
2045   my ($self, $values) = @_;
2046   $self->throw_exception('Values for update must be a hash')
2047     unless ref $values eq 'HASH';
2048
2049   return $self->_rs_update_delete ('update', $values);
2050 }
2051
2052 =head2 update_all
2053
2054 =over 4
2055
2056 =item Arguments: \%values
2057
2058 =item Return Value: 1
2059
2060 =back
2061
2062 Fetches all objects and updates them one at a time via
2063 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2064 triggers, while L</update> will not.
2065
2066 =cut
2067
2068 sub update_all {
2069   my ($self, $values) = @_;
2070   $self->throw_exception('Values for update_all must be a hash')
2071     unless ref $values eq 'HASH';
2072
2073   my $guard = $self->result_source->schema->txn_scope_guard;
2074   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2075   $guard->commit;
2076   return 1;
2077 }
2078
2079 =head2 delete
2080
2081 =over 4
2082
2083 =item Arguments: none
2084
2085 =item Return Value: $underlying_storage_rv
2086
2087 =back
2088
2089 Deletes the rows matching this resultset in a single query. Note that this
2090 will not run any delete triggers, nor will it alter the
2091 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2092 derived from this resultset (this includes the contents of the
2093 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2094 execute any on-delete triggers or cascades defined either by you or a
2095 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2096
2097 The return value is a pass through of what the underlying storage backend
2098 returned, and may vary. See L<DBI/execute> for the most common case.
2099
2100 =cut
2101
2102 sub delete {
2103   my $self = shift;
2104   $self->throw_exception('delete does not accept any arguments')
2105     if @_;
2106
2107   return $self->_rs_update_delete ('delete');
2108 }
2109
2110 =head2 delete_all
2111
2112 =over 4
2113
2114 =item Arguments: none
2115
2116 =item Return Value: 1
2117
2118 =back
2119
2120 Fetches all objects and deletes them one at a time via
2121 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2122 triggers, while L</delete> will not.
2123
2124 =cut
2125
2126 sub delete_all {
2127   my $self = shift;
2128   $self->throw_exception('delete_all does not accept any arguments')
2129     if @_;
2130
2131   my $guard = $self->result_source->schema->txn_scope_guard;
2132   $_->delete for $self->all;
2133   $guard->commit;
2134   return 1;
2135 }
2136
2137 =head2 populate
2138
2139 =over 4
2140
2141 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2142
2143 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2144
2145 =back
2146
2147 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2148 arrayrefs.
2149
2150 =over
2151
2152 =item NOTE
2153
2154 The context of this method call has an important effect on what is
2155 submitted to storage. In void context data is fed directly to fastpath
2156 insertion routines provided by the underlying storage (most often
2157 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2158 L<insert|DBIx::Class::Row/insert> calls on the
2159 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2160 augmentation of these methods provided by components. For example if you
2161 are using something like L<DBIx::Class::UUIDColumns> to create primary
2162 keys for you, you will find that your PKs are empty.  In this case you
2163 will have to explicitly force scalar or list context in order to create
2164 those values.
2165
2166 =back
2167
2168 In non-void (scalar or list) context, this method is simply a wrapper
2169 for L</create>. Depending on list or scalar context either a list of
2170 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2171 containing these objects is returned.
2172
2173 When supplying data in "arrayref of arrayrefs" invocation style, the
2174 first element should be a list of column names and each subsequent
2175 element should be a data value in the earlier specified column order.
2176 For example:
2177
2178   $schema->resultset("Artist")->populate([
2179     [ qw( artistid name ) ],
2180     [ 100, 'A Formally Unknown Singer' ],
2181     [ 101, 'A singer that jumped the shark two albums ago' ],
2182     [ 102, 'An actually cool singer' ],
2183   ]);
2184
2185 For the arrayref of hashrefs style each hashref should be a structure
2186 suitable for passing to L</create>. Multi-create is also permitted with
2187 this syntax.
2188
2189   $schema->resultset("Artist")->populate([
2190      { artistid => 4, name => 'Manufactured Crap', cds => [
2191         { title => 'My First CD', year => 2006 },
2192         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2193       ],
2194      },
2195      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2196         { title => 'My parents sold me to a record company', year => 2005 },
2197         { title => 'Why Am I So Ugly?', year => 2006 },
2198         { title => 'I Got Surgery and am now Popular', year => 2007 }
2199       ],
2200      },
2201   ]);
2202
2203 If you attempt a void-context multi-create as in the example above (each
2204 Artist also has the related list of CDs), and B<do not> supply the
2205 necessary autoinc foreign key information, this method will proxy to the
2206 less efficient L</create>, and then throw the Result objects away. In this
2207 case there are obviously no benefits to using this method over L</create>.
2208
2209 =cut
2210
2211 sub populate {
2212   my $self = shift;
2213
2214   # cruft placed in standalone method
2215   my $data = $self->_normalize_populate_args(@_);
2216
2217   return unless @$data;
2218
2219   if(defined wantarray) {
2220     my @created = map { $self->create($_) } @$data;
2221     return wantarray ? @created : \@created;
2222   }
2223   else {
2224     my $first = $data->[0];
2225
2226     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2227     # it relationship data
2228     my (@rels, @columns);
2229     my $rsrc = $self->result_source;
2230     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2231     for (keys %$first) {
2232       my $ref = ref $first->{$_};
2233       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2234         ? push @rels, $_
2235         : push @columns, $_
2236       ;
2237     }
2238
2239     my @pks = $rsrc->primary_columns;
2240
2241     ## do the belongs_to relationships
2242     foreach my $index (0..$#$data) {
2243
2244       # delegate to create() for any dataset without primary keys with specified relationships
2245       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2246         for my $r (@rels) {
2247           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2248             my @ret = $self->populate($data);
2249             return;
2250           }
2251         }
2252       }
2253
2254       foreach my $rel (@rels) {
2255         next unless ref $data->[$index]->{$rel} eq "HASH";
2256         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2257         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2258         my $related = $result->result_source->_resolve_condition(
2259           $reverse_relinfo->{cond},
2260           $self,
2261           $result,
2262           $rel,
2263         );
2264
2265         delete $data->[$index]->{$rel};
2266         $data->[$index] = {%{$data->[$index]}, %$related};
2267
2268         push @columns, keys %$related if $index == 0;
2269       }
2270     }
2271
2272     ## inherit the data locked in the conditions of the resultset
2273     my ($rs_data) = $self->_merge_with_rscond({});
2274     delete @{$rs_data}{@columns};
2275
2276     ## do bulk insert on current row
2277     $rsrc->storage->insert_bulk(
2278       $rsrc,
2279       [@columns, keys %$rs_data],
2280       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2281     );
2282
2283     ## do the has_many relationships
2284     foreach my $item (@$data) {
2285
2286       my $main_row;
2287
2288       foreach my $rel (@rels) {
2289         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2290
2291         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2292
2293         my $child = $main_row->$rel;
2294
2295         my $related = $child->result_source->_resolve_condition(
2296           $rels->{$rel}{cond},
2297           $child,
2298           $main_row,
2299           $rel,
2300         );
2301
2302         if (ref($related) eq 'REF' and ref($$related) eq 'HASH') {
2303           $related = $self->result_source
2304                           ->_extract_fixed_values_for($$related, $rel);
2305         }
2306
2307         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2308         my @populate = map { {%$_, %$related} } @rows_to_add;
2309
2310         $child->populate( \@populate );
2311       }
2312     }
2313   }
2314 }
2315
2316 # populate() arguments went over several incarnations
2317 # What we ultimately support is AoH
2318 sub _normalize_populate_args {
2319   my ($self, $arg) = @_;
2320
2321   if (ref $arg eq 'ARRAY') {
2322     if (!@$arg) {
2323       return [];
2324     }
2325     elsif (ref $arg->[0] eq 'HASH') {
2326       return $arg;
2327     }
2328     elsif (ref $arg->[0] eq 'ARRAY') {
2329       my @ret;
2330       my @colnames = @{$arg->[0]};
2331       foreach my $values (@{$arg}[1 .. $#$arg]) {
2332         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2333       }
2334       return \@ret;
2335     }
2336   }
2337
2338   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2339 }
2340
2341 =head2 pager
2342
2343 =over 4
2344
2345 =item Arguments: none
2346
2347 =item Return Value: L<$pager|Data::Page>
2348
2349 =back
2350
2351 Returns a L<Data::Page> object for the current resultset. Only makes
2352 sense for queries with a C<page> attribute.
2353
2354 To get the full count of entries for a paged resultset, call
2355 C<total_entries> on the L<Data::Page> object.
2356
2357 =cut
2358
2359 sub pager {
2360   my ($self) = @_;
2361
2362   return $self->{pager} if $self->{pager};
2363
2364   my $attrs = $self->{attrs};
2365   if (!defined $attrs->{page}) {
2366     $self->throw_exception("Can't create pager for non-paged rs");
2367   }
2368   elsif ($attrs->{page} <= 0) {
2369     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2370   }
2371   $attrs->{rows} ||= 10;
2372
2373   # throw away the paging flags and re-run the count (possibly
2374   # with a subselect) to get the real total count
2375   my $count_attrs = { %$attrs };
2376   delete @{$count_attrs}{qw/rows offset page pager/};
2377
2378   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2379
2380   require DBIx::Class::ResultSet::Pager;
2381   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2382     sub { $total_rs->count },  #lazy-get the total
2383     $attrs->{rows},
2384     $self->{attrs}{page},
2385   );
2386 }
2387
2388 =head2 page
2389
2390 =over 4
2391
2392 =item Arguments: $page_number
2393
2394 =item Return Value: L<$resultset|/search>
2395
2396 =back
2397
2398 Returns a resultset for the $page_number page of the resultset on which page
2399 is called, where each page contains a number of rows equal to the 'rows'
2400 attribute set on the resultset (10 by default).
2401
2402 =cut
2403
2404 sub page {
2405   my ($self, $page) = @_;
2406   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2407 }
2408
2409 =head2 new_result
2410
2411 =over 4
2412
2413 =item Arguments: \%col_data
2414
2415 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2416
2417 =back
2418
2419 Creates a new result object in the resultset's result class and returns
2420 it. The row is not inserted into the database at this point, call
2421 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2422 will tell you whether the result object has been inserted or not.
2423
2424 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2425
2426 =cut
2427
2428 sub new_result {
2429   my ($self, $values) = @_;
2430
2431   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2432     if @_ > 2;
2433
2434   $self->throw_exception( "new_result expects a hashref" )
2435     unless (ref $values eq 'HASH');
2436
2437   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2438
2439   my $new = $self->result_class->new({
2440     %$merged_cond,
2441     ( @$cols_from_relations
2442       ? (-cols_from_relations => $cols_from_relations)
2443       : ()
2444     ),
2445     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2446   });
2447
2448   if (
2449     reftype($new) eq 'HASH'
2450       and
2451     ! keys %$new
2452       and
2453     blessed($new)
2454   ) {
2455     carp_unique (sprintf (
2456       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2457       $self->result_class,
2458     ));
2459   }
2460
2461   $new;
2462 }
2463
2464 # _merge_with_rscond
2465 #
2466 # Takes a simple hash of K/V data and returns its copy merged with the
2467 # condition already present on the resultset. Additionally returns an
2468 # arrayref of value/condition names, which were inferred from related
2469 # objects (this is needed for in-memory related objects)
2470 sub _merge_with_rscond {
2471   my ($self, $data) = @_;
2472
2473   my (%new_data, @cols_from_relations);
2474
2475   my $alias = $self->{attrs}{alias};
2476
2477   if (! defined $self->{cond}) {
2478     # just massage $data below
2479   }
2480   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2481     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2482     @cols_from_relations = keys %new_data;
2483   }
2484   elsif (ref $self->{cond} eq 'HASH') {
2485     # precedence must be given to passed values over values inherited from
2486     # the cond, so the order here is important.
2487     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2488     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2489
2490     while ( my($col, $value) = each %implied ) {
2491       my $vref = ref $value;
2492       if (
2493         $vref eq 'HASH'
2494           and
2495         keys(%$value) == 1
2496           and
2497         (keys %$value)[0] eq '='
2498       ) {
2499         $new_data{$col} = $value->{'='};
2500       }
2501       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2502         $new_data{$col} = $value;
2503       }
2504     }
2505   }
2506   elsif (ref $self->{cond} eq 'REF' and ref ${$self->{cond}} eq 'HASH') {
2507     %new_data = %{$self->result_source
2508                        ->_extract_fixed_values_for(${$self->{cond}}, $alias)};
2509   }
2510   else {
2511     $self->throw_exception(
2512       "Can't abstract implicit construct, resultset condition not a hash"
2513     );
2514   }
2515
2516   %new_data = (
2517     %new_data,
2518     %{ $self->_remove_alias($data, $alias) },
2519   );
2520
2521   return (\%new_data, \@cols_from_relations);
2522 }
2523
2524 # _has_resolved_attr
2525 #
2526 # determines if the resultset defines at least one
2527 # of the attributes supplied
2528 #
2529 # used to determine if a subquery is necessary
2530 #
2531 # supports some virtual attributes:
2532 #   -join
2533 #     This will scan for any joins being present on the resultset.
2534 #     It is not a mere key-search but a deep inspection of {from}
2535 #
2536
2537 sub _has_resolved_attr {
2538   my ($self, @attr_names) = @_;
2539
2540   my $attrs = $self->_resolved_attrs;
2541
2542   my %extra_checks;
2543
2544   for my $n (@attr_names) {
2545     if (grep { $n eq $_ } (qw/-join/) ) {
2546       $extra_checks{$n}++;
2547       next;
2548     }
2549
2550     my $attr =  $attrs->{$n};
2551
2552     next if not defined $attr;
2553
2554     if (ref $attr eq 'HASH') {
2555       return 1 if keys %$attr;
2556     }
2557     elsif (ref $attr eq 'ARRAY') {
2558       return 1 if @$attr;
2559     }
2560     else {
2561       return 1 if $attr;
2562     }
2563   }
2564
2565   # a resolved join is expressed as a multi-level from
2566   return 1 if (
2567     $extra_checks{-join}
2568       and
2569     ref $attrs->{from} eq 'ARRAY'
2570       and
2571     @{$attrs->{from}} > 1
2572   );
2573
2574   return 0;
2575 }
2576
2577 # _collapse_cond
2578 #
2579 # Recursively collapse the condition.
2580
2581 sub _collapse_cond {
2582   my ($self, $cond, $collapsed) = @_;
2583
2584   $collapsed ||= {};
2585
2586   if (ref $cond eq 'ARRAY') {
2587     foreach my $subcond (@$cond) {
2588       next unless ref $subcond;  # -or
2589       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2590     }
2591   }
2592   elsif (ref $cond eq 'HASH') {
2593     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2594       foreach my $subcond (@{$cond->{-and}}) {
2595         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2596       }
2597     }
2598     else {
2599       foreach my $col (keys %$cond) {
2600         my $value = $cond->{$col};
2601         $collapsed->{$col} = $value;
2602       }
2603     }
2604   }
2605
2606   return $collapsed;
2607 }
2608
2609 # _remove_alias
2610 #
2611 # Remove the specified alias from the specified query hash. A copy is made so
2612 # the original query is not modified.
2613
2614 sub _remove_alias {
2615   my ($self, $query, $alias) = @_;
2616
2617   my %orig = %{ $query || {} };
2618   my %unaliased;
2619
2620   foreach my $key (keys %orig) {
2621     if ($key !~ /\./) {
2622       $unaliased{$key} = $orig{$key};
2623       next;
2624     }
2625     $unaliased{$1} = $orig{$key}
2626       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2627   }
2628
2629   return \%unaliased;
2630 }
2631
2632 =head2 as_query
2633
2634 =over 4
2635
2636 =item Arguments: none
2637
2638 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2639
2640 =back
2641
2642 Returns the SQL query and bind vars associated with the invocant.
2643
2644 This is generally used as the RHS for a subquery.
2645
2646 =cut
2647
2648 sub as_query {
2649   my $self = shift;
2650
2651   my $attrs = { %{ $self->_resolved_attrs } };
2652
2653   my $aq = $self->result_source->storage->_select_args_to_query (
2654     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2655   );
2656
2657   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
2658
2659   $aq;
2660 }
2661
2662 sub _as_select_dq {
2663   my $self = shift;
2664   my $attrs = { %{ $self->_resolved_attrs } };
2665   my $storage = $self->result_source->storage;
2666   my (undef, $ident, @args) = $storage->_select_args(
2667     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2668   );
2669   $ident = $ident->from if blessed($ident);
2670   $storage->sql_maker->converter->_select_to_dq(
2671     $ident, @args
2672   );
2673 }
2674
2675 =head2 find_or_new
2676
2677 =over 4
2678
2679 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2680
2681 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2682
2683 =back
2684
2685   my $artist = $schema->resultset('Artist')->find_or_new(
2686     { artist => 'fred' }, { key => 'artists' });
2687
2688   $cd->cd_to_producer->find_or_new({ producer => $producer },
2689                                    { key => 'primary' });
2690
2691 Find an existing record from this resultset using L</find>. if none exists,
2692 instantiate a new result object and return it. The object will not be saved
2693 into your storage until you call L<DBIx::Class::Row/insert> on it.
2694
2695 You most likely want this method when looking for existing rows using a unique
2696 constraint that is not the primary key, or looking for related rows.
2697
2698 If you want objects to be saved immediately, use L</find_or_create> instead.
2699
2700 B<Note>: Make sure to read the documentation of L</find> and understand the
2701 significance of the C<key> attribute, as its lack may skew your search, and
2702 subsequently result in spurious new objects.
2703
2704 B<Note>: Take care when using C<find_or_new> with a table having
2705 columns with default values that you intend to be automatically
2706 supplied by the database (e.g. an auto_increment primary key column).
2707 In normal usage, the value of such columns should NOT be included at
2708 all in the call to C<find_or_new>, even when set to C<undef>.
2709
2710 =cut
2711
2712 sub find_or_new {
2713   my $self     = shift;
2714   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2715   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2716   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2717     return $row;
2718   }
2719   return $self->new_result($hash);
2720 }
2721
2722 =head2 create
2723
2724 =over 4
2725
2726 =item Arguments: \%col_data
2727
2728 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2729
2730 =back
2731
2732 Attempt to create a single new row or a row with multiple related rows
2733 in the table represented by the resultset (and related tables). This
2734 will not check for duplicate rows before inserting, use
2735 L</find_or_create> to do that.
2736
2737 To create one row for this resultset, pass a hashref of key/value
2738 pairs representing the columns of the table and the values you wish to
2739 store. If the appropriate relationships are set up, foreign key fields
2740 can also be passed an object representing the foreign row, and the
2741 value will be set to its primary key.
2742
2743 To create related objects, pass a hashref of related-object column values
2744 B<keyed on the relationship name>. If the relationship is of type C<multi>
2745 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2746 The process will correctly identify columns holding foreign keys, and will
2747 transparently populate them from the keys of the corresponding relation.
2748 This can be applied recursively, and will work correctly for a structure
2749 with an arbitrary depth and width, as long as the relationships actually
2750 exists and the correct column data has been supplied.
2751
2752 Instead of hashrefs of plain related data (key/value pairs), you may
2753 also pass new or inserted objects. New objects (not inserted yet, see
2754 L</new_result>), will be inserted into their appropriate tables.
2755
2756 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2757
2758 Example of creating a new row.
2759
2760   $person_rs->create({
2761     name=>"Some Person",
2762     email=>"somebody@someplace.com"
2763   });
2764
2765 Example of creating a new row and also creating rows in a related C<has_many>
2766 or C<has_one> resultset.  Note Arrayref.
2767
2768   $artist_rs->create(
2769      { artistid => 4, name => 'Manufactured Crap', cds => [
2770         { title => 'My First CD', year => 2006 },
2771         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2772       ],
2773      },
2774   );
2775
2776 Example of creating a new row and also creating a row in a related
2777 C<belongs_to> resultset. Note Hashref.
2778
2779   $cd_rs->create({
2780     title=>"Music for Silly Walks",
2781     year=>2000,
2782     artist => {
2783       name=>"Silly Musician",
2784     }
2785   });
2786
2787 =over
2788
2789 =item WARNING
2790
2791 When subclassing ResultSet never attempt to override this method. Since
2792 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2793 lot of the internals simply never call it, so your override will be
2794 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2795 or L<DBIx::Class::Row/insert> depending on how early in the
2796 L</create> process you need to intervene. See also warning pertaining to
2797 L</new>.
2798
2799 =back
2800
2801 =cut
2802
2803 sub create {
2804   my ($self, $col_data) = @_;
2805   $self->throw_exception( "create needs a hashref" )
2806     unless ref $col_data eq 'HASH';
2807   return $self->new_result($col_data)->insert;
2808 }
2809
2810 =head2 find_or_create
2811
2812 =over 4
2813
2814 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2815
2816 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2817
2818 =back
2819
2820   $cd->cd_to_producer->find_or_create({ producer => $producer },
2821                                       { key => 'primary' });
2822
2823 Tries to find a record based on its primary key or unique constraints; if none
2824 is found, creates one and returns that instead.
2825
2826   my $cd = $schema->resultset('CD')->find_or_create({
2827     cdid   => 5,
2828     artist => 'Massive Attack',
2829     title  => 'Mezzanine',
2830     year   => 2005,
2831   });
2832
2833 Also takes an optional C<key> attribute, to search by a specific key or unique
2834 constraint. For example:
2835
2836   my $cd = $schema->resultset('CD')->find_or_create(
2837     {
2838       artist => 'Massive Attack',
2839       title  => 'Mezzanine',
2840     },
2841     { key => 'cd_artist_title' }
2842   );
2843
2844 B<Note>: Make sure to read the documentation of L</find> and understand the
2845 significance of the C<key> attribute, as its lack may skew your search, and
2846 subsequently result in spurious row creation.
2847
2848 B<Note>: Because find_or_create() reads from the database and then
2849 possibly inserts based on the result, this method is subject to a race
2850 condition. Another process could create a record in the table after
2851 the find has completed and before the create has started. To avoid
2852 this problem, use find_or_create() inside a transaction.
2853
2854 B<Note>: Take care when using C<find_or_create> with a table having
2855 columns with default values that you intend to be automatically
2856 supplied by the database (e.g. an auto_increment primary key column).
2857 In normal usage, the value of such columns should NOT be included at
2858 all in the call to C<find_or_create>, even when set to C<undef>.
2859
2860 See also L</find> and L</update_or_create>. For information on how to declare
2861 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2862
2863 If you need to know if an existing row was found or a new one created use
2864 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2865 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2866 database!
2867
2868   my $cd = $schema->resultset('CD')->find_or_new({
2869     cdid   => 5,
2870     artist => 'Massive Attack',
2871     title  => 'Mezzanine',
2872     year   => 2005,
2873   });
2874
2875   if( !$cd->in_storage ) {
2876       # do some stuff
2877       $cd->insert;
2878   }
2879
2880 =cut
2881
2882 sub find_or_create {
2883   my $self     = shift;
2884   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2885   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2886   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2887     return $row;
2888   }
2889   return $self->create($hash);
2890 }
2891
2892 =head2 update_or_create
2893
2894 =over 4
2895
2896 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2897
2898 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2899
2900 =back
2901
2902   $resultset->update_or_create({ col => $val, ... });
2903
2904 Like L</find_or_create>, but if a row is found it is immediately updated via
2905 C<< $found_row->update (\%col_data) >>.
2906
2907
2908 Takes an optional C<key> attribute to search on a specific unique constraint.
2909 For example:
2910
2911   # In your application
2912   my $cd = $schema->resultset('CD')->update_or_create(
2913     {
2914       artist => 'Massive Attack',
2915       title  => 'Mezzanine',
2916       year   => 1998,
2917     },
2918     { key => 'cd_artist_title' }
2919   );
2920
2921   $cd->cd_to_producer->update_or_create({
2922     producer => $producer,
2923     name => 'harry',
2924   }, {
2925     key => 'primary',
2926   });
2927
2928 B<Note>: Make sure to read the documentation of L</find> and understand the
2929 significance of the C<key> attribute, as its lack may skew your search, and
2930 subsequently result in spurious row creation.
2931
2932 B<Note>: Take care when using C<update_or_create> with a table having
2933 columns with default values that you intend to be automatically
2934 supplied by the database (e.g. an auto_increment primary key column).
2935 In normal usage, the value of such columns should NOT be included at
2936 all in the call to C<update_or_create>, even when set to C<undef>.
2937
2938 See also L</find> and L</find_or_create>. For information on how to declare
2939 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2940
2941 If you need to know if an existing row was updated or a new one created use
2942 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2943 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2944 database!
2945
2946 =cut
2947
2948 sub update_or_create {
2949   my $self = shift;
2950   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2951   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2952
2953   my $row = $self->find($cond, $attrs);
2954   if (defined $row) {
2955     $row->update($cond);
2956     return $row;
2957   }
2958
2959   return $self->create($cond);
2960 }
2961
2962 =head2 update_or_new
2963
2964 =over 4
2965
2966 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2967
2968 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2969
2970 =back
2971
2972   $resultset->update_or_new({ col => $val, ... });
2973
2974 Like L</find_or_new> but if a row is found it is immediately updated via
2975 C<< $found_row->update (\%col_data) >>.
2976
2977 For example:
2978
2979   # In your application
2980   my $cd = $schema->resultset('CD')->update_or_new(
2981     {
2982       artist => 'Massive Attack',
2983       title  => 'Mezzanine',
2984       year   => 1998,
2985     },
2986     { key => 'cd_artist_title' }
2987   );
2988
2989   if ($cd->in_storage) {
2990       # the cd was updated
2991   }
2992   else {
2993       # the cd is not yet in the database, let's insert it
2994       $cd->insert;
2995   }
2996
2997 B<Note>: Make sure to read the documentation of L</find> and understand the
2998 significance of the C<key> attribute, as its lack may skew your search, and
2999 subsequently result in spurious new objects.
3000
3001 B<Note>: Take care when using C<update_or_new> with a table having
3002 columns with default values that you intend to be automatically
3003 supplied by the database (e.g. an auto_increment primary key column).
3004 In normal usage, the value of such columns should NOT be included at
3005 all in the call to C<update_or_new>, even when set to C<undef>.
3006
3007 See also L</find>, L</find_or_create> and L</find_or_new>.
3008
3009 =cut
3010
3011 sub update_or_new {
3012     my $self  = shift;
3013     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3014     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3015
3016     my $row = $self->find( $cond, $attrs );
3017     if ( defined $row ) {
3018         $row->update($cond);
3019         return $row;
3020     }
3021
3022     return $self->new_result($cond);
3023 }
3024
3025 =head2 get_cache
3026
3027 =over 4
3028
3029 =item Arguments: none
3030
3031 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3032
3033 =back
3034
3035 Gets the contents of the cache for the resultset, if the cache is set.
3036
3037 The cache is populated either by using the L</prefetch> attribute to
3038 L</search> or by calling L</set_cache>.
3039
3040 =cut
3041
3042 sub get_cache {
3043   shift->{all_cache};
3044 }
3045
3046 =head2 set_cache
3047
3048 =over 4
3049
3050 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3051
3052 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3053
3054 =back
3055
3056 Sets the contents of the cache for the resultset. Expects an arrayref
3057 of objects of the same class as those produced by the resultset. Note that
3058 if the cache is set, the resultset will return the cached objects rather
3059 than re-querying the database even if the cache attr is not set.
3060
3061 The contents of the cache can also be populated by using the
3062 L</prefetch> attribute to L</search>.
3063
3064 =cut
3065
3066 sub set_cache {
3067   my ( $self, $data ) = @_;
3068   $self->throw_exception("set_cache requires an arrayref")
3069       if defined($data) && (ref $data ne 'ARRAY');
3070   $self->{all_cache} = $data;
3071 }
3072
3073 =head2 clear_cache
3074
3075 =over 4
3076
3077 =item Arguments: none
3078
3079 =item Return Value: undef
3080
3081 =back
3082
3083 Clears the cache for the resultset.
3084
3085 =cut
3086
3087 sub clear_cache {
3088   shift->set_cache(undef);
3089 }
3090
3091 =head2 is_paged
3092
3093 =over 4
3094
3095 =item Arguments: none
3096
3097 =item Return Value: true, if the resultset has been paginated
3098
3099 =back
3100
3101 =cut
3102
3103 sub is_paged {
3104   my ($self) = @_;
3105   return !!$self->{attrs}{page};
3106 }
3107
3108 =head2 is_ordered
3109
3110 =over 4
3111
3112 =item Arguments: none
3113
3114 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3115
3116 =back
3117
3118 =cut
3119
3120 sub is_ordered {
3121   my ($self) = @_;
3122   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3123 }
3124
3125 =head2 related_resultset
3126
3127 =over 4
3128
3129 =item Arguments: $rel_name
3130
3131 =item Return Value: L<$resultset|/search>
3132
3133 =back
3134
3135 Returns a related resultset for the supplied relationship name.
3136
3137   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3138
3139 =cut
3140
3141 sub related_resultset {
3142   my ($self, $rel) = @_;
3143
3144   return $self->{related_resultsets}{$rel}
3145     if defined $self->{related_resultsets}{$rel};
3146
3147   return $self->{related_resultsets}{$rel} = do {
3148     my $rsrc = $self->result_source;
3149     my $rel_info = $rsrc->relationship_info($rel);
3150
3151     $self->throw_exception(
3152       "search_related: result source '" . $rsrc->source_name .
3153         "' has no such relationship $rel")
3154       unless $rel_info;
3155
3156     my $attrs = $self->_chain_relationship($rel);
3157
3158     my $join_count = $attrs->{seen_join}{$rel};
3159
3160     my $alias = $self->result_source->storage
3161         ->relname_to_table_alias($rel, $join_count);
3162
3163     # since this is search_related, and we already slid the select window inwards
3164     # (the select/as attrs were deleted in the beginning), we need to flip all
3165     # left joins to inner, so we get the expected results
3166     # read the comment on top of the actual function to see what this does
3167     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3168
3169
3170     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3171     delete @{$attrs}{qw(result_class alias)};
3172
3173     my $rel_source = $rsrc->related_source($rel);
3174
3175     my $new = do {
3176
3177       # The reason we do this now instead of passing the alias to the
3178       # search_rs below is that if you wrap/overload resultset on the
3179       # source you need to know what alias it's -going- to have for things
3180       # to work sanely (e.g. RestrictWithObject wants to be able to add
3181       # extra query restrictions, and these may need to be $alias.)
3182
3183       my $rel_attrs = $rel_source->resultset_attributes;
3184       local $rel_attrs->{alias} = $alias;
3185
3186       $rel_source->resultset
3187                  ->search_rs(
3188                      undef, {
3189                        %$attrs,
3190                        where => $attrs->{where},
3191                    });
3192     };
3193
3194     if (my $cache = $self->get_cache) {
3195       my @related_cache = map
3196         { @{$_->related_resultset($rel)->get_cache||[]} }
3197         @$cache
3198       ;
3199
3200       $new->set_cache(\@related_cache) if @related_cache;
3201     }
3202
3203     $new;
3204   };
3205 }
3206
3207 =head2 current_source_alias
3208
3209 =over 4
3210
3211 =item Arguments: none
3212
3213 =item Return Value: $source_alias
3214
3215 =back
3216
3217 Returns the current table alias for the result source this resultset is built
3218 on, that will be used in the SQL query. Usually it is C<me>.
3219
3220 Currently the source alias that refers to the result set returned by a
3221 L</search>/L</find> family method depends on how you got to the resultset: it's
3222 C<me> by default, but eg. L</search_related> aliases it to the related result
3223 source name (and keeps C<me> referring to the original result set). The long
3224 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3225 (and make this method unnecessary).
3226
3227 Thus it's currently necessary to use this method in predefined queries (see
3228 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3229 source alias of the current result set:
3230
3231   # in a result set class
3232   sub modified_by {
3233     my ($self, $user) = @_;
3234
3235     my $me = $self->current_source_alias;
3236
3237     return $self->search({
3238       "$me.modified" => $user->id,
3239     });
3240   }
3241
3242 =cut
3243
3244 sub current_source_alias {
3245   return (shift->{attrs} || {})->{alias} || 'me';
3246 }
3247
3248 =head2 as_subselect_rs
3249
3250 =over 4
3251
3252 =item Arguments: none
3253
3254 =item Return Value: L<$resultset|/search>
3255
3256 =back
3257
3258 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3259 "virtual view" by including it as a subquery within the from clause.  From this
3260 point on, any joined tables are inaccessible to ->search on the resultset (as if
3261 it were simply where-filtered without joins).  For example:
3262
3263  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3264
3265  # 'x' now pollutes the query namespace
3266
3267  # So the following works as expected
3268  my $ok_rs = $rs->search({'x.other' => 1});
3269
3270  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3271  # def) we look for one row with contradictory terms and join in another table
3272  # (aliased 'x_2') which we never use
3273  my $broken_rs = $rs->search({'x.name' => 'def'});
3274
3275  my $rs2 = $rs->as_subselect_rs;
3276
3277  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3278  my $not_joined_rs = $rs2->search({'x.other' => 1});
3279
3280  # works as expected: finds a 'table' row related to two x rows (abc and def)
3281  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3282
3283 Another example of when one might use this would be to select a subset of
3284 columns in a group by clause:
3285
3286  my $rs = $schema->resultset('Bar')->search(undef, {
3287    group_by => [qw{ id foo_id baz_id }],
3288  })->as_subselect_rs->search(undef, {
3289    columns => [qw{ id foo_id }]
3290  });
3291
3292 In the above example normally columns would have to be equal to the group by,
3293 but because we isolated the group by into a subselect the above works.
3294
3295 =cut
3296
3297 sub as_subselect_rs {
3298   my $self = shift;
3299
3300   my $attrs = $self->_resolved_attrs;
3301
3302   my $fresh_rs = (ref $self)->new (
3303     $self->result_source
3304   );
3305
3306   # these pieces will be locked in the subquery
3307   delete $fresh_rs->{cond};
3308   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3309
3310   return $fresh_rs->search( {}, {
3311     from => [{
3312       $attrs->{alias} => $self->as_query,
3313       -alias  => $attrs->{alias},
3314       -rsrc   => $self->result_source,
3315     }],
3316     alias => $attrs->{alias},
3317   });
3318 }
3319
3320 # This code is called by search_related, and makes sure there
3321 # is clear separation between the joins before, during, and
3322 # after the relationship. This information is needed later
3323 # in order to properly resolve prefetch aliases (any alias
3324 # with a relation_chain_depth less than the depth of the
3325 # current prefetch is not considered)
3326 #
3327 # The increments happen twice per join. An even number means a
3328 # relationship specified via a search_related, whereas an odd
3329 # number indicates a join/prefetch added via attributes
3330 #
3331 # Also this code will wrap the current resultset (the one we
3332 # chain to) in a subselect IFF it contains limiting attributes
3333 sub _chain_relationship {
3334   my ($self, $rel) = @_;
3335   my $source = $self->result_source;
3336   my $attrs = { %{$self->{attrs}||{}} };
3337
3338   # we need to take the prefetch the attrs into account before we
3339   # ->_resolve_join as otherwise they get lost - captainL
3340   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3341
3342   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3343
3344   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3345
3346   my $from;
3347   my @force_subq_attrs = qw/offset rows group_by having/;
3348
3349   if (
3350     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3351       ||
3352     $self->_has_resolved_attr (@force_subq_attrs)
3353   ) {
3354     # Nuke the prefetch (if any) before the new $rs attrs
3355     # are resolved (prefetch is useless - we are wrapping
3356     # a subquery anyway).
3357     my $rs_copy = $self->search;
3358     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3359       $rs_copy->{attrs}{join},
3360       delete $rs_copy->{attrs}{prefetch},
3361     );
3362
3363     $from = [{
3364       -rsrc   => $source,
3365       -alias  => $attrs->{alias},
3366       $attrs->{alias} => $rs_copy->as_query,
3367     }];
3368     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3369     $seen->{-relation_chain_depth} = 0;
3370   }
3371   elsif ($attrs->{from}) {  #shallow copy suffices
3372     $from = [ @{$attrs->{from}} ];
3373   }
3374   else {
3375     $from = [{
3376       -rsrc  => $source,
3377       -alias => $attrs->{alias},
3378       $attrs->{alias} => $source->from,
3379     }];
3380   }
3381
3382   my $jpath = ($seen->{-relation_chain_depth})
3383     ? $from->[-1][0]{-join_path}
3384     : [];
3385
3386   my @requested_joins = $source->_resolve_join(
3387     $join,
3388     $attrs->{alias},
3389     $seen,
3390     $jpath,
3391   );
3392
3393   push @$from, @requested_joins;
3394
3395   $seen->{-relation_chain_depth}++;
3396
3397   # if $self already had a join/prefetch specified on it, the requested
3398   # $rel might very well be already included. What we do in this case
3399   # is effectively a no-op (except that we bump up the chain_depth on
3400   # the join in question so we could tell it *is* the search_related)
3401   my $already_joined;
3402
3403   # we consider the last one thus reverse
3404   for my $j (reverse @requested_joins) {
3405     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3406     if ($rel eq $last_j) {
3407       $j->[0]{-relation_chain_depth}++;
3408       $already_joined++;
3409       last;
3410     }
3411   }
3412
3413   unless ($already_joined) {
3414     push @$from, $source->_resolve_join(
3415       $rel,
3416       $attrs->{alias},
3417       $seen,
3418       $jpath,
3419     );
3420   }
3421
3422   $seen->{-relation_chain_depth}++;
3423
3424   return {%$attrs, from => $from, seen_join => $seen};
3425 }
3426
3427 sub _resolved_attrs {
3428   my $self = shift;
3429   return $self->{_attrs} if $self->{_attrs};
3430
3431   my $attrs  = { %{ $self->{attrs} || {} } };
3432   my $source = $self->result_source;
3433   my $alias  = $attrs->{alias};
3434
3435   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3436     if $attrs->{collapse} and $attrs->{distinct};
3437
3438   # default selection list
3439   $attrs->{columns} = [ $source->columns ]
3440     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3441
3442   # merge selectors together
3443   for (qw/columns select as/) {
3444     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3445       if $attrs->{$_} or $attrs->{"+$_"};
3446   }
3447
3448   # disassemble columns
3449   my (@sel, @as);
3450   if (my $cols = delete $attrs->{columns}) {
3451     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3452       if (ref $c eq 'HASH') {
3453         for my $as (sort keys %$c) {
3454           push @sel, $c->{$as};
3455           push @as, $as;
3456         }
3457       }
3458       else {
3459         push @sel, $c;
3460         push @as, $c;
3461       }
3462     }
3463   }
3464
3465   # when trying to weed off duplicates later do not go past this point -
3466   # everything added from here on is unbalanced "anyone's guess" stuff
3467   my $dedup_stop_idx = $#as;
3468
3469   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3470     if $attrs->{as};
3471   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3472     if $attrs->{select};
3473
3474   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3475   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3476
3477   # disqualify all $alias.col as-bits (inflate-map mandated)
3478   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3479
3480   # de-duplicate the result (remove *identical* select/as pairs)
3481   # and also die on duplicate {as} pointing to different {select}s
3482   # not using a c-style for as the condition is prone to shrinkage
3483   my $seen;
3484   my $i = 0;
3485   while ($i <= $dedup_stop_idx) {
3486     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3487       splice @sel, $i, 1;
3488       splice @as, $i, 1;
3489       $dedup_stop_idx--;
3490     }
3491     elsif ($seen->{$as[$i]}++) {
3492       $self->throw_exception(
3493         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3494       );
3495     }
3496     else {
3497       $i++;
3498     }
3499   }
3500
3501   $attrs->{select} = \@sel;
3502   $attrs->{as} = \@as;
3503
3504   $attrs->{from} ||= [{
3505     -rsrc   => $source,
3506     -alias  => $self->{attrs}{alias},
3507     $self->{attrs}{alias} => $source->from,
3508   }];
3509
3510   if ( $attrs->{join} || $attrs->{prefetch} ) {
3511
3512     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3513       if ref $attrs->{from} ne 'ARRAY';
3514
3515     my $join = (delete $attrs->{join}) || {};
3516
3517     if ( defined $attrs->{prefetch} ) {
3518       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3519     }
3520
3521     $attrs->{from} =    # have to copy here to avoid corrupting the original
3522       [
3523         @{ $attrs->{from} },
3524         $source->_resolve_join(
3525           $join,
3526           $alias,
3527           { %{ $attrs->{seen_join} || {} } },
3528           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3529             ? $attrs->{from}[-1][0]{-join_path}
3530             : []
3531           ,
3532         )
3533       ];
3534   }
3535
3536   if ( defined $attrs->{order_by} ) {
3537     $attrs->{order_by} = (
3538       ref( $attrs->{order_by} ) eq 'ARRAY'
3539       ? [ @{ $attrs->{order_by} } ]
3540       : [ $attrs->{order_by} || () ]
3541     );
3542   }
3543
3544   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3545     $attrs->{group_by} = [ $attrs->{group_by} ];
3546   }
3547
3548
3549   # generate selections based on the prefetch helper
3550   my ($prefetch, @prefetch_select, @prefetch_as);
3551   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3552     if defined $attrs->{prefetch};
3553
3554   if ($prefetch) {
3555
3556     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3557       if $attrs->{_dark_selector};
3558
3559     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3560       if defined $attrs->{collapse} and ! $attrs->{collapse};
3561
3562     $attrs->{collapse} = 1;
3563
3564     # this is a separate structure (we don't look in {from} directly)
3565     # as the resolver needs to shift things off the lists to work
3566     # properly (identical-prefetches on different branches)
3567     my $join_map = {};
3568     if (ref $attrs->{from} eq 'ARRAY') {
3569
3570       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3571
3572       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3573         next unless $j->[0]{-alias};
3574         next unless $j->[0]{-join_path};
3575         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3576
3577         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3578
3579         my $p = $join_map;
3580         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3581         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3582       }
3583     }
3584
3585     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3586
3587     # save these for after distinct resolution
3588     @prefetch_select = map { $_->[0] } @prefetch;
3589     @prefetch_as = map { $_->[1] } @prefetch;
3590   }
3591
3592   # run through the resulting joinstructure (starting from our current slot)
3593   # and unset collapse if proven unnecessary
3594   #
3595   # also while we are at it find out if the current root source has
3596   # been premultiplied by previous related_source chaining
3597   #
3598   # this allows to predict whether a root object with all other relation
3599   # data set to NULL is in fact unique
3600   if ($attrs->{collapse}) {
3601
3602     if (ref $attrs->{from} eq 'ARRAY') {
3603
3604       if (@{$attrs->{from}} == 1) {
3605         # no joins - no collapse
3606         $attrs->{collapse} = 0;
3607       }
3608       else {
3609         # find where our table-spec starts
3610         my @fromlist = @{$attrs->{from}};
3611         while (@fromlist) {
3612           my $t = shift @fromlist;
3613
3614           my $is_multi;
3615           # me vs join from-spec distinction - a ref means non-root
3616           if (ref $t eq 'ARRAY') {
3617             $t = $t->[0];
3618             $is_multi ||= ! $t->{-is_single};
3619           }
3620           last if ($t->{-alias} && $t->{-alias} eq $alias);
3621           $attrs->{_main_source_premultiplied} ||= $is_multi;
3622         }
3623
3624         # no non-singles remaining, nor any premultiplication - nothing to collapse
3625         if (
3626           ! $attrs->{_main_source_premultiplied}
3627             and
3628           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3629         ) {
3630           $attrs->{collapse} = 0;
3631         }
3632       }
3633     }
3634
3635     else {
3636       # if we can not analyze the from - err on the side of safety
3637       $attrs->{_main_source_premultiplied} = 1;
3638     }
3639   }
3640
3641   # generate the distinct induced group_by before injecting the prefetched select/as parts
3642   if (delete $attrs->{distinct}) {
3643     if ($attrs->{group_by}) {
3644       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3645     }
3646     else {
3647       $attrs->{_grouped_by_distinct} = 1;
3648       # distinct affects only the main selection part, not what prefetch may add below
3649       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3650
3651       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3652       # The thinking is: if we are collapsing the subquerying prefetch engine will
3653       # rip stuff apart for us anyway, and we do not want to have a potentially
3654       # function-converted external order_by
3655       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3656       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3657     }
3658   }
3659
3660   # inject prefetch-bound selection (if any)
3661   push @{$attrs->{select}}, @prefetch_select;
3662   push @{$attrs->{as}}, @prefetch_as;
3663
3664   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3665   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3666     $attrs->{_related_results_construction} = 1;
3667   }
3668
3669   # if both page and offset are specified, produce a combined offset
3670   # even though it doesn't make much sense, this is what pre 081xx has
3671   # been doing
3672   if (my $page = delete $attrs->{page}) {
3673     $attrs->{offset} =
3674       ($attrs->{rows} * ($page - 1))
3675             +
3676       ($attrs->{offset} || 0)
3677     ;
3678   }
3679
3680   return $self->{_attrs} = $attrs;
3681 }
3682
3683 sub _rollout_attr {
3684   my ($self, $attr) = @_;
3685
3686   if (ref $attr eq 'HASH') {
3687     return $self->_rollout_hash($attr);
3688   } elsif (ref $attr eq 'ARRAY') {
3689     return $self->_rollout_array($attr);
3690   } else {
3691     return [$attr];
3692   }
3693 }
3694
3695 sub _rollout_array {
3696   my ($self, $attr) = @_;
3697
3698   my @rolled_array;
3699   foreach my $element (@{$attr}) {
3700     if (ref $element eq 'HASH') {
3701       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3702     } elsif (ref $element eq 'ARRAY') {
3703       #  XXX - should probably recurse here
3704       push( @rolled_array, @{$self->_rollout_array($element)} );
3705     } else {
3706       push( @rolled_array, $element );
3707     }
3708   }
3709   return \@rolled_array;
3710 }
3711
3712 sub _rollout_hash {
3713   my ($self, $attr) = @_;
3714
3715   my @rolled_array;
3716   foreach my $key (keys %{$attr}) {
3717     push( @rolled_array, { $key => $attr->{$key} } );
3718   }
3719   return \@rolled_array;
3720 }
3721
3722 sub _calculate_score {
3723   my ($self, $a, $b) = @_;
3724
3725   if (defined $a xor defined $b) {
3726     return 0;
3727   }
3728   elsif (not defined $a) {
3729     return 1;
3730   }
3731
3732   if (ref $b eq 'HASH') {
3733     my ($b_key) = keys %{$b};
3734     if (ref $a eq 'HASH') {
3735       my ($a_key) = keys %{$a};
3736       if ($a_key eq $b_key) {
3737         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3738       } else {
3739         return 0;
3740       }
3741     } else {
3742       return ($a eq $b_key) ? 1 : 0;
3743     }
3744   } else {
3745     if (ref $a eq 'HASH') {
3746       my ($a_key) = keys %{$a};
3747       return ($b eq $a_key) ? 1 : 0;
3748     } else {
3749       return ($b eq $a) ? 1 : 0;
3750     }
3751   }
3752 }
3753
3754 sub _merge_joinpref_attr {
3755   my ($self, $orig, $import) = @_;
3756
3757   return $import unless defined($orig);
3758   return $orig unless defined($import);
3759
3760   $orig = $self->_rollout_attr($orig);
3761   $import = $self->_rollout_attr($import);
3762
3763   my $seen_keys;
3764   foreach my $import_element ( @{$import} ) {
3765     # find best candidate from $orig to merge $b_element into
3766     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3767     foreach my $orig_element ( @{$orig} ) {
3768       my $score = $self->_calculate_score( $orig_element, $import_element );
3769       if ($score > $best_candidate->{score}) {
3770         $best_candidate->{position} = $position;
3771         $best_candidate->{score} = $score;
3772       }
3773       $position++;
3774     }
3775     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3776     $import_key = '' if not defined $import_key;
3777
3778     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3779       push( @{$orig}, $import_element );
3780     } else {
3781       my $orig_best = $orig->[$best_candidate->{position}];
3782       # merge orig_best and b_element together and replace original with merged
3783       if (ref $orig_best ne 'HASH') {
3784         $orig->[$best_candidate->{position}] = $import_element;
3785       } elsif (ref $import_element eq 'HASH') {
3786         my ($key) = keys %{$orig_best};
3787         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3788       }
3789     }
3790     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3791   }
3792
3793   return @$orig ? $orig : ();
3794 }
3795
3796 {
3797   my $hm;
3798
3799   sub _merge_attr {
3800     $hm ||= do {
3801       require Hash::Merge;
3802       my $hm = Hash::Merge->new;
3803
3804       $hm->specify_behavior({
3805         SCALAR => {
3806           SCALAR => sub {
3807             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3808
3809             if ($defl xor $defr) {
3810               return [ $defl ? $_[0] : $_[1] ];
3811             }
3812             elsif (! $defl) {
3813               return [];
3814             }
3815             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3816               return [ $_[0] ];
3817             }
3818             else {
3819               return [$_[0], $_[1]];
3820             }
3821           },
3822           ARRAY => sub {
3823             return $_[1] if !defined $_[0];
3824             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3825             return [$_[0], @{$_[1]}]
3826           },
3827           HASH  => sub {
3828             return [] if !defined $_[0] and !keys %{$_[1]};
3829             return [ $_[1] ] if !defined $_[0];
3830             return [ $_[0] ] if !keys %{$_[1]};
3831             return [$_[0], $_[1]]
3832           },
3833         },
3834         ARRAY => {
3835           SCALAR => sub {
3836             return $_[0] if !defined $_[1];
3837             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3838             return [@{$_[0]}, $_[1]]
3839           },
3840           ARRAY => sub {
3841             my @ret = @{$_[0]} or return $_[1];
3842             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3843             my %idx = map { $_ => 1 } @ret;
3844             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3845             \@ret;
3846           },
3847           HASH => sub {
3848             return [ $_[1] ] if ! @{$_[0]};
3849             return $_[0] if !keys %{$_[1]};
3850             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3851             return [ @{$_[0]}, $_[1] ];
3852           },
3853         },
3854         HASH => {
3855           SCALAR => sub {
3856             return [] if !keys %{$_[0]} and !defined $_[1];
3857             return [ $_[0] ] if !defined $_[1];
3858             return [ $_[1] ] if !keys %{$_[0]};
3859             return [$_[0], $_[1]]
3860           },
3861           ARRAY => sub {
3862             return [] if !keys %{$_[0]} and !@{$_[1]};
3863             return [ $_[0] ] if !@{$_[1]};
3864             return $_[1] if !keys %{$_[0]};
3865             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3866             return [ $_[0], @{$_[1]} ];
3867           },
3868           HASH => sub {
3869             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3870             return [ $_[0] ] if !keys %{$_[1]};
3871             return [ $_[1] ] if !keys %{$_[0]};
3872             return [ $_[0] ] if $_[0] eq $_[1];
3873             return [ $_[0], $_[1] ];
3874           },
3875         }
3876       } => 'DBIC_RS_ATTR_MERGER');
3877       $hm;
3878     };
3879
3880     return $hm->merge ($_[1], $_[2]);
3881   }
3882 }
3883
3884 sub STORABLE_freeze {
3885   my ($self, $cloning) = @_;
3886   my $to_serialize = { %$self };
3887
3888   # A cursor in progress can't be serialized (and would make little sense anyway)
3889   # the parser can be regenerated (and can't be serialized)
3890   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3891
3892   # nor is it sensical to store a not-yet-fired-count pager
3893   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3894     delete $to_serialize->{pager};
3895   }
3896
3897   Storable::nfreeze($to_serialize);
3898 }
3899
3900 # need this hook for symmetry
3901 sub STORABLE_thaw {
3902   my ($self, $cloning, $serialized) = @_;
3903
3904   %$self = %{ Storable::thaw($serialized) };
3905
3906   $self;
3907 }
3908
3909
3910 =head2 throw_exception
3911
3912 See L<DBIx::Class::Schema/throw_exception> for details.
3913
3914 =cut
3915
3916 sub throw_exception {
3917   my $self=shift;
3918
3919   if (ref $self and my $rsrc = $self->result_source) {
3920     $rsrc->throw_exception(@_)
3921   }
3922   else {
3923     DBIx::Class::Exception->throw(@_);
3924   }
3925 }
3926
3927 1;
3928
3929 __END__
3930
3931 # XXX: FIXME: Attributes docs need clearing up
3932
3933 =head1 ATTRIBUTES
3934
3935 Attributes are used to refine a ResultSet in various ways when
3936 searching for data. They can be passed to any method which takes an
3937 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3938 L</count>.
3939
3940 Default attributes can be set on the result class using
3941 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3942 the CAVEATS on that feature before using it!)
3943
3944 These are in no particular order:
3945
3946 =head2 order_by
3947
3948 =over 4
3949
3950 =item Value: ( $order_by | \@order_by | \%order_by )
3951
3952 =back
3953
3954 Which column(s) to order the results by.
3955
3956 [The full list of suitable values is documented in
3957 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3958 common options.]
3959
3960 If a single column name, or an arrayref of names is supplied, the
3961 argument is passed through directly to SQL. The hashref syntax allows
3962 for connection-agnostic specification of ordering direction:
3963
3964  For descending order:
3965
3966   order_by => { -desc => [qw/col1 col2 col3/] }
3967
3968  For explicit ascending order:
3969
3970   order_by => { -asc => 'col' }
3971
3972 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3973 supported, although you are strongly encouraged to use the hashref
3974 syntax as outlined above.
3975
3976 =head2 columns
3977
3978 =over 4
3979
3980 =item Value: \@columns | \%columns | $column
3981
3982 =back
3983
3984 Shortcut to request a particular set of columns to be retrieved. Each
3985 column spec may be a string (a table column name), or a hash (in which
3986 case the key is the C<as> value, and the value is used as the C<select>
3987 expression). Adds C<me.> onto the start of any column without a C<.> in
3988 it and sets C<select> from that, then auto-populates C<as> from
3989 C<select> as normal. (You may also use the C<cols> attribute, as in
3990 earlier versions of DBIC, but this is deprecated.)
3991
3992 Essentially C<columns> does the same as L</select> and L</as>.
3993
3994     columns => [ 'foo', { bar => 'baz' } ]
3995
3996 is the same as
3997
3998     select => [qw/foo baz/],
3999     as => [qw/foo bar/]
4000
4001 =head2 +columns
4002
4003 =over 4
4004
4005 =item Value: \@columns
4006
4007 =back
4008
4009 Indicates additional columns to be selected from storage. Works the same as
4010 L</columns> but adds columns to the selection. (You may also use the
4011 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4012 deprecated). For example:-
4013
4014   $schema->resultset('CD')->search(undef, {
4015     '+columns' => ['artist.name'],
4016     join => ['artist']
4017   });
4018
4019 would return all CDs and include a 'name' column to the information
4020 passed to object inflation. Note that the 'artist' is the name of the
4021 column (or relationship) accessor, and 'name' is the name of the column
4022 accessor in the related table.
4023
4024 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
4025 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
4026 unary plus operator before it.
4027
4028 =head2 include_columns
4029
4030 =over 4
4031
4032 =item Value: \@columns
4033
4034 =back
4035
4036 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
4037
4038 =head2 select
4039
4040 =over 4
4041
4042 =item Value: \@select_columns
4043
4044 =back
4045
4046 Indicates which columns should be selected from the storage. You can use
4047 column names, or in the case of RDBMS back ends, function or stored procedure
4048 names:
4049
4050   $rs = $schema->resultset('Employee')->search(undef, {
4051     select => [
4052       'name',
4053       { count => 'employeeid' },
4054       { max => { length => 'name' }, -as => 'longest_name' }
4055     ]
4056   });
4057
4058   # Equivalent SQL
4059   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4060
4061 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4062 use L</select>, to instruct DBIx::Class how to store the result of the column.
4063 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4064 identifier aliasing. You can however alias a function, so you can use it in
4065 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4066 attribute> supplied as shown in the example above.
4067
4068 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4069 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4070 unary plus operator before it.
4071
4072 =head2 +select
4073
4074 =over 4
4075
4076 Indicates additional columns to be selected from storage.  Works the same as
4077 L</select> but adds columns to the default selection, instead of specifying
4078 an explicit list.
4079
4080 =back
4081
4082 =head2 as
4083
4084 =over 4
4085
4086 =item Value: \@inflation_names
4087
4088 =back
4089
4090 Indicates column names for object inflation. That is L</as> indicates the
4091 slot name in which the column value will be stored within the
4092 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4093 identifier by the C<get_column> method (or via the object accessor B<if one
4094 with the same name already exists>) as shown below. The L</as> attribute has
4095 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4096
4097   $rs = $schema->resultset('Employee')->search(undef, {
4098     select => [
4099       'name',
4100       { count => 'employeeid' },
4101       { max => { length => 'name' }, -as => 'longest_name' }
4102     ],
4103     as => [qw/
4104       name
4105       employee_count
4106       max_name_length
4107     /],
4108   });
4109
4110 If the object against which the search is performed already has an accessor
4111 matching a column name specified in C<as>, the value can be retrieved using
4112 the accessor as normal:
4113
4114   my $name = $employee->name();
4115
4116 If on the other hand an accessor does not exist in the object, you need to
4117 use C<get_column> instead:
4118
4119   my $employee_count = $employee->get_column('employee_count');
4120
4121 You can create your own accessors if required - see
4122 L<DBIx::Class::Manual::Cookbook> for details.
4123
4124 =head2 +as
4125
4126 =over 4
4127
4128 Indicates additional column names for those added via L</+select>. See L</as>.
4129
4130 =back
4131
4132 =head2 join
4133
4134 =over 4
4135
4136 =item Value: ($rel_name | \@rel_names | \%rel_names)
4137
4138 =back
4139
4140 Contains a list of relationships that should be joined for this query.  For
4141 example:
4142
4143   # Get CDs by Nine Inch Nails
4144   my $rs = $schema->resultset('CD')->search(
4145     { 'artist.name' => 'Nine Inch Nails' },
4146     { join => 'artist' }
4147   );
4148
4149 Can also contain a hash reference to refer to the other relation's relations.
4150 For example:
4151
4152   package MyApp::Schema::Track;
4153   use base qw/DBIx::Class/;
4154   __PACKAGE__->table('track');
4155   __PACKAGE__->add_columns(qw/trackid cd position title/);
4156   __PACKAGE__->set_primary_key('trackid');
4157   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4158   1;
4159
4160   # In your application
4161   my $rs = $schema->resultset('Artist')->search(
4162     { 'track.title' => 'Teardrop' },
4163     {
4164       join     => { cd => 'track' },
4165       order_by => 'artist.name',
4166     }
4167   );
4168
4169 You need to use the relationship (not the table) name in  conditions,
4170 because they are aliased as such. The current table is aliased as "me", so
4171 you need to use me.column_name in order to avoid ambiguity. For example:
4172
4173   # Get CDs from 1984 with a 'Foo' track
4174   my $rs = $schema->resultset('CD')->search(
4175     {
4176       'me.year' => 1984,
4177       'tracks.name' => 'Foo'
4178     },
4179     { join => 'tracks' }
4180   );
4181
4182 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4183 similarly for a third time). For e.g.
4184
4185   my $rs = $schema->resultset('Artist')->search({
4186     'cds.title'   => 'Down to Earth',
4187     'cds_2.title' => 'Popular',
4188   }, {
4189     join => [ qw/cds cds/ ],
4190   });
4191
4192 will return a set of all artists that have both a cd with title 'Down
4193 to Earth' and a cd with title 'Popular'.
4194
4195 If you want to fetch related objects from other tables as well, see L</prefetch>
4196 below.
4197
4198  NOTE: An internal join-chain pruner will discard certain joins while
4199  constructing the actual SQL query, as long as the joins in question do not
4200  affect the retrieved result. This for example includes 1:1 left joins
4201  that are not part of the restriction specification (WHERE/HAVING) nor are
4202  a part of the query selection.
4203
4204 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4205
4206 =head2 collapse
4207
4208 =over 4
4209
4210 =item Value: (0 | 1)
4211
4212 =back
4213
4214 When set to a true value, indicates that any rows fetched from joined has_many
4215 relationships are to be aggregated into the corresponding "parent" object. For
4216 example, the resultset:
4217
4218   my $rs = $schema->resultset('CD')->search({}, {
4219     '+columns' => [ qw/ tracks.title tracks.position / ],
4220     join => 'tracks',
4221     collapse => 1,
4222   });
4223
4224 While executing the following query:
4225
4226   SELECT me.*, tracks.title, tracks.position
4227     FROM cd me
4228     LEFT JOIN track tracks
4229       ON tracks.cdid = me.cdid
4230
4231 Will return only as many objects as there are rows in the CD source, even
4232 though the result of the query may span many rows. Each of these CD objects
4233 will in turn have multiple "Track" objects hidden behind the has_many
4234 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4235 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4236 product"), with each CD object containing exactly one of all fetched Track data.
4237
4238 When a collapse is requested on a non-ordered resultset, an order by some
4239 unique part of the main source (the left-most table) is inserted automatically.
4240 This is done so that the resultset is allowed to be "lazy" - calling
4241 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4242 object with all of its related data.
4243
4244 If an L</order_by> is already declared, and orders the resultset in a way that
4245 makes collapsing as described above impossible (e.g. C<< ORDER BY
4246 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4247 switch to "eager" mode and slurp the entire resultset before constructing the
4248 first object returned by L</next>.
4249
4250 Setting this attribute on a resultset that does not join any has_many
4251 relations is a no-op.
4252
4253 For a more in-depth discussion, see L</PREFETCHING>.
4254
4255 =head2 prefetch
4256
4257 =over 4
4258
4259 =item Value: ($rel_name | \@rel_names | \%rel_names)
4260
4261 =back
4262
4263 This attribute is a shorthand for specifying a L</join> spec, adding all
4264 columns from the joined related sources as L</+columns> and setting
4265 L</collapse> to a true value. For example, the following two queries are
4266 equivalent:
4267
4268   my $rs = $schema->resultset('Artist')->search({}, {
4269     prefetch => { cds => ['genre', 'tracks' ] },
4270   });
4271
4272 and
4273
4274   my $rs = $schema->resultset('Artist')->search({}, {
4275     join => { cds => ['genre', 'tracks' ] },
4276     collapse => 1,
4277     '+columns' => [
4278       (map
4279         { +{ "cds.$_" => "cds.$_" } }
4280         $schema->source('Artist')->related_source('cds')->columns
4281       ),
4282       (map
4283         { +{ "cds.genre.$_" => "genre.$_" } }
4284         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4285       ),
4286       (map
4287         { +{ "cds.tracks.$_" => "tracks.$_" } }
4288         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4289       ),
4290     ],
4291   });
4292
4293 Both producing the following SQL:
4294
4295   SELECT  me.artistid, me.name, me.rank, me.charfield,
4296           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4297           genre.genreid, genre.name,
4298           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4299     FROM artist me
4300     LEFT JOIN cd cds
4301       ON cds.artist = me.artistid
4302     LEFT JOIN genre genre
4303       ON genre.genreid = cds.genreid
4304     LEFT JOIN track tracks
4305       ON tracks.cd = cds.cdid
4306   ORDER BY me.artistid
4307
4308 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4309 the arguments are properly merged and generally do the right thing. For
4310 example, you may want to do the following:
4311
4312   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4313     { 'genre.genreid' => undef },
4314     {
4315       join => { cds => 'genre' },
4316       prefetch => 'cds',
4317     }
4318   );
4319
4320 Which generates the following SQL:
4321
4322   SELECT  me.artistid, me.name, me.rank, me.charfield,
4323           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4324     FROM artist me
4325     LEFT JOIN cd cds
4326       ON cds.artist = me.artistid
4327     LEFT JOIN genre genre
4328       ON genre.genreid = cds.genreid
4329   WHERE genre.genreid IS NULL
4330   ORDER BY me.artistid
4331
4332 For a more in-depth discussion, see L</PREFETCHING>.
4333
4334 =head2 alias
4335
4336 =over 4
4337
4338 =item Value: $source_alias
4339
4340 =back
4341
4342 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4343 nested search queries (sub-SELECTs) might need specific aliases set to
4344 reference inner queries.  For example:
4345
4346    my $q = $rs
4347       ->related_resultset('CDs')
4348       ->related_resultset('Tracks')
4349       ->search({
4350          'track.id' => { -ident => 'none_search.id' },
4351       })
4352       ->as_query;
4353
4354    my $ids = $self->search({
4355       -not_exists => $q,
4356    }, {
4357       alias    => 'none_search',
4358       group_by => 'none_search.id',
4359    })->get_column('id')->as_query;
4360
4361    $self->search({ id => { -in => $ids } })
4362
4363 This attribute is directly tied to L</current_source_alias>.
4364
4365 =head2 page
4366
4367 =over 4
4368
4369 =item Value: $page
4370
4371 =back
4372
4373 Makes the resultset paged and specifies the page to retrieve. Effectively
4374 identical to creating a non-pages resultset and then calling ->page($page)
4375 on it.
4376
4377 If L</rows> attribute is not specified it defaults to 10 rows per page.
4378
4379 When you have a paged resultset, L</count> will only return the number
4380 of rows in the page. To get the total, use the L</pager> and call
4381 C<total_entries> on it.
4382
4383 =head2 rows
4384
4385 =over 4
4386
4387 =item Value: $rows
4388
4389 =back
4390
4391 Specifies the maximum number of rows for direct retrieval or the number of
4392 rows per page if the page attribute or method is used.
4393
4394 =head2 offset
4395
4396 =over 4
4397
4398 =item Value: $offset
4399
4400 =back
4401
4402 Specifies the (zero-based) row number for the  first row to be returned, or the
4403 of the first row of the first page if paging is used.
4404
4405 =head2 software_limit
4406
4407 =over 4
4408
4409 =item Value: (0 | 1)
4410
4411 =back
4412
4413 When combined with L</rows> and/or L</offset> the generated SQL will not
4414 include any limit dialect stanzas. Instead the entire result will be selected
4415 as if no limits were specified, and DBIC will perform the limit locally, by
4416 artificially advancing and finishing the resulting L</cursor>.
4417
4418 This is the recommended way of performing resultset limiting when no sane RDBMS
4419 implementation is available (e.g.
4420 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4421 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4422
4423 =head2 group_by
4424
4425 =over 4
4426
4427 =item Value: \@columns
4428
4429 =back
4430
4431 A arrayref of columns to group by. Can include columns of joined tables.
4432
4433   group_by => [qw/ column1 column2 ... /]
4434
4435 =head2 having
4436
4437 =over 4
4438
4439 =item Value: $condition
4440
4441 =back
4442
4443 HAVING is a select statement attribute that is applied between GROUP BY and
4444 ORDER BY. It is applied to the after the grouping calculations have been
4445 done.
4446
4447   having => { 'count_employee' => { '>=', 100 } }
4448
4449 or with an in-place function in which case literal SQL is required:
4450
4451   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4452
4453 =head2 distinct
4454
4455 =over 4
4456
4457 =item Value: (0 | 1)
4458
4459 =back
4460
4461 Set to 1 to automatically generate a L</group_by> clause based on the selection
4462 (including intelligent handling of L</order_by> contents). Note that the group
4463 criteria calculation takes place over the B<final> selection. This includes
4464 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4465 L</search> calls, and standalone columns selected via
4466 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4467 extra selections specified via L</prefetch> - such selections are explicitly
4468 excluded from group criteria calculations.
4469
4470 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4471 setting is ignored and an appropriate warning is issued.
4472
4473 =head2 where
4474
4475 =over 4
4476
4477 Adds to the WHERE clause.
4478
4479   # only return rows WHERE deleted IS NULL for all searches
4480   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4481
4482 Can be overridden by passing C<< { where => undef } >> as an attribute
4483 to a resultset.
4484
4485 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4486
4487 =back
4488
4489 =head2 cache
4490
4491 Set to 1 to cache search results. This prevents extra SQL queries if you
4492 revisit rows in your ResultSet:
4493
4494   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4495
4496   while( my $artist = $resultset->next ) {
4497     ... do stuff ...
4498   }
4499
4500   $rs->first; # without cache, this would issue a query
4501
4502 By default, searches are not cached.
4503
4504 For more examples of using these attributes, see
4505 L<DBIx::Class::Manual::Cookbook>.
4506
4507 =head2 for
4508
4509 =over 4
4510
4511 =item Value: ( 'update' | 'shared' | \$scalar )
4512
4513 =back
4514
4515 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4516 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4517 query.
4518
4519 =head1 PREFETCHING
4520
4521 DBIx::Class supports arbitrary related data prefetching from multiple related
4522 sources. Any combination of relationship types and column sets are supported.
4523 If L<collapsing|/collapse> is requested, there is an additional requirement of
4524 selecting enough data to make every individual object uniquely identifiable.
4525
4526 Here are some more involved examples, based on the following relationship map:
4527
4528   # Assuming:
4529   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4530   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4531   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4532
4533   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4534
4535   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4536
4537
4538
4539   my $rs = $schema->resultset('Tag')->search(
4540     undef,
4541     {
4542       prefetch => {
4543         cd => 'artist'
4544       }
4545     }
4546   );
4547
4548 The initial search results in SQL like the following:
4549
4550   SELECT tag.*, cd.*, artist.* FROM tag
4551   JOIN cd ON tag.cd = cd.cdid
4552   JOIN artist ON cd.artist = artist.artistid
4553
4554 L<DBIx::Class> has no need to go back to the database when we access the
4555 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4556 case.
4557
4558 Simple prefetches will be joined automatically, so there is no need
4559 for a C<join> attribute in the above search.
4560
4561 The L</prefetch> attribute can be used with any of the relationship types
4562 and multiple prefetches can be specified together. Below is a more complex
4563 example that prefetches a CD's artist, its liner notes (if present),
4564 the cover image, the tracks on that CD, and the guests on those
4565 tracks.
4566
4567   my $rs = $schema->resultset('CD')->search(
4568     undef,
4569     {
4570       prefetch => [
4571         { artist => 'record_label'},  # belongs_to => belongs_to
4572         'liner_note',                 # might_have
4573         'cover_image',                # has_one
4574         { tracks => 'guests' },       # has_many => has_many
4575       ]
4576     }
4577   );
4578
4579 This will produce SQL like the following:
4580
4581   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4582          tracks.*, guests.*
4583     FROM cd me
4584     JOIN artist artist
4585       ON artist.artistid = me.artistid
4586     JOIN record_label record_label
4587       ON record_label.labelid = artist.labelid
4588     LEFT JOIN track tracks
4589       ON tracks.cdid = me.cdid
4590     LEFT JOIN guest guests
4591       ON guests.trackid = track.trackid
4592     LEFT JOIN liner_notes liner_note
4593       ON liner_note.cdid = me.cdid
4594     JOIN cd_artwork cover_image
4595       ON cover_image.cdid = me.cdid
4596   ORDER BY tracks.cd
4597
4598 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4599 C<tracks>, and C<guests> of the CD will all be available through the
4600 relationship accessors without the need for additional queries to the
4601 database.
4602
4603 =head3 CAVEATS
4604
4605 Prefetch does a lot of deep magic. As such, it may not behave exactly
4606 as you might expect.
4607
4608 =over 4
4609
4610 =item *
4611
4612 Prefetch uses the L</cache> to populate the prefetched relationships. This
4613 may or may not be what you want.
4614
4615 =item *
4616
4617 If you specify a condition on a prefetched relationship, ONLY those
4618 rows that match the prefetched condition will be fetched into that relationship.
4619 This means that adding prefetch to a search() B<may alter> what is returned by
4620 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4621
4622   my $artist_rs = $schema->resultset('Artist')->search({
4623       'cds.year' => 2008,
4624   }, {
4625       join => 'cds',
4626   });
4627
4628   my $count = $artist_rs->first->cds->count;
4629
4630   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4631
4632   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4633
4634   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4635
4636 That cmp_ok() may or may not pass depending on the datasets involved. In other
4637 words the C<WHERE> condition would apply to the entire dataset, just like
4638 it would in regular SQL. If you want to add a condition only to the "right side"
4639 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4640 condition|DBIx::Class::Relationship::Base/condition>
4641
4642 =back
4643
4644 =head1 DBIC BIND VALUES
4645
4646 Because DBIC may need more information to bind values than just the column name
4647 and value itself, it uses a special format for both passing and receiving bind
4648 values.  Each bind value should be composed of an arrayref of
4649 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4650
4651 =over 4
4652
4653 =item dbd_attrs
4654
4655 If present (in any form), this is what is being passed directly to bind_param.
4656 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4657 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4658
4659 If this is specified, all other bind options described below are ignored.
4660
4661 =item sqlt_datatype
4662
4663 If present, this is used to infer the actual bind attribute by passing to
4664 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4665 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4666
4667 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4668 currently drivers are expected to "Do the Right Thing" when given a common
4669 datatype name.  (Not ideal, but that's what we got at this point.)
4670
4671 =item sqlt_size
4672
4673 Currently used to correctly allocate buffers for bind_param_inout().
4674 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4675 or to a sensible value based on the "data_type".
4676
4677 =item dbic_colname
4678
4679 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4680 explicitly specified they are never overridden).  Also used by some weird DBDs,
4681 where the column name should be available at bind_param time (e.g. Oracle).
4682
4683 =back
4684
4685 For backwards compatibility and convenience, the following shortcuts are
4686 supported:
4687
4688   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4689   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4690   [ undef,   $val ] === [ {}, $val ]
4691   $val              === [ {}, $val ]
4692
4693 =head1 AUTHOR AND CONTRIBUTORS
4694
4695 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4696
4697 =head1 LICENSE
4698
4699 You may distribute this code under the same terms as Perl itself.
4700