lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util 'fail_on_internal_wantarray';
  10 use Try::Tiny;
  11 use Data::Compare (); # no imports!!! guard against insane architecture
  12
  13 # not importing first() as it will clash with our own method
  14 use List::Util ();
  15
  16 BEGIN {
  17   # De-duplication in _merge_attr() is disabled, but left in for reference
  18   # (the merger is used for other things that ought not to be de-duped)
  19   *__HM_DEDUP = sub () { 0 };
  20 }
  21
  22 use namespace::clean;
  23
  24 use overload
  25         '0+'     => "count",
  26         'bool'   => "_bool",
  27         fallback => 1;
  28
  29 # this is real - CDBICompat overrides it with insanity
  30 # yes, prototype won't matter, but that's for now ;)
  31 sub _bool () { 1 }
  32
  33 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  34
  35 =head1 NAME
  36
  37 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  38
  39 =head1 SYNOPSIS
  40
  41   my $users_rs = $schema->resultset('User');
  42   while( $user = $users_rs->next) {
  43     print $user->username;
  44   }
  45
  46   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  47   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  48
  49 =head1 DESCRIPTION
  50
  51 A ResultSet is an object which stores a set of conditions representing
  52 a query. It is the backbone of DBIx::Class (i.e. the really
  53 important/useful bit).
  54
  55 No SQL is executed on the database when a ResultSet is created, it
  56 just stores all the conditions needed to create the query.
  57
  58 A basic ResultSet representing the data of an entire table is returned
  59 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  60 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  61
  62   my $users_rs = $schema->resultset('User');
  63
  64 A new ResultSet is returned from calling L</search> on an existing
  65 ResultSet. The new one will contain all the conditions of the
  66 original, plus any new conditions added in the C<search> call.
  67
  68 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  69 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  70 represents.
  71
  72 The query that the ResultSet represents is B<only> executed against
  73 the database when these methods are called:
  74 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  75
  76 If a resultset is used in a numeric context it returns the L</count>.
  77 However, if it is used in a boolean context it is B<always> true.  So if
  78 you want to check if a resultset has any results, you must use C<if $rs
  79 != 0>.
  80
  81 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  82
  83 If you want to make your custom ResultSet classes with L<Moose>, use a template
  84 similar to:
  85
  86     package MyApp::Schema::ResultSet::User;
  87
  88     use Moose;
  89     use namespace::autoclean;
  90     use MooseX::NonMoose;
  91     extends 'DBIx::Class::ResultSet';
  92
  93     sub BUILDARGS { $_[2] }
  94
  95     ...your code...
  96
  97     __PACKAGE__->meta->make_immutable;
  98
  99     1;
 100
 101 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 102 clash with the regular ResultSet constructor. Alternatively, you can use:
 103
 104     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 105
 106 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 107 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 108
 109 =head1 EXAMPLES
 110
 111 =head2 Chaining resultsets
 112
 113 Let's say you've got a query that needs to be run to return some data
 114 to the user. But, you have an authorization system in place that
 115 prevents certain users from seeing certain information. So, you want
 116 to construct the basic query in one method, but add constraints to it in
 117 another.
 118
 119   sub get_data {
 120     my $self = shift;
 121     my $request = $self->get_request; # Get a request object somehow.
 122     my $schema = $self->result_source->schema;
 123
 124     my $cd_rs = $schema->resultset('CD')->search({
 125       title => $request->param('title'),
 126       year => $request->param('year'),
 127     });
 128
 129     $cd_rs = $self->apply_security_policy( $cd_rs );
 130
 131     return $cd_rs->all();
 132   }
 133
 134   sub apply_security_policy {
 135     my $self = shift;
 136     my ($rs) = @_;
 137
 138     return $rs->search({
 139       subversive => 0,
 140     });
 141   }
 142
 143 =head3 Resolving conditions and attributes
 144
 145 When a resultset is chained from another resultset (e.g.:
 146 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 147 and attributes with the same keys need resolving.
 148
 149 If any of L</columns>, L</select>, L</as> are present, they reset the
 150 original selection, and start the selection "clean".
 151
 152 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 153 are merged into the existing ones from the original resultset.
 154
 155 The L</where> and L</having> attributes, and any search conditions, are
 156 merged with an SQL C<AND> to the existing condition from the original
 157 resultset.
 158
 159 All other attributes are overridden by any new ones supplied in the
 160 search attributes.
 161
 162 =head2 Multiple queries
 163
 164 Since a resultset just defines a query, you can do all sorts of
 165 things with it with the same object.
 166
 167   # Don't hit the DB yet.
 168   my $cd_rs = $schema->resultset('CD')->search({
 169     title => 'something',
 170     year => 2009,
 171   });
 172
 173   # Each of these hits the DB individually.
 174   my $count = $cd_rs->count;
 175   my $most_recent = $cd_rs->get_column('date_released')->max();
 176   my @records = $cd_rs->all;
 177
 178 And it's not just limited to SELECT statements.
 179
 180   $cd_rs->delete();
 181
 182 This is even cooler:
 183
 184   $cd_rs->create({ artist => 'Fred' });
 185
 186 Which is the same as:
 187
 188   $schema->resultset('CD')->create({
 189     title => 'something',
 190     year => 2009,
 191     artist => 'Fred'
 192   });
 193
 194 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 195
 196 =head1 METHODS
 197
 198 =head2 new
 199
 200 =over 4
 201
 202 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 203
 204 =item Return Value: L<$resultset|/search>
 205
 206 =back
 207
 208 The resultset constructor. Takes a source object (usually a
 209 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 210 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 211 executed as needed by the other methods.
 212
 213 Generally you never construct a resultset manually. Instead you get one
 214 from e.g. a
 215 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 216 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 217 scalar context):
 218
 219   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 220
 221 =over
 222
 223 =item WARNING
 224
 225 If called on an object, proxies to L</new_result> instead, so
 226
 227   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 228
 229 will return a CD object, not a ResultSet, and is equivalent to:
 230
 231   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 232
 233 Please also keep in mind that many internals call L</new_result> directly,
 234 so overloading this method with the idea of intercepting new result object
 235 creation B<will not work>. See also warning pertaining to L</create>.
 236
 237 =back
 238
 239 =cut
 240
 241 sub new {
 242   my $class = shift;
 243   return $class->new_result(@_) if ref $class;
 244
 245   my ($source, $attrs) = @_;
 246   $source = $source->resolve
 247     if $source->isa('DBIx::Class::ResultSourceHandle');
 248
 249   $attrs = { %{$attrs||{}} };
 250   delete @{$attrs}{qw(_last_sqlmaker_alias_map _related_results_construction)};
 251
 252   if ($attrs->{page}) {
 253     $attrs->{rows} ||= 10;
 254   }
 255
 256   $attrs->{alias} ||= 'me';
 257
 258   my $self = bless {
 259     result_source => $source,
 260     cond => $attrs->{where},
 261     pager => undef,
 262     attrs => $attrs,
 263   }, $class;
 264
 265   # if there is a dark selector, this means we are already in a
 266   # chain and the cleanup/sanification was taken care of by
 267   # _search_rs already
 268   $self->_normalize_selection($attrs)
 269     unless $attrs->{_dark_selector};
 270
 271   $self->result_class(
 272     $attrs->{result_class} || $source->result_class
 273   );
 274
 275   $self;
 276 }
 277
 278 =head2 search
 279
 280 =over 4
 281
 282 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 283
 284 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 285
 286 =back
 287
 288   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 289   my $new_rs = $cd_rs->search({ year => 2005 });
 290
 291   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 292                  # year = 2005 OR year = 2004
 293
 294 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 295 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 296 To avoid that, use L</search_rs>.
 297
 298 If you need to pass in additional attributes but no additional condition,
 299 call it as C<search(undef, \%attrs)>.
 300
 301   # "SELECT name, artistid FROM $artist_table"
 302   my @all_artists = $schema->resultset('Artist')->search(undef, {
 303     columns => [qw/name artistid/],
 304   });
 305
 306 For a list of attributes that can be passed to C<search>, see
 307 L</ATTRIBUTES>. For more examples of using this function, see
 308 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 309 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 310 and its extension L<DBIx::Class::SQLMaker>.
 311
 312 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 313
 314 =head3 CAVEAT
 315
 316 Note that L</search> does not process/deflate any of the values passed in the
 317 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 318 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 319 manually that any value passed to this method will stringify to something the
 320 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 321 objects, for more info see:
 322 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 323
 324 =cut
 325
 326 sub search {
 327   my $self = shift;
 328   my $rs = $self->search_rs( @_ );
 329
 330   if (wantarray) {
 331     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray($rs);
 332     return $rs->all;
 333   }
 334   elsif (defined wantarray) {
 335     return $rs;
 336   }
 337   else {
 338     # we can be called by a relationship helper, which in
 339     # turn may be called in void context due to some braindead
 340     # overload or whatever else the user decided to be clever
 341     # at this particular day. Thus limit the exception to
 342     # external code calls only
 343     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 344       if (caller)[0] !~ /^\QDBIx::Class::/;
 345
 346     return ();
 347   }
 348 }
 349
 350 =head2 search_rs
 351
 352 =over 4
 353
 354 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 355
 356 =item Return Value: L<$resultset|/search>
 357
 358 =back
 359
 360 This method does the same exact thing as search() except it will
 361 always return a resultset, even in list context.
 362
 363 =cut
 364
 365 sub search_rs {
 366   my $self = shift;
 367
 368   my $rsrc = $self->result_source;
 369   my ($call_cond, $call_attrs);
 370
 371   # Special-case handling for (undef, undef) or (undef)
 372   # Note that (foo => undef) is valid deprecated syntax
 373   @_ = () if not scalar grep { defined $_ } @_;
 374
 375   # just a cond
 376   if (@_ == 1) {
 377     $call_cond = shift;
 378   }
 379   # fish out attrs in the ($condref, $attr) case
 380   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 381     ($call_cond, $call_attrs) = @_;
 382   }
 383   elsif (@_ % 2) {
 384     $self->throw_exception('Odd number of arguments to search')
 385   }
 386   # legacy search
 387   elsif (@_) {
 388     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 389       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 390
 391     for my $i (0 .. $#_) {
 392       next if $i % 2;
 393       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 394         if (! defined $_[$i] or ref $_[$i] ne '');
 395     }
 396
 397     $call_cond = { @_ };
 398   }
 399
 400   # see if we can keep the cache (no $rs changes)
 401   my $cache;
 402   my %safe = (alias => 1, cache => 1);
 403   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 404     ! defined $call_cond
 405       or
 406     ref $call_cond eq 'HASH' && ! keys %$call_cond
 407       or
 408     ref $call_cond eq 'ARRAY' && ! @$call_cond
 409   )) {
 410     $cache = $self->get_cache;
 411   }
 412
 413   my $old_attrs = { %{$self->{attrs}} };
 414   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 415
 416   my $new_attrs = { %$old_attrs };
 417
 418   # take care of call attrs (only if anything is changing)
 419   if ($call_attrs and keys %$call_attrs) {
 420
 421     # copy for _normalize_selection
 422     $call_attrs = { %$call_attrs };
 423
 424     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 425
 426     # reset the current selector list if new selectors are supplied
 427     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 428       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 429     }
 430
 431     # Normalize the new selector list (operates on the passed-in attr structure)
 432     # Need to do it on every chain instead of only once on _resolved_attrs, in
 433     # order to allow detection of empty vs partial 'as'
 434     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 435       if $old_attrs->{_dark_selector};
 436     $self->_normalize_selection ($call_attrs);
 437
 438     # start with blind overwriting merge, exclude selector attrs
 439     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 440     delete @{$new_attrs}{@selector_attrs};
 441
 442     for (@selector_attrs) {
 443       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 444         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 445     }
 446
 447     # older deprecated name, use only if {columns} is not there
 448     if (my $c = delete $new_attrs->{cols}) {
 449       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 450       if ($new_attrs->{columns}) {
 451         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 452       }
 453       else {
 454         $new_attrs->{columns} = $c;
 455       }
 456     }
 457
 458
 459     # join/prefetch use their own crazy merging heuristics
 460     foreach my $key (qw/join prefetch/) {
 461       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 462         if exists $call_attrs->{$key};
 463     }
 464
 465     # stack binds together
 466     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 467   }
 468
 469
 470   for ($old_where, $call_cond) {
 471     if (defined $_) {
 472       $new_attrs->{where} = $self->_stack_cond (
 473         $_, $new_attrs->{where}
 474       );
 475     }
 476   }
 477
 478   if (defined $old_having) {
 479     $new_attrs->{having} = $self->_stack_cond (
 480       $old_having, $new_attrs->{having}
 481     )
 482   }
 483
 484   my $rs = (ref $self)->new($rsrc, $new_attrs);
 485
 486   $rs->set_cache($cache) if ($cache);
 487
 488   return $rs;
 489 }
 490
 491 my $dark_sel_dumper;
 492 sub _normalize_selection {
 493   my ($self, $attrs) = @_;
 494
 495   # legacy syntax
 496   if ( exists $attrs->{include_columns} ) {
 497     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 498     $attrs->{'+columns'} = $self->_merge_attr(
 499       $attrs->{'+columns'}, delete $attrs->{include_columns}
 500     );
 501   }
 502
 503   # columns are always placed first, however
 504
 505   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 506   # delay the decision on whether to use a default select list ($rsrc->columns)
 507   # allowing stuff like the remove_columns helper to work
 508   #
 509   # select/as +select/+as pairs need special handling - the amount of select/as
 510   # elements in each pair does *not* have to be equal (think multicolumn
 511   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 512   # supplied at all) - try to infer the alias, either from the -as parameter
 513   # of the selector spec, or use the parameter whole if it looks like a column
 514   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 515   # is ok as well), but make sure no more additions to the 'as' chain take place
 516   for my $pref ('', '+') {
 517
 518     my ($sel, $as) = map {
 519       my $key = "${pref}${_}";
 520
 521       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 522         ? @{$attrs->{$key}}
 523         : $attrs->{$key} || ()
 524       ];
 525       delete $attrs->{$key};
 526       $val;
 527     } qw/select as/;
 528
 529     if (! @$as and ! @$sel ) {
 530       next;
 531     }
 532     elsif (@$as and ! @$sel) {
 533       $self->throw_exception(
 534         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 535       );
 536     }
 537     elsif( ! @$as ) {
 538       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 539       # if any @$as has been supplied we assume the user knows what (s)he is doing
 540       # and blindly keep stacking up pieces
 541       unless ($attrs->{_dark_selector}) {
 542         SELECTOR:
 543         for (@$sel) {
 544           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 545             push @$as, $_->{-as};
 546           }
 547           # assume any plain no-space, no-parenthesis string to be a column spec
 548           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 549           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 550             push @$as, $_;
 551           }
 552           # if all else fails - raise a flag that no more aliasing will be allowed
 553           else {
 554             $attrs->{_dark_selector} = {
 555               plus_stage => $pref,
 556               string => ($dark_sel_dumper ||= do {
 557                   require Data::Dumper::Concise;
 558                   Data::Dumper::Concise::DumperObject()->Indent(0);
 559                 })->Values([$_])->Dump
 560               ,
 561             };
 562             last SELECTOR;
 563           }
 564         }
 565       }
 566     }
 567     elsif (@$as < @$sel) {
 568       $self->throw_exception(
 569         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 570       );
 571     }
 572     elsif ($pref and $attrs->{_dark_selector}) {
 573       $self->throw_exception(
 574         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 575       );
 576     }
 577
 578
 579     # merge result
 580     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 581     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 582   }
 583 }
 584
 585 sub _stack_cond {
 586   my ($self, $left, $right) = @_;
 587
 588   # collapse single element top-level conditions
 589   # (single pass only, unlikely to need recursion)
 590   for ($left, $right) {
 591     if (ref $_ eq 'ARRAY') {
 592       if (@$_ == 0) {
 593         $_ = undef;
 594       }
 595       elsif (@$_ == 1) {
 596         $_ = $_->[0];
 597       }
 598     }
 599     elsif (ref $_ eq 'HASH') {
 600       my ($first, $more) = keys %$_;
 601
 602       # empty hash
 603       if (! defined $first) {
 604         $_ = undef;
 605       }
 606       # one element hash
 607       elsif (! defined $more) {
 608         if ($first eq '-and' and ref $_->{'-and'} eq 'HASH') {
 609           $_ = $_->{'-and'};
 610         }
 611         elsif ($first eq '-or' and ref $_->{'-or'} eq 'ARRAY') {
 612           $_ = $_->{'-or'};
 613         }
 614       }
 615     }
 616   }
 617
 618   # merge hashes with weeding out of duplicates (simple cases only)
 619   if (ref $left eq 'HASH' and ref $right eq 'HASH') {
 620
 621     # shallow copy to destroy
 622     $right = { %$right };
 623     for (grep { exists $right->{$_} } keys %$left) {
 624       # the use of eq_deeply here is justified - the rhs of an
 625       # expression can contain a lot of twisted weird stuff
 626       delete $right->{$_} if Data::Compare::Compare( $left->{$_}, $right->{$_} );
 627     }
 628
 629     $right = undef unless keys %$right;
 630   }
 631
 632
 633   if (defined $left xor defined $right) {
 634     return defined $left ? $left : $right;
 635   }
 636   elsif (! defined $left) {
 637     return undef;
 638   }
 639   else {
 640     return { -and => [ $left, $right ] };
 641   }
 642 }
 643
 644 =head2 search_literal
 645
 646 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 647 should only be used in that context. C<search_literal> is a convenience
 648 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 649 want to ensure columns are bound correctly, use L</search>.
 650
 651 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 652 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 653 require C<search_literal>.
 654
 655 =over 4
 656
 657 =item Arguments: $sql_fragment, @standalone_bind_values
 658
 659 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 660
 661 =back
 662
 663   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 664   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 665
 666 Pass a literal chunk of SQL to be added to the conditional part of the
 667 resultset query.
 668
 669 Example of how to use C<search> instead of C<search_literal>
 670
 671   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 672   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 673
 674 =cut
 675
 676 sub search_literal {
 677   my ($self, $sql, @bind) = @_;
 678   my $attr;
 679   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 680     $attr = pop @bind;
 681   }
 682   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 683 }
 684
 685 =head2 find
 686
 687 =over 4
 688
 689 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 690
 691 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 692
 693 =back
 694
 695 Finds and returns a single row based on supplied criteria. Takes either a
 696 hashref with the same format as L</create> (including inference of foreign
 697 keys from related objects), or a list of primary key values in the same
 698 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 699 declaration on the L</result_source>.
 700
 701 In either case an attempt is made to combine conditions already existing on
 702 the resultset with the condition passed to this method.
 703
 704 To aid with preparing the correct query for the storage you may supply the
 705 C<key> attribute, which is the name of a
 706 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 707 unique constraint corresponding to the
 708 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 709 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 710 to construct a query that satisfies the named unique constraint fully (
 711 non-NULL values for each column member of the constraint) an exception is
 712 thrown.
 713
 714 If no C<key> is specified, the search is carried over all unique constraints
 715 which are fully defined by the available condition.
 716
 717 If no such constraint is found, C<find> currently defaults to a simple
 718 C<< search->(\%column_values) >> which may or may not do what you expect.
 719 Note that this fallback behavior may be deprecated in further versions. If
 720 you need to search with arbitrary conditions - use L</search>. If the query
 721 resulting from this fallback produces more than one row, a warning to the
 722 effect is issued, though only the first row is constructed and returned as
 723 C<$result_object>.
 724
 725 In addition to C<key>, L</find> recognizes and applies standard
 726 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 727
 728 Note that if you have extra concerns about the correctness of the resulting
 729 query you need to specify the C<key> attribute and supply the entire condition
 730 as an argument to find (since it is not always possible to perform the
 731 combination of the resultset condition with the supplied one, especially if
 732 the resultset condition contains literal sql).
 733
 734 For example, to find a row by its primary key:
 735
 736   my $cd = $schema->resultset('CD')->find(5);
 737
 738 You can also find a row by a specific unique constraint:
 739
 740   my $cd = $schema->resultset('CD')->find(
 741     {
 742       artist => 'Massive Attack',
 743       title  => 'Mezzanine',
 744     },
 745     { key => 'cd_artist_title' }
 746   );
 747
 748 See also L</find_or_create> and L</update_or_create>.
 749
 750 =cut
 751
 752 sub find {
 753   my $self = shift;
 754   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 755
 756   my $rsrc = $self->result_source;
 757
 758   my $constraint_name;
 759   if (exists $attrs->{key}) {
 760     $constraint_name = defined $attrs->{key}
 761       ? $attrs->{key}
 762       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 763     ;
 764   }
 765
 766   # Parse out the condition from input
 767   my $call_cond;
 768
 769   if (ref $_[0] eq 'HASH') {
 770     $call_cond = { %{$_[0]} };
 771   }
 772   else {
 773     # if only values are supplied we need to default to 'primary'
 774     $constraint_name = 'primary' unless defined $constraint_name;
 775
 776     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 777
 778     $self->throw_exception(
 779       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 780     ) unless @c_cols;
 781
 782     $self->throw_exception (
 783       'find() expects either a column/value hashref, or a list of values '
 784     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 785     ) unless @c_cols == @_;
 786
 787     $call_cond = {};
 788     @{$call_cond}{@c_cols} = @_;
 789   }
 790
 791   my %related;
 792   for my $key (keys %$call_cond) {
 793     if (
 794       my $keyref = ref($call_cond->{$key})
 795         and
 796       my $relinfo = $rsrc->relationship_info($key)
 797     ) {
 798       my $val = delete $call_cond->{$key};
 799
 800       next if $keyref eq 'ARRAY'; # has_many for multi_create
 801
 802       my $rel_q = $rsrc->_resolve_condition(
 803         $relinfo->{cond}, $val, $key, $key
 804       );
 805       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 806       @related{keys %$rel_q} = values %$rel_q;
 807     }
 808   }
 809
 810   # relationship conditions take precedence (?)
 811   @{$call_cond}{keys %related} = values %related;
 812
 813   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 814   my $final_cond;
 815   if (defined $constraint_name) {
 816     $final_cond = $self->_qualify_cond_columns (
 817
 818       $self->_build_unique_cond (
 819         $constraint_name,
 820         $call_cond,
 821       ),
 822
 823       $alias,
 824     );
 825   }
 826   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 827     # This means that we got here after a merger of relationship conditions
 828     # in ::Relationship::Base::search_related (the row method), and furthermore
 829     # the relationship is of the 'single' type. This means that the condition
 830     # provided by the relationship (already attached to $self) is sufficient,
 831     # as there can be only one row in the database that would satisfy the
 832     # relationship
 833   }
 834   else {
 835     # no key was specified - fall down to heuristics mode:
 836     # run through all unique queries registered on the resultset, and
 837     # 'OR' all qualifying queries together
 838     my (@unique_queries, %seen_column_combinations);
 839     for my $c_name ($rsrc->unique_constraint_names) {
 840       next if $seen_column_combinations{
 841         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 842       }++;
 843
 844       push @unique_queries, try {
 845         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 846       } || ();
 847     }
 848
 849     $final_cond = @unique_queries
 850       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 851       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 852     ;
 853   }
 854
 855   # Run the query, passing the result_class since it should propagate for find
 856   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 857   if ($rs->_resolved_attrs->{collapse}) {
 858     my $row = $rs->next;
 859     carp "Query returned more than one row" if $rs->next;
 860     return $row;
 861   }
 862   else {
 863     return $rs->single;
 864   }
 865 }
 866
 867 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 868 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 869 #
 870 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 871 # condition. It is provided for overrides until a saner way forward is devised
 872 #
 873 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 874 # the road. Please adjust your tests accordingly to catch this situation early
 875 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 876 #
 877 # The method will not be removed without an adequately complete replacement
 878 # for strict-mode enforcement
 879 sub _non_unique_find_fallback {
 880   my ($self, $cond, $attrs) = @_;
 881
 882   return $self->_qualify_cond_columns(
 883     $cond,
 884     exists $attrs->{alias}
 885       ? $attrs->{alias}
 886       : $self->{attrs}{alias}
 887   );
 888 }
 889
 890
 891 sub _qualify_cond_columns {
 892   my ($self, $cond, $alias) = @_;
 893
 894   my %aliased = %$cond;
 895   for (keys %aliased) {
 896     $aliased{"$alias.$_"} = delete $aliased{$_}
 897       if $_ !~ /\./;
 898   }
 899
 900   return \%aliased;
 901 }
 902
 903 sub _build_unique_cond {
 904   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 905
 906   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 907
 908   # combination may fail if $self->{cond} is non-trivial
 909   my ($final_cond) = try {
 910     $self->_merge_with_rscond ($extra_cond)
 911   } catch {
 912     +{ %$extra_cond }
 913   };
 914
 915   # trim out everything not in $columns
 916   $final_cond = { map {
 917     exists $final_cond->{$_}
 918       ? ( $_ => $final_cond->{$_} )
 919       : ()
 920   } @c_cols };
 921
 922   if (my @missing = grep
 923     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 924     (@c_cols)
 925   ) {
 926     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 927       $constraint_name,
 928       join (', ', map { "'$_'" } @missing),
 929     ) );
 930   }
 931
 932   if (
 933     !$croak_on_null
 934       and
 935     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 936       and
 937     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 938   ) {
 939     carp_unique ( sprintf (
 940       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 941     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 942     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 943       $constraint_name,
 944       join (', ', map { "'$_'" } @undefs),
 945     ));
 946   }
 947
 948   return $final_cond;
 949 }
 950
 951 =head2 search_related
 952
 953 =over 4
 954
 955 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 956
 957 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 958
 959 =back
 960
 961   $new_rs = $cd_rs->search_related('artist', {
 962     name => 'Emo-R-Us',
 963   });
 964
 965 Searches the specified relationship, optionally specifying a condition and
 966 attributes for matching records. See L</ATTRIBUTES> for more information.
 967
 968 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 969 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 970
 971 See also L</search_related_rs>.
 972
 973 =cut
 974
 975 sub search_related {
 976   return shift->related_resultset(shift)->search(@_);
 977 }
 978
 979 =head2 search_related_rs
 980
 981 This method works exactly the same as search_related, except that
 982 it guarantees a resultset, even in list context.
 983
 984 =cut
 985
 986 sub search_related_rs {
 987   return shift->related_resultset(shift)->search_rs(@_);
 988 }
 989
 990 =head2 cursor
 991
 992 =over 4
 993
 994 =item Arguments: none
 995
 996 =item Return Value: L<$cursor|DBIx::Class::Cursor>
 997
 998 =back
 999
1000 Returns a storage-driven cursor to the given resultset. See
1001 L<DBIx::Class::Cursor> for more information.
1002
1003 =cut
1004
1005 sub cursor {
1006   my $self = shift;
1007
1008   return $self->{cursor} ||= do {
1009     my $attrs = $self->_resolved_attrs;
1010     $self->result_source->storage->select(
1011       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1012     );
1013   };
1014 }
1015
1016 =head2 single
1017
1018 =over 4
1019
1020 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1021
1022 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1023
1024 =back
1025
1026   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1027
1028 Inflates the first result without creating a cursor if the resultset has
1029 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1030 of L</search>.
1031
1032 While this method can take an optional search condition (just like L</search>)
1033 being a fast-code-path it does not recognize search attributes. If you need to
1034 add extra joins or similar, call L</search> and then chain-call L</single> on the
1035 L<DBIx::Class::ResultSet> returned.
1036
1037 =over
1038
1039 =item B<Note>
1040
1041 As of 0.08100, this method enforces the assumption that the preceding
1042 query returns only one row. If more than one row is returned, you will receive
1043 a warning:
1044
1045   Query returned more than one row
1046
1047 In this case, you should be using L</next> or L</find> instead, or if you really
1048 know what you are doing, use the L</rows> attribute to explicitly limit the size
1049 of the resultset.
1050
1051 This method will also throw an exception if it is called on a resultset prefetching
1052 has_many, as such a prefetch implies fetching multiple rows from the database in
1053 order to assemble the resulting object.
1054
1055 =back
1056
1057 =cut
1058
1059 sub single {
1060   my ($self, $where) = @_;
1061   if(@_ > 2) {
1062       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1063   }
1064
1065   my $attrs = { %{$self->_resolved_attrs} };
1066
1067   $self->throw_exception(
1068     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1069   ) if $attrs->{collapse};
1070
1071   if ($where) {
1072     if (defined $attrs->{where}) {
1073       $attrs->{where} = {
1074         '-and' =>
1075             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1076                $where, delete $attrs->{where} ]
1077       };
1078     } else {
1079       $attrs->{where} = $where;
1080     }
1081   }
1082
1083   my $data = [ $self->result_source->storage->select_single(
1084     $attrs->{from}, $attrs->{select},
1085     $attrs->{where}, $attrs
1086   )];
1087
1088   return undef unless @$data;
1089   $self->{_stashed_rows} = [ $data ];
1090   $self->_construct_results->[0];
1091 }
1092
1093 =head2 get_column
1094
1095 =over 4
1096
1097 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1098
1099 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1100
1101 =back
1102
1103   my $max_length = $rs->get_column('length')->max;
1104
1105 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1106
1107 =cut
1108
1109 sub get_column {
1110   my ($self, $column) = @_;
1111   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1112   return $new;
1113 }
1114
1115 =head2 search_like
1116
1117 =over 4
1118
1119 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1120
1121 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1122
1123 =back
1124
1125   # WHERE title LIKE '%blue%'
1126   $cd_rs = $rs->search_like({ title => '%blue%'});
1127
1128 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1129 that this is simply a convenience method retained for ex Class::DBI users.
1130 You most likely want to use L</search> with specific operators.
1131
1132 For more information, see L<DBIx::Class::Manual::Cookbook>.
1133
1134 This method is deprecated and will be removed in 0.09. Use L</search()>
1135 instead. An example conversion is:
1136
1137   ->search_like({ foo => 'bar' });
1138
1139   # Becomes
1140
1141   ->search({ foo => { like => 'bar' } });
1142
1143 =cut
1144
1145 sub search_like {
1146   my $class = shift;
1147   carp_unique (
1148     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1149    .' Instead use ->search({ x => { -like => "y%" } })'
1150    .' (note the outer pair of {}s - they are important!)'
1151   );
1152   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1153   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1154   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1155   return $class->search($query, { %$attrs });
1156 }
1157
1158 =head2 slice
1159
1160 =over 4
1161
1162 =item Arguments: $first, $last
1163
1164 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1165
1166 =back
1167
1168 Returns a resultset or object list representing a subset of elements from the
1169 resultset slice is called on. Indexes are from 0, i.e., to get the first
1170 three records, call:
1171
1172   my ($one, $two, $three) = $rs->slice(0, 2);
1173
1174 =cut
1175
1176 sub slice {
1177   my ($self, $min, $max) = @_;
1178   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1179   $attrs->{offset} = $self->{attrs}{offset} || 0;
1180   $attrs->{offset} += $min;
1181   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1182   return $self->search(undef, $attrs);
1183 }
1184
1185 =head2 next
1186
1187 =over 4
1188
1189 =item Arguments: none
1190
1191 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1192
1193 =back
1194
1195 Returns the next element in the resultset (C<undef> is there is none).
1196
1197 Can be used to efficiently iterate over records in the resultset:
1198
1199   my $rs = $schema->resultset('CD')->search;
1200   while (my $cd = $rs->next) {
1201     print $cd->title;
1202   }
1203
1204 Note that you need to store the resultset object, and call C<next> on it.
1205 Calling C<< resultset('Table')->next >> repeatedly will always return the
1206 first record from the resultset.
1207
1208 =cut
1209
1210 sub next {
1211   my ($self) = @_;
1212
1213   if (my $cache = $self->get_cache) {
1214     $self->{all_cache_position} ||= 0;
1215     return $cache->[$self->{all_cache_position}++];
1216   }
1217
1218   if ($self->{attrs}{cache}) {
1219     delete $self->{pager};
1220     $self->{all_cache_position} = 1;
1221     return ($self->all)[0];
1222   }
1223
1224   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1225
1226   $self->{_stashed_results} = $self->_construct_results
1227     or return undef;
1228
1229   return shift @{$self->{_stashed_results}};
1230 }
1231
1232 # Constructs as many results as it can in one pass while respecting
1233 # cursor laziness. Several modes of operation:
1234 #
1235 # * Always builds everything present in @{$self->{_stashed_rows}}
1236 # * If called with $fetch_all true - pulls everything off the cursor and
1237 #   builds all result structures (or objects) in one pass
1238 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1239 #   and if the resultset is ordered properly by the left side:
1240 #   * Fetches stuff off the cursor until the "master object" changes,
1241 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1242 #   OR
1243 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1244 #     was requested (there is no other way to collapse except for an
1245 #     eager cursor)
1246 # * If no collapse is requested - just get the next row, construct and
1247 #   return
1248 sub _construct_results {
1249   my ($self, $fetch_all) = @_;
1250
1251   my $rsrc = $self->result_source;
1252   my $attrs = $self->_resolved_attrs;
1253
1254   if (
1255     ! $fetch_all
1256       and
1257     ! $attrs->{order_by}
1258       and
1259     $attrs->{collapse}
1260       and
1261     my @pcols = $rsrc->primary_columns
1262   ) {
1263     # default order for collapsing unless the user asked for something
1264     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1265     $attrs->{_ordered_for_collapse} = 1;
1266     $attrs->{_order_is_artificial} = 1;
1267   }
1268
1269   # this will be used as both initial raw-row collector AND as a RV of
1270   # _construct_results. Not regrowing the array twice matters a lot...
1271   # a surprising amount actually
1272   my $rows = delete $self->{_stashed_rows};
1273
1274   my $cursor; # we may not need one at all
1275
1276   my $did_fetch_all = $fetch_all;
1277
1278   if ($fetch_all) {
1279     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1280     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1281   }
1282   elsif( $attrs->{collapse} ) {
1283
1284     # a cursor will need to be closed over in case of collapse
1285     $cursor = $self->cursor;
1286
1287     $attrs->{_ordered_for_collapse} = (
1288       (
1289         $attrs->{order_by}
1290           and
1291         $rsrc->schema
1292               ->storage
1293                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1294       ) ? 1 : 0
1295     ) unless defined $attrs->{_ordered_for_collapse};
1296
1297     if (! $attrs->{_ordered_for_collapse}) {
1298       $did_fetch_all = 1;
1299
1300       # instead of looping over ->next, use ->all in stealth mode
1301       # *without* calling a ->reset afterwards
1302       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1303       if (! $cursor->{_done}) {
1304         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1305         $cursor->{_done} = 1;
1306       }
1307     }
1308   }
1309
1310   if (! $did_fetch_all and ! @{$rows||[]} ) {
1311     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1312     $cursor ||= $self->cursor;
1313     if (scalar (my @r = $cursor->next) ) {
1314       $rows = [ \@r ];
1315     }
1316   }
1317
1318   return undef unless @{$rows||[]};
1319
1320   # sanity check - people are too clever for their own good
1321   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1322
1323     my $multiplied_selectors;
1324     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1325       if (
1326         $aliastypes->{multiplying}{$sel_alias}
1327           or
1328         $aliastypes->{premultiplied}{$sel_alias}
1329       ) {
1330         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1331       }
1332     }
1333
1334     for my $i (0 .. $#{$attrs->{as}} ) {
1335       my $sel = $attrs->{select}[$i];
1336
1337       if (ref $sel eq 'SCALAR') {
1338         $sel = $$sel;
1339       }
1340       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1341         $sel = $$sel->[0];
1342       }
1343
1344       $self->throw_exception(
1345         'Result collapse not possible - selection from a has_many source redirected to the main object'
1346       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1347     }
1348   }
1349
1350   # hotspot - skip the setter
1351   my $res_class = $self->_result_class;
1352
1353   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1354     $res_class->can ('inflate_result')
1355       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1356   };
1357
1358   my $infmap = $attrs->{as};
1359
1360   $self->{_result_inflator}{is_core_row} = ( (
1361     $inflator_cref
1362       ==
1363     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1364   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1365
1366   $self->{_result_inflator}{is_hri} = ( (
1367     ! $self->{_result_inflator}{is_core_row}
1368       and
1369     $inflator_cref == (
1370       require DBIx::Class::ResultClass::HashRefInflator
1371         &&
1372       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1373     )
1374   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1375
1376
1377   if (! $attrs->{_related_results_construction}) {
1378     # construct a much simpler array->hash folder for the one-table cases right here
1379     if ($self->{_result_inflator}{is_hri}) {
1380       for my $r (@$rows) {
1381         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1382       }
1383     }
1384     # FIXME SUBOPTIMAL this is a very very very hot spot
1385     # while rather optimal we can *still* do much better, by
1386     # building a smarter Row::inflate_result(), and
1387     # switch to feeding it data via a much leaner interface
1388     #
1389     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1390     # this particular resultset size
1391     elsif (@$rows < 60) {
1392       for my $r (@$rows) {
1393         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1394       }
1395     }
1396     else {
1397       eval sprintf (
1398         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1399         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1400       );
1401     }
1402   }
1403   else {
1404     my $parser_type =
1405         $self->{_result_inflator}{is_hri}       ? 'hri'
1406       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1407       :                                           'classic_nonpruning'
1408     ;
1409
1410     # $args and $attrs to _mk_row_parser are separated to delineate what is
1411     # core collapser stuff and what is dbic $rs specific
1412     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1413       eval => 1,
1414       inflate_map => $infmap,
1415       collapse => $attrs->{collapse},
1416       premultiplied => $attrs->{_main_source_premultiplied},
1417       hri_style => $self->{_result_inflator}{is_hri},
1418       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1419     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1420
1421     # column_info metadata historically hasn't been too reliable.
1422     # We need to start fixing this somehow (the collapse resolver
1423     # can't work without it). Add an explicit check for the *main*
1424     # result, hopefully this will gradually weed out such errors
1425     #
1426     # FIXME - this is a temporary kludge that reduces performance
1427     # It is however necessary for the time being
1428     my ($unrolled_non_null_cols_to_check, $err);
1429
1430     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1431
1432       $err =
1433         'Collapse aborted due to invalid ResultSource metadata - the following '
1434       . 'selections are declared non-nullable but NULLs were retrieved: '
1435       ;
1436
1437       my @violating_idx;
1438       COL: for my $i (@$check_non_null_cols) {
1439         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1440       }
1441
1442       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1443         if @violating_idx;
1444
1445       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1446     }
1447
1448     my $next_cref =
1449       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1450     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1451 sub {
1452   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1453   my @r = $cursor->next or return;
1454   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1455     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1456   }
1457   \@r
1458 }
1459 EOS
1460     : sub {
1461         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1462         my @r = $cursor->next or return;
1463         \@r
1464       }
1465     ;
1466
1467     $self->{_row_parser}{$parser_type}{cref}->(
1468       $rows,
1469       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1470     );
1471
1472     # Special-case multi-object HRI - there is no $inflator_cref pass
1473     unless ($self->{_result_inflator}{is_hri}) {
1474       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1475     }
1476   }
1477
1478   # The @$rows check seems odd at first - why wouldn't we want to warn
1479   # regardless? The issue is things like find() etc, where the user
1480   # *knows* only one result will come back. In these cases the ->all
1481   # is not a pessimization, but rather something we actually want
1482   carp_unique(
1483     'Unable to properly collapse has_many results in iterator mode due '
1484   . 'to order criteria - performed an eager cursor slurp underneath. '
1485   . 'Consider using ->all() instead'
1486   ) if ( ! $fetch_all and @$rows > 1 );
1487
1488   return $rows;
1489 }
1490
1491 =head2 result_source
1492
1493 =over 4
1494
1495 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1496
1497 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1498
1499 =back
1500
1501 An accessor for the primary ResultSource object from which this ResultSet
1502 is derived.
1503
1504 =head2 result_class
1505
1506 =over 4
1507
1508 =item Arguments: $result_class?
1509
1510 =item Return Value: $result_class
1511
1512 =back
1513
1514 An accessor for the class to use when creating result objects. Defaults to
1515 C<< result_source->result_class >> - which in most cases is the name of the
1516 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1517
1518 Note that changing the result_class will also remove any components
1519 that were originally loaded in the source class via
1520 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1521 in the original source class will not run.
1522
1523 =cut
1524
1525 sub result_class {
1526   my ($self, $result_class) = @_;
1527   if ($result_class) {
1528
1529     # don't fire this for an object
1530     $self->ensure_class_loaded($result_class)
1531       unless ref($result_class);
1532
1533     if ($self->get_cache) {
1534       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1535     }
1536     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1537     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1538       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1539     }
1540
1541     $self->_result_class($result_class);
1542
1543     delete $self->{_result_inflator};
1544   }
1545   $self->_result_class;
1546 }
1547
1548 =head2 count
1549
1550 =over 4
1551
1552 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1553
1554 =item Return Value: $count
1555
1556 =back
1557
1558 Performs an SQL C<COUNT> with the same query as the resultset was built
1559 with to find the number of elements. Passing arguments is equivalent to
1560 C<< $rs->search ($cond, \%attrs)->count >>
1561
1562 =cut
1563
1564 sub count {
1565   my $self = shift;
1566   return $self->search(@_)->count if @_ and defined $_[0];
1567   return scalar @{ $self->get_cache } if $self->get_cache;
1568
1569   my $attrs = { %{ $self->_resolved_attrs } };
1570
1571   # this is a little optimization - it is faster to do the limit
1572   # adjustments in software, instead of a subquery
1573   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1574
1575   my $crs;
1576   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1577     $crs = $self->_count_subq_rs ($attrs);
1578   }
1579   else {
1580     $crs = $self->_count_rs ($attrs);
1581   }
1582   my $count = $crs->next;
1583
1584   $count -= $offset if $offset;
1585   $count = $rows if $rows and $rows < $count;
1586   $count = 0 if ($count < 0);
1587
1588   return $count;
1589 }
1590
1591 =head2 count_rs
1592
1593 =over 4
1594
1595 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1596
1597 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1598
1599 =back
1600
1601 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1602 This can be very handy for subqueries:
1603
1604   ->search( { amount => $some_rs->count_rs->as_query } )
1605
1606 As with regular resultsets the SQL query will be executed only after
1607 the resultset is accessed via L</next> or L</all>. That would return
1608 the same single value obtainable via L</count>.
1609
1610 =cut
1611
1612 sub count_rs {
1613   my $self = shift;
1614   return $self->search(@_)->count_rs if @_;
1615
1616   # this may look like a lack of abstraction (count() does about the same)
1617   # but in fact an _rs *must* use a subquery for the limits, as the
1618   # software based limiting can not be ported if this $rs is to be used
1619   # in a subquery itself (i.e. ->as_query)
1620   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1621     return $self->_count_subq_rs($self->{_attrs});
1622   }
1623   else {
1624     return $self->_count_rs($self->{_attrs});
1625   }
1626 }
1627
1628 #
1629 # returns a ResultSetColumn object tied to the count query
1630 #
1631 sub _count_rs {
1632   my ($self, $attrs) = @_;
1633
1634   my $rsrc = $self->result_source;
1635
1636   my $tmp_attrs = { %$attrs };
1637   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1638   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1639
1640   # overwrite the selector (supplied by the storage)
1641   $rsrc->resultset_class->new($rsrc, {
1642     %$tmp_attrs,
1643     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1644     as => 'count',
1645   })->get_column ('count');
1646 }
1647
1648 #
1649 # same as above but uses a subquery
1650 #
1651 sub _count_subq_rs {
1652   my ($self, $attrs) = @_;
1653
1654   my $rsrc = $self->result_source;
1655
1656   my $sub_attrs = { %$attrs };
1657   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1658   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1659
1660   # if we multi-prefetch we group_by something unique, as this is what we would
1661   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1662   if ( $attrs->{collapse}  ) {
1663     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1664       $rsrc->_identifying_column_set || $self->throw_exception(
1665         'Unable to construct a unique group_by criteria properly collapsing the '
1666       . 'has_many prefetch before count()'
1667       );
1668     } ]
1669   }
1670
1671   # Calculate subquery selector
1672   if (my $g = $sub_attrs->{group_by}) {
1673
1674     my $sql_maker = $rsrc->storage->sql_maker;
1675
1676     # necessary as the group_by may refer to aliased functions
1677     my $sel_index;
1678     for my $sel (@{$attrs->{select}}) {
1679       $sel_index->{$sel->{-as}} = $sel
1680         if (ref $sel eq 'HASH' and $sel->{-as});
1681     }
1682
1683     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1684     # also look for named aggregates referred in the having clause
1685     # having often contains scalarrefs - thus parse it out entirely
1686     my @parts = @$g;
1687     if ($attrs->{having}) {
1688       local $sql_maker->{having_bind};
1689       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1690       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1691       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1692         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1693         # if we don't unset it we screw up retarded but unfortunately working
1694         # 'MAX(foo.bar)' => { '>', 3 }
1695         $sql_maker->{name_sep} = '';
1696       }
1697
1698       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1699
1700       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1701       my %seen_having;
1702
1703       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1704       # and if all fails for an utterly naive quoted scalar-with-function
1705       while ($having_sql =~ /
1706         $rquote $sep $lquote (.+?) $rquote
1707           |
1708         [\s,] \w+ \. (\w+) [\s,]
1709           |
1710         [\s,] $lquote (.+?) $rquote [\s,]
1711       /gx) {
1712         my $part = $1 || $2 || $3;  # one of them matched if we got here
1713         unless ($seen_having{$part}++) {
1714           push @parts, $part;
1715         }
1716       }
1717     }
1718
1719     for (@parts) {
1720       my $colpiece = $sel_index->{$_} || $_;
1721
1722       # unqualify join-based group_by's. Arcane but possible query
1723       # also horrible horrible hack to alias a column (not a func.)
1724       # (probably need to introduce SQLA syntax)
1725       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1726         my $as = $colpiece;
1727         $as =~ s/\./__/;
1728         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1729       }
1730       push @{$sub_attrs->{select}}, $colpiece;
1731     }
1732   }
1733   else {
1734     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1735     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1736   }
1737
1738   return $rsrc->resultset_class
1739                ->new ($rsrc, $sub_attrs)
1740                 ->as_subselect_rs
1741                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1742                   ->get_column ('count');
1743 }
1744
1745
1746 =head2 count_literal
1747
1748 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1749 should only be used in that context. See L</search_literal> for further info.
1750
1751 =over 4
1752
1753 =item Arguments: $sql_fragment, @standalone_bind_values
1754
1755 =item Return Value: $count
1756
1757 =back
1758
1759 Counts the results in a literal query. Equivalent to calling L</search_literal>
1760 with the passed arguments, then L</count>.
1761
1762 =cut
1763
1764 sub count_literal { shift->search_literal(@_)->count; }
1765
1766 =head2 all
1767
1768 =over 4
1769
1770 =item Arguments: none
1771
1772 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1773
1774 =back
1775
1776 Returns all elements in the resultset.
1777
1778 =cut
1779
1780 sub all {
1781   my $self = shift;
1782   if(@_) {
1783     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1784   }
1785
1786   delete @{$self}{qw/_stashed_rows _stashed_results/};
1787
1788   if (my $c = $self->get_cache) {
1789     return @$c;
1790   }
1791
1792   $self->cursor->reset;
1793
1794   my $objs = $self->_construct_results('fetch_all') || [];
1795
1796   $self->set_cache($objs) if $self->{attrs}{cache};
1797
1798   return @$objs;
1799 }
1800
1801 =head2 reset
1802
1803 =over 4
1804
1805 =item Arguments: none
1806
1807 =item Return Value: $self
1808
1809 =back
1810
1811 Resets the resultset's cursor, so you can iterate through the elements again.
1812 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1813 another query.
1814
1815 =cut
1816
1817 sub reset {
1818   my ($self) = @_;
1819
1820   delete @{$self}{qw/_stashed_rows _stashed_results/};
1821   $self->{all_cache_position} = 0;
1822   $self->cursor->reset;
1823   return $self;
1824 }
1825
1826 =head2 first
1827
1828 =over 4
1829
1830 =item Arguments: none
1831
1832 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1833
1834 =back
1835
1836 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1837 an object for the first result (or C<undef> if the resultset is empty).
1838
1839 =cut
1840
1841 sub first {
1842   return $_[0]->reset->next;
1843 }
1844
1845
1846 # _rs_update_delete
1847 #
1848 # Determines whether and what type of subquery is required for the $rs operation.
1849 # If grouping is necessary either supplies its own, or verifies the current one
1850 # After all is done delegates to the proper storage method.
1851
1852 sub _rs_update_delete {
1853   my ($self, $op, $values) = @_;
1854
1855   my $rsrc = $self->result_source;
1856   my $storage = $rsrc->schema->storage;
1857
1858   my $attrs = { %{$self->_resolved_attrs} };
1859
1860   my $join_classifications;
1861   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1862
1863   # do we need a subquery for any reason?
1864   my $needs_subq = (
1865     defined $existing_group_by
1866       or
1867     # if {from} is unparseable wrap a subq
1868     ref($attrs->{from}) ne 'ARRAY'
1869       or
1870     # limits call for a subq
1871     $self->_has_resolved_attr(qw/rows offset/)
1872   );
1873
1874   # simplify the joinmap, so we can further decide if a subq is necessary
1875   if (!$needs_subq and @{$attrs->{from}} > 1) {
1876
1877     ($attrs->{from}, $join_classifications) =
1878       $storage->_prune_unused_joins ($attrs);
1879
1880     # any non-pruneable non-local restricting joins imply subq
1881     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1882   }
1883
1884   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1885   $needs_subq ||= (
1886     (ref $attrs->{from}[0]) ne 'HASH'
1887       or
1888     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1889   );
1890
1891   my ($cond, $guard);
1892   # do we need anything like a subquery?
1893   if (! $needs_subq) {
1894     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1895     # a condition containing 'me' or other table prefixes will not work
1896     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1897     $cond = do {
1898       my $sqla = $rsrc->storage->sql_maker;
1899       local $sqla->{_dequalify_idents} = 1;
1900       \[ $sqla->_recurse_where($self->{cond}) ];
1901     };
1902   }
1903   else {
1904     # we got this far - means it is time to wrap a subquery
1905     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1906       sprintf(
1907         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1908         $op,
1909         $rsrc->source_name,
1910       )
1911     );
1912
1913     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1914     delete $attrs->{$_} for qw/select as collapse/;
1915     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1916
1917     # this will be consumed by the pruner waaaaay down the stack
1918     $attrs->{_force_prune_multiplying_joins} = 1;
1919
1920     my $subrs = (ref $self)->new($rsrc, $attrs);
1921
1922     if (@$idcols == 1) {
1923       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1924     }
1925     elsif ($storage->_use_multicolumn_in) {
1926       # no syntax for calling this properly yet
1927       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1928       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1929         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1930         $subrs->as_query
1931       ),
1932     }
1933     else {
1934       # if all else fails - get all primary keys and operate over a ORed set
1935       # wrap in a transaction for consistency
1936       # this is where the group_by/multiplication starts to matter
1937       if (
1938         $existing_group_by
1939           or
1940         # we do not need to check pre-multipliers, since if the premulti is there, its
1941         # parent (who is multi) will be there too
1942         keys %{ $join_classifications->{multiplying} || {} }
1943       ) {
1944         # make sure if there is a supplied group_by it matches the columns compiled above
1945         # perfectly. Anything else can not be sanely executed on most databases so croak
1946         # right then and there
1947         if ($existing_group_by) {
1948           my @current_group_by = map
1949             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1950             @$existing_group_by
1951           ;
1952
1953           if (
1954             join ("\x00", sort @current_group_by)
1955               ne
1956             join ("\x00", sort @{$attrs->{columns}} )
1957           ) {
1958             $self->throw_exception (
1959               "You have just attempted a $op operation on a resultset which does group_by"
1960               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1961               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1962               . ' kind of queries. Please retry the operation with a modified group_by or'
1963               . ' without using one at all.'
1964             );
1965           }
1966         }
1967
1968         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1969       }
1970
1971       $guard = $storage->txn_scope_guard;
1972
1973       $cond = [];
1974       for my $row ($subrs->cursor->all) {
1975         push @$cond, { map
1976           { $idcols->[$_] => $row->[$_] }
1977           (0 .. $#$idcols)
1978         };
1979       }
1980     }
1981   }
1982
1983   my $res = $storage->$op (
1984     $rsrc,
1985     $op eq 'update' ? $values : (),
1986     $cond,
1987   );
1988
1989   $guard->commit if $guard;
1990
1991   return $res;
1992 }
1993
1994 =head2 update
1995
1996 =over 4
1997
1998 =item Arguments: \%values
1999
2000 =item Return Value: $underlying_storage_rv
2001
2002 =back
2003
2004 Sets the specified columns in the resultset to the supplied values in a
2005 single query. Note that this will not run any accessor/set_column/update
2006 triggers, nor will it update any result object instances derived from this
2007 resultset (this includes the contents of the L<resultset cache|/set_cache>
2008 if any). See L</update_all> if you need to execute any on-update
2009 triggers or cascades defined either by you or a
2010 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2011
2012 The return value is a pass through of what the underlying
2013 storage backend returned, and may vary. See L<DBI/execute> for the most
2014 common case.
2015
2016 =head3 CAVEAT
2017
2018 Note that L</update> does not process/deflate any of the values passed in.
2019 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2020 ensure manually that any value passed to this method will stringify to
2021 something the RDBMS knows how to deal with. A notable example is the
2022 handling of L<DateTime> objects, for more info see:
2023 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2024
2025 =cut
2026
2027 sub update {
2028   my ($self, $values) = @_;
2029   $self->throw_exception('Values for update must be a hash')
2030     unless ref $values eq 'HASH';
2031
2032   return $self->_rs_update_delete ('update', $values);
2033 }
2034
2035 =head2 update_all
2036
2037 =over 4
2038
2039 =item Arguments: \%values
2040
2041 =item Return Value: 1
2042
2043 =back
2044
2045 Fetches all objects and updates them one at a time via
2046 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2047 triggers, while L</update> will not.
2048
2049 =cut
2050
2051 sub update_all {
2052   my ($self, $values) = @_;
2053   $self->throw_exception('Values for update_all must be a hash')
2054     unless ref $values eq 'HASH';
2055
2056   my $guard = $self->result_source->schema->txn_scope_guard;
2057   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2058   $guard->commit;
2059   return 1;
2060 }
2061
2062 =head2 delete
2063
2064 =over 4
2065
2066 =item Arguments: none
2067
2068 =item Return Value: $underlying_storage_rv
2069
2070 =back
2071
2072 Deletes the rows matching this resultset in a single query. Note that this
2073 will not run any delete triggers, nor will it alter the
2074 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2075 derived from this resultset (this includes the contents of the
2076 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2077 execute any on-delete triggers or cascades defined either by you or a
2078 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2079
2080 The return value is a pass through of what the underlying storage backend
2081 returned, and may vary. See L<DBI/execute> for the most common case.
2082
2083 =cut
2084
2085 sub delete {
2086   my $self = shift;
2087   $self->throw_exception('delete does not accept any arguments')
2088     if @_;
2089
2090   return $self->_rs_update_delete ('delete');
2091 }
2092
2093 =head2 delete_all
2094
2095 =over 4
2096
2097 =item Arguments: none
2098
2099 =item Return Value: 1
2100
2101 =back
2102
2103 Fetches all objects and deletes them one at a time via
2104 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2105 triggers, while L</delete> will not.
2106
2107 =cut
2108
2109 sub delete_all {
2110   my $self = shift;
2111   $self->throw_exception('delete_all does not accept any arguments')
2112     if @_;
2113
2114   my $guard = $self->result_source->schema->txn_scope_guard;
2115   $_->delete for $self->all;
2116   $guard->commit;
2117   return 1;
2118 }
2119
2120 =head2 populate
2121
2122 =over 4
2123
2124 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2125
2126 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2127
2128 =back
2129
2130 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2131 arrayrefs.
2132
2133 =over
2134
2135 =item NOTE
2136
2137 The context of this method call has an important effect on what is
2138 submitted to storage. In void context data is fed directly to fastpath
2139 insertion routines provided by the underlying storage (most often
2140 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2141 L<insert|DBIx::Class::Row/insert> calls on the
2142 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2143 augmentation of these methods provided by components. For example if you
2144 are using something like L<DBIx::Class::UUIDColumns> to create primary
2145 keys for you, you will find that your PKs are empty.  In this case you
2146 will have to explicitly force scalar or list context in order to create
2147 those values.
2148
2149 =back
2150
2151 In non-void (scalar or list) context, this method is simply a wrapper
2152 for L</create>. Depending on list or scalar context either a list of
2153 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2154 containing these objects is returned.
2155
2156 When supplying data in "arrayref of arrayrefs" invocation style, the
2157 first element should be a list of column names and each subsequent
2158 element should be a data value in the earlier specified column order.
2159 For example:
2160
2161   $schema->resultset("Artist")->populate([
2162     [ qw( artistid name ) ],
2163     [ 100, 'A Formally Unknown Singer' ],
2164     [ 101, 'A singer that jumped the shark two albums ago' ],
2165     [ 102, 'An actually cool singer' ],
2166   ]);
2167
2168 For the arrayref of hashrefs style each hashref should be a structure
2169 suitable for passing to L</create>. Multi-create is also permitted with
2170 this syntax.
2171
2172   $schema->resultset("Artist")->populate([
2173      { artistid => 4, name => 'Manufactured Crap', cds => [
2174         { title => 'My First CD', year => 2006 },
2175         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2176       ],
2177      },
2178      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2179         { title => 'My parents sold me to a record company', year => 2005 },
2180         { title => 'Why Am I So Ugly?', year => 2006 },
2181         { title => 'I Got Surgery and am now Popular', year => 2007 }
2182       ],
2183      },
2184   ]);
2185
2186 If you attempt a void-context multi-create as in the example above (each
2187 Artist also has the related list of CDs), and B<do not> supply the
2188 necessary autoinc foreign key information, this method will proxy to the
2189 less efficient L</create>, and then throw the Result objects away. In this
2190 case there are obviously no benefits to using this method over L</create>.
2191
2192 =cut
2193
2194 sub populate {
2195   my $self = shift;
2196
2197   # cruft placed in standalone method
2198   my $data = $self->_normalize_populate_args(@_);
2199
2200   return unless @$data;
2201
2202   if(defined wantarray) {
2203     my @created = map { $self->create($_) } @$data;
2204     return wantarray ? @created : \@created;
2205   }
2206   else {
2207     my $first = $data->[0];
2208
2209     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2210     # it relationship data
2211     my (@rels, @columns);
2212     my $rsrc = $self->result_source;
2213     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2214     for (keys %$first) {
2215       my $ref = ref $first->{$_};
2216       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2217         ? push @rels, $_
2218         : push @columns, $_
2219       ;
2220     }
2221
2222     my @pks = $rsrc->primary_columns;
2223
2224     ## do the belongs_to relationships
2225     foreach my $index (0..$#$data) {
2226
2227       # delegate to create() for any dataset without primary keys with specified relationships
2228       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2229         for my $r (@rels) {
2230           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2231             my @ret = $self->populate($data);
2232             return;
2233           }
2234         }
2235       }
2236
2237       foreach my $rel (@rels) {
2238         next unless ref $data->[$index]->{$rel} eq "HASH";
2239         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2240         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2241         my $related = $result->result_source->_resolve_condition(
2242           $reverse_relinfo->{cond},
2243           $self,
2244           $result,
2245           $rel,
2246         );
2247
2248         delete $data->[$index]->{$rel};
2249         $data->[$index] = {%{$data->[$index]}, %$related};
2250
2251         push @columns, keys %$related if $index == 0;
2252       }
2253     }
2254
2255     ## inherit the data locked in the conditions of the resultset
2256     my ($rs_data) = $self->_merge_with_rscond({});
2257     delete @{$rs_data}{@columns};
2258
2259     ## do bulk insert on current row
2260     $rsrc->storage->insert_bulk(
2261       $rsrc,
2262       [@columns, keys %$rs_data],
2263       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2264     );
2265
2266     ## do the has_many relationships
2267     foreach my $item (@$data) {
2268
2269       my $main_row;
2270
2271       foreach my $rel (@rels) {
2272         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2273
2274         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2275
2276         my $child = $main_row->$rel;
2277
2278         my $related = $child->result_source->_resolve_condition(
2279           $rels->{$rel}{cond},
2280           $child,
2281           $main_row,
2282           $rel,
2283         );
2284
2285         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2286         my @populate = map { {%$_, %$related} } @rows_to_add;
2287
2288         $child->populate( \@populate );
2289       }
2290     }
2291   }
2292 }
2293
2294
2295 # populate() arguments went over several incarnations
2296 # What we ultimately support is AoH
2297 sub _normalize_populate_args {
2298   my ($self, $arg) = @_;
2299
2300   if (ref $arg eq 'ARRAY') {
2301     if (!@$arg) {
2302       return [];
2303     }
2304     elsif (ref $arg->[0] eq 'HASH') {
2305       return $arg;
2306     }
2307     elsif (ref $arg->[0] eq 'ARRAY') {
2308       my @ret;
2309       my @colnames = @{$arg->[0]};
2310       foreach my $values (@{$arg}[1 .. $#$arg]) {
2311         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2312       }
2313       return \@ret;
2314     }
2315   }
2316
2317   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2318 }
2319
2320 =head2 pager
2321
2322 =over 4
2323
2324 =item Arguments: none
2325
2326 =item Return Value: L<$pager|Data::Page>
2327
2328 =back
2329
2330 Returns a L<Data::Page> object for the current resultset. Only makes
2331 sense for queries with a C<page> attribute.
2332
2333 To get the full count of entries for a paged resultset, call
2334 C<total_entries> on the L<Data::Page> object.
2335
2336 =cut
2337
2338 sub pager {
2339   my ($self) = @_;
2340
2341   return $self->{pager} if $self->{pager};
2342
2343   my $attrs = $self->{attrs};
2344   if (!defined $attrs->{page}) {
2345     $self->throw_exception("Can't create pager for non-paged rs");
2346   }
2347   elsif ($attrs->{page} <= 0) {
2348     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2349   }
2350   $attrs->{rows} ||= 10;
2351
2352   # throw away the paging flags and re-run the count (possibly
2353   # with a subselect) to get the real total count
2354   my $count_attrs = { %$attrs };
2355   delete @{$count_attrs}{qw/rows offset page pager/};
2356
2357   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2358
2359   require DBIx::Class::ResultSet::Pager;
2360   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2361     sub { $total_rs->count },  #lazy-get the total
2362     $attrs->{rows},
2363     $self->{attrs}{page},
2364   );
2365 }
2366
2367 =head2 page
2368
2369 =over 4
2370
2371 =item Arguments: $page_number
2372
2373 =item Return Value: L<$resultset|/search>
2374
2375 =back
2376
2377 Returns a resultset for the $page_number page of the resultset on which page
2378 is called, where each page contains a number of rows equal to the 'rows'
2379 attribute set on the resultset (10 by default).
2380
2381 =cut
2382
2383 sub page {
2384   my ($self, $page) = @_;
2385   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2386 }
2387
2388 =head2 new_result
2389
2390 =over 4
2391
2392 =item Arguments: \%col_data
2393
2394 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2395
2396 =back
2397
2398 Creates a new result object in the resultset's result class and returns
2399 it. The row is not inserted into the database at this point, call
2400 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2401 will tell you whether the result object has been inserted or not.
2402
2403 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2404
2405 =cut
2406
2407 sub new_result {
2408   my ($self, $values) = @_;
2409
2410   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2411     if @_ > 2;
2412
2413   $self->throw_exception( "new_result expects a hashref" )
2414     unless (ref $values eq 'HASH');
2415
2416   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2417
2418   my $new = $self->result_class->new({
2419     %$merged_cond,
2420     ( @$cols_from_relations
2421       ? (-cols_from_relations => $cols_from_relations)
2422       : ()
2423     ),
2424     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2425   });
2426
2427   if (
2428     reftype($new) eq 'HASH'
2429       and
2430     ! keys %$new
2431       and
2432     blessed($new)
2433   ) {
2434     carp_unique (sprintf (
2435       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2436       $self->result_class,
2437     ));
2438   }
2439
2440   $new;
2441 }
2442
2443 # _merge_with_rscond
2444 #
2445 # Takes a simple hash of K/V data and returns its copy merged with the
2446 # condition already present on the resultset. Additionally returns an
2447 # arrayref of value/condition names, which were inferred from related
2448 # objects (this is needed for in-memory related objects)
2449 sub _merge_with_rscond {
2450   my ($self, $data) = @_;
2451
2452   my (%new_data, @cols_from_relations);
2453
2454   my $alias = $self->{attrs}{alias};
2455
2456   if (! defined $self->{cond}) {
2457     # just massage $data below
2458   }
2459   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
2460     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2461     @cols_from_relations = keys %new_data;
2462   }
2463   elsif (ref $self->{cond} ne 'HASH') {
2464     $self->throw_exception(
2465       "Can't abstract implicit construct, resultset condition not a hash"
2466     );
2467   }
2468   else {
2469     # precedence must be given to passed values over values inherited from
2470     # the cond, so the order here is important.
2471     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2472     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2473
2474     while ( my($col, $value) = each %implied ) {
2475       my $vref = ref $value;
2476       if (
2477         $vref eq 'HASH'
2478           and
2479         keys(%$value) == 1
2480           and
2481         (keys %$value)[0] eq '='
2482       ) {
2483         $new_data{$col} = $value->{'='};
2484       }
2485       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2486         $new_data{$col} = $value;
2487       }
2488     }
2489   }
2490
2491   %new_data = (
2492     %new_data,
2493     %{ $self->_remove_alias($data, $alias) },
2494   );
2495
2496   return (\%new_data, \@cols_from_relations);
2497 }
2498
2499 # _has_resolved_attr
2500 #
2501 # determines if the resultset defines at least one
2502 # of the attributes supplied
2503 #
2504 # used to determine if a subquery is necessary
2505 #
2506 # supports some virtual attributes:
2507 #   -join
2508 #     This will scan for any joins being present on the resultset.
2509 #     It is not a mere key-search but a deep inspection of {from}
2510 #
2511
2512 sub _has_resolved_attr {
2513   my ($self, @attr_names) = @_;
2514
2515   my $attrs = $self->_resolved_attrs;
2516
2517   my %extra_checks;
2518
2519   for my $n (@attr_names) {
2520     if (grep { $n eq $_ } (qw/-join/) ) {
2521       $extra_checks{$n}++;
2522       next;
2523     }
2524
2525     my $attr =  $attrs->{$n};
2526
2527     next if not defined $attr;
2528
2529     if (ref $attr eq 'HASH') {
2530       return 1 if keys %$attr;
2531     }
2532     elsif (ref $attr eq 'ARRAY') {
2533       return 1 if @$attr;
2534     }
2535     else {
2536       return 1 if $attr;
2537     }
2538   }
2539
2540   # a resolved join is expressed as a multi-level from
2541   return 1 if (
2542     $extra_checks{-join}
2543       and
2544     ref $attrs->{from} eq 'ARRAY'
2545       and
2546     @{$attrs->{from}} > 1
2547   );
2548
2549   return 0;
2550 }
2551
2552 # _collapse_cond
2553 #
2554 # Recursively collapse the condition.
2555
2556 sub _collapse_cond {
2557   my ($self, $cond, $collapsed) = @_;
2558
2559   $collapsed ||= {};
2560
2561   if (ref $cond eq 'ARRAY') {
2562     foreach my $subcond (@$cond) {
2563       next unless ref $subcond;  # -or
2564       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2565     }
2566   }
2567   elsif (ref $cond eq 'HASH') {
2568     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2569       foreach my $subcond (@{$cond->{-and}}) {
2570         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2571       }
2572     }
2573     else {
2574       foreach my $col (keys %$cond) {
2575         my $value = $cond->{$col};
2576         $collapsed->{$col} = $value;
2577       }
2578     }
2579   }
2580
2581   return $collapsed;
2582 }
2583
2584 # _remove_alias
2585 #
2586 # Remove the specified alias from the specified query hash. A copy is made so
2587 # the original query is not modified.
2588
2589 sub _remove_alias {
2590   my ($self, $query, $alias) = @_;
2591
2592   my %orig = %{ $query || {} };
2593   my %unaliased;
2594
2595   foreach my $key (keys %orig) {
2596     if ($key !~ /\./) {
2597       $unaliased{$key} = $orig{$key};
2598       next;
2599     }
2600     $unaliased{$1} = $orig{$key}
2601       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2602   }
2603
2604   return \%unaliased;
2605 }
2606
2607 =head2 as_query
2608
2609 =over 4
2610
2611 =item Arguments: none
2612
2613 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2614
2615 =back
2616
2617 Returns the SQL query and bind vars associated with the invocant.
2618
2619 This is generally used as the RHS for a subquery.
2620
2621 =cut
2622
2623 sub as_query {
2624   my $self = shift;
2625
2626   my $attrs = { %{ $self->_resolved_attrs } };
2627
2628   my $aq = $self->result_source->storage->_select_args_to_query (
2629     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2630   );
2631
2632   $aq;
2633 }
2634
2635 =head2 find_or_new
2636
2637 =over 4
2638
2639 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2640
2641 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2642
2643 =back
2644
2645   my $artist = $schema->resultset('Artist')->find_or_new(
2646     { artist => 'fred' }, { key => 'artists' });
2647
2648   $cd->cd_to_producer->find_or_new({ producer => $producer },
2649                                    { key => 'primary' });
2650
2651 Find an existing record from this resultset using L</find>. if none exists,
2652 instantiate a new result object and return it. The object will not be saved
2653 into your storage until you call L<DBIx::Class::Row/insert> on it.
2654
2655 You most likely want this method when looking for existing rows using a unique
2656 constraint that is not the primary key, or looking for related rows.
2657
2658 If you want objects to be saved immediately, use L</find_or_create> instead.
2659
2660 B<Note>: Make sure to read the documentation of L</find> and understand the
2661 significance of the C<key> attribute, as its lack may skew your search, and
2662 subsequently result in spurious new objects.
2663
2664 B<Note>: Take care when using C<find_or_new> with a table having
2665 columns with default values that you intend to be automatically
2666 supplied by the database (e.g. an auto_increment primary key column).
2667 In normal usage, the value of such columns should NOT be included at
2668 all in the call to C<find_or_new>, even when set to C<undef>.
2669
2670 =cut
2671
2672 sub find_or_new {
2673   my $self     = shift;
2674   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2675   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2676   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2677     return $row;
2678   }
2679   return $self->new_result($hash);
2680 }
2681
2682 =head2 create
2683
2684 =over 4
2685
2686 =item Arguments: \%col_data
2687
2688 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2689
2690 =back
2691
2692 Attempt to create a single new row or a row with multiple related rows
2693 in the table represented by the resultset (and related tables). This
2694 will not check for duplicate rows before inserting, use
2695 L</find_or_create> to do that.
2696
2697 To create one row for this resultset, pass a hashref of key/value
2698 pairs representing the columns of the table and the values you wish to
2699 store. If the appropriate relationships are set up, foreign key fields
2700 can also be passed an object representing the foreign row, and the
2701 value will be set to its primary key.
2702
2703 To create related objects, pass a hashref of related-object column values
2704 B<keyed on the relationship name>. If the relationship is of type C<multi>
2705 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2706 The process will correctly identify columns holding foreign keys, and will
2707 transparently populate them from the keys of the corresponding relation.
2708 This can be applied recursively, and will work correctly for a structure
2709 with an arbitrary depth and width, as long as the relationships actually
2710 exists and the correct column data has been supplied.
2711
2712 Instead of hashrefs of plain related data (key/value pairs), you may
2713 also pass new or inserted objects. New objects (not inserted yet, see
2714 L</new_result>), will be inserted into their appropriate tables.
2715
2716 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2717
2718 Example of creating a new row.
2719
2720   $person_rs->create({
2721     name=>"Some Person",
2722     email=>"somebody@someplace.com"
2723   });
2724
2725 Example of creating a new row and also creating rows in a related C<has_many>
2726 or C<has_one> resultset.  Note Arrayref.
2727
2728   $artist_rs->create(
2729      { artistid => 4, name => 'Manufactured Crap', cds => [
2730         { title => 'My First CD', year => 2006 },
2731         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2732       ],
2733      },
2734   );
2735
2736 Example of creating a new row and also creating a row in a related
2737 C<belongs_to> resultset. Note Hashref.
2738
2739   $cd_rs->create({
2740     title=>"Music for Silly Walks",
2741     year=>2000,
2742     artist => {
2743       name=>"Silly Musician",
2744     }
2745   });
2746
2747 =over
2748
2749 =item WARNING
2750
2751 When subclassing ResultSet never attempt to override this method. Since
2752 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2753 lot of the internals simply never call it, so your override will be
2754 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2755 or L<DBIx::Class::Row/insert> depending on how early in the
2756 L</create> process you need to intervene. See also warning pertaining to
2757 L</new>.
2758
2759 =back
2760
2761 =cut
2762
2763 sub create {
2764   my ($self, $col_data) = @_;
2765   $self->throw_exception( "create needs a hashref" )
2766     unless ref $col_data eq 'HASH';
2767   return $self->new_result($col_data)->insert;
2768 }
2769
2770 =head2 find_or_create
2771
2772 =over 4
2773
2774 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2775
2776 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2777
2778 =back
2779
2780   $cd->cd_to_producer->find_or_create({ producer => $producer },
2781                                       { key => 'primary' });
2782
2783 Tries to find a record based on its primary key or unique constraints; if none
2784 is found, creates one and returns that instead.
2785
2786   my $cd = $schema->resultset('CD')->find_or_create({
2787     cdid   => 5,
2788     artist => 'Massive Attack',
2789     title  => 'Mezzanine',
2790     year   => 2005,
2791   });
2792
2793 Also takes an optional C<key> attribute, to search by a specific key or unique
2794 constraint. For example:
2795
2796   my $cd = $schema->resultset('CD')->find_or_create(
2797     {
2798       artist => 'Massive Attack',
2799       title  => 'Mezzanine',
2800     },
2801     { key => 'cd_artist_title' }
2802   );
2803
2804 B<Note>: Make sure to read the documentation of L</find> and understand the
2805 significance of the C<key> attribute, as its lack may skew your search, and
2806 subsequently result in spurious row creation.
2807
2808 B<Note>: Because find_or_create() reads from the database and then
2809 possibly inserts based on the result, this method is subject to a race
2810 condition. Another process could create a record in the table after
2811 the find has completed and before the create has started. To avoid
2812 this problem, use find_or_create() inside a transaction.
2813
2814 B<Note>: Take care when using C<find_or_create> with a table having
2815 columns with default values that you intend to be automatically
2816 supplied by the database (e.g. an auto_increment primary key column).
2817 In normal usage, the value of such columns should NOT be included at
2818 all in the call to C<find_or_create>, even when set to C<undef>.
2819
2820 See also L</find> and L</update_or_create>. For information on how to declare
2821 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2822
2823 If you need to know if an existing row was found or a new one created use
2824 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2825 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2826 database!
2827
2828   my $cd = $schema->resultset('CD')->find_or_new({
2829     cdid   => 5,
2830     artist => 'Massive Attack',
2831     title  => 'Mezzanine',
2832     year   => 2005,
2833   });
2834
2835   if( !$cd->in_storage ) {
2836       # do some stuff
2837       $cd->insert;
2838   }
2839
2840 =cut
2841
2842 sub find_or_create {
2843   my $self     = shift;
2844   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2845   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2846   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2847     return $row;
2848   }
2849   return $self->create($hash);
2850 }
2851
2852 =head2 update_or_create
2853
2854 =over 4
2855
2856 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2857
2858 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2859
2860 =back
2861
2862   $resultset->update_or_create({ col => $val, ... });
2863
2864 Like L</find_or_create>, but if a row is found it is immediately updated via
2865 C<< $found_row->update (\%col_data) >>.
2866
2867
2868 Takes an optional C<key> attribute to search on a specific unique constraint.
2869 For example:
2870
2871   # In your application
2872   my $cd = $schema->resultset('CD')->update_or_create(
2873     {
2874       artist => 'Massive Attack',
2875       title  => 'Mezzanine',
2876       year   => 1998,
2877     },
2878     { key => 'cd_artist_title' }
2879   );
2880
2881   $cd->cd_to_producer->update_or_create({
2882     producer => $producer,
2883     name => 'harry',
2884   }, {
2885     key => 'primary',
2886   });
2887
2888 B<Note>: Make sure to read the documentation of L</find> and understand the
2889 significance of the C<key> attribute, as its lack may skew your search, and
2890 subsequently result in spurious row creation.
2891
2892 B<Note>: Take care when using C<update_or_create> with a table having
2893 columns with default values that you intend to be automatically
2894 supplied by the database (e.g. an auto_increment primary key column).
2895 In normal usage, the value of such columns should NOT be included at
2896 all in the call to C<update_or_create>, even when set to C<undef>.
2897
2898 See also L</find> and L</find_or_create>. For information on how to declare
2899 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2900
2901 If you need to know if an existing row was updated or a new one created use
2902 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2903 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2904 database!
2905
2906 =cut
2907
2908 sub update_or_create {
2909   my $self = shift;
2910   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2911   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2912
2913   my $row = $self->find($cond, $attrs);
2914   if (defined $row) {
2915     $row->update($cond);
2916     return $row;
2917   }
2918
2919   return $self->create($cond);
2920 }
2921
2922 =head2 update_or_new
2923
2924 =over 4
2925
2926 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2927
2928 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2929
2930 =back
2931
2932   $resultset->update_or_new({ col => $val, ... });
2933
2934 Like L</find_or_new> but if a row is found it is immediately updated via
2935 C<< $found_row->update (\%col_data) >>.
2936
2937 For example:
2938
2939   # In your application
2940   my $cd = $schema->resultset('CD')->update_or_new(
2941     {
2942       artist => 'Massive Attack',
2943       title  => 'Mezzanine',
2944       year   => 1998,
2945     },
2946     { key => 'cd_artist_title' }
2947   );
2948
2949   if ($cd->in_storage) {
2950       # the cd was updated
2951   }
2952   else {
2953       # the cd is not yet in the database, let's insert it
2954       $cd->insert;
2955   }
2956
2957 B<Note>: Make sure to read the documentation of L</find> and understand the
2958 significance of the C<key> attribute, as its lack may skew your search, and
2959 subsequently result in spurious new objects.
2960
2961 B<Note>: Take care when using C<update_or_new> with a table having
2962 columns with default values that you intend to be automatically
2963 supplied by the database (e.g. an auto_increment primary key column).
2964 In normal usage, the value of such columns should NOT be included at
2965 all in the call to C<update_or_new>, even when set to C<undef>.
2966
2967 See also L</find>, L</find_or_create> and L</find_or_new>.
2968
2969 =cut
2970
2971 sub update_or_new {
2972     my $self  = shift;
2973     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2974     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2975
2976     my $row = $self->find( $cond, $attrs );
2977     if ( defined $row ) {
2978         $row->update($cond);
2979         return $row;
2980     }
2981
2982     return $self->new_result($cond);
2983 }
2984
2985 =head2 get_cache
2986
2987 =over 4
2988
2989 =item Arguments: none
2990
2991 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
2992
2993 =back
2994
2995 Gets the contents of the cache for the resultset, if the cache is set.
2996
2997 The cache is populated either by using the L</prefetch> attribute to
2998 L</search> or by calling L</set_cache>.
2999
3000 =cut
3001
3002 sub get_cache {
3003   shift->{all_cache};
3004 }
3005
3006 =head2 set_cache
3007
3008 =over 4
3009
3010 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3011
3012 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3013
3014 =back
3015
3016 Sets the contents of the cache for the resultset. Expects an arrayref
3017 of objects of the same class as those produced by the resultset. Note that
3018 if the cache is set, the resultset will return the cached objects rather
3019 than re-querying the database even if the cache attr is not set.
3020
3021 The contents of the cache can also be populated by using the
3022 L</prefetch> attribute to L</search>.
3023
3024 =cut
3025
3026 sub set_cache {
3027   my ( $self, $data ) = @_;
3028   $self->throw_exception("set_cache requires an arrayref")
3029       if defined($data) && (ref $data ne 'ARRAY');
3030   $self->{all_cache} = $data;
3031 }
3032
3033 =head2 clear_cache
3034
3035 =over 4
3036
3037 =item Arguments: none
3038
3039 =item Return Value: undef
3040
3041 =back
3042
3043 Clears the cache for the resultset.
3044
3045 =cut
3046
3047 sub clear_cache {
3048   shift->set_cache(undef);
3049 }
3050
3051 =head2 is_paged
3052
3053 =over 4
3054
3055 =item Arguments: none
3056
3057 =item Return Value: true, if the resultset has been paginated
3058
3059 =back
3060
3061 =cut
3062
3063 sub is_paged {
3064   my ($self) = @_;
3065   return !!$self->{attrs}{page};
3066 }
3067
3068 =head2 is_ordered
3069
3070 =over 4
3071
3072 =item Arguments: none
3073
3074 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3075
3076 =back
3077
3078 =cut
3079
3080 sub is_ordered {
3081   my ($self) = @_;
3082   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3083 }
3084
3085 =head2 related_resultset
3086
3087 =over 4
3088
3089 =item Arguments: $rel_name
3090
3091 =item Return Value: L<$resultset|/search>
3092
3093 =back
3094
3095 Returns a related resultset for the supplied relationship name.
3096
3097   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3098
3099 =cut
3100
3101 sub related_resultset {
3102   my ($self, $rel) = @_;
3103
3104   return $self->{related_resultsets}{$rel}
3105     if defined $self->{related_resultsets}{$rel};
3106
3107   return $self->{related_resultsets}{$rel} = do {
3108     my $rsrc = $self->result_source;
3109     my $rel_info = $rsrc->relationship_info($rel);
3110
3111     $self->throw_exception(
3112       "search_related: result source '" . $rsrc->source_name .
3113         "' has no such relationship $rel")
3114       unless $rel_info;
3115
3116     my $attrs = $self->_chain_relationship($rel);
3117
3118     my $join_count = $attrs->{seen_join}{$rel};
3119
3120     my $alias = $self->result_source->storage
3121         ->relname_to_table_alias($rel, $join_count);
3122
3123     # since this is search_related, and we already slid the select window inwards
3124     # (the select/as attrs were deleted in the beginning), we need to flip all
3125     # left joins to inner, so we get the expected results
3126     # read the comment on top of the actual function to see what this does
3127     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3128
3129
3130     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3131     delete @{$attrs}{qw(result_class alias)};
3132
3133     my $rel_source = $rsrc->related_source($rel);
3134
3135     my $new = do {
3136
3137       # The reason we do this now instead of passing the alias to the
3138       # search_rs below is that if you wrap/overload resultset on the
3139       # source you need to know what alias it's -going- to have for things
3140       # to work sanely (e.g. RestrictWithObject wants to be able to add
3141       # extra query restrictions, and these may need to be $alias.)
3142
3143       my $rel_attrs = $rel_source->resultset_attributes;
3144       local $rel_attrs->{alias} = $alias;
3145
3146       $rel_source->resultset
3147                  ->search_rs(
3148                      undef, {
3149                        %$attrs,
3150                        where => $attrs->{where},
3151                    });
3152     };
3153
3154     if (my $cache = $self->get_cache) {
3155       my @related_cache = map
3156         { @{$_->related_resultset($rel)->get_cache||[]} }
3157         @$cache
3158       ;
3159
3160       $new->set_cache(\@related_cache) if @related_cache;
3161     }
3162
3163     $new;
3164   };
3165 }
3166
3167 =head2 current_source_alias
3168
3169 =over 4
3170
3171 =item Arguments: none
3172
3173 =item Return Value: $source_alias
3174
3175 =back
3176
3177 Returns the current table alias for the result source this resultset is built
3178 on, that will be used in the SQL query. Usually it is C<me>.
3179
3180 Currently the source alias that refers to the result set returned by a
3181 L</search>/L</find> family method depends on how you got to the resultset: it's
3182 C<me> by default, but eg. L</search_related> aliases it to the related result
3183 source name (and keeps C<me> referring to the original result set). The long
3184 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3185 (and make this method unnecessary).
3186
3187 Thus it's currently necessary to use this method in predefined queries (see
3188 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3189 source alias of the current result set:
3190
3191   # in a result set class
3192   sub modified_by {
3193     my ($self, $user) = @_;
3194
3195     my $me = $self->current_source_alias;
3196
3197     return $self->search({
3198       "$me.modified" => $user->id,
3199     });
3200   }
3201
3202 =cut
3203
3204 sub current_source_alias {
3205   return (shift->{attrs} || {})->{alias} || 'me';
3206 }
3207
3208 =head2 as_subselect_rs
3209
3210 =over 4
3211
3212 =item Arguments: none
3213
3214 =item Return Value: L<$resultset|/search>
3215
3216 =back
3217
3218 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3219 "virtual view" by including it as a subquery within the from clause.  From this
3220 point on, any joined tables are inaccessible to ->search on the resultset (as if
3221 it were simply where-filtered without joins).  For example:
3222
3223  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3224
3225  # 'x' now pollutes the query namespace
3226
3227  # So the following works as expected
3228  my $ok_rs = $rs->search({'x.other' => 1});
3229
3230  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3231  # def) we look for one row with contradictory terms and join in another table
3232  # (aliased 'x_2') which we never use
3233  my $broken_rs = $rs->search({'x.name' => 'def'});
3234
3235  my $rs2 = $rs->as_subselect_rs;
3236
3237  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3238  my $not_joined_rs = $rs2->search({'x.other' => 1});
3239
3240  # works as expected: finds a 'table' row related to two x rows (abc and def)
3241  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3242
3243 Another example of when one might use this would be to select a subset of
3244 columns in a group by clause:
3245
3246  my $rs = $schema->resultset('Bar')->search(undef, {
3247    group_by => [qw{ id foo_id baz_id }],
3248  })->as_subselect_rs->search(undef, {
3249    columns => [qw{ id foo_id }]
3250  });
3251
3252 In the above example normally columns would have to be equal to the group by,
3253 but because we isolated the group by into a subselect the above works.
3254
3255 =cut
3256
3257 sub as_subselect_rs {
3258   my $self = shift;
3259
3260   my $attrs = $self->_resolved_attrs;
3261
3262   my $fresh_rs = (ref $self)->new (
3263     $self->result_source
3264   );
3265
3266   # these pieces will be locked in the subquery
3267   delete $fresh_rs->{cond};
3268   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3269
3270   return $fresh_rs->search( {}, {
3271     from => [{
3272       $attrs->{alias} => $self->as_query,
3273       -alias  => $attrs->{alias},
3274       -rsrc   => $self->result_source,
3275     }],
3276     alias => $attrs->{alias},
3277   });
3278 }
3279
3280 # This code is called by search_related, and makes sure there
3281 # is clear separation between the joins before, during, and
3282 # after the relationship. This information is needed later
3283 # in order to properly resolve prefetch aliases (any alias
3284 # with a relation_chain_depth less than the depth of the
3285 # current prefetch is not considered)
3286 #
3287 # The increments happen twice per join. An even number means a
3288 # relationship specified via a search_related, whereas an odd
3289 # number indicates a join/prefetch added via attributes
3290 #
3291 # Also this code will wrap the current resultset (the one we
3292 # chain to) in a subselect IFF it contains limiting attributes
3293 sub _chain_relationship {
3294   my ($self, $rel) = @_;
3295   my $source = $self->result_source;
3296   my $attrs = { %{$self->{attrs}||{}} };
3297
3298   # we need to take the prefetch the attrs into account before we
3299   # ->_resolve_join as otherwise they get lost - captainL
3300   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3301
3302   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3303
3304   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3305
3306   my $from;
3307   my @force_subq_attrs = qw/offset rows group_by having/;
3308
3309   if (
3310     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3311       ||
3312     $self->_has_resolved_attr (@force_subq_attrs)
3313   ) {
3314     # Nuke the prefetch (if any) before the new $rs attrs
3315     # are resolved (prefetch is useless - we are wrapping
3316     # a subquery anyway).
3317     my $rs_copy = $self->search;
3318     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3319       $rs_copy->{attrs}{join},
3320       delete $rs_copy->{attrs}{prefetch},
3321     );
3322
3323     $from = [{
3324       -rsrc   => $source,
3325       -alias  => $attrs->{alias},
3326       $attrs->{alias} => $rs_copy->as_query,
3327     }];
3328     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3329     $seen->{-relation_chain_depth} = 0;
3330   }
3331   elsif ($attrs->{from}) {  #shallow copy suffices
3332     $from = [ @{$attrs->{from}} ];
3333   }
3334   else {
3335     $from = [{
3336       -rsrc  => $source,
3337       -alias => $attrs->{alias},
3338       $attrs->{alias} => $source->from,
3339     }];
3340   }
3341
3342   my $jpath = ($seen->{-relation_chain_depth})
3343     ? $from->[-1][0]{-join_path}
3344     : [];
3345
3346   my @requested_joins = $source->_resolve_join(
3347     $join,
3348     $attrs->{alias},
3349     $seen,
3350     $jpath,
3351   );
3352
3353   push @$from, @requested_joins;
3354
3355   $seen->{-relation_chain_depth}++;
3356
3357   # if $self already had a join/prefetch specified on it, the requested
3358   # $rel might very well be already included. What we do in this case
3359   # is effectively a no-op (except that we bump up the chain_depth on
3360   # the join in question so we could tell it *is* the search_related)
3361   my $already_joined;
3362
3363   # we consider the last one thus reverse
3364   for my $j (reverse @requested_joins) {
3365     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3366     if ($rel eq $last_j) {
3367       $j->[0]{-relation_chain_depth}++;
3368       $already_joined++;
3369       last;
3370     }
3371   }
3372
3373   unless ($already_joined) {
3374     push @$from, $source->_resolve_join(
3375       $rel,
3376       $attrs->{alias},
3377       $seen,
3378       $jpath,
3379     );
3380   }
3381
3382   $seen->{-relation_chain_depth}++;
3383
3384   return {%$attrs, from => $from, seen_join => $seen};
3385 }
3386
3387 sub _resolved_attrs {
3388   my $self = shift;
3389   return $self->{_attrs} if $self->{_attrs};
3390
3391   my $attrs  = { %{ $self->{attrs} || {} } };
3392   my $source = $self->result_source;
3393   my $alias  = $attrs->{alias};
3394
3395   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3396     if $attrs->{collapse} and $attrs->{distinct};
3397
3398   # default selection list
3399   $attrs->{columns} = [ $source->columns ]
3400     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3401
3402   # merge selectors together
3403   for (qw/columns select as/) {
3404     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3405       if $attrs->{$_} or $attrs->{"+$_"};
3406   }
3407
3408   # disassemble columns
3409   my (@sel, @as);
3410   if (my $cols = delete $attrs->{columns}) {
3411     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3412       if (ref $c eq 'HASH') {
3413         for my $as (sort keys %$c) {
3414           push @sel, $c->{$as};
3415           push @as, $as;
3416         }
3417       }
3418       else {
3419         push @sel, $c;
3420         push @as, $c;
3421       }
3422     }
3423   }
3424
3425   # when trying to weed off duplicates later do not go past this point -
3426   # everything added from here on is unbalanced "anyone's guess" stuff
3427   my $dedup_stop_idx = $#as;
3428
3429   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3430     if $attrs->{as};
3431   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3432     if $attrs->{select};
3433
3434   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3435   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3436
3437   # disqualify all $alias.col as-bits (inflate-map mandated)
3438   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3439
3440   # de-duplicate the result (remove *identical* select/as pairs)
3441   # and also die on duplicate {as} pointing to different {select}s
3442   # not using a c-style for as the condition is prone to shrinkage
3443   my $seen;
3444   my $i = 0;
3445   while ($i <= $dedup_stop_idx) {
3446     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3447       splice @sel, $i, 1;
3448       splice @as, $i, 1;
3449       $dedup_stop_idx--;
3450     }
3451     elsif ($seen->{$as[$i]}++) {
3452       $self->throw_exception(
3453         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3454       );
3455     }
3456     else {
3457       $i++;
3458     }
3459   }
3460
3461   $attrs->{select} = \@sel;
3462   $attrs->{as} = \@as;
3463
3464   $attrs->{from} ||= [{
3465     -rsrc   => $source,
3466     -alias  => $self->{attrs}{alias},
3467     $self->{attrs}{alias} => $source->from,
3468   }];
3469
3470   if ( $attrs->{join} || $attrs->{prefetch} ) {
3471
3472     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3473       if ref $attrs->{from} ne 'ARRAY';
3474
3475     my $join = (delete $attrs->{join}) || {};
3476
3477     if ( defined $attrs->{prefetch} ) {
3478       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3479     }
3480
3481     $attrs->{from} =    # have to copy here to avoid corrupting the original
3482       [
3483         @{ $attrs->{from} },
3484         $source->_resolve_join(
3485           $join,
3486           $alias,
3487           { %{ $attrs->{seen_join} || {} } },
3488           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3489             ? $attrs->{from}[-1][0]{-join_path}
3490             : []
3491           ,
3492         )
3493       ];
3494   }
3495
3496   if ( defined $attrs->{order_by} ) {
3497     $attrs->{order_by} = (
3498       ref( $attrs->{order_by} ) eq 'ARRAY'
3499       ? [ @{ $attrs->{order_by} } ]
3500       : [ $attrs->{order_by} || () ]
3501     );
3502   }
3503
3504   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3505     $attrs->{group_by} = [ $attrs->{group_by} ];
3506   }
3507
3508
3509   # generate selections based on the prefetch helper
3510   my ($prefetch, @prefetch_select, @prefetch_as);
3511   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3512     if defined $attrs->{prefetch};
3513
3514   if ($prefetch) {
3515
3516     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3517       if $attrs->{_dark_selector};
3518
3519     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3520       if defined $attrs->{collapse} and ! $attrs->{collapse};
3521
3522     $attrs->{collapse} = 1;
3523
3524     # this is a separate structure (we don't look in {from} directly)
3525     # as the resolver needs to shift things off the lists to work
3526     # properly (identical-prefetches on different branches)
3527     my $join_map = {};
3528     if (ref $attrs->{from} eq 'ARRAY') {
3529
3530       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3531
3532       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3533         next unless $j->[0]{-alias};
3534         next unless $j->[0]{-join_path};
3535         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3536
3537         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3538
3539         my $p = $join_map;
3540         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3541         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3542       }
3543     }
3544
3545     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3546
3547     # save these for after distinct resolution
3548     @prefetch_select = map { $_->[0] } @prefetch;
3549     @prefetch_as = map { $_->[1] } @prefetch;
3550   }
3551
3552   # run through the resulting joinstructure (starting from our current slot)
3553   # and unset collapse if proven unnecessary
3554   #
3555   # also while we are at it find out if the current root source has
3556   # been premultiplied by previous related_source chaining
3557   #
3558   # this allows to predict whether a root object with all other relation
3559   # data set to NULL is in fact unique
3560   if ($attrs->{collapse}) {
3561
3562     if (ref $attrs->{from} eq 'ARRAY') {
3563
3564       if (@{$attrs->{from}} == 1) {
3565         # no joins - no collapse
3566         $attrs->{collapse} = 0;
3567       }
3568       else {
3569         # find where our table-spec starts
3570         my @fromlist = @{$attrs->{from}};
3571         while (@fromlist) {
3572           my $t = shift @fromlist;
3573
3574           my $is_multi;
3575           # me vs join from-spec distinction - a ref means non-root
3576           if (ref $t eq 'ARRAY') {
3577             $t = $t->[0];
3578             $is_multi ||= ! $t->{-is_single};
3579           }
3580           last if ($t->{-alias} && $t->{-alias} eq $alias);
3581           $attrs->{_main_source_premultiplied} ||= $is_multi;
3582         }
3583
3584         # no non-singles remaining, nor any premultiplication - nothing to collapse
3585         if (
3586           ! $attrs->{_main_source_premultiplied}
3587             and
3588           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3589         ) {
3590           $attrs->{collapse} = 0;
3591         }
3592       }
3593     }
3594
3595     else {
3596       # if we can not analyze the from - err on the side of safety
3597       $attrs->{_main_source_premultiplied} = 1;
3598     }
3599   }
3600
3601   # generate the distinct induced group_by before injecting the prefetched select/as parts
3602   if (delete $attrs->{distinct}) {
3603     if ($attrs->{group_by}) {
3604       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3605     }
3606     else {
3607       $attrs->{_grouped_by_distinct} = 1;
3608       # distinct affects only the main selection part, not what prefetch may add below
3609       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3610
3611       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3612       # The thinking is: if we are collapsing the subquerying prefetch engine will
3613       # rip stuff apart for us anyway, and we do not want to have a potentially
3614       # function-converted external order_by
3615       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3616       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3617     }
3618   }
3619
3620   # inject prefetch-bound selection (if any)
3621   push @{$attrs->{select}}, @prefetch_select;
3622   push @{$attrs->{as}}, @prefetch_as;
3623
3624   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3625   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3626     $attrs->{_related_results_construction} = 1;
3627   }
3628
3629   # if both page and offset are specified, produce a combined offset
3630   # even though it doesn't make much sense, this is what pre 081xx has
3631   # been doing
3632   if (my $page = delete $attrs->{page}) {
3633     $attrs->{offset} =
3634       ($attrs->{rows} * ($page - 1))
3635             +
3636       ($attrs->{offset} || 0)
3637     ;
3638   }
3639
3640   return $self->{_attrs} = $attrs;
3641 }
3642
3643 sub _rollout_attr {
3644   my ($self, $attr) = @_;
3645
3646   if (ref $attr eq 'HASH') {
3647     return $self->_rollout_hash($attr);
3648   } elsif (ref $attr eq 'ARRAY') {
3649     return $self->_rollout_array($attr);
3650   } else {
3651     return [$attr];
3652   }
3653 }
3654
3655 sub _rollout_array {
3656   my ($self, $attr) = @_;
3657
3658   my @rolled_array;
3659   foreach my $element (@{$attr}) {
3660     if (ref $element eq 'HASH') {
3661       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3662     } elsif (ref $element eq 'ARRAY') {
3663       #  XXX - should probably recurse here
3664       push( @rolled_array, @{$self->_rollout_array($element)} );
3665     } else {
3666       push( @rolled_array, $element );
3667     }
3668   }
3669   return \@rolled_array;
3670 }
3671
3672 sub _rollout_hash {
3673   my ($self, $attr) = @_;
3674
3675   my @rolled_array;
3676   foreach my $key (keys %{$attr}) {
3677     push( @rolled_array, { $key => $attr->{$key} } );
3678   }
3679   return \@rolled_array;
3680 }
3681
3682 sub _calculate_score {
3683   my ($self, $a, $b) = @_;
3684
3685   if (defined $a xor defined $b) {
3686     return 0;
3687   }
3688   elsif (not defined $a) {
3689     return 1;
3690   }
3691
3692   if (ref $b eq 'HASH') {
3693     my ($b_key) = keys %{$b};
3694     if (ref $a eq 'HASH') {
3695       my ($a_key) = keys %{$a};
3696       if ($a_key eq $b_key) {
3697         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3698       } else {
3699         return 0;
3700       }
3701     } else {
3702       return ($a eq $b_key) ? 1 : 0;
3703     }
3704   } else {
3705     if (ref $a eq 'HASH') {
3706       my ($a_key) = keys %{$a};
3707       return ($b eq $a_key) ? 1 : 0;
3708     } else {
3709       return ($b eq $a) ? 1 : 0;
3710     }
3711   }
3712 }
3713
3714 sub _merge_joinpref_attr {
3715   my ($self, $orig, $import) = @_;
3716
3717   return $import unless defined($orig);
3718   return $orig unless defined($import);
3719
3720   $orig = $self->_rollout_attr($orig);
3721   $import = $self->_rollout_attr($import);
3722
3723   my $seen_keys;
3724   foreach my $import_element ( @{$import} ) {
3725     # find best candidate from $orig to merge $b_element into
3726     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3727     foreach my $orig_element ( @{$orig} ) {
3728       my $score = $self->_calculate_score( $orig_element, $import_element );
3729       if ($score > $best_candidate->{score}) {
3730         $best_candidate->{position} = $position;
3731         $best_candidate->{score} = $score;
3732       }
3733       $position++;
3734     }
3735     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3736     $import_key = '' if not defined $import_key;
3737
3738     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3739       push( @{$orig}, $import_element );
3740     } else {
3741       my $orig_best = $orig->[$best_candidate->{position}];
3742       # merge orig_best and b_element together and replace original with merged
3743       if (ref $orig_best ne 'HASH') {
3744         $orig->[$best_candidate->{position}] = $import_element;
3745       } elsif (ref $import_element eq 'HASH') {
3746         my ($key) = keys %{$orig_best};
3747         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3748       }
3749     }
3750     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3751   }
3752
3753   return @$orig ? $orig : ();
3754 }
3755
3756 {
3757   my $hm;
3758
3759   sub _merge_attr {
3760     $hm ||= do {
3761       require Hash::Merge;
3762       my $hm = Hash::Merge->new;
3763
3764       $hm->specify_behavior({
3765         SCALAR => {
3766           SCALAR => sub {
3767             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3768
3769             if ($defl xor $defr) {
3770               return [ $defl ? $_[0] : $_[1] ];
3771             }
3772             elsif (! $defl) {
3773               return [];
3774             }
3775             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3776               return [ $_[0] ];
3777             }
3778             else {
3779               return [$_[0], $_[1]];
3780             }
3781           },
3782           ARRAY => sub {
3783             return $_[1] if !defined $_[0];
3784             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3785             return [$_[0], @{$_[1]}]
3786           },
3787           HASH  => sub {
3788             return [] if !defined $_[0] and !keys %{$_[1]};
3789             return [ $_[1] ] if !defined $_[0];
3790             return [ $_[0] ] if !keys %{$_[1]};
3791             return [$_[0], $_[1]]
3792           },
3793         },
3794         ARRAY => {
3795           SCALAR => sub {
3796             return $_[0] if !defined $_[1];
3797             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3798             return [@{$_[0]}, $_[1]]
3799           },
3800           ARRAY => sub {
3801             my @ret = @{$_[0]} or return $_[1];
3802             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3803             my %idx = map { $_ => 1 } @ret;
3804             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3805             \@ret;
3806           },
3807           HASH => sub {
3808             return [ $_[1] ] if ! @{$_[0]};
3809             return $_[0] if !keys %{$_[1]};
3810             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3811             return [ @{$_[0]}, $_[1] ];
3812           },
3813         },
3814         HASH => {
3815           SCALAR => sub {
3816             return [] if !keys %{$_[0]} and !defined $_[1];
3817             return [ $_[0] ] if !defined $_[1];
3818             return [ $_[1] ] if !keys %{$_[0]};
3819             return [$_[0], $_[1]]
3820           },
3821           ARRAY => sub {
3822             return [] if !keys %{$_[0]} and !@{$_[1]};
3823             return [ $_[0] ] if !@{$_[1]};
3824             return $_[1] if !keys %{$_[0]};
3825             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3826             return [ $_[0], @{$_[1]} ];
3827           },
3828           HASH => sub {
3829             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3830             return [ $_[0] ] if !keys %{$_[1]};
3831             return [ $_[1] ] if !keys %{$_[0]};
3832             return [ $_[0] ] if $_[0] eq $_[1];
3833             return [ $_[0], $_[1] ];
3834           },
3835         }
3836       } => 'DBIC_RS_ATTR_MERGER');
3837       $hm;
3838     };
3839
3840     return $hm->merge ($_[1], $_[2]);
3841   }
3842 }
3843
3844 sub STORABLE_freeze {
3845   my ($self, $cloning) = @_;
3846   my $to_serialize = { %$self };
3847
3848   # A cursor in progress can't be serialized (and would make little sense anyway)
3849   # the parser can be regenerated (and can't be serialized)
3850   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3851
3852   # nor is it sensical to store a not-yet-fired-count pager
3853   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3854     delete $to_serialize->{pager};
3855   }
3856
3857   Storable::nfreeze($to_serialize);
3858 }
3859
3860 # need this hook for symmetry
3861 sub STORABLE_thaw {
3862   my ($self, $cloning, $serialized) = @_;
3863
3864   %$self = %{ Storable::thaw($serialized) };
3865
3866   $self;
3867 }
3868
3869
3870 =head2 throw_exception
3871
3872 See L<DBIx::Class::Schema/throw_exception> for details.
3873
3874 =cut
3875
3876 sub throw_exception {
3877   my $self=shift;
3878
3879   if (ref $self and my $rsrc = $self->result_source) {
3880     $rsrc->throw_exception(@_)
3881   }
3882   else {
3883     DBIx::Class::Exception->throw(@_);
3884   }
3885 }
3886
3887 1;
3888
3889 __END__
3890
3891 # XXX: FIXME: Attributes docs need clearing up
3892
3893 =head1 ATTRIBUTES
3894
3895 Attributes are used to refine a ResultSet in various ways when
3896 searching for data. They can be passed to any method which takes an
3897 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3898 L</count>.
3899
3900 Default attributes can be set on the result class using
3901 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3902 the CAVEATS on that feature before using it!)
3903
3904 These are in no particular order:
3905
3906 =head2 order_by
3907
3908 =over 4
3909
3910 =item Value: ( $order_by | \@order_by | \%order_by )
3911
3912 =back
3913
3914 Which column(s) to order the results by.
3915
3916 [The full list of suitable values is documented in
3917 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3918 common options.]
3919
3920 If a single column name, or an arrayref of names is supplied, the
3921 argument is passed through directly to SQL. The hashref syntax allows
3922 for connection-agnostic specification of ordering direction:
3923
3924  For descending order:
3925
3926   order_by => { -desc => [qw/col1 col2 col3/] }
3927
3928  For explicit ascending order:
3929
3930   order_by => { -asc => 'col' }
3931
3932 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3933 supported, although you are strongly encouraged to use the hashref
3934 syntax as outlined above.
3935
3936 =head2 columns
3937
3938 =over 4
3939
3940 =item Value: \@columns | \%columns | $column
3941
3942 =back
3943
3944 Shortcut to request a particular set of columns to be retrieved. Each
3945 column spec may be a string (a table column name), or a hash (in which
3946 case the key is the C<as> value, and the value is used as the C<select>
3947 expression). Adds C<me.> onto the start of any column without a C<.> in
3948 it and sets C<select> from that, then auto-populates C<as> from
3949 C<select> as normal. (You may also use the C<cols> attribute, as in
3950 earlier versions of DBIC, but this is deprecated.)
3951
3952 Essentially C<columns> does the same as L</select> and L</as>.
3953
3954     columns => [ 'foo', { bar => 'baz' } ]
3955
3956 is the same as
3957
3958     select => [qw/foo baz/],
3959     as => [qw/foo bar/]
3960
3961 =head2 +columns
3962
3963 =over 4
3964
3965 =item Value: \@columns
3966
3967 =back
3968
3969 Indicates additional columns to be selected from storage. Works the same as
3970 L</columns> but adds columns to the selection. (You may also use the
3971 C<include_columns> attribute, as in earlier versions of DBIC, but this is
3972 deprecated). For example:-
3973
3974   $schema->resultset('CD')->search(undef, {
3975     '+columns' => ['artist.name'],
3976     join => ['artist']
3977   });
3978
3979 would return all CDs and include a 'name' column to the information
3980 passed to object inflation. Note that the 'artist' is the name of the
3981 column (or relationship) accessor, and 'name' is the name of the column
3982 accessor in the related table.
3983
3984 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
3985 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
3986 unary plus operator before it.
3987
3988 =head2 include_columns
3989
3990 =over 4
3991
3992 =item Value: \@columns
3993
3994 =back
3995
3996 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3997
3998 =head2 select
3999
4000 =over 4
4001
4002 =item Value: \@select_columns
4003
4004 =back
4005
4006 Indicates which columns should be selected from the storage. You can use
4007 column names, or in the case of RDBMS back ends, function or stored procedure
4008 names:
4009
4010   $rs = $schema->resultset('Employee')->search(undef, {
4011     select => [
4012       'name',
4013       { count => 'employeeid' },
4014       { max => { length => 'name' }, -as => 'longest_name' }
4015     ]
4016   });
4017
4018   # Equivalent SQL
4019   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4020
4021 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4022 use L</select>, to instruct DBIx::Class how to store the result of the column.
4023 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4024 identifier aliasing. You can however alias a function, so you can use it in
4025 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4026 attribute> supplied as shown in the example above.
4027
4028 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4029 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4030 unary plus operator before it.
4031
4032 =head2 +select
4033
4034 =over 4
4035
4036 Indicates additional columns to be selected from storage.  Works the same as
4037 L</select> but adds columns to the default selection, instead of specifying
4038 an explicit list.
4039
4040 =back
4041
4042 =head2 as
4043
4044 =over 4
4045
4046 =item Value: \@inflation_names
4047
4048 =back
4049
4050 Indicates column names for object inflation. That is L</as> indicates the
4051 slot name in which the column value will be stored within the
4052 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4053 identifier by the C<get_column> method (or via the object accessor B<if one
4054 with the same name already exists>) as shown below. The L</as> attribute has
4055 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4056
4057   $rs = $schema->resultset('Employee')->search(undef, {
4058     select => [
4059       'name',
4060       { count => 'employeeid' },
4061       { max => { length => 'name' }, -as => 'longest_name' }
4062     ],
4063     as => [qw/
4064       name
4065       employee_count
4066       max_name_length
4067     /],
4068   });
4069
4070 If the object against which the search is performed already has an accessor
4071 matching a column name specified in C<as>, the value can be retrieved using
4072 the accessor as normal:
4073
4074   my $name = $employee->name();
4075
4076 If on the other hand an accessor does not exist in the object, you need to
4077 use C<get_column> instead:
4078
4079   my $employee_count = $employee->get_column('employee_count');
4080
4081 You can create your own accessors if required - see
4082 L<DBIx::Class::Manual::Cookbook> for details.
4083
4084 =head2 +as
4085
4086 =over 4
4087
4088 Indicates additional column names for those added via L</+select>. See L</as>.
4089
4090 =back
4091
4092 =head2 join
4093
4094 =over 4
4095
4096 =item Value: ($rel_name | \@rel_names | \%rel_names)
4097
4098 =back
4099
4100 Contains a list of relationships that should be joined for this query.  For
4101 example:
4102
4103   # Get CDs by Nine Inch Nails
4104   my $rs = $schema->resultset('CD')->search(
4105     { 'artist.name' => 'Nine Inch Nails' },
4106     { join => 'artist' }
4107   );
4108
4109 Can also contain a hash reference to refer to the other relation's relations.
4110 For example:
4111
4112   package MyApp::Schema::Track;
4113   use base qw/DBIx::Class/;
4114   __PACKAGE__->table('track');
4115   __PACKAGE__->add_columns(qw/trackid cd position title/);
4116   __PACKAGE__->set_primary_key('trackid');
4117   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4118   1;
4119
4120   # In your application
4121   my $rs = $schema->resultset('Artist')->search(
4122     { 'track.title' => 'Teardrop' },
4123     {
4124       join     => { cd => 'track' },
4125       order_by => 'artist.name',
4126     }
4127   );
4128
4129 You need to use the relationship (not the table) name in  conditions,
4130 because they are aliased as such. The current table is aliased as "me", so
4131 you need to use me.column_name in order to avoid ambiguity. For example:
4132
4133   # Get CDs from 1984 with a 'Foo' track
4134   my $rs = $schema->resultset('CD')->search(
4135     {
4136       'me.year' => 1984,
4137       'tracks.name' => 'Foo'
4138     },
4139     { join => 'tracks' }
4140   );
4141
4142 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4143 similarly for a third time). For e.g.
4144
4145   my $rs = $schema->resultset('Artist')->search({
4146     'cds.title'   => 'Down to Earth',
4147     'cds_2.title' => 'Popular',
4148   }, {
4149     join => [ qw/cds cds/ ],
4150   });
4151
4152 will return a set of all artists that have both a cd with title 'Down
4153 to Earth' and a cd with title 'Popular'.
4154
4155 If you want to fetch related objects from other tables as well, see L</prefetch>
4156 below.
4157
4158  NOTE: An internal join-chain pruner will discard certain joins while
4159  constructing the actual SQL query, as long as the joins in question do not
4160  affect the retrieved result. This for example includes 1:1 left joins
4161  that are not part of the restriction specification (WHERE/HAVING) nor are
4162  a part of the query selection.
4163
4164 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4165
4166 =head2 collapse
4167
4168 =over 4
4169
4170 =item Value: (0 | 1)
4171
4172 =back
4173
4174 When set to a true value, indicates that any rows fetched from joined has_many
4175 relationships are to be aggregated into the corresponding "parent" object. For
4176 example, the resultset:
4177
4178   my $rs = $schema->resultset('CD')->search({}, {
4179     '+columns' => [ qw/ tracks.title tracks.position / ],
4180     join => 'tracks',
4181     collapse => 1,
4182   });
4183
4184 While executing the following query:
4185
4186   SELECT me.*, tracks.title, tracks.position
4187     FROM cd me
4188     LEFT JOIN track tracks
4189       ON tracks.cdid = me.cdid
4190
4191 Will return only as many objects as there are rows in the CD source, even
4192 though the result of the query may span many rows. Each of these CD objects
4193 will in turn have multiple "Track" objects hidden behind the has_many
4194 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4195 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4196 product"), with each CD object containing exactly one of all fetched Track data.
4197
4198 When a collapse is requested on a non-ordered resultset, an order by some
4199 unique part of the main source (the left-most table) is inserted automatically.
4200 This is done so that the resultset is allowed to be "lazy" - calling
4201 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4202 object with all of its related data.
4203
4204 If an L</order_by> is already declared, and orders the resultset in a way that
4205 makes collapsing as described above impossible (e.g. C<< ORDER BY
4206 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4207 switch to "eager" mode and slurp the entire resultset before constructing the
4208 first object returned by L</next>.
4209
4210 Setting this attribute on a resultset that does not join any has_many
4211 relations is a no-op.
4212
4213 For a more in-depth discussion, see L</PREFETCHING>.
4214
4215 =head2 prefetch
4216
4217 =over 4
4218
4219 =item Value: ($rel_name | \@rel_names | \%rel_names)
4220
4221 =back
4222
4223 This attribute is a shorthand for specifying a L</join> spec, adding all
4224 columns from the joined related sources as L</+columns> and setting
4225 L</collapse> to a true value. For example, the following two queries are
4226 equivalent:
4227
4228   my $rs = $schema->resultset('Artist')->search({}, {
4229     prefetch => { cds => ['genre', 'tracks' ] },
4230   });
4231
4232 and
4233
4234   my $rs = $schema->resultset('Artist')->search({}, {
4235     join => { cds => ['genre', 'tracks' ] },
4236     collapse => 1,
4237     '+columns' => [
4238       (map
4239         { +{ "cds.$_" => "cds.$_" } }
4240         $schema->source('Artist')->related_source('cds')->columns
4241       ),
4242       (map
4243         { +{ "cds.genre.$_" => "genre.$_" } }
4244         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4245       ),
4246       (map
4247         { +{ "cds.tracks.$_" => "tracks.$_" } }
4248         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4249       ),
4250     ],
4251   });
4252
4253 Both producing the following SQL:
4254
4255   SELECT  me.artistid, me.name, me.rank, me.charfield,
4256           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4257           genre.genreid, genre.name,
4258           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4259     FROM artist me
4260     LEFT JOIN cd cds
4261       ON cds.artist = me.artistid
4262     LEFT JOIN genre genre
4263       ON genre.genreid = cds.genreid
4264     LEFT JOIN track tracks
4265       ON tracks.cd = cds.cdid
4266   ORDER BY me.artistid
4267
4268 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4269 the arguments are properly merged and generally do the right thing. For
4270 example, you may want to do the following:
4271
4272   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4273     { 'genre.genreid' => undef },
4274     {
4275       join => { cds => 'genre' },
4276       prefetch => 'cds',
4277     }
4278   );
4279
4280 Which generates the following SQL:
4281
4282   SELECT  me.artistid, me.name, me.rank, me.charfield,
4283           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4284     FROM artist me
4285     LEFT JOIN cd cds
4286       ON cds.artist = me.artistid
4287     LEFT JOIN genre genre
4288       ON genre.genreid = cds.genreid
4289   WHERE genre.genreid IS NULL
4290   ORDER BY me.artistid
4291
4292 For a more in-depth discussion, see L</PREFETCHING>.
4293
4294 =head2 alias
4295
4296 =over 4
4297
4298 =item Value: $source_alias
4299
4300 =back
4301
4302 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4303 nested search queries (sub-SELECTs) might need specific aliases set to
4304 reference inner queries.  For example:
4305
4306    my $q = $rs
4307       ->related_resultset('CDs')
4308       ->related_resultset('Tracks')
4309       ->search({
4310          'track.id' => { -ident => 'none_search.id' },
4311       })
4312       ->as_query;
4313
4314    my $ids = $self->search({
4315       -not_exists => $q,
4316    }, {
4317       alias    => 'none_search',
4318       group_by => 'none_search.id',
4319    })->get_column('id')->as_query;
4320
4321    $self->search({ id => { -in => $ids } })
4322
4323 This attribute is directly tied to L</current_source_alias>.
4324
4325 =head2 page
4326
4327 =over 4
4328
4329 =item Value: $page
4330
4331 =back
4332
4333 Makes the resultset paged and specifies the page to retrieve. Effectively
4334 identical to creating a non-pages resultset and then calling ->page($page)
4335 on it.
4336
4337 If L</rows> attribute is not specified it defaults to 10 rows per page.
4338
4339 When you have a paged resultset, L</count> will only return the number
4340 of rows in the page. To get the total, use the L</pager> and call
4341 C<total_entries> on it.
4342
4343 =head2 rows
4344
4345 =over 4
4346
4347 =item Value: $rows
4348
4349 =back
4350
4351 Specifies the maximum number of rows for direct retrieval or the number of
4352 rows per page if the page attribute or method is used.
4353
4354 =head2 offset
4355
4356 =over 4
4357
4358 =item Value: $offset
4359
4360 =back
4361
4362 Specifies the (zero-based) row number for the  first row to be returned, or the
4363 of the first row of the first page if paging is used.
4364
4365 =head2 software_limit
4366
4367 =over 4
4368
4369 =item Value: (0 | 1)
4370
4371 =back
4372
4373 When combined with L</rows> and/or L</offset> the generated SQL will not
4374 include any limit dialect stanzas. Instead the entire result will be selected
4375 as if no limits were specified, and DBIC will perform the limit locally, by
4376 artificially advancing and finishing the resulting L</cursor>.
4377
4378 This is the recommended way of performing resultset limiting when no sane RDBMS
4379 implementation is available (e.g.
4380 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4381 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4382
4383 =head2 group_by
4384
4385 =over 4
4386
4387 =item Value: \@columns
4388
4389 =back
4390
4391 A arrayref of columns to group by. Can include columns of joined tables.
4392
4393   group_by => [qw/ column1 column2 ... /]
4394
4395 =head2 having
4396
4397 =over 4
4398
4399 =item Value: $condition
4400
4401 =back
4402
4403 HAVING is a select statement attribute that is applied between GROUP BY and
4404 ORDER BY. It is applied to the after the grouping calculations have been
4405 done.
4406
4407   having => { 'count_employee' => { '>=', 100 } }
4408
4409 or with an in-place function in which case literal SQL is required:
4410
4411   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4412
4413 =head2 distinct
4414
4415 =over 4
4416
4417 =item Value: (0 | 1)
4418
4419 =back
4420
4421 Set to 1 to automatically generate a L</group_by> clause based on the selection
4422 (including intelligent handling of L</order_by> contents). Note that the group
4423 criteria calculation takes place over the B<final> selection. This includes
4424 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4425 L</search> calls, and standalone columns selected via
4426 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4427 extra selections specified via L</prefetch> - such selections are explicitly
4428 excluded from group criteria calculations.
4429
4430 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4431 setting is ignored and an appropriate warning is issued.
4432
4433 =head2 where
4434
4435 =over 4
4436
4437 Adds to the WHERE clause.
4438
4439   # only return rows WHERE deleted IS NULL for all searches
4440   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4441
4442 Can be overridden by passing C<< { where => undef } >> as an attribute
4443 to a resultset.
4444
4445 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4446
4447 =back
4448
4449 =head2 cache
4450
4451 Set to 1 to cache search results. This prevents extra SQL queries if you
4452 revisit rows in your ResultSet:
4453
4454   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4455
4456   while( my $artist = $resultset->next ) {
4457     ... do stuff ...
4458   }
4459
4460   $rs->first; # without cache, this would issue a query
4461
4462 By default, searches are not cached.
4463
4464 For more examples of using these attributes, see
4465 L<DBIx::Class::Manual::Cookbook>.
4466
4467 =head2 for
4468
4469 =over 4
4470
4471 =item Value: ( 'update' | 'shared' | \$scalar )
4472
4473 =back
4474
4475 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4476 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4477 query.
4478
4479 =head1 PREFETCHING
4480
4481 DBIx::Class supports arbitrary related data prefetching from multiple related
4482 sources. Any combination of relationship types and column sets are supported.
4483 If L<collapsing|/collapse> is requested, there is an additional requirement of
4484 selecting enough data to make every individual object uniquely identifiable.
4485
4486 Here are some more involved examples, based on the following relationship map:
4487
4488   # Assuming:
4489   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4490   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4491   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4492
4493   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4494
4495   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4496
4497
4498
4499   my $rs = $schema->resultset('Tag')->search(
4500     undef,
4501     {
4502       prefetch => {
4503         cd => 'artist'
4504       }
4505     }
4506   );
4507
4508 The initial search results in SQL like the following:
4509
4510   SELECT tag.*, cd.*, artist.* FROM tag
4511   JOIN cd ON tag.cd = cd.cdid
4512   JOIN artist ON cd.artist = artist.artistid
4513
4514 L<DBIx::Class> has no need to go back to the database when we access the
4515 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4516 case.
4517
4518 Simple prefetches will be joined automatically, so there is no need
4519 for a C<join> attribute in the above search.
4520
4521 The L</prefetch> attribute can be used with any of the relationship types
4522 and multiple prefetches can be specified together. Below is a more complex
4523 example that prefetches a CD's artist, its liner notes (if present),
4524 the cover image, the tracks on that CD, and the guests on those
4525 tracks.
4526
4527   my $rs = $schema->resultset('CD')->search(
4528     undef,
4529     {
4530       prefetch => [
4531         { artist => 'record_label'},  # belongs_to => belongs_to
4532         'liner_note',                 # might_have
4533         'cover_image',                # has_one
4534         { tracks => 'guests' },       # has_many => has_many
4535       ]
4536     }
4537   );
4538
4539 This will produce SQL like the following:
4540
4541   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4542          tracks.*, guests.*
4543     FROM cd me
4544     JOIN artist artist
4545       ON artist.artistid = me.artistid
4546     JOIN record_label record_label
4547       ON record_label.labelid = artist.labelid
4548     LEFT JOIN track tracks
4549       ON tracks.cdid = me.cdid
4550     LEFT JOIN guest guests
4551       ON guests.trackid = track.trackid
4552     LEFT JOIN liner_notes liner_note
4553       ON liner_note.cdid = me.cdid
4554     JOIN cd_artwork cover_image
4555       ON cover_image.cdid = me.cdid
4556   ORDER BY tracks.cd
4557
4558 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4559 C<tracks>, and C<guests> of the CD will all be available through the
4560 relationship accessors without the need for additional queries to the
4561 database.
4562
4563 =head3 CAVEATS
4564
4565 Prefetch does a lot of deep magic. As such, it may not behave exactly
4566 as you might expect.
4567
4568 =over 4
4569
4570 =item *
4571
4572 Prefetch uses the L</cache> to populate the prefetched relationships. This
4573 may or may not be what you want.
4574
4575 =item *
4576
4577 If you specify a condition on a prefetched relationship, ONLY those
4578 rows that match the prefetched condition will be fetched into that relationship.
4579 This means that adding prefetch to a search() B<may alter> what is returned by
4580 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4581
4582   my $artist_rs = $schema->resultset('Artist')->search({
4583       'cds.year' => 2008,
4584   }, {
4585       join => 'cds',
4586   });
4587
4588   my $count = $artist_rs->first->cds->count;
4589
4590   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4591
4592   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4593
4594   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4595
4596 That cmp_ok() may or may not pass depending on the datasets involved. In other
4597 words the C<WHERE> condition would apply to the entire dataset, just like
4598 it would in regular SQL. If you want to add a condition only to the "right side"
4599 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4600 condition|DBIx::Class::Relationship::Base/condition>
4601
4602 =back
4603
4604 =head1 DBIC BIND VALUES
4605
4606 Because DBIC may need more information to bind values than just the column name
4607 and value itself, it uses a special format for both passing and receiving bind
4608 values.  Each bind value should be composed of an arrayref of
4609 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4610
4611 =over 4
4612
4613 =item dbd_attrs
4614
4615 If present (in any form), this is what is being passed directly to bind_param.
4616 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4617 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4618
4619 If this is specified, all other bind options described below are ignored.
4620
4621 =item sqlt_datatype
4622
4623 If present, this is used to infer the actual bind attribute by passing to
4624 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4625 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4626
4627 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4628 currently drivers are expected to "Do the Right Thing" when given a common
4629 datatype name.  (Not ideal, but that's what we got at this point.)
4630
4631 =item sqlt_size
4632
4633 Currently used to correctly allocate buffers for bind_param_inout().
4634 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4635 or to a sensible value based on the "data_type".
4636
4637 =item dbic_colname
4638
4639 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4640 explicitly specified they are never overridden).  Also used by some weird DBDs,
4641 where the column name should be available at bind_param time (e.g. Oracle).
4642
4643 =back
4644
4645 For backwards compatibility and convenience, the following shortcuts are
4646 supported:
4647
4648   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4649   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4650   [ undef,   $val ] === [ {}, $val ]
4651   $val              === [ {}, $val ]
4652
4653 =head1 AUTHOR AND CONTRIBUTORS
4654
4655 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4656
4657 =head1 LICENSE
4658
4659 You may distribute this code under the same terms as Perl itself.
4660