lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 961   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 962   @new = $self->{_attrs}{record_filter}->(@new)
 963     if exists $self->{_attrs}{record_filter};
 964   return @new;
 965 }
 966
 967 sub _collapse_result {
 968   my ($self, $as_proto, $row) = @_;
 969
 970   my @copy = @$row;
 971
 972   # 'foo'         => [ undef, 'foo' ]
 973   # 'foo.bar'     => [ 'foo', 'bar' ]
 974   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 975
 976   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 977
 978   my %collapse = %{$self->{_attrs}{collapse}||{}};
 979
 980   my @pri_index;
 981
 982   # if we're doing collapsing (has_many prefetch) we need to grab records
 983   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 984   # we know we don't have to bother.
 985
 986   # the reason for not using the collapse stuff directly is because if you
 987   # had for e.g. two artists in a row with no cds, the collapse info for
 988   # both would be NULL (undef) so you'd lose the second artist
 989
 990   # store just the index so we can check the array positions from the row
 991   # without having to contruct the full hash
 992
 993   if (keys %collapse) {
 994     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 995     foreach my $i (0 .. $#construct_as) {
 996       next if defined($construct_as[$i][0]); # only self table
 997       if (delete $pri{$construct_as[$i][1]}) {
 998         push(@pri_index, $i);
 999       }
1000       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1001     }
1002   }
1003
1004   # no need to do an if, it'll be empty if @pri_index is empty anyway
1005
1006   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1007
1008   my @const_rows;
1009
1010   do { # no need to check anything at the front, we always want the first row
1011
1012     my %const;
1013
1014     foreach my $this_as (@construct_as) {
1015       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1016     }
1017
1018     push(@const_rows, \%const);
1019
1020   } until ( # no pri_index => no collapse => drop straight out
1021       !@pri_index
1022     or
1023       do { # get another row, stash it, drop out if different PK
1024
1025         @copy = $self->cursor->next;
1026         $self->{stashed_row} = \@copy;
1027
1028         # last thing in do block, counts as true if anything doesn't match
1029
1030         # check xor defined first for NULL vs. NOT NULL then if one is
1031         # defined the other must be so check string equality
1032
1033         grep {
1034           (defined $pri_vals{$_} ^ defined $copy[$_])
1035           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1036         } @pri_index;
1037       }
1038   );
1039
1040   my $alias = $self->{attrs}{alias};
1041   my $info = [];
1042
1043   my %collapse_pos;
1044
1045   my @const_keys;
1046
1047   foreach my $const (@const_rows) {
1048     scalar @const_keys or do {
1049       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1050     };
1051     foreach my $key (@const_keys) {
1052       if (length $key) {
1053         my $target = $info;
1054         my @parts = split(/\./, $key);
1055         my $cur = '';
1056         my $data = $const->{$key};
1057         foreach my $p (@parts) {
1058           $target = $target->[1]->{$p} ||= [];
1059           $cur .= ".${p}";
1060           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1061             # collapsing at this point and on final part
1062             my $pos = $collapse_pos{$cur};
1063             CK: foreach my $ck (@ckey) {
1064               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1065                 $collapse_pos{$cur} = $data;
1066                 delete @collapse_pos{ # clear all positioning for sub-entries
1067                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1068                 };
1069                 push(@$target, []);
1070                 last CK;
1071               }
1072             }
1073           }
1074           if (exists $collapse{$cur}) {
1075             $target = $target->[-1];
1076           }
1077         }
1078         $target->[0] = $data;
1079       } else {
1080         $info->[0] = $const->{$key};
1081       }
1082     }
1083   }
1084
1085   return $info;
1086 }
1087
1088 =head2 result_source
1089
1090 =over 4
1091
1092 =item Arguments: $result_source?
1093
1094 =item Return Value: $result_source
1095
1096 =back
1097
1098 An accessor for the primary ResultSource object from which this ResultSet
1099 is derived.
1100
1101 =head2 result_class
1102
1103 =over 4
1104
1105 =item Arguments: $result_class?
1106
1107 =item Return Value: $result_class
1108
1109 =back
1110
1111 An accessor for the class to use when creating row objects. Defaults to
1112 C<< result_source->result_class >> - which in most cases is the name of the
1113 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1114
1115 Note that changing the result_class will also remove any components
1116 that were originally loaded in the source class via
1117 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1118 in the original source class will not run.
1119
1120 =cut
1121
1122 sub result_class {
1123   my ($self, $result_class) = @_;
1124   if ($result_class) {
1125     $self->ensure_class_loaded($result_class);
1126     $self->_result_class($result_class);
1127   }
1128   $self->_result_class;
1129 }
1130
1131 =head2 count
1132
1133 =over 4
1134
1135 =item Arguments: $cond, \%attrs??
1136
1137 =item Return Value: $count
1138
1139 =back
1140
1141 Performs an SQL C<COUNT> with the same query as the resultset was built
1142 with to find the number of elements. Passing arguments is equivalent to
1143 C<< $rs->search ($cond, \%attrs)->count >>
1144
1145 =cut
1146
1147 sub count {
1148   my $self = shift;
1149   return $self->search(@_)->count if @_ and defined $_[0];
1150   return scalar @{ $self->get_cache } if $self->get_cache;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153
1154   # this is a little optimization - it is faster to do the limit
1155   # adjustments in software, instead of a subquery
1156   my $rows = delete $attrs->{rows};
1157   my $offset = delete $attrs->{offset};
1158
1159   my $crs;
1160   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1161     $crs = $self->_count_subq_rs ($attrs);
1162   }
1163   else {
1164     $crs = $self->_count_rs ($attrs);
1165   }
1166   my $count = $crs->next;
1167
1168   $count -= $offset if $offset;
1169   $count = $rows if $rows and $rows < $count;
1170   $count = 0 if ($count < 0);
1171
1172   return $count;
1173 }
1174
1175 =head2 count_rs
1176
1177 =over 4
1178
1179 =item Arguments: $cond, \%attrs??
1180
1181 =item Return Value: $count_rs
1182
1183 =back
1184
1185 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1186 This can be very handy for subqueries:
1187
1188   ->search( { amount => $some_rs->count_rs->as_query } )
1189
1190 As with regular resultsets the SQL query will be executed only after
1191 the resultset is accessed via L</next> or L</all>. That would return
1192 the same single value obtainable via L</count>.
1193
1194 =cut
1195
1196 sub count_rs {
1197   my $self = shift;
1198   return $self->search(@_)->count_rs if @_;
1199
1200   # this may look like a lack of abstraction (count() does about the same)
1201   # but in fact an _rs *must* use a subquery for the limits, as the
1202   # software based limiting can not be ported if this $rs is to be used
1203   # in a subquery itself (i.e. ->as_query)
1204   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1205     return $self->_count_subq_rs;
1206   }
1207   else {
1208     return $self->_count_rs;
1209   }
1210 }
1211
1212 #
1213 # returns a ResultSetColumn object tied to the count query
1214 #
1215 sub _count_rs {
1216   my ($self, $attrs) = @_;
1217
1218   my $rsrc = $self->result_source;
1219   $attrs ||= $self->_resolved_attrs;
1220
1221   my $tmp_attrs = { %$attrs };
1222
1223   # take off any limits, record_filter is cdbi, and no point of ordering a count
1224   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1225
1226   # overwrite the selector (supplied by the storage)
1227   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1228   $tmp_attrs->{as} = 'count';
1229
1230   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1231
1232   return $tmp_rs;
1233 }
1234
1235 #
1236 # same as above but uses a subquery
1237 #
1238 sub _count_subq_rs {
1239   my ($self, $attrs) = @_;
1240
1241   my $rsrc = $self->result_source;
1242   $attrs ||= $self->_resolved_attrs_copy;
1243
1244   my $sub_attrs = { %$attrs };
1245
1246   # extra selectors do not go in the subquery and there is no point of ordering it
1247   delete $sub_attrs->{$_} for qw/collapse prefetch_select select as order_by/;
1248
1249   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1250   # clobber old group_by regardless
1251   if ( keys %{$attrs->{collapse}} ) {
1252     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1253   }
1254
1255   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1256
1257   # this is so that ordering can be thrown away in things like Top limit
1258   $sub_attrs->{-for_count_only} = 1;
1259
1260   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1261   $attrs->{from} = [{
1262     -alias => 'count_subq',
1263     -source_handle => $rsrc->handle,
1264     count_subq => $sub_rs->as_query,
1265   }];
1266
1267   # the subquery replaces this
1268   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1269
1270   return $self->_count_rs ($attrs);
1271 }
1272
1273
1274 sub _bool {
1275   return 1;
1276 }
1277
1278 =head2 count_literal
1279
1280 =over 4
1281
1282 =item Arguments: $sql_fragment, @bind_values
1283
1284 =item Return Value: $count
1285
1286 =back
1287
1288 Counts the results in a literal query. Equivalent to calling L</search_literal>
1289 with the passed arguments, then L</count>.
1290
1291 =cut
1292
1293 sub count_literal { shift->search_literal(@_)->count; }
1294
1295 =head2 all
1296
1297 =over 4
1298
1299 =item Arguments: none
1300
1301 =item Return Value: @objects
1302
1303 =back
1304
1305 Returns all elements in the resultset. Called implicitly if the resultset
1306 is returned in list context.
1307
1308 =cut
1309
1310 sub all {
1311   my $self = shift;
1312   if(@_) {
1313       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1314   }
1315
1316   return @{ $self->get_cache } if $self->get_cache;
1317
1318   my @obj;
1319
1320   if (keys %{$self->_resolved_attrs->{collapse}}) {
1321     # Using $self->cursor->all is really just an optimisation.
1322     # If we're collapsing has_many prefetches it probably makes
1323     # very little difference, and this is cleaner than hacking
1324     # _construct_object to survive the approach
1325     $self->cursor->reset;
1326     my @row = $self->cursor->next;
1327     while (@row) {
1328       push(@obj, $self->_construct_object(@row));
1329       @row = (exists $self->{stashed_row}
1330                ? @{delete $self->{stashed_row}}
1331                : $self->cursor->next);
1332     }
1333   } else {
1334     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1335   }
1336
1337   $self->set_cache(\@obj) if $self->{attrs}{cache};
1338   return @obj;
1339 }
1340
1341 =head2 reset
1342
1343 =over 4
1344
1345 =item Arguments: none
1346
1347 =item Return Value: $self
1348
1349 =back
1350
1351 Resets the resultset's cursor, so you can iterate through the elements again.
1352 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1353 another query.
1354
1355 =cut
1356
1357 sub reset {
1358   my ($self) = @_;
1359   delete $self->{_attrs} if exists $self->{_attrs};
1360   $self->{all_cache_position} = 0;
1361   $self->cursor->reset;
1362   return $self;
1363 }
1364
1365 =head2 first
1366
1367 =over 4
1368
1369 =item Arguments: none
1370
1371 =item Return Value: $object?
1372
1373 =back
1374
1375 Resets the resultset and returns an object for the first result (if the
1376 resultset returns anything).
1377
1378 =cut
1379
1380 sub first {
1381   return $_[0]->reset->next;
1382 }
1383
1384
1385 # _rs_update_delete
1386 #
1387 # Determines whether and what type of subquery is required for the $rs operation.
1388 # If grouping is necessary either supplies its own, or verifies the current one
1389 # After all is done delegates to the proper storage method.
1390
1391 sub _rs_update_delete {
1392   my ($self, $op, $values) = @_;
1393
1394   my $rsrc = $self->result_source;
1395
1396   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1397   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1398
1399   if ($needs_group_by_subq or $needs_subq) {
1400
1401     # make a new $rs selecting only the PKs (that's all we really need)
1402     my $attrs = $self->_resolved_attrs_copy;
1403
1404     delete $attrs->{$_} for qw/collapse select as/;
1405     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1406
1407     if ($needs_group_by_subq) {
1408       # make sure no group_by was supplied, or if there is one - make sure it matches
1409       # the columns compiled above perfectly. Anything else can not be sanely executed
1410       # on most databases so croak right then and there
1411
1412       if (my $g = $attrs->{group_by}) {
1413         my @current_group_by = map
1414           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1415           (ref $g eq 'ARRAY' ? @$g : $g );
1416
1417         if (
1418           join ("\x00", sort @current_group_by)
1419             ne
1420           join ("\x00", sort @{$attrs->{columns}} )
1421         ) {
1422           $self->throw_exception (
1423             "You have just attempted a $op operation on a resultset which does group_by"
1424             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1425             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1426             . ' kind of queries. Please retry the operation with a modified group_by or'
1427             . ' without using one at all.'
1428           );
1429         }
1430       }
1431       else {
1432         $attrs->{group_by} = $attrs->{columns};
1433       }
1434     }
1435
1436     my $subrs = (ref $self)->new($rsrc, $attrs);
1437
1438     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1439   }
1440   else {
1441     return $rsrc->storage->$op(
1442       $rsrc,
1443       $op eq 'update' ? $values : (),
1444       $self->_cond_for_update_delete,
1445     );
1446   }
1447 }
1448
1449
1450 # _cond_for_update_delete
1451 #
1452 # update/delete require the condition to be modified to handle
1453 # the differing SQL syntax available.  This transforms the $self->{cond}
1454 # appropriately, returning the new condition.
1455
1456 sub _cond_for_update_delete {
1457   my ($self, $full_cond) = @_;
1458   my $cond = {};
1459
1460   $full_cond ||= $self->{cond};
1461   # No-op. No condition, we're updating/deleting everything
1462   return $cond unless ref $full_cond;
1463
1464   if (ref $full_cond eq 'ARRAY') {
1465     $cond = [
1466       map {
1467         my %hash;
1468         foreach my $key (keys %{$_}) {
1469           $key =~ /([^.]+)$/;
1470           $hash{$1} = $_->{$key};
1471         }
1472         \%hash;
1473       } @{$full_cond}
1474     ];
1475   }
1476   elsif (ref $full_cond eq 'HASH') {
1477     if ((keys %{$full_cond})[0] eq '-and') {
1478       $cond->{-and} = [];
1479       my @cond = @{$full_cond->{-and}};
1480        for (my $i = 0; $i < @cond; $i++) {
1481         my $entry = $cond[$i];
1482         my $hash;
1483         if (ref $entry eq 'HASH') {
1484           $hash = $self->_cond_for_update_delete($entry);
1485         }
1486         else {
1487           $entry =~ /([^.]+)$/;
1488           $hash->{$1} = $cond[++$i];
1489         }
1490         push @{$cond->{-and}}, $hash;
1491       }
1492     }
1493     else {
1494       foreach my $key (keys %{$full_cond}) {
1495         $key =~ /([^.]+)$/;
1496         $cond->{$1} = $full_cond->{$key};
1497       }
1498     }
1499   }
1500   else {
1501     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1502   }
1503
1504   return $cond;
1505 }
1506
1507
1508 =head2 update
1509
1510 =over 4
1511
1512 =item Arguments: \%values
1513
1514 =item Return Value: $storage_rv
1515
1516 =back
1517
1518 Sets the specified columns in the resultset to the supplied values in a
1519 single query. Return value will be true if the update succeeded or false
1520 if no records were updated; exact type of success value is storage-dependent.
1521
1522 =cut
1523
1524 sub update {
1525   my ($self, $values) = @_;
1526   $self->throw_exception('Values for update must be a hash')
1527     unless ref $values eq 'HASH';
1528
1529   return $self->_rs_update_delete ('update', $values);
1530 }
1531
1532 =head2 update_all
1533
1534 =over 4
1535
1536 =item Arguments: \%values
1537
1538 =item Return Value: 1
1539
1540 =back
1541
1542 Fetches all objects and updates them one at a time. Note that C<update_all>
1543 will run DBIC cascade triggers, while L</update> will not.
1544
1545 =cut
1546
1547 sub update_all {
1548   my ($self, $values) = @_;
1549   $self->throw_exception('Values for update_all must be a hash')
1550     unless ref $values eq 'HASH';
1551   foreach my $obj ($self->all) {
1552     $obj->set_columns($values)->update;
1553   }
1554   return 1;
1555 }
1556
1557 =head2 delete
1558
1559 =over 4
1560
1561 =item Arguments: none
1562
1563 =item Return Value: $storage_rv
1564
1565 =back
1566
1567 Deletes the contents of the resultset from its result source. Note that this
1568 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1569 to run. See also L<DBIx::Class::Row/delete>.
1570
1571 Return value will be the amount of rows deleted; exact type of return value
1572 is storage-dependent.
1573
1574 =cut
1575
1576 sub delete {
1577   my $self = shift;
1578   $self->throw_exception('delete does not accept any arguments')
1579     if @_;
1580
1581   return $self->_rs_update_delete ('delete');
1582 }
1583
1584 =head2 delete_all
1585
1586 =over 4
1587
1588 =item Arguments: none
1589
1590 =item Return Value: 1
1591
1592 =back
1593
1594 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1595 will run DBIC cascade triggers, while L</delete> will not.
1596
1597 =cut
1598
1599 sub delete_all {
1600   my $self = shift;
1601   $self->throw_exception('delete_all does not accept any arguments')
1602     if @_;
1603
1604   $_->delete for $self->all;
1605   return 1;
1606 }
1607
1608 =head2 populate
1609
1610 =over 4
1611
1612 =item Arguments: \@data;
1613
1614 =back
1615
1616 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1617 For the arrayref of hashrefs style each hashref should be a structure suitable
1618 forsubmitting to a $resultset->create(...) method.
1619
1620 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1621 to insert the data, as this is a faster method.
1622
1623 Otherwise, each set of data is inserted into the database using
1624 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1625 accumulated into an array. The array itself, or an array reference
1626 is returned depending on scalar or list context.
1627
1628 Example:  Assuming an Artist Class that has many CDs Classes relating:
1629
1630   my $Artist_rs = $schema->resultset("Artist");
1631
1632   ## Void Context Example
1633   $Artist_rs->populate([
1634      { artistid => 4, name => 'Manufactured Crap', cds => [
1635         { title => 'My First CD', year => 2006 },
1636         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1637       ],
1638      },
1639      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1640         { title => 'My parents sold me to a record company' ,year => 2005 },
1641         { title => 'Why Am I So Ugly?', year => 2006 },
1642         { title => 'I Got Surgery and am now Popular', year => 2007 }
1643       ],
1644      },
1645   ]);
1646
1647   ## Array Context Example
1648   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1649     { name => "Artist One"},
1650     { name => "Artist Two"},
1651     { name => "Artist Three", cds=> [
1652     { title => "First CD", year => 2007},
1653     { title => "Second CD", year => 2008},
1654   ]}
1655   ]);
1656
1657   print $ArtistOne->name; ## response is 'Artist One'
1658   print $ArtistThree->cds->count ## reponse is '2'
1659
1660 For the arrayref of arrayrefs style,  the first element should be a list of the
1661 fieldsnames to which the remaining elements are rows being inserted.  For
1662 example:
1663
1664   $Arstist_rs->populate([
1665     [qw/artistid name/],
1666     [100, 'A Formally Unknown Singer'],
1667     [101, 'A singer that jumped the shark two albums ago'],
1668     [102, 'An actually cool singer.'],
1669   ]);
1670
1671 Please note an important effect on your data when choosing between void and
1672 wantarray context. Since void context goes straight to C<insert_bulk> in
1673 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1674 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1675 create primary keys for you, you will find that your PKs are empty.  In this
1676 case you will have to use the wantarray context in order to create those
1677 values.
1678
1679 =cut
1680
1681 sub populate {
1682   my $self = shift @_;
1683   my $data = ref $_[0][0] eq 'HASH'
1684     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1685     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1686
1687   if(defined wantarray) {
1688     my @created;
1689     foreach my $item (@$data) {
1690       push(@created, $self->create($item));
1691     }
1692     return wantarray ? @created : \@created;
1693   } else {
1694     my ($first, @rest) = @$data;
1695
1696     my @names = grep {!ref $first->{$_}} keys %$first;
1697     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1698     my @pks = $self->result_source->primary_columns;
1699
1700     ## do the belongs_to relationships
1701     foreach my $index (0..$#$data) {
1702
1703       # delegate to create() for any dataset without primary keys with specified relationships
1704       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1705         for my $r (@rels) {
1706           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1707             my @ret = $self->populate($data);
1708             return;
1709           }
1710         }
1711       }
1712
1713       foreach my $rel (@rels) {
1714         next unless ref $data->[$index]->{$rel} eq "HASH";
1715         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1716         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1717         my $related = $result->result_source->_resolve_condition(
1718           $result->result_source->relationship_info($reverse)->{cond},
1719           $self,
1720           $result,
1721         );
1722
1723         delete $data->[$index]->{$rel};
1724         $data->[$index] = {%{$data->[$index]}, %$related};
1725
1726         push @names, keys %$related if $index == 0;
1727       }
1728     }
1729
1730     ## do bulk insert on current row
1731     my @values = map { [ @$_{@names} ] } @$data;
1732
1733     $self->result_source->storage->insert_bulk(
1734       $self->result_source,
1735       \@names,
1736       \@values,
1737     );
1738
1739     ## do the has_many relationships
1740     foreach my $item (@$data) {
1741
1742       foreach my $rel (@rels) {
1743         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1744
1745         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1746      || $self->throw_exception('Cannot find the relating object.');
1747
1748         my $child = $parent->$rel;
1749
1750         my $related = $child->result_source->_resolve_condition(
1751           $parent->result_source->relationship_info($rel)->{cond},
1752           $child,
1753           $parent,
1754         );
1755
1756         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1757         my @populate = map { {%$_, %$related} } @rows_to_add;
1758
1759         $child->populate( \@populate );
1760       }
1761     }
1762   }
1763 }
1764
1765 =head2 _normalize_populate_args ($args)
1766
1767 Private method used by L</populate> to normalize its incoming arguments.  Factored
1768 out in case you want to subclass and accept new argument structures to the
1769 L</populate> method.
1770
1771 =cut
1772
1773 sub _normalize_populate_args {
1774   my ($self, $data) = @_;
1775   my @names = @{shift(@$data)};
1776   my @results_to_create;
1777   foreach my $datum (@$data) {
1778     my %result_to_create;
1779     foreach my $index (0..$#names) {
1780       $result_to_create{$names[$index]} = $$datum[$index];
1781     }
1782     push @results_to_create, \%result_to_create;
1783   }
1784   return \@results_to_create;
1785 }
1786
1787 =head2 pager
1788
1789 =over 4
1790
1791 =item Arguments: none
1792
1793 =item Return Value: $pager
1794
1795 =back
1796
1797 Return Value a L<Data::Page> object for the current resultset. Only makes
1798 sense for queries with a C<page> attribute.
1799
1800 To get the full count of entries for a paged resultset, call
1801 C<total_entries> on the L<Data::Page> object.
1802
1803 =cut
1804
1805 sub pager {
1806   my ($self) = @_;
1807
1808   return $self->{pager} if $self->{pager};
1809
1810   my $attrs = $self->{attrs};
1811   $self->throw_exception("Can't create pager for non-paged rs")
1812     unless $self->{attrs}{page};
1813   $attrs->{rows} ||= 10;
1814
1815   # throw away the paging flags and re-run the count (possibly
1816   # with a subselect) to get the real total count
1817   my $count_attrs = { %$attrs };
1818   delete $count_attrs->{$_} for qw/rows offset page pager/;
1819   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1820
1821   return $self->{pager} = Data::Page->new(
1822     $total_count,
1823     $attrs->{rows},
1824     $self->{attrs}{page}
1825   );
1826 }
1827
1828 =head2 page
1829
1830 =over 4
1831
1832 =item Arguments: $page_number
1833
1834 =item Return Value: $rs
1835
1836 =back
1837
1838 Returns a resultset for the $page_number page of the resultset on which page
1839 is called, where each page contains a number of rows equal to the 'rows'
1840 attribute set on the resultset (10 by default).
1841
1842 =cut
1843
1844 sub page {
1845   my ($self, $page) = @_;
1846   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1847 }
1848
1849 =head2 new_result
1850
1851 =over 4
1852
1853 =item Arguments: \%vals
1854
1855 =item Return Value: $rowobject
1856
1857 =back
1858
1859 Creates a new row object in the resultset's result class and returns
1860 it. The row is not inserted into the database at this point, call
1861 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1862 will tell you whether the row object has been inserted or not.
1863
1864 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1865
1866 =cut
1867
1868 sub new_result {
1869   my ($self, $values) = @_;
1870   $self->throw_exception( "new_result needs a hash" )
1871     unless (ref $values eq 'HASH');
1872
1873   my %new;
1874   my $alias = $self->{attrs}{alias};
1875
1876   if (
1877     defined $self->{cond}
1878     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1879   ) {
1880     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1881     $new{-from_resultset} = [ keys %new ] if keys %new;
1882   } else {
1883     $self->throw_exception(
1884       "Can't abstract implicit construct, condition not a hash"
1885     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1886
1887     my $collapsed_cond = (
1888       $self->{cond}
1889         ? $self->_collapse_cond($self->{cond})
1890         : {}
1891     );
1892
1893     # precendence must be given to passed values over values inherited from
1894     # the cond, so the order here is important.
1895     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1896     while( my($col,$value) = each %implied ){
1897       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1898         $new{$col} = $value->{'='};
1899         next;
1900       }
1901       $new{$col} = $value if $self->_is_deterministic_value($value);
1902     }
1903   }
1904
1905   %new = (
1906     %new,
1907     %{ $self->_remove_alias($values, $alias) },
1908     -source_handle => $self->_source_handle,
1909     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1910   );
1911
1912   return $self->result_class->new(\%new);
1913 }
1914
1915 # _is_deterministic_value
1916 #
1917 # Make an effor to strip non-deterministic values from the condition,
1918 # to make sure new_result chokes less
1919
1920 sub _is_deterministic_value {
1921   my $self = shift;
1922   my $value = shift;
1923   my $ref_type = ref $value;
1924   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1925   return 1 if Scalar::Util::blessed($value);
1926   return 0;
1927 }
1928
1929 # _has_resolved_attr
1930 #
1931 # determines if the resultset defines at least one
1932 # of the attributes supplied
1933 #
1934 # used to determine if a subquery is neccessary
1935
1936 sub _has_resolved_attr {
1937   my ($self, @attr_names) = @_;
1938
1939   my $attrs = $self->_resolved_attrs;
1940
1941   my $join_check_req;
1942
1943   for my $n (@attr_names) {
1944     ++$join_check_req if $n eq '-join';
1945
1946     my $attr =  $attrs->{$n};
1947
1948     next if not defined $attr;
1949
1950     if (ref $attr eq 'HASH') {
1951       return 1 if keys %$attr;
1952     }
1953     elsif (ref $attr eq 'ARRAY') {
1954       return 1 if @$attr;
1955     }
1956     else {
1957       return 1 if $attr;
1958     }
1959   }
1960
1961   # a resolved join is expressed as a multi-level from
1962   return 1 if (
1963     $join_check_req
1964       and
1965     ref $attrs->{from} eq 'ARRAY'
1966       and
1967     @{$attrs->{from}} > 1
1968   );
1969
1970   return 0;
1971 }
1972
1973 # _collapse_cond
1974 #
1975 # Recursively collapse the condition.
1976
1977 sub _collapse_cond {
1978   my ($self, $cond, $collapsed) = @_;
1979
1980   $collapsed ||= {};
1981
1982   if (ref $cond eq 'ARRAY') {
1983     foreach my $subcond (@$cond) {
1984       next unless ref $subcond;  # -or
1985       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1986     }
1987   }
1988   elsif (ref $cond eq 'HASH') {
1989     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1990       foreach my $subcond (@{$cond->{-and}}) {
1991         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1992       }
1993     }
1994     else {
1995       foreach my $col (keys %$cond) {
1996         my $value = $cond->{$col};
1997         $collapsed->{$col} = $value;
1998       }
1999     }
2000   }
2001
2002   return $collapsed;
2003 }
2004
2005 # _remove_alias
2006 #
2007 # Remove the specified alias from the specified query hash. A copy is made so
2008 # the original query is not modified.
2009
2010 sub _remove_alias {
2011   my ($self, $query, $alias) = @_;
2012
2013   my %orig = %{ $query || {} };
2014   my %unaliased;
2015
2016   foreach my $key (keys %orig) {
2017     if ($key !~ /\./) {
2018       $unaliased{$key} = $orig{$key};
2019       next;
2020     }
2021     $unaliased{$1} = $orig{$key}
2022       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2023   }
2024
2025   return \%unaliased;
2026 }
2027
2028 =head2 as_query (EXPERIMENTAL)
2029
2030 =over 4
2031
2032 =item Arguments: none
2033
2034 =item Return Value: \[ $sql, @bind ]
2035
2036 =back
2037
2038 Returns the SQL query and bind vars associated with the invocant.
2039
2040 This is generally used as the RHS for a subquery.
2041
2042 B<NOTE>: This feature is still experimental.
2043
2044 =cut
2045
2046 sub as_query {
2047   my $self = shift;
2048
2049   my $attrs = $self->_resolved_attrs_copy;
2050
2051   # For future use:
2052   #
2053   # in list ctx:
2054   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2055   # $sql also has no wrapping parenthesis in list ctx
2056   #
2057   my $sqlbind = $self->result_source->storage
2058     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2059
2060   return $sqlbind;
2061 }
2062
2063 =head2 find_or_new
2064
2065 =over 4
2066
2067 =item Arguments: \%vals, \%attrs?
2068
2069 =item Return Value: $rowobject
2070
2071 =back
2072
2073   my $artist = $schema->resultset('Artist')->find_or_new(
2074     { artist => 'fred' }, { key => 'artists' });
2075
2076   $cd->cd_to_producer->find_or_new({ producer => $producer },
2077                                    { key => 'primary });
2078
2079 Find an existing record from this resultset, based on its primary
2080 key, or a unique constraint. If none exists, instantiate a new result
2081 object and return it. The object will not be saved into your storage
2082 until you call L<DBIx::Class::Row/insert> on it.
2083
2084 You most likely want this method when looking for existing rows using
2085 a unique constraint that is not the primary key, or looking for
2086 related rows.
2087
2088 If you want objects to be saved immediately, use L</find_or_create> instead.
2089
2090 B<Note>: C<find_or_new> is probably not what you want when creating a
2091 new row in a table that uses primary keys supplied by the
2092 database. Passing in a primary key column with a value of I<undef>
2093 will cause L</find> to attempt to search for a row with a value of
2094 I<NULL>.
2095
2096 =cut
2097
2098 sub find_or_new {
2099   my $self     = shift;
2100   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2101   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2102   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2103     return $row;
2104   }
2105   return $self->new_result($hash);
2106 }
2107
2108 =head2 create
2109
2110 =over 4
2111
2112 =item Arguments: \%vals
2113
2114 =item Return Value: a L<DBIx::Class::Row> $object
2115
2116 =back
2117
2118 Attempt to create a single new row or a row with multiple related rows
2119 in the table represented by the resultset (and related tables). This
2120 will not check for duplicate rows before inserting, use
2121 L</find_or_create> to do that.
2122
2123 To create one row for this resultset, pass a hashref of key/value
2124 pairs representing the columns of the table and the values you wish to
2125 store. If the appropriate relationships are set up, foreign key fields
2126 can also be passed an object representing the foreign row, and the
2127 value will be set to its primary key.
2128
2129 To create related objects, pass a hashref for the value if the related
2130 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2131 and use the name of the relationship as the key. (NOT the name of the field,
2132 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2133 of hashrefs containing the data for each of the rows to create in the foreign
2134 tables, again using the relationship name as the key.
2135
2136 Instead of hashrefs of plain related data (key/value pairs), you may
2137 also pass new or inserted objects. New objects (not inserted yet, see
2138 L</new>), will be inserted into their appropriate tables.
2139
2140 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2141
2142 Example of creating a new row.
2143
2144   $person_rs->create({
2145     name=>"Some Person",
2146     email=>"somebody@someplace.com"
2147   });
2148
2149 Example of creating a new row and also creating rows in a related C<has_many>
2150 or C<has_one> resultset.  Note Arrayref.
2151
2152   $artist_rs->create(
2153      { artistid => 4, name => 'Manufactured Crap', cds => [
2154         { title => 'My First CD', year => 2006 },
2155         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2156       ],
2157      },
2158   );
2159
2160 Example of creating a new row and also creating a row in a related
2161 C<belongs_to>resultset. Note Hashref.
2162
2163   $cd_rs->create({
2164     title=>"Music for Silly Walks",
2165     year=>2000,
2166     artist => {
2167       name=>"Silly Musician",
2168     }
2169   });
2170
2171 =cut
2172
2173 sub create {
2174   my ($self, $attrs) = @_;
2175   $self->throw_exception( "create needs a hashref" )
2176     unless ref $attrs eq 'HASH';
2177   return $self->new_result($attrs)->insert;
2178 }
2179
2180 =head2 find_or_create
2181
2182 =over 4
2183
2184 =item Arguments: \%vals, \%attrs?
2185
2186 =item Return Value: $rowobject
2187
2188 =back
2189
2190   $cd->cd_to_producer->find_or_create({ producer => $producer },
2191                                       { key => 'primary' });
2192
2193 Tries to find a record based on its primary key or unique constraints; if none
2194 is found, creates one and returns that instead.
2195
2196   my $cd = $schema->resultset('CD')->find_or_create({
2197     cdid   => 5,
2198     artist => 'Massive Attack',
2199     title  => 'Mezzanine',
2200     year   => 2005,
2201   });
2202
2203 Also takes an optional C<key> attribute, to search by a specific key or unique
2204 constraint. For example:
2205
2206   my $cd = $schema->resultset('CD')->find_or_create(
2207     {
2208       artist => 'Massive Attack',
2209       title  => 'Mezzanine',
2210     },
2211     { key => 'cd_artist_title' }
2212   );
2213
2214 B<Note>: Because find_or_create() reads from the database and then
2215 possibly inserts based on the result, this method is subject to a race
2216 condition. Another process could create a record in the table after
2217 the find has completed and before the create has started. To avoid
2218 this problem, use find_or_create() inside a transaction.
2219
2220 B<Note>: C<find_or_create> is probably not what you want when creating
2221 a new row in a table that uses primary keys supplied by the
2222 database. Passing in a primary key column with a value of I<undef>
2223 will cause L</find> to attempt to search for a row with a value of
2224 I<NULL>.
2225
2226 See also L</find> and L</update_or_create>. For information on how to declare
2227 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2228
2229 =cut
2230
2231 sub find_or_create {
2232   my $self     = shift;
2233   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2234   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2235   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2236     return $row;
2237   }
2238   return $self->create($hash);
2239 }
2240
2241 =head2 update_or_create
2242
2243 =over 4
2244
2245 =item Arguments: \%col_values, { key => $unique_constraint }?
2246
2247 =item Return Value: $rowobject
2248
2249 =back
2250
2251   $resultset->update_or_create({ col => $val, ... });
2252
2253 First, searches for an existing row matching one of the unique constraints
2254 (including the primary key) on the source of this resultset. If a row is
2255 found, updates it with the other given column values. Otherwise, creates a new
2256 row.
2257
2258 Takes an optional C<key> attribute to search on a specific unique constraint.
2259 For example:
2260
2261   # In your application
2262   my $cd = $schema->resultset('CD')->update_or_create(
2263     {
2264       artist => 'Massive Attack',
2265       title  => 'Mezzanine',
2266       year   => 1998,
2267     },
2268     { key => 'cd_artist_title' }
2269   );
2270
2271   $cd->cd_to_producer->update_or_create({
2272     producer => $producer,
2273     name => 'harry',
2274   }, {
2275     key => 'primary,
2276   });
2277
2278
2279 If no C<key> is specified, it searches on all unique constraints defined on the
2280 source, including the primary key.
2281
2282 If the C<key> is specified as C<primary>, it searches only on the primary key.
2283
2284 See also L</find> and L</find_or_create>. For information on how to declare
2285 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2286
2287 B<Note>: C<update_or_create> is probably not what you want when
2288 looking for a row in a table that uses primary keys supplied by the
2289 database, unless you actually have a key value. Passing in a primary
2290 key column with a value of I<undef> will cause L</find> to attempt to
2291 search for a row with a value of I<NULL>.
2292
2293 =cut
2294
2295 sub update_or_create {
2296   my $self = shift;
2297   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2298   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2299
2300   my $row = $self->find($cond, $attrs);
2301   if (defined $row) {
2302     $row->update($cond);
2303     return $row;
2304   }
2305
2306   return $self->create($cond);
2307 }
2308
2309 =head2 update_or_new
2310
2311 =over 4
2312
2313 =item Arguments: \%col_values, { key => $unique_constraint }?
2314
2315 =item Return Value: $rowobject
2316
2317 =back
2318
2319   $resultset->update_or_new({ col => $val, ... });
2320
2321 First, searches for an existing row matching one of the unique constraints
2322 (including the primary key) on the source of this resultset. If a row is
2323 found, updates it with the other given column values. Otherwise, instantiate
2324 a new result object and return it. The object will not be saved into your storage
2325 until you call L<DBIx::Class::Row/insert> on it.
2326
2327 Takes an optional C<key> attribute to search on a specific unique constraint.
2328 For example:
2329
2330   # In your application
2331   my $cd = $schema->resultset('CD')->update_or_new(
2332     {
2333       artist => 'Massive Attack',
2334       title  => 'Mezzanine',
2335       year   => 1998,
2336     },
2337     { key => 'cd_artist_title' }
2338   );
2339
2340   if ($cd->in_storage) {
2341       # the cd was updated
2342   }
2343   else {
2344       # the cd is not yet in the database, let's insert it
2345       $cd->insert;
2346   }
2347
2348 See also L</find>, L</find_or_create> and L<find_or_new>.
2349
2350 =cut
2351
2352 sub update_or_new {
2353     my $self  = shift;
2354     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2355     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2356
2357     my $row = $self->find( $cond, $attrs );
2358     if ( defined $row ) {
2359         $row->update($cond);
2360         return $row;
2361     }
2362
2363     return $self->new_result($cond);
2364 }
2365
2366 =head2 get_cache
2367
2368 =over 4
2369
2370 =item Arguments: none
2371
2372 =item Return Value: \@cache_objects?
2373
2374 =back
2375
2376 Gets the contents of the cache for the resultset, if the cache is set.
2377
2378 The cache is populated either by using the L</prefetch> attribute to
2379 L</search> or by calling L</set_cache>.
2380
2381 =cut
2382
2383 sub get_cache {
2384   shift->{all_cache};
2385 }
2386
2387 =head2 set_cache
2388
2389 =over 4
2390
2391 =item Arguments: \@cache_objects
2392
2393 =item Return Value: \@cache_objects
2394
2395 =back
2396
2397 Sets the contents of the cache for the resultset. Expects an arrayref
2398 of objects of the same class as those produced by the resultset. Note that
2399 if the cache is set the resultset will return the cached objects rather
2400 than re-querying the database even if the cache attr is not set.
2401
2402 The contents of the cache can also be populated by using the
2403 L</prefetch> attribute to L</search>.
2404
2405 =cut
2406
2407 sub set_cache {
2408   my ( $self, $data ) = @_;
2409   $self->throw_exception("set_cache requires an arrayref")
2410       if defined($data) && (ref $data ne 'ARRAY');
2411   $self->{all_cache} = $data;
2412 }
2413
2414 =head2 clear_cache
2415
2416 =over 4
2417
2418 =item Arguments: none
2419
2420 =item Return Value: []
2421
2422 =back
2423
2424 Clears the cache for the resultset.
2425
2426 =cut
2427
2428 sub clear_cache {
2429   shift->set_cache(undef);
2430 }
2431
2432 =head2 related_resultset
2433
2434 =over 4
2435
2436 =item Arguments: $relationship_name
2437
2438 =item Return Value: $resultset
2439
2440 =back
2441
2442 Returns a related resultset for the supplied relationship name.
2443
2444   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2445
2446 =cut
2447
2448 sub related_resultset {
2449   my ($self, $rel) = @_;
2450
2451   $self->{related_resultsets} ||= {};
2452   return $self->{related_resultsets}{$rel} ||= do {
2453     my $rel_info = $self->result_source->relationship_info($rel);
2454
2455     $self->throw_exception(
2456       "search_related: result source '" . $self->result_source->source_name .
2457         "' has no such relationship $rel")
2458       unless $rel_info;
2459
2460     my ($from,$seen) = $self->_chain_relationship($rel);
2461
2462     my $join_count = $seen->{$rel};
2463     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2464
2465     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2466     my %attrs = %{$self->{attrs}||{}};
2467     delete @attrs{qw(result_class alias)};
2468
2469     my $new_cache;
2470
2471     if (my $cache = $self->get_cache) {
2472       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2473         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2474                         @$cache ];
2475       }
2476     }
2477
2478     my $rel_source = $self->result_source->related_source($rel);
2479
2480     my $new = do {
2481
2482       # The reason we do this now instead of passing the alias to the
2483       # search_rs below is that if you wrap/overload resultset on the
2484       # source you need to know what alias it's -going- to have for things
2485       # to work sanely (e.g. RestrictWithObject wants to be able to add
2486       # extra query restrictions, and these may need to be $alias.)
2487
2488       my $attrs = $rel_source->resultset_attributes;
2489       local $attrs->{alias} = $alias;
2490
2491       $rel_source->resultset
2492                  ->search_rs(
2493                      undef, {
2494                        %attrs,
2495                        join => undef,
2496                        prefetch => undef,
2497                        select => undef,
2498                        as => undef,
2499                        where => $self->{cond},
2500                        seen_join => $seen,
2501                        from => $from,
2502                    });
2503     };
2504     $new->set_cache($new_cache) if $new_cache;
2505     $new;
2506   };
2507 }
2508
2509 =head2 current_source_alias
2510
2511 =over 4
2512
2513 =item Arguments: none
2514
2515 =item Return Value: $source_alias
2516
2517 =back
2518
2519 Returns the current table alias for the result source this resultset is built
2520 on, that will be used in the SQL query. Usually it is C<me>.
2521
2522 Currently the source alias that refers to the result set returned by a
2523 L</search>/L</find> family method depends on how you got to the resultset: it's
2524 C<me> by default, but eg. L</search_related> aliases it to the related result
2525 source name (and keeps C<me> referring to the original result set). The long
2526 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2527 (and make this method unnecessary).
2528
2529 Thus it's currently necessary to use this method in predefined queries (see
2530 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2531 source alias of the current result set:
2532
2533   # in a result set class
2534   sub modified_by {
2535     my ($self, $user) = @_;
2536
2537     my $me = $self->current_source_alias;
2538
2539     return $self->search(
2540       "$me.modified" => $user->id,
2541     );
2542   }
2543
2544 =cut
2545
2546 sub current_source_alias {
2547   my ($self) = @_;
2548
2549   return ($self->{attrs} || {})->{alias} || 'me';
2550 }
2551
2552 # This code is called by search_related, and makes sure there
2553 # is clear separation between the joins before, during, and
2554 # after the relationship. This information is needed later
2555 # in order to properly resolve prefetch aliases (any alias
2556 # with a relation_chain_depth less than the depth of the
2557 # current prefetch is not considered)
2558 sub _chain_relationship {
2559   my ($self, $rel) = @_;
2560   my $source = $self->result_source;
2561   my $attrs = $self->{attrs};
2562
2563   my $from = [ @{
2564       $attrs->{from}
2565         ||
2566       [{
2567         -source_handle => $source->handle,
2568         -alias => $attrs->{alias},
2569         $attrs->{alias} => $source->from,
2570       }]
2571   }];
2572
2573   my $seen = { %{$attrs->{seen_join} || {} } };
2574
2575   # we need to take the prefetch the attrs into account before we
2576   # ->_resolve_join as otherwise they get lost - captainL
2577   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2578
2579   my @requested_joins = $source->_resolve_join($merged, $attrs->{alias}, $seen);
2580
2581   push @$from, @requested_joins;
2582
2583   ++$seen->{-relation_chain_depth};
2584
2585   # if $self already had a join/prefetch specified on it, the requested
2586   # $rel might very well be already included. What we do in this case
2587   # is effectively a no-op (except that we bump up the chain_depth on
2588   # the join in question so we could tell it *is* the search_related)
2589   my $already_joined;
2590
2591   # we consider the last one thus reverse
2592   for my $j (reverse @requested_joins) {
2593     if ($rel eq $j->[0]{-join_path}[-1]) {
2594       $j->[0]{-relation_chain_depth}++;
2595       $already_joined++;
2596       last;
2597     }
2598   }
2599   unless ($already_joined) {
2600     push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2601   }
2602
2603   ++$seen->{-relation_chain_depth};
2604
2605   return ($from,$seen);
2606 }
2607
2608 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2609 sub _resolved_attrs_copy {
2610   my $self = shift;
2611   return { %{$self->_resolved_attrs (@_)} };
2612 }
2613
2614 sub _resolved_attrs {
2615   my $self = shift;
2616   return $self->{_attrs} if $self->{_attrs};
2617
2618   my $attrs  = { %{ $self->{attrs} || {} } };
2619   my $source = $self->result_source;
2620   my $alias  = $attrs->{alias};
2621
2622   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2623   my @colbits;
2624
2625   # build columns (as long as select isn't set) into a set of as/select hashes
2626   unless ( $attrs->{select} ) {
2627       @colbits = map {
2628           ( ref($_) eq 'HASH' )
2629               ? $_
2630               : {
2631                   (
2632                     /^\Q${alias}.\E(.+)$/
2633                       ? "$1"
2634                       : "$_"
2635                   )
2636                 =>
2637                   (
2638                     /\./
2639                       ? "$_"
2640                       : "${alias}.$_"
2641                   )
2642             }
2643       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2644   }
2645   # add the additional columns on
2646   foreach ( 'include_columns', '+columns' ) {
2647       push @colbits, map {
2648           ( ref($_) eq 'HASH' )
2649             ? $_
2650             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2651       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2652   }
2653
2654   # start with initial select items
2655   if ( $attrs->{select} ) {
2656     $attrs->{select} =
2657         ( ref $attrs->{select} eq 'ARRAY' )
2658       ? [ @{ $attrs->{select} } ]
2659       : [ $attrs->{select} ];
2660     $attrs->{as} = (
2661       $attrs->{as}
2662       ? (
2663         ref $attrs->{as} eq 'ARRAY'
2664         ? [ @{ $attrs->{as} } ]
2665         : [ $attrs->{as} ]
2666         )
2667       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2668     );
2669   }
2670   else {
2671
2672     # otherwise we intialise select & as to empty
2673     $attrs->{select} = [];
2674     $attrs->{as}     = [];
2675   }
2676
2677   # now add colbits to select/as
2678   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2679   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2680
2681   my $adds;
2682   if ( $adds = delete $attrs->{'+select'} ) {
2683     $adds = [$adds] unless ref $adds eq 'ARRAY';
2684     push(
2685       @{ $attrs->{select} },
2686       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2687     );
2688   }
2689   if ( $adds = delete $attrs->{'+as'} ) {
2690     $adds = [$adds] unless ref $adds eq 'ARRAY';
2691     push( @{ $attrs->{as} }, @$adds );
2692   }
2693
2694   $attrs->{from} ||= [ {
2695     -source_handle => $source->handle,
2696     -alias => $self->{attrs}{alias},
2697     $self->{attrs}{alias} => $source->from,
2698   } ];
2699
2700   if ( $attrs->{join} || $attrs->{prefetch} ) {
2701
2702     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2703       if ref $attrs->{from} ne 'ARRAY';
2704
2705     my $join = delete $attrs->{join} || {};
2706
2707     if ( defined $attrs->{prefetch} ) {
2708       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2709     }
2710
2711     $attrs->{from} =    # have to copy here to avoid corrupting the original
2712       [
2713         @{ $attrs->{from} },
2714         $source->_resolve_join(
2715           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2716         )
2717       ];
2718   }
2719
2720   if ( $attrs->{order_by} ) {
2721     $attrs->{order_by} = (
2722       ref( $attrs->{order_by} ) eq 'ARRAY'
2723       ? [ @{ $attrs->{order_by} } ]
2724       : [ $attrs->{order_by} ]
2725     );
2726   }
2727
2728   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2729     $attrs->{group_by} = [ $attrs->{group_by} ];
2730   }
2731
2732   # If the order_by is otherwise empty - we will use this for TOP limit
2733   # emulation and the like.
2734   # Although this is needed only if the order_by is not defined, it is
2735   # actually cheaper to just populate this rather than properly examining
2736   # order_by (stuf like [ {} ] and the like)
2737   my $prefix = $alias . ($source->schema->storage->sql_maker->{name_sep} || '.');
2738   $attrs->{_virtual_order_by} = [
2739     map { $prefix . $_ } ($source->primary_columns)
2740   ];
2741
2742   $attrs->{collapse} ||= {};
2743   if ( my $prefetch = delete $attrs->{prefetch} ) {
2744     $prefetch = $self->_merge_attr( {}, $prefetch );
2745
2746     my $prefetch_ordering = [];
2747
2748     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2749
2750     my @prefetch =
2751       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2752
2753     $attrs->{prefetch_select} = [ map { $_->[0] } @prefetch ];
2754     push @{ $attrs->{select} }, @{$attrs->{prefetch_select}};
2755     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2756
2757     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2758     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2759   }
2760
2761
2762   if (delete $attrs->{distinct}) {
2763     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2764   }
2765
2766   # if both page and offset are specified, produce a combined offset
2767   # even though it doesn't make much sense, this is what pre 081xx has
2768   # been doing
2769   if (my $page = delete $attrs->{page}) {
2770     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2771       ($attrs->{offset} || 0);
2772   }
2773
2774   return $self->{_attrs} = $attrs;
2775 }
2776
2777 sub _joinpath_aliases {
2778   my ($self, $fromspec, $seen) = @_;
2779
2780   my $paths = {};
2781   return $paths unless ref $fromspec eq 'ARRAY';
2782
2783   for my $j (@$fromspec) {
2784
2785     next if ref $j ne 'ARRAY';
2786     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2787
2788     my $p = $paths;
2789     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2790     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2791   }
2792
2793   return $paths;
2794 }
2795
2796 sub _rollout_attr {
2797   my ($self, $attr) = @_;
2798
2799   if (ref $attr eq 'HASH') {
2800     return $self->_rollout_hash($attr);
2801   } elsif (ref $attr eq 'ARRAY') {
2802     return $self->_rollout_array($attr);
2803   } else {
2804     return [$attr];
2805   }
2806 }
2807
2808 sub _rollout_array {
2809   my ($self, $attr) = @_;
2810
2811   my @rolled_array;
2812   foreach my $element (@{$attr}) {
2813     if (ref $element eq 'HASH') {
2814       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2815     } elsif (ref $element eq 'ARRAY') {
2816       #  XXX - should probably recurse here
2817       push( @rolled_array, @{$self->_rollout_array($element)} );
2818     } else {
2819       push( @rolled_array, $element );
2820     }
2821   }
2822   return \@rolled_array;
2823 }
2824
2825 sub _rollout_hash {
2826   my ($self, $attr) = @_;
2827
2828   my @rolled_array;
2829   foreach my $key (keys %{$attr}) {
2830     push( @rolled_array, { $key => $attr->{$key} } );
2831   }
2832   return \@rolled_array;
2833 }
2834
2835 sub _calculate_score {
2836   my ($self, $a, $b) = @_;
2837
2838   if (ref $b eq 'HASH') {
2839     my ($b_key) = keys %{$b};
2840     if (ref $a eq 'HASH') {
2841       my ($a_key) = keys %{$a};
2842       if ($a_key eq $b_key) {
2843         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2844       } else {
2845         return 0;
2846       }
2847     } else {
2848       return ($a eq $b_key) ? 1 : 0;
2849     }
2850   } else {
2851     if (ref $a eq 'HASH') {
2852       my ($a_key) = keys %{$a};
2853       return ($b eq $a_key) ? 1 : 0;
2854     } else {
2855       return ($b eq $a) ? 1 : 0;
2856     }
2857   }
2858 }
2859
2860 sub _merge_attr {
2861   my ($self, $orig, $import) = @_;
2862
2863   return $import unless defined($orig);
2864   return $orig unless defined($import);
2865
2866   $orig = $self->_rollout_attr($orig);
2867   $import = $self->_rollout_attr($import);
2868
2869   my $seen_keys;
2870   foreach my $import_element ( @{$import} ) {
2871     # find best candidate from $orig to merge $b_element into
2872     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2873     foreach my $orig_element ( @{$orig} ) {
2874       my $score = $self->_calculate_score( $orig_element, $import_element );
2875       if ($score > $best_candidate->{score}) {
2876         $best_candidate->{position} = $position;
2877         $best_candidate->{score} = $score;
2878       }
2879       $position++;
2880     }
2881     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2882
2883     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2884       push( @{$orig}, $import_element );
2885     } else {
2886       my $orig_best = $orig->[$best_candidate->{position}];
2887       # merge orig_best and b_element together and replace original with merged
2888       if (ref $orig_best ne 'HASH') {
2889         $orig->[$best_candidate->{position}] = $import_element;
2890       } elsif (ref $import_element eq 'HASH') {
2891         my ($key) = keys %{$orig_best};
2892         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2893       }
2894     }
2895     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2896   }
2897
2898   return $orig;
2899 }
2900
2901 sub result_source {
2902     my $self = shift;
2903
2904     if (@_) {
2905         $self->_source_handle($_[0]->handle);
2906     } else {
2907         $self->_source_handle->resolve;
2908     }
2909 }
2910
2911 =head2 throw_exception
2912
2913 See L<DBIx::Class::Schema/throw_exception> for details.
2914
2915 =cut
2916
2917 sub throw_exception {
2918   my $self=shift;
2919   if (ref $self && $self->_source_handle->schema) {
2920     $self->_source_handle->schema->throw_exception(@_)
2921   } else {
2922     croak(@_);
2923   }
2924
2925 }
2926
2927 # XXX: FIXME: Attributes docs need clearing up
2928
2929 =head1 ATTRIBUTES
2930
2931 Attributes are used to refine a ResultSet in various ways when
2932 searching for data. They can be passed to any method which takes an
2933 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2934 L</count>.
2935
2936 These are in no particular order:
2937
2938 =head2 order_by
2939
2940 =over 4
2941
2942 =item Value: ( $order_by | \@order_by | \%order_by )
2943
2944 =back
2945
2946 Which column(s) to order the results by. If a single column name, or
2947 an arrayref of names is supplied, the argument is passed through
2948 directly to SQL. The hashref syntax allows for connection-agnostic
2949 specification of ordering direction:
2950
2951  For descending order:
2952
2953   order_by => { -desc => [qw/col1 col2 col3/] }
2954
2955  For explicit ascending order:
2956
2957   order_by => { -asc => 'col' }
2958
2959 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2960 supported, although you are strongly encouraged to use the hashref
2961 syntax as outlined above.
2962
2963 =head2 columns
2964
2965 =over 4
2966
2967 =item Value: \@columns
2968
2969 =back
2970
2971 Shortcut to request a particular set of columns to be retrieved. Each
2972 column spec may be a string (a table column name), or a hash (in which
2973 case the key is the C<as> value, and the value is used as the C<select>
2974 expression). Adds C<me.> onto the start of any column without a C<.> in
2975 it and sets C<select> from that, then auto-populates C<as> from
2976 C<select> as normal. (You may also use the C<cols> attribute, as in
2977 earlier versions of DBIC.)
2978
2979 =head2 +columns
2980
2981 =over 4
2982
2983 =item Value: \@columns
2984
2985 =back
2986
2987 Indicates additional columns to be selected from storage. Works the same
2988 as L</columns> but adds columns to the selection. (You may also use the
2989 C<include_columns> attribute, as in earlier versions of DBIC). For
2990 example:-
2991
2992   $schema->resultset('CD')->search(undef, {
2993     '+columns' => ['artist.name'],
2994     join => ['artist']
2995   });
2996
2997 would return all CDs and include a 'name' column to the information
2998 passed to object inflation. Note that the 'artist' is the name of the
2999 column (or relationship) accessor, and 'name' is the name of the column
3000 accessor in the related table.
3001
3002 =head2 include_columns
3003
3004 =over 4
3005
3006 =item Value: \@columns
3007
3008 =back
3009
3010 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3011
3012 =head2 select
3013
3014 =over 4
3015
3016 =item Value: \@select_columns
3017
3018 =back
3019
3020 Indicates which columns should be selected from the storage. You can use
3021 column names, or in the case of RDBMS back ends, function or stored procedure
3022 names:
3023
3024   $rs = $schema->resultset('Employee')->search(undef, {
3025     select => [
3026       'name',
3027       { count => 'employeeid' },
3028       { sum => 'salary' }
3029     ]
3030   });
3031
3032 When you use function/stored procedure names and do not supply an C<as>
3033 attribute, the column names returned are storage-dependent. E.g. MySQL would
3034 return a column named C<count(employeeid)> in the above example.
3035
3036 =head2 +select
3037
3038 =over 4
3039
3040 Indicates additional columns to be selected from storage.  Works the same as
3041 L</select> but adds columns to the selection.
3042
3043 =back
3044
3045 =head2 +as
3046
3047 =over 4
3048
3049 Indicates additional column names for those added via L</+select>. See L</as>.
3050
3051 =back
3052
3053 =head2 as
3054
3055 =over 4
3056
3057 =item Value: \@inflation_names
3058
3059 =back
3060
3061 Indicates column names for object inflation. That is, C<as>
3062 indicates the name that the column can be accessed as via the
3063 C<get_column> method (or via the object accessor, B<if one already
3064 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3065
3066 The C<as> attribute is used in conjunction with C<select>,
3067 usually when C<select> contains one or more function or stored
3068 procedure names:
3069
3070   $rs = $schema->resultset('Employee')->search(undef, {
3071     select => [
3072       'name',
3073       { count => 'employeeid' }
3074     ],
3075     as => ['name', 'employee_count'],
3076   });
3077
3078   my $employee = $rs->first(); # get the first Employee
3079
3080 If the object against which the search is performed already has an accessor
3081 matching a column name specified in C<as>, the value can be retrieved using
3082 the accessor as normal:
3083
3084   my $name = $employee->name();
3085
3086 If on the other hand an accessor does not exist in the object, you need to
3087 use C<get_column> instead:
3088
3089   my $employee_count = $employee->get_column('employee_count');
3090
3091 You can create your own accessors if required - see
3092 L<DBIx::Class::Manual::Cookbook> for details.
3093
3094 Please note: This will NOT insert an C<AS employee_count> into the SQL
3095 statement produced, it is used for internal access only. Thus
3096 attempting to use the accessor in an C<order_by> clause or similar
3097 will fail miserably.
3098
3099 To get around this limitation, you can supply literal SQL to your
3100 C<select> attibute that contains the C<AS alias> text, eg:
3101
3102   select => [\'myfield AS alias']
3103
3104 =head2 join
3105
3106 =over 4
3107
3108 =item Value: ($rel_name | \@rel_names | \%rel_names)
3109
3110 =back
3111
3112 Contains a list of relationships that should be joined for this query.  For
3113 example:
3114
3115   # Get CDs by Nine Inch Nails
3116   my $rs = $schema->resultset('CD')->search(
3117     { 'artist.name' => 'Nine Inch Nails' },
3118     { join => 'artist' }
3119   );
3120
3121 Can also contain a hash reference to refer to the other relation's relations.
3122 For example:
3123
3124   package MyApp::Schema::Track;
3125   use base qw/DBIx::Class/;
3126   __PACKAGE__->table('track');
3127   __PACKAGE__->add_columns(qw/trackid cd position title/);
3128   __PACKAGE__->set_primary_key('trackid');
3129   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3130   1;
3131
3132   # In your application
3133   my $rs = $schema->resultset('Artist')->search(
3134     { 'track.title' => 'Teardrop' },
3135     {
3136       join     => { cd => 'track' },
3137       order_by => 'artist.name',
3138     }
3139   );
3140
3141 You need to use the relationship (not the table) name in  conditions,
3142 because they are aliased as such. The current table is aliased as "me", so
3143 you need to use me.column_name in order to avoid ambiguity. For example:
3144
3145   # Get CDs from 1984 with a 'Foo' track
3146   my $rs = $schema->resultset('CD')->search(
3147     {
3148       'me.year' => 1984,
3149       'tracks.name' => 'Foo'
3150     },
3151     { join => 'tracks' }
3152   );
3153
3154 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3155 similarly for a third time). For e.g.
3156
3157   my $rs = $schema->resultset('Artist')->search({
3158     'cds.title'   => 'Down to Earth',
3159     'cds_2.title' => 'Popular',
3160   }, {
3161     join => [ qw/cds cds/ ],
3162   });
3163
3164 will return a set of all artists that have both a cd with title 'Down
3165 to Earth' and a cd with title 'Popular'.
3166
3167 If you want to fetch related objects from other tables as well, see C<prefetch>
3168 below.
3169
3170 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3171
3172 =head2 prefetch
3173
3174 =over 4
3175
3176 =item Value: ($rel_name | \@rel_names | \%rel_names)
3177
3178 =back
3179
3180 Contains one or more relationships that should be fetched along with
3181 the main query (when they are accessed afterwards the data will
3182 already be available, without extra queries to the database).  This is
3183 useful for when you know you will need the related objects, because it
3184 saves at least one query:
3185
3186   my $rs = $schema->resultset('Tag')->search(
3187     undef,
3188     {
3189       prefetch => {
3190         cd => 'artist'
3191       }
3192     }
3193   );
3194
3195 The initial search results in SQL like the following:
3196
3197   SELECT tag.*, cd.*, artist.* FROM tag
3198   JOIN cd ON tag.cd = cd.cdid
3199   JOIN artist ON cd.artist = artist.artistid
3200
3201 L<DBIx::Class> has no need to go back to the database when we access the
3202 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3203 case.
3204
3205 Simple prefetches will be joined automatically, so there is no need
3206 for a C<join> attribute in the above search.
3207
3208 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3209 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3210 with an accessor type of 'single' or 'filter'). A more complex example that
3211 prefetches an artists cds, the tracks on those cds, and the tags associted
3212 with that artist is given below (assuming many-to-many from artists to tags):
3213
3214  my $rs = $schema->resultset('Artist')->search(
3215    undef,
3216    {
3217      prefetch => [
3218        { cds => 'tracks' },
3219        { artist_tags => 'tags' }
3220      ]
3221    }
3222  );
3223
3224
3225 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3226 attributes will be ignored.
3227
3228 =head2 page
3229
3230 =over 4
3231
3232 =item Value: $page
3233
3234 =back
3235
3236 Makes the resultset paged and specifies the page to retrieve. Effectively
3237 identical to creating a non-pages resultset and then calling ->page($page)
3238 on it.
3239
3240 If L<rows> attribute is not specified it defaults to 10 rows per page.
3241
3242 When you have a paged resultset, L</count> will only return the number
3243 of rows in the page. To get the total, use the L</pager> and call
3244 C<total_entries> on it.
3245
3246 =head2 rows
3247
3248 =over 4
3249
3250 =item Value: $rows
3251
3252 =back
3253
3254 Specifes the maximum number of rows for direct retrieval or the number of
3255 rows per page if the page attribute or method is used.
3256
3257 =head2 offset
3258
3259 =over 4
3260
3261 =item Value: $offset
3262
3263 =back
3264
3265 Specifies the (zero-based) row number for the  first row to be returned, or the
3266 of the first row of the first page if paging is used.
3267
3268 =head2 group_by
3269
3270 =over 4
3271
3272 =item Value: \@columns
3273
3274 =back
3275
3276 A arrayref of columns to group by. Can include columns of joined tables.
3277
3278   group_by => [qw/ column1 column2 ... /]
3279
3280 =head2 having
3281
3282 =over 4
3283
3284 =item Value: $condition
3285
3286 =back
3287
3288 HAVING is a select statement attribute that is applied between GROUP BY and
3289 ORDER BY. It is applied to the after the grouping calculations have been
3290 done.
3291
3292   having => { 'count(employee)' => { '>=', 100 } }
3293
3294 =head2 distinct
3295
3296 =over 4
3297
3298 =item Value: (0 | 1)
3299
3300 =back
3301
3302 Set to 1 to group by all columns.
3303
3304 =head2 where
3305
3306 =over 4
3307
3308 Adds to the WHERE clause.
3309
3310   # only return rows WHERE deleted IS NULL for all searches
3311   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3312
3313 Can be overridden by passing C<{ where => undef }> as an attribute
3314 to a resulset.
3315
3316 =back
3317
3318 =head2 cache
3319
3320 Set to 1 to cache search results. This prevents extra SQL queries if you
3321 revisit rows in your ResultSet:
3322
3323   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3324
3325   while( my $artist = $resultset->next ) {
3326     ... do stuff ...
3327   }
3328
3329   $rs->first; # without cache, this would issue a query
3330
3331 By default, searches are not cached.
3332
3333 For more examples of using these attributes, see
3334 L<DBIx::Class::Manual::Cookbook>.
3335
3336 =head2 from
3337
3338 =over 4
3339
3340 =item Value: \@from_clause
3341
3342 =back
3343
3344 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3345 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3346 clauses.
3347
3348 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3349
3350 C<join> will usually do what you need and it is strongly recommended that you
3351 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3352 And we really do mean "cannot", not just tried and failed. Attempting to use
3353 this because you're having problems with C<join> is like trying to use x86
3354 ASM because you've got a syntax error in your C. Trust us on this.
3355
3356 Now, if you're still really, really sure you need to use this (and if you're
3357 not 100% sure, ask the mailing list first), here's an explanation of how this
3358 works.
3359
3360 The syntax is as follows -
3361
3362   [
3363     { <alias1> => <table1> },
3364     [
3365       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3366       [], # nested JOIN (optional)
3367       { <table1.column1> => <table2.column2>, ... (more conditions) },
3368     ],
3369     # More of the above [ ] may follow for additional joins
3370   ]
3371
3372   <table1> <alias1>
3373   JOIN
3374     <table2> <alias2>
3375     [JOIN ...]
3376   ON <table1.column1> = <table2.column2>
3377   <more joins may follow>
3378
3379 An easy way to follow the examples below is to remember the following:
3380
3381     Anything inside "[]" is a JOIN
3382     Anything inside "{}" is a condition for the enclosing JOIN
3383
3384 The following examples utilize a "person" table in a family tree application.
3385 In order to express parent->child relationships, this table is self-joined:
3386
3387     # Person->belongs_to('father' => 'Person');
3388     # Person->belongs_to('mother' => 'Person');
3389
3390 C<from> can be used to nest joins. Here we return all children with a father,
3391 then search against all mothers of those children:
3392
3393   $rs = $schema->resultset('Person')->search(
3394       undef,
3395       {
3396           alias => 'mother', # alias columns in accordance with "from"
3397           from => [
3398               { mother => 'person' },
3399               [
3400                   [
3401                       { child => 'person' },
3402                       [
3403                           { father => 'person' },
3404                           { 'father.person_id' => 'child.father_id' }
3405                       ]
3406                   ],
3407                   { 'mother.person_id' => 'child.mother_id' }
3408               ],
3409           ]
3410       },
3411   );
3412
3413   # Equivalent SQL:
3414   # SELECT mother.* FROM person mother
3415   # JOIN (
3416   #   person child
3417   #   JOIN person father
3418   #   ON ( father.person_id = child.father_id )
3419   # )
3420   # ON ( mother.person_id = child.mother_id )
3421
3422 The type of any join can be controlled manually. To search against only people
3423 with a father in the person table, we could explicitly use C<INNER JOIN>:
3424
3425     $rs = $schema->resultset('Person')->search(
3426         undef,
3427         {
3428             alias => 'child', # alias columns in accordance with "from"
3429             from => [
3430                 { child => 'person' },
3431                 [
3432                     { father => 'person', -join_type => 'inner' },
3433                     { 'father.id' => 'child.father_id' }
3434                 ],
3435             ]
3436         },
3437     );
3438
3439     # Equivalent SQL:
3440     # SELECT child.* FROM person child
3441     # INNER JOIN person father ON child.father_id = father.id
3442
3443 You can select from a subquery by passing a resultset to from as follows.
3444
3445     $schema->resultset('Artist')->search(
3446         undef,
3447         {   alias => 'artist2',
3448             from  => [ { artist2 => $artist_rs->as_query } ],
3449         } );
3450
3451     # and you'll get sql like this..
3452     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3453     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3454
3455 If you need to express really complex joins, you
3456 can supply literal SQL to C<from> via a scalar reference. In this case
3457 the contents of the scalar will replace the table name associated with the
3458 resultsource.
3459
3460 WARNING: This technique might very well not work as expected on chained
3461 searches - you have been warned.
3462
3463     # Assuming the Event resultsource is defined as:
3464
3465         MySchema::Event->add_columns (
3466             sequence => {
3467                 data_type => 'INT',
3468                 is_auto_increment => 1,
3469             },
3470             location => {
3471                 data_type => 'INT',
3472             },
3473             type => {
3474                 data_type => 'INT',
3475             },
3476         );
3477         MySchema::Event->set_primary_key ('sequence');
3478
3479     # This will get back the latest event for every location. The column
3480     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3481     # combo to limit the resultset
3482
3483     $rs = $schema->resultset('Event');
3484     $table = $rs->result_source->name;
3485     $latest = $rs->search (
3486         undef,
3487         { from => \ "
3488             (SELECT e1.* FROM $table e1
3489                 JOIN $table e2
3490                     ON e1.location = e2.location
3491                     AND e1.sequence < e2.sequence
3492                 WHERE e2.sequence is NULL
3493             ) me",
3494         },
3495     );
3496
3497     # Equivalent SQL (with the DBIC chunks added):
3498
3499     SELECT me.sequence, me.location, me.type FROM
3500        (SELECT e1.* FROM events e1
3501            JOIN events e2
3502                ON e1.location = e2.location
3503                AND e1.sequence < e2.sequence
3504            WHERE e2.sequence is NULL
3505        ) me;
3506
3507 =head2 for
3508
3509 =over 4
3510
3511 =item Value: ( 'update' | 'shared' )
3512
3513 =back
3514
3515 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3516 ... FOR SHARED.
3517
3518 =cut
3519
3520 1;