lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->_resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 my @count_via_subq_attrs = qw/join seen_join prefetch group_by having/;
1154 sub count {
1155   my $self = shift;
1156   return $self->search(@_)->count if @_ and defined $_[0];
1157   return scalar @{ $self->get_cache } if $self->get_cache;
1158
1159   my @check_attrs = @count_via_subq_attrs;
1160
1161   # if we are not paged - we are simply asking for a limit
1162   if (not $self->{attrs}{page} and not $self->{attrs}{software_limit}) {
1163     push @check_attrs, qw/rows offset/;
1164   }
1165
1166   return $self->_has_attr (@check_attrs)
1167     ? $self->_count_subq
1168     : $self->_count_simple
1169 }
1170
1171 sub _count_subq {
1172   my $self = shift;
1173
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   # copy for the subquery, we need to do some adjustments to it too
1177   my $sub_attrs = { %$attrs };
1178
1179   # these can not go in the subquery either
1180   delete $sub_attrs->{$_} for qw/prefetch select +select as +as columns +columns/;
1181
1182   # force a group_by and the same set of columns (most databases require this)
1183   $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1184
1185   $attrs->{from} = [{
1186     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1187   }];
1188
1189   # the subquery replaces this
1190   delete $attrs->{where};
1191
1192   return $self->__count ($attrs);
1193 }
1194
1195 sub _count_simple {
1196   my $self = shift;
1197
1198   my $count = $self->__count;
1199   return 0 unless $count;
1200
1201   # need to take offset from resolved attrs
1202
1203   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1204   $count = $self->{attrs}{rows} if
1205     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1206   $count = 0 if ($count < 0);
1207   return $count;
1208 }
1209
1210 sub __count {
1211   my ($self, $attrs) = @_;
1212
1213   $attrs ||= { %{$self->{attrs}} };
1214
1215   # these are the only attributes that actually matter for count
1216   $attrs = { map { exists $attrs->{$_} ? ( $_ => $attrs->{$_} ) : () } qw/where bind alias from from_bind/ };
1217
1218   $attrs->{select} = { count => '*' };
1219   $attrs->{as} = [qw/count/];
1220
1221   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1222   my ($count) = $tmp_rs->cursor->next;
1223
1224   return $count;
1225 }
1226
1227 sub _bool {
1228   return 1;
1229 }
1230
1231 =head2 count_literal
1232
1233 =over 4
1234
1235 =item Arguments: $sql_fragment, @bind_values
1236
1237 =item Return Value: $count
1238
1239 =back
1240
1241 Counts the results in a literal query. Equivalent to calling L</search_literal>
1242 with the passed arguments, then L</count>.
1243
1244 =cut
1245
1246 sub count_literal { shift->search_literal(@_)->count; }
1247
1248 =head2 all
1249
1250 =over 4
1251
1252 =item Arguments: none
1253
1254 =item Return Value: @objects
1255
1256 =back
1257
1258 Returns all elements in the resultset. Called implicitly if the resultset
1259 is returned in list context.
1260
1261 =cut
1262
1263 sub all {
1264   my $self = shift;
1265   if(@_) {
1266       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1267   }
1268
1269   return @{ $self->get_cache } if $self->get_cache;
1270
1271   my @obj;
1272
1273   # TODO: don't call resolve here
1274   if (keys %{$self->_resolved_attrs->{collapse}}) {
1275 #  if ($self->{attrs}{prefetch}) {
1276       # Using $self->cursor->all is really just an optimisation.
1277       # If we're collapsing has_many prefetches it probably makes
1278       # very little difference, and this is cleaner than hacking
1279       # _construct_object to survive the approach
1280     my @row = $self->cursor->next;
1281     while (@row) {
1282       push(@obj, $self->_construct_object(@row));
1283       @row = (exists $self->{stashed_row}
1284                ? @{delete $self->{stashed_row}}
1285                : $self->cursor->next);
1286     }
1287   } else {
1288     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1289   }
1290
1291   $self->set_cache(\@obj) if $self->{attrs}{cache};
1292   return @obj;
1293 }
1294
1295 =head2 reset
1296
1297 =over 4
1298
1299 =item Arguments: none
1300
1301 =item Return Value: $self
1302
1303 =back
1304
1305 Resets the resultset's cursor, so you can iterate through the elements again.
1306
1307 =cut
1308
1309 sub reset {
1310   my ($self) = @_;
1311   delete $self->{_attrs} if exists $self->{_attrs};
1312   $self->{all_cache_position} = 0;
1313   $self->cursor->reset;
1314   return $self;
1315 }
1316
1317 =head2 first
1318
1319 =over 4
1320
1321 =item Arguments: none
1322
1323 =item Return Value: $object?
1324
1325 =back
1326
1327 Resets the resultset and returns an object for the first result (if the
1328 resultset returns anything).
1329
1330 =cut
1331
1332 sub first {
1333   return $_[0]->reset->next;
1334 }
1335
1336
1337 # _update_delete_via_subq
1338 #
1339 # Presence of some rs attributes requires a subquery to reliably
1340 # update/deletre
1341 #
1342
1343 sub _update_delete_via_subq {
1344   return $_[0]->_has_attr (qw/join seen_join group_by row offset page/);
1345 }
1346
1347
1348 # _cond_for_update_delete
1349 #
1350 # update/delete require the condition to be modified to handle
1351 # the differing SQL syntax available.  This transforms the $self->{cond}
1352 # appropriately, returning the new condition.
1353
1354 sub _cond_for_update_delete {
1355   my ($self, $full_cond) = @_;
1356   my $cond = {};
1357
1358   $full_cond ||= $self->{cond};
1359   # No-op. No condition, we're updating/deleting everything
1360   return $cond unless ref $full_cond;
1361
1362   if (ref $full_cond eq 'ARRAY') {
1363     $cond = [
1364       map {
1365         my %hash;
1366         foreach my $key (keys %{$_}) {
1367           $key =~ /([^.]+)$/;
1368           $hash{$1} = $_->{$key};
1369         }
1370         \%hash;
1371       } @{$full_cond}
1372     ];
1373   }
1374   elsif (ref $full_cond eq 'HASH') {
1375     if ((keys %{$full_cond})[0] eq '-and') {
1376       $cond->{-and} = [];
1377       my @cond = @{$full_cond->{-and}};
1378        for (my $i = 0; $i < @cond; $i++) {
1379         my $entry = $cond[$i];
1380         my $hash;
1381         if (ref $entry eq 'HASH') {
1382           $hash = $self->_cond_for_update_delete($entry);
1383         }
1384         else {
1385           $entry =~ /([^.]+)$/;
1386           $hash->{$1} = $cond[++$i];
1387         }
1388         push @{$cond->{-and}}, $hash;
1389       }
1390     }
1391     else {
1392       foreach my $key (keys %{$full_cond}) {
1393         $key =~ /([^.]+)$/;
1394         $cond->{$1} = $full_cond->{$key};
1395       }
1396     }
1397   }
1398   else {
1399     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1400   }
1401
1402   return $cond;
1403 }
1404
1405
1406 =head2 update
1407
1408 =over 4
1409
1410 =item Arguments: \%values
1411
1412 =item Return Value: $storage_rv
1413
1414 =back
1415
1416 Sets the specified columns in the resultset to the supplied values in a
1417 single query. Return value will be true if the update succeeded or false
1418 if no records were updated; exact type of success value is storage-dependent.
1419
1420 =cut
1421
1422 sub update {
1423   my ($self, $values) = @_;
1424   $self->throw_exception('Values for update must be a hash')
1425     unless ref $values eq 'HASH';
1426
1427   # rs operations with subqueries are Storage dependent - delegate
1428   if ($self->_update_delete_via_subq) {
1429     return $self->result_source->storage->subq_update_delete($self, 'update', $values);
1430   }
1431
1432   my $cond = $self->_cond_for_update_delete;
1433
1434   return $self->result_source->storage->update(
1435     $self->result_source, $values, $cond
1436   );
1437 }
1438
1439 =head2 update_all
1440
1441 =over 4
1442
1443 =item Arguments: \%values
1444
1445 =item Return Value: 1
1446
1447 =back
1448
1449 Fetches all objects and updates them one at a time. Note that C<update_all>
1450 will run DBIC cascade triggers, while L</update> will not.
1451
1452 =cut
1453
1454 sub update_all {
1455   my ($self, $values) = @_;
1456   $self->throw_exception('Values for update_all must be a hash')
1457     unless ref $values eq 'HASH';
1458   foreach my $obj ($self->all) {
1459     $obj->set_columns($values)->update;
1460   }
1461   return 1;
1462 }
1463
1464 =head2 delete
1465
1466 =over 4
1467
1468 =item Arguments: none
1469
1470 =item Return Value: 1
1471
1472 =back
1473
1474 Deletes the contents of the resultset from its result source. Note that this
1475 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1476 to run. See also L<DBIx::Class::Row/delete>.
1477
1478 delete may not generate correct SQL for a query with joins or a resultset
1479 chained from a related resultset.  In this case it will generate a warning:-
1480
1481 In these cases you may find that delete_all is more appropriate, or you
1482 need to respecify your query in a way that can be expressed without a join.
1483
1484 =cut
1485
1486 sub delete {
1487   my $self = shift;
1488   $self->throw_exception('delete does not accept any arguments')
1489     if @_;
1490
1491   # rs operations with subqueries are Storage dependent - delegate
1492   if ($self->_update_delete_via_subq) {
1493     return $self->result_source->storage->subq_update_delete($self, 'delete');
1494   }
1495
1496   my $cond = $self->_cond_for_update_delete;
1497
1498   $self->result_source->storage->delete($self->result_source, $cond);
1499   return 1;
1500 }
1501
1502 =head2 delete_all
1503
1504 =over 4
1505
1506 =item Arguments: none
1507
1508 =item Return Value: 1
1509
1510 =back
1511
1512 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1513 will run DBIC cascade triggers, while L</delete> will not.
1514
1515 =cut
1516
1517 sub delete_all {
1518   my $self = shift;
1519   $self->throw_exception('delete_all does not accept any arguments')
1520     if @_;
1521
1522   $_->delete for $self->all;
1523   return 1;
1524 }
1525
1526 =head2 populate
1527
1528 =over 4
1529
1530 =item Arguments: \@data;
1531
1532 =back
1533
1534 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1535 For the arrayref of hashrefs style each hashref should be a structure suitable
1536 forsubmitting to a $resultset->create(...) method.
1537
1538 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1539 to insert the data, as this is a faster method.
1540
1541 Otherwise, each set of data is inserted into the database using
1542 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1543 objects is returned.
1544
1545 Example:  Assuming an Artist Class that has many CDs Classes relating:
1546
1547   my $Artist_rs = $schema->resultset("Artist");
1548
1549   ## Void Context Example
1550   $Artist_rs->populate([
1551      { artistid => 4, name => 'Manufactured Crap', cds => [
1552         { title => 'My First CD', year => 2006 },
1553         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1554       ],
1555      },
1556      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1557         { title => 'My parents sold me to a record company' ,year => 2005 },
1558         { title => 'Why Am I So Ugly?', year => 2006 },
1559         { title => 'I Got Surgery and am now Popular', year => 2007 }
1560       ],
1561      },
1562   ]);
1563
1564   ## Array Context Example
1565   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1566     { name => "Artist One"},
1567     { name => "Artist Two"},
1568     { name => "Artist Three", cds=> [
1569     { title => "First CD", year => 2007},
1570     { title => "Second CD", year => 2008},
1571   ]}
1572   ]);
1573
1574   print $ArtistOne->name; ## response is 'Artist One'
1575   print $ArtistThree->cds->count ## reponse is '2'
1576
1577 For the arrayref of arrayrefs style,  the first element should be a list of the
1578 fieldsnames to which the remaining elements are rows being inserted.  For
1579 example:
1580
1581   $Arstist_rs->populate([
1582     [qw/artistid name/],
1583     [100, 'A Formally Unknown Singer'],
1584     [101, 'A singer that jumped the shark two albums ago'],
1585     [102, 'An actually cool singer.'],
1586   ]);
1587
1588 Please note an important effect on your data when choosing between void and
1589 wantarray context. Since void context goes straight to C<insert_bulk> in
1590 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1591 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1592 create primary keys for you, you will find that your PKs are empty.  In this
1593 case you will have to use the wantarray context in order to create those
1594 values.
1595
1596 =cut
1597
1598 sub populate {
1599   my $self = shift @_;
1600   my $data = ref $_[0][0] eq 'HASH'
1601     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1602     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1603
1604   if(defined wantarray) {
1605     my @created;
1606     foreach my $item (@$data) {
1607       push(@created, $self->create($item));
1608     }
1609     return @created;
1610   } else {
1611     my ($first, @rest) = @$data;
1612
1613     my @names = grep {!ref $first->{$_}} keys %$first;
1614     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1615     my @pks = $self->result_source->primary_columns;
1616
1617     ## do the belongs_to relationships
1618     foreach my $index (0..$#$data) {
1619       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1620         my @ret = $self->populate($data);
1621         return;
1622       }
1623
1624       foreach my $rel (@rels) {
1625         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1626         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1627         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1628         my $related = $result->result_source->_resolve_condition(
1629           $result->result_source->relationship_info($reverse)->{cond},
1630           $self,
1631           $result,
1632         );
1633
1634         delete $data->[$index]->{$rel};
1635         $data->[$index] = {%{$data->[$index]}, %$related};
1636
1637         push @names, keys %$related if $index == 0;
1638       }
1639     }
1640
1641     ## do bulk insert on current row
1642     my @values = map { [ @$_{@names} ] } @$data;
1643
1644     $self->result_source->storage->insert_bulk(
1645       $self->result_source,
1646       \@names,
1647       \@values,
1648     );
1649
1650     ## do the has_many relationships
1651     foreach my $item (@$data) {
1652
1653       foreach my $rel (@rels) {
1654         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1655
1656         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1657      || $self->throw_exception('Cannot find the relating object.');
1658
1659         my $child = $parent->$rel;
1660
1661         my $related = $child->result_source->_resolve_condition(
1662           $parent->result_source->relationship_info($rel)->{cond},
1663           $child,
1664           $parent,
1665         );
1666
1667         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1668         my @populate = map { {%$_, %$related} } @rows_to_add;
1669
1670         $child->populate( \@populate );
1671       }
1672     }
1673   }
1674 }
1675
1676 =head2 _normalize_populate_args ($args)
1677
1678 Private method used by L</populate> to normalize its incoming arguments.  Factored
1679 out in case you want to subclass and accept new argument structures to the
1680 L</populate> method.
1681
1682 =cut
1683
1684 sub _normalize_populate_args {
1685   my ($self, $data) = @_;
1686   my @names = @{shift(@$data)};
1687   my @results_to_create;
1688   foreach my $datum (@$data) {
1689     my %result_to_create;
1690     foreach my $index (0..$#names) {
1691       $result_to_create{$names[$index]} = $$datum[$index];
1692     }
1693     push @results_to_create, \%result_to_create;
1694   }
1695   return \@results_to_create;
1696 }
1697
1698 =head2 pager
1699
1700 =over 4
1701
1702 =item Arguments: none
1703
1704 =item Return Value: $pager
1705
1706 =back
1707
1708 Return Value a L<Data::Page> object for the current resultset. Only makes
1709 sense for queries with a C<page> attribute.
1710
1711 To get the full count of entries for a paged resultset, call
1712 C<total_entries> on the L<Data::Page> object.
1713
1714 =cut
1715
1716 sub pager {
1717   my ($self) = @_;
1718
1719   return $self->{pager} if $self->{pager};
1720
1721   my $attrs = $self->{attrs};
1722   $self->throw_exception("Can't create pager for non-paged rs")
1723     unless $self->{attrs}{page};
1724   $attrs->{rows} ||= 10;
1725
1726   # throw away the paging flags and re-run the count (possibly
1727   # with a subselect) to get the real total count
1728   my $count_attrs = { %$attrs };
1729   delete $count_attrs->{$_} for qw/rows offset page pager/;
1730   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1731
1732   return $self->{pager} = Data::Page->new(
1733     $total_count,
1734     $attrs->{rows},
1735     $self->{attrs}{page}
1736   );
1737 }
1738
1739 =head2 page
1740
1741 =over 4
1742
1743 =item Arguments: $page_number
1744
1745 =item Return Value: $rs
1746
1747 =back
1748
1749 Returns a resultset for the $page_number page of the resultset on which page
1750 is called, where each page contains a number of rows equal to the 'rows'
1751 attribute set on the resultset (10 by default).
1752
1753 =cut
1754
1755 sub page {
1756   my ($self, $page) = @_;
1757   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1758 }
1759
1760 =head2 new_result
1761
1762 =over 4
1763
1764 =item Arguments: \%vals
1765
1766 =item Return Value: $rowobject
1767
1768 =back
1769
1770 Creates a new row object in the resultset's result class and returns
1771 it. The row is not inserted into the database at this point, call
1772 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1773 will tell you whether the row object has been inserted or not.
1774
1775 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1776
1777 =cut
1778
1779 sub new_result {
1780   my ($self, $values) = @_;
1781   $self->throw_exception( "new_result needs a hash" )
1782     unless (ref $values eq 'HASH');
1783
1784   my %new;
1785   my $alias = $self->{attrs}{alias};
1786
1787   if (
1788     defined $self->{cond}
1789     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1790   ) {
1791     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1792     $new{-from_resultset} = [ keys %new ] if keys %new;
1793   } else {
1794     $self->throw_exception(
1795       "Can't abstract implicit construct, condition not a hash"
1796     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1797
1798     my $collapsed_cond = (
1799       $self->{cond}
1800         ? $self->_collapse_cond($self->{cond})
1801         : {}
1802     );
1803
1804     # precendence must be given to passed values over values inherited from
1805     # the cond, so the order here is important.
1806     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1807     while( my($col,$value) = each %implied ){
1808       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1809         $new{$col} = $value->{'='};
1810         next;
1811       }
1812       $new{$col} = $value if $self->_is_deterministic_value($value);
1813     }
1814   }
1815
1816   %new = (
1817     %new,
1818     %{ $self->_remove_alias($values, $alias) },
1819     -source_handle => $self->_source_handle,
1820     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1821   );
1822
1823   return $self->result_class->new(\%new);
1824 }
1825
1826 # _is_deterministic_value
1827 #
1828 # Make an effor to strip non-deterministic values from the condition,
1829 # to make sure new_result chokes less
1830
1831 sub _is_deterministic_value {
1832   my $self = shift;
1833   my $value = shift;
1834   my $ref_type = ref $value;
1835   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1836   return 1 if Scalar::Util::blessed($value);
1837   return 0;
1838 }
1839
1840 # _has_attr
1841 #
1842 # determines if the resultset defines at least one
1843 # of the attributes supplied
1844 #
1845 # used to determine if a subquery is neccessary
1846
1847 sub _has_attr {
1848   my ($self, @attr_names) = @_;
1849
1850   my $attrs = $self->_resolved_attrs;
1851
1852   my $join_check_req;
1853
1854   for my $n (@attr_names) {
1855     return 1 if defined $attrs->{$n};
1856     ++$join_check_req if $n =~ /join/;
1857   }
1858
1859   # a join can be expressed as a multi-level from
1860   return 1 if (
1861     $join_check_req
1862       and
1863     ref $attrs->{from} eq 'ARRAY'
1864       and
1865     @{$attrs->{from}} > 1
1866   );
1867
1868   return 0;
1869 }
1870
1871 # _collapse_cond
1872 #
1873 # Recursively collapse the condition.
1874
1875 sub _collapse_cond {
1876   my ($self, $cond, $collapsed) = @_;
1877
1878   $collapsed ||= {};
1879
1880   if (ref $cond eq 'ARRAY') {
1881     foreach my $subcond (@$cond) {
1882       next unless ref $subcond;  # -or
1883       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1884     }
1885   }
1886   elsif (ref $cond eq 'HASH') {
1887     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1888       foreach my $subcond (@{$cond->{-and}}) {
1889         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1890       }
1891     }
1892     else {
1893       foreach my $col (keys %$cond) {
1894         my $value = $cond->{$col};
1895         $collapsed->{$col} = $value;
1896       }
1897     }
1898   }
1899
1900   return $collapsed;
1901 }
1902
1903 # _remove_alias
1904 #
1905 # Remove the specified alias from the specified query hash. A copy is made so
1906 # the original query is not modified.
1907
1908 sub _remove_alias {
1909   my ($self, $query, $alias) = @_;
1910
1911   my %orig = %{ $query || {} };
1912   my %unaliased;
1913
1914   foreach my $key (keys %orig) {
1915     if ($key !~ /\./) {
1916       $unaliased{$key} = $orig{$key};
1917       next;
1918     }
1919     $unaliased{$1} = $orig{$key}
1920       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1921   }
1922
1923   return \%unaliased;
1924 }
1925
1926 =head2 as_query (EXPERIMENTAL)
1927
1928 =over 4
1929
1930 =item Arguments: none
1931
1932 =item Return Value: \[ $sql, @bind ]
1933
1934 =back
1935
1936 Returns the SQL query and bind vars associated with the invocant.
1937
1938 This is generally used as the RHS for a subquery.
1939
1940 B<NOTE>: This feature is still experimental.
1941
1942 =cut
1943
1944 sub as_query { return shift->cursor->as_query(@_) }
1945
1946 =head2 find_or_new
1947
1948 =over 4
1949
1950 =item Arguments: \%vals, \%attrs?
1951
1952 =item Return Value: $rowobject
1953
1954 =back
1955
1956   my $artist = $schema->resultset('Artist')->find_or_new(
1957     { artist => 'fred' }, { key => 'artists' });
1958
1959   $cd->cd_to_producer->find_or_new({ producer => $producer },
1960                                    { key => 'primary });
1961
1962 Find an existing record from this resultset, based on its primary
1963 key, or a unique constraint. If none exists, instantiate a new result
1964 object and return it. The object will not be saved into your storage
1965 until you call L<DBIx::Class::Row/insert> on it.
1966
1967 You most likely want this method when looking for existing rows using
1968 a unique constraint that is not the primary key, or looking for
1969 related rows.
1970
1971 If you want objects to be saved immediately, use L</find_or_create> instead.
1972
1973 B<Note>: C<find_or_new> is probably not what you want when creating a
1974 new row in a table that uses primary keys supplied by the
1975 database. Passing in a primary key column with a value of I<undef>
1976 will cause L</find> to attempt to search for a row with a value of
1977 I<NULL>.
1978
1979 =cut
1980
1981 sub find_or_new {
1982   my $self     = shift;
1983   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1984   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1985   my $exists   = $self->find($hash, $attrs);
1986   return defined $exists ? $exists : $self->new_result($hash);
1987 }
1988
1989 =head2 create
1990
1991 =over 4
1992
1993 =item Arguments: \%vals
1994
1995 =item Return Value: a L<DBIx::Class::Row> $object
1996
1997 =back
1998
1999 Attempt to create a single new row or a row with multiple related rows
2000 in the table represented by the resultset (and related tables). This
2001 will not check for duplicate rows before inserting, use
2002 L</find_or_create> to do that.
2003
2004 To create one row for this resultset, pass a hashref of key/value
2005 pairs representing the columns of the table and the values you wish to
2006 store. If the appropriate relationships are set up, foreign key fields
2007 can also be passed an object representing the foreign row, and the
2008 value will be set to its primary key.
2009
2010 To create related objects, pass a hashref for the value if the related
2011 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2012 and use the name of the relationship as the key. (NOT the name of the field,
2013 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2014 of hashrefs containing the data for each of the rows to create in the foreign
2015 tables, again using the relationship name as the key.
2016
2017 Instead of hashrefs of plain related data (key/value pairs), you may
2018 also pass new or inserted objects. New objects (not inserted yet, see
2019 L</new>), will be inserted into their appropriate tables.
2020
2021 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2022
2023 Example of creating a new row.
2024
2025   $person_rs->create({
2026     name=>"Some Person",
2027     email=>"somebody@someplace.com"
2028   });
2029
2030 Example of creating a new row and also creating rows in a related C<has_many>
2031 or C<has_one> resultset.  Note Arrayref.
2032
2033   $artist_rs->create(
2034      { artistid => 4, name => 'Manufactured Crap', cds => [
2035         { title => 'My First CD', year => 2006 },
2036         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2037       ],
2038      },
2039   );
2040
2041 Example of creating a new row and also creating a row in a related
2042 C<belongs_to>resultset. Note Hashref.
2043
2044   $cd_rs->create({
2045     title=>"Music for Silly Walks",
2046     year=>2000,
2047     artist => {
2048       name=>"Silly Musician",
2049     }
2050   });
2051
2052 =cut
2053
2054 sub create {
2055   my ($self, $attrs) = @_;
2056   $self->throw_exception( "create needs a hashref" )
2057     unless ref $attrs eq 'HASH';
2058   return $self->new_result($attrs)->insert;
2059 }
2060
2061 =head2 find_or_create
2062
2063 =over 4
2064
2065 =item Arguments: \%vals, \%attrs?
2066
2067 =item Return Value: $rowobject
2068
2069 =back
2070
2071   $cd->cd_to_producer->find_or_create({ producer => $producer },
2072                                       { key => 'primary });
2073
2074 Tries to find a record based on its primary key or unique constraints; if none
2075 is found, creates one and returns that instead.
2076
2077   my $cd = $schema->resultset('CD')->find_or_create({
2078     cdid   => 5,
2079     artist => 'Massive Attack',
2080     title  => 'Mezzanine',
2081     year   => 2005,
2082   });
2083
2084 Also takes an optional C<key> attribute, to search by a specific key or unique
2085 constraint. For example:
2086
2087   my $cd = $schema->resultset('CD')->find_or_create(
2088     {
2089       artist => 'Massive Attack',
2090       title  => 'Mezzanine',
2091     },
2092     { key => 'cd_artist_title' }
2093   );
2094
2095 B<Note>: Because find_or_create() reads from the database and then
2096 possibly inserts based on the result, this method is subject to a race
2097 condition. Another process could create a record in the table after
2098 the find has completed and before the create has started. To avoid
2099 this problem, use find_or_create() inside a transaction.
2100
2101 B<Note>: C<find_or_create> is probably not what you want when creating
2102 a new row in a table that uses primary keys supplied by the
2103 database. Passing in a primary key column with a value of I<undef>
2104 will cause L</find> to attempt to search for a row with a value of
2105 I<NULL>.
2106
2107 See also L</find> and L</update_or_create>. For information on how to declare
2108 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2109
2110 =cut
2111
2112 sub find_or_create {
2113   my $self     = shift;
2114   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2115   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2116   my $exists   = $self->find($hash, $attrs);
2117   return defined $exists ? $exists : $self->create($hash);
2118 }
2119
2120 =head2 update_or_create
2121
2122 =over 4
2123
2124 =item Arguments: \%col_values, { key => $unique_constraint }?
2125
2126 =item Return Value: $rowobject
2127
2128 =back
2129
2130   $resultset->update_or_create({ col => $val, ... });
2131
2132 First, searches for an existing row matching one of the unique constraints
2133 (including the primary key) on the source of this resultset. If a row is
2134 found, updates it with the other given column values. Otherwise, creates a new
2135 row.
2136
2137 Takes an optional C<key> attribute to search on a specific unique constraint.
2138 For example:
2139
2140   # In your application
2141   my $cd = $schema->resultset('CD')->update_or_create(
2142     {
2143       artist => 'Massive Attack',
2144       title  => 'Mezzanine',
2145       year   => 1998,
2146     },
2147     { key => 'cd_artist_title' }
2148   );
2149
2150   $cd->cd_to_producer->update_or_create({
2151     producer => $producer,
2152     name => 'harry',
2153   }, {
2154     key => 'primary,
2155   });
2156
2157
2158 If no C<key> is specified, it searches on all unique constraints defined on the
2159 source, including the primary key.
2160
2161 If the C<key> is specified as C<primary>, it searches only on the primary key.
2162
2163 See also L</find> and L</find_or_create>. For information on how to declare
2164 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2165
2166 B<Note>: C<update_or_create> is probably not what you want when
2167 looking for a row in a table that uses primary keys supplied by the
2168 database, unless you actually have a key value. Passing in a primary
2169 key column with a value of I<undef> will cause L</find> to attempt to
2170 search for a row with a value of I<NULL>.
2171
2172 =cut
2173
2174 sub update_or_create {
2175   my $self = shift;
2176   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2177   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2178
2179   my $row = $self->find($cond, $attrs);
2180   if (defined $row) {
2181     $row->update($cond);
2182     return $row;
2183   }
2184
2185   return $self->create($cond);
2186 }
2187
2188 =head2 update_or_new
2189
2190 =over 4
2191
2192 =item Arguments: \%col_values, { key => $unique_constraint }?
2193
2194 =item Return Value: $rowobject
2195
2196 =back
2197
2198   $resultset->update_or_new({ col => $val, ... });
2199
2200 First, searches for an existing row matching one of the unique constraints
2201 (including the primary key) on the source of this resultset. If a row is
2202 found, updates it with the other given column values. Otherwise, instantiate
2203 a new result object and return it. The object will not be saved into your storage
2204 until you call L<DBIx::Class::Row/insert> on it.
2205
2206 Takes an optional C<key> attribute to search on a specific unique constraint.
2207 For example:
2208
2209   # In your application
2210   my $cd = $schema->resultset('CD')->update_or_new(
2211     {
2212       artist => 'Massive Attack',
2213       title  => 'Mezzanine',
2214       year   => 1998,
2215     },
2216     { key => 'cd_artist_title' }
2217   );
2218
2219   if ($cd->in_storage) {
2220       # the cd was updated
2221   }
2222   else {
2223       # the cd is not yet in the database, let's insert it
2224       $cd->insert;
2225   }
2226
2227 See also L</find>, L</find_or_create> and L<find_or_new>.
2228
2229 =cut
2230
2231 sub update_or_new {
2232     my $self  = shift;
2233     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2234     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2235
2236     my $row = $self->find( $cond, $attrs );
2237     if ( defined $row ) {
2238         $row->update($cond);
2239         return $row;
2240     }
2241
2242     return $self->new_result($cond);
2243 }
2244
2245 =head2 get_cache
2246
2247 =over 4
2248
2249 =item Arguments: none
2250
2251 =item Return Value: \@cache_objects?
2252
2253 =back
2254
2255 Gets the contents of the cache for the resultset, if the cache is set.
2256
2257 The cache is populated either by using the L</prefetch> attribute to
2258 L</search> or by calling L</set_cache>.
2259
2260 =cut
2261
2262 sub get_cache {
2263   shift->{all_cache};
2264 }
2265
2266 =head2 set_cache
2267
2268 =over 4
2269
2270 =item Arguments: \@cache_objects
2271
2272 =item Return Value: \@cache_objects
2273
2274 =back
2275
2276 Sets the contents of the cache for the resultset. Expects an arrayref
2277 of objects of the same class as those produced by the resultset. Note that
2278 if the cache is set the resultset will return the cached objects rather
2279 than re-querying the database even if the cache attr is not set.
2280
2281 The contents of the cache can also be populated by using the
2282 L</prefetch> attribute to L</search>.
2283
2284 =cut
2285
2286 sub set_cache {
2287   my ( $self, $data ) = @_;
2288   $self->throw_exception("set_cache requires an arrayref")
2289       if defined($data) && (ref $data ne 'ARRAY');
2290   $self->{all_cache} = $data;
2291 }
2292
2293 =head2 clear_cache
2294
2295 =over 4
2296
2297 =item Arguments: none
2298
2299 =item Return Value: []
2300
2301 =back
2302
2303 Clears the cache for the resultset.
2304
2305 =cut
2306
2307 sub clear_cache {
2308   shift->set_cache(undef);
2309 }
2310
2311 =head2 related_resultset
2312
2313 =over 4
2314
2315 =item Arguments: $relationship_name
2316
2317 =item Return Value: $resultset
2318
2319 =back
2320
2321 Returns a related resultset for the supplied relationship name.
2322
2323   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2324
2325 =cut
2326
2327 sub related_resultset {
2328   my ($self, $rel) = @_;
2329
2330   $self->{related_resultsets} ||= {};
2331   return $self->{related_resultsets}{$rel} ||= do {
2332     my $rel_obj = $self->result_source->relationship_info($rel);
2333
2334     $self->throw_exception(
2335       "search_related: result source '" . $self->result_source->source_name .
2336         "' has no such relationship $rel")
2337       unless $rel_obj;
2338
2339     my ($from,$seen) = $self->_resolve_from($rel);
2340
2341     my $join_count = $seen->{$rel};
2342     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2343
2344     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2345     my %attrs = %{$self->{attrs}||{}};
2346     delete @attrs{qw(result_class alias)};
2347
2348     my $new_cache;
2349
2350     if (my $cache = $self->get_cache) {
2351       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2352         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2353                         @$cache ];
2354       }
2355     }
2356
2357     my $rel_source = $self->result_source->related_source($rel);
2358
2359     my $new = do {
2360
2361       # The reason we do this now instead of passing the alias to the
2362       # search_rs below is that if you wrap/overload resultset on the
2363       # source you need to know what alias it's -going- to have for things
2364       # to work sanely (e.g. RestrictWithObject wants to be able to add
2365       # extra query restrictions, and these may need to be $alias.)
2366
2367       my $attrs = $rel_source->resultset_attributes;
2368       local $attrs->{alias} = $alias;
2369
2370       $rel_source->resultset
2371                  ->search_rs(
2372                      undef, {
2373                        %attrs,
2374                        join => undef,
2375                        prefetch => undef,
2376                        select => undef,
2377                        as => undef,
2378                        where => $self->{cond},
2379                        seen_join => $seen,
2380                        from => $from,
2381                    });
2382     };
2383     $new->set_cache($new_cache) if $new_cache;
2384     $new;
2385   };
2386 }
2387
2388 =head2 current_source_alias
2389
2390 =over 4
2391
2392 =item Arguments: none
2393
2394 =item Return Value: $source_alias
2395
2396 =back
2397
2398 Returns the current table alias for the result source this resultset is built
2399 on, that will be used in the SQL query. Usually it is C<me>.
2400
2401 Currently the source alias that refers to the result set returned by a
2402 L</search>/L</find> family method depends on how you got to the resultset: it's
2403 C<me> by default, but eg. L</search_related> aliases it to the related result
2404 source name (and keeps C<me> referring to the original result set). The long
2405 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2406 (and make this method unnecessary).
2407
2408 Thus it's currently necessary to use this method in predefined queries (see
2409 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2410 source alias of the current result set:
2411
2412   # in a result set class
2413   sub modified_by {
2414     my ($self, $user) = @_;
2415
2416     my $me = $self->current_source_alias;
2417
2418     return $self->search(
2419       "$me.modified" => $user->id,
2420     );
2421   }
2422
2423 =cut
2424
2425 sub current_source_alias {
2426   my ($self) = @_;
2427
2428   return ($self->{attrs} || {})->{alias} || 'me';
2429 }
2430
2431 # This code is called by search_related, and makes sure there
2432 # is clear separation between the joins before, during, and
2433 # after the relationship. This information is needed later
2434 # in order to properly resolve prefetch aliases (any alias
2435 # with a relation_chain_depth less than the depth of the
2436 # current prefetch is not considered)
2437 sub _resolve_from {
2438   my ($self, $extra_join) = @_;
2439   my $source = $self->result_source;
2440   my $attrs = $self->{attrs};
2441
2442   my $from = $attrs->{from}
2443     || [ { $attrs->{alias} => $source->from } ];
2444
2445   my $seen = { %{$attrs->{seen_join}||{}} };
2446
2447   # we need to take the prefetch the attrs into account before we
2448   # ->_resolve_join as otherwise they get lost - captainL
2449   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2450
2451   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2452
2453   ++$seen->{-relation_chain_depth};
2454
2455   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2456
2457   ++$seen->{-relation_chain_depth};
2458
2459   return ($from,$seen);
2460 }
2461
2462 sub _resolved_attrs {
2463   my $self = shift;
2464   return $self->{_attrs} if $self->{_attrs};
2465
2466   my $attrs  = { %{ $self->{attrs} || {} } };
2467   my $source = $self->result_source;
2468   my $alias  = $attrs->{alias};
2469
2470   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2471   my @colbits;
2472
2473   # build columns (as long as select isn't set) into a set of as/select hashes
2474   unless ( $attrs->{select} ) {
2475       @colbits = map {
2476           ( ref($_) eq 'HASH' )
2477               ? $_
2478               : {
2479                   (
2480                     /^\Q${alias}.\E(.+)$/
2481                       ? "$1"
2482                       : "$_"
2483                   )
2484                 =>
2485                   (
2486                     /\./
2487                       ? "$_"
2488                       : "${alias}.$_"
2489                   )
2490             }
2491       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2492   }
2493   # add the additional columns on
2494   foreach ( 'include_columns', '+columns' ) {
2495       push @colbits, map {
2496           ( ref($_) eq 'HASH' )
2497             ? $_
2498             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2499       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2500   }
2501
2502   # start with initial select items
2503   if ( $attrs->{select} ) {
2504     $attrs->{select} =
2505         ( ref $attrs->{select} eq 'ARRAY' )
2506       ? [ @{ $attrs->{select} } ]
2507       : [ $attrs->{select} ];
2508     $attrs->{as} = (
2509       $attrs->{as}
2510       ? (
2511         ref $attrs->{as} eq 'ARRAY'
2512         ? [ @{ $attrs->{as} } ]
2513         : [ $attrs->{as} ]
2514         )
2515       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2516     );
2517   }
2518   else {
2519
2520     # otherwise we intialise select & as to empty
2521     $attrs->{select} = [];
2522     $attrs->{as}     = [];
2523   }
2524
2525   # now add colbits to select/as
2526   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2527   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2528
2529   my $adds;
2530   if ( $adds = delete $attrs->{'+select'} ) {
2531     $adds = [$adds] unless ref $adds eq 'ARRAY';
2532     push(
2533       @{ $attrs->{select} },
2534       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2535     );
2536   }
2537   if ( $adds = delete $attrs->{'+as'} ) {
2538     $adds = [$adds] unless ref $adds eq 'ARRAY';
2539     push( @{ $attrs->{as} }, @$adds );
2540   }
2541
2542   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2543
2544   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2545     my $join = delete $attrs->{join} || {};
2546
2547     if ( defined $attrs->{prefetch} ) {
2548       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2549
2550     }
2551
2552     $attrs->{from} =    # have to copy here to avoid corrupting the original
2553       [
2554       @{ $attrs->{from} },
2555       $source->_resolve_join(
2556         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2557       )
2558       ];
2559
2560   }
2561
2562   $attrs->{group_by} ||= $attrs->{select}
2563     if delete $attrs->{distinct};
2564   if ( $attrs->{order_by} ) {
2565     $attrs->{order_by} = (
2566       ref( $attrs->{order_by} ) eq 'ARRAY'
2567       ? [ @{ $attrs->{order_by} } ]
2568       : [ $attrs->{order_by} ]
2569     );
2570   }
2571   else {
2572     $attrs->{order_by} = [];
2573   }
2574
2575   my $collapse = $attrs->{collapse} || {};
2576   if ( my $prefetch = delete $attrs->{prefetch} ) {
2577     $prefetch = $self->_merge_attr( {}, $prefetch );
2578     my @pre_order;
2579     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2580
2581       # bring joins back to level of current class
2582       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2583       my @prefetch =
2584         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2585       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2586       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2587     }
2588     push( @{ $attrs->{order_by} }, @pre_order );
2589   }
2590   $attrs->{collapse} = $collapse;
2591
2592   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2593     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2594   }
2595
2596   return $self->{_attrs} = $attrs;
2597 }
2598
2599 sub _joinpath_aliases {
2600   my ($self, $fromspec, $seen) = @_;
2601
2602   my $paths = {};
2603   return $paths unless ref $fromspec eq 'ARRAY';
2604
2605   for my $j (@$fromspec) {
2606
2607     next if ref $j ne 'ARRAY';
2608     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2609
2610     my $p = $paths;
2611     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2612     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2613   }
2614
2615   return $paths;
2616 }
2617
2618 sub _rollout_attr {
2619   my ($self, $attr) = @_;
2620
2621   if (ref $attr eq 'HASH') {
2622     return $self->_rollout_hash($attr);
2623   } elsif (ref $attr eq 'ARRAY') {
2624     return $self->_rollout_array($attr);
2625   } else {
2626     return [$attr];
2627   }
2628 }
2629
2630 sub _rollout_array {
2631   my ($self, $attr) = @_;
2632
2633   my @rolled_array;
2634   foreach my $element (@{$attr}) {
2635     if (ref $element eq 'HASH') {
2636       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2637     } elsif (ref $element eq 'ARRAY') {
2638       #  XXX - should probably recurse here
2639       push( @rolled_array, @{$self->_rollout_array($element)} );
2640     } else {
2641       push( @rolled_array, $element );
2642     }
2643   }
2644   return \@rolled_array;
2645 }
2646
2647 sub _rollout_hash {
2648   my ($self, $attr) = @_;
2649
2650   my @rolled_array;
2651   foreach my $key (keys %{$attr}) {
2652     push( @rolled_array, { $key => $attr->{$key} } );
2653   }
2654   return \@rolled_array;
2655 }
2656
2657 sub _calculate_score {
2658   my ($self, $a, $b) = @_;
2659
2660   if (ref $b eq 'HASH') {
2661     my ($b_key) = keys %{$b};
2662     if (ref $a eq 'HASH') {
2663       my ($a_key) = keys %{$a};
2664       if ($a_key eq $b_key) {
2665         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2666       } else {
2667         return 0;
2668       }
2669     } else {
2670       return ($a eq $b_key) ? 1 : 0;
2671     }
2672   } else {
2673     if (ref $a eq 'HASH') {
2674       my ($a_key) = keys %{$a};
2675       return ($b eq $a_key) ? 1 : 0;
2676     } else {
2677       return ($b eq $a) ? 1 : 0;
2678     }
2679   }
2680 }
2681
2682 sub _merge_attr {
2683   my ($self, $orig, $import) = @_;
2684
2685   return $import unless defined($orig);
2686   return $orig unless defined($import);
2687
2688   $orig = $self->_rollout_attr($orig);
2689   $import = $self->_rollout_attr($import);
2690
2691   my $seen_keys;
2692   foreach my $import_element ( @{$import} ) {
2693     # find best candidate from $orig to merge $b_element into
2694     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2695     foreach my $orig_element ( @{$orig} ) {
2696       my $score = $self->_calculate_score( $orig_element, $import_element );
2697       if ($score > $best_candidate->{score}) {
2698         $best_candidate->{position} = $position;
2699         $best_candidate->{score} = $score;
2700       }
2701       $position++;
2702     }
2703     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2704
2705     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2706       push( @{$orig}, $import_element );
2707     } else {
2708       my $orig_best = $orig->[$best_candidate->{position}];
2709       # merge orig_best and b_element together and replace original with merged
2710       if (ref $orig_best ne 'HASH') {
2711         $orig->[$best_candidate->{position}] = $import_element;
2712       } elsif (ref $import_element eq 'HASH') {
2713         my ($key) = keys %{$orig_best};
2714         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2715       }
2716     }
2717     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2718   }
2719
2720   return $orig;
2721 }
2722
2723 sub result_source {
2724     my $self = shift;
2725
2726     if (@_) {
2727         $self->_source_handle($_[0]->handle);
2728     } else {
2729         $self->_source_handle->resolve;
2730     }
2731 }
2732
2733 =head2 throw_exception
2734
2735 See L<DBIx::Class::Schema/throw_exception> for details.
2736
2737 =cut
2738
2739 sub throw_exception {
2740   my $self=shift;
2741   if (ref $self && $self->_source_handle->schema) {
2742     $self->_source_handle->schema->throw_exception(@_)
2743   } else {
2744     croak(@_);
2745   }
2746
2747 }
2748
2749 # XXX: FIXME: Attributes docs need clearing up
2750
2751 =head1 ATTRIBUTES
2752
2753 Attributes are used to refine a ResultSet in various ways when
2754 searching for data. They can be passed to any method which takes an
2755 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2756 L</count>.
2757
2758 These are in no particular order:
2759
2760 =head2 order_by
2761
2762 =over 4
2763
2764 =item Value: ( $order_by | \@order_by | \%order_by )
2765
2766 =back
2767
2768 Which column(s) to order the results by. If a single column name, or
2769 an arrayref of names is supplied, the argument is passed through
2770 directly to SQL. The hashref syntax allows for connection-agnostic
2771 specification of ordering direction:
2772
2773  For descending order:
2774
2775   order_by => { -desc => [qw/col1 col2 col3/] }
2776
2777  For explicit ascending order:
2778
2779   order_by => { -asc => 'col' }
2780
2781 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2782 supported, although you are strongly encouraged to use the hashref
2783 syntax as outlined above.
2784
2785 =head2 columns
2786
2787 =over 4
2788
2789 =item Value: \@columns
2790
2791 =back
2792
2793 Shortcut to request a particular set of columns to be retrieved. Each
2794 column spec may be a string (a table column name), or a hash (in which
2795 case the key is the C<as> value, and the value is used as the C<select>
2796 expression). Adds C<me.> onto the start of any column without a C<.> in
2797 it and sets C<select> from that, then auto-populates C<as> from
2798 C<select> as normal. (You may also use the C<cols> attribute, as in
2799 earlier versions of DBIC.)
2800
2801 =head2 +columns
2802
2803 =over 4
2804
2805 =item Value: \@columns
2806
2807 =back
2808
2809 Indicates additional columns to be selected from storage. Works the same
2810 as L</columns> but adds columns to the selection. (You may also use the
2811 C<include_columns> attribute, as in earlier versions of DBIC). For
2812 example:-
2813
2814   $schema->resultset('CD')->search(undef, {
2815     '+columns' => ['artist.name'],
2816     join => ['artist']
2817   });
2818
2819 would return all CDs and include a 'name' column to the information
2820 passed to object inflation. Note that the 'artist' is the name of the
2821 column (or relationship) accessor, and 'name' is the name of the column
2822 accessor in the related table.
2823
2824 =head2 include_columns
2825
2826 =over 4
2827
2828 =item Value: \@columns
2829
2830 =back
2831
2832 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2833
2834 =head2 select
2835
2836 =over 4
2837
2838 =item Value: \@select_columns
2839
2840 =back
2841
2842 Indicates which columns should be selected from the storage. You can use
2843 column names, or in the case of RDBMS back ends, function or stored procedure
2844 names:
2845
2846   $rs = $schema->resultset('Employee')->search(undef, {
2847     select => [
2848       'name',
2849       { count => 'employeeid' },
2850       { sum => 'salary' }
2851     ]
2852   });
2853
2854 When you use function/stored procedure names and do not supply an C<as>
2855 attribute, the column names returned are storage-dependent. E.g. MySQL would
2856 return a column named C<count(employeeid)> in the above example.
2857
2858 =head2 +select
2859
2860 =over 4
2861
2862 Indicates additional columns to be selected from storage.  Works the same as
2863 L</select> but adds columns to the selection.
2864
2865 =back
2866
2867 =head2 +as
2868
2869 =over 4
2870
2871 Indicates additional column names for those added via L</+select>. See L</as>.
2872
2873 =back
2874
2875 =head2 as
2876
2877 =over 4
2878
2879 =item Value: \@inflation_names
2880
2881 =back
2882
2883 Indicates column names for object inflation. That is, C<as>
2884 indicates the name that the column can be accessed as via the
2885 C<get_column> method (or via the object accessor, B<if one already
2886 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2887
2888 The C<as> attribute is used in conjunction with C<select>,
2889 usually when C<select> contains one or more function or stored
2890 procedure names:
2891
2892   $rs = $schema->resultset('Employee')->search(undef, {
2893     select => [
2894       'name',
2895       { count => 'employeeid' }
2896     ],
2897     as => ['name', 'employee_count'],
2898   });
2899
2900   my $employee = $rs->first(); # get the first Employee
2901
2902 If the object against which the search is performed already has an accessor
2903 matching a column name specified in C<as>, the value can be retrieved using
2904 the accessor as normal:
2905
2906   my $name = $employee->name();
2907
2908 If on the other hand an accessor does not exist in the object, you need to
2909 use C<get_column> instead:
2910
2911   my $employee_count = $employee->get_column('employee_count');
2912
2913 You can create your own accessors if required - see
2914 L<DBIx::Class::Manual::Cookbook> for details.
2915
2916 Please note: This will NOT insert an C<AS employee_count> into the SQL
2917 statement produced, it is used for internal access only. Thus
2918 attempting to use the accessor in an C<order_by> clause or similar
2919 will fail miserably.
2920
2921 To get around this limitation, you can supply literal SQL to your
2922 C<select> attibute that contains the C<AS alias> text, eg:
2923
2924   select => [\'myfield AS alias']
2925
2926 =head2 join
2927
2928 =over 4
2929
2930 =item Value: ($rel_name | \@rel_names | \%rel_names)
2931
2932 =back
2933
2934 Contains a list of relationships that should be joined for this query.  For
2935 example:
2936
2937   # Get CDs by Nine Inch Nails
2938   my $rs = $schema->resultset('CD')->search(
2939     { 'artist.name' => 'Nine Inch Nails' },
2940     { join => 'artist' }
2941   );
2942
2943 Can also contain a hash reference to refer to the other relation's relations.
2944 For example:
2945
2946   package MyApp::Schema::Track;
2947   use base qw/DBIx::Class/;
2948   __PACKAGE__->table('track');
2949   __PACKAGE__->add_columns(qw/trackid cd position title/);
2950   __PACKAGE__->set_primary_key('trackid');
2951   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2952   1;
2953
2954   # In your application
2955   my $rs = $schema->resultset('Artist')->search(
2956     { 'track.title' => 'Teardrop' },
2957     {
2958       join     => { cd => 'track' },
2959       order_by => 'artist.name',
2960     }
2961   );
2962
2963 You need to use the relationship (not the table) name in  conditions,
2964 because they are aliased as such. The current table is aliased as "me", so
2965 you need to use me.column_name in order to avoid ambiguity. For example:
2966
2967   # Get CDs from 1984 with a 'Foo' track
2968   my $rs = $schema->resultset('CD')->search(
2969     {
2970       'me.year' => 1984,
2971       'tracks.name' => 'Foo'
2972     },
2973     { join => 'tracks' }
2974   );
2975
2976 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2977 similarly for a third time). For e.g.
2978
2979   my $rs = $schema->resultset('Artist')->search({
2980     'cds.title'   => 'Down to Earth',
2981     'cds_2.title' => 'Popular',
2982   }, {
2983     join => [ qw/cds cds/ ],
2984   });
2985
2986 will return a set of all artists that have both a cd with title 'Down
2987 to Earth' and a cd with title 'Popular'.
2988
2989 If you want to fetch related objects from other tables as well, see C<prefetch>
2990 below.
2991
2992 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2993
2994 =head2 prefetch
2995
2996 =over 4
2997
2998 =item Value: ($rel_name | \@rel_names | \%rel_names)
2999
3000 =back
3001
3002 Contains one or more relationships that should be fetched along with
3003 the main query (when they are accessed afterwards the data will
3004 already be available, without extra queries to the database).  This is
3005 useful for when you know you will need the related objects, because it
3006 saves at least one query:
3007
3008   my $rs = $schema->resultset('Tag')->search(
3009     undef,
3010     {
3011       prefetch => {
3012         cd => 'artist'
3013       }
3014     }
3015   );
3016
3017 The initial search results in SQL like the following:
3018
3019   SELECT tag.*, cd.*, artist.* FROM tag
3020   JOIN cd ON tag.cd = cd.cdid
3021   JOIN artist ON cd.artist = artist.artistid
3022
3023 L<DBIx::Class> has no need to go back to the database when we access the
3024 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3025 case.
3026
3027 Simple prefetches will be joined automatically, so there is no need
3028 for a C<join> attribute in the above search.
3029
3030 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3031 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3032 with an accessor type of 'single' or 'filter'). A more complex example that
3033 prefetches an artists cds, the tracks on those cds, and the tags associted
3034 with that artist is given below (assuming many-to-many from artists to tags):
3035
3036  my $rs = $schema->resultset('Artist')->search(
3037    undef,
3038    {
3039      prefetch => [
3040        { cds => 'tracks' },
3041        { artist_tags => 'tags' }
3042      ]
3043    }
3044  );
3045
3046
3047 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3048 attributes will be ignored.
3049
3050 =head2 page
3051
3052 =over 4
3053
3054 =item Value: $page
3055
3056 =back
3057
3058 Makes the resultset paged and specifies the page to retrieve. Effectively
3059 identical to creating a non-pages resultset and then calling ->page($page)
3060 on it.
3061
3062 If L<rows> attribute is not specified it defualts to 10 rows per page.
3063
3064 When you have a paged resultset, L</count> will only return the number
3065 of rows in the page. To get the total, use the L</pager> and call
3066 C<total_entries> on it.
3067
3068 =head2 rows
3069
3070 =over 4
3071
3072 =item Value: $rows
3073
3074 =back
3075
3076 Specifes the maximum number of rows for direct retrieval or the number of
3077 rows per page if the page attribute or method is used.
3078
3079 =head2 offset
3080
3081 =over 4
3082
3083 =item Value: $offset
3084
3085 =back
3086
3087 Specifies the (zero-based) row number for the  first row to be returned, or the
3088 of the first row of the first page if paging is used.
3089
3090 =head2 group_by
3091
3092 =over 4
3093
3094 =item Value: \@columns
3095
3096 =back
3097
3098 A arrayref of columns to group by. Can include columns of joined tables.
3099
3100   group_by => [qw/ column1 column2 ... /]
3101
3102 =head2 having
3103
3104 =over 4
3105
3106 =item Value: $condition
3107
3108 =back
3109
3110 HAVING is a select statement attribute that is applied between GROUP BY and
3111 ORDER BY. It is applied to the after the grouping calculations have been
3112 done.
3113
3114   having => { 'count(employee)' => { '>=', 100 } }
3115
3116 =head2 distinct
3117
3118 =over 4
3119
3120 =item Value: (0 | 1)
3121
3122 =back
3123
3124 Set to 1 to group by all columns.
3125
3126 =head2 where
3127
3128 =over 4
3129
3130 Adds to the WHERE clause.
3131
3132   # only return rows WHERE deleted IS NULL for all searches
3133   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3134
3135 Can be overridden by passing C<{ where => undef }> as an attribute
3136 to a resulset.
3137
3138 =back
3139
3140 =head2 cache
3141
3142 Set to 1 to cache search results. This prevents extra SQL queries if you
3143 revisit rows in your ResultSet:
3144
3145   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3146
3147   while( my $artist = $resultset->next ) {
3148     ... do stuff ...
3149   }
3150
3151   $rs->first; # without cache, this would issue a query
3152
3153 By default, searches are not cached.
3154
3155 For more examples of using these attributes, see
3156 L<DBIx::Class::Manual::Cookbook>.
3157
3158 =head2 from
3159
3160 =over 4
3161
3162 =item Value: \@from_clause
3163
3164 =back
3165
3166 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3167 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3168 clauses.
3169
3170 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3171
3172 C<join> will usually do what you need and it is strongly recommended that you
3173 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3174 And we really do mean "cannot", not just tried and failed. Attempting to use
3175 this because you're having problems with C<join> is like trying to use x86
3176 ASM because you've got a syntax error in your C. Trust us on this.
3177
3178 Now, if you're still really, really sure you need to use this (and if you're
3179 not 100% sure, ask the mailing list first), here's an explanation of how this
3180 works.
3181
3182 The syntax is as follows -
3183
3184   [
3185     { <alias1> => <table1> },
3186     [
3187       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3188       [], # nested JOIN (optional)
3189       { <table1.column1> => <table2.column2>, ... (more conditions) },
3190     ],
3191     # More of the above [ ] may follow for additional joins
3192   ]
3193
3194   <table1> <alias1>
3195   JOIN
3196     <table2> <alias2>
3197     [JOIN ...]
3198   ON <table1.column1> = <table2.column2>
3199   <more joins may follow>
3200
3201 An easy way to follow the examples below is to remember the following:
3202
3203     Anything inside "[]" is a JOIN
3204     Anything inside "{}" is a condition for the enclosing JOIN
3205
3206 The following examples utilize a "person" table in a family tree application.
3207 In order to express parent->child relationships, this table is self-joined:
3208
3209     # Person->belongs_to('father' => 'Person');
3210     # Person->belongs_to('mother' => 'Person');
3211
3212 C<from> can be used to nest joins. Here we return all children with a father,
3213 then search against all mothers of those children:
3214
3215   $rs = $schema->resultset('Person')->search(
3216       undef,
3217       {
3218           alias => 'mother', # alias columns in accordance with "from"
3219           from => [
3220               { mother => 'person' },
3221               [
3222                   [
3223                       { child => 'person' },
3224                       [
3225                           { father => 'person' },
3226                           { 'father.person_id' => 'child.father_id' }
3227                       ]
3228                   ],
3229                   { 'mother.person_id' => 'child.mother_id' }
3230               ],
3231           ]
3232       },
3233   );
3234
3235   # Equivalent SQL:
3236   # SELECT mother.* FROM person mother
3237   # JOIN (
3238   #   person child
3239   #   JOIN person father
3240   #   ON ( father.person_id = child.father_id )
3241   # )
3242   # ON ( mother.person_id = child.mother_id )
3243
3244 The type of any join can be controlled manually. To search against only people
3245 with a father in the person table, we could explicitly use C<INNER JOIN>:
3246
3247     $rs = $schema->resultset('Person')->search(
3248         undef,
3249         {
3250             alias => 'child', # alias columns in accordance with "from"
3251             from => [
3252                 { child => 'person' },
3253                 [
3254                     { father => 'person', -join_type => 'inner' },
3255                     { 'father.id' => 'child.father_id' }
3256                 ],
3257             ]
3258         },
3259     );
3260
3261     # Equivalent SQL:
3262     # SELECT child.* FROM person child
3263     # INNER JOIN person father ON child.father_id = father.id
3264
3265 If you need to express really complex joins or you need a subselect, you
3266 can supply literal SQL to C<from> via a scalar reference. In this case
3267 the contents of the scalar will replace the table name asscoiated with the
3268 resultsource.
3269
3270 WARNING: This technique might very well not work as expected on chained
3271 searches - you have been warned.
3272
3273     # Assuming the Event resultsource is defined as:
3274
3275         MySchema::Event->add_columns (
3276             sequence => {
3277                 data_type => 'INT',
3278                 is_auto_increment => 1,
3279             },
3280             location => {
3281                 data_type => 'INT',
3282             },
3283             type => {
3284                 data_type => 'INT',
3285             },
3286         );
3287         MySchema::Event->set_primary_key ('sequence');
3288
3289     # This will get back the latest event for every location. The column
3290     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3291     # combo to limit the resultset
3292
3293     $rs = $schema->resultset('Event');
3294     $table = $rs->result_source->name;
3295     $latest = $rs->search (
3296         undef,
3297         { from => \ "
3298             (SELECT e1.* FROM $table e1
3299                 JOIN $table e2
3300                     ON e1.location = e2.location
3301                     AND e1.sequence < e2.sequence
3302                 WHERE e2.sequence is NULL
3303             ) me",
3304         },
3305     );
3306
3307     # Equivalent SQL (with the DBIC chunks added):
3308
3309     SELECT me.sequence, me.location, me.type FROM
3310        (SELECT e1.* FROM events e1
3311            JOIN events e2
3312                ON e1.location = e2.location
3313                AND e1.sequence < e2.sequence
3314            WHERE e2.sequence is NULL
3315        ) me;
3316
3317 =head2 for
3318
3319 =over 4
3320
3321 =item Value: ( 'update' | 'shared' )
3322
3323 =back
3324
3325 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3326 ... FOR SHARED.
3327
3328 =cut
3329
3330 1;