lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util 'fail_on_internal_wantarray';
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12 use Data::Query::Constants;
  13 use Data::Query::ExprHelpers;
  14 # not importing first() as it will clash with our own method
  15 use List::Util ();
  16
  17 BEGIN {
  18   # De-duplication in _merge_attr() is disabled, but left in for reference
  19   # (the merger is used for other things that ought not to be de-duped)
  20   *__HM_DEDUP = sub () { 0 };
  21 }
  22
  23 use namespace::clean;
  24
  25 use overload
  26         '0+'     => "count",
  27         'bool'   => "_bool",
  28         fallback => 1;
  29
  30 # this is real - CDBICompat overrides it with insanity
  31 # yes, prototype won't matter, but that's for now ;)
  32 sub _bool () { 1 }
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  35
  36 =head1 NAME
  37
  38 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  39
  40 =head1 SYNOPSIS
  41
  42   my $users_rs = $schema->resultset('User');
  43   while( $user = $users_rs->next) {
  44     print $user->username;
  45   }
  46
  47   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  48   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  49
  50 =head1 DESCRIPTION
  51
  52 A ResultSet is an object which stores a set of conditions representing
  53 a query. It is the backbone of DBIx::Class (i.e. the really
  54 important/useful bit).
  55
  56 No SQL is executed on the database when a ResultSet is created, it
  57 just stores all the conditions needed to create the query.
  58
  59 A basic ResultSet representing the data of an entire table is returned
  60 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  61 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  62
  63   my $users_rs = $schema->resultset('User');
  64
  65 A new ResultSet is returned from calling L</search> on an existing
  66 ResultSet. The new one will contain all the conditions of the
  67 original, plus any new conditions added in the C<search> call.
  68
  69 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  70 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  71 represents.
  72
  73 The query that the ResultSet represents is B<only> executed against
  74 the database when these methods are called:
  75 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  76
  77 If a resultset is used in a numeric context it returns the L</count>.
  78 However, if it is used in a boolean context it is B<always> true.  So if
  79 you want to check if a resultset has any results, you must use C<if $rs
  80 != 0>.
  81
  82 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  83
  84 If you want to make your custom ResultSet classes with L<Moose>, use a template
  85 similar to:
  86
  87     package MyApp::Schema::ResultSet::User;
  88
  89     use Moose;
  90     use namespace::autoclean;
  91     use MooseX::NonMoose;
  92     extends 'DBIx::Class::ResultSet';
  93
  94     sub BUILDARGS { $_[2] }
  95
  96     ...your code...
  97
  98     __PACKAGE__->meta->make_immutable;
  99
 100     1;
 101
 102 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 103 clash with the regular ResultSet constructor. Alternatively, you can use:
 104
 105     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 106
 107 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 108 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 109
 110 =head1 EXAMPLES
 111
 112 =head2 Chaining resultsets
 113
 114 Let's say you've got a query that needs to be run to return some data
 115 to the user. But, you have an authorization system in place that
 116 prevents certain users from seeing certain information. So, you want
 117 to construct the basic query in one method, but add constraints to it in
 118 another.
 119
 120   sub get_data {
 121     my $self = shift;
 122     my $request = $self->get_request; # Get a request object somehow.
 123     my $schema = $self->result_source->schema;
 124
 125     my $cd_rs = $schema->resultset('CD')->search({
 126       title => $request->param('title'),
 127       year => $request->param('year'),
 128     });
 129
 130     $cd_rs = $self->apply_security_policy( $cd_rs );
 131
 132     return $cd_rs->all();
 133   }
 134
 135   sub apply_security_policy {
 136     my $self = shift;
 137     my ($rs) = @_;
 138
 139     return $rs->search({
 140       subversive => 0,
 141     });
 142   }
 143
 144 =head3 Resolving conditions and attributes
 145
 146 When a resultset is chained from another resultset (e.g.:
 147 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 148 and attributes with the same keys need resolving.
 149
 150 If any of L</columns>, L</select>, L</as> are present, they reset the
 151 original selection, and start the selection "clean".
 152
 153 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 154 are merged into the existing ones from the original resultset.
 155
 156 The L</where> and L</having> attributes, and any search conditions, are
 157 merged with an SQL C<AND> to the existing condition from the original
 158 resultset.
 159
 160 All other attributes are overridden by any new ones supplied in the
 161 search attributes.
 162
 163 =head2 Multiple queries
 164
 165 Since a resultset just defines a query, you can do all sorts of
 166 things with it with the same object.
 167
 168   # Don't hit the DB yet.
 169   my $cd_rs = $schema->resultset('CD')->search({
 170     title => 'something',
 171     year => 2009,
 172   });
 173
 174   # Each of these hits the DB individually.
 175   my $count = $cd_rs->count;
 176   my $most_recent = $cd_rs->get_column('date_released')->max();
 177   my @records = $cd_rs->all;
 178
 179 And it's not just limited to SELECT statements.
 180
 181   $cd_rs->delete();
 182
 183 This is even cooler:
 184
 185   $cd_rs->create({ artist => 'Fred' });
 186
 187 Which is the same as:
 188
 189   $schema->resultset('CD')->create({
 190     title => 'something',
 191     year => 2009,
 192     artist => 'Fred'
 193   });
 194
 195 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 196
 197 =head1 METHODS
 198
 199 =head2 new
 200
 201 =over 4
 202
 203 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 204
 205 =item Return Value: L<$resultset|/search>
 206
 207 =back
 208
 209 The resultset constructor. Takes a source object (usually a
 210 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 211 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 212 executed as needed by the other methods.
 213
 214 Generally you never construct a resultset manually. Instead you get one
 215 from e.g. a
 216 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 217 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 218 scalar context):
 219
 220   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 221
 222 =over
 223
 224 =item WARNING
 225
 226 If called on an object, proxies to L</new_result> instead, so
 227
 228   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 229
 230 will return a CD object, not a ResultSet, and is equivalent to:
 231
 232   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 233
 234 Please also keep in mind that many internals call L</new_result> directly,
 235 so overloading this method with the idea of intercepting new result object
 236 creation B<will not work>. See also warning pertaining to L</create>.
 237
 238 =back
 239
 240 =cut
 241
 242 sub new {
 243   my $class = shift;
 244   return $class->new_result(@_) if ref $class;
 245
 246   my ($source, $attrs) = @_;
 247   $source = $source->resolve
 248     if $source->isa('DBIx::Class::ResultSourceHandle');
 249
 250   $attrs = { %{$attrs||{}} };
 251   delete @{$attrs}{qw(_sqlmaker_select_args _related_results_construction)};
 252
 253   if ($attrs->{page}) {
 254     $attrs->{rows} ||= 10;
 255   }
 256
 257   $attrs->{alias} ||= 'me';
 258
 259   my $self = bless {
 260     result_source => $source,
 261     cond => $attrs->{where},
 262     pager => undef,
 263     attrs => $attrs,
 264   }, $class;
 265
 266   # if there is a dark selector, this means we are already in a
 267   # chain and the cleanup/sanification was taken care of by
 268   # _search_rs already
 269   $self->_normalize_selection($attrs)
 270     unless $attrs->{_dark_selector};
 271
 272   $self->result_class(
 273     $attrs->{result_class} || $source->result_class
 274   );
 275
 276   $self;
 277 }
 278
 279 =head2 search
 280
 281 =over 4
 282
 283 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 284
 285 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 286
 287 =back
 288
 289   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 290   my $new_rs = $cd_rs->search({ year => 2005 });
 291
 292   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 293                  # year = 2005 OR year = 2004
 294
 295 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 296 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 297 To avoid that, use L</search_rs>.
 298
 299 If you need to pass in additional attributes but no additional condition,
 300 call it as C<search(undef, \%attrs)>.
 301
 302   # "SELECT name, artistid FROM $artist_table"
 303   my @all_artists = $schema->resultset('Artist')->search(undef, {
 304     columns => [qw/name artistid/],
 305   });
 306
 307 For a list of attributes that can be passed to C<search>, see
 308 L</ATTRIBUTES>. For more examples of using this function, see
 309 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 310 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 311 and its extension L<DBIx::Class::SQLMaker>.
 312
 313 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 314
 315 =head3 CAVEAT
 316
 317 Note that L</search> does not process/deflate any of the values passed in the
 318 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 319 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 320 manually that any value passed to this method will stringify to something the
 321 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 322 objects, for more info see:
 323 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 324
 325 =cut
 326
 327 sub search {
 328   my $self = shift;
 329   my $rs = $self->search_rs( @_ );
 330
 331   if (wantarray) {
 332     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray($rs);
 333     return $rs->all;
 334   }
 335   elsif (defined wantarray) {
 336     return $rs;
 337   }
 338   else {
 339     # we can be called by a relationship helper, which in
 340     # turn may be called in void context due to some braindead
 341     # overload or whatever else the user decided to be clever
 342     # at this particular day. Thus limit the exception to
 343     # external code calls only
 344     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 345       if (caller)[0] !~ /^\QDBIx::Class::/;
 346
 347     return ();
 348   }
 349 }
 350
 351 =head2 search_rs
 352
 353 =over 4
 354
 355 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 356
 357 =item Return Value: L<$resultset|/search>
 358
 359 =back
 360
 361 This method does the same exact thing as search() except it will
 362 always return a resultset, even in list context.
 363
 364 =cut
 365
 366 sub search_rs {
 367   my $self = shift;
 368
 369   my $rsrc = $self->result_source;
 370   my ($call_cond, $call_attrs);
 371
 372   # Special-case handling for (undef, undef) or (undef)
 373   # Note that (foo => undef) is valid deprecated syntax
 374   @_ = () if not scalar grep { defined $_ } @_;
 375
 376   # just a cond
 377   if (@_ == 1) {
 378     $call_cond = shift;
 379   }
 380   # fish out attrs in the ($condref, $attr) case
 381   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 382     ($call_cond, $call_attrs) = @_;
 383   }
 384   elsif (@_ % 2) {
 385     $self->throw_exception('Odd number of arguments to search')
 386   }
 387   # legacy search
 388   elsif (@_) {
 389     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 390       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 391
 392     for my $i (0 .. $#_) {
 393       next if $i % 2;
 394       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 395         if (! defined $_[$i] or ref $_[$i] ne '');
 396     }
 397
 398     $call_cond = { @_ };
 399   }
 400
 401   if (blessed($call_cond) and $call_cond->isa('Data::Query::ExprBuilder')) {
 402     $call_cond = \$call_cond->{expr};
 403   }
 404
 405   # see if we can keep the cache (no $rs changes)
 406   my $cache;
 407   my %safe = (alias => 1, cache => 1);
 408   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 409     ! defined $call_cond
 410       or
 411     ref $call_cond eq 'HASH' && ! keys %$call_cond
 412       or
 413     ref $call_cond eq 'ARRAY' && ! @$call_cond
 414   )) {
 415     $cache = $self->get_cache;
 416   }
 417
 418   my $old_attrs = { %{$self->{attrs}} };
 419   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 420
 421   my $new_attrs = { %$old_attrs };
 422
 423   # take care of call attrs (only if anything is changing)
 424   if ($call_attrs and keys %$call_attrs) {
 425
 426     # copy for _normalize_selection
 427     $call_attrs = { %$call_attrs };
 428
 429     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 430
 431     # reset the current selector list if new selectors are supplied
 432     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 433       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 434     }
 435
 436     # Normalize the new selector list (operates on the passed-in attr structure)
 437     # Need to do it on every chain instead of only once on _resolved_attrs, in
 438     # order to allow detection of empty vs partial 'as'
 439     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 440       if $old_attrs->{_dark_selector};
 441     $self->_normalize_selection ($call_attrs);
 442
 443     # start with blind overwriting merge, exclude selector attrs
 444     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 445     delete @{$new_attrs}{@selector_attrs};
 446
 447     for (@selector_attrs) {
 448       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 449         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 450     }
 451
 452     # older deprecated name, use only if {columns} is not there
 453     if (my $c = delete $new_attrs->{cols}) {
 454       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 455       if ($new_attrs->{columns}) {
 456         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 457       }
 458       else {
 459         $new_attrs->{columns} = $c;
 460       }
 461     }
 462
 463
 464     # join/prefetch use their own crazy merging heuristics
 465     foreach my $key (qw/join prefetch/) {
 466       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 467         if exists $call_attrs->{$key};
 468     }
 469
 470     # stack binds together
 471     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 472   }
 473
 474
 475   for ($old_where, $call_cond) {
 476     if (defined $_) {
 477       $new_attrs->{where} = $self->_stack_cond (
 478         $_, $new_attrs->{where}
 479       );
 480     }
 481   }
 482
 483   if (defined $old_having) {
 484     $new_attrs->{having} = $self->_stack_cond (
 485       $old_having, $new_attrs->{having}
 486     )
 487   }
 488
 489   my $rs = (ref $self)->new($rsrc, $new_attrs);
 490
 491   $rs->set_cache($cache) if ($cache);
 492
 493   return $rs;
 494 }
 495
 496 my $dark_sel_dumper;
 497 sub _normalize_selection {
 498   my ($self, $attrs) = @_;
 499
 500   # legacy syntax
 501   if ( exists $attrs->{include_columns} ) {
 502     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 503     $attrs->{'+columns'} = $self->_merge_attr(
 504       $attrs->{'+columns'}, delete $attrs->{include_columns}
 505     );
 506   }
 507
 508   # columns are always placed first, however
 509
 510   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 511   # delay the decision on whether to use a default select list ($rsrc->columns)
 512   # allowing stuff like the remove_columns helper to work
 513   #
 514   # select/as +select/+as pairs need special handling - the amount of select/as
 515   # elements in each pair does *not* have to be equal (think multicolumn
 516   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 517   # supplied at all) - try to infer the alias, either from the -as parameter
 518   # of the selector spec, or use the parameter whole if it looks like a column
 519   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 520   # is ok as well), but make sure no more additions to the 'as' chain take place
 521   for my $pref ('', '+') {
 522
 523     my ($sel, $as) = map {
 524       my $key = "${pref}${_}";
 525
 526       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 527         ? @{$attrs->{$key}}
 528         : $attrs->{$key} || ()
 529       ];
 530       delete $attrs->{$key};
 531       $val;
 532     } qw/select as/;
 533
 534     if (! @$as and ! @$sel ) {
 535       next;
 536     }
 537     elsif (@$as and ! @$sel) {
 538       $self->throw_exception(
 539         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 540       );
 541     }
 542     elsif( ! @$as ) {
 543       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 544       # if any @$as has been supplied we assume the user knows what (s)he is doing
 545       # and blindly keep stacking up pieces
 546       unless ($attrs->{_dark_selector}) {
 547         SELECTOR:
 548         for (@$sel) {
 549           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 550             push @$as, $_->{-as};
 551           }
 552           # assume any plain no-space, no-parenthesis string to be a column spec
 553           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 554           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 555             push @$as, $_;
 556           }
 557           # if all else fails - raise a flag that no more aliasing will be allowed
 558           else {
 559             $attrs->{_dark_selector} = {
 560               plus_stage => $pref,
 561               string => ($dark_sel_dumper ||= do {
 562                   require Data::Dumper::Concise;
 563                   Data::Dumper::Concise::DumperObject()->Indent(0);
 564                 })->Values([$_])->Dump
 565               ,
 566             };
 567             last SELECTOR;
 568           }
 569         }
 570       }
 571     }
 572     elsif (@$as < @$sel) {
 573       $self->throw_exception(
 574         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 575       );
 576     }
 577     elsif ($pref and $attrs->{_dark_selector}) {
 578       $self->throw_exception(
 579         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 580       );
 581     }
 582
 583
 584     # merge result
 585     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 586     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 587   }
 588 }
 589
 590 sub _stack_cond {
 591   my ($self, $left, $right) = @_;
 592
 593   # collapse single element top-level conditions
 594   # (single pass only, unlikely to need recursion)
 595   for ($left, $right) {
 596     if (ref $_ eq 'ARRAY') {
 597       if (@$_ == 0) {
 598         $_ = undef;
 599       }
 600       elsif (@$_ == 1) {
 601         $_ = $_->[0];
 602       }
 603     }
 604     elsif (ref $_ eq 'HASH') {
 605       my ($first, $more) = keys %$_;
 606
 607       # empty hash
 608       if (! defined $first) {
 609         $_ = undef;
 610       }
 611       # one element hash
 612       elsif (! defined $more) {
 613         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 614           $_ = $_->{'-and'};
 615         }
 616         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 617           $_ = $_->{'-or'};
 618         }
 619       }
 620     }
 621   }
 622
 623   # merge hashes with weeding out of duplicates (simple cases only)
 624   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 625
 626     # shallow copy to destroy
 627     $right = { %$right };
 628     for (grep { exists $right->{$_} } keys %$left) {
 629       # the use of eq_deeply here is justified - the rhs of an
 630       # expression can contain a lot of twisted weird stuff
 631       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 632     }
 633
 634     $right = undef unless keys %$right;
 635   }
 636
 637
 638   if (defined $left xor defined $right) {
 639     return defined $left ? $left : $right;
 640   }
 641   elsif (! defined $left) {
 642     return undef;
 643   }
 644   else {
 645     return { -and => [ $left, $right ] };
 646   }
 647 }
 648
 649 =head2 search_literal
 650
 651 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 652 should only be used in that context. C<search_literal> is a convenience
 653 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 654 want to ensure columns are bound correctly, use L</search>.
 655
 656 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 657 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 658 require C<search_literal>.
 659
 660 =over 4
 661
 662 =item Arguments: $sql_fragment, @standalone_bind_values
 663
 664 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 665
 666 =back
 667
 668   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 669   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 670
 671 Pass a literal chunk of SQL to be added to the conditional part of the
 672 resultset query.
 673
 674 Example of how to use C<search> instead of C<search_literal>
 675
 676   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 677   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 678
 679 =cut
 680
 681 sub search_literal {
 682   my ($self, $sql, @bind) = @_;
 683   my $attr;
 684   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 685     $attr = pop @bind;
 686   }
 687   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 688 }
 689
 690 =head2 find
 691
 692 =over 4
 693
 694 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 695
 696 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 697
 698 =back
 699
 700 Finds and returns a single row based on supplied criteria. Takes either a
 701 hashref with the same format as L</create> (including inference of foreign
 702 keys from related objects), or a list of primary key values in the same
 703 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 704 declaration on the L</result_source>.
 705
 706 In either case an attempt is made to combine conditions already existing on
 707 the resultset with the condition passed to this method.
 708
 709 To aid with preparing the correct query for the storage you may supply the
 710 C<key> attribute, which is the name of a
 711 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 712 unique constraint corresponding to the
 713 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 714 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 715 to construct a query that satisfies the named unique constraint fully (
 716 non-NULL values for each column member of the constraint) an exception is
 717 thrown.
 718
 719 If no C<key> is specified, the search is carried over all unique constraints
 720 which are fully defined by the available condition.
 721
 722 If no such constraint is found, C<find> currently defaults to a simple
 723 C<< search->(\%column_values) >> which may or may not do what you expect.
 724 Note that this fallback behavior may be deprecated in further versions. If
 725 you need to search with arbitrary conditions - use L</search>. If the query
 726 resulting from this fallback produces more than one row, a warning to the
 727 effect is issued, though only the first row is constructed and returned as
 728 C<$result_object>.
 729
 730 In addition to C<key>, L</find> recognizes and applies standard
 731 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 732
 733 Note that if you have extra concerns about the correctness of the resulting
 734 query you need to specify the C<key> attribute and supply the entire condition
 735 as an argument to find (since it is not always possible to perform the
 736 combination of the resultset condition with the supplied one, especially if
 737 the resultset condition contains literal sql).
 738
 739 For example, to find a row by its primary key:
 740
 741   my $cd = $schema->resultset('CD')->find(5);
 742
 743 You can also find a row by a specific unique constraint:
 744
 745   my $cd = $schema->resultset('CD')->find(
 746     {
 747       artist => 'Massive Attack',
 748       title  => 'Mezzanine',
 749     },
 750     { key => 'cd_artist_title' }
 751   );
 752
 753 See also L</find_or_create> and L</update_or_create>.
 754
 755 =cut
 756
 757 sub find {
 758   my $self = shift;
 759   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 760
 761   my $rsrc = $self->result_source;
 762
 763   my $constraint_name;
 764   if (exists $attrs->{key}) {
 765     $constraint_name = defined $attrs->{key}
 766       ? $attrs->{key}
 767       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 768     ;
 769   }
 770
 771   # Parse out the condition from input
 772   my $call_cond;
 773
 774   if (ref $_[0] eq 'HASH') {
 775     $call_cond = { %{$_[0]} };
 776   }
 777   else {
 778     # if only values are supplied we need to default to 'primary'
 779     $constraint_name = 'primary' unless defined $constraint_name;
 780
 781     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 782
 783     $self->throw_exception(
 784       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 785     ) unless @c_cols;
 786
 787     $self->throw_exception (
 788       'find() expects either a column/value hashref, or a list of values '
 789     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 790     ) unless @c_cols == @_;
 791
 792     $call_cond = {};
 793     @{$call_cond}{@c_cols} = @_;
 794   }
 795
 796   my %related;
 797   for my $key (keys %$call_cond) {
 798     if (
 799       my $keyref = ref($call_cond->{$key})
 800         and
 801       my $relinfo = $rsrc->relationship_info($key)
 802     ) {
 803       my $val = delete $call_cond->{$key};
 804
 805       next if $keyref eq 'ARRAY'; # has_many for multi_create
 806
 807       my $rel_q = $rsrc->_resolve_condition(
 808         $relinfo->{cond}, $val, $key, $key
 809       );
 810       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 811       @related{keys %$rel_q} = values %$rel_q;
 812     }
 813   }
 814
 815   # relationship conditions take precedence (?)
 816   @{$call_cond}{keys %related} = values %related;
 817
 818   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 819   my $final_cond;
 820   if (defined $constraint_name) {
 821     $final_cond = $self->_qualify_cond_columns (
 822
 823       $self->_build_unique_cond (
 824         $constraint_name,
 825         $call_cond,
 826       ),
 827
 828       $alias,
 829     );
 830   }
 831   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 832     # This means that we got here after a merger of relationship conditions
 833     # in ::Relationship::Base::search_related (the row method), and furthermore
 834     # the relationship is of the 'single' type. This means that the condition
 835     # provided by the relationship (already attached to $self) is sufficient,
 836     # as there can be only one row in the database that would satisfy the
 837     # relationship
 838   }
 839   else {
 840     # no key was specified - fall down to heuristics mode:
 841     # run through all unique queries registered on the resultset, and
 842     # 'OR' all qualifying queries together
 843     my (@unique_queries, %seen_column_combinations);
 844     for my $c_name ($rsrc->unique_constraint_names) {
 845       next if $seen_column_combinations{
 846         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 847       }++;
 848
 849       push @unique_queries, try {
 850         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 851       } || ();
 852     }
 853
 854     $final_cond = @unique_queries
 855       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 856       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 857     ;
 858   }
 859
 860   # Run the query, passing the result_class since it should propagate for find
 861   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 862   if ($rs->_resolved_attrs->{collapse}) {
 863     my $row = $rs->next;
 864     carp "Query returned more than one row" if $rs->next;
 865     return $row;
 866   }
 867   else {
 868     return $rs->single;
 869   }
 870 }
 871
 872 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 873 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 874 #
 875 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 876 # condition. It is provided for overrides until a saner way forward is devised
 877 #
 878 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 879 # the road. Please adjust your tests accordingly to catch this situation early
 880 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 881 #
 882 # The method will not be removed without an adequately complete replacement
 883 # for strict-mode enforcement
 884 sub _non_unique_find_fallback {
 885   my ($self, $cond, $attrs) = @_;
 886
 887   return $self->_qualify_cond_columns(
 888     $cond,
 889     exists $attrs->{alias}
 890       ? $attrs->{alias}
 891       : $self->{attrs}{alias}
 892   );
 893 }
 894
 895
 896 sub _qualify_cond_columns {
 897   my ($self, $cond, $alias) = @_;
 898
 899   my %aliased = %$cond;
 900   for (keys %aliased) {
 901     $aliased{"$alias.$_"} = delete $aliased{$_}
 902       if $_ !~ /\./;
 903   }
 904
 905   return \%aliased;
 906 }
 907
 908 sub _build_unique_cond {
 909   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 910
 911   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 912
 913   # combination may fail if $self->{cond} is non-trivial
 914   my ($final_cond) = try {
 915     $self->_merge_with_rscond ($extra_cond)
 916   } catch {
 917     +{ %$extra_cond }
 918   };
 919
 920   # trim out everything not in $columns
 921   $final_cond = { map {
 922     exists $final_cond->{$_}
 923       ? ( $_ => $final_cond->{$_} )
 924       : ()
 925   } @c_cols };
 926
 927   if (my @missing = grep
 928     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 929     (@c_cols)
 930   ) {
 931     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 932       $constraint_name,
 933       join (', ', map { "'$_'" } @missing),
 934     ) );
 935   }
 936
 937   if (
 938     !$croak_on_null
 939       and
 940     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 941       and
 942     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 943   ) {
 944     carp_unique ( sprintf (
 945       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 946     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 947     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 948       $constraint_name,
 949       join (', ', map { "'$_'" } @undefs),
 950     ));
 951   }
 952
 953   return $final_cond;
 954 }
 955
 956 =head2 search_related
 957
 958 =over 4
 959
 960 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 961
 962 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 963
 964 =back
 965
 966   $new_rs = $cd_rs->search_related('artist', {
 967     name => 'Emo-R-Us',
 968   });
 969
 970 Searches the specified relationship, optionally specifying a condition and
 971 attributes for matching records. See L</ATTRIBUTES> for more information.
 972
 973 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 974 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 975
 976 See also L</search_related_rs>.
 977
 978 =cut
 979
 980 sub search_related {
 981   return shift->related_resultset(shift)->search(@_);
 982 }
 983
 984 =head2 search_related_rs
 985
 986 This method works exactly the same as search_related, except that
 987 it guarantees a resultset, even in list context.
 988
 989 =cut
 990
 991 sub search_related_rs {
 992   return shift->related_resultset(shift)->search_rs(@_);
 993 }
 994
 995 =head2 cursor
 996
 997 =over 4
 998
 999 =item Arguments: none
1000
1001 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1002
1003 =back
1004
1005 Returns a storage-driven cursor to the given resultset. See
1006 L<DBIx::Class::Cursor> for more information.
1007
1008 =cut
1009
1010 sub cursor {
1011   my $self = shift;
1012
1013   return $self->{cursor} ||= do {
1014     my $attrs = $self->_resolved_attrs;
1015     $self->result_source->storage->select(
1016       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1017     );
1018   };
1019 }
1020
1021 =head2 single
1022
1023 =over 4
1024
1025 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1026
1027 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1028
1029 =back
1030
1031   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1032
1033 Inflates the first result without creating a cursor if the resultset has
1034 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1035 of L</search>.
1036
1037 While this method can take an optional search condition (just like L</search>)
1038 being a fast-code-path it does not recognize search attributes. If you need to
1039 add extra joins or similar, call L</search> and then chain-call L</single> on the
1040 L<DBIx::Class::ResultSet> returned.
1041
1042 =over
1043
1044 =item B<Note>
1045
1046 As of 0.08100, this method enforces the assumption that the preceding
1047 query returns only one row. If more than one row is returned, you will receive
1048 a warning:
1049
1050   Query returned more than one row
1051
1052 In this case, you should be using L</next> or L</find> instead, or if you really
1053 know what you are doing, use the L</rows> attribute to explicitly limit the size
1054 of the resultset.
1055
1056 This method will also throw an exception if it is called on a resultset prefetching
1057 has_many, as such a prefetch implies fetching multiple rows from the database in
1058 order to assemble the resulting object.
1059
1060 =back
1061
1062 =cut
1063
1064 sub single {
1065   my ($self, $where) = @_;
1066   if(@_ > 2) {
1067       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1068   }
1069
1070   my $attrs = { %{$self->_resolved_attrs} };
1071
1072   $self->throw_exception(
1073     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1074   ) if $attrs->{collapse};
1075
1076   if ($where) {
1077     if (defined $attrs->{where}) {
1078       $attrs->{where} = {
1079         '-and' =>
1080             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1081                $where, delete $attrs->{where} ]
1082       };
1083     } else {
1084       $attrs->{where} = $where;
1085     }
1086   }
1087
1088   my $data = [ $self->result_source->storage->select_single(
1089     $attrs->{from}, $attrs->{select},
1090     $attrs->{where}, $attrs
1091   )];
1092
1093   return undef unless @$data;
1094   $self->{_stashed_rows} = [ $data ];
1095   $self->_construct_results->[0];
1096 }
1097
1098
1099 # _collapse_query
1100 #
1101 # Recursively collapse the query, accumulating values for each column.
1102
1103 sub _collapse_query {
1104   my ($self, $query, $collapsed) = @_;
1105
1106   $collapsed ||= {};
1107
1108   if (ref $query eq 'ARRAY') {
1109     foreach my $subquery (@$query) {
1110       next unless ref $subquery;  # -or
1111       $collapsed = $self->_collapse_query($subquery, $collapsed);
1112     }
1113   }
1114   elsif (ref $query eq 'HASH') {
1115     if (keys %$query and (keys %$query)[0] eq '-and') {
1116       foreach my $subquery (@{$query->{-and}}) {
1117         $collapsed = $self->_collapse_query($subquery, $collapsed);
1118       }
1119     }
1120     else {
1121       foreach my $col (keys %$query) {
1122         my $value = $query->{$col};
1123         $collapsed->{$col}{$value}++;
1124       }
1125     }
1126   }
1127
1128   return $collapsed;
1129 }
1130
1131 =head2 get_column
1132
1133 =over 4
1134
1135 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1136
1137 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1138
1139 =back
1140
1141   my $max_length = $rs->get_column('length')->max;
1142
1143 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1144
1145 =cut
1146
1147 sub get_column {
1148   my ($self, $column) = @_;
1149   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1150   return $new;
1151 }
1152
1153 =head2 search_like
1154
1155 =over 4
1156
1157 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1158
1159 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1160
1161 =back
1162
1163   # WHERE title LIKE '%blue%'
1164   $cd_rs = $rs->search_like({ title => '%blue%'});
1165
1166 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1167 that this is simply a convenience method retained for ex Class::DBI users.
1168 You most likely want to use L</search> with specific operators.
1169
1170 For more information, see L<DBIx::Class::Manual::Cookbook>.
1171
1172 This method is deprecated and will be removed in 0.09. Use L</search()>
1173 instead. An example conversion is:
1174
1175   ->search_like({ foo => 'bar' });
1176
1177   # Becomes
1178
1179   ->search({ foo => { like => 'bar' } });
1180
1181 =cut
1182
1183 sub search_like {
1184   my $class = shift;
1185   carp_unique (
1186     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1187    .' Instead use ->search({ x => { -like => "y%" } })'
1188    .' (note the outer pair of {}s - they are important!)'
1189   );
1190   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1191   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1192   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1193   return $class->search($query, { %$attrs });
1194 }
1195
1196 =head2 slice
1197
1198 =over 4
1199
1200 =item Arguments: $first, $last
1201
1202 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1203
1204 =back
1205
1206 Returns a resultset or object list representing a subset of elements from the
1207 resultset slice is called on. Indexes are from 0, i.e., to get the first
1208 three records, call:
1209
1210   my ($one, $two, $three) = $rs->slice(0, 2);
1211
1212 =cut
1213
1214 sub slice {
1215   my ($self, $min, $max) = @_;
1216   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1217   $attrs->{offset} = $self->{attrs}{offset} || 0;
1218   $attrs->{offset} += $min;
1219   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1220   return $self->search(undef, $attrs);
1221 }
1222
1223 =head2 next
1224
1225 =over 4
1226
1227 =item Arguments: none
1228
1229 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1230
1231 =back
1232
1233 Returns the next element in the resultset (C<undef> is there is none).
1234
1235 Can be used to efficiently iterate over records in the resultset:
1236
1237   my $rs = $schema->resultset('CD')->search;
1238   while (my $cd = $rs->next) {
1239     print $cd->title;
1240   }
1241
1242 Note that you need to store the resultset object, and call C<next> on it.
1243 Calling C<< resultset('Table')->next >> repeatedly will always return the
1244 first record from the resultset.
1245
1246 =cut
1247
1248 sub next {
1249   my ($self) = @_;
1250
1251   if (my $cache = $self->get_cache) {
1252     $self->{all_cache_position} ||= 0;
1253     return $cache->[$self->{all_cache_position}++];
1254   }
1255
1256   if ($self->{attrs}{cache}) {
1257     delete $self->{pager};
1258     $self->{all_cache_position} = 1;
1259     return ($self->all)[0];
1260   }
1261
1262   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1263
1264   $self->{_stashed_results} = $self->_construct_results
1265     or return undef;
1266
1267   return shift @{$self->{_stashed_results}};
1268 }
1269
1270 # Constructs as many results as it can in one pass while respecting
1271 # cursor laziness. Several modes of operation:
1272 #
1273 # * Always builds everything present in @{$self->{_stashed_rows}}
1274 # * If called with $fetch_all true - pulls everything off the cursor and
1275 #   builds all result structures (or objects) in one pass
1276 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1277 #   and if the resultset is ordered properly by the left side:
1278 #   * Fetches stuff off the cursor until the "master object" changes,
1279 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1280 #   OR
1281 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1282 #     was requested (there is no other way to collapse except for an
1283 #     eager cursor)
1284 # * If no collapse is requested - just get the next row, construct and
1285 #   return
1286 sub _construct_results {
1287   my ($self, $fetch_all) = @_;
1288
1289   my $rsrc = $self->result_source;
1290   my $attrs = $self->_resolved_attrs;
1291
1292   if (
1293     ! $fetch_all
1294       and
1295     ! $attrs->{order_by}
1296       and
1297     $attrs->{collapse}
1298       and
1299     my @pcols = $rsrc->primary_columns
1300   ) {
1301     # default order for collapsing unless the user asked for something
1302     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1303     $attrs->{_ordered_for_collapse} = 1;
1304     $attrs->{_order_is_artificial} = 1;
1305   }
1306
1307   # this will be used as both initial raw-row collector AND as a RV of
1308   # _construct_results. Not regrowing the array twice matters a lot...
1309   # a surprising amount actually
1310   my $rows = delete $self->{_stashed_rows};
1311
1312   my $cursor; # we may not need one at all
1313
1314   my $did_fetch_all = $fetch_all;
1315
1316   if ($fetch_all) {
1317     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1318     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1319   }
1320   elsif( $attrs->{collapse} ) {
1321
1322     # a cursor will need to be closed over in case of collapse
1323     $cursor = $self->cursor;
1324
1325     $attrs->{_ordered_for_collapse} = (
1326       (
1327         $attrs->{order_by}
1328           and
1329         $rsrc->schema
1330               ->storage
1331                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1332       ) ? 1 : 0
1333     ) unless defined $attrs->{_ordered_for_collapse};
1334
1335     if (! $attrs->{_ordered_for_collapse}) {
1336       $did_fetch_all = 1;
1337
1338       # instead of looping over ->next, use ->all in stealth mode
1339       # *without* calling a ->reset afterwards
1340       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1341       if (! $cursor->{_done}) {
1342         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1343         $cursor->{_done} = 1;
1344       }
1345     }
1346   }
1347
1348   if (! $did_fetch_all and ! @{$rows||[]} ) {
1349     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1350     $cursor ||= $self->cursor;
1351     if (scalar (my @r = $cursor->next) ) {
1352       $rows = [ \@r ];
1353     }
1354   }
1355
1356   return undef unless @{$rows||[]};
1357
1358   # sanity check - people are too clever for their own good
1359   if ($attrs->{collapse} and my $aliastypes = $attrs->{_sqlmaker_select_args}[3]{_aliastypes} ) {
1360
1361     my $multiplied_selectors;
1362     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1363       if (
1364         $aliastypes->{multiplying}{$sel_alias}
1365           or
1366         $aliastypes->{premultiplied}{$sel_alias}
1367       ) {
1368         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1369       }
1370     }
1371
1372     for my $i (0 .. $#{$attrs->{as}} ) {
1373       my $sel = $attrs->{select}[$i];
1374
1375       if (ref $sel eq 'SCALAR') {
1376         $sel = $$sel;
1377       }
1378       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1379         $sel = $$sel->[0];
1380       }
1381
1382       $self->throw_exception(
1383         'Result collapse not possible - selection from a has_many source redirected to the main object'
1384       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1385     }
1386   }
1387
1388   # hotspot - skip the setter
1389   my $res_class = $self->_result_class;
1390
1391   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1392     $res_class->can ('inflate_result')
1393       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1394   };
1395
1396   my $infmap = $attrs->{as};
1397
1398   $self->{_result_inflator}{is_core_row} = ( (
1399     $inflator_cref
1400       ==
1401     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1402   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1403
1404   $self->{_result_inflator}{is_hri} = ( (
1405     ! $self->{_result_inflator}{is_core_row}
1406       and
1407     $inflator_cref == (
1408       require DBIx::Class::ResultClass::HashRefInflator
1409         &&
1410       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1411     )
1412   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1413
1414
1415   if (! $attrs->{_related_results_construction}) {
1416     # construct a much simpler array->hash folder for the one-table cases right here
1417     if ($self->{_result_inflator}{is_hri}) {
1418       for my $r (@$rows) {
1419         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1420       }
1421     }
1422     # FIXME SUBOPTIMAL this is a very very very hot spot
1423     # while rather optimal we can *still* do much better, by
1424     # building a smarter Row::inflate_result(), and
1425     # switch to feeding it data via a much leaner interface
1426     #
1427     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1428     # this particular resultset size
1429     elsif (@$rows < 60) {
1430       for my $r (@$rows) {
1431         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1432       }
1433     }
1434     else {
1435       eval sprintf (
1436         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1437         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1438       );
1439     }
1440   }
1441   else {
1442     my $parser_type =
1443         $self->{_result_inflator}{is_hri}       ? 'hri'
1444       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1445       :                                           'classic_nonpruning'
1446     ;
1447
1448     # $args and $attrs to _mk_row_parser are separated to delineate what is
1449     # core collapser stuff and what is dbic $rs specific
1450     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1451       eval => 1,
1452       inflate_map => $infmap,
1453       collapse => $attrs->{collapse},
1454       premultiplied => $attrs->{_main_source_premultiplied},
1455       hri_style => $self->{_result_inflator}{is_hri},
1456       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1457     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1458
1459     # column_info metadata historically hasn't been too reliable.
1460     # We need to start fixing this somehow (the collapse resolver
1461     # can't work without it). Add an explicit check for the *main*
1462     # result, hopefully this will gradually weed out such errors
1463     #
1464     # FIXME - this is a temporary kludge that reduces performance
1465     # It is however necessary for the time being
1466     my ($unrolled_non_null_cols_to_check, $err);
1467
1468     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1469
1470       $err =
1471         'Collapse aborted due to invalid ResultSource metadata - the following '
1472       . 'selections are declared non-nullable but NULLs were retrieved: '
1473       ;
1474
1475       my @violating_idx;
1476       COL: for my $i (@$check_non_null_cols) {
1477         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1478       }
1479
1480       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1481         if @violating_idx;
1482
1483       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1484     }
1485
1486     my $next_cref =
1487       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1488     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1489 sub {
1490   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1491   my @r = $cursor->next or return;
1492   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1493     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1494   }
1495   \@r
1496 }
1497 EOS
1498     : sub {
1499         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1500         my @r = $cursor->next or return;
1501         \@r
1502       }
1503     ;
1504
1505     $self->{_row_parser}{$parser_type}{cref}->(
1506       $rows,
1507       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1508     );
1509
1510     # Special-case multi-object HRI - there is no $inflator_cref pass
1511     unless ($self->{_result_inflator}{is_hri}) {
1512       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1513     }
1514   }
1515
1516   # The @$rows check seems odd at first - why wouldn't we want to warn
1517   # regardless? The issue is things like find() etc, where the user
1518   # *knows* only one result will come back. In these cases the ->all
1519   # is not a pessimization, but rather something we actually want
1520   carp_unique(
1521     'Unable to properly collapse has_many results in iterator mode due '
1522   . 'to order criteria - performed an eager cursor slurp underneath. '
1523   . 'Consider using ->all() instead'
1524   ) if ( ! $fetch_all and @$rows > 1 );
1525
1526   return $rows;
1527 }
1528
1529 =head2 result_source
1530
1531 =over 4
1532
1533 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1534
1535 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1536
1537 =back
1538
1539 An accessor for the primary ResultSource object from which this ResultSet
1540 is derived.
1541
1542 =head2 result_class
1543
1544 =over 4
1545
1546 =item Arguments: $result_class?
1547
1548 =item Return Value: $result_class
1549
1550 =back
1551
1552 An accessor for the class to use when creating result objects. Defaults to
1553 C<< result_source->result_class >> - which in most cases is the name of the
1554 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1555
1556 Note that changing the result_class will also remove any components
1557 that were originally loaded in the source class via
1558 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1559 in the original source class will not run.
1560
1561 =cut
1562
1563 sub result_class {
1564   my ($self, $result_class) = @_;
1565   if ($result_class) {
1566
1567     # don't fire this for an object
1568     $self->ensure_class_loaded($result_class)
1569       unless ref($result_class);
1570
1571     if ($self->get_cache) {
1572       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1573     }
1574     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1575     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1576       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1577     }
1578
1579     $self->_result_class($result_class);
1580
1581     delete $self->{_result_inflator};
1582   }
1583   $self->_result_class;
1584 }
1585
1586 =head2 count
1587
1588 =over 4
1589
1590 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1591
1592 =item Return Value: $count
1593
1594 =back
1595
1596 Performs an SQL C<COUNT> with the same query as the resultset was built
1597 with to find the number of elements. Passing arguments is equivalent to
1598 C<< $rs->search ($cond, \%attrs)->count >>
1599
1600 =cut
1601
1602 sub count {
1603   my $self = shift;
1604   return $self->search(@_)->count if @_ and defined $_[0];
1605   return scalar @{ $self->get_cache } if $self->get_cache;
1606
1607   my $attrs = { %{ $self->_resolved_attrs } };
1608
1609   # this is a little optimization - it is faster to do the limit
1610   # adjustments in software, instead of a subquery
1611   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1612
1613   my $crs;
1614   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1615     $crs = $self->_count_subq_rs ($attrs);
1616   }
1617   else {
1618     $crs = $self->_count_rs ($attrs);
1619   }
1620   my $count = $crs->next;
1621
1622   $count -= $offset if $offset;
1623   $count = $rows if $rows and $rows < $count;
1624   $count = 0 if ($count < 0);
1625
1626   return $count;
1627 }
1628
1629 =head2 count_rs
1630
1631 =over 4
1632
1633 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1634
1635 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1636
1637 =back
1638
1639 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1640 This can be very handy for subqueries:
1641
1642   ->search( { amount => $some_rs->count_rs->as_query } )
1643
1644 As with regular resultsets the SQL query will be executed only after
1645 the resultset is accessed via L</next> or L</all>. That would return
1646 the same single value obtainable via L</count>.
1647
1648 =cut
1649
1650 sub count_rs {
1651   my $self = shift;
1652   return $self->search(@_)->count_rs if @_;
1653
1654   # this may look like a lack of abstraction (count() does about the same)
1655   # but in fact an _rs *must* use a subquery for the limits, as the
1656   # software based limiting can not be ported if this $rs is to be used
1657   # in a subquery itself (i.e. ->as_query)
1658   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1659     return $self->_count_subq_rs($self->{_attrs});
1660   }
1661   else {
1662     return $self->_count_rs($self->{_attrs});
1663   }
1664 }
1665
1666 #
1667 # returns a ResultSetColumn object tied to the count query
1668 #
1669 sub _count_rs {
1670   my ($self, $attrs) = @_;
1671
1672   my $rsrc = $self->result_source;
1673
1674   my $tmp_attrs = { %$attrs };
1675   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1676   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1677
1678   # overwrite the selector (supplied by the storage)
1679   $rsrc->resultset_class->new($rsrc, {
1680     %$tmp_attrs,
1681     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1682     as => 'count',
1683   })->get_column ('count');
1684 }
1685
1686 #
1687 # same as above but uses a subquery
1688 #
1689 sub _count_subq_rs {
1690   my ($self, $attrs) = @_;
1691
1692   my $rsrc = $self->result_source;
1693
1694   my $sub_attrs = { %$attrs };
1695   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1696   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1697
1698   # if we multi-prefetch we group_by something unique, as this is what we would
1699   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1700   if ( $attrs->{collapse}  ) {
1701     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1702       $rsrc->_identifying_column_set || $self->throw_exception(
1703         'Unable to construct a unique group_by criteria properly collapsing the '
1704       . 'has_many prefetch before count()'
1705       );
1706     } ]
1707   }
1708
1709   # Calculate subquery selector
1710   if (my $g = $sub_attrs->{group_by}) {
1711
1712     my $sql_maker = $rsrc->storage->sql_maker;
1713
1714     # necessary as the group_by may refer to aliased functions
1715     my $sel_index;
1716     for my $sel (@{$attrs->{select}}) {
1717       $sel_index->{$sel->{-as}} = $sel
1718         if (ref $sel eq 'HASH' and $sel->{-as});
1719     }
1720
1721     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1722     # also look for named aggregates referred in the having clause
1723     # having often contains scalarrefs - thus parse it out entirely
1724     my @parts = @$g;
1725     if ($attrs->{having}) {
1726       local $sql_maker->{having_bind};
1727       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1728       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1729       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1730         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1731         # if we don't unset it we screw up retarded but unfortunately working
1732         # 'MAX(foo.bar)' => { '>', 3 }
1733         $sql_maker->{name_sep} = '';
1734       }
1735
1736       $sql_maker->clear_renderer;
1737       $sql_maker->clear_converter;
1738
1739       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1740
1741       my $having_sql = $sql_maker->_render_sqla(where => $attrs->{having});
1742
1743       $sql_maker->clear_renderer;
1744       $sql_maker->clear_converter;
1745
1746       my %seen_having;
1747
1748       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1749       # and if all fails for an utterly naive quoted scalar-with-function
1750       while ($having_sql =~ /
1751         (?: $rquote $sep)? $lquote (.+?) $rquote
1752           |
1753         [\s,] \w+ \. (\w+) [\s,]
1754           |
1755         [\s,] $lquote (.+?) $rquote [\s,]
1756       /gx) {
1757         my $part = $1 || $2 || $3;  # one of them matched if we got here
1758         unless ($seen_having{$part}++) {
1759           push @parts, $part;
1760         }
1761       }
1762     }
1763
1764     for (@parts) {
1765       my $colpiece = $sel_index->{$_} || $_;
1766
1767       # unqualify join-based group_by's. Arcane but possible query
1768       # also horrible horrible hack to alias a column (not a func.)
1769       # (probably need to introduce SQLA syntax)
1770       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1771         my $as = $colpiece;
1772         $as =~ s/\./__/;
1773         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1774       }
1775       push @{$sub_attrs->{select}}, $colpiece;
1776     }
1777   }
1778   else {
1779     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1780     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1781   }
1782
1783   return $rsrc->resultset_class
1784                ->new ($rsrc, $sub_attrs)
1785                 ->as_subselect_rs
1786                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1787                   ->get_column ('count');
1788 }
1789
1790
1791 =head2 count_literal
1792
1793 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1794 should only be used in that context. See L</search_literal> for further info.
1795
1796 =over 4
1797
1798 =item Arguments: $sql_fragment, @standalone_bind_values
1799
1800 =item Return Value: $count
1801
1802 =back
1803
1804 Counts the results in a literal query. Equivalent to calling L</search_literal>
1805 with the passed arguments, then L</count>.
1806
1807 =cut
1808
1809 sub count_literal { shift->search_literal(@_)->count; }
1810
1811 =head2 all
1812
1813 =over 4
1814
1815 =item Arguments: none
1816
1817 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1818
1819 =back
1820
1821 Returns all elements in the resultset.
1822
1823 =cut
1824
1825 sub all {
1826   my $self = shift;
1827   if(@_) {
1828     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1829   }
1830
1831   delete @{$self}{qw/_stashed_rows _stashed_results/};
1832
1833   if (my $c = $self->get_cache) {
1834     return @$c;
1835   }
1836
1837   $self->cursor->reset;
1838
1839   my $objs = $self->_construct_results('fetch_all') || [];
1840
1841   $self->set_cache($objs) if $self->{attrs}{cache};
1842
1843   return @$objs;
1844 }
1845
1846 =head2 reset
1847
1848 =over 4
1849
1850 =item Arguments: none
1851
1852 =item Return Value: $self
1853
1854 =back
1855
1856 Resets the resultset's cursor, so you can iterate through the elements again.
1857 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1858 another query.
1859
1860 =cut
1861
1862 sub reset {
1863   my ($self) = @_;
1864
1865   delete @{$self}{qw/_stashed_rows _stashed_results/};
1866   $self->{all_cache_position} = 0;
1867   $self->cursor->reset;
1868   return $self;
1869 }
1870
1871 =head2 first
1872
1873 =over 4
1874
1875 =item Arguments: none
1876
1877 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1878
1879 =back
1880
1881 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1882 an object for the first result (or C<undef> if the resultset is empty).
1883
1884 =cut
1885
1886 sub first {
1887   return $_[0]->reset->next;
1888 }
1889
1890
1891 # _rs_update_delete
1892 #
1893 # Determines whether and what type of subquery is required for the $rs operation.
1894 # If grouping is necessary either supplies its own, or verifies the current one
1895 # After all is done delegates to the proper storage method.
1896
1897 sub _rs_update_delete {
1898   my ($self, $op, $values) = @_;
1899
1900   my $rsrc = $self->result_source;
1901   my $storage = $rsrc->schema->storage;
1902
1903   my $attrs = { %{$self->_resolved_attrs} };
1904
1905   my $join_classifications;
1906   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1907
1908   # do we need a subquery for any reason?
1909   my $needs_subq = (
1910     defined $existing_group_by
1911       or
1912     # if {from} is unparseable wrap a subq
1913     ref($attrs->{from}) ne 'ARRAY'
1914       or
1915     # limits call for a subq
1916     $self->_has_resolved_attr(qw/rows offset/)
1917   );
1918
1919   # simplify the joinmap, so we can further decide if a subq is necessary
1920   if (!$needs_subq and @{$attrs->{from}} > 1) {
1921
1922     ($attrs->{from}, $join_classifications) =
1923       $storage->_prune_unused_joins ($attrs);
1924
1925     # any non-pruneable non-local restricting joins imply subq
1926     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1927   }
1928
1929   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1930   $needs_subq ||= (
1931     (ref $attrs->{from}[0]) ne 'HASH'
1932       or
1933     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1934   );
1935
1936   my ($cond, $guard);
1937   # do we need anything like a subquery?
1938   if (! $needs_subq) {
1939     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1940     # a condition containing 'me' or other table prefixes will not work
1941     # at all - so we convert the WHERE to a dq tree now, dequalify all
1942     # identifiers found therein via a scan across the tree, and then use
1943     # \{} style to pass the result onwards for use in the final query
1944     if ($self->{cond}) {
1945       $cond = do {
1946         my $converter = $rsrc->storage->sql_maker->converter;
1947         scan_dq_nodes({
1948           DQ_IDENTIFIER ,=> sub { $_ = [ $_->[-1] ] for $_[0]->{elements} }
1949         }, my $where_dq = $converter->_where_to_dq($self->{cond}));
1950         \$where_dq;
1951       };
1952     }
1953   }
1954   else {
1955     # we got this far - means it is time to wrap a subquery
1956     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1957       sprintf(
1958         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1959         $op,
1960         $rsrc->source_name,
1961       )
1962     );
1963
1964     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1965     delete $attrs->{$_} for qw/select as collapse/;
1966     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1967
1968     # this will be consumed by the pruner waaaaay down the stack
1969     $attrs->{_force_prune_multiplying_joins} = 1;
1970
1971     my $subrs = (ref $self)->new($rsrc, $attrs);
1972
1973     if (@$idcols == 1) {
1974       $cond = { $idcols->[0] => { -in => \$subrs->_as_select_dq } };
1975     }
1976     elsif ($storage->_use_multicolumn_in) {
1977       # no syntax for calling this properly yet
1978       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1979       my $left = $storage->sql_maker->_render_sqla(select_select => $idcols);
1980       $left =~ s/^SELECT //i;
1981       my $right = $storage->sql_maker
1982                           ->converter
1983                           ->_literal_to_dq(${$subrs->as_query});
1984       $cond = \Operator(
1985         { 'SQL.Naive' => 'in' },
1986         [ Literal(SQL => "( $left )"), $right ],
1987       ),
1988     }
1989     else {
1990       # if all else fails - get all primary keys and operate over a ORed set
1991       # wrap in a transaction for consistency
1992       # this is where the group_by/multiplication starts to matter
1993       if (
1994         $existing_group_by
1995           or
1996         # we do not need to check pre-multipliers, since if the premulti is there, its
1997         # parent (who is multi) will be there too
1998         keys %{ $join_classifications->{multiplying} || {} }
1999       ) {
2000         # make sure if there is a supplied group_by it matches the columns compiled above
2001         # perfectly. Anything else can not be sanely executed on most databases so croak
2002         # right then and there
2003         if ($existing_group_by) {
2004           my @current_group_by = map
2005             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
2006             @$existing_group_by
2007           ;
2008
2009           if (
2010             join ("\x00", sort @current_group_by)
2011               ne
2012             join ("\x00", sort @{$attrs->{columns}} )
2013           ) {
2014             $self->throw_exception (
2015               "You have just attempted a $op operation on a resultset which does group_by"
2016               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
2017               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
2018               . ' kind of queries. Please retry the operation with a modified group_by or'
2019               . ' without using one at all.'
2020             );
2021           }
2022         }
2023
2024         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2025       }
2026
2027       $guard = $storage->txn_scope_guard;
2028
2029       $cond = [];
2030       for my $row ($subrs->cursor->all) {
2031         push @$cond, { map
2032           { $idcols->[$_] => $row->[$_] }
2033           (0 .. $#$idcols)
2034         };
2035       }
2036     }
2037   }
2038
2039   my $res = $storage->$op (
2040     $rsrc,
2041     $op eq 'update' ? $values : (),
2042     $cond,
2043   );
2044
2045   $guard->commit if $guard;
2046
2047   return $res;
2048 }
2049
2050 =head2 update
2051
2052 =over 4
2053
2054 =item Arguments: \%values
2055
2056 =item Return Value: $underlying_storage_rv
2057
2058 =back
2059
2060 Sets the specified columns in the resultset to the supplied values in a
2061 single query. Note that this will not run any accessor/set_column/update
2062 triggers, nor will it update any result object instances derived from this
2063 resultset (this includes the contents of the L<resultset cache|/set_cache>
2064 if any). See L</update_all> if you need to execute any on-update
2065 triggers or cascades defined either by you or a
2066 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2067
2068 The return value is a pass through of what the underlying
2069 storage backend returned, and may vary. See L<DBI/execute> for the most
2070 common case.
2071
2072 =head3 CAVEAT
2073
2074 Note that L</update> does not process/deflate any of the values passed in.
2075 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2076 ensure manually that any value passed to this method will stringify to
2077 something the RDBMS knows how to deal with. A notable example is the
2078 handling of L<DateTime> objects, for more info see:
2079 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2080
2081 =cut
2082
2083 sub update {
2084   my ($self, $values) = @_;
2085   $self->throw_exception('Values for update must be a hash')
2086     unless ref $values eq 'HASH';
2087
2088   return $self->_rs_update_delete ('update', $values);
2089 }
2090
2091 =head2 update_all
2092
2093 =over 4
2094
2095 =item Arguments: \%values
2096
2097 =item Return Value: 1
2098
2099 =back
2100
2101 Fetches all objects and updates them one at a time via
2102 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2103 triggers, while L</update> will not.
2104
2105 =cut
2106
2107 sub update_all {
2108   my ($self, $values) = @_;
2109   $self->throw_exception('Values for update_all must be a hash')
2110     unless ref $values eq 'HASH';
2111
2112   my $guard = $self->result_source->schema->txn_scope_guard;
2113   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2114   $guard->commit;
2115   return 1;
2116 }
2117
2118 =head2 delete
2119
2120 =over 4
2121
2122 =item Arguments: none
2123
2124 =item Return Value: $underlying_storage_rv
2125
2126 =back
2127
2128 Deletes the rows matching this resultset in a single query. Note that this
2129 will not run any delete triggers, nor will it alter the
2130 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2131 derived from this resultset (this includes the contents of the
2132 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2133 execute any on-delete triggers or cascades defined either by you or a
2134 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2135
2136 The return value is a pass through of what the underlying storage backend
2137 returned, and may vary. See L<DBI/execute> for the most common case.
2138
2139 =cut
2140
2141 sub delete {
2142   my $self = shift;
2143   $self->throw_exception('delete does not accept any arguments')
2144     if @_;
2145
2146   return $self->_rs_update_delete ('delete');
2147 }
2148
2149 =head2 delete_all
2150
2151 =over 4
2152
2153 =item Arguments: none
2154
2155 =item Return Value: 1
2156
2157 =back
2158
2159 Fetches all objects and deletes them one at a time via
2160 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2161 triggers, while L</delete> will not.
2162
2163 =cut
2164
2165 sub delete_all {
2166   my $self = shift;
2167   $self->throw_exception('delete_all does not accept any arguments')
2168     if @_;
2169
2170   my $guard = $self->result_source->schema->txn_scope_guard;
2171   $_->delete for $self->all;
2172   $guard->commit;
2173   return 1;
2174 }
2175
2176 =head2 populate
2177
2178 =over 4
2179
2180 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2181
2182 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2183
2184 =back
2185
2186 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2187 arrayrefs.
2188
2189 =over
2190
2191 =item NOTE
2192
2193 The context of this method call has an important effect on what is
2194 submitted to storage. In void context data is fed directly to fastpath
2195 insertion routines provided by the underlying storage (most often
2196 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2197 L<insert|DBIx::Class::Row/insert> calls on the
2198 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2199 augmentation of these methods provided by components. For example if you
2200 are using something like L<DBIx::Class::UUIDColumns> to create primary
2201 keys for you, you will find that your PKs are empty.  In this case you
2202 will have to explicitly force scalar or list context in order to create
2203 those values.
2204
2205 =back
2206
2207 In non-void (scalar or list) context, this method is simply a wrapper
2208 for L</create>. Depending on list or scalar context either a list of
2209 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2210 containing these objects is returned.
2211
2212 When supplying data in "arrayref of arrayrefs" invocation style, the
2213 first element should be a list of column names and each subsequent
2214 element should be a data value in the earlier specified column order.
2215 For example:
2216
2217   $schema->resultset("Artist")->populate([
2218     [ qw( artistid name ) ],
2219     [ 100, 'A Formally Unknown Singer' ],
2220     [ 101, 'A singer that jumped the shark two albums ago' ],
2221     [ 102, 'An actually cool singer' ],
2222   ]);
2223
2224 For the arrayref of hashrefs style each hashref should be a structure
2225 suitable for passing to L</create>. Multi-create is also permitted with
2226 this syntax.
2227
2228   $schema->resultset("Artist")->populate([
2229      { artistid => 4, name => 'Manufactured Crap', cds => [
2230         { title => 'My First CD', year => 2006 },
2231         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2232       ],
2233      },
2234      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2235         { title => 'My parents sold me to a record company', year => 2005 },
2236         { title => 'Why Am I So Ugly?', year => 2006 },
2237         { title => 'I Got Surgery and am now Popular', year => 2007 }
2238       ],
2239      },
2240   ]);
2241
2242 If you attempt a void-context multi-create as in the example above (each
2243 Artist also has the related list of CDs), and B<do not> supply the
2244 necessary autoinc foreign key information, this method will proxy to the
2245 less efficient L</create>, and then throw the Result objects away. In this
2246 case there are obviously no benefits to using this method over L</create>.
2247
2248 =cut
2249
2250 sub populate {
2251   my $self = shift;
2252
2253   # cruft placed in standalone method
2254   my $data = $self->_normalize_populate_args(@_);
2255
2256   return unless @$data;
2257
2258   if(defined wantarray) {
2259     my @created = map { $self->create($_) } @$data;
2260     return wantarray ? @created : \@created;
2261   }
2262   else {
2263     my $first = $data->[0];
2264
2265     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2266     # it relationship data
2267     my (@rels, @columns);
2268     my $rsrc = $self->result_source;
2269     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2270     for (keys %$first) {
2271       my $ref = ref $first->{$_};
2272       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2273         ? push @rels, $_
2274         : push @columns, $_
2275       ;
2276     }
2277
2278     my @pks = $rsrc->primary_columns;
2279
2280     ## do the belongs_to relationships
2281     foreach my $index (0..$#$data) {
2282
2283       # delegate to create() for any dataset without primary keys with specified relationships
2284       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2285         for my $r (@rels) {
2286           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2287             my @ret = $self->populate($data);
2288             return;
2289           }
2290         }
2291       }
2292
2293       foreach my $rel (@rels) {
2294         next unless ref $data->[$index]->{$rel} eq "HASH";
2295         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2296         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2297         my $related = $result->result_source->_resolve_condition(
2298           $reverse_relinfo->{cond},
2299           $self,
2300           $result,
2301           $rel,
2302         );
2303
2304         delete $data->[$index]->{$rel};
2305         $data->[$index] = {%{$data->[$index]}, %$related};
2306
2307         push @columns, keys %$related if $index == 0;
2308       }
2309     }
2310
2311     ## inherit the data locked in the conditions of the resultset
2312     my ($rs_data) = $self->_merge_with_rscond({});
2313     delete @{$rs_data}{@columns};
2314
2315     ## do bulk insert on current row
2316     $rsrc->storage->insert_bulk(
2317       $rsrc,
2318       [@columns, keys %$rs_data],
2319       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2320     );
2321
2322     ## do the has_many relationships
2323     foreach my $item (@$data) {
2324
2325       my $main_row;
2326
2327       foreach my $rel (@rels) {
2328         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2329
2330         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2331
2332         my $child = $main_row->$rel;
2333
2334         my $related = $child->result_source->_resolve_condition(
2335           $rels->{$rel}{cond},
2336           $child,
2337           $main_row,
2338           $rel,
2339         );
2340
2341         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2342         my @populate = map { {%$_, %$related} } @rows_to_add;
2343
2344         $child->populate( \@populate );
2345       }
2346     }
2347   }
2348 }
2349
2350
2351 # populate() arguments went over several incarnations
2352 # What we ultimately support is AoH
2353 sub _normalize_populate_args {
2354   my ($self, $arg) = @_;
2355
2356   if (ref $arg eq 'ARRAY') {
2357     if (!@$arg) {
2358       return [];
2359     }
2360     elsif (ref $arg->[0] eq 'HASH') {
2361       return $arg;
2362     }
2363     elsif (ref $arg->[0] eq 'ARRAY') {
2364       my @ret;
2365       my @colnames = @{$arg->[0]};
2366       foreach my $values (@{$arg}[1 .. $#$arg]) {
2367         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2368       }
2369       return \@ret;
2370     }
2371   }
2372
2373   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2374 }
2375
2376 =head2 pager
2377
2378 =over 4
2379
2380 =item Arguments: none
2381
2382 =item Return Value: L<$pager|Data::Page>
2383
2384 =back
2385
2386 Returns a L<Data::Page> object for the current resultset. Only makes
2387 sense for queries with a C<page> attribute.
2388
2389 To get the full count of entries for a paged resultset, call
2390 C<total_entries> on the L<Data::Page> object.
2391
2392 =cut
2393
2394 sub pager {
2395   my ($self) = @_;
2396
2397   return $self->{pager} if $self->{pager};
2398
2399   my $attrs = $self->{attrs};
2400   if (!defined $attrs->{page}) {
2401     $self->throw_exception("Can't create pager for non-paged rs");
2402   }
2403   elsif ($attrs->{page} <= 0) {
2404     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2405   }
2406   $attrs->{rows} ||= 10;
2407
2408   # throw away the paging flags and re-run the count (possibly
2409   # with a subselect) to get the real total count
2410   my $count_attrs = { %$attrs };
2411   delete @{$count_attrs}{qw/rows offset page pager/};
2412
2413   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2414
2415   require DBIx::Class::ResultSet::Pager;
2416   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2417     sub { $total_rs->count },  #lazy-get the total
2418     $attrs->{rows},
2419     $self->{attrs}{page},
2420   );
2421 }
2422
2423 =head2 page
2424
2425 =over 4
2426
2427 =item Arguments: $page_number
2428
2429 =item Return Value: L<$resultset|/search>
2430
2431 =back
2432
2433 Returns a resultset for the $page_number page of the resultset on which page
2434 is called, where each page contains a number of rows equal to the 'rows'
2435 attribute set on the resultset (10 by default).
2436
2437 =cut
2438
2439 sub page {
2440   my ($self, $page) = @_;
2441   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2442 }
2443
2444 =head2 new_result
2445
2446 =over 4
2447
2448 =item Arguments: \%col_data
2449
2450 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2451
2452 =back
2453
2454 Creates a new result object in the resultset's result class and returns
2455 it. The row is not inserted into the database at this point, call
2456 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2457 will tell you whether the result object has been inserted or not.
2458
2459 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2460
2461 =cut
2462
2463 sub new_result {
2464   my ($self, $values) = @_;
2465
2466   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2467     if @_ > 2;
2468
2469   $self->throw_exception( "new_result expects a hashref" )
2470     unless (ref $values eq 'HASH');
2471
2472   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2473
2474   my $new = $self->result_class->new({
2475     %$merged_cond,
2476     ( @$cols_from_relations
2477       ? (-cols_from_relations => $cols_from_relations)
2478       : ()
2479     ),
2480     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2481   });
2482
2483   if (
2484     reftype($new) eq 'HASH'
2485       and
2486     ! keys %$new
2487       and
2488     blessed($new)
2489   ) {
2490     carp_unique (sprintf (
2491       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2492       $self->result_class,
2493     ));
2494   }
2495
2496   $new;
2497 }
2498
2499 # _merge_with_rscond
2500 #
2501 # Takes a simple hash of K/V data and returns its copy merged with the
2502 # condition already present on the resultset. Additionally returns an
2503 # arrayref of value/condition names, which were inferred from related
2504 # objects (this is needed for in-memory related objects)
2505 sub _merge_with_rscond {
2506   my ($self, $data) = @_;
2507
2508   my (%new_data, @cols_from_relations);
2509
2510   my $alias = $self->{attrs}{alias};
2511
2512   if (! defined $self->{cond}) {
2513     # just massage $data below
2514   }
2515   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2516     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2517     @cols_from_relations = keys %new_data;
2518   }
2519   elsif (ref $self->{cond} ne 'HASH') {
2520     $self->throw_exception(
2521       "Can't abstract implicit construct, resultset condition not a hash"
2522     );
2523   }
2524   else {
2525     # precedence must be given to passed values over values inherited from
2526     # the cond, so the order here is important.
2527     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2528     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2529
2530     while ( my($col, $value) = each %implied ) {
2531       my $vref = ref $value;
2532       if (
2533         $vref eq 'HASH'
2534           and
2535         keys(%$value) == 1
2536           and
2537         (keys %$value)[0] eq '='
2538       ) {
2539         $new_data{$col} = $value->{'='};
2540       }
2541       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2542         $new_data{$col} = $value;
2543       }
2544     }
2545   }
2546
2547   %new_data = (
2548     %new_data,
2549     %{ $self->_remove_alias($data, $alias) },
2550   );
2551
2552   return (\%new_data, \@cols_from_relations);
2553 }
2554
2555 # _has_resolved_attr
2556 #
2557 # determines if the resultset defines at least one
2558 # of the attributes supplied
2559 #
2560 # used to determine if a subquery is necessary
2561 #
2562 # supports some virtual attributes:
2563 #   -join
2564 #     This will scan for any joins being present on the resultset.
2565 #     It is not a mere key-search but a deep inspection of {from}
2566 #
2567
2568 sub _has_resolved_attr {
2569   my ($self, @attr_names) = @_;
2570
2571   my $attrs = $self->_resolved_attrs;
2572
2573   my %extra_checks;
2574
2575   for my $n (@attr_names) {
2576     if (grep { $n eq $_ } (qw/-join/) ) {
2577       $extra_checks{$n}++;
2578       next;
2579     }
2580
2581     my $attr =  $attrs->{$n};
2582
2583     next if not defined $attr;
2584
2585     if (ref $attr eq 'HASH') {
2586       return 1 if keys %$attr;
2587     }
2588     elsif (ref $attr eq 'ARRAY') {
2589       return 1 if @$attr;
2590     }
2591     else {
2592       return 1 if $attr;
2593     }
2594   }
2595
2596   # a resolved join is expressed as a multi-level from
2597   return 1 if (
2598     $extra_checks{-join}
2599       and
2600     ref $attrs->{from} eq 'ARRAY'
2601       and
2602     @{$attrs->{from}} > 1
2603   );
2604
2605   return 0;
2606 }
2607
2608 # _collapse_cond
2609 #
2610 # Recursively collapse the condition.
2611
2612 sub _collapse_cond {
2613   my ($self, $cond, $collapsed) = @_;
2614
2615   $collapsed ||= {};
2616
2617   if (ref $cond eq 'ARRAY') {
2618     foreach my $subcond (@$cond) {
2619       next unless ref $subcond;  # -or
2620       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2621     }
2622   }
2623   elsif (ref $cond eq 'HASH') {
2624     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2625       foreach my $subcond (@{$cond->{-and}}) {
2626         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2627       }
2628     }
2629     else {
2630       foreach my $col (keys %$cond) {
2631         my $value = $cond->{$col};
2632         $collapsed->{$col} = $value;
2633       }
2634     }
2635   }
2636
2637   return $collapsed;
2638 }
2639
2640 # _remove_alias
2641 #
2642 # Remove the specified alias from the specified query hash. A copy is made so
2643 # the original query is not modified.
2644
2645 sub _remove_alias {
2646   my ($self, $query, $alias) = @_;
2647
2648   my %orig = %{ $query || {} };
2649   my %unaliased;
2650
2651   foreach my $key (keys %orig) {
2652     if ($key !~ /\./) {
2653       $unaliased{$key} = $orig{$key};
2654       next;
2655     }
2656     $unaliased{$1} = $orig{$key}
2657       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2658   }
2659
2660   return \%unaliased;
2661 }
2662
2663 =head2 as_query
2664
2665 =over 4
2666
2667 =item Arguments: none
2668
2669 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2670
2671 =back
2672
2673 Returns the SQL query and bind vars associated with the invocant.
2674
2675 This is generally used as the RHS for a subquery.
2676
2677 =cut
2678
2679 sub as_query {
2680   my $self = shift;
2681
2682   my $attrs = { %{ $self->_resolved_attrs } };
2683
2684   my $aq = $self->result_source->storage->_select_args_to_query (
2685     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2686   );
2687
2688   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
2689
2690   $aq;
2691 }
2692
2693 sub _as_select_dq {
2694   my $self = shift;
2695   my $attrs = { %{ $self->_resolved_attrs } };
2696   my $storage = $self->result_source->storage;
2697   my (undef, $ident, @args) = $storage->_select_args(
2698     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2699   );
2700   $ident = $ident->from if blessed($ident);
2701   $storage->sql_maker->converter->_select_to_dq(
2702     $ident, @args
2703   );
2704 }
2705
2706 =head2 find_or_new
2707
2708 =over 4
2709
2710 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2711
2712 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2713
2714 =back
2715
2716   my $artist = $schema->resultset('Artist')->find_or_new(
2717     { artist => 'fred' }, { key => 'artists' });
2718
2719   $cd->cd_to_producer->find_or_new({ producer => $producer },
2720                                    { key => 'primary' });
2721
2722 Find an existing record from this resultset using L</find>. if none exists,
2723 instantiate a new result object and return it. The object will not be saved
2724 into your storage until you call L<DBIx::Class::Row/insert> on it.
2725
2726 You most likely want this method when looking for existing rows using a unique
2727 constraint that is not the primary key, or looking for related rows.
2728
2729 If you want objects to be saved immediately, use L</find_or_create> instead.
2730
2731 B<Note>: Make sure to read the documentation of L</find> and understand the
2732 significance of the C<key> attribute, as its lack may skew your search, and
2733 subsequently result in spurious new objects.
2734
2735 B<Note>: Take care when using C<find_or_new> with a table having
2736 columns with default values that you intend to be automatically
2737 supplied by the database (e.g. an auto_increment primary key column).
2738 In normal usage, the value of such columns should NOT be included at
2739 all in the call to C<find_or_new>, even when set to C<undef>.
2740
2741 =cut
2742
2743 sub find_or_new {
2744   my $self     = shift;
2745   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2746   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2747   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2748     return $row;
2749   }
2750   return $self->new_result($hash);
2751 }
2752
2753 =head2 create
2754
2755 =over 4
2756
2757 =item Arguments: \%col_data
2758
2759 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2760
2761 =back
2762
2763 Attempt to create a single new row or a row with multiple related rows
2764 in the table represented by the resultset (and related tables). This
2765 will not check for duplicate rows before inserting, use
2766 L</find_or_create> to do that.
2767
2768 To create one row for this resultset, pass a hashref of key/value
2769 pairs representing the columns of the table and the values you wish to
2770 store. If the appropriate relationships are set up, foreign key fields
2771 can also be passed an object representing the foreign row, and the
2772 value will be set to its primary key.
2773
2774 To create related objects, pass a hashref of related-object column values
2775 B<keyed on the relationship name>. If the relationship is of type C<multi>
2776 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2777 The process will correctly identify columns holding foreign keys, and will
2778 transparently populate them from the keys of the corresponding relation.
2779 This can be applied recursively, and will work correctly for a structure
2780 with an arbitrary depth and width, as long as the relationships actually
2781 exists and the correct column data has been supplied.
2782
2783 Instead of hashrefs of plain related data (key/value pairs), you may
2784 also pass new or inserted objects. New objects (not inserted yet, see
2785 L</new_result>), will be inserted into their appropriate tables.
2786
2787 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2788
2789 Example of creating a new row.
2790
2791   $person_rs->create({
2792     name=>"Some Person",
2793     email=>"somebody@someplace.com"
2794   });
2795
2796 Example of creating a new row and also creating rows in a related C<has_many>
2797 or C<has_one> resultset.  Note Arrayref.
2798
2799   $artist_rs->create(
2800      { artistid => 4, name => 'Manufactured Crap', cds => [
2801         { title => 'My First CD', year => 2006 },
2802         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2803       ],
2804      },
2805   );
2806
2807 Example of creating a new row and also creating a row in a related
2808 C<belongs_to> resultset. Note Hashref.
2809
2810   $cd_rs->create({
2811     title=>"Music for Silly Walks",
2812     year=>2000,
2813     artist => {
2814       name=>"Silly Musician",
2815     }
2816   });
2817
2818 =over
2819
2820 =item WARNING
2821
2822 When subclassing ResultSet never attempt to override this method. Since
2823 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2824 lot of the internals simply never call it, so your override will be
2825 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2826 or L<DBIx::Class::Row/insert> depending on how early in the
2827 L</create> process you need to intervene. See also warning pertaining to
2828 L</new>.
2829
2830 =back
2831
2832 =cut
2833
2834 sub create {
2835   my ($self, $col_data) = @_;
2836   $self->throw_exception( "create needs a hashref" )
2837     unless ref $col_data eq 'HASH';
2838   return $self->new_result($col_data)->insert;
2839 }
2840
2841 =head2 find_or_create
2842
2843 =over 4
2844
2845 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2846
2847 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2848
2849 =back
2850
2851   $cd->cd_to_producer->find_or_create({ producer => $producer },
2852                                       { key => 'primary' });
2853
2854 Tries to find a record based on its primary key or unique constraints; if none
2855 is found, creates one and returns that instead.
2856
2857   my $cd = $schema->resultset('CD')->find_or_create({
2858     cdid   => 5,
2859     artist => 'Massive Attack',
2860     title  => 'Mezzanine',
2861     year   => 2005,
2862   });
2863
2864 Also takes an optional C<key> attribute, to search by a specific key or unique
2865 constraint. For example:
2866
2867   my $cd = $schema->resultset('CD')->find_or_create(
2868     {
2869       artist => 'Massive Attack',
2870       title  => 'Mezzanine',
2871     },
2872     { key => 'cd_artist_title' }
2873   );
2874
2875 B<Note>: Make sure to read the documentation of L</find> and understand the
2876 significance of the C<key> attribute, as its lack may skew your search, and
2877 subsequently result in spurious row creation.
2878
2879 B<Note>: Because find_or_create() reads from the database and then
2880 possibly inserts based on the result, this method is subject to a race
2881 condition. Another process could create a record in the table after
2882 the find has completed and before the create has started. To avoid
2883 this problem, use find_or_create() inside a transaction.
2884
2885 B<Note>: Take care when using C<find_or_create> with a table having
2886 columns with default values that you intend to be automatically
2887 supplied by the database (e.g. an auto_increment primary key column).
2888 In normal usage, the value of such columns should NOT be included at
2889 all in the call to C<find_or_create>, even when set to C<undef>.
2890
2891 See also L</find> and L</update_or_create>. For information on how to declare
2892 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2893
2894 If you need to know if an existing row was found or a new one created use
2895 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2896 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2897 database!
2898
2899   my $cd = $schema->resultset('CD')->find_or_new({
2900     cdid   => 5,
2901     artist => 'Massive Attack',
2902     title  => 'Mezzanine',
2903     year   => 2005,
2904   });
2905
2906   if( !$cd->in_storage ) {
2907       # do some stuff
2908       $cd->insert;
2909   }
2910
2911 =cut
2912
2913 sub find_or_create {
2914   my $self     = shift;
2915   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2916   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2917   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2918     return $row;
2919   }
2920   return $self->create($hash);
2921 }
2922
2923 =head2 update_or_create
2924
2925 =over 4
2926
2927 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2928
2929 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2930
2931 =back
2932
2933   $resultset->update_or_create({ col => $val, ... });
2934
2935 Like L</find_or_create>, but if a row is found it is immediately updated via
2936 C<< $found_row->update (\%col_data) >>.
2937
2938
2939 Takes an optional C<key> attribute to search on a specific unique constraint.
2940 For example:
2941
2942   # In your application
2943   my $cd = $schema->resultset('CD')->update_or_create(
2944     {
2945       artist => 'Massive Attack',
2946       title  => 'Mezzanine',
2947       year   => 1998,
2948     },
2949     { key => 'cd_artist_title' }
2950   );
2951
2952   $cd->cd_to_producer->update_or_create({
2953     producer => $producer,
2954     name => 'harry',
2955   }, {
2956     key => 'primary',
2957   });
2958
2959 B<Note>: Make sure to read the documentation of L</find> and understand the
2960 significance of the C<key> attribute, as its lack may skew your search, and
2961 subsequently result in spurious row creation.
2962
2963 B<Note>: Take care when using C<update_or_create> with a table having
2964 columns with default values that you intend to be automatically
2965 supplied by the database (e.g. an auto_increment primary key column).
2966 In normal usage, the value of such columns should NOT be included at
2967 all in the call to C<update_or_create>, even when set to C<undef>.
2968
2969 See also L</find> and L</find_or_create>. For information on how to declare
2970 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2971
2972 If you need to know if an existing row was updated or a new one created use
2973 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2974 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2975 database!
2976
2977 =cut
2978
2979 sub update_or_create {
2980   my $self = shift;
2981   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2982   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2983
2984   my $row = $self->find($cond, $attrs);
2985   if (defined $row) {
2986     $row->update($cond);
2987     return $row;
2988   }
2989
2990   return $self->create($cond);
2991 }
2992
2993 =head2 update_or_new
2994
2995 =over 4
2996
2997 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2998
2999 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3000
3001 =back
3002
3003   $resultset->update_or_new({ col => $val, ... });
3004
3005 Like L</find_or_new> but if a row is found it is immediately updated via
3006 C<< $found_row->update (\%col_data) >>.
3007
3008 For example:
3009
3010   # In your application
3011   my $cd = $schema->resultset('CD')->update_or_new(
3012     {
3013       artist => 'Massive Attack',
3014       title  => 'Mezzanine',
3015       year   => 1998,
3016     },
3017     { key => 'cd_artist_title' }
3018   );
3019
3020   if ($cd->in_storage) {
3021       # the cd was updated
3022   }
3023   else {
3024       # the cd is not yet in the database, let's insert it
3025       $cd->insert;
3026   }
3027
3028 B<Note>: Make sure to read the documentation of L</find> and understand the
3029 significance of the C<key> attribute, as its lack may skew your search, and
3030 subsequently result in spurious new objects.
3031
3032 B<Note>: Take care when using C<update_or_new> with a table having
3033 columns with default values that you intend to be automatically
3034 supplied by the database (e.g. an auto_increment primary key column).
3035 In normal usage, the value of such columns should NOT be included at
3036 all in the call to C<update_or_new>, even when set to C<undef>.
3037
3038 See also L</find>, L</find_or_create> and L</find_or_new>.
3039
3040 =cut
3041
3042 sub update_or_new {
3043     my $self  = shift;
3044     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3045     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3046
3047     my $row = $self->find( $cond, $attrs );
3048     if ( defined $row ) {
3049         $row->update($cond);
3050         return $row;
3051     }
3052
3053     return $self->new_result($cond);
3054 }
3055
3056 =head2 get_cache
3057
3058 =over 4
3059
3060 =item Arguments: none
3061
3062 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3063
3064 =back
3065
3066 Gets the contents of the cache for the resultset, if the cache is set.
3067
3068 The cache is populated either by using the L</prefetch> attribute to
3069 L</search> or by calling L</set_cache>.
3070
3071 =cut
3072
3073 sub get_cache {
3074   shift->{all_cache};
3075 }
3076
3077 =head2 set_cache
3078
3079 =over 4
3080
3081 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3082
3083 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3084
3085 =back
3086
3087 Sets the contents of the cache for the resultset. Expects an arrayref
3088 of objects of the same class as those produced by the resultset. Note that
3089 if the cache is set, the resultset will return the cached objects rather
3090 than re-querying the database even if the cache attr is not set.
3091
3092 The contents of the cache can also be populated by using the
3093 L</prefetch> attribute to L</search>.
3094
3095 =cut
3096
3097 sub set_cache {
3098   my ( $self, $data ) = @_;
3099   $self->throw_exception("set_cache requires an arrayref")
3100       if defined($data) && (ref $data ne 'ARRAY');
3101   $self->{all_cache} = $data;
3102 }
3103
3104 =head2 clear_cache
3105
3106 =over 4
3107
3108 =item Arguments: none
3109
3110 =item Return Value: undef
3111
3112 =back
3113
3114 Clears the cache for the resultset.
3115
3116 =cut
3117
3118 sub clear_cache {
3119   shift->set_cache(undef);
3120 }
3121
3122 =head2 is_paged
3123
3124 =over 4
3125
3126 =item Arguments: none
3127
3128 =item Return Value: true, if the resultset has been paginated
3129
3130 =back
3131
3132 =cut
3133
3134 sub is_paged {
3135   my ($self) = @_;
3136   return !!$self->{attrs}{page};
3137 }
3138
3139 =head2 is_ordered
3140
3141 =over 4
3142
3143 =item Arguments: none
3144
3145 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3146
3147 =back
3148
3149 =cut
3150
3151 sub is_ordered {
3152   my ($self) = @_;
3153   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3154 }
3155
3156 =head2 related_resultset
3157
3158 =over 4
3159
3160 =item Arguments: $rel_name
3161
3162 =item Return Value: L<$resultset|/search>
3163
3164 =back
3165
3166 Returns a related resultset for the supplied relationship name.
3167
3168   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3169
3170 =cut
3171
3172 sub related_resultset {
3173   my ($self, $rel) = @_;
3174
3175   return $self->{related_resultsets}{$rel}
3176     if defined $self->{related_resultsets}{$rel};
3177
3178   return $self->{related_resultsets}{$rel} = do {
3179     my $rsrc = $self->result_source;
3180     my $rel_info = $rsrc->relationship_info($rel);
3181
3182     $self->throw_exception(
3183       "search_related: result source '" . $rsrc->source_name .
3184         "' has no such relationship $rel")
3185       unless $rel_info;
3186
3187     my $attrs = $self->_chain_relationship($rel);
3188
3189     my $join_count = $attrs->{seen_join}{$rel};
3190
3191     my $alias = $self->result_source->storage
3192         ->relname_to_table_alias($rel, $join_count);
3193
3194     # since this is search_related, and we already slid the select window inwards
3195     # (the select/as attrs were deleted in the beginning), we need to flip all
3196     # left joins to inner, so we get the expected results
3197     # read the comment on top of the actual function to see what this does
3198     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3199
3200
3201     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3202     delete @{$attrs}{qw(result_class alias)};
3203
3204     my $rel_source = $rsrc->related_source($rel);
3205
3206     my $new = do {
3207
3208       # The reason we do this now instead of passing the alias to the
3209       # search_rs below is that if you wrap/overload resultset on the
3210       # source you need to know what alias it's -going- to have for things
3211       # to work sanely (e.g. RestrictWithObject wants to be able to add
3212       # extra query restrictions, and these may need to be $alias.)
3213
3214       my $rel_attrs = $rel_source->resultset_attributes;
3215       local $rel_attrs->{alias} = $alias;
3216
3217       $rel_source->resultset
3218                  ->search_rs(
3219                      undef, {
3220                        %$attrs,
3221                        where => $attrs->{where},
3222                    });
3223     };
3224
3225     if (my $cache = $self->get_cache) {
3226       my @related_cache = map
3227         { @{$_->related_resultset($rel)->get_cache||[]} }
3228         @$cache
3229       ;
3230
3231       $new->set_cache(\@related_cache) if @related_cache;
3232     }
3233
3234     $new;
3235   };
3236 }
3237
3238 =head2 current_source_alias
3239
3240 =over 4
3241
3242 =item Arguments: none
3243
3244 =item Return Value: $source_alias
3245
3246 =back
3247
3248 Returns the current table alias for the result source this resultset is built
3249 on, that will be used in the SQL query. Usually it is C<me>.
3250
3251 Currently the source alias that refers to the result set returned by a
3252 L</search>/L</find> family method depends on how you got to the resultset: it's
3253 C<me> by default, but eg. L</search_related> aliases it to the related result
3254 source name (and keeps C<me> referring to the original result set). The long
3255 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3256 (and make this method unnecessary).
3257
3258 Thus it's currently necessary to use this method in predefined queries (see
3259 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3260 source alias of the current result set:
3261
3262   # in a result set class
3263   sub modified_by {
3264     my ($self, $user) = @_;
3265
3266     my $me = $self->current_source_alias;
3267
3268     return $self->search({
3269       "$me.modified" => $user->id,
3270     });
3271   }
3272
3273 =cut
3274
3275 sub current_source_alias {
3276   return (shift->{attrs} || {})->{alias} || 'me';
3277 }
3278
3279 =head2 as_subselect_rs
3280
3281 =over 4
3282
3283 =item Arguments: none
3284
3285 =item Return Value: L<$resultset|/search>
3286
3287 =back
3288
3289 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3290 "virtual view" by including it as a subquery within the from clause.  From this
3291 point on, any joined tables are inaccessible to ->search on the resultset (as if
3292 it were simply where-filtered without joins).  For example:
3293
3294  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3295
3296  # 'x' now pollutes the query namespace
3297
3298  # So the following works as expected
3299  my $ok_rs = $rs->search({'x.other' => 1});
3300
3301  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3302  # def) we look for one row with contradictory terms and join in another table
3303  # (aliased 'x_2') which we never use
3304  my $broken_rs = $rs->search({'x.name' => 'def'});
3305
3306  my $rs2 = $rs->as_subselect_rs;
3307
3308  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3309  my $not_joined_rs = $rs2->search({'x.other' => 1});
3310
3311  # works as expected: finds a 'table' row related to two x rows (abc and def)
3312  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3313
3314 Another example of when one might use this would be to select a subset of
3315 columns in a group by clause:
3316
3317  my $rs = $schema->resultset('Bar')->search(undef, {
3318    group_by => [qw{ id foo_id baz_id }],
3319  })->as_subselect_rs->search(undef, {
3320    columns => [qw{ id foo_id }]
3321  });
3322
3323 In the above example normally columns would have to be equal to the group by,
3324 but because we isolated the group by into a subselect the above works.
3325
3326 =cut
3327
3328 sub as_subselect_rs {
3329   my $self = shift;
3330
3331   my $attrs = $self->_resolved_attrs;
3332
3333   my $fresh_rs = (ref $self)->new (
3334     $self->result_source
3335   );
3336
3337   # these pieces will be locked in the subquery
3338   delete $fresh_rs->{cond};
3339   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3340
3341   return $fresh_rs->search( {}, {
3342     from => [{
3343       $attrs->{alias} => $self->as_query,
3344       -alias  => $attrs->{alias},
3345       -rsrc   => $self->result_source,
3346     }],
3347     alias => $attrs->{alias},
3348   });
3349 }
3350
3351 # This code is called by search_related, and makes sure there
3352 # is clear separation between the joins before, during, and
3353 # after the relationship. This information is needed later
3354 # in order to properly resolve prefetch aliases (any alias
3355 # with a relation_chain_depth less than the depth of the
3356 # current prefetch is not considered)
3357 #
3358 # The increments happen twice per join. An even number means a
3359 # relationship specified via a search_related, whereas an odd
3360 # number indicates a join/prefetch added via attributes
3361 #
3362 # Also this code will wrap the current resultset (the one we
3363 # chain to) in a subselect IFF it contains limiting attributes
3364 sub _chain_relationship {
3365   my ($self, $rel) = @_;
3366   my $source = $self->result_source;
3367   my $attrs = { %{$self->{attrs}||{}} };
3368
3369   # we need to take the prefetch the attrs into account before we
3370   # ->_resolve_join as otherwise they get lost - captainL
3371   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3372
3373   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3374
3375   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3376
3377   my $from;
3378   my @force_subq_attrs = qw/offset rows group_by having/;
3379
3380   if (
3381     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3382       ||
3383     $self->_has_resolved_attr (@force_subq_attrs)
3384   ) {
3385     # Nuke the prefetch (if any) before the new $rs attrs
3386     # are resolved (prefetch is useless - we are wrapping
3387     # a subquery anyway).
3388     my $rs_copy = $self->search;
3389     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3390       $rs_copy->{attrs}{join},
3391       delete $rs_copy->{attrs}{prefetch},
3392     );
3393
3394     $from = [{
3395       -rsrc   => $source,
3396       -alias  => $attrs->{alias},
3397       $attrs->{alias} => $rs_copy->as_query,
3398     }];
3399     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3400     $seen->{-relation_chain_depth} = 0;
3401   }
3402   elsif ($attrs->{from}) {  #shallow copy suffices
3403     $from = [ @{$attrs->{from}} ];
3404   }
3405   else {
3406     $from = [{
3407       -rsrc  => $source,
3408       -alias => $attrs->{alias},
3409       $attrs->{alias} => $source->from,
3410     }];
3411   }
3412
3413   my $jpath = ($seen->{-relation_chain_depth})
3414     ? $from->[-1][0]{-join_path}
3415     : [];
3416
3417   my @requested_joins = $source->_resolve_join(
3418     $join,
3419     $attrs->{alias},
3420     $seen,
3421     $jpath,
3422   );
3423
3424   push @$from, @requested_joins;
3425
3426   $seen->{-relation_chain_depth}++;
3427
3428   # if $self already had a join/prefetch specified on it, the requested
3429   # $rel might very well be already included. What we do in this case
3430   # is effectively a no-op (except that we bump up the chain_depth on
3431   # the join in question so we could tell it *is* the search_related)
3432   my $already_joined;
3433
3434   # we consider the last one thus reverse
3435   for my $j (reverse @requested_joins) {
3436     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3437     if ($rel eq $last_j) {
3438       $j->[0]{-relation_chain_depth}++;
3439       $already_joined++;
3440       last;
3441     }
3442   }
3443
3444   unless ($already_joined) {
3445     push @$from, $source->_resolve_join(
3446       $rel,
3447       $attrs->{alias},
3448       $seen,
3449       $jpath,
3450     );
3451   }
3452
3453   $seen->{-relation_chain_depth}++;
3454
3455   return {%$attrs, from => $from, seen_join => $seen};
3456 }
3457
3458 sub _resolved_attrs {
3459   my $self = shift;
3460   return $self->{_attrs} if $self->{_attrs};
3461
3462   my $attrs  = { %{ $self->{attrs} || {} } };
3463   my $source = $self->result_source;
3464   my $alias  = $attrs->{alias};
3465
3466   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3467     if $attrs->{collapse} and $attrs->{distinct};
3468
3469   # default selection list
3470   $attrs->{columns} = [ $source->columns ]
3471     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3472
3473   # merge selectors together
3474   for (qw/columns select as/) {
3475     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3476       if $attrs->{$_} or $attrs->{"+$_"};
3477   }
3478
3479   # disassemble columns
3480   my (@sel, @as);
3481   if (my $cols = delete $attrs->{columns}) {
3482     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3483       if (ref $c eq 'HASH') {
3484         for my $as (sort keys %$c) {
3485           push @sel, $c->{$as};
3486           push @as, $as;
3487         }
3488       }
3489       else {
3490         push @sel, $c;
3491         push @as, $c;
3492       }
3493     }
3494   }
3495
3496   # when trying to weed off duplicates later do not go past this point -
3497   # everything added from here on is unbalanced "anyone's guess" stuff
3498   my $dedup_stop_idx = $#as;
3499
3500   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3501     if $attrs->{as};
3502   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3503     if $attrs->{select};
3504
3505   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3506   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3507
3508   # disqualify all $alias.col as-bits (inflate-map mandated)
3509   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3510
3511   # de-duplicate the result (remove *identical* select/as pairs)
3512   # and also die on duplicate {as} pointing to different {select}s
3513   # not using a c-style for as the condition is prone to shrinkage
3514   my $seen;
3515   my $i = 0;
3516   while ($i <= $dedup_stop_idx) {
3517     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3518       splice @sel, $i, 1;
3519       splice @as, $i, 1;
3520       $dedup_stop_idx--;
3521     }
3522     elsif ($seen->{$as[$i]}++) {
3523       $self->throw_exception(
3524         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3525       );
3526     }
3527     else {
3528       $i++;
3529     }
3530   }
3531
3532   $attrs->{select} = \@sel;
3533   $attrs->{as} = \@as;
3534
3535   $attrs->{from} ||= [{
3536     -rsrc   => $source,
3537     -alias  => $self->{attrs}{alias},
3538     $self->{attrs}{alias} => $source->from,
3539   }];
3540
3541   if ( $attrs->{join} || $attrs->{prefetch} ) {
3542
3543     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3544       if ref $attrs->{from} ne 'ARRAY';
3545
3546     my $join = (delete $attrs->{join}) || {};
3547
3548     if ( defined $attrs->{prefetch} ) {
3549       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3550     }
3551
3552     $attrs->{from} =    # have to copy here to avoid corrupting the original
3553       [
3554         @{ $attrs->{from} },
3555         $source->_resolve_join(
3556           $join,
3557           $alias,
3558           { %{ $attrs->{seen_join} || {} } },
3559           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3560             ? $attrs->{from}[-1][0]{-join_path}
3561             : []
3562           ,
3563         )
3564       ];
3565   }
3566
3567   if ( defined $attrs->{order_by} ) {
3568     $attrs->{order_by} = (
3569       ref( $attrs->{order_by} ) eq 'ARRAY'
3570       ? [ @{ $attrs->{order_by} } ]
3571       : [ $attrs->{order_by} || () ]
3572     );
3573   }
3574
3575   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3576     $attrs->{group_by} = [ $attrs->{group_by} ];
3577   }
3578
3579
3580   # generate selections based on the prefetch helper
3581   my ($prefetch, @prefetch_select, @prefetch_as);
3582   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3583     if defined $attrs->{prefetch};
3584
3585   if ($prefetch) {
3586
3587     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3588       if $attrs->{_dark_selector};
3589
3590     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3591       if defined $attrs->{collapse} and ! $attrs->{collapse};
3592
3593     $attrs->{collapse} = 1;
3594
3595     # this is a separate structure (we don't look in {from} directly)
3596     # as the resolver needs to shift things off the lists to work
3597     # properly (identical-prefetches on different branches)
3598     my $join_map = {};
3599     if (ref $attrs->{from} eq 'ARRAY') {
3600
3601       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3602
3603       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3604         next unless $j->[0]{-alias};
3605         next unless $j->[0]{-join_path};
3606         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3607
3608         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3609
3610         my $p = $join_map;
3611         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3612         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3613       }
3614     }
3615
3616     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3617
3618     # save these for after distinct resolution
3619     @prefetch_select = map { $_->[0] } @prefetch;
3620     @prefetch_as = map { $_->[1] } @prefetch;
3621   }
3622
3623   # run through the resulting joinstructure (starting from our current slot)
3624   # and unset collapse if proven unnecessary
3625   #
3626   # also while we are at it find out if the current root source has
3627   # been premultiplied by previous related_source chaining
3628   #
3629   # this allows to predict whether a root object with all other relation
3630   # data set to NULL is in fact unique
3631   if ($attrs->{collapse}) {
3632
3633     if (ref $attrs->{from} eq 'ARRAY') {
3634
3635       if (@{$attrs->{from}} == 1) {
3636         # no joins - no collapse
3637         $attrs->{collapse} = 0;
3638       }
3639       else {
3640         # find where our table-spec starts
3641         my @fromlist = @{$attrs->{from}};
3642         while (@fromlist) {
3643           my $t = shift @fromlist;
3644
3645           my $is_multi;
3646           # me vs join from-spec distinction - a ref means non-root
3647           if (ref $t eq 'ARRAY') {
3648             $t = $t->[0];
3649             $is_multi ||= ! $t->{-is_single};
3650           }
3651           last if ($t->{-alias} && $t->{-alias} eq $alias);
3652           $attrs->{_main_source_premultiplied} ||= $is_multi;
3653         }
3654
3655         # no non-singles remaining, nor any premultiplication - nothing to collapse
3656         if (
3657           ! $attrs->{_main_source_premultiplied}
3658             and
3659           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3660         ) {
3661           $attrs->{collapse} = 0;
3662         }
3663       }
3664     }
3665
3666     else {
3667       # if we can not analyze the from - err on the side of safety
3668       $attrs->{_main_source_premultiplied} = 1;
3669     }
3670   }
3671
3672   # generate the distinct induced group_by before injecting the prefetched select/as parts
3673   if (delete $attrs->{distinct}) {
3674     if ($attrs->{group_by}) {
3675       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3676     }
3677     else {
3678       $attrs->{_grouped_by_distinct} = 1;
3679       # distinct affects only the main selection part, not what prefetch may add below
3680       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3681
3682       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3683       # The thinking is: if we are collapsing the subquerying prefetch engine will
3684       # rip stuff apart for us anyway, and we do not want to have a potentially
3685       # function-converted external order_by
3686       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3687       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3688     }
3689   }
3690
3691   # inject prefetch-bound selection (if any)
3692   push @{$attrs->{select}}, @prefetch_select;
3693   push @{$attrs->{as}}, @prefetch_as;
3694
3695   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3696   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3697     $attrs->{_related_results_construction} = 1;
3698   }
3699
3700   # if both page and offset are specified, produce a combined offset
3701   # even though it doesn't make much sense, this is what pre 081xx has
3702   # been doing
3703   if (my $page = delete $attrs->{page}) {
3704     $attrs->{offset} =
3705       ($attrs->{rows} * ($page - 1))
3706             +
3707       ($attrs->{offset} || 0)
3708     ;
3709   }
3710
3711   return $self->{_attrs} = $attrs;
3712 }
3713
3714 sub _rollout_attr {
3715   my ($self, $attr) = @_;
3716
3717   if (ref $attr eq 'HASH') {
3718     return $self->_rollout_hash($attr);
3719   } elsif (ref $attr eq 'ARRAY') {
3720     return $self->_rollout_array($attr);
3721   } else {
3722     return [$attr];
3723   }
3724 }
3725
3726 sub _rollout_array {
3727   my ($self, $attr) = @_;
3728
3729   my @rolled_array;
3730   foreach my $element (@{$attr}) {
3731     if (ref $element eq 'HASH') {
3732       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3733     } elsif (ref $element eq 'ARRAY') {
3734       #  XXX - should probably recurse here
3735       push( @rolled_array, @{$self->_rollout_array($element)} );
3736     } else {
3737       push( @rolled_array, $element );
3738     }
3739   }
3740   return \@rolled_array;
3741 }
3742
3743 sub _rollout_hash {
3744   my ($self, $attr) = @_;
3745
3746   my @rolled_array;
3747   foreach my $key (keys %{$attr}) {
3748     push( @rolled_array, { $key => $attr->{$key} } );
3749   }
3750   return \@rolled_array;
3751 }
3752
3753 sub _calculate_score {
3754   my ($self, $a, $b) = @_;
3755
3756   if (defined $a xor defined $b) {
3757     return 0;
3758   }
3759   elsif (not defined $a) {
3760     return 1;
3761   }
3762
3763   if (ref $b eq 'HASH') {
3764     my ($b_key) = keys %{$b};
3765     if (ref $a eq 'HASH') {
3766       my ($a_key) = keys %{$a};
3767       if ($a_key eq $b_key) {
3768         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3769       } else {
3770         return 0;
3771       }
3772     } else {
3773       return ($a eq $b_key) ? 1 : 0;
3774     }
3775   } else {
3776     if (ref $a eq 'HASH') {
3777       my ($a_key) = keys %{$a};
3778       return ($b eq $a_key) ? 1 : 0;
3779     } else {
3780       return ($b eq $a) ? 1 : 0;
3781     }
3782   }
3783 }
3784
3785 sub _merge_joinpref_attr {
3786   my ($self, $orig, $import) = @_;
3787
3788   return $import unless defined($orig);
3789   return $orig unless defined($import);
3790
3791   $orig = $self->_rollout_attr($orig);
3792   $import = $self->_rollout_attr($import);
3793
3794   my $seen_keys;
3795   foreach my $import_element ( @{$import} ) {
3796     # find best candidate from $orig to merge $b_element into
3797     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3798     foreach my $orig_element ( @{$orig} ) {
3799       my $score = $self->_calculate_score( $orig_element, $import_element );
3800       if ($score > $best_candidate->{score}) {
3801         $best_candidate->{position} = $position;
3802         $best_candidate->{score} = $score;
3803       }
3804       $position++;
3805     }
3806     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3807     $import_key = '' if not defined $import_key;
3808
3809     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3810       push( @{$orig}, $import_element );
3811     } else {
3812       my $orig_best = $orig->[$best_candidate->{position}];
3813       # merge orig_best and b_element together and replace original with merged
3814       if (ref $orig_best ne 'HASH') {
3815         $orig->[$best_candidate->{position}] = $import_element;
3816       } elsif (ref $import_element eq 'HASH') {
3817         my ($key) = keys %{$orig_best};
3818         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3819       }
3820     }
3821     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3822   }
3823
3824   return @$orig ? $orig : ();
3825 }
3826
3827 {
3828   my $hm;
3829
3830   sub _merge_attr {
3831     $hm ||= do {
3832       require Hash::Merge;
3833       my $hm = Hash::Merge->new;
3834
3835       $hm->specify_behavior({
3836         SCALAR => {
3837           SCALAR => sub {
3838             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3839
3840             if ($defl xor $defr) {
3841               return [ $defl ? $_[0] : $_[1] ];
3842             }
3843             elsif (! $defl) {
3844               return [];
3845             }
3846             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3847               return [ $_[0] ];
3848             }
3849             else {
3850               return [$_[0], $_[1]];
3851             }
3852           },
3853           ARRAY => sub {
3854             return $_[1] if !defined $_[0];
3855             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3856             return [$_[0], @{$_[1]}]
3857           },
3858           HASH  => sub {
3859             return [] if !defined $_[0] and !keys %{$_[1]};
3860             return [ $_[1] ] if !defined $_[0];
3861             return [ $_[0] ] if !keys %{$_[1]};
3862             return [$_[0], $_[1]]
3863           },
3864         },
3865         ARRAY => {
3866           SCALAR => sub {
3867             return $_[0] if !defined $_[1];
3868             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3869             return [@{$_[0]}, $_[1]]
3870           },
3871           ARRAY => sub {
3872             my @ret = @{$_[0]} or return $_[1];
3873             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3874             my %idx = map { $_ => 1 } @ret;
3875             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3876             \@ret;
3877           },
3878           HASH => sub {
3879             return [ $_[1] ] if ! @{$_[0]};
3880             return $_[0] if !keys %{$_[1]};
3881             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3882             return [ @{$_[0]}, $_[1] ];
3883           },
3884         },
3885         HASH => {
3886           SCALAR => sub {
3887             return [] if !keys %{$_[0]} and !defined $_[1];
3888             return [ $_[0] ] if !defined $_[1];
3889             return [ $_[1] ] if !keys %{$_[0]};
3890             return [$_[0], $_[1]]
3891           },
3892           ARRAY => sub {
3893             return [] if !keys %{$_[0]} and !@{$_[1]};
3894             return [ $_[0] ] if !@{$_[1]};
3895             return $_[1] if !keys %{$_[0]};
3896             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3897             return [ $_[0], @{$_[1]} ];
3898           },
3899           HASH => sub {
3900             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3901             return [ $_[0] ] if !keys %{$_[1]};
3902             return [ $_[1] ] if !keys %{$_[0]};
3903             return [ $_[0] ] if $_[0] eq $_[1];
3904             return [ $_[0], $_[1] ];
3905           },
3906         }
3907       } => 'DBIC_RS_ATTR_MERGER');
3908       $hm;
3909     };
3910
3911     return $hm->merge ($_[1], $_[2]);
3912   }
3913 }
3914
3915 sub STORABLE_freeze {
3916   my ($self, $cloning) = @_;
3917   my $to_serialize = { %$self };
3918
3919   # A cursor in progress can't be serialized (and would make little sense anyway)
3920   # the parser can be regenerated (and can't be serialized)
3921   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3922
3923   # nor is it sensical to store a not-yet-fired-count pager
3924   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3925     delete $to_serialize->{pager};
3926   }
3927
3928   Storable::nfreeze($to_serialize);
3929 }
3930
3931 # need this hook for symmetry
3932 sub STORABLE_thaw {
3933   my ($self, $cloning, $serialized) = @_;
3934
3935   %$self = %{ Storable::thaw($serialized) };
3936
3937   $self;
3938 }
3939
3940
3941 =head2 throw_exception
3942
3943 See L<DBIx::Class::Schema/throw_exception> for details.
3944
3945 =cut
3946
3947 sub throw_exception {
3948   my $self=shift;
3949
3950   if (ref $self and my $rsrc = $self->result_source) {
3951     $rsrc->throw_exception(@_)
3952   }
3953   else {
3954     DBIx::Class::Exception->throw(@_);
3955   }
3956 }
3957
3958 1;
3959
3960 __END__
3961
3962 # XXX: FIXME: Attributes docs need clearing up
3963
3964 =head1 ATTRIBUTES
3965
3966 Attributes are used to refine a ResultSet in various ways when
3967 searching for data. They can be passed to any method which takes an
3968 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3969 L</count>.
3970
3971 Default attributes can be set on the result class using
3972 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3973 the CAVEATS on that feature before using it!)
3974
3975 These are in no particular order:
3976
3977 =head2 order_by
3978
3979 =over 4
3980
3981 =item Value: ( $order_by | \@order_by | \%order_by )
3982
3983 =back
3984
3985 Which column(s) to order the results by.
3986
3987 [The full list of suitable values is documented in
3988 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3989 common options.]
3990
3991 If a single column name, or an arrayref of names is supplied, the
3992 argument is passed through directly to SQL. The hashref syntax allows
3993 for connection-agnostic specification of ordering direction:
3994
3995  For descending order:
3996
3997   order_by => { -desc => [qw/col1 col2 col3/] }
3998
3999  For explicit ascending order:
4000
4001   order_by => { -asc => 'col' }
4002
4003 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4004 supported, although you are strongly encouraged to use the hashref
4005 syntax as outlined above.
4006
4007 =head2 columns
4008
4009 =over 4
4010
4011 =item Value: \@columns | \%columns | $column
4012
4013 =back
4014
4015 Shortcut to request a particular set of columns to be retrieved. Each
4016 column spec may be a string (a table column name), or a hash (in which
4017 case the key is the C<as> value, and the value is used as the C<select>
4018 expression). Adds C<me.> onto the start of any column without a C<.> in
4019 it and sets C<select> from that, then auto-populates C<as> from
4020 C<select> as normal. (You may also use the C<cols> attribute, as in
4021 earlier versions of DBIC, but this is deprecated.)
4022
4023 Essentially C<columns> does the same as L</select> and L</as>.
4024
4025     columns => [ 'foo', { bar => 'baz' } ]
4026
4027 is the same as
4028
4029     select => [qw/foo baz/],
4030     as => [qw/foo bar/]
4031
4032 =head2 +columns
4033
4034 =over 4
4035
4036 =item Value: \@columns
4037
4038 =back
4039
4040 Indicates additional columns to be selected from storage. Works the same as
4041 L</columns> but adds columns to the selection. (You may also use the
4042 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4043 deprecated). For example:-
4044
4045   $schema->resultset('CD')->search(undef, {
4046     '+columns' => ['artist.name'],
4047     join => ['artist']
4048   });
4049
4050 would return all CDs and include a 'name' column to the information
4051 passed to object inflation. Note that the 'artist' is the name of the
4052 column (or relationship) accessor, and 'name' is the name of the column
4053 accessor in the related table.
4054
4055 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
4056 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
4057 unary plus operator before it.
4058
4059 =head2 include_columns
4060
4061 =over 4
4062
4063 =item Value: \@columns
4064
4065 =back
4066
4067 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
4068
4069 =head2 select
4070
4071 =over 4
4072
4073 =item Value: \@select_columns
4074
4075 =back
4076
4077 Indicates which columns should be selected from the storage. You can use
4078 column names, or in the case of RDBMS back ends, function or stored procedure
4079 names:
4080
4081   $rs = $schema->resultset('Employee')->search(undef, {
4082     select => [
4083       'name',
4084       { count => 'employeeid' },
4085       { max => { length => 'name' }, -as => 'longest_name' }
4086     ]
4087   });
4088
4089   # Equivalent SQL
4090   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4091
4092 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4093 use L</select>, to instruct DBIx::Class how to store the result of the column.
4094 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4095 identifier aliasing. You can however alias a function, so you can use it in
4096 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4097 attribute> supplied as shown in the example above.
4098
4099 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4100 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4101 unary plus operator before it.
4102
4103 =head2 +select
4104
4105 =over 4
4106
4107 Indicates additional columns to be selected from storage.  Works the same as
4108 L</select> but adds columns to the default selection, instead of specifying
4109 an explicit list.
4110
4111 =back
4112
4113 =head2 as
4114
4115 =over 4
4116
4117 =item Value: \@inflation_names
4118
4119 =back
4120
4121 Indicates column names for object inflation. That is L</as> indicates the
4122 slot name in which the column value will be stored within the
4123 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4124 identifier by the C<get_column> method (or via the object accessor B<if one
4125 with the same name already exists>) as shown below. The L</as> attribute has
4126 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4127
4128   $rs = $schema->resultset('Employee')->search(undef, {
4129     select => [
4130       'name',
4131       { count => 'employeeid' },
4132       { max => { length => 'name' }, -as => 'longest_name' }
4133     ],
4134     as => [qw/
4135       name
4136       employee_count
4137       max_name_length
4138     /],
4139   });
4140
4141 If the object against which the search is performed already has an accessor
4142 matching a column name specified in C<as>, the value can be retrieved using
4143 the accessor as normal:
4144
4145   my $name = $employee->name();
4146
4147 If on the other hand an accessor does not exist in the object, you need to
4148 use C<get_column> instead:
4149
4150   my $employee_count = $employee->get_column('employee_count');
4151
4152 You can create your own accessors if required - see
4153 L<DBIx::Class::Manual::Cookbook> for details.
4154
4155 =head2 +as
4156
4157 =over 4
4158
4159 Indicates additional column names for those added via L</+select>. See L</as>.
4160
4161 =back
4162
4163 =head2 join
4164
4165 =over 4
4166
4167 =item Value: ($rel_name | \@rel_names | \%rel_names)
4168
4169 =back
4170
4171 Contains a list of relationships that should be joined for this query.  For
4172 example:
4173
4174   # Get CDs by Nine Inch Nails
4175   my $rs = $schema->resultset('CD')->search(
4176     { 'artist.name' => 'Nine Inch Nails' },
4177     { join => 'artist' }
4178   );
4179
4180 Can also contain a hash reference to refer to the other relation's relations.
4181 For example:
4182
4183   package MyApp::Schema::Track;
4184   use base qw/DBIx::Class/;
4185   __PACKAGE__->table('track');
4186   __PACKAGE__->add_columns(qw/trackid cd position title/);
4187   __PACKAGE__->set_primary_key('trackid');
4188   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4189   1;
4190
4191   # In your application
4192   my $rs = $schema->resultset('Artist')->search(
4193     { 'track.title' => 'Teardrop' },
4194     {
4195       join     => { cd => 'track' },
4196       order_by => 'artist.name',
4197     }
4198   );
4199
4200 You need to use the relationship (not the table) name in  conditions,
4201 because they are aliased as such. The current table is aliased as "me", so
4202 you need to use me.column_name in order to avoid ambiguity. For example:
4203
4204   # Get CDs from 1984 with a 'Foo' track
4205   my $rs = $schema->resultset('CD')->search(
4206     {
4207       'me.year' => 1984,
4208       'tracks.name' => 'Foo'
4209     },
4210     { join => 'tracks' }
4211   );
4212
4213 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4214 similarly for a third time). For e.g.
4215
4216   my $rs = $schema->resultset('Artist')->search({
4217     'cds.title'   => 'Down to Earth',
4218     'cds_2.title' => 'Popular',
4219   }, {
4220     join => [ qw/cds cds/ ],
4221   });
4222
4223 will return a set of all artists that have both a cd with title 'Down
4224 to Earth' and a cd with title 'Popular'.
4225
4226 If you want to fetch related objects from other tables as well, see L</prefetch>
4227 below.
4228
4229  NOTE: An internal join-chain pruner will discard certain joins while
4230  constructing the actual SQL query, as long as the joins in question do not
4231  affect the retrieved result. This for example includes 1:1 left joins
4232  that are not part of the restriction specification (WHERE/HAVING) nor are
4233  a part of the query selection.
4234
4235 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4236
4237 =head2 collapse
4238
4239 =over 4
4240
4241 =item Value: (0 | 1)
4242
4243 =back
4244
4245 When set to a true value, indicates that any rows fetched from joined has_many
4246 relationships are to be aggregated into the corresponding "parent" object. For
4247 example, the resultset:
4248
4249   my $rs = $schema->resultset('CD')->search({}, {
4250     '+columns' => [ qw/ tracks.title tracks.position / ],
4251     join => 'tracks',
4252     collapse => 1,
4253   });
4254
4255 While executing the following query:
4256
4257   SELECT me.*, tracks.title, tracks.position
4258     FROM cd me
4259     LEFT JOIN track tracks
4260       ON tracks.cdid = me.cdid
4261
4262 Will return only as many objects as there are rows in the CD source, even
4263 though the result of the query may span many rows. Each of these CD objects
4264 will in turn have multiple "Track" objects hidden behind the has_many
4265 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4266 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4267 product"), with each CD object containing exactly one of all fetched Track data.
4268
4269 When a collapse is requested on a non-ordered resultset, an order by some
4270 unique part of the main source (the left-most table) is inserted automatically.
4271 This is done so that the resultset is allowed to be "lazy" - calling
4272 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4273 object with all of its related data.
4274
4275 If an L</order_by> is already declared, and orders the resultset in a way that
4276 makes collapsing as described above impossible (e.g. C<< ORDER BY
4277 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4278 switch to "eager" mode and slurp the entire resultset before constructing the
4279 first object returned by L</next>.
4280
4281 Setting this attribute on a resultset that does not join any has_many
4282 relations is a no-op.
4283
4284 For a more in-depth discussion, see L</PREFETCHING>.
4285
4286 =head2 prefetch
4287
4288 =over 4
4289
4290 =item Value: ($rel_name | \@rel_names | \%rel_names)
4291
4292 =back
4293
4294 This attribute is a shorthand for specifying a L</join> spec, adding all
4295 columns from the joined related sources as L</+columns> and setting
4296 L</collapse> to a true value. For example, the following two queries are
4297 equivalent:
4298
4299   my $rs = $schema->resultset('Artist')->search({}, {
4300     prefetch => { cds => ['genre', 'tracks' ] },
4301   });
4302
4303 and
4304
4305   my $rs = $schema->resultset('Artist')->search({}, {
4306     join => { cds => ['genre', 'tracks' ] },
4307     collapse => 1,
4308     '+columns' => [
4309       (map
4310         { +{ "cds.$_" => "cds.$_" } }
4311         $schema->source('Artist')->related_source('cds')->columns
4312       ),
4313       (map
4314         { +{ "cds.genre.$_" => "genre.$_" } }
4315         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4316       ),
4317       (map
4318         { +{ "cds.tracks.$_" => "tracks.$_" } }
4319         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4320       ),
4321     ],
4322   });
4323
4324 Both producing the following SQL:
4325
4326   SELECT  me.artistid, me.name, me.rank, me.charfield,
4327           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4328           genre.genreid, genre.name,
4329           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4330     FROM artist me
4331     LEFT JOIN cd cds
4332       ON cds.artist = me.artistid
4333     LEFT JOIN genre genre
4334       ON genre.genreid = cds.genreid
4335     LEFT JOIN track tracks
4336       ON tracks.cd = cds.cdid
4337   ORDER BY me.artistid
4338
4339 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4340 the arguments are properly merged and generally do the right thing. For
4341 example, you may want to do the following:
4342
4343   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4344     { 'genre.genreid' => undef },
4345     {
4346       join => { cds => 'genre' },
4347       prefetch => 'cds',
4348     }
4349   );
4350
4351 Which generates the following SQL:
4352
4353   SELECT  me.artistid, me.name, me.rank, me.charfield,
4354           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4355     FROM artist me
4356     LEFT JOIN cd cds
4357       ON cds.artist = me.artistid
4358     LEFT JOIN genre genre
4359       ON genre.genreid = cds.genreid
4360   WHERE genre.genreid IS NULL
4361   ORDER BY me.artistid
4362
4363 For a more in-depth discussion, see L</PREFETCHING>.
4364
4365 =head2 alias
4366
4367 =over 4
4368
4369 =item Value: $source_alias
4370
4371 =back
4372
4373 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4374 nested search queries (sub-SELECTs) might need specific aliases set to
4375 reference inner queries.  For example:
4376
4377    my $q = $rs
4378       ->related_resultset('CDs')
4379       ->related_resultset('Tracks')
4380       ->search({
4381          'track.id' => { -ident => 'none_search.id' },
4382       })
4383       ->as_query;
4384
4385    my $ids = $self->search({
4386       -not_exists => $q,
4387    }, {
4388       alias    => 'none_search',
4389       group_by => 'none_search.id',
4390    })->get_column('id')->as_query;
4391
4392    $self->search({ id => { -in => $ids } })
4393
4394 This attribute is directly tied to L</current_source_alias>.
4395
4396 =head2 page
4397
4398 =over 4
4399
4400 =item Value: $page
4401
4402 =back
4403
4404 Makes the resultset paged and specifies the page to retrieve. Effectively
4405 identical to creating a non-pages resultset and then calling ->page($page)
4406 on it.
4407
4408 If L</rows> attribute is not specified it defaults to 10 rows per page.
4409
4410 When you have a paged resultset, L</count> will only return the number
4411 of rows in the page. To get the total, use the L</pager> and call
4412 C<total_entries> on it.
4413
4414 =head2 rows
4415
4416 =over 4
4417
4418 =item Value: $rows
4419
4420 =back
4421
4422 Specifies the maximum number of rows for direct retrieval or the number of
4423 rows per page if the page attribute or method is used.
4424
4425 =head2 offset
4426
4427 =over 4
4428
4429 =item Value: $offset
4430
4431 =back
4432
4433 Specifies the (zero-based) row number for the  first row to be returned, or the
4434 of the first row of the first page if paging is used.
4435
4436 =head2 software_limit
4437
4438 =over 4
4439
4440 =item Value: (0 | 1)
4441
4442 =back
4443
4444 When combined with L</rows> and/or L</offset> the generated SQL will not
4445 include any limit dialect stanzas. Instead the entire result will be selected
4446 as if no limits were specified, and DBIC will perform the limit locally, by
4447 artificially advancing and finishing the resulting L</cursor>.
4448
4449 This is the recommended way of performing resultset limiting when no sane RDBMS
4450 implementation is available (e.g.
4451 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4452 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4453
4454 =head2 group_by
4455
4456 =over 4
4457
4458 =item Value: \@columns
4459
4460 =back
4461
4462 A arrayref of columns to group by. Can include columns of joined tables.
4463
4464   group_by => [qw/ column1 column2 ... /]
4465
4466 =head2 having
4467
4468 =over 4
4469
4470 =item Value: $condition
4471
4472 =back
4473
4474 HAVING is a select statement attribute that is applied between GROUP BY and
4475 ORDER BY. It is applied to the after the grouping calculations have been
4476 done.
4477
4478   having => { 'count_employee' => { '>=', 100 } }
4479
4480 or with an in-place function in which case literal SQL is required:
4481
4482   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4483
4484 =head2 distinct
4485
4486 =over 4
4487
4488 =item Value: (0 | 1)
4489
4490 =back
4491
4492 Set to 1 to automatically generate a L</group_by> clause based on the selection
4493 (including intelligent handling of L</order_by> contents). Note that the group
4494 criteria calculation takes place over the B<final> selection. This includes
4495 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4496 L</search> calls, and standalone columns selected via
4497 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4498 extra selections specified via L</prefetch> - such selections are explicitly
4499 excluded from group criteria calculations.
4500
4501 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4502 setting is ignored and an appropriate warning is issued.
4503
4504 =head2 where
4505
4506 =over 4
4507
4508 Adds to the WHERE clause.
4509
4510   # only return rows WHERE deleted IS NULL for all searches
4511   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4512
4513 Can be overridden by passing C<< { where => undef } >> as an attribute
4514 to a resultset.
4515
4516 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4517
4518 =back
4519
4520 =head2 cache
4521
4522 Set to 1 to cache search results. This prevents extra SQL queries if you
4523 revisit rows in your ResultSet:
4524
4525   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4526
4527   while( my $artist = $resultset->next ) {
4528     ... do stuff ...
4529   }
4530
4531   $rs->first; # without cache, this would issue a query
4532
4533 By default, searches are not cached.
4534
4535 For more examples of using these attributes, see
4536 L<DBIx::Class::Manual::Cookbook>.
4537
4538 =head2 for
4539
4540 =over 4
4541
4542 =item Value: ( 'update' | 'shared' | \$scalar )
4543
4544 =back
4545
4546 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4547 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4548 query.
4549
4550 =head1 PREFETCHING
4551
4552 DBIx::Class supports arbitrary related data prefetching from multiple related
4553 sources. Any combination of relationship types and column sets are supported.
4554 If L<collapsing|/collapse> is requested, there is an additional requirement of
4555 selecting enough data to make every individual object uniquely identifiable.
4556
4557 Here are some more involved examples, based on the following relationship map:
4558
4559   # Assuming:
4560   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4561   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4562   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4563
4564   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4565
4566   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4567
4568
4569
4570   my $rs = $schema->resultset('Tag')->search(
4571     undef,
4572     {
4573       prefetch => {
4574         cd => 'artist'
4575       }
4576     }
4577   );
4578
4579 The initial search results in SQL like the following:
4580
4581   SELECT tag.*, cd.*, artist.* FROM tag
4582   JOIN cd ON tag.cd = cd.cdid
4583   JOIN artist ON cd.artist = artist.artistid
4584
4585 L<DBIx::Class> has no need to go back to the database when we access the
4586 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4587 case.
4588
4589 Simple prefetches will be joined automatically, so there is no need
4590 for a C<join> attribute in the above search.
4591
4592 The L</prefetch> attribute can be used with any of the relationship types
4593 and multiple prefetches can be specified together. Below is a more complex
4594 example that prefetches a CD's artist, its liner notes (if present),
4595 the cover image, the tracks on that CD, and the guests on those
4596 tracks.
4597
4598   my $rs = $schema->resultset('CD')->search(
4599     undef,
4600     {
4601       prefetch => [
4602         { artist => 'record_label'},  # belongs_to => belongs_to
4603         'liner_note',                 # might_have
4604         'cover_image',                # has_one
4605         { tracks => 'guests' },       # has_many => has_many
4606       ]
4607     }
4608   );
4609
4610 This will produce SQL like the following:
4611
4612   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4613          tracks.*, guests.*
4614     FROM cd me
4615     JOIN artist artist
4616       ON artist.artistid = me.artistid
4617     JOIN record_label record_label
4618       ON record_label.labelid = artist.labelid
4619     LEFT JOIN track tracks
4620       ON tracks.cdid = me.cdid
4621     LEFT JOIN guest guests
4622       ON guests.trackid = track.trackid
4623     LEFT JOIN liner_notes liner_note
4624       ON liner_note.cdid = me.cdid
4625     JOIN cd_artwork cover_image
4626       ON cover_image.cdid = me.cdid
4627   ORDER BY tracks.cd
4628
4629 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4630 C<tracks>, and C<guests> of the CD will all be available through the
4631 relationship accessors without the need for additional queries to the
4632 database.
4633
4634 =head3 CAVEATS
4635
4636 Prefetch does a lot of deep magic. As such, it may not behave exactly
4637 as you might expect.
4638
4639 =over 4
4640
4641 =item *
4642
4643 Prefetch uses the L</cache> to populate the prefetched relationships. This
4644 may or may not be what you want.
4645
4646 =item *
4647
4648 If you specify a condition on a prefetched relationship, ONLY those
4649 rows that match the prefetched condition will be fetched into that relationship.
4650 This means that adding prefetch to a search() B<may alter> what is returned by
4651 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4652
4653   my $artist_rs = $schema->resultset('Artist')->search({
4654       'cds.year' => 2008,
4655   }, {
4656       join => 'cds',
4657   });
4658
4659   my $count = $artist_rs->first->cds->count;
4660
4661   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4662
4663   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4664
4665   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4666
4667 That cmp_ok() may or may not pass depending on the datasets involved. In other
4668 words the C<WHERE> condition would apply to the entire dataset, just like
4669 it would in regular SQL. If you want to add a condition only to the "right side"
4670 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4671 condition|DBIx::Class::Relationship::Base/condition>
4672
4673 =back
4674
4675 =head1 DBIC BIND VALUES
4676
4677 Because DBIC may need more information to bind values than just the column name
4678 and value itself, it uses a special format for both passing and receiving bind
4679 values.  Each bind value should be composed of an arrayref of
4680 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4681
4682 =over 4
4683
4684 =item dbd_attrs
4685
4686 If present (in any form), this is what is being passed directly to bind_param.
4687 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4688 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4689
4690 If this is specified, all other bind options described below are ignored.
4691
4692 =item sqlt_datatype
4693
4694 If present, this is used to infer the actual bind attribute by passing to
4695 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4696 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4697
4698 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4699 currently drivers are expected to "Do the Right Thing" when given a common
4700 datatype name.  (Not ideal, but that's what we got at this point.)
4701
4702 =item sqlt_size
4703
4704 Currently used to correctly allocate buffers for bind_param_inout().
4705 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4706 or to a sensible value based on the "data_type".
4707
4708 =item dbic_colname
4709
4710 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4711 explicitly specified they are never overridden).  Also used by some weird DBDs,
4712 where the column name should be available at bind_param time (e.g. Oracle).
4713
4714 =back
4715
4716 For backwards compatibility and convenience, the following shortcuts are
4717 supported:
4718
4719   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4720   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4721   [ undef,   $val ] === [ {}, $val ]
4722   $val              === [ {}, $val ]
4723
4724 =head1 AUTHOR AND CONTRIBUTORS
4725
4726 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4727
4728 =head1 LICENSE
4729
4730 You may distribute this code under the same terms as Perl itself.
4731