lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use Try::Tiny;
  10 use Data::Compare (); # no imports!!! guard against insane architecture
  11 use Data::Query::Constants;
  12 use Data::Query::ExprHelpers;
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 # this is real - CDBICompat overrides it with insanity
  30 # yes, prototype won't matter, but that's for now ;)
  31 sub _bool () { 1 }
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  34
  35 =head1 NAME
  36
  37 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  38
  39 =head1 SYNOPSIS
  40
  41   my $users_rs = $schema->resultset('User');
  42   while( $user = $users_rs->next) {
  43     print $user->username;
  44   }
  45
  46   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  47   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  48
  49 =head1 DESCRIPTION
  50
  51 A ResultSet is an object which stores a set of conditions representing
  52 a query. It is the backbone of DBIx::Class (i.e. the really
  53 important/useful bit).
  54
  55 No SQL is executed on the database when a ResultSet is created, it
  56 just stores all the conditions needed to create the query.
  57
  58 A basic ResultSet representing the data of an entire table is returned
  59 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  60 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  61
  62   my $users_rs = $schema->resultset('User');
  63
  64 A new ResultSet is returned from calling L</search> on an existing
  65 ResultSet. The new one will contain all the conditions of the
  66 original, plus any new conditions added in the C<search> call.
  67
  68 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  69 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  70 represents.
  71
  72 The query that the ResultSet represents is B<only> executed against
  73 the database when these methods are called:
  74 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  75
  76 If a resultset is used in a numeric context it returns the L</count>.
  77 However, if it is used in a boolean context it is B<always> true.  So if
  78 you want to check if a resultset has any results, you must use C<if $rs
  79 != 0>.
  80
  81 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  82
  83 If you want to make your custom ResultSet classes with L<Moose>, use a template
  84 similar to:
  85
  86     package MyApp::Schema::ResultSet::User;
  87
  88     use Moose;
  89     use namespace::autoclean;
  90     use MooseX::NonMoose;
  91     extends 'DBIx::Class::ResultSet';
  92
  93     sub BUILDARGS { $_[2] }
  94
  95     ...your code...
  96
  97     __PACKAGE__->meta->make_immutable;
  98
  99     1;
 100
 101 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 102 clash with the regular ResultSet constructor. Alternatively, you can use:
 103
 104     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 105
 106 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 107 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 108
 109 =head1 EXAMPLES
 110
 111 =head2 Chaining resultsets
 112
 113 Let's say you've got a query that needs to be run to return some data
 114 to the user. But, you have an authorization system in place that
 115 prevents certain users from seeing certain information. So, you want
 116 to construct the basic query in one method, but add constraints to it in
 117 another.
 118
 119   sub get_data {
 120     my $self = shift;
 121     my $request = $self->get_request; # Get a request object somehow.
 122     my $schema = $self->result_source->schema;
 123
 124     my $cd_rs = $schema->resultset('CD')->search({
 125       title => $request->param('title'),
 126       year => $request->param('year'),
 127     });
 128
 129     $cd_rs = $self->apply_security_policy( $cd_rs );
 130
 131     return $cd_rs->all();
 132   }
 133
 134   sub apply_security_policy {
 135     my $self = shift;
 136     my ($rs) = @_;
 137
 138     return $rs->search({
 139       subversive => 0,
 140     });
 141   }
 142
 143 =head3 Resolving conditions and attributes
 144
 145 When a resultset is chained from another resultset (e.g.:
 146 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 147 and attributes with the same keys need resolving.
 148
 149 If any of L</columns>, L</select>, L</as> are present, they reset the
 150 original selection, and start the selection "clean".
 151
 152 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 153 are merged into the existing ones from the original resultset.
 154
 155 The L</where> and L</having> attributes, and any search conditions, are
 156 merged with an SQL C<AND> to the existing condition from the original
 157 resultset.
 158
 159 All other attributes are overridden by any new ones supplied in the
 160 search attributes.
 161
 162 =head2 Multiple queries
 163
 164 Since a resultset just defines a query, you can do all sorts of
 165 things with it with the same object.
 166
 167   # Don't hit the DB yet.
 168   my $cd_rs = $schema->resultset('CD')->search({
 169     title => 'something',
 170     year => 2009,
 171   });
 172
 173   # Each of these hits the DB individually.
 174   my $count = $cd_rs->count;
 175   my $most_recent = $cd_rs->get_column('date_released')->max();
 176   my @records = $cd_rs->all;
 177
 178 And it's not just limited to SELECT statements.
 179
 180   $cd_rs->delete();
 181
 182 This is even cooler:
 183
 184   $cd_rs->create({ artist => 'Fred' });
 185
 186 Which is the same as:
 187
 188   $schema->resultset('CD')->create({
 189     title => 'something',
 190     year => 2009,
 191     artist => 'Fred'
 192   });
 193
 194 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 195
 196 =head1 METHODS
 197
 198 =head2 new
 199
 200 =over 4
 201
 202 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 203
 204 =item Return Value: L<$resultset|/search>
 205
 206 =back
 207
 208 The resultset constructor. Takes a source object (usually a
 209 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 210 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 211 executed as needed by the other methods.
 212
 213 Generally you never construct a resultset manually. Instead you get one
 214 from e.g. a
 215 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 216 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 217 scalar context):
 218
 219   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 220
 221 =over
 222
 223 =item WARNING
 224
 225 If called on an object, proxies to L</new_result> instead, so
 226
 227   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 228
 229 will return a CD object, not a ResultSet, and is equivalent to:
 230
 231   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 232
 233 Please also keep in mind that many internals call L</new_result> directly,
 234 so overloading this method with the idea of intercepting new result object
 235 creation B<will not work>. See also warning pertaining to L</create>.
 236
 237 =back
 238
 239 =cut
 240
 241 sub new {
 242   my $class = shift;
 243   return $class->new_result(@_) if ref $class;
 244
 245   my ($source, $attrs) = @_;
 246   $source = $source->resolve
 247     if $source->isa('DBIx::Class::ResultSourceHandle');
 248
 249   $attrs = { %{$attrs||{}} };
 250   delete @{$attrs}{qw(_sqlmaker_select_args _related_results_construction)};
 251
 252   if ($attrs->{page}) {
 253     $attrs->{rows} ||= 10;
 254   }
 255
 256   $attrs->{alias} ||= 'me';
 257
 258   my $self = bless {
 259     result_source => $source,
 260     cond => $attrs->{where},
 261     pager => undef,
 262     attrs => $attrs,
 263   }, $class;
 264
 265   # if there is a dark selector, this means we are already in a
 266   # chain and the cleanup/sanification was taken care of by
 267   # _search_rs already
 268   $self->_normalize_selection($attrs)
 269     unless $attrs->{_dark_selector};
 270
 271   $self->result_class(
 272     $attrs->{result_class} || $source->result_class
 273   );
 274
 275   $self;
 276 }
 277
 278 =head2 search
 279
 280 =over 4
 281
 282 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 283
 284 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 285
 286 =back
 287
 288   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 289   my $new_rs = $cd_rs->search({ year => 2005 });
 290
 291   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 292                  # year = 2005 OR year = 2004
 293
 294 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 295 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 296 To avoid that, use L</search_rs>.
 297
 298 If you need to pass in additional attributes but no additional condition,
 299 call it as C<search(undef, \%attrs)>.
 300
 301   # "SELECT name, artistid FROM $artist_table"
 302   my @all_artists = $schema->resultset('Artist')->search(undef, {
 303     columns => [qw/name artistid/],
 304   });
 305
 306 For a list of attributes that can be passed to C<search>, see
 307 L</ATTRIBUTES>. For more examples of using this function, see
 308 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 309 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 310 and its extension L<DBIx::Class::SQLMaker>.
 311
 312 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 313
 314 =head3 CAVEAT
 315
 316 Note that L</search> does not process/deflate any of the values passed in the
 317 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 318 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 319 manually that any value passed to this method will stringify to something the
 320 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 321 objects, for more info see:
 322 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 323
 324 =cut
 325
 326 sub search {
 327   my $self = shift;
 328   my $rs = $self->search_rs( @_ );
 329
 330   if (wantarray) {
 331     return $rs->all;
 332   }
 333   elsif (defined wantarray) {
 334     return $rs;
 335   }
 336   else {
 337     # we can be called by a relationship helper, which in
 338     # turn may be called in void context due to some braindead
 339     # overload or whatever else the user decided to be clever
 340     # at this particular day. Thus limit the exception to
 341     # external code calls only
 342     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 343       if (caller)[0] !~ /^\QDBIx::Class::/;
 344
 345     return ();
 346   }
 347 }
 348
 349 =head2 search_rs
 350
 351 =over 4
 352
 353 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 354
 355 =item Return Value: L<$resultset|/search>
 356
 357 =back
 358
 359 This method does the same exact thing as search() except it will
 360 always return a resultset, even in list context.
 361
 362 =cut
 363
 364 sub search_rs {
 365   my $self = shift;
 366
 367   my $rsrc = $self->result_source;
 368   my ($call_cond, $call_attrs);
 369
 370   # Special-case handling for (undef, undef) or (undef)
 371   # Note that (foo => undef) is valid deprecated syntax
 372   @_ = () if not scalar grep { defined $_ } @_;
 373
 374   # just a cond
 375   if (@_ == 1) {
 376     $call_cond = shift;
 377   }
 378   # fish out attrs in the ($condref, $attr) case
 379   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 380     ($call_cond, $call_attrs) = @_;
 381   }
 382   elsif (@_ % 2) {
 383     $self->throw_exception('Odd number of arguments to search')
 384   }
 385   # legacy search
 386   elsif (@_) {
 387     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 388       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 389
 390     for my $i (0 .. $#_) {
 391       next if $i % 2;
 392       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 393         if (! defined $_[$i] or ref $_[$i] ne '');
 394     }
 395
 396     $call_cond = { @_ };
 397   }
 398
 399   # see if we can keep the cache (no $rs changes)
 400   my $cache;
 401   my %safe = (alias => 1, cache => 1);
 402   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 403     ! defined $call_cond
 404       or
 405     ref $call_cond eq 'HASH' && ! keys %$call_cond
 406       or
 407     ref $call_cond eq 'ARRAY' && ! @$call_cond
 408   )) {
 409     $cache = $self->get_cache;
 410   }
 411
 412   my $old_attrs = { %{$self->{attrs}} };
 413   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 414
 415   my $new_attrs = { %$old_attrs };
 416
 417   # take care of call attrs (only if anything is changing)
 418   if ($call_attrs and keys %$call_attrs) {
 419
 420     # copy for _normalize_selection
 421     $call_attrs = { %$call_attrs };
 422
 423     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 424
 425     # reset the current selector list if new selectors are supplied
 426     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 427       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 428     }
 429
 430     # Normalize the new selector list (operates on the passed-in attr structure)
 431     # Need to do it on every chain instead of only once on _resolved_attrs, in
 432     # order to allow detection of empty vs partial 'as'
 433     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 434       if $old_attrs->{_dark_selector};
 435     $self->_normalize_selection ($call_attrs);
 436
 437     # start with blind overwriting merge, exclude selector attrs
 438     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 439     delete @{$new_attrs}{@selector_attrs};
 440
 441     for (@selector_attrs) {
 442       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 443         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 444     }
 445
 446     # older deprecated name, use only if {columns} is not there
 447     if (my $c = delete $new_attrs->{cols}) {
 448       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 449       if ($new_attrs->{columns}) {
 450         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 451       }
 452       else {
 453         $new_attrs->{columns} = $c;
 454       }
 455     }
 456
 457
 458     # join/prefetch use their own crazy merging heuristics
 459     foreach my $key (qw/join prefetch/) {
 460       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 461         if exists $call_attrs->{$key};
 462     }
 463
 464     # stack binds together
 465     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 466   }
 467
 468
 469   for ($old_where, $call_cond) {
 470     if (defined $_) {
 471       $new_attrs->{where} = $self->_stack_cond (
 472         $_, $new_attrs->{where}
 473       );
 474     }
 475   }
 476
 477   if (defined $old_having) {
 478     $new_attrs->{having} = $self->_stack_cond (
 479       $old_having, $new_attrs->{having}
 480     )
 481   }
 482
 483   my $rs = (ref $self)->new($rsrc, $new_attrs);
 484
 485   $rs->set_cache($cache) if ($cache);
 486
 487   return $rs;
 488 }
 489
 490 my $dark_sel_dumper;
 491 sub _normalize_selection {
 492   my ($self, $attrs) = @_;
 493
 494   # legacy syntax
 495   if ( exists $attrs->{include_columns} ) {
 496     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 497     $attrs->{'+columns'} = $self->_merge_attr(
 498       $attrs->{'+columns'}, delete $attrs->{include_columns}
 499     );
 500   }
 501
 502   # columns are always placed first, however
 503
 504   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 505   # delay the decision on whether to use a default select list ($rsrc->columns)
 506   # allowing stuff like the remove_columns helper to work
 507   #
 508   # select/as +select/+as pairs need special handling - the amount of select/as
 509   # elements in each pair does *not* have to be equal (think multicolumn
 510   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 511   # supplied at all) - try to infer the alias, either from the -as parameter
 512   # of the selector spec, or use the parameter whole if it looks like a column
 513   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 514   # is ok as well), but make sure no more additions to the 'as' chain take place
 515   for my $pref ('', '+') {
 516
 517     my ($sel, $as) = map {
 518       my $key = "${pref}${_}";
 519
 520       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 521         ? @{$attrs->{$key}}
 522         : $attrs->{$key} || ()
 523       ];
 524       delete $attrs->{$key};
 525       $val;
 526     } qw/select as/;
 527
 528     if (! @$as and ! @$sel ) {
 529       next;
 530     }
 531     elsif (@$as and ! @$sel) {
 532       $self->throw_exception(
 533         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 534       );
 535     }
 536     elsif( ! @$as ) {
 537       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 538       # if any @$as has been supplied we assume the user knows what (s)he is doing
 539       # and blindly keep stacking up pieces
 540       unless ($attrs->{_dark_selector}) {
 541         SELECTOR:
 542         for (@$sel) {
 543           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 544             push @$as, $_->{-as};
 545           }
 546           # assume any plain no-space, no-parenthesis string to be a column spec
 547           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 548           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 549             push @$as, $_;
 550           }
 551           # if all else fails - raise a flag that no more aliasing will be allowed
 552           else {
 553             $attrs->{_dark_selector} = {
 554               plus_stage => $pref,
 555               string => ($dark_sel_dumper ||= do {
 556                   require Data::Dumper::Concise;
 557                   Data::Dumper::Concise::DumperObject()->Indent(0);
 558                 })->Values([$_])->Dump
 559               ,
 560             };
 561             last SELECTOR;
 562           }
 563         }
 564       }
 565     }
 566     elsif (@$as < @$sel) {
 567       $self->throw_exception(
 568         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 569       );
 570     }
 571     elsif ($pref and $attrs->{_dark_selector}) {
 572       $self->throw_exception(
 573         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 574       );
 575     }
 576
 577
 578     # merge result
 579     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 580     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 581   }
 582 }
 583
 584 sub _stack_cond {
 585   my ($self, $left, $right) = @_;
 586
 587   # collapse single element top-level conditions
 588   # (single pass only, unlikely to need recursion)
 589   for ($left, $right) {
 590     if (ref $_ eq 'ARRAY') {
 591       if (@$_ == 0) {
 592         $_ = undef;
 593       }
 594       elsif (@$_ == 1) {
 595         $_ = $_->[0];
 596       }
 597     }
 598     elsif (ref $_ eq 'HASH') {
 599       my ($first, $more) = keys %$_;
 600
 601       # empty hash
 602       if (! defined $first) {
 603         $_ = undef;
 604       }
 605       # one element hash
 606       elsif (! defined $more) {
 607         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 608           $_ = $_->{'-and'};
 609         }
 610         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 611           $_ = $_->{'-or'};
 612         }
 613       }
 614     }
 615   }
 616
 617   # merge hashes with weeding out of duplicates (simple cases only)
 618   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 619
 620     # shallow copy to destroy
 621     $right = { %$right };
 622     for (grep { exists $right->{$_} } keys %$left) {
 623       # the use of eq_deeply here is justified - the rhs of an
 624       # expression can contain a lot of twisted weird stuff
 625       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 626     }
 627
 628     $right = undef unless keys %$right;
 629   }
 630
 631
 632   if (defined $left xor defined $right) {
 633     return defined $left ? $left : $right;
 634   }
 635   elsif (! defined $left) {
 636     return undef;
 637   }
 638   else {
 639     return { -and => [ $left, $right ] };
 640   }
 641 }
 642
 643 =head2 search_literal
 644
 645 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 646 should only be used in that context. C<search_literal> is a convenience
 647 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 648 want to ensure columns are bound correctly, use L</search>.
 649
 650 See L<DBIx::Class::Manual::Cookbook/Searching> and
 651 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 652 require C<search_literal>.
 653
 654 =over 4
 655
 656 =item Arguments: $sql_fragment, @standalone_bind_values
 657
 658 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 659
 660 =back
 661
 662   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 663   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 664
 665 Pass a literal chunk of SQL to be added to the conditional part of the
 666 resultset query.
 667
 668 Example of how to use C<search> instead of C<search_literal>
 669
 670   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 671   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 672
 673 =cut
 674
 675 sub search_literal {
 676   my ($self, $sql, @bind) = @_;
 677   my $attr;
 678   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 679     $attr = pop @bind;
 680   }
 681   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 682 }
 683
 684 =head2 find
 685
 686 =over 4
 687
 688 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 689
 690 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 691
 692 =back
 693
 694 Finds and returns a single row based on supplied criteria. Takes either a
 695 hashref with the same format as L</create> (including inference of foreign
 696 keys from related objects), or a list of primary key values in the same
 697 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 698 declaration on the L</result_source>.
 699
 700 In either case an attempt is made to combine conditions already existing on
 701 the resultset with the condition passed to this method.
 702
 703 To aid with preparing the correct query for the storage you may supply the
 704 C<key> attribute, which is the name of a
 705 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 706 unique constraint corresponding to the
 707 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 708 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 709 to construct a query that satisfies the named unique constraint fully (
 710 non-NULL values for each column member of the constraint) an exception is
 711 thrown.
 712
 713 If no C<key> is specified, the search is carried over all unique constraints
 714 which are fully defined by the available condition.
 715
 716 If no such constraint is found, C<find> currently defaults to a simple
 717 C<< search->(\%column_values) >> which may or may not do what you expect.
 718 Note that this fallback behavior may be deprecated in further versions. If
 719 you need to search with arbitrary conditions - use L</search>. If the query
 720 resulting from this fallback produces more than one row, a warning to the
 721 effect is issued, though only the first row is constructed and returned as
 722 C<$result_object>.
 723
 724 In addition to C<key>, L</find> recognizes and applies standard
 725 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 726
 727 Note that if you have extra concerns about the correctness of the resulting
 728 query you need to specify the C<key> attribute and supply the entire condition
 729 as an argument to find (since it is not always possible to perform the
 730 combination of the resultset condition with the supplied one, especially if
 731 the resultset condition contains literal sql).
 732
 733 For example, to find a row by its primary key:
 734
 735   my $cd = $schema->resultset('CD')->find(5);
 736
 737 You can also find a row by a specific unique constraint:
 738
 739   my $cd = $schema->resultset('CD')->find(
 740     {
 741       artist => 'Massive Attack',
 742       title  => 'Mezzanine',
 743     },
 744     { key => 'cd_artist_title' }
 745   );
 746
 747 See also L</find_or_create> and L</update_or_create>.
 748
 749 =cut
 750
 751 sub find {
 752   my $self = shift;
 753   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 754
 755   my $rsrc = $self->result_source;
 756
 757   my $constraint_name;
 758   if (exists $attrs->{key}) {
 759     $constraint_name = defined $attrs->{key}
 760       ? $attrs->{key}
 761       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 762     ;
 763   }
 764
 765   # Parse out the condition from input
 766   my $call_cond;
 767
 768   if (ref $_[0] eq 'HASH') {
 769     $call_cond = { %{$_[0]} };
 770   }
 771   else {
 772     # if only values are supplied we need to default to 'primary'
 773     $constraint_name = 'primary' unless defined $constraint_name;
 774
 775     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 776
 777     $self->throw_exception(
 778       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 779     ) unless @c_cols;
 780
 781     $self->throw_exception (
 782       'find() expects either a column/value hashref, or a list of values '
 783     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 784     ) unless @c_cols == @_;
 785
 786     $call_cond = {};
 787     @{$call_cond}{@c_cols} = @_;
 788   }
 789
 790   my %related;
 791   for my $key (keys %$call_cond) {
 792     if (
 793       my $keyref = ref($call_cond->{$key})
 794         and
 795       my $relinfo = $rsrc->relationship_info($key)
 796     ) {
 797       my $val = delete $call_cond->{$key};
 798
 799       next if $keyref eq 'ARRAY'; # has_many for multi_create
 800
 801       my $rel_q = $rsrc->_resolve_condition(
 802         $relinfo->{cond}, $val, $key, $key
 803       );
 804       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 805       @related{keys %$rel_q} = values %$rel_q;
 806     }
 807   }
 808
 809   # relationship conditions take precedence (?)
 810   @{$call_cond}{keys %related} = values %related;
 811
 812   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 813   my $final_cond;
 814   if (defined $constraint_name) {
 815     $final_cond = $self->_qualify_cond_columns (
 816
 817       $self->_build_unique_cond (
 818         $constraint_name,
 819         $call_cond,
 820       ),
 821
 822       $alias,
 823     );
 824   }
 825   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 826     # This means that we got here after a merger of relationship conditions
 827     # in ::Relationship::Base::search_related (the row method), and furthermore
 828     # the relationship is of the 'single' type. This means that the condition
 829     # provided by the relationship (already attached to $self) is sufficient,
 830     # as there can be only one row in the database that would satisfy the
 831     # relationship
 832   }
 833   else {
 834     # no key was specified - fall down to heuristics mode:
 835     # run through all unique queries registered on the resultset, and
 836     # 'OR' all qualifying queries together
 837     my (@unique_queries, %seen_column_combinations);
 838     for my $c_name ($rsrc->unique_constraint_names) {
 839       next if $seen_column_combinations{
 840         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 841       }++;
 842
 843       push @unique_queries, try {
 844         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 845       } || ();
 846     }
 847
 848     $final_cond = @unique_queries
 849       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 850       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 851     ;
 852   }
 853
 854   # Run the query, passing the result_class since it should propagate for find
 855   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 856   if ($rs->_resolved_attrs->{collapse}) {
 857     my $row = $rs->next;
 858     carp "Query returned more than one row" if $rs->next;
 859     return $row;
 860   }
 861   else {
 862     return $rs->single;
 863   }
 864 }
 865
 866 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 867 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 868 #
 869 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 870 # condition. It is provided for overrides until a saner way forward is devised
 871 #
 872 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 873 # the road. Please adjust your tests accordingly to catch this situation early
 874 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 875 #
 876 # The method will not be removed without an adequately complete replacement
 877 # for strict-mode enforcement
 878 sub _non_unique_find_fallback {
 879   my ($self, $cond, $attrs) = @_;
 880
 881   return $self->_qualify_cond_columns(
 882     $cond,
 883     exists $attrs->{alias}
 884       ? $attrs->{alias}
 885       : $self->{attrs}{alias}
 886   );
 887 }
 888
 889
 890 sub _qualify_cond_columns {
 891   my ($self, $cond, $alias) = @_;
 892
 893   my %aliased = %$cond;
 894   for (keys %aliased) {
 895     $aliased{"$alias.$_"} = delete $aliased{$_}
 896       if $_ !~ /\./;
 897   }
 898
 899   return \%aliased;
 900 }
 901
 902 sub _build_unique_cond {
 903   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 904
 905   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 906
 907   # combination may fail if $self->{cond} is non-trivial
 908   my ($final_cond) = try {
 909     $self->_merge_with_rscond ($extra_cond)
 910   } catch {
 911     +{ %$extra_cond }
 912   };
 913
 914   # trim out everything not in $columns
 915   $final_cond = { map {
 916     exists $final_cond->{$_}
 917       ? ( $_ => $final_cond->{$_} )
 918       : ()
 919   } @c_cols };
 920
 921   if (my @missing = grep
 922     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 923     (@c_cols)
 924   ) {
 925     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 926       $constraint_name,
 927       join (', ', map { "'$_'" } @missing),
 928     ) );
 929   }
 930
 931   if (
 932     !$croak_on_null
 933       and
 934     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 935       and
 936     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 937   ) {
 938     carp_unique ( sprintf (
 939       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 940     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 941     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 942       $constraint_name,
 943       join (', ', map { "'$_'" } @undefs),
 944     ));
 945   }
 946
 947   return $final_cond;
 948 }
 949
 950 =head2 search_related
 951
 952 =over 4
 953
 954 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 955
 956 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 957
 958 =back
 959
 960   $new_rs = $cd_rs->search_related('artist', {
 961     name => 'Emo-R-Us',
 962   });
 963
 964 Searches the specified relationship, optionally specifying a condition and
 965 attributes for matching records. See L</ATTRIBUTES> for more information.
 966
 967 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 968 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 969
 970 See also L</search_related_rs>.
 971
 972 =cut
 973
 974 sub search_related {
 975   return shift->related_resultset(shift)->search(@_);
 976 }
 977
 978 =head2 search_related_rs
 979
 980 This method works exactly the same as search_related, except that
 981 it guarantees a resultset, even in list context.
 982
 983 =cut
 984
 985 sub search_related_rs {
 986   return shift->related_resultset(shift)->search_rs(@_);
 987 }
 988
 989 =head2 cursor
 990
 991 =over 4
 992
 993 =item Arguments: none
 994
 995 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 996
 997 =back
 998
 999 Returns a storage-driven cursor to the given resultset. See
1000 L<DBIx::Class::Cursor> for more information.
1001
1002 =cut
1003
1004 sub cursor {
1005   my $self = shift;
1006
1007   return $self->{cursor} ||= do {
1008     my $attrs = $self->_resolved_attrs;
1009     $self->result_source->storage->select(
1010       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1011     );
1012   };
1013 }
1014
1015 =head2 single
1016
1017 =over 4
1018
1019 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1020
1021 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1022
1023 =back
1024
1025   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1026
1027 Inflates the first result without creating a cursor if the resultset has
1028 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1029 of L</search>.
1030
1031 While this method can take an optional search condition (just like L</search>)
1032 being a fast-code-path it does not recognize search attributes. If you need to
1033 add extra joins or similar, call L</search> and then chain-call L</single> on the
1034 L<DBIx::Class::ResultSet> returned.
1035
1036 =over
1037
1038 =item B<Note>
1039
1040 As of 0.08100, this method enforces the assumption that the preceding
1041 query returns only one row. If more than one row is returned, you will receive
1042 a warning:
1043
1044   Query returned more than one row
1045
1046 In this case, you should be using L</next> or L</find> instead, or if you really
1047 know what you are doing, use the L</rows> attribute to explicitly limit the size
1048 of the resultset.
1049
1050 This method will also throw an exception if it is called on a resultset prefetching
1051 has_many, as such a prefetch implies fetching multiple rows from the database in
1052 order to assemble the resulting object.
1053
1054 =back
1055
1056 =cut
1057
1058 sub single {
1059   my ($self, $where) = @_;
1060   if(@_ > 2) {
1061       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1062   }
1063
1064   my $attrs = { %{$self->_resolved_attrs} };
1065
1066   $self->throw_exception(
1067     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1068   ) if $attrs->{collapse};
1069
1070   if ($where) {
1071     if (defined $attrs->{where}) {
1072       $attrs->{where} = {
1073         '-and' =>
1074             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1075                $where, delete $attrs->{where} ]
1076       };
1077     } else {
1078       $attrs->{where} = $where;
1079     }
1080   }
1081
1082   my $data = [ $self->result_source->storage->select_single(
1083     $attrs->{from}, $attrs->{select},
1084     $attrs->{where}, $attrs
1085   )];
1086
1087   return undef unless @$data;
1088   $self->{_stashed_rows} = [ $data ];
1089   $self->_construct_results->[0];
1090 }
1091
1092
1093 # _collapse_query
1094 #
1095 # Recursively collapse the query, accumulating values for each column.
1096
1097 sub _collapse_query {
1098   my ($self, $query, $collapsed) = @_;
1099
1100   $collapsed ||= {};
1101
1102   if (ref $query eq 'ARRAY') {
1103     foreach my $subquery (@$query) {
1104       next unless ref $subquery;  # -or
1105       $collapsed = $self->_collapse_query($subquery, $collapsed);
1106     }
1107   }
1108   elsif (ref $query eq 'HASH') {
1109     if (keys %$query and (keys %$query)[0] eq '-and') {
1110       foreach my $subquery (@{$query->{-and}}) {
1111         $collapsed = $self->_collapse_query($subquery, $collapsed);
1112       }
1113     }
1114     else {
1115       foreach my $col (keys %$query) {
1116         my $value = $query->{$col};
1117         $collapsed->{$col}{$value}++;
1118       }
1119     }
1120   }
1121
1122   return $collapsed;
1123 }
1124
1125 =head2 get_column
1126
1127 =over 4
1128
1129 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1130
1131 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1132
1133 =back
1134
1135   my $max_length = $rs->get_column('length')->max;
1136
1137 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1138
1139 =cut
1140
1141 sub get_column {
1142   my ($self, $column) = @_;
1143   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1144   return $new;
1145 }
1146
1147 =head2 search_like
1148
1149 =over 4
1150
1151 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1152
1153 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1154
1155 =back
1156
1157   # WHERE title LIKE '%blue%'
1158   $cd_rs = $rs->search_like({ title => '%blue%'});
1159
1160 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1161 that this is simply a convenience method retained for ex Class::DBI users.
1162 You most likely want to use L</search> with specific operators.
1163
1164 For more information, see L<DBIx::Class::Manual::Cookbook>.
1165
1166 This method is deprecated and will be removed in 0.09. Use L</search()>
1167 instead. An example conversion is:
1168
1169   ->search_like({ foo => 'bar' });
1170
1171   # Becomes
1172
1173   ->search({ foo => { like => 'bar' } });
1174
1175 =cut
1176
1177 sub search_like {
1178   my $class = shift;
1179   carp_unique (
1180     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1181    .' Instead use ->search({ x => { -like => "y%" } })'
1182    .' (note the outer pair of {}s - they are important!)'
1183   );
1184   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1185   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1186   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1187   return $class->search($query, { %$attrs });
1188 }
1189
1190 =head2 slice
1191
1192 =over 4
1193
1194 =item Arguments: $first, $last
1195
1196 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1197
1198 =back
1199
1200 Returns a resultset or object list representing a subset of elements from the
1201 resultset slice is called on. Indexes are from 0, i.e., to get the first
1202 three records, call:
1203
1204   my ($one, $two, $three) = $rs->slice(0, 2);
1205
1206 =cut
1207
1208 sub slice {
1209   my ($self, $min, $max) = @_;
1210   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1211   $attrs->{offset} = $self->{attrs}{offset} || 0;
1212   $attrs->{offset} += $min;
1213   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1214   return $self->search(undef, $attrs);
1215   #my $slice = (ref $self)->new($self->result_source, $attrs);
1216   #return (wantarray ? $slice->all : $slice);
1217 }
1218
1219 =head2 next
1220
1221 =over 4
1222
1223 =item Arguments: none
1224
1225 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1226
1227 =back
1228
1229 Returns the next element in the resultset (C<undef> is there is none).
1230
1231 Can be used to efficiently iterate over records in the resultset:
1232
1233   my $rs = $schema->resultset('CD')->search;
1234   while (my $cd = $rs->next) {
1235     print $cd->title;
1236   }
1237
1238 Note that you need to store the resultset object, and call C<next> on it.
1239 Calling C<< resultset('Table')->next >> repeatedly will always return the
1240 first record from the resultset.
1241
1242 =cut
1243
1244 sub next {
1245   my ($self) = @_;
1246
1247   if (my $cache = $self->get_cache) {
1248     $self->{all_cache_position} ||= 0;
1249     return $cache->[$self->{all_cache_position}++];
1250   }
1251
1252   if ($self->{attrs}{cache}) {
1253     delete $self->{pager};
1254     $self->{all_cache_position} = 1;
1255     return ($self->all)[0];
1256   }
1257
1258   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1259
1260   $self->{_stashed_results} = $self->_construct_results
1261     or return undef;
1262
1263   return shift @{$self->{_stashed_results}};
1264 }
1265
1266 # Constructs as many results as it can in one pass while respecting
1267 # cursor laziness. Several modes of operation:
1268 #
1269 # * Always builds everything present in @{$self->{_stashed_rows}}
1270 # * If called with $fetch_all true - pulls everything off the cursor and
1271 #   builds all result structures (or objects) in one pass
1272 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1273 #   and if the resultset is ordered properly by the left side:
1274 #   * Fetches stuff off the cursor until the "master object" changes,
1275 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1276 #   OR
1277 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1278 #     was requested (there is no other way to collapse except for an
1279 #     eager cursor)
1280 # * If no collapse is requested - just get the next row, construct and
1281 #   return
1282 sub _construct_results {
1283   my ($self, $fetch_all) = @_;
1284
1285   my $rsrc = $self->result_source;
1286   my $attrs = $self->_resolved_attrs;
1287
1288   if (
1289     ! $fetch_all
1290       and
1291     ! $attrs->{order_by}
1292       and
1293     $attrs->{collapse}
1294       and
1295     my @pcols = $rsrc->primary_columns
1296   ) {
1297     # default order for collapsing unless the user asked for something
1298     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1299     $attrs->{_ordered_for_collapse} = 1;
1300     $attrs->{_order_is_artificial} = 1;
1301   }
1302
1303   # this will be used as both initial raw-row collector AND as a RV of
1304   # _construct_results. Not regrowing the array twice matters a lot...
1305   # a surprising amount actually
1306   my $rows = delete $self->{_stashed_rows};
1307
1308   my $cursor; # we may not need one at all
1309
1310   my $did_fetch_all = $fetch_all;
1311
1312   if ($fetch_all) {
1313     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1314     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1315   }
1316   elsif( $attrs->{collapse} ) {
1317
1318     # a cursor will need to be closed over in case of collapse
1319     $cursor = $self->cursor;
1320
1321     $attrs->{_ordered_for_collapse} = (
1322       (
1323         $attrs->{order_by}
1324           and
1325         $rsrc->schema
1326               ->storage
1327                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1328       ) ? 1 : 0
1329     ) unless defined $attrs->{_ordered_for_collapse};
1330
1331     if (! $attrs->{_ordered_for_collapse}) {
1332       $did_fetch_all = 1;
1333
1334       # instead of looping over ->next, use ->all in stealth mode
1335       # *without* calling a ->reset afterwards
1336       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1337       if (! $cursor->{_done}) {
1338         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1339         $cursor->{_done} = 1;
1340       }
1341     }
1342   }
1343
1344   if (! $did_fetch_all and ! @{$rows||[]} ) {
1345     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1346     $cursor ||= $self->cursor;
1347     if (scalar (my @r = $cursor->next) ) {
1348       $rows = [ \@r ];
1349     }
1350   }
1351
1352   return undef unless @{$rows||[]};
1353
1354   # sanity check - people are too clever for their own good
1355   if ($attrs->{collapse} and my $aliastypes = $attrs->{_sqlmaker_select_args}[3]{_aliastypes} ) {
1356
1357     my $multiplied_selectors;
1358     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1359       if (
1360         $aliastypes->{multiplying}{$sel_alias}
1361           or
1362         scalar grep { $aliastypes->{multiplying}{(values %$_)[0]} } @{ $aliastypes->{selecting}{$sel_alias}{-parents} }
1363       ) {
1364         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1365       }
1366     }
1367
1368     for my $i (0 .. $#{$attrs->{as}} ) {
1369       my $sel = $attrs->{select}[$i];
1370
1371       if (ref $sel eq 'SCALAR') {
1372         $sel = $$sel;
1373       }
1374       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1375         $sel = $$sel->[0];
1376       }
1377
1378       $self->throw_exception(
1379         'Result collapse not possible - selection from a has_many source redirected to the main object'
1380       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1381     }
1382   }
1383
1384   # hotspot - skip the setter
1385   my $res_class = $self->_result_class;
1386
1387   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1388     $res_class->can ('inflate_result')
1389       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1390   };
1391
1392   my $infmap = $attrs->{as};
1393
1394   $self->{_result_inflator}{is_core_row} = ( (
1395     $inflator_cref
1396       ==
1397     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1398   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1399
1400   $self->{_result_inflator}{is_hri} = ( (
1401     ! $self->{_result_inflator}{is_core_row}
1402       and
1403     $inflator_cref == (
1404       require DBIx::Class::ResultClass::HashRefInflator
1405         &&
1406       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1407     )
1408   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1409
1410
1411   if (! $attrs->{_related_results_construction}) {
1412     # construct a much simpler array->hash folder for the one-table cases right here
1413     if ($self->{_result_inflator}{is_hri}) {
1414       for my $r (@$rows) {
1415         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1416       }
1417     }
1418     # FIXME SUBOPTIMAL this is a very very very hot spot
1419     # while rather optimal we can *still* do much better, by
1420     # building a smarter Row::inflate_result(), and
1421     # switch to feeding it data via a much leaner interface
1422     #
1423     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1424     # this particular resultset size
1425     elsif (@$rows < 60) {
1426       for my $r (@$rows) {
1427         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1428       }
1429     }
1430     else {
1431       eval sprintf (
1432         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1433         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1434       );
1435     }
1436   }
1437   else {
1438     my $parser_type =
1439         $self->{_result_inflator}{is_hri}       ? 'hri'
1440       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1441       :                                           'classic_nonpruning'
1442     ;
1443
1444     # $args and $attrs to _mk_row_parser are separated to delineate what is
1445     # core collapser stuff and what is dbic $rs specific
1446     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1447       eval => 1,
1448       inflate_map => $infmap,
1449       collapse => $attrs->{collapse},
1450       premultiplied => $attrs->{_main_source_premultiplied},
1451       hri_style => $self->{_result_inflator}{is_hri},
1452       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1453     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1454
1455     # column_info metadata historically hasn't been too reliable.
1456     # We need to start fixing this somehow (the collapse resolver
1457     # can't work without it). Add an explicit check for the *main*
1458     # result, hopefully this will gradually weed out such errors
1459     #
1460     # FIXME - this is a temporary kludge that reduces performance
1461     # It is however necessary for the time being
1462     my ($unrolled_non_null_cols_to_check, $err);
1463
1464     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1465
1466       $err =
1467         'Collapse aborted due to invalid ResultSource metadata - the following '
1468       . 'selections are declared non-nullable but NULLs were retrieved: '
1469       ;
1470
1471       my @violating_idx;
1472       COL: for my $i (@$check_non_null_cols) {
1473         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1474       }
1475
1476       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1477         if @violating_idx;
1478
1479       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1480     }
1481
1482     my $next_cref =
1483       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1484     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1485 sub {
1486   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1487   my @r = $cursor->next or return;
1488   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1489     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1490   }
1491   \@r
1492 }
1493 EOS
1494     : sub {
1495         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1496         my @r = $cursor->next or return;
1497         \@r
1498       }
1499     ;
1500
1501     $self->{_row_parser}{$parser_type}{cref}->(
1502       $rows,
1503       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1504     );
1505
1506     # Special-case multi-object HRI - there is no $inflator_cref pass
1507     unless ($self->{_result_inflator}{is_hri}) {
1508       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1509     }
1510   }
1511
1512   # The @$rows check seems odd at first - why wouldn't we want to warn
1513   # regardless? The issue is things like find() etc, where the user
1514   # *knows* only one result will come back. In these cases the ->all
1515   # is not a pessimization, but rather something we actually want
1516   carp_unique(
1517     'Unable to properly collapse has_many results in iterator mode due '
1518   . 'to order criteria - performed an eager cursor slurp underneath. '
1519   . 'Consider using ->all() instead'
1520   ) if ( ! $fetch_all and @$rows > 1 );
1521
1522   return $rows;
1523 }
1524
1525 =head2 result_source
1526
1527 =over 4
1528
1529 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1530
1531 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1532
1533 =back
1534
1535 An accessor for the primary ResultSource object from which this ResultSet
1536 is derived.
1537
1538 =head2 result_class
1539
1540 =over 4
1541
1542 =item Arguments: $result_class?
1543
1544 =item Return Value: $result_class
1545
1546 =back
1547
1548 An accessor for the class to use when creating result objects. Defaults to
1549 C<< result_source->result_class >> - which in most cases is the name of the
1550 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1551
1552 Note that changing the result_class will also remove any components
1553 that were originally loaded in the source class via
1554 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1555 in the original source class will not run.
1556
1557 =cut
1558
1559 sub result_class {
1560   my ($self, $result_class) = @_;
1561   if ($result_class) {
1562
1563     # don't fire this for an object
1564     $self->ensure_class_loaded($result_class)
1565       unless ref($result_class);
1566
1567     if ($self->get_cache) {
1568       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1569     }
1570     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1571     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1572       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1573     }
1574
1575     $self->_result_class($result_class);
1576
1577     delete $self->{_result_inflator};
1578   }
1579   $self->_result_class;
1580 }
1581
1582 =head2 count
1583
1584 =over 4
1585
1586 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1587
1588 =item Return Value: $count
1589
1590 =back
1591
1592 Performs an SQL C<COUNT> with the same query as the resultset was built
1593 with to find the number of elements. Passing arguments is equivalent to
1594 C<< $rs->search ($cond, \%attrs)->count >>
1595
1596 =cut
1597
1598 sub count {
1599   my $self = shift;
1600   return $self->search(@_)->count if @_ and defined $_[0];
1601   return scalar @{ $self->get_cache } if $self->get_cache;
1602
1603   my $attrs = { %{ $self->_resolved_attrs } };
1604
1605   # this is a little optimization - it is faster to do the limit
1606   # adjustments in software, instead of a subquery
1607   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1608
1609   my $crs;
1610   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1611     $crs = $self->_count_subq_rs ($attrs);
1612   }
1613   else {
1614     $crs = $self->_count_rs ($attrs);
1615   }
1616   my $count = $crs->next;
1617
1618   $count -= $offset if $offset;
1619   $count = $rows if $rows and $rows < $count;
1620   $count = 0 if ($count < 0);
1621
1622   return $count;
1623 }
1624
1625 =head2 count_rs
1626
1627 =over 4
1628
1629 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1630
1631 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1632
1633 =back
1634
1635 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1636 This can be very handy for subqueries:
1637
1638   ->search( { amount => $some_rs->count_rs->as_query } )
1639
1640 As with regular resultsets the SQL query will be executed only after
1641 the resultset is accessed via L</next> or L</all>. That would return
1642 the same single value obtainable via L</count>.
1643
1644 =cut
1645
1646 sub count_rs {
1647   my $self = shift;
1648   return $self->search(@_)->count_rs if @_;
1649
1650   # this may look like a lack of abstraction (count() does about the same)
1651   # but in fact an _rs *must* use a subquery for the limits, as the
1652   # software based limiting can not be ported if this $rs is to be used
1653   # in a subquery itself (i.e. ->as_query)
1654   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1655     return $self->_count_subq_rs($self->{_attrs});
1656   }
1657   else {
1658     return $self->_count_rs($self->{_attrs});
1659   }
1660 }
1661
1662 #
1663 # returns a ResultSetColumn object tied to the count query
1664 #
1665 sub _count_rs {
1666   my ($self, $attrs) = @_;
1667
1668   my $rsrc = $self->result_source;
1669
1670   my $tmp_attrs = { %$attrs };
1671   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1672   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1673
1674   # overwrite the selector (supplied by the storage)
1675   $rsrc->resultset_class->new($rsrc, {
1676     %$tmp_attrs,
1677     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1678     as => 'count',
1679   })->get_column ('count');
1680 }
1681
1682 #
1683 # same as above but uses a subquery
1684 #
1685 sub _count_subq_rs {
1686   my ($self, $attrs) = @_;
1687
1688   my $rsrc = $self->result_source;
1689
1690   my $sub_attrs = { %$attrs };
1691   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1692   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1693
1694   # if we multi-prefetch we group_by something unique, as this is what we would
1695   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1696   if ( $attrs->{collapse}  ) {
1697     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1698       $rsrc->_identifying_column_set || $self->throw_exception(
1699         'Unable to construct a unique group_by criteria properly collapsing the '
1700       . 'has_many prefetch before count()'
1701       );
1702     } ]
1703   }
1704
1705   # Calculate subquery selector
1706   if (my $g = $sub_attrs->{group_by}) {
1707
1708     my $sql_maker = $rsrc->storage->sql_maker;
1709
1710     # necessary as the group_by may refer to aliased functions
1711     my $sel_index;
1712     for my $sel (@{$attrs->{select}}) {
1713       $sel_index->{$sel->{-as}} = $sel
1714         if (ref $sel eq 'HASH' and $sel->{-as});
1715     }
1716
1717     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1718     # also look for named aggregates referred in the having clause
1719     # having often contains scalarrefs - thus parse it out entirely
1720     my @parts = @$g;
1721     if ($attrs->{having}) {
1722       local $sql_maker->{having_bind};
1723       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1724       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1725       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1726         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1727         # if we don't unset it we screw up retarded but unfortunately working
1728         # 'MAX(foo.bar)' => { '>', 3 }
1729         $sql_maker->{name_sep} = '';
1730       }
1731
1732       $sql_maker->clear_renderer;
1733       $sql_maker->clear_converter;
1734
1735       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1736
1737       my $having_sql = $sql_maker->_render_sqla(where => $attrs->{having});
1738
1739       $sql_maker->clear_renderer;
1740       $sql_maker->clear_converter;
1741
1742       my %seen_having;
1743
1744       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1745       # and if all fails for an utterly naive quoted scalar-with-function
1746       while ($having_sql =~ /
1747         (?: $rquote $sep)? $lquote (.+?) $rquote
1748           |
1749         [\s,] \w+ \. (\w+) [\s,]
1750           |
1751         [\s,] $lquote (.+?) $rquote [\s,]
1752       /gx) {
1753         my $part = $1 || $2 || $3;  # one of them matched if we got here
1754         unless ($seen_having{$part}++) {
1755           push @parts, $part;
1756         }
1757       }
1758     }
1759
1760     for (@parts) {
1761       my $colpiece = $sel_index->{$_} || $_;
1762
1763       # unqualify join-based group_by's. Arcane but possible query
1764       # also horrible horrible hack to alias a column (not a func.)
1765       # (probably need to introduce SQLA syntax)
1766       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1767         my $as = $colpiece;
1768         $as =~ s/\./__/;
1769         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1770       }
1771       push @{$sub_attrs->{select}}, $colpiece;
1772     }
1773   }
1774   else {
1775     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1776     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1777   }
1778
1779   return $rsrc->resultset_class
1780                ->new ($rsrc, $sub_attrs)
1781                 ->as_subselect_rs
1782                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1783                   ->get_column ('count');
1784 }
1785
1786
1787 =head2 count_literal
1788
1789 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1790 should only be used in that context. See L</search_literal> for further info.
1791
1792 =over 4
1793
1794 =item Arguments: $sql_fragment, @standalone_bind_values
1795
1796 =item Return Value: $count
1797
1798 =back
1799
1800 Counts the results in a literal query. Equivalent to calling L</search_literal>
1801 with the passed arguments, then L</count>.
1802
1803 =cut
1804
1805 sub count_literal { shift->search_literal(@_)->count; }
1806
1807 =head2 all
1808
1809 =over 4
1810
1811 =item Arguments: none
1812
1813 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1814
1815 =back
1816
1817 Returns all elements in the resultset.
1818
1819 =cut
1820
1821 sub all {
1822   my $self = shift;
1823   if(@_) {
1824     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1825   }
1826
1827   delete @{$self}{qw/_stashed_rows _stashed_results/};
1828
1829   if (my $c = $self->get_cache) {
1830     return @$c;
1831   }
1832
1833   $self->cursor->reset;
1834
1835   my $objs = $self->_construct_results('fetch_all') || [];
1836
1837   $self->set_cache($objs) if $self->{attrs}{cache};
1838
1839   return @$objs;
1840 }
1841
1842 =head2 reset
1843
1844 =over 4
1845
1846 =item Arguments: none
1847
1848 =item Return Value: $self
1849
1850 =back
1851
1852 Resets the resultset's cursor, so you can iterate through the elements again.
1853 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1854 another query.
1855
1856 =cut
1857
1858 sub reset {
1859   my ($self) = @_;
1860
1861   delete @{$self}{qw/_stashed_rows _stashed_results/};
1862   $self->{all_cache_position} = 0;
1863   $self->cursor->reset;
1864   return $self;
1865 }
1866
1867 =head2 first
1868
1869 =over 4
1870
1871 =item Arguments: none
1872
1873 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1874
1875 =back
1876
1877 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1878 an object for the first result (or C<undef> if the resultset is empty).
1879
1880 =cut
1881
1882 sub first {
1883   return $_[0]->reset->next;
1884 }
1885
1886
1887 # _rs_update_delete
1888 #
1889 # Determines whether and what type of subquery is required for the $rs operation.
1890 # If grouping is necessary either supplies its own, or verifies the current one
1891 # After all is done delegates to the proper storage method.
1892
1893 sub _rs_update_delete {
1894   my ($self, $op, $values) = @_;
1895
1896   my $rsrc = $self->result_source;
1897   my $storage = $rsrc->schema->storage;
1898
1899   my $attrs = { %{$self->_resolved_attrs} };
1900
1901   my $join_classifications;
1902   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1903
1904   # do we need a subquery for any reason?
1905   my $needs_subq = (
1906     defined $existing_group_by
1907       or
1908     # if {from} is unparseable wrap a subq
1909     ref($attrs->{from}) ne 'ARRAY'
1910       or
1911     # limits call for a subq
1912     $self->_has_resolved_attr(qw/rows offset/)
1913   );
1914
1915   # simplify the joinmap, so we can further decide if a subq is necessary
1916   if (!$needs_subq and @{$attrs->{from}} > 1) {
1917
1918     ($attrs->{from}, $join_classifications) =
1919       $storage->_prune_unused_joins ($attrs->{from}, $attrs->{select}, $self->{cond}, $attrs);
1920
1921     # any non-pruneable non-local restricting joins imply subq
1922     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1923   }
1924
1925   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1926   $needs_subq ||= (
1927     (ref $attrs->{from}[0]) ne 'HASH'
1928       or
1929     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1930   );
1931
1932   my ($cond, $guard);
1933   # do we need anything like a subquery?
1934   if (! $needs_subq) {
1935     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1936     # a condition containing 'me' or other table prefixes will not work
1937     # at all - so we convert the WHERE to a dq tree now, dequalify all
1938     # identifiers found therein via a scan across the tree, and then use
1939     # \{} style to pass the result onwards for use in the final query
1940     if ($self->{cond}) {
1941       $cond = do {
1942         my $converter = $rsrc->storage->sql_maker->converter;
1943         scan_dq_nodes({
1944           DQ_IDENTIFIER ,=> sub { $_ = [ $_->[-1] ] for $_[0]->{elements} }
1945         }, my $where_dq = $converter->_where_to_dq($self->{cond}));
1946         \$where_dq;
1947       };
1948     }
1949   }
1950   else {
1951     # we got this far - means it is time to wrap a subquery
1952     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1953       sprintf(
1954         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1955         $op,
1956         $rsrc->source_name,
1957       )
1958     );
1959
1960     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1961     delete $attrs->{$_} for qw/select as collapse/;
1962     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1963
1964     # this will be consumed by the pruner waaaaay down the stack
1965     $attrs->{_force_prune_multiplying_joins} = 1;
1966
1967     my $subrs = (ref $self)->new($rsrc, $attrs);
1968
1969     if (@$idcols == 1) {
1970       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1971     }
1972     elsif ($storage->_use_multicolumn_in) {
1973       # no syntax for calling this properly yet
1974       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1975       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1976         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1977         $subrs->as_query
1978       ),
1979     }
1980     else {
1981       # if all else fails - get all primary keys and operate over a ORed set
1982       # wrap in a transaction for consistency
1983       # this is where the group_by/multiplication starts to matter
1984       if (
1985         $existing_group_by
1986           or
1987         keys %{ $join_classifications->{multiplying} || {} }
1988       ) {
1989         # make sure if there is a supplied group_by it matches the columns compiled above
1990         # perfectly. Anything else can not be sanely executed on most databases so croak
1991         # right then and there
1992         if ($existing_group_by) {
1993           my @current_group_by = map
1994             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1995             @$existing_group_by
1996           ;
1997
1998           if (
1999             join ("\x00", sort @current_group_by)
2000               ne
2001             join ("\x00", sort @{$attrs->{columns}} )
2002           ) {
2003             $self->throw_exception (
2004               "You have just attempted a $op operation on a resultset which does group_by"
2005               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
2006               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
2007               . ' kind of queries. Please retry the operation with a modified group_by or'
2008               . ' without using one at all.'
2009             );
2010           }
2011         }
2012
2013         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2014       }
2015
2016       $guard = $storage->txn_scope_guard;
2017
2018       $cond = [];
2019       for my $row ($subrs->cursor->all) {
2020         push @$cond, { map
2021           { $idcols->[$_] => $row->[$_] }
2022           (0 .. $#$idcols)
2023         };
2024       }
2025     }
2026   }
2027
2028   my $res = $storage->$op (
2029     $rsrc,
2030     $op eq 'update' ? $values : (),
2031     $cond,
2032   );
2033
2034   $guard->commit if $guard;
2035
2036   return $res;
2037 }
2038
2039 =head2 update
2040
2041 =over 4
2042
2043 =item Arguments: \%values
2044
2045 =item Return Value: $underlying_storage_rv
2046
2047 =back
2048
2049 Sets the specified columns in the resultset to the supplied values in a
2050 single query. Note that this will not run any accessor/set_column/update
2051 triggers, nor will it update any result object instances derived from this
2052 resultset (this includes the contents of the L<resultset cache|/set_cache>
2053 if any). See L</update_all> if you need to execute any on-update
2054 triggers or cascades defined either by you or a
2055 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2056
2057 The return value is a pass through of what the underlying
2058 storage backend returned, and may vary. See L<DBI/execute> for the most
2059 common case.
2060
2061 =head3 CAVEAT
2062
2063 Note that L</update> does not process/deflate any of the values passed in.
2064 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2065 ensure manually that any value passed to this method will stringify to
2066 something the RDBMS knows how to deal with. A notable example is the
2067 handling of L<DateTime> objects, for more info see:
2068 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2069
2070 =cut
2071
2072 sub update {
2073   my ($self, $values) = @_;
2074   $self->throw_exception('Values for update must be a hash')
2075     unless ref $values eq 'HASH';
2076
2077   return $self->_rs_update_delete ('update', $values);
2078 }
2079
2080 =head2 update_all
2081
2082 =over 4
2083
2084 =item Arguments: \%values
2085
2086 =item Return Value: 1
2087
2088 =back
2089
2090 Fetches all objects and updates them one at a time via
2091 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2092 triggers, while L</update> will not.
2093
2094 =cut
2095
2096 sub update_all {
2097   my ($self, $values) = @_;
2098   $self->throw_exception('Values for update_all must be a hash')
2099     unless ref $values eq 'HASH';
2100
2101   my $guard = $self->result_source->schema->txn_scope_guard;
2102   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2103   $guard->commit;
2104   return 1;
2105 }
2106
2107 =head2 delete
2108
2109 =over 4
2110
2111 =item Arguments: none
2112
2113 =item Return Value: $underlying_storage_rv
2114
2115 =back
2116
2117 Deletes the rows matching this resultset in a single query. Note that this
2118 will not run any delete triggers, nor will it alter the
2119 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2120 derived from this resultset (this includes the contents of the
2121 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2122 execute any on-delete triggers or cascades defined either by you or a
2123 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2124
2125 The return value is a pass through of what the underlying storage backend
2126 returned, and may vary. See L<DBI/execute> for the most common case.
2127
2128 =cut
2129
2130 sub delete {
2131   my $self = shift;
2132   $self->throw_exception('delete does not accept any arguments')
2133     if @_;
2134
2135   return $self->_rs_update_delete ('delete');
2136 }
2137
2138 =head2 delete_all
2139
2140 =over 4
2141
2142 =item Arguments: none
2143
2144 =item Return Value: 1
2145
2146 =back
2147
2148 Fetches all objects and deletes them one at a time via
2149 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2150 triggers, while L</delete> will not.
2151
2152 =cut
2153
2154 sub delete_all {
2155   my $self = shift;
2156   $self->throw_exception('delete_all does not accept any arguments')
2157     if @_;
2158
2159   my $guard = $self->result_source->schema->txn_scope_guard;
2160   $_->delete for $self->all;
2161   $guard->commit;
2162   return 1;
2163 }
2164
2165 =head2 populate
2166
2167 =over 4
2168
2169 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2170
2171 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2172
2173 =back
2174
2175 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2176 arrayrefs.
2177
2178 =over
2179
2180 =item NOTE
2181
2182 The context of this method call has an important effect on what is
2183 submitted to storage. In void context data is fed directly to fastpath
2184 insertion routines provided by the underlying storage (most often
2185 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2186 L<insert|DBIx::Class::Row/insert> calls on the
2187 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2188 augmentation of these methods provided by components. For example if you
2189 are using something like L<DBIx::Class::UUIDColumns> to create primary
2190 keys for you, you will find that your PKs are empty.  In this case you
2191 will have to explicitly force scalar or list context in order to create
2192 those values.
2193
2194 =back
2195
2196 In non-void (scalar or list) context, this method is simply a wrapper
2197 for L</create>. Depending on list or scalar context either a list of
2198 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2199 containing these objects is returned.
2200
2201 When supplying data in "arrayref of arrayrefs" invocation style, the
2202 first element should be a list of column names and each subsequent
2203 element should be a data value in the earlier specified column order.
2204 For example:
2205
2206   $schema->resultset("Artist")->populate([
2207     [ qw( artistid name ) ],
2208     [ 100, 'A Formally Unknown Singer' ],
2209     [ 101, 'A singer that jumped the shark two albums ago' ],
2210     [ 102, 'An actually cool singer' ],
2211   ]);
2212
2213 For the arrayref of hashrefs style each hashref should be a structure
2214 suitable for passing to L</create>. Multi-create is also permitted with
2215 this syntax.
2216
2217   $schema->resultset("Artist")->populate([
2218      { artistid => 4, name => 'Manufactured Crap', cds => [
2219         { title => 'My First CD', year => 2006 },
2220         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2221       ],
2222      },
2223      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2224         { title => 'My parents sold me to a record company', year => 2005 },
2225         { title => 'Why Am I So Ugly?', year => 2006 },
2226         { title => 'I Got Surgery and am now Popular', year => 2007 }
2227       ],
2228      },
2229   ]);
2230
2231 If you attempt a void-context multi-create as in the example above (each
2232 Artist also has the related list of CDs), and B<do not> supply the
2233 necessary autoinc foreign key information, this method will proxy to the
2234 less efficient L</create>, and then throw the Result objects away. In this
2235 case there are obviously no benefits to using this method over L</create>.
2236
2237 =cut
2238
2239 sub populate {
2240   my $self = shift;
2241
2242   # cruft placed in standalone method
2243   my $data = $self->_normalize_populate_args(@_);
2244
2245   return unless @$data;
2246
2247   if(defined wantarray) {
2248     my @created = map { $self->create($_) } @$data;
2249     return wantarray ? @created : \@created;
2250   }
2251   else {
2252     my $first = $data->[0];
2253
2254     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2255     # it relationship data
2256     my (@rels, @columns);
2257     my $rsrc = $self->result_source;
2258     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2259     for (keys %$first) {
2260       my $ref = ref $first->{$_};
2261       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2262         ? push @rels, $_
2263         : push @columns, $_
2264       ;
2265     }
2266
2267     my @pks = $rsrc->primary_columns;
2268
2269     ## do the belongs_to relationships
2270     foreach my $index (0..$#$data) {
2271
2272       # delegate to create() for any dataset without primary keys with specified relationships
2273       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2274         for my $r (@rels) {
2275           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2276             my @ret = $self->populate($data);
2277             return;
2278           }
2279         }
2280       }
2281
2282       foreach my $rel (@rels) {
2283         next unless ref $data->[$index]->{$rel} eq "HASH";
2284         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2285         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2286         my $related = $result->result_source->_resolve_condition(
2287           $reverse_relinfo->{cond},
2288           $self,
2289           $result,
2290           $rel,
2291         );
2292
2293         delete $data->[$index]->{$rel};
2294         $data->[$index] = {%{$data->[$index]}, %$related};
2295
2296         push @columns, keys %$related if $index == 0;
2297       }
2298     }
2299
2300     ## inherit the data locked in the conditions of the resultset
2301     my ($rs_data) = $self->_merge_with_rscond({});
2302     delete @{$rs_data}{@columns};
2303
2304     ## do bulk insert on current row
2305     $rsrc->storage->insert_bulk(
2306       $rsrc,
2307       [@columns, keys %$rs_data],
2308       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2309     );
2310
2311     ## do the has_many relationships
2312     foreach my $item (@$data) {
2313
2314       my $main_row;
2315
2316       foreach my $rel (@rels) {
2317         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2318
2319         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2320
2321         my $child = $main_row->$rel;
2322
2323         my $related = $child->result_source->_resolve_condition(
2324           $rels->{$rel}{cond},
2325           $child,
2326           $main_row,
2327           $rel,
2328         );
2329
2330         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2331         my @populate = map { {%$_, %$related} } @rows_to_add;
2332
2333         $child->populate( \@populate );
2334       }
2335     }
2336   }
2337 }
2338
2339
2340 # populate() arguments went over several incarnations
2341 # What we ultimately support is AoH
2342 sub _normalize_populate_args {
2343   my ($self, $arg) = @_;
2344
2345   if (ref $arg eq 'ARRAY') {
2346     if (!@$arg) {
2347       return [];
2348     }
2349     elsif (ref $arg->[0] eq 'HASH') {
2350       return $arg;
2351     }
2352     elsif (ref $arg->[0] eq 'ARRAY') {
2353       my @ret;
2354       my @colnames = @{$arg->[0]};
2355       foreach my $values (@{$arg}[1 .. $#$arg]) {
2356         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2357       }
2358       return \@ret;
2359     }
2360   }
2361
2362   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2363 }
2364
2365 =head2 pager
2366
2367 =over 4
2368
2369 =item Arguments: none
2370
2371 =item Return Value: L<$pager|Data::Page>
2372
2373 =back
2374
2375 Returns a L<Data::Page> object for the current resultset. Only makes
2376 sense for queries with a C<page> attribute.
2377
2378 To get the full count of entries for a paged resultset, call
2379 C<total_entries> on the L<Data::Page> object.
2380
2381 =cut
2382
2383 sub pager {
2384   my ($self) = @_;
2385
2386   return $self->{pager} if $self->{pager};
2387
2388   my $attrs = $self->{attrs};
2389   if (!defined $attrs->{page}) {
2390     $self->throw_exception("Can't create pager for non-paged rs");
2391   }
2392   elsif ($attrs->{page} <= 0) {
2393     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2394   }
2395   $attrs->{rows} ||= 10;
2396
2397   # throw away the paging flags and re-run the count (possibly
2398   # with a subselect) to get the real total count
2399   my $count_attrs = { %$attrs };
2400   delete @{$count_attrs}{qw/rows offset page pager/};
2401
2402   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2403
2404   require DBIx::Class::ResultSet::Pager;
2405   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2406     sub { $total_rs->count },  #lazy-get the total
2407     $attrs->{rows},
2408     $self->{attrs}{page},
2409   );
2410 }
2411
2412 =head2 page
2413
2414 =over 4
2415
2416 =item Arguments: $page_number
2417
2418 =item Return Value: L<$resultset|/search>
2419
2420 =back
2421
2422 Returns a resultset for the $page_number page of the resultset on which page
2423 is called, where each page contains a number of rows equal to the 'rows'
2424 attribute set on the resultset (10 by default).
2425
2426 =cut
2427
2428 sub page {
2429   my ($self, $page) = @_;
2430   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2431 }
2432
2433 =head2 new_result
2434
2435 =over 4
2436
2437 =item Arguments: \%col_data
2438
2439 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2440
2441 =back
2442
2443 Creates a new result object in the resultset's result class and returns
2444 it. The row is not inserted into the database at this point, call
2445 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2446 will tell you whether the result object has been inserted or not.
2447
2448 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2449
2450 =cut
2451
2452 sub new_result {
2453   my ($self, $values) = @_;
2454
2455   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2456     if @_ > 2;
2457
2458   $self->throw_exception( "new_result expects a hashref" )
2459     unless (ref $values eq 'HASH');
2460
2461   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2462
2463   my $new = $self->result_class->new({
2464     %$merged_cond,
2465     ( @$cols_from_relations
2466       ? (-cols_from_relations => $cols_from_relations)
2467       : ()
2468     ),
2469     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2470   });
2471
2472   if (
2473     reftype($new) eq 'HASH'
2474       and
2475     ! keys %$new
2476       and
2477     blessed($new)
2478   ) {
2479     carp_unique (sprintf (
2480       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2481       $self->result_class,
2482     ));
2483   }
2484
2485   $new;
2486 }
2487
2488 # _merge_with_rscond
2489 #
2490 # Takes a simple hash of K/V data and returns its copy merged with the
2491 # condition already present on the resultset. Additionally returns an
2492 # arrayref of value/condition names, which were inferred from related
2493 # objects (this is needed for in-memory related objects)
2494 sub _merge_with_rscond {
2495   my ($self, $data) = @_;
2496
2497   my (%new_data, @cols_from_relations);
2498
2499   my $alias = $self->{attrs}{alias};
2500
2501   if (! defined $self->{cond}) {
2502     # just massage $data below
2503   }
2504   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2505     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2506     @cols_from_relations = keys %new_data;
2507   }
2508   elsif (ref $self->{cond} ne 'HASH') {
2509     $self->throw_exception(
2510       "Can't abstract implicit construct, resultset condition not a hash"
2511     );
2512   }
2513   else {
2514     # precedence must be given to passed values over values inherited from
2515     # the cond, so the order here is important.
2516     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2517     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2518
2519     while ( my($col, $value) = each %implied ) {
2520       my $vref = ref $value;
2521       if (
2522         $vref eq 'HASH'
2523           and
2524         keys(%$value) == 1
2525           and
2526         (keys %$value)[0] eq '='
2527       ) {
2528         $new_data{$col} = $value->{'='};
2529       }
2530       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2531         $new_data{$col} = $value;
2532       }
2533     }
2534   }
2535
2536   %new_data = (
2537     %new_data,
2538     %{ $self->_remove_alias($data, $alias) },
2539   );
2540
2541   return (\%new_data, \@cols_from_relations);
2542 }
2543
2544 # _has_resolved_attr
2545 #
2546 # determines if the resultset defines at least one
2547 # of the attributes supplied
2548 #
2549 # used to determine if a subquery is necessary
2550 #
2551 # supports some virtual attributes:
2552 #   -join
2553 #     This will scan for any joins being present on the resultset.
2554 #     It is not a mere key-search but a deep inspection of {from}
2555 #
2556
2557 sub _has_resolved_attr {
2558   my ($self, @attr_names) = @_;
2559
2560   my $attrs = $self->_resolved_attrs;
2561
2562   my %extra_checks;
2563
2564   for my $n (@attr_names) {
2565     if (grep { $n eq $_ } (qw/-join/) ) {
2566       $extra_checks{$n}++;
2567       next;
2568     }
2569
2570     my $attr =  $attrs->{$n};
2571
2572     next if not defined $attr;
2573
2574     if (ref $attr eq 'HASH') {
2575       return 1 if keys %$attr;
2576     }
2577     elsif (ref $attr eq 'ARRAY') {
2578       return 1 if @$attr;
2579     }
2580     else {
2581       return 1 if $attr;
2582     }
2583   }
2584
2585   # a resolved join is expressed as a multi-level from
2586   return 1 if (
2587     $extra_checks{-join}
2588       and
2589     ref $attrs->{from} eq 'ARRAY'
2590       and
2591     @{$attrs->{from}} > 1
2592   );
2593
2594   return 0;
2595 }
2596
2597 # _collapse_cond
2598 #
2599 # Recursively collapse the condition.
2600
2601 sub _collapse_cond {
2602   my ($self, $cond, $collapsed) = @_;
2603
2604   $collapsed ||= {};
2605
2606   if (ref $cond eq 'ARRAY') {
2607     foreach my $subcond (@$cond) {
2608       next unless ref $subcond;  # -or
2609       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2610     }
2611   }
2612   elsif (ref $cond eq 'HASH') {
2613     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2614       foreach my $subcond (@{$cond->{-and}}) {
2615         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2616       }
2617     }
2618     else {
2619       foreach my $col (keys %$cond) {
2620         my $value = $cond->{$col};
2621         $collapsed->{$col} = $value;
2622       }
2623     }
2624   }
2625
2626   return $collapsed;
2627 }
2628
2629 # _remove_alias
2630 #
2631 # Remove the specified alias from the specified query hash. A copy is made so
2632 # the original query is not modified.
2633
2634 sub _remove_alias {
2635   my ($self, $query, $alias) = @_;
2636
2637   my %orig = %{ $query || {} };
2638   my %unaliased;
2639
2640   foreach my $key (keys %orig) {
2641     if ($key !~ /\./) {
2642       $unaliased{$key} = $orig{$key};
2643       next;
2644     }
2645     $unaliased{$1} = $orig{$key}
2646       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2647   }
2648
2649   return \%unaliased;
2650 }
2651
2652 =head2 as_query
2653
2654 =over 4
2655
2656 =item Arguments: none
2657
2658 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2659
2660 =back
2661
2662 Returns the SQL query and bind vars associated with the invocant.
2663
2664 This is generally used as the RHS for a subquery.
2665
2666 =cut
2667
2668 sub as_query {
2669   my $self = shift;
2670
2671   my $attrs = { %{ $self->_resolved_attrs } };
2672
2673   my $aq = $self->result_source->storage->_select_args_to_query (
2674     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2675   );
2676
2677   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
2678
2679   $aq;
2680 }
2681
2682 =head2 find_or_new
2683
2684 =over 4
2685
2686 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2687
2688 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2689
2690 =back
2691
2692   my $artist = $schema->resultset('Artist')->find_or_new(
2693     { artist => 'fred' }, { key => 'artists' });
2694
2695   $cd->cd_to_producer->find_or_new({ producer => $producer },
2696                                    { key => 'primary' });
2697
2698 Find an existing record from this resultset using L</find>. if none exists,
2699 instantiate a new result object and return it. The object will not be saved
2700 into your storage until you call L<DBIx::Class::Row/insert> on it.
2701
2702 You most likely want this method when looking for existing rows using a unique
2703 constraint that is not the primary key, or looking for related rows.
2704
2705 If you want objects to be saved immediately, use L</find_or_create> instead.
2706
2707 B<Note>: Make sure to read the documentation of L</find> and understand the
2708 significance of the C<key> attribute, as its lack may skew your search, and
2709 subsequently result in spurious new objects.
2710
2711 B<Note>: Take care when using C<find_or_new> with a table having
2712 columns with default values that you intend to be automatically
2713 supplied by the database (e.g. an auto_increment primary key column).
2714 In normal usage, the value of such columns should NOT be included at
2715 all in the call to C<find_or_new>, even when set to C<undef>.
2716
2717 =cut
2718
2719 sub find_or_new {
2720   my $self     = shift;
2721   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2722   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2723   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2724     return $row;
2725   }
2726   return $self->new_result($hash);
2727 }
2728
2729 =head2 create
2730
2731 =over 4
2732
2733 =item Arguments: \%col_data
2734
2735 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2736
2737 =back
2738
2739 Attempt to create a single new row or a row with multiple related rows
2740 in the table represented by the resultset (and related tables). This
2741 will not check for duplicate rows before inserting, use
2742 L</find_or_create> to do that.
2743
2744 To create one row for this resultset, pass a hashref of key/value
2745 pairs representing the columns of the table and the values you wish to
2746 store. If the appropriate relationships are set up, foreign key fields
2747 can also be passed an object representing the foreign row, and the
2748 value will be set to its primary key.
2749
2750 To create related objects, pass a hashref of related-object column values
2751 B<keyed on the relationship name>. If the relationship is of type C<multi>
2752 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2753 The process will correctly identify columns holding foreign keys, and will
2754 transparently populate them from the keys of the corresponding relation.
2755 This can be applied recursively, and will work correctly for a structure
2756 with an arbitrary depth and width, as long as the relationships actually
2757 exists and the correct column data has been supplied.
2758
2759 Instead of hashrefs of plain related data (key/value pairs), you may
2760 also pass new or inserted objects. New objects (not inserted yet, see
2761 L</new_result>), will be inserted into their appropriate tables.
2762
2763 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2764
2765 Example of creating a new row.
2766
2767   $person_rs->create({
2768     name=>"Some Person",
2769     email=>"somebody@someplace.com"
2770   });
2771
2772 Example of creating a new row and also creating rows in a related C<has_many>
2773 or C<has_one> resultset.  Note Arrayref.
2774
2775   $artist_rs->create(
2776      { artistid => 4, name => 'Manufactured Crap', cds => [
2777         { title => 'My First CD', year => 2006 },
2778         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2779       ],
2780      },
2781   );
2782
2783 Example of creating a new row and also creating a row in a related
2784 C<belongs_to> resultset. Note Hashref.
2785
2786   $cd_rs->create({
2787     title=>"Music for Silly Walks",
2788     year=>2000,
2789     artist => {
2790       name=>"Silly Musician",
2791     }
2792   });
2793
2794 =over
2795
2796 =item WARNING
2797
2798 When subclassing ResultSet never attempt to override this method. Since
2799 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2800 lot of the internals simply never call it, so your override will be
2801 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2802 or L<DBIx::Class::Row/insert> depending on how early in the
2803 L</create> process you need to intervene. See also warning pertaining to
2804 L</new>.
2805
2806 =back
2807
2808 =cut
2809
2810 sub create {
2811   my ($self, $col_data) = @_;
2812   $self->throw_exception( "create needs a hashref" )
2813     unless ref $col_data eq 'HASH';
2814   return $self->new_result($col_data)->insert;
2815 }
2816
2817 =head2 find_or_create
2818
2819 =over 4
2820
2821 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2822
2823 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2824
2825 =back
2826
2827   $cd->cd_to_producer->find_or_create({ producer => $producer },
2828                                       { key => 'primary' });
2829
2830 Tries to find a record based on its primary key or unique constraints; if none
2831 is found, creates one and returns that instead.
2832
2833   my $cd = $schema->resultset('CD')->find_or_create({
2834     cdid   => 5,
2835     artist => 'Massive Attack',
2836     title  => 'Mezzanine',
2837     year   => 2005,
2838   });
2839
2840 Also takes an optional C<key> attribute, to search by a specific key or unique
2841 constraint. For example:
2842
2843   my $cd = $schema->resultset('CD')->find_or_create(
2844     {
2845       artist => 'Massive Attack',
2846       title  => 'Mezzanine',
2847     },
2848     { key => 'cd_artist_title' }
2849   );
2850
2851 B<Note>: Make sure to read the documentation of L</find> and understand the
2852 significance of the C<key> attribute, as its lack may skew your search, and
2853 subsequently result in spurious row creation.
2854
2855 B<Note>: Because find_or_create() reads from the database and then
2856 possibly inserts based on the result, this method is subject to a race
2857 condition. Another process could create a record in the table after
2858 the find has completed and before the create has started. To avoid
2859 this problem, use find_or_create() inside a transaction.
2860
2861 B<Note>: Take care when using C<find_or_create> with a table having
2862 columns with default values that you intend to be automatically
2863 supplied by the database (e.g. an auto_increment primary key column).
2864 In normal usage, the value of such columns should NOT be included at
2865 all in the call to C<find_or_create>, even when set to C<undef>.
2866
2867 See also L</find> and L</update_or_create>. For information on how to declare
2868 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2869
2870 If you need to know if an existing row was found or a new one created use
2871 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2872 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2873 database!
2874
2875   my $cd = $schema->resultset('CD')->find_or_new({
2876     cdid   => 5,
2877     artist => 'Massive Attack',
2878     title  => 'Mezzanine',
2879     year   => 2005,
2880   });
2881
2882   if( !$cd->in_storage ) {
2883       # do some stuff
2884       $cd->insert;
2885   }
2886
2887 =cut
2888
2889 sub find_or_create {
2890   my $self     = shift;
2891   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2892   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2893   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2894     return $row;
2895   }
2896   return $self->create($hash);
2897 }
2898
2899 =head2 update_or_create
2900
2901 =over 4
2902
2903 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2904
2905 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2906
2907 =back
2908
2909   $resultset->update_or_create({ col => $val, ... });
2910
2911 Like L</find_or_create>, but if a row is found it is immediately updated via
2912 C<< $found_row->update (\%col_data) >>.
2913
2914
2915 Takes an optional C<key> attribute to search on a specific unique constraint.
2916 For example:
2917
2918   # In your application
2919   my $cd = $schema->resultset('CD')->update_or_create(
2920     {
2921       artist => 'Massive Attack',
2922       title  => 'Mezzanine',
2923       year   => 1998,
2924     },
2925     { key => 'cd_artist_title' }
2926   );
2927
2928   $cd->cd_to_producer->update_or_create({
2929     producer => $producer,
2930     name => 'harry',
2931   }, {
2932     key => 'primary',
2933   });
2934
2935 B<Note>: Make sure to read the documentation of L</find> and understand the
2936 significance of the C<key> attribute, as its lack may skew your search, and
2937 subsequently result in spurious row creation.
2938
2939 B<Note>: Take care when using C<update_or_create> with a table having
2940 columns with default values that you intend to be automatically
2941 supplied by the database (e.g. an auto_increment primary key column).
2942 In normal usage, the value of such columns should NOT be included at
2943 all in the call to C<update_or_create>, even when set to C<undef>.
2944
2945 See also L</find> and L</find_or_create>. For information on how to declare
2946 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2947
2948 If you need to know if an existing row was updated or a new one created use
2949 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2950 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2951 database!
2952
2953 =cut
2954
2955 sub update_or_create {
2956   my $self = shift;
2957   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2958   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2959
2960   my $row = $self->find($cond, $attrs);
2961   if (defined $row) {
2962     $row->update($cond);
2963     return $row;
2964   }
2965
2966   return $self->create($cond);
2967 }
2968
2969 =head2 update_or_new
2970
2971 =over 4
2972
2973 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2974
2975 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2976
2977 =back
2978
2979   $resultset->update_or_new({ col => $val, ... });
2980
2981 Like L</find_or_new> but if a row is found it is immediately updated via
2982 C<< $found_row->update (\%col_data) >>.
2983
2984 For example:
2985
2986   # In your application
2987   my $cd = $schema->resultset('CD')->update_or_new(
2988     {
2989       artist => 'Massive Attack',
2990       title  => 'Mezzanine',
2991       year   => 1998,
2992     },
2993     { key => 'cd_artist_title' }
2994   );
2995
2996   if ($cd->in_storage) {
2997       # the cd was updated
2998   }
2999   else {
3000       # the cd is not yet in the database, let's insert it
3001       $cd->insert;
3002   }
3003
3004 B<Note>: Make sure to read the documentation of L</find> and understand the
3005 significance of the C<key> attribute, as its lack may skew your search, and
3006 subsequently result in spurious new objects.
3007
3008 B<Note>: Take care when using C<update_or_new> with a table having
3009 columns with default values that you intend to be automatically
3010 supplied by the database (e.g. an auto_increment primary key column).
3011 In normal usage, the value of such columns should NOT be included at
3012 all in the call to C<update_or_new>, even when set to C<undef>.
3013
3014 See also L</find>, L</find_or_create> and L</find_or_new>.
3015
3016 =cut
3017
3018 sub update_or_new {
3019     my $self  = shift;
3020     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3021     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3022
3023     my $row = $self->find( $cond, $attrs );
3024     if ( defined $row ) {
3025         $row->update($cond);
3026         return $row;
3027     }
3028
3029     return $self->new_result($cond);
3030 }
3031
3032 =head2 get_cache
3033
3034 =over 4
3035
3036 =item Arguments: none
3037
3038 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3039
3040 =back
3041
3042 Gets the contents of the cache for the resultset, if the cache is set.
3043
3044 The cache is populated either by using the L</prefetch> attribute to
3045 L</search> or by calling L</set_cache>.
3046
3047 =cut
3048
3049 sub get_cache {
3050   shift->{all_cache};
3051 }
3052
3053 =head2 set_cache
3054
3055 =over 4
3056
3057 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3058
3059 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3060
3061 =back
3062
3063 Sets the contents of the cache for the resultset. Expects an arrayref
3064 of objects of the same class as those produced by the resultset. Note that
3065 if the cache is set, the resultset will return the cached objects rather
3066 than re-querying the database even if the cache attr is not set.
3067
3068 The contents of the cache can also be populated by using the
3069 L</prefetch> attribute to L</search>.
3070
3071 =cut
3072
3073 sub set_cache {
3074   my ( $self, $data ) = @_;
3075   $self->throw_exception("set_cache requires an arrayref")
3076       if defined($data) && (ref $data ne 'ARRAY');
3077   $self->{all_cache} = $data;
3078 }
3079
3080 =head2 clear_cache
3081
3082 =over 4
3083
3084 =item Arguments: none
3085
3086 =item Return Value: undef
3087
3088 =back
3089
3090 Clears the cache for the resultset.
3091
3092 =cut
3093
3094 sub clear_cache {
3095   shift->set_cache(undef);
3096 }
3097
3098 =head2 is_paged
3099
3100 =over 4
3101
3102 =item Arguments: none
3103
3104 =item Return Value: true, if the resultset has been paginated
3105
3106 =back
3107
3108 =cut
3109
3110 sub is_paged {
3111   my ($self) = @_;
3112   return !!$self->{attrs}{page};
3113 }
3114
3115 =head2 is_ordered
3116
3117 =over 4
3118
3119 =item Arguments: none
3120
3121 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3122
3123 =back
3124
3125 =cut
3126
3127 sub is_ordered {
3128   my ($self) = @_;
3129   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3130 }
3131
3132 =head2 related_resultset
3133
3134 =over 4
3135
3136 =item Arguments: $rel_name
3137
3138 =item Return Value: L<$resultset|/search>
3139
3140 =back
3141
3142 Returns a related resultset for the supplied relationship name.
3143
3144   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3145
3146 =cut
3147
3148 sub related_resultset {
3149   my ($self, $rel) = @_;
3150
3151   return $self->{related_resultsets}{$rel}
3152     if defined $self->{related_resultsets}{$rel};
3153
3154   return $self->{related_resultsets}{$rel} = do {
3155     my $rsrc = $self->result_source;
3156     my $rel_info = $rsrc->relationship_info($rel);
3157
3158     $self->throw_exception(
3159       "search_related: result source '" . $rsrc->source_name .
3160         "' has no such relationship $rel")
3161       unless $rel_info;
3162
3163     my $attrs = $self->_chain_relationship($rel);
3164
3165     my $join_count = $attrs->{seen_join}{$rel};
3166
3167     my $alias = $self->result_source->storage
3168         ->relname_to_table_alias($rel, $join_count);
3169
3170     # since this is search_related, and we already slid the select window inwards
3171     # (the select/as attrs were deleted in the beginning), we need to flip all
3172     # left joins to inner, so we get the expected results
3173     # read the comment on top of the actual function to see what this does
3174     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3175
3176
3177     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3178     delete @{$attrs}{qw(result_class alias)};
3179
3180     my $rel_source = $rsrc->related_source($rel);
3181
3182     my $new = do {
3183
3184       # The reason we do this now instead of passing the alias to the
3185       # search_rs below is that if you wrap/overload resultset on the
3186       # source you need to know what alias it's -going- to have for things
3187       # to work sanely (e.g. RestrictWithObject wants to be able to add
3188       # extra query restrictions, and these may need to be $alias.)
3189
3190       my $rel_attrs = $rel_source->resultset_attributes;
3191       local $rel_attrs->{alias} = $alias;
3192
3193       $rel_source->resultset
3194                  ->search_rs(
3195                      undef, {
3196                        %$attrs,
3197                        where => $attrs->{where},
3198                    });
3199     };
3200
3201     if (my $cache = $self->get_cache) {
3202       my @related_cache = map
3203         { @{$_->related_resultset($rel)->get_cache||[]} }
3204         @$cache
3205       ;
3206
3207       $new->set_cache(\@related_cache) if @related_cache;
3208     }
3209
3210     $new;
3211   };
3212 }
3213
3214 =head2 current_source_alias
3215
3216 =over 4
3217
3218 =item Arguments: none
3219
3220 =item Return Value: $source_alias
3221
3222 =back
3223
3224 Returns the current table alias for the result source this resultset is built
3225 on, that will be used in the SQL query. Usually it is C<me>.
3226
3227 Currently the source alias that refers to the result set returned by a
3228 L</search>/L</find> family method depends on how you got to the resultset: it's
3229 C<me> by default, but eg. L</search_related> aliases it to the related result
3230 source name (and keeps C<me> referring to the original result set). The long
3231 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3232 (and make this method unnecessary).
3233
3234 Thus it's currently necessary to use this method in predefined queries (see
3235 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3236 source alias of the current result set:
3237
3238   # in a result set class
3239   sub modified_by {
3240     my ($self, $user) = @_;
3241
3242     my $me = $self->current_source_alias;
3243
3244     return $self->search({
3245       "$me.modified" => $user->id,
3246     });
3247   }
3248
3249 =cut
3250
3251 sub current_source_alias {
3252   return (shift->{attrs} || {})->{alias} || 'me';
3253 }
3254
3255 =head2 as_subselect_rs
3256
3257 =over 4
3258
3259 =item Arguments: none
3260
3261 =item Return Value: L<$resultset|/search>
3262
3263 =back
3264
3265 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3266 "virtual view" by including it as a subquery within the from clause.  From this
3267 point on, any joined tables are inaccessible to ->search on the resultset (as if
3268 it were simply where-filtered without joins).  For example:
3269
3270  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3271
3272  # 'x' now pollutes the query namespace
3273
3274  # So the following works as expected
3275  my $ok_rs = $rs->search({'x.other' => 1});
3276
3277  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3278  # def) we look for one row with contradictory terms and join in another table
3279  # (aliased 'x_2') which we never use
3280  my $broken_rs = $rs->search({'x.name' => 'def'});
3281
3282  my $rs2 = $rs->as_subselect_rs;
3283
3284  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3285  my $not_joined_rs = $rs2->search({'x.other' => 1});
3286
3287  # works as expected: finds a 'table' row related to two x rows (abc and def)
3288  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3289
3290 Another example of when one might use this would be to select a subset of
3291 columns in a group by clause:
3292
3293  my $rs = $schema->resultset('Bar')->search(undef, {
3294    group_by => [qw{ id foo_id baz_id }],
3295  })->as_subselect_rs->search(undef, {
3296    columns => [qw{ id foo_id }]
3297  });
3298
3299 In the above example normally columns would have to be equal to the group by,
3300 but because we isolated the group by into a subselect the above works.
3301
3302 =cut
3303
3304 sub as_subselect_rs {
3305   my $self = shift;
3306
3307   my $attrs = $self->_resolved_attrs;
3308
3309   my $fresh_rs = (ref $self)->new (
3310     $self->result_source
3311   );
3312
3313   # these pieces will be locked in the subquery
3314   delete $fresh_rs->{cond};
3315   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3316
3317   return $fresh_rs->search( {}, {
3318     from => [{
3319       $attrs->{alias} => $self->as_query,
3320       -alias  => $attrs->{alias},
3321       -rsrc   => $self->result_source,
3322     }],
3323     alias => $attrs->{alias},
3324   });
3325 }
3326
3327 # This code is called by search_related, and makes sure there
3328 # is clear separation between the joins before, during, and
3329 # after the relationship. This information is needed later
3330 # in order to properly resolve prefetch aliases (any alias
3331 # with a relation_chain_depth less than the depth of the
3332 # current prefetch is not considered)
3333 #
3334 # The increments happen twice per join. An even number means a
3335 # relationship specified via a search_related, whereas an odd
3336 # number indicates a join/prefetch added via attributes
3337 #
3338 # Also this code will wrap the current resultset (the one we
3339 # chain to) in a subselect IFF it contains limiting attributes
3340 sub _chain_relationship {
3341   my ($self, $rel) = @_;
3342   my $source = $self->result_source;
3343   my $attrs = { %{$self->{attrs}||{}} };
3344
3345   # we need to take the prefetch the attrs into account before we
3346   # ->_resolve_join as otherwise they get lost - captainL
3347   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3348
3349   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3350
3351   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3352
3353   my $from;
3354   my @force_subq_attrs = qw/offset rows group_by having/;
3355
3356   if (
3357     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3358       ||
3359     $self->_has_resolved_attr (@force_subq_attrs)
3360   ) {
3361     # Nuke the prefetch (if any) before the new $rs attrs
3362     # are resolved (prefetch is useless - we are wrapping
3363     # a subquery anyway).
3364     my $rs_copy = $self->search;
3365     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3366       $rs_copy->{attrs}{join},
3367       delete $rs_copy->{attrs}{prefetch},
3368     );
3369
3370     $from = [{
3371       -rsrc   => $source,
3372       -alias  => $attrs->{alias},
3373       $attrs->{alias} => $rs_copy->as_query,
3374     }];
3375     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3376     $seen->{-relation_chain_depth} = 0;
3377   }
3378   elsif ($attrs->{from}) {  #shallow copy suffices
3379     $from = [ @{$attrs->{from}} ];
3380   }
3381   else {
3382     $from = [{
3383       -rsrc  => $source,
3384       -alias => $attrs->{alias},
3385       $attrs->{alias} => $source->from,
3386     }];
3387   }
3388
3389   my $jpath = ($seen->{-relation_chain_depth})
3390     ? $from->[-1][0]{-join_path}
3391     : [];
3392
3393   my @requested_joins = $source->_resolve_join(
3394     $join,
3395     $attrs->{alias},
3396     $seen,
3397     $jpath,
3398   );
3399
3400   push @$from, @requested_joins;
3401
3402   $seen->{-relation_chain_depth}++;
3403
3404   # if $self already had a join/prefetch specified on it, the requested
3405   # $rel might very well be already included. What we do in this case
3406   # is effectively a no-op (except that we bump up the chain_depth on
3407   # the join in question so we could tell it *is* the search_related)
3408   my $already_joined;
3409
3410   # we consider the last one thus reverse
3411   for my $j (reverse @requested_joins) {
3412     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3413     if ($rel eq $last_j) {
3414       $j->[0]{-relation_chain_depth}++;
3415       $already_joined++;
3416       last;
3417     }
3418   }
3419
3420   unless ($already_joined) {
3421     push @$from, $source->_resolve_join(
3422       $rel,
3423       $attrs->{alias},
3424       $seen,
3425       $jpath,
3426     );
3427   }
3428
3429   $seen->{-relation_chain_depth}++;
3430
3431   return {%$attrs, from => $from, seen_join => $seen};
3432 }
3433
3434 sub _resolved_attrs {
3435   my $self = shift;
3436   return $self->{_attrs} if $self->{_attrs};
3437
3438   my $attrs  = { %{ $self->{attrs} || {} } };
3439   my $source = $self->result_source;
3440   my $alias  = $attrs->{alias};
3441
3442   # default selection list
3443   $attrs->{columns} = [ $source->columns ]
3444     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3445
3446   # merge selectors together
3447   for (qw/columns select as/) {
3448     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3449       if $attrs->{$_} or $attrs->{"+$_"};
3450   }
3451
3452   # disassemble columns
3453   my (@sel, @as);
3454   if (my $cols = delete $attrs->{columns}) {
3455     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3456       if (ref $c eq 'HASH') {
3457         for my $as (sort keys %$c) {
3458           push @sel, $c->{$as};
3459           push @as, $as;
3460         }
3461       }
3462       else {
3463         push @sel, $c;
3464         push @as, $c;
3465       }
3466     }
3467   }
3468
3469   # when trying to weed off duplicates later do not go past this point -
3470   # everything added from here on is unbalanced "anyone's guess" stuff
3471   my $dedup_stop_idx = $#as;
3472
3473   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3474     if $attrs->{as};
3475   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3476     if $attrs->{select};
3477
3478   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3479   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3480
3481   # disqualify all $alias.col as-bits (inflate-map mandated)
3482   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3483
3484   # de-duplicate the result (remove *identical* select/as pairs)
3485   # and also die on duplicate {as} pointing to different {select}s
3486   # not using a c-style for as the condition is prone to shrinkage
3487   my $seen;
3488   my $i = 0;
3489   while ($i <= $dedup_stop_idx) {
3490     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3491       splice @sel, $i, 1;
3492       splice @as, $i, 1;
3493       $dedup_stop_idx--;
3494     }
3495     elsif ($seen->{$as[$i]}++) {
3496       $self->throw_exception(
3497         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3498       );
3499     }
3500     else {
3501       $i++;
3502     }
3503   }
3504
3505   $attrs->{select} = \@sel;
3506   $attrs->{as} = \@as;
3507
3508   $attrs->{from} ||= [{
3509     -rsrc   => $source,
3510     -alias  => $self->{attrs}{alias},
3511     $self->{attrs}{alias} => $source->from,
3512   }];
3513
3514   if ( $attrs->{join} || $attrs->{prefetch} ) {
3515
3516     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3517       if ref $attrs->{from} ne 'ARRAY';
3518
3519     my $join = (delete $attrs->{join}) || {};
3520
3521     if ( defined $attrs->{prefetch} ) {
3522       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3523     }
3524
3525     $attrs->{from} =    # have to copy here to avoid corrupting the original
3526       [
3527         @{ $attrs->{from} },
3528         $source->_resolve_join(
3529           $join,
3530           $alias,
3531           { %{ $attrs->{seen_join} || {} } },
3532           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3533             ? $attrs->{from}[-1][0]{-join_path}
3534             : []
3535           ,
3536         )
3537       ];
3538   }
3539
3540   if ( defined $attrs->{order_by} ) {
3541     $attrs->{order_by} = (
3542       ref( $attrs->{order_by} ) eq 'ARRAY'
3543       ? [ @{ $attrs->{order_by} } ]
3544       : [ $attrs->{order_by} || () ]
3545     );
3546   }
3547
3548   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3549     $attrs->{group_by} = [ $attrs->{group_by} ];
3550   }
3551
3552   # generate the distinct induced group_by early, as prefetch will be carried via a
3553   # subquery (since a group_by is present)
3554   if (delete $attrs->{distinct}) {
3555     if ($attrs->{group_by}) {
3556       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3557     }
3558     else {
3559       $attrs->{_grouped_by_distinct} = 1;
3560       # distinct affects only the main selection part, not what prefetch may
3561       # add below.
3562       $attrs->{group_by} = $source->storage->_group_over_selection($attrs);
3563     }
3564   }
3565
3566   # generate selections based on the prefetch helper
3567   my $prefetch;
3568   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3569     if defined $attrs->{prefetch};
3570
3571   if ($prefetch) {
3572
3573     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3574       if $attrs->{_dark_selector};
3575
3576     $attrs->{collapse} = 1;
3577
3578     # this is a separate structure (we don't look in {from} directly)
3579     # as the resolver needs to shift things off the lists to work
3580     # properly (identical-prefetches on different branches)
3581     my $join_map = {};
3582     if (ref $attrs->{from} eq 'ARRAY') {
3583
3584       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3585
3586       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3587         next unless $j->[0]{-alias};
3588         next unless $j->[0]{-join_path};
3589         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3590
3591         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3592
3593         my $p = $join_map;
3594         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3595         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3596       }
3597     }
3598
3599     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3600
3601     push @{ $attrs->{select} }, (map { $_->[0] } @prefetch);
3602     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
3603   }
3604
3605   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3606     $attrs->{_related_results_construction} = 1;
3607   }
3608
3609   # run through the resulting joinstructure (starting from our current slot)
3610   # and unset collapse if proven unnecessary
3611   #
3612   # also while we are at it find out if the current root source has
3613   # been premultiplied by previous related_source chaining
3614   #
3615   # this allows to predict whether a root object with all other relation
3616   # data set to NULL is in fact unique
3617   if ($attrs->{collapse}) {
3618
3619     if (ref $attrs->{from} eq 'ARRAY') {
3620
3621       if (@{$attrs->{from}} == 1) {
3622         # no joins - no collapse
3623         $attrs->{collapse} = 0;
3624       }
3625       else {
3626         # find where our table-spec starts
3627         my @fromlist = @{$attrs->{from}};
3628         while (@fromlist) {
3629           my $t = shift @fromlist;
3630
3631           my $is_multi;
3632           # me vs join from-spec distinction - a ref means non-root
3633           if (ref $t eq 'ARRAY') {
3634             $t = $t->[0];
3635             $is_multi ||= ! $t->{-is_single};
3636           }
3637           last if ($t->{-alias} && $t->{-alias} eq $alias);
3638           $attrs->{_main_source_premultiplied} ||= $is_multi;
3639         }
3640
3641         # no non-singles remaining, nor any premultiplication - nothing to collapse
3642         if (
3643           ! $attrs->{_main_source_premultiplied}
3644             and
3645           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3646         ) {
3647           $attrs->{collapse} = 0;
3648         }
3649       }
3650     }
3651
3652     else {
3653       # if we can not analyze the from - err on the side of safety
3654       $attrs->{_main_source_premultiplied} = 1;
3655     }
3656   }
3657
3658   # if both page and offset are specified, produce a combined offset
3659   # even though it doesn't make much sense, this is what pre 081xx has
3660   # been doing
3661   if (my $page = delete $attrs->{page}) {
3662     $attrs->{offset} =
3663       ($attrs->{rows} * ($page - 1))
3664             +
3665       ($attrs->{offset} || 0)
3666     ;
3667   }
3668
3669   return $self->{_attrs} = $attrs;
3670 }
3671
3672 sub _rollout_attr {
3673   my ($self, $attr) = @_;
3674
3675   if (ref $attr eq 'HASH') {
3676     return $self->_rollout_hash($attr);
3677   } elsif (ref $attr eq 'ARRAY') {
3678     return $self->_rollout_array($attr);
3679   } else {
3680     return [$attr];
3681   }
3682 }
3683
3684 sub _rollout_array {
3685   my ($self, $attr) = @_;
3686
3687   my @rolled_array;
3688   foreach my $element (@{$attr}) {
3689     if (ref $element eq 'HASH') {
3690       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3691     } elsif (ref $element eq 'ARRAY') {
3692       #  XXX - should probably recurse here
3693       push( @rolled_array, @{$self->_rollout_array($element)} );
3694     } else {
3695       push( @rolled_array, $element );
3696     }
3697   }
3698   return \@rolled_array;
3699 }
3700
3701 sub _rollout_hash {
3702   my ($self, $attr) = @_;
3703
3704   my @rolled_array;
3705   foreach my $key (keys %{$attr}) {
3706     push( @rolled_array, { $key => $attr->{$key} } );
3707   }
3708   return \@rolled_array;
3709 }
3710
3711 sub _calculate_score {
3712   my ($self, $a, $b) = @_;
3713
3714   if (defined $a xor defined $b) {
3715     return 0;
3716   }
3717   elsif (not defined $a) {
3718     return 1;
3719   }
3720
3721   if (ref $b eq 'HASH') {
3722     my ($b_key) = keys %{$b};
3723     if (ref $a eq 'HASH') {
3724       my ($a_key) = keys %{$a};
3725       if ($a_key eq $b_key) {
3726         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3727       } else {
3728         return 0;
3729       }
3730     } else {
3731       return ($a eq $b_key) ? 1 : 0;
3732     }
3733   } else {
3734     if (ref $a eq 'HASH') {
3735       my ($a_key) = keys %{$a};
3736       return ($b eq $a_key) ? 1 : 0;
3737     } else {
3738       return ($b eq $a) ? 1 : 0;
3739     }
3740   }
3741 }
3742
3743 sub _merge_joinpref_attr {
3744   my ($self, $orig, $import) = @_;
3745
3746   return $import unless defined($orig);
3747   return $orig unless defined($import);
3748
3749   $orig = $self->_rollout_attr($orig);
3750   $import = $self->_rollout_attr($import);
3751
3752   my $seen_keys;
3753   foreach my $import_element ( @{$import} ) {
3754     # find best candidate from $orig to merge $b_element into
3755     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3756     foreach my $orig_element ( @{$orig} ) {
3757       my $score = $self->_calculate_score( $orig_element, $import_element );
3758       if ($score > $best_candidate->{score}) {
3759         $best_candidate->{position} = $position;
3760         $best_candidate->{score} = $score;
3761       }
3762       $position++;
3763     }
3764     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3765     $import_key = '' if not defined $import_key;
3766
3767     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3768       push( @{$orig}, $import_element );
3769     } else {
3770       my $orig_best = $orig->[$best_candidate->{position}];
3771       # merge orig_best and b_element together and replace original with merged
3772       if (ref $orig_best ne 'HASH') {
3773         $orig->[$best_candidate->{position}] = $import_element;
3774       } elsif (ref $import_element eq 'HASH') {
3775         my ($key) = keys %{$orig_best};
3776         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3777       }
3778     }
3779     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3780   }
3781
3782   return @$orig ? $orig : ();
3783 }
3784
3785 {
3786   my $hm;
3787
3788   sub _merge_attr {
3789     $hm ||= do {
3790       require Hash::Merge;
3791       my $hm = Hash::Merge->new;
3792
3793       $hm->specify_behavior({
3794         SCALAR => {
3795           SCALAR => sub {
3796             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3797
3798             if ($defl xor $defr) {
3799               return [ $defl ? $_[0] : $_[1] ];
3800             }
3801             elsif (! $defl) {
3802               return [];
3803             }
3804             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3805               return [ $_[0] ];
3806             }
3807             else {
3808               return [$_[0], $_[1]];
3809             }
3810           },
3811           ARRAY => sub {
3812             return $_[1] if !defined $_[0];
3813             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3814             return [$_[0], @{$_[1]}]
3815           },
3816           HASH  => sub {
3817             return [] if !defined $_[0] and !keys %{$_[1]};
3818             return [ $_[1] ] if !defined $_[0];
3819             return [ $_[0] ] if !keys %{$_[1]};
3820             return [$_[0], $_[1]]
3821           },
3822         },
3823         ARRAY => {
3824           SCALAR => sub {
3825             return $_[0] if !defined $_[1];
3826             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3827             return [@{$_[0]}, $_[1]]
3828           },
3829           ARRAY => sub {
3830             my @ret = @{$_[0]} or return $_[1];
3831             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3832             my %idx = map { $_ => 1 } @ret;
3833             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3834             \@ret;
3835           },
3836           HASH => sub {
3837             return [ $_[1] ] if ! @{$_[0]};
3838             return $_[0] if !keys %{$_[1]};
3839             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3840             return [ @{$_[0]}, $_[1] ];
3841           },
3842         },
3843         HASH => {
3844           SCALAR => sub {
3845             return [] if !keys %{$_[0]} and !defined $_[1];
3846             return [ $_[0] ] if !defined $_[1];
3847             return [ $_[1] ] if !keys %{$_[0]};
3848             return [$_[0], $_[1]]
3849           },
3850           ARRAY => sub {
3851             return [] if !keys %{$_[0]} and !@{$_[1]};
3852             return [ $_[0] ] if !@{$_[1]};
3853             return $_[1] if !keys %{$_[0]};
3854             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3855             return [ $_[0], @{$_[1]} ];
3856           },
3857           HASH => sub {
3858             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3859             return [ $_[0] ] if !keys %{$_[1]};
3860             return [ $_[1] ] if !keys %{$_[0]};
3861             return [ $_[0] ] if $_[0] eq $_[1];
3862             return [ $_[0], $_[1] ];
3863           },
3864         }
3865       } => 'DBIC_RS_ATTR_MERGER');
3866       $hm;
3867     };
3868
3869     return $hm->merge ($_[1], $_[2]);
3870   }
3871 }
3872
3873 sub STORABLE_freeze {
3874   my ($self, $cloning) = @_;
3875   my $to_serialize = { %$self };
3876
3877   # A cursor in progress can't be serialized (and would make little sense anyway)
3878   # the parser can be regenerated (and can't be serialized)
3879   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3880
3881   # nor is it sensical to store a not-yet-fired-count pager
3882   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3883     delete $to_serialize->{pager};
3884   }
3885
3886   Storable::nfreeze($to_serialize);
3887 }
3888
3889 # need this hook for symmetry
3890 sub STORABLE_thaw {
3891   my ($self, $cloning, $serialized) = @_;
3892
3893   %$self = %{ Storable::thaw($serialized) };
3894
3895   $self;
3896 }
3897
3898
3899 =head2 throw_exception
3900
3901 See L<DBIx::Class::Schema/throw_exception> for details.
3902
3903 =cut
3904
3905 sub throw_exception {
3906   my $self=shift;
3907
3908   if (ref $self and my $rsrc = $self->result_source) {
3909     $rsrc->throw_exception(@_)
3910   }
3911   else {
3912     DBIx::Class::Exception->throw(@_);
3913   }
3914 }
3915
3916 1;
3917
3918 __END__
3919
3920 # XXX: FIXME: Attributes docs need clearing up
3921
3922 =head1 ATTRIBUTES
3923
3924 Attributes are used to refine a ResultSet in various ways when
3925 searching for data. They can be passed to any method which takes an
3926 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3927 L</count>.
3928
3929 Default attributes can be set on the result class using
3930 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3931 the CAVEATS on that feature before using it!)
3932
3933 These are in no particular order:
3934
3935 =head2 order_by
3936
3937 =over 4
3938
3939 =item Value: ( $order_by | \@order_by | \%order_by )
3940
3941 =back
3942
3943 Which column(s) to order the results by.
3944
3945 [The full list of suitable values is documented in
3946 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3947 common options.]
3948
3949 If a single column name, or an arrayref of names is supplied, the
3950 argument is passed through directly to SQL. The hashref syntax allows
3951 for connection-agnostic specification of ordering direction:
3952
3953  For descending order:
3954
3955   order_by => { -desc => [qw/col1 col2 col3/] }
3956
3957  For explicit ascending order:
3958
3959   order_by => { -asc => 'col' }
3960
3961 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3962 supported, although you are strongly encouraged to use the hashref
3963 syntax as outlined above.
3964
3965 =head2 columns
3966
3967 =over 4
3968
3969 =item Value: \@columns | \%columns | $column
3970
3971 =back
3972
3973 Shortcut to request a particular set of columns to be retrieved. Each
3974 column spec may be a string (a table column name), or a hash (in which
3975 case the key is the C<as> value, and the value is used as the C<select>
3976 expression). Adds C<me.> onto the start of any column without a C<.> in
3977 it and sets C<select> from that, then auto-populates C<as> from
3978 C<select> as normal. (You may also use the C<cols> attribute, as in
3979 earlier versions of DBIC, but this is deprecated.)
3980
3981 Essentially C<columns> does the same as L</select> and L</as>.
3982
3983     columns => [ 'foo', { bar => 'baz' } ]
3984
3985 is the same as
3986
3987     select => [qw/foo baz/],
3988     as => [qw/foo bar/]
3989
3990 =head2 +columns
3991
3992 =over 4
3993
3994 =item Value: \@columns
3995
3996 =back
3997
3998 Indicates additional columns to be selected from storage. Works the same as
3999 L</columns> but adds columns to the selection. (You may also use the
4000 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4001 deprecated). For example:-
4002
4003   $schema->resultset('CD')->search(undef, {
4004     '+columns' => ['artist.name'],
4005     join => ['artist']
4006   });
4007
4008 would return all CDs and include a 'name' column to the information
4009 passed to object inflation. Note that the 'artist' is the name of the
4010 column (or relationship) accessor, and 'name' is the name of the column
4011 accessor in the related table.
4012
4013 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
4014 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
4015 unary plus operator before it.
4016
4017 =head2 include_columns
4018
4019 =over 4
4020
4021 =item Value: \@columns
4022
4023 =back
4024
4025 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
4026
4027 =head2 select
4028
4029 =over 4
4030
4031 =item Value: \@select_columns
4032
4033 =back
4034
4035 Indicates which columns should be selected from the storage. You can use
4036 column names, or in the case of RDBMS back ends, function or stored procedure
4037 names:
4038
4039   $rs = $schema->resultset('Employee')->search(undef, {
4040     select => [
4041       'name',
4042       { count => 'employeeid' },
4043       { max => { length => 'name' }, -as => 'longest_name' }
4044     ]
4045   });
4046
4047   # Equivalent SQL
4048   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4049
4050 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4051 use L</select>, to instruct DBIx::Class how to store the result of the column.
4052 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4053 identifier aliasing. You can however alias a function, so you can use it in
4054 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4055 attribute> supplied as shown in the example above.
4056
4057 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4058 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4059 unary plus operator before it.
4060
4061 =head2 +select
4062
4063 =over 4
4064
4065 Indicates additional columns to be selected from storage.  Works the same as
4066 L</select> but adds columns to the default selection, instead of specifying
4067 an explicit list.
4068
4069 =back
4070
4071 =head2 as
4072
4073 =over 4
4074
4075 =item Value: \@inflation_names
4076
4077 =back
4078
4079 Indicates column names for object inflation. That is L</as> indicates the
4080 slot name in which the column value will be stored within the
4081 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4082 identifier by the C<get_column> method (or via the object accessor B<if one
4083 with the same name already exists>) as shown below. The L</as> attribute has
4084 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4085
4086   $rs = $schema->resultset('Employee')->search(undef, {
4087     select => [
4088       'name',
4089       { count => 'employeeid' },
4090       { max => { length => 'name' }, -as => 'longest_name' }
4091     ],
4092     as => [qw/
4093       name
4094       employee_count
4095       max_name_length
4096     /],
4097   });
4098
4099 If the object against which the search is performed already has an accessor
4100 matching a column name specified in C<as>, the value can be retrieved using
4101 the accessor as normal:
4102
4103   my $name = $employee->name();
4104
4105 If on the other hand an accessor does not exist in the object, you need to
4106 use C<get_column> instead:
4107
4108   my $employee_count = $employee->get_column('employee_count');
4109
4110 You can create your own accessors if required - see
4111 L<DBIx::Class::Manual::Cookbook> for details.
4112
4113 =head2 +as
4114
4115 =over 4
4116
4117 Indicates additional column names for those added via L</+select>. See L</as>.
4118
4119 =back
4120
4121 =head2 join
4122
4123 =over 4
4124
4125 =item Value: ($rel_name | \@rel_names | \%rel_names)
4126
4127 =back
4128
4129 Contains a list of relationships that should be joined for this query.  For
4130 example:
4131
4132   # Get CDs by Nine Inch Nails
4133   my $rs = $schema->resultset('CD')->search(
4134     { 'artist.name' => 'Nine Inch Nails' },
4135     { join => 'artist' }
4136   );
4137
4138 Can also contain a hash reference to refer to the other relation's relations.
4139 For example:
4140
4141   package MyApp::Schema::Track;
4142   use base qw/DBIx::Class/;
4143   __PACKAGE__->table('track');
4144   __PACKAGE__->add_columns(qw/trackid cd position title/);
4145   __PACKAGE__->set_primary_key('trackid');
4146   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4147   1;
4148
4149   # In your application
4150   my $rs = $schema->resultset('Artist')->search(
4151     { 'track.title' => 'Teardrop' },
4152     {
4153       join     => { cd => 'track' },
4154       order_by => 'artist.name',
4155     }
4156   );
4157
4158 You need to use the relationship (not the table) name in  conditions,
4159 because they are aliased as such. The current table is aliased as "me", so
4160 you need to use me.column_name in order to avoid ambiguity. For example:
4161
4162   # Get CDs from 1984 with a 'Foo' track
4163   my $rs = $schema->resultset('CD')->search(
4164     {
4165       'me.year' => 1984,
4166       'tracks.name' => 'Foo'
4167     },
4168     { join => 'tracks' }
4169   );
4170
4171 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4172 similarly for a third time). For e.g.
4173
4174   my $rs = $schema->resultset('Artist')->search({
4175     'cds.title'   => 'Down to Earth',
4176     'cds_2.title' => 'Popular',
4177   }, {
4178     join => [ qw/cds cds/ ],
4179   });
4180
4181 will return a set of all artists that have both a cd with title 'Down
4182 to Earth' and a cd with title 'Popular'.
4183
4184 If you want to fetch related objects from other tables as well, see L</prefetch>
4185 below.
4186
4187  NOTE: An internal join-chain pruner will discard certain joins while
4188  constructing the actual SQL query, as long as the joins in question do not
4189  affect the retrieved result. This for example includes 1:1 left joins
4190  that are not part of the restriction specification (WHERE/HAVING) nor are
4191  a part of the query selection.
4192
4193 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4194
4195 =head2 collapse
4196
4197 =over 4
4198
4199 =item Value: (0 | 1)
4200
4201 =back
4202
4203 When set to a true value, indicates that any rows fetched from joined has_many
4204 relationships are to be aggregated into the corresponding "parent" object. For
4205 example, the resultset:
4206
4207   my $rs = $schema->resultset('CD')->search({}, {
4208     '+columns' => [ qw/ tracks.title tracks.position / ],
4209     join => 'tracks',
4210     collapse => 1,
4211   });
4212
4213 While executing the following query:
4214
4215   SELECT me.*, tracks.title, tracks.position
4216     FROM cd me
4217     LEFT JOIN track tracks
4218       ON tracks.cdid = me.cdid
4219
4220 Will return only as many objects as there are rows in the CD source, even
4221 though the result of the query may span many rows. Each of these CD objects
4222 will in turn have multiple "Track" objects hidden behind the has_many
4223 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4224 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4225 product"), with each CD object containing exactly one of all fetched Track data.
4226
4227 When a collapse is requested on a non-ordered resultset, an order by some
4228 unique part of the main source (the left-most table) is inserted automatically.
4229 This is done so that the resultset is allowed to be "lazy" - calling
4230 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4231 object with all of its related data.
4232
4233 If an L</order_by> is already declared, and orders the resultset in a way that
4234 makes collapsing as described above impossible (e.g. C<< ORDER BY
4235 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4236 switch to "eager" mode and slurp the entire resultset before constructing the
4237 first object returned by L</next>.
4238
4239 Setting this attribute on a resultset that does not join any has_many
4240 relations is a no-op.
4241
4242 For a more in-depth discussion, see L</PREFETCHING>.
4243
4244 =head2 prefetch
4245
4246 =over 4
4247
4248 =item Value: ($rel_name | \@rel_names | \%rel_names)
4249
4250 =back
4251
4252 This attribute is a shorthand for specifying a L</join> spec, adding all
4253 columns from the joined related sources as L</+columns> and setting
4254 L</collapse> to a true value. For example, the following two queries are
4255 equivalent:
4256
4257   my $rs = $schema->resultset('Artist')->search({}, {
4258     prefetch => { cds => ['genre', 'tracks' ] },
4259   });
4260
4261 and
4262
4263   my $rs = $schema->resultset('Artist')->search({}, {
4264     join => { cds => ['genre', 'tracks' ] },
4265     collapse => 1,
4266     '+columns' => [
4267       (map
4268         { +{ "cds.$_" => "cds.$_" } }
4269         $schema->source('Artist')->related_source('cds')->columns
4270       ),
4271       (map
4272         { +{ "cds.genre.$_" => "genre.$_" } }
4273         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4274       ),
4275       (map
4276         { +{ "cds.tracks.$_" => "tracks.$_" } }
4277         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4278       ),
4279     ],
4280   });
4281
4282 Both producing the following SQL:
4283
4284   SELECT  me.artistid, me.name, me.rank, me.charfield,
4285           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4286           genre.genreid, genre.name,
4287           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4288     FROM artist me
4289     LEFT JOIN cd cds
4290       ON cds.artist = me.artistid
4291     LEFT JOIN genre genre
4292       ON genre.genreid = cds.genreid
4293     LEFT JOIN track tracks
4294       ON tracks.cd = cds.cdid
4295   ORDER BY me.artistid
4296
4297 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4298 the arguments are properly merged and generally do the right thing. For
4299 example, you may want to do the following:
4300
4301   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4302     { 'genre.genreid' => undef },
4303     {
4304       join => { cds => 'genre' },
4305       prefetch => 'cds',
4306     }
4307   );
4308
4309 Which generates the following SQL:
4310
4311   SELECT  me.artistid, me.name, me.rank, me.charfield,
4312           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4313     FROM artist me
4314     LEFT JOIN cd cds
4315       ON cds.artist = me.artistid
4316     LEFT JOIN genre genre
4317       ON genre.genreid = cds.genreid
4318   WHERE genre.genreid IS NULL
4319   ORDER BY me.artistid
4320
4321 For a more in-depth discussion, see L</PREFETCHING>.
4322
4323 =head2 alias
4324
4325 =over 4
4326
4327 =item Value: $source_alias
4328
4329 =back
4330
4331 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4332 nested search queries (sub-SELECTs) might need specific aliases set to
4333 reference inner queries.  For example:
4334
4335    my $q = $rs
4336       ->related_resultset('CDs')
4337       ->related_resultset('Tracks')
4338       ->search({
4339          'track.id' => { -ident => 'none_search.id' },
4340       })
4341       ->as_query;
4342
4343    my $ids = $self->search({
4344       -not_exists => $q,
4345    }, {
4346       alias    => 'none_search',
4347       group_by => 'none_search.id',
4348    })->get_column('id')->as_query;
4349
4350    $self->search({ id => { -in => $ids } })
4351
4352 This attribute is directly tied to L</current_source_alias>.
4353
4354 =head2 page
4355
4356 =over 4
4357
4358 =item Value: $page
4359
4360 =back
4361
4362 Makes the resultset paged and specifies the page to retrieve. Effectively
4363 identical to creating a non-pages resultset and then calling ->page($page)
4364 on it.
4365
4366 If L</rows> attribute is not specified it defaults to 10 rows per page.
4367
4368 When you have a paged resultset, L</count> will only return the number
4369 of rows in the page. To get the total, use the L</pager> and call
4370 C<total_entries> on it.
4371
4372 =head2 rows
4373
4374 =over 4
4375
4376 =item Value: $rows
4377
4378 =back
4379
4380 Specifies the maximum number of rows for direct retrieval or the number of
4381 rows per page if the page attribute or method is used.
4382
4383 =head2 offset
4384
4385 =over 4
4386
4387 =item Value: $offset
4388
4389 =back
4390
4391 Specifies the (zero-based) row number for the  first row to be returned, or the
4392 of the first row of the first page if paging is used.
4393
4394 =head2 software_limit
4395
4396 =over 4
4397
4398 =item Value: (0 | 1)
4399
4400 =back
4401
4402 When combined with L</rows> and/or L</offset> the generated SQL will not
4403 include any limit dialect stanzas. Instead the entire result will be selected
4404 as if no limits were specified, and DBIC will perform the limit locally, by
4405 artificially advancing and finishing the resulting L</cursor>.
4406
4407 This is the recommended way of performing resultset limiting when no sane RDBMS
4408 implementation is available (e.g.
4409 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4410 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4411
4412 =head2 group_by
4413
4414 =over 4
4415
4416 =item Value: \@columns
4417
4418 =back
4419
4420 A arrayref of columns to group by. Can include columns of joined tables.
4421
4422   group_by => [qw/ column1 column2 ... /]
4423
4424 =head2 having
4425
4426 =over 4
4427
4428 =item Value: $condition
4429
4430 =back
4431
4432 HAVING is a select statement attribute that is applied between GROUP BY and
4433 ORDER BY. It is applied to the after the grouping calculations have been
4434 done.
4435
4436   having => { 'count_employee' => { '>=', 100 } }
4437
4438 or with an in-place function in which case literal SQL is required:
4439
4440   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4441
4442 =head2 distinct
4443
4444 =over 4
4445
4446 =item Value: (0 | 1)
4447
4448 =back
4449
4450 Set to 1 to group by all columns. If the resultset already has a group_by
4451 attribute, this setting is ignored and an appropriate warning is issued.
4452
4453 =head2 where
4454
4455 =over 4
4456
4457 Adds to the WHERE clause.
4458
4459   # only return rows WHERE deleted IS NULL for all searches
4460   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4461
4462 Can be overridden by passing C<< { where => undef } >> as an attribute
4463 to a resultset.
4464
4465 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4466
4467 =back
4468
4469 =head2 cache
4470
4471 Set to 1 to cache search results. This prevents extra SQL queries if you
4472 revisit rows in your ResultSet:
4473
4474   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4475
4476   while( my $artist = $resultset->next ) {
4477     ... do stuff ...
4478   }
4479
4480   $rs->first; # without cache, this would issue a query
4481
4482 By default, searches are not cached.
4483
4484 For more examples of using these attributes, see
4485 L<DBIx::Class::Manual::Cookbook>.
4486
4487 =head2 for
4488
4489 =over 4
4490
4491 =item Value: ( 'update' | 'shared' | \$scalar )
4492
4493 =back
4494
4495 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4496 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4497 query.
4498
4499 =head1 PREFETCHING
4500
4501 DBIx::Class supports arbitrary related data prefetching from multiple related
4502 sources. Any combination of relationship types and column sets are supported.
4503 If L<collapsing|/collapse> is requested, there is an additional requirement of
4504 selecting enough data to make every individual object uniquely identifiable.
4505
4506 Here are some more involved examples, based on the following relationship map:
4507
4508   # Assuming:
4509   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4510   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4511   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4512
4513   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4514
4515   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4516
4517
4518
4519   my $rs = $schema->resultset('Tag')->search(
4520     undef,
4521     {
4522       prefetch => {
4523         cd => 'artist'
4524       }
4525     }
4526   );
4527
4528 The initial search results in SQL like the following:
4529
4530   SELECT tag.*, cd.*, artist.* FROM tag
4531   JOIN cd ON tag.cd = cd.cdid
4532   JOIN artist ON cd.artist = artist.artistid
4533
4534 L<DBIx::Class> has no need to go back to the database when we access the
4535 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4536 case.
4537
4538 Simple prefetches will be joined automatically, so there is no need
4539 for a C<join> attribute in the above search.
4540
4541 The L</prefetch> attribute can be used with any of the relationship types
4542 and multiple prefetches can be specified together. Below is a more complex
4543 example that prefetches a CD's artist, its liner notes (if present),
4544 the cover image, the tracks on that CD, and the guests on those
4545 tracks.
4546
4547   my $rs = $schema->resultset('CD')->search(
4548     undef,
4549     {
4550       prefetch => [
4551         { artist => 'record_label'},  # belongs_to => belongs_to
4552         'liner_note',                 # might_have
4553         'cover_image',                # has_one
4554         { tracks => 'guests' },       # has_many => has_many
4555       ]
4556     }
4557   );
4558
4559 This will produce SQL like the following:
4560
4561   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4562          tracks.*, guests.*
4563     FROM cd me
4564     JOIN artist artist
4565       ON artist.artistid = me.artistid
4566     JOIN record_label record_label
4567       ON record_label.labelid = artist.labelid
4568     LEFT JOIN track tracks
4569       ON tracks.cdid = me.cdid
4570     LEFT JOIN guest guests
4571       ON guests.trackid = track.trackid
4572     LEFT JOIN liner_notes liner_note
4573       ON liner_note.cdid = me.cdid
4574     JOIN cd_artwork cover_image
4575       ON cover_image.cdid = me.cdid
4576   ORDER BY tracks.cd
4577
4578 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4579 C<tracks>, and C<guests> of the CD will all be available through the
4580 relationship accessors without the need for additional queries to the
4581 database.
4582
4583 =head3 CAVEATS
4584
4585 Prefetch does a lot of deep magic. As such, it may not behave exactly
4586 as you might expect.
4587
4588 =over 4
4589
4590 =item *
4591
4592 Prefetch uses the L</cache> to populate the prefetched relationships. This
4593 may or may not be what you want.
4594
4595 =item *
4596
4597 If you specify a condition on a prefetched relationship, ONLY those
4598 rows that match the prefetched condition will be fetched into that relationship.
4599 This means that adding prefetch to a search() B<may alter> what is returned by
4600 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4601
4602   my $artist_rs = $schema->resultset('Artist')->search({
4603       'cds.year' => 2008,
4604   }, {
4605       join => 'cds',
4606   });
4607
4608   my $count = $artist_rs->first->cds->count;
4609
4610   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4611
4612   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4613
4614   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4615
4616 That cmp_ok() may or may not pass depending on the datasets involved. In other
4617 words the C<WHERE> condition would apply to the entire dataset, just like
4618 it would in regular SQL. If you want to add a condition only to the "right side"
4619 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4620 condition|DBIx::Class::Relationship::Base/condition>
4621
4622 =back
4623
4624 =head1 DBIC BIND VALUES
4625
4626 Because DBIC may need more information to bind values than just the column name
4627 and value itself, it uses a special format for both passing and receiving bind
4628 values.  Each bind value should be composed of an arrayref of
4629 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4630
4631 =over 4
4632
4633 =item dbd_attrs
4634
4635 If present (in any form), this is what is being passed directly to bind_param.
4636 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4637 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4638
4639 If this is specified, all other bind options described below are ignored.
4640
4641 =item sqlt_datatype
4642
4643 If present, this is used to infer the actual bind attribute by passing to
4644 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4645 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4646
4647 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4648 currently drivers are expected to "Do the Right Thing" when given a common
4649 datatype name.  (Not ideal, but that's what we got at this point.)
4650
4651 =item sqlt_size
4652
4653 Currently used to correctly allocate buffers for bind_param_inout().
4654 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4655 or to a sensible value based on the "data_type".
4656
4657 =item dbic_colname
4658
4659 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4660 explicitly specified they are never overridden).  Also used by some weird DBDs,
4661 where the column name should be available at bind_param time (e.g. Oracle).
4662
4663 =back
4664
4665 For backwards compatibility and convenience, the following shortcuts are
4666 supported:
4667
4668   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4669   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4670   [ undef,   $val ] === [ {}, $val ]
4671   $val              === [ {}, $val ]
4672
4673 =head1 AUTHOR AND CONTRIBUTORS
4674
4675 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4676
4677 =head1 LICENSE
4678
4679 You may distribute this code under the same terms as Perl itself.
4680