lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => \&count,
   7         'bool'   => sub { 1; },
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use base qw/DBIx::Class/;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/result_class _source_handle/);
  17
  18 =head1 NAME
  19
  20 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  21
  22 =head1 SYNOPSIS
  23
  24   my $rs   = $schema->resultset('User')->search(registered => 1);
  25   my @rows = $schema->resultset('CD')->search(year => 2005);
  26
  27 =head1 DESCRIPTION
  28
  29 The resultset is also known as an iterator. It is responsible for handling
  30 queries that may return an arbitrary number of rows, e.g. via L</search>
  31 or a C<has_many> relationship.
  32
  33 In the examples below, the following table classes are used:
  34
  35   package MyApp::Schema::Artist;
  36   use base qw/DBIx::Class/;
  37   __PACKAGE__->load_components(qw/Core/);
  38   __PACKAGE__->table('artist');
  39   __PACKAGE__->add_columns(qw/artistid name/);
  40   __PACKAGE__->set_primary_key('artistid');
  41   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  42   1;
  43
  44   package MyApp::Schema::CD;
  45   use base qw/DBIx::Class/;
  46   __PACKAGE__->load_components(qw/Core/);
  47   __PACKAGE__->table('cd');
  48   __PACKAGE__->add_columns(qw/cdid artist title year/);
  49   __PACKAGE__->set_primary_key('cdid');
  50   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  51   1;
  52
  53 =head1 METHODS
  54
  55 =head2 new
  56
  57 =over 4
  58
  59 =item Arguments: $source, \%$attrs
  60
  61 =item Return Value: $rs
  62
  63 =back
  64
  65 The resultset constructor. Takes a source object (usually a
  66 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  67 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  68 executed as needed by the other methods.
  69
  70 Generally you won't need to construct a resultset manually.  You'll
  71 automatically get one from e.g. a L</search> called in scalar context:
  72
  73   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  74
  75 IMPORTANT: If called on an object, proxies to new_result instead so
  76
  77   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  78
  79 will return a CD object, not a ResultSet.
  80
  81 =cut
  82
  83 sub new {
  84   my $class = shift;
  85   return $class->new_result(@_) if ref $class;
  86
  87   my ($source, $attrs) = @_;
  88   $source = $source->handle
  89     unless $source->isa('DBIx::Class::ResultSourceHandle');
  90   $attrs = { %{$attrs||{}} };
  91
  92   if ($attrs->{page}) {
  93     $attrs->{rows} ||= 10;
  94     $attrs->{offset} ||= 0;
  95     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
  96   }
  97
  98   $attrs->{alias} ||= 'me';
  99
 100   my $self = {
 101     _source_handle => $source,
 102     result_class => $attrs->{result_class} || $source->resolve->result_class,
 103     cond => $attrs->{where},
 104     count => undef,
 105     pager => undef,
 106     attrs => $attrs
 107   };
 108
 109   bless $self, $class;
 110
 111   return $self;
 112 }
 113
 114 =head2 search
 115
 116 =over 4
 117
 118 =item Arguments: $cond, \%attrs?
 119
 120 =item Return Value: $resultset (scalar context), @row_objs (list context)
 121
 122 =back
 123
 124   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 125   my $new_rs = $cd_rs->search({ year => 2005 });
 126
 127   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 128                  # year = 2005 OR year = 2004
 129
 130 If you need to pass in additional attributes but no additional condition,
 131 call it as C<search(undef, \%attrs)>.
 132
 133   # "SELECT name, artistid FROM $artist_table"
 134   my @all_artists = $schema->resultset('Artist')->search(undef, {
 135     columns => [qw/name artistid/],
 136   });
 137
 138 For a list of attributes that can be passed to C<search>, see
 139 L</ATTRIBUTES>. For more examples of using this function, see
 140 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 141 documentation for the first argument, see L<SQL::Abstract>.
 142
 143 =cut
 144
 145 sub search {
 146   my $self = shift;
 147   my $rs = $self->search_rs( @_ );
 148   return (wantarray ? $rs->all : $rs);
 149 }
 150
 151 =head2 search_rs
 152
 153 =over 4
 154
 155 =item Arguments: $cond, \%attrs?
 156
 157 =item Return Value: $resultset
 158
 159 =back
 160
 161 This method does the same exact thing as search() except it will
 162 always return a resultset, even in list context.
 163
 164 =cut
 165
 166 sub search_rs {
 167   my $self = shift;
 168
 169   my $rows;
 170
 171   unless (@_) {                 # no search, effectively just a clone
 172     $rows = $self->get_cache;
 173   }
 174
 175   my $attrs = {};
 176   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 177   my $our_attrs = { %{$self->{attrs}} };
 178   my $having = delete $our_attrs->{having};
 179   my $where = delete $our_attrs->{where};
 180
 181   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 182
 183   # merge new attrs into inherited
 184   foreach my $key (qw/join prefetch/) {
 185     next unless exists $attrs->{$key};
 186     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 187   }
 188
 189   my $cond = (@_
 190     ? (
 191         (@_ == 1 || ref $_[0] eq "HASH")
 192           ? (
 193               (ref $_[0] eq 'HASH')
 194                 ? (
 195                     (keys %{ $_[0] }  > 0)
 196                       ? shift
 197                       : undef
 198                    )
 199                 :  shift
 200              )
 201           : (
 202               (@_ % 2)
 203                 ? $self->throw_exception("Odd number of arguments to search")
 204                 : {@_}
 205              )
 206       )
 207     : undef
 208   );
 209
 210   if (defined $where) {
 211     $new_attrs->{where} = (
 212       defined $new_attrs->{where}
 213         ? { '-and' => [
 214               map {
 215                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 216               } $where, $new_attrs->{where}
 217             ]
 218           }
 219         : $where);
 220   }
 221
 222   if (defined $cond) {
 223     $new_attrs->{where} = (
 224       defined $new_attrs->{where}
 225         ? { '-and' => [
 226               map {
 227                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 228               } $cond, $new_attrs->{where}
 229             ]
 230           }
 231         : $cond);
 232   }
 233
 234   if (defined $having) {
 235     $new_attrs->{having} = (
 236       defined $new_attrs->{having}
 237         ? { '-and' => [
 238               map {
 239                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 240               } $having, $new_attrs->{having}
 241             ]
 242           }
 243         : $having);
 244   }
 245
 246   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 247   if ($rows) {
 248     $rs->set_cache($rows);
 249   }
 250   return $rs;
 251 }
 252
 253 =head2 search_literal
 254
 255 =over 4
 256
 257 =item Arguments: $sql_fragment, @bind_values
 258
 259 =item Return Value: $resultset (scalar context), @row_objs (list context)
 260
 261 =back
 262
 263   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 264   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 265
 266 Pass a literal chunk of SQL to be added to the conditional part of the
 267 resultset query.
 268
 269 =cut
 270
 271 sub search_literal {
 272   my ($self, $cond, @vals) = @_;
 273   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 274   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 275   return $self->search(\$cond, $attrs);
 276 }
 277
 278 =head2 find
 279
 280 =over 4
 281
 282 =item Arguments: @values | \%cols, \%attrs?
 283
 284 =item Return Value: $row_object
 285
 286 =back
 287
 288 Finds a row based on its primary key or unique constraint. For example, to find
 289 a row by its primary key:
 290
 291   my $cd = $schema->resultset('CD')->find(5);
 292
 293 You can also find a row by a specific unique constraint using the C<key>
 294 attribute. For example:
 295
 296   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 297     key => 'cd_artist_title'
 298   });
 299
 300 Additionally, you can specify the columns explicitly by name:
 301
 302   my $cd = $schema->resultset('CD')->find(
 303     {
 304       artist => 'Massive Attack',
 305       title  => 'Mezzanine',
 306     },
 307     { key => 'cd_artist_title' }
 308   );
 309
 310 If the C<key> is specified as C<primary>, it searches only on the primary key.
 311
 312 If no C<key> is specified, it searches on all unique constraints defined on the
 313 source, including the primary key.
 314
 315 If your table does not have a primary key, you B<must> provide a value for the
 316 C<key> attribute matching one of the unique constraints on the source.
 317
 318 See also L</find_or_create> and L</update_or_create>. For information on how to
 319 declare unique constraints, see
 320 L<DBIx::Class::ResultSource/add_unique_constraint>.
 321
 322 =cut
 323
 324 sub find {
 325   my $self = shift;
 326   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 327
 328   # Default to the primary key, but allow a specific key
 329   my @cols = exists $attrs->{key}
 330     ? $self->result_source->unique_constraint_columns($attrs->{key})
 331     : $self->result_source->primary_columns;
 332   $self->throw_exception(
 333     "Can't find unless a primary key is defined or unique constraint is specified"
 334   ) unless @cols;
 335
 336   # Parse out a hashref from input
 337   my $input_query;
 338   if (ref $_[0] eq 'HASH') {
 339     $input_query = { %{$_[0]} };
 340   }
 341   elsif (@_ == @cols) {
 342     $input_query = {};
 343     @{$input_query}{@cols} = @_;
 344   }
 345   else {
 346     # Compatibility: Allow e.g. find(id => $value)
 347     carp "Find by key => value deprecated; please use a hashref instead";
 348     $input_query = {@_};
 349   }
 350
 351   my (%related, $info);
 352
 353   foreach my $key (keys %$input_query) {
 354     if (ref($input_query->{$key})
 355         && ($info = $self->result_source->relationship_info($key))) {
 356       my $rel_q = $self->result_source->resolve_condition(
 357                     $info->{cond}, delete $input_query->{$key}, $key
 358                   );
 359       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 360       @related{keys %$rel_q} = values %$rel_q;
 361     }
 362   }
 363   if (my @keys = keys %related) {
 364     @{$input_query}{@keys} = values %related;
 365   }
 366
 367   my @unique_queries = $self->_unique_queries($input_query, $attrs);
 368
 369   # Build the final query: Default to the disjunction of the unique queries,
 370   # but allow the input query in case the ResultSet defines the query or the
 371   # user is abusing find
 372   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 373   my $query = @unique_queries
 374     ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 375     : $self->_add_alias($input_query, $alias);
 376
 377   # Run the query
 378   if (keys %$attrs) {
 379     my $rs = $self->search($query, $attrs);
 380     return keys %{$rs->_resolved_attrs->{collapse}} ? $rs->next : $rs->single;
 381   }
 382   else {
 383     return keys %{$self->_resolved_attrs->{collapse}}
 384       ? $self->search($query)->next
 385       : $self->single($query);
 386   }
 387 }
 388
 389 # _add_alias
 390 #
 391 # Add the specified alias to the specified query hash. A copy is made so the
 392 # original query is not modified.
 393
 394 sub _add_alias {
 395   my ($self, $query, $alias) = @_;
 396
 397   my %aliased = %$query;
 398   foreach my $col (grep { ! m/\./ } keys %aliased) {
 399     $aliased{"$alias.$col"} = delete $aliased{$col};
 400   }
 401
 402   return \%aliased;
 403 }
 404
 405 # _unique_queries
 406 #
 407 # Build a list of queries which satisfy unique constraints.
 408
 409 sub _unique_queries {
 410   my ($self, $query, $attrs) = @_;
 411
 412   my @constraint_names = exists $attrs->{key}
 413     ? ($attrs->{key})
 414     : $self->result_source->unique_constraint_names;
 415
 416   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 417   my $num_where = scalar keys %$where;
 418
 419   my @unique_queries;
 420   foreach my $name (@constraint_names) {
 421     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 422     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 423
 424     my $num_cols = scalar @unique_cols;
 425     my $num_query = scalar keys %$unique_query;
 426
 427     my $total = $num_query + $num_where;
 428     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 429       # The query is either unique on its own or is unique in combination with
 430       # the existing where clause
 431       push @unique_queries, $unique_query;
 432     }
 433   }
 434
 435   return @unique_queries;
 436 }
 437
 438 # _build_unique_query
 439 #
 440 # Constrain the specified query hash based on the specified column names.
 441
 442 sub _build_unique_query {
 443   my ($self, $query, $unique_cols) = @_;
 444
 445   return {
 446     map  { $_ => $query->{$_} }
 447     grep { exists $query->{$_} }
 448       @$unique_cols
 449   };
 450 }
 451
 452 =head2 search_related
 453
 454 =over 4
 455
 456 =item Arguments: $rel, $cond, \%attrs?
 457
 458 =item Return Value: $new_resultset
 459
 460 =back
 461
 462   $new_rs = $cd_rs->search_related('artist', {
 463     name => 'Emo-R-Us',
 464   });
 465
 466 Searches the specified relationship, optionally specifying a condition and
 467 attributes for matching records. See L</ATTRIBUTES> for more information.
 468
 469 =cut
 470
 471 sub search_related {
 472   return shift->related_resultset(shift)->search(@_);
 473 }
 474
 475 =head2 cursor
 476
 477 =over 4
 478
 479 =item Arguments: none
 480
 481 =item Return Value: $cursor
 482
 483 =back
 484
 485 Returns a storage-driven cursor to the given resultset. See
 486 L<DBIx::Class::Cursor> for more information.
 487
 488 =cut
 489
 490 sub cursor {
 491   my ($self) = @_;
 492
 493   my $attrs = { %{$self->_resolved_attrs} };
 494   return $self->{cursor}
 495     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 496           $attrs->{where},$attrs);
 497 }
 498
 499 =head2 single
 500
 501 =over 4
 502
 503 =item Arguments: $cond?
 504
 505 =item Return Value: $row_object?
 506
 507 =back
 508
 509   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 510
 511 Inflates the first result without creating a cursor if the resultset has
 512 any records in it; if not returns nothing. Used by L</find> as an optimisation.
 513
 514 Can optionally take an additional condition *only* - this is a fast-code-path
 515 method; if you need to add extra joins or similar call ->search and then
 516 ->single without a condition on the $rs returned from that.
 517
 518 =cut
 519
 520 sub single {
 521   my ($self, $where) = @_;
 522   my $attrs = { %{$self->_resolved_attrs} };
 523   if ($where) {
 524     if (defined $attrs->{where}) {
 525       $attrs->{where} = {
 526         '-and' =>
 527             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 528                $where, delete $attrs->{where} ]
 529       };
 530     } else {
 531       $attrs->{where} = $where;
 532     }
 533   }
 534
 535 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 536 #  unless ($self->_is_unique_query($attrs->{where})) {
 537 #    carp "Query not guaranteed to return a single row"
 538 #      . "; please declare your unique constraints or use search instead";
 539 #  }
 540
 541   my @data = $self->result_source->storage->select_single(
 542     $attrs->{from}, $attrs->{select},
 543     $attrs->{where}, $attrs
 544   );
 545
 546   return (@data ? ($self->_construct_object(@data))[0] : undef);
 547 }
 548
 549 # _is_unique_query
 550 #
 551 # Try to determine if the specified query is guaranteed to be unique, based on
 552 # the declared unique constraints.
 553
 554 sub _is_unique_query {
 555   my ($self, $query) = @_;
 556
 557   my $collapsed = $self->_collapse_query($query);
 558   my $alias = $self->{attrs}{alias};
 559
 560   foreach my $name ($self->result_source->unique_constraint_names) {
 561     my @unique_cols = map {
 562       "$alias.$_"
 563     } $self->result_source->unique_constraint_columns($name);
 564
 565     # Count the values for each unique column
 566     my %seen = map { $_ => 0 } @unique_cols;
 567
 568     foreach my $key (keys %$collapsed) {
 569       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 570       next unless exists $seen{$aliased};  # Additional constraints are okay
 571       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 572     }
 573
 574     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 575     return 1 unless grep { $_ != 1 } values %seen;
 576   }
 577
 578   return 0;
 579 }
 580
 581 # _collapse_query
 582 #
 583 # Recursively collapse the query, accumulating values for each column.
 584
 585 sub _collapse_query {
 586   my ($self, $query, $collapsed) = @_;
 587
 588   $collapsed ||= {};
 589
 590   if (ref $query eq 'ARRAY') {
 591     foreach my $subquery (@$query) {
 592       next unless ref $subquery;  # -or
 593 #      warn "ARRAY: " . Dumper $subquery;
 594       $collapsed = $self->_collapse_query($subquery, $collapsed);
 595     }
 596   }
 597   elsif (ref $query eq 'HASH') {
 598     if (keys %$query and (keys %$query)[0] eq '-and') {
 599       foreach my $subquery (@{$query->{-and}}) {
 600 #        warn "HASH: " . Dumper $subquery;
 601         $collapsed = $self->_collapse_query($subquery, $collapsed);
 602       }
 603     }
 604     else {
 605 #      warn "LEAF: " . Dumper $query;
 606       foreach my $col (keys %$query) {
 607         my $value = $query->{$col};
 608         $collapsed->{$col}{$value}++;
 609       }
 610     }
 611   }
 612
 613   return $collapsed;
 614 }
 615
 616 =head2 get_column
 617
 618 =over 4
 619
 620 =item Arguments: $cond?
 621
 622 =item Return Value: $resultsetcolumn
 623
 624 =back
 625
 626   my $max_length = $rs->get_column('length')->max;
 627
 628 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 629
 630 =cut
 631
 632 sub get_column {
 633   my ($self, $column) = @_;
 634   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 635   return $new;
 636 }
 637
 638 =head2 search_like
 639
 640 =over 4
 641
 642 =item Arguments: $cond, \%attrs?
 643
 644 =item Return Value: $resultset (scalar context), @row_objs (list context)
 645
 646 =back
 647
 648   # WHERE title LIKE '%blue%'
 649   $cd_rs = $rs->search_like({ title => '%blue%'});
 650
 651 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 652 that this is simply a convenience method. You most likely want to use
 653 L</search> with specific operators.
 654
 655 For more information, see L<DBIx::Class::Manual::Cookbook>.
 656
 657 =cut
 658
 659 sub search_like {
 660   my $class = shift;
 661   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 662   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 663   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 664   return $class->search($query, { %$attrs });
 665 }
 666
 667 =head2 slice
 668
 669 =over 4
 670
 671 =item Arguments: $first, $last
 672
 673 =item Return Value: $resultset (scalar context), @row_objs (list context)
 674
 675 =back
 676
 677 Returns a resultset or object list representing a subset of elements from the
 678 resultset slice is called on. Indexes are from 0, i.e., to get the first
 679 three records, call:
 680
 681   my ($one, $two, $three) = $rs->slice(0, 2);
 682
 683 =cut
 684
 685 sub slice {
 686   my ($self, $min, $max) = @_;
 687   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 688   $attrs->{offset} = $self->{attrs}{offset} || 0;
 689   $attrs->{offset} += $min;
 690   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 691   return $self->search(undef(), $attrs);
 692   #my $slice = (ref $self)->new($self->result_source, $attrs);
 693   #return (wantarray ? $slice->all : $slice);
 694 }
 695
 696 =head2 next
 697
 698 =over 4
 699
 700 =item Arguments: none
 701
 702 =item Return Value: $result?
 703
 704 =back
 705
 706 Returns the next element in the resultset (C<undef> is there is none).
 707
 708 Can be used to efficiently iterate over records in the resultset:
 709
 710   my $rs = $schema->resultset('CD')->search;
 711   while (my $cd = $rs->next) {
 712     print $cd->title;
 713   }
 714
 715 Note that you need to store the resultset object, and call C<next> on it.
 716 Calling C<< resultset('Table')->next >> repeatedly will always return the
 717 first record from the resultset.
 718
 719 =cut
 720
 721 sub next {
 722   my ($self) = @_;
 723   if (my $cache = $self->get_cache) {
 724     $self->{all_cache_position} ||= 0;
 725     return $cache->[$self->{all_cache_position}++];
 726   }
 727   if ($self->{attrs}{cache}) {
 728     $self->{all_cache_position} = 1;
 729     return ($self->all)[0];
 730   }
 731   if ($self->{stashed_objects}) {
 732     my $obj = shift(@{$self->{stashed_objects}});
 733     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 734     return $obj;
 735   }
 736   my @row = (
 737     exists $self->{stashed_row}
 738       ? @{delete $self->{stashed_row}}
 739       : $self->cursor->next
 740   );
 741   return undef unless (@row);
 742   my ($row, @more) = $self->_construct_object(@row);
 743   $self->{stashed_objects} = \@more if @more;
 744   return $row;
 745 }
 746
 747 sub _construct_object {
 748   my ($self, @row) = @_;
 749   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 750   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 751   @new = $self->{_attrs}{record_filter}->(@new)
 752     if exists $self->{_attrs}{record_filter};
 753   return @new;
 754 }
 755
 756 sub _collapse_result {
 757   my ($self, $as_proto, $row) = @_;
 758
 759   my @copy = @$row;
 760
 761   # 'foo'         => [ undef, 'foo' ]
 762   # 'foo.bar'     => [ 'foo', 'bar' ]
 763   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 764
 765   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 766
 767   my %collapse = %{$self->{_attrs}{collapse}||{}};
 768
 769   my @pri_index;
 770
 771   # if we're doing collapsing (has_many prefetch) we need to grab records
 772   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 773   # we know we don't have to bother.
 774
 775   # the reason for not using the collapse stuff directly is because if you
 776   # had for e.g. two artists in a row with no cds, the collapse info for
 777   # both would be NULL (undef) so you'd lose the second artist
 778
 779   # store just the index so we can check the array positions from the row
 780   # without having to contruct the full hash
 781
 782   if (keys %collapse) {
 783     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 784     foreach my $i (0 .. $#construct_as) {
 785       next if defined($construct_as[$i][0]); # only self table
 786       if (delete $pri{$construct_as[$i][1]}) {
 787         push(@pri_index, $i);
 788       }
 789       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 790     }
 791   }
 792
 793   # no need to do an if, it'll be empty if @pri_index is empty anyway
 794
 795   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 796
 797   my @const_rows;
 798
 799   do { # no need to check anything at the front, we always want the first row
 800
 801     my %const;
 802
 803     foreach my $this_as (@construct_as) {
 804       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 805     }
 806
 807     push(@const_rows, \%const);
 808
 809   } until ( # no pri_index => no collapse => drop straight out
 810       !@pri_index
 811     or
 812       do { # get another row, stash it, drop out if different PK
 813
 814         @copy = $self->cursor->next;
 815         $self->{stashed_row} = \@copy;
 816
 817         # last thing in do block, counts as true if anything doesn't match
 818
 819         # check xor defined first for NULL vs. NOT NULL then if one is
 820         # defined the other must be so check string equality
 821
 822         grep {
 823           (defined $pri_vals{$_} ^ defined $copy[$_])
 824           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 825         } @pri_index;
 826       }
 827   );
 828
 829   my $alias = $self->{attrs}{alias};
 830   my $info = [];
 831
 832   my %collapse_pos;
 833
 834   my @const_keys;
 835
 836   use Data::Dumper;
 837
 838   foreach my $const (@const_rows) {
 839     scalar @const_keys or do {
 840       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 841     };
 842     foreach my $key (@const_keys) {
 843       if (length $key) {
 844         my $target = $info;
 845         my @parts = split(/\./, $key);
 846         my $cur = '';
 847         my $data = $const->{$key};
 848         foreach my $p (@parts) {
 849           $target = $target->[1]->{$p} ||= [];
 850           $cur .= ".${p}";
 851           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 852             # collapsing at this point and on final part
 853             my $pos = $collapse_pos{$cur};
 854             CK: foreach my $ck (@ckey) {
 855               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 856                 $collapse_pos{$cur} = $data;
 857                 delete @collapse_pos{ # clear all positioning for sub-entries
 858                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 859                 };
 860                 push(@$target, []);
 861                 last CK;
 862               }
 863             }
 864           }
 865           if (exists $collapse{$cur}) {
 866             $target = $target->[-1];
 867           }
 868         }
 869         $target->[0] = $data;
 870       } else {
 871         $info->[0] = $const->{$key};
 872       }
 873     }
 874   }
 875
 876   return $info;
 877 }
 878
 879 =head2 result_source
 880
 881 =over 4
 882
 883 =item Arguments: $result_source?
 884
 885 =item Return Value: $result_source
 886
 887 =back
 888
 889 An accessor for the primary ResultSource object from which this ResultSet
 890 is derived.
 891
 892 =head2 result_class
 893
 894 =over 4
 895
 896 =item Arguments: $result_class?
 897
 898 =item Return Value: $result_class
 899
 900 =back
 901
 902 An accessor for the class to use when creating row objects. Defaults to
 903 C<< result_source->result_class >> - which in most cases is the name of the
 904 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 905
 906 =cut
 907
 908
 909 =head2 count
 910
 911 =over 4
 912
 913 =item Arguments: $cond, \%attrs??
 914
 915 =item Return Value: $count
 916
 917 =back
 918
 919 Performs an SQL C<COUNT> with the same query as the resultset was built
 920 with to find the number of elements. If passed arguments, does a search
 921 on the resultset and counts the results of that.
 922
 923 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 924 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 925 not support C<DISTINCT> with multiple columns. If you are using such a
 926 database, you should only use columns from the main table in your C<group_by>
 927 clause.
 928
 929 =cut
 930
 931 sub count {
 932   my $self = shift;
 933   return $self->search(@_)->count if @_ and defined $_[0];
 934   return scalar @{ $self->get_cache } if $self->get_cache;
 935   my $count = $self->_count;
 936   return 0 unless $count;
 937
 938   $count -= $self->{attrs}{offset} if $self->{attrs}{offset};
 939   $count = $self->{attrs}{rows} if
 940     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 941   return $count;
 942 }
 943
 944 sub _count { # Separated out so pager can get the full count
 945   my $self = shift;
 946   my $select = { count => '*' };
 947
 948   my $attrs = { %{$self->_resolved_attrs} };
 949   if (my $group_by = delete $attrs->{group_by}) {
 950     delete $attrs->{having};
 951     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 952     # todo: try CONCAT for multi-column pk
 953     my @pk = $self->result_source->primary_columns;
 954     if (@pk == 1) {
 955       my $alias = $attrs->{alias};
 956       foreach my $column (@distinct) {
 957         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
 958           @distinct = ($column);
 959           last;
 960         }
 961       }
 962     }
 963
 964     $select = { count => { distinct => \@distinct } };
 965   }
 966
 967   $attrs->{select} = $select;
 968   $attrs->{as} = [qw/count/];
 969
 970   # offset, order by and page are not needed to count. record_filter is cdbi
 971   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 972
 973   my $tmp_rs = (ref $self)->new($self->_source_handle, $attrs);
 974   my ($count) = $tmp_rs->cursor->next;
 975   return $count;
 976 }
 977
 978 =head2 count_literal
 979
 980 =over 4
 981
 982 =item Arguments: $sql_fragment, @bind_values
 983
 984 =item Return Value: $count
 985
 986 =back
 987
 988 Counts the results in a literal query. Equivalent to calling L</search_literal>
 989 with the passed arguments, then L</count>.
 990
 991 =cut
 992
 993 sub count_literal { shift->search_literal(@_)->count; }
 994
 995 =head2 all
 996
 997 =over 4
 998
 999 =item Arguments: none
1000
1001 =item Return Value: @objects
1002
1003 =back
1004
1005 Returns all elements in the resultset. Called implicitly if the resultset
1006 is returned in list context.
1007
1008 =cut
1009
1010 sub all {
1011   my ($self) = @_;
1012   return @{ $self->get_cache } if $self->get_cache;
1013
1014   my @obj;
1015
1016   # TODO: don't call resolve here
1017   if (keys %{$self->_resolved_attrs->{collapse}}) {
1018 #  if ($self->{attrs}{prefetch}) {
1019       # Using $self->cursor->all is really just an optimisation.
1020       # If we're collapsing has_many prefetches it probably makes
1021       # very little difference, and this is cleaner than hacking
1022       # _construct_object to survive the approach
1023     my @row = $self->cursor->next;
1024     while (@row) {
1025       push(@obj, $self->_construct_object(@row));
1026       @row = (exists $self->{stashed_row}
1027                ? @{delete $self->{stashed_row}}
1028                : $self->cursor->next);
1029     }
1030   } else {
1031     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1032   }
1033
1034   $self->set_cache(\@obj) if $self->{attrs}{cache};
1035   return @obj;
1036 }
1037
1038 =head2 reset
1039
1040 =over 4
1041
1042 =item Arguments: none
1043
1044 =item Return Value: $self
1045
1046 =back
1047
1048 Resets the resultset's cursor, so you can iterate through the elements again.
1049
1050 =cut
1051
1052 sub reset {
1053   my ($self) = @_;
1054   delete $self->{_attrs} if exists $self->{_attrs};
1055   $self->{all_cache_position} = 0;
1056   $self->cursor->reset;
1057   return $self;
1058 }
1059
1060 =head2 first
1061
1062 =over 4
1063
1064 =item Arguments: none
1065
1066 =item Return Value: $object?
1067
1068 =back
1069
1070 Resets the resultset and returns an object for the first result (if the
1071 resultset returns anything).
1072
1073 =cut
1074
1075 sub first {
1076   return $_[0]->reset->next;
1077 }
1078
1079 # _cond_for_update_delete
1080 #
1081 # update/delete require the condition to be modified to handle
1082 # the differing SQL syntax available.  This transforms the $self->{cond}
1083 # appropriately, returning the new condition.
1084
1085 sub _cond_for_update_delete {
1086   my ($self, $full_cond) = @_;
1087   my $cond = {};
1088
1089   $full_cond ||= $self->{cond};
1090   # No-op. No condition, we're updating/deleting everything
1091   return $cond unless ref $full_cond;
1092
1093   if (ref $full_cond eq 'ARRAY') {
1094     $cond = [
1095       map {
1096         my %hash;
1097         foreach my $key (keys %{$_}) {
1098           $key =~ /([^.]+)$/;
1099           $hash{$1} = $_->{$key};
1100         }
1101         \%hash;
1102       } @{$full_cond}
1103     ];
1104   }
1105   elsif (ref $full_cond eq 'HASH') {
1106     if ((keys %{$full_cond})[0] eq '-and') {
1107       $cond->{-and} = [];
1108
1109       my @cond = @{$full_cond->{-and}};
1110       for (my $i = 0; $i < @cond; $i++) {
1111         my $entry = $cond[$i];
1112
1113         my $hash;
1114         if (ref $entry eq 'HASH') {
1115           $hash = $self->_cond_for_update_delete($entry);
1116         }
1117         else {
1118           $entry =~ /([^.]+)$/;
1119           $hash->{$1} = $cond[++$i];
1120         }
1121
1122         push @{$cond->{-and}}, $hash;
1123       }
1124     }
1125     else {
1126       foreach my $key (keys %{$full_cond}) {
1127         $key =~ /([^.]+)$/;
1128         $cond->{$1} = $full_cond->{$key};
1129       }
1130     }
1131   }
1132   else {
1133     $self->throw_exception(
1134       "Can't update/delete on resultset with condition unless hash or array"
1135     );
1136   }
1137
1138   return $cond;
1139 }
1140
1141
1142 =head2 update
1143
1144 =over 4
1145
1146 =item Arguments: \%values
1147
1148 =item Return Value: $storage_rv
1149
1150 =back
1151
1152 Sets the specified columns in the resultset to the supplied values in a
1153 single query. Return value will be true if the update succeeded or false
1154 if no records were updated; exact type of success value is storage-dependent.
1155
1156 =cut
1157
1158 sub update {
1159   my ($self, $values) = @_;
1160   $self->throw_exception("Values for update must be a hash")
1161     unless ref $values eq 'HASH';
1162
1163   my $cond = $self->_cond_for_update_delete;
1164
1165   return $self->result_source->storage->update(
1166     $self->result_source, $values, $cond
1167   );
1168 }
1169
1170 =head2 update_all
1171
1172 =over 4
1173
1174 =item Arguments: \%values
1175
1176 =item Return Value: 1
1177
1178 =back
1179
1180 Fetches all objects and updates them one at a time. Note that C<update_all>
1181 will run DBIC cascade triggers, while L</update> will not.
1182
1183 =cut
1184
1185 sub update_all {
1186   my ($self, $values) = @_;
1187   $self->throw_exception("Values for update must be a hash")
1188     unless ref $values eq 'HASH';
1189   foreach my $obj ($self->all) {
1190     $obj->set_columns($values)->update;
1191   }
1192   return 1;
1193 }
1194
1195 =head2 delete
1196
1197 =over 4
1198
1199 =item Arguments: none
1200
1201 =item Return Value: 1
1202
1203 =back
1204
1205 Deletes the contents of the resultset from its result source. Note that this
1206 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1207 to run. See also L<DBIx::Class::Row/delete>.
1208
1209 =cut
1210
1211 sub delete {
1212   my ($self) = @_;
1213
1214   my $cond = $self->_cond_for_update_delete;
1215
1216   $self->result_source->storage->delete($self->result_source, $cond);
1217   return 1;
1218 }
1219
1220 =head2 delete_all
1221
1222 =over 4
1223
1224 =item Arguments: none
1225
1226 =item Return Value: 1
1227
1228 =back
1229
1230 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1231 will run DBIC cascade triggers, while L</delete> will not.
1232
1233 =cut
1234
1235 sub delete_all {
1236   my ($self) = @_;
1237   $_->delete for $self->all;
1238   return 1;
1239 }
1240
1241 =head2 pager
1242
1243 =over 4
1244
1245 =item Arguments: none
1246
1247 =item Return Value: $pager
1248
1249 =back
1250
1251 Return Value a L<Data::Page> object for the current resultset. Only makes
1252 sense for queries with a C<page> attribute.
1253
1254 =cut
1255
1256 sub pager {
1257   my ($self) = @_;
1258   my $attrs = $self->{attrs};
1259   $self->throw_exception("Can't create pager for non-paged rs")
1260     unless $self->{attrs}{page};
1261   $attrs->{rows} ||= 10;
1262   return $self->{pager} ||= Data::Page->new(
1263     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1264 }
1265
1266 =head2 page
1267
1268 =over 4
1269
1270 =item Arguments: $page_number
1271
1272 =item Return Value: $rs
1273
1274 =back
1275
1276 Returns a resultset for the $page_number page of the resultset on which page
1277 is called, where each page contains a number of rows equal to the 'rows'
1278 attribute set on the resultset (10 by default).
1279
1280 =cut
1281
1282 sub page {
1283   my ($self, $page) = @_;
1284   return (ref $self)->new($self->_source_handle, { %{$self->{attrs}}, page => $page });
1285 }
1286
1287 =head2 new_result
1288
1289 =over 4
1290
1291 =item Arguments: \%vals
1292
1293 =item Return Value: $object
1294
1295 =back
1296
1297 Creates an object in the resultset's result class and returns it.
1298
1299 =cut
1300
1301 sub new_result {
1302   my ($self, $values) = @_;
1303   $self->throw_exception( "new_result needs a hash" )
1304     unless (ref $values eq 'HASH');
1305   $self->throw_exception(
1306     "Can't abstract implicit construct, condition not a hash"
1307   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1308
1309   my $alias = $self->{attrs}{alias};
1310   my $collapsed_cond = $self->{cond} ? $self->_collapse_cond($self->{cond}) : {};
1311   my %new = (
1312     %{ $self->_remove_alias($values, $alias) },
1313     %{ $self->_remove_alias($collapsed_cond, $alias) },
1314     -source_handle => $self->_source_handle,
1315     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1316   );
1317
1318   return $self->result_class->new(\%new);
1319 }
1320
1321 # _collapse_cond
1322 #
1323 # Recursively collapse the condition.
1324
1325 sub _collapse_cond {
1326   my ($self, $cond, $collapsed) = @_;
1327
1328   $collapsed ||= {};
1329
1330   if (ref $cond eq 'ARRAY') {
1331     foreach my $subcond (@$cond) {
1332       next unless ref $subcond;  # -or
1333 #      warn "ARRAY: " . Dumper $subcond;
1334       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1335     }
1336   }
1337   elsif (ref $cond eq 'HASH') {
1338     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1339       foreach my $subcond (@{$cond->{-and}}) {
1340 #        warn "HASH: " . Dumper $subcond;
1341         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1342       }
1343     }
1344     else {
1345 #      warn "LEAF: " . Dumper $cond;
1346       foreach my $col (keys %$cond) {
1347         my $value = $cond->{$col};
1348         $collapsed->{$col} = $value;
1349       }
1350     }
1351   }
1352
1353   return $collapsed;
1354 }
1355
1356 # _remove_alias
1357 #
1358 # Remove the specified alias from the specified query hash. A copy is made so
1359 # the original query is not modified.
1360
1361 sub _remove_alias {
1362   my ($self, $query, $alias) = @_;
1363
1364   my %orig = %{ $query || {} };
1365   my %unaliased;
1366
1367   foreach my $key (keys %orig) {
1368     if ($key !~ /\./) {
1369       $unaliased{$key} = $orig{$key};
1370       next;
1371     }
1372     $unaliased{$1} = $orig{$key}
1373       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1374   }
1375
1376   return \%unaliased;
1377 }
1378
1379 =head2 find_or_new
1380
1381 =over 4
1382
1383 =item Arguments: \%vals, \%attrs?
1384
1385 =item Return Value: $object
1386
1387 =back
1388
1389 Find an existing record from this resultset. If none exists, instantiate a new
1390 result object and return it. The object will not be saved into your storage
1391 until you call L<DBIx::Class::Row/insert> on it.
1392
1393 If you want objects to be saved immediately, use L</find_or_create> instead.
1394
1395 =cut
1396
1397 sub find_or_new {
1398   my $self     = shift;
1399   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1400   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1401   my $exists   = $self->find($hash, $attrs);
1402   return defined $exists ? $exists : $self->new_result($hash);
1403 }
1404
1405 =head2 create
1406
1407 =over 4
1408
1409 =item Arguments: \%vals
1410
1411 =item Return Value: $object
1412
1413 =back
1414
1415 Inserts a record into the resultset and returns the object representing it.
1416
1417 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1418
1419 =cut
1420
1421 sub create {
1422   my ($self, $attrs) = @_;
1423   $self->throw_exception( "create needs a hashref" )
1424     unless ref $attrs eq 'HASH';
1425   return $self->new_result($attrs)->insert;
1426 }
1427
1428 =head2 find_or_create
1429
1430 =over 4
1431
1432 =item Arguments: \%vals, \%attrs?
1433
1434 =item Return Value: $object
1435
1436 =back
1437
1438   $class->find_or_create({ key => $val, ... });
1439
1440 Tries to find a record based on its primary key or unique constraint; if none
1441 is found, creates one and returns that instead.
1442
1443   my $cd = $schema->resultset('CD')->find_or_create({
1444     cdid   => 5,
1445     artist => 'Massive Attack',
1446     title  => 'Mezzanine',
1447     year   => 2005,
1448   });
1449
1450 Also takes an optional C<key> attribute, to search by a specific key or unique
1451 constraint. For example:
1452
1453   my $cd = $schema->resultset('CD')->find_or_create(
1454     {
1455       artist => 'Massive Attack',
1456       title  => 'Mezzanine',
1457     },
1458     { key => 'cd_artist_title' }
1459   );
1460
1461 See also L</find> and L</update_or_create>. For information on how to declare
1462 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1463
1464 =cut
1465
1466 sub find_or_create {
1467   my $self     = shift;
1468   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1469   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1470   my $exists   = $self->find($hash, $attrs);
1471   return defined $exists ? $exists : $self->create($hash);
1472 }
1473
1474 =head2 update_or_create
1475
1476 =over 4
1477
1478 =item Arguments: \%col_values, { key => $unique_constraint }?
1479
1480 =item Return Value: $object
1481
1482 =back
1483
1484   $class->update_or_create({ col => $val, ... });
1485
1486 First, searches for an existing row matching one of the unique constraints
1487 (including the primary key) on the source of this resultset. If a row is
1488 found, updates it with the other given column values. Otherwise, creates a new
1489 row.
1490
1491 Takes an optional C<key> attribute to search on a specific unique constraint.
1492 For example:
1493
1494   # In your application
1495   my $cd = $schema->resultset('CD')->update_or_create(
1496     {
1497       artist => 'Massive Attack',
1498       title  => 'Mezzanine',
1499       year   => 1998,
1500     },
1501     { key => 'cd_artist_title' }
1502   );
1503
1504 If no C<key> is specified, it searches on all unique constraints defined on the
1505 source, including the primary key.
1506
1507 If the C<key> is specified as C<primary>, it searches only on the primary key.
1508
1509 See also L</find> and L</find_or_create>. For information on how to declare
1510 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1511
1512 =cut
1513
1514 sub update_or_create {
1515   my $self = shift;
1516   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1517   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1518
1519   my $row = $self->find($cond, $attrs);
1520   if (defined $row) {
1521     $row->update($cond);
1522     return $row;
1523   }
1524
1525   return $self->create($cond);
1526 }
1527
1528 =head2 get_cache
1529
1530 =over 4
1531
1532 =item Arguments: none
1533
1534 =item Return Value: \@cache_objects?
1535
1536 =back
1537
1538 Gets the contents of the cache for the resultset, if the cache is set.
1539
1540 =cut
1541
1542 sub get_cache {
1543   shift->{all_cache};
1544 }
1545
1546 =head2 set_cache
1547
1548 =over 4
1549
1550 =item Arguments: \@cache_objects
1551
1552 =item Return Value: \@cache_objects
1553
1554 =back
1555
1556 Sets the contents of the cache for the resultset. Expects an arrayref
1557 of objects of the same class as those produced by the resultset. Note that
1558 if the cache is set the resultset will return the cached objects rather
1559 than re-querying the database even if the cache attr is not set.
1560
1561 =cut
1562
1563 sub set_cache {
1564   my ( $self, $data ) = @_;
1565   $self->throw_exception("set_cache requires an arrayref")
1566       if defined($data) && (ref $data ne 'ARRAY');
1567   $self->{all_cache} = $data;
1568 }
1569
1570 =head2 clear_cache
1571
1572 =over 4
1573
1574 =item Arguments: none
1575
1576 =item Return Value: []
1577
1578 =back
1579
1580 Clears the cache for the resultset.
1581
1582 =cut
1583
1584 sub clear_cache {
1585   shift->set_cache(undef);
1586 }
1587
1588 =head2 related_resultset
1589
1590 =over 4
1591
1592 =item Arguments: $relationship_name
1593
1594 =item Return Value: $resultset
1595
1596 =back
1597
1598 Returns a related resultset for the supplied relationship name.
1599
1600   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1601
1602 =cut
1603
1604 sub related_resultset {
1605   my ($self, $rel) = @_;
1606
1607   $self->{related_resultsets} ||= {};
1608   return $self->{related_resultsets}{$rel} ||= do {
1609     my $rel_obj = $self->result_source->relationship_info($rel);
1610
1611     $self->throw_exception(
1612       "search_related: result source '" . $self->_source_handle->source_moniker .
1613         "' has no such relationship $rel")
1614       unless $rel_obj;
1615
1616     my ($from,$seen) = $self->_resolve_from($rel);
1617
1618     my $join_count = $seen->{$rel};
1619     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
1620
1621     $self->_source_handle->schema->resultset($rel_obj->{class})->search_rs(
1622       undef, {
1623         %{$self->{attrs}||{}},
1624         join => undef,
1625         prefetch => undef,
1626         select => undef,
1627         as => undef,
1628         alias => $alias,
1629         where => $self->{cond},
1630         seen_join => $seen,
1631         from => $from,
1632     });
1633   };
1634 }
1635
1636 sub _resolve_from {
1637   my ($self, $extra_join) = @_;
1638   my $source = $self->result_source;
1639   my $attrs = $self->{attrs};
1640
1641   my $from = $attrs->{from}
1642     || [ { $attrs->{alias} => $source->from } ];
1643
1644   my $seen = { %{$attrs->{seen_join}||{}} };
1645
1646   my $join = ($attrs->{join}
1647                ? [ $attrs->{join}, $extra_join ]
1648                : $extra_join);
1649   $from = [
1650     @$from,
1651     ($join ? $source->resolve_join($join, $attrs->{alias}, $seen) : ()),
1652   ];
1653
1654   return ($from,$seen);
1655 }
1656
1657 sub _resolved_attrs {
1658   my $self = shift;
1659   return $self->{_attrs} if $self->{_attrs};
1660
1661   my $attrs = { %{$self->{attrs}||{}} };
1662   my $source = $self->result_source;
1663   my $alias = $attrs->{alias};
1664
1665   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
1666   if ($attrs->{columns}) {
1667     delete $attrs->{as};
1668   } elsif (!$attrs->{select}) {
1669     $attrs->{columns} = [ $source->columns ];
1670   }
1671
1672   $attrs->{select} =
1673     ($attrs->{select}
1674       ? (ref $attrs->{select} eq 'ARRAY'
1675           ? [ @{$attrs->{select}} ]
1676           : [ $attrs->{select} ])
1677       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
1678     );
1679   $attrs->{as} =
1680     ($attrs->{as}
1681       ? (ref $attrs->{as} eq 'ARRAY'
1682           ? [ @{$attrs->{as}} ]
1683           : [ $attrs->{as} ])
1684       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
1685     );
1686
1687   my $adds;
1688   if ($adds = delete $attrs->{include_columns}) {
1689     $adds = [$adds] unless ref $adds eq 'ARRAY';
1690     push(@{$attrs->{select}}, @$adds);
1691     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
1692   }
1693   if ($adds = delete $attrs->{'+select'}) {
1694     $adds = [$adds] unless ref $adds eq 'ARRAY';
1695     push(@{$attrs->{select}},
1696            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
1697   }
1698   if (my $adds = delete $attrs->{'+as'}) {
1699     $adds = [$adds] unless ref $adds eq 'ARRAY';
1700     push(@{$attrs->{as}}, @$adds);
1701   }
1702
1703   $attrs->{from} ||= [ { 'me' => $source->from } ];
1704
1705   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
1706     my $join = delete $attrs->{join} || {};
1707
1708     if (defined $attrs->{prefetch}) {
1709       $join = $self->_merge_attr(
1710         $join, $attrs->{prefetch}
1711       );
1712     }
1713
1714     $attrs->{from} =   # have to copy here to avoid corrupting the original
1715       [
1716         @{$attrs->{from}},
1717         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
1718       ];
1719   }
1720
1721   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
1722   if ($attrs->{order_by}) {
1723     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
1724                            ? [ @{$attrs->{order_by}} ]
1725                            : [ $attrs->{order_by} ]);
1726   } else {
1727     $attrs->{order_by} = [];
1728   }
1729
1730   my $collapse = $attrs->{collapse} || {};
1731   if (my $prefetch = delete $attrs->{prefetch}) {
1732     $prefetch = $self->_merge_attr({}, $prefetch);
1733     my @pre_order;
1734     my $seen = $attrs->{seen_join} || {};
1735     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
1736       # bring joins back to level of current class
1737       my @prefetch = $source->resolve_prefetch(
1738         $p, $alias, $seen, \@pre_order, $collapse
1739       );
1740       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
1741       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
1742     }
1743     push(@{$attrs->{order_by}}, @pre_order);
1744   }
1745   $attrs->{collapse} = $collapse;
1746
1747   return $self->{_attrs} = $attrs;
1748 }
1749
1750 sub _merge_attr {
1751   my ($self, $a, $b) = @_;
1752   return $b unless defined($a);
1753   return $a unless defined($b);
1754
1755   if (ref $b eq 'HASH' && ref $a eq 'HASH') {
1756     foreach my $key (keys %{$b}) {
1757       if (exists $a->{$key}) {
1758         $a->{$key} = $self->_merge_attr($a->{$key}, $b->{$key});
1759       } else {
1760         $a->{$key} = $b->{$key};
1761       }
1762     }
1763     return $a;
1764   } else {
1765     $a = [$a] unless ref $a eq 'ARRAY';
1766     $b = [$b] unless ref $b eq 'ARRAY';
1767
1768     my $hash = {};
1769     my @array;
1770     foreach my $x ($a, $b) {
1771       foreach my $element (@{$x}) {
1772         if (ref $element eq 'HASH') {
1773           $hash = $self->_merge_attr($hash, $element);
1774         } elsif (ref $element eq 'ARRAY') {
1775           push(@array, @{$element});
1776         } else {
1777           push(@array, $element) unless $b == $x
1778             && grep { $_ eq $element } @array;
1779         }
1780       }
1781     }
1782
1783     @array = grep { !exists $hash->{$_} } @array;
1784
1785     return keys %{$hash}
1786       ? ( scalar(@array)
1787             ? [$hash, @array]
1788             : $hash
1789         )
1790       : \@array;
1791   }
1792 }
1793
1794 sub result_source {
1795     my $self = shift;
1796
1797     if (@_) {
1798         $self->_source_handle($_[0]->handle);
1799     } else {
1800         $self->_source_handle->resolve;
1801     }
1802 }
1803
1804 =head2 throw_exception
1805
1806 See L<DBIx::Class::Schema/throw_exception> for details.
1807
1808 =cut
1809
1810 sub throw_exception {
1811   my $self=shift;
1812   $self->_source_handle->schema->throw_exception(@_);
1813 }
1814
1815 # XXX: FIXME: Attributes docs need clearing up
1816
1817 =head1 ATTRIBUTES
1818
1819 The resultset takes various attributes that modify its behavior. Here's an
1820 overview of them:
1821
1822 =head2 order_by
1823
1824 =over 4
1825
1826 =item Value: ($order_by | \@order_by)
1827
1828 =back
1829
1830 Which column(s) to order the results by. This is currently passed
1831 through directly to SQL, so you can give e.g. C<year DESC> for a
1832 descending order on the column `year'.
1833
1834 Please note that if you have C<quote_char> enabled (see
1835 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
1836 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
1837 so you will need to manually quote things as appropriate.)
1838
1839 =head2 columns
1840
1841 =over 4
1842
1843 =item Value: \@columns
1844
1845 =back
1846
1847 Shortcut to request a particular set of columns to be retrieved.  Adds
1848 C<me.> onto the start of any column without a C<.> in it and sets C<select>
1849 from that, then auto-populates C<as> from C<select> as normal. (You may also
1850 use the C<cols> attribute, as in earlier versions of DBIC.)
1851
1852 =head2 include_columns
1853
1854 =over 4
1855
1856 =item Value: \@columns
1857
1858 =back
1859
1860 Shortcut to include additional columns in the returned results - for example
1861
1862   $schema->resultset('CD')->search(undef, {
1863     include_columns => ['artist.name'],
1864     join => ['artist']
1865   });
1866
1867 would return all CDs and include a 'name' column to the information
1868 passed to object inflation. Note that the 'artist' is the name of the
1869 column (or relationship) accessor, and 'name' is the name of the column
1870 accessor in the related table.
1871
1872 =head2 select
1873
1874 =over 4
1875
1876 =item Value: \@select_columns
1877
1878 =back
1879
1880 Indicates which columns should be selected from the storage. You can use
1881 column names, or in the case of RDBMS back ends, function or stored procedure
1882 names:
1883
1884   $rs = $schema->resultset('Employee')->search(undef, {
1885     select => [
1886       'name',
1887       { count => 'employeeid' },
1888       { sum => 'salary' }
1889     ]
1890   });
1891
1892 When you use function/stored procedure names and do not supply an C<as>
1893 attribute, the column names returned are storage-dependent. E.g. MySQL would
1894 return a column named C<count(employeeid)> in the above example.
1895
1896 =head2 +select
1897
1898 =over 4
1899
1900 Indicates additional columns to be selected from storage.  Works the same as
1901 L<select> but adds columns to the selection.
1902
1903 =back
1904
1905 =head2 +as
1906
1907 =over 4
1908
1909 Indicates additional column names for those added via L<+select>.
1910
1911 =back
1912
1913 =head2 as
1914
1915 =over 4
1916
1917 =item Value: \@inflation_names
1918
1919 =back
1920
1921 Indicates column names for object inflation. That is, c< as >
1922 indicates the name that the column can be accessed as via the
1923 C<get_column> method (or via the object accessor, B<if one already
1924 exists>).  It has nothing to do with the SQL code C< SELECT foo AS bar
1925 >.
1926
1927 The C< as > attribute is used in conjunction with C<select>,
1928 usually when C<select> contains one or more function or stored
1929 procedure names:
1930
1931   $rs = $schema->resultset('Employee')->search(undef, {
1932     select => [
1933       'name',
1934       { count => 'employeeid' }
1935     ],
1936     as => ['name', 'employee_count'],
1937   });
1938
1939   my $employee = $rs->first(); # get the first Employee
1940
1941 If the object against which the search is performed already has an accessor
1942 matching a column name specified in C<as>, the value can be retrieved using
1943 the accessor as normal:
1944
1945   my $name = $employee->name();
1946
1947 If on the other hand an accessor does not exist in the object, you need to
1948 use C<get_column> instead:
1949
1950   my $employee_count = $employee->get_column('employee_count');
1951
1952 You can create your own accessors if required - see
1953 L<DBIx::Class::Manual::Cookbook> for details.
1954
1955 Please note: This will NOT insert an C<AS employee_count> into the SQL
1956 statement produced, it is used for internal access only. Thus
1957 attempting to use the accessor in an C<order_by> clause or similar
1958 will fail miserably.
1959
1960 To get around this limitation, you can supply literal SQL to your
1961 C<select> attibute that contains the C<AS alias> text, eg:
1962
1963   select => [\'myfield AS alias']
1964
1965 =head2 join
1966
1967 =over 4
1968
1969 =item Value: ($rel_name | \@rel_names | \%rel_names)
1970
1971 =back
1972
1973 Contains a list of relationships that should be joined for this query.  For
1974 example:
1975
1976   # Get CDs by Nine Inch Nails
1977   my $rs = $schema->resultset('CD')->search(
1978     { 'artist.name' => 'Nine Inch Nails' },
1979     { join => 'artist' }
1980   );
1981
1982 Can also contain a hash reference to refer to the other relation's relations.
1983 For example:
1984
1985   package MyApp::Schema::Track;
1986   use base qw/DBIx::Class/;
1987   __PACKAGE__->table('track');
1988   __PACKAGE__->add_columns(qw/trackid cd position title/);
1989   __PACKAGE__->set_primary_key('trackid');
1990   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
1991   1;
1992
1993   # In your application
1994   my $rs = $schema->resultset('Artist')->search(
1995     { 'track.title' => 'Teardrop' },
1996     {
1997       join     => { cd => 'track' },
1998       order_by => 'artist.name',
1999     }
2000   );
2001
2002 You need to use the relationship (not the table) name in  conditions,
2003 because they are aliased as such. The current table is aliased as "me", so
2004 you need to use me.column_name in order to avoid ambiguity. For example:
2005
2006   # Get CDs from 1984 with a 'Foo' track
2007   my $rs = $schema->resultset('CD')->search(
2008     {
2009       'me.year' => 1984,
2010       'tracks.name' => 'Foo'
2011     },
2012     { join => 'tracks' }
2013   );
2014
2015 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2016 similarly for a third time). For e.g.
2017
2018   my $rs = $schema->resultset('Artist')->search({
2019     'cds.title'   => 'Down to Earth',
2020     'cds_2.title' => 'Popular',
2021   }, {
2022     join => [ qw/cds cds/ ],
2023   });
2024
2025 will return a set of all artists that have both a cd with title 'Down
2026 to Earth' and a cd with title 'Popular'.
2027
2028 If you want to fetch related objects from other tables as well, see C<prefetch>
2029 below.
2030
2031 =head2 prefetch
2032
2033 =over 4
2034
2035 =item Value: ($rel_name | \@rel_names | \%rel_names)
2036
2037 =back
2038
2039 Contains one or more relationships that should be fetched along with the main
2040 query (when they are accessed afterwards they will have already been
2041 "prefetched").  This is useful for when you know you will need the related
2042 objects, because it saves at least one query:
2043
2044   my $rs = $schema->resultset('Tag')->search(
2045     undef,
2046     {
2047       prefetch => {
2048         cd => 'artist'
2049       }
2050     }
2051   );
2052
2053 The initial search results in SQL like the following:
2054
2055   SELECT tag.*, cd.*, artist.* FROM tag
2056   JOIN cd ON tag.cd = cd.cdid
2057   JOIN artist ON cd.artist = artist.artistid
2058
2059 L<DBIx::Class> has no need to go back to the database when we access the
2060 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2061 case.
2062
2063 Simple prefetches will be joined automatically, so there is no need
2064 for a C<join> attribute in the above search. If you're prefetching to
2065 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
2066 specify the join as well.
2067
2068 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2069 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2070 with an accessor type of 'single' or 'filter').
2071
2072 =head2 page
2073
2074 =over 4
2075
2076 =item Value: $page
2077
2078 =back
2079
2080 Makes the resultset paged and specifies the page to retrieve. Effectively
2081 identical to creating a non-pages resultset and then calling ->page($page)
2082 on it.
2083
2084 If L<rows> attribute is not specified it defualts to 10 rows per page.
2085
2086 =head2 rows
2087
2088 =over 4
2089
2090 =item Value: $rows
2091
2092 =back
2093
2094 Specifes the maximum number of rows for direct retrieval or the number of
2095 rows per page if the page attribute or method is used.
2096
2097 =head2 offset
2098
2099 =over 4
2100
2101 =item Value: $offset
2102
2103 =back
2104
2105 Specifies the (zero-based) row number for the  first row to be returned, or the
2106 of the first row of the first page if paging is used.
2107
2108 =head2 group_by
2109
2110 =over 4
2111
2112 =item Value: \@columns
2113
2114 =back
2115
2116 A arrayref of columns to group by. Can include columns of joined tables.
2117
2118   group_by => [qw/ column1 column2 ... /]
2119
2120 =head2 having
2121
2122 =over 4
2123
2124 =item Value: $condition
2125
2126 =back
2127
2128 HAVING is a select statement attribute that is applied between GROUP BY and
2129 ORDER BY. It is applied to the after the grouping calculations have been
2130 done.
2131
2132   having => { 'count(employee)' => { '>=', 100 } }
2133
2134 =head2 distinct
2135
2136 =over 4
2137
2138 =item Value: (0 | 1)
2139
2140 =back
2141
2142 Set to 1 to group by all columns.
2143
2144 =head2 where
2145
2146 =over 4
2147
2148 Adds to the WHERE clause.
2149
2150   # only return rows WHERE deleted IS NULL for all searches
2151   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2152
2153 Can be overridden by passing C<{ where => undef }> as an attribute
2154 to a resulset.
2155
2156 =back
2157
2158 =head2 cache
2159
2160 Set to 1 to cache search results. This prevents extra SQL queries if you
2161 revisit rows in your ResultSet:
2162
2163   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2164
2165   while( my $artist = $resultset->next ) {
2166     ... do stuff ...
2167   }
2168
2169   $rs->first; # without cache, this would issue a query
2170
2171 By default, searches are not cached.
2172
2173 For more examples of using these attributes, see
2174 L<DBIx::Class::Manual::Cookbook>.
2175
2176 =head2 from
2177
2178 =over 4
2179
2180 =item Value: \@from_clause
2181
2182 =back
2183
2184 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2185 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2186 clauses.
2187
2188 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2189
2190 C<join> will usually do what you need and it is strongly recommended that you
2191 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2192 And we really do mean "cannot", not just tried and failed. Attempting to use
2193 this because you're having problems with C<join> is like trying to use x86
2194 ASM because you've got a syntax error in your C. Trust us on this.
2195
2196 Now, if you're still really, really sure you need to use this (and if you're
2197 not 100% sure, ask the mailing list first), here's an explanation of how this
2198 works.
2199
2200 The syntax is as follows -
2201
2202   [
2203     { <alias1> => <table1> },
2204     [
2205       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2206       [], # nested JOIN (optional)
2207       { <table1.column1> => <table2.column2>, ... (more conditions) },
2208     ],
2209     # More of the above [ ] may follow for additional joins
2210   ]
2211
2212   <table1> <alias1>
2213   JOIN
2214     <table2> <alias2>
2215     [JOIN ...]
2216   ON <table1.column1> = <table2.column2>
2217   <more joins may follow>
2218
2219 An easy way to follow the examples below is to remember the following:
2220
2221     Anything inside "[]" is a JOIN
2222     Anything inside "{}" is a condition for the enclosing JOIN
2223
2224 The following examples utilize a "person" table in a family tree application.
2225 In order to express parent->child relationships, this table is self-joined:
2226
2227     # Person->belongs_to('father' => 'Person');
2228     # Person->belongs_to('mother' => 'Person');
2229
2230 C<from> can be used to nest joins. Here we return all children with a father,
2231 then search against all mothers of those children:
2232
2233   $rs = $schema->resultset('Person')->search(
2234       undef,
2235       {
2236           alias => 'mother', # alias columns in accordance with "from"
2237           from => [
2238               { mother => 'person' },
2239               [
2240                   [
2241                       { child => 'person' },
2242                       [
2243                           { father => 'person' },
2244                           { 'father.person_id' => 'child.father_id' }
2245                       ]
2246                   ],
2247                   { 'mother.person_id' => 'child.mother_id' }
2248               ],
2249           ]
2250       },
2251   );
2252
2253   # Equivalent SQL:
2254   # SELECT mother.* FROM person mother
2255   # JOIN (
2256   #   person child
2257   #   JOIN person father
2258   #   ON ( father.person_id = child.father_id )
2259   # )
2260   # ON ( mother.person_id = child.mother_id )
2261
2262 The type of any join can be controlled manually. To search against only people
2263 with a father in the person table, we could explicitly use C<INNER JOIN>:
2264
2265     $rs = $schema->resultset('Person')->search(
2266         undef,
2267         {
2268             alias => 'child', # alias columns in accordance with "from"
2269             from => [
2270                 { child => 'person' },
2271                 [
2272                     { father => 'person', -join_type => 'inner' },
2273                     { 'father.id' => 'child.father_id' }
2274                 ],
2275             ]
2276         },
2277     );
2278
2279     # Equivalent SQL:
2280     # SELECT child.* FROM person child
2281     # INNER JOIN person father ON child.father_id = father.id
2282
2283 =cut
2284
2285 1;