lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::ResultSetColumn;
   8 use Scalar::Util qw/blessed weaken reftype/;
   9 use DBIx::Class::_Util 'fail_on_internal_wantarray';
  10 use Try::Tiny;
  11 use Data::Dumper::Concise ();
  12 use Data::Query::Constants;
  13 use Data::Query::ExprHelpers;
  14 # not importing first() as it will clash with our own method
  15 use List::Util ();
  16
  17 BEGIN {
  18   # De-duplication in _merge_attr() is disabled, but left in for reference
  19   # (the merger is used for other things that ought not to be de-duped)
  20   *__HM_DEDUP = sub () { 0 };
  21 }
  22
  23 use namespace::clean;
  24
  25 use overload
  26         '0+'     => "count",
  27         'bool'   => "_bool",
  28         fallback => 1;
  29
  30 # this is real - CDBICompat overrides it with insanity
  31 # yes, prototype won't matter, but that's for now ;)
  32 sub _bool () { 1 }
  33
  34 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class result_source/);
  35
  36 =head1 NAME
  37
  38 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  39
  40 =head1 SYNOPSIS
  41
  42   my $users_rs = $schema->resultset('User');
  43   while( $user = $users_rs->next) {
  44     print $user->username;
  45   }
  46
  47   my $registered_users_rs = $schema->resultset('User')->search({ registered => 1 });
  48   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  49
  50 =head1 DESCRIPTION
  51
  52 A ResultSet is an object which stores a set of conditions representing
  53 a query. It is the backbone of DBIx::Class (i.e. the really
  54 important/useful bit).
  55
  56 No SQL is executed on the database when a ResultSet is created, it
  57 just stores all the conditions needed to create the query.
  58
  59 A basic ResultSet representing the data of an entire table is returned
  60 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  61 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  62
  63   my $users_rs = $schema->resultset('User');
  64
  65 A new ResultSet is returned from calling L</search> on an existing
  66 ResultSet. The new one will contain all the conditions of the
  67 original, plus any new conditions added in the C<search> call.
  68
  69 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  70 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  71 represents.
  72
  73 The query that the ResultSet represents is B<only> executed against
  74 the database when these methods are called:
  75 L</find>, L</next>, L</all>, L</first>, L</single>, L</count>.
  76
  77 If a resultset is used in a numeric context it returns the L</count>.
  78 However, if it is used in a boolean context it is B<always> true.  So if
  79 you want to check if a resultset has any results, you must use C<if $rs
  80 != 0>.
  81
  82 =head1 CUSTOM ResultSet CLASSES THAT USE Moose
  83
  84 If you want to make your custom ResultSet classes with L<Moose>, use a template
  85 similar to:
  86
  87     package MyApp::Schema::ResultSet::User;
  88
  89     use Moose;
  90     use namespace::autoclean;
  91     use MooseX::NonMoose;
  92     extends 'DBIx::Class::ResultSet';
  93
  94     sub BUILDARGS { $_[2] }
  95
  96     ...your code...
  97
  98     __PACKAGE__->meta->make_immutable;
  99
 100     1;
 101
 102 The L<MooseX::NonMoose> is necessary so that the L<Moose> constructor does not
 103 clash with the regular ResultSet constructor. Alternatively, you can use:
 104
 105     __PACKAGE__->meta->make_immutable(inline_constructor => 0);
 106
 107 The L<BUILDARGS|Moose::Manual::Construction/BUILDARGS> is necessary because the
 108 signature of the ResultSet C<new> is C<< ->new($source, \%args) >>.
 109
 110 =head1 EXAMPLES
 111
 112 =head2 Chaining resultsets
 113
 114 Let's say you've got a query that needs to be run to return some data
 115 to the user. But, you have an authorization system in place that
 116 prevents certain users from seeing certain information. So, you want
 117 to construct the basic query in one method, but add constraints to it in
 118 another.
 119
 120   sub get_data {
 121     my $self = shift;
 122     my $request = $self->get_request; # Get a request object somehow.
 123     my $schema = $self->result_source->schema;
 124
 125     my $cd_rs = $schema->resultset('CD')->search({
 126       title => $request->param('title'),
 127       year => $request->param('year'),
 128     });
 129
 130     $cd_rs = $self->apply_security_policy( $cd_rs );
 131
 132     return $cd_rs->all();
 133   }
 134
 135   sub apply_security_policy {
 136     my $self = shift;
 137     my ($rs) = @_;
 138
 139     return $rs->search({
 140       subversive => 0,
 141     });
 142   }
 143
 144 =head3 Resolving conditions and attributes
 145
 146 When a resultset is chained from another resultset (e.g.:
 147 C<< my $new_rs = $old_rs->search(\%extra_cond, \%attrs) >>), conditions
 148 and attributes with the same keys need resolving.
 149
 150 If any of L</columns>, L</select>, L</as> are present, they reset the
 151 original selection, and start the selection "clean".
 152
 153 The L</join>, L</prefetch>, L</+columns>, L</+select>, L</+as> attributes
 154 are merged into the existing ones from the original resultset.
 155
 156 The L</where> and L</having> attributes, and any search conditions, are
 157 merged with an SQL C<AND> to the existing condition from the original
 158 resultset.
 159
 160 All other attributes are overridden by any new ones supplied in the
 161 search attributes.
 162
 163 =head2 Multiple queries
 164
 165 Since a resultset just defines a query, you can do all sorts of
 166 things with it with the same object.
 167
 168   # Don't hit the DB yet.
 169   my $cd_rs = $schema->resultset('CD')->search({
 170     title => 'something',
 171     year => 2009,
 172   });
 173
 174   # Each of these hits the DB individually.
 175   my $count = $cd_rs->count;
 176   my $most_recent = $cd_rs->get_column('date_released')->max();
 177   my @records = $cd_rs->all;
 178
 179 And it's not just limited to SELECT statements.
 180
 181   $cd_rs->delete();
 182
 183 This is even cooler:
 184
 185   $cd_rs->create({ artist => 'Fred' });
 186
 187 Which is the same as:
 188
 189   $schema->resultset('CD')->create({
 190     title => 'something',
 191     year => 2009,
 192     artist => 'Fred'
 193   });
 194
 195 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 196
 197 =head1 METHODS
 198
 199 =head2 new
 200
 201 =over 4
 202
 203 =item Arguments: L<$source|DBIx::Class::ResultSource>, L<\%attrs?|/ATTRIBUTES>
 204
 205 =item Return Value: L<$resultset|/search>
 206
 207 =back
 208
 209 The resultset constructor. Takes a source object (usually a
 210 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 211 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 212 executed as needed by the other methods.
 213
 214 Generally you never construct a resultset manually. Instead you get one
 215 from e.g. a
 216 C<< $schema->L<resultset|DBIx::Class::Schema/resultset>('$source_name') >>
 217 or C<< $another_resultset->L<search|/search>(...) >> (the later called in
 218 scalar context):
 219
 220   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 221
 222 =over
 223
 224 =item WARNING
 225
 226 If called on an object, proxies to L</new_result> instead, so
 227
 228   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 229
 230 will return a CD object, not a ResultSet, and is equivalent to:
 231
 232   my $cd = $schema->resultset('CD')->new_result({ title => 'Spoon' });
 233
 234 Please also keep in mind that many internals call L</new_result> directly,
 235 so overloading this method with the idea of intercepting new result object
 236 creation B<will not work>. See also warning pertaining to L</create>.
 237
 238 =back
 239
 240 =cut
 241
 242 sub new {
 243   my $class = shift;
 244   return $class->new_result(@_) if ref $class;
 245
 246   my ($source, $attrs) = @_;
 247   $source = $source->resolve
 248     if $source->isa('DBIx::Class::ResultSourceHandle');
 249
 250   $attrs = { %{$attrs||{}} };
 251   delete @{$attrs}{qw(_sqlmaker_select_args _related_results_construction)};
 252
 253   if ($attrs->{page}) {
 254     $attrs->{rows} ||= 10;
 255   }
 256
 257   $attrs->{alias} ||= 'me';
 258
 259   my $self = bless {
 260     result_source => $source,
 261     cond => $attrs->{where},
 262     pager => undef,
 263     attrs => $attrs,
 264   }, $class;
 265
 266   # if there is a dark selector, this means we are already in a
 267   # chain and the cleanup/sanification was taken care of by
 268   # _search_rs already
 269   $self->_normalize_selection($attrs)
 270     unless $attrs->{_dark_selector};
 271
 272   $self->result_class(
 273     $attrs->{result_class} || $source->result_class
 274   );
 275
 276   $self;
 277 }
 278
 279 =head2 search
 280
 281 =over 4
 282
 283 =item Arguments: L<$cond|DBIx::Class::SQLMaker> | undef, L<\%attrs?|/ATTRIBUTES>
 284
 285 =item Return Value: $resultset (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 286
 287 =back
 288
 289   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 290   my $new_rs = $cd_rs->search({ year => 2005 });
 291
 292   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 293                  # year = 2005 OR year = 2004
 294
 295 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 296 returning a list of L<result|DBIx::Class::Manual::ResultClass> objects instead.
 297 To avoid that, use L</search_rs>.
 298
 299 If you need to pass in additional attributes but no additional condition,
 300 call it as C<search(undef, \%attrs)>.
 301
 302   # "SELECT name, artistid FROM $artist_table"
 303   my @all_artists = $schema->resultset('Artist')->search(undef, {
 304     columns => [qw/name artistid/],
 305   });
 306
 307 For a list of attributes that can be passed to C<search>, see
 308 L</ATTRIBUTES>. For more examples of using this function, see
 309 L<Searching|DBIx::Class::Manual::Cookbook/SEARCHING>. For a complete
 310 documentation for the first argument, see L<SQL::Abstract/"WHERE CLAUSES">
 311 and its extension L<DBIx::Class::SQLMaker>.
 312
 313 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 314
 315 =head3 CAVEAT
 316
 317 Note that L</search> does not process/deflate any of the values passed in the
 318 L<SQL::Abstract>-compatible search condition structure. This is unlike other
 319 condition-bound methods L</new_result>, L</create> and L</find>. The user must ensure
 320 manually that any value passed to this method will stringify to something the
 321 RDBMS knows how to deal with. A notable example is the handling of L<DateTime>
 322 objects, for more info see:
 323 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
 324
 325 =cut
 326
 327 sub search {
 328   my $self = shift;
 329   my $rs = $self->search_rs( @_ );
 330
 331   if (wantarray) {
 332     DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = fail_on_internal_wantarray($rs);
 333     return $rs->all;
 334   }
 335   elsif (defined wantarray) {
 336     return $rs;
 337   }
 338   else {
 339     # we can be called by a relationship helper, which in
 340     # turn may be called in void context due to some braindead
 341     # overload or whatever else the user decided to be clever
 342     # at this particular day. Thus limit the exception to
 343     # external code calls only
 344     $self->throw_exception ('->search is *not* a mutator, calling it in void context makes no sense')
 345       if (caller)[0] !~ /^\QDBIx::Class::/;
 346
 347     return ();
 348   }
 349 }
 350
 351 =head2 search_rs
 352
 353 =over 4
 354
 355 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
 356
 357 =item Return Value: L<$resultset|/search>
 358
 359 =back
 360
 361 This method does the same exact thing as search() except it will
 362 always return a resultset, even in list context.
 363
 364 =cut
 365
 366 sub search_rs {
 367   my $self = shift;
 368
 369   my $rsrc = $self->result_source;
 370   my ($call_cond, $call_attrs);
 371
 372   # Special-case handling for (undef, undef) or (undef)
 373   # Note that (foo => undef) is valid deprecated syntax
 374   @_ = () if not scalar grep { defined $_ } @_;
 375
 376   # just a cond
 377   if (@_ == 1) {
 378     $call_cond = shift;
 379   }
 380   # fish out attrs in the ($condref, $attr) case
 381   elsif (@_ == 2 and ( ! defined $_[0] or (ref $_[0]) ne '') ) {
 382     ($call_cond, $call_attrs) = @_;
 383   }
 384   elsif (@_ % 2) {
 385     $self->throw_exception('Odd number of arguments to search')
 386   }
 387   # legacy search
 388   elsif (@_) {
 389     carp_unique 'search( %condition ) is deprecated, use search( \%condition ) instead'
 390       unless $rsrc->result_class->isa('DBIx::Class::CDBICompat');
 391
 392     for my $i (0 .. $#_) {
 393       next if $i % 2;
 394       $self->throw_exception ('All keys in condition key/value pairs must be plain scalars')
 395         if (! defined $_[$i] or ref $_[$i] ne '');
 396     }
 397
 398     $call_cond = { @_ };
 399   }
 400
 401   if (blessed($call_cond) and $call_cond->isa('Data::Query::ExprBuilder')) {
 402     my ($mapped_expr, $extra_join)
 403       = $self->_remap_identifiers($call_cond->{expr});
 404     $call_cond = \$mapped_expr;
 405     if (@$extra_join) {
 406       $self->throw_exception("Can't handle join-requiring DQ expr when join attribute specified")
 407         if $call_attrs->{join};
 408       $call_attrs->{join} = $extra_join;
 409     }
 410   }
 411
 412   # see if we can keep the cache (no $rs changes)
 413   my $cache;
 414   my %safe = (alias => 1, cache => 1);
 415   if ( ! List::Util::first { !$safe{$_} } keys %$call_attrs and (
 416     ! defined $call_cond
 417       or
 418     ref $call_cond eq 'HASH' && ! keys %$call_cond
 419       or
 420     ref $call_cond eq 'ARRAY' && ! @$call_cond
 421   )) {
 422     $cache = $self->get_cache;
 423   }
 424
 425   my $old_attrs = { %{$self->{attrs}} };
 426   my ($old_having, $old_where) = delete @{$old_attrs}{qw(having where)};
 427
 428   my $new_attrs = { %$old_attrs };
 429
 430   # take care of call attrs (only if anything is changing)
 431   if ($call_attrs and keys %$call_attrs) {
 432
 433     # copy for _normalize_selection
 434     $call_attrs = { %$call_attrs };
 435
 436     my @selector_attrs = qw/select as columns cols +select +as +columns include_columns/;
 437
 438     # reset the current selector list if new selectors are supplied
 439     if (List::Util::first { exists $call_attrs->{$_} } qw/columns cols select as/) {
 440       delete @{$old_attrs}{(@selector_attrs, '_dark_selector')};
 441     }
 442
 443     # Normalize the new selector list (operates on the passed-in attr structure)
 444     # Need to do it on every chain instead of only once on _resolved_attrs, in
 445     # order to allow detection of empty vs partial 'as'
 446     $call_attrs->{_dark_selector} = $old_attrs->{_dark_selector}
 447       if $old_attrs->{_dark_selector};
 448     $self->_normalize_selection ($call_attrs);
 449
 450     # start with blind overwriting merge, exclude selector attrs
 451     $new_attrs = { %{$old_attrs}, %{$call_attrs} };
 452     delete @{$new_attrs}{@selector_attrs};
 453
 454     for (@selector_attrs) {
 455       $new_attrs->{$_} = $self->_merge_attr($old_attrs->{$_}, $call_attrs->{$_})
 456         if ( exists $old_attrs->{$_} or exists $call_attrs->{$_} );
 457     }
 458
 459     # older deprecated name, use only if {columns} is not there
 460     if (my $c = delete $new_attrs->{cols}) {
 461       carp_unique( "Resultset attribute 'cols' is deprecated, use 'columns' instead" );
 462       if ($new_attrs->{columns}) {
 463         carp "Resultset specifies both the 'columns' and the legacy 'cols' attributes - ignoring 'cols'";
 464       }
 465       else {
 466         $new_attrs->{columns} = $c;
 467       }
 468     }
 469
 470
 471     # join/prefetch use their own crazy merging heuristics
 472     foreach my $key (qw/join prefetch/) {
 473       $new_attrs->{$key} = $self->_merge_joinpref_attr($old_attrs->{$key}, $call_attrs->{$key})
 474         if exists $call_attrs->{$key};
 475     }
 476
 477     # stack binds together
 478     $new_attrs->{bind} = [ @{ $old_attrs->{bind} || [] }, @{ $call_attrs->{bind} || [] } ];
 479   }
 480
 481
 482   for ($old_where, $call_cond) {
 483     if (defined $_) {
 484       $new_attrs->{where} = $self->_stack_cond (
 485         $_, $new_attrs->{where}
 486       );
 487     }
 488   }
 489
 490   if (defined $old_having) {
 491     $new_attrs->{having} = $self->_stack_cond (
 492       $old_having, $new_attrs->{having}
 493     )
 494   }
 495
 496   my $rs = (ref $self)->new($rsrc, $new_attrs);
 497
 498   $rs->set_cache($cache) if ($cache);
 499
 500   return $rs;
 501 }
 502
 503 sub _remap_identifiers {
 504   my ($self, $dq) = @_;
 505   my $map = {};
 506   my $attrs = $self->_resolved_attrs;
 507   foreach my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
 508     next unless $j->[0]{-alias};
 509     next unless $j->[0]{-join_path};
 510     my $p = $map;
 511     $p = $p->{$_} ||= {} for map { keys %$_ } @{$j->[0]{-join_path}};
 512     $p->{''} = $j->[0]{-alias};
 513   }
 514
 515   my $seen_join = { %{$attrs->{seen_join}||{}} };
 516   my $storage = $self->result_source->storage;
 517   my @need_join;
 518   my $mapped = map_dq_tree {
 519     return $_ unless is_Identifier;
 520     my @el = @{$_->{elements}};
 521     my $last = pop @el;
 522     unless (@el) {
 523       return Identifier($attrs->{alias}, $last);
 524     }
 525     my $p = $map;
 526     $p = $p->{$_} ||= {} for @el;
 527     if (my $alias = $p->{''}) {
 528       return Identifier($alias, $last);
 529     }
 530     my $need = my $j = {};
 531     $j = $j->{$_} = {} for @el;
 532     push @need_join, $need;
 533     my $alias = $storage->relname_to_table_alias(
 534       $el[-1], ++$seen_join->{$el[-1]}
 535     );
 536     return Identifier($alias, $last);
 537   } $dq;
 538   return ($mapped, \@need_join);
 539 }
 540
 541 my $dark_sel_dumper;
 542 sub _normalize_selection {
 543   my ($self, $attrs) = @_;
 544
 545   # legacy syntax
 546   if ( exists $attrs->{include_columns} ) {
 547     carp_unique( "Resultset attribute 'include_columns' is deprecated, use '+columns' instead" );
 548     $attrs->{'+columns'} = $self->_merge_attr(
 549       $attrs->{'+columns'}, delete $attrs->{include_columns}
 550     );
 551   }
 552
 553   # columns are always placed first, however
 554
 555   # Keep the X vs +X separation until _resolved_attrs time - this allows to
 556   # delay the decision on whether to use a default select list ($rsrc->columns)
 557   # allowing stuff like the remove_columns helper to work
 558   #
 559   # select/as +select/+as pairs need special handling - the amount of select/as
 560   # elements in each pair does *not* have to be equal (think multicolumn
 561   # selectors like distinct(foo, bar) ). If the selector is bare (no 'as'
 562   # supplied at all) - try to infer the alias, either from the -as parameter
 563   # of the selector spec, or use the parameter whole if it looks like a column
 564   # name (ugly legacy heuristic). If all fails - leave the selector bare (which
 565   # is ok as well), but make sure no more additions to the 'as' chain take place
 566   for my $pref ('', '+') {
 567
 568     my ($sel, $as) = map {
 569       my $key = "${pref}${_}";
 570
 571       my $val = [ ref $attrs->{$key} eq 'ARRAY'
 572         ? @{$attrs->{$key}}
 573         : $attrs->{$key} || ()
 574       ];
 575       delete $attrs->{$key};
 576       $val;
 577     } qw/select as/;
 578
 579     if (! @$as and ! @$sel ) {
 580       next;
 581     }
 582     elsif (@$as and ! @$sel) {
 583       $self->throw_exception(
 584         "Unable to handle ${pref}as specification (@$as) without a corresponding ${pref}select"
 585       );
 586     }
 587     elsif( ! @$as ) {
 588       # no as part supplied at all - try to deduce (unless explicit end of named selection is declared)
 589       # if any @$as has been supplied we assume the user knows what (s)he is doing
 590       # and blindly keep stacking up pieces
 591       unless ($attrs->{_dark_selector}) {
 592         SELECTOR:
 593         for (@$sel) {
 594           if ( ref $_ eq 'HASH' and exists $_->{-as} ) {
 595             push @$as, $_->{-as};
 596           }
 597           # assume any plain no-space, no-parenthesis string to be a column spec
 598           # FIXME - this is retarded but is necessary to support shit like 'count(foo)'
 599           elsif ( ! ref $_ and $_ =~ /^ [^\s\(\)]+ $/x) {
 600             push @$as, $_;
 601           }
 602           # if all else fails - raise a flag that no more aliasing will be allowed
 603           else {
 604             $attrs->{_dark_selector} = {
 605               plus_stage => $pref,
 606               string => ($dark_sel_dumper ||= do {
 607                   require Data::Dumper::Concise;
 608                   Data::Dumper::Concise::DumperObject()->Indent(0);
 609                 })->Values([$_])->Dump
 610               ,
 611             };
 612             last SELECTOR;
 613           }
 614         }
 615       }
 616     }
 617     elsif (@$as < @$sel) {
 618       $self->throw_exception(
 619         "Unable to handle an ${pref}as specification (@$as) with less elements than the corresponding ${pref}select"
 620       );
 621     }
 622     elsif ($pref and $attrs->{_dark_selector}) {
 623       $self->throw_exception(
 624         "Unable to process named '+select', resultset contains an unnamed selector $attrs->{_dark_selector}{string}"
 625       );
 626     }
 627
 628
 629     # merge result
 630     $attrs->{"${pref}select"} = $self->_merge_attr($attrs->{"${pref}select"}, $sel);
 631     $attrs->{"${pref}as"} = $self->_merge_attr($attrs->{"${pref}as"}, $as);
 632   }
 633 }
 634
 635 sub _stack_cond {
 636   my ($self, $left, $right) = @_;
 637
 638   my $source = $self->result_source;
 639
 640   my $converter = $source->schema->storage->sql_maker->converter;
 641
 642   my @top = map $source->_extract_top_level_conditions(
 643     $converter->_expr_to_dq($_)
 644   ), grep defined, $left, $right;
 645
 646   return undef unless @top;
 647
 648   my %seen;
 649
 650   my @uniq = grep { !$seen{Data::Dumper::Concise::Dumper($_)}++ } @top;
 651
 652   return \$uniq[0] if @uniq == 1;
 653
 654   return \Operator({ 'SQL.Naive' => 'AND' }, \@uniq);
 655 }
 656
 657 =head2 search_literal
 658
 659 B<CAVEAT>: C<search_literal> is provided for Class::DBI compatibility and
 660 should only be used in that context. C<search_literal> is a convenience
 661 method. It is equivalent to calling C<< $schema->search(\[]) >>, but if you
 662 want to ensure columns are bound correctly, use L</search>.
 663
 664 See L<DBIx::Class::Manual::Cookbook/SEARCHING> and
 665 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 666 require C<search_literal>.
 667
 668 =over 4
 669
 670 =item Arguments: $sql_fragment, @standalone_bind_values
 671
 672 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 673
 674 =back
 675
 676   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 677   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 678
 679 Pass a literal chunk of SQL to be added to the conditional part of the
 680 resultset query.
 681
 682 Example of how to use C<search> instead of C<search_literal>
 683
 684   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 685   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 686
 687 =cut
 688
 689 sub search_literal {
 690   my ($self, $sql, @bind) = @_;
 691   my $attr;
 692   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 693     $attr = pop @bind;
 694   }
 695   return $self->search(\[ $sql, map [ {} => $_ ], @bind ], ($attr || () ));
 696 }
 697
 698 =head2 find
 699
 700 =over 4
 701
 702 =item Arguments: \%columns_values | @pk_values, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
 703
 704 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
 705
 706 =back
 707
 708 Finds and returns a single row based on supplied criteria. Takes either a
 709 hashref with the same format as L</create> (including inference of foreign
 710 keys from related objects), or a list of primary key values in the same
 711 order as the L<primary columns|DBIx::Class::ResultSource/primary_columns>
 712 declaration on the L</result_source>.
 713
 714 In either case an attempt is made to combine conditions already existing on
 715 the resultset with the condition passed to this method.
 716
 717 To aid with preparing the correct query for the storage you may supply the
 718 C<key> attribute, which is the name of a
 719 L<unique constraint|DBIx::Class::ResultSource/add_unique_constraint> (the
 720 unique constraint corresponding to the
 721 L<primary columns|DBIx::Class::ResultSource/primary_columns> is always named
 722 C<primary>). If the C<key> attribute has been supplied, and DBIC is unable
 723 to construct a query that satisfies the named unique constraint fully (
 724 non-NULL values for each column member of the constraint) an exception is
 725 thrown.
 726
 727 If no C<key> is specified, the search is carried over all unique constraints
 728 which are fully defined by the available condition.
 729
 730 If no such constraint is found, C<find> currently defaults to a simple
 731 C<< search->(\%column_values) >> which may or may not do what you expect.
 732 Note that this fallback behavior may be deprecated in further versions. If
 733 you need to search with arbitrary conditions - use L</search>. If the query
 734 resulting from this fallback produces more than one row, a warning to the
 735 effect is issued, though only the first row is constructed and returned as
 736 C<$result_object>.
 737
 738 In addition to C<key>, L</find> recognizes and applies standard
 739 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 740
 741 Note that if you have extra concerns about the correctness of the resulting
 742 query you need to specify the C<key> attribute and supply the entire condition
 743 as an argument to find (since it is not always possible to perform the
 744 combination of the resultset condition with the supplied one, especially if
 745 the resultset condition contains literal sql).
 746
 747 For example, to find a row by its primary key:
 748
 749   my $cd = $schema->resultset('CD')->find(5);
 750
 751 You can also find a row by a specific unique constraint:
 752
 753   my $cd = $schema->resultset('CD')->find(
 754     {
 755       artist => 'Massive Attack',
 756       title  => 'Mezzanine',
 757     },
 758     { key => 'cd_artist_title' }
 759   );
 760
 761 See also L</find_or_create> and L</update_or_create>.
 762
 763 =cut
 764
 765 sub find {
 766   my $self = shift;
 767   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 768
 769   my $rsrc = $self->result_source;
 770
 771   my $constraint_name;
 772   if (exists $attrs->{key}) {
 773     $constraint_name = defined $attrs->{key}
 774       ? $attrs->{key}
 775       : $self->throw_exception("An undefined 'key' resultset attribute makes no sense")
 776     ;
 777   }
 778
 779   # Parse out the condition from input
 780   my $call_cond;
 781
 782   if (ref $_[0] eq 'HASH') {
 783     $call_cond = { %{$_[0]} };
 784   }
 785   else {
 786     # if only values are supplied we need to default to 'primary'
 787     $constraint_name = 'primary' unless defined $constraint_name;
 788
 789     my @c_cols = $rsrc->unique_constraint_columns($constraint_name);
 790
 791     $self->throw_exception(
 792       "No constraint columns, maybe a malformed '$constraint_name' constraint?"
 793     ) unless @c_cols;
 794
 795     $self->throw_exception (
 796       'find() expects either a column/value hashref, or a list of values '
 797     . "corresponding to the columns of the specified unique constraint '$constraint_name'"
 798     ) unless @c_cols == @_;
 799
 800     $call_cond = {};
 801     @{$call_cond}{@c_cols} = @_;
 802   }
 803
 804   my %related;
 805   for my $key (keys %$call_cond) {
 806     if (
 807       my $keyref = ref($call_cond->{$key})
 808         and
 809       my $relinfo = $rsrc->relationship_info($key)
 810     ) {
 811       my $val = delete $call_cond->{$key};
 812
 813       next if $keyref eq 'ARRAY'; # has_many for multi_create
 814
 815       my $rel_q = $rsrc->_resolve_condition(
 816         $relinfo->{cond}, $val, $key, $key
 817       );
 818       die "Can't handle complex relationship conditions in find" if ref($rel_q) ne 'HASH';
 819       @related{keys %$rel_q} = values %$rel_q;
 820     }
 821   }
 822
 823   # relationship conditions take precedence (?)
 824   @{$call_cond}{keys %related} = values %related;
 825
 826   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 827   my $final_cond;
 828   if (defined $constraint_name) {
 829     $final_cond = $self->_qualify_cond_columns (
 830
 831       $self->_build_unique_cond (
 832         $constraint_name,
 833         $call_cond,
 834       ),
 835
 836       $alias,
 837     );
 838   }
 839   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 840     # This means that we got here after a merger of relationship conditions
 841     # in ::Relationship::Base::search_related (the row method), and furthermore
 842     # the relationship is of the 'single' type. This means that the condition
 843     # provided by the relationship (already attached to $self) is sufficient,
 844     # as there can be only one row in the database that would satisfy the
 845     # relationship
 846   }
 847   else {
 848     # no key was specified - fall down to heuristics mode:
 849     # run through all unique queries registered on the resultset, and
 850     # 'OR' all qualifying queries together
 851     my (@unique_queries, %seen_column_combinations);
 852     for my $c_name ($rsrc->unique_constraint_names) {
 853       next if $seen_column_combinations{
 854         join "\x00", sort $rsrc->unique_constraint_columns($c_name)
 855       }++;
 856
 857       push @unique_queries, try {
 858         $self->_build_unique_cond ($c_name, $call_cond, 'croak_on_nulls')
 859       } || ();
 860     }
 861
 862     $final_cond = @unique_queries
 863       ? [ map { $self->_qualify_cond_columns($_, $alias) } @unique_queries ]
 864       : $self->_non_unique_find_fallback ($call_cond, $attrs)
 865     ;
 866   }
 867
 868   # Run the query, passing the result_class since it should propagate for find
 869   my $rs = $self->search ($final_cond, {result_class => $self->result_class, %$attrs});
 870   if ($rs->_resolved_attrs->{collapse}) {
 871     my $row = $rs->next;
 872     carp "Query returned more than one row" if $rs->next;
 873     return $row;
 874   }
 875   else {
 876     return $rs->single;
 877   }
 878 }
 879
 880 # This is a stop-gap method as agreed during the discussion on find() cleanup:
 881 # http://lists.scsys.co.uk/pipermail/dbix-class/2010-October/009535.html
 882 #
 883 # It is invoked when find() is called in legacy-mode with insufficiently-unique
 884 # condition. It is provided for overrides until a saner way forward is devised
 885 #
 886 # *NOTE* This is not a public method, and it's *GUARANTEED* to disappear down
 887 # the road. Please adjust your tests accordingly to catch this situation early
 888 # DBIx::Class::ResultSet->can('_non_unique_find_fallback') is reasonable
 889 #
 890 # The method will not be removed without an adequately complete replacement
 891 # for strict-mode enforcement
 892 sub _non_unique_find_fallback {
 893   my ($self, $cond, $attrs) = @_;
 894
 895   return $self->_qualify_cond_columns(
 896     $cond,
 897     exists $attrs->{alias}
 898       ? $attrs->{alias}
 899       : $self->{attrs}{alias}
 900   );
 901 }
 902
 903
 904 sub _qualify_cond_columns {
 905   my ($self, $cond, $alias) = @_;
 906
 907   my %aliased = %$cond;
 908   for (keys %aliased) {
 909     $aliased{"$alias.$_"} = delete $aliased{$_}
 910       if $_ !~ /\./;
 911   }
 912
 913   return \%aliased;
 914 }
 915
 916 sub _build_unique_cond {
 917   my ($self, $constraint_name, $extra_cond, $croak_on_null) = @_;
 918
 919   my @c_cols = $self->result_source->unique_constraint_columns($constraint_name);
 920
 921   # combination may fail if $self->{cond} is non-trivial
 922   my ($final_cond) = try {
 923     $self->_merge_with_rscond ($extra_cond)
 924   } catch {
 925     +{ %$extra_cond }
 926   };
 927
 928   # trim out everything not in $columns
 929   $final_cond = { map {
 930     exists $final_cond->{$_}
 931       ? ( $_ => $final_cond->{$_} )
 932       : ()
 933   } @c_cols };
 934
 935   if (my @missing = grep
 936     { ! ($croak_on_null ? defined $final_cond->{$_} : exists $final_cond->{$_}) }
 937     (@c_cols)
 938   ) {
 939     $self->throw_exception( sprintf ( "Unable to satisfy requested constraint '%s', no values for column(s): %s",
 940       $constraint_name,
 941       join (', ', map { "'$_'" } @missing),
 942     ) );
 943   }
 944
 945   if (
 946     !$croak_on_null
 947       and
 948     !$ENV{DBIC_NULLABLE_KEY_NOWARN}
 949       and
 950     my @undefs = sort grep { ! defined $final_cond->{$_} } (keys %$final_cond)
 951   ) {
 952     carp_unique ( sprintf (
 953       "NULL/undef values supplied for requested unique constraint '%s' (NULL "
 954     . 'values in column(s): %s). This is almost certainly not what you wanted, '
 955     . 'though you can set DBIC_NULLABLE_KEY_NOWARN to disable this warning.',
 956       $constraint_name,
 957       join (', ', map { "'$_'" } @undefs),
 958     ));
 959   }
 960
 961   return $final_cond;
 962 }
 963
 964 =head2 search_related
 965
 966 =over 4
 967
 968 =item Arguments: $rel_name, $cond?, L<\%attrs?|/ATTRIBUTES>
 969
 970 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
 971
 972 =back
 973
 974   $new_rs = $cd_rs->search_related('artist', {
 975     name => 'Emo-R-Us',
 976   });
 977
 978 Searches the specified relationship, optionally specifying a condition and
 979 attributes for matching records. See L</ATTRIBUTES> for more information.
 980
 981 In list context, C<< ->all() >> is called implicitly on the resultset, thus
 982 returning a list of result objects instead. To avoid that, use L</search_related_rs>.
 983
 984 See also L</search_related_rs>.
 985
 986 =cut
 987
 988 sub search_related {
 989   return shift->related_resultset(shift)->search(@_);
 990 }
 991
 992 =head2 search_related_rs
 993
 994 This method works exactly the same as search_related, except that
 995 it guarantees a resultset, even in list context.
 996
 997 =cut
 998
 999 sub search_related_rs {
1000   return shift->related_resultset(shift)->search_rs(@_);
1001 }
1002
1003 =head2 cursor
1004
1005 =over 4
1006
1007 =item Arguments: none
1008
1009 =item Return Value: L<$cursor|DBIx::Class::Cursor>
1010
1011 =back
1012
1013 Returns a storage-driven cursor to the given resultset. See
1014 L<DBIx::Class::Cursor> for more information.
1015
1016 =cut
1017
1018 sub cursor {
1019   my $self = shift;
1020
1021   return $self->{cursor} ||= do {
1022     my $attrs = $self->_resolved_attrs;
1023     $self->result_source->storage->select(
1024       $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
1025     );
1026   };
1027 }
1028
1029 =head2 single
1030
1031 =over 4
1032
1033 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1034
1035 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1036
1037 =back
1038
1039   my $cd = $schema->resultset('CD')->single({ year => 2001 });
1040
1041 Inflates the first result without creating a cursor if the resultset has
1042 any records in it; if not returns C<undef>. Used by L</find> as a lean version
1043 of L</search>.
1044
1045 While this method can take an optional search condition (just like L</search>)
1046 being a fast-code-path it does not recognize search attributes. If you need to
1047 add extra joins or similar, call L</search> and then chain-call L</single> on the
1048 L<DBIx::Class::ResultSet> returned.
1049
1050 =over
1051
1052 =item B<Note>
1053
1054 As of 0.08100, this method enforces the assumption that the preceding
1055 query returns only one row. If more than one row is returned, you will receive
1056 a warning:
1057
1058   Query returned more than one row
1059
1060 In this case, you should be using L</next> or L</find> instead, or if you really
1061 know what you are doing, use the L</rows> attribute to explicitly limit the size
1062 of the resultset.
1063
1064 This method will also throw an exception if it is called on a resultset prefetching
1065 has_many, as such a prefetch implies fetching multiple rows from the database in
1066 order to assemble the resulting object.
1067
1068 =back
1069
1070 =cut
1071
1072 sub single {
1073   my ($self, $where) = @_;
1074   if(@_ > 2) {
1075       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
1076   }
1077
1078   my $attrs = { %{$self->_resolved_attrs} };
1079
1080   $self->throw_exception(
1081     'single() can not be used on resultsets collapsing a has_many. Use find( \%cond ) or next() instead'
1082   ) if $attrs->{collapse};
1083
1084   if ($where) {
1085     if (defined $attrs->{where}) {
1086       $attrs->{where} = {
1087         '-and' =>
1088             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
1089                $where, delete $attrs->{where} ]
1090       };
1091     } else {
1092       $attrs->{where} = $where;
1093     }
1094   }
1095
1096   my $data = [ $self->result_source->storage->select_single(
1097     $attrs->{from}, $attrs->{select},
1098     $attrs->{where}, $attrs
1099   )];
1100
1101   return undef unless @$data;
1102   $self->{_stashed_rows} = [ $data ];
1103   $self->_construct_results->[0];
1104 }
1105
1106
1107 # _collapse_query
1108 #
1109 # Recursively collapse the query, accumulating values for each column.
1110
1111 sub _collapse_query {
1112   my ($self, $query, $collapsed) = @_;
1113
1114   $collapsed ||= {};
1115
1116   if (ref $query eq 'ARRAY') {
1117     foreach my $subquery (@$query) {
1118       next unless ref $subquery;  # -or
1119       $collapsed = $self->_collapse_query($subquery, $collapsed);
1120     }
1121   }
1122   elsif (ref $query eq 'HASH') {
1123     if (keys %$query and (keys %$query)[0] eq '-and') {
1124       foreach my $subquery (@{$query->{-and}}) {
1125         $collapsed = $self->_collapse_query($subquery, $collapsed);
1126       }
1127     }
1128     else {
1129       foreach my $col (keys %$query) {
1130         my $value = $query->{$col};
1131         $collapsed->{$col}{$value}++;
1132       }
1133     }
1134   }
1135
1136   return $collapsed;
1137 }
1138
1139 =head2 get_column
1140
1141 =over 4
1142
1143 =item Arguments: L<$cond?|DBIx::Class::SQLMaker>
1144
1145 =item Return Value: L<$resultsetcolumn|DBIx::Class::ResultSetColumn>
1146
1147 =back
1148
1149   my $max_length = $rs->get_column('length')->max;
1150
1151 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
1152
1153 =cut
1154
1155 sub get_column {
1156   my ($self, $column) = @_;
1157   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
1158   return $new;
1159 }
1160
1161 =head2 search_like
1162
1163 =over 4
1164
1165 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1166
1167 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1168
1169 =back
1170
1171   # WHERE title LIKE '%blue%'
1172   $cd_rs = $rs->search_like({ title => '%blue%'});
1173
1174 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
1175 that this is simply a convenience method retained for ex Class::DBI users.
1176 You most likely want to use L</search> with specific operators.
1177
1178 For more information, see L<DBIx::Class::Manual::Cookbook>.
1179
1180 This method is deprecated and will be removed in 0.09. Use L</search()>
1181 instead. An example conversion is:
1182
1183   ->search_like({ foo => 'bar' });
1184
1185   # Becomes
1186
1187   ->search({ foo => { like => 'bar' } });
1188
1189 =cut
1190
1191 sub search_like {
1192   my $class = shift;
1193   carp_unique (
1194     'search_like() is deprecated and will be removed in DBIC version 0.09.'
1195    .' Instead use ->search({ x => { -like => "y%" } })'
1196    .' (note the outer pair of {}s - they are important!)'
1197   );
1198   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1199   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
1200   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
1201   return $class->search($query, { %$attrs });
1202 }
1203
1204 =head2 slice
1205
1206 =over 4
1207
1208 =item Arguments: $first, $last
1209
1210 =item Return Value: L<$resultset|/search> (scalar context) | L<@result_objs|DBIx::Class::Manual::ResultClass> (list context)
1211
1212 =back
1213
1214 Returns a resultset or object list representing a subset of elements from the
1215 resultset slice is called on. Indexes are from 0, i.e., to get the first
1216 three records, call:
1217
1218   my ($one, $two, $three) = $rs->slice(0, 2);
1219
1220 =cut
1221
1222 sub slice {
1223   my ($self, $min, $max) = @_;
1224   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
1225   $attrs->{offset} = $self->{attrs}{offset} || 0;
1226   $attrs->{offset} += $min;
1227   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
1228   return $self->search(undef, $attrs);
1229 }
1230
1231 =head2 next
1232
1233 =over 4
1234
1235 =item Arguments: none
1236
1237 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1238
1239 =back
1240
1241 Returns the next element in the resultset (C<undef> is there is none).
1242
1243 Can be used to efficiently iterate over records in the resultset:
1244
1245   my $rs = $schema->resultset('CD')->search;
1246   while (my $cd = $rs->next) {
1247     print $cd->title;
1248   }
1249
1250 Note that you need to store the resultset object, and call C<next> on it.
1251 Calling C<< resultset('Table')->next >> repeatedly will always return the
1252 first record from the resultset.
1253
1254 =cut
1255
1256 sub next {
1257   my ($self) = @_;
1258
1259   if (my $cache = $self->get_cache) {
1260     $self->{all_cache_position} ||= 0;
1261     return $cache->[$self->{all_cache_position}++];
1262   }
1263
1264   if ($self->{attrs}{cache}) {
1265     delete $self->{pager};
1266     $self->{all_cache_position} = 1;
1267     return ($self->all)[0];
1268   }
1269
1270   return shift(@{$self->{_stashed_results}}) if @{ $self->{_stashed_results}||[] };
1271
1272   $self->{_stashed_results} = $self->_construct_results
1273     or return undef;
1274
1275   return shift @{$self->{_stashed_results}};
1276 }
1277
1278 # Constructs as many results as it can in one pass while respecting
1279 # cursor laziness. Several modes of operation:
1280 #
1281 # * Always builds everything present in @{$self->{_stashed_rows}}
1282 # * If called with $fetch_all true - pulls everything off the cursor and
1283 #   builds all result structures (or objects) in one pass
1284 # * If $self->_resolved_attrs->{collapse} is true, checks the order_by
1285 #   and if the resultset is ordered properly by the left side:
1286 #   * Fetches stuff off the cursor until the "master object" changes,
1287 #     and saves the last extra row (if any) in @{$self->{_stashed_rows}}
1288 #   OR
1289 #   * Just fetches, and collapses/constructs everything as if $fetch_all
1290 #     was requested (there is no other way to collapse except for an
1291 #     eager cursor)
1292 # * If no collapse is requested - just get the next row, construct and
1293 #   return
1294 sub _construct_results {
1295   my ($self, $fetch_all) = @_;
1296
1297   my $rsrc = $self->result_source;
1298   my $attrs = $self->_resolved_attrs;
1299
1300   if (
1301     ! $fetch_all
1302       and
1303     ! $attrs->{order_by}
1304       and
1305     $attrs->{collapse}
1306       and
1307     my @pcols = $rsrc->primary_columns
1308   ) {
1309     # default order for collapsing unless the user asked for something
1310     $attrs->{order_by} = [ map { join '.', $attrs->{alias}, $_} @pcols ];
1311     $attrs->{_ordered_for_collapse} = 1;
1312     $attrs->{_order_is_artificial} = 1;
1313   }
1314
1315   # this will be used as both initial raw-row collector AND as a RV of
1316   # _construct_results. Not regrowing the array twice matters a lot...
1317   # a surprising amount actually
1318   my $rows = delete $self->{_stashed_rows};
1319
1320   my $cursor; # we may not need one at all
1321
1322   my $did_fetch_all = $fetch_all;
1323
1324   if ($fetch_all) {
1325     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1326     $rows = [ ($rows ? @$rows : ()), $self->cursor->all ];
1327   }
1328   elsif( $attrs->{collapse} ) {
1329
1330     # a cursor will need to be closed over in case of collapse
1331     $cursor = $self->cursor;
1332
1333     $attrs->{_ordered_for_collapse} = (
1334       (
1335         $attrs->{order_by}
1336           and
1337         $rsrc->schema
1338               ->storage
1339                ->_main_source_order_by_portion_is_stable($rsrc, $attrs->{order_by}, $attrs->{where})
1340       ) ? 1 : 0
1341     ) unless defined $attrs->{_ordered_for_collapse};
1342
1343     if (! $attrs->{_ordered_for_collapse}) {
1344       $did_fetch_all = 1;
1345
1346       # instead of looping over ->next, use ->all in stealth mode
1347       # *without* calling a ->reset afterwards
1348       # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1349       if (! $cursor->{_done}) {
1350         $rows = [ ($rows ? @$rows : ()), $cursor->all ];
1351         $cursor->{_done} = 1;
1352       }
1353     }
1354   }
1355
1356   if (! $did_fetch_all and ! @{$rows||[]} ) {
1357     # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1358     $cursor ||= $self->cursor;
1359     if (scalar (my @r = $cursor->next) ) {
1360       $rows = [ \@r ];
1361     }
1362   }
1363
1364   return undef unless @{$rows||[]};
1365
1366   # sanity check - people are too clever for their own good
1367   if ($attrs->{collapse} and my $aliastypes = $attrs->{_sqlmaker_select_args}[3]{_aliastypes} ) {
1368
1369     my $multiplied_selectors;
1370     for my $sel_alias ( grep { $_ ne $attrs->{alias} } keys %{ $aliastypes->{selecting} } ) {
1371       if (
1372         $aliastypes->{multiplying}{$sel_alias}
1373           or
1374         $aliastypes->{premultiplied}{$sel_alias}
1375       ) {
1376         $multiplied_selectors->{$_} = 1 for values %{$aliastypes->{selecting}{$sel_alias}{-seen_columns}}
1377       }
1378     }
1379
1380     for my $i (0 .. $#{$attrs->{as}} ) {
1381       my $sel = $attrs->{select}[$i];
1382
1383       if (ref $sel eq 'SCALAR') {
1384         $sel = $$sel;
1385       }
1386       elsif( ref $sel eq 'REF' and ref $$sel eq 'ARRAY' ) {
1387         $sel = $$sel->[0];
1388       }
1389
1390       $self->throw_exception(
1391         'Result collapse not possible - selection from a has_many source redirected to the main object'
1392       ) if ($multiplied_selectors->{$sel} and $attrs->{as}[$i] !~ /\./);
1393     }
1394   }
1395
1396   # hotspot - skip the setter
1397   my $res_class = $self->_result_class;
1398
1399   my $inflator_cref = $self->{_result_inflator}{cref} ||= do {
1400     $res_class->can ('inflate_result')
1401       or $self->throw_exception("Inflator $res_class does not provide an inflate_result() method");
1402   };
1403
1404   my $infmap = $attrs->{as};
1405
1406   $self->{_result_inflator}{is_core_row} = ( (
1407     $inflator_cref
1408       ==
1409     ( \&DBIx::Class::Row::inflate_result || die "No ::Row::inflate_result() - can't happen" )
1410   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_core_row};
1411
1412   $self->{_result_inflator}{is_hri} = ( (
1413     ! $self->{_result_inflator}{is_core_row}
1414       and
1415     $inflator_cref == (
1416       require DBIx::Class::ResultClass::HashRefInflator
1417         &&
1418       DBIx::Class::ResultClass::HashRefInflator->can('inflate_result')
1419     )
1420   ) ? 1 : 0 ) unless defined $self->{_result_inflator}{is_hri};
1421
1422
1423   if (! $attrs->{_related_results_construction}) {
1424     # construct a much simpler array->hash folder for the one-table cases right here
1425     if ($self->{_result_inflator}{is_hri}) {
1426       for my $r (@$rows) {
1427         $r = { map { $infmap->[$_] => $r->[$_] } 0..$#$infmap };
1428       }
1429     }
1430     # FIXME SUBOPTIMAL this is a very very very hot spot
1431     # while rather optimal we can *still* do much better, by
1432     # building a smarter Row::inflate_result(), and
1433     # switch to feeding it data via a much leaner interface
1434     #
1435     # crude unscientific benchmarking indicated the shortcut eval is not worth it for
1436     # this particular resultset size
1437     elsif (@$rows < 60) {
1438       for my $r (@$rows) {
1439         $r = $inflator_cref->($res_class, $rsrc, { map { $infmap->[$_] => $r->[$_] } (0..$#$infmap) } );
1440       }
1441     }
1442     else {
1443       eval sprintf (
1444         '$_ = $inflator_cref->($res_class, $rsrc, { %s }) for @$rows',
1445         join (', ', map { "\$infmap->[$_] => \$_->[$_]" } 0..$#$infmap )
1446       );
1447     }
1448   }
1449   else {
1450     my $parser_type =
1451         $self->{_result_inflator}{is_hri}       ? 'hri'
1452       : $self->{_result_inflator}{is_core_row}  ? 'classic_pruning'
1453       :                                           'classic_nonpruning'
1454     ;
1455
1456     # $args and $attrs to _mk_row_parser are separated to delineate what is
1457     # core collapser stuff and what is dbic $rs specific
1458     @{$self->{_row_parser}{$parser_type}}{qw(cref nullcheck)} = $rsrc->_mk_row_parser({
1459       eval => 1,
1460       inflate_map => $infmap,
1461       collapse => $attrs->{collapse},
1462       premultiplied => $attrs->{_main_source_premultiplied},
1463       hri_style => $self->{_result_inflator}{is_hri},
1464       prune_null_branches => $self->{_result_inflator}{is_hri} || $self->{_result_inflator}{is_core_row},
1465     }, $attrs) unless $self->{_row_parser}{$parser_type}{cref};
1466
1467     # column_info metadata historically hasn't been too reliable.
1468     # We need to start fixing this somehow (the collapse resolver
1469     # can't work without it). Add an explicit check for the *main*
1470     # result, hopefully this will gradually weed out such errors
1471     #
1472     # FIXME - this is a temporary kludge that reduces performance
1473     # It is however necessary for the time being
1474     my ($unrolled_non_null_cols_to_check, $err);
1475
1476     if (my $check_non_null_cols = $self->{_row_parser}{$parser_type}{nullcheck} ) {
1477
1478       $err =
1479         'Collapse aborted due to invalid ResultSource metadata - the following '
1480       . 'selections are declared non-nullable but NULLs were retrieved: '
1481       ;
1482
1483       my @violating_idx;
1484       COL: for my $i (@$check_non_null_cols) {
1485         ! defined $_->[$i] and push @violating_idx, $i and next COL for @$rows;
1486       }
1487
1488       $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1489         if @violating_idx;
1490
1491       $unrolled_non_null_cols_to_check = join (',', @$check_non_null_cols);
1492     }
1493
1494     my $next_cref =
1495       ($did_fetch_all or ! $attrs->{collapse})  ? undef
1496     : defined $unrolled_non_null_cols_to_check  ? eval sprintf <<'EOS', $unrolled_non_null_cols_to_check
1497 sub {
1498   # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1499   my @r = $cursor->next or return;
1500   if (my @violating_idx = grep { ! defined $r[$_] } (%s) ) {
1501     $self->throw_exception( $err . join (', ', map { "'$infmap->[$_]'" } @violating_idx ) )
1502   }
1503   \@r
1504 }
1505 EOS
1506     : sub {
1507         # FIXME SUBOPTIMAL - we can do better, cursor->next/all (well diff. methods) should return a ref
1508         my @r = $cursor->next or return;
1509         \@r
1510       }
1511     ;
1512
1513     $self->{_row_parser}{$parser_type}{cref}->(
1514       $rows,
1515       $next_cref ? ( $next_cref, $self->{_stashed_rows} = [] ) : (),
1516     );
1517
1518     # Special-case multi-object HRI - there is no $inflator_cref pass
1519     unless ($self->{_result_inflator}{is_hri}) {
1520       $_ = $inflator_cref->($res_class, $rsrc, @$_) for @$rows
1521     }
1522   }
1523
1524   # The @$rows check seems odd at first - why wouldn't we want to warn
1525   # regardless? The issue is things like find() etc, where the user
1526   # *knows* only one result will come back. In these cases the ->all
1527   # is not a pessimization, but rather something we actually want
1528   carp_unique(
1529     'Unable to properly collapse has_many results in iterator mode due '
1530   . 'to order criteria - performed an eager cursor slurp underneath. '
1531   . 'Consider using ->all() instead'
1532   ) if ( ! $fetch_all and @$rows > 1 );
1533
1534   return $rows;
1535 }
1536
1537 =head2 result_source
1538
1539 =over 4
1540
1541 =item Arguments: L<$result_source?|DBIx::Class::ResultSource>
1542
1543 =item Return Value: L<$result_source|DBIx::Class::ResultSource>
1544
1545 =back
1546
1547 An accessor for the primary ResultSource object from which this ResultSet
1548 is derived.
1549
1550 =head2 result_class
1551
1552 =over 4
1553
1554 =item Arguments: $result_class?
1555
1556 =item Return Value: $result_class
1557
1558 =back
1559
1560 An accessor for the class to use when creating result objects. Defaults to
1561 C<< result_source->result_class >> - which in most cases is the name of the
1562 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1563
1564 Note that changing the result_class will also remove any components
1565 that were originally loaded in the source class via
1566 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1567 in the original source class will not run.
1568
1569 =cut
1570
1571 sub result_class {
1572   my ($self, $result_class) = @_;
1573   if ($result_class) {
1574
1575     # don't fire this for an object
1576     $self->ensure_class_loaded($result_class)
1577       unless ref($result_class);
1578
1579     if ($self->get_cache) {
1580       carp_unique('Changing the result_class of a ResultSet instance with cached results is a noop - the cache contents will not be altered');
1581     }
1582     # FIXME ENCAPSULATION - encapsulation breach, cursor method additions pending
1583     elsif ($self->{cursor} && $self->{cursor}{_pos}) {
1584       $self->throw_exception('Changing the result_class of a ResultSet instance with an active cursor is not supported');
1585     }
1586
1587     $self->_result_class($result_class);
1588
1589     delete $self->{_result_inflator};
1590   }
1591   $self->_result_class;
1592 }
1593
1594 =head2 count
1595
1596 =over 4
1597
1598 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1599
1600 =item Return Value: $count
1601
1602 =back
1603
1604 Performs an SQL C<COUNT> with the same query as the resultset was built
1605 with to find the number of elements. Passing arguments is equivalent to
1606 C<< $rs->search ($cond, \%attrs)->count >>
1607
1608 =cut
1609
1610 sub count {
1611   my $self = shift;
1612   return $self->search(@_)->count if @_ and defined $_[0];
1613   return scalar @{ $self->get_cache } if $self->get_cache;
1614
1615   my $attrs = { %{ $self->_resolved_attrs } };
1616
1617   # this is a little optimization - it is faster to do the limit
1618   # adjustments in software, instead of a subquery
1619   my ($rows, $offset) = delete @{$attrs}{qw/rows offset/};
1620
1621   my $crs;
1622   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1623     $crs = $self->_count_subq_rs ($attrs);
1624   }
1625   else {
1626     $crs = $self->_count_rs ($attrs);
1627   }
1628   my $count = $crs->next;
1629
1630   $count -= $offset if $offset;
1631   $count = $rows if $rows and $rows < $count;
1632   $count = 0 if ($count < 0);
1633
1634   return $count;
1635 }
1636
1637 =head2 count_rs
1638
1639 =over 4
1640
1641 =item Arguments: L<$cond|DBIx::Class::SQLMaker>, L<\%attrs?|/ATTRIBUTES>
1642
1643 =item Return Value: L<$count_rs|DBIx::Class::ResultSetColumn>
1644
1645 =back
1646
1647 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1648 This can be very handy for subqueries:
1649
1650   ->search( { amount => $some_rs->count_rs->as_query } )
1651
1652 As with regular resultsets the SQL query will be executed only after
1653 the resultset is accessed via L</next> or L</all>. That would return
1654 the same single value obtainable via L</count>.
1655
1656 =cut
1657
1658 sub count_rs {
1659   my $self = shift;
1660   return $self->search(@_)->count_rs if @_;
1661
1662   # this may look like a lack of abstraction (count() does about the same)
1663   # but in fact an _rs *must* use a subquery for the limits, as the
1664   # software based limiting can not be ported if this $rs is to be used
1665   # in a subquery itself (i.e. ->as_query)
1666   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1667     return $self->_count_subq_rs($self->{_attrs});
1668   }
1669   else {
1670     return $self->_count_rs($self->{_attrs});
1671   }
1672 }
1673
1674 #
1675 # returns a ResultSetColumn object tied to the count query
1676 #
1677 sub _count_rs {
1678   my ($self, $attrs) = @_;
1679
1680   my $rsrc = $self->result_source;
1681
1682   my $tmp_attrs = { %$attrs };
1683   # take off any limits, record_filter is cdbi, and no point of ordering nor locking a count
1684   delete @{$tmp_attrs}{qw/rows offset order_by record_filter for/};
1685
1686   # overwrite the selector (supplied by the storage)
1687   $rsrc->resultset_class->new($rsrc, {
1688     %$tmp_attrs,
1689     select => $rsrc->storage->_count_select ($rsrc, $attrs),
1690     as => 'count',
1691   })->get_column ('count');
1692 }
1693
1694 #
1695 # same as above but uses a subquery
1696 #
1697 sub _count_subq_rs {
1698   my ($self, $attrs) = @_;
1699
1700   my $rsrc = $self->result_source;
1701
1702   my $sub_attrs = { %$attrs };
1703   # extra selectors do not go in the subquery and there is no point of ordering it, nor locking it
1704   delete @{$sub_attrs}{qw/collapse columns as select order_by for/};
1705
1706   # if we multi-prefetch we group_by something unique, as this is what we would
1707   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1708   if ( $attrs->{collapse}  ) {
1709     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } @{
1710       $rsrc->_identifying_column_set || $self->throw_exception(
1711         'Unable to construct a unique group_by criteria properly collapsing the '
1712       . 'has_many prefetch before count()'
1713       );
1714     } ]
1715   }
1716
1717   # Calculate subquery selector
1718   if (my $g = $sub_attrs->{group_by}) {
1719
1720     my $sql_maker = $rsrc->storage->sql_maker;
1721
1722     # necessary as the group_by may refer to aliased functions
1723     my $sel_index;
1724     for my $sel (@{$attrs->{select}}) {
1725       $sel_index->{$sel->{-as}} = $sel
1726         if (ref $sel eq 'HASH' and $sel->{-as});
1727     }
1728
1729     # anything from the original select mentioned on the group-by needs to make it to the inner selector
1730     # also look for named aggregates referred in the having clause
1731     # having often contains scalarrefs - thus parse it out entirely
1732     my @parts = @$g;
1733     if ($attrs->{having}) {
1734       local $sql_maker->{having_bind};
1735       local $sql_maker->{quote_char} = $sql_maker->{quote_char};
1736       local $sql_maker->{name_sep} = $sql_maker->{name_sep};
1737       unless (defined $sql_maker->{quote_char} and length $sql_maker->{quote_char}) {
1738         $sql_maker->{quote_char} = [ "\x00", "\xFF" ];
1739         # if we don't unset it we screw up retarded but unfortunately working
1740         # 'MAX(foo.bar)' => { '>', 3 }
1741         $sql_maker->{name_sep} = '';
1742       }
1743
1744       # delete local is 5.12+
1745       local @{$sql_maker}{qw(renderer converter)};
1746       delete @{$sql_maker}{qw(renderer converter)};
1747
1748       my ($lquote, $rquote, $sep) = map { quotemeta $_ } ($sql_maker->_quote_chars, $sql_maker->name_sep);
1749
1750       my $having_sql = $sql_maker->_render_sqla(where => $attrs->{having});
1751
1752       my %seen_having;
1753
1754       # search for both a proper quoted qualified string, for a naive unquoted scalarref
1755       # and if all fails for an utterly naive quoted scalar-with-function
1756       while ($having_sql =~ /
1757         (?: $rquote $sep)? $lquote (.+?) $rquote
1758           |
1759         [\s,] \w+ \. (\w+) [\s,]
1760           |
1761         [\s,] $lquote (.+?) $rquote [\s,]
1762       /gx) {
1763         my $part = $1 || $2 || $3;  # one of them matched if we got here
1764         unless ($seen_having{$part}++) {
1765           push @parts, $part;
1766         }
1767       }
1768     }
1769
1770     for (@parts) {
1771       my $colpiece = $sel_index->{$_} || $_;
1772
1773       # unqualify join-based group_by's. Arcane but possible query
1774       # also horrible horrible hack to alias a column (not a func.)
1775       # (probably need to introduce SQLA syntax)
1776       if ($colpiece =~ /\./ && $colpiece !~ /^$attrs->{alias}\./) {
1777         my $as = $colpiece;
1778         $as =~ s/\./__/;
1779         $colpiece = \ sprintf ('%s AS %s', map { $sql_maker->_quote ($_) } ($colpiece, $as) );
1780       }
1781       push @{$sub_attrs->{select}}, $colpiece;
1782     }
1783   }
1784   else {
1785     my @pcols = map { "$attrs->{alias}.$_" } ($rsrc->primary_columns);
1786     $sub_attrs->{select} = @pcols ? \@pcols : [ 1 ];
1787   }
1788
1789   return $rsrc->resultset_class
1790                ->new ($rsrc, $sub_attrs)
1791                 ->as_subselect_rs
1792                  ->search ({}, { columns => { count => $rsrc->storage->_count_select ($rsrc, $attrs) } })
1793                   ->get_column ('count');
1794 }
1795
1796
1797 =head2 count_literal
1798
1799 B<CAVEAT>: C<count_literal> is provided for Class::DBI compatibility and
1800 should only be used in that context. See L</search_literal> for further info.
1801
1802 =over 4
1803
1804 =item Arguments: $sql_fragment, @standalone_bind_values
1805
1806 =item Return Value: $count
1807
1808 =back
1809
1810 Counts the results in a literal query. Equivalent to calling L</search_literal>
1811 with the passed arguments, then L</count>.
1812
1813 =cut
1814
1815 sub count_literal { shift->search_literal(@_)->count; }
1816
1817 =head2 all
1818
1819 =over 4
1820
1821 =item Arguments: none
1822
1823 =item Return Value: L<@result_objs|DBIx::Class::Manual::ResultClass>
1824
1825 =back
1826
1827 Returns all elements in the resultset.
1828
1829 =cut
1830
1831 sub all {
1832   my $self = shift;
1833   if(@_) {
1834     $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1835   }
1836
1837   delete @{$self}{qw/_stashed_rows _stashed_results/};
1838
1839   if (my $c = $self->get_cache) {
1840     return @$c;
1841   }
1842
1843   $self->cursor->reset;
1844
1845   my $objs = $self->_construct_results('fetch_all') || [];
1846
1847   $self->set_cache($objs) if $self->{attrs}{cache};
1848
1849   return @$objs;
1850 }
1851
1852 =head2 reset
1853
1854 =over 4
1855
1856 =item Arguments: none
1857
1858 =item Return Value: $self
1859
1860 =back
1861
1862 Resets the resultset's cursor, so you can iterate through the elements again.
1863 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1864 another query.
1865
1866 =cut
1867
1868 sub reset {
1869   my ($self) = @_;
1870
1871   delete @{$self}{qw/_stashed_rows _stashed_results/};
1872   $self->{all_cache_position} = 0;
1873   $self->cursor->reset;
1874   return $self;
1875 }
1876
1877 =head2 first
1878
1879 =over 4
1880
1881 =item Arguments: none
1882
1883 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass> | undef
1884
1885 =back
1886
1887 L<Resets|/reset> the resultset (causing a fresh query to storage) and returns
1888 an object for the first result (or C<undef> if the resultset is empty).
1889
1890 =cut
1891
1892 sub first {
1893   return $_[0]->reset->next;
1894 }
1895
1896
1897 # _rs_update_delete
1898 #
1899 # Determines whether and what type of subquery is required for the $rs operation.
1900 # If grouping is necessary either supplies its own, or verifies the current one
1901 # After all is done delegates to the proper storage method.
1902
1903 sub _rs_update_delete {
1904   my ($self, $op, $values) = @_;
1905
1906   my $rsrc = $self->result_source;
1907   my $storage = $rsrc->schema->storage;
1908
1909   my $attrs = { %{$self->_resolved_attrs} };
1910
1911   my $join_classifications;
1912   my ($existing_group_by) = delete @{$attrs}{qw(group_by _grouped_by_distinct)};
1913
1914   # do we need a subquery for any reason?
1915   my $needs_subq = (
1916     defined $existing_group_by
1917       or
1918     # if {from} is unparseable wrap a subq
1919     ref($attrs->{from}) ne 'ARRAY'
1920       or
1921     # limits call for a subq
1922     $self->_has_resolved_attr(qw/rows offset/)
1923   );
1924
1925   # simplify the joinmap, so we can further decide if a subq is necessary
1926   if (!$needs_subq and @{$attrs->{from}} > 1) {
1927
1928     ($attrs->{from}, $join_classifications) =
1929       $storage->_prune_unused_joins ($attrs);
1930
1931     # any non-pruneable non-local restricting joins imply subq
1932     $needs_subq = defined List::Util::first { $_ ne $attrs->{alias} } keys %{ $join_classifications->{restricting} || {} };
1933   }
1934
1935   # check if the head is composite (by now all joins are thrown out unless $needs_subq)
1936   $needs_subq ||= (
1937     (ref $attrs->{from}[0]) ne 'HASH'
1938       or
1939     ref $attrs->{from}[0]{ $attrs->{from}[0]{-alias} }
1940   );
1941
1942   my ($cond, $guard);
1943   # do we need anything like a subquery?
1944   if (! $needs_subq) {
1945     # Most databases do not allow aliasing of tables in UPDATE/DELETE. Thus
1946     # a condition containing 'me' or other table prefixes will not work
1947     # at all - so we convert the WHERE to a dq tree now, dequalify all
1948     # identifiers found therein via a scan across the tree, and then use
1949     # \{} style to pass the result onwards for use in the final query
1950     if ($self->{cond}) {
1951       $cond = do {
1952         my $converter = $rsrc->storage->sql_maker->converter;
1953         scan_dq_nodes({
1954           DQ_IDENTIFIER ,=> sub { $_ = [ $_->[-1] ] for $_[0]->{elements} }
1955         }, my $where_dq = $converter->_where_to_dq($self->{cond}));
1956         \$where_dq;
1957       };
1958     }
1959   }
1960   else {
1961     # we got this far - means it is time to wrap a subquery
1962     my $idcols = $rsrc->_identifying_column_set || $self->throw_exception(
1963       sprintf(
1964         "Unable to perform complex resultset %s() without an identifying set of columns on source '%s'",
1965         $op,
1966         $rsrc->source_name,
1967       )
1968     );
1969
1970     # make a new $rs selecting only the PKs (that's all we really need for the subq)
1971     delete $attrs->{$_} for qw/select as collapse/;
1972     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } @$idcols ];
1973
1974     # this will be consumed by the pruner waaaaay down the stack
1975     $attrs->{_force_prune_multiplying_joins} = 1;
1976
1977     my $subrs = (ref $self)->new($rsrc, $attrs);
1978
1979     if (@$idcols == 1) {
1980       $cond = { $idcols->[0] => { -in => \$subrs->_as_select_dq } };
1981     }
1982     elsif ($storage->_use_multicolumn_in) {
1983       # no syntax for calling this properly yet
1984       # !!! EXPERIMENTAL API !!! WILL CHANGE !!!
1985       my $left = $storage->sql_maker->_render_sqla(select_select => $idcols);
1986       $left =~ s/^SELECT //i;
1987       my $right = $storage->sql_maker
1988                           ->converter
1989                           ->_literal_to_dq(${$subrs->as_query});
1990       $cond = \Operator(
1991         { 'SQL.Naive' => 'in' },
1992         [ Literal(SQL => "( $left )"), $right ],
1993       ),
1994     }
1995     else {
1996       # if all else fails - get all primary keys and operate over a ORed set
1997       # wrap in a transaction for consistency
1998       # this is where the group_by/multiplication starts to matter
1999       if (
2000         $existing_group_by
2001           or
2002         # we do not need to check pre-multipliers, since if the premulti is there, its
2003         # parent (who is multi) will be there too
2004         keys %{ $join_classifications->{multiplying} || {} }
2005       ) {
2006         # make sure if there is a supplied group_by it matches the columns compiled above
2007         # perfectly. Anything else can not be sanely executed on most databases so croak
2008         # right then and there
2009         if ($existing_group_by) {
2010           my @current_group_by = map
2011             { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
2012             @$existing_group_by
2013           ;
2014
2015           if (
2016             join ("\x00", sort @current_group_by)
2017               ne
2018             join ("\x00", sort @{$attrs->{columns}} )
2019           ) {
2020             $self->throw_exception (
2021               "You have just attempted a $op operation on a resultset which does group_by"
2022               . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
2023               . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
2024               . ' kind of queries. Please retry the operation with a modified group_by or'
2025               . ' without using one at all.'
2026             );
2027           }
2028         }
2029
2030         $subrs = $subrs->search({}, { group_by => $attrs->{columns} });
2031       }
2032
2033       $guard = $storage->txn_scope_guard;
2034
2035       $cond = [];
2036       for my $row ($subrs->cursor->all) {
2037         push @$cond, { map
2038           { $idcols->[$_] => $row->[$_] }
2039           (0 .. $#$idcols)
2040         };
2041       }
2042     }
2043   }
2044
2045   my $res = $storage->$op (
2046     $rsrc,
2047     $op eq 'update' ? $values : (),
2048     $cond,
2049   );
2050
2051   $guard->commit if $guard;
2052
2053   return $res;
2054 }
2055
2056 =head2 update
2057
2058 =over 4
2059
2060 =item Arguments: \%values
2061
2062 =item Return Value: $underlying_storage_rv
2063
2064 =back
2065
2066 Sets the specified columns in the resultset to the supplied values in a
2067 single query. Note that this will not run any accessor/set_column/update
2068 triggers, nor will it update any result object instances derived from this
2069 resultset (this includes the contents of the L<resultset cache|/set_cache>
2070 if any). See L</update_all> if you need to execute any on-update
2071 triggers or cascades defined either by you or a
2072 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2073
2074 The return value is a pass through of what the underlying
2075 storage backend returned, and may vary. See L<DBI/execute> for the most
2076 common case.
2077
2078 =head3 CAVEAT
2079
2080 Note that L</update> does not process/deflate any of the values passed in.
2081 This is unlike the corresponding L<DBIx::Class::Row/update>. The user must
2082 ensure manually that any value passed to this method will stringify to
2083 something the RDBMS knows how to deal with. A notable example is the
2084 handling of L<DateTime> objects, for more info see:
2085 L<DBIx::Class::Manual::Cookbook/Formatting DateTime objects in queries>.
2086
2087 =cut
2088
2089 sub update {
2090   my ($self, $values) = @_;
2091   $self->throw_exception('Values for update must be a hash')
2092     unless ref $values eq 'HASH';
2093
2094   return $self->_rs_update_delete ('update', $values);
2095 }
2096
2097 =head2 update_all
2098
2099 =over 4
2100
2101 =item Arguments: \%values
2102
2103 =item Return Value: 1
2104
2105 =back
2106
2107 Fetches all objects and updates them one at a time via
2108 L<DBIx::Class::Row/update>. Note that C<update_all> will run DBIC defined
2109 triggers, while L</update> will not.
2110
2111 =cut
2112
2113 sub update_all {
2114   my ($self, $values) = @_;
2115   $self->throw_exception('Values for update_all must be a hash')
2116     unless ref $values eq 'HASH';
2117
2118   my $guard = $self->result_source->schema->txn_scope_guard;
2119   $_->update({%$values}) for $self->all;  # shallow copy - update will mangle it
2120   $guard->commit;
2121   return 1;
2122 }
2123
2124 =head2 delete
2125
2126 =over 4
2127
2128 =item Arguments: none
2129
2130 =item Return Value: $underlying_storage_rv
2131
2132 =back
2133
2134 Deletes the rows matching this resultset in a single query. Note that this
2135 will not run any delete triggers, nor will it alter the
2136 L<in_storage|DBIx::Class::Row/in_storage> status of any result object instances
2137 derived from this resultset (this includes the contents of the
2138 L<resultset cache|/set_cache> if any). See L</delete_all> if you need to
2139 execute any on-delete triggers or cascades defined either by you or a
2140 L<result component|DBIx::Class::Manual::Component/WHAT IS A COMPONENT>.
2141
2142 The return value is a pass through of what the underlying storage backend
2143 returned, and may vary. See L<DBI/execute> for the most common case.
2144
2145 =cut
2146
2147 sub delete {
2148   my $self = shift;
2149   $self->throw_exception('delete does not accept any arguments')
2150     if @_;
2151
2152   return $self->_rs_update_delete ('delete');
2153 }
2154
2155 =head2 delete_all
2156
2157 =over 4
2158
2159 =item Arguments: none
2160
2161 =item Return Value: 1
2162
2163 =back
2164
2165 Fetches all objects and deletes them one at a time via
2166 L<DBIx::Class::Row/delete>. Note that C<delete_all> will run DBIC defined
2167 triggers, while L</delete> will not.
2168
2169 =cut
2170
2171 sub delete_all {
2172   my $self = shift;
2173   $self->throw_exception('delete_all does not accept any arguments')
2174     if @_;
2175
2176   my $guard = $self->result_source->schema->txn_scope_guard;
2177   $_->delete for $self->all;
2178   $guard->commit;
2179   return 1;
2180 }
2181
2182 =head2 populate
2183
2184 =over 4
2185
2186 =item Arguments: [ \@column_list, \@row_values+ ] | [ \%col_data+ ]
2187
2188 =item Return Value: L<\@result_objects|DBIx::Class::Manual::ResultClass> (scalar context) | L<@result_objects|DBIx::Class::Manual::ResultClass> (list context)
2189
2190 =back
2191
2192 Accepts either an arrayref of hashrefs or alternatively an arrayref of
2193 arrayrefs.
2194
2195 =over
2196
2197 =item NOTE
2198
2199 The context of this method call has an important effect on what is
2200 submitted to storage. In void context data is fed directly to fastpath
2201 insertion routines provided by the underlying storage (most often
2202 L<DBI/execute_for_fetch>), bypassing the L<new|DBIx::Class::Row/new> and
2203 L<insert|DBIx::Class::Row/insert> calls on the
2204 L<Result|DBIx::Class::Manual::ResultClass> class, including any
2205 augmentation of these methods provided by components. For example if you
2206 are using something like L<DBIx::Class::UUIDColumns> to create primary
2207 keys for you, you will find that your PKs are empty.  In this case you
2208 will have to explicitly force scalar or list context in order to create
2209 those values.
2210
2211 =back
2212
2213 In non-void (scalar or list) context, this method is simply a wrapper
2214 for L</create>. Depending on list or scalar context either a list of
2215 L<Result|DBIx::Class::Manual::ResultClass> objects or an arrayref
2216 containing these objects is returned.
2217
2218 When supplying data in "arrayref of arrayrefs" invocation style, the
2219 first element should be a list of column names and each subsequent
2220 element should be a data value in the earlier specified column order.
2221 For example:
2222
2223   $schema->resultset("Artist")->populate([
2224     [ qw( artistid name ) ],
2225     [ 100, 'A Formally Unknown Singer' ],
2226     [ 101, 'A singer that jumped the shark two albums ago' ],
2227     [ 102, 'An actually cool singer' ],
2228   ]);
2229
2230 For the arrayref of hashrefs style each hashref should be a structure
2231 suitable for passing to L</create>. Multi-create is also permitted with
2232 this syntax.
2233
2234   $schema->resultset("Artist")->populate([
2235      { artistid => 4, name => 'Manufactured Crap', cds => [
2236         { title => 'My First CD', year => 2006 },
2237         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2238       ],
2239      },
2240      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
2241         { title => 'My parents sold me to a record company', year => 2005 },
2242         { title => 'Why Am I So Ugly?', year => 2006 },
2243         { title => 'I Got Surgery and am now Popular', year => 2007 }
2244       ],
2245      },
2246   ]);
2247
2248 If you attempt a void-context multi-create as in the example above (each
2249 Artist also has the related list of CDs), and B<do not> supply the
2250 necessary autoinc foreign key information, this method will proxy to the
2251 less efficient L</create>, and then throw the Result objects away. In this
2252 case there are obviously no benefits to using this method over L</create>.
2253
2254 =cut
2255
2256 sub populate {
2257   my $self = shift;
2258
2259   # cruft placed in standalone method
2260   my $data = $self->_normalize_populate_args(@_);
2261
2262   return unless @$data;
2263
2264   if(defined wantarray) {
2265     my @created = map { $self->create($_) } @$data;
2266     return wantarray ? @created : \@created;
2267   }
2268   else {
2269     my $first = $data->[0];
2270
2271     # if a column is a registered relationship, and is a non-blessed hash/array, consider
2272     # it relationship data
2273     my (@rels, @columns);
2274     my $rsrc = $self->result_source;
2275     my $rels = { map { $_ => $rsrc->relationship_info($_) } $rsrc->relationships };
2276     for (keys %$first) {
2277       my $ref = ref $first->{$_};
2278       $rels->{$_} && ($ref eq 'ARRAY' or $ref eq 'HASH')
2279         ? push @rels, $_
2280         : push @columns, $_
2281       ;
2282     }
2283
2284     my @pks = $rsrc->primary_columns;
2285
2286     ## do the belongs_to relationships
2287     foreach my $index (0..$#$data) {
2288
2289       # delegate to create() for any dataset without primary keys with specified relationships
2290       if (grep { !defined $data->[$index]->{$_} } @pks ) {
2291         for my $r (@rels) {
2292           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
2293             my @ret = $self->populate($data);
2294             return;
2295           }
2296         }
2297       }
2298
2299       foreach my $rel (@rels) {
2300         next unless ref $data->[$index]->{$rel} eq "HASH";
2301         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
2302         my ($reverse_relname, $reverse_relinfo) = %{$rsrc->reverse_relationship_info($rel)};
2303         my $related = $result->result_source->_resolve_condition(
2304           $reverse_relinfo->{cond},
2305           $self,
2306           $result,
2307           $rel,
2308         );
2309
2310         delete $data->[$index]->{$rel};
2311         $data->[$index] = {%{$data->[$index]}, %$related};
2312
2313         push @columns, keys %$related if $index == 0;
2314       }
2315     }
2316
2317     ## inherit the data locked in the conditions of the resultset
2318     my ($rs_data) = $self->_merge_with_rscond({});
2319     delete @{$rs_data}{@columns};
2320
2321     ## do bulk insert on current row
2322     $rsrc->storage->insert_bulk(
2323       $rsrc,
2324       [@columns, keys %$rs_data],
2325       [ map { [ @$_{@columns}, values %$rs_data ] } @$data ],
2326     );
2327
2328     ## do the has_many relationships
2329     foreach my $item (@$data) {
2330
2331       my $main_row;
2332
2333       foreach my $rel (@rels) {
2334         next unless ref $item->{$rel} eq "ARRAY" && @{ $item->{$rel} };
2335
2336         $main_row ||= $self->new_result({map { $_ => $item->{$_} } @pks});
2337
2338         my $child = $main_row->$rel;
2339
2340         my $related = $child->result_source->_resolve_condition(
2341           $rels->{$rel}{cond},
2342           $child,
2343           $main_row,
2344           $rel,
2345         );
2346
2347         if (ref($related) eq 'REF' and ref($$related) eq 'HASH') {
2348           $related = $self->result_source
2349                           ->_extract_fixed_values_for($$related, $rel);
2350         }
2351
2352         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
2353         my @populate = map { {%$_, %$related} } @rows_to_add;
2354
2355         $child->populate( \@populate );
2356       }
2357     }
2358   }
2359 }
2360
2361 # populate() arguments went over several incarnations
2362 # What we ultimately support is AoH
2363 sub _normalize_populate_args {
2364   my ($self, $arg) = @_;
2365
2366   if (ref $arg eq 'ARRAY') {
2367     if (!@$arg) {
2368       return [];
2369     }
2370     elsif (ref $arg->[0] eq 'HASH') {
2371       return $arg;
2372     }
2373     elsif (ref $arg->[0] eq 'ARRAY') {
2374       my @ret;
2375       my @colnames = @{$arg->[0]};
2376       foreach my $values (@{$arg}[1 .. $#$arg]) {
2377         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
2378       }
2379       return \@ret;
2380     }
2381   }
2382
2383   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
2384 }
2385
2386 =head2 pager
2387
2388 =over 4
2389
2390 =item Arguments: none
2391
2392 =item Return Value: L<$pager|Data::Page>
2393
2394 =back
2395
2396 Returns a L<Data::Page> object for the current resultset. Only makes
2397 sense for queries with a C<page> attribute.
2398
2399 To get the full count of entries for a paged resultset, call
2400 C<total_entries> on the L<Data::Page> object.
2401
2402 =cut
2403
2404 sub pager {
2405   my ($self) = @_;
2406
2407   return $self->{pager} if $self->{pager};
2408
2409   my $attrs = $self->{attrs};
2410   if (!defined $attrs->{page}) {
2411     $self->throw_exception("Can't create pager for non-paged rs");
2412   }
2413   elsif ($attrs->{page} <= 0) {
2414     $self->throw_exception('Invalid page number (page-numbers are 1-based)');
2415   }
2416   $attrs->{rows} ||= 10;
2417
2418   # throw away the paging flags and re-run the count (possibly
2419   # with a subselect) to get the real total count
2420   my $count_attrs = { %$attrs };
2421   delete @{$count_attrs}{qw/rows offset page pager/};
2422
2423   my $total_rs = (ref $self)->new($self->result_source, $count_attrs);
2424
2425   require DBIx::Class::ResultSet::Pager;
2426   return $self->{pager} = DBIx::Class::ResultSet::Pager->new(
2427     sub { $total_rs->count },  #lazy-get the total
2428     $attrs->{rows},
2429     $self->{attrs}{page},
2430   );
2431 }
2432
2433 =head2 page
2434
2435 =over 4
2436
2437 =item Arguments: $page_number
2438
2439 =item Return Value: L<$resultset|/search>
2440
2441 =back
2442
2443 Returns a resultset for the $page_number page of the resultset on which page
2444 is called, where each page contains a number of rows equal to the 'rows'
2445 attribute set on the resultset (10 by default).
2446
2447 =cut
2448
2449 sub page {
2450   my ($self, $page) = @_;
2451   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
2452 }
2453
2454 =head2 new_result
2455
2456 =over 4
2457
2458 =item Arguments: \%col_data
2459
2460 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2461
2462 =back
2463
2464 Creates a new result object in the resultset's result class and returns
2465 it. The row is not inserted into the database at this point, call
2466 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
2467 will tell you whether the result object has been inserted or not.
2468
2469 Passes the hashref of input on to L<DBIx::Class::Row/new>.
2470
2471 =cut
2472
2473 sub new_result {
2474   my ($self, $values) = @_;
2475
2476   $self->throw_exception( "new_result takes only one argument - a hashref of values" )
2477     if @_ > 2;
2478
2479   $self->throw_exception( "new_result expects a hashref" )
2480     unless (ref $values eq 'HASH');
2481
2482   my ($merged_cond, $cols_from_relations) = $self->_merge_with_rscond($values);
2483
2484   my $new = $self->result_class->new({
2485     %$merged_cond,
2486     ( @$cols_from_relations
2487       ? (-cols_from_relations => $cols_from_relations)
2488       : ()
2489     ),
2490     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2491   });
2492
2493   if (
2494     reftype($new) eq 'HASH'
2495       and
2496     ! keys %$new
2497       and
2498     blessed($new)
2499   ) {
2500     carp_unique (sprintf (
2501       "%s->new returned a blessed empty hashref - a strong indicator something is wrong with its inheritance chain",
2502       $self->result_class,
2503     ));
2504   }
2505
2506   $new;
2507 }
2508
2509 # _merge_with_rscond
2510 #
2511 # Takes a simple hash of K/V data and returns its copy merged with the
2512 # condition already present on the resultset. Additionally returns an
2513 # arrayref of value/condition names, which were inferred from related
2514 # objects (this is needed for in-memory related objects)
2515 sub _merge_with_rscond {
2516   my ($self, $data) = @_;
2517
2518   my (%new_data, @cols_from_relations);
2519
2520   my $alias = $self->{attrs}{alias};
2521
2522   if (! defined $self->{cond}) {
2523     # just massage $data below
2524   }
2525   elsif (ref $self->{cond} eq 'HASH') {
2526     # precedence must be given to passed values over values inherited from
2527     # the cond, so the order here is important.
2528     my $collapsed_cond = $self->_collapse_cond($self->{cond});
2529     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2530
2531     while ( my($col, $value) = each %implied ) {
2532       my $vref = ref $value;
2533       if (
2534         $vref eq 'HASH'
2535           and
2536         keys(%$value) == 1
2537           and
2538         (keys %$value)[0] eq '='
2539       ) {
2540         $new_data{$col} = $value->{'='};
2541       }
2542       elsif( !$vref or $vref eq 'SCALAR' or blessed($value) ) {
2543         $new_data{$col} = $value;
2544       }
2545     }
2546   }
2547   elsif (ref $self->{cond} eq 'REF' and ref ${$self->{cond}} eq 'HASH') {
2548     if ((${$self->{cond}})->{'DBIx::Class::ResultSource.UNRESOLVABLE'}) {
2549       %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2550       @cols_from_relations = keys %new_data;
2551     } else {
2552       %new_data = %{$self->_remove_alias(
2553         $self->result_source
2554              ->_extract_fixed_values_for(${$self->{cond}}),
2555         $alias
2556       )};
2557     }
2558   }
2559   else {
2560     $self->throw_exception(
2561       "Can't abstract implicit construct, resultset condition not a hash"
2562     );
2563   }
2564
2565   %new_data = (
2566     %new_data,
2567     %{ $self->_remove_alias($data, $alias) },
2568   );
2569
2570   return (\%new_data, \@cols_from_relations);
2571 }
2572
2573 # _has_resolved_attr
2574 #
2575 # determines if the resultset defines at least one
2576 # of the attributes supplied
2577 #
2578 # used to determine if a subquery is necessary
2579 #
2580 # supports some virtual attributes:
2581 #   -join
2582 #     This will scan for any joins being present on the resultset.
2583 #     It is not a mere key-search but a deep inspection of {from}
2584 #
2585
2586 sub _has_resolved_attr {
2587   my ($self, @attr_names) = @_;
2588
2589   my $attrs = $self->_resolved_attrs;
2590
2591   my %extra_checks;
2592
2593   for my $n (@attr_names) {
2594     if (grep { $n eq $_ } (qw/-join/) ) {
2595       $extra_checks{$n}++;
2596       next;
2597     }
2598
2599     my $attr =  $attrs->{$n};
2600
2601     next if not defined $attr;
2602
2603     if (ref $attr eq 'HASH') {
2604       return 1 if keys %$attr;
2605     }
2606     elsif (ref $attr eq 'ARRAY') {
2607       return 1 if @$attr;
2608     }
2609     else {
2610       return 1 if $attr;
2611     }
2612   }
2613
2614   # a resolved join is expressed as a multi-level from
2615   return 1 if (
2616     $extra_checks{-join}
2617       and
2618     ref $attrs->{from} eq 'ARRAY'
2619       and
2620     @{$attrs->{from}} > 1
2621   );
2622
2623   return 0;
2624 }
2625
2626 # _collapse_cond
2627 #
2628 # Recursively collapse the condition.
2629
2630 sub _collapse_cond {
2631   my ($self, $cond, $collapsed) = @_;
2632
2633   $collapsed ||= {};
2634
2635   if (ref $cond eq 'ARRAY') {
2636     foreach my $subcond (@$cond) {
2637       next unless ref $subcond;  # -or
2638       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2639     }
2640   }
2641   elsif (ref $cond eq 'HASH') {
2642     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2643       foreach my $subcond (@{$cond->{-and}}) {
2644         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2645       }
2646     }
2647     else {
2648       foreach my $col (keys %$cond) {
2649         my $value = $cond->{$col};
2650         $collapsed->{$col} = $value;
2651       }
2652     }
2653   }
2654
2655   return $collapsed;
2656 }
2657
2658 # _remove_alias
2659 #
2660 # Remove the specified alias from the specified query hash. A copy is made so
2661 # the original query is not modified.
2662
2663 sub _remove_alias {
2664   my ($self, $query, $alias) = @_;
2665
2666   my %orig = %{ $query || {} };
2667   my %unaliased;
2668
2669   foreach my $key (keys %orig) {
2670     if ($key !~ /\./) {
2671       $unaliased{$key} = $orig{$key};
2672       next;
2673     }
2674     $unaliased{$1} = $orig{$key}
2675       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2676   }
2677
2678   return \%unaliased;
2679 }
2680
2681 =head2 as_query
2682
2683 =over 4
2684
2685 =item Arguments: none
2686
2687 =item Return Value: \[ $sql, L<@bind_values|/DBIC BIND VALUES> ]
2688
2689 =back
2690
2691 Returns the SQL query and bind vars associated with the invocant.
2692
2693 This is generally used as the RHS for a subquery.
2694
2695 =cut
2696
2697 sub as_query {
2698   my $self = shift;
2699
2700   my $attrs = { %{ $self->_resolved_attrs } };
2701
2702   my $aq = $self->result_source->storage->_select_args_to_query (
2703     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2704   );
2705
2706   $self->{_attrs}{_sqlmaker_select_args} = $attrs->{_sqlmaker_select_args};
2707
2708   $aq;
2709 }
2710
2711 sub _as_select_dq {
2712   my $self = shift;
2713   my $attrs = { %{ $self->_resolved_attrs } };
2714   my $storage = $self->result_source->storage;
2715   my (undef, $ident, @args) = $storage->_select_args(
2716     $attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs
2717   );
2718   $ident = $ident->from if blessed($ident);
2719   $storage->sql_maker->converter->_select_to_dq(
2720     $ident, @args
2721   );
2722 }
2723
2724 =head2 find_or_new
2725
2726 =over 4
2727
2728 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2729
2730 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2731
2732 =back
2733
2734   my $artist = $schema->resultset('Artist')->find_or_new(
2735     { artist => 'fred' }, { key => 'artists' });
2736
2737   $cd->cd_to_producer->find_or_new({ producer => $producer },
2738                                    { key => 'primary' });
2739
2740 Find an existing record from this resultset using L</find>. if none exists,
2741 instantiate a new result object and return it. The object will not be saved
2742 into your storage until you call L<DBIx::Class::Row/insert> on it.
2743
2744 You most likely want this method when looking for existing rows using a unique
2745 constraint that is not the primary key, or looking for related rows.
2746
2747 If you want objects to be saved immediately, use L</find_or_create> instead.
2748
2749 B<Note>: Make sure to read the documentation of L</find> and understand the
2750 significance of the C<key> attribute, as its lack may skew your search, and
2751 subsequently result in spurious new objects.
2752
2753 B<Note>: Take care when using C<find_or_new> with a table having
2754 columns with default values that you intend to be automatically
2755 supplied by the database (e.g. an auto_increment primary key column).
2756 In normal usage, the value of such columns should NOT be included at
2757 all in the call to C<find_or_new>, even when set to C<undef>.
2758
2759 =cut
2760
2761 sub find_or_new {
2762   my $self     = shift;
2763   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2764   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2765   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2766     return $row;
2767   }
2768   return $self->new_result($hash);
2769 }
2770
2771 =head2 create
2772
2773 =over 4
2774
2775 =item Arguments: \%col_data
2776
2777 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2778
2779 =back
2780
2781 Attempt to create a single new row or a row with multiple related rows
2782 in the table represented by the resultset (and related tables). This
2783 will not check for duplicate rows before inserting, use
2784 L</find_or_create> to do that.
2785
2786 To create one row for this resultset, pass a hashref of key/value
2787 pairs representing the columns of the table and the values you wish to
2788 store. If the appropriate relationships are set up, foreign key fields
2789 can also be passed an object representing the foreign row, and the
2790 value will be set to its primary key.
2791
2792 To create related objects, pass a hashref of related-object column values
2793 B<keyed on the relationship name>. If the relationship is of type C<multi>
2794 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2795 The process will correctly identify columns holding foreign keys, and will
2796 transparently populate them from the keys of the corresponding relation.
2797 This can be applied recursively, and will work correctly for a structure
2798 with an arbitrary depth and width, as long as the relationships actually
2799 exists and the correct column data has been supplied.
2800
2801 Instead of hashrefs of plain related data (key/value pairs), you may
2802 also pass new or inserted objects. New objects (not inserted yet, see
2803 L</new_result>), will be inserted into their appropriate tables.
2804
2805 Effectively a shortcut for C<< ->new_result(\%col_data)->insert >>.
2806
2807 Example of creating a new row.
2808
2809   $person_rs->create({
2810     name=>"Some Person",
2811     email=>"somebody@someplace.com"
2812   });
2813
2814 Example of creating a new row and also creating rows in a related C<has_many>
2815 or C<has_one> resultset.  Note Arrayref.
2816
2817   $artist_rs->create(
2818      { artistid => 4, name => 'Manufactured Crap', cds => [
2819         { title => 'My First CD', year => 2006 },
2820         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2821       ],
2822      },
2823   );
2824
2825 Example of creating a new row and also creating a row in a related
2826 C<belongs_to> resultset. Note Hashref.
2827
2828   $cd_rs->create({
2829     title=>"Music for Silly Walks",
2830     year=>2000,
2831     artist => {
2832       name=>"Silly Musician",
2833     }
2834   });
2835
2836 =over
2837
2838 =item WARNING
2839
2840 When subclassing ResultSet never attempt to override this method. Since
2841 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2842 lot of the internals simply never call it, so your override will be
2843 bypassed more often than not. Override either L<DBIx::Class::Row/new>
2844 or L<DBIx::Class::Row/insert> depending on how early in the
2845 L</create> process you need to intervene. See also warning pertaining to
2846 L</new>.
2847
2848 =back
2849
2850 =cut
2851
2852 sub create {
2853   my ($self, $col_data) = @_;
2854   $self->throw_exception( "create needs a hashref" )
2855     unless ref $col_data eq 'HASH';
2856   return $self->new_result($col_data)->insert;
2857 }
2858
2859 =head2 find_or_create
2860
2861 =over 4
2862
2863 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2864
2865 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2866
2867 =back
2868
2869   $cd->cd_to_producer->find_or_create({ producer => $producer },
2870                                       { key => 'primary' });
2871
2872 Tries to find a record based on its primary key or unique constraints; if none
2873 is found, creates one and returns that instead.
2874
2875   my $cd = $schema->resultset('CD')->find_or_create({
2876     cdid   => 5,
2877     artist => 'Massive Attack',
2878     title  => 'Mezzanine',
2879     year   => 2005,
2880   });
2881
2882 Also takes an optional C<key> attribute, to search by a specific key or unique
2883 constraint. For example:
2884
2885   my $cd = $schema->resultset('CD')->find_or_create(
2886     {
2887       artist => 'Massive Attack',
2888       title  => 'Mezzanine',
2889     },
2890     { key => 'cd_artist_title' }
2891   );
2892
2893 B<Note>: Make sure to read the documentation of L</find> and understand the
2894 significance of the C<key> attribute, as its lack may skew your search, and
2895 subsequently result in spurious row creation.
2896
2897 B<Note>: Because find_or_create() reads from the database and then
2898 possibly inserts based on the result, this method is subject to a race
2899 condition. Another process could create a record in the table after
2900 the find has completed and before the create has started. To avoid
2901 this problem, use find_or_create() inside a transaction.
2902
2903 B<Note>: Take care when using C<find_or_create> with a table having
2904 columns with default values that you intend to be automatically
2905 supplied by the database (e.g. an auto_increment primary key column).
2906 In normal usage, the value of such columns should NOT be included at
2907 all in the call to C<find_or_create>, even when set to C<undef>.
2908
2909 See also L</find> and L</update_or_create>. For information on how to declare
2910 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2911
2912 If you need to know if an existing row was found or a new one created use
2913 L</find_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2914 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2915 database!
2916
2917   my $cd = $schema->resultset('CD')->find_or_new({
2918     cdid   => 5,
2919     artist => 'Massive Attack',
2920     title  => 'Mezzanine',
2921     year   => 2005,
2922   });
2923
2924   if( !$cd->in_storage ) {
2925       # do some stuff
2926       $cd->insert;
2927   }
2928
2929 =cut
2930
2931 sub find_or_create {
2932   my $self     = shift;
2933   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2934   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2935   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2936     return $row;
2937   }
2938   return $self->create($hash);
2939 }
2940
2941 =head2 update_or_create
2942
2943 =over 4
2944
2945 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
2946
2947 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
2948
2949 =back
2950
2951   $resultset->update_or_create({ col => $val, ... });
2952
2953 Like L</find_or_create>, but if a row is found it is immediately updated via
2954 C<< $found_row->update (\%col_data) >>.
2955
2956
2957 Takes an optional C<key> attribute to search on a specific unique constraint.
2958 For example:
2959
2960   # In your application
2961   my $cd = $schema->resultset('CD')->update_or_create(
2962     {
2963       artist => 'Massive Attack',
2964       title  => 'Mezzanine',
2965       year   => 1998,
2966     },
2967     { key => 'cd_artist_title' }
2968   );
2969
2970   $cd->cd_to_producer->update_or_create({
2971     producer => $producer,
2972     name => 'harry',
2973   }, {
2974     key => 'primary',
2975   });
2976
2977 B<Note>: Make sure to read the documentation of L</find> and understand the
2978 significance of the C<key> attribute, as its lack may skew your search, and
2979 subsequently result in spurious row creation.
2980
2981 B<Note>: Take care when using C<update_or_create> with a table having
2982 columns with default values that you intend to be automatically
2983 supplied by the database (e.g. an auto_increment primary key column).
2984 In normal usage, the value of such columns should NOT be included at
2985 all in the call to C<update_or_create>, even when set to C<undef>.
2986
2987 See also L</find> and L</find_or_create>. For information on how to declare
2988 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2989
2990 If you need to know if an existing row was updated or a new one created use
2991 L</update_or_new> and L<DBIx::Class::Row/in_storage> instead. Don't forget
2992 to call L<DBIx::Class::Row/insert> to save the newly created row to the
2993 database!
2994
2995 =cut
2996
2997 sub update_or_create {
2998   my $self = shift;
2999   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
3000   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
3001
3002   my $row = $self->find($cond, $attrs);
3003   if (defined $row) {
3004     $row->update($cond);
3005     return $row;
3006   }
3007
3008   return $self->create($cond);
3009 }
3010
3011 =head2 update_or_new
3012
3013 =over 4
3014
3015 =item Arguments: \%col_data, { key => $unique_constraint, L<%attrs|/ATTRIBUTES> }?
3016
3017 =item Return Value: L<$result|DBIx::Class::Manual::ResultClass>
3018
3019 =back
3020
3021   $resultset->update_or_new({ col => $val, ... });
3022
3023 Like L</find_or_new> but if a row is found it is immediately updated via
3024 C<< $found_row->update (\%col_data) >>.
3025
3026 For example:
3027
3028   # In your application
3029   my $cd = $schema->resultset('CD')->update_or_new(
3030     {
3031       artist => 'Massive Attack',
3032       title  => 'Mezzanine',
3033       year   => 1998,
3034     },
3035     { key => 'cd_artist_title' }
3036   );
3037
3038   if ($cd->in_storage) {
3039       # the cd was updated
3040   }
3041   else {
3042       # the cd is not yet in the database, let's insert it
3043       $cd->insert;
3044   }
3045
3046 B<Note>: Make sure to read the documentation of L</find> and understand the
3047 significance of the C<key> attribute, as its lack may skew your search, and
3048 subsequently result in spurious new objects.
3049
3050 B<Note>: Take care when using C<update_or_new> with a table having
3051 columns with default values that you intend to be automatically
3052 supplied by the database (e.g. an auto_increment primary key column).
3053 In normal usage, the value of such columns should NOT be included at
3054 all in the call to C<update_or_new>, even when set to C<undef>.
3055
3056 See also L</find>, L</find_or_create> and L</find_or_new>.
3057
3058 =cut
3059
3060 sub update_or_new {
3061     my $self  = shift;
3062     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
3063     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
3064
3065     my $row = $self->find( $cond, $attrs );
3066     if ( defined $row ) {
3067         $row->update($cond);
3068         return $row;
3069     }
3070
3071     return $self->new_result($cond);
3072 }
3073
3074 =head2 get_cache
3075
3076 =over 4
3077
3078 =item Arguments: none
3079
3080 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass> | undef
3081
3082 =back
3083
3084 Gets the contents of the cache for the resultset, if the cache is set.
3085
3086 The cache is populated either by using the L</prefetch> attribute to
3087 L</search> or by calling L</set_cache>.
3088
3089 =cut
3090
3091 sub get_cache {
3092   shift->{all_cache};
3093 }
3094
3095 =head2 set_cache
3096
3097 =over 4
3098
3099 =item Arguments: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3100
3101 =item Return Value: L<\@result_objs|DBIx::Class::Manual::ResultClass>
3102
3103 =back
3104
3105 Sets the contents of the cache for the resultset. Expects an arrayref
3106 of objects of the same class as those produced by the resultset. Note that
3107 if the cache is set, the resultset will return the cached objects rather
3108 than re-querying the database even if the cache attr is not set.
3109
3110 The contents of the cache can also be populated by using the
3111 L</prefetch> attribute to L</search>.
3112
3113 =cut
3114
3115 sub set_cache {
3116   my ( $self, $data ) = @_;
3117   $self->throw_exception("set_cache requires an arrayref")
3118       if defined($data) && (ref $data ne 'ARRAY');
3119   $self->{all_cache} = $data;
3120 }
3121
3122 =head2 clear_cache
3123
3124 =over 4
3125
3126 =item Arguments: none
3127
3128 =item Return Value: undef
3129
3130 =back
3131
3132 Clears the cache for the resultset.
3133
3134 =cut
3135
3136 sub clear_cache {
3137   shift->set_cache(undef);
3138 }
3139
3140 =head2 is_paged
3141
3142 =over 4
3143
3144 =item Arguments: none
3145
3146 =item Return Value: true, if the resultset has been paginated
3147
3148 =back
3149
3150 =cut
3151
3152 sub is_paged {
3153   my ($self) = @_;
3154   return !!$self->{attrs}{page};
3155 }
3156
3157 =head2 is_ordered
3158
3159 =over 4
3160
3161 =item Arguments: none
3162
3163 =item Return Value: true, if the resultset has been ordered with C<order_by>.
3164
3165 =back
3166
3167 =cut
3168
3169 sub is_ordered {
3170   my ($self) = @_;
3171   return scalar $self->result_source->storage->_extract_order_criteria($self->{attrs}{order_by});
3172 }
3173
3174 =head2 related_resultset
3175
3176 =over 4
3177
3178 =item Arguments: $rel_name
3179
3180 =item Return Value: L<$resultset|/search>
3181
3182 =back
3183
3184 Returns a related resultset for the supplied relationship name.
3185
3186   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
3187
3188 =cut
3189
3190 sub related_resultset {
3191   my ($self, $rel) = @_;
3192
3193   return $self->{related_resultsets}{$rel}
3194     if defined $self->{related_resultsets}{$rel};
3195
3196   return $self->{related_resultsets}{$rel} = do {
3197     my $rsrc = $self->result_source;
3198     my $rel_info = $rsrc->relationship_info($rel);
3199
3200     $self->throw_exception(
3201       "search_related: result source '" . $rsrc->source_name .
3202         "' has no such relationship $rel")
3203       unless $rel_info;
3204
3205     my $attrs = $self->_chain_relationship($rel);
3206
3207     my $join_count = $attrs->{seen_join}{$rel};
3208
3209     my $alias = $self->result_source->storage
3210         ->relname_to_table_alias($rel, $join_count);
3211
3212     # since this is search_related, and we already slid the select window inwards
3213     # (the select/as attrs were deleted in the beginning), we need to flip all
3214     # left joins to inner, so we get the expected results
3215     # read the comment on top of the actual function to see what this does
3216     $attrs->{from} = $rsrc->schema->storage->_inner_join_to_node ($attrs->{from}, $alias);
3217
3218
3219     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
3220     delete @{$attrs}{qw(result_class alias)};
3221
3222     my $rel_source = $rsrc->related_source($rel);
3223
3224     my $new = do {
3225
3226       # The reason we do this now instead of passing the alias to the
3227       # search_rs below is that if you wrap/overload resultset on the
3228       # source you need to know what alias it's -going- to have for things
3229       # to work sanely (e.g. RestrictWithObject wants to be able to add
3230       # extra query restrictions, and these may need to be $alias.)
3231
3232       my $rel_attrs = $rel_source->resultset_attributes;
3233       local $rel_attrs->{alias} = $alias;
3234
3235       $rel_source->resultset
3236                  ->search_rs(
3237                      undef, {
3238                        %$attrs,
3239                        where => $attrs->{where},
3240                    });
3241     };
3242
3243     if (my $cache = $self->get_cache) {
3244       my @related_cache = map
3245         { @{$_->related_resultset($rel)->get_cache||[]} }
3246         @$cache
3247       ;
3248
3249       $new->set_cache(\@related_cache) if @related_cache;
3250     }
3251
3252     $new;
3253   };
3254 }
3255
3256 =head2 current_source_alias
3257
3258 =over 4
3259
3260 =item Arguments: none
3261
3262 =item Return Value: $source_alias
3263
3264 =back
3265
3266 Returns the current table alias for the result source this resultset is built
3267 on, that will be used in the SQL query. Usually it is C<me>.
3268
3269 Currently the source alias that refers to the result set returned by a
3270 L</search>/L</find> family method depends on how you got to the resultset: it's
3271 C<me> by default, but eg. L</search_related> aliases it to the related result
3272 source name (and keeps C<me> referring to the original result set). The long
3273 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
3274 (and make this method unnecessary).
3275
3276 Thus it's currently necessary to use this method in predefined queries (see
3277 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
3278 source alias of the current result set:
3279
3280   # in a result set class
3281   sub modified_by {
3282     my ($self, $user) = @_;
3283
3284     my $me = $self->current_source_alias;
3285
3286     return $self->search({
3287       "$me.modified" => $user->id,
3288     });
3289   }
3290
3291 =cut
3292
3293 sub current_source_alias {
3294   return (shift->{attrs} || {})->{alias} || 'me';
3295 }
3296
3297 =head2 as_subselect_rs
3298
3299 =over 4
3300
3301 =item Arguments: none
3302
3303 =item Return Value: L<$resultset|/search>
3304
3305 =back
3306
3307 Act as a barrier to SQL symbols.  The resultset provided will be made into a
3308 "virtual view" by including it as a subquery within the from clause.  From this
3309 point on, any joined tables are inaccessible to ->search on the resultset (as if
3310 it were simply where-filtered without joins).  For example:
3311
3312  my $rs = $schema->resultset('Bar')->search({'x.name' => 'abc'},{ join => 'x' });
3313
3314  # 'x' now pollutes the query namespace
3315
3316  # So the following works as expected
3317  my $ok_rs = $rs->search({'x.other' => 1});
3318
3319  # But this doesn't: instead of finding a 'Bar' related to two x rows (abc and
3320  # def) we look for one row with contradictory terms and join in another table
3321  # (aliased 'x_2') which we never use
3322  my $broken_rs = $rs->search({'x.name' => 'def'});
3323
3324  my $rs2 = $rs->as_subselect_rs;
3325
3326  # doesn't work - 'x' is no longer accessible in $rs2, having been sealed away
3327  my $not_joined_rs = $rs2->search({'x.other' => 1});
3328
3329  # works as expected: finds a 'table' row related to two x rows (abc and def)
3330  my $correctly_joined_rs = $rs2->search({'x.name' => 'def'});
3331
3332 Another example of when one might use this would be to select a subset of
3333 columns in a group by clause:
3334
3335  my $rs = $schema->resultset('Bar')->search(undef, {
3336    group_by => [qw{ id foo_id baz_id }],
3337  })->as_subselect_rs->search(undef, {
3338    columns => [qw{ id foo_id }]
3339  });
3340
3341 In the above example normally columns would have to be equal to the group by,
3342 but because we isolated the group by into a subselect the above works.
3343
3344 =cut
3345
3346 sub as_subselect_rs {
3347   my $self = shift;
3348
3349   my $attrs = $self->_resolved_attrs;
3350
3351   my $fresh_rs = (ref $self)->new (
3352     $self->result_source
3353   );
3354
3355   # these pieces will be locked in the subquery
3356   delete $fresh_rs->{cond};
3357   delete @{$fresh_rs->{attrs}}{qw/where bind/};
3358
3359   return $fresh_rs->search( {}, {
3360     from => [{
3361       $attrs->{alias} => $self->as_query,
3362       -alias  => $attrs->{alias},
3363       -rsrc   => $self->result_source,
3364     }],
3365     alias => $attrs->{alias},
3366   });
3367 }
3368
3369 # This code is called by search_related, and makes sure there
3370 # is clear separation between the joins before, during, and
3371 # after the relationship. This information is needed later
3372 # in order to properly resolve prefetch aliases (any alias
3373 # with a relation_chain_depth less than the depth of the
3374 # current prefetch is not considered)
3375 #
3376 # The increments happen twice per join. An even number means a
3377 # relationship specified via a search_related, whereas an odd
3378 # number indicates a join/prefetch added via attributes
3379 #
3380 # Also this code will wrap the current resultset (the one we
3381 # chain to) in a subselect IFF it contains limiting attributes
3382 sub _chain_relationship {
3383   my ($self, $rel) = @_;
3384   my $source = $self->result_source;
3385   my $attrs = { %{$self->{attrs}||{}} };
3386
3387   # we need to take the prefetch the attrs into account before we
3388   # ->_resolve_join as otherwise they get lost - captainL
3389   my $join = $self->_merge_joinpref_attr( $attrs->{join}, $attrs->{prefetch} );
3390
3391   delete @{$attrs}{qw/join prefetch collapse group_by distinct _grouped_by_distinct select as columns +select +as +columns/};
3392
3393   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
3394
3395   my $from;
3396   my @force_subq_attrs = qw/offset rows group_by having/;
3397
3398   if (
3399     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
3400       ||
3401     $self->_has_resolved_attr (@force_subq_attrs)
3402   ) {
3403     # Nuke the prefetch (if any) before the new $rs attrs
3404     # are resolved (prefetch is useless - we are wrapping
3405     # a subquery anyway).
3406     my $rs_copy = $self->search;
3407     $rs_copy->{attrs}{join} = $self->_merge_joinpref_attr (
3408       $rs_copy->{attrs}{join},
3409       delete $rs_copy->{attrs}{prefetch},
3410     );
3411
3412     $from = [{
3413       -rsrc   => $source,
3414       -alias  => $attrs->{alias},
3415       $attrs->{alias} => $rs_copy->as_query,
3416     }];
3417     delete @{$attrs}{@force_subq_attrs, qw/where bind/};
3418     $seen->{-relation_chain_depth} = 0;
3419   }
3420   elsif ($attrs->{from}) {  #shallow copy suffices
3421     $from = [ @{$attrs->{from}} ];
3422   }
3423   else {
3424     $from = [{
3425       -rsrc  => $source,
3426       -alias => $attrs->{alias},
3427       $attrs->{alias} => $source->from,
3428     }];
3429   }
3430
3431   my $jpath = ($seen->{-relation_chain_depth})
3432     ? $from->[-1][0]{-join_path}
3433     : [];
3434
3435   my @requested_joins = $source->_resolve_join(
3436     $join,
3437     $attrs->{alias},
3438     $seen,
3439     $jpath,
3440   );
3441
3442   push @$from, @requested_joins;
3443
3444   $seen->{-relation_chain_depth}++;
3445
3446   # if $self already had a join/prefetch specified on it, the requested
3447   # $rel might very well be already included. What we do in this case
3448   # is effectively a no-op (except that we bump up the chain_depth on
3449   # the join in question so we could tell it *is* the search_related)
3450   my $already_joined;
3451
3452   # we consider the last one thus reverse
3453   for my $j (reverse @requested_joins) {
3454     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
3455     if ($rel eq $last_j) {
3456       $j->[0]{-relation_chain_depth}++;
3457       $already_joined++;
3458       last;
3459     }
3460   }
3461
3462   unless ($already_joined) {
3463     push @$from, $source->_resolve_join(
3464       $rel,
3465       $attrs->{alias},
3466       $seen,
3467       $jpath,
3468     );
3469   }
3470
3471   $seen->{-relation_chain_depth}++;
3472
3473   return {%$attrs, from => $from, seen_join => $seen};
3474 }
3475
3476 sub _resolved_attrs {
3477   my $self = shift;
3478   return $self->{_attrs} if $self->{_attrs};
3479
3480   my $attrs  = { %{ $self->{attrs} || {} } };
3481   my $source = $self->result_source;
3482   my $alias  = $attrs->{alias};
3483
3484   $self->throw_exception("Specifying distinct => 1 in conjunction with collapse => 1 is unsupported")
3485     if $attrs->{collapse} and $attrs->{distinct};
3486
3487   # default selection list
3488   $attrs->{columns} = [ $source->columns ]
3489     unless List::Util::first { exists $attrs->{$_} } qw/columns cols select as/;
3490
3491   # merge selectors together
3492   for (qw/columns select as/) {
3493     $attrs->{$_} = $self->_merge_attr($attrs->{$_}, delete $attrs->{"+$_"})
3494       if $attrs->{$_} or $attrs->{"+$_"};
3495   }
3496
3497   # disassemble columns
3498   my (@sel, @as);
3499   if (my $cols = delete $attrs->{columns}) {
3500     for my $c (ref $cols eq 'ARRAY' ? @$cols : $cols) {
3501       if (ref $c eq 'HASH') {
3502         for my $as (sort keys %$c) {
3503           push @sel, $c->{$as};
3504           push @as, $as;
3505         }
3506       }
3507       else {
3508         push @sel, $c;
3509         push @as, $c;
3510       }
3511     }
3512   }
3513
3514   # when trying to weed off duplicates later do not go past this point -
3515   # everything added from here on is unbalanced "anyone's guess" stuff
3516   my $dedup_stop_idx = $#as;
3517
3518   push @as, @{ ref $attrs->{as} eq 'ARRAY' ? $attrs->{as} : [ $attrs->{as} ] }
3519     if $attrs->{as};
3520   push @sel, @{ ref $attrs->{select} eq 'ARRAY' ? $attrs->{select} : [ $attrs->{select} ] }
3521     if $attrs->{select};
3522
3523   # assume all unqualified selectors to apply to the current alias (legacy stuff)
3524   $_ = (ref $_ or $_ =~ /\./) ? $_ : "$alias.$_" for @sel;
3525
3526   # disqualify all $alias.col as-bits (inflate-map mandated)
3527   $_ = ($_ =~ /^\Q$alias.\E(.+)$/) ? $1 : $_ for @as;
3528
3529   # de-duplicate the result (remove *identical* select/as pairs)
3530   # and also die on duplicate {as} pointing to different {select}s
3531   # not using a c-style for as the condition is prone to shrinkage
3532   my $seen;
3533   my $i = 0;
3534   while ($i <= $dedup_stop_idx) {
3535     if ($seen->{"$sel[$i] \x00\x00 $as[$i]"}++) {
3536       splice @sel, $i, 1;
3537       splice @as, $i, 1;
3538       $dedup_stop_idx--;
3539     }
3540     elsif ($seen->{$as[$i]}++) {
3541       $self->throw_exception(
3542         "inflate_result() alias '$as[$i]' specified twice with different SQL-side {select}-ors"
3543       );
3544     }
3545     else {
3546       $i++;
3547     }
3548   }
3549
3550   $attrs->{select} = \@sel;
3551   $attrs->{as} = \@as;
3552
3553   $attrs->{from} ||= [{
3554     -rsrc   => $source,
3555     -alias  => $self->{attrs}{alias},
3556     $self->{attrs}{alias} => $source->from,
3557   }];
3558
3559   if ( $attrs->{join} || $attrs->{prefetch} ) {
3560
3561     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
3562       if ref $attrs->{from} ne 'ARRAY';
3563
3564     my $join = (delete $attrs->{join}) || {};
3565
3566     if ( defined $attrs->{prefetch} ) {
3567       $join = $self->_merge_joinpref_attr( $join, $attrs->{prefetch} );
3568     }
3569
3570     $attrs->{from} =    # have to copy here to avoid corrupting the original
3571       [
3572         @{ $attrs->{from} },
3573         $source->_resolve_join(
3574           $join,
3575           $alias,
3576           ($attrs->{seen_join} = { %{ $attrs->{seen_join} || {} } }),
3577           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
3578             ? $attrs->{from}[-1][0]{-join_path}
3579             : []
3580           ,
3581         )
3582       ];
3583   }
3584
3585   if ( defined $attrs->{order_by} ) {
3586     $attrs->{order_by} = (
3587       ref( $attrs->{order_by} ) eq 'ARRAY'
3588       ? [ @{ $attrs->{order_by} } ]
3589       : [ $attrs->{order_by} || () ]
3590     );
3591   }
3592
3593   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
3594     $attrs->{group_by} = [ $attrs->{group_by} ];
3595   }
3596
3597
3598   # generate selections based on the prefetch helper
3599   my ($prefetch, @prefetch_select, @prefetch_as);
3600   $prefetch = $self->_merge_joinpref_attr( {}, delete $attrs->{prefetch} )
3601     if defined $attrs->{prefetch};
3602
3603   if ($prefetch) {
3604
3605     $self->throw_exception("Unable to prefetch, resultset contains an unnamed selector $attrs->{_dark_selector}{string}")
3606       if $attrs->{_dark_selector};
3607
3608     $self->throw_exception("Specifying prefetch in conjunction with an explicit collapse => 0 is unsupported")
3609       if defined $attrs->{collapse} and ! $attrs->{collapse};
3610
3611     $attrs->{collapse} = 1;
3612
3613     # this is a separate structure (we don't look in {from} directly)
3614     # as the resolver needs to shift things off the lists to work
3615     # properly (identical-prefetches on different branches)
3616     my $join_map = {};
3617     if (ref $attrs->{from} eq 'ARRAY') {
3618
3619       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
3620
3621       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
3622         next unless $j->[0]{-alias};
3623         next unless $j->[0]{-join_path};
3624         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
3625
3626         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
3627
3628         my $p = $join_map;
3629         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
3630         push @{$p->{-join_aliases} }, $j->[0]{-alias};
3631       }
3632     }
3633
3634     my @prefetch = $source->_resolve_prefetch( $prefetch, $alias, $join_map );
3635
3636     # save these for after distinct resolution
3637     @prefetch_select = map { $_->[0] } @prefetch;
3638     @prefetch_as = map { $_->[1] } @prefetch;
3639   }
3640
3641   # run through the resulting joinstructure (starting from our current slot)
3642   # and unset collapse if proven unnecessary
3643   #
3644   # also while we are at it find out if the current root source has
3645   # been premultiplied by previous related_source chaining
3646   #
3647   # this allows to predict whether a root object with all other relation
3648   # data set to NULL is in fact unique
3649   if ($attrs->{collapse}) {
3650
3651     if (ref $attrs->{from} eq 'ARRAY') {
3652
3653       if (@{$attrs->{from}} == 1) {
3654         # no joins - no collapse
3655         $attrs->{collapse} = 0;
3656       }
3657       else {
3658         # find where our table-spec starts
3659         my @fromlist = @{$attrs->{from}};
3660         while (@fromlist) {
3661           my $t = shift @fromlist;
3662
3663           my $is_multi;
3664           # me vs join from-spec distinction - a ref means non-root
3665           if (ref $t eq 'ARRAY') {
3666             $t = $t->[0];
3667             $is_multi ||= ! $t->{-is_single};
3668           }
3669           last if ($t->{-alias} && $t->{-alias} eq $alias);
3670           $attrs->{_main_source_premultiplied} ||= $is_multi;
3671         }
3672
3673         # no non-singles remaining, nor any premultiplication - nothing to collapse
3674         if (
3675           ! $attrs->{_main_source_premultiplied}
3676             and
3677           ! List::Util::first { ! $_->[0]{-is_single} } @fromlist
3678         ) {
3679           $attrs->{collapse} = 0;
3680         }
3681       }
3682     }
3683
3684     else {
3685       # if we can not analyze the from - err on the side of safety
3686       $attrs->{_main_source_premultiplied} = 1;
3687     }
3688   }
3689
3690   # generate the distinct induced group_by before injecting the prefetched select/as parts
3691   if (delete $attrs->{distinct}) {
3692     if ($attrs->{group_by}) {
3693       carp_unique ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
3694     }
3695     else {
3696       $attrs->{_grouped_by_distinct} = 1;
3697       # distinct affects only the main selection part, not what prefetch may add below
3698       ($attrs->{group_by}, my $new_order) = $source->storage->_group_over_selection($attrs);
3699
3700       # FIXME possibly ignore a rewritten order_by (may turn out to be an issue)
3701       # The thinking is: if we are collapsing the subquerying prefetch engine will
3702       # rip stuff apart for us anyway, and we do not want to have a potentially
3703       # function-converted external order_by
3704       # ( there is an explicit if ( collapse && _grouped_by_distinct ) check in DBIHacks )
3705       $attrs->{order_by} = $new_order unless $attrs->{collapse};
3706     }
3707   }
3708
3709   # inject prefetch-bound selection (if any)
3710   push @{$attrs->{select}}, @prefetch_select;
3711   push @{$attrs->{as}}, @prefetch_as;
3712
3713   # whether we can get away with the dumbest (possibly DBI-internal) collapser
3714   if ( List::Util::first { $_ =~ /\./ } @{$attrs->{as}} ) {
3715     $attrs->{_related_results_construction} = 1;
3716   }
3717
3718   # if both page and offset are specified, produce a combined offset
3719   # even though it doesn't make much sense, this is what pre 081xx has
3720   # been doing
3721   if (my $page = delete $attrs->{page}) {
3722     $attrs->{offset} =
3723       ($attrs->{rows} * ($page - 1))
3724             +
3725       ($attrs->{offset} || 0)
3726     ;
3727   }
3728
3729   return $self->{_attrs} = $attrs;
3730 }
3731
3732 sub _rollout_attr {
3733   my ($self, $attr) = @_;
3734
3735   if (ref $attr eq 'HASH') {
3736     return $self->_rollout_hash($attr);
3737   } elsif (ref $attr eq 'ARRAY') {
3738     return $self->_rollout_array($attr);
3739   } else {
3740     return [$attr];
3741   }
3742 }
3743
3744 sub _rollout_array {
3745   my ($self, $attr) = @_;
3746
3747   my @rolled_array;
3748   foreach my $element (@{$attr}) {
3749     if (ref $element eq 'HASH') {
3750       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3751     } elsif (ref $element eq 'ARRAY') {
3752       #  XXX - should probably recurse here
3753       push( @rolled_array, @{$self->_rollout_array($element)} );
3754     } else {
3755       push( @rolled_array, $element );
3756     }
3757   }
3758   return \@rolled_array;
3759 }
3760
3761 sub _rollout_hash {
3762   my ($self, $attr) = @_;
3763
3764   my @rolled_array;
3765   foreach my $key (keys %{$attr}) {
3766     push( @rolled_array, { $key => $attr->{$key} } );
3767   }
3768   return \@rolled_array;
3769 }
3770
3771 sub _calculate_score {
3772   my ($self, $a, $b) = @_;
3773
3774   if (defined $a xor defined $b) {
3775     return 0;
3776   }
3777   elsif (not defined $a) {
3778     return 1;
3779   }
3780
3781   if (ref $b eq 'HASH') {
3782     my ($b_key) = keys %{$b};
3783     if (ref $a eq 'HASH') {
3784       my ($a_key) = keys %{$a};
3785       if ($a_key eq $b_key) {
3786         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3787       } else {
3788         return 0;
3789       }
3790     } else {
3791       return ($a eq $b_key) ? 1 : 0;
3792     }
3793   } else {
3794     if (ref $a eq 'HASH') {
3795       my ($a_key) = keys %{$a};
3796       return ($b eq $a_key) ? 1 : 0;
3797     } else {
3798       return ($b eq $a) ? 1 : 0;
3799     }
3800   }
3801 }
3802
3803 sub _merge_joinpref_attr {
3804   my ($self, $orig, $import) = @_;
3805
3806   return $import unless defined($orig);
3807   return $orig unless defined($import);
3808
3809   $orig = $self->_rollout_attr($orig);
3810   $import = $self->_rollout_attr($import);
3811
3812   my $seen_keys;
3813   foreach my $import_element ( @{$import} ) {
3814     # find best candidate from $orig to merge $b_element into
3815     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3816     foreach my $orig_element ( @{$orig} ) {
3817       my $score = $self->_calculate_score( $orig_element, $import_element );
3818       if ($score > $best_candidate->{score}) {
3819         $best_candidate->{position} = $position;
3820         $best_candidate->{score} = $score;
3821       }
3822       $position++;
3823     }
3824     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3825     $import_key = '' if not defined $import_key;
3826
3827     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3828       push( @{$orig}, $import_element );
3829     } else {
3830       my $orig_best = $orig->[$best_candidate->{position}];
3831       # merge orig_best and b_element together and replace original with merged
3832       if (ref $orig_best ne 'HASH') {
3833         $orig->[$best_candidate->{position}] = $import_element;
3834       } elsif (ref $import_element eq 'HASH') {
3835         my ($key) = keys %{$orig_best};
3836         $orig->[$best_candidate->{position}] = { $key => $self->_merge_joinpref_attr($orig_best->{$key}, $import_element->{$key}) };
3837       }
3838     }
3839     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3840   }
3841
3842   return @$orig ? $orig : ();
3843 }
3844
3845 {
3846   my $hm;
3847
3848   sub _merge_attr {
3849     $hm ||= do {
3850       require Hash::Merge;
3851       my $hm = Hash::Merge->new;
3852
3853       $hm->specify_behavior({
3854         SCALAR => {
3855           SCALAR => sub {
3856             my ($defl, $defr) = map { defined $_ } (@_[0,1]);
3857
3858             if ($defl xor $defr) {
3859               return [ $defl ? $_[0] : $_[1] ];
3860             }
3861             elsif (! $defl) {
3862               return [];
3863             }
3864             elsif (__HM_DEDUP and $_[0] eq $_[1]) {
3865               return [ $_[0] ];
3866             }
3867             else {
3868               return [$_[0], $_[1]];
3869             }
3870           },
3871           ARRAY => sub {
3872             return $_[1] if !defined $_[0];
3873             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3874             return [$_[0], @{$_[1]}]
3875           },
3876           HASH  => sub {
3877             return [] if !defined $_[0] and !keys %{$_[1]};
3878             return [ $_[1] ] if !defined $_[0];
3879             return [ $_[0] ] if !keys %{$_[1]};
3880             return [$_[0], $_[1]]
3881           },
3882         },
3883         ARRAY => {
3884           SCALAR => sub {
3885             return $_[0] if !defined $_[1];
3886             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3887             return [@{$_[0]}, $_[1]]
3888           },
3889           ARRAY => sub {
3890             my @ret = @{$_[0]} or return $_[1];
3891             return [ @ret, @{$_[1]} ] unless __HM_DEDUP;
3892             my %idx = map { $_ => 1 } @ret;
3893             push @ret, grep { ! defined $idx{$_} } (@{$_[1]});
3894             \@ret;
3895           },
3896           HASH => sub {
3897             return [ $_[1] ] if ! @{$_[0]};
3898             return $_[0] if !keys %{$_[1]};
3899             return $_[0] if __HM_DEDUP and List::Util::first { $_ eq $_[1] } @{$_[0]};
3900             return [ @{$_[0]}, $_[1] ];
3901           },
3902         },
3903         HASH => {
3904           SCALAR => sub {
3905             return [] if !keys %{$_[0]} and !defined $_[1];
3906             return [ $_[0] ] if !defined $_[1];
3907             return [ $_[1] ] if !keys %{$_[0]};
3908             return [$_[0], $_[1]]
3909           },
3910           ARRAY => sub {
3911             return [] if !keys %{$_[0]} and !@{$_[1]};
3912             return [ $_[0] ] if !@{$_[1]};
3913             return $_[1] if !keys %{$_[0]};
3914             return $_[1] if __HM_DEDUP and List::Util::first { $_ eq $_[0] } @{$_[1]};
3915             return [ $_[0], @{$_[1]} ];
3916           },
3917           HASH => sub {
3918             return [] if !keys %{$_[0]} and !keys %{$_[1]};
3919             return [ $_[0] ] if !keys %{$_[1]};
3920             return [ $_[1] ] if !keys %{$_[0]};
3921             return [ $_[0] ] if $_[0] eq $_[1];
3922             return [ $_[0], $_[1] ];
3923           },
3924         }
3925       } => 'DBIC_RS_ATTR_MERGER');
3926       $hm;
3927     };
3928
3929     return $hm->merge ($_[1], $_[2]);
3930   }
3931 }
3932
3933 sub STORABLE_freeze {
3934   my ($self, $cloning) = @_;
3935   my $to_serialize = { %$self };
3936
3937   # A cursor in progress can't be serialized (and would make little sense anyway)
3938   # the parser can be regenerated (and can't be serialized)
3939   delete @{$to_serialize}{qw/cursor _row_parser _result_inflator/};
3940
3941   # nor is it sensical to store a not-yet-fired-count pager
3942   if ($to_serialize->{pager} and ref $to_serialize->{pager}{total_entries} eq 'CODE') {
3943     delete $to_serialize->{pager};
3944   }
3945
3946   Storable::nfreeze($to_serialize);
3947 }
3948
3949 # need this hook for symmetry
3950 sub STORABLE_thaw {
3951   my ($self, $cloning, $serialized) = @_;
3952
3953   %$self = %{ Storable::thaw($serialized) };
3954
3955   $self;
3956 }
3957
3958
3959 =head2 throw_exception
3960
3961 See L<DBIx::Class::Schema/throw_exception> for details.
3962
3963 =cut
3964
3965 sub throw_exception {
3966   my $self=shift;
3967
3968   if (ref $self and my $rsrc = $self->result_source) {
3969     $rsrc->throw_exception(@_)
3970   }
3971   else {
3972     DBIx::Class::Exception->throw(@_);
3973   }
3974 }
3975
3976 1;
3977
3978 __END__
3979
3980 # XXX: FIXME: Attributes docs need clearing up
3981
3982 =head1 ATTRIBUTES
3983
3984 Attributes are used to refine a ResultSet in various ways when
3985 searching for data. They can be passed to any method which takes an
3986 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3987 L</count>.
3988
3989 Default attributes can be set on the result class using
3990 L<DBIx::Class::ResultSource/resultset_attributes>.  (Please read
3991 the CAVEATS on that feature before using it!)
3992
3993 These are in no particular order:
3994
3995 =head2 order_by
3996
3997 =over 4
3998
3999 =item Value: ( $order_by | \@order_by | \%order_by )
4000
4001 =back
4002
4003 Which column(s) to order the results by.
4004
4005 [The full list of suitable values is documented in
4006 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
4007 common options.]
4008
4009 If a single column name, or an arrayref of names is supplied, the
4010 argument is passed through directly to SQL. The hashref syntax allows
4011 for connection-agnostic specification of ordering direction:
4012
4013  For descending order:
4014
4015   order_by => { -desc => [qw/col1 col2 col3/] }
4016
4017  For explicit ascending order:
4018
4019   order_by => { -asc => 'col' }
4020
4021 The old scalarref syntax (i.e. order_by => \'year DESC') is still
4022 supported, although you are strongly encouraged to use the hashref
4023 syntax as outlined above.
4024
4025 =head2 columns
4026
4027 =over 4
4028
4029 =item Value: \@columns | \%columns | $column
4030
4031 =back
4032
4033 Shortcut to request a particular set of columns to be retrieved. Each
4034 column spec may be a string (a table column name), or a hash (in which
4035 case the key is the C<as> value, and the value is used as the C<select>
4036 expression). Adds C<me.> onto the start of any column without a C<.> in
4037 it and sets C<select> from that, then auto-populates C<as> from
4038 C<select> as normal. (You may also use the C<cols> attribute, as in
4039 earlier versions of DBIC, but this is deprecated.)
4040
4041 Essentially C<columns> does the same as L</select> and L</as>.
4042
4043     columns => [ 'foo', { bar => 'baz' } ]
4044
4045 is the same as
4046
4047     select => [qw/foo baz/],
4048     as => [qw/foo bar/]
4049
4050 =head2 +columns
4051
4052 =over 4
4053
4054 =item Value: \@columns
4055
4056 =back
4057
4058 Indicates additional columns to be selected from storage. Works the same as
4059 L</columns> but adds columns to the selection. (You may also use the
4060 C<include_columns> attribute, as in earlier versions of DBIC, but this is
4061 deprecated). For example:-
4062
4063   $schema->resultset('CD')->search(undef, {
4064     '+columns' => ['artist.name'],
4065     join => ['artist']
4066   });
4067
4068 would return all CDs and include a 'name' column to the information
4069 passed to object inflation. Note that the 'artist' is the name of the
4070 column (or relationship) accessor, and 'name' is the name of the column
4071 accessor in the related table.
4072
4073 B<NOTE:> You need to explicitly quote '+columns' when defining the attribute.
4074 Not doing so causes Perl to incorrectly interpret +columns as a bareword with a
4075 unary plus operator before it.
4076
4077 =head2 include_columns
4078
4079 =over 4
4080
4081 =item Value: \@columns
4082
4083 =back
4084
4085 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
4086
4087 =head2 select
4088
4089 =over 4
4090
4091 =item Value: \@select_columns
4092
4093 =back
4094
4095 Indicates which columns should be selected from the storage. You can use
4096 column names, or in the case of RDBMS back ends, function or stored procedure
4097 names:
4098
4099   $rs = $schema->resultset('Employee')->search(undef, {
4100     select => [
4101       'name',
4102       { count => 'employeeid' },
4103       { max => { length => 'name' }, -as => 'longest_name' }
4104     ]
4105   });
4106
4107   # Equivalent SQL
4108   SELECT name, COUNT( employeeid ), MAX( LENGTH( name ) ) AS longest_name FROM employee
4109
4110 B<NOTE:> You will almost always need a corresponding L</as> attribute when you
4111 use L</select>, to instruct DBIx::Class how to store the result of the column.
4112 Also note that the L</as> attribute has nothing to do with the SQL-side 'AS'
4113 identifier aliasing. You can however alias a function, so you can use it in
4114 e.g. an C<ORDER BY> clause. This is done via the C<-as> B<select function
4115 attribute> supplied as shown in the example above.
4116
4117 B<NOTE:> You need to explicitly quote '+select'/'+as' when defining the attributes.
4118 Not doing so causes Perl to incorrectly interpret them as a bareword with a
4119 unary plus operator before it.
4120
4121 =head2 +select
4122
4123 =over 4
4124
4125 Indicates additional columns to be selected from storage.  Works the same as
4126 L</select> but adds columns to the default selection, instead of specifying
4127 an explicit list.
4128
4129 =back
4130
4131 =head2 as
4132
4133 =over 4
4134
4135 =item Value: \@inflation_names
4136
4137 =back
4138
4139 Indicates column names for object inflation. That is L</as> indicates the
4140 slot name in which the column value will be stored within the
4141 L<Row|DBIx::Class::Row> object. The value will then be accessible via this
4142 identifier by the C<get_column> method (or via the object accessor B<if one
4143 with the same name already exists>) as shown below. The L</as> attribute has
4144 B<nothing to do> with the SQL-side C<AS>. See L</select> for details.
4145
4146   $rs = $schema->resultset('Employee')->search(undef, {
4147     select => [
4148       'name',
4149       { count => 'employeeid' },
4150       { max => { length => 'name' }, -as => 'longest_name' }
4151     ],
4152     as => [qw/
4153       name
4154       employee_count
4155       max_name_length
4156     /],
4157   });
4158
4159 If the object against which the search is performed already has an accessor
4160 matching a column name specified in C<as>, the value can be retrieved using
4161 the accessor as normal:
4162
4163   my $name = $employee->name();
4164
4165 If on the other hand an accessor does not exist in the object, you need to
4166 use C<get_column> instead:
4167
4168   my $employee_count = $employee->get_column('employee_count');
4169
4170 You can create your own accessors if required - see
4171 L<DBIx::Class::Manual::Cookbook> for details.
4172
4173 =head2 +as
4174
4175 =over 4
4176
4177 Indicates additional column names for those added via L</+select>. See L</as>.
4178
4179 =back
4180
4181 =head2 join
4182
4183 =over 4
4184
4185 =item Value: ($rel_name | \@rel_names | \%rel_names)
4186
4187 =back
4188
4189 Contains a list of relationships that should be joined for this query.  For
4190 example:
4191
4192   # Get CDs by Nine Inch Nails
4193   my $rs = $schema->resultset('CD')->search(
4194     { 'artist.name' => 'Nine Inch Nails' },
4195     { join => 'artist' }
4196   );
4197
4198 Can also contain a hash reference to refer to the other relation's relations.
4199 For example:
4200
4201   package MyApp::Schema::Track;
4202   use base qw/DBIx::Class/;
4203   __PACKAGE__->table('track');
4204   __PACKAGE__->add_columns(qw/trackid cd position title/);
4205   __PACKAGE__->set_primary_key('trackid');
4206   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
4207   1;
4208
4209   # In your application
4210   my $rs = $schema->resultset('Artist')->search(
4211     { 'track.title' => 'Teardrop' },
4212     {
4213       join     => { cd => 'track' },
4214       order_by => 'artist.name',
4215     }
4216   );
4217
4218 You need to use the relationship (not the table) name in  conditions,
4219 because they are aliased as such. The current table is aliased as "me", so
4220 you need to use me.column_name in order to avoid ambiguity. For example:
4221
4222   # Get CDs from 1984 with a 'Foo' track
4223   my $rs = $schema->resultset('CD')->search(
4224     {
4225       'me.year' => 1984,
4226       'tracks.name' => 'Foo'
4227     },
4228     { join => 'tracks' }
4229   );
4230
4231 If the same join is supplied twice, it will be aliased to <rel>_2 (and
4232 similarly for a third time). For e.g.
4233
4234   my $rs = $schema->resultset('Artist')->search({
4235     'cds.title'   => 'Down to Earth',
4236     'cds_2.title' => 'Popular',
4237   }, {
4238     join => [ qw/cds cds/ ],
4239   });
4240
4241 will return a set of all artists that have both a cd with title 'Down
4242 to Earth' and a cd with title 'Popular'.
4243
4244 If you want to fetch related objects from other tables as well, see L</prefetch>
4245 below.
4246
4247  NOTE: An internal join-chain pruner will discard certain joins while
4248  constructing the actual SQL query, as long as the joins in question do not
4249  affect the retrieved result. This for example includes 1:1 left joins
4250  that are not part of the restriction specification (WHERE/HAVING) nor are
4251  a part of the query selection.
4252
4253 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
4254
4255 =head2 collapse
4256
4257 =over 4
4258
4259 =item Value: (0 | 1)
4260
4261 =back
4262
4263 When set to a true value, indicates that any rows fetched from joined has_many
4264 relationships are to be aggregated into the corresponding "parent" object. For
4265 example, the resultset:
4266
4267   my $rs = $schema->resultset('CD')->search({}, {
4268     '+columns' => [ qw/ tracks.title tracks.position / ],
4269     join => 'tracks',
4270     collapse => 1,
4271   });
4272
4273 While executing the following query:
4274
4275   SELECT me.*, tracks.title, tracks.position
4276     FROM cd me
4277     LEFT JOIN track tracks
4278       ON tracks.cdid = me.cdid
4279
4280 Will return only as many objects as there are rows in the CD source, even
4281 though the result of the query may span many rows. Each of these CD objects
4282 will in turn have multiple "Track" objects hidden behind the has_many
4283 generated accessor C<tracks>. Without C<< collapse => 1 >>, the return values
4284 of this resultset would be as many CD objects as there are tracks (a "Cartesian
4285 product"), with each CD object containing exactly one of all fetched Track data.
4286
4287 When a collapse is requested on a non-ordered resultset, an order by some
4288 unique part of the main source (the left-most table) is inserted automatically.
4289 This is done so that the resultset is allowed to be "lazy" - calling
4290 L<< $rs->next|/next >> will fetch only as many rows as it needs to build the next
4291 object with all of its related data.
4292
4293 If an L</order_by> is already declared, and orders the resultset in a way that
4294 makes collapsing as described above impossible (e.g. C<< ORDER BY
4295 has_many_rel.column >> or C<ORDER BY RANDOM()>), DBIC will automatically
4296 switch to "eager" mode and slurp the entire resultset before constructing the
4297 first object returned by L</next>.
4298
4299 Setting this attribute on a resultset that does not join any has_many
4300 relations is a no-op.
4301
4302 For a more in-depth discussion, see L</PREFETCHING>.
4303
4304 =head2 prefetch
4305
4306 =over 4
4307
4308 =item Value: ($rel_name | \@rel_names | \%rel_names)
4309
4310 =back
4311
4312 This attribute is a shorthand for specifying a L</join> spec, adding all
4313 columns from the joined related sources as L</+columns> and setting
4314 L</collapse> to a true value. For example, the following two queries are
4315 equivalent:
4316
4317   my $rs = $schema->resultset('Artist')->search({}, {
4318     prefetch => { cds => ['genre', 'tracks' ] },
4319   });
4320
4321 and
4322
4323   my $rs = $schema->resultset('Artist')->search({}, {
4324     join => { cds => ['genre', 'tracks' ] },
4325     collapse => 1,
4326     '+columns' => [
4327       (map
4328         { +{ "cds.$_" => "cds.$_" } }
4329         $schema->source('Artist')->related_source('cds')->columns
4330       ),
4331       (map
4332         { +{ "cds.genre.$_" => "genre.$_" } }
4333         $schema->source('Artist')->related_source('cds')->related_source('genre')->columns
4334       ),
4335       (map
4336         { +{ "cds.tracks.$_" => "tracks.$_" } }
4337         $schema->source('Artist')->related_source('cds')->related_source('tracks')->columns
4338       ),
4339     ],
4340   });
4341
4342 Both producing the following SQL:
4343
4344   SELECT  me.artistid, me.name, me.rank, me.charfield,
4345           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track,
4346           genre.genreid, genre.name,
4347           tracks.trackid, tracks.cd, tracks.position, tracks.title, tracks.last_updated_on, tracks.last_updated_at
4348     FROM artist me
4349     LEFT JOIN cd cds
4350       ON cds.artist = me.artistid
4351     LEFT JOIN genre genre
4352       ON genre.genreid = cds.genreid
4353     LEFT JOIN track tracks
4354       ON tracks.cd = cds.cdid
4355   ORDER BY me.artistid
4356
4357 While L</prefetch> implies a L</join>, it is ok to mix the two together, as
4358 the arguments are properly merged and generally do the right thing. For
4359 example, you may want to do the following:
4360
4361   my $artists_and_cds_without_genre = $schema->resultset('Artist')->search(
4362     { 'genre.genreid' => undef },
4363     {
4364       join => { cds => 'genre' },
4365       prefetch => 'cds',
4366     }
4367   );
4368
4369 Which generates the following SQL:
4370
4371   SELECT  me.artistid, me.name, me.rank, me.charfield,
4372           cds.cdid, cds.artist, cds.title, cds.year, cds.genreid, cds.single_track
4373     FROM artist me
4374     LEFT JOIN cd cds
4375       ON cds.artist = me.artistid
4376     LEFT JOIN genre genre
4377       ON genre.genreid = cds.genreid
4378   WHERE genre.genreid IS NULL
4379   ORDER BY me.artistid
4380
4381 For a more in-depth discussion, see L</PREFETCHING>.
4382
4383 =head2 alias
4384
4385 =over 4
4386
4387 =item Value: $source_alias
4388
4389 =back
4390
4391 Sets the source alias for the query.  Normally, this defaults to C<me>, but
4392 nested search queries (sub-SELECTs) might need specific aliases set to
4393 reference inner queries.  For example:
4394
4395    my $q = $rs
4396       ->related_resultset('CDs')
4397       ->related_resultset('Tracks')
4398       ->search({
4399          'track.id' => { -ident => 'none_search.id' },
4400       })
4401       ->as_query;
4402
4403    my $ids = $self->search({
4404       -not_exists => $q,
4405    }, {
4406       alias    => 'none_search',
4407       group_by => 'none_search.id',
4408    })->get_column('id')->as_query;
4409
4410    $self->search({ id => { -in => $ids } })
4411
4412 This attribute is directly tied to L</current_source_alias>.
4413
4414 =head2 page
4415
4416 =over 4
4417
4418 =item Value: $page
4419
4420 =back
4421
4422 Makes the resultset paged and specifies the page to retrieve. Effectively
4423 identical to creating a non-pages resultset and then calling ->page($page)
4424 on it.
4425
4426 If L</rows> attribute is not specified it defaults to 10 rows per page.
4427
4428 When you have a paged resultset, L</count> will only return the number
4429 of rows in the page. To get the total, use the L</pager> and call
4430 C<total_entries> on it.
4431
4432 =head2 rows
4433
4434 =over 4
4435
4436 =item Value: $rows
4437
4438 =back
4439
4440 Specifies the maximum number of rows for direct retrieval or the number of
4441 rows per page if the page attribute or method is used.
4442
4443 =head2 offset
4444
4445 =over 4
4446
4447 =item Value: $offset
4448
4449 =back
4450
4451 Specifies the (zero-based) row number for the  first row to be returned, or the
4452 of the first row of the first page if paging is used.
4453
4454 =head2 software_limit
4455
4456 =over 4
4457
4458 =item Value: (0 | 1)
4459
4460 =back
4461
4462 When combined with L</rows> and/or L</offset> the generated SQL will not
4463 include any limit dialect stanzas. Instead the entire result will be selected
4464 as if no limits were specified, and DBIC will perform the limit locally, by
4465 artificially advancing and finishing the resulting L</cursor>.
4466
4467 This is the recommended way of performing resultset limiting when no sane RDBMS
4468 implementation is available (e.g.
4469 L<Sybase ASE|DBIx::Class::Storage::DBI::Sybase::ASE> using the
4470 L<Generic Sub Query|DBIx::Class::SQLMaker::LimitDialects/GenericSubQ> hack)
4471
4472 =head2 group_by
4473
4474 =over 4
4475
4476 =item Value: \@columns
4477
4478 =back
4479
4480 A arrayref of columns to group by. Can include columns of joined tables.
4481
4482   group_by => [qw/ column1 column2 ... /]
4483
4484 =head2 having
4485
4486 =over 4
4487
4488 =item Value: $condition
4489
4490 =back
4491
4492 HAVING is a select statement attribute that is applied between GROUP BY and
4493 ORDER BY. It is applied to the after the grouping calculations have been
4494 done.
4495
4496   having => { 'count_employee' => { '>=', 100 } }
4497
4498 or with an in-place function in which case literal SQL is required:
4499
4500   having => \[ 'count(employee) >= ?', [ count => 100 ] ]
4501
4502 =head2 distinct
4503
4504 =over 4
4505
4506 =item Value: (0 | 1)
4507
4508 =back
4509
4510 Set to 1 to automatically generate a L</group_by> clause based on the selection
4511 (including intelligent handling of L</order_by> contents). Note that the group
4512 criteria calculation takes place over the B<final> selection. This includes
4513 any L</+columns>, L</+select> or L</order_by> additions in subsequent
4514 L</search> calls, and standalone columns selected via
4515 L<DBIx::Class::ResultSetColumn> (L</get_column>). A notable exception are the
4516 extra selections specified via L</prefetch> - such selections are explicitly
4517 excluded from group criteria calculations.
4518
4519 If the final ResultSet also explicitly defines a L</group_by> attribute, this
4520 setting is ignored and an appropriate warning is issued.
4521
4522 =head2 where
4523
4524 =over 4
4525
4526 Adds to the WHERE clause.
4527
4528   # only return rows WHERE deleted IS NULL for all searches
4529   __PACKAGE__->resultset_attributes({ where => { deleted => undef } });
4530
4531 Can be overridden by passing C<< { where => undef } >> as an attribute
4532 to a resultset.
4533
4534 For more complicated where clauses see L<SQL::Abstract/WHERE CLAUSES>.
4535
4536 =back
4537
4538 =head2 cache
4539
4540 Set to 1 to cache search results. This prevents extra SQL queries if you
4541 revisit rows in your ResultSet:
4542
4543   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
4544
4545   while( my $artist = $resultset->next ) {
4546     ... do stuff ...
4547   }
4548
4549   $rs->first; # without cache, this would issue a query
4550
4551 By default, searches are not cached.
4552
4553 For more examples of using these attributes, see
4554 L<DBIx::Class::Manual::Cookbook>.
4555
4556 =head2 for
4557
4558 =over 4
4559
4560 =item Value: ( 'update' | 'shared' | \$scalar )
4561
4562 =back
4563
4564 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
4565 ... FOR SHARED. If \$scalar is passed, this is taken directly and embedded in the
4566 query.
4567
4568 =head1 PREFETCHING
4569
4570 DBIx::Class supports arbitrary related data prefetching from multiple related
4571 sources. Any combination of relationship types and column sets are supported.
4572 If L<collapsing|/collapse> is requested, there is an additional requirement of
4573 selecting enough data to make every individual object uniquely identifiable.
4574
4575 Here are some more involved examples, based on the following relationship map:
4576
4577   # Assuming:
4578   My::Schema::CD->belongs_to( artist      => 'My::Schema::Artist'     );
4579   My::Schema::CD->might_have( liner_note  => 'My::Schema::LinerNotes' );
4580   My::Schema::CD->has_many(   tracks      => 'My::Schema::Track'      );
4581
4582   My::Schema::Artist->belongs_to( record_label => 'My::Schema::RecordLabel' );
4583
4584   My::Schema::Track->has_many( guests => 'My::Schema::Guest' );
4585
4586
4587
4588   my $rs = $schema->resultset('Tag')->search(
4589     undef,
4590     {
4591       prefetch => {
4592         cd => 'artist'
4593       }
4594     }
4595   );
4596
4597 The initial search results in SQL like the following:
4598
4599   SELECT tag.*, cd.*, artist.* FROM tag
4600   JOIN cd ON tag.cd = cd.cdid
4601   JOIN artist ON cd.artist = artist.artistid
4602
4603 L<DBIx::Class> has no need to go back to the database when we access the
4604 C<cd> or C<artist> relationships, which saves us two SQL statements in this
4605 case.
4606
4607 Simple prefetches will be joined automatically, so there is no need
4608 for a C<join> attribute in the above search.
4609
4610 The L</prefetch> attribute can be used with any of the relationship types
4611 and multiple prefetches can be specified together. Below is a more complex
4612 example that prefetches a CD's artist, its liner notes (if present),
4613 the cover image, the tracks on that CD, and the guests on those
4614 tracks.
4615
4616   my $rs = $schema->resultset('CD')->search(
4617     undef,
4618     {
4619       prefetch => [
4620         { artist => 'record_label'},  # belongs_to => belongs_to
4621         'liner_note',                 # might_have
4622         'cover_image',                # has_one
4623         { tracks => 'guests' },       # has_many => has_many
4624       ]
4625     }
4626   );
4627
4628 This will produce SQL like the following:
4629
4630   SELECT cd.*, artist.*, record_label.*, liner_note.*, cover_image.*,
4631          tracks.*, guests.*
4632     FROM cd me
4633     JOIN artist artist
4634       ON artist.artistid = me.artistid
4635     JOIN record_label record_label
4636       ON record_label.labelid = artist.labelid
4637     LEFT JOIN track tracks
4638       ON tracks.cdid = me.cdid
4639     LEFT JOIN guest guests
4640       ON guests.trackid = track.trackid
4641     LEFT JOIN liner_notes liner_note
4642       ON liner_note.cdid = me.cdid
4643     JOIN cd_artwork cover_image
4644       ON cover_image.cdid = me.cdid
4645   ORDER BY tracks.cd
4646
4647 Now the C<artist>, C<record_label>, C<liner_note>, C<cover_image>,
4648 C<tracks>, and C<guests> of the CD will all be available through the
4649 relationship accessors without the need for additional queries to the
4650 database.
4651
4652 =head3 CAVEATS
4653
4654 Prefetch does a lot of deep magic. As such, it may not behave exactly
4655 as you might expect.
4656
4657 =over 4
4658
4659 =item *
4660
4661 Prefetch uses the L</cache> to populate the prefetched relationships. This
4662 may or may not be what you want.
4663
4664 =item *
4665
4666 If you specify a condition on a prefetched relationship, ONLY those
4667 rows that match the prefetched condition will be fetched into that relationship.
4668 This means that adding prefetch to a search() B<may alter> what is returned by
4669 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
4670
4671   my $artist_rs = $schema->resultset('Artist')->search({
4672       'cds.year' => 2008,
4673   }, {
4674       join => 'cds',
4675   });
4676
4677   my $count = $artist_rs->first->cds->count;
4678
4679   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
4680
4681   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
4682
4683   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
4684
4685 That cmp_ok() may or may not pass depending on the datasets involved. In other
4686 words the C<WHERE> condition would apply to the entire dataset, just like
4687 it would in regular SQL. If you want to add a condition only to the "right side"
4688 of a C<LEFT JOIN> - consider declaring and using a L<relationship with a custom
4689 condition|DBIx::Class::Relationship::Base/condition>
4690
4691 =back
4692
4693 =head1 DBIC BIND VALUES
4694
4695 Because DBIC may need more information to bind values than just the column name
4696 and value itself, it uses a special format for both passing and receiving bind
4697 values.  Each bind value should be composed of an arrayref of
4698 C<< [ \%args => $val ] >>.  The format of C<< \%args >> is currently:
4699
4700 =over 4
4701
4702 =item dbd_attrs
4703
4704 If present (in any form), this is what is being passed directly to bind_param.
4705 Note that different DBD's expect different bind args.  (e.g. DBD::SQLite takes
4706 a single numerical type, while DBD::Pg takes a hashref if bind options.)
4707
4708 If this is specified, all other bind options described below are ignored.
4709
4710 =item sqlt_datatype
4711
4712 If present, this is used to infer the actual bind attribute by passing to
4713 C<< $resolved_storage->bind_attribute_by_data_type() >>.  Defaults to the
4714 "data_type" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>.
4715
4716 Note that the data type is somewhat freeform (hence the sqlt_ prefix);
4717 currently drivers are expected to "Do the Right Thing" when given a common
4718 datatype name.  (Not ideal, but that's what we got at this point.)
4719
4720 =item sqlt_size
4721
4722 Currently used to correctly allocate buffers for bind_param_inout().
4723 Defaults to "size" from the L<add_columns column info|DBIx::Class::ResultSource/add_columns>,
4724 or to a sensible value based on the "data_type".
4725
4726 =item dbic_colname
4727
4728 Used to fill in missing sqlt_datatype and sqlt_size attributes (if they are
4729 explicitly specified they are never overridden).  Also used by some weird DBDs,
4730 where the column name should be available at bind_param time (e.g. Oracle).
4731
4732 =back
4733
4734 For backwards compatibility and convenience, the following shortcuts are
4735 supported:
4736
4737   [ $name => $val ] === [ { dbic_colname => $name }, $val ]
4738   [ \$dt  => $val ] === [ { sqlt_datatype => $dt }, $val ]
4739   [ undef,   $val ] === [ {}, $val ]
4740   $val              === [ {}, $val ]
4741
4742 =head1 AUTHOR AND CONTRIBUTORS
4743
4744 See L<AUTHOR|DBIx::Class/AUTHOR> and L<CONTRIBUTORS|DBIx::Class/CONTRIBUTORS> in DBIx::Class
4745
4746 =head1 LICENSE
4747
4748 You may distribute this code under the same terms as Perl itself.
4749