lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use DBIx::Class::ResultClass::HashRefInflator;
   9 use Scalar::Util qw/blessed weaken reftype/;
  10 use DBIx::Class::_Util qw(
  11   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  12 );
  13 use Try::Tiny;
  14
  15 # not importing first() as it will clash with our own method
  16 use List::Util ();
  17
  18 BEGIN {
  19   # De-duplication in _merge_attr() is disabled, but left in for reference
  20   # (the merger is used for other things that ought not to be de-duped)
  21   *__HM_DEDUP = sub () { 0 };
  22 }
  23
  24 use namespace::clean;
  25
  26 use overload
  27         '0+'     => "count",
  28         'bool'   => "_bool",
  29         fallback => 1;
  30
  31 # this is real - CDBICompat overrides it with insanity
  32 # yes, prototype won't matter, but that's for now ;)
  33 sub _bool () { 1 }
  34
  35 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  36
  37 =head1 NAME
  38
  39 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  40
  41 =head1 SYNOPSIS
  42
  43   my $users_rs = $schema->resultset('User');
  44   while( $user = $users_rs->next) {
  45     print $user->username;
  46   }
  47
  48   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  49   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  50
  51 =head1 DESCRIPTION
  52
  53 A ResultSet is an object which stores a set of conditions representing
  54 a query. It is the backbone of DBIx::Class (i.e. the really
  55 important/useful bit).
  56
  57 No SQL is executed on the database when a ResultSet is created, it
  58 just stores all the conditions needed to create the query.
  59
  60 A basic ResultSet representing the data of an entire table is returned
  61 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  62 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  63
  64   my $users_rs = $schema->resultset('User');
  65
  66 A new ResultSet is returned from calling L</search> on an existing
  67 ResultSet. The new one will contain all the conditions of the
  68 original, plus any new conditions added in the C<search> call.
  69
  70 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  71 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  72 represents.
  73
  74 The query that the ResultSet represents is B<only> executed against
  75 the database when these methods are called:
  76 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  77
  78 If a resultset is used in a numeric context it returns the L</count>.
  79 However, if it is used in a boolean context it is B<always> true.  So if
  80 you want to check if a resultset has any results, you must use C<if $rs
  81 != 0>.
  82
  83 =head1 EXAMPLES
  84
  85 =head2 Chaining resultsets
  86
  87 Let's say you've got a query that needs to be run to return some data
  88 to the user. But, you have an authorization system in place that
  89 prevents certain users from seeing certain information. So, you want
  90 to construct the basic query in one method, but add constraints to it in
  91 another.
  92
  93   sub get_data {
  94     my $self = shift;
  95     my $request = $self->get_request; # Get a request object somehow.
  96     my $schema = $self->result_source->schema;
  97
  98     my $cd_rs = $schema->resultset('CD')->search({
  99       title => $request->param('title'),
 100       year => $request->param('year'),
 101     });
 102
 103     $cd_rs = $self->apply_security_policy( $cd_rs );
 104
 105     return $cd_rs->all();
 106   }
 107
 108   sub apply_security_policy {
 109     my $self = shift;
 110     my ($rs) = @_;
 111
 112     return $rs->search({
 113       subversive => 0,
 114     });
 115   }
 116
 117 =head3 Resolving conditions and attributes
 118
 119 When a resultset is chained from another resultset (e.g.:
 120 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 121 and attributes with the same keys need resolving.
 122
 123 If any of L</columns>, L</select>, L</as> are present, they reset the
 124 original selection, and start the selection "clean".
 125
 126 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 127 are merged into the existing ones from the original resultset.
 128
 129 The L</where> and L</having> attributes, and any search conditions, are
 130 merged with an SQL C<AND> to the existing condition from the original
 131 resultset.
 132
 133 All other attributes are overridden by any new ones supplied in the
 134 search attributes.
 135
 136 =head2 Multiple queries
 137
 138 Since a resultset just defines a query, you can do all sorts of
 139 things with it with the same object.
 140
 141   # Don't hit the DB yet.
 142   my $cd_rs = $schema->resultset('CD')->search({
 143     title => 'something',
 144     year => 2009,
 145   });
 146
 147   # Each of these hits the DB individually.
 148   my $count = $cd_rs->count;
 149   my $most_recent = $cd_rs->get_column('date_released')->max();
 150   my @records = $cd_rs->all;
 151
 152 And it's not just limited to SELECT statements.
 153
 154   $cd_rs->delete();
 155
 156 This is even cooler:
 157
 158   $cd_rs->create({ artist => 'Fred' });
 159
 160 Which is the same as:
 161
 162   $schema->resultset('CD')->create({
 163     title => 'something',
 164     year => 2009,
 165     artist => 'Fred'
 166   });
 167
 168 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 169
 170 =head2 Custom ResultSet classes
 171
 172 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 173
 174   package MyApp::Schema::ResultSet::User;
 175
 176   use strict;
 177   use warnings;
 178
 179   use base 'DBIx::Class::ResultSet';
 180
 181   sub active {
 182     my $self = shift;
 183     $self->search({ $self->current_source_alias . '.active' => 1 });
 184   }
 185
 186   sub unverified {
 187     my $self = shift;
 188     $self->search({ $self->current_source_alias . '.verified' => 0 });
 189   }
 190
 191   sub created_n_days_ago {
 192     my ($self, $days_ago) = @_;
 193     $self->search({
 194       $self->current_source_alias . '.create_date' => {
 195         '<=',
 196       $self->result_source->schema->storage->datetime_parser->format_datetime(
 197         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 198       )}
 199     });
 200   }
 201
 202   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 203
 204   1;
 205
 206 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 207 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 208 L<ResulSet|DBIx::Class::ResultSet> classes.
 209
 210 =head3 ResultSet subclassing with Moose and similar constructor-providers
 211
 212 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 213 you may find it useful if your ResultSets contain a lot of business logic
 214 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 215 your code via roles.
 216
 217 In order to write custom ResultSet classes with L<Moo> you need to use the
 218 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 219 unusual signature of the L<constructor provided by DBIC
 220 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 221
 222   use Moo;
 223   extends 'DBIx::Class::ResultSet';
 224   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 225
 226   ...your code...
 227
 228   1;
 229
 230 If you want to build your custom ResultSet classes with L<Moose>, you need
 231 a similar, though a little more elaborate template in order to interface the
 232 inlining of the L<Moose>-provided
 233 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 234 with the DBIC one.
 235
 236   package MyApp::Schema::ResultSet::User;
 237
 238   use Moose;
 239   use MooseX::NonMoose;
 240   extends 'DBIx::Class::ResultSet';
 241
 242   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 243
 244   ...your code...
 245
 246   __PACKAGE__->meta->make_immutable;
 247
 248   1;
 249
 250 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 251 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 252 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 253 instead by doing:
 254
 255   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 256
 257 =head1 METHODS
 258
 259 =head2 new
 260
 261 =over 4
 262
 263 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 264
 265 =item Return Value: L<$resultset|/search>
 266
 267 =back
 268
 269 The resultset constructor. Takes a source object (usually a
 270 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 271 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 272 executed as needed by the other methods.
 273
 274 Generally you never construct a resultset manually. Instead you get one
 275 from e.g. a
 276 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 277 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 278 scalar context):
 279
 280   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 281
 282 =over
 283
 284 =item WARNING
 285
 286 If called on an object, proxies to L</new_result> instead, so
 287
 288   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 289
 290 will return a CD object, not a ResultSet, and is equivalent to:
 291
 292   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 293
 294 Please also keep in mind that many internals call L</new_result> directly,
 295 so overloading this method with the idea of intercepting new result object
 296 creation B<will not work>. See also warning pertaining to L</create>.
 297
 298 =back
 299
 300 =cut
 301
 302 sub new {
 303   my $class = shift;
 304
 305   if (ref $class) {
 306     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 307     return $class->new_result(@_);
 308   }
 309
 310   my ($source, $attrs) = @_;
 311   $source = $source->resolve
 312     if $source->isa('DBIx::Class::ResultSourceHandle');
 313
 314   $attrs = { %{$attrs||{}} };
 315   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 316
 317   if ($attrs->{page}) {
 318     $attrs->{rows} ||= 10;
 319   }
 320
 321   $attrs->{alias} ||= 'me';
 322
 323   my $self = bless {
 324     result_source => $source,
 325     cond => $attrs->{where},
 326     pager => undef,
 327     attrs => $attrs,
 328   }, $class;
 329
 330   # if there is a dark selector, this means we are already in a
 331   # chain and the cleanup/sanification was taken care of by
 332   # _search_rs already
 333   $self->_normalize_selection($attrs)
 334     unless $attrs->{_dark_selector};
 335
 336   $self->result_class(
 337     $attrs->{result_class} || $source->result_class
 338   );
 339
 340   $self;
 341 }
 342
 343 =head2 search
 344
 345 =over 4
 346
 347 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 348
 349 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 350
 351 =back
 352
 353   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 354   my $new_rs = $cd_rs->search({ year => 2005 });
 355
 356   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 357                  # year = 2005 OR year = 2004
 358
 359 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 360 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 361 To avoid that, use L</search_rs>.
 362
 363 If you need to pass in additional attributes but no additional condition,
 364 call it as C<search(undef, \%attrs)>.
 365
 366   # "SELECT name, artistid FROM $artist_table"
 367   my @all_artists = $schema->resultset('Artist')->search(undef, {
 368     columns => [qw/name artistid/],
 369   });
 370
 371 For a list of attributes that can be passed to C<search>, see
 372 L</ATTRIBUTES>. For more examples of using this function, see
 373 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 374 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 375 and its extension L<DBIx::Class::SQLMaker>.
 376
 377 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 378
 379 =head3 CAVEAT
 380
 381 Note that L</search> does not process/deflate any of the values passed in the
 382 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 383 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 384 manually that any value passed to this method will stringify to something the
 385 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 386 objects, for more info see:
 387 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 388
 389 =cut
 390
 391 sub search {
 392   my $self = shift;
 393   my $rs = $self->search_rs( @_ );
 394
 395   if (wantarray) {
 396     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 397     return $rs->all;
 398   }
 399   elsif (defined wantarray) {
 400     return $rs;
 401   }
 402   else {
 403     # we can be called by a relationship helper, which in
 404     # turn may be called in void context due to some braindead
 405     # overload or whatever else the user decided to be clever
 406     # at this particular day. Thus limit the exception to
 407     # external code calls only
 408     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 409       if (caller)[0] !~ /^\QDBIx::Class::/;
 410
 411     return ();
 412   }
 413 }
 414
 415 =head2 search_rs
 416
 417 =over 4
 418
 419 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 420
 421 =item Return Value: L<$resultset|/search>
 422
 423 =back
 424
 425 This method does the same exact thing as search() except it will
 426 always return a resultset, even in list context.
 427
 428 =cut
 429
 430 sub search_rs {
 431   my $self = shift;
 432
 433   my $rsrc = $self->result_source;
 434   my ($call_cond, $call_attrs);
 435
 436   # Special-case handling for (undef, undef) or (undef)
 437   # Note that (foo => undef) is valid deprecated syntax
 438   @_ = () if not scalar grep { defined $_ } @_;
 439
 440   # just a cond
 441   if (@_ == 1) {
 442     $call_cond = shift;
 443   }
 444   # fish out attrs in the ($condref, $attr) case
 445   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 446     ($call_cond, $call_attrs) = @_;
 447   }
 448   elsif (@_ % 2) {
 449     $self->throw_exception('Odd number of arguments to search')
 450   }
 451   # legacy search
 452   elsif (@_) {
 453     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 454       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 455
 456     for my $i (0 .. $#_) {
 457       next if $i % 2;
 458       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 459         if (! defined $_[$i] or ref $_[$i] ne '');
 460     }
 461
 462     $call_cond = { @_ };
 463   }
 464
 465   # see if we can keep the cache (no $rs changes)
 466   my $cache;
 467   my %safe = (alias => 1, cache => 1);
 468   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 469     ! defined $call_cond
 470       or
 471     ref $call_cond eq 'HASH' && ! keys %$call_cond
 472       or
 473     ref $call_cond eq 'ARRAY' && ! @$call_cond
 474   )) {
 475     $cache = $self->get_cache;
 476   }
 477
 478   my $old_attrs = { %{$self->{attrs}} };
 479   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 480
 481   my $new_attrs = { %$old_attrs };
 482
 483   # take care of call attrs (only if anything is changing)
 484   if ($call_attrs and keys %$call_attrs) {
 485
 486     # copy for _normalize_selection
 487     $call_attrs = { %$call_attrs };
 488
 489     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 490
 491     # reset the current selector list if new selectors are supplied
 492     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 493       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 494     }
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 my $dark_sel_dumper;
 557 sub _normalize_selection {
 558   my ($self, $attrs) = @_;
 559
 560   # legacy syntax
 561   if ( exists $attrs->{include_columns} ) {
 562     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 563     $attrs->{'+columns'} = $self->_merge_attr(
 564       $attrs->{'+columns'}, delete $attrs->{include_columns}
 565     );
 566   }
 567
 568   # columns are always placed first, however
 569
 570   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 571   # delay the decision on whether to use a default select list ($rsrc->columns)
 572   # allowing stuff like the remove_columns helper to work
 573   #
 574   # select/as +select/+as pairs need special handling - the amount of select/as
 575   # elements in each pair does *not* have to be equal (think multicolumn
 576   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 577   # supplied at all) - try to infer the alias, either from the -as parameter
 578   # of the selector spec, or use the parameter whole if it looks like a column
 579   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 580   # is ok as well), but make sure no more additions to the 'as' chain take place
 581   for my $pref ('', '+') {
 582
 583     my ($sel, $as) = map {
 584       my $key = "${pref}${_}";
 585
 586       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 587         ? @{$attrs->{$key}}
 588         : $attrs->{$key} || ()
 589       ];
 590       delete $attrs->{$key};
 591       $val;
 592     } qw/select as/;
 593
 594     if (! @$as and ! @$sel ) {
 595       next;
 596     }
 597     elsif (@$as and ! @$sel) {
 598       $self->throw_exception(
 599         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 600       );
 601     }
 602     elsif( ! @$as ) {
 603       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 604       # if any @$as has been supplied we assume the user knows what (s)he is doing
 605       # and blindly keep stacking up pieces
 606       unless ($attrs->{_dark_selector}) {
 607         SELECTOR:
 608         for (@$sel) {
 609           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 610             push @$as, $_->{-as};
 611           }
 612           # assume any plain no-space, no-parenthesis string to be a column spec
 613           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 614           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 615             push @$as, $_;
 616           }
 617           # if all else fails - raise a flag that no more aliasing will be allowed
 618           else {
 619             $attrs->{_dark_selector} = {
 620               plus_stage => $pref,
 621               string => ($dark_sel_dumper ||= do {
 622                   require Data::Dumper::Concise;
 623                   Data::Dumper::Concise::DumperObject()->Indent(0);
 624                 })->Values([$_])->Dump
 625               ,
 626             };
 627             last SELECTOR;
 628           }
 629         }
 630       }
 631     }
 632     elsif (@$as < @$sel) {
 633       $self->throw_exception(
 634         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 635       );
 636     }
 637     elsif ($pref and $attrs->{_dark_selector}) {
 638       $self->throw_exception(
 639         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 640       );
 641     }
 642
 643
 644     # merge result
 645     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 646     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 647   }
 648 }
 649
 650 sub _stack_cond {
 651   my ($self, $left, $right) = @_;
 652
 653   (
 654     (ref $_ eq 'ARRAY' and !@$_)
 655       or
 656     (ref $_ eq 'HASH' and ! keys %$_)
 657   ) and $_ = undef for ($left, $right);
 658
 659   # either one of the two undef
 660   if ( (defined $left) xor (defined $right) ) {
 661     return defined $left ? $left : $right;
 662   }
 663   # both undef
 664   elsif ( ! defined $left ) {
 665     return undef
 666   }
 667   else {
 668     return $self->result_source->schema->storage->_collapse_cond({ -and => [$left, $right] });
 669   }
 670 }
 671
 672 =head2 search_literal
 673
 674 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 675 should only be used in that context. C<search_literal> is a convenience
 676 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 677 want to ensure columns are bound correctly, use L</search>.
 678
 679 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 680 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 681 require C<search_literal>.
 682
 683 =over 4
 684
 685 =item Arguments: $sql_fragment, @standalone_bind_values
 686
 687 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 688
 689 =back
 690
 691   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 692   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 693
 694 Pass a literal chunk of SQL to be added to the conditional part of the
 695 resultset query.
 696
 697 Example of how to use C<search> instead of C<search_literal>
 698
 699   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 700   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 701
 702 =cut
 703
 704 sub search_literal {
 705   my ($self, $sql, @bind) = @_;
 706   my $attr;
 707   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 708     $attr = pop @bind;
 709   }
 710   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 711 }
 712
 713 =head2 find
 714
 715 =over 4
 716
 717 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 718
 719 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 720
 721 =back
 722
 723 Finds and returns a single row based on supplied criteria. Takes either a
 724 hashref with the same format as L</create> (including inference of foreign
 725 keys from related objects), or a list of primary key values in the same
 726 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 727 declaration on the L</result_source>.
 728
 729 In either case an attempt is made to combine conditions already existing on
 730 the resultset with the condition passed to this method.
 731
 732 To aid with preparing the correct query for the storage you may supply the
 733 C<key> attribute, which is the name of a
 734 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 735 unique constraint corresponding to the
 736 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 737 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 738 to construct a query that satisfies the named unique constraint fully (
 739 non-NULL values for each column member of the constraint) an exception is
 740 thrown.
 741
 742 If no C<key> is specified, the search is carried over all unique constraints
 743 which are fully defined by the available condition.
 744
 745 If no such constraint is found, C<find> currently defaults to a simple
 746 C<< search->(\%column_values) >> which may or may not do what you expect.
 747 Note that this fallback behavior may be deprecated in further versions. If
 748 you need to search with arbitrary conditions - use L</search>. If the query
 749 resulting from this fallback produces more than one row, a warning to the
 750 effect is issued, though only the first row is constructed and returned as
 751 C<$result_object>.
 752
 753 In addition to C<key>, L</find> recognizes and applies standard
 754 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 755
 756 Note that if you have extra concerns about the correctness of the resulting
 757 query you need to specify the C<key> attribute and supply the entire condition
 758 as an argument to find (since it is not always possible to perform the
 759 combination of the resultset condition with the supplied one, especially if
 760 the resultset condition contains literal sql).
 761
 762 For example, to find a row by its primary key:
 763
 764   my $cd = $schema->resultset('CD')->find(5);
 765
 766 You can also find a row by a specific unique constraint:
 767
 768   my $cd = $schema->resultset('CD')->find(
 769     {
 770       artist => 'Massive Attack',
 771       title  => 'Mezzanine',
 772     },
 773     { key => 'cd_artist_title' }
 774   );
 775
 776 See also L</find_or_create> and L</update_or_create>.
 777
 778 =cut
 779
 780 sub find {
 781   my $self = shift;
 782   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 783
 784   my $rsrc = $self->result_source;
 785
 786   my $constraint_name;
 787   if (exists $attrs->{key}) {
 788     $constraint_name = defined $attrs->{key}
 789       ? $attrs->{key}
 790       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 791     ;
 792   }
 793
 794   # Parse out the condition from input
 795   my $call_cond;
 796
 797   if (ref $_[0] eq 'HASH') {
 798     $call_cond = { %{$_[0]} };
 799   }
 800   else {
 801     # if only values are supplied we need to default to 'primary'
 802     $constraint_name = 'primary' unless defined $constraint_name;
 803
 804     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 805
 806     $self->throw_exception(
 807       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 808     ) unless @c_cols;
 809
 810     $self->throw_exception (
 811       'find() expects either a column/value hashref, or a list of values '
 812     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 813     ) unless @c_cols == @_;
 814
 815     @{$call_cond}{@c_cols} = @_;
 816   }
 817
 818   # process relationship data if any
 819   for my $key (keys %$call_cond) {
 820     if (
 821       length ref($call_cond->{$key})
 822         and
 823       my $relinfo = $rsrc->relationship_info($key)
 824         and
 825       # implicitly skip has_many's (likely MC)
 826       (ref (my $val = delete $call_cond->{$key}) ne 'ARRAY' )
 827     ) {
 828       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 829         $relinfo->{cond}, $val, $key, $key
 830       );
 831
 832       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 833          if $crosstable or ref($rel_cond) ne 'HASH';
 834
 835       # supplement condition
 836       # relationship conditions take precedence (?)
 837       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 838     }
 839   }
 840
 841   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 842   my $final_cond;
 843   if (defined $constraint_name) {
 844     $final_cond = $self->_qualify_cond_columns (
 845
 846       $self->result_source->_minimal_valueset_satisfying_constraint(
 847         constraint_name => $constraint_name,
 848         values => ($self->_merge_with_rscond($call_cond))[0],
 849         carp_on_nulls => 1,
 850       ),
 851
 852       $alias,
 853     );
 854   }
 855   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 856     # This means that we got here after a merger of relationship conditions
 857     # in ::Relationship::Base::search_related (the row method), and furthermore
 858     # the relationship is of the 'single' type. This means that the condition
 859     # provided by the relationship (already attached to $self) is sufficient,
 860     # as there can be only one row in the database that would satisfy the
 861     # relationship
 862   }
 863   else {
 864     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 865
 866     # no key was specified - fall down to heuristics mode:
 867     # run through all unique queries registered on the resultset, and
 868     # 'OR' all qualifying queries together
 869     #
 870     # always start from 'primary' if it exists at all
 871     for my $c_name ( sort {
 872         $a eq 'primary' ? -1
 873       : $b eq 'primary' ? 1
 874       : $a cmp $b
 875     } $rsrc->unique_constraint_names) {
 876
 877       next if $seen_column_combinations{
 878         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 879       }++;
 880
 881       try {
 882         push @unique_queries, $self->_qualify_cond_columns(
 883           $self->result_source->_minimal_valueset_satisfying_constraint(
 884             constraint_name => $c_name,
 885             values => ($self->_merge_with_rscond($call_cond))[0],
 886             columns_info => ($ci ||= $self->result_source->columns_info),
 887           ),
 888           $alias
 889         );
 890       }
 891       catch {
 892         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 893       };
 894     }
 895
 896     $final_cond =
 897         @unique_queries   ? \@unique_queries
 898       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 899       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 900     ;
 901   }
 902
 903   # Run the query, passing the result_class since it should propagate for find
 904   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 905   if ($rs->_resolved_attrs->{collapse}) {
 906     my $row = $rs->next;
 907     carp "Query returned more than one row" if $rs->next;
 908     return $row;
 909   }
 910   else {
 911     return $rs->single;
 912   }
 913 }
 914
 915 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 916 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 917 #
 918 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 919 # condition. It is provided for overrides until a saner way forward is devised
 920 #
 921 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 922 # the road. Please adjust your tests accordingly to catch this situation early
 923 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 924 #
 925 # The method will not be removed without an adequately complete replacement
 926 # for strict-mode enforcement
 927 sub _non_unique_find_fallback {
 928   my ($self, $cond, $attrs) = @_;
 929
 930   return $self->_qualify_cond_columns(
 931     $cond,
 932     exists $attrs->{alias}
 933       ? $attrs->{alias}
 934       : $self->{attrs}{alias}
 935   );
 936 }
 937
 938
 939 sub _qualify_cond_columns {
 940   my ($self, $cond, $alias) = @_;
 941
 942   my %aliased = %$cond;
 943   for (keys %aliased) {
 944     $aliased{"$alias.$_"} = delete $aliased{$_}
 945       if $_ !~ /\./;
 946   }
 947
 948   return \%aliased;
 949 }
 950
 951 sub _build_unique_cond {
 952   carp_unique sprintf
 953     '_build_unique_cond is a private method, and moreover is about to go '
 954   . 'away. Please contact the development team at %s if you believe you '
 955   . 'have a genuine use for this method, in order to discuss alternatives.',
 956     DBIx::Class::_ENV_::HELP_URL,
 957   ;
 958
 959   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 960
 961   $self->result_source->_minimal_valueset_satisfying_constraint(
 962     constraint_name => $constraint_name,
 963     values => $cond,
 964     carp_on_nulls => !$croak_on_null
 965   );
 966 }
 967
 968 =head2 search_related
 969
 970 =over 4
 971
 972 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 973
 974 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 975
 976 =back
 977
 978   $new_rs = $cd_rs->search_related('artist', {
 979     name => 'Emo-R-Us',
 980   });
 981
 982 Searches the specified relationship, optionally specifying a condition and
 983 attributes for matching records. See L</ATTRIBUTES> for more information.
 984
 985 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 986 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 987
 988 See also L</search_related_rs>.
 989
 990 =cut
 991
 992 sub search_related {
 993   return shift->related_resultset(shift)->search(@_);
 994 }
 995
 996 =head2 search_related_rs
 997
 998 This method works exactly the same as search_related, except that
 999 it guarantees a resultset, even in list context.
1000
1001 =cut
1002
1003 sub search_related_rs {
1004   return shift->related_resultset(shift)->search_rs(@_);
1005 }
1006
1007 =head2 cursor
1008
1009 =over 4
1010
1011 =item Arguments: none
1012
1013 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1014
1015 =back
1016
1017 Returns a storage-driven cursor to the given resultset. See
1018 L<DBIx::Class::Cursor> for more information.
1019
1020 =cut
1021
1022 sub cursor {
1023   my $self = shift;
1024
1025   return $self->{cursor} ||= do {
1026     my $attrs = $self->_resolved_attrs;
1027     $self->result_source->storage->select(
1028       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1029     );
1030   };
1031 }
1032
1033 =head2 single
1034
1035 =over 4
1036
1037 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1038
1039 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1040
1041 =back
1042
1043   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1044
1045 Inflates the first result without creating a cursor if the resultset has
1046 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1047 of L</search>.
1048
1049 While this method can take an optional search condition (just like L</search>)
1050 being a fast-code-path it does not recognize search attributes. If you need to
1051 add extra joins or similar, call L</search> and then chain-call L</single> on the
1052 L<DBIx::Class::ResultSet> returned.
1053
1054 =over
1055
1056 =item B<Note>
1057
1058 As of 0.08100, this method enforces the assumption that the preceding
1059 query returns only one row. If more than one row is returned, you will receive
1060 a warning:
1061
1062   Query returned more than one row
1063
1064 In this case, you should be using L</next> or L</find> instead, or if you really
1065 know what you are doing, use the L</rows> attribute to explicitly limit the size
1066 of the resultset.
1067
1068 This method will also throw an exception if it is called on a resultset prefetching
1069 has_many, as such a prefetch implies fetching multiple rows from the database in
1070 order to assemble the resulting object.
1071
1072 =back
1073
1074 =cut
1075
1076 sub single {
1077   my ($self, $where) = @_;
1078   if(@_ > 2) {
1079       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1080   }
1081
1082   my $attrs = { %{$self->_resolved_attrs} };
1083
1084   $self->throw_exception(
1085     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1086   ) if $attrs->{collapse};
1087
1088   if ($where) {
1089     if (defined $attrs->{where}) {
1090       $attrs->{where} = {
1091         '-and' =>
1092             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1093                $where, delete $attrs->{where} ]
1094       };
1095     } else {
1096       $attrs->{where} = $where;
1097     }
1098   }
1099
1100   my $data = [ $self->result_source->storage->select_single(
1101     $attrs->{from}, $attrs->{select},
1102     $attrs->{where}, $attrs
1103   )];
1104
1105   return undef unless @$data;
1106   $self->{_stashed_rows} = [ $data ];
1107   $self->_construct_results->[0];
1108 }
1109
1110 =head2 get_column
1111
1112 =over 4
1113
1114 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1115
1116 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1117
1118 =back
1119
1120   my $max_length = $rs->get_column('length')->max;
1121
1122 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1123
1124 =cut
1125
1126 sub get_column {
1127   my ($self, $column) = @_;
1128   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1129   return $new;
1130 }
1131
1132 =head2 search_like
1133
1134 =over 4
1135
1136 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1137
1138 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1139
1140 =back
1141
1142   # WHERE title LIKE '%blue%'
1143   $cd_rs = $rs->search_like({ title => '%blue%'});
1144
1145 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1146 that this is simply a convenience method retained for ex Class::DBI users.
1147 You most likely want to use L</search> with specific operators.
1148
1149 For more information, see L<DBIx::Class::Manual::Cookbook>.
1150
1151 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1152 instead. An example conversion is:
1153
1154   ->search_like({ foo => 'bar' });
1155
1156   # Becomes
1157
1158   ->search({ foo => { like => 'bar' } });
1159
1160 =cut
1161
1162 sub search_like {
1163   my $class = shift;
1164   carp_unique (
1165     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1166    .' Instead use ->search({ x => { -like => "y%" } })'
1167    .' (note the outer pair of {}s - they are important!)'
1168   );
1169   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1170   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1171   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1172   return $class->search($query, { %$attrs });
1173 }
1174
1175 =head2 slice
1176
1177 =over 4
1178
1179 =item Arguments: $first, $last
1180
1181 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1182
1183 =back
1184
1185 Returns a resultset or object list representing a subset of elements from the
1186 resultset slice is called on. Indexes are from 0, i.e., to get the first
1187 three records, call:
1188
1189   my ($one, $two, $three) = $rs->slice(0, 2);
1190
1191 =cut
1192
1193 sub slice {
1194   my ($self, $min, $max) = @_;
1195   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1196   $attrs->{offset} = $self->{attrs}{offset} || 0;
1197   $attrs->{offset} += $min;
1198   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1199   return $self->search(undef, $attrs);
1200 }
1201
1202 =head2 next
1203
1204 =over 4
1205
1206 =item Arguments: none
1207
1208 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1209
1210 =back
1211
1212 Returns the next element in the resultset (C<undef> is there is none).
1213
1214 Can be used to efficiently iterate over records in the resultset:
1215
1216   my $rs = $schema->resultset('CD')->search;
1217   while (my $cd = $rs->next) {
1218     print $cd->title;
1219   }
1220
1221 Note that you need to store the resultset object, and call C<next> on it.
1222 Calling C<< resultset('Table')->next >> repeatedly will always return the
1223 first record from the resultset.
1224
1225 =cut
1226
1227 sub next {
1228   my ($self) = @_;
1229
1230   if (my $cache = $self->get_cache) {
1231     $self->{all_cache_position} ||= 0;
1232     return $cache->[$self->{all_cache_position}++];
1233   }
1234
1235   if ($self->{attrs}{cache}) {
1236     delete $self->{pager};
1237     $self->{all_cache_position} = 1;
1238     return ($self->all)[0];
1239   }
1240
1241   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1242
1243   $self->{_stashed_results} = $self->_construct_results
1244     or return undef;
1245
1246   return shift @{$self->{_stashed_results}};
1247 }
1248
1249 # Constructs as many results as it can in one pass while respecting
1250 # cursor laziness. Several modes of operation:
1251 #
1252 # * Always builds everything present in @{$self->{_stashed_rows}}
1253 # * If called with $fetch_all true - pulls everything off the cursor and
1254 #   builds all result structures (or objects) in one pass
1255 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1256 #   and if the resultset is ordered properly by the left side:
1257 #   * Fetches stuff off the cursor until the "master object" changes,
1258 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1259 #   OR
1260 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1261 #     was requested (there is no other way to collapse except for an
1262 #     eager cursor)
1263 # * If no collapse is requested - just get the next row, construct and
1264 #   return
1265 sub _construct_results {
1266   my ($self, $fetch_all) = @_;
1267
1268   my $rsrc = $self->result_source;
1269   my $attrs = $self->_resolved_attrs;
1270
1271   if (
1272     ! $fetch_all
1273       and
1274     ! $attrs->{order_by}
1275       and
1276     $attrs->{collapse}
1277       and
1278     my @pcols = $rsrc->primary_columns
1279   ) {
1280     # default order for collapsing unless the user asked for something
1281     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1282     $attrs->{_ordered_for_collapse} = 1;
1283     $attrs->{_order_is_artificial} = 1;
1284   }
1285
1286   # this will be used as both initial raw-row collector AND as a RV of
1287   # _construct_results. Not regrowing the array twice matters a lot...
1288   # a surprising amount actually
1289   my $rows = delete $self->{_stashed_rows};
1290
1291   my $cursor; # we may not need one at all
1292
1293   my $did_fetch_all = $fetch_all;
1294
1295   if ($fetch_all) {
1296     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1297     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1298   }
1299   elsif( $attrs->{collapse} ) {
1300
1301     # a cursor will need to be closed over in case of collapse
1302     $cursor = $self->cursor;
1303
1304     $attrs->{_ordered_for_collapse} = (
1305       (
1306         $attrs->{order_by}
1307           and
1308         $rsrc->schema
1309               ->storage
1310                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1311       ) ? 1 : 0
1312     ) unless defined $attrs->{_ordered_for_collapse};
1313
1314     if (! $attrs->{_ordered_for_collapse}) {
1315       $did_fetch_all = 1;
1316
1317       # instead of looping over ->next, use ->all in stealth mode
1318       # *without* calling a ->reset afterwards
1319       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1320       if (! $cursor->{_done}) {
1321         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1322         $cursor->{_done} = 1;
1323       }
1324     }
1325   }
1326
1327   if (! $did_fetch_all and ! @{$rows||[]} ) {
1328     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1329     $cursor ||= $self->cursor;
1330     if (scalar (my @r = $cursor->next) ) {
1331       $rows = [ \@r ];
1332     }
1333   }
1334
1335   return undef unless @{$rows||[]};
1336
1337   # sanity check - people are too clever for their own good
1338   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1339
1340     my $multiplied_selectors;
1341     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1342       if (
1343         $aliastypes->{multiplying}{$sel_alias}
1344           or
1345         $aliastypes->{premultiplied}{$sel_alias}
1346       ) {
1347         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1348       }
1349     }
1350
1351     for my $i (0 .. $#{$attrs->{as}} ) {
1352       my $sel = $attrs->{select}[$i];
1353
1354       if (ref $sel eq 'SCALAR') {
1355         $sel = $$sel;
1356       }
1357       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1358         $sel = $$sel->[0];
1359       }
1360
1361       $self->throw_exception(
1362         'Result collapse not possible - selection from a has_many source redirected to the main object'
1363       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1364     }
1365   }
1366
1367   # hotspot - skip the setter
1368   my $res_class = $self->_result_class;
1369
1370   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1371     $res_class->can ('inflate_result')
1372       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1373   };
1374
1375   my $infmap = $attrs->{as};
1376
1377   $self->{_result_inflator}{is_core_row} = ( (
1378     $inflator_cref
1379       ==
1380     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1381   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1382
1383   $self->{_result_inflator}{is_hri} = ( (
1384     ! $self->{_result_inflator}{is_core_row}
1385       and
1386     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1387   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1388
1389
1390   if ($attrs->{_simple_passthrough_construction}) {
1391     # construct a much simpler array->hash folder for the one-table HRI cases right here
1392     if ($self->{_result_inflator}{is_hri}) {
1393       for my $r (@$rows) {
1394         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1395       }
1396     }
1397     # FIXME SUBOPTIMAL this is a very very very hot spot
1398     # while rather optimal we can *still* do much better, by
1399     # building a smarter Row::inflate_result(), and
1400     # switch to feeding it data via a much leaner interface
1401     #
1402     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1403     # this particular resultset size
1404     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1405       for my $r (@$rows) {
1406         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1407       }
1408     }
1409     else {
1410       eval sprintf (
1411         ( $self->{_result_inflator}{is_core_row}
1412           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1413           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1414           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1415         ),
1416         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1417       );
1418     }
1419   }
1420   else {
1421     my $parser_type =
1422         $self->{_result_inflator}{is_hri}       ? 'hri'
1423       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1424       :                                           'classic_nonpruning'
1425     ;
1426
1427     # $args and $attrs to _mk_row_parser are separated to delineate what is
1428     # core collapser stuff and what is dbic $rs specific
1429     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1430       eval => 1,
1431       inflate_map => $infmap,
1432       collapse => $attrs->{collapse},
1433       premultiplied => $attrs->{_main_source_premultiplied},
1434       hri_style => $self->{_result_inflator}{is_hri},
1435       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1436     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1437
1438     # column_info metadata historically hasn't been too reliable.
1439     # We need to start fixing this somehow (the collapse resolver
1440     # can't work without it). Add an explicit check for the *main*
1441     # result, hopefully this will gradually weed out such errors
1442     #
1443     # FIXME - this is a temporary kludge that reduces performance
1444     # It is however necessary for the time being
1445     my ($unrolled_non_null_cols_to_check, $err);
1446
1447     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1448
1449       $err =
1450         'Collapse aborted due to invalid ResultSource metadata - the following '
1451       . 'selections are declared non-nullable but NULLs were retrieved: '
1452       ;
1453
1454       my @violating_idx;
1455       COL: for my $i (@$check_non_null_cols) {
1456         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1457       }
1458
1459       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1460         if @violating_idx;
1461
1462       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1463
1464       utf8::upgrade($unrolled_non_null_cols_to_check)
1465         if DBIx::Class::_ENV_::STRESSTEST_UTF8_UPGRADE_GENERATED_COLLAPSER_SOURCE;
1466     }
1467
1468     my $next_cref =
1469       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1470     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1471 sub {
1472   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1473   my @r = $cursor->next or return;
1474   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1475     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1476   }
1477   \@r
1478 }
1479 EOS
1480     : sub {
1481         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1482         my @r = $cursor->next or return;
1483         \@r
1484       }
1485     ;
1486
1487     $self->{_row_parser}{$parser_type}{cref}->(
1488       $rows,
1489       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1490     );
1491
1492     # simple in-place substitution, does not regrow $rows
1493     if ($self->{_result_inflator}{is_core_row}) {
1494       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1495     }
1496     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1497     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1498       # the inflator may be a multiplier/reductor - put it in list ctx
1499       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1500     }
1501   }
1502
1503   # The @$rows check seems odd at first - why wouldn't we want to warn
1504   # regardless? The issue is things like find() etc, where the user
1505   # *knows* only one result will come back. In these cases the ->all
1506   # is not a pessimization, but rather something we actually want
1507   carp_unique(
1508     'Unable to properly collapse has_many results in iterator mode due '
1509   . 'to order criteria - performed an eager cursor slurp underneath. '
1510   . 'Consider using ->all() instead'
1511   ) if ( ! $fetch_all and @$rows > 1 );
1512
1513   return $rows;
1514 }
1515
1516 =head2 result_source
1517
1518 =over 4
1519
1520 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1521
1522 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1523
1524 =back
1525
1526 An accessor for the primary ResultSource object from which this ResultSet
1527 is derived.
1528
1529 =head2 result_class
1530
1531 =over 4
1532
1533 =item Arguments: $result_class?
1534
1535 =item Return Value: $result_class
1536
1537 =back
1538
1539 An accessor for the class to use when creating result objects. Defaults to
1540 C<< result_source->result_class >> - which in most cases is the name of the
1541 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1542
1543 Note that changing the result_class will also remove any components
1544 that were originally loaded in the source class via
1545 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1546 Any overloaded methods in the original source class will not run.
1547
1548 =cut
1549
1550 sub result_class {
1551   my ($self, $result_class) = @_;
1552   if ($result_class) {
1553
1554     # don't fire this for an object
1555     $self->ensure_class_loaded($result_class)
1556       unless ref($result_class);
1557
1558     if ($self->get_cache) {
1559       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1560     }
1561     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1562     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1563       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1564     }
1565
1566     $self->_result_class($result_class);
1567
1568     delete $self->{_result_inflator};
1569   }
1570   $self->_result_class;
1571 }
1572
1573 =head2 count
1574
1575 =over 4
1576
1577 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1578
1579 =item Return Value: $count
1580
1581 =back
1582
1583 Performs an SQL C<COUNT> with the same query as the resultset was built
1584 with to find the number of elements. Passing arguments is equivalent to
1585 C<< $rs->search ($cond, \%attrs)->count >>
1586
1587 =cut
1588
1589 sub count {
1590   my $self = shift;
1591   return $self->search(@_)->count if @_ and defined $_[0];
1592   return scalar @{ $self->get_cache } if $self->get_cache;
1593
1594   my $attrs = { %{ $self->_resolved_attrs } };
1595
1596   # this is a little optimization - it is faster to do the limit
1597   # adjustments in software, instead of a subquery
1598   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1599
1600   my $crs;
1601   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1602     $crs = $self->_count_subq_rs ($attrs);
1603   }
1604   else {
1605     $crs = $self->_count_rs ($attrs);
1606   }
1607   my $count = $crs->next;
1608
1609   $count -= $offset if $offset;
1610   $count = $rows if $rows and $rows < $count;
1611   $count = 0 if ($count < 0);
1612
1613   return $count;
1614 }
1615
1616 =head2 count_rs
1617
1618 =over 4
1619
1620 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1621
1622 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1623
1624 =back
1625
1626 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1627 This can be very handy for subqueries:
1628
1629   ->search( { amount => $some_rs->count_rs->as_query } )
1630
1631 As with regular resultsets the SQL query will be executed only after
1632 the resultset is accessed via L</next> or L</all>. That would return
1633 the same single value obtainable via L</count>.
1634
1635 =cut
1636
1637 sub count_rs {
1638   my $self = shift;
1639   return $self->search(@_)->count_rs if @_;
1640
1641   # this may look like a lack of abstraction (count() does about the same)
1642   # but in fact an _rs *must* use a subquery for the limits, as the
1643   # software based limiting can not be ported if this $rs is to be used
1644   # in a subquery itself (i.e. ->as_query)
1645   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1646     return $self->_count_subq_rs($self->{_attrs});
1647   }
1648   else {
1649     return $self->_count_rs($self->{_attrs});
1650   }
1651 }
1652
1653 #
1654 # returns a ResultSetColumn object tied to the count query
1655 #
1656 sub _count_rs {
1657   my ($self, $attrs) = @_;
1658
1659   my $rsrc = $self->result_source;
1660
1661   my $tmp_attrs = { %$attrs };
1662   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1663   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1664
1665   # overwrite the selector (supplied by the storage)
1666   $rsrc->resultset_class->new($rsrc, {
1667     %$tmp_attrs,
1668     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1669     as => 'count',
1670   })->get_column ('count');
1671 }
1672
1673 #
1674 # same as above but uses a subquery
1675 #
1676 sub _count_subq_rs {
1677   my ($self, $attrs) = @_;
1678
1679   my $rsrc = $self->result_source;
1680
1681   my $sub_attrs = { %$attrs };
1682   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1683   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1684
1685   # if we multi-prefetch we group_by something unique, as this is what we would
1686   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1687   if ( $attrs->{collapse}  ) {
1688     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1689       $rsrc->_identifying_column_set || $self->throw_exception(
1690         'Unable to construct a unique group_by criteria properly collapsing the '
1691       . 'has_many prefetch before count()'
1692       );
1693     } ]
1694   }
1695
1696   # Calculate subquery selector
1697   if (my $g = $sub_attrs->{group_by}) {
1698
1699     my $sql_maker = $rsrc->storage->sql_maker;
1700
1701     # necessary as the group_by may refer to aliased functions
1702     my $sel_index;
1703     for my $sel (@{$attrs->{select}}) {
1704       $sel_index->{$sel->{-as}} = $sel
1705         if (ref $sel eq 'HASH' and $sel->{-as});
1706     }
1707
1708     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1709     # also look for named aggregates referred in the having clause
1710     # having often contains scalarrefs - thus parse it out entirely
1711     my @parts = @$g;
1712     if ($attrs->{having}) {
1713       local $sql_maker->{having_bind};
1714       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1715       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1716       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1717         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1718         # if we don't unset it we screw up retarded but unfortunately working
1719         # 'MAX(foo.bar)' => { '>', 3 }
1720         $sql_maker->{name_sep} = '';
1721       }
1722
1723       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1724
1725       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1726       my %seen_having;
1727
1728       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1729       # and if all fails for an utterly naive quoted scalar-with-function
1730       while ($having_sql =~ /
1731         $rquote $sep $lquote (.+?) $rquote
1732           |
1733         [\s,] \w+ \. (\w+) [\s,]
1734           |
1735         [\s,] $lquote (.+?) $rquote [\s,]
1736       /gx) {
1737         my $part = $1 || $2 || $3;  # one of them matched if we got here
1738         unless ($seen_having{$part}++) {
1739           push @parts, $part;
1740         }
1741       }
1742     }
1743
1744     for (@parts) {
1745       my $colpiece = $sel_index->{$_} || $_;
1746
1747       # unqualify join-based group_by's. Arcane but possible query
1748       # also horrible horrible hack to alias a column (not a func.)
1749       # (probably need to introduce SQLA syntax)
1750       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1751         my $as = $colpiece;
1752         $as =~ s/\./__/;
1753         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1754       }
1755       push @{$sub_attrs->{select}}, $colpiece;
1756     }
1757   }
1758   else {
1759     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1760     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1761   }
1762
1763   return $rsrc->resultset_class
1764                ->new ($rsrc, $sub_attrs)
1765                 ->as_subselect_rs
1766                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1767                   ->get_column ('count');
1768 }
1769
1770
1771 =head2 count_literal
1772
1773 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1774 should only be used in that context. See L</search_literal> for further info.
1775
1776 =over 4
1777
1778 =item Arguments: $sql_fragment, @standalone_bind_values
1779
1780 =item Return Value: $count
1781
1782 =back
1783
1784 Counts the results in a literal query. Equivalent to calling L</search_literal>
1785 with the passed arguments, then L</count>.
1786
1787 =cut
1788
1789 sub count_literal { shift->search_literal(@_)->count; }
1790
1791 =head2 all
1792
1793 =over 4
1794
1795 =item Arguments: none
1796
1797 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1798
1799 =back
1800
1801 Returns all elements in the resultset.
1802
1803 =cut
1804
1805 sub all {
1806   my $self = shift;
1807   if(@_) {
1808     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1809   }
1810
1811   delete @{$self}{qw/_stashed_rows _stashed_results/};
1812
1813   if (my $c = $self->get_cache) {
1814     return @$c;
1815   }
1816
1817   $self->cursor->reset;
1818
1819   my $objs = $self->_construct_results('fetch_all') || [];
1820
1821   $self->set_cache($objs) if $self->{attrs}{cache};
1822
1823   return @$objs;
1824 }
1825
1826 =head2 reset
1827
1828 =over 4
1829
1830 =item Arguments: none
1831
1832 =item Return Value: $self
1833
1834 =back
1835
1836 Resets the resultset's cursor, so you can iterate through the elements again.
1837 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1838 another query.
1839
1840 =cut
1841
1842 sub reset {
1843   my ($self) = @_;
1844
1845   delete @{$self}{qw/_stashed_rows _stashed_results/};
1846   $self->{all_cache_position} = 0;
1847   $self->cursor->reset;
1848   return $self;
1849 }
1850
1851 =head2 first
1852
1853 =over 4
1854
1855 =item Arguments: none
1856
1857 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1858
1859 =back
1860
1861 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1862 an object for the first result (or C<undef> if the resultset is empty).
1863
1864 =cut
1865
1866 sub first {
1867   return $_[0]->reset->next;
1868 }
1869
1870
1871 # _rs_update_delete
1872 #
1873 # Determines whether and what type of subquery is required for the $rs operation.
1874 # If grouping is necessary either supplies its own, or verifies the current one
1875 # After all is done delegates to the proper storage method.
1876
1877 sub _rs_update_delete {
1878   my ($self, $op, $values) = @_;
1879
1880   my $rsrc = $self->result_source;
1881   my $storage = $rsrc->schema->storage;
1882
1883   my $attrs = { %{$self->_resolved_attrs} };
1884
1885   my $join_classifications;
1886   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1887
1888   # do we need a subquery for any reason?
1889   my $needs_subq = (
1890     defined $existing_group_by
1891       or
1892     # if {from} is unparseable wrap a subq
1893     ref($attrs->{from}) ne 'ARRAY'
1894       or
1895     # limits call for a subq
1896     $self->_has_resolved_attr(qw/rows offset/)
1897   );
1898
1899   # simplify the joinmap, so we can further decide if a subq is necessary
1900   if (!$needs_subq and @{$attrs->{from}} > 1) {
1901
1902     ($attrs->{from}, $join_classifications) =
1903       $storage->_prune_unused_joins ($attrs);
1904
1905     # any non-pruneable non-local restricting joins imply subq
1906     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1907   }
1908
1909   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1910   $needs_subq ||= (
1911     (ref $attrs->{from}[0]) ne 'HASH'
1912       or
1913     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1914   );
1915
1916   my ($cond, $guard);
1917   # do we need anything like a subquery?
1918   if (! $needs_subq) {
1919     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1920     # a condition containing 'me' or other table prefixes will not work
1921     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1922     $cond = do {
1923       my $sqla = $rsrc->storage->sql_maker;
1924       local $sqla->{_dequalify_idents} = 1;
1925       \[ $sqla->_recurse_where($self->{cond}) ];
1926     };
1927   }
1928   else {
1929     # we got this far - means it is time to wrap a subquery
1930     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1931       sprintf(
1932         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1933         $op,
1934         $rsrc->source_name,
1935       )
1936     );
1937
1938     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1939     delete $attrs->{$_} for qw/select as collapse/;
1940     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1941
1942     # this will be consumed by the pruner waaaaay down the stack
1943     $attrs->{_force_prune_multiplying_joins} = 1;
1944
1945     my $subrs = (ref $self)->new($rsrc, $attrs);
1946
1947     if (@$idcols == 1) {
1948       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1949     }
1950     elsif ($storage->_use_multicolumn_in) {
1951       # no syntax for calling this properly yet
1952       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1953       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1954         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1955         $subrs->as_query
1956       ),
1957     }
1958     else {
1959       # if all else fails - get all primary keys and operate over a ORed set
1960       # wrap in a transaction for consistency
1961       # this is where the group_by/multiplication starts to matter
1962       if (
1963         $existing_group_by
1964           or
1965         # we do not need to check pre-multipliers, since if the premulti is there, its
1966         # parent (who is multi) will be there too
1967         keys %{ $join_classifications->{multiplying} || {} }
1968       ) {
1969         # make sure if there is a supplied group_by it matches the columns compiled above
1970         # perfectly. Anything else can not be sanely executed on most databases so croak
1971         # right then and there
1972         if ($existing_group_by) {
1973           my @current_group_by = map
1974             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1975             @$existing_group_by
1976           ;
1977
1978           if (
1979             join ("\x00", sort @current_group_by)
1980               ne
1981             join ("\x00", sort @{$attrs->{columns}} )
1982           ) {
1983             $self->throw_exception (
1984               "You have just attempted a $op operation on a resultset which does group_by"
1985               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1986               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1987               . ' kind of queries. Please retry the operation with a modified group_by or'
1988               . ' without using one at all.'
1989             );
1990           }
1991         }
1992
1993         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1994       }
1995
1996       $guard = $storage->txn_scope_guard;
1997
1998       for my $row ($subrs->cursor->all) {
1999         push @$cond, { map
2000           { $idcols->[$_] => $row->[$_] }
2001           (0 .. $#$idcols)
2002         };
2003       }
2004     }
2005   }
2006
2007   my $res = $cond ? $storage->$op (
2008     $rsrc,
2009     $op eq 'update' ? $values : (),
2010     $cond,
2011   ) : '0E0';
2012
2013   $guard->commit if $guard;
2014
2015   return $res;
2016 }
2017
2018 =head2 update
2019
2020 =over 4
2021
2022 =item Arguments: \%values
2023
2024 =item Return Value: $underlying_storage_rv
2025
2026 =back
2027
2028 Sets the specified columns in the resultset to the supplied values in a
2029 single query. Note that this will not run any accessor/set_column/update
2030 triggers, nor will it update any result object instances derived from this
2031 resultset (this includes the contents of the L<resultset cache|/set_cache>
2032 if any). See L</update_all> if you need to execute any on-update
2033 triggers or cascades defined either by you or a
2034 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2035
2036 The return value is a pass through of what the underlying
2037 storage backend returned, and may vary. See L<DBI/execute> for the most
2038 common case.
2039
2040 =head3 CAVEAT
2041
2042 Note that L</update> does not process/deflate any of the values passed in.
2043 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2044 ensure manually that any value passed to this method will stringify to
2045 something the RDBMS knows how to deal with. A notable example is the
2046 handling of L<DateTime> objects, for more info see:
2047 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2048
2049 =cut
2050
2051 sub update {
2052   my ($self, $values) = @_;
2053   $self->throw_exception('Values for update must be a hash')
2054     unless ref $values eq 'HASH';
2055
2056   return $self->_rs_update_delete ('update', $values);
2057 }
2058
2059 =head2 update_all
2060
2061 =over 4
2062
2063 =item Arguments: \%values
2064
2065 =item Return Value: 1
2066
2067 =back
2068
2069 Fetches all objects and updates them one at a time via
2070 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2071 triggers, while L</update> will not.
2072
2073 =cut
2074
2075 sub update_all {
2076   my ($self, $values) = @_;
2077   $self->throw_exception('Values for update_all must be a hash')
2078     unless ref $values eq 'HASH';
2079
2080   my $guard = $self->result_source->schema->txn_scope_guard;
2081   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2082   $guard->commit;
2083   return 1;
2084 }
2085
2086 =head2 delete
2087
2088 =over 4
2089
2090 =item Arguments: none
2091
2092 =item Return Value: $underlying_storage_rv
2093
2094 =back
2095
2096 Deletes the rows matching this resultset in a single query. Note that this
2097 will not run any delete triggers, nor will it alter the
2098 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2099 derived from this resultset (this includes the contents of the
2100 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2101 execute any on-delete triggers or cascades defined either by you or a
2102 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2103
2104 The return value is a pass through of what the underlying storage backend
2105 returned, and may vary. See L<DBI/execute> for the most common case.
2106
2107 =cut
2108
2109 sub delete {
2110   my $self = shift;
2111   $self->throw_exception('delete does not accept any arguments')
2112     if @_;
2113
2114   return $self->_rs_update_delete ('delete');
2115 }
2116
2117 =head2 delete_all
2118
2119 =over 4
2120
2121 =item Arguments: none
2122
2123 =item Return Value: 1
2124
2125 =back
2126
2127 Fetches all objects and deletes them one at a time via
2128 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2129 triggers, while L</delete> will not.
2130
2131 =cut
2132
2133 sub delete_all {
2134   my $self = shift;
2135   $self->throw_exception('delete_all does not accept any arguments')
2136     if @_;
2137
2138   my $guard = $self->result_source->schema->txn_scope_guard;
2139   $_->delete for $self->all;
2140   $guard->commit;
2141   return 1;
2142 }
2143
2144 =head2 populate
2145
2146 =over 4
2147
2148 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2149
2150 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2151
2152 =back
2153
2154 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2155 arrayrefs.
2156
2157 =over
2158
2159 =item NOTE
2160
2161 The context of this method call has an important effect on what is
2162 submitted to storage. In void context data is fed directly to fastpath
2163 insertion routines provided by the underlying storage (most often
2164 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2165 L<insert|DBIx::Class::Row/insert> calls on the
2166 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2167 augmentation of these methods provided by components. For example if you
2168 are using something like L<DBIx::Class::UUIDColumns> to create primary
2169 keys for you, you will find that your PKs are empty.  In this case you
2170 will have to explicitly force scalar or list context in order to create
2171 those values.
2172
2173 =back
2174
2175 In non-void (scalar or list) context, this method is simply a wrapper
2176 for L</create>. Depending on list or scalar context either a list of
2177 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2178 containing these objects is returned.
2179
2180 When supplying data in "arrayref of arrayrefs" invocation style, the
2181 first element should be a list of column names and each subsequent
2182 element should be a data value in the earlier specified column order.
2183 For example:
2184
2185   $schema->resultset("Artist")->populate([
2186     [ qw( artistid name ) ],
2187     [ 100, 'A Formally Unknown Singer' ],
2188     [ 101, 'A singer that jumped the shark two albums ago' ],
2189     [ 102, 'An actually cool singer' ],
2190   ]);
2191
2192 For the arrayref of hashrefs style each hashref should be a structure
2193 suitable for passing to L</create>. Multi-create is also permitted with
2194 this syntax.
2195
2196   $schema->resultset("Artist")->populate([
2197      { artistid => 4, name => 'Manufactured Crap', cds => [
2198         { title => 'My First CD', year => 2006 },
2199         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2200       ],
2201      },
2202      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2203         { title => 'My parents sold me to a record company', year => 2005 },
2204         { title => 'Why Am I So Ugly?', year => 2006 },
2205         { title => 'I Got Surgery and am now Popular', year => 2007 }
2206       ],
2207      },
2208   ]);
2209
2210 If you attempt a void-context multi-create as in the example above (each
2211 Artist also has the related list of CDs), and B<do not> supply the
2212 necessary autoinc foreign key information, this method will proxy to the
2213 less efficient L</create>, and then throw the Result objects away. In this
2214 case there are obviously no benefits to using this method over L</create>.
2215
2216 =cut
2217
2218 sub populate {
2219   my $self = shift;
2220
2221   # this is naive and just a quick check
2222   # the types will need to be checked more thoroughly when the
2223   # multi-source populate gets added
2224   my $data = (
2225     ref $_[0] eq 'ARRAY'
2226       and
2227     ( @{$_[0]} or return )
2228       and
2229     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2230       and
2231     $_[0]
2232   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2233
2234   # FIXME - no cref handling
2235   # At this point assume either hashes or arrays
2236
2237   if(defined wantarray) {
2238     my (@results, $guard);
2239
2240     if (ref $data->[0] eq 'ARRAY') {
2241       # column names only, nothing to do
2242       return if @$data == 1;
2243
2244       $guard = $self->result_source->schema->storage->txn_scope_guard
2245         if @$data > 2;
2246
2247       @results = map
2248         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2249         @{$data}[1 .. $#$data]
2250       ;
2251     }
2252     else {
2253
2254       $guard = $self->result_source->schema->storage->txn_scope_guard
2255         if @$data > 1;
2256
2257       @results = map { $self->new_result($_)->insert } @$data;
2258     }
2259
2260     $guard->commit if $guard;
2261     return wantarray ? @results : \@results;
2262   }
2263
2264   # we have to deal with *possibly incomplete* related data
2265   # this means we have to walk the data structure twice
2266   # whether we want this or not
2267   # jnap, I hate you ;)
2268   my $rsrc = $self->result_source;
2269   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2270
2271   my ($colinfo, $colnames, $slices_with_rels);
2272   my $data_start = 0;
2273
2274   DATA_SLICE:
2275   for my $i (0 .. $#$data) {
2276
2277     my $current_slice_seen_rel_infos;
2278
2279 ### Determine/Supplement collists
2280 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2281     if( ref $data->[$i] eq 'ARRAY' ) {
2282
2283       # positional(!) explicit column list
2284       if ($i == 0) {
2285         # column names only, nothing to do
2286         return if @$data == 1;
2287
2288         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2289           for 0 .. $#{$data->[0]};
2290
2291         $data_start = 1;
2292
2293         next DATA_SLICE;
2294       }
2295       else {
2296         for (values %$colinfo) {
2297           if ($_->{is_rel} ||= (
2298             $rel_info->{$_->{name}}
2299               and
2300             (
2301               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2302                 or
2303               ref $data->[$i][$_->{pos}] eq 'HASH'
2304                 or
2305               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2306             )
2307               and
2308             1
2309           )) {
2310
2311             # moar sanity check... sigh
2312             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2313               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2314                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2315                 return my $throwaway = $self->populate(@_);
2316               }
2317             }
2318
2319             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2320           }
2321         }
2322       }
2323
2324      if ($current_slice_seen_rel_infos) {
2325         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2326
2327         # this is needed further down to decide whether or not to fallback to create()
2328         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2329           for 0 .. $#$colnames;
2330       }
2331     }
2332     elsif( ref $data->[$i] eq 'HASH' ) {
2333
2334       for ( sort keys %{$data->[$i]} ) {
2335
2336         $colinfo->{$_} ||= do {
2337
2338           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2339             if $data_start; # it will be 0 on AoH, 1 on AoA
2340
2341           push @$colnames, $_;
2342
2343           # RV
2344           { pos => $#$colnames, name => $_ }
2345         };
2346
2347         if ($colinfo->{$_}{is_rel} ||= (
2348           $rel_info->{$_}
2349             and
2350           (
2351             ref $data->[$i]{$_} eq 'ARRAY'
2352               or
2353             ref $data->[$i]{$_} eq 'HASH'
2354               or
2355             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2356           )
2357             and
2358           1
2359         )) {
2360
2361           # moar sanity check... sigh
2362           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2363             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2364               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2365               return my $throwaway = $self->populate(@_);
2366             }
2367           }
2368
2369           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2370         }
2371       }
2372
2373       if ($current_slice_seen_rel_infos) {
2374         push @$slices_with_rels, $data->[$i];
2375
2376         # this is needed further down to decide whether or not to fallback to create()
2377         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2378           for keys %{$data->[$i]};
2379       }
2380     }
2381     else {
2382       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2383     }
2384
2385     if ( grep
2386       { $_->{attrs}{is_depends_on} }
2387       @{ $current_slice_seen_rel_infos || [] }
2388     ) {
2389       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2390       return my $throwaway = $self->populate(@_);
2391     }
2392   }
2393
2394   if( $slices_with_rels ) {
2395
2396     # need to exclude the rel "columns"
2397     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2398
2399     # extra sanity check - ensure the main source is in fact identifiable
2400     # the localizing of nullability is insane, but oh well... the use-case is legit
2401     my $ci = $rsrc->columns_info($colnames);
2402
2403     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2404       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2405
2406     unless( $rsrc->_identifying_column_set($ci) ) {
2407       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2408       return my $throwaway = $self->populate(@_);
2409     }
2410   }
2411
2412 ### inherit the data locked in the conditions of the resultset
2413   my ($rs_data) = $self->_merge_with_rscond({});
2414   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2415
2416   # if anything left - decompose rs_data
2417   my $rs_data_vals;
2418   if (keys %$rs_data) {
2419      push @$rs_data_vals, $rs_data->{$_}
2420       for sort keys %$rs_data;
2421   }
2422
2423 ### start work
2424   my $guard;
2425   $guard = $rsrc->schema->storage->txn_scope_guard
2426     if $slices_with_rels;
2427
2428 ### main source data
2429   # FIXME - need to switch entirely to a coderef-based thing,
2430   # so that large sets aren't copied several times... I think
2431   $rsrc->storage->_insert_bulk(
2432     $rsrc,
2433     [ @$colnames, sort keys %$rs_data ],
2434     [ map {
2435       ref $data->[$_] eq 'ARRAY'
2436       ? (
2437           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2438         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2439         :                     $data->[$_]
2440       )
2441       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2442     } $data_start .. $#$data ],
2443   );
2444
2445 ### do the children relationships
2446   if ( $slices_with_rels ) {
2447     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2448       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2449
2450     for my $sl (@$slices_with_rels) {
2451
2452       my ($main_proto, $main_proto_rs);
2453       for my $rel (@rels) {
2454         next unless defined $sl->{$rel};
2455
2456         $main_proto ||= {
2457           %$rs_data,
2458           (map { $_ => $sl->{$_} } @$colnames),
2459         };
2460
2461         unless (defined $colinfo->{$rel}{rs}) {
2462
2463           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2464
2465           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2466             rel_name => $rel,
2467             self_alias => "\xFE", # irrelevant
2468             foreign_alias => "\xFF", # irrelevant
2469           )->{identity_map} || {} } };
2470
2471         }
2472
2473         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2474           {
2475             $_ => { '=' =>
2476               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2477                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2478                  ->as_query
2479             }
2480           }
2481           keys %{$colinfo->{$rel}{fk_map}}
2482         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2483
2484         1;
2485       }
2486     }
2487   }
2488
2489   $guard->commit if $guard;
2490 }
2491
2492 =head2 pager
2493
2494 =over 4
2495
2496 =item Arguments: none
2497
2498 =item Return Value: L<$pager|Data::Page>
2499
2500 =back
2501
2502 Returns a L<Data::Page> object for the current resultset. Only makes
2503 sense for queries with a C<page> attribute.
2504
2505 To get the full count of entries for a paged resultset, call
2506 C<total_entries> on the L<Data::Page> object.
2507
2508 =cut
2509
2510 sub pager {
2511   my ($self) = @_;
2512
2513   return $self->{pager} if $self->{pager};
2514
2515   my $attrs = $self->{attrs};
2516   if (!defined $attrs->{page}) {
2517     $self->throw_exception("Can't create pager for non-paged rs");
2518   }
2519   elsif ($attrs->{page} <= 0) {
2520     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2521   }
2522   $attrs->{rows} ||= 10;
2523
2524   # throw away the paging flags and re-run the count (possibly
2525   # with a subselect) to get the real total count
2526   my $count_attrs = { %$attrs };
2527   delete @{$count_attrs}{qw/rows offset page pager/};
2528
2529   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2530
2531   require DBIx::Class::ResultSet::Pager;
2532   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2533     sub { $total_rs->count },  #lazy-get the total
2534     $attrs->{rows},
2535     $self->{attrs}{page},
2536   );
2537 }
2538
2539 =head2 page
2540
2541 =over 4
2542
2543 =item Arguments: $page_number
2544
2545 =item Return Value: L<$resultset|/search>
2546
2547 =back
2548
2549 Returns a resultset for the $page_number page of the resultset on which page
2550 is called, where each page contains a number of rows equal to the 'rows'
2551 attribute set on the resultset (10 by default).
2552
2553 =cut
2554
2555 sub page {
2556   my ($self, $page) = @_;
2557   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2558 }
2559
2560 =head2 new_result
2561
2562 =over 4
2563
2564 =item Arguments: \%col_data
2565
2566 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2567
2568 =back
2569
2570 Creates a new result object in the resultset's result class and returns
2571 it. The row is not inserted into the database at this point, call
2572 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2573 will tell you whether the result object has been inserted or not.
2574
2575 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2576
2577 =cut
2578
2579 sub new_result {
2580   my ($self, $values) = @_;
2581
2582   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2583     if @_ > 2;
2584
2585   $self->throw_exception( "Result object instantiation requires a hashref as argument" )
2586     unless (ref $values eq 'HASH');
2587
2588   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2589
2590   my $new = $self->result_class->new({
2591     %$merged_cond,
2592     ( @$cols_from_relations
2593       ? (-cols_from_relations => $cols_from_relations)
2594       : ()
2595     ),
2596     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2597   });
2598
2599   if (
2600     reftype($new) eq 'HASH'
2601       and
2602     ! keys %$new
2603       and
2604     blessed($new)
2605   ) {
2606     carp_unique (sprintf (
2607       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2608       $self->result_class,
2609     ));
2610   }
2611
2612   $new;
2613 }
2614
2615 # _merge_with_rscond
2616 #
2617 # Takes a simple hash of K/V data and returns its copy merged with the
2618 # condition already present on the resultset. Additionally returns an
2619 # arrayref of value/condition names, which were inferred from related
2620 # objects (this is needed for in-memory related objects)
2621 sub _merge_with_rscond {
2622   my ($self, $data) = @_;
2623
2624   my ($implied_data, @cols_from_relations);
2625
2626   my $alias = $self->{attrs}{alias};
2627
2628   if (! defined $self->{cond}) {
2629     # just massage $data below
2630   }
2631   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2632     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2633     @cols_from_relations = keys %{ $implied_data || {} };
2634   }
2635   else {
2636     my $eqs = $self->result_source->schema->storage->_extract_fixed_condition_columns($self->{cond}, 'consider_nulls');
2637     $implied_data = { map {
2638       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2639     } keys %$eqs };
2640   }
2641
2642   return (
2643     { map
2644       { %{ $self->_remove_alias($_, $alias) } }
2645       # precedence must be given to passed values over values inherited from
2646       # the cond, so the order here is important.
2647       ( $implied_data||(), $data)
2648     },
2649     \@cols_from_relations
2650   );
2651 }
2652
2653 # _has_resolved_attr
2654 #
2655 # determines if the resultset defines at least one
2656 # of the attributes supplied
2657 #
2658 # used to determine if a subquery is necessary
2659 #
2660 # supports some virtual attributes:
2661 #   -join
2662 #     This will scan for any joins being present on the resultset.
2663 #     It is not a mere key-search but a deep inspection of {from}
2664 #
2665
2666 sub _has_resolved_attr {
2667   my ($self, @attr_names) = @_;
2668
2669   my $attrs = $self->_resolved_attrs;
2670
2671   my %extra_checks;
2672
2673   for my $n (@attr_names) {
2674     if (grep { $n eq $_ } (qw/-join/) ) {
2675       $extra_checks{$n}++;
2676       next;
2677     }
2678
2679     my $attr =  $attrs->{$n};
2680
2681     next if not defined $attr;
2682
2683     if (ref $attr eq 'HASH') {
2684       return 1 if keys %$attr;
2685     }
2686     elsif (ref $attr eq 'ARRAY') {
2687       return 1 if @$attr;
2688     }
2689     else {
2690       return 1 if $attr;
2691     }
2692   }
2693
2694   # a resolved join is expressed as a multi-level from
2695   return 1 if (
2696     $extra_checks{-join}
2697       and
2698     ref $attrs->{from} eq 'ARRAY'
2699       and
2700     @{$attrs->{from}} > 1
2701   );
2702
2703   return 0;
2704 }
2705
2706 # _remove_alias
2707 #
2708 # Remove the specified alias from the specified query hash. A copy is made so
2709 # the original query is not modified.
2710
2711 sub _remove_alias {
2712   my ($self, $query, $alias) = @_;
2713
2714   my %orig = %{ $query || {} };
2715   my %unaliased;
2716
2717   foreach my $key (keys %orig) {
2718     if ($key !~ /\./) {
2719       $unaliased{$key} = $orig{$key};
2720       next;
2721     }
2722     $unaliased{$1} = $orig{$key}
2723       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2724   }
2725
2726   return \%unaliased;
2727 }
2728
2729 =head2 as_query
2730
2731 =over 4
2732
2733 =item Arguments: none
2734
2735 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2736
2737 =back
2738
2739 Returns the SQL query and bind vars associated with the invocant.
2740
2741 This is generally used as the RHS for a subquery.
2742
2743 =cut
2744
2745 sub as_query {
2746   my $self = shift;
2747
2748   my $attrs = { %{ $self->_resolved_attrs } };
2749
2750   my $aq = $self->result_source->storage->_select_args_to_query (
2751     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2752   );
2753
2754   $aq;
2755 }
2756
2757 =head2 find_or_new
2758
2759 =over 4
2760
2761 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2762
2763 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2764
2765 =back
2766
2767   my $artist = $schema->resultset('Artist')->find_or_new(
2768     { artist => 'fred' }, { key => 'artists' });
2769
2770   $cd->cd_to_producer->find_or_new({ producer => $producer },
2771                                    { key => 'primary' });
2772
2773 Find an existing record from this resultset using L</find>. if none exists,
2774 instantiate a new result object and return it. The object will not be saved
2775 into your storage until you call L<DBIx::Class::Row/insert> on it.
2776
2777 You most likely want this method when looking for existing rows using a unique
2778 constraint that is not the primary key, or looking for related rows.
2779
2780 If you want objects to be saved immediately, use L</find_or_create> instead.
2781
2782 B<Note>: Make sure to read the documentation of L</find> and understand the
2783 significance of the C<key> attribute, as its lack may skew your search, and
2784 subsequently result in spurious new objects.
2785
2786 B<Note>: Take care when using C<find_or_new> with a table having
2787 columns with default values that you intend to be automatically
2788 supplied by the database (e.g. an auto_increment primary key column).
2789 In normal usage, the value of such columns should NOT be included at
2790 all in the call to C<find_or_new>, even when set to C<undef>.
2791
2792 =cut
2793
2794 sub find_or_new {
2795   my $self     = shift;
2796   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2797   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2798   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2799     return $row;
2800   }
2801   return $self->new_result($hash);
2802 }
2803
2804 =head2 create
2805
2806 =over 4
2807
2808 =item Arguments: \%col_data
2809
2810 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2811
2812 =back
2813
2814 Attempt to create a single new row or a row with multiple related rows
2815 in the table represented by the resultset (and related tables). This
2816 will not check for duplicate rows before inserting, use
2817 L</find_or_create> to do that.
2818
2819 To create one row for this resultset, pass a hashref of key/value
2820 pairs representing the columns of the table and the values you wish to
2821 store. If the appropriate relationships are set up, foreign key fields
2822 can also be passed an object representing the foreign row, and the
2823 value will be set to its primary key.
2824
2825 To create related objects, pass a hashref of related-object column values
2826 B<keyed on the relationship name>. If the relationship is of type C<multi>
2827 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2828 The process will correctly identify columns holding foreign keys, and will
2829 transparently populate them from the keys of the corresponding relation.
2830 This can be applied recursively, and will work correctly for a structure
2831 with an arbitrary depth and width, as long as the relationships actually
2832 exists and the correct column data has been supplied.
2833
2834 Instead of hashrefs of plain related data (key/value pairs), you may
2835 also pass new or inserted objects. New objects (not inserted yet, see
2836 L</new_result>), will be inserted into their appropriate tables.
2837
2838 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2839
2840 Example of creating a new row.
2841
2842   $person_rs->create({
2843     name=>"Some Person",
2844     email=>"somebody@someplace.com"
2845   });
2846
2847 Example of creating a new row and also creating rows in a related C<has_many>
2848 or C<has_one> resultset.  Note Arrayref.
2849
2850   $artist_rs->create(
2851      { artistid => 4, name => 'Manufactured Crap', cds => [
2852         { title => 'My First CD', year => 2006 },
2853         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2854       ],
2855      },
2856   );
2857
2858 Example of creating a new row and also creating a row in a related
2859 C<belongs_to> resultset. Note Hashref.
2860
2861   $cd_rs->create({
2862     title=>"Music for Silly Walks",
2863     year=>2000,
2864     artist => {
2865       name=>"Silly Musician",
2866     }
2867   });
2868
2869 =over
2870
2871 =item WARNING
2872
2873 When subclassing ResultSet never attempt to override this method. Since
2874 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2875 lot of the internals simply never call it, so your override will be
2876 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2877 or L<DBIx::Class::Row/insert> depending on how early in the
2878 L</create> process you need to intervene. See also warning pertaining to
2879 L</new>.
2880
2881 =back
2882
2883 =cut
2884
2885 sub create {
2886   #my ($self, $col_data) = @_;
2887   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2888   return shift->new_result(shift)->insert;
2889 }
2890
2891 =head2 find_or_create
2892
2893 =over 4
2894
2895 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2896
2897 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2898
2899 =back
2900
2901   $cd->cd_to_producer->find_or_create({ producer => $producer },
2902                                       { key => 'primary' });
2903
2904 Tries to find a record based on its primary key or unique constraints; if none
2905 is found, creates one and returns that instead.
2906
2907   my $cd = $schema->resultset('CD')->find_or_create({
2908     cdid   => 5,
2909     artist => 'Massive Attack',
2910     title  => 'Mezzanine',
2911     year   => 2005,
2912   });
2913
2914 Also takes an optional C<key> attribute, to search by a specific key or unique
2915 constraint. For example:
2916
2917   my $cd = $schema->resultset('CD')->find_or_create(
2918     {
2919       artist => 'Massive Attack',
2920       title  => 'Mezzanine',
2921     },
2922     { key => 'cd_artist_title' }
2923   );
2924
2925 B<Note>: Make sure to read the documentation of L</find> and understand the
2926 significance of the C<key> attribute, as its lack may skew your search, and
2927 subsequently result in spurious row creation.
2928
2929 B<Note>: Because find_or_create() reads from the database and then
2930 possibly inserts based on the result, this method is subject to a race
2931 condition. Another process could create a record in the table after
2932 the find has completed and before the create has started. To avoid
2933 this problem, use find_or_create() inside a transaction.
2934
2935 B<Note>: Take care when using C<find_or_create> with a table having
2936 columns with default values that you intend to be automatically
2937 supplied by the database (e.g. an auto_increment primary key column).
2938 In normal usage, the value of such columns should NOT be included at
2939 all in the call to C<find_or_create>, even when set to C<undef>.
2940
2941 See also L</find> and L</update_or_create>. For information on how to declare
2942 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2943
2944 If you need to know if an existing row was found or a new one created use
2945 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2946 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2947 database!
2948
2949   my $cd = $schema->resultset('CD')->find_or_new({
2950     cdid   => 5,
2951     artist => 'Massive Attack',
2952     title  => 'Mezzanine',
2953     year   => 2005,
2954   });
2955
2956   if( !$cd->in_storage ) {
2957       # do some stuff
2958       $cd->insert;
2959   }
2960
2961 =cut
2962
2963 sub find_or_create {
2964   my $self     = shift;
2965   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2966   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2967   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2968     return $row;
2969   }
2970   return $self->new_result($hash)->insert;
2971 }
2972
2973 =head2 update_or_create
2974
2975 =over 4
2976
2977 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2978
2979 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2980
2981 =back
2982
2983   $resultset->update_or_create({ col => $val, ... });
2984
2985 Like L</find_or_create>, but if a row is found it is immediately updated via
2986 C<< $found_row->update (\%col_data) >>.
2987
2988
2989 Takes an optional C<key> attribute to search on a specific unique constraint.
2990 For example:
2991
2992   # In your application
2993   my $cd = $schema->resultset('CD')->update_or_create(
2994     {
2995       artist => 'Massive Attack',
2996       title  => 'Mezzanine',
2997       year   => 1998,
2998     },
2999     { key => 'cd_artist_title' }
3000   );
3001
3002   $cd->cd_to_producer->update_or_create({
3003     producer => $producer,
3004     name => 'harry',
3005   }, {
3006     key => 'primary',
3007   });
3008
3009 B<Note>: Make sure to read the documentation of L</find> and understand the
3010 significance of the C<key> attribute, as its lack may skew your search, and
3011 subsequently result in spurious row creation.
3012
3013 B<Note>: Take care when using C<update_or_create> with a table having
3014 columns with default values that you intend to be automatically
3015 supplied by the database (e.g. an auto_increment primary key column).
3016 In normal usage, the value of such columns should NOT be included at
3017 all in the call to C<update_or_create>, even when set to C<undef>.
3018
3019 See also L</find> and L</find_or_create>. For information on how to declare
3020 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3021
3022 If you need to know if an existing row was updated or a new one created use
3023 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3024 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3025 database!
3026
3027 =cut
3028
3029 sub update_or_create {
3030   my $self = shift;
3031   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3032   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3033
3034   my $row = $self->find($cond, $attrs);
3035   if (defined $row) {
3036     $row->update($cond);
3037     return $row;
3038   }
3039
3040   return $self->new_result($cond)->insert;
3041 }
3042
3043 =head2 update_or_new
3044
3045 =over 4
3046
3047 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3048
3049 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3050
3051 =back
3052
3053   $resultset->update_or_new({ col => $val, ... });
3054
3055 Like L</find_or_new> but if a row is found it is immediately updated via
3056 C<< $found_row->update (\%col_data) >>.
3057
3058 For example:
3059
3060   # In your application
3061   my $cd = $schema->resultset('CD')->update_or_new(
3062     {
3063       artist => 'Massive Attack',
3064       title  => 'Mezzanine',
3065       year   => 1998,
3066     },
3067     { key => 'cd_artist_title' }
3068   );
3069
3070   if ($cd->in_storage) {
3071       # the cd was updated
3072   }
3073   else {
3074       # the cd is not yet in the database, let's insert it
3075       $cd->insert;
3076   }
3077
3078 B<Note>: Make sure to read the documentation of L</find> and understand the
3079 significance of the C<key> attribute, as its lack may skew your search, and
3080 subsequently result in spurious new objects.
3081
3082 B<Note>: Take care when using C<update_or_new> with a table having
3083 columns with default values that you intend to be automatically
3084 supplied by the database (e.g. an auto_increment primary key column).
3085 In normal usage, the value of such columns should NOT be included at
3086 all in the call to C<update_or_new>, even when set to C<undef>.
3087
3088 See also L</find>, L</find_or_create> and L</find_or_new>.
3089
3090 =cut
3091
3092 sub update_or_new {
3093     my $self  = shift;
3094     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3095     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3096
3097     my $row = $self->find( $cond, $attrs );
3098     if ( defined $row ) {
3099         $row->update($cond);
3100         return $row;
3101     }
3102
3103     return $self->new_result($cond);
3104 }
3105
3106 =head2 get_cache
3107
3108 =over 4
3109
3110 =item Arguments: none
3111
3112 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3113
3114 =back
3115
3116 Gets the contents of the cache for the resultset, if the cache is set.
3117
3118 The cache is populated either by using the L</prefetch> attribute to
3119 L</search> or by calling L</set_cache>.
3120
3121 =cut
3122
3123 sub get_cache {
3124   shift->{all_cache};
3125 }
3126
3127 =head2 set_cache
3128
3129 =over 4
3130
3131 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3132
3133 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3134
3135 =back
3136
3137 Sets the contents of the cache for the resultset. Expects an arrayref
3138 of objects of the same class as those produced by the resultset. Note that
3139 if the cache is set, the resultset will return the cached objects rather
3140 than re-querying the database even if the cache attr is not set.
3141
3142 The contents of the cache can also be populated by using the
3143 L</prefetch> attribute to L</search>.
3144
3145 =cut
3146
3147 sub set_cache {
3148   my ( $self, $data ) = @_;
3149   $self->throw_exception("set_cache requires an arrayref")
3150       if defined($data) && (ref $data ne 'ARRAY');
3151   $self->{all_cache} = $data;
3152 }
3153
3154 =head2 clear_cache
3155
3156 =over 4
3157
3158 =item Arguments: none
3159
3160 =item Return Value: undef
3161
3162 =back
3163
3164 Clears the cache for the resultset.
3165
3166 =cut
3167
3168 sub clear_cache {
3169   shift->set_cache(undef);
3170 }
3171
3172 =head2 is_paged
3173
3174 =over 4
3175
3176 =item Arguments: none
3177
3178 =item Return Value: true, if the resultset has been paginated
3179
3180 =back
3181
3182 =cut
3183
3184 sub is_paged {
3185   my ($self) = @_;
3186   return !!$self->{attrs}{page};
3187 }
3188
3189 =head2 is_ordered
3190
3191 =over 4
3192
3193 =item Arguments: none
3194
3195 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3196
3197 =back
3198
3199 =cut
3200
3201 sub is_ordered {
3202   my ($self) = @_;
3203   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3204 }
3205
3206 =head2 related_resultset
3207
3208 =over 4
3209
3210 =item Arguments: $rel_name
3211
3212 =item Return Value: L<$resultset|/search>
3213
3214 =back
3215
3216 Returns a related resultset for the supplied relationship name.
3217
3218   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3219
3220 =cut
3221
3222 sub related_resultset {
3223   my ($self, $rel) = @_;
3224
3225   return $self->{related_resultsets}{$rel}
3226     if defined $self->{related_resultsets}{$rel};
3227
3228   return $self->{related_resultsets}{$rel} = do {
3229     my $rsrc = $self->result_source;
3230     my $rel_info = $rsrc->relationship_info($rel);
3231
3232     $self->throw_exception(
3233       "search_related: result source '" . $rsrc->source_name .
3234         "' has no such relationship $rel")
3235       unless $rel_info;
3236
3237     my $attrs = $self->_chain_relationship($rel);
3238
3239     my $storage = $rsrc->schema->storage;
3240
3241     # Previously this atribute was deleted (instead of being set as it is now)
3242     # Doing so seems to be harmless in all available test permutations
3243     # See also 01d59a6a6 and mst's comment below
3244     #
3245     $attrs->{alias} = $storage->relname_to_table_alias(
3246       $rel,
3247       $attrs->{seen_join}{$rel}
3248     );
3249
3250     # since this is search_related, and we already slid the select window inwards
3251     # (the select/as attrs were deleted in the beginning), we need to flip all
3252     # left joins to inner, so we get the expected results
3253     # read the comment on top of the actual function to see what this does
3254     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3255
3256     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3257     delete $attrs->{result_class};
3258
3259     my $new = do {
3260
3261       # The reason we do this now instead of passing the alias to the
3262       # search_rs below is that if you wrap/overload resultset on the
3263       # source you need to know what alias it's -going- to have for things
3264       # to work sanely (e.g. RestrictWithObject wants to be able to add
3265       # extra query restrictions, and these may need to be $alias.)
3266       #                                       -- mst ~ 2007 (01d59a6a6)
3267       #
3268       # FIXME - this seems to be no longer neccessary (perhaps due to the
3269       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3270       # dependent (as of Jun 2015 ) does not yield any difference with or
3271       # without this line. Nevertheless keep it as is for now, to minimize
3272       # churn, there is enough potential for breakage in 0.0829xx as it is
3273       #                                       -- ribasushi Jun 2015
3274       #
3275       my $rel_source = $rsrc->related_source($rel);
3276       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3277
3278       $rel_source->resultset->search_rs( undef, $attrs );
3279     };
3280
3281     if (my $cache = $self->get_cache) {
3282       my @related_cache = map
3283         { $_->related_resultset($rel)->get_cache || () }
3284         @$cache
3285       ;
3286
3287       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3288     }
3289
3290     $new;
3291   };
3292 }
3293
3294 =head2 current_source_alias
3295
3296 =over 4
3297
3298 =item Arguments: none
3299
3300 =item Return Value: $source_alias
3301
3302 =back
3303
3304 Returns the current table alias for the result source this resultset is built
3305 on, that will be used in the SQL query. Usually it is C<me>.
3306
3307 Currently the source alias that refers to the result set returned by a
3308 L</search>/L</find> family method depends on how you got to the resultset: it's
3309 C<me> by default, but eg. L</search_related> aliases it to the related result
3310 source name (and keeps C<me> referring to the original result set). The long
3311 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3312 (and make this method unnecessary).
3313
3314 Thus it's currently necessary to use this method in predefined queries (see
3315 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3316 source alias of the current result set:
3317
3318   # in a result set class
3319   sub modified_by {
3320     my ($self, $user) = @_;
3321
3322     my $me = $self->current_source_alias;
3323
3324     return $self->search({
3325       "$me.modified" => $user->id,
3326     });
3327   }
3328
3329 The alias of L<newly created resultsets|/search> can be altered by the
3330 L<alias attribute|/alias>.
3331
3332 =cut
3333
3334 sub current_source_alias {
3335   return (shift->{attrs} || {})->{alias} || 'me';
3336 }
3337
3338 =head2 as_subselect_rs
3339
3340 =over 4
3341
3342 =item Arguments: none
3343
3344 =item Return Value: L<$resultset|/search>
3345
3346 =back
3347
3348 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3349 "virtual view" by including it as a subquery within the from clause.  From this
3350 point on, any joined tables are inaccessible to ->search on the resultset (as if
3351 it were simply where-filtered without joins).  For example:
3352
3353  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3354
3355  # 'x' now pollutes the query namespace
3356
3357  # So the following works as expected
3358  my $ok_rs = $rs->search({'x.other' => 1});
3359
3360  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3361  # def) we look for one row with contradictory terms and join in another table
3362  # (aliased 'x_2') which we never use
3363  my $broken_rs = $rs->search({'x.name' => 'def'});
3364
3365  my $rs2 = $rs->as_subselect_rs;
3366
3367  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3368  my $not_joined_rs = $rs2->search({'x.other' => 1});
3369
3370  # works as expected: finds a 'table' row related to two x rows (abc and def)
3371  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3372
3373 Another example of when one might use this would be to select a subset of
3374 columns in a group by clause:
3375
3376  my $rs = $schema->resultset('Bar')->search(undef, {
3377    group_by => [qw{ id foo_id baz_id }],
3378  })->as_subselect_rs->search(undef, {
3379    columns => [qw{ id foo_id }]
3380  });
3381
3382 In the above example normally columns would have to be equal to the group by,
3383 but because we isolated the group by into a subselect the above works.
3384
3385 =cut
3386
3387 sub as_subselect_rs {
3388   my $self = shift;
3389
3390   my $attrs = $self->_resolved_attrs;
3391
3392   my $fresh_rs = (ref $self)->new (
3393     $self->result_source
3394   );
3395
3396   # these pieces will be locked in the subquery
3397   delete $fresh_rs->{cond};
3398   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3399
3400   return $fresh_rs->search( {}, {
3401     from => [{
3402       $attrs->{alias} => $self->as_query,
3403       -alias  => $attrs->{alias},
3404       -rsrc   => $self->result_source,
3405     }],
3406     alias => $attrs->{alias},
3407   });
3408 }
3409
3410 # This code is called by search_related, and makes sure there
3411 # is clear separation between the joins before, during, and
3412 # after the relationship. This information is needed later
3413 # in order to properly resolve prefetch aliases (any alias
3414 # with a relation_chain_depth less than the depth of the
3415 # current prefetch is not considered)
3416 #
3417 # The increments happen twice per join. An even number means a
3418 # relationship specified via a search_related, whereas an odd
3419 # number indicates a join/prefetch added via attributes
3420 #
3421 # Also this code will wrap the current resultset (the one we
3422 # chain to) in a subselect IFF it contains limiting attributes
3423 sub _chain_relationship {
3424   my ($self, $rel) = @_;
3425   my $source = $self->result_source;
3426   my $attrs = { %{$self->{attrs}||{}} };
3427
3428   # we need to take the prefetch the attrs into account before we
3429   # ->_resolve_join as otherwise they get lost - captainL
3430   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3431
3432   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3433
3434   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3435
3436   my $from;
3437   my @force_subq_attrs = qw/offset rows group_by having/;
3438
3439   if (
3440     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3441       ||
3442     $self->_has_resolved_attr (@force_subq_attrs)
3443   ) {
3444     # Nuke the prefetch (if any) before the new $rs attrs
3445     # are resolved (prefetch is useless - we are wrapping
3446     # a subquery anyway).
3447     my $rs_copy = $self->search;
3448     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3449       $rs_copy->{attrs}{join},
3450       delete $rs_copy->{attrs}{prefetch},
3451     );
3452
3453     $from = [{
3454       -rsrc   => $source,
3455       -alias  => $attrs->{alias},
3456       $attrs->{alias} => $rs_copy->as_query,
3457     }];
3458     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3459     $seen->{-relation_chain_depth} = 0;
3460   }
3461   elsif ($attrs->{from}) {  #shallow copy suffices
3462     $from = [ @{$attrs->{from}} ];
3463   }
3464   else {
3465     $from = [{
3466       -rsrc  => $source,
3467       -alias => $attrs->{alias},
3468       $attrs->{alias} => $source->from,
3469     }];
3470   }
3471
3472   my $jpath = ($seen->{-relation_chain_depth})
3473     ? $from->[-1][0]{-join_path}
3474     : [];
3475
3476   my @requested_joins = $source->_resolve_join(
3477     $join,
3478     $attrs->{alias},
3479     $seen,
3480     $jpath,
3481   );
3482
3483   push @$from, @requested_joins;
3484
3485   $seen->{-relation_chain_depth}++;
3486
3487   # if $self already had a join/prefetch specified on it, the requested
3488   # $rel might very well be already included. What we do in this case
3489   # is effectively a no-op (except that we bump up the chain_depth on
3490   # the join in question so we could tell it *is* the search_related)
3491   my $already_joined;
3492
3493   # we consider the last one thus reverse
3494   for my $j (reverse @requested_joins) {
3495     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3496     if ($rel eq $last_j) {
3497       $j->[0]{-relation_chain_depth}++;
3498       $already_joined++;
3499       last;
3500     }
3501   }
3502
3503   unless ($already_joined) {
3504     push @$from, $source->_resolve_join(
3505       $rel,
3506       $attrs->{alias},
3507       $seen,
3508       $jpath,
3509     );
3510   }
3511
3512   $seen->{-relation_chain_depth}++;
3513
3514   return {%$attrs, from => $from, seen_join => $seen};
3515 }
3516
3517 sub _resolved_attrs {
3518   my $self = shift;
3519   return $self->{_attrs} if $self->{_attrs};
3520
3521   my $attrs  = { %{ $self->{attrs} || {} } };
3522   my $source = $attrs->{result_source} = $self->result_source;
3523   my $alias  = $attrs->{alias};
3524
3525   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3526     if $attrs->{collapse} and $attrs->{distinct};
3527
3528   # default selection list
3529   $attrs->{columns} = [ $source->columns ]
3530     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3531
3532   # merge selectors together
3533   for (qw/columns select as/) {
3534     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3535       if $attrs->{$_} or $attrs->{"+$_"};
3536   }
3537
3538   # disassemble columns
3539   my (@sel, @as);
3540   if (my $cols = delete $attrs->{columns}) {
3541     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3542       if (ref $c eq 'HASH') {
3543         for my $as (sort keys %$c) {
3544           push @sel, $c->{$as};
3545           push @as, $as;
3546         }
3547       }
3548       else {
3549         push @sel, $c;
3550         push @as, $c;
3551       }
3552     }
3553   }
3554
3555   # when trying to weed off duplicates later do not go past this point -
3556   # everything added from here on is unbalanced "anyone's guess" stuff
3557   my $dedup_stop_idx = $#as;
3558
3559   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3560     if $attrs->{as};
3561   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3562     if $attrs->{select};
3563
3564   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3565   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3566
3567   # disqualify all $alias.col as-bits (inflate-map mandated)
3568   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3569
3570   # de-duplicate the result (remove *identical* select/as pairs)
3571   # and also die on duplicate {as} pointing to different {select}s
3572   # not using a c-style for as the condition is prone to shrinkage
3573   my $seen;
3574   my $i = 0;
3575   while ($i <= $dedup_stop_idx) {
3576     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3577       splice @sel, $i, 1;
3578       splice @as, $i, 1;
3579       $dedup_stop_idx--;
3580     }
3581     elsif ($seen->{$as[$i]}++) {
3582       $self->throw_exception(
3583         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3584       );
3585     }
3586     else {
3587       $i++;
3588     }
3589   }
3590
3591   $attrs->{select} = \@sel;
3592   $attrs->{as} = \@as;
3593
3594   $attrs->{from} ||= [{
3595     -rsrc   => $source,
3596     -alias  => $self->{attrs}{alias},
3597     $self->{attrs}{alias} => $source->from,
3598   }];
3599
3600   if ( $attrs->{join} || $attrs->{prefetch} ) {
3601
3602     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3603       if ref $attrs->{from} ne 'ARRAY';
3604
3605     my $join = (delete $attrs->{join}) || {};
3606
3607     if ( defined $attrs->{prefetch} ) {
3608       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3609     }
3610
3611     $attrs->{from} =    # have to copy here to avoid corrupting the original
3612       [
3613         @{ $attrs->{from} },
3614         $source->_resolve_join(
3615           $join,
3616           $alias,
3617           { %{ $attrs->{seen_join} || {} } },
3618           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3619             ? $attrs->{from}[-1][0]{-join_path}
3620             : []
3621           ,
3622         )
3623       ];
3624   }
3625
3626
3627   for my $attr (qw(order_by group_by)) {
3628
3629     if ( defined $attrs->{$attr} ) {
3630       $attrs->{$attr} = (
3631         ref( $attrs->{$attr} ) eq 'ARRAY'
3632         ? [ @{ $attrs->{$attr} } ]
3633         : [ $attrs->{$attr} || () ]
3634       );
3635
3636       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3637     }
3638   }
3639
3640
3641   # set collapse default based on presence of prefetch
3642   my $prefetch;
3643   if (
3644     defined $attrs->{prefetch}
3645       and
3646     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3647   ) {
3648     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3649       if defined $attrs->{collapse} and ! $attrs->{collapse};
3650
3651     $attrs->{collapse} = 1;
3652   }
3653
3654
3655   # run through the resulting joinstructure (starting from our current slot)
3656   # and unset collapse if proven unnecessary
3657   #
3658   # also while we are at it find out if the current root source has
3659   # been premultiplied by previous related_source chaining
3660   #
3661   # this allows to predict whether a root object with all other relation
3662   # data set to NULL is in fact unique
3663   if ($attrs->{collapse}) {
3664
3665     if (ref $attrs->{from} eq 'ARRAY') {
3666
3667       if (@{$attrs->{from}} == 1) {
3668         # no joins - no collapse
3669         $attrs->{collapse} = 0;
3670       }
3671       else {
3672         # find where our table-spec starts
3673         my @fromlist = @{$attrs->{from}};
3674         while (@fromlist) {
3675           my $t = shift @fromlist;
3676
3677           my $is_multi;
3678           # me vs join from-spec distinction - a ref means non-root
3679           if (ref $t eq 'ARRAY') {
3680             $t = $t->[0];
3681             $is_multi ||= ! $t->{-is_single};
3682           }
3683           last if ($t->{-alias} && $t->{-alias} eq $alias);
3684           $attrs->{_main_source_premultiplied} ||= $is_multi;
3685         }
3686
3687         # no non-singles remaining, nor any premultiplication - nothing to collapse
3688         if (
3689           ! $attrs->{_main_source_premultiplied}
3690             and
3691           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3692         ) {
3693           $attrs->{collapse} = 0;
3694         }
3695       }
3696     }
3697
3698     else {
3699       # if we can not analyze the from - err on the side of safety
3700       $attrs->{_main_source_premultiplied} = 1;
3701     }
3702   }
3703
3704
3705   # generate the distinct induced group_by before injecting the prefetched select/as parts
3706   if (delete $attrs->{distinct}) {
3707     if ($attrs->{group_by}) {
3708       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3709     }
3710     else {
3711       $attrs->{_grouped_by_distinct} = 1;
3712       # distinct affects only the main selection part, not what prefetch may add below
3713       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3714
3715       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3716       # The thinking is: if we are collapsing the subquerying prefetch engine will
3717       # rip stuff apart for us anyway, and we do not want to have a potentially
3718       # function-converted external order_by
3719       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3720       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3721     }
3722   }
3723
3724
3725   # generate selections based on the prefetch helper
3726   if ($prefetch) {
3727
3728     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3729       if $attrs->{_dark_selector};
3730
3731     # this is a separate structure (we don't look in {from} directly)
3732     # as the resolver needs to shift things off the lists to work
3733     # properly (identical-prefetches on different branches)
3734     my $joined_node_aliases_map = {};
3735     if (ref $attrs->{from} eq 'ARRAY') {
3736
3737       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3738
3739       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3740         next unless $j->[0]{-alias};
3741         next unless $j->[0]{-join_path};
3742         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3743
3744         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3745
3746         my $p = $joined_node_aliases_map;
3747         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3748         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3749       }
3750     }
3751
3752     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3753       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3754   }
3755
3756
3757   $attrs->{_simple_passthrough_construction} = !(
3758     $attrs->{collapse}
3759       or
3760     grep { $_ =~ /\./ } @{$attrs->{as}}
3761   );
3762
3763
3764   # if both page and offset are specified, produce a combined offset
3765   # even though it doesn't make much sense, this is what pre 081xx has
3766   # been doing
3767   if (my $page = delete $attrs->{page}) {
3768     $attrs->{offset} =
3769       ($attrs->{rows} * ($page - 1))
3770             +
3771       ($attrs->{offset} || 0)
3772     ;
3773   }
3774
3775   return $self->{_attrs} = $attrs;
3776 }
3777
3778 sub _rollout_attr {
3779   my ($self, $attr) = @_;
3780
3781   if (ref $attr eq 'HASH') {
3782     return $self->_rollout_hash($attr);
3783   } elsif (ref $attr eq 'ARRAY') {
3784     return $self->_rollout_array($attr);
3785   } else {
3786     return [$attr];
3787   }
3788 }
3789
3790 sub _rollout_array {
3791   my ($self, $attr) = @_;
3792
3793   my @rolled_array;
3794   foreach my $element (@{$attr}) {
3795     if (ref $element eq 'HASH') {
3796       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3797     } elsif (ref $element eq 'ARRAY') {
3798       #  XXX - should probably recurse here
3799       push( @rolled_array, @{$self->_rollout_array($element)} );
3800     } else {
3801       push( @rolled_array, $element );
3802     }
3803   }
3804   return \@rolled_array;
3805 }
3806
3807 sub _rollout_hash {
3808   my ($self, $attr) = @_;
3809
3810   my @rolled_array;
3811   foreach my $key (keys %{$attr}) {
3812     push( @rolled_array, { $key => $attr->{$key} } );
3813   }
3814   return \@rolled_array;
3815 }
3816
3817 sub _calculate_score {
3818   my ($self, $a, $b) = @_;
3819
3820   if (defined $a xor defined $b) {
3821     return 0;
3822   }
3823   elsif (not defined $a) {
3824     return 1;
3825   }
3826
3827   if (ref $b eq 'HASH') {
3828     my ($b_key) = keys %{$b};
3829     $b_key = '' if ! defined $b_key;
3830     if (ref $a eq 'HASH') {
3831       my ($a_key) = keys %{$a};
3832       $a_key = '' if ! defined $a_key;
3833       if ($a_key eq $b_key) {
3834         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3835       } else {
3836         return 0;
3837       }
3838     } else {
3839       return ($a eq $b_key) ? 1 : 0;
3840     }
3841   } else {
3842     if (ref $a eq 'HASH') {
3843       my ($a_key) = keys %{$a};
3844       return ($b eq $a_key) ? 1 : 0;
3845     } else {
3846       return ($b eq $a) ? 1 : 0;
3847     }
3848   }
3849 }
3850
3851 sub _merge_joinpref_attr {
3852   my ($self, $orig, $import) = @_;
3853
3854   return $import unless defined($orig);
3855   return $orig unless defined($import);
3856
3857   $orig = $self->_rollout_attr($orig);
3858   $import = $self->_rollout_attr($import);
3859
3860   my $seen_keys;
3861   foreach my $import_element ( @{$import} ) {
3862     # find best candidate from $orig to merge $b_element into
3863     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3864     foreach my $orig_element ( @{$orig} ) {
3865       my $score = $self->_calculate_score( $orig_element, $import_element );
3866       if ($score > $best_candidate->{score}) {
3867         $best_candidate->{position} = $position;
3868         $best_candidate->{score} = $score;
3869       }
3870       $position++;
3871     }
3872     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3873     $import_key = '' if not defined $import_key;
3874
3875     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3876       push( @{$orig}, $import_element );
3877     } else {
3878       my $orig_best = $orig->[$best_candidate->{position}];
3879       # merge orig_best and b_element together and replace original with merged
3880       if (ref $orig_best ne 'HASH') {
3881         $orig->[$best_candidate->{position}] = $import_element;
3882       } elsif (ref $import_element eq 'HASH') {
3883         my ($key) = keys %{$orig_best};
3884         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3885       }
3886     }
3887     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3888   }
3889
3890   return @$orig ? $orig : ();
3891 }
3892
3893 {
3894   my $hm;
3895
3896   sub _merge_attr {
3897     $hm ||= do {
3898       require Hash::Merge;
3899       my $hm = Hash::Merge->new;
3900
3901       $hm->specify_behavior({
3902         SCALAR => {
3903           SCALAR => sub {
3904             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3905
3906             if ($defl xor $defr) {
3907               return [ $defl ? $_[0] : $_[1] ];
3908             }
3909             elsif (! $defl) {
3910               return [];
3911             }
3912             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3913               return [ $_[0] ];
3914             }
3915             else {
3916               return [$_[0], $_[1]];
3917             }
3918           },
3919           ARRAY => sub {
3920             return $_[1] if !defined $_[0];
3921             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3922             return [$_[0], @{$_[1]}]
3923           },
3924           HASH  => sub {
3925             return [] if !defined $_[0] and !keys %{$_[1]};
3926             return [ $_[1] ] if !defined $_[0];
3927             return [ $_[0] ] if !keys %{$_[1]};
3928             return [$_[0], $_[1]]
3929           },
3930         },
3931         ARRAY => {
3932           SCALAR => sub {
3933             return $_[0] if !defined $_[1];
3934             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3935             return [@{$_[0]}, $_[1]]
3936           },
3937           ARRAY => sub {
3938             my @ret = @{$_[0]} or return $_[1];
3939             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3940             my %idx = map { $_ => 1 } @ret;
3941             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3942             \@ret;
3943           },
3944           HASH => sub {
3945             return [ $_[1] ] if ! @{$_[0]};
3946             return $_[0] if !keys %{$_[1]};
3947             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3948             return [ @{$_[0]}, $_[1] ];
3949           },
3950         },
3951         HASH => {
3952           SCALAR => sub {
3953             return [] if !keys %{$_[0]} and !defined $_[1];
3954             return [ $_[0] ] if !defined $_[1];
3955             return [ $_[1] ] if !keys %{$_[0]};
3956             return [$_[0], $_[1]]
3957           },
3958           ARRAY => sub {
3959             return [] if !keys %{$_[0]} and !@{$_[1]};
3960             return [ $_[0] ] if !@{$_[1]};
3961             return $_[1] if !keys %{$_[0]};
3962             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3963             return [ $_[0], @{$_[1]} ];
3964           },
3965           HASH => sub {
3966             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3967             return [ $_[0] ] if !keys %{$_[1]};
3968             return [ $_[1] ] if !keys %{$_[0]};
3969             return [ $_[0] ] if $_[0] eq $_[1];
3970             return [ $_[0], $_[1] ];
3971           },
3972         }
3973       } => 'DBIC_RS_ATTR_MERGER');
3974       $hm;
3975     };
3976
3977     return $hm->merge ($_[1], $_[2]);
3978   }
3979 }
3980
3981 sub STORABLE_freeze {
3982   my ($self, $cloning) = @_;
3983   my $to_serialize = { %$self };
3984
3985   # A cursor in progress can't be serialized (and would make little sense anyway)
3986   # the parser can be regenerated (and can't be serialized)
3987   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3988
3989   # nor is it sensical to store a not-yet-fired-count pager
3990   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3991     delete $to_serialize->{pager};
3992   }
3993
3994   Storable::nfreeze($to_serialize);
3995 }
3996
3997 # need this hook for symmetry
3998 sub STORABLE_thaw {
3999   my ($self, $cloning, $serialized) = @_;
4000
4001   %$self = %{ Storable::thaw($serialized) };
4002
4003   $self;
4004 }
4005
4006
4007 =head2 throw_exception
4008
4009 See L<DBIx::Class::Schema/throw_exception> for details.
4010
4011 =cut
4012
4013 sub throw_exception {
4014   my $self=shift;
4015
4016   if (ref $self and my $rsrc = $self->result_source) {
4017     $rsrc->throw_exception(@_)
4018   }
4019   else {
4020     DBIx::Class::Exception->throw(@_);
4021   }
4022 }
4023
4024 1;
4025
4026 __END__
4027
4028 # XXX: FIXME: Attributes docs need clearing up
4029
4030 =head1 ATTRIBUTES
4031
4032 Attributes are used to refine a ResultSet in various ways when
4033 searching for data. They can be passed to any method which takes an
4034 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4035 L</count>.
4036
4037 Default attributes can be set on the result class using
4038 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4039 the CAVEATS on that feature before using it!)
4040
4041 These are in no particular order:
4042
4043 =head2 order_by
4044
4045 =over 4
4046
4047 =item Value: ( $order_by | \@order_by | \%order_by )
4048
4049 =back
4050
4051 Which column(s) to order the results by.
4052
4053 [The full list of suitable values is documented in
4054 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4055 common options.]
4056
4057 If a single column name, or an arrayref of names is supplied, the
4058 argument is passed through directly to SQL. The hashref syntax allows
4059 for connection-agnostic specification of ordering direction:
4060
4061  For descending order:
4062
4063   order_by => { -desc => [qw/col1 col2 col3/] }
4064
4065  For explicit ascending order:
4066
4067   order_by => { -asc => 'col' }
4068
4069 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4070 supported, although you are strongly encouraged to use the hashref
4071 syntax as outlined above.
4072
4073 =head2 columns
4074
4075 =over 4
4076
4077 =item Value: \@columns | \%columns | $column
4078
4079 =back
4080
4081 Shortcut to request a particular set of columns to be retrieved. Each
4082 column spec may be a string (a table column name), or a hash (in which
4083 case the key is the C<as> value, and the value is used as the C<select>
4084 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4085 it and sets C<select> from that, then auto-populates C<as> from
4086 C<select> as normal. (You may also use the C<cols> attribute, as in
4087 earlier versions of DBIC, but this is deprecated)
4088
4089 Essentially C<columns> does the same as L</select> and L</as>.
4090
4091     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4092
4093 is the same as
4094
4095     select => [qw(some_column another_column)],
4096     as     => [qw(some_column dbic_slot)]
4097
4098 If you want to individually retrieve related columns (in essence perform
4099 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4100 chain such that it matches existing relationships:
4101
4102     my $rs = $schema->resultset('Artist')->search({}, {
4103         # required to tell DBIC to collapse has_many relationships
4104         collapse => 1,
4105         join     => { cds => 'tracks' },
4106         '+columns'  => {
4107           'cds.cdid'         => 'cds.cdid',
4108           'cds.tracks.title' => 'tracks.title',
4109         },
4110     });
4111
4112 Like elsewhere, literal SQL or literal values can be included by using a
4113 scalar reference or a literal bind value, and these values will be available
4114 in the result with C<get_column> (see also
4115 L<SQL::Abstract/Literal SQL and value type operators>):
4116
4117     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4118     # bind values: $true_value, $false_value
4119     columns => [
4120         {
4121             foo => \1,
4122             bar => \q{'a string'},
4123             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4124         }
4125     ]
4126
4127 =head2 +columns
4128
4129 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4130 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4131 with a unary plus operator before it, which is the same as simply C<columns>.
4132
4133 =over 4
4134
4135 =item Value: \@extra_columns
4136
4137 =back
4138
4139 Indicates additional columns to be selected from storage. Works the same as
4140 L</columns> but adds columns to the current selection. (You may also use the
4141 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4142 deprecated)
4143
4144   $schema->resultset('CD')->search(undef, {
4145     '+columns' => ['artist.name'],
4146     join => ['artist']
4147   });
4148
4149 would return all CDs and include a 'name' column to the information
4150 passed to object inflation. Note that the 'artist' is the name of the
4151 column (or relationship) accessor, and 'name' is the name of the column
4152 accessor in the related table.
4153
4154 =head2 select
4155
4156 =over 4
4157
4158 =item Value: \@select_columns
4159
4160 =back
4161
4162 Indicates which columns should be selected from the storage. You can use
4163 column names, or in the case of RDBMS back ends, function or stored procedure
4164 names:
4165
4166   $rs = $schema->resultset('Employee')->search(undef, {
4167     select => [
4168       'name',
4169       { count => 'employeeid' },
4170       { max => { length => 'name' }, -as => 'longest_name' }
4171     ]
4172   });
4173
4174   # Equivalent SQL
4175   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4176
4177 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4178 use L</select>, to instruct DBIx::Class how to store the result of the column.
4179
4180 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4181 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4182 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4183 function attribute> supplied as shown in the example above.
4184
4185 =head2 +select
4186
4187 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4188 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4189 with a unary plus operator before it, which is the same as simply C<select>.
4190
4191 =over 4
4192
4193 =item Value: \@extra_select_columns
4194
4195 =back
4196
4197 Indicates additional columns to be selected from storage.  Works the same as
4198 L</select> but adds columns to the current selection, instead of specifying
4199 a new explicit list.
4200
4201 =head2 as
4202
4203 =over 4
4204
4205 =item Value: \@inflation_names
4206
4207 =back
4208
4209 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4210 slot name in which the column value will be stored within the
4211 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4212 identifier by the C<get_column> method (or via the object accessor B<if one
4213 with the same name already exists>) as shown below.
4214
4215 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4216 aliasing C<AS>. See L</select> for details.
4217
4218   $rs = $schema->resultset('Employee')->search(undef, {
4219     select => [
4220       'name',
4221       { count => 'employeeid' },
4222       { max => { length => 'name' }, -as => 'longest_name' }
4223     ],
4224     as => [qw/
4225       name
4226       employee_count
4227       max_name_length
4228     /],
4229   });
4230
4231 If the object against which the search is performed already has an accessor
4232 matching a column name specified in C<as>, the value can be retrieved using
4233 the accessor as normal:
4234
4235   my $name = $employee->name();
4236
4237 If on the other hand an accessor does not exist in the object, you need to
4238 use C<get_column> instead:
4239
4240   my $employee_count = $employee->get_column('employee_count');
4241
4242 You can create your own accessors if required - see
4243 L<DBIx::Class::Manual::Cookbook> for details.
4244
4245 =head2 +as
4246
4247 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4248 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4249 with a unary plus operator before it, which is the same as simply C<as>.
4250
4251 =over 4
4252
4253 =item Value: \@extra_inflation_names
4254
4255 =back
4256
4257 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4258
4259 =head2 join
4260
4261 =over 4
4262
4263 =item Value: ($rel_name | \@rel_names | \%rel_names)
4264
4265 =back
4266
4267 Contains a list of relationships that should be joined for this query.  For
4268 example:
4269
4270   # Get CDs by Nine Inch Nails
4271   my $rs = $schema->resultset('CD')->search(
4272     { 'artist.name' => 'Nine Inch Nails' },
4273     { join => 'artist' }
4274   );
4275
4276 Can also contain a hash reference to refer to the other relation's relations.
4277 For example:
4278
4279   package MyApp::Schema::Track;
4280   use base qw/DBIx::Class/;
4281   __PACKAGE__->table('track');
4282   __PACKAGE__->add_columns(qw/trackid cd position title/);
4283   __PACKAGE__->set_primary_key('trackid');
4284   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4285   1;
4286
4287   # In your application
4288   my $rs = $schema->resultset('Artist')->search(
4289     { 'track.title' => 'Teardrop' },
4290     {
4291       join     => { cd => 'track' },
4292       order_by => 'artist.name',
4293     }
4294   );
4295
4296 You need to use the relationship (not the table) name in  conditions,
4297 because they are aliased as such. The current table is aliased as "me", so
4298 you need to use me.column_name in order to avoid ambiguity. For example:
4299
4300   # Get CDs from 1984 with a 'Foo' track
4301   my $rs = $schema->resultset('CD')->search(
4302     {
4303       'me.year' => 1984,
4304       'tracks.name' => 'Foo'
4305     },
4306     { join => 'tracks' }
4307   );
4308
4309 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4310 similarly for a third time). For e.g.
4311
4312   my $rs = $schema->resultset('Artist')->search({
4313     'cds.title'   => 'Down to Earth',
4314     'cds_2.title' => 'Popular',
4315   }, {
4316     join => [ qw/cds cds/ ],
4317   });
4318
4319 will return a set of all artists that have both a cd with title 'Down
4320 to Earth' and a cd with title 'Popular'.
4321
4322 If you want to fetch related objects from other tables as well, see L</prefetch>
4323 below.
4324
4325  NOTE: An internal join-chain pruner will discard certain joins while
4326  constructing the actual SQL query, as long as the joins in question do not
4327  affect the retrieved result. This for example includes 1:1 left joins
4328  that are not part of the restriction specification (WHERE/HAVING) nor are
4329  a part of the query selection.
4330
4331 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4332
4333 =head2 collapse
4334
4335 =over 4
4336
4337 =item Value: (0 | 1)
4338
4339 =back
4340
4341 When set to a true value, indicates that any rows fetched from joined has_many
4342 relationships are to be aggregated into the corresponding "parent" object. For
4343 example, the resultset:
4344
4345   my $rs = $schema->resultset('CD')->search({}, {
4346     '+columns' => [ qw/ tracks.title tracks.position / ],
4347     join => 'tracks',
4348     collapse => 1,
4349   });
4350
4351 While executing the following query:
4352
4353   SELECT me.*, tracks.title, tracks.position
4354     FROM cd me
4355     LEFT JOIN track tracks
4356       ON tracks.cdid = me.cdid
4357
4358 Will return only as many objects as there are rows in the CD source, even
4359 though the result of the query may span many rows. Each of these CD objects
4360 will in turn have multiple "Track" objects hidden behind the has_many
4361 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4362 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4363 product"), with each CD object containing exactly one of all fetched Track data.
4364
4365 When a collapse is requested on a non-ordered resultset, an order by some
4366 unique part of the main source (the left-most table) is inserted automatically.
4367 This is done so that the resultset is allowed to be "lazy" - calling
4368 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4369 object with all of its related data.
4370
4371 If an L</order_by> is already declared, and orders the resultset in a way that
4372 makes collapsing as described above impossible (e.g. C<< ORDER BY
4373 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4374 switch to "eager" mode and slurp the entire resultset before constructing the
4375 first object returned by L</next>.
4376
4377 Setting this attribute on a resultset that does not join any has_many
4378 relations is a no-op.
4379
4380 For a more in-depth discussion, see L</PREFETCHING>.
4381
4382 =head2 prefetch
4383
4384 =over 4
4385
4386 =item Value: ($rel_name | \@rel_names | \%rel_names)
4387
4388 =back
4389
4390 This attribute is a shorthand for specifying a L</join> spec, adding all
4391 columns from the joined related sources as L</+columns> and setting
4392 L</collapse> to a true value. It can be thought of as a rough B<superset>
4393 of the L</join> attribute.
4394
4395 For example, the following two queries are equivalent:
4396
4397   my $rs = $schema->resultset('Artist')->search({}, {
4398     prefetch => { cds => ['genre', 'tracks' ] },
4399   });
4400
4401 and
4402
4403   my $rs = $schema->resultset('Artist')->search({}, {
4404     join => { cds => ['genre', 'tracks' ] },
4405     collapse => 1,
4406     '+columns' => [
4407       (map
4408         { +{ "cds.$_" => "cds.$_" } }
4409         $schema->source('Artist')->related_source('cds')->columns
4410       ),
4411       (map
4412         { +{ "cds.genre.$_" => "genre.$_" } }
4413         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4414       ),
4415       (map
4416         { +{ "cds.tracks.$_" => "tracks.$_" } }
4417         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4418       ),
4419     ],
4420   });
4421
4422 Both producing the following SQL:
4423
4424   SELECT  me.artistid, me.name, me.rank, me.charfield,
4425           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4426           genre.genreid, genre.name,
4427           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4428     FROM artist me
4429     LEFT JOIN cd cds
4430       ON cds.artist = me.artistid
4431     LEFT JOIN genre genre
4432       ON genre.genreid = cds.genreid
4433     LEFT JOIN track tracks
4434       ON tracks.cd = cds.cdid
4435   ORDER BY me.artistid
4436
4437 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4438 the arguments are properly merged and generally do the right thing. For
4439 example, you may want to do the following:
4440
4441   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4442     { 'genre.genreid' => undef },
4443     {
4444       join => { cds => 'genre' },
4445       prefetch => 'cds',
4446     }
4447   );
4448
4449 Which generates the following SQL:
4450
4451   SELECT  me.artistid, me.name, me.rank, me.charfield,
4452           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4453     FROM artist me
4454     LEFT JOIN cd cds
4455       ON cds.artist = me.artistid
4456     LEFT JOIN genre genre
4457       ON genre.genreid = cds.genreid
4458   WHERE genre.genreid IS NULL
4459   ORDER BY me.artistid
4460
4461 For a more in-depth discussion, see L</PREFETCHING>.
4462
4463 =head2 alias
4464
4465 =over 4
4466
4467 =item Value: $source_alias
4468
4469 =back
4470
4471 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4472 nested search queries (sub-SELECTs) might need specific aliases set to
4473 reference inner queries.  For example:
4474
4475    my $q = $rs
4476       ->related_resultset('CDs')
4477       ->related_resultset('Tracks')
4478       ->search({
4479          'track.id' => { -ident => 'none_search.id' },
4480       })
4481       ->as_query;
4482
4483    my $ids = $self->search({
4484       -not_exists => $q,
4485    }, {
4486       alias    => 'none_search',
4487       group_by => 'none_search.id',
4488    })->get_column('id')->as_query;
4489
4490    $self->search({ id => { -in => $ids } })
4491
4492 This attribute is directly tied to L</current_source_alias>.
4493
4494 =head2 page
4495
4496 =over 4
4497
4498 =item Value: $page
4499
4500 =back
4501
4502 Makes the resultset paged and specifies the page to retrieve. Effectively
4503 identical to creating a non-pages resultset and then calling ->page($page)
4504 on it.
4505
4506 If L</rows> attribute is not specified it defaults to 10 rows per page.
4507
4508 When you have a paged resultset, L</count> will only return the number
4509 of rows in the page. To get the total, use the L</pager> and call
4510 C<total_entries> on it.
4511
4512 =head2 rows
4513
4514 =over 4
4515
4516 =item Value: $rows
4517
4518 =back
4519
4520 Specifies the maximum number of rows for direct retrieval or the number of
4521 rows per page if the page attribute or method is used.
4522
4523 =head2 offset
4524
4525 =over 4
4526
4527 =item Value: $offset
4528
4529 =back
4530
4531 Specifies the (zero-based) row number for the  first row to be returned, or the
4532 of the first row of the first page if paging is used.
4533
4534 =head2 software_limit
4535
4536 =over 4
4537
4538 =item Value: (0 | 1)
4539
4540 =back
4541
4542 When combined with L</rows> and/or L</offset> the generated SQL will not
4543 include any limit dialect stanzas. Instead the entire result will be selected
4544 as if no limits were specified, and DBIC will perform the limit locally, by
4545 artificially advancing and finishing the resulting L</cursor>.
4546
4547 This is the recommended way of performing resultset limiting when no sane RDBMS
4548 implementation is available (e.g.
4549 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4550 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4551
4552 =head2 group_by
4553
4554 =over 4
4555
4556 =item Value: \@columns
4557
4558 =back
4559
4560 A arrayref of columns to group by. Can include columns of joined tables.
4561
4562   group_by => [qw/ column1 column2 ... /]
4563
4564 =head2 having
4565
4566 =over 4
4567
4568 =item Value: $condition
4569
4570 =back
4571
4572 The HAVING operator specifies a B<secondary> condition applied to the set
4573 after the grouping calculations have been done. In other words it is a
4574 constraint just like L</where> (and accepting the same
4575 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4576 as it exists after GROUP BY has taken place. Specifying L</having> without
4577 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4578
4579 E.g.
4580
4581   having => { 'count_employee' => { '>=', 100 } }
4582
4583 or with an in-place function in which case literal SQL is required:
4584
4585   having => \[ 'count(employee) >= ?', 100 ]
4586
4587 =head2 distinct
4588
4589 =over 4
4590
4591 =item Value: (0 | 1)
4592
4593 =back
4594
4595 Set to 1 to automatically generate a L</group_by> clause based on the selection
4596 (including intelligent handling of L</order_by> contents). Note that the group
4597 criteria calculation takes place over the B<final> selection. This includes
4598 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4599 L</search> calls, and standalone columns selected via
4600 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4601 extra selections specified via L</prefetch> - such selections are explicitly
4602 excluded from group criteria calculations.
4603
4604 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4605 setting is ignored and an appropriate warning is issued.
4606
4607 =head2 where
4608
4609 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4610 conditions, same as the B<first> argument to the L<search operator|/search>
4611
4612   # only return rows WHERE deleted IS NULL for all searches
4613   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4614
4615 Note that the above example is
4616 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4617
4618 =head2 cache
4619
4620 Set to 1 to cache search results. This prevents extra SQL queries if you
4621 revisit rows in your ResultSet:
4622
4623   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4624
4625   while( my $artist = $resultset->next ) {
4626     ... do stuff ...
4627   }
4628
4629   $rs->first; # without cache, this would issue a query
4630
4631 By default, searches are not cached.
4632
4633 For more examples of using these attributes, see
4634 L<DBIx::Class::Manual::Cookbook>.
4635
4636 =head2 for
4637
4638 =over 4
4639
4640 =item Value: ( 'update' | 'shared' | \$scalar )
4641
4642 =back
4643
4644 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4645 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4646 query.
4647
4648 =head1 PREFETCHING
4649
4650 DBIx::Class supports arbitrary related data prefetching from multiple related
4651 sources. Any combination of relationship types and column sets are supported.
4652 If L<collapsing|/collapse> is requested, there is an additional requirement of
4653 selecting enough data to make every individual object uniquely identifiable.
4654
4655 Here are some more involved examples, based on the following relationship map:
4656
4657   # Assuming:
4658   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4659   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4660   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4661
4662   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4663
4664   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4665
4666
4667
4668   my $rs = $schema->resultset('Tag')->search(
4669     undef,
4670     {
4671       prefetch => {
4672         cd => 'artist'
4673       }
4674     }
4675   );
4676
4677 The initial search results in SQL like the following:
4678
4679   SELECT tag.*, cd.*, artist.* FROM tag
4680   JOIN cd ON tag.cd = cd.cdid
4681   JOIN artist ON cd.artist = artist.artistid
4682
4683 L<DBIx::Class> has no need to go back to the database when we access the
4684 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4685 case.
4686
4687 Simple prefetches will be joined automatically, so there is no need
4688 for a C<join> attribute in the above search.
4689
4690 The L</prefetch> attribute can be used with any of the relationship types
4691 and multiple prefetches can be specified together. Below is a more complex
4692 example that prefetches a CD's artist, its liner notes (if present),
4693 the cover image, the tracks on that CD, and the guests on those
4694 tracks.
4695
4696   my $rs = $schema->resultset('CD')->search(
4697     undef,
4698     {
4699       prefetch => [
4700         { artist => 'record_label'},  # belongs_to => belongs_to
4701         'liner_note',                 # might_have
4702         'cover_image',                # has_one
4703         { tracks => 'guests' },       # has_many => has_many
4704       ]
4705     }
4706   );
4707
4708 This will produce SQL like the following:
4709
4710   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4711          tracks.*, guests.*
4712     FROM cd me
4713     JOIN artist artist
4714       ON artist.artistid = me.artistid
4715     JOIN record_label record_label
4716       ON record_label.labelid = artist.labelid
4717     LEFT JOIN track tracks
4718       ON tracks.cdid = me.cdid
4719     LEFT JOIN guest guests
4720       ON guests.trackid = track.trackid
4721     LEFT JOIN liner_notes liner_note
4722       ON liner_note.cdid = me.cdid
4723     JOIN cd_artwork cover_image
4724       ON cover_image.cdid = me.cdid
4725   ORDER BY tracks.cd
4726
4727 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4728 C<tracks>, and C<guests> of the CD will all be available through the
4729 relationship accessors without the need for additional queries to the
4730 database.
4731
4732 =head3 CAVEATS
4733
4734 Prefetch does a lot of deep magic. As such, it may not behave exactly
4735 as you might expect.
4736
4737 =over 4
4738
4739 =item *
4740
4741 Prefetch uses the L</cache> to populate the prefetched relationships. This
4742 may or may not be what you want.
4743
4744 =item *
4745
4746 If you specify a condition on a prefetched relationship, ONLY those
4747 rows that match the prefetched condition will be fetched into that relationship.
4748 This means that adding prefetch to a search() B<may alter> what is returned by
4749 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4750
4751   my $artist_rs = $schema->resultset('Artist')->search({
4752       'cds.year' => 2008,
4753   }, {
4754       join => 'cds',
4755   });
4756
4757   my $count = $artist_rs->first->cds->count;
4758
4759   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4760
4761   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4762
4763   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4764
4765 That cmp_ok() may or may not pass depending on the datasets involved. In other
4766 words the C<WHERE> condition would apply to the entire dataset, just like
4767 it would in regular SQL. If you want to add a condition only to the "right side"
4768 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4769 condition|DBIx::Class::Relationship::Base/condition>
4770
4771 =back
4772
4773 =head1 DBIC BIND VALUES
4774
4775 Because DBIC may need more information to bind values than just the column name
4776 and value itself, it uses a special format for both passing and receiving bind
4777 values.  Each bind value should be composed of an arrayref of
4778 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4779
4780 =over 4
4781
4782 =item dbd_attrs
4783
4784 If present (in any form), this is what is being passed directly to bind_param.
4785 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4786 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4787
4788 If this is specified, all other bind options described below are ignored.
4789
4790 =item sqlt_datatype
4791
4792 If present, this is used to infer the actual bind attribute by passing to
4793 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4794 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4795
4796 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4797 currently drivers are expected to "Do the Right Thing" when given a common
4798 datatype name.  (Not ideal, but that's what we got at this point.)
4799
4800 =item sqlt_size
4801
4802 Currently used to correctly allocate buffers for bind_param_inout().
4803 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4804 or to a sensible value based on the "data_type".
4805
4806 =item dbic_colname
4807
4808 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4809 explicitly specified they are never overridden).  Also used by some weird DBDs,
4810 where the column name should be available at bind_param time (e.g. Oracle).
4811
4812 =back
4813
4814 For backwards compatibility and convenience, the following shortcuts are
4815 supported:
4816
4817   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4818   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4819   [ undef,   $val ] === [ {}, $val ]
4820   $val              === [ {}, $val ]
4821
4822 =head1 FURTHER QUESTIONS?
4823
4824 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4825
4826 =head1 COPYRIGHT AND LICENSE
4827
4828 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4829 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4830 redistribute it and/or modify it under the same terms as the
4831 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4832
4833 =cut