lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => \&count,
   7         'bool'   => sub { 1; },
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use base qw/DBIx::Class/;
  15
  16 __PACKAGE__->mk_group_accessors('simple' => qw/result_class _source_handle/);
  17
  18 =head1 NAME
  19
  20 DBIx::Class::ResultSet - Responsible for fetching and creating resultset.
  21
  22 =head1 SYNOPSIS
  23
  24   my $rs   = $schema->resultset('User')->search(registered => 1);
  25   my @rows = $schema->resultset('CD')->search(year => 2005);
  26
  27 =head1 DESCRIPTION
  28
  29 The resultset is also known as an iterator. It is responsible for handling
  30 queries that may return an arbitrary number of rows, e.g. via L</search>
  31 or a C<has_many> relationship.
  32
  33 In the examples below, the following table classes are used:
  34
  35   package MyApp::Schema::Artist;
  36   use base qw/DBIx::Class/;
  37   __PACKAGE__->load_components(qw/Core/);
  38   __PACKAGE__->table('artist');
  39   __PACKAGE__->add_columns(qw/artistid name/);
  40   __PACKAGE__->set_primary_key('artistid');
  41   __PACKAGE__->has_many(cds => 'MyApp::Schema::CD');
  42   1;
  43
  44   package MyApp::Schema::CD;
  45   use base qw/DBIx::Class/;
  46   __PACKAGE__->load_components(qw/Core/);
  47   __PACKAGE__->table('cd');
  48   __PACKAGE__->add_columns(qw/cdid artist title year/);
  49   __PACKAGE__->set_primary_key('cdid');
  50   __PACKAGE__->belongs_to(artist => 'MyApp::Schema::Artist');
  51   1;
  52
  53 =head1 METHODS
  54
  55 =head2 new
  56
  57 =over 4
  58
  59 =item Arguments: $source, \%$attrs
  60
  61 =item Return Value: $rs
  62
  63 =back
  64
  65 The resultset constructor. Takes a source object (usually a
  66 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
  67 L</ATTRIBUTES> below).  Does not perform any queries -- these are
  68 executed as needed by the other methods.
  69
  70 Generally you won't need to construct a resultset manually.  You'll
  71 automatically get one from e.g. a L</search> called in scalar context:
  72
  73   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
  74
  75 IMPORTANT: If called on an object, proxies to new_result instead so
  76
  77   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
  78
  79 will return a CD object, not a ResultSet.
  80
  81 =cut
  82
  83 sub new {
  84   my $class = shift;
  85   return $class->new_result(@_) if ref $class;
  86
  87   my ($source, $attrs) = @_;
  88   $source = $source->handle
  89     unless $source->isa('DBIx::Class::ResultSourceHandle');
  90   $attrs = { %{$attrs||{}} };
  91
  92   if ($attrs->{page}) {
  93     $attrs->{rows} ||= 10;
  94   }
  95
  96   $attrs->{alias} ||= 'me';
  97
  98   my $self = {
  99     _source_handle => $source,
 100     result_class => $attrs->{result_class} || $source->resolve->result_class,
 101     cond => $attrs->{where},
 102     count => undef,
 103     pager => undef,
 104     attrs => $attrs
 105   };
 106
 107   bless $self, $class;
 108
 109   return $self;
 110 }
 111
 112 =head2 search
 113
 114 =over 4
 115
 116 =item Arguments: $cond, \%attrs?
 117
 118 =item Return Value: $resultset (scalar context), @row_objs (list context)
 119
 120 =back
 121
 122   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 123   my $new_rs = $cd_rs->search({ year => 2005 });
 124
 125   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 126                  # year = 2005 OR year = 2004
 127
 128 If you need to pass in additional attributes but no additional condition,
 129 call it as C<search(undef, \%attrs)>.
 130
 131   # "SELECT name, artistid FROM $artist_table"
 132   my @all_artists = $schema->resultset('Artist')->search(undef, {
 133     columns => [qw/name artistid/],
 134   });
 135
 136 For a list of attributes that can be passed to C<search>, see
 137 L</ATTRIBUTES>. For more examples of using this function, see
 138 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 139 documentation for the first argument, see L<SQL::Abstract>.
 140
 141 =cut
 142
 143 sub search {
 144   my $self = shift;
 145   my $rs = $self->search_rs( @_ );
 146   return (wantarray ? $rs->all : $rs);
 147 }
 148
 149 =head2 search_rs
 150
 151 =over 4
 152
 153 =item Arguments: $cond, \%attrs?
 154
 155 =item Return Value: $resultset
 156
 157 =back
 158
 159 This method does the same exact thing as search() except it will
 160 always return a resultset, even in list context.
 161
 162 =cut
 163
 164 sub search_rs {
 165   my $self = shift;
 166
 167   my $rows;
 168
 169   unless (@_) {                 # no search, effectively just a clone
 170     $rows = $self->get_cache;
 171   }
 172
 173   my $attrs = {};
 174   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 175   my $our_attrs = { %{$self->{attrs}} };
 176   my $having = delete $our_attrs->{having};
 177   my $where = delete $our_attrs->{where};
 178
 179   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 180
 181   # merge new attrs into inherited
 182   foreach my $key (qw/join prefetch/) {
 183     next unless exists $attrs->{$key};
 184     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 185   }
 186
 187   my $cond = (@_
 188     ? (
 189         (@_ == 1 || ref $_[0] eq "HASH")
 190           ? (
 191               (ref $_[0] eq 'HASH')
 192                 ? (
 193                     (keys %{ $_[0] }  > 0)
 194                       ? shift
 195                       : undef
 196                    )
 197                 :  shift
 198              )
 199           : (
 200               (@_ % 2)
 201                 ? $self->throw_exception("Odd number of arguments to search")
 202                 : {@_}
 203              )
 204       )
 205     : undef
 206   );
 207
 208   if (defined $where) {
 209     $new_attrs->{where} = (
 210       defined $new_attrs->{where}
 211         ? { '-and' => [
 212               map {
 213                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 214               } $where, $new_attrs->{where}
 215             ]
 216           }
 217         : $where);
 218   }
 219
 220   if (defined $cond) {
 221     $new_attrs->{where} = (
 222       defined $new_attrs->{where}
 223         ? { '-and' => [
 224               map {
 225                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 226               } $cond, $new_attrs->{where}
 227             ]
 228           }
 229         : $cond);
 230   }
 231
 232   if (defined $having) {
 233     $new_attrs->{having} = (
 234       defined $new_attrs->{having}
 235         ? { '-and' => [
 236               map {
 237                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 238               } $having, $new_attrs->{having}
 239             ]
 240           }
 241         : $having);
 242   }
 243
 244   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 245   if ($rows) {
 246     $rs->set_cache($rows);
 247   }
 248   return $rs;
 249 }
 250
 251 =head2 search_literal
 252
 253 =over 4
 254
 255 =item Arguments: $sql_fragment, @bind_values
 256
 257 =item Return Value: $resultset (scalar context), @row_objs (list context)
 258
 259 =back
 260
 261   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 262   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 263
 264 Pass a literal chunk of SQL to be added to the conditional part of the
 265 resultset query.
 266
 267 =cut
 268
 269 sub search_literal {
 270   my ($self, $cond, @vals) = @_;
 271   my $attrs = (ref $vals[$#vals] eq 'HASH' ? { %{ pop(@vals) } } : {});
 272   $attrs->{bind} = [ @{$self->{attrs}{bind}||[]}, @vals ];
 273   return $self->search(\$cond, $attrs);
 274 }
 275
 276 =head2 find
 277
 278 =over 4
 279
 280 =item Arguments: @values | \%cols, \%attrs?
 281
 282 =item Return Value: $row_object
 283
 284 =back
 285
 286 Finds a row based on its primary key or unique constraint. For example, to find
 287 a row by its primary key:
 288
 289   my $cd = $schema->resultset('CD')->find(5);
 290
 291 You can also find a row by a specific unique constraint using the C<key>
 292 attribute. For example:
 293
 294   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 295     key => 'cd_artist_title'
 296   });
 297
 298 Additionally, you can specify the columns explicitly by name:
 299
 300   my $cd = $schema->resultset('CD')->find(
 301     {
 302       artist => 'Massive Attack',
 303       title  => 'Mezzanine',
 304     },
 305     { key => 'cd_artist_title' }
 306   );
 307
 308 If the C<key> is specified as C<primary>, it searches only on the primary key.
 309
 310 If no C<key> is specified, it searches on all unique constraints defined on the
 311 source, including the primary key.
 312
 313 If your table does not have a primary key, you B<must> provide a value for the
 314 C<key> attribute matching one of the unique constraints on the source.
 315
 316 See also L</find_or_create> and L</update_or_create>. For information on how to
 317 declare unique constraints, see
 318 L<DBIx::Class::ResultSource/add_unique_constraint>.
 319
 320 =cut
 321
 322 sub find {
 323   my $self = shift;
 324   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 325
 326   # Default to the primary key, but allow a specific key
 327   my @cols = exists $attrs->{key}
 328     ? $self->result_source->unique_constraint_columns($attrs->{key})
 329     : $self->result_source->primary_columns;
 330   $self->throw_exception(
 331     "Can't find unless a primary key is defined or unique constraint is specified"
 332   ) unless @cols;
 333
 334   # Parse out a hashref from input
 335   my $input_query;
 336   if (ref $_[0] eq 'HASH') {
 337     $input_query = { %{$_[0]} };
 338   }
 339   elsif (@_ == @cols) {
 340     $input_query = {};
 341     @{$input_query}{@cols} = @_;
 342   }
 343   else {
 344     # Compatibility: Allow e.g. find(id => $value)
 345     carp "Find by key => value deprecated; please use a hashref instead";
 346     $input_query = {@_};
 347   }
 348
 349   my (%related, $info);
 350
 351   KEY: foreach my $key (keys %$input_query) {
 352     if (ref($input_query->{$key})
 353         && ($info = $self->result_source->relationship_info($key))) {
 354       my $val = delete $input_query->{$key};
 355       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 356       my $rel_q = $self->result_source->resolve_condition(
 357                     $info->{cond}, $val, $key
 358                   );
 359       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 360       @related{keys %$rel_q} = values %$rel_q;
 361     }
 362   }
 363   if (my @keys = keys %related) {
 364     @{$input_query}{@keys} = values %related;
 365   }
 366
 367   my @unique_queries = $self->_unique_queries($input_query, $attrs);
 368
 369   # Build the final query: Default to the disjunction of the unique queries,
 370   # but allow the input query in case the ResultSet defines the query or the
 371   # user is abusing find
 372   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 373   my $query = @unique_queries
 374     ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 375     : $self->_add_alias($input_query, $alias);
 376
 377   # Run the query
 378   if (keys %$attrs) {
 379     my $rs = $self->search($query, $attrs);
 380     return keys %{$rs->_resolved_attrs->{collapse}} ? $rs->next : $rs->single;
 381   }
 382   else {
 383     return keys %{$self->_resolved_attrs->{collapse}}
 384       ? $self->search($query)->next
 385       : $self->single($query);
 386   }
 387 }
 388
 389 # _add_alias
 390 #
 391 # Add the specified alias to the specified query hash. A copy is made so the
 392 # original query is not modified.
 393
 394 sub _add_alias {
 395   my ($self, $query, $alias) = @_;
 396
 397   my %aliased = %$query;
 398   foreach my $col (grep { ! m/\./ } keys %aliased) {
 399     $aliased{"$alias.$col"} = delete $aliased{$col};
 400   }
 401
 402   return \%aliased;
 403 }
 404
 405 # _unique_queries
 406 #
 407 # Build a list of queries which satisfy unique constraints.
 408
 409 sub _unique_queries {
 410   my ($self, $query, $attrs) = @_;
 411
 412   my @constraint_names = exists $attrs->{key}
 413     ? ($attrs->{key})
 414     : $self->result_source->unique_constraint_names;
 415
 416   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 417   my $num_where = scalar keys %$where;
 418
 419   my @unique_queries;
 420   foreach my $name (@constraint_names) {
 421     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 422     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 423
 424     my $num_cols = scalar @unique_cols;
 425     my $num_query = scalar keys %$unique_query;
 426
 427     my $total = $num_query + $num_where;
 428     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 429       # The query is either unique on its own or is unique in combination with
 430       # the existing where clause
 431       push @unique_queries, $unique_query;
 432     }
 433   }
 434
 435   return @unique_queries;
 436 }
 437
 438 # _build_unique_query
 439 #
 440 # Constrain the specified query hash based on the specified column names.
 441
 442 sub _build_unique_query {
 443   my ($self, $query, $unique_cols) = @_;
 444
 445   return {
 446     map  { $_ => $query->{$_} }
 447     grep { exists $query->{$_} }
 448       @$unique_cols
 449   };
 450 }
 451
 452 =head2 search_related
 453
 454 =over 4
 455
 456 =item Arguments: $rel, $cond, \%attrs?
 457
 458 =item Return Value: $new_resultset
 459
 460 =back
 461
 462   $new_rs = $cd_rs->search_related('artist', {
 463     name => 'Emo-R-Us',
 464   });
 465
 466 Searches the specified relationship, optionally specifying a condition and
 467 attributes for matching records. See L</ATTRIBUTES> for more information.
 468
 469 =cut
 470
 471 sub search_related {
 472   return shift->related_resultset(shift)->search(@_);
 473 }
 474
 475 =head2 cursor
 476
 477 =over 4
 478
 479 =item Arguments: none
 480
 481 =item Return Value: $cursor
 482
 483 =back
 484
 485 Returns a storage-driven cursor to the given resultset. See
 486 L<DBIx::Class::Cursor> for more information.
 487
 488 =cut
 489
 490 sub cursor {
 491   my ($self) = @_;
 492
 493   my $attrs = { %{$self->_resolved_attrs} };
 494   return $self->{cursor}
 495     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 496           $attrs->{where},$attrs);
 497 }
 498
 499 =head2 single
 500
 501 =over 4
 502
 503 =item Arguments: $cond?
 504
 505 =item Return Value: $row_object?
 506
 507 =back
 508
 509   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 510
 511 Inflates the first result without creating a cursor if the resultset has
 512 any records in it; if not returns nothing. Used by L</find> as an optimisation.
 513
 514 Can optionally take an additional condition *only* - this is a fast-code-path
 515 method; if you need to add extra joins or similar call ->search and then
 516 ->single without a condition on the $rs returned from that.
 517
 518 =cut
 519
 520 sub single {
 521   my ($self, $where) = @_;
 522   my $attrs = { %{$self->_resolved_attrs} };
 523   if ($where) {
 524     if (defined $attrs->{where}) {
 525       $attrs->{where} = {
 526         '-and' =>
 527             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 528                $where, delete $attrs->{where} ]
 529       };
 530     } else {
 531       $attrs->{where} = $where;
 532     }
 533   }
 534
 535 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 536 #  unless ($self->_is_unique_query($attrs->{where})) {
 537 #    carp "Query not guaranteed to return a single row"
 538 #      . "; please declare your unique constraints or use search instead";
 539 #  }
 540
 541   my @data = $self->result_source->storage->select_single(
 542     $attrs->{from}, $attrs->{select},
 543     $attrs->{where}, $attrs
 544   );
 545
 546   return (@data ? ($self->_construct_object(@data))[0] : undef);
 547 }
 548
 549 # _is_unique_query
 550 #
 551 # Try to determine if the specified query is guaranteed to be unique, based on
 552 # the declared unique constraints.
 553
 554 sub _is_unique_query {
 555   my ($self, $query) = @_;
 556
 557   my $collapsed = $self->_collapse_query($query);
 558   my $alias = $self->{attrs}{alias};
 559
 560   foreach my $name ($self->result_source->unique_constraint_names) {
 561     my @unique_cols = map {
 562       "$alias.$_"
 563     } $self->result_source->unique_constraint_columns($name);
 564
 565     # Count the values for each unique column
 566     my %seen = map { $_ => 0 } @unique_cols;
 567
 568     foreach my $key (keys %$collapsed) {
 569       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 570       next unless exists $seen{$aliased};  # Additional constraints are okay
 571       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 572     }
 573
 574     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 575     return 1 unless grep { $_ != 1 } values %seen;
 576   }
 577
 578   return 0;
 579 }
 580
 581 # _collapse_query
 582 #
 583 # Recursively collapse the query, accumulating values for each column.
 584
 585 sub _collapse_query {
 586   my ($self, $query, $collapsed) = @_;
 587
 588   $collapsed ||= {};
 589
 590   if (ref $query eq 'ARRAY') {
 591     foreach my $subquery (@$query) {
 592       next unless ref $subquery;  # -or
 593 #      warn "ARRAY: " . Dumper $subquery;
 594       $collapsed = $self->_collapse_query($subquery, $collapsed);
 595     }
 596   }
 597   elsif (ref $query eq 'HASH') {
 598     if (keys %$query and (keys %$query)[0] eq '-and') {
 599       foreach my $subquery (@{$query->{-and}}) {
 600 #        warn "HASH: " . Dumper $subquery;
 601         $collapsed = $self->_collapse_query($subquery, $collapsed);
 602       }
 603     }
 604     else {
 605 #      warn "LEAF: " . Dumper $query;
 606       foreach my $col (keys %$query) {
 607         my $value = $query->{$col};
 608         $collapsed->{$col}{$value}++;
 609       }
 610     }
 611   }
 612
 613   return $collapsed;
 614 }
 615
 616 =head2 get_column
 617
 618 =over 4
 619
 620 =item Arguments: $cond?
 621
 622 =item Return Value: $resultsetcolumn
 623
 624 =back
 625
 626   my $max_length = $rs->get_column('length')->max;
 627
 628 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 629
 630 =cut
 631
 632 sub get_column {
 633   my ($self, $column) = @_;
 634   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 635   return $new;
 636 }
 637
 638 =head2 search_like
 639
 640 =over 4
 641
 642 =item Arguments: $cond, \%attrs?
 643
 644 =item Return Value: $resultset (scalar context), @row_objs (list context)
 645
 646 =back
 647
 648   # WHERE title LIKE '%blue%'
 649   $cd_rs = $rs->search_like({ title => '%blue%'});
 650
 651 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 652 that this is simply a convenience method. You most likely want to use
 653 L</search> with specific operators.
 654
 655 For more information, see L<DBIx::Class::Manual::Cookbook>.
 656
 657 =cut
 658
 659 sub search_like {
 660   my $class = shift;
 661   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 662   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 663   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 664   return $class->search($query, { %$attrs });
 665 }
 666
 667 =head2 slice
 668
 669 =over 4
 670
 671 =item Arguments: $first, $last
 672
 673 =item Return Value: $resultset (scalar context), @row_objs (list context)
 674
 675 =back
 676
 677 Returns a resultset or object list representing a subset of elements from the
 678 resultset slice is called on. Indexes are from 0, i.e., to get the first
 679 three records, call:
 680
 681   my ($one, $two, $three) = $rs->slice(0, 2);
 682
 683 =cut
 684
 685 sub slice {
 686   my ($self, $min, $max) = @_;
 687   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 688   $attrs->{offset} = $self->{attrs}{offset} || 0;
 689   $attrs->{offset} += $min;
 690   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 691   return $self->search(undef(), $attrs);
 692   #my $slice = (ref $self)->new($self->result_source, $attrs);
 693   #return (wantarray ? $slice->all : $slice);
 694 }
 695
 696 =head2 next
 697
 698 =over 4
 699
 700 =item Arguments: none
 701
 702 =item Return Value: $result?
 703
 704 =back
 705
 706 Returns the next element in the resultset (C<undef> is there is none).
 707
 708 Can be used to efficiently iterate over records in the resultset:
 709
 710   my $rs = $schema->resultset('CD')->search;
 711   while (my $cd = $rs->next) {
 712     print $cd->title;
 713   }
 714
 715 Note that you need to store the resultset object, and call C<next> on it.
 716 Calling C<< resultset('Table')->next >> repeatedly will always return the
 717 first record from the resultset.
 718
 719 =cut
 720
 721 sub next {
 722   my ($self) = @_;
 723   if (my $cache = $self->get_cache) {
 724     $self->{all_cache_position} ||= 0;
 725     return $cache->[$self->{all_cache_position}++];
 726   }
 727   if ($self->{attrs}{cache}) {
 728     $self->{all_cache_position} = 1;
 729     return ($self->all)[0];
 730   }
 731   if ($self->{stashed_objects}) {
 732     my $obj = shift(@{$self->{stashed_objects}});
 733     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 734     return $obj;
 735   }
 736   my @row = (
 737     exists $self->{stashed_row}
 738       ? @{delete $self->{stashed_row}}
 739       : $self->cursor->next
 740   );
 741   return undef unless (@row);
 742   my ($row, @more) = $self->_construct_object(@row);
 743   $self->{stashed_objects} = \@more if @more;
 744   return $row;
 745 }
 746
 747 sub _construct_object {
 748   my ($self, @row) = @_;
 749   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 750   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 751   @new = $self->{_attrs}{record_filter}->(@new)
 752     if exists $self->{_attrs}{record_filter};
 753   return @new;
 754 }
 755
 756 sub _collapse_result {
 757   my ($self, $as_proto, $row) = @_;
 758
 759   my @copy = @$row;
 760
 761   # 'foo'         => [ undef, 'foo' ]
 762   # 'foo.bar'     => [ 'foo', 'bar' ]
 763   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 764
 765   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 766
 767   my %collapse = %{$self->{_attrs}{collapse}||{}};
 768
 769   my @pri_index;
 770
 771   # if we're doing collapsing (has_many prefetch) we need to grab records
 772   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 773   # we know we don't have to bother.
 774
 775   # the reason for not using the collapse stuff directly is because if you
 776   # had for e.g. two artists in a row with no cds, the collapse info for
 777   # both would be NULL (undef) so you'd lose the second artist
 778
 779   # store just the index so we can check the array positions from the row
 780   # without having to contruct the full hash
 781
 782   if (keys %collapse) {
 783     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 784     foreach my $i (0 .. $#construct_as) {
 785       next if defined($construct_as[$i][0]); # only self table
 786       if (delete $pri{$construct_as[$i][1]}) {
 787         push(@pri_index, $i);
 788       }
 789       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 790     }
 791   }
 792
 793   # no need to do an if, it'll be empty if @pri_index is empty anyway
 794
 795   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 796
 797   my @const_rows;
 798
 799   do { # no need to check anything at the front, we always want the first row
 800
 801     my %const;
 802
 803     foreach my $this_as (@construct_as) {
 804       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
 805     }
 806
 807     push(@const_rows, \%const);
 808
 809   } until ( # no pri_index => no collapse => drop straight out
 810       !@pri_index
 811     or
 812       do { # get another row, stash it, drop out if different PK
 813
 814         @copy = $self->cursor->next;
 815         $self->{stashed_row} = \@copy;
 816
 817         # last thing in do block, counts as true if anything doesn't match
 818
 819         # check xor defined first for NULL vs. NOT NULL then if one is
 820         # defined the other must be so check string equality
 821
 822         grep {
 823           (defined $pri_vals{$_} ^ defined $copy[$_])
 824           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
 825         } @pri_index;
 826       }
 827   );
 828
 829   my $alias = $self->{attrs}{alias};
 830   my $info = [];
 831
 832   my %collapse_pos;
 833
 834   my @const_keys;
 835
 836   foreach my $const (@const_rows) {
 837     scalar @const_keys or do {
 838       @const_keys = sort { length($a) <=> length($b) } keys %$const;
 839     };
 840     foreach my $key (@const_keys) {
 841       if (length $key) {
 842         my $target = $info;
 843         my @parts = split(/\./, $key);
 844         my $cur = '';
 845         my $data = $const->{$key};
 846         foreach my $p (@parts) {
 847           $target = $target->[1]->{$p} ||= [];
 848           $cur .= ".${p}";
 849           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
 850             # collapsing at this point and on final part
 851             my $pos = $collapse_pos{$cur};
 852             CK: foreach my $ck (@ckey) {
 853               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
 854                 $collapse_pos{$cur} = $data;
 855                 delete @collapse_pos{ # clear all positioning for sub-entries
 856                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
 857                 };
 858                 push(@$target, []);
 859                 last CK;
 860               }
 861             }
 862           }
 863           if (exists $collapse{$cur}) {
 864             $target = $target->[-1];
 865           }
 866         }
 867         $target->[0] = $data;
 868       } else {
 869         $info->[0] = $const->{$key};
 870       }
 871     }
 872   }
 873
 874   return $info;
 875 }
 876
 877 =head2 result_source
 878
 879 =over 4
 880
 881 =item Arguments: $result_source?
 882
 883 =item Return Value: $result_source
 884
 885 =back
 886
 887 An accessor for the primary ResultSource object from which this ResultSet
 888 is derived.
 889
 890 =head2 result_class
 891
 892 =over 4
 893
 894 =item Arguments: $result_class?
 895
 896 =item Return Value: $result_class
 897
 898 =back
 899
 900 An accessor for the class to use when creating row objects. Defaults to
 901 C<< result_source->result_class >> - which in most cases is the name of the
 902 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
 903
 904 =cut
 905
 906
 907 =head2 count
 908
 909 =over 4
 910
 911 =item Arguments: $cond, \%attrs??
 912
 913 =item Return Value: $count
 914
 915 =back
 916
 917 Performs an SQL C<COUNT> with the same query as the resultset was built
 918 with to find the number of elements. If passed arguments, does a search
 919 on the resultset and counts the results of that.
 920
 921 Note: When using C<count> with C<group_by>, L<DBIX::Class> emulates C<GROUP BY>
 922 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
 923 not support C<DISTINCT> with multiple columns. If you are using such a
 924 database, you should only use columns from the main table in your C<group_by>
 925 clause.
 926
 927 =cut
 928
 929 sub count {
 930   my $self = shift;
 931   return $self->search(@_)->count if @_ and defined $_[0];
 932   return scalar @{ $self->get_cache } if $self->get_cache;
 933   my $count = $self->_count;
 934   return 0 unless $count;
 935
 936   # need to take offset from resolved attrs
 937
 938   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
 939   $count = $self->{attrs}{rows} if
 940     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
 941   return $count;
 942 }
 943
 944 sub _count { # Separated out so pager can get the full count
 945   my $self = shift;
 946   my $select = { count => '*' };
 947
 948   my $attrs = { %{$self->_resolved_attrs} };
 949   if (my $group_by = delete $attrs->{group_by}) {
 950     delete $attrs->{having};
 951     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
 952     # todo: try CONCAT for multi-column pk
 953     my @pk = $self->result_source->primary_columns;
 954     if (@pk == 1) {
 955       my $alias = $attrs->{alias};
 956       foreach my $column (@distinct) {
 957         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
 958           @distinct = ($column);
 959           last;
 960         }
 961       }
 962     }
 963
 964     $select = { count => { distinct => \@distinct } };
 965   }
 966
 967   $attrs->{select} = $select;
 968   $attrs->{as} = [qw/count/];
 969
 970   # offset, order by and page are not needed to count. record_filter is cdbi
 971   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
 972
 973   my $tmp_rs = (ref $self)->new($self->_source_handle, $attrs);
 974   my ($count) = $tmp_rs->cursor->next;
 975   return $count;
 976 }
 977
 978 =head2 count_literal
 979
 980 =over 4
 981
 982 =item Arguments: $sql_fragment, @bind_values
 983
 984 =item Return Value: $count
 985
 986 =back
 987
 988 Counts the results in a literal query. Equivalent to calling L</search_literal>
 989 with the passed arguments, then L</count>.
 990
 991 =cut
 992
 993 sub count_literal { shift->search_literal(@_)->count; }
 994
 995 =head2 all
 996
 997 =over 4
 998
 999 =item Arguments: none
1000
1001 =item Return Value: @objects
1002
1003 =back
1004
1005 Returns all elements in the resultset. Called implicitly if the resultset
1006 is returned in list context.
1007
1008 =cut
1009
1010 sub all {
1011   my ($self) = @_;
1012   return @{ $self->get_cache } if $self->get_cache;
1013
1014   my @obj;
1015
1016   # TODO: don't call resolve here
1017   if (keys %{$self->_resolved_attrs->{collapse}}) {
1018 #  if ($self->{attrs}{prefetch}) {
1019       # Using $self->cursor->all is really just an optimisation.
1020       # If we're collapsing has_many prefetches it probably makes
1021       # very little difference, and this is cleaner than hacking
1022       # _construct_object to survive the approach
1023     my @row = $self->cursor->next;
1024     while (@row) {
1025       push(@obj, $self->_construct_object(@row));
1026       @row = (exists $self->{stashed_row}
1027                ? @{delete $self->{stashed_row}}
1028                : $self->cursor->next);
1029     }
1030   } else {
1031     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1032   }
1033
1034   $self->set_cache(\@obj) if $self->{attrs}{cache};
1035   return @obj;
1036 }
1037
1038 =head2 reset
1039
1040 =over 4
1041
1042 =item Arguments: none
1043
1044 =item Return Value: $self
1045
1046 =back
1047
1048 Resets the resultset's cursor, so you can iterate through the elements again.
1049
1050 =cut
1051
1052 sub reset {
1053   my ($self) = @_;
1054   delete $self->{_attrs} if exists $self->{_attrs};
1055   $self->{all_cache_position} = 0;
1056   $self->cursor->reset;
1057   return $self;
1058 }
1059
1060 =head2 first
1061
1062 =over 4
1063
1064 =item Arguments: none
1065
1066 =item Return Value: $object?
1067
1068 =back
1069
1070 Resets the resultset and returns an object for the first result (if the
1071 resultset returns anything).
1072
1073 =cut
1074
1075 sub first {
1076   return $_[0]->reset->next;
1077 }
1078
1079 # _cond_for_update_delete
1080 #
1081 # update/delete require the condition to be modified to handle
1082 # the differing SQL syntax available.  This transforms the $self->{cond}
1083 # appropriately, returning the new condition.
1084
1085 sub _cond_for_update_delete {
1086   my ($self, $full_cond) = @_;
1087   my $cond = {};
1088
1089   $full_cond ||= $self->{cond};
1090   # No-op. No condition, we're updating/deleting everything
1091   return $cond unless ref $full_cond;
1092
1093   if (ref $full_cond eq 'ARRAY') {
1094     $cond = [
1095       map {
1096         my %hash;
1097         foreach my $key (keys %{$_}) {
1098           $key =~ /([^.]+)$/;
1099           $hash{$1} = $_->{$key};
1100         }
1101         \%hash;
1102       } @{$full_cond}
1103     ];
1104   }
1105   elsif (ref $full_cond eq 'HASH') {
1106     if ((keys %{$full_cond})[0] eq '-and') {
1107       $cond->{-and} = [];
1108
1109       my @cond = @{$full_cond->{-and}};
1110       for (my $i = 0; $i < @cond; $i++) {
1111         my $entry = $cond[$i];
1112
1113         my $hash;
1114         if (ref $entry eq 'HASH') {
1115           $hash = $self->_cond_for_update_delete($entry);
1116         }
1117         else {
1118           $entry =~ /([^.]+)$/;
1119           $hash->{$1} = $cond[++$i];
1120         }
1121
1122         push @{$cond->{-and}}, $hash;
1123       }
1124     }
1125     else {
1126       foreach my $key (keys %{$full_cond}) {
1127         $key =~ /([^.]+)$/;
1128         $cond->{$1} = $full_cond->{$key};
1129       }
1130     }
1131   }
1132   else {
1133     $self->throw_exception(
1134       "Can't update/delete on resultset with condition unless hash or array"
1135     );
1136   }
1137
1138   return $cond;
1139 }
1140
1141
1142 =head2 update
1143
1144 =over 4
1145
1146 =item Arguments: \%values
1147
1148 =item Return Value: $storage_rv
1149
1150 =back
1151
1152 Sets the specified columns in the resultset to the supplied values in a
1153 single query. Return value will be true if the update succeeded or false
1154 if no records were updated; exact type of success value is storage-dependent.
1155
1156 =cut
1157
1158 sub update {
1159   my ($self, $values) = @_;
1160   $self->throw_exception("Values for update must be a hash")
1161     unless ref $values eq 'HASH';
1162
1163   my $cond = $self->_cond_for_update_delete;
1164
1165   return $self->result_source->storage->update(
1166     $self->result_source, $values, $cond
1167   );
1168 }
1169
1170 =head2 update_all
1171
1172 =over 4
1173
1174 =item Arguments: \%values
1175
1176 =item Return Value: 1
1177
1178 =back
1179
1180 Fetches all objects and updates them one at a time. Note that C<update_all>
1181 will run DBIC cascade triggers, while L</update> will not.
1182
1183 =cut
1184
1185 sub update_all {
1186   my ($self, $values) = @_;
1187   $self->throw_exception("Values for update must be a hash")
1188     unless ref $values eq 'HASH';
1189   foreach my $obj ($self->all) {
1190     $obj->set_columns($values)->update;
1191   }
1192   return 1;
1193 }
1194
1195 =head2 delete
1196
1197 =over 4
1198
1199 =item Arguments: none
1200
1201 =item Return Value: 1
1202
1203 =back
1204
1205 Deletes the contents of the resultset from its result source. Note that this
1206 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1207 to run. See also L<DBIx::Class::Row/delete>.
1208
1209 =cut
1210
1211 sub delete {
1212   my ($self) = @_;
1213
1214   my $cond = $self->_cond_for_update_delete;
1215
1216   $self->result_source->storage->delete($self->result_source, $cond);
1217   return 1;
1218 }
1219
1220 =head2 delete_all
1221
1222 =over 4
1223
1224 =item Arguments: none
1225
1226 =item Return Value: 1
1227
1228 =back
1229
1230 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1231 will run DBIC cascade triggers, while L</delete> will not.
1232
1233 =cut
1234
1235 sub delete_all {
1236   my ($self) = @_;
1237   $_->delete for $self->all;
1238   return 1;
1239 }
1240
1241 =head2 populate
1242
1243 =over 4
1244
1245 =item Arguments: \@data;
1246
1247 =back
1248
1249 Pass an arrayref of hashrefs. Each hashref should be a structure suitable for
1250 submitting to a $resultset->create(...) method.
1251
1252 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1253 to insert the data, as this is a faster method.
1254
1255 Otherwise, each set of data is inserted into the database using
1256 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1257 objects is returned.
1258
1259 Example:  Assuming an Artist Class that has many CDs Classes relating:
1260
1261   my $Artist_rs = $schema->resultset("Artist");
1262
1263   ## Void Context Example
1264   $Artist_rs->populate([
1265      { artistid => 4, name => 'Manufactured Crap', cds => [
1266         { title => 'My First CD', year => 2006 },
1267         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1268       ],
1269      },
1270      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1271         { title => 'My parents sold me to a record company' ,year => 2005 },
1272         { title => 'Why Am I So Ugly?', year => 2006 },
1273         { title => 'I Got Surgery and am now Popular', year => 2007 }
1274       ],
1275      },
1276   ]);
1277
1278   ## Array Context Example
1279   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1280     { name => "Artist One"},
1281     { name => "Artist Two"},
1282     { name => "Artist Three", cds=> [
1283     { title => "First CD", year => 2007},
1284     { title => "Second CD", year => 2008},
1285   ]}
1286   ]);
1287
1288   print $ArtistOne->name; ## response is 'Artist One'
1289   print $ArtistThree->cds->count ## reponse is '2'
1290
1291 =cut
1292
1293 sub populate {
1294   my ($self, $data) = @_;
1295
1296   if(defined wantarray) {
1297     my @created;
1298     foreach my $item (@$data) {
1299       push(@created, $self->create($item));
1300     }
1301     return @created;
1302   } else {
1303     my ($first, @rest) = @$data;
1304
1305     my @names = grep {!ref $first->{$_}} keys %$first;
1306     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1307     my @pks = $self->result_source->primary_columns;
1308
1309     ## do the belongs_to relationships
1310     foreach my $index (0..$#$data) {
1311       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1312         my @ret = $self->populate($data);
1313         return;
1314       }
1315
1316       foreach my $rel (@rels) {
1317         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1318         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1319         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1320         my $related = $result->result_source->resolve_condition(
1321           $result->result_source->relationship_info($reverse)->{cond},
1322           $self,
1323           $result,
1324         );
1325
1326         delete $data->[$index]->{$rel};
1327         $data->[$index] = {%{$data->[$index]}, %$related};
1328
1329         push @names, keys %$related if $index == 0;
1330       }
1331     }
1332
1333     ## do bulk insert on current row
1334     my @values = map {
1335       [ map {
1336          defined $_ ? $_ : $self->throw_exception("Undefined value for column!")
1337       } @$_{@names} ]
1338     } @$data;
1339
1340     $self->result_source->storage->insert_bulk(
1341       $self->result_source,
1342       \@names,
1343       \@values,
1344     );
1345
1346     ## do the has_many relationships
1347     foreach my $item (@$data) {
1348
1349       foreach my $rel (@rels) {
1350         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1351
1352         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1353      || $self->throw_exception('Cannot find the relating object.');
1354
1355         my $child = $parent->$rel;
1356
1357         my $related = $child->result_source->resolve_condition(
1358           $parent->result_source->relationship_info($rel)->{cond},
1359           $child,
1360           $parent,
1361         );
1362
1363         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1364         my @populate = map { {%$_, %$related} } @rows_to_add;
1365
1366         $child->populate( \@populate );
1367       }
1368     }
1369   }
1370 }
1371
1372 =head2 pager
1373
1374 =over 4
1375
1376 =item Arguments: none
1377
1378 =item Return Value: $pager
1379
1380 =back
1381
1382 Return Value a L<Data::Page> object for the current resultset. Only makes
1383 sense for queries with a C<page> attribute.
1384
1385 =cut
1386
1387 sub pager {
1388   my ($self) = @_;
1389   my $attrs = $self->{attrs};
1390   $self->throw_exception("Can't create pager for non-paged rs")
1391     unless $self->{attrs}{page};
1392   $attrs->{rows} ||= 10;
1393   return $self->{pager} ||= Data::Page->new(
1394     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1395 }
1396
1397 =head2 page
1398
1399 =over 4
1400
1401 =item Arguments: $page_number
1402
1403 =item Return Value: $rs
1404
1405 =back
1406
1407 Returns a resultset for the $page_number page of the resultset on which page
1408 is called, where each page contains a number of rows equal to the 'rows'
1409 attribute set on the resultset (10 by default).
1410
1411 =cut
1412
1413 sub page {
1414   my ($self, $page) = @_;
1415   return (ref $self)->new($self->_source_handle, { %{$self->{attrs}}, page => $page });
1416 }
1417
1418 =head2 new_result
1419
1420 =over 4
1421
1422 =item Arguments: \%vals
1423
1424 =item Return Value: $object
1425
1426 =back
1427
1428 Creates an object in the resultset's result class and returns it.
1429
1430 =cut
1431
1432 sub new_result {
1433   my ($self, $values) = @_;
1434   $self->throw_exception( "new_result needs a hash" )
1435     unless (ref $values eq 'HASH');
1436   $self->throw_exception(
1437     "Can't abstract implicit construct, condition not a hash"
1438   ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1439
1440   my $alias = $self->{attrs}{alias};
1441   my $collapsed_cond = $self->{cond} ? $self->_collapse_cond($self->{cond}) : {};
1442   my %new = (
1443     %{ $self->_remove_alias($values, $alias) },
1444     %{ $self->_remove_alias($collapsed_cond, $alias) },
1445     -source_handle => $self->_source_handle,
1446     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1447   );
1448
1449   return $self->result_class->new(\%new);
1450 }
1451
1452 # _collapse_cond
1453 #
1454 # Recursively collapse the condition.
1455
1456 sub _collapse_cond {
1457   my ($self, $cond, $collapsed) = @_;
1458
1459   $collapsed ||= {};
1460
1461   if (ref $cond eq 'ARRAY') {
1462     foreach my $subcond (@$cond) {
1463       next unless ref $subcond;  # -or
1464 #      warn "ARRAY: " . Dumper $subcond;
1465       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1466     }
1467   }
1468   elsif (ref $cond eq 'HASH') {
1469     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1470       foreach my $subcond (@{$cond->{-and}}) {
1471 #        warn "HASH: " . Dumper $subcond;
1472         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1473       }
1474     }
1475     else {
1476 #      warn "LEAF: " . Dumper $cond;
1477       foreach my $col (keys %$cond) {
1478         my $value = $cond->{$col};
1479         $collapsed->{$col} = $value;
1480       }
1481     }
1482   }
1483
1484   return $collapsed;
1485 }
1486
1487 # _remove_alias
1488 #
1489 # Remove the specified alias from the specified query hash. A copy is made so
1490 # the original query is not modified.
1491
1492 sub _remove_alias {
1493   my ($self, $query, $alias) = @_;
1494
1495   my %orig = %{ $query || {} };
1496   my %unaliased;
1497
1498   foreach my $key (keys %orig) {
1499     if ($key !~ /\./) {
1500       $unaliased{$key} = $orig{$key};
1501       next;
1502     }
1503     $unaliased{$1} = $orig{$key}
1504       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1505   }
1506
1507   return \%unaliased;
1508 }
1509
1510 =head2 find_or_new
1511
1512 =over 4
1513
1514 =item Arguments: \%vals, \%attrs?
1515
1516 =item Return Value: $object
1517
1518 =back
1519
1520 Find an existing record from this resultset. If none exists, instantiate a new
1521 result object and return it. The object will not be saved into your storage
1522 until you call L<DBIx::Class::Row/insert> on it.
1523
1524 If you want objects to be saved immediately, use L</find_or_create> instead.
1525
1526 =cut
1527
1528 sub find_or_new {
1529   my $self     = shift;
1530   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1531   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1532   my $exists   = $self->find($hash, $attrs);
1533   return defined $exists ? $exists : $self->new_result($hash);
1534 }
1535
1536 =head2 create
1537
1538 =over 4
1539
1540 =item Arguments: \%vals
1541
1542 =item Return Value: $object
1543
1544 =back
1545
1546 Inserts a record into the resultset and returns the object representing it.
1547
1548 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1549
1550 =cut
1551
1552 sub create {
1553   my ($self, $attrs) = @_;
1554   $self->throw_exception( "create needs a hashref" )
1555     unless ref $attrs eq 'HASH';
1556   return $self->new_result($attrs)->insert;
1557 }
1558
1559 =head2 find_or_create
1560
1561 =over 4
1562
1563 =item Arguments: \%vals, \%attrs?
1564
1565 =item Return Value: $object
1566
1567 =back
1568
1569   $class->find_or_create({ key => $val, ... });
1570
1571 Tries to find a record based on its primary key or unique constraint; if none
1572 is found, creates one and returns that instead.
1573
1574   my $cd = $schema->resultset('CD')->find_or_create({
1575     cdid   => 5,
1576     artist => 'Massive Attack',
1577     title  => 'Mezzanine',
1578     year   => 2005,
1579   });
1580
1581 Also takes an optional C<key> attribute, to search by a specific key or unique
1582 constraint. For example:
1583
1584   my $cd = $schema->resultset('CD')->find_or_create(
1585     {
1586       artist => 'Massive Attack',
1587       title  => 'Mezzanine',
1588     },
1589     { key => 'cd_artist_title' }
1590   );
1591
1592 See also L</find> and L</update_or_create>. For information on how to declare
1593 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1594
1595 =cut
1596
1597 sub find_or_create {
1598   my $self     = shift;
1599   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1600   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1601   my $exists   = $self->find($hash, $attrs);
1602   return defined $exists ? $exists : $self->create($hash);
1603 }
1604
1605 =head2 update_or_create
1606
1607 =over 4
1608
1609 =item Arguments: \%col_values, { key => $unique_constraint }?
1610
1611 =item Return Value: $object
1612
1613 =back
1614
1615   $class->update_or_create({ col => $val, ... });
1616
1617 First, searches for an existing row matching one of the unique constraints
1618 (including the primary key) on the source of this resultset. If a row is
1619 found, updates it with the other given column values. Otherwise, creates a new
1620 row.
1621
1622 Takes an optional C<key> attribute to search on a specific unique constraint.
1623 For example:
1624
1625   # In your application
1626   my $cd = $schema->resultset('CD')->update_or_create(
1627     {
1628       artist => 'Massive Attack',
1629       title  => 'Mezzanine',
1630       year   => 1998,
1631     },
1632     { key => 'cd_artist_title' }
1633   );
1634
1635 If no C<key> is specified, it searches on all unique constraints defined on the
1636 source, including the primary key.
1637
1638 If the C<key> is specified as C<primary>, it searches only on the primary key.
1639
1640 See also L</find> and L</find_or_create>. For information on how to declare
1641 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1642
1643 =cut
1644
1645 sub update_or_create {
1646   my $self = shift;
1647   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1648   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
1649
1650   my $row = $self->find($cond, $attrs);
1651   if (defined $row) {
1652     $row->update($cond);
1653     return $row;
1654   }
1655
1656   return $self->create($cond);
1657 }
1658
1659 =head2 get_cache
1660
1661 =over 4
1662
1663 =item Arguments: none
1664
1665 =item Return Value: \@cache_objects?
1666
1667 =back
1668
1669 Gets the contents of the cache for the resultset, if the cache is set.
1670
1671 =cut
1672
1673 sub get_cache {
1674   shift->{all_cache};
1675 }
1676
1677 =head2 set_cache
1678
1679 =over 4
1680
1681 =item Arguments: \@cache_objects
1682
1683 =item Return Value: \@cache_objects
1684
1685 =back
1686
1687 Sets the contents of the cache for the resultset. Expects an arrayref
1688 of objects of the same class as those produced by the resultset. Note that
1689 if the cache is set the resultset will return the cached objects rather
1690 than re-querying the database even if the cache attr is not set.
1691
1692 =cut
1693
1694 sub set_cache {
1695   my ( $self, $data ) = @_;
1696   $self->throw_exception("set_cache requires an arrayref")
1697       if defined($data) && (ref $data ne 'ARRAY');
1698   $self->{all_cache} = $data;
1699 }
1700
1701 =head2 clear_cache
1702
1703 =over 4
1704
1705 =item Arguments: none
1706
1707 =item Return Value: []
1708
1709 =back
1710
1711 Clears the cache for the resultset.
1712
1713 =cut
1714
1715 sub clear_cache {
1716   shift->set_cache(undef);
1717 }
1718
1719 =head2 related_resultset
1720
1721 =over 4
1722
1723 =item Arguments: $relationship_name
1724
1725 =item Return Value: $resultset
1726
1727 =back
1728
1729 Returns a related resultset for the supplied relationship name.
1730
1731   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
1732
1733 =cut
1734
1735 sub related_resultset {
1736   my ($self, $rel) = @_;
1737
1738   $self->{related_resultsets} ||= {};
1739   return $self->{related_resultsets}{$rel} ||= do {
1740     my $rel_obj = $self->result_source->relationship_info($rel);
1741
1742     $self->throw_exception(
1743       "search_related: result source '" . $self->_source_handle->source_moniker .
1744         "' has no such relationship $rel")
1745       unless $rel_obj;
1746
1747     my ($from,$seen) = $self->_resolve_from($rel);
1748
1749     my $join_count = $seen->{$rel};
1750     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
1751
1752     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
1753     my %attrs = %{$self->{attrs}||{}};
1754     delete $attrs{result_class};
1755
1756     my $new_cache;
1757
1758     if (my $cache = $self->get_cache) {
1759       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
1760         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
1761                         @$cache ];
1762       }
1763     }
1764
1765     my $new = $self->_source_handle
1766                    ->schema
1767                    ->resultset($rel_obj->{class})
1768                    ->search_rs(
1769                        undef, {
1770                          %attrs,
1771                          join => undef,
1772                          prefetch => undef,
1773                          select => undef,
1774                          as => undef,
1775                          alias => $alias,
1776                          where => $self->{cond},
1777                          seen_join => $seen,
1778                          from => $from,
1779                      });
1780     $new->set_cache($new_cache) if $new_cache;
1781     $new;
1782   };
1783 }
1784
1785 sub _resolve_from {
1786   my ($self, $extra_join) = @_;
1787   my $source = $self->result_source;
1788   my $attrs = $self->{attrs};
1789
1790   my $from = $attrs->{from}
1791     || [ { $attrs->{alias} => $source->from } ];
1792
1793   my $seen = { %{$attrs->{seen_join}||{}} };
1794
1795   my $join = ($attrs->{join}
1796                ? [ $attrs->{join}, $extra_join ]
1797                : $extra_join);
1798
1799   # we need to take the prefetch the attrs into account before we
1800   # ->resolve_join as otherwise they get lost - captainL
1801   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
1802
1803   $from = [
1804     @$from,
1805     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
1806   ];
1807
1808   return ($from,$seen);
1809 }
1810
1811 sub _resolved_attrs {
1812   my $self = shift;
1813   return $self->{_attrs} if $self->{_attrs};
1814
1815   my $attrs = { %{$self->{attrs}||{}} };
1816   my $source = $self->result_source;
1817   my $alias = $attrs->{alias};
1818
1819   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
1820   if ($attrs->{columns}) {
1821     delete $attrs->{as};
1822   } elsif (!$attrs->{select}) {
1823     $attrs->{columns} = [ $source->columns ];
1824   }
1825
1826   $attrs->{select} =
1827     ($attrs->{select}
1828       ? (ref $attrs->{select} eq 'ARRAY'
1829           ? [ @{$attrs->{select}} ]
1830           : [ $attrs->{select} ])
1831       : [ map { m/\./ ? $_ : "${alias}.$_" } @{delete $attrs->{columns}} ]
1832     );
1833   $attrs->{as} =
1834     ($attrs->{as}
1835       ? (ref $attrs->{as} eq 'ARRAY'
1836           ? [ @{$attrs->{as}} ]
1837           : [ $attrs->{as} ])
1838       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{$attrs->{select}} ]
1839     );
1840
1841   my $adds;
1842   if ($adds = delete $attrs->{include_columns}) {
1843     $adds = [$adds] unless ref $adds eq 'ARRAY';
1844     push(@{$attrs->{select}}, @$adds);
1845     push(@{$attrs->{as}}, map { m/([^.]+)$/; $1 } @$adds);
1846   }
1847   if ($adds = delete $attrs->{'+select'}) {
1848     $adds = [$adds] unless ref $adds eq 'ARRAY';
1849     push(@{$attrs->{select}},
1850            map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds);
1851   }
1852   if (my $adds = delete $attrs->{'+as'}) {
1853     $adds = [$adds] unless ref $adds eq 'ARRAY';
1854     push(@{$attrs->{as}}, @$adds);
1855   }
1856
1857   $attrs->{from} ||= [ { 'me' => $source->from } ];
1858
1859   if (exists $attrs->{join} || exists $attrs->{prefetch}) {
1860     my $join = delete $attrs->{join} || {};
1861
1862     if (defined $attrs->{prefetch}) {
1863       $join = $self->_merge_attr(
1864         $join, $attrs->{prefetch}
1865       );
1866
1867     }
1868
1869     $attrs->{from} =   # have to copy here to avoid corrupting the original
1870       [
1871         @{$attrs->{from}},
1872         $source->resolve_join($join, $alias, { %{$attrs->{seen_join}||{}} })
1873       ];
1874
1875   }
1876
1877   $attrs->{group_by} ||= $attrs->{select} if delete $attrs->{distinct};
1878   if ($attrs->{order_by}) {
1879     $attrs->{order_by} = (ref($attrs->{order_by}) eq 'ARRAY'
1880                            ? [ @{$attrs->{order_by}} ]
1881                            : [ $attrs->{order_by} ]);
1882   } else {
1883     $attrs->{order_by} = [];
1884   }
1885
1886   my $collapse = $attrs->{collapse} || {};
1887   if (my $prefetch = delete $attrs->{prefetch}) {
1888     $prefetch = $self->_merge_attr({}, $prefetch);
1889     my @pre_order;
1890     my $seen = $attrs->{seen_join} || {};
1891     foreach my $p (ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch)) {
1892       # bring joins back to level of current class
1893       my @prefetch = $source->resolve_prefetch(
1894         $p, $alias, $seen, \@pre_order, $collapse
1895       );
1896       push(@{$attrs->{select}}, map { $_->[0] } @prefetch);
1897       push(@{$attrs->{as}}, map { $_->[1] } @prefetch);
1898     }
1899     push(@{$attrs->{order_by}}, @pre_order);
1900   }
1901   $attrs->{collapse} = $collapse;
1902
1903   if ($attrs->{page}) {
1904     $attrs->{offset} ||= 0;
1905     $attrs->{offset} += ($attrs->{rows} * ($attrs->{page} - 1));
1906   }
1907
1908   return $self->{_attrs} = $attrs;
1909 }
1910
1911 sub _rollout_attr {
1912   my ($self, $attr) = @_;
1913
1914   if (ref $attr eq 'HASH') {
1915     return $self->_rollout_hash($attr);
1916   } elsif (ref $attr eq 'ARRAY') {
1917     return $self->_rollout_array($attr);
1918   } else {
1919     return [$attr];
1920   }
1921 }
1922
1923 sub _rollout_array {
1924   my ($self, $attr) = @_;
1925
1926   my @rolled_array;
1927   foreach my $element (@{$attr}) {
1928     if (ref $element eq 'HASH') {
1929       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
1930     } elsif (ref $element eq 'ARRAY') {
1931       #  XXX - should probably recurse here
1932       push( @rolled_array, @{$self->_rollout_array($element)} );
1933     } else {
1934       push( @rolled_array, $element );
1935     }
1936   }
1937   return \@rolled_array;
1938 }
1939
1940 sub _rollout_hash {
1941   my ($self, $attr) = @_;
1942
1943   my @rolled_array;
1944   foreach my $key (keys %{$attr}) {
1945     push( @rolled_array, { $key => $attr->{$key} } );
1946   }
1947   return \@rolled_array;
1948 }
1949
1950 sub _calculate_score {
1951   my ($self, $a, $b) = @_;
1952
1953   if (ref $b eq 'HASH') {
1954     my ($b_key) = keys %{$b};
1955     if (ref $a eq 'HASH') {
1956       my ($a_key) = keys %{$a};
1957       if ($a_key eq $b_key) {
1958         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
1959       } else {
1960         return 0;
1961       }
1962     } else {
1963       return ($a eq $b_key) ? 1 : 0;
1964     }
1965   } else {
1966     if (ref $a eq 'HASH') {
1967       my ($a_key) = keys %{$a};
1968       return ($b eq $a_key) ? 1 : 0;
1969     } else {
1970       return ($b eq $a) ? 1 : 0;
1971     }
1972   }
1973 }
1974
1975 sub _merge_attr {
1976   my ($self, $a, $b) = @_;
1977
1978   return $b unless defined($a);
1979   return $a unless defined($b);
1980
1981   $a = $self->_rollout_attr($a);
1982   $b = $self->_rollout_attr($b);
1983
1984   my $seen_keys;
1985   foreach my $b_element ( @{$b} ) {
1986     # find best candidate from $a to merge $b_element into
1987     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
1988     foreach my $a_element ( @{$a} ) {
1989       my $score = $self->_calculate_score( $a_element, $b_element );
1990       if ($score > $best_candidate->{score}) {
1991         $best_candidate->{position} = $position;
1992         $best_candidate->{score} = $score;
1993       }
1994       $position++;
1995     }
1996     my ($b_key) = ( ref $b_element eq 'HASH' ) ? keys %{$b_element} : ($b_element);
1997     if ($best_candidate->{score} == 0 || exists $seen_keys->{$b_key}) {
1998       push( @{$a}, $b_element );
1999     } else {
2000       $seen_keys->{$b_key} = 1; # don't merge the same key twice
2001       my $a_best = $a->[$best_candidate->{position}];
2002       # merge a_best and b_element together and replace original with merged
2003       if (ref $a_best ne 'HASH') {
2004         $a->[$best_candidate->{position}] = $b_element;
2005       } elsif (ref $b_element eq 'HASH') {
2006         my ($key) = keys %{$a_best};
2007         $a->[$best_candidate->{position}] = { $key => $self->_merge_attr($a_best->{$key}, $b_element->{$key}) };
2008       }
2009     }
2010   }
2011
2012   return $a;
2013 }
2014
2015 sub result_source {
2016     my $self = shift;
2017
2018     if (@_) {
2019         $self->_source_handle($_[0]->handle);
2020     } else {
2021         $self->_source_handle->resolve;
2022     }
2023 }
2024
2025 =head2 throw_exception
2026
2027 See L<DBIx::Class::Schema/throw_exception> for details.
2028
2029 =cut
2030
2031 sub throw_exception {
2032   my $self=shift;
2033   $self->_source_handle->schema->throw_exception(@_);
2034 }
2035
2036 # XXX: FIXME: Attributes docs need clearing up
2037
2038 =head1 ATTRIBUTES
2039
2040 The resultset takes various attributes that modify its behavior. Here's an
2041 overview of them:
2042
2043 =head2 order_by
2044
2045 =over 4
2046
2047 =item Value: ($order_by | \@order_by)
2048
2049 =back
2050
2051 Which column(s) to order the results by. This is currently passed
2052 through directly to SQL, so you can give e.g. C<year DESC> for a
2053 descending order on the column `year'.
2054
2055 Please note that if you have C<quote_char> enabled (see
2056 L<DBIx::Class::Storage::DBI/connect_info>) you will need to do C<\'year DESC' > to
2057 specify an order. (The scalar ref causes it to be passed as raw sql to the DB,
2058 so you will need to manually quote things as appropriate.)
2059
2060 =head2 columns
2061
2062 =over 4
2063
2064 =item Value: \@columns
2065
2066 =back
2067
2068 Shortcut to request a particular set of columns to be retrieved.  Adds
2069 C<me.> onto the start of any column without a C<.> in it and sets C<select>
2070 from that, then auto-populates C<as> from C<select> as normal. (You may also
2071 use the C<cols> attribute, as in earlier versions of DBIC.)
2072
2073 =head2 include_columns
2074
2075 =over 4
2076
2077 =item Value: \@columns
2078
2079 =back
2080
2081 Shortcut to include additional columns in the returned results - for example
2082
2083   $schema->resultset('CD')->search(undef, {
2084     include_columns => ['artist.name'],
2085     join => ['artist']
2086   });
2087
2088 would return all CDs and include a 'name' column to the information
2089 passed to object inflation. Note that the 'artist' is the name of the
2090 column (or relationship) accessor, and 'name' is the name of the column
2091 accessor in the related table.
2092
2093 =head2 select
2094
2095 =over 4
2096
2097 =item Value: \@select_columns
2098
2099 =back
2100
2101 Indicates which columns should be selected from the storage. You can use
2102 column names, or in the case of RDBMS back ends, function or stored procedure
2103 names:
2104
2105   $rs = $schema->resultset('Employee')->search(undef, {
2106     select => [
2107       'name',
2108       { count => 'employeeid' },
2109       { sum => 'salary' }
2110     ]
2111   });
2112
2113 When you use function/stored procedure names and do not supply an C<as>
2114 attribute, the column names returned are storage-dependent. E.g. MySQL would
2115 return a column named C<count(employeeid)> in the above example.
2116
2117 =head2 +select
2118
2119 =over 4
2120
2121 Indicates additional columns to be selected from storage.  Works the same as
2122 L<select> but adds columns to the selection.
2123
2124 =back
2125
2126 =head2 +as
2127
2128 =over 4
2129
2130 Indicates additional column names for those added via L<+select>.
2131
2132 =back
2133
2134 =head2 as
2135
2136 =over 4
2137
2138 =item Value: \@inflation_names
2139
2140 =back
2141
2142 Indicates column names for object inflation. That is, c< as >
2143 indicates the name that the column can be accessed as via the
2144 C<get_column> method (or via the object accessor, B<if one already
2145 exists>).  It has nothing to do with the SQL code C< SELECT foo AS bar
2146 >.
2147
2148 The C< as > attribute is used in conjunction with C<select>,
2149 usually when C<select> contains one or more function or stored
2150 procedure names:
2151
2152   $rs = $schema->resultset('Employee')->search(undef, {
2153     select => [
2154       'name',
2155       { count => 'employeeid' }
2156     ],
2157     as => ['name', 'employee_count'],
2158   });
2159
2160   my $employee = $rs->first(); # get the first Employee
2161
2162 If the object against which the search is performed already has an accessor
2163 matching a column name specified in C<as>, the value can be retrieved using
2164 the accessor as normal:
2165
2166   my $name = $employee->name();
2167
2168 If on the other hand an accessor does not exist in the object, you need to
2169 use C<get_column> instead:
2170
2171   my $employee_count = $employee->get_column('employee_count');
2172
2173 You can create your own accessors if required - see
2174 L<DBIx::Class::Manual::Cookbook> for details.
2175
2176 Please note: This will NOT insert an C<AS employee_count> into the SQL
2177 statement produced, it is used for internal access only. Thus
2178 attempting to use the accessor in an C<order_by> clause or similar
2179 will fail miserably.
2180
2181 To get around this limitation, you can supply literal SQL to your
2182 C<select> attibute that contains the C<AS alias> text, eg:
2183
2184   select => [\'myfield AS alias']
2185
2186 =head2 join
2187
2188 =over 4
2189
2190 =item Value: ($rel_name | \@rel_names | \%rel_names)
2191
2192 =back
2193
2194 Contains a list of relationships that should be joined for this query.  For
2195 example:
2196
2197   # Get CDs by Nine Inch Nails
2198   my $rs = $schema->resultset('CD')->search(
2199     { 'artist.name' => 'Nine Inch Nails' },
2200     { join => 'artist' }
2201   );
2202
2203 Can also contain a hash reference to refer to the other relation's relations.
2204 For example:
2205
2206   package MyApp::Schema::Track;
2207   use base qw/DBIx::Class/;
2208   __PACKAGE__->table('track');
2209   __PACKAGE__->add_columns(qw/trackid cd position title/);
2210   __PACKAGE__->set_primary_key('trackid');
2211   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2212   1;
2213
2214   # In your application
2215   my $rs = $schema->resultset('Artist')->search(
2216     { 'track.title' => 'Teardrop' },
2217     {
2218       join     => { cd => 'track' },
2219       order_by => 'artist.name',
2220     }
2221   );
2222
2223 You need to use the relationship (not the table) name in  conditions,
2224 because they are aliased as such. The current table is aliased as "me", so
2225 you need to use me.column_name in order to avoid ambiguity. For example:
2226
2227   # Get CDs from 1984 with a 'Foo' track
2228   my $rs = $schema->resultset('CD')->search(
2229     {
2230       'me.year' => 1984,
2231       'tracks.name' => 'Foo'
2232     },
2233     { join => 'tracks' }
2234   );
2235
2236 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2237 similarly for a third time). For e.g.
2238
2239   my $rs = $schema->resultset('Artist')->search({
2240     'cds.title'   => 'Down to Earth',
2241     'cds_2.title' => 'Popular',
2242   }, {
2243     join => [ qw/cds cds/ ],
2244   });
2245
2246 will return a set of all artists that have both a cd with title 'Down
2247 to Earth' and a cd with title 'Popular'.
2248
2249 If you want to fetch related objects from other tables as well, see C<prefetch>
2250 below.
2251
2252 =head2 prefetch
2253
2254 =over 4
2255
2256 =item Value: ($rel_name | \@rel_names | \%rel_names)
2257
2258 =back
2259
2260 Contains one or more relationships that should be fetched along with the main
2261 query (when they are accessed afterwards they will have already been
2262 "prefetched").  This is useful for when you know you will need the related
2263 objects, because it saves at least one query:
2264
2265   my $rs = $schema->resultset('Tag')->search(
2266     undef,
2267     {
2268       prefetch => {
2269         cd => 'artist'
2270       }
2271     }
2272   );
2273
2274 The initial search results in SQL like the following:
2275
2276   SELECT tag.*, cd.*, artist.* FROM tag
2277   JOIN cd ON tag.cd = cd.cdid
2278   JOIN artist ON cd.artist = artist.artistid
2279
2280 L<DBIx::Class> has no need to go back to the database when we access the
2281 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2282 case.
2283
2284 Simple prefetches will be joined automatically, so there is no need
2285 for a C<join> attribute in the above search. If you're prefetching to
2286 depth (e.g. { cd => { artist => 'label' } or similar), you'll need to
2287 specify the join as well.
2288
2289 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2290 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2291 with an accessor type of 'single' or 'filter').
2292
2293 =head2 page
2294
2295 =over 4
2296
2297 =item Value: $page
2298
2299 =back
2300
2301 Makes the resultset paged and specifies the page to retrieve. Effectively
2302 identical to creating a non-pages resultset and then calling ->page($page)
2303 on it.
2304
2305 If L<rows> attribute is not specified it defualts to 10 rows per page.
2306
2307 =head2 rows
2308
2309 =over 4
2310
2311 =item Value: $rows
2312
2313 =back
2314
2315 Specifes the maximum number of rows for direct retrieval or the number of
2316 rows per page if the page attribute or method is used.
2317
2318 =head2 offset
2319
2320 =over 4
2321
2322 =item Value: $offset
2323
2324 =back
2325
2326 Specifies the (zero-based) row number for the  first row to be returned, or the
2327 of the first row of the first page if paging is used.
2328
2329 =head2 group_by
2330
2331 =over 4
2332
2333 =item Value: \@columns
2334
2335 =back
2336
2337 A arrayref of columns to group by. Can include columns of joined tables.
2338
2339   group_by => [qw/ column1 column2 ... /]
2340
2341 =head2 having
2342
2343 =over 4
2344
2345 =item Value: $condition
2346
2347 =back
2348
2349 HAVING is a select statement attribute that is applied between GROUP BY and
2350 ORDER BY. It is applied to the after the grouping calculations have been
2351 done.
2352
2353   having => { 'count(employee)' => { '>=', 100 } }
2354
2355 =head2 distinct
2356
2357 =over 4
2358
2359 =item Value: (0 | 1)
2360
2361 =back
2362
2363 Set to 1 to group by all columns.
2364
2365 =head2 where
2366
2367 =over 4
2368
2369 Adds to the WHERE clause.
2370
2371   # only return rows WHERE deleted IS NULL for all searches
2372   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2373
2374 Can be overridden by passing C<{ where => undef }> as an attribute
2375 to a resulset.
2376
2377 =back
2378
2379 =head2 cache
2380
2381 Set to 1 to cache search results. This prevents extra SQL queries if you
2382 revisit rows in your ResultSet:
2383
2384   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2385
2386   while( my $artist = $resultset->next ) {
2387     ... do stuff ...
2388   }
2389
2390   $rs->first; # without cache, this would issue a query
2391
2392 By default, searches are not cached.
2393
2394 For more examples of using these attributes, see
2395 L<DBIx::Class::Manual::Cookbook>.
2396
2397 =head2 from
2398
2399 =over 4
2400
2401 =item Value: \@from_clause
2402
2403 =back
2404
2405 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2406 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2407 clauses.
2408
2409 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
2410
2411 C<join> will usually do what you need and it is strongly recommended that you
2412 avoid using C<from> unless you cannot achieve the desired result using C<join>.
2413 And we really do mean "cannot", not just tried and failed. Attempting to use
2414 this because you're having problems with C<join> is like trying to use x86
2415 ASM because you've got a syntax error in your C. Trust us on this.
2416
2417 Now, if you're still really, really sure you need to use this (and if you're
2418 not 100% sure, ask the mailing list first), here's an explanation of how this
2419 works.
2420
2421 The syntax is as follows -
2422
2423   [
2424     { <alias1> => <table1> },
2425     [
2426       { <alias2> => <table2>, -join_type => 'inner|left|right' },
2427       [], # nested JOIN (optional)
2428       { <table1.column1> => <table2.column2>, ... (more conditions) },
2429     ],
2430     # More of the above [ ] may follow for additional joins
2431   ]
2432
2433   <table1> <alias1>
2434   JOIN
2435     <table2> <alias2>
2436     [JOIN ...]
2437   ON <table1.column1> = <table2.column2>
2438   <more joins may follow>
2439
2440 An easy way to follow the examples below is to remember the following:
2441
2442     Anything inside "[]" is a JOIN
2443     Anything inside "{}" is a condition for the enclosing JOIN
2444
2445 The following examples utilize a "person" table in a family tree application.
2446 In order to express parent->child relationships, this table is self-joined:
2447
2448     # Person->belongs_to('father' => 'Person');
2449     # Person->belongs_to('mother' => 'Person');
2450
2451 C<from> can be used to nest joins. Here we return all children with a father,
2452 then search against all mothers of those children:
2453
2454   $rs = $schema->resultset('Person')->search(
2455       undef,
2456       {
2457           alias => 'mother', # alias columns in accordance with "from"
2458           from => [
2459               { mother => 'person' },
2460               [
2461                   [
2462                       { child => 'person' },
2463                       [
2464                           { father => 'person' },
2465                           { 'father.person_id' => 'child.father_id' }
2466                       ]
2467                   ],
2468                   { 'mother.person_id' => 'child.mother_id' }
2469               ],
2470           ]
2471       },
2472   );
2473
2474   # Equivalent SQL:
2475   # SELECT mother.* FROM person mother
2476   # JOIN (
2477   #   person child
2478   #   JOIN person father
2479   #   ON ( father.person_id = child.father_id )
2480   # )
2481   # ON ( mother.person_id = child.mother_id )
2482
2483 The type of any join can be controlled manually. To search against only people
2484 with a father in the person table, we could explicitly use C<INNER JOIN>:
2485
2486     $rs = $schema->resultset('Person')->search(
2487         undef,
2488         {
2489             alias => 'child', # alias columns in accordance with "from"
2490             from => [
2491                 { child => 'person' },
2492                 [
2493                     { father => 'person', -join_type => 'inner' },
2494                     { 'father.id' => 'child.father_id' }
2495                 ],
2496             ]
2497         },
2498     );
2499
2500     # Equivalent SQL:
2501     # SELECT child.* FROM person child
2502     # INNER JOIN person father ON child.father_id = father.id
2503
2504 =cut
2505
2506 1;