lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960
 961   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 962     or return ();
 963   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 964   @new = $self->{_attrs}{record_filter}->(@new)
 965     if exists $self->{_attrs}{record_filter};
 966   return @new;
 967 }
 968
 969 sub _collapse_result {
 970   my ($self, $as_proto, $row) = @_;
 971
 972   # if the first row that ever came in is totally empty - this means we got
 973   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 974   # instead of producing a {}
 975   #
 976   my $has_def;
 977   for (@$row) {
 978     if (defined $_) {
 979       $has_def++;
 980       last;
 981     }
 982   }
 983   return undef unless $has_def;
 984
 985   my @copy = @$row;
 986
 987   # 'foo'         => [ undef, 'foo' ]
 988   # 'foo.bar'     => [ 'foo', 'bar' ]
 989   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 990
 991   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 992
 993   my %collapse = %{$self->{_attrs}{collapse}||{}};
 994
 995   my @pri_index;
 996
 997   # if we're doing collapsing (has_many prefetch) we need to grab records
 998   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 999   # we know we don't have to bother.
1000
1001   # the reason for not using the collapse stuff directly is because if you
1002   # had for e.g. two artists in a row with no cds, the collapse info for
1003   # both would be NULL (undef) so you'd lose the second artist
1004
1005   # store just the index so we can check the array positions from the row
1006   # without having to contruct the full hash
1007
1008   if (keys %collapse) {
1009     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1010     foreach my $i (0 .. $#construct_as) {
1011       next if defined($construct_as[$i][0]); # only self table
1012       if (delete $pri{$construct_as[$i][1]}) {
1013         push(@pri_index, $i);
1014       }
1015       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1016     }
1017   }
1018
1019   # no need to do an if, it'll be empty if @pri_index is empty anyway
1020
1021   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1022
1023   my @const_rows;
1024
1025   do { # no need to check anything at the front, we always want the first row
1026
1027     my %const;
1028
1029     foreach my $this_as (@construct_as) {
1030       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1031     }
1032
1033     push(@const_rows, \%const);
1034
1035   } until ( # no pri_index => no collapse => drop straight out
1036       !@pri_index
1037     or
1038       do { # get another row, stash it, drop out if different PK
1039
1040         @copy = $self->cursor->next;
1041         $self->{stashed_row} = \@copy;
1042
1043         # last thing in do block, counts as true if anything doesn't match
1044
1045         # check xor defined first for NULL vs. NOT NULL then if one is
1046         # defined the other must be so check string equality
1047
1048         grep {
1049           (defined $pri_vals{$_} ^ defined $copy[$_])
1050           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1051         } @pri_index;
1052       }
1053   );
1054
1055   my $alias = $self->{attrs}{alias};
1056   my $info = [];
1057
1058   my %collapse_pos;
1059
1060   my @const_keys;
1061
1062   foreach my $const (@const_rows) {
1063     scalar @const_keys or do {
1064       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1065     };
1066     foreach my $key (@const_keys) {
1067       if (length $key) {
1068         my $target = $info;
1069         my @parts = split(/\./, $key);
1070         my $cur = '';
1071         my $data = $const->{$key};
1072         foreach my $p (@parts) {
1073           $target = $target->[1]->{$p} ||= [];
1074           $cur .= ".${p}";
1075           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1076             # collapsing at this point and on final part
1077             my $pos = $collapse_pos{$cur};
1078             CK: foreach my $ck (@ckey) {
1079               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1080                 $collapse_pos{$cur} = $data;
1081                 delete @collapse_pos{ # clear all positioning for sub-entries
1082                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1083                 };
1084                 push(@$target, []);
1085                 last CK;
1086               }
1087             }
1088           }
1089           if (exists $collapse{$cur}) {
1090             $target = $target->[-1];
1091           }
1092         }
1093         $target->[0] = $data;
1094       } else {
1095         $info->[0] = $const->{$key};
1096       }
1097     }
1098   }
1099
1100   return $info;
1101 }
1102
1103 =head2 result_source
1104
1105 =over 4
1106
1107 =item Arguments: $result_source?
1108
1109 =item Return Value: $result_source
1110
1111 =back
1112
1113 An accessor for the primary ResultSource object from which this ResultSet
1114 is derived.
1115
1116 =head2 result_class
1117
1118 =over 4
1119
1120 =item Arguments: $result_class?
1121
1122 =item Return Value: $result_class
1123
1124 =back
1125
1126 An accessor for the class to use when creating row objects. Defaults to
1127 C<< result_source->result_class >> - which in most cases is the name of the
1128 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1129
1130 Note that changing the result_class will also remove any components
1131 that were originally loaded in the source class via
1132 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1133 in the original source class will not run.
1134
1135 =cut
1136
1137 sub result_class {
1138   my ($self, $result_class) = @_;
1139   if ($result_class) {
1140     $self->ensure_class_loaded($result_class);
1141     $self->_result_class($result_class);
1142   }
1143   $self->_result_class;
1144 }
1145
1146 =head2 count
1147
1148 =over 4
1149
1150 =item Arguments: $cond, \%attrs??
1151
1152 =item Return Value: $count
1153
1154 =back
1155
1156 Performs an SQL C<COUNT> with the same query as the resultset was built
1157 with to find the number of elements. Passing arguments is equivalent to
1158 C<< $rs->search ($cond, \%attrs)->count >>
1159
1160 =cut
1161
1162 sub count {
1163   my $self = shift;
1164   return $self->search(@_)->count if @_ and defined $_[0];
1165   return scalar @{ $self->get_cache } if $self->get_cache;
1166
1167   my $attrs = $self->_resolved_attrs_copy;
1168
1169   # this is a little optimization - it is faster to do the limit
1170   # adjustments in software, instead of a subquery
1171   my $rows = delete $attrs->{rows};
1172   my $offset = delete $attrs->{offset};
1173
1174   my $crs;
1175   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1176     $crs = $self->_count_subq_rs ($attrs);
1177   }
1178   else {
1179     $crs = $self->_count_rs ($attrs);
1180   }
1181   my $count = $crs->next;
1182
1183   $count -= $offset if $offset;
1184   $count = $rows if $rows and $rows < $count;
1185   $count = 0 if ($count < 0);
1186
1187   return $count;
1188 }
1189
1190 =head2 count_rs
1191
1192 =over 4
1193
1194 =item Arguments: $cond, \%attrs??
1195
1196 =item Return Value: $count_rs
1197
1198 =back
1199
1200 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1201 This can be very handy for subqueries:
1202
1203   ->search( { amount => $some_rs->count_rs->as_query } )
1204
1205 As with regular resultsets the SQL query will be executed only after
1206 the resultset is accessed via L</next> or L</all>. That would return
1207 the same single value obtainable via L</count>.
1208
1209 =cut
1210
1211 sub count_rs {
1212   my $self = shift;
1213   return $self->search(@_)->count_rs if @_;
1214
1215   # this may look like a lack of abstraction (count() does about the same)
1216   # but in fact an _rs *must* use a subquery for the limits, as the
1217   # software based limiting can not be ported if this $rs is to be used
1218   # in a subquery itself (i.e. ->as_query)
1219   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1220     return $self->_count_subq_rs;
1221   }
1222   else {
1223     return $self->_count_rs;
1224   }
1225 }
1226
1227 #
1228 # returns a ResultSetColumn object tied to the count query
1229 #
1230 sub _count_rs {
1231   my ($self, $attrs) = @_;
1232
1233   my $rsrc = $self->result_source;
1234   $attrs ||= $self->_resolved_attrs;
1235
1236   my $tmp_attrs = { %$attrs };
1237
1238   # take off any limits, record_filter is cdbi, and no point of ordering a count
1239   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1240
1241   # overwrite the selector (supplied by the storage)
1242   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1243   $tmp_attrs->{as} = 'count';
1244
1245   # read the comment on top of the actual function to see what this does
1246   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1247     $tmp_attrs->{from}, $tmp_attrs->{alias}
1248   );
1249
1250   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1251
1252   return $tmp_rs;
1253 }
1254
1255 #
1256 # same as above but uses a subquery
1257 #
1258 sub _count_subq_rs {
1259   my ($self, $attrs) = @_;
1260
1261   my $rsrc = $self->result_source;
1262   $attrs ||= $self->_resolved_attrs_copy;
1263
1264   my $sub_attrs = { %$attrs };
1265
1266   # extra selectors do not go in the subquery and there is no point of ordering it
1267   delete $sub_attrs->{$_} for qw/collapse prefetch_select select as order_by/;
1268
1269   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1270   # clobber old group_by regardless
1271   if ( keys %{$attrs->{collapse}} ) {
1272     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1273   }
1274
1275   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1276
1277   # read the comment on top of the actual function to see what this does
1278   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1279     $sub_attrs->{from}, $sub_attrs->{alias}
1280   );
1281
1282   $attrs->{from} = [{
1283     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1284   }];
1285
1286   # the subquery replaces this
1287   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1288
1289   return $self->_count_rs ($attrs);
1290 }
1291
1292
1293 # The DBIC relationship chaining implementation is pretty simple - every
1294 # new related_relationship is pushed onto the {from} stack, and the {select}
1295 # window simply slides further in. This means that when we count somewhere
1296 # in the middle, we got to make sure that everything in the join chain is an
1297 # actual inner join, otherwise the count will come back with unpredictable
1298 # results (a resultset may be generated with _some_ rows regardless of if
1299 # the relation which the $rs currently selects has rows or not). E.g.
1300 # $artist_rs->cds->count - normally generates:
1301 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1302 # which actually returns the number of artists * (number of cds || 1)
1303 #
1304 # So what we do here is crawl {from}, determine if the current alias is at
1305 # the top of the stack, and if not - make sure the chain is inner-joined down
1306 # to the root.
1307 #
1308 sub _switch_to_inner_join_if_needed {
1309   my ($self, $from, $alias) = @_;
1310
1311   return $from if (
1312     ref $from ne 'ARRAY'
1313       ||
1314     ref $from->[0] ne 'HASH'
1315       ||
1316     ! $from->[0]{-alias}
1317       ||
1318     $from->[0]{-alias} eq $alias
1319   );
1320
1321   # this would be the case with a subquery - we'll never find
1322   # the target as it is not in the parseable part of {from}
1323   return $from if @$from == 1;
1324
1325   my (@switch_idx, $found_target);
1326
1327   JOINSCAN:
1328   for my $i (1 .. $#$from) {
1329
1330     push @switch_idx, $i;
1331     my $j = $from->[$i];
1332     my $jalias = $j->[0]{-alias};
1333
1334     # we found our current target - delete any siblings (same level joins)
1335     # and bail out
1336     if ($jalias eq $alias) {
1337       $found_target++;
1338
1339       my $cur_depth = $j->[0]{-relation_chain_depth};
1340       # we are -1, so look at -2
1341       while (@switch_idx > 1
1342               && $from->[$switch_idx[-2]][0]{-relation_chain_depth} == $cur_depth
1343       ) {
1344         splice @switch_idx, -2, 1;
1345       }
1346
1347       last JOINSCAN;
1348     }
1349   }
1350
1351   # something else went wrong
1352   return $from unless $found_target;
1353
1354   # So it looks like we will have to switch some stuff around.
1355   # local() is useless here as we will be leaving the scope
1356   # anyway, and deep cloning is just too fucking expensive
1357   # So replace the inner hashref manually
1358   my @new_from;
1359   my $sw_idx = { map { $_ => 1 } @switch_idx };
1360
1361   for my $i (0 .. $#$from) {
1362     if ($sw_idx->{$i}) {
1363       my %attrs = %{$from->[$i][0]};
1364       delete $attrs{-join_type};
1365
1366       push @new_from, [
1367         \%attrs,
1368         @{$from->[$i]}[ 1 .. $#{$from->[$i]} ],
1369       ];
1370     }
1371     else {
1372       push @new_from, $from->[$i];
1373     }
1374   }
1375
1376   return \@new_from;
1377 }
1378
1379
1380 sub _bool {
1381   return 1;
1382 }
1383
1384 =head2 count_literal
1385
1386 =over 4
1387
1388 =item Arguments: $sql_fragment, @bind_values
1389
1390 =item Return Value: $count
1391
1392 =back
1393
1394 Counts the results in a literal query. Equivalent to calling L</search_literal>
1395 with the passed arguments, then L</count>.
1396
1397 =cut
1398
1399 sub count_literal { shift->search_literal(@_)->count; }
1400
1401 =head2 all
1402
1403 =over 4
1404
1405 =item Arguments: none
1406
1407 =item Return Value: @objects
1408
1409 =back
1410
1411 Returns all elements in the resultset. Called implicitly if the resultset
1412 is returned in list context.
1413
1414 =cut
1415
1416 sub all {
1417   my $self = shift;
1418   if(@_) {
1419       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1420   }
1421
1422   return @{ $self->get_cache } if $self->get_cache;
1423
1424   my @obj;
1425
1426   if (keys %{$self->_resolved_attrs->{collapse}}) {
1427     # Using $self->cursor->all is really just an optimisation.
1428     # If we're collapsing has_many prefetches it probably makes
1429     # very little difference, and this is cleaner than hacking
1430     # _construct_object to survive the approach
1431     $self->cursor->reset;
1432     my @row = $self->cursor->next;
1433     while (@row) {
1434       push(@obj, $self->_construct_object(@row));
1435       @row = (exists $self->{stashed_row}
1436                ? @{delete $self->{stashed_row}}
1437                : $self->cursor->next);
1438     }
1439   } else {
1440     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1441   }
1442
1443   $self->set_cache(\@obj) if $self->{attrs}{cache};
1444
1445   return @obj;
1446 }
1447
1448 =head2 reset
1449
1450 =over 4
1451
1452 =item Arguments: none
1453
1454 =item Return Value: $self
1455
1456 =back
1457
1458 Resets the resultset's cursor, so you can iterate through the elements again.
1459 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1460 another query.
1461
1462 =cut
1463
1464 sub reset {
1465   my ($self) = @_;
1466   delete $self->{_attrs} if exists $self->{_attrs};
1467   $self->{all_cache_position} = 0;
1468   $self->cursor->reset;
1469   return $self;
1470 }
1471
1472 =head2 first
1473
1474 =over 4
1475
1476 =item Arguments: none
1477
1478 =item Return Value: $object?
1479
1480 =back
1481
1482 Resets the resultset and returns an object for the first result (if the
1483 resultset returns anything).
1484
1485 =cut
1486
1487 sub first {
1488   return $_[0]->reset->next;
1489 }
1490
1491
1492 # _rs_update_delete
1493 #
1494 # Determines whether and what type of subquery is required for the $rs operation.
1495 # If grouping is necessary either supplies its own, or verifies the current one
1496 # After all is done delegates to the proper storage method.
1497
1498 sub _rs_update_delete {
1499   my ($self, $op, $values) = @_;
1500
1501   my $rsrc = $self->result_source;
1502
1503   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1504   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1505
1506   if ($needs_group_by_subq or $needs_subq) {
1507
1508     # make a new $rs selecting only the PKs (that's all we really need)
1509     my $attrs = $self->_resolved_attrs_copy;
1510
1511     delete $attrs->{$_} for qw/collapse select as/;
1512     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1513
1514     if ($needs_group_by_subq) {
1515       # make sure no group_by was supplied, or if there is one - make sure it matches
1516       # the columns compiled above perfectly. Anything else can not be sanely executed
1517       # on most databases so croak right then and there
1518
1519       if (my $g = $attrs->{group_by}) {
1520         my @current_group_by = map
1521           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1522           (ref $g eq 'ARRAY' ? @$g : $g );
1523
1524         if (
1525           join ("\x00", sort @current_group_by)
1526             ne
1527           join ("\x00", sort @{$attrs->{columns}} )
1528         ) {
1529           $self->throw_exception (
1530             "You have just attempted a $op operation on a resultset which does group_by"
1531             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1532             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1533             . ' kind of queries. Please retry the operation with a modified group_by or'
1534             . ' without using one at all.'
1535           );
1536         }
1537       }
1538       else {
1539         $attrs->{group_by} = $attrs->{columns};
1540       }
1541     }
1542
1543     my $subrs = (ref $self)->new($rsrc, $attrs);
1544
1545     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1546   }
1547   else {
1548     return $rsrc->storage->$op(
1549       $rsrc,
1550       $op eq 'update' ? $values : (),
1551       $self->_cond_for_update_delete,
1552     );
1553   }
1554 }
1555
1556
1557 # _cond_for_update_delete
1558 #
1559 # update/delete require the condition to be modified to handle
1560 # the differing SQL syntax available.  This transforms the $self->{cond}
1561 # appropriately, returning the new condition.
1562
1563 sub _cond_for_update_delete {
1564   my ($self, $full_cond) = @_;
1565   my $cond = {};
1566
1567   $full_cond ||= $self->{cond};
1568   # No-op. No condition, we're updating/deleting everything
1569   return $cond unless ref $full_cond;
1570
1571   if (ref $full_cond eq 'ARRAY') {
1572     $cond = [
1573       map {
1574         my %hash;
1575         foreach my $key (keys %{$_}) {
1576           $key =~ /([^.]+)$/;
1577           $hash{$1} = $_->{$key};
1578         }
1579         \%hash;
1580       } @{$full_cond}
1581     ];
1582   }
1583   elsif (ref $full_cond eq 'HASH') {
1584     if ((keys %{$full_cond})[0] eq '-and') {
1585       $cond->{-and} = [];
1586       my @cond = @{$full_cond->{-and}};
1587        for (my $i = 0; $i < @cond; $i++) {
1588         my $entry = $cond[$i];
1589         my $hash;
1590         if (ref $entry eq 'HASH') {
1591           $hash = $self->_cond_for_update_delete($entry);
1592         }
1593         else {
1594           $entry =~ /([^.]+)$/;
1595           $hash->{$1} = $cond[++$i];
1596         }
1597         push @{$cond->{-and}}, $hash;
1598       }
1599     }
1600     else {
1601       foreach my $key (keys %{$full_cond}) {
1602         $key =~ /([^.]+)$/;
1603         $cond->{$1} = $full_cond->{$key};
1604       }
1605     }
1606   }
1607   else {
1608     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1609   }
1610
1611   return $cond;
1612 }
1613
1614
1615 =head2 update
1616
1617 =over 4
1618
1619 =item Arguments: \%values
1620
1621 =item Return Value: $storage_rv
1622
1623 =back
1624
1625 Sets the specified columns in the resultset to the supplied values in a
1626 single query. Return value will be true if the update succeeded or false
1627 if no records were updated; exact type of success value is storage-dependent.
1628
1629 =cut
1630
1631 sub update {
1632   my ($self, $values) = @_;
1633   $self->throw_exception('Values for update must be a hash')
1634     unless ref $values eq 'HASH';
1635
1636   return $self->_rs_update_delete ('update', $values);
1637 }
1638
1639 =head2 update_all
1640
1641 =over 4
1642
1643 =item Arguments: \%values
1644
1645 =item Return Value: 1
1646
1647 =back
1648
1649 Fetches all objects and updates them one at a time. Note that C<update_all>
1650 will run DBIC cascade triggers, while L</update> will not.
1651
1652 =cut
1653
1654 sub update_all {
1655   my ($self, $values) = @_;
1656   $self->throw_exception('Values for update_all must be a hash')
1657     unless ref $values eq 'HASH';
1658   foreach my $obj ($self->all) {
1659     $obj->set_columns($values)->update;
1660   }
1661   return 1;
1662 }
1663
1664 =head2 delete
1665
1666 =over 4
1667
1668 =item Arguments: none
1669
1670 =item Return Value: $storage_rv
1671
1672 =back
1673
1674 Deletes the contents of the resultset from its result source. Note that this
1675 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1676 to run. See also L<DBIx::Class::Row/delete>.
1677
1678 Return value will be the amount of rows deleted; exact type of return value
1679 is storage-dependent.
1680
1681 =cut
1682
1683 sub delete {
1684   my $self = shift;
1685   $self->throw_exception('delete does not accept any arguments')
1686     if @_;
1687
1688   return $self->_rs_update_delete ('delete');
1689 }
1690
1691 =head2 delete_all
1692
1693 =over 4
1694
1695 =item Arguments: none
1696
1697 =item Return Value: 1
1698
1699 =back
1700
1701 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1702 will run DBIC cascade triggers, while L</delete> will not.
1703
1704 =cut
1705
1706 sub delete_all {
1707   my $self = shift;
1708   $self->throw_exception('delete_all does not accept any arguments')
1709     if @_;
1710
1711   $_->delete for $self->all;
1712   return 1;
1713 }
1714
1715 =head2 populate
1716
1717 =over 4
1718
1719 =item Arguments: \@data;
1720
1721 =back
1722
1723 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1724 For the arrayref of hashrefs style each hashref should be a structure suitable
1725 forsubmitting to a $resultset->create(...) method.
1726
1727 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1728 to insert the data, as this is a faster method.
1729
1730 Otherwise, each set of data is inserted into the database using
1731 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1732 accumulated into an array. The array itself, or an array reference
1733 is returned depending on scalar or list context.
1734
1735 Example:  Assuming an Artist Class that has many CDs Classes relating:
1736
1737   my $Artist_rs = $schema->resultset("Artist");
1738
1739   ## Void Context Example
1740   $Artist_rs->populate([
1741      { artistid => 4, name => 'Manufactured Crap', cds => [
1742         { title => 'My First CD', year => 2006 },
1743         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1744       ],
1745      },
1746      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1747         { title => 'My parents sold me to a record company' ,year => 2005 },
1748         { title => 'Why Am I So Ugly?', year => 2006 },
1749         { title => 'I Got Surgery and am now Popular', year => 2007 }
1750       ],
1751      },
1752   ]);
1753
1754   ## Array Context Example
1755   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1756     { name => "Artist One"},
1757     { name => "Artist Two"},
1758     { name => "Artist Three", cds=> [
1759     { title => "First CD", year => 2007},
1760     { title => "Second CD", year => 2008},
1761   ]}
1762   ]);
1763
1764   print $ArtistOne->name; ## response is 'Artist One'
1765   print $ArtistThree->cds->count ## reponse is '2'
1766
1767 For the arrayref of arrayrefs style,  the first element should be a list of the
1768 fieldsnames to which the remaining elements are rows being inserted.  For
1769 example:
1770
1771   $Arstist_rs->populate([
1772     [qw/artistid name/],
1773     [100, 'A Formally Unknown Singer'],
1774     [101, 'A singer that jumped the shark two albums ago'],
1775     [102, 'An actually cool singer.'],
1776   ]);
1777
1778 Please note an important effect on your data when choosing between void and
1779 wantarray context. Since void context goes straight to C<insert_bulk> in
1780 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1781 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1782 create primary keys for you, you will find that your PKs are empty.  In this
1783 case you will have to use the wantarray context in order to create those
1784 values.
1785
1786 =cut
1787
1788 sub populate {
1789   my $self = shift @_;
1790   my $data = ref $_[0][0] eq 'HASH'
1791     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1792     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1793
1794   if(defined wantarray) {
1795     my @created;
1796     foreach my $item (@$data) {
1797       push(@created, $self->create($item));
1798     }
1799     return wantarray ? @created : \@created;
1800   } else {
1801     my ($first, @rest) = @$data;
1802
1803     my @names = grep {!ref $first->{$_}} keys %$first;
1804     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1805     my @pks = $self->result_source->primary_columns;
1806
1807     ## do the belongs_to relationships
1808     foreach my $index (0..$#$data) {
1809
1810       # delegate to create() for any dataset without primary keys with specified relationships
1811       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1812         for my $r (@rels) {
1813           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1814             my @ret = $self->populate($data);
1815             return;
1816           }
1817         }
1818       }
1819
1820       foreach my $rel (@rels) {
1821         next unless ref $data->[$index]->{$rel} eq "HASH";
1822         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1823         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1824         my $related = $result->result_source->_resolve_condition(
1825           $result->result_source->relationship_info($reverse)->{cond},
1826           $self,
1827           $result,
1828         );
1829
1830         delete $data->[$index]->{$rel};
1831         $data->[$index] = {%{$data->[$index]}, %$related};
1832
1833         push @names, keys %$related if $index == 0;
1834       }
1835     }
1836
1837     ## do bulk insert on current row
1838     my @values = map { [ @$_{@names} ] } @$data;
1839
1840     $self->result_source->storage->insert_bulk(
1841       $self->result_source,
1842       \@names,
1843       \@values,
1844     );
1845
1846     ## do the has_many relationships
1847     foreach my $item (@$data) {
1848
1849       foreach my $rel (@rels) {
1850         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1851
1852         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1853      || $self->throw_exception('Cannot find the relating object.');
1854
1855         my $child = $parent->$rel;
1856
1857         my $related = $child->result_source->_resolve_condition(
1858           $parent->result_source->relationship_info($rel)->{cond},
1859           $child,
1860           $parent,
1861         );
1862
1863         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1864         my @populate = map { {%$_, %$related} } @rows_to_add;
1865
1866         $child->populate( \@populate );
1867       }
1868     }
1869   }
1870 }
1871
1872 =head2 _normalize_populate_args ($args)
1873
1874 Private method used by L</populate> to normalize its incoming arguments.  Factored
1875 out in case you want to subclass and accept new argument structures to the
1876 L</populate> method.
1877
1878 =cut
1879
1880 sub _normalize_populate_args {
1881   my ($self, $data) = @_;
1882   my @names = @{shift(@$data)};
1883   my @results_to_create;
1884   foreach my $datum (@$data) {
1885     my %result_to_create;
1886     foreach my $index (0..$#names) {
1887       $result_to_create{$names[$index]} = $$datum[$index];
1888     }
1889     push @results_to_create, \%result_to_create;
1890   }
1891   return \@results_to_create;
1892 }
1893
1894 =head2 pager
1895
1896 =over 4
1897
1898 =item Arguments: none
1899
1900 =item Return Value: $pager
1901
1902 =back
1903
1904 Return Value a L<Data::Page> object for the current resultset. Only makes
1905 sense for queries with a C<page> attribute.
1906
1907 To get the full count of entries for a paged resultset, call
1908 C<total_entries> on the L<Data::Page> object.
1909
1910 =cut
1911
1912 sub pager {
1913   my ($self) = @_;
1914
1915   return $self->{pager} if $self->{pager};
1916
1917   my $attrs = $self->{attrs};
1918   $self->throw_exception("Can't create pager for non-paged rs")
1919     unless $self->{attrs}{page};
1920   $attrs->{rows} ||= 10;
1921
1922   # throw away the paging flags and re-run the count (possibly
1923   # with a subselect) to get the real total count
1924   my $count_attrs = { %$attrs };
1925   delete $count_attrs->{$_} for qw/rows offset page pager/;
1926   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1927
1928   return $self->{pager} = Data::Page->new(
1929     $total_count,
1930     $attrs->{rows},
1931     $self->{attrs}{page}
1932   );
1933 }
1934
1935 =head2 page
1936
1937 =over 4
1938
1939 =item Arguments: $page_number
1940
1941 =item Return Value: $rs
1942
1943 =back
1944
1945 Returns a resultset for the $page_number page of the resultset on which page
1946 is called, where each page contains a number of rows equal to the 'rows'
1947 attribute set on the resultset (10 by default).
1948
1949 =cut
1950
1951 sub page {
1952   my ($self, $page) = @_;
1953   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1954 }
1955
1956 =head2 new_result
1957
1958 =over 4
1959
1960 =item Arguments: \%vals
1961
1962 =item Return Value: $rowobject
1963
1964 =back
1965
1966 Creates a new row object in the resultset's result class and returns
1967 it. The row is not inserted into the database at this point, call
1968 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1969 will tell you whether the row object has been inserted or not.
1970
1971 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1972
1973 =cut
1974
1975 sub new_result {
1976   my ($self, $values) = @_;
1977   $self->throw_exception( "new_result needs a hash" )
1978     unless (ref $values eq 'HASH');
1979
1980   my %new;
1981   my $alias = $self->{attrs}{alias};
1982
1983   if (
1984     defined $self->{cond}
1985     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1986   ) {
1987     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1988     $new{-from_resultset} = [ keys %new ] if keys %new;
1989   } else {
1990     $self->throw_exception(
1991       "Can't abstract implicit construct, condition not a hash"
1992     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1993
1994     my $collapsed_cond = (
1995       $self->{cond}
1996         ? $self->_collapse_cond($self->{cond})
1997         : {}
1998     );
1999
2000     # precendence must be given to passed values over values inherited from
2001     # the cond, so the order here is important.
2002     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
2003     while( my($col,$value) = each %implied ){
2004       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
2005         $new{$col} = $value->{'='};
2006         next;
2007       }
2008       $new{$col} = $value if $self->_is_deterministic_value($value);
2009     }
2010   }
2011
2012   %new = (
2013     %new,
2014     %{ $self->_remove_alias($values, $alias) },
2015     -source_handle => $self->_source_handle,
2016     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2017   );
2018
2019   return $self->result_class->new(\%new);
2020 }
2021
2022 # _is_deterministic_value
2023 #
2024 # Make an effor to strip non-deterministic values from the condition,
2025 # to make sure new_result chokes less
2026
2027 sub _is_deterministic_value {
2028   my $self = shift;
2029   my $value = shift;
2030   my $ref_type = ref $value;
2031   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2032   return 1 if Scalar::Util::blessed($value);
2033   return 0;
2034 }
2035
2036 # _has_resolved_attr
2037 #
2038 # determines if the resultset defines at least one
2039 # of the attributes supplied
2040 #
2041 # used to determine if a subquery is neccessary
2042 #
2043 # supports some virtual attributes:
2044 #   -join
2045 #     This will scan for any joins being present on the resultset.
2046 #     It is not a mere key-search but a deep inspection of {from}
2047 #
2048
2049 sub _has_resolved_attr {
2050   my ($self, @attr_names) = @_;
2051
2052   my $attrs = $self->_resolved_attrs;
2053
2054   my %extra_checks;
2055
2056   for my $n (@attr_names) {
2057     if (grep { $n eq $_ } (qw/-join/) ) {
2058       $extra_checks{$n}++;
2059       next;
2060     }
2061
2062     my $attr =  $attrs->{$n};
2063
2064     next if not defined $attr;
2065
2066     if (ref $attr eq 'HASH') {
2067       return 1 if keys %$attr;
2068     }
2069     elsif (ref $attr eq 'ARRAY') {
2070       return 1 if @$attr;
2071     }
2072     else {
2073       return 1 if $attr;
2074     }
2075   }
2076
2077   # a resolved join is expressed as a multi-level from
2078   return 1 if (
2079     $extra_checks{-join}
2080       and
2081     ref $attrs->{from} eq 'ARRAY'
2082       and
2083     @{$attrs->{from}} > 1
2084   );
2085
2086   return 0;
2087 }
2088
2089 # _collapse_cond
2090 #
2091 # Recursively collapse the condition.
2092
2093 sub _collapse_cond {
2094   my ($self, $cond, $collapsed) = @_;
2095
2096   $collapsed ||= {};
2097
2098   if (ref $cond eq 'ARRAY') {
2099     foreach my $subcond (@$cond) {
2100       next unless ref $subcond;  # -or
2101       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2102     }
2103   }
2104   elsif (ref $cond eq 'HASH') {
2105     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2106       foreach my $subcond (@{$cond->{-and}}) {
2107         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2108       }
2109     }
2110     else {
2111       foreach my $col (keys %$cond) {
2112         my $value = $cond->{$col};
2113         $collapsed->{$col} = $value;
2114       }
2115     }
2116   }
2117
2118   return $collapsed;
2119 }
2120
2121 # _remove_alias
2122 #
2123 # Remove the specified alias from the specified query hash. A copy is made so
2124 # the original query is not modified.
2125
2126 sub _remove_alias {
2127   my ($self, $query, $alias) = @_;
2128
2129   my %orig = %{ $query || {} };
2130   my %unaliased;
2131
2132   foreach my $key (keys %orig) {
2133     if ($key !~ /\./) {
2134       $unaliased{$key} = $orig{$key};
2135       next;
2136     }
2137     $unaliased{$1} = $orig{$key}
2138       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2139   }
2140
2141   return \%unaliased;
2142 }
2143
2144 =head2 as_query (EXPERIMENTAL)
2145
2146 =over 4
2147
2148 =item Arguments: none
2149
2150 =item Return Value: \[ $sql, @bind ]
2151
2152 =back
2153
2154 Returns the SQL query and bind vars associated with the invocant.
2155
2156 This is generally used as the RHS for a subquery.
2157
2158 B<NOTE>: This feature is still experimental.
2159
2160 =cut
2161
2162 sub as_query {
2163   my $self = shift;
2164
2165   my $attrs = $self->_resolved_attrs_copy;
2166
2167   # For future use:
2168   #
2169   # in list ctx:
2170   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2171   # $sql also has no wrapping parenthesis in list ctx
2172   #
2173   my $sqlbind = $self->result_source->storage
2174     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2175
2176   return $sqlbind;
2177 }
2178
2179 =head2 find_or_new
2180
2181 =over 4
2182
2183 =item Arguments: \%vals, \%attrs?
2184
2185 =item Return Value: $rowobject
2186
2187 =back
2188
2189   my $artist = $schema->resultset('Artist')->find_or_new(
2190     { artist => 'fred' }, { key => 'artists' });
2191
2192   $cd->cd_to_producer->find_or_new({ producer => $producer },
2193                                    { key => 'primary });
2194
2195 Find an existing record from this resultset, based on its primary
2196 key, or a unique constraint. If none exists, instantiate a new result
2197 object and return it. The object will not be saved into your storage
2198 until you call L<DBIx::Class::Row/insert> on it.
2199
2200 You most likely want this method when looking for existing rows using
2201 a unique constraint that is not the primary key, or looking for
2202 related rows.
2203
2204 If you want objects to be saved immediately, use L</find_or_create> instead.
2205
2206 B<Note>: C<find_or_new> is probably not what you want when creating a
2207 new row in a table that uses primary keys supplied by the
2208 database. Passing in a primary key column with a value of I<undef>
2209 will cause L</find> to attempt to search for a row with a value of
2210 I<NULL>.
2211
2212 =cut
2213
2214 sub find_or_new {
2215   my $self     = shift;
2216   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2217   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2218   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2219     return $row;
2220   }
2221   return $self->new_result($hash);
2222 }
2223
2224 =head2 create
2225
2226 =over 4
2227
2228 =item Arguments: \%vals
2229
2230 =item Return Value: a L<DBIx::Class::Row> $object
2231
2232 =back
2233
2234 Attempt to create a single new row or a row with multiple related rows
2235 in the table represented by the resultset (and related tables). This
2236 will not check for duplicate rows before inserting, use
2237 L</find_or_create> to do that.
2238
2239 To create one row for this resultset, pass a hashref of key/value
2240 pairs representing the columns of the table and the values you wish to
2241 store. If the appropriate relationships are set up, foreign key fields
2242 can also be passed an object representing the foreign row, and the
2243 value will be set to its primary key.
2244
2245 To create related objects, pass a hashref for the value if the related
2246 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2247 and use the name of the relationship as the key. (NOT the name of the field,
2248 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2249 of hashrefs containing the data for each of the rows to create in the foreign
2250 tables, again using the relationship name as the key.
2251
2252 Instead of hashrefs of plain related data (key/value pairs), you may
2253 also pass new or inserted objects. New objects (not inserted yet, see
2254 L</new>), will be inserted into their appropriate tables.
2255
2256 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2257
2258 Example of creating a new row.
2259
2260   $person_rs->create({
2261     name=>"Some Person",
2262     email=>"somebody@someplace.com"
2263   });
2264
2265 Example of creating a new row and also creating rows in a related C<has_many>
2266 or C<has_one> resultset.  Note Arrayref.
2267
2268   $artist_rs->create(
2269      { artistid => 4, name => 'Manufactured Crap', cds => [
2270         { title => 'My First CD', year => 2006 },
2271         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2272       ],
2273      },
2274   );
2275
2276 Example of creating a new row and also creating a row in a related
2277 C<belongs_to>resultset. Note Hashref.
2278
2279   $cd_rs->create({
2280     title=>"Music for Silly Walks",
2281     year=>2000,
2282     artist => {
2283       name=>"Silly Musician",
2284     }
2285   });
2286
2287 =cut
2288
2289 sub create {
2290   my ($self, $attrs) = @_;
2291   $self->throw_exception( "create needs a hashref" )
2292     unless ref $attrs eq 'HASH';
2293   return $self->new_result($attrs)->insert;
2294 }
2295
2296 =head2 find_or_create
2297
2298 =over 4
2299
2300 =item Arguments: \%vals, \%attrs?
2301
2302 =item Return Value: $rowobject
2303
2304 =back
2305
2306   $cd->cd_to_producer->find_or_create({ producer => $producer },
2307                                       { key => 'primary' });
2308
2309 Tries to find a record based on its primary key or unique constraints; if none
2310 is found, creates one and returns that instead.
2311
2312   my $cd = $schema->resultset('CD')->find_or_create({
2313     cdid   => 5,
2314     artist => 'Massive Attack',
2315     title  => 'Mezzanine',
2316     year   => 2005,
2317   });
2318
2319 Also takes an optional C<key> attribute, to search by a specific key or unique
2320 constraint. For example:
2321
2322   my $cd = $schema->resultset('CD')->find_or_create(
2323     {
2324       artist => 'Massive Attack',
2325       title  => 'Mezzanine',
2326     },
2327     { key => 'cd_artist_title' }
2328   );
2329
2330 B<Note>: Because find_or_create() reads from the database and then
2331 possibly inserts based on the result, this method is subject to a race
2332 condition. Another process could create a record in the table after
2333 the find has completed and before the create has started. To avoid
2334 this problem, use find_or_create() inside a transaction.
2335
2336 B<Note>: C<find_or_create> is probably not what you want when creating
2337 a new row in a table that uses primary keys supplied by the
2338 database. Passing in a primary key column with a value of I<undef>
2339 will cause L</find> to attempt to search for a row with a value of
2340 I<NULL>.
2341
2342 See also L</find> and L</update_or_create>. For information on how to declare
2343 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2344
2345 =cut
2346
2347 sub find_or_create {
2348   my $self     = shift;
2349   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2350   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2351   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2352     return $row;
2353   }
2354   return $self->create($hash);
2355 }
2356
2357 =head2 update_or_create
2358
2359 =over 4
2360
2361 =item Arguments: \%col_values, { key => $unique_constraint }?
2362
2363 =item Return Value: $rowobject
2364
2365 =back
2366
2367   $resultset->update_or_create({ col => $val, ... });
2368
2369 First, searches for an existing row matching one of the unique constraints
2370 (including the primary key) on the source of this resultset. If a row is
2371 found, updates it with the other given column values. Otherwise, creates a new
2372 row.
2373
2374 Takes an optional C<key> attribute to search on a specific unique constraint.
2375 For example:
2376
2377   # In your application
2378   my $cd = $schema->resultset('CD')->update_or_create(
2379     {
2380       artist => 'Massive Attack',
2381       title  => 'Mezzanine',
2382       year   => 1998,
2383     },
2384     { key => 'cd_artist_title' }
2385   );
2386
2387   $cd->cd_to_producer->update_or_create({
2388     producer => $producer,
2389     name => 'harry',
2390   }, {
2391     key => 'primary,
2392   });
2393
2394
2395 If no C<key> is specified, it searches on all unique constraints defined on the
2396 source, including the primary key.
2397
2398 If the C<key> is specified as C<primary>, it searches only on the primary key.
2399
2400 See also L</find> and L</find_or_create>. For information on how to declare
2401 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2402
2403 B<Note>: C<update_or_create> is probably not what you want when
2404 looking for a row in a table that uses primary keys supplied by the
2405 database, unless you actually have a key value. Passing in a primary
2406 key column with a value of I<undef> will cause L</find> to attempt to
2407 search for a row with a value of I<NULL>.
2408
2409 =cut
2410
2411 sub update_or_create {
2412   my $self = shift;
2413   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2414   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2415
2416   my $row = $self->find($cond, $attrs);
2417   if (defined $row) {
2418     $row->update($cond);
2419     return $row;
2420   }
2421
2422   return $self->create($cond);
2423 }
2424
2425 =head2 update_or_new
2426
2427 =over 4
2428
2429 =item Arguments: \%col_values, { key => $unique_constraint }?
2430
2431 =item Return Value: $rowobject
2432
2433 =back
2434
2435   $resultset->update_or_new({ col => $val, ... });
2436
2437 First, searches for an existing row matching one of the unique constraints
2438 (including the primary key) on the source of this resultset. If a row is
2439 found, updates it with the other given column values. Otherwise, instantiate
2440 a new result object and return it. The object will not be saved into your storage
2441 until you call L<DBIx::Class::Row/insert> on it.
2442
2443 Takes an optional C<key> attribute to search on a specific unique constraint.
2444 For example:
2445
2446   # In your application
2447   my $cd = $schema->resultset('CD')->update_or_new(
2448     {
2449       artist => 'Massive Attack',
2450       title  => 'Mezzanine',
2451       year   => 1998,
2452     },
2453     { key => 'cd_artist_title' }
2454   );
2455
2456   if ($cd->in_storage) {
2457       # the cd was updated
2458   }
2459   else {
2460       # the cd is not yet in the database, let's insert it
2461       $cd->insert;
2462   }
2463
2464 See also L</find>, L</find_or_create> and L<find_or_new>.
2465
2466 =cut
2467
2468 sub update_or_new {
2469     my $self  = shift;
2470     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2471     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2472
2473     my $row = $self->find( $cond, $attrs );
2474     if ( defined $row ) {
2475         $row->update($cond);
2476         return $row;
2477     }
2478
2479     return $self->new_result($cond);
2480 }
2481
2482 =head2 get_cache
2483
2484 =over 4
2485
2486 =item Arguments: none
2487
2488 =item Return Value: \@cache_objects?
2489
2490 =back
2491
2492 Gets the contents of the cache for the resultset, if the cache is set.
2493
2494 The cache is populated either by using the L</prefetch> attribute to
2495 L</search> or by calling L</set_cache>.
2496
2497 =cut
2498
2499 sub get_cache {
2500   shift->{all_cache};
2501 }
2502
2503 =head2 set_cache
2504
2505 =over 4
2506
2507 =item Arguments: \@cache_objects
2508
2509 =item Return Value: \@cache_objects
2510
2511 =back
2512
2513 Sets the contents of the cache for the resultset. Expects an arrayref
2514 of objects of the same class as those produced by the resultset. Note that
2515 if the cache is set the resultset will return the cached objects rather
2516 than re-querying the database even if the cache attr is not set.
2517
2518 The contents of the cache can also be populated by using the
2519 L</prefetch> attribute to L</search>.
2520
2521 =cut
2522
2523 sub set_cache {
2524   my ( $self, $data ) = @_;
2525   $self->throw_exception("set_cache requires an arrayref")
2526       if defined($data) && (ref $data ne 'ARRAY');
2527   $self->{all_cache} = $data;
2528 }
2529
2530 =head2 clear_cache
2531
2532 =over 4
2533
2534 =item Arguments: none
2535
2536 =item Return Value: []
2537
2538 =back
2539
2540 Clears the cache for the resultset.
2541
2542 =cut
2543
2544 sub clear_cache {
2545   shift->set_cache(undef);
2546 }
2547
2548 =head2 related_resultset
2549
2550 =over 4
2551
2552 =item Arguments: $relationship_name
2553
2554 =item Return Value: $resultset
2555
2556 =back
2557
2558 Returns a related resultset for the supplied relationship name.
2559
2560   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2561
2562 =cut
2563
2564 sub related_resultset {
2565   my ($self, $rel) = @_;
2566
2567   $self->{related_resultsets} ||= {};
2568   return $self->{related_resultsets}{$rel} ||= do {
2569     my $rel_info = $self->result_source->relationship_info($rel);
2570
2571     $self->throw_exception(
2572       "search_related: result source '" . $self->result_source->source_name .
2573         "' has no such relationship $rel")
2574       unless $rel_info;
2575
2576     my ($from,$seen) = $self->_chain_relationship($rel);
2577
2578     my $join_count = $seen->{$rel};
2579     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2580
2581     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2582     my %attrs = %{$self->{attrs}||{}};
2583     delete @attrs{qw(result_class alias)};
2584
2585     my $new_cache;
2586
2587     if (my $cache = $self->get_cache) {
2588       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2589         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2590                         @$cache ];
2591       }
2592     }
2593
2594     my $rel_source = $self->result_source->related_source($rel);
2595
2596     my $new = do {
2597
2598       # The reason we do this now instead of passing the alias to the
2599       # search_rs below is that if you wrap/overload resultset on the
2600       # source you need to know what alias it's -going- to have for things
2601       # to work sanely (e.g. RestrictWithObject wants to be able to add
2602       # extra query restrictions, and these may need to be $alias.)
2603
2604       my $attrs = $rel_source->resultset_attributes;
2605       local $attrs->{alias} = $alias;
2606
2607       $rel_source->resultset
2608                  ->search_rs(
2609                      undef, {
2610                        %attrs,
2611                        join => undef,
2612                        prefetch => undef,
2613                        select => undef,
2614                        as => undef,
2615                        where => $self->{cond},
2616                        seen_join => $seen,
2617                        from => $from,
2618                    });
2619     };
2620     $new->set_cache($new_cache) if $new_cache;
2621     $new;
2622   };
2623 }
2624
2625 =head2 current_source_alias
2626
2627 =over 4
2628
2629 =item Arguments: none
2630
2631 =item Return Value: $source_alias
2632
2633 =back
2634
2635 Returns the current table alias for the result source this resultset is built
2636 on, that will be used in the SQL query. Usually it is C<me>.
2637
2638 Currently the source alias that refers to the result set returned by a
2639 L</search>/L</find> family method depends on how you got to the resultset: it's
2640 C<me> by default, but eg. L</search_related> aliases it to the related result
2641 source name (and keeps C<me> referring to the original result set). The long
2642 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2643 (and make this method unnecessary).
2644
2645 Thus it's currently necessary to use this method in predefined queries (see
2646 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2647 source alias of the current result set:
2648
2649   # in a result set class
2650   sub modified_by {
2651     my ($self, $user) = @_;
2652
2653     my $me = $self->current_source_alias;
2654
2655     return $self->search(
2656       "$me.modified" => $user->id,
2657     );
2658   }
2659
2660 =cut
2661
2662 sub current_source_alias {
2663   my ($self) = @_;
2664
2665   return ($self->{attrs} || {})->{alias} || 'me';
2666 }
2667
2668 # This code is called by search_related, and makes sure there
2669 # is clear separation between the joins before, during, and
2670 # after the relationship. This information is needed later
2671 # in order to properly resolve prefetch aliases (any alias
2672 # with a relation_chain_depth less than the depth of the
2673 # current prefetch is not considered)
2674 sub _chain_relationship {
2675   my ($self, $rel) = @_;
2676   my $source = $self->result_source;
2677   my $attrs = $self->{attrs};
2678
2679   my $from = [ @{
2680       $attrs->{from}
2681         ||
2682       [{
2683         -source_handle => $source->handle,
2684         -alias => $attrs->{alias},
2685         $attrs->{alias} => $source->from,
2686       }]
2687   }];
2688
2689   my $seen = { %{$attrs->{seen_join} || {} } };
2690
2691   # we need to take the prefetch the attrs into account before we
2692   # ->_resolve_join as otherwise they get lost - captainL
2693   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2694
2695   my @requested_joins = $source->_resolve_join($merged, $attrs->{alias}, $seen);
2696
2697   push @$from, @requested_joins;
2698
2699   ++$seen->{-relation_chain_depth};
2700
2701   # if $self already had a join/prefetch specified on it, the requested
2702   # $rel might very well be already included. What we do in this case
2703   # is effectively a no-op (except that we bump up the chain_depth on
2704   # the join in question so we could tell it *is* the search_related)
2705   my $already_joined;
2706
2707   # we consider the last one thus reverse
2708   for my $j (reverse @requested_joins) {
2709     if ($rel eq $j->[0]{-join_path}[-1]) {
2710       $j->[0]{-relation_chain_depth}++;
2711       $already_joined++;
2712       last;
2713     }
2714   }
2715   unless ($already_joined) {
2716     push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2717   }
2718
2719   ++$seen->{-relation_chain_depth};
2720
2721   return ($from,$seen);
2722 }
2723
2724 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2725 sub _resolved_attrs_copy {
2726   my $self = shift;
2727   return { %{$self->_resolved_attrs (@_)} };
2728 }
2729
2730 sub _resolved_attrs {
2731   my $self = shift;
2732   return $self->{_attrs} if $self->{_attrs};
2733
2734   my $attrs  = { %{ $self->{attrs} || {} } };
2735   my $source = $self->result_source;
2736   my $alias  = $attrs->{alias};
2737
2738   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2739   my @colbits;
2740
2741   # build columns (as long as select isn't set) into a set of as/select hashes
2742   unless ( $attrs->{select} ) {
2743       @colbits = map {
2744           ( ref($_) eq 'HASH' )
2745               ? $_
2746               : {
2747                   (
2748                     /^\Q${alias}.\E(.+)$/
2749                       ? "$1"
2750                       : "$_"
2751                   )
2752                 =>
2753                   (
2754                     /\./
2755                       ? "$_"
2756                       : "${alias}.$_"
2757                   )
2758             }
2759       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2760   }
2761   # add the additional columns on
2762   foreach ( 'include_columns', '+columns' ) {
2763       push @colbits, map {
2764           ( ref($_) eq 'HASH' )
2765             ? $_
2766             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2767       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2768   }
2769
2770   # start with initial select items
2771   if ( $attrs->{select} ) {
2772     $attrs->{select} =
2773         ( ref $attrs->{select} eq 'ARRAY' )
2774       ? [ @{ $attrs->{select} } ]
2775       : [ $attrs->{select} ];
2776     $attrs->{as} = (
2777       $attrs->{as}
2778       ? (
2779         ref $attrs->{as} eq 'ARRAY'
2780         ? [ @{ $attrs->{as} } ]
2781         : [ $attrs->{as} ]
2782         )
2783       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2784     );
2785   }
2786   else {
2787
2788     # otherwise we intialise select & as to empty
2789     $attrs->{select} = [];
2790     $attrs->{as}     = [];
2791   }
2792
2793   # now add colbits to select/as
2794   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2795   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2796
2797   my $adds;
2798   if ( $adds = delete $attrs->{'+select'} ) {
2799     $adds = [$adds] unless ref $adds eq 'ARRAY';
2800     push(
2801       @{ $attrs->{select} },
2802       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2803     );
2804   }
2805   if ( $adds = delete $attrs->{'+as'} ) {
2806     $adds = [$adds] unless ref $adds eq 'ARRAY';
2807     push( @{ $attrs->{as} }, @$adds );
2808   }
2809
2810   $attrs->{from} ||= [ {
2811     -source_handle => $source->handle,
2812     -alias => $self->{attrs}{alias},
2813     $self->{attrs}{alias} => $source->from,
2814   } ];
2815
2816   if ( $attrs->{join} || $attrs->{prefetch} ) {
2817
2818     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2819       if ref $attrs->{from} ne 'ARRAY';
2820
2821     my $join = delete $attrs->{join} || {};
2822
2823     if ( defined $attrs->{prefetch} ) {
2824       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2825     }
2826
2827     $attrs->{from} =    # have to copy here to avoid corrupting the original
2828       [
2829         @{ $attrs->{from} },
2830         $source->_resolve_join(
2831           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2832         )
2833       ];
2834   }
2835
2836   if ( $attrs->{order_by} ) {
2837     $attrs->{order_by} = (
2838       ref( $attrs->{order_by} ) eq 'ARRAY'
2839       ? [ @{ $attrs->{order_by} } ]
2840       : [ $attrs->{order_by} ]
2841     );
2842   }
2843
2844   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2845     $attrs->{group_by} = [ $attrs->{group_by} ];
2846   }
2847
2848   # If the order_by is otherwise empty - we will use this for TOP limit
2849   # emulation and the like.
2850   # Although this is needed only if the order_by is not defined, it is
2851   # actually cheaper to just populate this rather than properly examining
2852   # order_by (stuf like [ {} ] and the like)
2853   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2854
2855
2856   $attrs->{collapse} ||= {};
2857   if ( my $prefetch = delete $attrs->{prefetch} ) {
2858     $prefetch = $self->_merge_attr( {}, $prefetch );
2859
2860     my $prefetch_ordering = [];
2861
2862     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2863
2864     my @prefetch =
2865       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2866
2867     $attrs->{prefetch_select} = [ map { $_->[0] } @prefetch ];
2868     push @{ $attrs->{select} }, @{$attrs->{prefetch_select}};
2869     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2870
2871     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2872     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2873   }
2874
2875
2876   if (delete $attrs->{distinct}) {
2877     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2878   }
2879
2880   # if both page and offset are specified, produce a combined offset
2881   # even though it doesn't make much sense, this is what pre 081xx has
2882   # been doing
2883   if (my $page = delete $attrs->{page}) {
2884     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2885       ($attrs->{offset} || 0);
2886   }
2887
2888   return $self->{_attrs} = $attrs;
2889 }
2890
2891 sub _joinpath_aliases {
2892   my ($self, $fromspec, $seen) = @_;
2893
2894   my $paths = {};
2895   return $paths unless ref $fromspec eq 'ARRAY';
2896
2897   for my $j (@$fromspec) {
2898
2899     next if ref $j ne 'ARRAY';
2900     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2901
2902     my $p = $paths;
2903     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2904     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2905   }
2906
2907   return $paths;
2908 }
2909
2910 sub _rollout_attr {
2911   my ($self, $attr) = @_;
2912
2913   if (ref $attr eq 'HASH') {
2914     return $self->_rollout_hash($attr);
2915   } elsif (ref $attr eq 'ARRAY') {
2916     return $self->_rollout_array($attr);
2917   } else {
2918     return [$attr];
2919   }
2920 }
2921
2922 sub _rollout_array {
2923   my ($self, $attr) = @_;
2924
2925   my @rolled_array;
2926   foreach my $element (@{$attr}) {
2927     if (ref $element eq 'HASH') {
2928       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2929     } elsif (ref $element eq 'ARRAY') {
2930       #  XXX - should probably recurse here
2931       push( @rolled_array, @{$self->_rollout_array($element)} );
2932     } else {
2933       push( @rolled_array, $element );
2934     }
2935   }
2936   return \@rolled_array;
2937 }
2938
2939 sub _rollout_hash {
2940   my ($self, $attr) = @_;
2941
2942   my @rolled_array;
2943   foreach my $key (keys %{$attr}) {
2944     push( @rolled_array, { $key => $attr->{$key} } );
2945   }
2946   return \@rolled_array;
2947 }
2948
2949 sub _calculate_score {
2950   my ($self, $a, $b) = @_;
2951
2952   if (ref $b eq 'HASH') {
2953     my ($b_key) = keys %{$b};
2954     if (ref $a eq 'HASH') {
2955       my ($a_key) = keys %{$a};
2956       if ($a_key eq $b_key) {
2957         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2958       } else {
2959         return 0;
2960       }
2961     } else {
2962       return ($a eq $b_key) ? 1 : 0;
2963     }
2964   } else {
2965     if (ref $a eq 'HASH') {
2966       my ($a_key) = keys %{$a};
2967       return ($b eq $a_key) ? 1 : 0;
2968     } else {
2969       return ($b eq $a) ? 1 : 0;
2970     }
2971   }
2972 }
2973
2974 sub _merge_attr {
2975   my ($self, $orig, $import) = @_;
2976
2977   return $import unless defined($orig);
2978   return $orig unless defined($import);
2979
2980   $orig = $self->_rollout_attr($orig);
2981   $import = $self->_rollout_attr($import);
2982
2983   my $seen_keys;
2984   foreach my $import_element ( @{$import} ) {
2985     # find best candidate from $orig to merge $b_element into
2986     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2987     foreach my $orig_element ( @{$orig} ) {
2988       my $score = $self->_calculate_score( $orig_element, $import_element );
2989       if ($score > $best_candidate->{score}) {
2990         $best_candidate->{position} = $position;
2991         $best_candidate->{score} = $score;
2992       }
2993       $position++;
2994     }
2995     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2996
2997     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2998       push( @{$orig}, $import_element );
2999     } else {
3000       my $orig_best = $orig->[$best_candidate->{position}];
3001       # merge orig_best and b_element together and replace original with merged
3002       if (ref $orig_best ne 'HASH') {
3003         $orig->[$best_candidate->{position}] = $import_element;
3004       } elsif (ref $import_element eq 'HASH') {
3005         my ($key) = keys %{$orig_best};
3006         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3007       }
3008     }
3009     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3010   }
3011
3012   return $orig;
3013 }
3014
3015 sub result_source {
3016     my $self = shift;
3017
3018     if (@_) {
3019         $self->_source_handle($_[0]->handle);
3020     } else {
3021         $self->_source_handle->resolve;
3022     }
3023 }
3024
3025 =head2 throw_exception
3026
3027 See L<DBIx::Class::Schema/throw_exception> for details.
3028
3029 =cut
3030
3031 sub throw_exception {
3032   my $self=shift;
3033   if (ref $self && $self->_source_handle->schema) {
3034     $self->_source_handle->schema->throw_exception(@_)
3035   } else {
3036     croak(@_);
3037   }
3038
3039 }
3040
3041 # XXX: FIXME: Attributes docs need clearing up
3042
3043 =head1 ATTRIBUTES
3044
3045 Attributes are used to refine a ResultSet in various ways when
3046 searching for data. They can be passed to any method which takes an
3047 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3048 L</count>.
3049
3050 These are in no particular order:
3051
3052 =head2 order_by
3053
3054 =over 4
3055
3056 =item Value: ( $order_by | \@order_by | \%order_by )
3057
3058 =back
3059
3060 Which column(s) to order the results by. If a single column name, or
3061 an arrayref of names is supplied, the argument is passed through
3062 directly to SQL. The hashref syntax allows for connection-agnostic
3063 specification of ordering direction:
3064
3065  For descending order:
3066
3067   order_by => { -desc => [qw/col1 col2 col3/] }
3068
3069  For explicit ascending order:
3070
3071   order_by => { -asc => 'col' }
3072
3073 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3074 supported, although you are strongly encouraged to use the hashref
3075 syntax as outlined above.
3076
3077 =head2 columns
3078
3079 =over 4
3080
3081 =item Value: \@columns
3082
3083 =back
3084
3085 Shortcut to request a particular set of columns to be retrieved. Each
3086 column spec may be a string (a table column name), or a hash (in which
3087 case the key is the C<as> value, and the value is used as the C<select>
3088 expression). Adds C<me.> onto the start of any column without a C<.> in
3089 it and sets C<select> from that, then auto-populates C<as> from
3090 C<select> as normal. (You may also use the C<cols> attribute, as in
3091 earlier versions of DBIC.)
3092
3093 =head2 +columns
3094
3095 =over 4
3096
3097 =item Value: \@columns
3098
3099 =back
3100
3101 Indicates additional columns to be selected from storage. Works the same
3102 as L</columns> but adds columns to the selection. (You may also use the
3103 C<include_columns> attribute, as in earlier versions of DBIC). For
3104 example:-
3105
3106   $schema->resultset('CD')->search(undef, {
3107     '+columns' => ['artist.name'],
3108     join => ['artist']
3109   });
3110
3111 would return all CDs and include a 'name' column to the information
3112 passed to object inflation. Note that the 'artist' is the name of the
3113 column (or relationship) accessor, and 'name' is the name of the column
3114 accessor in the related table.
3115
3116 =head2 include_columns
3117
3118 =over 4
3119
3120 =item Value: \@columns
3121
3122 =back
3123
3124 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3125
3126 =head2 select
3127
3128 =over 4
3129
3130 =item Value: \@select_columns
3131
3132 =back
3133
3134 Indicates which columns should be selected from the storage. You can use
3135 column names, or in the case of RDBMS back ends, function or stored procedure
3136 names:
3137
3138   $rs = $schema->resultset('Employee')->search(undef, {
3139     select => [
3140       'name',
3141       { count => 'employeeid' },
3142       { sum => 'salary' }
3143     ]
3144   });
3145
3146 When you use function/stored procedure names and do not supply an C<as>
3147 attribute, the column names returned are storage-dependent. E.g. MySQL would
3148 return a column named C<count(employeeid)> in the above example.
3149
3150 =head2 +select
3151
3152 =over 4
3153
3154 Indicates additional columns to be selected from storage.  Works the same as
3155 L</select> but adds columns to the selection.
3156
3157 =back
3158
3159 =head2 +as
3160
3161 =over 4
3162
3163 Indicates additional column names for those added via L</+select>. See L</as>.
3164
3165 =back
3166
3167 =head2 as
3168
3169 =over 4
3170
3171 =item Value: \@inflation_names
3172
3173 =back
3174
3175 Indicates column names for object inflation. That is, C<as>
3176 indicates the name that the column can be accessed as via the
3177 C<get_column> method (or via the object accessor, B<if one already
3178 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3179
3180 The C<as> attribute is used in conjunction with C<select>,
3181 usually when C<select> contains one or more function or stored
3182 procedure names:
3183
3184   $rs = $schema->resultset('Employee')->search(undef, {
3185     select => [
3186       'name',
3187       { count => 'employeeid' }
3188     ],
3189     as => ['name', 'employee_count'],
3190   });
3191
3192   my $employee = $rs->first(); # get the first Employee
3193
3194 If the object against which the search is performed already has an accessor
3195 matching a column name specified in C<as>, the value can be retrieved using
3196 the accessor as normal:
3197
3198   my $name = $employee->name();
3199
3200 If on the other hand an accessor does not exist in the object, you need to
3201 use C<get_column> instead:
3202
3203   my $employee_count = $employee->get_column('employee_count');
3204
3205 You can create your own accessors if required - see
3206 L<DBIx::Class::Manual::Cookbook> for details.
3207
3208 Please note: This will NOT insert an C<AS employee_count> into the SQL
3209 statement produced, it is used for internal access only. Thus
3210 attempting to use the accessor in an C<order_by> clause or similar
3211 will fail miserably.
3212
3213 To get around this limitation, you can supply literal SQL to your
3214 C<select> attibute that contains the C<AS alias> text, eg:
3215
3216   select => [\'myfield AS alias']
3217
3218 =head2 join
3219
3220 =over 4
3221
3222 =item Value: ($rel_name | \@rel_names | \%rel_names)
3223
3224 =back
3225
3226 Contains a list of relationships that should be joined for this query.  For
3227 example:
3228
3229   # Get CDs by Nine Inch Nails
3230   my $rs = $schema->resultset('CD')->search(
3231     { 'artist.name' => 'Nine Inch Nails' },
3232     { join => 'artist' }
3233   );
3234
3235 Can also contain a hash reference to refer to the other relation's relations.
3236 For example:
3237
3238   package MyApp::Schema::Track;
3239   use base qw/DBIx::Class/;
3240   __PACKAGE__->table('track');
3241   __PACKAGE__->add_columns(qw/trackid cd position title/);
3242   __PACKAGE__->set_primary_key('trackid');
3243   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3244   1;
3245
3246   # In your application
3247   my $rs = $schema->resultset('Artist')->search(
3248     { 'track.title' => 'Teardrop' },
3249     {
3250       join     => { cd => 'track' },
3251       order_by => 'artist.name',
3252     }
3253   );
3254
3255 You need to use the relationship (not the table) name in  conditions,
3256 because they are aliased as such. The current table is aliased as "me", so
3257 you need to use me.column_name in order to avoid ambiguity. For example:
3258
3259   # Get CDs from 1984 with a 'Foo' track
3260   my $rs = $schema->resultset('CD')->search(
3261     {
3262       'me.year' => 1984,
3263       'tracks.name' => 'Foo'
3264     },
3265     { join => 'tracks' }
3266   );
3267
3268 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3269 similarly for a third time). For e.g.
3270
3271   my $rs = $schema->resultset('Artist')->search({
3272     'cds.title'   => 'Down to Earth',
3273     'cds_2.title' => 'Popular',
3274   }, {
3275     join => [ qw/cds cds/ ],
3276   });
3277
3278 will return a set of all artists that have both a cd with title 'Down
3279 to Earth' and a cd with title 'Popular'.
3280
3281 If you want to fetch related objects from other tables as well, see C<prefetch>
3282 below.
3283
3284 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3285
3286 =head2 prefetch
3287
3288 =over 4
3289
3290 =item Value: ($rel_name | \@rel_names | \%rel_names)
3291
3292 =back
3293
3294 Contains one or more relationships that should be fetched along with
3295 the main query (when they are accessed afterwards the data will
3296 already be available, without extra queries to the database).  This is
3297 useful for when you know you will need the related objects, because it
3298 saves at least one query:
3299
3300   my $rs = $schema->resultset('Tag')->search(
3301     undef,
3302     {
3303       prefetch => {
3304         cd => 'artist'
3305       }
3306     }
3307   );
3308
3309 The initial search results in SQL like the following:
3310
3311   SELECT tag.*, cd.*, artist.* FROM tag
3312   JOIN cd ON tag.cd = cd.cdid
3313   JOIN artist ON cd.artist = artist.artistid
3314
3315 L<DBIx::Class> has no need to go back to the database when we access the
3316 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3317 case.
3318
3319 Simple prefetches will be joined automatically, so there is no need
3320 for a C<join> attribute in the above search.
3321
3322 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3323 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3324 with an accessor type of 'single' or 'filter'). A more complex example that
3325 prefetches an artists cds, the tracks on those cds, and the tags associted
3326 with that artist is given below (assuming many-to-many from artists to tags):
3327
3328  my $rs = $schema->resultset('Artist')->search(
3329    undef,
3330    {
3331      prefetch => [
3332        { cds => 'tracks' },
3333        { artist_tags => 'tags' }
3334      ]
3335    }
3336  );
3337
3338
3339 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3340 attributes will be ignored.
3341
3342 =head2 page
3343
3344 =over 4
3345
3346 =item Value: $page
3347
3348 =back
3349
3350 Makes the resultset paged and specifies the page to retrieve. Effectively
3351 identical to creating a non-pages resultset and then calling ->page($page)
3352 on it.
3353
3354 If L<rows> attribute is not specified it defaults to 10 rows per page.
3355
3356 When you have a paged resultset, L</count> will only return the number
3357 of rows in the page. To get the total, use the L</pager> and call
3358 C<total_entries> on it.
3359
3360 =head2 rows
3361
3362 =over 4
3363
3364 =item Value: $rows
3365
3366 =back
3367
3368 Specifes the maximum number of rows for direct retrieval or the number of
3369 rows per page if the page attribute or method is used.
3370
3371 =head2 offset
3372
3373 =over 4
3374
3375 =item Value: $offset
3376
3377 =back
3378
3379 Specifies the (zero-based) row number for the  first row to be returned, or the
3380 of the first row of the first page if paging is used.
3381
3382 =head2 group_by
3383
3384 =over 4
3385
3386 =item Value: \@columns
3387
3388 =back
3389
3390 A arrayref of columns to group by. Can include columns of joined tables.
3391
3392   group_by => [qw/ column1 column2 ... /]
3393
3394 =head2 having
3395
3396 =over 4
3397
3398 =item Value: $condition
3399
3400 =back
3401
3402 HAVING is a select statement attribute that is applied between GROUP BY and
3403 ORDER BY. It is applied to the after the grouping calculations have been
3404 done.
3405
3406   having => { 'count(employee)' => { '>=', 100 } }
3407
3408 =head2 distinct
3409
3410 =over 4
3411
3412 =item Value: (0 | 1)
3413
3414 =back
3415
3416 Set to 1 to group by all columns.
3417
3418 =head2 where
3419
3420 =over 4
3421
3422 Adds to the WHERE clause.
3423
3424   # only return rows WHERE deleted IS NULL for all searches
3425   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3426
3427 Can be overridden by passing C<{ where => undef }> as an attribute
3428 to a resulset.
3429
3430 =back
3431
3432 =head2 cache
3433
3434 Set to 1 to cache search results. This prevents extra SQL queries if you
3435 revisit rows in your ResultSet:
3436
3437   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3438
3439   while( my $artist = $resultset->next ) {
3440     ... do stuff ...
3441   }
3442
3443   $rs->first; # without cache, this would issue a query
3444
3445 By default, searches are not cached.
3446
3447 For more examples of using these attributes, see
3448 L<DBIx::Class::Manual::Cookbook>.
3449
3450 =head2 from
3451
3452 =over 4
3453
3454 =item Value: \@from_clause
3455
3456 =back
3457
3458 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3459 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3460 clauses.
3461
3462 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3463
3464 C<join> will usually do what you need and it is strongly recommended that you
3465 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3466 And we really do mean "cannot", not just tried and failed. Attempting to use
3467 this because you're having problems with C<join> is like trying to use x86
3468 ASM because you've got a syntax error in your C. Trust us on this.
3469
3470 Now, if you're still really, really sure you need to use this (and if you're
3471 not 100% sure, ask the mailing list first), here's an explanation of how this
3472 works.
3473
3474 The syntax is as follows -
3475
3476   [
3477     { <alias1> => <table1> },
3478     [
3479       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3480       [], # nested JOIN (optional)
3481       { <table1.column1> => <table2.column2>, ... (more conditions) },
3482     ],
3483     # More of the above [ ] may follow for additional joins
3484   ]
3485
3486   <table1> <alias1>
3487   JOIN
3488     <table2> <alias2>
3489     [JOIN ...]
3490   ON <table1.column1> = <table2.column2>
3491   <more joins may follow>
3492
3493 An easy way to follow the examples below is to remember the following:
3494
3495     Anything inside "[]" is a JOIN
3496     Anything inside "{}" is a condition for the enclosing JOIN
3497
3498 The following examples utilize a "person" table in a family tree application.
3499 In order to express parent->child relationships, this table is self-joined:
3500
3501     # Person->belongs_to('father' => 'Person');
3502     # Person->belongs_to('mother' => 'Person');
3503
3504 C<from> can be used to nest joins. Here we return all children with a father,
3505 then search against all mothers of those children:
3506
3507   $rs = $schema->resultset('Person')->search(
3508       undef,
3509       {
3510           alias => 'mother', # alias columns in accordance with "from"
3511           from => [
3512               { mother => 'person' },
3513               [
3514                   [
3515                       { child => 'person' },
3516                       [
3517                           { father => 'person' },
3518                           { 'father.person_id' => 'child.father_id' }
3519                       ]
3520                   ],
3521                   { 'mother.person_id' => 'child.mother_id' }
3522               ],
3523           ]
3524       },
3525   );
3526
3527   # Equivalent SQL:
3528   # SELECT mother.* FROM person mother
3529   # JOIN (
3530   #   person child
3531   #   JOIN person father
3532   #   ON ( father.person_id = child.father_id )
3533   # )
3534   # ON ( mother.person_id = child.mother_id )
3535
3536 The type of any join can be controlled manually. To search against only people
3537 with a father in the person table, we could explicitly use C<INNER JOIN>:
3538
3539     $rs = $schema->resultset('Person')->search(
3540         undef,
3541         {
3542             alias => 'child', # alias columns in accordance with "from"
3543             from => [
3544                 { child => 'person' },
3545                 [
3546                     { father => 'person', -join_type => 'inner' },
3547                     { 'father.id' => 'child.father_id' }
3548                 ],
3549             ]
3550         },
3551     );
3552
3553     # Equivalent SQL:
3554     # SELECT child.* FROM person child
3555     # INNER JOIN person father ON child.father_id = father.id
3556
3557 You can select from a subquery by passing a resultset to from as follows.
3558
3559     $schema->resultset('Artist')->search(
3560         undef,
3561         {   alias => 'artist2',
3562             from  => [ { artist2 => $artist_rs->as_query } ],
3563         } );
3564
3565     # and you'll get sql like this..
3566     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3567     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3568
3569 If you need to express really complex joins, you
3570 can supply literal SQL to C<from> via a scalar reference. In this case
3571 the contents of the scalar will replace the table name associated with the
3572 resultsource.
3573
3574 WARNING: This technique might very well not work as expected on chained
3575 searches - you have been warned.
3576
3577     # Assuming the Event resultsource is defined as:
3578
3579         MySchema::Event->add_columns (
3580             sequence => {
3581                 data_type => 'INT',
3582                 is_auto_increment => 1,
3583             },
3584             location => {
3585                 data_type => 'INT',
3586             },
3587             type => {
3588                 data_type => 'INT',
3589             },
3590         );
3591         MySchema::Event->set_primary_key ('sequence');
3592
3593     # This will get back the latest event for every location. The column
3594     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3595     # combo to limit the resultset
3596
3597     $rs = $schema->resultset('Event');
3598     $table = $rs->result_source->name;
3599     $latest = $rs->search (
3600         undef,
3601         { from => \ "
3602             (SELECT e1.* FROM $table e1
3603                 JOIN $table e2
3604                     ON e1.location = e2.location
3605                     AND e1.sequence < e2.sequence
3606                 WHERE e2.sequence is NULL
3607             ) me",
3608         },
3609     );
3610
3611     # Equivalent SQL (with the DBIC chunks added):
3612
3613     SELECT me.sequence, me.location, me.type FROM
3614        (SELECT e1.* FROM events e1
3615            JOIN events e2
3616                ON e1.location = e2.location
3617                AND e1.sequence < e2.sequence
3618            WHERE e2.sequence is NULL
3619        ) me;
3620
3621 =head2 for
3622
3623 =over 4
3624
3625 =item Value: ( 'update' | 'shared' )
3626
3627 =back
3628
3629 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3630 ... FOR SHARED.
3631
3632 =cut
3633
3634 1;