lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360
 361   $rs->set_cache($rows) if ($rows);
 362
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   # if the first row that ever came in is totally empty - this means we got
 978   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 979   # instead of producing a {}
 980   #
 981   my $has_def;
 982   for (@$row) {
 983     if (defined $_) {
 984       $has_def++;
 985       last;
 986     }
 987   }
 988   return undef unless $has_def;
 989
 990   my @copy = @$row;
 991
 992   # 'foo'         => [ undef, 'foo' ]
 993   # 'foo.bar'     => [ 'foo', 'bar' ]
 994   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 995
 996   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 997
 998   my %collapse = %{$self->{_attrs}{collapse}||{}};
 999
1000   my @pri_index;
1001
1002   # if we're doing collapsing (has_many prefetch) we need to grab records
1003   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1004   # we know we don't have to bother.
1005
1006   # the reason for not using the collapse stuff directly is because if you
1007   # had for e.g. two artists in a row with no cds, the collapse info for
1008   # both would be NULL (undef) so you'd lose the second artist
1009
1010   # store just the index so we can check the array positions from the row
1011   # without having to contruct the full hash
1012
1013   if (keys %collapse) {
1014     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1015     foreach my $i (0 .. $#construct_as) {
1016       next if defined($construct_as[$i][0]); # only self table
1017       if (delete $pri{$construct_as[$i][1]}) {
1018         push(@pri_index, $i);
1019       }
1020       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1021     }
1022   }
1023
1024   # no need to do an if, it'll be empty if @pri_index is empty anyway
1025
1026   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1027
1028   my @const_rows;
1029
1030   do { # no need to check anything at the front, we always want the first row
1031
1032     my %const;
1033
1034     foreach my $this_as (@construct_as) {
1035       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1036     }
1037
1038     push(@const_rows, \%const);
1039
1040   } until ( # no pri_index => no collapse => drop straight out
1041       !@pri_index
1042     or
1043       do { # get another row, stash it, drop out if different PK
1044
1045         @copy = $self->cursor->next;
1046         $self->{stashed_row} = \@copy;
1047
1048         # last thing in do block, counts as true if anything doesn't match
1049
1050         # check xor defined first for NULL vs. NOT NULL then if one is
1051         # defined the other must be so check string equality
1052
1053         grep {
1054           (defined $pri_vals{$_} ^ defined $copy[$_])
1055           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1056         } @pri_index;
1057       }
1058   );
1059
1060   my $alias = $self->{attrs}{alias};
1061   my $info = [];
1062
1063   my %collapse_pos;
1064
1065   my @const_keys;
1066
1067   foreach my $const (@const_rows) {
1068     scalar @const_keys or do {
1069       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1070     };
1071     foreach my $key (@const_keys) {
1072       if (length $key) {
1073         my $target = $info;
1074         my @parts = split(/\./, $key);
1075         my $cur = '';
1076         my $data = $const->{$key};
1077         foreach my $p (@parts) {
1078           $target = $target->[1]->{$p} ||= [];
1079           $cur .= ".${p}";
1080           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1081             # collapsing at this point and on final part
1082             my $pos = $collapse_pos{$cur};
1083             CK: foreach my $ck (@ckey) {
1084               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1085                 $collapse_pos{$cur} = $data;
1086                 delete @collapse_pos{ # clear all positioning for sub-entries
1087                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1088                 };
1089                 push(@$target, []);
1090                 last CK;
1091               }
1092             }
1093           }
1094           if (exists $collapse{$cur}) {
1095             $target = $target->[-1];
1096           }
1097         }
1098         $target->[0] = $data;
1099       } else {
1100         $info->[0] = $const->{$key};
1101       }
1102     }
1103   }
1104
1105   return $info;
1106 }
1107
1108 =head2 result_source
1109
1110 =over 4
1111
1112 =item Arguments: $result_source?
1113
1114 =item Return Value: $result_source
1115
1116 =back
1117
1118 An accessor for the primary ResultSource object from which this ResultSet
1119 is derived.
1120
1121 =head2 result_class
1122
1123 =over 4
1124
1125 =item Arguments: $result_class?
1126
1127 =item Return Value: $result_class
1128
1129 =back
1130
1131 An accessor for the class to use when creating row objects. Defaults to
1132 C<< result_source->result_class >> - which in most cases is the name of the
1133 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1134
1135 Note that changing the result_class will also remove any components
1136 that were originally loaded in the source class via
1137 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1138 in the original source class will not run.
1139
1140 =cut
1141
1142 sub result_class {
1143   my ($self, $result_class) = @_;
1144   if ($result_class) {
1145     $self->ensure_class_loaded($result_class);
1146     $self->_result_class($result_class);
1147   }
1148   $self->_result_class;
1149 }
1150
1151 =head2 count
1152
1153 =over 4
1154
1155 =item Arguments: $cond, \%attrs??
1156
1157 =item Return Value: $count
1158
1159 =back
1160
1161 Performs an SQL C<COUNT> with the same query as the resultset was built
1162 with to find the number of elements. Passing arguments is equivalent to
1163 C<< $rs->search ($cond, \%attrs)->count >>
1164
1165 =cut
1166
1167 sub count {
1168   my $self = shift;
1169   return $self->search(@_)->count if @_ and defined $_[0];
1170   return scalar @{ $self->get_cache } if $self->get_cache;
1171
1172   my $attrs = $self->_resolved_attrs_copy;
1173
1174   # this is a little optimization - it is faster to do the limit
1175   # adjustments in software, instead of a subquery
1176   my $rows = delete $attrs->{rows};
1177   my $offset = delete $attrs->{offset};
1178
1179   my $crs;
1180   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1181     $crs = $self->_count_subq_rs ($attrs);
1182   }
1183   else {
1184     $crs = $self->_count_rs ($attrs);
1185   }
1186   my $count = $crs->next;
1187
1188   $count -= $offset if $offset;
1189   $count = $rows if $rows and $rows < $count;
1190   $count = 0 if ($count < 0);
1191
1192   return $count;
1193 }
1194
1195 =head2 count_rs
1196
1197 =over 4
1198
1199 =item Arguments: $cond, \%attrs??
1200
1201 =item Return Value: $count_rs
1202
1203 =back
1204
1205 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1206 This can be very handy for subqueries:
1207
1208   ->search( { amount => $some_rs->count_rs->as_query } )
1209
1210 As with regular resultsets the SQL query will be executed only after
1211 the resultset is accessed via L</next> or L</all>. That would return
1212 the same single value obtainable via L</count>.
1213
1214 =cut
1215
1216 sub count_rs {
1217   my $self = shift;
1218   return $self->search(@_)->count_rs if @_;
1219
1220   # this may look like a lack of abstraction (count() does about the same)
1221   # but in fact an _rs *must* use a subquery for the limits, as the
1222   # software based limiting can not be ported if this $rs is to be used
1223   # in a subquery itself (i.e. ->as_query)
1224   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1225     return $self->_count_subq_rs;
1226   }
1227   else {
1228     return $self->_count_rs;
1229   }
1230 }
1231
1232 #
1233 # returns a ResultSetColumn object tied to the count query
1234 #
1235 sub _count_rs {
1236   my ($self, $attrs) = @_;
1237
1238   my $rsrc = $self->result_source;
1239   $attrs ||= $self->_resolved_attrs;
1240
1241   my $tmp_attrs = { %$attrs };
1242
1243   # take off any limits, record_filter is cdbi, and no point of ordering a count
1244   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   # read the comment on top of the actual function to see what this does
1251   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1252     $tmp_attrs->{from}, $tmp_attrs->{alias}
1253   );
1254
1255   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1256
1257   return $tmp_rs;
1258 }
1259
1260 #
1261 # same as above but uses a subquery
1262 #
1263 sub _count_subq_rs {
1264   my ($self, $attrs) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   $attrs ||= $self->_resolved_attrs_copy;
1268
1269   my $sub_attrs = { %$attrs };
1270
1271   # extra selectors do not go in the subquery and there is no point of ordering it
1272   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1273
1274   # if we prefetch, we group_by primary keys only as this is what we would get out
1275   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1276   if ( keys %{$attrs->{collapse}} ) {
1277     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1278   }
1279
1280   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1281
1282   # read the comment on top of the actual function to see what this does
1283   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1284     $sub_attrs->{from}, $sub_attrs->{alias}
1285   );
1286
1287   # this is so that ordering can be thrown away in things like Top limit
1288   $sub_attrs->{-for_count_only} = 1;
1289
1290   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1291
1292   $attrs->{from} = [{
1293     -alias => 'count_subq',
1294     -source_handle => $rsrc->handle,
1295     count_subq => $sub_rs->as_query,
1296   }];
1297
1298   # the subquery replaces this
1299   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1300
1301   return $self->_count_rs ($attrs);
1302 }
1303
1304
1305 # The DBIC relationship chaining implementation is pretty simple - every
1306 # new related_relationship is pushed onto the {from} stack, and the {select}
1307 # window simply slides further in. This means that when we count somewhere
1308 # in the middle, we got to make sure that everything in the join chain is an
1309 # actual inner join, otherwise the count will come back with unpredictable
1310 # results (a resultset may be generated with _some_ rows regardless of if
1311 # the relation which the $rs currently selects has rows or not). E.g.
1312 # $artist_rs->cds->count - normally generates:
1313 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1314 # which actually returns the number of artists * (number of cds || 1)
1315 #
1316 # So what we do here is crawl {from}, determine if the current alias is at
1317 # the top of the stack, and if not - make sure the chain is inner-joined down
1318 # to the root.
1319 #
1320 sub _switch_to_inner_join_if_needed {
1321   my ($self, $from, $alias) = @_;
1322
1323   # subqueries and other oddness is naturally not supported
1324   return $from if (
1325     ref $from ne 'ARRAY'
1326       ||
1327     @$from <= 1
1328       ||
1329     ref $from->[0] ne 'HASH'
1330       ||
1331     ! $from->[0]{-alias}
1332       ||
1333     $from->[0]{-alias} eq $alias
1334   );
1335
1336   my $switch_branch;
1337   JOINSCAN:
1338   for my $j (@{$from}[1 .. $#$from]) {
1339     if ($j->[0]{-alias} eq $alias) {
1340       $switch_branch = $j->[0]{-join_path};
1341       last JOINSCAN;
1342     }
1343   }
1344
1345   # something else went wrong
1346   return $from unless $switch_branch;
1347
1348   # So it looks like we will have to switch some stuff around.
1349   # local() is useless here as we will be leaving the scope
1350   # anyway, and deep cloning is just too fucking expensive
1351   # So replace the inner hashref manually
1352   my @new_from = ($from->[0]);
1353   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1354
1355   for my $j (@{$from}[1 .. $#$from]) {
1356     my $jalias = $j->[0]{-alias};
1357
1358     if ($sw_idx->{$jalias}) {
1359       my %attrs = %{$j->[0]};
1360       delete $attrs{-join_type};
1361       push @new_from, [
1362         \%attrs,
1363         @{$j}[ 1 .. $#$j ],
1364       ];
1365     }
1366     else {
1367       push @new_from, $j;
1368     }
1369   }
1370
1371   return \@new_from;
1372 }
1373
1374
1375 sub _bool {
1376   return 1;
1377 }
1378
1379 =head2 count_literal
1380
1381 =over 4
1382
1383 =item Arguments: $sql_fragment, @bind_values
1384
1385 =item Return Value: $count
1386
1387 =back
1388
1389 Counts the results in a literal query. Equivalent to calling L</search_literal>
1390 with the passed arguments, then L</count>.
1391
1392 =cut
1393
1394 sub count_literal { shift->search_literal(@_)->count; }
1395
1396 =head2 all
1397
1398 =over 4
1399
1400 =item Arguments: none
1401
1402 =item Return Value: @objects
1403
1404 =back
1405
1406 Returns all elements in the resultset. Called implicitly if the resultset
1407 is returned in list context.
1408
1409 =cut
1410
1411 sub all {
1412   my $self = shift;
1413   if(@_) {
1414       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1415   }
1416
1417   return @{ $self->get_cache } if $self->get_cache;
1418
1419   my @obj;
1420
1421   if (keys %{$self->_resolved_attrs->{collapse}}) {
1422     # Using $self->cursor->all is really just an optimisation.
1423     # If we're collapsing has_many prefetches it probably makes
1424     # very little difference, and this is cleaner than hacking
1425     # _construct_object to survive the approach
1426     $self->cursor->reset;
1427     my @row = $self->cursor->next;
1428     while (@row) {
1429       push(@obj, $self->_construct_object(@row));
1430       @row = (exists $self->{stashed_row}
1431                ? @{delete $self->{stashed_row}}
1432                : $self->cursor->next);
1433     }
1434   } else {
1435     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1436   }
1437
1438   $self->set_cache(\@obj) if $self->{attrs}{cache};
1439
1440   return @obj;
1441 }
1442
1443 =head2 reset
1444
1445 =over 4
1446
1447 =item Arguments: none
1448
1449 =item Return Value: $self
1450
1451 =back
1452
1453 Resets the resultset's cursor, so you can iterate through the elements again.
1454 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1455 another query.
1456
1457 =cut
1458
1459 sub reset {
1460   my ($self) = @_;
1461   delete $self->{_attrs} if exists $self->{_attrs};
1462   $self->{all_cache_position} = 0;
1463   $self->cursor->reset;
1464   return $self;
1465 }
1466
1467 =head2 first
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: $object?
1474
1475 =back
1476
1477 Resets the resultset and returns an object for the first result (if the
1478 resultset returns anything).
1479
1480 =cut
1481
1482 sub first {
1483   return $_[0]->reset->next;
1484 }
1485
1486
1487 # _rs_update_delete
1488 #
1489 # Determines whether and what type of subquery is required for the $rs operation.
1490 # If grouping is necessary either supplies its own, or verifies the current one
1491 # After all is done delegates to the proper storage method.
1492
1493 sub _rs_update_delete {
1494   my ($self, $op, $values) = @_;
1495
1496   my $rsrc = $self->result_source;
1497
1498   # if a condition exists we need to strip all table qualifiers
1499   # if this is not possible we'll force a subquery below
1500   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1501
1502   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1503   my $needs_subq = (not defined $cond) || $self->_has_resolved_attr(qw/row offset/);
1504
1505   if ($needs_group_by_subq or $needs_subq) {
1506
1507     # make a new $rs selecting only the PKs (that's all we really need)
1508     my $attrs = $self->_resolved_attrs_copy;
1509
1510     delete $attrs->{$_} for qw/collapse select as/;
1511     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1512
1513     if ($needs_group_by_subq) {
1514       # make sure no group_by was supplied, or if there is one - make sure it matches
1515       # the columns compiled above perfectly. Anything else can not be sanely executed
1516       # on most databases so croak right then and there
1517
1518       if (my $g = $attrs->{group_by}) {
1519         my @current_group_by = map
1520           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1521           @$g
1522         ;
1523
1524         if (
1525           join ("\x00", sort @current_group_by)
1526             ne
1527           join ("\x00", sort @{$attrs->{columns}} )
1528         ) {
1529           $self->throw_exception (
1530             "You have just attempted a $op operation on a resultset which does group_by"
1531             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1532             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1533             . ' kind of queries. Please retry the operation with a modified group_by or'
1534             . ' without using one at all.'
1535           );
1536         }
1537       }
1538       else {
1539         $attrs->{group_by} = $attrs->{columns};
1540       }
1541     }
1542
1543     my $subrs = (ref $self)->new($rsrc, $attrs);
1544
1545     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1546   }
1547   else {
1548     return $rsrc->storage->$op(
1549       $rsrc,
1550       $op eq 'update' ? $values : (),
1551       $cond,
1552     );
1553   }
1554 }
1555
1556 =head2 update
1557
1558 =over 4
1559
1560 =item Arguments: \%values
1561
1562 =item Return Value: $storage_rv
1563
1564 =back
1565
1566 Sets the specified columns in the resultset to the supplied values in a
1567 single query. Return value will be true if the update succeeded or false
1568 if no records were updated; exact type of success value is storage-dependent.
1569
1570 =cut
1571
1572 sub update {
1573   my ($self, $values) = @_;
1574   $self->throw_exception('Values for update must be a hash')
1575     unless ref $values eq 'HASH';
1576
1577   return $self->_rs_update_delete ('update', $values);
1578 }
1579
1580 =head2 update_all
1581
1582 =over 4
1583
1584 =item Arguments: \%values
1585
1586 =item Return Value: 1
1587
1588 =back
1589
1590 Fetches all objects and updates them one at a time. Note that C<update_all>
1591 will run DBIC cascade triggers, while L</update> will not.
1592
1593 =cut
1594
1595 sub update_all {
1596   my ($self, $values) = @_;
1597   $self->throw_exception('Values for update_all must be a hash')
1598     unless ref $values eq 'HASH';
1599   foreach my $obj ($self->all) {
1600     $obj->set_columns($values)->update;
1601   }
1602   return 1;
1603 }
1604
1605 =head2 delete
1606
1607 =over 4
1608
1609 =item Arguments: none
1610
1611 =item Return Value: $storage_rv
1612
1613 =back
1614
1615 Deletes the contents of the resultset from its result source. Note that this
1616 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1617 to run. See also L<DBIx::Class::Row/delete>.
1618
1619 Return value will be the amount of rows deleted; exact type of return value
1620 is storage-dependent.
1621
1622 =cut
1623
1624 sub delete {
1625   my $self = shift;
1626   $self->throw_exception('delete does not accept any arguments')
1627     if @_;
1628
1629   return $self->_rs_update_delete ('delete');
1630 }
1631
1632 =head2 delete_all
1633
1634 =over 4
1635
1636 =item Arguments: none
1637
1638 =item Return Value: 1
1639
1640 =back
1641
1642 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1643 will run DBIC cascade triggers, while L</delete> will not.
1644
1645 =cut
1646
1647 sub delete_all {
1648   my $self = shift;
1649   $self->throw_exception('delete_all does not accept any arguments')
1650     if @_;
1651
1652   $_->delete for $self->all;
1653   return 1;
1654 }
1655
1656 =head2 populate
1657
1658 =over 4
1659
1660 =item Arguments: \@data;
1661
1662 =back
1663
1664 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1665 For the arrayref of hashrefs style each hashref should be a structure suitable
1666 forsubmitting to a $resultset->create(...) method.
1667
1668 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1669 to insert the data, as this is a faster method.
1670
1671 Otherwise, each set of data is inserted into the database using
1672 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1673 accumulated into an array. The array itself, or an array reference
1674 is returned depending on scalar or list context.
1675
1676 Example:  Assuming an Artist Class that has many CDs Classes relating:
1677
1678   my $Artist_rs = $schema->resultset("Artist");
1679
1680   ## Void Context Example
1681   $Artist_rs->populate([
1682      { artistid => 4, name => 'Manufactured Crap', cds => [
1683         { title => 'My First CD', year => 2006 },
1684         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1685       ],
1686      },
1687      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1688         { title => 'My parents sold me to a record company' ,year => 2005 },
1689         { title => 'Why Am I So Ugly?', year => 2006 },
1690         { title => 'I Got Surgery and am now Popular', year => 2007 }
1691       ],
1692      },
1693   ]);
1694
1695   ## Array Context Example
1696   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1697     { name => "Artist One"},
1698     { name => "Artist Two"},
1699     { name => "Artist Three", cds=> [
1700     { title => "First CD", year => 2007},
1701     { title => "Second CD", year => 2008},
1702   ]}
1703   ]);
1704
1705   print $ArtistOne->name; ## response is 'Artist One'
1706   print $ArtistThree->cds->count ## reponse is '2'
1707
1708 For the arrayref of arrayrefs style,  the first element should be a list of the
1709 fieldsnames to which the remaining elements are rows being inserted.  For
1710 example:
1711
1712   $Arstist_rs->populate([
1713     [qw/artistid name/],
1714     [100, 'A Formally Unknown Singer'],
1715     [101, 'A singer that jumped the shark two albums ago'],
1716     [102, 'An actually cool singer.'],
1717   ]);
1718
1719 Please note an important effect on your data when choosing between void and
1720 wantarray context. Since void context goes straight to C<insert_bulk> in
1721 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1722 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1723 create primary keys for you, you will find that your PKs are empty.  In this
1724 case you will have to use the wantarray context in order to create those
1725 values.
1726
1727 =cut
1728
1729 sub populate {
1730   my $self = shift @_;
1731   my $data = ref $_[0][0] eq 'HASH'
1732     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1733     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1734
1735   if(defined wantarray) {
1736     my @created;
1737     foreach my $item (@$data) {
1738       push(@created, $self->create($item));
1739     }
1740     return wantarray ? @created : \@created;
1741   } else {
1742     my $first = $data->[0];
1743
1744     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1745     # it relationship data
1746     my (@rels, @columns);
1747     for (keys %$first) {
1748       my $ref = ref $first->{$_};
1749       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1750         ? push @rels, $_
1751         : push @columns, $_
1752       ;
1753     }
1754
1755     my @pks = $self->result_source->primary_columns;
1756
1757     ## do the belongs_to relationships
1758     foreach my $index (0..$#$data) {
1759
1760       # delegate to create() for any dataset without primary keys with specified relationships
1761       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1762         for my $r (@rels) {
1763           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1764             my @ret = $self->populate($data);
1765             return;
1766           }
1767         }
1768       }
1769
1770       foreach my $rel (@rels) {
1771         next unless ref $data->[$index]->{$rel} eq "HASH";
1772         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1773         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1774         my $related = $result->result_source->_resolve_condition(
1775           $result->result_source->relationship_info($reverse)->{cond},
1776           $self,
1777           $result,
1778         );
1779
1780         delete $data->[$index]->{$rel};
1781         $data->[$index] = {%{$data->[$index]}, %$related};
1782
1783         push @columns, keys %$related if $index == 0;
1784       }
1785     }
1786
1787     ## do bulk insert on current row
1788     $self->result_source->storage->insert_bulk(
1789       $self->result_source,
1790       \@columns,
1791       [ map { [ @$_{@columns} ] } @$data ],
1792     );
1793
1794     ## do the has_many relationships
1795     foreach my $item (@$data) {
1796
1797       foreach my $rel (@rels) {
1798         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1799
1800         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1801      || $self->throw_exception('Cannot find the relating object.');
1802
1803         my $child = $parent->$rel;
1804
1805         my $related = $child->result_source->_resolve_condition(
1806           $parent->result_source->relationship_info($rel)->{cond},
1807           $child,
1808           $parent,
1809         );
1810
1811         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1812         my @populate = map { {%$_, %$related} } @rows_to_add;
1813
1814         $child->populate( \@populate );
1815       }
1816     }
1817   }
1818 }
1819
1820 =head2 _normalize_populate_args ($args)
1821
1822 Private method used by L</populate> to normalize its incoming arguments.  Factored
1823 out in case you want to subclass and accept new argument structures to the
1824 L</populate> method.
1825
1826 =cut
1827
1828 sub _normalize_populate_args {
1829   my ($self, $data) = @_;
1830   my @names = @{shift(@$data)};
1831   my @results_to_create;
1832   foreach my $datum (@$data) {
1833     my %result_to_create;
1834     foreach my $index (0..$#names) {
1835       $result_to_create{$names[$index]} = $$datum[$index];
1836     }
1837     push @results_to_create, \%result_to_create;
1838   }
1839   return \@results_to_create;
1840 }
1841
1842 =head2 pager
1843
1844 =over 4
1845
1846 =item Arguments: none
1847
1848 =item Return Value: $pager
1849
1850 =back
1851
1852 Return Value a L<Data::Page> object for the current resultset. Only makes
1853 sense for queries with a C<page> attribute.
1854
1855 To get the full count of entries for a paged resultset, call
1856 C<total_entries> on the L<Data::Page> object.
1857
1858 =cut
1859
1860 sub pager {
1861   my ($self) = @_;
1862
1863   return $self->{pager} if $self->{pager};
1864
1865   my $attrs = $self->{attrs};
1866   $self->throw_exception("Can't create pager for non-paged rs")
1867     unless $self->{attrs}{page};
1868   $attrs->{rows} ||= 10;
1869
1870   # throw away the paging flags and re-run the count (possibly
1871   # with a subselect) to get the real total count
1872   my $count_attrs = { %$attrs };
1873   delete $count_attrs->{$_} for qw/rows offset page pager/;
1874   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1875
1876   return $self->{pager} = Data::Page->new(
1877     $total_count,
1878     $attrs->{rows},
1879     $self->{attrs}{page}
1880   );
1881 }
1882
1883 =head2 page
1884
1885 =over 4
1886
1887 =item Arguments: $page_number
1888
1889 =item Return Value: $rs
1890
1891 =back
1892
1893 Returns a resultset for the $page_number page of the resultset on which page
1894 is called, where each page contains a number of rows equal to the 'rows'
1895 attribute set on the resultset (10 by default).
1896
1897 =cut
1898
1899 sub page {
1900   my ($self, $page) = @_;
1901   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1902 }
1903
1904 =head2 new_result
1905
1906 =over 4
1907
1908 =item Arguments: \%vals
1909
1910 =item Return Value: $rowobject
1911
1912 =back
1913
1914 Creates a new row object in the resultset's result class and returns
1915 it. The row is not inserted into the database at this point, call
1916 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1917 will tell you whether the row object has been inserted or not.
1918
1919 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1920
1921 =cut
1922
1923 sub new_result {
1924   my ($self, $values) = @_;
1925   $self->throw_exception( "new_result needs a hash" )
1926     unless (ref $values eq 'HASH');
1927
1928   my %new;
1929   my $alias = $self->{attrs}{alias};
1930
1931   if (
1932     defined $self->{cond}
1933     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1934   ) {
1935     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1936     $new{-from_resultset} = [ keys %new ] if keys %new;
1937   } else {
1938     $self->throw_exception(
1939       "Can't abstract implicit construct, condition not a hash"
1940     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1941
1942     my $collapsed_cond = (
1943       $self->{cond}
1944         ? $self->_collapse_cond($self->{cond})
1945         : {}
1946     );
1947
1948     # precendence must be given to passed values over values inherited from
1949     # the cond, so the order here is important.
1950     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1951     while( my($col,$value) = each %implied ){
1952       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1953         $new{$col} = $value->{'='};
1954         next;
1955       }
1956       $new{$col} = $value if $self->_is_deterministic_value($value);
1957     }
1958   }
1959
1960   %new = (
1961     %new,
1962     %{ $self->_remove_alias($values, $alias) },
1963     -source_handle => $self->_source_handle,
1964     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1965   );
1966
1967   return $self->result_class->new(\%new);
1968 }
1969
1970 # _is_deterministic_value
1971 #
1972 # Make an effor to strip non-deterministic values from the condition,
1973 # to make sure new_result chokes less
1974
1975 sub _is_deterministic_value {
1976   my $self = shift;
1977   my $value = shift;
1978   my $ref_type = ref $value;
1979   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1980   return 1 if Scalar::Util::blessed($value);
1981   return 0;
1982 }
1983
1984 # _has_resolved_attr
1985 #
1986 # determines if the resultset defines at least one
1987 # of the attributes supplied
1988 #
1989 # used to determine if a subquery is neccessary
1990 #
1991 # supports some virtual attributes:
1992 #   -join
1993 #     This will scan for any joins being present on the resultset.
1994 #     It is not a mere key-search but a deep inspection of {from}
1995 #
1996
1997 sub _has_resolved_attr {
1998   my ($self, @attr_names) = @_;
1999
2000   my $attrs = $self->_resolved_attrs;
2001
2002   my %extra_checks;
2003
2004   for my $n (@attr_names) {
2005     if (grep { $n eq $_ } (qw/-join/) ) {
2006       $extra_checks{$n}++;
2007       next;
2008     }
2009
2010     my $attr =  $attrs->{$n};
2011
2012     next if not defined $attr;
2013
2014     if (ref $attr eq 'HASH') {
2015       return 1 if keys %$attr;
2016     }
2017     elsif (ref $attr eq 'ARRAY') {
2018       return 1 if @$attr;
2019     }
2020     else {
2021       return 1 if $attr;
2022     }
2023   }
2024
2025   # a resolved join is expressed as a multi-level from
2026   return 1 if (
2027     $extra_checks{-join}
2028       and
2029     ref $attrs->{from} eq 'ARRAY'
2030       and
2031     @{$attrs->{from}} > 1
2032   );
2033
2034   return 0;
2035 }
2036
2037 # _collapse_cond
2038 #
2039 # Recursively collapse the condition.
2040
2041 sub _collapse_cond {
2042   my ($self, $cond, $collapsed) = @_;
2043
2044   $collapsed ||= {};
2045
2046   if (ref $cond eq 'ARRAY') {
2047     foreach my $subcond (@$cond) {
2048       next unless ref $subcond;  # -or
2049       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2050     }
2051   }
2052   elsif (ref $cond eq 'HASH') {
2053     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2054       foreach my $subcond (@{$cond->{-and}}) {
2055         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2056       }
2057     }
2058     else {
2059       foreach my $col (keys %$cond) {
2060         my $value = $cond->{$col};
2061         $collapsed->{$col} = $value;
2062       }
2063     }
2064   }
2065
2066   return $collapsed;
2067 }
2068
2069 # _remove_alias
2070 #
2071 # Remove the specified alias from the specified query hash. A copy is made so
2072 # the original query is not modified.
2073
2074 sub _remove_alias {
2075   my ($self, $query, $alias) = @_;
2076
2077   my %orig = %{ $query || {} };
2078   my %unaliased;
2079
2080   foreach my $key (keys %orig) {
2081     if ($key !~ /\./) {
2082       $unaliased{$key} = $orig{$key};
2083       next;
2084     }
2085     $unaliased{$1} = $orig{$key}
2086       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2087   }
2088
2089   return \%unaliased;
2090 }
2091
2092 =head2 as_query (EXPERIMENTAL)
2093
2094 =over 4
2095
2096 =item Arguments: none
2097
2098 =item Return Value: \[ $sql, @bind ]
2099
2100 =back
2101
2102 Returns the SQL query and bind vars associated with the invocant.
2103
2104 This is generally used as the RHS for a subquery.
2105
2106 B<NOTE>: This feature is still experimental.
2107
2108 =cut
2109
2110 sub as_query {
2111   my $self = shift;
2112
2113   my $attrs = $self->_resolved_attrs_copy;
2114
2115   # For future use:
2116   #
2117   # in list ctx:
2118   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2119   # $sql also has no wrapping parenthesis in list ctx
2120   #
2121   my $sqlbind = $self->result_source->storage
2122     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2123
2124   return $sqlbind;
2125 }
2126
2127 =head2 find_or_new
2128
2129 =over 4
2130
2131 =item Arguments: \%vals, \%attrs?
2132
2133 =item Return Value: $rowobject
2134
2135 =back
2136
2137   my $artist = $schema->resultset('Artist')->find_or_new(
2138     { artist => 'fred' }, { key => 'artists' });
2139
2140   $cd->cd_to_producer->find_or_new({ producer => $producer },
2141                                    { key => 'primary });
2142
2143 Find an existing record from this resultset, based on its primary
2144 key, or a unique constraint. If none exists, instantiate a new result
2145 object and return it. The object will not be saved into your storage
2146 until you call L<DBIx::Class::Row/insert> on it.
2147
2148 You most likely want this method when looking for existing rows using
2149 a unique constraint that is not the primary key, or looking for
2150 related rows.
2151
2152 If you want objects to be saved immediately, use L</find_or_create>
2153 instead.
2154
2155 B<Note>: Take care when using C<find_or_new> with a table having
2156 columns with default values that you intend to be automatically
2157 supplied by the database (e.g. an auto_increment primary key column).
2158 In normal usage, the value of such columns should NOT be included at
2159 all in the call to C<find_or_new>, even when set to C<undef>.
2160
2161 =cut
2162
2163 sub find_or_new {
2164   my $self     = shift;
2165   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2166   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2167   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2168     return $row;
2169   }
2170   return $self->new_result($hash);
2171 }
2172
2173 =head2 create
2174
2175 =over 4
2176
2177 =item Arguments: \%vals
2178
2179 =item Return Value: a L<DBIx::Class::Row> $object
2180
2181 =back
2182
2183 Attempt to create a single new row or a row with multiple related rows
2184 in the table represented by the resultset (and related tables). This
2185 will not check for duplicate rows before inserting, use
2186 L</find_or_create> to do that.
2187
2188 To create one row for this resultset, pass a hashref of key/value
2189 pairs representing the columns of the table and the values you wish to
2190 store. If the appropriate relationships are set up, foreign key fields
2191 can also be passed an object representing the foreign row, and the
2192 value will be set to its primary key.
2193
2194 To create related objects, pass a hashref of related-object column values
2195 B<keyed on the relationship name>. If the relationship is of type C<multi>
2196 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2197 The process will correctly identify columns holding foreign keys, and will
2198 transparrently populate them from the keys of the corresponding relation.
2199 This can be applied recursively, and will work correctly for a structure
2200 with an arbitrary depth and width, as long as the relationships actually
2201 exists and the correct column data has been supplied.
2202
2203
2204 Instead of hashrefs of plain related data (key/value pairs), you may
2205 also pass new or inserted objects. New objects (not inserted yet, see
2206 L</new>), will be inserted into their appropriate tables.
2207
2208 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2209
2210 Example of creating a new row.
2211
2212   $person_rs->create({
2213     name=>"Some Person",
2214     email=>"somebody@someplace.com"
2215   });
2216
2217 Example of creating a new row and also creating rows in a related C<has_many>
2218 or C<has_one> resultset.  Note Arrayref.
2219
2220   $artist_rs->create(
2221      { artistid => 4, name => 'Manufactured Crap', cds => [
2222         { title => 'My First CD', year => 2006 },
2223         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2224       ],
2225      },
2226   );
2227
2228 Example of creating a new row and also creating a row in a related
2229 C<belongs_to>resultset. Note Hashref.
2230
2231   $cd_rs->create({
2232     title=>"Music for Silly Walks",
2233     year=>2000,
2234     artist => {
2235       name=>"Silly Musician",
2236     }
2237   });
2238
2239 =over
2240
2241 =item WARNING
2242
2243 When subclassing ResultSet never attempt to override this method. Since
2244 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2245 lot of the internals simply never call it, so your override will be
2246 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2247 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2248 L</create> process you need to intervene.
2249
2250 =back
2251
2252 =cut
2253
2254 sub create {
2255   my ($self, $attrs) = @_;
2256   $self->throw_exception( "create needs a hashref" )
2257     unless ref $attrs eq 'HASH';
2258   return $self->new_result($attrs)->insert;
2259 }
2260
2261 =head2 find_or_create
2262
2263 =over 4
2264
2265 =item Arguments: \%vals, \%attrs?
2266
2267 =item Return Value: $rowobject
2268
2269 =back
2270
2271   $cd->cd_to_producer->find_or_create({ producer => $producer },
2272                                       { key => 'primary' });
2273
2274 Tries to find a record based on its primary key or unique constraints; if none
2275 is found, creates one and returns that instead.
2276
2277   my $cd = $schema->resultset('CD')->find_or_create({
2278     cdid   => 5,
2279     artist => 'Massive Attack',
2280     title  => 'Mezzanine',
2281     year   => 2005,
2282   });
2283
2284 Also takes an optional C<key> attribute, to search by a specific key or unique
2285 constraint. For example:
2286
2287   my $cd = $schema->resultset('CD')->find_or_create(
2288     {
2289       artist => 'Massive Attack',
2290       title  => 'Mezzanine',
2291     },
2292     { key => 'cd_artist_title' }
2293   );
2294
2295 B<Note>: Because find_or_create() reads from the database and then
2296 possibly inserts based on the result, this method is subject to a race
2297 condition. Another process could create a record in the table after
2298 the find has completed and before the create has started. To avoid
2299 this problem, use find_or_create() inside a transaction.
2300
2301 B<Note>: Take care when using C<find_or_create> with a table having
2302 columns with default values that you intend to be automatically
2303 supplied by the database (e.g. an auto_increment primary key column).
2304 In normal usage, the value of such columns should NOT be included at
2305 all in the call to C<find_or_create>, even when set to C<undef>.
2306
2307 See also L</find> and L</update_or_create>. For information on how to declare
2308 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2309
2310 =cut
2311
2312 sub find_or_create {
2313   my $self     = shift;
2314   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2315   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2316   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2317     return $row;
2318   }
2319   return $self->create($hash);
2320 }
2321
2322 =head2 update_or_create
2323
2324 =over 4
2325
2326 =item Arguments: \%col_values, { key => $unique_constraint }?
2327
2328 =item Return Value: $rowobject
2329
2330 =back
2331
2332   $resultset->update_or_create({ col => $val, ... });
2333
2334 First, searches for an existing row matching one of the unique constraints
2335 (including the primary key) on the source of this resultset. If a row is
2336 found, updates it with the other given column values. Otherwise, creates a new
2337 row.
2338
2339 Takes an optional C<key> attribute to search on a specific unique constraint.
2340 For example:
2341
2342   # In your application
2343   my $cd = $schema->resultset('CD')->update_or_create(
2344     {
2345       artist => 'Massive Attack',
2346       title  => 'Mezzanine',
2347       year   => 1998,
2348     },
2349     { key => 'cd_artist_title' }
2350   );
2351
2352   $cd->cd_to_producer->update_or_create({
2353     producer => $producer,
2354     name => 'harry',
2355   }, {
2356     key => 'primary,
2357   });
2358
2359
2360 If no C<key> is specified, it searches on all unique constraints defined on the
2361 source, including the primary key.
2362
2363 If the C<key> is specified as C<primary>, it searches only on the primary key.
2364
2365 See also L</find> and L</find_or_create>. For information on how to declare
2366 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2367
2368 B<Note>: Take care when using C<update_or_create> with a table having
2369 columns with default values that you intend to be automatically
2370 supplied by the database (e.g. an auto_increment primary key column).
2371 In normal usage, the value of such columns should NOT be included at
2372 all in the call to C<update_or_create>, even when set to C<undef>.
2373
2374 =cut
2375
2376 sub update_or_create {
2377   my $self = shift;
2378   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2379   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2380
2381   my $row = $self->find($cond, $attrs);
2382   if (defined $row) {
2383     $row->update($cond);
2384     return $row;
2385   }
2386
2387   return $self->create($cond);
2388 }
2389
2390 =head2 update_or_new
2391
2392 =over 4
2393
2394 =item Arguments: \%col_values, { key => $unique_constraint }?
2395
2396 =item Return Value: $rowobject
2397
2398 =back
2399
2400   $resultset->update_or_new({ col => $val, ... });
2401
2402 First, searches for an existing row matching one of the unique constraints
2403 (including the primary key) on the source of this resultset. If a row is
2404 found, updates it with the other given column values. Otherwise, instantiate
2405 a new result object and return it. The object will not be saved into your storage
2406 until you call L<DBIx::Class::Row/insert> on it.
2407
2408 Takes an optional C<key> attribute to search on a specific unique constraint.
2409 For example:
2410
2411   # In your application
2412   my $cd = $schema->resultset('CD')->update_or_new(
2413     {
2414       artist => 'Massive Attack',
2415       title  => 'Mezzanine',
2416       year   => 1998,
2417     },
2418     { key => 'cd_artist_title' }
2419   );
2420
2421   if ($cd->in_storage) {
2422       # the cd was updated
2423   }
2424   else {
2425       # the cd is not yet in the database, let's insert it
2426       $cd->insert;
2427   }
2428
2429 B<Note>: Take care when using C<update_or_new> with a table having
2430 columns with default values that you intend to be automatically
2431 supplied by the database (e.g. an auto_increment primary key column).
2432 In normal usage, the value of such columns should NOT be included at
2433 all in the call to C<update_or_new>, even when set to C<undef>.
2434
2435 See also L</find>, L</find_or_create> and L</find_or_new>.
2436
2437 =cut
2438
2439 sub update_or_new {
2440     my $self  = shift;
2441     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2442     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2443
2444     my $row = $self->find( $cond, $attrs );
2445     if ( defined $row ) {
2446         $row->update($cond);
2447         return $row;
2448     }
2449
2450     return $self->new_result($cond);
2451 }
2452
2453 =head2 get_cache
2454
2455 =over 4
2456
2457 =item Arguments: none
2458
2459 =item Return Value: \@cache_objects?
2460
2461 =back
2462
2463 Gets the contents of the cache for the resultset, if the cache is set.
2464
2465 The cache is populated either by using the L</prefetch> attribute to
2466 L</search> or by calling L</set_cache>.
2467
2468 =cut
2469
2470 sub get_cache {
2471   shift->{all_cache};
2472 }
2473
2474 =head2 set_cache
2475
2476 =over 4
2477
2478 =item Arguments: \@cache_objects
2479
2480 =item Return Value: \@cache_objects
2481
2482 =back
2483
2484 Sets the contents of the cache for the resultset. Expects an arrayref
2485 of objects of the same class as those produced by the resultset. Note that
2486 if the cache is set the resultset will return the cached objects rather
2487 than re-querying the database even if the cache attr is not set.
2488
2489 The contents of the cache can also be populated by using the
2490 L</prefetch> attribute to L</search>.
2491
2492 =cut
2493
2494 sub set_cache {
2495   my ( $self, $data ) = @_;
2496   $self->throw_exception("set_cache requires an arrayref")
2497       if defined($data) && (ref $data ne 'ARRAY');
2498   $self->{all_cache} = $data;
2499 }
2500
2501 =head2 clear_cache
2502
2503 =over 4
2504
2505 =item Arguments: none
2506
2507 =item Return Value: []
2508
2509 =back
2510
2511 Clears the cache for the resultset.
2512
2513 =cut
2514
2515 sub clear_cache {
2516   shift->set_cache(undef);
2517 }
2518
2519 =head2 is_paged
2520
2521 =over 4
2522
2523 =item Arguments: none
2524
2525 =item Return Value: true, if the resultset has been paginated
2526
2527 =back
2528
2529 =cut
2530
2531 sub is_paged {
2532   my ($self) = @_;
2533   return !!$self->{attrs}{page};
2534 }
2535
2536 =head2 related_resultset
2537
2538 =over 4
2539
2540 =item Arguments: $relationship_name
2541
2542 =item Return Value: $resultset
2543
2544 =back
2545
2546 Returns a related resultset for the supplied relationship name.
2547
2548   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2549
2550 =cut
2551
2552 sub related_resultset {
2553   my ($self, $rel) = @_;
2554
2555   $self->{related_resultsets} ||= {};
2556   return $self->{related_resultsets}{$rel} ||= do {
2557     my $rel_info = $self->result_source->relationship_info($rel);
2558
2559     $self->throw_exception(
2560       "search_related: result source '" . $self->result_source->source_name .
2561         "' has no such relationship $rel")
2562       unless $rel_info;
2563
2564     my ($from,$seen) = $self->_chain_relationship($rel);
2565
2566     my $join_count = $seen->{$rel};
2567     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2568
2569     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2570     my %attrs = %{$self->{attrs}||{}};
2571     delete @attrs{qw(result_class alias)};
2572
2573     my $new_cache;
2574
2575     if (my $cache = $self->get_cache) {
2576       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2577         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2578                         @$cache ];
2579       }
2580     }
2581
2582     my $rel_source = $self->result_source->related_source($rel);
2583
2584     my $new = do {
2585
2586       # The reason we do this now instead of passing the alias to the
2587       # search_rs below is that if you wrap/overload resultset on the
2588       # source you need to know what alias it's -going- to have for things
2589       # to work sanely (e.g. RestrictWithObject wants to be able to add
2590       # extra query restrictions, and these may need to be $alias.)
2591
2592       my $attrs = $rel_source->resultset_attributes;
2593       local $attrs->{alias} = $alias;
2594
2595       $rel_source->resultset
2596                  ->search_rs(
2597                      undef, {
2598                        %attrs,
2599                        join => undef,
2600                        prefetch => undef,
2601                        select => undef,
2602                        as => undef,
2603                        where => $self->{cond},
2604                        seen_join => $seen,
2605                        from => $from,
2606                    });
2607     };
2608     $new->set_cache($new_cache) if $new_cache;
2609     $new;
2610   };
2611 }
2612
2613 =head2 current_source_alias
2614
2615 =over 4
2616
2617 =item Arguments: none
2618
2619 =item Return Value: $source_alias
2620
2621 =back
2622
2623 Returns the current table alias for the result source this resultset is built
2624 on, that will be used in the SQL query. Usually it is C<me>.
2625
2626 Currently the source alias that refers to the result set returned by a
2627 L</search>/L</find> family method depends on how you got to the resultset: it's
2628 C<me> by default, but eg. L</search_related> aliases it to the related result
2629 source name (and keeps C<me> referring to the original result set). The long
2630 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2631 (and make this method unnecessary).
2632
2633 Thus it's currently necessary to use this method in predefined queries (see
2634 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2635 source alias of the current result set:
2636
2637   # in a result set class
2638   sub modified_by {
2639     my ($self, $user) = @_;
2640
2641     my $me = $self->current_source_alias;
2642
2643     return $self->search(
2644       "$me.modified" => $user->id,
2645     );
2646   }
2647
2648 =cut
2649
2650 sub current_source_alias {
2651   my ($self) = @_;
2652
2653   return ($self->{attrs} || {})->{alias} || 'me';
2654 }
2655
2656 # This code is called by search_related, and makes sure there
2657 # is clear separation between the joins before, during, and
2658 # after the relationship. This information is needed later
2659 # in order to properly resolve prefetch aliases (any alias
2660 # with a relation_chain_depth less than the depth of the
2661 # current prefetch is not considered)
2662 #
2663 # The increments happen in 1/2s to make it easier to correlate the
2664 # join depth with the join path. An integer means a relationship
2665 # specified via a search_related, whereas a fraction means an added
2666 # join/prefetch via attributes
2667 sub _chain_relationship {
2668   my ($self, $rel) = @_;
2669   my $source = $self->result_source;
2670   my $attrs = $self->{attrs};
2671
2672   my $from = [ @{
2673       $attrs->{from}
2674         ||
2675       [{
2676         -source_handle => $source->handle,
2677         -alias => $attrs->{alias},
2678         $attrs->{alias} => $source->from,
2679       }]
2680   }];
2681
2682   my $seen = { %{$attrs->{seen_join} || {} } };
2683   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2684     ? $from->[-1][0]{-join_path}
2685     : [];
2686
2687
2688   # we need to take the prefetch the attrs into account before we
2689   # ->_resolve_join as otherwise they get lost - captainL
2690   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2691
2692   my @requested_joins = $source->_resolve_join(
2693     $merged,
2694     $attrs->{alias},
2695     $seen,
2696     $jpath,
2697   );
2698
2699   push @$from, @requested_joins;
2700
2701   $seen->{-relation_chain_depth} += 0.5;
2702
2703   # if $self already had a join/prefetch specified on it, the requested
2704   # $rel might very well be already included. What we do in this case
2705   # is effectively a no-op (except that we bump up the chain_depth on
2706   # the join in question so we could tell it *is* the search_related)
2707   my $already_joined;
2708
2709
2710   # we consider the last one thus reverse
2711   for my $j (reverse @requested_joins) {
2712     if ($rel eq $j->[0]{-join_path}[-1]) {
2713       $j->[0]{-relation_chain_depth} += 0.5;
2714       $already_joined++;
2715       last;
2716     }
2717   }
2718
2719 # alternative way to scan the entire chain - not backwards compatible
2720 #  for my $j (reverse @$from) {
2721 #    next unless ref $j eq 'ARRAY';
2722 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2723 #      $j->[0]{-relation_chain_depth} += 0.5;
2724 #      $already_joined++;
2725 #      last;
2726 #    }
2727 #  }
2728
2729   unless ($already_joined) {
2730     push @$from, $source->_resolve_join(
2731       $rel,
2732       $attrs->{alias},
2733       $seen,
2734       $jpath,
2735     );
2736   }
2737
2738   $seen->{-relation_chain_depth} += 0.5;
2739
2740   return ($from,$seen);
2741 }
2742
2743 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2744 sub _resolved_attrs_copy {
2745   my $self = shift;
2746   return { %{$self->_resolved_attrs (@_)} };
2747 }
2748
2749 sub _resolved_attrs {
2750   my $self = shift;
2751   return $self->{_attrs} if $self->{_attrs};
2752
2753   my $attrs  = { %{ $self->{attrs} || {} } };
2754   my $source = $self->result_source;
2755   my $alias  = $attrs->{alias};
2756
2757   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2758   my @colbits;
2759
2760   # build columns (as long as select isn't set) into a set of as/select hashes
2761   unless ( $attrs->{select} ) {
2762
2763     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2764       ? @{ delete $attrs->{columns}}
2765       : (
2766           ( delete $attrs->{columns} )
2767             ||
2768           $source->columns
2769         )
2770     ;
2771
2772     @colbits = map {
2773       ( ref($_) eq 'HASH' )
2774       ? $_
2775       : {
2776           (
2777             /^\Q${alias}.\E(.+)$/
2778               ? "$1"
2779               : "$_"
2780           )
2781             =>
2782           (
2783             /\./
2784               ? "$_"
2785               : "${alias}.$_"
2786           )
2787         }
2788     } @cols;
2789   }
2790
2791   # add the additional columns on
2792   foreach ( 'include_columns', '+columns' ) {
2793       push @colbits, map {
2794           ( ref($_) eq 'HASH' )
2795             ? $_
2796             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2797       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2798   }
2799
2800   # start with initial select items
2801   if ( $attrs->{select} ) {
2802     $attrs->{select} =
2803         ( ref $attrs->{select} eq 'ARRAY' )
2804       ? [ @{ $attrs->{select} } ]
2805       : [ $attrs->{select} ];
2806     $attrs->{as} = (
2807       $attrs->{as}
2808       ? (
2809         ref $attrs->{as} eq 'ARRAY'
2810         ? [ @{ $attrs->{as} } ]
2811         : [ $attrs->{as} ]
2812         )
2813       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2814     );
2815   }
2816   else {
2817
2818     # otherwise we intialise select & as to empty
2819     $attrs->{select} = [];
2820     $attrs->{as}     = [];
2821   }
2822
2823   # now add colbits to select/as
2824   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2825   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2826
2827   my $adds;
2828   if ( $adds = delete $attrs->{'+select'} ) {
2829     $adds = [$adds] unless ref $adds eq 'ARRAY';
2830     push(
2831       @{ $attrs->{select} },
2832       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2833     );
2834   }
2835   if ( $adds = delete $attrs->{'+as'} ) {
2836     $adds = [$adds] unless ref $adds eq 'ARRAY';
2837     push( @{ $attrs->{as} }, @$adds );
2838   }
2839
2840   $attrs->{from} ||= [ {
2841     -source_handle => $source->handle,
2842     -alias => $self->{attrs}{alias},
2843     $self->{attrs}{alias} => $source->from,
2844   } ];
2845
2846   if ( $attrs->{join} || $attrs->{prefetch} ) {
2847
2848     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2849       if ref $attrs->{from} ne 'ARRAY';
2850
2851     my $join = delete $attrs->{join} || {};
2852
2853     if ( defined $attrs->{prefetch} ) {
2854       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2855     }
2856
2857     $attrs->{from} =    # have to copy here to avoid corrupting the original
2858       [
2859         @{ $attrs->{from} },
2860         $source->_resolve_join(
2861           $join,
2862           $alias,
2863           { %{ $attrs->{seen_join} || {} } },
2864           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2865             ? $attrs->{from}[-1][0]{-join_path}
2866             : []
2867           ,
2868         )
2869       ];
2870   }
2871
2872   if ( defined $attrs->{order_by} ) {
2873     $attrs->{order_by} = (
2874       ref( $attrs->{order_by} ) eq 'ARRAY'
2875       ? [ @{ $attrs->{order_by} } ]
2876       : [ $attrs->{order_by} || () ]
2877     );
2878   }
2879
2880   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2881     $attrs->{group_by} = [ $attrs->{group_by} ];
2882   }
2883
2884   # generate the distinct induced group_by early, as prefetch will be carried via a
2885   # subquery (since a group_by is present)
2886   if (delete $attrs->{distinct}) {
2887     if ($attrs->{group_by}) {
2888       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2889     }
2890     else {
2891       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2892     }
2893   }
2894
2895   $attrs->{collapse} ||= {};
2896   if ( my $prefetch = delete $attrs->{prefetch} ) {
2897     $prefetch = $self->_merge_attr( {}, $prefetch );
2898
2899     my $prefetch_ordering = [];
2900
2901     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2902
2903     my @prefetch =
2904       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2905
2906     # we need to somehow mark which columns came from prefetch
2907     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2908
2909     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2910     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2911
2912     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2913     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2914   }
2915
2916   # if both page and offset are specified, produce a combined offset
2917   # even though it doesn't make much sense, this is what pre 081xx has
2918   # been doing
2919   if (my $page = delete $attrs->{page}) {
2920     $attrs->{offset} =
2921       ($attrs->{rows} * ($page - 1))
2922             +
2923       ($attrs->{offset} || 0)
2924     ;
2925   }
2926
2927   return $self->{_attrs} = $attrs;
2928 }
2929
2930 sub _joinpath_aliases {
2931   my ($self, $fromspec, $seen) = @_;
2932
2933   my $paths = {};
2934   return $paths unless ref $fromspec eq 'ARRAY';
2935
2936   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2937
2938   if (int ($cur_depth) != $cur_depth) {
2939     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2940   }
2941
2942   for my $j (@$fromspec) {
2943
2944     next if ref $j ne 'ARRAY';
2945     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2946
2947     my $jpath = $j->[0]{-join_path};
2948
2949     my $p = $paths;
2950     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2951     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2952   }
2953
2954   return $paths;
2955 }
2956
2957 sub _rollout_attr {
2958   my ($self, $attr) = @_;
2959
2960   if (ref $attr eq 'HASH') {
2961     return $self->_rollout_hash($attr);
2962   } elsif (ref $attr eq 'ARRAY') {
2963     return $self->_rollout_array($attr);
2964   } else {
2965     return [$attr];
2966   }
2967 }
2968
2969 sub _rollout_array {
2970   my ($self, $attr) = @_;
2971
2972   my @rolled_array;
2973   foreach my $element (@{$attr}) {
2974     if (ref $element eq 'HASH') {
2975       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2976     } elsif (ref $element eq 'ARRAY') {
2977       #  XXX - should probably recurse here
2978       push( @rolled_array, @{$self->_rollout_array($element)} );
2979     } else {
2980       push( @rolled_array, $element );
2981     }
2982   }
2983   return \@rolled_array;
2984 }
2985
2986 sub _rollout_hash {
2987   my ($self, $attr) = @_;
2988
2989   my @rolled_array;
2990   foreach my $key (keys %{$attr}) {
2991     push( @rolled_array, { $key => $attr->{$key} } );
2992   }
2993   return \@rolled_array;
2994 }
2995
2996 sub _calculate_score {
2997   my ($self, $a, $b) = @_;
2998
2999   if (defined $a xor defined $b) {
3000     return 0;
3001   }
3002   elsif (not defined $a) {
3003     return 1;
3004   }
3005
3006   if (ref $b eq 'HASH') {
3007     my ($b_key) = keys %{$b};
3008     if (ref $a eq 'HASH') {
3009       my ($a_key) = keys %{$a};
3010       if ($a_key eq $b_key) {
3011         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3012       } else {
3013         return 0;
3014       }
3015     } else {
3016       return ($a eq $b_key) ? 1 : 0;
3017     }
3018   } else {
3019     if (ref $a eq 'HASH') {
3020       my ($a_key) = keys %{$a};
3021       return ($b eq $a_key) ? 1 : 0;
3022     } else {
3023       return ($b eq $a) ? 1 : 0;
3024     }
3025   }
3026 }
3027
3028 sub _merge_attr {
3029   my ($self, $orig, $import) = @_;
3030
3031   return $import unless defined($orig);
3032   return $orig unless defined($import);
3033
3034   $orig = $self->_rollout_attr($orig);
3035   $import = $self->_rollout_attr($import);
3036
3037   my $seen_keys;
3038   foreach my $import_element ( @{$import} ) {
3039     # find best candidate from $orig to merge $b_element into
3040     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3041     foreach my $orig_element ( @{$orig} ) {
3042       my $score = $self->_calculate_score( $orig_element, $import_element );
3043       if ($score > $best_candidate->{score}) {
3044         $best_candidate->{position} = $position;
3045         $best_candidate->{score} = $score;
3046       }
3047       $position++;
3048     }
3049     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3050
3051     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3052       push( @{$orig}, $import_element );
3053     } else {
3054       my $orig_best = $orig->[$best_candidate->{position}];
3055       # merge orig_best and b_element together and replace original with merged
3056       if (ref $orig_best ne 'HASH') {
3057         $orig->[$best_candidate->{position}] = $import_element;
3058       } elsif (ref $import_element eq 'HASH') {
3059         my ($key) = keys %{$orig_best};
3060         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3061       }
3062     }
3063     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3064   }
3065
3066   return $orig;
3067 }
3068
3069 sub result_source {
3070     my $self = shift;
3071
3072     if (@_) {
3073         $self->_source_handle($_[0]->handle);
3074     } else {
3075         $self->_source_handle->resolve;
3076     }
3077 }
3078
3079 =head2 throw_exception
3080
3081 See L<DBIx::Class::Schema/throw_exception> for details.
3082
3083 =cut
3084
3085 sub throw_exception {
3086   my $self=shift;
3087
3088   if (ref $self && $self->_source_handle->schema) {
3089     $self->_source_handle->schema->throw_exception(@_)
3090   }
3091   else {
3092     DBIx::Class::Exception->throw(@_);
3093   }
3094 }
3095
3096 # XXX: FIXME: Attributes docs need clearing up
3097
3098 =head1 ATTRIBUTES
3099
3100 Attributes are used to refine a ResultSet in various ways when
3101 searching for data. They can be passed to any method which takes an
3102 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3103 L</count>.
3104
3105 These are in no particular order:
3106
3107 =head2 order_by
3108
3109 =over 4
3110
3111 =item Value: ( $order_by | \@order_by | \%order_by )
3112
3113 =back
3114
3115 Which column(s) to order the results by.
3116
3117 [The full list of suitable values is documented in
3118 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3119 common options.]
3120
3121 If a single column name, or an arrayref of names is supplied, the
3122 argument is passed through directly to SQL. The hashref syntax allows
3123 for connection-agnostic specification of ordering direction:
3124
3125  For descending order:
3126
3127   order_by => { -desc => [qw/col1 col2 col3/] }
3128
3129  For explicit ascending order:
3130
3131   order_by => { -asc => 'col' }
3132
3133 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3134 supported, although you are strongly encouraged to use the hashref
3135 syntax as outlined above.
3136
3137 =head2 columns
3138
3139 =over 4
3140
3141 =item Value: \@columns
3142
3143 =back
3144
3145 Shortcut to request a particular set of columns to be retrieved. Each
3146 column spec may be a string (a table column name), or a hash (in which
3147 case the key is the C<as> value, and the value is used as the C<select>
3148 expression). Adds C<me.> onto the start of any column without a C<.> in
3149 it and sets C<select> from that, then auto-populates C<as> from
3150 C<select> as normal. (You may also use the C<cols> attribute, as in
3151 earlier versions of DBIC.)
3152
3153 =head2 +columns
3154
3155 =over 4
3156
3157 =item Value: \@columns
3158
3159 =back
3160
3161 Indicates additional columns to be selected from storage. Works the same
3162 as L</columns> but adds columns to the selection. (You may also use the
3163 C<include_columns> attribute, as in earlier versions of DBIC). For
3164 example:-
3165
3166   $schema->resultset('CD')->search(undef, {
3167     '+columns' => ['artist.name'],
3168     join => ['artist']
3169   });
3170
3171 would return all CDs and include a 'name' column to the information
3172 passed to object inflation. Note that the 'artist' is the name of the
3173 column (or relationship) accessor, and 'name' is the name of the column
3174 accessor in the related table.
3175
3176 =head2 include_columns
3177
3178 =over 4
3179
3180 =item Value: \@columns
3181
3182 =back
3183
3184 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3185
3186 =head2 select
3187
3188 =over 4
3189
3190 =item Value: \@select_columns
3191
3192 =back
3193
3194 Indicates which columns should be selected from the storage. You can use
3195 column names, or in the case of RDBMS back ends, function or stored procedure
3196 names:
3197
3198   $rs = $schema->resultset('Employee')->search(undef, {
3199     select => [
3200       'name',
3201       { count => 'employeeid' },
3202       { sum => 'salary' }
3203     ]
3204   });
3205
3206 When you use function/stored procedure names and do not supply an C<as>
3207 attribute, the column names returned are storage-dependent. E.g. MySQL would
3208 return a column named C<count(employeeid)> in the above example.
3209
3210 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3211 'select'.
3212
3213 =head2 +select
3214
3215 =over 4
3216
3217 Indicates additional columns to be selected from storage.  Works the same as
3218 L</select> but adds columns to the selection.
3219
3220 =back
3221
3222 =head2 +as
3223
3224 =over 4
3225
3226 Indicates additional column names for those added via L</+select>. See L</as>.
3227
3228 =back
3229
3230 =head2 as
3231
3232 =over 4
3233
3234 =item Value: \@inflation_names
3235
3236 =back
3237
3238 Indicates column names for object inflation. That is, C<as>
3239 indicates the name that the column can be accessed as via the
3240 C<get_column> method (or via the object accessor, B<if one already
3241 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3242
3243 The C<as> attribute is used in conjunction with C<select>,
3244 usually when C<select> contains one or more function or stored
3245 procedure names:
3246
3247   $rs = $schema->resultset('Employee')->search(undef, {
3248     select => [
3249       'name',
3250       { count => 'employeeid' }
3251     ],
3252     as => ['name', 'employee_count'],
3253   });
3254
3255   my $employee = $rs->first(); # get the first Employee
3256
3257 If the object against which the search is performed already has an accessor
3258 matching a column name specified in C<as>, the value can be retrieved using
3259 the accessor as normal:
3260
3261   my $name = $employee->name();
3262
3263 If on the other hand an accessor does not exist in the object, you need to
3264 use C<get_column> instead:
3265
3266   my $employee_count = $employee->get_column('employee_count');
3267
3268 You can create your own accessors if required - see
3269 L<DBIx::Class::Manual::Cookbook> for details.
3270
3271 Please note: This will NOT insert an C<AS employee_count> into the SQL
3272 statement produced, it is used for internal access only. Thus
3273 attempting to use the accessor in an C<order_by> clause or similar
3274 will fail miserably.
3275
3276 To get around this limitation, you can supply literal SQL to your
3277 C<select> attibute that contains the C<AS alias> text, eg:
3278
3279   select => [\'myfield AS alias']
3280
3281 =head2 join
3282
3283 =over 4
3284
3285 =item Value: ($rel_name | \@rel_names | \%rel_names)
3286
3287 =back
3288
3289 Contains a list of relationships that should be joined for this query.  For
3290 example:
3291
3292   # Get CDs by Nine Inch Nails
3293   my $rs = $schema->resultset('CD')->search(
3294     { 'artist.name' => 'Nine Inch Nails' },
3295     { join => 'artist' }
3296   );
3297
3298 Can also contain a hash reference to refer to the other relation's relations.
3299 For example:
3300
3301   package MyApp::Schema::Track;
3302   use base qw/DBIx::Class/;
3303   __PACKAGE__->table('track');
3304   __PACKAGE__->add_columns(qw/trackid cd position title/);
3305   __PACKAGE__->set_primary_key('trackid');
3306   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3307   1;
3308
3309   # In your application
3310   my $rs = $schema->resultset('Artist')->search(
3311     { 'track.title' => 'Teardrop' },
3312     {
3313       join     => { cd => 'track' },
3314       order_by => 'artist.name',
3315     }
3316   );
3317
3318 You need to use the relationship (not the table) name in  conditions,
3319 because they are aliased as such. The current table is aliased as "me", so
3320 you need to use me.column_name in order to avoid ambiguity. For example:
3321
3322   # Get CDs from 1984 with a 'Foo' track
3323   my $rs = $schema->resultset('CD')->search(
3324     {
3325       'me.year' => 1984,
3326       'tracks.name' => 'Foo'
3327     },
3328     { join => 'tracks' }
3329   );
3330
3331 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3332 similarly for a third time). For e.g.
3333
3334   my $rs = $schema->resultset('Artist')->search({
3335     'cds.title'   => 'Down to Earth',
3336     'cds_2.title' => 'Popular',
3337   }, {
3338     join => [ qw/cds cds/ ],
3339   });
3340
3341 will return a set of all artists that have both a cd with title 'Down
3342 to Earth' and a cd with title 'Popular'.
3343
3344 If you want to fetch related objects from other tables as well, see C<prefetch>
3345 below.
3346
3347 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3348
3349 =head2 prefetch
3350
3351 =over 4
3352
3353 =item Value: ($rel_name | \@rel_names | \%rel_names)
3354
3355 =back
3356
3357 Contains one or more relationships that should be fetched along with
3358 the main query (when they are accessed afterwards the data will
3359 already be available, without extra queries to the database).  This is
3360 useful for when you know you will need the related objects, because it
3361 saves at least one query:
3362
3363   my $rs = $schema->resultset('Tag')->search(
3364     undef,
3365     {
3366       prefetch => {
3367         cd => 'artist'
3368       }
3369     }
3370   );
3371
3372 The initial search results in SQL like the following:
3373
3374   SELECT tag.*, cd.*, artist.* FROM tag
3375   JOIN cd ON tag.cd = cd.cdid
3376   JOIN artist ON cd.artist = artist.artistid
3377
3378 L<DBIx::Class> has no need to go back to the database when we access the
3379 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3380 case.
3381
3382 Simple prefetches will be joined automatically, so there is no need
3383 for a C<join> attribute in the above search.
3384
3385 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3386 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3387 with an accessor type of 'single' or 'filter'). A more complex example that
3388 prefetches an artists cds, the tracks on those cds, and the tags associted
3389 with that artist is given below (assuming many-to-many from artists to tags):
3390
3391  my $rs = $schema->resultset('Artist')->search(
3392    undef,
3393    {
3394      prefetch => [
3395        { cds => 'tracks' },
3396        { artist_tags => 'tags' }
3397      ]
3398    }
3399  );
3400
3401
3402 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3403 attributes will be ignored.
3404
3405 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3406 exactly as you might expect.
3407
3408 =over 4
3409
3410 =item *
3411
3412 Prefetch uses the L</cache> to populate the prefetched relationships. This
3413 may or may not be what you want.
3414
3415 =item *
3416
3417 If you specify a condition on a prefetched relationship, ONLY those
3418 rows that match the prefetched condition will be fetched into that relationship.
3419 This means that adding prefetch to a search() B<may alter> what is returned by
3420 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3421
3422   my $artist_rs = $schema->resultset('Artist')->search({
3423       'cds.year' => 2008,
3424   }, {
3425       join => 'cds',
3426   });
3427
3428   my $count = $artist_rs->first->cds->count;
3429
3430   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3431
3432   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3433
3434   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3435
3436 that cmp_ok() may or may not pass depending on the datasets involved. This
3437 behavior may or may not survive the 0.09 transition.
3438
3439 =back
3440
3441 =head2 page
3442
3443 =over 4
3444
3445 =item Value: $page
3446
3447 =back
3448
3449 Makes the resultset paged and specifies the page to retrieve. Effectively
3450 identical to creating a non-pages resultset and then calling ->page($page)
3451 on it.
3452
3453 If L<rows> attribute is not specified it defaults to 10 rows per page.
3454
3455 When you have a paged resultset, L</count> will only return the number
3456 of rows in the page. To get the total, use the L</pager> and call
3457 C<total_entries> on it.
3458
3459 =head2 rows
3460
3461 =over 4
3462
3463 =item Value: $rows
3464
3465 =back
3466
3467 Specifes the maximum number of rows for direct retrieval or the number of
3468 rows per page if the page attribute or method is used.
3469
3470 =head2 offset
3471
3472 =over 4
3473
3474 =item Value: $offset
3475
3476 =back
3477
3478 Specifies the (zero-based) row number for the  first row to be returned, or the
3479 of the first row of the first page if paging is used.
3480
3481 =head2 group_by
3482
3483 =over 4
3484
3485 =item Value: \@columns
3486
3487 =back
3488
3489 A arrayref of columns to group by. Can include columns of joined tables.
3490
3491   group_by => [qw/ column1 column2 ... /]
3492
3493 =head2 having
3494
3495 =over 4
3496
3497 =item Value: $condition
3498
3499 =back
3500
3501 HAVING is a select statement attribute that is applied between GROUP BY and
3502 ORDER BY. It is applied to the after the grouping calculations have been
3503 done.
3504
3505   having => { 'count(employee)' => { '>=', 100 } }
3506
3507 =head2 distinct
3508
3509 =over 4
3510
3511 =item Value: (0 | 1)
3512
3513 =back
3514
3515 Set to 1 to group by all columns. If the resultset already has a group_by
3516 attribute, this setting is ignored and an appropriate warning is issued.
3517
3518 =head2 where
3519
3520 =over 4
3521
3522 Adds to the WHERE clause.
3523
3524   # only return rows WHERE deleted IS NULL for all searches
3525   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3526
3527 Can be overridden by passing C<< { where => undef } >> as an attribute
3528 to a resultset.
3529
3530 =back
3531
3532 =head2 cache
3533
3534 Set to 1 to cache search results. This prevents extra SQL queries if you
3535 revisit rows in your ResultSet:
3536
3537   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3538
3539   while( my $artist = $resultset->next ) {
3540     ... do stuff ...
3541   }
3542
3543   $rs->first; # without cache, this would issue a query
3544
3545 By default, searches are not cached.
3546
3547 For more examples of using these attributes, see
3548 L<DBIx::Class::Manual::Cookbook>.
3549
3550 =head2 for
3551
3552 =over 4
3553
3554 =item Value: ( 'update' | 'shared' )
3555
3556 =back
3557
3558 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3559 ... FOR SHARED.
3560
3561 =cut
3562
3563 1;