lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5
   6 use base 'DBIx::Class';
   7
   8 use DBIx::Class::Carp;
   9 use DBIx::Class::ResultSetColumn;
  10 use DBIx::Class::ResultClass::HashRefInflator;
  11 use Scalar::Util qw( blessed reftype );
  12 use DBIx::Class::_Util qw(
  13   dbic_internal_try dump_value
  14   fail_on_internal_wantarray fail_on_internal_call UNRESOLVABLE_CONDITION
  15 );
  16 use DBIx::Class::SQLMaker::Util qw( normalize_sqla_condition extract_equality_conditions );
  17 use Try::Tiny;
  18
  19 BEGIN {
  20   # De-duplication in _merge_attr() is disabled, but left in for reference
  21   # (the merger is used for other things that ought not to be de-duped)
  22   *__HM_DEDUP = sub () { 0 };
  23 }
  24
  25 use namespace::clean;
  26
  27 use overload
  28         '0+'     => "count",
  29         'bool'   => "_bool",
  30         fallback => 1;
  31
  32 # this is real - CDBICompat overrides it with insanity
  33 # yes, prototype won't matter, but that's for now ;)
  34 sub _bool () { 1 }
  35
  36 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  37
  38 =head1 NAME
  39
  40 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  41
  42 =head1 SYNOPSIS
  43
  44   my $users_rs = $schema->resultset('User');
  45   while( $user = $users_rs->next) {
  46     print $user->username;
  47   }
  48
  49   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  50   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  51
  52 =head1 DESCRIPTION
  53
  54 A ResultSet is an object which stores a set of conditions representing
  55 a query. It is the backbone of DBIx::Class (i.e. the really
  56 important/useful bit).
  57
  58 No SQL is executed on the database when a ResultSet is created, it
  59 just stores all the conditions needed to create the query.
  60
  61 A basic ResultSet representing the data of an entire table is returned
  62 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  63 L<Source|DBIx::Class::Manual::Glossary/ResultSource> name.
  64
  65   my $users_rs = $schema->resultset('User');
  66
  67 A new ResultSet is returned from calling L</search> on an existing
  68 ResultSet. The new one will contain all the conditions of the
  69 original, plus any new conditions added in the C<search> call.
  70
  71 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  72 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  73 represents.
  74
  75 The query that the ResultSet represents is B<only> executed against
  76 the database when these methods are called:
  77 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  78
  79 If a resultset is used in a numeric context it returns the L</count>.
  80 However, if it is used in a boolean context it is B<always> true.  So if
  81 you want to check if a resultset has any results, you must use C<if $rs
  82 != 0>.
  83
  84 =head1 EXAMPLES
  85
  86 =head2 Chaining resultsets
  87
  88 Let's say you've got a query that needs to be run to return some data
  89 to the user. But, you have an authorization system in place that
  90 prevents certain users from seeing certain information. So, you want
  91 to construct the basic query in one method, but add constraints to it in
  92 another.
  93
  94   sub get_data {
  95     my $self = shift;
  96     my $request = $self->get_request; # Get a request object somehow.
  97     my $schema = $self->result_source->schema;
  98
  99     my $cd_rs = $schema->resultset('CD')->search({
 100       title => $request->param('title'),
 101       year => $request->param('year'),
 102     });
 103
 104     $cd_rs = $self->apply_security_policy( $cd_rs );
 105
 106     return $cd_rs->all();
 107   }
 108
 109   sub apply_security_policy {
 110     my $self = shift;
 111     my ($rs) = @_;
 112
 113     return $rs->search({
 114       subversive => 0,
 115     });
 116   }
 117
 118 =head3 Resolving conditions and attributes
 119
 120 When a resultset is chained from another resultset (e.g.:
 121 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 122 and attributes with the same keys need resolving.
 123
 124 If any of L</columns>, L</select>, L</as> are present, they reset the
 125 original selection, and start the selection "clean".
 126
 127 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 128 are merged into the existing ones from the original resultset.
 129
 130 The L</where> and L</having> attributes, and any search conditions, are
 131 merged with an SQL C<AND> to the existing condition from the original
 132 resultset.
 133
 134 All other attributes are overridden by any new ones supplied in the
 135 search attributes.
 136
 137 =head2 Multiple queries
 138
 139 Since a resultset just defines a query, you can do all sorts of
 140 things with it with the same object.
 141
 142   # Don't hit the DB yet.
 143   my $cd_rs = $schema->resultset('CD')->search({
 144     title => 'something',
 145     year => 2009,
 146   });
 147
 148   # Each of these hits the DB individually.
 149   my $count = $cd_rs->count;
 150   my $most_recent = $cd_rs->get_column('date_released')->max();
 151   my @records = $cd_rs->all;
 152
 153 And it's not just limited to SELECT statements.
 154
 155   $cd_rs->delete();
 156
 157 This is even cooler:
 158
 159   $cd_rs->create({ artist => 'Fred' });
 160
 161 Which is the same as:
 162
 163   $schema->resultset('CD')->create({
 164     title => 'something',
 165     year => 2009,
 166     artist => 'Fred'
 167   });
 168
 169 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 170
 171 =head2 Custom ResultSet classes
 172
 173 To add methods to your resultsets, you can subclass L<DBIx::Class::ResultSet>, similar to:
 174
 175   package MyApp::Schema::ResultSet::User;
 176
 177   use strict;
 178   use warnings;
 179
 180   use base 'DBIx::Class::ResultSet';
 181
 182   sub active {
 183     my $self = shift;
 184     $self->search({ $self->current_source_alias . '.active' => 1 });
 185   }
 186
 187   sub unverified {
 188     my $self = shift;
 189     $self->search({ $self->current_source_alias . '.verified' => 0 });
 190   }
 191
 192   sub created_n_days_ago {
 193     my ($self, $days_ago) = @_;
 194     $self->search({
 195       $self->current_source_alias . '.create_date' => {
 196         '<=',
 197       $self->result_source->schema->storage->datetime_parser->format_datetime(
 198         DateTime->now( time_zone => 'UTC' )->subtract( days => $days_ago )
 199       )}
 200     });
 201   }
 202
 203   sub users_to_warn { shift->active->unverified->created_n_days_ago(7) }
 204
 205   1;
 206
 207 See L<DBIx::Class::Schema/load_namespaces> on how DBIC can discover and
 208 automatically attach L<Result|DBIx::Class::Manual::ResultClass>-specific
 209 L<ResulSet|DBIx::Class::ResultSet> classes.
 210
 211 =head3 ResultSet subclassing with Moose and similar constructor-providers
 212
 213 Using L<Moose> or L<Moo> in your ResultSet classes is usually overkill, but
 214 you may find it useful if your ResultSets contain a lot of business logic
 215 (e.g. C<has xml_parser>, C<has json>, etc) or if you just prefer to organize
 216 your code via roles.
 217
 218 In order to write custom ResultSet classes with L<Moo> you need to use the
 219 following template. The L<BUILDARGS|Moo/BUILDARGS> is necessary due to the
 220 unusual signature of the L<constructor provided by DBIC
 221 |DBIx::Class::ResultSet/new> C<< ->new($source, \%args) >>.
 222
 223   use Moo;
 224   extends 'DBIx::Class::ResultSet';
 225   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 226
 227   ...your code...
 228
 229   1;
 230
 231 If you want to build your custom ResultSet classes with L<Moose>, you need
 232 a similar, though a little more elaborate template in order to interface the
 233 inlining of the L<Moose>-provided
 234 L<object constructor|Moose::Manual::Construction/WHERE'S THE CONSTRUCTOR?>,
 235 with the DBIC one.
 236
 237   package MyApp::Schema::ResultSet::User;
 238
 239   use Moose;
 240   use MooseX::NonMoose;
 241   extends 'DBIx::Class::ResultSet';
 242
 243   sub BUILDARGS { $_[2] } # ::RS::new() expects my ($class, $rsrc, $args) = @_
 244
 245   ...your code...
 246
 247   __PACKAGE__->meta->make_immutable;
 248
 249   1;
 250
 251 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 252 entirely overwrite the DBIC one (in contrast L<Moo> does this automatically).
 253 Alternatively, you can skip L<MooseX::NonMoose> and get by with just L<Moose>
 254 instead by doing:
 255
 256   __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 257
 258 =head1 METHODS
 259
 260 =head2 new
 261
 262 =over 4
 263
 264 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 265
 266 =item Return Value: L<$resultset|/search>
 267
 268 =back
 269
 270 The resultset constructor. Takes a source object (usually a
 271 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 272 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 273 executed as needed by the other methods.
 274
 275 Generally you never construct a resultset manually. Instead you get one
 276 from e.g. a
 277 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 278 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 279 scalar context):
 280
 281   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 282
 283 =over
 284
 285 =item WARNING
 286
 287 If called on an object, proxies to L</new_result> instead, so
 288
 289   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 290
 291 will return a CD object, not a ResultSet, and is equivalent to:
 292
 293   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 294
 295 Please also keep in mind that many internals call L</new_result> directly,
 296 so overloading this method with the idea of intercepting new result object
 297 creation B<will not work>. See also warning pertaining to L</create>.
 298
 299 =back
 300
 301 =cut
 302
 303 sub new {
 304   my $class = shift;
 305
 306   if (ref $class) {
 307     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 308     return $class->new_result(@_);
 309   }
 310
 311   my ($source, $attrs) = @_;
 312   $source = $source->resolve
 313     if $source->isa('DBIx::Class::ResultSourceHandle');
 314
 315   $attrs = { %{$attrs||{}} };
 316   delete @{$attrs}{qw(_last_sqlmaker_alias_map _simple_passthrough_construction)};
 317
 318   if ($attrs->{page}) {
 319     $attrs->{rows} ||= 10;
 320   }
 321
 322   $attrs->{alias} ||= 'me';
 323
 324   my $self = bless {
 325     result_source => $source,
 326     cond => $attrs->{where},
 327     pager => undef,
 328     attrs => $attrs,
 329   }, $class;
 330
 331   # if there is a dark selector, this means we are already in a
 332   # chain and the cleanup/sanification was taken care of by
 333   # _search_rs already
 334   $self->_normalize_selection($attrs)
 335     unless $attrs->{_dark_selector};
 336
 337   $self->result_class(
 338     $attrs->{result_class} || $source->result_class
 339   );
 340
 341   $self;
 342 }
 343
 344 =head2 search
 345
 346 =over 4
 347
 348 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 349
 350 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 351
 352 =back
 353
 354   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 355   my $new_rs = $cd_rs->search({ year => 2005 });
 356
 357   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 358                  # year = 2005 OR year = 2004
 359
 360 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 361 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 362 To avoid that, use L</search_rs>.
 363
 364 If you need to pass in additional attributes but no additional condition,
 365 call it as C<search(undef, \%attrs)>.
 366
 367   # "SELECT name, artistid FROM $artist_table"
 368   my @all_artists = $schema->resultset('Artist')->search(undef, {
 369     columns => [qw/name artistid/],
 370   });
 371
 372 For a list of attributes that can be passed to C<search>, see
 373 L</ATTRIBUTES>. For more examples of using this function, see
 374 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 375 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 376 and its extension L<DBIx::Class::SQLMaker>.
 377
 378 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 379
 380 =head3 CAVEAT
 381
 382 Note that L</search> does not process/deflate any of the values passed in the
 383 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 384 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 385 manually that any value passed to this method will stringify to something the
 386 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 387 objects, for more info see:
 388 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 389
 390 =cut
 391
 392 sub search {
 393   my $self = shift;
 394   my $rs = $self->search_rs( @_ );
 395
 396   if (wantarray) {
 397     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray;
 398     return $rs->all;
 399   }
 400   elsif (defined wantarray) {
 401     return $rs;
 402   }
 403   else {
 404     # we can be called by a relationship helper, which in
 405     # turn may be called in void context due to some braindead
 406     # overload or whatever else the user decided to be clever
 407     # at this particular day. Thus limit the exception to
 408     # external code calls only
 409     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 410       if (caller)[0] !~ /^\QDBIx::Class::/;
 411
 412     return ();
 413   }
 414 }
 415
 416 =head2 search_rs
 417
 418 =over 4
 419
 420 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 421
 422 =item Return Value: L<$resultset|/search>
 423
 424 =back
 425
 426 This method does the same exact thing as search() except it will
 427 always return a resultset, even in list context.
 428
 429 =cut
 430
 431 sub search_rs {
 432   my $self = shift;
 433
 434   my $rsrc = $self->result_source;
 435   my ($call_cond, $call_attrs);
 436
 437   # Special-case handling for (undef, undef) or (undef)
 438   # Note that (foo => undef) is valid deprecated syntax
 439   @_ = () if not scalar grep { defined $_ } @_;
 440
 441   # just a cond
 442   if (@_ == 1) {
 443     $call_cond = shift;
 444   }
 445   # fish out attrs in the ($condref, $attr) case
 446   elsif (@_ == 2 and ( ! defined $_[0] or length ref $_[0] ) ) {
 447     ($call_cond, $call_attrs) = @_;
 448   }
 449   elsif (@_ % 2) {
 450     $self->throw_exception('Odd number of arguments to search')
 451   }
 452   # legacy search
 453   elsif (@_) {
 454     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 455       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 456
 457     for my $i (0 .. $#_) {
 458       next if $i % 2;
 459       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 460         if (! defined $_[$i] or length ref $_[$i] );
 461     }
 462
 463     $call_cond = { @_ };
 464   }
 465
 466   # see if we can keep the cache (no $rs changes)
 467   my $cache;
 468   my %safe = (alias => 1, cache => 1);
 469   if ( ! grep { !$safe{$_} } keys %$call_attrs and (
 470     ! defined $call_cond
 471       or
 472     ref $call_cond eq 'HASH' && ! keys %$call_cond
 473       or
 474     ref $call_cond eq 'ARRAY' && ! @$call_cond
 475   )) {
 476     $cache = $self->get_cache;
 477   }
 478
 479   my $old_attrs = { %{$self->{attrs}} };
 480   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 481
 482   my $new_attrs = { %$old_attrs };
 483
 484   # take care of call attrs (only if anything is changing)
 485   if ($call_attrs and keys %$call_attrs) {
 486
 487     # copy for _normalize_selection
 488     $call_attrs = { %$call_attrs };
 489
 490     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 491
 492     # reset the current selector list if new selectors are supplied
 493     delete @{$old_attrs}{(@selector_attrs, '_dark_selector')}
 494       if grep { exists $call_attrs->{$_} } qw(columns cols select as);
 495
 496     # Normalize the new selector list (operates on the passed-in attr structure)
 497     # Need to do it on every chain instead of only once on _resolved_attrs, in
 498     # order to allow detection of empty vs partial 'as'
 499     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 500       if $old_attrs->{_dark_selector};
 501     $self->_normalize_selection ($call_attrs);
 502
 503     # start with blind overwriting merge, exclude selector attrs
 504     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 505     delete @{$new_attrs}{@selector_attrs};
 506
 507     for (@selector_attrs) {
 508       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 509         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 510     }
 511
 512     # older deprecated name, use only if {columns} is not there
 513     if (my $c = delete $new_attrs->{cols}) {
 514       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 515       if ($new_attrs->{columns}) {
 516         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 517       }
 518       else {
 519         $new_attrs->{columns} = $c;
 520       }
 521     }
 522
 523
 524     # join/prefetch use their own crazy merging heuristics
 525     foreach my $key (qw/join prefetch/) {
 526       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 527         if exists $call_attrs->{$key};
 528     }
 529
 530     # stack binds together
 531     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 532   }
 533
 534
 535   for ($old_where, $call_cond) {
 536     if (defined $_) {
 537       $new_attrs->{where} = $self->_stack_cond (
 538         $_, $new_attrs->{where}
 539       );
 540     }
 541   }
 542
 543   if (defined $old_having) {
 544     $new_attrs->{having} = $self->_stack_cond (
 545       $old_having, $new_attrs->{having}
 546     )
 547   }
 548
 549   my $rs = (ref $self)->new($rsrc, $new_attrs);
 550
 551   $rs->set_cache($cache) if ($cache);
 552
 553   return $rs;
 554 }
 555
 556 sub _normalize_selection {
 557   my ($self, $attrs) = @_;
 558
 559   # legacy syntax
 560   if ( exists $attrs->{include_columns} ) {
 561     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 562     $attrs->{'+columns'} = $self->_merge_attr(
 563       $attrs->{'+columns'}, delete $attrs->{include_columns}
 564     );
 565   }
 566
 567   # columns are always placed first, however
 568
 569   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 570   # delay the decision on whether to use a default select list ($rsrc->columns)
 571   # allowing stuff like the remove_columns helper to work
 572   #
 573   # select/as +select/+as pairs need special handling - the amount of select/as
 574   # elements in each pair does *not* have to be equal (think multicolumn
 575   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 576   # supplied at all) - try to infer the alias, either from the -as parameter
 577   # of the selector spec, or use the parameter whole if it looks like a column
 578   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 579   # is ok as well), but make sure no more additions to the 'as' chain take place
 580   for my $pref ('', '+') {
 581
 582     my ($sel, $as) = map {
 583       my $key = "${pref}${_}";
 584
 585       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 586         ? @{$attrs->{$key}}
 587         : $attrs->{$key} || ()
 588       ];
 589       delete $attrs->{$key};
 590       $val;
 591     } qw/select as/;
 592
 593     if (! @$as and ! @$sel ) {
 594       next;
 595     }
 596     elsif (@$as and ! @$sel) {
 597       $self->throw_exception(
 598         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 599       );
 600     }
 601     elsif( ! @$as ) {
 602       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 603       # if any @$as has been supplied we assume the user knows what (s)he is doing
 604       # and blindly keep stacking up pieces
 605       unless ($attrs->{_dark_selector}) {
 606         SELECTOR:
 607         for (@$sel) {
 608           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 609             push @$as, $_->{-as};
 610           }
 611           # assume any plain no-space, no-parenthesis string to be a column spec
 612           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 613           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 614             push @$as, $_;
 615           }
 616           # if all else fails - raise a flag that no more aliasing will be allowed
 617           else {
 618             $attrs->{_dark_selector} = {
 619               plus_stage => $pref,
 620               string => do {
 621                 local $Data::Dumper::Indent = 0;
 622                 dump_value $_;
 623               },
 624             };
 625             last SELECTOR;
 626           }
 627         }
 628       }
 629     }
 630     elsif (@$as < @$sel) {
 631       $self->throw_exception(
 632         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 633       );
 634     }
 635     elsif ($pref and $attrs->{_dark_selector}) {
 636       $self->throw_exception(
 637         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 638       );
 639     }
 640
 641
 642     # merge result
 643     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 644     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 645   }
 646 }
 647
 648 sub _stack_cond {
 649   my ($self, $left, $right) = @_;
 650
 651   (
 652     (ref $_ eq 'ARRAY' and !@$_)
 653       or
 654     (ref $_ eq 'HASH' and ! keys %$_)
 655   ) and $_ = undef for ($left, $right);
 656
 657   return(
 658     # either one of the two undef
 659     ( (defined $left) xor (defined $right) )  ? ( defined $left ? $left : $right )
 660
 661     # both undef
 662   : ( ! defined $left )                       ? undef
 663
 664                                               : { -and => [$left, $right] }
 665   );
 666 }
 667
 668 =head2 search_literal
 669
 670 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 671 should only be used in that context. C<search_literal> is a convenience
 672 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 673 want to ensure columns are bound correctly, use L</search>.
 674
 675 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 676 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 677 require C<search_literal>.
 678
 679 =over 4
 680
 681 =item Arguments: $sql_fragment, @standalone_bind_values
 682
 683 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 684
 685 =back
 686
 687   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 688   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 689
 690 Pass a literal chunk of SQL to be added to the conditional part of the
 691 resultset query.
 692
 693 Example of how to use C<search> instead of C<search_literal>
 694
 695   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 696   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 697
 698 =cut
 699
 700 sub search_literal {
 701   my ($self, $sql, @bind) = @_;
 702   my $attr;
 703   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 704     $attr = pop @bind;
 705   }
 706   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 707 }
 708
 709 =head2 find
 710
 711 =over 4
 712
 713 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 714
 715 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 716
 717 =back
 718
 719 Finds and returns a single row based on supplied criteria. Takes either a
 720 hashref with the same format as L</create> (including inference of foreign
 721 keys from related objects), or a list of primary key values in the same
 722 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 723 declaration on the L</result_source>.
 724
 725 In either case an attempt is made to combine conditions already existing on
 726 the resultset with the condition passed to this method.
 727
 728 To aid with preparing the correct query for the storage you may supply the
 729 C<key> attribute, which is the name of a
 730 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 731 unique constraint corresponding to the
 732 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 733 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 734 to construct a query that satisfies the named unique constraint fully (
 735 non-NULL values for each column member of the constraint) an exception is
 736 thrown.
 737
 738 If no C<key> is specified, the search is carried over all unique constraints
 739 which are fully defined by the available condition.
 740
 741 If no such constraint is found, C<find> currently defaults to a simple
 742 C<< search->(\%column_values) >> which may or may not do what you expect.
 743 Note that this fallback behavior may be deprecated in further versions. If
 744 you need to search with arbitrary conditions - use L</search>. If the query
 745 resulting from this fallback produces more than one row, a warning to the
 746 effect is issued, though only the first row is constructed and returned as
 747 C<$result_object>.
 748
 749 In addition to C<key>, L</find> recognizes and applies standard
 750 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 751
 752 Note that if you have extra concerns about the correctness of the resulting
 753 query you need to specify the C<key> attribute and supply the entire condition
 754 as an argument to find (since it is not always possible to perform the
 755 combination of the resultset condition with the supplied one, especially if
 756 the resultset condition contains literal sql).
 757
 758 For example, to find a row by its primary key:
 759
 760   my $cd = $schema->resultset('CD')->find(5);
 761
 762 You can also find a row by a specific unique constraint:
 763
 764   my $cd = $schema->resultset('CD')->find(
 765     {
 766       artist => 'Massive Attack',
 767       title  => 'Mezzanine',
 768     },
 769     { key => 'cd_artist_title' }
 770   );
 771
 772 See also L</find_or_create> and L</update_or_create>.
 773
 774 =cut
 775
 776 sub find {
 777   my $self = shift;
 778   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
 779
 780   my $rsrc = $self->result_source;
 781
 782   my $constraint_name;
 783   if (exists $attrs->{key}) {
 784     $constraint_name = defined $attrs->{key}
 785       ? $attrs->{key}
 786       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 787     ;
 788   }
 789
 790   # Parse out the condition from input
 791   my $call_cond;
 792
 793   if (ref $_[0] eq 'HASH') {
 794     $call_cond = { %{$_[0]} };
 795   }
 796   else {
 797     # if only values are supplied we need to default to 'primary'
 798     $constraint_name = 'primary' unless defined $constraint_name;
 799
 800     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 801
 802     $self->throw_exception(
 803       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 804     ) unless @c_cols;
 805
 806     $self->throw_exception (
 807       'find() expects either a column/value hashref, or a list of values '
 808     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 809     ) unless @c_cols == @_;
 810
 811     @{$call_cond}{@c_cols} = @_;
 812   }
 813
 814   # process relationship data if any
 815   for my $key (keys %$call_cond) {
 816     if (
 817       length ref($call_cond->{$key})
 818         and
 819       my $relinfo = $rsrc->relationship_info($key)
 820         and
 821       # implicitly skip has_many's (likely MC)
 822       ( ref( my $val = delete $call_cond->{$key} ) ne 'ARRAY' )
 823     ) {
 824       my ($rel_cond, $crosstable) = $rsrc->_resolve_condition(
 825         $relinfo->{cond}, $val, $key, $key
 826       );
 827
 828       $self->throw_exception("Complex condition via relationship '$key' is unsupported in find()")
 829          if $crosstable or ref($rel_cond) ne 'HASH';
 830
 831       # supplement condition
 832       # relationship conditions take precedence (?)
 833       @{$call_cond}{keys %$rel_cond} = values %$rel_cond;
 834     }
 835   }
 836
 837   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 838   my $final_cond;
 839   if (defined $constraint_name) {
 840     $final_cond = $self->_qualify_cond_columns (
 841
 842       $rsrc->_minimal_valueset_satisfying_constraint(
 843         constraint_name => $constraint_name,
 844         values => ($self->_merge_with_rscond($call_cond))[0],
 845         carp_on_nulls => 1,
 846       ),
 847
 848       $alias,
 849     );
 850   }
 851   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 852     # This means that we got here after a merger of relationship conditions
 853     # in ::Relationship::Base::search_related (the row method), and furthermore
 854     # the relationship is of the 'single' type. This means that the condition
 855     # provided by the relationship (already attached to $self) is sufficient,
 856     # as there can be only one row in the database that would satisfy the
 857     # relationship
 858   }
 859   else {
 860     my (@unique_queries, %seen_column_combinations, $ci, @fc_exceptions);
 861
 862     # no key was specified - fall down to heuristics mode:
 863     # run through all unique queries registered on the resultset, and
 864     # 'OR' all qualifying queries together
 865     #
 866     # always start from 'primary' if it exists at all
 867     for my $c_name ( sort {
 868         $a eq 'primary' ? -1
 869       : $b eq 'primary' ? 1
 870       : $a cmp $b
 871     } $rsrc->unique_constraint_names) {
 872
 873       next if $seen_column_combinations{
 874         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 875       }++;
 876
 877       dbic_internal_try {
 878         push @unique_queries, $self->_qualify_cond_columns(
 879           $rsrc->_minimal_valueset_satisfying_constraint(
 880             constraint_name => $c_name,
 881             values => ($self->_merge_with_rscond($call_cond))[0],
 882             columns_info => ($ci ||= $rsrc->columns_info),
 883           ),
 884           $alias
 885         );
 886       }
 887       catch {
 888         push @fc_exceptions, $_ if $_ =~ /\bFilterColumn\b/;
 889       };
 890     }
 891
 892     $final_cond =
 893         @unique_queries   ? \@unique_queries
 894       : @fc_exceptions    ? $self->throw_exception(join "; ", map { $_ =~ /(.*) at .+ line \d+$/s } @fc_exceptions )
 895       :                     $self->_non_unique_find_fallback ($call_cond, $attrs)
 896     ;
 897   }
 898
 899   # Run the query, passing the result_class since it should propagate for find
 900   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 901   if ($rs->_resolved_attrs->{collapse}) {
 902     my $row = $rs->next;
 903     carp "Query returned more than one row" if $rs->next;
 904     return $row;
 905   }
 906   else {
 907     return $rs->single;
 908   }
 909 }
 910
 911 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 912 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 913 #
 914 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 915 # condition. It is provided for overrides until a saner way forward is devised
 916 #
 917 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 918 # the road. Please adjust your tests accordingly to catch this situation early
 919 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 920 #
 921 # The method will not be removed without an adequately complete replacement
 922 # for strict-mode enforcement
 923 sub _non_unique_find_fallback {
 924   my ($self, $cond, $attrs) = @_;
 925
 926   return $self->_qualify_cond_columns(
 927     $cond,
 928     exists $attrs->{alias}
 929       ? $attrs->{alias}
 930       : $self->{attrs}{alias}
 931   );
 932 }
 933
 934
 935 sub _qualify_cond_columns {
 936   my ($self, $cond, $alias) = @_;
 937
 938   my %aliased = %$cond;
 939   for (keys %aliased) {
 940     $aliased{"$alias.$_"} = delete $aliased{$_}
 941       if $_ !~ /\./;
 942   }
 943
 944   return \%aliased;
 945 }
 946
 947 sub _build_unique_cond {
 948   carp_unique sprintf
 949     '_build_unique_cond is a private method, and moreover is about to go '
 950   . 'away. Please contact the development team at %s if you believe you '
 951   . 'have a genuine use for this method, in order to discuss alternatives.',
 952     DBIx::Class::_ENV_::HELP_URL,
 953   ;
 954
 955   my ($self, $constraint_name, $cond, $croak_on_null) = @_;
 956
 957   $self->result_source->_minimal_valueset_satisfying_constraint(
 958     constraint_name => $constraint_name,
 959     values => $cond,
 960     carp_on_nulls => !$croak_on_null
 961   );
 962 }
 963
 964 =head2 search_related
 965
 966 =over 4
 967
 968 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 969
 970 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 971
 972 =back
 973
 974   $new_rs = $cd_rs->search_related('artist', {
 975     name => 'Emo-R-Us',
 976   });
 977
 978 Searches the specified relationship, optionally specifying a condition and
 979 attributes for matching records. See L</ATTRIBUTES> for more information.
 980
 981 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 982 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 983
 984 See also L</search_related_rs>.
 985
 986 =cut
 987
 988 sub search_related :DBIC_method_is_indirect_sugar {
 989   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
 990   return shift->related_resultset(shift)->search(@_);
 991 }
 992
 993 =head2 search_related_rs
 994
 995 This method works exactly the same as search_related, except that
 996 it guarantees a resultset, even in list context.
 997
 998 =cut
 999
1000 sub search_related_rs :DBIC_method_is_indirect_sugar {
1001   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1002   return shift->related_resultset(shift)->search_rs(@_);
1003 }
1004
1005 =head2 cursor
1006
1007 =over 4
1008
1009 =item Arguments: none
1010
1011 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1012
1013 =back
1014
1015 Returns a storage-driven cursor to the given resultset. See
1016 L<DBIx::Class::Cursor> for more information.
1017
1018 =cut
1019
1020 sub cursor {
1021   my $self = shift;
1022
1023   return $self->{cursor} ||= do {
1024     my $attrs = $self->_resolved_attrs;
1025     $self->result_source->schema->storage->select(
1026       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1027     );
1028   };
1029 }
1030
1031 =head2 single
1032
1033 =over 4
1034
1035 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1036
1037 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1038
1039 =back
1040
1041   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1042
1043 Inflates the first result without creating a cursor if the resultset has
1044 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1045 of L</search>.
1046
1047 While this method can take an optional search condition (just like L</search>)
1048 being a fast-code-path it does not recognize search attributes. If you need to
1049 add extra joins or similar, call L</search> and then chain-call L</single> on the
1050 L<DBIx::Class::ResultSet> returned.
1051
1052 =over
1053
1054 =item B<Note>
1055
1056 As of 0.08100, this method enforces the assumption that the preceding
1057 query returns only one row. If more than one row is returned, you will receive
1058 a warning:
1059
1060   Query returned more than one row
1061
1062 In this case, you should be using L</next> or L</find> instead, or if you really
1063 know what you are doing, use the L</rows> attribute to explicitly limit the size
1064 of the resultset.
1065
1066 This method will also throw an exception if it is called on a resultset prefetching
1067 has_many, as such a prefetch implies fetching multiple rows from the database in
1068 order to assemble the resulting object.
1069
1070 =back
1071
1072 =cut
1073
1074 sub single {
1075   my ($self, $where) = @_;
1076   if(@_ > 2) {
1077       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1078   }
1079
1080   my $attrs = { %{$self->_resolved_attrs} };
1081
1082   $self->throw_exception(
1083     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1084   ) if $attrs->{collapse};
1085
1086   if ($where) {
1087     if (defined $attrs->{where}) {
1088       $attrs->{where} = {
1089         '-and' =>
1090             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1091                $where, delete $attrs->{where} ]
1092       };
1093     } else {
1094       $attrs->{where} = $where;
1095     }
1096   }
1097
1098   my $data = [ $self->result_source->schema->storage->select_single(
1099     $attrs->{from}, $attrs->{select},
1100     $attrs->{where}, $attrs
1101   )];
1102
1103   return undef unless @$data;
1104   $self->{_stashed_rows} = [ $data ];
1105   $self->_construct_results->[0];
1106 }
1107
1108 =head2 get_column
1109
1110 =over 4
1111
1112 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1113
1114 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1115
1116 =back
1117
1118   my $max_length = $rs->get_column('length')->max;
1119
1120 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1121
1122 =cut
1123
1124 sub get_column {
1125   DBIx::Class::ResultSetColumn->new(@_);
1126 }
1127
1128 =head2 search_like
1129
1130 =over 4
1131
1132 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1133
1134 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1135
1136 =back
1137
1138   # WHERE title LIKE '%blue%'
1139   $cd_rs = $rs->search_like({ title => '%blue%'});
1140
1141 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1142 that this is simply a convenience method retained for ex Class::DBI users.
1143 You most likely want to use L</search> with specific operators.
1144
1145 For more information, see L<DBIx::Class::Manual::Cookbook>.
1146
1147 This method is deprecated and will be removed in 0.09. Use L<search()|/search>
1148 instead. An example conversion is:
1149
1150   ->search_like({ foo => 'bar' });
1151
1152   # Becomes
1153
1154   ->search({ foo => { like => 'bar' } });
1155
1156 =cut
1157
1158 sub search_like {
1159   my $class = shift;
1160   carp_unique (
1161     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1162    .' Instead use ->search({ x => { -like => "y%" } })'
1163    .' (note the outer pair of {}s - they are important!)'
1164   );
1165   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
1166   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1167   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1168   return $class->search($query, { %$attrs });
1169 }
1170
1171 =head2 slice
1172
1173 =over 4
1174
1175 =item Arguments: $first, $last
1176
1177 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1178
1179 =back
1180
1181 Returns a resultset or object list representing a subset of elements from the
1182 resultset slice is called on. Indexes are from 0, i.e., to get the first
1183 three records, call:
1184
1185   my ($one, $two, $three) = $rs->slice(0, 2);
1186
1187 =cut
1188
1189 sub slice {
1190   my ($self, $min, $max) = @_;
1191   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1192   $attrs->{offset} = $self->{attrs}{offset} || 0;
1193   $attrs->{offset} += $min;
1194   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1195   return $self->search(undef, $attrs);
1196 }
1197
1198 =head2 next
1199
1200 =over 4
1201
1202 =item Arguments: none
1203
1204 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1205
1206 =back
1207
1208 Returns the next element in the resultset (C<undef> is there is none).
1209
1210 Can be used to efficiently iterate over records in the resultset:
1211
1212   my $rs = $schema->resultset('CD')->search;
1213   while (my $cd = $rs->next) {
1214     print $cd->title;
1215   }
1216
1217 Note that you need to store the resultset object, and call C<next> on it.
1218 Calling C<< resultset('Table')->next >> repeatedly will always return the
1219 first record from the resultset.
1220
1221 =cut
1222
1223 sub next {
1224   my ($self) = @_;
1225
1226   if (my $cache = $self->get_cache) {
1227     $self->{all_cache_position} ||= 0;
1228     return $cache->[$self->{all_cache_position}++];
1229   }
1230
1231   if ($self->{attrs}{cache}) {
1232     delete $self->{pager};
1233     $self->{all_cache_position} = 1;
1234     return ($self->all)[0];
1235   }
1236
1237   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1238
1239   $self->{_stashed_results} = $self->_construct_results
1240     or return undef;
1241
1242   return shift @{$self->{_stashed_results}};
1243 }
1244
1245 # Constructs as many results as it can in one pass while respecting
1246 # cursor laziness. Several modes of operation:
1247 #
1248 # * Always builds everything present in @{$self->{_stashed_rows}}
1249 # * If called with $fetch_all true - pulls everything off the cursor and
1250 #   builds all result structures (or objects) in one pass
1251 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1252 #   and if the resultset is ordered properly by the left side:
1253 #   * Fetches stuff off the cursor until the "master object" changes,
1254 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1255 #   OR
1256 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1257 #     was requested (there is no other way to collapse except for an
1258 #     eager cursor)
1259 # * If no collapse is requested - just get the next row, construct and
1260 #   return
1261 sub _construct_results {
1262   my ($self, $fetch_all) = @_;
1263
1264   my $rsrc = $self->result_source;
1265   my $attrs = $self->_resolved_attrs;
1266
1267   if (
1268     ! $fetch_all
1269       and
1270     ! $attrs->{order_by}
1271       and
1272     $attrs->{collapse}
1273       and
1274     my @pcols = $rsrc->primary_columns
1275   ) {
1276     # default order for collapsing unless the user asked for something
1277     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1278     $attrs->{_ordered_for_collapse} = 1;
1279     $attrs->{_order_is_artificial} = 1;
1280   }
1281
1282   # this will be used as both initial raw-row collector AND as a RV of
1283   # _construct_results. Not regrowing the array twice matters a lot...
1284   # a surprising amount actually
1285   my $rows = delete $self->{_stashed_rows};
1286
1287   my $cursor; # we may not need one at all
1288
1289   my $did_fetch_all = $fetch_all;
1290
1291   if ($fetch_all) {
1292     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1293     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1294   }
1295   elsif( $attrs->{collapse} ) {
1296
1297     # a cursor will need to be closed over in case of collapse
1298     $cursor = $self->cursor;
1299
1300     $attrs->{_ordered_for_collapse} = (
1301       (
1302         $attrs->{order_by}
1303           and
1304         $rsrc->schema
1305               ->storage
1306                ->_extract_colinfo_of_stable_main_source_order_by_portion($attrs)
1307       ) ? 1 : 0
1308     ) unless defined $attrs->{_ordered_for_collapse};
1309
1310     if (! $attrs->{_ordered_for_collapse}) {
1311       $did_fetch_all = 1;
1312
1313       # instead of looping over ->next, use ->all in stealth mode
1314       # *without* calling a ->reset afterwards
1315       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1316       if (! $cursor->{_done}) {
1317         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1318         $cursor->{_done} = 1;
1319       }
1320     }
1321   }
1322
1323   if (! $did_fetch_all and ! @{$rows||[]} ) {
1324     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1325     $cursor ||= $self->cursor;
1326     if (scalar (my @r = $cursor->next) ) {
1327       $rows = [ \@r ];
1328     }
1329   }
1330
1331   return undef unless @{$rows||[]};
1332
1333   # sanity check - people are too clever for their own good
1334   if ($attrs->{collapse} and my $aliastypes = $attrs->{_last_sqlmaker_alias_map} ) {
1335
1336     my $multiplied_selectors;
1337     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1338       if (
1339         $aliastypes->{multiplying}{$sel_alias}
1340           or
1341         $aliastypes->{premultiplied}{$sel_alias}
1342       ) {
1343         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1344       }
1345     }
1346
1347     for my $i (0 .. $#{$attrs->{as}} ) {
1348       my $sel = $attrs->{select}[$i];
1349
1350       if (ref $sel eq 'SCALAR') {
1351         $sel = $$sel;
1352       }
1353       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1354         $sel = $$sel->[0];
1355       }
1356
1357       $self->throw_exception(
1358         'Result collapse not possible - selection from a has_many source redirected to the main object'
1359       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1360     }
1361   }
1362
1363   # hotspot - skip the setter
1364   my $res_class = $self->_result_class;
1365
1366   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1367     $res_class->can ('inflate_result')
1368       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1369   };
1370
1371   my $infmap = $attrs->{as};
1372
1373   $self->{_result_inflator}{is_core_row} = ( (
1374     $inflator_cref
1375       ==
1376     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1377   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1378
1379   $self->{_result_inflator}{is_hri} = ( (
1380     ! $self->{_result_inflator}{is_core_row}
1381       and
1382     $inflator_cref == \&DBIx::Class::ResultClass::HashRefInflator::inflate_result
1383   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1384
1385
1386   if ($attrs->{_simple_passthrough_construction}) {
1387     # construct a much simpler array->hash folder for the one-table HRI cases right here
1388     if ($self->{_result_inflator}{is_hri}) {
1389       for my $r (@$rows) {
1390         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1391       }
1392     }
1393     # FIXME SUBOPTIMAL this is a very very very hot spot
1394     # while rather optimal we can *still* do much better, by
1395     # building a smarter Row::inflate_result(), and
1396     # switch to feeding it data via a much leaner interface
1397     #
1398     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1399     # this particular resultset size
1400     elsif ( $self->{_result_inflator}{is_core_row} and @$rows < 60 ) {
1401       for my $r (@$rows) {
1402         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1403       }
1404     }
1405     else {
1406       eval sprintf (
1407         ( $self->{_result_inflator}{is_core_row}
1408           ? '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows'
1409           # a custom inflator may be a multiplier/reductor - put it in direct list ctx
1410           : '@$rows = map { $inflator_cref->($res_class, $rsrc, { %s } ) } @$rows'
1411         ),
1412         ( join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap ) )
1413       ) . '; 1' or die;
1414     }
1415   }
1416   else {
1417     my $parser_type =
1418         $self->{_result_inflator}{is_hri}       ? 'hri'
1419       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1420       :                                           'classic_nonpruning'
1421     ;
1422
1423     unless( $self->{_row_parser}{$parser_type}{cref} ) {
1424
1425       # $args and $attrs to _mk_row_parser are separated to delineate what is
1426       # core collapser stuff and what is dbic $rs specific
1427       $self->{_row_parser}{$parser_type}{src} = $rsrc->_mk_row_parser({
1428         inflate_map => $infmap,
1429         collapse => $attrs->{collapse},
1430         premultiplied => $attrs->{_main_source_premultiplied},
1431         hri_style => $self->{_result_inflator}{is_hri},
1432         prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1433       }, $attrs);
1434
1435       $self->{_row_parser}{$parser_type}{cref} = do {
1436         package # hide form PAUSE
1437           DBIx::Class::__GENERATED_ROW_PARSER__;
1438
1439         eval $self->{_row_parser}{$parser_type}{src};
1440       } || die $@;
1441     }
1442
1443     # this needs to close over the *current* cursor, hence why it is not cached above
1444     my $next_cref = ($did_fetch_all or ! $attrs->{collapse})
1445       ? undef
1446       : sub {
1447         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1448         my @r = $cursor->next or return;
1449         \@r
1450       }
1451     ;
1452
1453     $self->{_row_parser}{$parser_type}{cref}->(
1454       $rows,
1455       $next_cref,
1456       ( $self->{_stashed_rows} = [] ),
1457       ( my $null_violations = {} ),
1458     );
1459
1460     $self->throw_exception(
1461       'Collapse aborted - the following columns are declared (or defaulted to) '
1462     . 'non-nullable within DBIC but NULLs were retrieved from storage: '
1463     . join( ', ', map { "'$infmap->[$_]'" } sort { $a <=> $b } keys %$null_violations )
1464     . ' within data row ' . dump_value({
1465       map {
1466         $infmap->[$_] =>
1467           ( ! defined $self->{_stashed_rows}[0][$_] or length $self->{_stashed_rows}[0][$_] < 50 )
1468             ? $self->{_stashed_rows}[0][$_]
1469             : substr( $self->{_stashed_rows}[0][$_], 0, 50 ) . '...'
1470       } 0 .. $#{$self->{_stashed_rows}[0]}
1471     })
1472     ) if keys %$null_violations;
1473
1474     # simple in-place substitution, does not regrow $rows
1475     if ($self->{_result_inflator}{is_core_row}) {
1476       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1477     }
1478     # Special-case multi-object HRI - there is no $inflator_cref pass at all
1479     elsif ( ! $self->{_result_inflator}{is_hri} ) {
1480       # the inflator may be a multiplier/reductor - put it in list ctx
1481       @$rows = map { $inflator_cref->($res_class, $rsrc, @$_) } @$rows;
1482     }
1483   }
1484
1485   # The @$rows check seems odd at first - why wouldn't we want to warn
1486   # regardless? The issue is things like find() etc, where the user
1487   # *knows* only one result will come back. In these cases the ->all
1488   # is not a pessimization, but rather something we actually want
1489   carp_unique(
1490     'Unable to properly collapse has_many results in iterator mode due '
1491   . 'to order criteria - performed an eager cursor slurp underneath. '
1492   . 'Consider using ->all() instead'
1493   ) if ( ! $fetch_all and @$rows > 1 );
1494
1495   return $rows;
1496 }
1497
1498 =head2 result_source
1499
1500 =over 4
1501
1502 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1503
1504 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1505
1506 =back
1507
1508 An accessor for the primary ResultSource object from which this ResultSet
1509 is derived.
1510
1511 =head2 result_class
1512
1513 =over 4
1514
1515 =item Arguments: $result_class?
1516
1517 =item Return Value: $result_class
1518
1519 =back
1520
1521 An accessor for the class to use when creating result objects. Defaults to
1522 C<< result_source->result_class >> - which in most cases is the name of the
1523 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1524
1525 Note that changing the result_class will also remove any components
1526 that were originally loaded in the source class via
1527 L<load_components|Class::C3::Componentised/load_components( @comps )>.
1528 Any overloaded methods in the original source class will not run.
1529
1530 =cut
1531
1532 sub result_class {
1533   my ($self, $result_class) = @_;
1534   if ($result_class) {
1535
1536     # don't fire this for an object
1537     $self->ensure_class_loaded($result_class)
1538       unless ref($result_class);
1539
1540     if ($self->get_cache) {
1541       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1542     }
1543     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1544     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1545       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1546     }
1547
1548     $self->_result_class($result_class);
1549
1550     delete $self->{_result_inflator};
1551   }
1552   $self->_result_class;
1553 }
1554
1555 =head2 count
1556
1557 =over 4
1558
1559 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1560
1561 =item Return Value: $count
1562
1563 =back
1564
1565 Performs an SQL C<COUNT> with the same query as the resultset was built
1566 with to find the number of elements. Passing arguments is equivalent to
1567 C<< $rs->search ($cond, \%attrs)->count >>
1568
1569 =cut
1570
1571 sub count {
1572   my $self = shift;
1573   return $self->search(@_)->count if @_ and defined $_[0];
1574   return scalar @{ $self->get_cache } if $self->get_cache;
1575
1576   my $attrs = { %{ $self->_resolved_attrs } };
1577
1578   # this is a little optimization - it is faster to do the limit
1579   # adjustments in software, instead of a subquery
1580   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1581
1582   my $crs;
1583   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1584     $crs = $self->_count_subq_rs ($attrs);
1585   }
1586   else {
1587     $crs = $self->_count_rs ($attrs);
1588   }
1589   my $count = $crs->next;
1590
1591   $count -= $offset if $offset;
1592   $count = $rows if $rows and $rows < $count;
1593   $count = 0 if ($count < 0);
1594
1595   return $count;
1596 }
1597
1598 =head2 count_rs
1599
1600 =over 4
1601
1602 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1603
1604 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1605
1606 =back
1607
1608 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1609 This can be very handy for subqueries:
1610
1611   ->search( { amount => $some_rs->count_rs->as_query } )
1612
1613 As with regular resultsets the SQL query will be executed only after
1614 the resultset is accessed via L</next> or L</all>. That would return
1615 the same single value obtainable via L</count>.
1616
1617 =cut
1618
1619 sub count_rs {
1620   my $self = shift;
1621   return $self->search(@_)->count_rs if @_;
1622
1623   # this may look like a lack of abstraction (count() does about the same)
1624   # but in fact an _rs *must* use a subquery for the limits, as the
1625   # software based limiting can not be ported if this $rs is to be used
1626   # in a subquery itself (i.e. ->as_query)
1627   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1628     return $self->_count_subq_rs($self->{_attrs});
1629   }
1630   else {
1631     return $self->_count_rs($self->{_attrs});
1632   }
1633 }
1634
1635 #
1636 # returns a ResultSetColumn object tied to the count query
1637 #
1638 sub _count_rs {
1639   my ($self, $attrs) = @_;
1640
1641   my $rsrc = $self->result_source;
1642
1643   my $tmp_attrs = { %$attrs };
1644   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1645   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1646
1647   # overwrite the selector (supplied by the storage)
1648   $rsrc->resultset_class->new($rsrc, {
1649     %$tmp_attrs,
1650     select => $rsrc->schema->storage->_count_select ($rsrc, $attrs),
1651     as => 'count',
1652   })->get_column ('count');
1653 }
1654
1655 #
1656 # same as above but uses a subquery
1657 #
1658 sub _count_subq_rs {
1659   my ($self, $attrs) = @_;
1660
1661   my $rsrc = $self->result_source;
1662
1663   my $sub_attrs = { %$attrs };
1664   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1665   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1666
1667   # if we multi-prefetch we group_by something unique, as this is what we would
1668   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1669   if ( $attrs->{collapse}  ) {
1670     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1671       $rsrc->_identifying_column_set || $self->throw_exception(
1672         'Unable to construct a unique group_by criteria properly collapsing the '
1673       . 'has_many prefetch before count()'
1674       );
1675     } ]
1676   }
1677
1678   # Calculate subquery selector
1679   if (my $g = $sub_attrs->{group_by}) {
1680
1681     my $sql_maker = $rsrc->schema->storage->sql_maker;
1682
1683     # necessary as the group_by may refer to aliased functions
1684     my $sel_index;
1685     for my $sel (@{$attrs->{select}}) {
1686       $sel_index->{$sel->{-as}} = $sel
1687         if (ref $sel eq 'HASH' and $sel->{-as});
1688     }
1689
1690     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1691     # also look for named aggregates referred in the having clause
1692     # having often contains scalarrefs - thus parse it out entirely
1693     my @parts = @$g;
1694     if ($attrs->{having}) {
1695       local $sql_maker->{having_bind};
1696       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1697       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1698       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1699         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1700         # if we don't unset it we screw up retarded but unfortunately working
1701         # 'MAX(foo.bar)' => { '>', 3 }
1702         $sql_maker->{name_sep} = '';
1703       }
1704
1705       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1706
1707       my $having_sql = $sql_maker->_parse_rs_attrs ({ having => $attrs->{having} });
1708       my %seen_having;
1709
1710       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1711       # and if all fails for an utterly naive quoted scalar-with-function
1712       while ($having_sql =~ /
1713         $rquote $sep $lquote (.+?) $rquote
1714           |
1715         [\s,] \w+ \. (\w+) [\s,]
1716           |
1717         [\s,] $lquote (.+?) $rquote [\s,]
1718       /gx) {
1719         my $part = $1 || $2 || $3;  # one of them matched if we got here
1720         unless ($seen_having{$part}++) {
1721           push @parts, $part;
1722         }
1723       }
1724     }
1725
1726     for (@parts) {
1727       my $colpiece = $sel_index->{$_} || $_;
1728
1729       # unqualify join-based group_by's. Arcane but possible query
1730       # also horrible horrible hack to alias a column (not a func.)
1731       # (probably need to introduce SQLA syntax)
1732       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1733         my $as = $colpiece;
1734         $as =~ s/\./__/;
1735         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1736       }
1737       push @{$sub_attrs->{select}}, $colpiece;
1738     }
1739   }
1740   else {
1741     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1742     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1743   }
1744
1745   return $rsrc->resultset_class
1746                ->new ($rsrc, $sub_attrs)
1747                 ->as_subselect_rs
1748                  ->search ({}, { columns => { count => $rsrc->schema->storage->_count_select ($rsrc, $attrs) } })
1749                   ->get_column ('count');
1750 }
1751
1752
1753 =head2 count_literal
1754
1755 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1756 should only be used in that context. See L</search_literal> for further info.
1757
1758 =over 4
1759
1760 =item Arguments: $sql_fragment, @standalone_bind_values
1761
1762 =item Return Value: $count
1763
1764 =back
1765
1766 Counts the results in a literal query. Equivalent to calling L</search_literal>
1767 with the passed arguments, then L</count>.
1768
1769 =cut
1770
1771 sub count_literal :DBIC_method_is_indirect_sugar {
1772   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1773   shift->search_literal(@_)->count
1774 }
1775
1776 =head2 all
1777
1778 =over 4
1779
1780 =item Arguments: none
1781
1782 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1783
1784 =back
1785
1786 Returns all elements in the resultset.
1787
1788 =cut
1789
1790 sub all {
1791   my $self = shift;
1792   if(@_) {
1793     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1794   }
1795
1796   delete @{$self}{qw/_stashed_rows _stashed_results/};
1797
1798   if (my $c = $self->get_cache) {
1799     return @$c;
1800   }
1801
1802   $self->cursor->reset;
1803
1804   my $objs = $self->_construct_results('fetch_all') || [];
1805
1806   $self->set_cache($objs) if $self->{attrs}{cache};
1807
1808   return @$objs;
1809 }
1810
1811 =head2 reset
1812
1813 =over 4
1814
1815 =item Arguments: none
1816
1817 =item Return Value: $self
1818
1819 =back
1820
1821 Resets the resultset's cursor, so you can iterate through the elements again.
1822 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1823 another query.
1824
1825 =cut
1826
1827 sub reset {
1828   my ($self) = @_;
1829
1830   delete @{$self}{qw/_stashed_rows _stashed_results/};
1831   $self->{all_cache_position} = 0;
1832   $self->cursor->reset;
1833   return $self;
1834 }
1835
1836 =head2 first
1837
1838 =over 4
1839
1840 =item Arguments: none
1841
1842 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1843
1844 =back
1845
1846 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1847 an object for the first result (or C<undef> if the resultset is empty).
1848
1849 =cut
1850
1851 sub first :DBIC_method_is_indirect_sugar {
1852   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
1853   return $_[0]->reset->next;
1854 }
1855
1856
1857 # _rs_update_delete
1858 #
1859 # Determines whether and what type of subquery is required for the $rs operation.
1860 # If grouping is necessary either supplies its own, or verifies the current one
1861 # After all is done delegates to the proper storage method.
1862
1863 sub _rs_update_delete {
1864   my ($self, $op, $values) = @_;
1865
1866   my $rsrc = $self->result_source;
1867   my $storage = $rsrc->schema->storage;
1868
1869   my $attrs = { %{$self->_resolved_attrs} };
1870
1871   my $join_classifications;
1872   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1873
1874   # do we need a subquery for any reason?
1875   my $needs_subq = (
1876     defined $existing_group_by
1877       or
1878     # if {from} is unparseable wrap a subq
1879     ref($attrs->{from}) ne 'ARRAY'
1880       or
1881     # limits call for a subq
1882     $self->_has_resolved_attr(qw/rows offset/)
1883   );
1884
1885   # simplify the joinmap, so we can further decide if a subq is necessary
1886   if (!$needs_subq and @{$attrs->{from}} > 1) {
1887
1888     ($attrs->{from}, $join_classifications) =
1889       $storage->_prune_unused_joins ($attrs);
1890
1891     # any non-pruneable non-local restricting joins imply subq
1892     $needs_subq = grep { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1893   }
1894
1895   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1896   $needs_subq ||= (
1897     (ref $attrs->{from}[0]) ne 'HASH'
1898       or
1899     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1900   );
1901
1902   my ($cond, $guard);
1903   # do we need anything like a subquery?
1904   if (! $needs_subq) {
1905     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1906     # a condition containing 'me' or other table prefixes will not work
1907     # at all. Tell SQLMaker to dequalify idents via a gross hack.
1908     $cond = do {
1909       my $sqla = $rsrc->schema->storage->sql_maker;
1910       local $sqla->{_dequalify_idents} = 1;
1911       \[ $sqla->_recurse_where($self->{cond}) ];
1912     };
1913   }
1914   else {
1915     # we got this far - means it is time to wrap a subquery
1916     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1917       sprintf(
1918         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1919         $op,
1920         $rsrc->source_name,
1921       )
1922     );
1923
1924     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1925     delete $attrs->{$_} for qw/select as collapse/;
1926     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1927
1928     # this will be consumed by the pruner waaaaay down the stack
1929     $attrs->{_force_prune_multiplying_joins} = 1;
1930
1931     my $subrs = (ref $self)->new($rsrc, $attrs);
1932
1933     if (@$idcols == 1) {
1934       $cond = { $idcols->[0] => { -in => $subrs->as_query } };
1935     }
1936     elsif ($storage->_use_multicolumn_in) {
1937       # no syntax for calling this properly yet
1938       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1939       $cond = $storage->sql_maker->_where_op_multicolumn_in (
1940         $idcols, # how do I convey a list of idents...? can binds reside on lhs?
1941         $subrs->as_query
1942       ),
1943     }
1944     else {
1945       # if all else fails - get all primary keys and operate over a ORed set
1946       # wrap in a transaction for consistency
1947       # this is where the group_by/multiplication starts to matter
1948       if (
1949         $existing_group_by
1950           or
1951         # we do not need to check pre-multipliers, since if the premulti is there, its
1952         # parent (who is multi) will be there too
1953         keys %{ $join_classifications->{multiplying} || {} }
1954       ) {
1955         # make sure if there is a supplied group_by it matches the columns compiled above
1956         # perfectly. Anything else can not be sanely executed on most databases so croak
1957         # right then and there
1958         if ($existing_group_by) {
1959           my @current_group_by = map
1960             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1961             @$existing_group_by
1962           ;
1963
1964           if (
1965             join ("\x00", sort @current_group_by)
1966               ne
1967             join ("\x00", sort @{$attrs->{columns}} )
1968           ) {
1969             $self->throw_exception (
1970               "You have just attempted a $op operation on a resultset which does group_by"
1971               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1972               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1973               . ' kind of queries. Please retry the operation with a modified group_by or'
1974               . ' without using one at all.'
1975             );
1976           }
1977         }
1978
1979         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
1980       }
1981
1982       $guard = $storage->txn_scope_guard;
1983
1984       for my $row ($subrs->cursor->all) {
1985         push @$cond, { map
1986           { $idcols->[$_] => $row->[$_] }
1987           (0 .. $#$idcols)
1988         };
1989       }
1990     }
1991   }
1992
1993   my $res = $cond ? $storage->$op (
1994     $rsrc,
1995     $op eq 'update' ? $values : (),
1996     $cond,
1997   ) : '0E0';
1998
1999   $guard->commit if $guard;
2000
2001   return $res;
2002 }
2003
2004 =head2 update
2005
2006 =over 4
2007
2008 =item Arguments: \%values
2009
2010 =item Return Value: $underlying_storage_rv
2011
2012 =back
2013
2014 Sets the specified columns in the resultset to the supplied values in a
2015 single query. Note that this will not run any accessor/set_column/update
2016 triggers, nor will it update any result object instances derived from this
2017 resultset (this includes the contents of the L<resultset cache|/set_cache>
2018 if any). See L</update_all> if you need to execute any on-update
2019 triggers or cascades defined either by you or a
2020 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2021
2022 The return value is a pass through of what the underlying
2023 storage backend returned, and may vary. See L<DBI/execute> for the most
2024 common case.
2025
2026 =head3 CAVEAT
2027
2028 Note that L</update> does not process/deflate any of the values passed in.
2029 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2030 ensure manually that any value passed to this method will stringify to
2031 something the RDBMS knows how to deal with. A notable example is the
2032 handling of L<DateTime> objects, for more info see:
2033 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2034
2035 =cut
2036
2037 sub update {
2038   my ($self, $values) = @_;
2039   $self->throw_exception('Values for update must be a hash')
2040     unless ref $values eq 'HASH';
2041
2042   return $self->_rs_update_delete ('update', $values);
2043 }
2044
2045 =head2 update_all
2046
2047 =over 4
2048
2049 =item Arguments: \%values
2050
2051 =item Return Value: 1
2052
2053 =back
2054
2055 Fetches all objects and updates them one at a time via
2056 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2057 triggers, while L</update> will not.
2058
2059 =cut
2060
2061 sub update_all {
2062   my ($self, $values) = @_;
2063   $self->throw_exception('Values for update_all must be a hash')
2064     unless ref $values eq 'HASH';
2065
2066   my $guard = $self->result_source->schema->txn_scope_guard;
2067   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2068   $guard->commit;
2069   return 1;
2070 }
2071
2072 =head2 delete
2073
2074 =over 4
2075
2076 =item Arguments: none
2077
2078 =item Return Value: $underlying_storage_rv
2079
2080 =back
2081
2082 Deletes the rows matching this resultset in a single query. Note that this
2083 will not run any delete triggers, nor will it alter the
2084 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2085 derived from this resultset (this includes the contents of the
2086 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2087 execute any on-delete triggers or cascades defined either by you or a
2088 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2089
2090 The return value is a pass through of what the underlying storage backend
2091 returned, and may vary. See L<DBI/execute> for the most common case.
2092
2093 =cut
2094
2095 sub delete {
2096   my $self = shift;
2097   $self->throw_exception('delete does not accept any arguments')
2098     if @_;
2099
2100   return $self->_rs_update_delete ('delete');
2101 }
2102
2103 =head2 delete_all
2104
2105 =over 4
2106
2107 =item Arguments: none
2108
2109 =item Return Value: 1
2110
2111 =back
2112
2113 Fetches all objects and deletes them one at a time via
2114 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2115 triggers, while L</delete> will not.
2116
2117 =cut
2118
2119 sub delete_all {
2120   my $self = shift;
2121   $self->throw_exception('delete_all does not accept any arguments')
2122     if @_;
2123
2124   my $guard = $self->result_source->schema->txn_scope_guard;
2125   $_->delete for $self->all;
2126   $guard->commit;
2127   return 1;
2128 }
2129
2130 =head2 populate
2131
2132 =over 4
2133
2134 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2135
2136 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2137
2138 =back
2139
2140 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2141 arrayrefs.
2142
2143 =over
2144
2145 =item NOTE
2146
2147 The context of this method call has an important effect on what is
2148 submitted to storage. In void context data is fed directly to fastpath
2149 insertion routines provided by the underlying storage (most often
2150 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2151 L<insert|DBIx::Class::Row/insert> calls on the
2152 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2153 augmentation of these methods provided by components. For example if you
2154 are using something like L<DBIx::Class::UUIDColumns> to create primary
2155 keys for you, you will find that your PKs are empty.  In this case you
2156 will have to explicitly force scalar or list context in order to create
2157 those values.
2158
2159 =back
2160
2161 In non-void (scalar or list) context, this method is simply a wrapper
2162 for L</create>. Depending on list or scalar context either a list of
2163 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2164 containing these objects is returned.
2165
2166 When supplying data in "arrayref of arrayrefs" invocation style, the
2167 first element should be a list of column names and each subsequent
2168 element should be a data value in the earlier specified column order.
2169 For example:
2170
2171   $schema->resultset("Artist")->populate([
2172     [ qw( artistid name ) ],
2173     [ 100, 'A Formally Unknown Singer' ],
2174     [ 101, 'A singer that jumped the shark two albums ago' ],
2175     [ 102, 'An actually cool singer' ],
2176   ]);
2177
2178 For the arrayref of hashrefs style each hashref should be a structure
2179 suitable for passing to L</create>. Multi-create is also permitted with
2180 this syntax.
2181
2182   $schema->resultset("Artist")->populate([
2183      { artistid => 4, name => 'Manufactured Crap', cds => [
2184         { title => 'My First CD', year => 2006 },
2185         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2186       ],
2187      },
2188      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2189         { title => 'My parents sold me to a record company', year => 2005 },
2190         { title => 'Why Am I So Ugly?', year => 2006 },
2191         { title => 'I Got Surgery and am now Popular', year => 2007 }
2192       ],
2193      },
2194   ]);
2195
2196 If you attempt a void-context multi-create as in the example above (each
2197 Artist also has the related list of CDs), and B<do not> supply the
2198 necessary autoinc foreign key information, this method will proxy to the
2199 less efficient L</create>, and then throw the Result objects away. In this
2200 case there are obviously no benefits to using this method over L</create>.
2201
2202 =cut
2203
2204 sub populate {
2205   my $self = shift;
2206
2207   # this is naive and just a quick check
2208   # the types will need to be checked more thoroughly when the
2209   # multi-source populate gets added
2210   my $data = (
2211     ref $_[0] eq 'ARRAY'
2212       and
2213     ( @{$_[0]} or return )
2214       and
2215     ( ref $_[0][0] eq 'HASH' or ref $_[0][0] eq 'ARRAY' )
2216       and
2217     $_[0]
2218   ) or $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2219
2220   # FIXME - no cref handling
2221   # At this point assume either hashes or arrays
2222
2223   my $rsrc = $self->result_source;
2224
2225   if(defined wantarray) {
2226     my (@results, $guard);
2227
2228     if (ref $data->[0] eq 'ARRAY') {
2229       # column names only, nothing to do
2230       return if @$data == 1;
2231
2232       $guard = $rsrc->schema->storage->txn_scope_guard
2233         if @$data > 2;
2234
2235       @results = map
2236         { my $vals = $_; $self->new_result({ map { $data->[0][$_] => $vals->[$_] } 0..$#{$data->[0]} })->insert }
2237         @{$data}[1 .. $#$data]
2238       ;
2239     }
2240     else {
2241
2242       $guard = $rsrc->schema->storage->txn_scope_guard
2243         if @$data > 1;
2244
2245       @results = map { $self->new_result($_)->insert } @$data;
2246     }
2247
2248     $guard->commit if $guard;
2249     return wantarray ? @results : \@results;
2250   }
2251
2252   # we have to deal with *possibly incomplete* related data
2253   # this means we have to walk the data structure twice
2254   # whether we want this or not
2255   # jnap, I hate you ;)
2256   my $rel_info = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2257
2258   my ($colinfo, $colnames, $slices_with_rels);
2259   my $data_start = 0;
2260
2261   DATA_SLICE:
2262   for my $i (0 .. $#$data) {
2263
2264     my $current_slice_seen_rel_infos;
2265
2266 ### Determine/Supplement collists
2267 ### BEWARE - This is a hot piece of code, a lot of weird idioms were used
2268     if( ref $data->[$i] eq 'ARRAY' ) {
2269
2270       # positional(!) explicit column list
2271       if ($i == 0) {
2272         # column names only, nothing to do
2273         return if @$data == 1;
2274
2275         $colinfo->{$data->[0][$_]} = { pos => $_, name => $data->[0][$_] } and push @$colnames, $data->[0][$_]
2276           for 0 .. $#{$data->[0]};
2277
2278         $data_start = 1;
2279
2280         next DATA_SLICE;
2281       }
2282       else {
2283         for (values %$colinfo) {
2284           if ($_->{is_rel} ||= (
2285             $rel_info->{$_->{name}}
2286               and
2287             (
2288               ref $data->[$i][$_->{pos}] eq 'ARRAY'
2289                 or
2290               ref $data->[$i][$_->{pos}] eq 'HASH'
2291                 or
2292               ( defined blessed $data->[$i][$_->{pos}] and $data->[$i][$_->{pos}]->isa('DBIx::Class::Row') )
2293             )
2294               and
2295             1
2296           )) {
2297
2298             # moar sanity check... sigh
2299             for ( ref $data->[$i][$_->{pos}] eq 'ARRAY' ? @{$data->[$i][$_->{pos}]} : $data->[$i][$_->{pos}] ) {
2300               if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2301                 carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2302                 return my $throwaway = $self->populate(@_);
2303               }
2304             }
2305
2306             push @$current_slice_seen_rel_infos, $rel_info->{$_->{name}};
2307           }
2308         }
2309       }
2310
2311      if ($current_slice_seen_rel_infos) {
2312         push @$slices_with_rels, { map { $colnames->[$_] => $data->[$i][$_] } 0 .. $#$colnames };
2313
2314         # this is needed further down to decide whether or not to fallback to create()
2315         $colinfo->{$colnames->[$_]}{seen_null} ||= ! defined $data->[$i][$_]
2316           for 0 .. $#$colnames;
2317       }
2318     }
2319     elsif( ref $data->[$i] eq 'HASH' ) {
2320
2321       for ( sort keys %{$data->[$i]} ) {
2322
2323         $colinfo->{$_} ||= do {
2324
2325           $self->throw_exception("Column '$_' must be present in supplied explicit column list")
2326             if $data_start; # it will be 0 on AoH, 1 on AoA
2327
2328           push @$colnames, $_;
2329
2330           # RV
2331           { pos => $#$colnames, name => $_ }
2332         };
2333
2334         if ($colinfo->{$_}{is_rel} ||= (
2335           $rel_info->{$_}
2336             and
2337           (
2338             ref $data->[$i]{$_} eq 'ARRAY'
2339               or
2340             ref $data->[$i]{$_} eq 'HASH'
2341               or
2342             ( defined blessed $data->[$i]{$_} and $data->[$i]{$_}->isa('DBIx::Class::Row') )
2343           )
2344             and
2345           1
2346         )) {
2347
2348           # moar sanity check... sigh
2349           for ( ref $data->[$i]{$_} eq 'ARRAY' ? @{$data->[$i]{$_}} : $data->[$i]{$_} ) {
2350             if ( defined blessed $_ and $_->isa('DBIx::Class::Row' ) ) {
2351               carp_unique("Fast-path populate() with supplied related objects is not possible - falling back to regular create()");
2352               return my $throwaway = $self->populate(@_);
2353             }
2354           }
2355
2356           push @$current_slice_seen_rel_infos, $rel_info->{$_};
2357         }
2358       }
2359
2360       if ($current_slice_seen_rel_infos) {
2361         push @$slices_with_rels, $data->[$i];
2362
2363         # this is needed further down to decide whether or not to fallback to create()
2364         $colinfo->{$_}{seen_null} ||= ! defined $data->[$i]{$_}
2365           for keys %{$data->[$i]};
2366       }
2367     }
2368     else {
2369       $self->throw_exception('Unexpected populate() data structure member type: ' . ref $data->[$i] );
2370     }
2371
2372     if ( grep
2373       { $_->{attrs}{is_depends_on} }
2374       @{ $current_slice_seen_rel_infos || [] }
2375     ) {
2376       carp_unique("Fast-path populate() of belongs_to relationship data is not possible - falling back to regular create()");
2377       return my $throwaway = $self->populate(@_);
2378     }
2379   }
2380
2381   if( $slices_with_rels ) {
2382
2383     # need to exclude the rel "columns"
2384     $colnames = [ grep { ! $colinfo->{$_}{is_rel} } @$colnames ];
2385
2386     # extra sanity check - ensure the main source is in fact identifiable
2387     # the localizing of nullability is insane, but oh well... the use-case is legit
2388     my $ci = $rsrc->columns_info($colnames);
2389
2390     $ci->{$_} = { %{$ci->{$_}}, is_nullable => 0 }
2391       for grep { ! $colinfo->{$_}{seen_null} } keys %$ci;
2392
2393     unless( $rsrc->_identifying_column_set($ci) ) {
2394       carp_unique("Fast-path populate() of non-uniquely identifiable rows with related data is not possible - falling back to regular create()");
2395       return my $throwaway = $self->populate(@_);
2396     }
2397   }
2398
2399 ### inherit the data locked in the conditions of the resultset
2400   my ($rs_data) = $self->_merge_with_rscond({});
2401   delete @{$rs_data}{@$colnames};  # passed-in stuff takes precedence
2402
2403   # if anything left - decompose rs_data
2404   my $rs_data_vals;
2405   if (keys %$rs_data) {
2406      push @$rs_data_vals, $rs_data->{$_}
2407       for sort keys %$rs_data;
2408   }
2409
2410 ### start work
2411   my $guard;
2412   $guard = $rsrc->schema->storage->txn_scope_guard
2413     if $slices_with_rels;
2414
2415 ### main source data
2416   # FIXME - need to switch entirely to a coderef-based thing,
2417   # so that large sets aren't copied several times... I think
2418   $rsrc->schema->storage->_insert_bulk(
2419     $rsrc,
2420     [ @$colnames, sort keys %$rs_data ],
2421     [ map {
2422       ref $data->[$_] eq 'ARRAY'
2423       ? (
2424           $slices_with_rels ? [ @{$data->[$_]}[0..$#$colnames], @{$rs_data_vals||[]} ]  # the collist changed
2425         : $rs_data_vals     ? [ @{$data->[$_]}, @$rs_data_vals ]
2426         :                     $data->[$_]
2427       )
2428       : [ @{$data->[$_]}{@$colnames}, @{$rs_data_vals||[]} ]
2429     } $data_start .. $#$data ],
2430   );
2431
2432 ### do the children relationships
2433   if ( $slices_with_rels ) {
2434     my @rels = grep { $colinfo->{$_}{is_rel} } keys %$colinfo
2435       or die 'wtf... please report a bug with DBIC_TRACE=1 output (stacktrace)';
2436
2437     for my $sl (@$slices_with_rels) {
2438
2439       my ($main_proto, $main_proto_rs);
2440       for my $rel (@rels) {
2441         next unless defined $sl->{$rel};
2442
2443         $main_proto ||= {
2444           %$rs_data,
2445           (map { $_ => $sl->{$_} } @$colnames),
2446         };
2447
2448         unless (defined $colinfo->{$rel}{rs}) {
2449
2450           $colinfo->{$rel}{rs} = $rsrc->related_source($rel)->resultset;
2451
2452           $colinfo->{$rel}{fk_map} = { reverse %{ $rsrc->_resolve_relationship_condition(
2453             rel_name => $rel,
2454             self_alias => "\xFE", # irrelevant
2455             foreign_alias => "\xFF", # irrelevant
2456           )->{identity_map} || {} } };
2457
2458         }
2459
2460         $colinfo->{$rel}{rs}->search({ map # only so that we inherit them values properly, no actual search
2461           {
2462             $_ => { '=' =>
2463               ( $main_proto_rs ||= $rsrc->resultset->search($main_proto) )
2464                 ->get_column( $colinfo->{$rel}{fk_map}{$_} )
2465                  ->as_query
2466             }
2467           }
2468           keys %{$colinfo->{$rel}{fk_map}}
2469         })->populate( ref $sl->{$rel} eq 'ARRAY' ? $sl->{$rel} : [ $sl->{$rel} ] );
2470
2471         1;
2472       }
2473     }
2474   }
2475
2476   $guard->commit if $guard;
2477 }
2478
2479 =head2 pager
2480
2481 =over 4
2482
2483 =item Arguments: none
2484
2485 =item Return Value: L<$pager|Data::Page>
2486
2487 =back
2488
2489 Returns a L<Data::Page> object for the current resultset. Only makes
2490 sense for queries with a C<page> attribute.
2491
2492 To get the full count of entries for a paged resultset, call
2493 C<total_entries> on the L<Data::Page> object.
2494
2495 =cut
2496
2497 sub pager {
2498   my ($self) = @_;
2499
2500   return $self->{pager} if $self->{pager};
2501
2502   my $attrs = $self->{attrs};
2503   if (!defined $attrs->{page}) {
2504     $self->throw_exception("Can't create pager for non-paged rs");
2505   }
2506   elsif ($attrs->{page} <= 0) {
2507     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2508   }
2509   $attrs->{rows} ||= 10;
2510
2511   # throw away the paging flags and re-run the count (possibly
2512   # with a subselect) to get the real total count
2513   my $count_attrs = { %$attrs };
2514   delete @{$count_attrs}{qw/rows offset page pager/};
2515
2516   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2517
2518   require DBIx::Class::ResultSet::Pager;
2519   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2520     sub { $total_rs->count },  #lazy-get the total
2521     $attrs->{rows},
2522     $self->{attrs}{page},
2523   );
2524 }
2525
2526 =head2 page
2527
2528 =over 4
2529
2530 =item Arguments: $page_number
2531
2532 =item Return Value: L<$resultset|/search>
2533
2534 =back
2535
2536 Returns a resultset for the $page_number page of the resultset on which page
2537 is called, where each page contains a number of rows equal to the 'rows'
2538 attribute set on the resultset (10 by default).
2539
2540 =cut
2541
2542 sub page {
2543   my ($self, $page) = @_;
2544   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2545 }
2546
2547 =head2 new_result
2548
2549 =over 4
2550
2551 =item Arguments: \%col_data
2552
2553 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2554
2555 =back
2556
2557 Creates a new result object in the resultset's result class and returns
2558 it. The row is not inserted into the database at this point, call
2559 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2560 will tell you whether the result object has been inserted or not.
2561
2562 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2563
2564 =cut
2565
2566 sub new_result {
2567   my ($self, $values) = @_;
2568
2569   $self->throw_exception( "Result object instantiation requires a single hashref argument" )
2570     if @_ > 2 or ref $values ne 'HASH';
2571
2572   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2573
2574   my $new = $self->result_class->new({
2575     %$merged_cond,
2576     ( @$cols_from_relations
2577       ? (-cols_from_relations => $cols_from_relations)
2578       : ()
2579     ),
2580     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2581   });
2582
2583   if (
2584     reftype($new) eq 'HASH'
2585       and
2586     ! keys %$new
2587       and
2588     blessed($new)
2589   ) {
2590     carp_unique (sprintf (
2591       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2592       $self->result_class,
2593     ));
2594   }
2595
2596   $new;
2597 }
2598
2599 # _merge_with_rscond
2600 #
2601 # Takes a simple hash of K/V data and returns its copy merged with the
2602 # condition already present on the resultset. Additionally returns an
2603 # arrayref of value/condition names, which were inferred from related
2604 # objects (this is needed for in-memory related objects)
2605 sub _merge_with_rscond {
2606   my ($self, $data) = @_;
2607
2608   my ($implied_data, @cols_from_relations);
2609
2610   my $alias = $self->{attrs}{alias};
2611
2612   if (! defined $self->{cond}) {
2613     # just massage $data below
2614   }
2615   elsif ($self->{cond} eq UNRESOLVABLE_CONDITION) {
2616     $implied_data = $self->{attrs}{related_objects};  # nothing might have been inserted yet
2617     @cols_from_relations = keys %{ $implied_data || {} };
2618   }
2619   else {
2620     my $eqs = extract_equality_conditions( $self->{cond}, 'consider_nulls' );
2621     $implied_data = { map {
2622       ( ($eqs->{$_}||'') eq UNRESOLVABLE_CONDITION ) ? () : ( $_ => $eqs->{$_} )
2623     } keys %$eqs };
2624   }
2625
2626   return (
2627     { map
2628       { %{ $self->_remove_alias($_, $alias) } }
2629       # precedence must be given to passed values over values inherited from
2630       # the cond, so the order here is important.
2631       ( $implied_data||(), $data)
2632     },
2633     \@cols_from_relations
2634   );
2635 }
2636
2637 # _has_resolved_attr
2638 #
2639 # determines if the resultset defines at least one
2640 # of the attributes supplied
2641 #
2642 # used to determine if a subquery is necessary
2643 #
2644 # supports some virtual attributes:
2645 #   -join
2646 #     This will scan for any joins being present on the resultset.
2647 #     It is not a mere key-search but a deep inspection of {from}
2648 #
2649
2650 sub _has_resolved_attr {
2651   my ($self, @attr_names) = @_;
2652
2653   my $attrs = $self->_resolved_attrs;
2654
2655   my %extra_checks;
2656
2657   for my $n (@attr_names) {
2658     if (grep { $n eq $_ } (qw/-join/) ) {
2659       $extra_checks{$n}++;
2660       next;
2661     }
2662
2663     my $attr =  $attrs->{$n};
2664
2665     next if not defined $attr;
2666
2667     if (ref $attr eq 'HASH') {
2668       return 1 if keys %$attr;
2669     }
2670     elsif (ref $attr eq 'ARRAY') {
2671       return 1 if @$attr;
2672     }
2673     else {
2674       return 1 if $attr;
2675     }
2676   }
2677
2678   # a resolved join is expressed as a multi-level from
2679   return 1 if (
2680     $extra_checks{-join}
2681       and
2682     ref $attrs->{from} eq 'ARRAY'
2683       and
2684     @{$attrs->{from}} > 1
2685   );
2686
2687   return 0;
2688 }
2689
2690 # _remove_alias
2691 #
2692 # Remove the specified alias from the specified query hash. A copy is made so
2693 # the original query is not modified.
2694
2695 sub _remove_alias {
2696   my ($self, $query, $alias) = @_;
2697
2698   my %orig = %{ $query || {} };
2699   my %unaliased;
2700
2701   foreach my $key (keys %orig) {
2702     if ($key !~ /\./) {
2703       $unaliased{$key} = $orig{$key};
2704       next;
2705     }
2706     $unaliased{$1} = $orig{$key}
2707       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2708   }
2709
2710   return \%unaliased;
2711 }
2712
2713 =head2 as_query
2714
2715 =over 4
2716
2717 =item Arguments: none
2718
2719 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2720
2721 =back
2722
2723 Returns the SQL query and bind vars associated with the invocant.
2724
2725 This is generally used as the RHS for a subquery.
2726
2727 =cut
2728
2729 sub as_query {
2730   my $self = shift;
2731
2732   my $attrs = { %{ $self->_resolved_attrs } };
2733
2734   my $aq = $self->result_source->schema->storage->_select_args_to_query (
2735     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2736   );
2737
2738   $aq;
2739 }
2740
2741 =head2 find_or_new
2742
2743 =over 4
2744
2745 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2746
2747 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2748
2749 =back
2750
2751   my $artist = $schema->resultset('Artist')->find_or_new(
2752     { artist => 'fred' }, { key => 'artists' });
2753
2754   $cd->cd_to_producer->find_or_new({ producer => $producer },
2755                                    { key => 'primary' });
2756
2757 Find an existing record from this resultset using L</find>. if none exists,
2758 instantiate a new result object and return it. The object will not be saved
2759 into your storage until you call L<DBIx::Class::Row/insert> on it.
2760
2761 You most likely want this method when looking for existing rows using a unique
2762 constraint that is not the primary key, or looking for related rows.
2763
2764 If you want objects to be saved immediately, use L</find_or_create> instead.
2765
2766 B<Note>: Make sure to read the documentation of L</find> and understand the
2767 significance of the C<key> attribute, as its lack may skew your search, and
2768 subsequently result in spurious new objects.
2769
2770 B<Note>: Take care when using C<find_or_new> with a table having
2771 columns with default values that you intend to be automatically
2772 supplied by the database (e.g. an auto_increment primary key column).
2773 In normal usage, the value of such columns should NOT be included at
2774 all in the call to C<find_or_new>, even when set to C<undef>.
2775
2776 =cut
2777
2778 sub find_or_new {
2779   my $self     = shift;
2780   my $attrs    = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
2781   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2782   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2783     return $row;
2784   }
2785   return $self->new_result($hash);
2786 }
2787
2788 =head2 create
2789
2790 =over 4
2791
2792 =item Arguments: \%col_data
2793
2794 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2795
2796 =back
2797
2798 Attempt to create a single new row or a row with multiple related rows
2799 in the table represented by the resultset (and related tables). This
2800 will not check for duplicate rows before inserting, use
2801 L</find_or_create> to do that.
2802
2803 To create one row for this resultset, pass a hashref of key/value
2804 pairs representing the columns of the table and the values you wish to
2805 store. If the appropriate relationships are set up, foreign key fields
2806 can also be passed an object representing the foreign row, and the
2807 value will be set to its primary key.
2808
2809 To create related objects, pass a hashref of related-object column values
2810 B<keyed on the relationship name>. If the relationship is of type C<multi>
2811 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2812 The process will correctly identify columns holding foreign keys, and will
2813 transparently populate them from the keys of the corresponding relation.
2814 This can be applied recursively, and will work correctly for a structure
2815 with an arbitrary depth and width, as long as the relationships actually
2816 exists and the correct column data has been supplied.
2817
2818 Instead of hashrefs of plain related data (key/value pairs), you may
2819 also pass new or inserted objects. New objects (not inserted yet, see
2820 L</new_result>), will be inserted into their appropriate tables.
2821
2822 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2823
2824 Example of creating a new row.
2825
2826   $person_rs->create({
2827     name=>"Some Person",
2828     email=>"somebody@someplace.com"
2829   });
2830
2831 Example of creating a new row and also creating rows in a related C<has_many>
2832 or C<has_one> resultset.  Note Arrayref.
2833
2834   $artist_rs->create(
2835      { artistid => 4, name => 'Manufactured Crap', cds => [
2836         { title => 'My First CD', year => 2006 },
2837         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2838       ],
2839      },
2840   );
2841
2842 Example of creating a new row and also creating a row in a related
2843 C<belongs_to> resultset. Note Hashref.
2844
2845   $cd_rs->create({
2846     title=>"Music for Silly Walks",
2847     year=>2000,
2848     artist => {
2849       name=>"Silly Musician",
2850     }
2851   });
2852
2853 =over
2854
2855 =item WARNING
2856
2857 When subclassing ResultSet never attempt to override this method. Since
2858 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2859 lot of the internals simply never call it, so your override will be
2860 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2861 or L<DBIx::Class::Row/insert> depending on how early in the
2862 L</create> process you need to intervene. See also warning pertaining to
2863 L</new>.
2864
2865 =back
2866
2867 =cut
2868
2869 sub create :DBIC_method_is_indirect_sugar {
2870   #my ($self, $col_data) = @_;
2871   DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and fail_on_internal_call;
2872   return shift->new_result(shift)->insert;
2873 }
2874
2875 =head2 find_or_create
2876
2877 =over 4
2878
2879 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2880
2881 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2882
2883 =back
2884
2885   $cd->cd_to_producer->find_or_create({ producer => $producer },
2886                                       { key => 'primary' });
2887
2888 Tries to find a record based on its primary key or unique constraints; if none
2889 is found, creates one and returns that instead.
2890
2891   my $cd = $schema->resultset('CD')->find_or_create({
2892     cdid   => 5,
2893     artist => 'Massive Attack',
2894     title  => 'Mezzanine',
2895     year   => 2005,
2896   });
2897
2898 Also takes an optional C<key> attribute, to search by a specific key or unique
2899 constraint. For example:
2900
2901   my $cd = $schema->resultset('CD')->find_or_create(
2902     {
2903       artist => 'Massive Attack',
2904       title  => 'Mezzanine',
2905     },
2906     { key => 'cd_artist_title' }
2907   );
2908
2909 B<Note>: Make sure to read the documentation of L</find> and understand the
2910 significance of the C<key> attribute, as its lack may skew your search, and
2911 subsequently result in spurious row creation.
2912
2913 B<Note>: Because find_or_create() reads from the database and then
2914 possibly inserts based on the result, this method is subject to a race
2915 condition. Another process could create a record in the table after
2916 the find has completed and before the create has started. To avoid
2917 this problem, use find_or_create() inside a transaction.
2918
2919 B<Note>: Take care when using C<find_or_create> with a table having
2920 columns with default values that you intend to be automatically
2921 supplied by the database (e.g. an auto_increment primary key column).
2922 In normal usage, the value of such columns should NOT be included at
2923 all in the call to C<find_or_create>, even when set to C<undef>.
2924
2925 See also L</find> and L</update_or_create>. For information on how to declare
2926 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2927
2928 If you need to know if an existing row was found or a new one created use
2929 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2930 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2931 database!
2932
2933   my $cd = $schema->resultset('CD')->find_or_new({
2934     cdid   => 5,
2935     artist => 'Massive Attack',
2936     title  => 'Mezzanine',
2937     year   => 2005,
2938   });
2939
2940   if( !$cd->in_storage ) {
2941       # do some stuff
2942       $cd->insert;
2943   }
2944
2945 =cut
2946
2947 sub find_or_create {
2948   my $self     = shift;
2949   my $attrs    = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
2950   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2951   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2952     return $row;
2953   }
2954   return $self->new_result($hash)->insert;
2955 }
2956
2957 =head2 update_or_create
2958
2959 =over 4
2960
2961 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2962
2963 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2964
2965 =back
2966
2967   $resultset->update_or_create({ col => $val, ... });
2968
2969 Like L</find_or_create>, but if a row is found it is immediately updated via
2970 C<< $found_row->update (\%col_data) >>.
2971
2972
2973 Takes an optional C<key> attribute to search on a specific unique constraint.
2974 For example:
2975
2976   # In your application
2977   my $cd = $schema->resultset('CD')->update_or_create(
2978     {
2979       artist => 'Massive Attack',
2980       title  => 'Mezzanine',
2981       year   => 1998,
2982     },
2983     { key => 'cd_artist_title' }
2984   );
2985
2986   $cd->cd_to_producer->update_or_create({
2987     producer => $producer,
2988     name => 'harry',
2989   }, {
2990     key => 'primary',
2991   });
2992
2993 B<Note>: Make sure to read the documentation of L</find> and understand the
2994 significance of the C<key> attribute, as its lack may skew your search, and
2995 subsequently result in spurious row creation.
2996
2997 B<Note>: Take care when using C<update_or_create> with a table having
2998 columns with default values that you intend to be automatically
2999 supplied by the database (e.g. an auto_increment primary key column).
3000 In normal usage, the value of such columns should NOT be included at
3001 all in the call to C<update_or_create>, even when set to C<undef>.
3002
3003 See also L</find> and L</find_or_create>. For information on how to declare
3004 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
3005
3006 If you need to know if an existing row was updated or a new one created use
3007 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
3008 to call L<DBIx::Class::Row/insert> to save the newly created row to the
3009 database!
3010
3011 =cut
3012
3013 sub update_or_create {
3014   my $self = shift;
3015   my $attrs = (@_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {});
3016   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3017
3018   my $row = $self->find($cond, $attrs);
3019   if (defined $row) {
3020     $row->update($cond);
3021     return $row;
3022   }
3023
3024   return $self->new_result($cond)->insert;
3025 }
3026
3027 =head2 update_or_new
3028
3029 =over 4
3030
3031 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3032
3033 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3034
3035 =back
3036
3037   $resultset->update_or_new({ col => $val, ... });
3038
3039 Like L</find_or_new> but if a row is found it is immediately updated via
3040 C<< $found_row->update (\%col_data) >>.
3041
3042 For example:
3043
3044   # In your application
3045   my $cd = $schema->resultset('CD')->update_or_new(
3046     {
3047       artist => 'Massive Attack',
3048       title  => 'Mezzanine',
3049       year   => 1998,
3050     },
3051     { key => 'cd_artist_title' }
3052   );
3053
3054   if ($cd->in_storage) {
3055       # the cd was updated
3056   }
3057   else {
3058       # the cd is not yet in the database, let's insert it
3059       $cd->insert;
3060   }
3061
3062 B<Note>: Make sure to read the documentation of L</find> and understand the
3063 significance of the C<key> attribute, as its lack may skew your search, and
3064 subsequently result in spurious new objects.
3065
3066 B<Note>: Take care when using C<update_or_new> with a table having
3067 columns with default values that you intend to be automatically
3068 supplied by the database (e.g. an auto_increment primary key column).
3069 In normal usage, the value of such columns should NOT be included at
3070 all in the call to C<update_or_new>, even when set to C<undef>.
3071
3072 See also L</find>, L</find_or_create> and L</find_or_new>.
3073
3074 =cut
3075
3076 sub update_or_new {
3077     my $self  = shift;
3078     my $attrs = ( @_ > 1 && ref $_[-1] eq 'HASH' ? pop(@_) : {} );
3079     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3080
3081     my $row = $self->find( $cond, $attrs );
3082     if ( defined $row ) {
3083         $row->update($cond);
3084         return $row;
3085     }
3086
3087     return $self->new_result($cond);
3088 }
3089
3090 =head2 get_cache
3091
3092 =over 4
3093
3094 =item Arguments: none
3095
3096 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3097
3098 =back
3099
3100 Gets the contents of the cache for the resultset, if the cache is set.
3101
3102 The cache is populated either by using the L</prefetch> attribute to
3103 L</search> or by calling L</set_cache>.
3104
3105 =cut
3106
3107 sub get_cache {
3108   shift->{all_cache};
3109 }
3110
3111 =head2 set_cache
3112
3113 =over 4
3114
3115 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3116
3117 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3118
3119 =back
3120
3121 Sets the contents of the cache for the resultset. Expects an arrayref
3122 of objects of the same class as those produced by the resultset. Note that
3123 if the cache is set, the resultset will return the cached objects rather
3124 than re-querying the database even if the cache attr is not set.
3125
3126 The contents of the cache can also be populated by using the
3127 L</prefetch> attribute to L</search>.
3128
3129 =cut
3130
3131 sub set_cache {
3132   my ( $self, $data ) = @_;
3133   $self->throw_exception("set_cache requires an arrayref")
3134       if defined($data) && (ref $data ne 'ARRAY');
3135   $self->{all_cache} = $data;
3136 }
3137
3138 =head2 clear_cache
3139
3140 =over 4
3141
3142 =item Arguments: none
3143
3144 =item Return Value: undef
3145
3146 =back
3147
3148 Clears the cache for the resultset.
3149
3150 =cut
3151
3152 sub clear_cache {
3153   shift->set_cache(undef);
3154 }
3155
3156 =head2 is_paged
3157
3158 =over 4
3159
3160 =item Arguments: none
3161
3162 =item Return Value: true, if the resultset has been paginated
3163
3164 =back
3165
3166 =cut
3167
3168 sub is_paged {
3169   my ($self) = @_;
3170   return !!$self->{attrs}{page};
3171 }
3172
3173 =head2 is_ordered
3174
3175 =over 4
3176
3177 =item Arguments: none
3178
3179 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3180
3181 =back
3182
3183 =cut
3184
3185 sub is_ordered {
3186   my ($self) = @_;
3187   return scalar $self->result_source->schema->storage->_extract_order_criteria($self->{attrs}{order_by});
3188 }
3189
3190 =head2 related_resultset
3191
3192 =over 4
3193
3194 =item Arguments: $rel_name
3195
3196 =item Return Value: L<$resultset|/search>
3197
3198 =back
3199
3200 Returns a related resultset for the supplied relationship name.
3201
3202   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3203
3204 =cut
3205
3206 sub related_resultset {
3207   $_[0]->throw_exception(
3208     'Extra arguments to $rs->related_resultset() were always quietly '
3209   . 'discarded without consideration, you need to switch to '
3210   . '...->related_resultset( $relname )->search_rs( $search, $args ) instead.'
3211   ) if @_ > 2;
3212
3213   return $_[0]->{related_resultsets}{$_[1]}
3214     if defined $_[0]->{related_resultsets}{$_[1]};
3215
3216   my ($self, $rel) = @_;
3217
3218   return $self->{related_resultsets}{$rel} = do {
3219     my $rsrc = $self->result_source;
3220     my $rel_info = $rsrc->relationship_info($rel);
3221
3222     $self->throw_exception(
3223       "search_related: result source '" . $rsrc->source_name .
3224         "' has no such relationship $rel")
3225       unless $rel_info;
3226
3227     my $attrs = $self->_chain_relationship($rel);
3228
3229     my $storage = $rsrc->schema->storage;
3230
3231     # Previously this atribute was deleted (instead of being set as it is now)
3232     # Doing so seems to be harmless in all available test permutations
3233     # See also 01d59a6a6 and mst's comment below
3234     #
3235     $attrs->{alias} = $storage->relname_to_table_alias(
3236       $rel,
3237       $attrs->{seen_join}{$rel}
3238     );
3239
3240     # since this is search_related, and we already slid the select window inwards
3241     # (the select/as attrs were deleted in the beginning), we need to flip all
3242     # left joins to inner, so we get the expected results
3243     # read the comment on top of the actual function to see what this does
3244     $attrs->{from} = $storage->_inner_join_to_node( $attrs->{from}, $attrs->{alias} );
3245
3246     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3247     delete $attrs->{result_class};
3248
3249     my $new = do {
3250
3251       # The reason we do this now instead of passing the alias to the
3252       # search_rs below is that if you wrap/overload resultset on the
3253       # source you need to know what alias it's -going- to have for things
3254       # to work sanely (e.g. RestrictWithObject wants to be able to add
3255       # extra query restrictions, and these may need to be $alias.)
3256       #                                       -- mst ~ 2007 (01d59a6a6)
3257       #
3258       # FIXME - this seems to be no longer neccessary (perhaps due to the
3259       # advances in relcond resolution. Testing DBIC::S::RWO and its only
3260       # dependent (as of Jun 2015 ) does not yield any difference with or
3261       # without this line. Nevertheless keep it as is for now, to minimize
3262       # churn, there is enough potential for breakage in 0.0829xx as it is
3263       #                                       -- ribasushi Jun 2015
3264       #
3265       my $rel_source = $rsrc->related_source($rel);
3266       local $rel_source->resultset_attributes->{alias} = $attrs->{alias};
3267
3268       $rel_source->resultset->search_rs( undef, $attrs );
3269     };
3270
3271     if (my $cache = $self->get_cache) {
3272       my @related_cache = map
3273         { $_->related_resultset($rel)->get_cache || () }
3274         @$cache
3275       ;
3276
3277       $new->set_cache([ map @$_, @related_cache ]) if @related_cache == @$cache;
3278     }
3279
3280     $new;
3281   };
3282 }
3283
3284 =head2 current_source_alias
3285
3286 =over 4
3287
3288 =item Arguments: none
3289
3290 =item Return Value: $source_alias
3291
3292 =back
3293
3294 Returns the current table alias for the result source this resultset is built
3295 on, that will be used in the SQL query. Usually it is C<me>.
3296
3297 Currently the source alias that refers to the result set returned by a
3298 L</search>/L</find> family method depends on how you got to the resultset: it's
3299 C<me> by default, but eg. L</search_related> aliases it to the related result
3300 source name (and keeps C<me> referring to the original result set). The long
3301 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3302 (and make this method unnecessary).
3303
3304 Thus it's currently necessary to use this method in predefined queries (see
3305 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3306 source alias of the current result set:
3307
3308   # in a result set class
3309   sub modified_by {
3310     my ($self, $user) = @_;
3311
3312     my $me = $self->current_source_alias;
3313
3314     return $self->search({
3315       "$me.modified" => $user->id,
3316     });
3317   }
3318
3319 The alias of L<newly created resultsets|/search> can be altered by the
3320 L<alias attribute|/alias>.
3321
3322 =cut
3323
3324 sub current_source_alias {
3325   return (shift->{attrs} || {})->{alias} || 'me';
3326 }
3327
3328 =head2 as_subselect_rs
3329
3330 =over 4
3331
3332 =item Arguments: none
3333
3334 =item Return Value: L<$resultset|/search>
3335
3336 =back
3337
3338 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3339 "virtual view" by including it as a subquery within the from clause.  From this
3340 point on, any joined tables are inaccessible to ->search on the resultset (as if
3341 it were simply where-filtered without joins).  For example:
3342
3343  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3344
3345  # 'x' now pollutes the query namespace
3346
3347  # So the following works as expected
3348  my $ok_rs = $rs->search({'x.other' => 1});
3349
3350  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3351  # def) we look for one row with contradictory terms and join in another table
3352  # (aliased 'x_2') which we never use
3353  my $broken_rs = $rs->search({'x.name' => 'def'});
3354
3355  my $rs2 = $rs->as_subselect_rs;
3356
3357  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3358  my $not_joined_rs = $rs2->search({'x.other' => 1});
3359
3360  # works as expected: finds a 'table' row related to two x rows (abc and def)
3361  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3362
3363 Another example of when one might use this would be to select a subset of
3364 columns in a group by clause:
3365
3366  my $rs = $schema->resultset('Bar')->search(undef, {
3367    group_by => [qw{ id foo_id baz_id }],
3368  })->as_subselect_rs->search(undef, {
3369    columns => [qw{ id foo_id }]
3370  });
3371
3372 In the above example normally columns would have to be equal to the group by,
3373 but because we isolated the group by into a subselect the above works.
3374
3375 =cut
3376
3377 sub as_subselect_rs {
3378   my $self = shift;
3379
3380   my $attrs = $self->_resolved_attrs;
3381
3382   my $fresh_rs = (ref $self)->new (
3383     $self->result_source
3384   );
3385
3386   # these pieces will be locked in the subquery
3387   delete $fresh_rs->{cond};
3388   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3389
3390   return $fresh_rs->search( {}, {
3391     from => [{
3392       $attrs->{alias} => $self->as_query,
3393       -alias  => $attrs->{alias},
3394       -rsrc   => $self->result_source,
3395     }],
3396     alias => $attrs->{alias},
3397   });
3398 }
3399
3400 # This code is called by search_related, and makes sure there
3401 # is clear separation between the joins before, during, and
3402 # after the relationship. This information is needed later
3403 # in order to properly resolve prefetch aliases (any alias
3404 # with a relation_chain_depth less than the depth of the
3405 # current prefetch is not considered)
3406 #
3407 # The increments happen twice per join. An even number means a
3408 # relationship specified via a search_related, whereas an odd
3409 # number indicates a join/prefetch added via attributes
3410 #
3411 # Also this code will wrap the current resultset (the one we
3412 # chain to) in a subselect IFF it contains limiting attributes
3413 sub _chain_relationship {
3414   my ($self, $rel) = @_;
3415   my $source = $self->result_source;
3416   my $attrs = { %{$self->{attrs}||{}} };
3417
3418   # we need to take the prefetch the attrs into account before we
3419   # ->_resolve_join as otherwise they get lost - captainL
3420   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3421
3422   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3423
3424   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3425
3426   my $from;
3427   my @force_subq_attrs = qw/offset rows group_by having/;
3428
3429   if (
3430     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3431       ||
3432     $self->_has_resolved_attr (@force_subq_attrs)
3433   ) {
3434     # Nuke the prefetch (if any) before the new $rs attrs
3435     # are resolved (prefetch is useless - we are wrapping
3436     # a subquery anyway).
3437     my $rs_copy = $self->search;
3438     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3439       $rs_copy->{attrs}{join},
3440       delete $rs_copy->{attrs}{prefetch},
3441     );
3442
3443     $from = [{
3444       -rsrc   => $source,
3445       -alias  => $attrs->{alias},
3446       $attrs->{alias} => $rs_copy->as_query,
3447     }];
3448     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3449     $seen->{-relation_chain_depth} = 0;
3450   }
3451   elsif ($attrs->{from}) {  #shallow copy suffices
3452     $from = [ @{$attrs->{from}} ];
3453   }
3454   else {
3455     $from = [{
3456       -rsrc  => $source,
3457       -alias => $attrs->{alias},
3458       $attrs->{alias} => $source->from,
3459     }];
3460   }
3461
3462   my $jpath = ($seen->{-relation_chain_depth})
3463     ? $from->[-1][0]{-join_path}
3464     : [];
3465
3466   my @requested_joins = $source->_resolve_join(
3467     $join,
3468     $attrs->{alias},
3469     $seen,
3470     $jpath,
3471   );
3472
3473   push @$from, @requested_joins;
3474
3475   $seen->{-relation_chain_depth}++;
3476
3477   # if $self already had a join/prefetch specified on it, the requested
3478   # $rel might very well be already included. What we do in this case
3479   # is effectively a no-op (except that we bump up the chain_depth on
3480   # the join in question so we could tell it *is* the search_related)
3481   my $already_joined;
3482
3483   # we consider the last one thus reverse
3484   for my $j (reverse @requested_joins) {
3485     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3486     if ($rel eq $last_j) {
3487       $j->[0]{-relation_chain_depth}++;
3488       $already_joined++;
3489       last;
3490     }
3491   }
3492
3493   unless ($already_joined) {
3494     push @$from, $source->_resolve_join(
3495       $rel,
3496       $attrs->{alias},
3497       $seen,
3498       $jpath,
3499     );
3500   }
3501
3502   $seen->{-relation_chain_depth}++;
3503
3504   return {%$attrs, from => $from, seen_join => $seen};
3505 }
3506
3507 sub _resolved_attrs {
3508   my $self = shift;
3509   return $self->{_attrs} if $self->{_attrs};
3510
3511   my $attrs  = { %{ $self->{attrs} || {} } };
3512   my $source = $attrs->{result_source} = $self->result_source;
3513   my $alias  = $attrs->{alias};
3514
3515   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3516     if $attrs->{collapse} and $attrs->{distinct};
3517
3518
3519   # Sanity check the paging attributes
3520   # SQLMaker does it too, but in case of a software_limit we'll never get there
3521   if (defined $attrs->{offset}) {
3522     $self->throw_exception('A supplied offset attribute must be a non-negative integer')
3523       if ( $attrs->{offset} =~ /[^0-9]/ or $attrs->{offset} < 0 );
3524   }
3525   if (defined $attrs->{rows}) {
3526     $self->throw_exception("The rows attribute must be a positive integer if present")
3527       if ( $attrs->{rows} =~ /[^0-9]/ or $attrs->{rows} <= 0 );
3528   }
3529
3530   # normalize where condition
3531   $attrs->{where} = normalize_sqla_condition( $attrs->{where} )
3532     if $attrs->{where};
3533
3534   # default selection list
3535   $attrs->{columns} = [ $source->columns ]
3536     unless grep { exists $attrs->{$_} } qw/columns cols select as/;
3537
3538   # merge selectors together
3539   for (qw/columns select as/) {
3540     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3541       if $attrs->{$_} or $attrs->{"+$_"};
3542   }
3543
3544   # disassemble columns
3545   my (@sel, @as);
3546   if (my $cols = delete $attrs->{columns}) {
3547     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3548       if (ref $c eq 'HASH') {
3549         for my $as (sort keys %$c) {
3550           push @sel, $c->{$as};
3551           push @as, $as;
3552         }
3553       }
3554       else {
3555         push @sel, $c;
3556         push @as, $c;
3557       }
3558     }
3559   }
3560
3561   # when trying to weed off duplicates later do not go past this point -
3562   # everything added from here on is unbalanced "anyone's guess" stuff
3563   my $dedup_stop_idx = $#as;
3564
3565   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3566     if $attrs->{as};
3567   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3568     if $attrs->{select};
3569
3570   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3571   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3572
3573   # disqualify all $alias.col as-bits (inflate-map mandated)
3574   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3575
3576   # de-duplicate the result (remove *identical* select/as pairs)
3577   # and also die on duplicate {as} pointing to different {select}s
3578   # not using a c-style for as the condition is prone to shrinkage
3579   my $seen;
3580   my $i = 0;
3581   while ($i <= $dedup_stop_idx) {
3582     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3583       splice @sel, $i, 1;
3584       splice @as, $i, 1;
3585       $dedup_stop_idx--;
3586     }
3587     elsif ($seen->{$as[$i]}++) {
3588       $self->throw_exception(
3589         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3590       );
3591     }
3592     else {
3593       $i++;
3594     }
3595   }
3596
3597   $attrs->{select} = \@sel;
3598   $attrs->{as} = \@as;
3599
3600   $attrs->{from} ||= [{
3601     -rsrc   => $source,
3602     -alias  => $self->{attrs}{alias},
3603     $self->{attrs}{alias} => $source->from,
3604   }];
3605
3606   if ( $attrs->{join} || $attrs->{prefetch} ) {
3607
3608     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3609       if ref $attrs->{from} ne 'ARRAY';
3610
3611     my $join = (delete $attrs->{join}) || {};
3612
3613     if ( defined $attrs->{prefetch} ) {
3614       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3615     }
3616
3617     $attrs->{from} =    # have to copy here to avoid corrupting the original
3618       [
3619         @{ $attrs->{from} },
3620         $source->_resolve_join(
3621           $join,
3622           $alias,
3623           { %{ $attrs->{seen_join} || {} } },
3624           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3625             ? $attrs->{from}[-1][0]{-join_path}
3626             : []
3627           ,
3628         )
3629       ];
3630   }
3631
3632
3633   for my $attr (qw(order_by group_by)) {
3634
3635     if ( defined $attrs->{$attr} ) {
3636       $attrs->{$attr} = (
3637         ref( $attrs->{$attr} ) eq 'ARRAY'
3638         ? [ @{ $attrs->{$attr} } ]
3639         : [ $attrs->{$attr} || () ]
3640       );
3641
3642       delete $attrs->{$attr} unless @{$attrs->{$attr}};
3643     }
3644   }
3645
3646
3647   # set collapse default based on presence of prefetch
3648   my $prefetch;
3649   if (
3650     defined $attrs->{prefetch}
3651       and
3652     $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3653   ) {
3654     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3655       if defined $attrs->{collapse} and ! $attrs->{collapse};
3656
3657     $attrs->{collapse} = 1;
3658   }
3659
3660
3661   # run through the resulting joinstructure (starting from our current slot)
3662   # and unset collapse if proven unnecessary
3663   #
3664   # also while we are at it find out if the current root source has
3665   # been premultiplied by previous related_source chaining
3666   #
3667   # this allows to predict whether a root object with all other relation
3668   # data set to NULL is in fact unique
3669   if ($attrs->{collapse}) {
3670
3671     if (ref $attrs->{from} eq 'ARRAY') {
3672
3673       if (@{$attrs->{from}} == 1) {
3674         # no joins - no collapse
3675         $attrs->{collapse} = 0;
3676       }
3677       else {
3678         # find where our table-spec starts
3679         my @fromlist = @{$attrs->{from}};
3680         while (@fromlist) {
3681           my $t = shift @fromlist;
3682
3683           my $is_multi;
3684           # me vs join from-spec distinction - a ref means non-root
3685           if (ref $t eq 'ARRAY') {
3686             $t = $t->[0];
3687             $is_multi ||= ! $t->{-is_single};
3688           }
3689           last if ($t->{-alias} && $t->{-alias} eq $alias);
3690           $attrs->{_main_source_premultiplied} ||= $is_multi;
3691         }
3692
3693         # no non-singles remaining, nor any premultiplication - nothing to collapse
3694         if (
3695           ! $attrs->{_main_source_premultiplied}
3696             and
3697           ! grep { ! $_->[0]{-is_single} } @fromlist
3698         ) {
3699           $attrs->{collapse} = 0;
3700         }
3701       }
3702     }
3703
3704     else {
3705       # if we can not analyze the from - err on the side of safety
3706       $attrs->{_main_source_premultiplied} = 1;
3707     }
3708   }
3709
3710
3711   # generate the distinct induced group_by before injecting the prefetched select/as parts
3712   if (delete $attrs->{distinct}) {
3713     if ($attrs->{group_by}) {
3714       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3715     }
3716     else {
3717       $attrs->{_grouped_by_distinct} = 1;
3718       # distinct affects only the main selection part, not what prefetch may add below
3719       ($attrs->{group_by}, my $new_order) = $source->schema->storage->_group_over_selection($attrs);
3720
3721       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3722       # The thinking is: if we are collapsing the subquerying prefetch engine will
3723       # rip stuff apart for us anyway, and we do not want to have a potentially
3724       # function-converted external order_by
3725       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3726       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3727     }
3728   }
3729
3730
3731   # generate selections based on the prefetch helper
3732   if ($prefetch) {
3733
3734     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3735       if $attrs->{_dark_selector};
3736
3737     # this is a separate structure (we don't look in {from} directly)
3738     # as the resolver needs to shift things off the lists to work
3739     # properly (identical-prefetches on different branches)
3740     my $joined_node_aliases_map = {};
3741     if (ref $attrs->{from} eq 'ARRAY') {
3742
3743       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3744
3745       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3746         next unless $j->[0]{-alias};
3747         next unless $j->[0]{-join_path};
3748         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3749
3750         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3751
3752         my $p = $joined_node_aliases_map;
3753         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3754         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3755       }
3756     }
3757
3758     ( push @{$attrs->{select}}, $_->[0] ) and ( push @{$attrs->{as}}, $_->[1] )
3759       for $source->_resolve_selection_from_prefetch( $prefetch, $joined_node_aliases_map );
3760   }
3761
3762
3763   $attrs->{_simple_passthrough_construction} = !(
3764     $attrs->{collapse}
3765       or
3766     grep { $_ =~ /\./ } @{$attrs->{as}}
3767   );
3768
3769
3770   # if both page and offset are specified, produce a combined offset
3771   # even though it doesn't make much sense, this is what pre 081xx has
3772   # been doing
3773   if (my $page = delete $attrs->{page}) {
3774     $attrs->{offset} =
3775       ($attrs->{rows} * ($page - 1))
3776             +
3777       ($attrs->{offset} || 0)
3778     ;
3779   }
3780
3781   return $self->{_attrs} = $attrs;
3782 }
3783
3784 sub _rollout_attr {
3785   my ($self, $attr) = @_;
3786
3787   if (ref $attr eq 'HASH') {
3788     return $self->_rollout_hash($attr);
3789   } elsif (ref $attr eq 'ARRAY') {
3790     return $self->_rollout_array($attr);
3791   } else {
3792     return [$attr];
3793   }
3794 }
3795
3796 sub _rollout_array {
3797   my ($self, $attr) = @_;
3798
3799   my @rolled_array;
3800   foreach my $element (@{$attr}) {
3801     if (ref $element eq 'HASH') {
3802       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3803     } elsif (ref $element eq 'ARRAY') {
3804       #  XXX - should probably recurse here
3805       push( @rolled_array, @{$self->_rollout_array($element)} );
3806     } else {
3807       push( @rolled_array, $element );
3808     }
3809   }
3810   return \@rolled_array;
3811 }
3812
3813 sub _rollout_hash {
3814   my ($self, $attr) = @_;
3815
3816   my @rolled_array;
3817   foreach my $key (keys %{$attr}) {
3818     push( @rolled_array, { $key => $attr->{$key} } );
3819   }
3820   return \@rolled_array;
3821 }
3822
3823 sub _calculate_score {
3824   my ($self, $a, $b) = @_;
3825
3826   if (defined $a xor defined $b) {
3827     return 0;
3828   }
3829   elsif (not defined $a) {
3830     return 1;
3831   }
3832
3833   if (ref $b eq 'HASH') {
3834     my ($b_key) = keys %{$b};
3835     $b_key = '' if ! defined $b_key;
3836     if (ref $a eq 'HASH') {
3837       my ($a_key) = keys %{$a};
3838       $a_key = '' if ! defined $a_key;
3839       if ($a_key eq $b_key) {
3840         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3841       } else {
3842         return 0;
3843       }
3844     } else {
3845       return ($a eq $b_key) ? 1 : 0;
3846     }
3847   } else {
3848     if (ref $a eq 'HASH') {
3849       my ($a_key) = keys %{$a};
3850       return ($b eq $a_key) ? 1 : 0;
3851     } else {
3852       return ($b eq $a) ? 1 : 0;
3853     }
3854   }
3855 }
3856
3857 sub _merge_joinpref_attr {
3858   my ($self, $orig, $import) = @_;
3859
3860   return $import unless defined($orig);
3861   return $orig unless defined($import);
3862
3863   $orig = $self->_rollout_attr($orig);
3864   $import = $self->_rollout_attr($import);
3865
3866   my $seen_keys;
3867   foreach my $import_element ( @{$import} ) {
3868     # find best candidate from $orig to merge $b_element into
3869     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3870     foreach my $orig_element ( @{$orig} ) {
3871       my $score = $self->_calculate_score( $orig_element, $import_element );
3872       if ($score > $best_candidate->{score}) {
3873         $best_candidate->{position} = $position;
3874         $best_candidate->{score} = $score;
3875       }
3876       $position++;
3877     }
3878     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3879     $import_key = '' if not defined $import_key;
3880
3881     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3882       push( @{$orig}, $import_element );
3883     } else {
3884       my $orig_best = $orig->[$best_candidate->{position}];
3885       # merge orig_best and b_element together and replace original with merged
3886       if (ref $orig_best ne 'HASH') {
3887         $orig->[$best_candidate->{position}] = $import_element;
3888       } elsif (ref $import_element eq 'HASH') {
3889         my ($key) = keys %{$orig_best};
3890         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3891       }
3892     }
3893     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3894   }
3895
3896   return @$orig ? $orig : ();
3897 }
3898
3899 {
3900   my $hm;
3901
3902   sub _merge_attr {
3903     $hm ||= do {
3904       require Hash::Merge;
3905       my $hm = Hash::Merge->new;
3906
3907       $hm->specify_behavior({
3908         SCALAR => {
3909           SCALAR => sub {
3910             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3911
3912             if ($defl xor $defr) {
3913               return [ $defl ? $_[0] : $_[1] ];
3914             }
3915             elsif (! $defl) {
3916               return [];
3917             }
3918             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3919               return [ $_[0] ];
3920             }
3921             else {
3922               return [$_[0], $_[1]];
3923             }
3924           },
3925           ARRAY => sub {
3926             return $_[1] if !defined $_[0];
3927             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3928             return [$_[0], @{$_[1]}]
3929           },
3930           HASH  => sub {
3931             return [] if !defined $_[0] and !keys %{$_[1]};
3932             return [ $_[1] ] if !defined $_[0];
3933             return [ $_[0] ] if !keys %{$_[1]};
3934             return [$_[0], $_[1]]
3935           },
3936         },
3937         ARRAY => {
3938           SCALAR => sub {
3939             return $_[0] if !defined $_[1];
3940             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3941             return [@{$_[0]}, $_[1]]
3942           },
3943           ARRAY => sub {
3944             my @ret = @{$_[0]} or return $_[1];
3945             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3946             my %idx = map { $_ => 1 } @ret;
3947             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3948             \@ret;
3949           },
3950           HASH => sub {
3951             return [ $_[1] ] if ! @{$_[0]};
3952             return $_[0] if !keys %{$_[1]};
3953             return $_[0] if __HM_DEDUP and grep { $_ eq $_[1] } @{$_[0]};
3954             return [ @{$_[0]}, $_[1] ];
3955           },
3956         },
3957         HASH => {
3958           SCALAR => sub {
3959             return [] if !keys %{$_[0]} and !defined $_[1];
3960             return [ $_[0] ] if !defined $_[1];
3961             return [ $_[1] ] if !keys %{$_[0]};
3962             return [$_[0], $_[1]]
3963           },
3964           ARRAY => sub {
3965             return [] if !keys %{$_[0]} and !@{$_[1]};
3966             return [ $_[0] ] if !@{$_[1]};
3967             return $_[1] if !keys %{$_[0]};
3968             return $_[1] if __HM_DEDUP and grep { $_ eq $_[0] } @{$_[1]};
3969             return [ $_[0], @{$_[1]} ];
3970           },
3971           HASH => sub {
3972             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3973             return [ $_[0] ] if !keys %{$_[1]};
3974             return [ $_[1] ] if !keys %{$_[0]};
3975             return [ $_[0] ] if $_[0] eq $_[1];
3976             return [ $_[0], $_[1] ];
3977           },
3978         }
3979       } => 'DBIC_RS_ATTR_MERGER');
3980       $hm;
3981     };
3982
3983     return $hm->merge ($_[1], $_[2]);
3984   }
3985 }
3986
3987 sub STORABLE_freeze {
3988   my ($self, $cloning) = @_;
3989   my $to_serialize = { %$self };
3990
3991   # A cursor in progress can't be serialized (and would make little sense anyway)
3992   # the parser can be regenerated (and can't be serialized)
3993   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3994
3995   # nor is it sensical to store a not-yet-fired-count pager
3996   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3997     delete $to_serialize->{pager};
3998   }
3999
4000   Storable::nfreeze($to_serialize);
4001 }
4002
4003 # need this hook for symmetry
4004 sub STORABLE_thaw {
4005   my ($self, $cloning, $serialized) = @_;
4006
4007   %$self = %{ Storable::thaw($serialized) };
4008
4009   $self;
4010 }
4011
4012
4013 =head2 throw_exception
4014
4015 See L<DBIx::Class::Schema/throw_exception> for details.
4016
4017 =cut
4018
4019 sub throw_exception {
4020   my $self=shift;
4021
4022   if (ref $self and my $rsrc = $self->result_source) {
4023     $rsrc->throw_exception(@_)
4024   }
4025   else {
4026     DBIx::Class::Exception->throw(@_);
4027   }
4028 }
4029
4030 1;
4031
4032 __END__
4033
4034 # XXX: FIXME: Attributes docs need clearing up
4035
4036 =head1 ATTRIBUTES
4037
4038 Attributes are used to refine a ResultSet in various ways when
4039 searching for data. They can be passed to any method which takes an
4040 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
4041 L</count>.
4042
4043 Default attributes can be set on the result class using
4044 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
4045 the CAVEATS on that feature before using it!)
4046
4047 These are in no particular order:
4048
4049 =head2 order_by
4050
4051 =over 4
4052
4053 =item Value: ( $order_by | \@order_by | \%order_by )
4054
4055 =back
4056
4057 Which column(s) to order the results by.
4058
4059 [The full list of suitable values is documented in
4060 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4061 common options.]
4062
4063 If a single column name, or an arrayref of names is supplied, the
4064 argument is passed through directly to SQL. The hashref syntax allows
4065 for connection-agnostic specification of ordering direction:
4066
4067  For descending order:
4068
4069   order_by => { -desc => [qw/col1 col2 col3/] }
4070
4071  For explicit ascending order:
4072
4073   order_by => { -asc => 'col' }
4074
4075 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4076 supported, although you are strongly encouraged to use the hashref
4077 syntax as outlined above.
4078
4079 =head2 columns
4080
4081 =over 4
4082
4083 =item Value: \@columns | \%columns | $column
4084
4085 =back
4086
4087 Shortcut to request a particular set of columns to be retrieved. Each
4088 column spec may be a string (a table column name), or a hash (in which
4089 case the key is the C<as> value, and the value is used as the C<select>
4090 expression). Adds the L</current_source_alias> onto the start of any column without a C<.> in
4091 it and sets C<select> from that, then auto-populates C<as> from
4092 C<select> as normal. (You may also use the C<cols> attribute, as in
4093 earlier versions of DBIC, but this is deprecated)
4094
4095 Essentially C<columns> does the same as L</select> and L</as>.
4096
4097     columns => [ 'some_column', { dbic_slot => 'another_column' } ]
4098
4099 is the same as
4100
4101     select => [qw(some_column another_column)],
4102     as     => [qw(some_column dbic_slot)]
4103
4104 If you want to individually retrieve related columns (in essence perform
4105 manual L</prefetch>) you have to make sure to specify the correct inflation slot
4106 chain such that it matches existing relationships:
4107
4108     my $rs = $schema->resultset('Artist')->search({}, {
4109         # required to tell DBIC to collapse has_many relationships
4110         collapse => 1,
4111         join     => { cds => 'tracks' },
4112         '+columns'  => {
4113           'cds.cdid'         => 'cds.cdid',
4114           'cds.tracks.title' => 'tracks.title',
4115         },
4116     });
4117
4118 Like elsewhere, literal SQL or literal values can be included by using a
4119 scalar reference or a literal bind value, and these values will be available
4120 in the result with C<get_column> (see also
4121 L<SQL::Abstract/Literal SQL and value type operators>):
4122
4123     # equivalent SQL: SELECT 1, 'a string', IF(my_column,?,?) ...
4124     # bind values: $true_value, $false_value
4125     columns => [
4126         {
4127             foo => \1,
4128             bar => \q{'a string'},
4129             baz => \[ 'IF(my_column,?,?)', $true_value, $false_value ],
4130         }
4131     ]
4132
4133 =head2 +columns
4134
4135 B<NOTE:> You B<MUST> explicitly quote C<'+columns'> when using this attribute.
4136 Not doing so causes Perl to incorrectly interpret C<+columns> as a bareword
4137 with a unary plus operator before it, which is the same as simply C<columns>.
4138
4139 =over 4
4140
4141 =item Value: \@extra_columns
4142
4143 =back
4144
4145 Indicates additional columns to be selected from storage. Works the same as
4146 L</columns> but adds columns to the current selection. (You may also use the
4147 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4148 deprecated)
4149
4150   $schema->resultset('CD')->search(undef, {
4151     '+columns' => ['artist.name'],
4152     join => ['artist']
4153   });
4154
4155 would return all CDs and include a 'name' column to the information
4156 passed to object inflation. Note that the 'artist' is the name of the
4157 column (or relationship) accessor, and 'name' is the name of the column
4158 accessor in the related table.
4159
4160 =head2 select
4161
4162 =over 4
4163
4164 =item Value: \@select_columns
4165
4166 =back
4167
4168 Indicates which columns should be selected from the storage. You can use
4169 column names, or in the case of RDBMS back ends, function or stored procedure
4170 names:
4171
4172   $rs = $schema->resultset('Employee')->search(undef, {
4173     select => [
4174       'name',
4175       { count => 'employeeid' },
4176       { max => { length => 'name' }, -as => 'longest_name' }
4177     ]
4178   });
4179
4180   # Equivalent SQL
4181   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4182
4183 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4184 use L</select>, to instruct DBIx::Class how to store the result of the column.
4185
4186 Also note that the L</as> attribute has B<nothing to do> with the SQL-side
4187 C<AS> identifier aliasing. You B<can> alias a function (so you can use it e.g.
4188 in an C<ORDER BY> clause), however this is done via the C<-as> B<select
4189 function attribute> supplied as shown in the example above.
4190
4191 =head2 +select
4192
4193 B<NOTE:> You B<MUST> explicitly quote C<'+select'> when using this attribute.
4194 Not doing so causes Perl to incorrectly interpret C<+select> as a bareword
4195 with a unary plus operator before it, which is the same as simply C<select>.
4196
4197 =over 4
4198
4199 =item Value: \@extra_select_columns
4200
4201 =back
4202
4203 Indicates additional columns to be selected from storage.  Works the same as
4204 L</select> but adds columns to the current selection, instead of specifying
4205 a new explicit list.
4206
4207 =head2 as
4208
4209 =over 4
4210
4211 =item Value: \@inflation_names
4212
4213 =back
4214
4215 Indicates DBIC-side names for object inflation. That is L</as> indicates the
4216 slot name in which the column value will be stored within the
4217 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4218 identifier by the C<get_column> method (or via the object accessor B<if one
4219 with the same name already exists>) as shown below.
4220
4221 The L</as> attribute has B<nothing to do> with the SQL-side identifier
4222 aliasing C<AS>. See L</select> for details.
4223
4224   $rs = $schema->resultset('Employee')->search(undef, {
4225     select => [
4226       'name',
4227       { count => 'employeeid' },
4228       { max => { length => 'name' }, -as => 'longest_name' }
4229     ],
4230     as => [qw/
4231       name
4232       employee_count
4233       max_name_length
4234     /],
4235   });
4236
4237 If the object against which the search is performed already has an accessor
4238 matching a column name specified in C<as>, the value can be retrieved using
4239 the accessor as normal:
4240
4241   my $name = $employee->name();
4242
4243 If on the other hand an accessor does not exist in the object, you need to
4244 use C<get_column> instead:
4245
4246   my $employee_count = $employee->get_column('employee_count');
4247
4248 You can create your own accessors if required - see
4249 L<DBIx::Class::Manual::Cookbook> for details.
4250
4251 =head2 +as
4252
4253 B<NOTE:> You B<MUST> explicitly quote C<'+as'> when using this attribute.
4254 Not doing so causes Perl to incorrectly interpret C<+as> as a bareword
4255 with a unary plus operator before it, which is the same as simply C<as>.
4256
4257 =over 4
4258
4259 =item Value: \@extra_inflation_names
4260
4261 =back
4262
4263 Indicates additional inflation names for selectors added via L</+select>. See L</as>.
4264
4265 =head2 join
4266
4267 =over 4
4268
4269 =item Value: ($rel_name | \@rel_names | \%rel_names)
4270
4271 =back
4272
4273 Contains a list of relationships that should be joined for this query.  For
4274 example:
4275
4276   # Get CDs by Nine Inch Nails
4277   my $rs = $schema->resultset('CD')->search(
4278     { 'artist.name' => 'Nine Inch Nails' },
4279     { join => 'artist' }
4280   );
4281
4282 Can also contain a hash reference to refer to the other relation's relations.
4283 For example:
4284
4285   package MyApp::Schema::Track;
4286   use base qw/DBIx::Class/;
4287   __PACKAGE__->table('track');
4288   __PACKAGE__->add_columns(qw/trackid cd position title/);
4289   __PACKAGE__->set_primary_key('trackid');
4290   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4291   1;
4292
4293   # In your application
4294   my $rs = $schema->resultset('Artist')->search(
4295     { 'track.title' => 'Teardrop' },
4296     {
4297       join     => { cd => 'track' },
4298       order_by => 'artist.name',
4299     }
4300   );
4301
4302 You need to use the relationship (not the table) name in  conditions,
4303 because they are aliased as such. The current table is aliased as "me", so
4304 you need to use me.column_name in order to avoid ambiguity. For example:
4305
4306   # Get CDs from 1984 with a 'Foo' track
4307   my $rs = $schema->resultset('CD')->search(
4308     {
4309       'me.year' => 1984,
4310       'tracks.name' => 'Foo'
4311     },
4312     { join => 'tracks' }
4313   );
4314
4315 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4316 similarly for a third time). For e.g.
4317
4318   my $rs = $schema->resultset('Artist')->search({
4319     'cds.title'   => 'Down to Earth',
4320     'cds_2.title' => 'Popular',
4321   }, {
4322     join => [ qw/cds cds/ ],
4323   });
4324
4325 will return a set of all artists that have both a cd with title 'Down
4326 to Earth' and a cd with title 'Popular'.
4327
4328 If you want to fetch related objects from other tables as well, see L</prefetch>
4329 below.
4330
4331  NOTE: An internal join-chain pruner will discard certain joins while
4332  constructing the actual SQL query, as long as the joins in question do not
4333  affect the retrieved result. This for example includes 1:1 left joins
4334  that are not part of the restriction specification (WHERE/HAVING) nor are
4335  a part of the query selection.
4336
4337 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4338
4339 =head2 collapse
4340
4341 =over 4
4342
4343 =item Value: (0 | 1)
4344
4345 =back
4346
4347 When set to a true value, indicates that any rows fetched from joined has_many
4348 relationships are to be aggregated into the corresponding "parent" object. For
4349 example, the resultset:
4350
4351   my $rs = $schema->resultset('CD')->search({}, {
4352     '+columns' => [ qw/ tracks.title tracks.position / ],
4353     join => 'tracks',
4354     collapse => 1,
4355   });
4356
4357 While executing the following query:
4358
4359   SELECT me.*, tracks.title, tracks.position
4360     FROM cd me
4361     LEFT JOIN track tracks
4362       ON tracks.cdid = me.cdid
4363
4364 Will return only as many objects as there are rows in the CD source, even
4365 though the result of the query may span many rows. Each of these CD objects
4366 will in turn have multiple "Track" objects hidden behind the has_many
4367 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4368 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4369 product"), with each CD object containing exactly one of all fetched Track data.
4370
4371 When a collapse is requested on a non-ordered resultset, an order by some
4372 unique part of the main source (the left-most table) is inserted automatically.
4373 This is done so that the resultset is allowed to be "lazy" - calling
4374 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4375 object with all of its related data.
4376
4377 If an L</order_by> is already declared, and orders the resultset in a way that
4378 makes collapsing as described above impossible (e.g. C<< ORDER BY
4379 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4380 switch to "eager" mode and slurp the entire resultset before constructing the
4381 first object returned by L</next>.
4382
4383 Setting this attribute on a resultset that does not join any has_many
4384 relations is a no-op.
4385
4386 For a more in-depth discussion, see L</PREFETCHING>.
4387
4388 =head2 prefetch
4389
4390 =over 4
4391
4392 =item Value: ($rel_name | \@rel_names | \%rel_names)
4393
4394 =back
4395
4396 This attribute is a shorthand for specifying a L</join> spec, adding all
4397 columns from the joined related sources as L</+columns> and setting
4398 L</collapse> to a true value. It can be thought of as a rough B<superset>
4399 of the L</join> attribute.
4400
4401 For example, the following two queries are equivalent:
4402
4403   my $rs = $schema->resultset('Artist')->search({}, {
4404     prefetch => { cds => ['genre', 'tracks' ] },
4405   });
4406
4407 and
4408
4409   my $rs = $schema->resultset('Artist')->search({}, {
4410     join => { cds => ['genre', 'tracks' ] },
4411     collapse => 1,
4412     '+columns' => [
4413       (map
4414         { +{ "cds.$_" => "cds.$_" } }
4415         $schema->source('Artist')->related_source('cds')->columns
4416       ),
4417       (map
4418         { +{ "cds.genre.$_" => "genre.$_" } }
4419         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4420       ),
4421       (map
4422         { +{ "cds.tracks.$_" => "tracks.$_" } }
4423         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4424       ),
4425     ],
4426   });
4427
4428 Both producing the following SQL:
4429
4430   SELECT  me.artistid, me.name, me.rank, me.charfield,
4431           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4432           genre.genreid, genre.name,
4433           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4434     FROM artist me
4435     LEFT JOIN cd cds
4436       ON cds.artist = me.artistid
4437     LEFT JOIN genre genre
4438       ON genre.genreid = cds.genreid
4439     LEFT JOIN track tracks
4440       ON tracks.cd = cds.cdid
4441   ORDER BY me.artistid
4442
4443 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4444 the arguments are properly merged and generally do the right thing. For
4445 example, you may want to do the following:
4446
4447   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4448     { 'genre.genreid' => undef },
4449     {
4450       join => { cds => 'genre' },
4451       prefetch => 'cds',
4452     }
4453   );
4454
4455 Which generates the following SQL:
4456
4457   SELECT  me.artistid, me.name, me.rank, me.charfield,
4458           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4459     FROM artist me
4460     LEFT JOIN cd cds
4461       ON cds.artist = me.artistid
4462     LEFT JOIN genre genre
4463       ON genre.genreid = cds.genreid
4464   WHERE genre.genreid IS NULL
4465   ORDER BY me.artistid
4466
4467 For a more in-depth discussion, see L</PREFETCHING>.
4468
4469 =head2 alias
4470
4471 =over 4
4472
4473 =item Value: $source_alias
4474
4475 =back
4476
4477 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4478 nested search queries (sub-SELECTs) might need specific aliases set to
4479 reference inner queries.  For example:
4480
4481    my $q = $rs
4482       ->related_resultset('CDs')
4483       ->related_resultset('Tracks')
4484       ->search({
4485          'track.id' => { -ident => 'none_search.id' },
4486       })
4487       ->as_query;
4488
4489    my $ids = $self->search({
4490       -not_exists => $q,
4491    }, {
4492       alias    => 'none_search',
4493       group_by => 'none_search.id',
4494    })->get_column('id')->as_query;
4495
4496    $self->search({ id => { -in => $ids } })
4497
4498 This attribute is directly tied to L</current_source_alias>.
4499
4500 =head2 page
4501
4502 =over 4
4503
4504 =item Value: $page
4505
4506 =back
4507
4508 Makes the resultset paged and specifies the page to retrieve. Effectively
4509 identical to creating a non-pages resultset and then calling ->page($page)
4510 on it.
4511
4512 If L</rows> attribute is not specified it defaults to 10 rows per page.
4513
4514 When you have a paged resultset, L</count> will only return the number
4515 of rows in the page. To get the total, use the L</pager> and call
4516 C<total_entries> on it.
4517
4518 =head2 rows
4519
4520 =over 4
4521
4522 =item Value: $rows
4523
4524 =back
4525
4526 Specifies the maximum number of rows for direct retrieval or the number of
4527 rows per page if the page attribute or method is used.
4528
4529 =head2 offset
4530
4531 =over 4
4532
4533 =item Value: $offset
4534
4535 =back
4536
4537 Specifies the (zero-based) row number for the  first row to be returned, or the
4538 of the first row of the first page if paging is used.
4539
4540 =head2 software_limit
4541
4542 =over 4
4543
4544 =item Value: (0 | 1)
4545
4546 =back
4547
4548 When combined with L</rows> and/or L</offset> the generated SQL will not
4549 include any limit dialect stanzas. Instead the entire result will be selected
4550 as if no limits were specified, and DBIC will perform the limit locally, by
4551 artificially advancing and finishing the resulting L</cursor>.
4552
4553 This is the recommended way of performing resultset limiting when no sane RDBMS
4554 implementation is available (e.g.
4555 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4556 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4557
4558 =head2 group_by
4559
4560 =over 4
4561
4562 =item Value: \@columns
4563
4564 =back
4565
4566 A arrayref of columns to group by. Can include columns of joined tables.
4567
4568   group_by => [qw/ column1 column2 ... /]
4569
4570 =head2 having
4571
4572 =over 4
4573
4574 =item Value: $condition
4575
4576 =back
4577
4578 The HAVING operator specifies a B<secondary> condition applied to the set
4579 after the grouping calculations have been done. In other words it is a
4580 constraint just like L</where> (and accepting the same
4581 L<SQL::Abstract syntax|SQL::Abstract/WHERE CLAUSES>) applied to the data
4582 as it exists after GROUP BY has taken place. Specifying L</having> without
4583 L</group_by> is a logical mistake, and a fatal error on most RDBMS engines.
4584
4585 E.g.
4586
4587   having => { 'count_employee' => { '>=', 100 } }
4588
4589 or with an in-place function in which case literal SQL is required:
4590
4591   having => \[ 'count(employee) >= ?', 100 ]
4592
4593 =head2 distinct
4594
4595 =over 4
4596
4597 =item Value: (0 | 1)
4598
4599 =back
4600
4601 Set to 1 to automatically generate a L</group_by> clause based on the selection
4602 (including intelligent handling of L</order_by> contents). Note that the group
4603 criteria calculation takes place over the B<final> selection. This includes
4604 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4605 L</search> calls, and standalone columns selected via
4606 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4607 extra selections specified via L</prefetch> - such selections are explicitly
4608 excluded from group criteria calculations.
4609
4610 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4611 setting is ignored and an appropriate warning is issued.
4612
4613 =head2 where
4614
4615 Adds extra conditions to the resultset, combined with the preexisting C<WHERE>
4616 conditions, same as the B<first> argument to the L<search operator|/search>
4617
4618   # only return rows WHERE deleted IS NULL for all searches
4619   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4620
4621 Note that the above example is
4622 L<strongly discouraged|DBIx::Class::ResultSource/resultset_attributes>.
4623
4624 =head2 cache
4625
4626 Set to 1 to cache search results. This prevents extra SQL queries if you
4627 revisit rows in your ResultSet:
4628
4629   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4630
4631   while( my $artist = $resultset->next ) {
4632     ... do stuff ...
4633   }
4634
4635   $resultset->first; # without cache, this would issue a query
4636
4637 By default, searches are not cached.
4638
4639 For more examples of using these attributes, see
4640 L<DBIx::Class::Manual::Cookbook>.
4641
4642 =head2 for
4643
4644 =over 4
4645
4646 =item Value: ( 'update' | 'shared' | \$scalar )
4647
4648 =back
4649
4650 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4651 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4652 query.
4653
4654 =head1 PREFETCHING
4655
4656 DBIx::Class supports arbitrary related data prefetching from multiple related
4657 sources. Any combination of relationship types and column sets are supported.
4658 If L<collapsing|/collapse> is requested, there is an additional requirement of
4659 selecting enough data to make every individual object uniquely identifiable.
4660
4661 Here are some more involved examples, based on the following relationship map:
4662
4663   # Assuming:
4664   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4665   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4666   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4667
4668   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4669
4670   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4671
4672
4673
4674   my $rs = $schema->resultset('Tag')->search(
4675     undef,
4676     {
4677       prefetch => {
4678         cd => 'artist'
4679       }
4680     }
4681   );
4682
4683 The initial search results in SQL like the following:
4684
4685   SELECT tag.*, cd.*, artist.* FROM tag
4686   JOIN cd ON tag.cd = cd.cdid
4687   JOIN artist ON cd.artist = artist.artistid
4688
4689 L<DBIx::Class> has no need to go back to the database when we access the
4690 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4691 case.
4692
4693 Simple prefetches will be joined automatically, so there is no need
4694 for a C<join> attribute in the above search.
4695
4696 The L</prefetch> attribute can be used with any of the relationship types
4697 and multiple prefetches can be specified together. Below is a more complex
4698 example that prefetches a CD's artist, its liner notes (if present),
4699 the cover image, the tracks on that CD, and the guests on those
4700 tracks.
4701
4702   my $rs = $schema->resultset('CD')->search(
4703     undef,
4704     {
4705       prefetch => [
4706         { artist => 'record_label'},  # belongs_to => belongs_to
4707         'liner_note',                 # might_have
4708         'cover_image',                # has_one
4709         { tracks => 'guests' },       # has_many => has_many
4710       ]
4711     }
4712   );
4713
4714 This will produce SQL like the following:
4715
4716   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4717          tracks.*, guests.*
4718     FROM cd me
4719     JOIN artist artist
4720       ON artist.artistid = me.artistid
4721     JOIN record_label record_label
4722       ON record_label.labelid = artist.labelid
4723     LEFT JOIN track tracks
4724       ON tracks.cdid = me.cdid
4725     LEFT JOIN guest guests
4726       ON guests.trackid = track.trackid
4727     LEFT JOIN liner_notes liner_note
4728       ON liner_note.cdid = me.cdid
4729     JOIN cd_artwork cover_image
4730       ON cover_image.cdid = me.cdid
4731   ORDER BY tracks.cd
4732
4733 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4734 C<tracks>, and C<guests> of the CD will all be available through the
4735 relationship accessors without the need for additional queries to the
4736 database.
4737
4738 =head3 CAVEATS
4739
4740 Prefetch does a lot of deep magic. As such, it may not behave exactly
4741 as you might expect.
4742
4743 =over 4
4744
4745 =item *
4746
4747 Prefetch uses the L</cache> to populate the prefetched relationships. This
4748 may or may not be what you want.
4749
4750 =item *
4751
4752 If you specify a condition on a prefetched relationship, ONLY those
4753 rows that match the prefetched condition will be fetched into that relationship.
4754 This means that adding prefetch to a search() B<may alter> what is returned by
4755 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4756
4757   my $artist_rs = $schema->resultset('Artist')->search({
4758       'cds.year' => 2008,
4759   }, {
4760       join => 'cds',
4761   });
4762
4763   my $count = $artist_rs->first->cds->count;
4764
4765   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4766
4767   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4768
4769   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4770
4771 That cmp_ok() may or may not pass depending on the datasets involved. In other
4772 words the C<WHERE> condition would apply to the entire dataset, just like
4773 it would in regular SQL. If you want to add a condition only to the "right side"
4774 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4775 condition|DBIx::Class::Relationship::Base/condition>
4776
4777 =back
4778
4779 =head1 DBIC BIND VALUES
4780
4781 Because DBIC may need more information to bind values than just the column name
4782 and value itself, it uses a special format for both passing and receiving bind
4783 values.  Each bind value should be composed of an arrayref of
4784 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4785
4786 =over 4
4787
4788 =item dbd_attrs
4789
4790 If present (in any form), this is what is being passed directly to bind_param.
4791 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4792 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4793
4794 If this is specified, all other bind options described below are ignored.
4795
4796 =item sqlt_datatype
4797
4798 If present, this is used to infer the actual bind attribute by passing to
4799 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4800 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4801
4802 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4803 currently drivers are expected to "Do the Right Thing" when given a common
4804 datatype name.  (Not ideal, but that's what we got at this point.)
4805
4806 =item sqlt_size
4807
4808 Currently used to correctly allocate buffers for bind_param_inout().
4809 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4810 or to a sensible value based on the "data_type".
4811
4812 =item dbic_colname
4813
4814 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4815 explicitly specified they are never overridden).  Also used by some weird DBDs,
4816 where the column name should be available at bind_param time (e.g. Oracle).
4817
4818 =back
4819
4820 For backwards compatibility and convenience, the following shortcuts are
4821 supported:
4822
4823   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4824   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4825   [ undef,   $val ] === [ {}, $val ]
4826   $val              === [ {}, $val ]
4827
4828 =head1 FURTHER QUESTIONS?
4829
4830 Check the list of L<additional DBIC resources|DBIx::Class/GETTING HELP/SUPPORT>.
4831
4832 =head1 COPYRIGHT AND LICENSE
4833
4834 This module is free software L<copyright|DBIx::Class/COPYRIGHT AND LICENSE>
4835 by the L<DBIx::Class (DBIC) authors|DBIx::Class/AUTHORS>. You can
4836 redistribute it and/or modify it under the same terms as the
4837 L<DBIx::Class library|DBIx::Class/COPYRIGHT AND LICENSE>.
4838
4839 =cut