lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my (@unique_queries, %seen_column_combinations);
 574   foreach my $name (@constraint_names) {
 575     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 576
 577     my $constraint_sig = join "\x00", sort @constraint_cols;
 578     next if $seen_column_combinations{$constraint_sig}++;
 579
 580     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 581
 582     my $num_cols = scalar @constraint_cols;
 583     my $num_query = scalar keys %$unique_query;
 584
 585     my $total = $num_query + $num_where;
 586     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 587       # The query is either unique on its own or is unique in combination with
 588       # the existing where clause
 589       push @unique_queries, $unique_query;
 590     }
 591   }
 592
 593   return @unique_queries;
 594 }
 595
 596 # _build_unique_query
 597 #
 598 # Constrain the specified query hash based on the specified column names.
 599
 600 sub _build_unique_query {
 601   my ($self, $query, $unique_cols) = @_;
 602
 603   return {
 604     map  { $_ => $query->{$_} }
 605     grep { exists $query->{$_} }
 606       @$unique_cols
 607   };
 608 }
 609
 610 =head2 search_related
 611
 612 =over 4
 613
 614 =item Arguments: $rel, $cond, \%attrs?
 615
 616 =item Return Value: $new_resultset
 617
 618 =back
 619
 620   $new_rs = $cd_rs->search_related('artist', {
 621     name => 'Emo-R-Us',
 622   });
 623
 624 Searches the specified relationship, optionally specifying a condition and
 625 attributes for matching records. See L</ATTRIBUTES> for more information.
 626
 627 =cut
 628
 629 sub search_related {
 630   return shift->related_resultset(shift)->search(@_);
 631 }
 632
 633 =head2 search_related_rs
 634
 635 This method works exactly the same as search_related, except that
 636 it guarantees a restultset, even in list context.
 637
 638 =cut
 639
 640 sub search_related_rs {
 641   return shift->related_resultset(shift)->search_rs(@_);
 642 }
 643
 644 =head2 cursor
 645
 646 =over 4
 647
 648 =item Arguments: none
 649
 650 =item Return Value: $cursor
 651
 652 =back
 653
 654 Returns a storage-driven cursor to the given resultset. See
 655 L<DBIx::Class::Cursor> for more information.
 656
 657 =cut
 658
 659 sub cursor {
 660   my ($self) = @_;
 661
 662   my $attrs = $self->_resolved_attrs_copy;
 663
 664   return $self->{cursor}
 665     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 666           $attrs->{where},$attrs);
 667 }
 668
 669 =head2 single
 670
 671 =over 4
 672
 673 =item Arguments: $cond?
 674
 675 =item Return Value: $row_object?
 676
 677 =back
 678
 679   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 680
 681 Inflates the first result without creating a cursor if the resultset has
 682 any records in it; if not returns nothing. Used by L</find> as a lean version of
 683 L</search>.
 684
 685 While this method can take an optional search condition (just like L</search>)
 686 being a fast-code-path it does not recognize search attributes. If you need to
 687 add extra joins or similar, call L</search> and then chain-call L</single> on the
 688 L<DBIx::Class::ResultSet> returned.
 689
 690 =over
 691
 692 =item B<Note>
 693
 694 As of 0.08100, this method enforces the assumption that the preceeding
 695 query returns only one row. If more than one row is returned, you will receive
 696 a warning:
 697
 698   Query returned more than one row
 699
 700 In this case, you should be using L</next> or L</find> instead, or if you really
 701 know what you are doing, use the L</rows> attribute to explicitly limit the size
 702 of the resultset.
 703
 704 This method will also throw an exception if it is called on a resultset prefetching
 705 has_many, as such a prefetch implies fetching multiple rows from the database in
 706 order to assemble the resulting object.
 707
 708 =back
 709
 710 =cut
 711
 712 sub single {
 713   my ($self, $where) = @_;
 714   if(@_ > 2) {
 715       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 716   }
 717
 718   my $attrs = $self->_resolved_attrs_copy;
 719
 720   if (keys %{$attrs->{collapse}}) {
 721     $self->throw_exception(
 722       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 723     );
 724   }
 725
 726   if ($where) {
 727     if (defined $attrs->{where}) {
 728       $attrs->{where} = {
 729         '-and' =>
 730             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 731                $where, delete $attrs->{where} ]
 732       };
 733     } else {
 734       $attrs->{where} = $where;
 735     }
 736   }
 737
 738 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 739 #  unless ($self->_is_unique_query($attrs->{where})) {
 740 #    carp "Query not guaranteed to return a single row"
 741 #      . "; please declare your unique constraints or use search instead";
 742 #  }
 743
 744   my @data = $self->result_source->storage->select_single(
 745     $attrs->{from}, $attrs->{select},
 746     $attrs->{where}, $attrs
 747   );
 748
 749   return (@data ? ($self->_construct_object(@data))[0] : undef);
 750 }
 751
 752
 753 # _is_unique_query
 754 #
 755 # Try to determine if the specified query is guaranteed to be unique, based on
 756 # the declared unique constraints.
 757
 758 sub _is_unique_query {
 759   my ($self, $query) = @_;
 760
 761   my $collapsed = $self->_collapse_query($query);
 762   my $alias = $self->{attrs}{alias};
 763
 764   foreach my $name ($self->result_source->unique_constraint_names) {
 765     my @unique_cols = map {
 766       "$alias.$_"
 767     } $self->result_source->unique_constraint_columns($name);
 768
 769     # Count the values for each unique column
 770     my %seen = map { $_ => 0 } @unique_cols;
 771
 772     foreach my $key (keys %$collapsed) {
 773       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 774       next unless exists $seen{$aliased};  # Additional constraints are okay
 775       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 776     }
 777
 778     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 779     return 1 unless grep { $_ != 1 } values %seen;
 780   }
 781
 782   return 0;
 783 }
 784
 785 # _collapse_query
 786 #
 787 # Recursively collapse the query, accumulating values for each column.
 788
 789 sub _collapse_query {
 790   my ($self, $query, $collapsed) = @_;
 791
 792   $collapsed ||= {};
 793
 794   if (ref $query eq 'ARRAY') {
 795     foreach my $subquery (@$query) {
 796       next unless ref $subquery;  # -or
 797       $collapsed = $self->_collapse_query($subquery, $collapsed);
 798     }
 799   }
 800   elsif (ref $query eq 'HASH') {
 801     if (keys %$query and (keys %$query)[0] eq '-and') {
 802       foreach my $subquery (@{$query->{-and}}) {
 803         $collapsed = $self->_collapse_query($subquery, $collapsed);
 804       }
 805     }
 806     else {
 807       foreach my $col (keys %$query) {
 808         my $value = $query->{$col};
 809         $collapsed->{$col}{$value}++;
 810       }
 811     }
 812   }
 813
 814   return $collapsed;
 815 }
 816
 817 =head2 get_column
 818
 819 =over 4
 820
 821 =item Arguments: $cond?
 822
 823 =item Return Value: $resultsetcolumn
 824
 825 =back
 826
 827   my $max_length = $rs->get_column('length')->max;
 828
 829 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 830
 831 =cut
 832
 833 sub get_column {
 834   my ($self, $column) = @_;
 835   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 836   return $new;
 837 }
 838
 839 =head2 search_like
 840
 841 =over 4
 842
 843 =item Arguments: $cond, \%attrs?
 844
 845 =item Return Value: $resultset (scalar context), @row_objs (list context)
 846
 847 =back
 848
 849   # WHERE title LIKE '%blue%'
 850   $cd_rs = $rs->search_like({ title => '%blue%'});
 851
 852 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 853 that this is simply a convenience method retained for ex Class::DBI users.
 854 You most likely want to use L</search> with specific operators.
 855
 856 For more information, see L<DBIx::Class::Manual::Cookbook>.
 857
 858 This method is deprecated and will be removed in 0.09. Use L</search()>
 859 instead. An example conversion is:
 860
 861   ->search_like({ foo => 'bar' });
 862
 863   # Becomes
 864
 865   ->search({ foo => { like => 'bar' } });
 866
 867 =cut
 868
 869 sub search_like {
 870   my $class = shift;
 871   carp (
 872     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 873    .' Instead use ->search({ x => { -like => "y%" } })'
 874    .' (note the outer pair of {}s - they are important!)'
 875   );
 876   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 877   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 878   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 879   return $class->search($query, { %$attrs });
 880 }
 881
 882 =head2 slice
 883
 884 =over 4
 885
 886 =item Arguments: $first, $last
 887
 888 =item Return Value: $resultset (scalar context), @row_objs (list context)
 889
 890 =back
 891
 892 Returns a resultset or object list representing a subset of elements from the
 893 resultset slice is called on. Indexes are from 0, i.e., to get the first
 894 three records, call:
 895
 896   my ($one, $two, $three) = $rs->slice(0, 2);
 897
 898 =cut
 899
 900 sub slice {
 901   my ($self, $min, $max) = @_;
 902   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 903   $attrs->{offset} = $self->{attrs}{offset} || 0;
 904   $attrs->{offset} += $min;
 905   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 906   return $self->search(undef(), $attrs);
 907   #my $slice = (ref $self)->new($self->result_source, $attrs);
 908   #return (wantarray ? $slice->all : $slice);
 909 }
 910
 911 =head2 next
 912
 913 =over 4
 914
 915 =item Arguments: none
 916
 917 =item Return Value: $result?
 918
 919 =back
 920
 921 Returns the next element in the resultset (C<undef> is there is none).
 922
 923 Can be used to efficiently iterate over records in the resultset:
 924
 925   my $rs = $schema->resultset('CD')->search;
 926   while (my $cd = $rs->next) {
 927     print $cd->title;
 928   }
 929
 930 Note that you need to store the resultset object, and call C<next> on it.
 931 Calling C<< resultset('Table')->next >> repeatedly will always return the
 932 first record from the resultset.
 933
 934 =cut
 935
 936 sub next {
 937   my ($self) = @_;
 938   if (my $cache = $self->get_cache) {
 939     $self->{all_cache_position} ||= 0;
 940     return $cache->[$self->{all_cache_position}++];
 941   }
 942   if ($self->{attrs}{cache}) {
 943     $self->{all_cache_position} = 1;
 944     return ($self->all)[0];
 945   }
 946   if ($self->{stashed_objects}) {
 947     my $obj = shift(@{$self->{stashed_objects}});
 948     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 949     return $obj;
 950   }
 951   my @row = (
 952     exists $self->{stashed_row}
 953       ? @{delete $self->{stashed_row}}
 954       : $self->cursor->next
 955   );
 956   return undef unless (@row);
 957   my ($row, @more) = $self->_construct_object(@row);
 958   $self->{stashed_objects} = \@more if @more;
 959   return $row;
 960 }
 961
 962 sub _construct_object {
 963   my ($self, @row) = @_;
 964
 965   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 966     or return ();
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   # if the first row that ever came in is totally empty - this means we got
 977   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 978   # instead of producing a {}
 979   #
 980   my $has_def;
 981   for (@$row) {
 982     if (defined $_) {
 983       $has_def++;
 984       last;
 985     }
 986   }
 987   return undef unless $has_def;
 988
 989   my @copy = @$row;
 990
 991   # 'foo'         => [ undef, 'foo' ]
 992   # 'foo.bar'     => [ 'foo', 'bar' ]
 993   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 994
 995   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 996
 997   my %collapse = %{$self->{_attrs}{collapse}||{}};
 998
 999   my @pri_index;
1000
1001   # if we're doing collapsing (has_many prefetch) we need to grab records
1002   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1003   # we know we don't have to bother.
1004
1005   # the reason for not using the collapse stuff directly is because if you
1006   # had for e.g. two artists in a row with no cds, the collapse info for
1007   # both would be NULL (undef) so you'd lose the second artist
1008
1009   # store just the index so we can check the array positions from the row
1010   # without having to contruct the full hash
1011
1012   if (keys %collapse) {
1013     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1014     foreach my $i (0 .. $#construct_as) {
1015       next if defined($construct_as[$i][0]); # only self table
1016       if (delete $pri{$construct_as[$i][1]}) {
1017         push(@pri_index, $i);
1018       }
1019       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1020     }
1021   }
1022
1023   # no need to do an if, it'll be empty if @pri_index is empty anyway
1024
1025   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1026
1027   my @const_rows;
1028
1029   do { # no need to check anything at the front, we always want the first row
1030
1031     my %const;
1032
1033     foreach my $this_as (@construct_as) {
1034       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1035     }
1036
1037     push(@const_rows, \%const);
1038
1039   } until ( # no pri_index => no collapse => drop straight out
1040       !@pri_index
1041     or
1042       do { # get another row, stash it, drop out if different PK
1043
1044         @copy = $self->cursor->next;
1045         $self->{stashed_row} = \@copy;
1046
1047         # last thing in do block, counts as true if anything doesn't match
1048
1049         # check xor defined first for NULL vs. NOT NULL then if one is
1050         # defined the other must be so check string equality
1051
1052         grep {
1053           (defined $pri_vals{$_} ^ defined $copy[$_])
1054           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1055         } @pri_index;
1056       }
1057   );
1058
1059   my $alias = $self->{attrs}{alias};
1060   my $info = [];
1061
1062   my %collapse_pos;
1063
1064   my @const_keys;
1065
1066   foreach my $const (@const_rows) {
1067     scalar @const_keys or do {
1068       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1069     };
1070     foreach my $key (@const_keys) {
1071       if (length $key) {
1072         my $target = $info;
1073         my @parts = split(/\./, $key);
1074         my $cur = '';
1075         my $data = $const->{$key};
1076         foreach my $p (@parts) {
1077           $target = $target->[1]->{$p} ||= [];
1078           $cur .= ".${p}";
1079           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1080             # collapsing at this point and on final part
1081             my $pos = $collapse_pos{$cur};
1082             CK: foreach my $ck (@ckey) {
1083               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1084                 $collapse_pos{$cur} = $data;
1085                 delete @collapse_pos{ # clear all positioning for sub-entries
1086                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1087                 };
1088                 push(@$target, []);
1089                 last CK;
1090               }
1091             }
1092           }
1093           if (exists $collapse{$cur}) {
1094             $target = $target->[-1];
1095           }
1096         }
1097         $target->[0] = $data;
1098       } else {
1099         $info->[0] = $const->{$key};
1100       }
1101     }
1102   }
1103
1104   return $info;
1105 }
1106
1107 =head2 result_source
1108
1109 =over 4
1110
1111 =item Arguments: $result_source?
1112
1113 =item Return Value: $result_source
1114
1115 =back
1116
1117 An accessor for the primary ResultSource object from which this ResultSet
1118 is derived.
1119
1120 =head2 result_class
1121
1122 =over 4
1123
1124 =item Arguments: $result_class?
1125
1126 =item Return Value: $result_class
1127
1128 =back
1129
1130 An accessor for the class to use when creating row objects. Defaults to
1131 C<< result_source->result_class >> - which in most cases is the name of the
1132 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1133
1134 Note that changing the result_class will also remove any components
1135 that were originally loaded in the source class via
1136 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1137 in the original source class will not run.
1138
1139 =cut
1140
1141 sub result_class {
1142   my ($self, $result_class) = @_;
1143   if ($result_class) {
1144     $self->ensure_class_loaded($result_class);
1145     $self->_result_class($result_class);
1146   }
1147   $self->_result_class;
1148 }
1149
1150 =head2 count
1151
1152 =over 4
1153
1154 =item Arguments: $cond, \%attrs??
1155
1156 =item Return Value: $count
1157
1158 =back
1159
1160 Performs an SQL C<COUNT> with the same query as the resultset was built
1161 with to find the number of elements. Passing arguments is equivalent to
1162 C<< $rs->search ($cond, \%attrs)->count >>
1163
1164 =cut
1165
1166 sub count {
1167   my $self = shift;
1168   return $self->search(@_)->count if @_ and defined $_[0];
1169   return scalar @{ $self->get_cache } if $self->get_cache;
1170
1171   my $attrs = $self->_resolved_attrs_copy;
1172
1173   # this is a little optimization - it is faster to do the limit
1174   # adjustments in software, instead of a subquery
1175   my $rows = delete $attrs->{rows};
1176   my $offset = delete $attrs->{offset};
1177
1178   my $crs;
1179   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1180     $crs = $self->_count_subq_rs ($attrs);
1181   }
1182   else {
1183     $crs = $self->_count_rs ($attrs);
1184   }
1185   my $count = $crs->next;
1186
1187   $count -= $offset if $offset;
1188   $count = $rows if $rows and $rows < $count;
1189   $count = 0 if ($count < 0);
1190
1191   return $count;
1192 }
1193
1194 =head2 count_rs
1195
1196 =over 4
1197
1198 =item Arguments: $cond, \%attrs??
1199
1200 =item Return Value: $count_rs
1201
1202 =back
1203
1204 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1205 This can be very handy for subqueries:
1206
1207   ->search( { amount => $some_rs->count_rs->as_query } )
1208
1209 As with regular resultsets the SQL query will be executed only after
1210 the resultset is accessed via L</next> or L</all>. That would return
1211 the same single value obtainable via L</count>.
1212
1213 =cut
1214
1215 sub count_rs {
1216   my $self = shift;
1217   return $self->search(@_)->count_rs if @_;
1218
1219   # this may look like a lack of abstraction (count() does about the same)
1220   # but in fact an _rs *must* use a subquery for the limits, as the
1221   # software based limiting can not be ported if this $rs is to be used
1222   # in a subquery itself (i.e. ->as_query)
1223   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1224     return $self->_count_subq_rs;
1225   }
1226   else {
1227     return $self->_count_rs;
1228   }
1229 }
1230
1231 #
1232 # returns a ResultSetColumn object tied to the count query
1233 #
1234 sub _count_rs {
1235   my ($self, $attrs) = @_;
1236
1237   my $rsrc = $self->result_source;
1238   $attrs ||= $self->_resolved_attrs;
1239
1240   my $tmp_attrs = { %$attrs };
1241
1242   # take off any limits, record_filter is cdbi, and no point of ordering a count
1243   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1244
1245   # overwrite the selector (supplied by the storage)
1246   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1247   $tmp_attrs->{as} = 'count';
1248
1249   # read the comment on top of the actual function to see what this does
1250   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1251     $tmp_attrs->{from}, $tmp_attrs->{alias}
1252   );
1253
1254   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1255
1256   return $tmp_rs;
1257 }
1258
1259 #
1260 # same as above but uses a subquery
1261 #
1262 sub _count_subq_rs {
1263   my ($self, $attrs) = @_;
1264
1265   my $rsrc = $self->result_source;
1266   $attrs ||= $self->_resolved_attrs_copy;
1267
1268   my $sub_attrs = { %$attrs };
1269
1270   # extra selectors do not go in the subquery and there is no point of ordering it
1271   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1272
1273   # if we prefetch, we group_by primary keys only as this is what we would get out
1274   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1275   if ( keys %{$attrs->{collapse}} ) {
1276     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1277   }
1278
1279   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1280
1281   # read the comment on top of the actual function to see what this does
1282   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1283     $sub_attrs->{from}, $sub_attrs->{alias}
1284   );
1285
1286   # this is so that ordering can be thrown away in things like Top limit
1287   $sub_attrs->{-for_count_only} = 1;
1288
1289   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1290
1291   $attrs->{from} = [{
1292     -alias => 'count_subq',
1293     -source_handle => $rsrc->handle,
1294     count_subq => $sub_rs->as_query,
1295   }];
1296
1297   # the subquery replaces this
1298   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1299
1300   return $self->_count_rs ($attrs);
1301 }
1302
1303
1304 # The DBIC relationship chaining implementation is pretty simple - every
1305 # new related_relationship is pushed onto the {from} stack, and the {select}
1306 # window simply slides further in. This means that when we count somewhere
1307 # in the middle, we got to make sure that everything in the join chain is an
1308 # actual inner join, otherwise the count will come back with unpredictable
1309 # results (a resultset may be generated with _some_ rows regardless of if
1310 # the relation which the $rs currently selects has rows or not). E.g.
1311 # $artist_rs->cds->count - normally generates:
1312 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1313 # which actually returns the number of artists * (number of cds || 1)
1314 #
1315 # So what we do here is crawl {from}, determine if the current alias is at
1316 # the top of the stack, and if not - make sure the chain is inner-joined down
1317 # to the root.
1318 #
1319 sub _switch_to_inner_join_if_needed {
1320   my ($self, $from, $alias) = @_;
1321
1322   # subqueries and other oddness is naturally not supported
1323   return $from if (
1324     ref $from ne 'ARRAY'
1325       ||
1326     @$from <= 1
1327       ||
1328     ref $from->[0] ne 'HASH'
1329       ||
1330     ! $from->[0]{-alias}
1331       ||
1332     $from->[0]{-alias} eq $alias
1333   );
1334
1335   my $switch_branch;
1336   JOINSCAN:
1337   for my $j (@{$from}[1 .. $#$from]) {
1338     if ($j->[0]{-alias} eq $alias) {
1339       $switch_branch = $j->[0]{-join_path};
1340       last JOINSCAN;
1341     }
1342   }
1343
1344   # something else went wrong
1345   return $from unless $switch_branch;
1346
1347   # So it looks like we will have to switch some stuff around.
1348   # local() is useless here as we will be leaving the scope
1349   # anyway, and deep cloning is just too fucking expensive
1350   # So replace the inner hashref manually
1351   my @new_from = ($from->[0]);
1352   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1353
1354   for my $j (@{$from}[1 .. $#$from]) {
1355     my $jalias = $j->[0]{-alias};
1356
1357     if ($sw_idx->{$jalias}) {
1358       my %attrs = %{$j->[0]};
1359       delete $attrs{-join_type};
1360       push @new_from, [
1361         \%attrs,
1362         @{$j}[ 1 .. $#$j ],
1363       ];
1364     }
1365     else {
1366       push @new_from, $j;
1367     }
1368   }
1369
1370   return \@new_from;
1371 }
1372
1373
1374 sub _bool {
1375   return 1;
1376 }
1377
1378 =head2 count_literal
1379
1380 =over 4
1381
1382 =item Arguments: $sql_fragment, @bind_values
1383
1384 =item Return Value: $count
1385
1386 =back
1387
1388 Counts the results in a literal query. Equivalent to calling L</search_literal>
1389 with the passed arguments, then L</count>.
1390
1391 =cut
1392
1393 sub count_literal { shift->search_literal(@_)->count; }
1394
1395 =head2 all
1396
1397 =over 4
1398
1399 =item Arguments: none
1400
1401 =item Return Value: @objects
1402
1403 =back
1404
1405 Returns all elements in the resultset. Called implicitly if the resultset
1406 is returned in list context.
1407
1408 =cut
1409
1410 sub all {
1411   my $self = shift;
1412   if(@_) {
1413       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1414   }
1415
1416   return @{ $self->get_cache } if $self->get_cache;
1417
1418   my @obj;
1419
1420   if (keys %{$self->_resolved_attrs->{collapse}}) {
1421     # Using $self->cursor->all is really just an optimisation.
1422     # If we're collapsing has_many prefetches it probably makes
1423     # very little difference, and this is cleaner than hacking
1424     # _construct_object to survive the approach
1425     $self->cursor->reset;
1426     my @row = $self->cursor->next;
1427     while (@row) {
1428       push(@obj, $self->_construct_object(@row));
1429       @row = (exists $self->{stashed_row}
1430                ? @{delete $self->{stashed_row}}
1431                : $self->cursor->next);
1432     }
1433   } else {
1434     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1435   }
1436
1437   $self->set_cache(\@obj) if $self->{attrs}{cache};
1438
1439   return @obj;
1440 }
1441
1442 =head2 reset
1443
1444 =over 4
1445
1446 =item Arguments: none
1447
1448 =item Return Value: $self
1449
1450 =back
1451
1452 Resets the resultset's cursor, so you can iterate through the elements again.
1453 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1454 another query.
1455
1456 =cut
1457
1458 sub reset {
1459   my ($self) = @_;
1460   delete $self->{_attrs} if exists $self->{_attrs};
1461   $self->{all_cache_position} = 0;
1462   $self->cursor->reset;
1463   return $self;
1464 }
1465
1466 =head2 first
1467
1468 =over 4
1469
1470 =item Arguments: none
1471
1472 =item Return Value: $object?
1473
1474 =back
1475
1476 Resets the resultset and returns an object for the first result (if the
1477 resultset returns anything).
1478
1479 =cut
1480
1481 sub first {
1482   return $_[0]->reset->next;
1483 }
1484
1485
1486 # _rs_update_delete
1487 #
1488 # Determines whether and what type of subquery is required for the $rs operation.
1489 # If grouping is necessary either supplies its own, or verifies the current one
1490 # After all is done delegates to the proper storage method.
1491
1492 sub _rs_update_delete {
1493   my ($self, $op, $values) = @_;
1494
1495   my $rsrc = $self->result_source;
1496
1497   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1498   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1499
1500   if ($needs_group_by_subq or $needs_subq) {
1501
1502     # make a new $rs selecting only the PKs (that's all we really need)
1503     my $attrs = $self->_resolved_attrs_copy;
1504
1505     delete $attrs->{$_} for qw/collapse select as/;
1506     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1507
1508     if ($needs_group_by_subq) {
1509       # make sure no group_by was supplied, or if there is one - make sure it matches
1510       # the columns compiled above perfectly. Anything else can not be sanely executed
1511       # on most databases so croak right then and there
1512
1513       if (my $g = $attrs->{group_by}) {
1514         my @current_group_by = map
1515           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1516           @$g
1517         ;
1518
1519         if (
1520           join ("\x00", sort @current_group_by)
1521             ne
1522           join ("\x00", sort @{$attrs->{columns}} )
1523         ) {
1524           $self->throw_exception (
1525             "You have just attempted a $op operation on a resultset which does group_by"
1526             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1527             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1528             . ' kind of queries. Please retry the operation with a modified group_by or'
1529             . ' without using one at all.'
1530           );
1531         }
1532       }
1533       else {
1534         $attrs->{group_by} = $attrs->{columns};
1535       }
1536     }
1537
1538     my $subrs = (ref $self)->new($rsrc, $attrs);
1539
1540     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1541   }
1542   else {
1543     return $rsrc->storage->$op(
1544       $rsrc,
1545       $op eq 'update' ? $values : (),
1546       $self->_cond_for_update_delete,
1547     );
1548   }
1549 }
1550
1551
1552 # _cond_for_update_delete
1553 #
1554 # update/delete require the condition to be modified to handle
1555 # the differing SQL syntax available.  This transforms the $self->{cond}
1556 # appropriately, returning the new condition.
1557
1558 sub _cond_for_update_delete {
1559   my ($self, $full_cond) = @_;
1560   my $cond = {};
1561
1562   $full_cond ||= $self->{cond};
1563   # No-op. No condition, we're updating/deleting everything
1564   return $cond unless ref $full_cond;
1565
1566   if (ref $full_cond eq 'ARRAY') {
1567     $cond = [
1568       map {
1569         my %hash;
1570         foreach my $key (keys %{$_}) {
1571           $key =~ /([^.]+)$/;
1572           $hash{$1} = $_->{$key};
1573         }
1574         \%hash;
1575       } @{$full_cond}
1576     ];
1577   }
1578   elsif (ref $full_cond eq 'HASH') {
1579     if ((keys %{$full_cond})[0] eq '-and') {
1580       $cond->{-and} = [];
1581       my @cond = @{$full_cond->{-and}};
1582        for (my $i = 0; $i < @cond; $i++) {
1583         my $entry = $cond[$i];
1584         my $hash;
1585         if (ref $entry eq 'HASH') {
1586           $hash = $self->_cond_for_update_delete($entry);
1587         }
1588         else {
1589           $entry =~ /([^.]+)$/;
1590           $hash->{$1} = $cond[++$i];
1591         }
1592         push @{$cond->{-and}}, $hash;
1593       }
1594     }
1595     else {
1596       foreach my $key (keys %{$full_cond}) {
1597         $key =~ /([^.]+)$/;
1598         $cond->{$1} = $full_cond->{$key};
1599       }
1600     }
1601   }
1602   else {
1603     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1604   }
1605
1606   return $cond;
1607 }
1608
1609
1610 =head2 update
1611
1612 =over 4
1613
1614 =item Arguments: \%values
1615
1616 =item Return Value: $storage_rv
1617
1618 =back
1619
1620 Sets the specified columns in the resultset to the supplied values in a
1621 single query. Return value will be true if the update succeeded or false
1622 if no records were updated; exact type of success value is storage-dependent.
1623
1624 =cut
1625
1626 sub update {
1627   my ($self, $values) = @_;
1628   $self->throw_exception('Values for update must be a hash')
1629     unless ref $values eq 'HASH';
1630
1631   return $self->_rs_update_delete ('update', $values);
1632 }
1633
1634 =head2 update_all
1635
1636 =over 4
1637
1638 =item Arguments: \%values
1639
1640 =item Return Value: 1
1641
1642 =back
1643
1644 Fetches all objects and updates them one at a time. Note that C<update_all>
1645 will run DBIC cascade triggers, while L</update> will not.
1646
1647 =cut
1648
1649 sub update_all {
1650   my ($self, $values) = @_;
1651   $self->throw_exception('Values for update_all must be a hash')
1652     unless ref $values eq 'HASH';
1653   foreach my $obj ($self->all) {
1654     $obj->set_columns($values)->update;
1655   }
1656   return 1;
1657 }
1658
1659 =head2 delete
1660
1661 =over 4
1662
1663 =item Arguments: none
1664
1665 =item Return Value: $storage_rv
1666
1667 =back
1668
1669 Deletes the contents of the resultset from its result source. Note that this
1670 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1671 to run. See also L<DBIx::Class::Row/delete>.
1672
1673 Return value will be the amount of rows deleted; exact type of return value
1674 is storage-dependent.
1675
1676 =cut
1677
1678 sub delete {
1679   my $self = shift;
1680   $self->throw_exception('delete does not accept any arguments')
1681     if @_;
1682
1683   return $self->_rs_update_delete ('delete');
1684 }
1685
1686 =head2 delete_all
1687
1688 =over 4
1689
1690 =item Arguments: none
1691
1692 =item Return Value: 1
1693
1694 =back
1695
1696 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1697 will run DBIC cascade triggers, while L</delete> will not.
1698
1699 =cut
1700
1701 sub delete_all {
1702   my $self = shift;
1703   $self->throw_exception('delete_all does not accept any arguments')
1704     if @_;
1705
1706   $_->delete for $self->all;
1707   return 1;
1708 }
1709
1710 =head2 populate
1711
1712 =over 4
1713
1714 =item Arguments: \@data;
1715
1716 =back
1717
1718 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1719 For the arrayref of hashrefs style each hashref should be a structure suitable
1720 forsubmitting to a $resultset->create(...) method.
1721
1722 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1723 to insert the data, as this is a faster method.
1724
1725 Otherwise, each set of data is inserted into the database using
1726 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1727 accumulated into an array. The array itself, or an array reference
1728 is returned depending on scalar or list context.
1729
1730 Example:  Assuming an Artist Class that has many CDs Classes relating:
1731
1732   my $Artist_rs = $schema->resultset("Artist");
1733
1734   ## Void Context Example
1735   $Artist_rs->populate([
1736      { artistid => 4, name => 'Manufactured Crap', cds => [
1737         { title => 'My First CD', year => 2006 },
1738         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1739       ],
1740      },
1741      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1742         { title => 'My parents sold me to a record company' ,year => 2005 },
1743         { title => 'Why Am I So Ugly?', year => 2006 },
1744         { title => 'I Got Surgery and am now Popular', year => 2007 }
1745       ],
1746      },
1747   ]);
1748
1749   ## Array Context Example
1750   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1751     { name => "Artist One"},
1752     { name => "Artist Two"},
1753     { name => "Artist Three", cds=> [
1754     { title => "First CD", year => 2007},
1755     { title => "Second CD", year => 2008},
1756   ]}
1757   ]);
1758
1759   print $ArtistOne->name; ## response is 'Artist One'
1760   print $ArtistThree->cds->count ## reponse is '2'
1761
1762 For the arrayref of arrayrefs style,  the first element should be a list of the
1763 fieldsnames to which the remaining elements are rows being inserted.  For
1764 example:
1765
1766   $Arstist_rs->populate([
1767     [qw/artistid name/],
1768     [100, 'A Formally Unknown Singer'],
1769     [101, 'A singer that jumped the shark two albums ago'],
1770     [102, 'An actually cool singer.'],
1771   ]);
1772
1773 Please note an important effect on your data when choosing between void and
1774 wantarray context. Since void context goes straight to C<insert_bulk> in
1775 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1776 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1777 create primary keys for you, you will find that your PKs are empty.  In this
1778 case you will have to use the wantarray context in order to create those
1779 values.
1780
1781 =cut
1782
1783 sub populate {
1784   my $self = shift @_;
1785   my $data = ref $_[0][0] eq 'HASH'
1786     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1787     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1788
1789   if(defined wantarray) {
1790     my @created;
1791     foreach my $item (@$data) {
1792       push(@created, $self->create($item));
1793     }
1794     return wantarray ? @created : \@created;
1795   } else {
1796     my ($first, @rest) = @$data;
1797
1798     my @names = grep {!ref $first->{$_}} keys %$first;
1799     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1800     my @pks = $self->result_source->primary_columns;
1801
1802     ## do the belongs_to relationships
1803     foreach my $index (0..$#$data) {
1804
1805       # delegate to create() for any dataset without primary keys with specified relationships
1806       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1807         for my $r (@rels) {
1808           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1809             my @ret = $self->populate($data);
1810             return;
1811           }
1812         }
1813       }
1814
1815       foreach my $rel (@rels) {
1816         next unless ref $data->[$index]->{$rel} eq "HASH";
1817         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1818         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1819         my $related = $result->result_source->_resolve_condition(
1820           $result->result_source->relationship_info($reverse)->{cond},
1821           $self,
1822           $result,
1823         );
1824
1825         delete $data->[$index]->{$rel};
1826         $data->[$index] = {%{$data->[$index]}, %$related};
1827
1828         push @names, keys %$related if $index == 0;
1829       }
1830     }
1831
1832     ## do bulk insert on current row
1833     my @values = map { [ @$_{@names} ] } @$data;
1834
1835     $self->result_source->storage->insert_bulk(
1836       $self->result_source,
1837       \@names,
1838       \@values,
1839     );
1840
1841     ## do the has_many relationships
1842     foreach my $item (@$data) {
1843
1844       foreach my $rel (@rels) {
1845         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1846
1847         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1848      || $self->throw_exception('Cannot find the relating object.');
1849
1850         my $child = $parent->$rel;
1851
1852         my $related = $child->result_source->_resolve_condition(
1853           $parent->result_source->relationship_info($rel)->{cond},
1854           $child,
1855           $parent,
1856         );
1857
1858         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1859         my @populate = map { {%$_, %$related} } @rows_to_add;
1860
1861         $child->populate( \@populate );
1862       }
1863     }
1864   }
1865 }
1866
1867 =head2 _normalize_populate_args ($args)
1868
1869 Private method used by L</populate> to normalize its incoming arguments.  Factored
1870 out in case you want to subclass and accept new argument structures to the
1871 L</populate> method.
1872
1873 =cut
1874
1875 sub _normalize_populate_args {
1876   my ($self, $data) = @_;
1877   my @names = @{shift(@$data)};
1878   my @results_to_create;
1879   foreach my $datum (@$data) {
1880     my %result_to_create;
1881     foreach my $index (0..$#names) {
1882       $result_to_create{$names[$index]} = $$datum[$index];
1883     }
1884     push @results_to_create, \%result_to_create;
1885   }
1886   return \@results_to_create;
1887 }
1888
1889 =head2 pager
1890
1891 =over 4
1892
1893 =item Arguments: none
1894
1895 =item Return Value: $pager
1896
1897 =back
1898
1899 Return Value a L<Data::Page> object for the current resultset. Only makes
1900 sense for queries with a C<page> attribute.
1901
1902 To get the full count of entries for a paged resultset, call
1903 C<total_entries> on the L<Data::Page> object.
1904
1905 =cut
1906
1907 sub pager {
1908   my ($self) = @_;
1909
1910   return $self->{pager} if $self->{pager};
1911
1912   my $attrs = $self->{attrs};
1913   $self->throw_exception("Can't create pager for non-paged rs")
1914     unless $self->{attrs}{page};
1915   $attrs->{rows} ||= 10;
1916
1917   # throw away the paging flags and re-run the count (possibly
1918   # with a subselect) to get the real total count
1919   my $count_attrs = { %$attrs };
1920   delete $count_attrs->{$_} for qw/rows offset page pager/;
1921   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1922
1923   return $self->{pager} = Data::Page->new(
1924     $total_count,
1925     $attrs->{rows},
1926     $self->{attrs}{page}
1927   );
1928 }
1929
1930 =head2 page
1931
1932 =over 4
1933
1934 =item Arguments: $page_number
1935
1936 =item Return Value: $rs
1937
1938 =back
1939
1940 Returns a resultset for the $page_number page of the resultset on which page
1941 is called, where each page contains a number of rows equal to the 'rows'
1942 attribute set on the resultset (10 by default).
1943
1944 =cut
1945
1946 sub page {
1947   my ($self, $page) = @_;
1948   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1949 }
1950
1951 =head2 new_result
1952
1953 =over 4
1954
1955 =item Arguments: \%vals
1956
1957 =item Return Value: $rowobject
1958
1959 =back
1960
1961 Creates a new row object in the resultset's result class and returns
1962 it. The row is not inserted into the database at this point, call
1963 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1964 will tell you whether the row object has been inserted or not.
1965
1966 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1967
1968 =cut
1969
1970 sub new_result {
1971   my ($self, $values) = @_;
1972   $self->throw_exception( "new_result needs a hash" )
1973     unless (ref $values eq 'HASH');
1974
1975   my %new;
1976   my $alias = $self->{attrs}{alias};
1977
1978   if (
1979     defined $self->{cond}
1980     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1981   ) {
1982     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1983     $new{-from_resultset} = [ keys %new ] if keys %new;
1984   } else {
1985     $self->throw_exception(
1986       "Can't abstract implicit construct, condition not a hash"
1987     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1988
1989     my $collapsed_cond = (
1990       $self->{cond}
1991         ? $self->_collapse_cond($self->{cond})
1992         : {}
1993     );
1994
1995     # precendence must be given to passed values over values inherited from
1996     # the cond, so the order here is important.
1997     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1998     while( my($col,$value) = each %implied ){
1999       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
2000         $new{$col} = $value->{'='};
2001         next;
2002       }
2003       $new{$col} = $value if $self->_is_deterministic_value($value);
2004     }
2005   }
2006
2007   %new = (
2008     %new,
2009     %{ $self->_remove_alias($values, $alias) },
2010     -source_handle => $self->_source_handle,
2011     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2012   );
2013
2014   return $self->result_class->new(\%new);
2015 }
2016
2017 # _is_deterministic_value
2018 #
2019 # Make an effor to strip non-deterministic values from the condition,
2020 # to make sure new_result chokes less
2021
2022 sub _is_deterministic_value {
2023   my $self = shift;
2024   my $value = shift;
2025   my $ref_type = ref $value;
2026   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2027   return 1 if Scalar::Util::blessed($value);
2028   return 0;
2029 }
2030
2031 # _has_resolved_attr
2032 #
2033 # determines if the resultset defines at least one
2034 # of the attributes supplied
2035 #
2036 # used to determine if a subquery is neccessary
2037 #
2038 # supports some virtual attributes:
2039 #   -join
2040 #     This will scan for any joins being present on the resultset.
2041 #     It is not a mere key-search but a deep inspection of {from}
2042 #
2043
2044 sub _has_resolved_attr {
2045   my ($self, @attr_names) = @_;
2046
2047   my $attrs = $self->_resolved_attrs;
2048
2049   my %extra_checks;
2050
2051   for my $n (@attr_names) {
2052     if (grep { $n eq $_ } (qw/-join/) ) {
2053       $extra_checks{$n}++;
2054       next;
2055     }
2056
2057     my $attr =  $attrs->{$n};
2058
2059     next if not defined $attr;
2060
2061     if (ref $attr eq 'HASH') {
2062       return 1 if keys %$attr;
2063     }
2064     elsif (ref $attr eq 'ARRAY') {
2065       return 1 if @$attr;
2066     }
2067     else {
2068       return 1 if $attr;
2069     }
2070   }
2071
2072   # a resolved join is expressed as a multi-level from
2073   return 1 if (
2074     $extra_checks{-join}
2075       and
2076     ref $attrs->{from} eq 'ARRAY'
2077       and
2078     @{$attrs->{from}} > 1
2079   );
2080
2081   return 0;
2082 }
2083
2084 # _collapse_cond
2085 #
2086 # Recursively collapse the condition.
2087
2088 sub _collapse_cond {
2089   my ($self, $cond, $collapsed) = @_;
2090
2091   $collapsed ||= {};
2092
2093   if (ref $cond eq 'ARRAY') {
2094     foreach my $subcond (@$cond) {
2095       next unless ref $subcond;  # -or
2096       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2097     }
2098   }
2099   elsif (ref $cond eq 'HASH') {
2100     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2101       foreach my $subcond (@{$cond->{-and}}) {
2102         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2103       }
2104     }
2105     else {
2106       foreach my $col (keys %$cond) {
2107         my $value = $cond->{$col};
2108         $collapsed->{$col} = $value;
2109       }
2110     }
2111   }
2112
2113   return $collapsed;
2114 }
2115
2116 # _remove_alias
2117 #
2118 # Remove the specified alias from the specified query hash. A copy is made so
2119 # the original query is not modified.
2120
2121 sub _remove_alias {
2122   my ($self, $query, $alias) = @_;
2123
2124   my %orig = %{ $query || {} };
2125   my %unaliased;
2126
2127   foreach my $key (keys %orig) {
2128     if ($key !~ /\./) {
2129       $unaliased{$key} = $orig{$key};
2130       next;
2131     }
2132     $unaliased{$1} = $orig{$key}
2133       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2134   }
2135
2136   return \%unaliased;
2137 }
2138
2139 =head2 as_query (EXPERIMENTAL)
2140
2141 =over 4
2142
2143 =item Arguments: none
2144
2145 =item Return Value: \[ $sql, @bind ]
2146
2147 =back
2148
2149 Returns the SQL query and bind vars associated with the invocant.
2150
2151 This is generally used as the RHS for a subquery.
2152
2153 B<NOTE>: This feature is still experimental.
2154
2155 =cut
2156
2157 sub as_query {
2158   my $self = shift;
2159
2160   my $attrs = $self->_resolved_attrs_copy;
2161
2162   # For future use:
2163   #
2164   # in list ctx:
2165   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2166   # $sql also has no wrapping parenthesis in list ctx
2167   #
2168   my $sqlbind = $self->result_source->storage
2169     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2170
2171   return $sqlbind;
2172 }
2173
2174 =head2 find_or_new
2175
2176 =over 4
2177
2178 =item Arguments: \%vals, \%attrs?
2179
2180 =item Return Value: $rowobject
2181
2182 =back
2183
2184   my $artist = $schema->resultset('Artist')->find_or_new(
2185     { artist => 'fred' }, { key => 'artists' });
2186
2187   $cd->cd_to_producer->find_or_new({ producer => $producer },
2188                                    { key => 'primary });
2189
2190 Find an existing record from this resultset, based on its primary
2191 key, or a unique constraint. If none exists, instantiate a new result
2192 object and return it. The object will not be saved into your storage
2193 until you call L<DBIx::Class::Row/insert> on it.
2194
2195 You most likely want this method when looking for existing rows using
2196 a unique constraint that is not the primary key, or looking for
2197 related rows.
2198
2199 If you want objects to be saved immediately, use L</find_or_create>
2200 instead.
2201
2202 B<Note>: Take care when using C<find_or_new> with a table having
2203 columns with default values that you intend to be automatically
2204 supplied by the database (e.g. an auto_increment primary key column).
2205 In normal usage, the value of such columns should NOT be included at
2206 all in the call to C<find_or_new>, even when set to C<undef>.
2207
2208 =cut
2209
2210 sub find_or_new {
2211   my $self     = shift;
2212   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2213   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2214   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2215     return $row;
2216   }
2217   return $self->new_result($hash);
2218 }
2219
2220 =head2 create
2221
2222 =over 4
2223
2224 =item Arguments: \%vals
2225
2226 =item Return Value: a L<DBIx::Class::Row> $object
2227
2228 =back
2229
2230 Attempt to create a single new row or a row with multiple related rows
2231 in the table represented by the resultset (and related tables). This
2232 will not check for duplicate rows before inserting, use
2233 L</find_or_create> to do that.
2234
2235 To create one row for this resultset, pass a hashref of key/value
2236 pairs representing the columns of the table and the values you wish to
2237 store. If the appropriate relationships are set up, foreign key fields
2238 can also be passed an object representing the foreign row, and the
2239 value will be set to its primary key.
2240
2241 To create related objects, pass a hashref of related-object column values
2242 B<keyed on the relationship name>. If the relationship is of type C<multi>
2243 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2244 The process will correctly identify columns holding foreign keys, and will
2245 transparrently populate them from the keys of the corresponding relation.
2246 This can be applied recursively, and will work correctly for a structure
2247 with an arbitrary depth and width, as long as the relationships actually
2248 exists and the correct column data has been supplied.
2249
2250
2251 Instead of hashrefs of plain related data (key/value pairs), you may
2252 also pass new or inserted objects. New objects (not inserted yet, see
2253 L</new>), will be inserted into their appropriate tables.
2254
2255 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2256
2257 Example of creating a new row.
2258
2259   $person_rs->create({
2260     name=>"Some Person",
2261     email=>"somebody@someplace.com"
2262   });
2263
2264 Example of creating a new row and also creating rows in a related C<has_many>
2265 or C<has_one> resultset.  Note Arrayref.
2266
2267   $artist_rs->create(
2268      { artistid => 4, name => 'Manufactured Crap', cds => [
2269         { title => 'My First CD', year => 2006 },
2270         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2271       ],
2272      },
2273   );
2274
2275 Example of creating a new row and also creating a row in a related
2276 C<belongs_to>resultset. Note Hashref.
2277
2278   $cd_rs->create({
2279     title=>"Music for Silly Walks",
2280     year=>2000,
2281     artist => {
2282       name=>"Silly Musician",
2283     }
2284   });
2285
2286 =over
2287
2288 =item WARNING
2289
2290 When subclassing ResultSet never attempt to override this method. Since
2291 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2292 lot of the internals simply never call it, so your override will be
2293 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2294 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2295 L</create> process you need to intervene.
2296
2297 =back
2298
2299 =cut
2300
2301 sub create {
2302   my ($self, $attrs) = @_;
2303   $self->throw_exception( "create needs a hashref" )
2304     unless ref $attrs eq 'HASH';
2305   return $self->new_result($attrs)->insert;
2306 }
2307
2308 =head2 find_or_create
2309
2310 =over 4
2311
2312 =item Arguments: \%vals, \%attrs?
2313
2314 =item Return Value: $rowobject
2315
2316 =back
2317
2318   $cd->cd_to_producer->find_or_create({ producer => $producer },
2319                                       { key => 'primary' });
2320
2321 Tries to find a record based on its primary key or unique constraints; if none
2322 is found, creates one and returns that instead.
2323
2324   my $cd = $schema->resultset('CD')->find_or_create({
2325     cdid   => 5,
2326     artist => 'Massive Attack',
2327     title  => 'Mezzanine',
2328     year   => 2005,
2329   });
2330
2331 Also takes an optional C<key> attribute, to search by a specific key or unique
2332 constraint. For example:
2333
2334   my $cd = $schema->resultset('CD')->find_or_create(
2335     {
2336       artist => 'Massive Attack',
2337       title  => 'Mezzanine',
2338     },
2339     { key => 'cd_artist_title' }
2340   );
2341
2342 B<Note>: Because find_or_create() reads from the database and then
2343 possibly inserts based on the result, this method is subject to a race
2344 condition. Another process could create a record in the table after
2345 the find has completed and before the create has started. To avoid
2346 this problem, use find_or_create() inside a transaction.
2347
2348 B<Note>: Take care when using C<find_or_create> with a table having
2349 columns with default values that you intend to be automatically
2350 supplied by the database (e.g. an auto_increment primary key column).
2351 In normal usage, the value of such columns should NOT be included at
2352 all in the call to C<find_or_create>, even when set to C<undef>.
2353
2354 See also L</find> and L</update_or_create>. For information on how to declare
2355 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2356
2357 =cut
2358
2359 sub find_or_create {
2360   my $self     = shift;
2361   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2362   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2363   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2364     return $row;
2365   }
2366   return $self->create($hash);
2367 }
2368
2369 =head2 update_or_create
2370
2371 =over 4
2372
2373 =item Arguments: \%col_values, { key => $unique_constraint }?
2374
2375 =item Return Value: $rowobject
2376
2377 =back
2378
2379   $resultset->update_or_create({ col => $val, ... });
2380
2381 First, searches for an existing row matching one of the unique constraints
2382 (including the primary key) on the source of this resultset. If a row is
2383 found, updates it with the other given column values. Otherwise, creates a new
2384 row.
2385
2386 Takes an optional C<key> attribute to search on a specific unique constraint.
2387 For example:
2388
2389   # In your application
2390   my $cd = $schema->resultset('CD')->update_or_create(
2391     {
2392       artist => 'Massive Attack',
2393       title  => 'Mezzanine',
2394       year   => 1998,
2395     },
2396     { key => 'cd_artist_title' }
2397   );
2398
2399   $cd->cd_to_producer->update_or_create({
2400     producer => $producer,
2401     name => 'harry',
2402   }, {
2403     key => 'primary,
2404   });
2405
2406
2407 If no C<key> is specified, it searches on all unique constraints defined on the
2408 source, including the primary key.
2409
2410 If the C<key> is specified as C<primary>, it searches only on the primary key.
2411
2412 See also L</find> and L</find_or_create>. For information on how to declare
2413 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2414
2415 B<Note>: Take care when using C<update_or_create> with a table having
2416 columns with default values that you intend to be automatically
2417 supplied by the database (e.g. an auto_increment primary key column).
2418 In normal usage, the value of such columns should NOT be included at
2419 all in the call to C<update_or_create>, even when set to C<undef>.
2420
2421 =cut
2422
2423 sub update_or_create {
2424   my $self = shift;
2425   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2426   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2427
2428   my $row = $self->find($cond, $attrs);
2429   if (defined $row) {
2430     $row->update($cond);
2431     return $row;
2432   }
2433
2434   return $self->create($cond);
2435 }
2436
2437 =head2 update_or_new
2438
2439 =over 4
2440
2441 =item Arguments: \%col_values, { key => $unique_constraint }?
2442
2443 =item Return Value: $rowobject
2444
2445 =back
2446
2447   $resultset->update_or_new({ col => $val, ... });
2448
2449 First, searches for an existing row matching one of the unique constraints
2450 (including the primary key) on the source of this resultset. If a row is
2451 found, updates it with the other given column values. Otherwise, instantiate
2452 a new result object and return it. The object will not be saved into your storage
2453 until you call L<DBIx::Class::Row/insert> on it.
2454
2455 Takes an optional C<key> attribute to search on a specific unique constraint.
2456 For example:
2457
2458   # In your application
2459   my $cd = $schema->resultset('CD')->update_or_new(
2460     {
2461       artist => 'Massive Attack',
2462       title  => 'Mezzanine',
2463       year   => 1998,
2464     },
2465     { key => 'cd_artist_title' }
2466   );
2467
2468   if ($cd->in_storage) {
2469       # the cd was updated
2470   }
2471   else {
2472       # the cd is not yet in the database, let's insert it
2473       $cd->insert;
2474   }
2475
2476 B<Note>: Take care when using C<update_or_new> with a table having
2477 columns with default values that you intend to be automatically
2478 supplied by the database (e.g. an auto_increment primary key column).
2479 In normal usage, the value of such columns should NOT be included at
2480 all in the call to C<update_or_new>, even when set to C<undef>.
2481
2482 See also L</find>, L</find_or_create> and L</find_or_new>.
2483
2484 =cut
2485
2486 sub update_or_new {
2487     my $self  = shift;
2488     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2489     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2490
2491     my $row = $self->find( $cond, $attrs );
2492     if ( defined $row ) {
2493         $row->update($cond);
2494         return $row;
2495     }
2496
2497     return $self->new_result($cond);
2498 }
2499
2500 =head2 get_cache
2501
2502 =over 4
2503
2504 =item Arguments: none
2505
2506 =item Return Value: \@cache_objects?
2507
2508 =back
2509
2510 Gets the contents of the cache for the resultset, if the cache is set.
2511
2512 The cache is populated either by using the L</prefetch> attribute to
2513 L</search> or by calling L</set_cache>.
2514
2515 =cut
2516
2517 sub get_cache {
2518   shift->{all_cache};
2519 }
2520
2521 =head2 set_cache
2522
2523 =over 4
2524
2525 =item Arguments: \@cache_objects
2526
2527 =item Return Value: \@cache_objects
2528
2529 =back
2530
2531 Sets the contents of the cache for the resultset. Expects an arrayref
2532 of objects of the same class as those produced by the resultset. Note that
2533 if the cache is set the resultset will return the cached objects rather
2534 than re-querying the database even if the cache attr is not set.
2535
2536 The contents of the cache can also be populated by using the
2537 L</prefetch> attribute to L</search>.
2538
2539 =cut
2540
2541 sub set_cache {
2542   my ( $self, $data ) = @_;
2543   $self->throw_exception("set_cache requires an arrayref")
2544       if defined($data) && (ref $data ne 'ARRAY');
2545   $self->{all_cache} = $data;
2546 }
2547
2548 =head2 clear_cache
2549
2550 =over 4
2551
2552 =item Arguments: none
2553
2554 =item Return Value: []
2555
2556 =back
2557
2558 Clears the cache for the resultset.
2559
2560 =cut
2561
2562 sub clear_cache {
2563   shift->set_cache(undef);
2564 }
2565
2566 =head2 related_resultset
2567
2568 =over 4
2569
2570 =item Arguments: $relationship_name
2571
2572 =item Return Value: $resultset
2573
2574 =back
2575
2576 Returns a related resultset for the supplied relationship name.
2577
2578   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2579
2580 =cut
2581
2582 sub related_resultset {
2583   my ($self, $rel) = @_;
2584
2585   $self->{related_resultsets} ||= {};
2586   return $self->{related_resultsets}{$rel} ||= do {
2587     my $rel_info = $self->result_source->relationship_info($rel);
2588
2589     $self->throw_exception(
2590       "search_related: result source '" . $self->result_source->source_name .
2591         "' has no such relationship $rel")
2592       unless $rel_info;
2593
2594     my ($from,$seen) = $self->_chain_relationship($rel);
2595
2596     my $join_count = $seen->{$rel};
2597     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2598
2599     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2600     my %attrs = %{$self->{attrs}||{}};
2601     delete @attrs{qw(result_class alias)};
2602
2603     my $new_cache;
2604
2605     if (my $cache = $self->get_cache) {
2606       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2607         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2608                         @$cache ];
2609       }
2610     }
2611
2612     my $rel_source = $self->result_source->related_source($rel);
2613
2614     my $new = do {
2615
2616       # The reason we do this now instead of passing the alias to the
2617       # search_rs below is that if you wrap/overload resultset on the
2618       # source you need to know what alias it's -going- to have for things
2619       # to work sanely (e.g. RestrictWithObject wants to be able to add
2620       # extra query restrictions, and these may need to be $alias.)
2621
2622       my $attrs = $rel_source->resultset_attributes;
2623       local $attrs->{alias} = $alias;
2624
2625       $rel_source->resultset
2626                  ->search_rs(
2627                      undef, {
2628                        %attrs,
2629                        join => undef,
2630                        prefetch => undef,
2631                        select => undef,
2632                        as => undef,
2633                        where => $self->{cond},
2634                        seen_join => $seen,
2635                        from => $from,
2636                    });
2637     };
2638     $new->set_cache($new_cache) if $new_cache;
2639     $new;
2640   };
2641 }
2642
2643 =head2 current_source_alias
2644
2645 =over 4
2646
2647 =item Arguments: none
2648
2649 =item Return Value: $source_alias
2650
2651 =back
2652
2653 Returns the current table alias for the result source this resultset is built
2654 on, that will be used in the SQL query. Usually it is C<me>.
2655
2656 Currently the source alias that refers to the result set returned by a
2657 L</search>/L</find> family method depends on how you got to the resultset: it's
2658 C<me> by default, but eg. L</search_related> aliases it to the related result
2659 source name (and keeps C<me> referring to the original result set). The long
2660 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2661 (and make this method unnecessary).
2662
2663 Thus it's currently necessary to use this method in predefined queries (see
2664 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2665 source alias of the current result set:
2666
2667   # in a result set class
2668   sub modified_by {
2669     my ($self, $user) = @_;
2670
2671     my $me = $self->current_source_alias;
2672
2673     return $self->search(
2674       "$me.modified" => $user->id,
2675     );
2676   }
2677
2678 =cut
2679
2680 sub current_source_alias {
2681   my ($self) = @_;
2682
2683   return ($self->{attrs} || {})->{alias} || 'me';
2684 }
2685
2686 # This code is called by search_related, and makes sure there
2687 # is clear separation between the joins before, during, and
2688 # after the relationship. This information is needed later
2689 # in order to properly resolve prefetch aliases (any alias
2690 # with a relation_chain_depth less than the depth of the
2691 # current prefetch is not considered)
2692 #
2693 # The increments happen in 1/2s to make it easier to correlate the
2694 # join depth with the join path. An integer means a relationship
2695 # specified via a search_related, whereas a fraction means an added
2696 # join/prefetch via attributes
2697 sub _chain_relationship {
2698   my ($self, $rel) = @_;
2699   my $source = $self->result_source;
2700   my $attrs = $self->{attrs};
2701
2702   my $from = [ @{
2703       $attrs->{from}
2704         ||
2705       [{
2706         -source_handle => $source->handle,
2707         -alias => $attrs->{alias},
2708         $attrs->{alias} => $source->from,
2709       }]
2710   }];
2711
2712   my $seen = { %{$attrs->{seen_join} || {} } };
2713   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2714     ? $from->[-1][0]{-join_path}
2715     : [];
2716
2717
2718   # we need to take the prefetch the attrs into account before we
2719   # ->_resolve_join as otherwise they get lost - captainL
2720   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2721
2722   my @requested_joins = $source->_resolve_join(
2723     $merged,
2724     $attrs->{alias},
2725     $seen,
2726     $jpath,
2727   );
2728
2729   push @$from, @requested_joins;
2730
2731   $seen->{-relation_chain_depth} += 0.5;
2732
2733   # if $self already had a join/prefetch specified on it, the requested
2734   # $rel might very well be already included. What we do in this case
2735   # is effectively a no-op (except that we bump up the chain_depth on
2736   # the join in question so we could tell it *is* the search_related)
2737   my $already_joined;
2738
2739
2740   # we consider the last one thus reverse
2741   for my $j (reverse @requested_joins) {
2742     if ($rel eq $j->[0]{-join_path}[-1]) {
2743       $j->[0]{-relation_chain_depth} += 0.5;
2744       $already_joined++;
2745       last;
2746     }
2747   }
2748
2749 # alternative way to scan the entire chain - not backwards compatible
2750 #  for my $j (reverse @$from) {
2751 #    next unless ref $j eq 'ARRAY';
2752 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2753 #      $j->[0]{-relation_chain_depth} += 0.5;
2754 #      $already_joined++;
2755 #      last;
2756 #    }
2757 #  }
2758
2759   unless ($already_joined) {
2760     push @$from, $source->_resolve_join(
2761       $rel,
2762       $attrs->{alias},
2763       $seen,
2764       $jpath,
2765     );
2766   }
2767
2768   $seen->{-relation_chain_depth} += 0.5;
2769
2770   return ($from,$seen);
2771 }
2772
2773 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2774 sub _resolved_attrs_copy {
2775   my $self = shift;
2776   return { %{$self->_resolved_attrs (@_)} };
2777 }
2778
2779 sub _resolved_attrs {
2780   my $self = shift;
2781   return $self->{_attrs} if $self->{_attrs};
2782
2783   my $attrs  = { %{ $self->{attrs} || {} } };
2784   my $source = $self->result_source;
2785   my $alias  = $attrs->{alias};
2786
2787   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2788   my @colbits;
2789
2790   # build columns (as long as select isn't set) into a set of as/select hashes
2791   unless ( $attrs->{select} ) {
2792
2793     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2794       ? @{ delete $attrs->{columns}}
2795       : (
2796           ( delete $attrs->{columns} )
2797             ||
2798           $source->storage->_order_select_columns(
2799               $source,
2800               [ $source->columns ],
2801           )
2802         )
2803     ;
2804
2805     @colbits = map {
2806       ( ref($_) eq 'HASH' )
2807       ? $_
2808       : {
2809           (
2810             /^\Q${alias}.\E(.+)$/
2811               ? "$1"
2812               : "$_"
2813           )
2814             =>
2815           (
2816             /\./
2817               ? "$_"
2818               : "${alias}.$_"
2819           )
2820         }
2821     } @cols;
2822   }
2823
2824   # add the additional columns on
2825   foreach ( 'include_columns', '+columns' ) {
2826       push @colbits, map {
2827           ( ref($_) eq 'HASH' )
2828             ? $_
2829             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2830       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2831   }
2832
2833   # start with initial select items
2834   if ( $attrs->{select} ) {
2835     $attrs->{select} =
2836         ( ref $attrs->{select} eq 'ARRAY' )
2837       ? [ @{ $attrs->{select} } ]
2838       : [ $attrs->{select} ];
2839     $attrs->{as} = (
2840       $attrs->{as}
2841       ? (
2842         ref $attrs->{as} eq 'ARRAY'
2843         ? [ @{ $attrs->{as} } ]
2844         : [ $attrs->{as} ]
2845         )
2846       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2847     );
2848   }
2849   else {
2850
2851     # otherwise we intialise select & as to empty
2852     $attrs->{select} = [];
2853     $attrs->{as}     = [];
2854   }
2855
2856   # now add colbits to select/as
2857   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2858   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2859
2860   my $adds;
2861   if ( $adds = delete $attrs->{'+select'} ) {
2862     $adds = [$adds] unless ref $adds eq 'ARRAY';
2863     push(
2864       @{ $attrs->{select} },
2865       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2866     );
2867   }
2868   if ( $adds = delete $attrs->{'+as'} ) {
2869     $adds = [$adds] unless ref $adds eq 'ARRAY';
2870     push( @{ $attrs->{as} }, @$adds );
2871   }
2872
2873   $attrs->{from} ||= [ {
2874     -source_handle => $source->handle,
2875     -alias => $self->{attrs}{alias},
2876     $self->{attrs}{alias} => $source->from,
2877   } ];
2878
2879   if ( $attrs->{join} || $attrs->{prefetch} ) {
2880
2881     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2882       if ref $attrs->{from} ne 'ARRAY';
2883
2884     my $join = delete $attrs->{join} || {};
2885
2886     if ( defined $attrs->{prefetch} ) {
2887       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2888     }
2889
2890     $attrs->{from} =    # have to copy here to avoid corrupting the original
2891       [
2892         @{ $attrs->{from} },
2893         $source->_resolve_join(
2894           $join,
2895           $alias,
2896           { %{ $attrs->{seen_join} || {} } },
2897           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2898             ? $attrs->{from}[-1][0]{-join_path}
2899             : []
2900           ,
2901         )
2902       ];
2903   }
2904
2905   if ( defined $attrs->{order_by} ) {
2906     $attrs->{order_by} = (
2907       ref( $attrs->{order_by} ) eq 'ARRAY'
2908       ? [ @{ $attrs->{order_by} } ]
2909       : [ $attrs->{order_by} || () ]
2910     );
2911   }
2912
2913   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2914     $attrs->{group_by} = [ $attrs->{group_by} ];
2915   }
2916
2917   # generate the distinct induced group_by early, as prefetch will be carried via a
2918   # subquery (since a group_by is present)
2919   if (delete $attrs->{distinct}) {
2920     if ($attrs->{group_by}) {
2921       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2922     }
2923     else {
2924       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2925     }
2926   }
2927
2928   $attrs->{collapse} ||= {};
2929   if ( my $prefetch = delete $attrs->{prefetch} ) {
2930     $prefetch = $self->_merge_attr( {}, $prefetch );
2931
2932     my $prefetch_ordering = [];
2933
2934     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2935
2936     my @prefetch =
2937       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2938
2939     # we need to somehow mark which columns came from prefetch
2940     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2941
2942     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2943     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2944
2945     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2946     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2947   }
2948
2949   # if both page and offset are specified, produce a combined offset
2950   # even though it doesn't make much sense, this is what pre 081xx has
2951   # been doing
2952   if (my $page = delete $attrs->{page}) {
2953     $attrs->{offset} =
2954       ($attrs->{rows} * ($page - 1))
2955             +
2956       ($attrs->{offset} || 0)
2957     ;
2958   }
2959
2960   return $self->{_attrs} = $attrs;
2961 }
2962
2963 sub _joinpath_aliases {
2964   my ($self, $fromspec, $seen) = @_;
2965
2966   my $paths = {};
2967   return $paths unless ref $fromspec eq 'ARRAY';
2968
2969   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2970
2971   if (int ($cur_depth) != $cur_depth) {
2972     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2973   }
2974
2975   for my $j (@$fromspec) {
2976
2977     next if ref $j ne 'ARRAY';
2978     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2979
2980     my $jpath = $j->[0]{-join_path};
2981
2982     my $p = $paths;
2983     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2984     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2985   }
2986
2987   return $paths;
2988 }
2989
2990 sub _rollout_attr {
2991   my ($self, $attr) = @_;
2992
2993   if (ref $attr eq 'HASH') {
2994     return $self->_rollout_hash($attr);
2995   } elsif (ref $attr eq 'ARRAY') {
2996     return $self->_rollout_array($attr);
2997   } else {
2998     return [$attr];
2999   }
3000 }
3001
3002 sub _rollout_array {
3003   my ($self, $attr) = @_;
3004
3005   my @rolled_array;
3006   foreach my $element (@{$attr}) {
3007     if (ref $element eq 'HASH') {
3008       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3009     } elsif (ref $element eq 'ARRAY') {
3010       #  XXX - should probably recurse here
3011       push( @rolled_array, @{$self->_rollout_array($element)} );
3012     } else {
3013       push( @rolled_array, $element );
3014     }
3015   }
3016   return \@rolled_array;
3017 }
3018
3019 sub _rollout_hash {
3020   my ($self, $attr) = @_;
3021
3022   my @rolled_array;
3023   foreach my $key (keys %{$attr}) {
3024     push( @rolled_array, { $key => $attr->{$key} } );
3025   }
3026   return \@rolled_array;
3027 }
3028
3029 sub _calculate_score {
3030   my ($self, $a, $b) = @_;
3031
3032   if (defined $a xor defined $b) {
3033     return 0;
3034   }
3035   elsif (not defined $a) {
3036     return 1;
3037   }
3038
3039   if (ref $b eq 'HASH') {
3040     my ($b_key) = keys %{$b};
3041     if (ref $a eq 'HASH') {
3042       my ($a_key) = keys %{$a};
3043       if ($a_key eq $b_key) {
3044         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3045       } else {
3046         return 0;
3047       }
3048     } else {
3049       return ($a eq $b_key) ? 1 : 0;
3050     }
3051   } else {
3052     if (ref $a eq 'HASH') {
3053       my ($a_key) = keys %{$a};
3054       return ($b eq $a_key) ? 1 : 0;
3055     } else {
3056       return ($b eq $a) ? 1 : 0;
3057     }
3058   }
3059 }
3060
3061 sub _merge_attr {
3062   my ($self, $orig, $import) = @_;
3063
3064   return $import unless defined($orig);
3065   return $orig unless defined($import);
3066
3067   $orig = $self->_rollout_attr($orig);
3068   $import = $self->_rollout_attr($import);
3069
3070   my $seen_keys;
3071   foreach my $import_element ( @{$import} ) {
3072     # find best candidate from $orig to merge $b_element into
3073     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3074     foreach my $orig_element ( @{$orig} ) {
3075       my $score = $self->_calculate_score( $orig_element, $import_element );
3076       if ($score > $best_candidate->{score}) {
3077         $best_candidate->{position} = $position;
3078         $best_candidate->{score} = $score;
3079       }
3080       $position++;
3081     }
3082     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3083
3084     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3085       push( @{$orig}, $import_element );
3086     } else {
3087       my $orig_best = $orig->[$best_candidate->{position}];
3088       # merge orig_best and b_element together and replace original with merged
3089       if (ref $orig_best ne 'HASH') {
3090         $orig->[$best_candidate->{position}] = $import_element;
3091       } elsif (ref $import_element eq 'HASH') {
3092         my ($key) = keys %{$orig_best};
3093         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3094       }
3095     }
3096     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3097   }
3098
3099   return $orig;
3100 }
3101
3102 sub result_source {
3103     my $self = shift;
3104
3105     if (@_) {
3106         $self->_source_handle($_[0]->handle);
3107     } else {
3108         $self->_source_handle->resolve;
3109     }
3110 }
3111
3112 =head2 throw_exception
3113
3114 See L<DBIx::Class::Schema/throw_exception> for details.
3115
3116 =cut
3117
3118 sub throw_exception {
3119   my $self=shift;
3120   if (ref $self && $self->_source_handle->schema) {
3121     $self->_source_handle->schema->throw_exception(@_)
3122   } else {
3123     croak(@_);
3124   }
3125
3126 }
3127
3128 # XXX: FIXME: Attributes docs need clearing up
3129
3130 =head1 ATTRIBUTES
3131
3132 Attributes are used to refine a ResultSet in various ways when
3133 searching for data. They can be passed to any method which takes an
3134 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3135 L</count>.
3136
3137 These are in no particular order:
3138
3139 =head2 order_by
3140
3141 =over 4
3142
3143 =item Value: ( $order_by | \@order_by | \%order_by )
3144
3145 =back
3146
3147 Which column(s) to order the results by.
3148
3149 [The full list of suitable values is documented in
3150 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3151 common options.]
3152
3153 If a single column name, or an arrayref of names is supplied, the
3154 argument is passed through directly to SQL. The hashref syntax allows
3155 for connection-agnostic specification of ordering direction:
3156
3157  For descending order:
3158
3159   order_by => { -desc => [qw/col1 col2 col3/] }
3160
3161  For explicit ascending order:
3162
3163   order_by => { -asc => 'col' }
3164
3165 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3166 supported, although you are strongly encouraged to use the hashref
3167 syntax as outlined above.
3168
3169 =head2 columns
3170
3171 =over 4
3172
3173 =item Value: \@columns
3174
3175 =back
3176
3177 Shortcut to request a particular set of columns to be retrieved. Each
3178 column spec may be a string (a table column name), or a hash (in which
3179 case the key is the C<as> value, and the value is used as the C<select>
3180 expression). Adds C<me.> onto the start of any column without a C<.> in
3181 it and sets C<select> from that, then auto-populates C<as> from
3182 C<select> as normal. (You may also use the C<cols> attribute, as in
3183 earlier versions of DBIC.)
3184
3185 =head2 +columns
3186
3187 =over 4
3188
3189 =item Value: \@columns
3190
3191 =back
3192
3193 Indicates additional columns to be selected from storage. Works the same
3194 as L</columns> but adds columns to the selection. (You may also use the
3195 C<include_columns> attribute, as in earlier versions of DBIC). For
3196 example:-
3197
3198   $schema->resultset('CD')->search(undef, {
3199     '+columns' => ['artist.name'],
3200     join => ['artist']
3201   });
3202
3203 would return all CDs and include a 'name' column to the information
3204 passed to object inflation. Note that the 'artist' is the name of the
3205 column (or relationship) accessor, and 'name' is the name of the column
3206 accessor in the related table.
3207
3208 =head2 include_columns
3209
3210 =over 4
3211
3212 =item Value: \@columns
3213
3214 =back
3215
3216 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3217
3218 =head2 select
3219
3220 =over 4
3221
3222 =item Value: \@select_columns
3223
3224 =back
3225
3226 Indicates which columns should be selected from the storage. You can use
3227 column names, or in the case of RDBMS back ends, function or stored procedure
3228 names:
3229
3230   $rs = $schema->resultset('Employee')->search(undef, {
3231     select => [
3232       'name',
3233       { count => 'employeeid' },
3234       { sum => 'salary' }
3235     ]
3236   });
3237
3238 When you use function/stored procedure names and do not supply an C<as>
3239 attribute, the column names returned are storage-dependent. E.g. MySQL would
3240 return a column named C<count(employeeid)> in the above example.
3241
3242 =head2 +select
3243
3244 =over 4
3245
3246 Indicates additional columns to be selected from storage.  Works the same as
3247 L</select> but adds columns to the selection.
3248
3249 =back
3250
3251 =head2 +as
3252
3253 =over 4
3254
3255 Indicates additional column names for those added via L</+select>. See L</as>.
3256
3257 =back
3258
3259 =head2 as
3260
3261 =over 4
3262
3263 =item Value: \@inflation_names
3264
3265 =back
3266
3267 Indicates column names for object inflation. That is, C<as>
3268 indicates the name that the column can be accessed as via the
3269 C<get_column> method (or via the object accessor, B<if one already
3270 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3271
3272 The C<as> attribute is used in conjunction with C<select>,
3273 usually when C<select> contains one or more function or stored
3274 procedure names:
3275
3276   $rs = $schema->resultset('Employee')->search(undef, {
3277     select => [
3278       'name',
3279       { count => 'employeeid' }
3280     ],
3281     as => ['name', 'employee_count'],
3282   });
3283
3284   my $employee = $rs->first(); # get the first Employee
3285
3286 If the object against which the search is performed already has an accessor
3287 matching a column name specified in C<as>, the value can be retrieved using
3288 the accessor as normal:
3289
3290   my $name = $employee->name();
3291
3292 If on the other hand an accessor does not exist in the object, you need to
3293 use C<get_column> instead:
3294
3295   my $employee_count = $employee->get_column('employee_count');
3296
3297 You can create your own accessors if required - see
3298 L<DBIx::Class::Manual::Cookbook> for details.
3299
3300 Please note: This will NOT insert an C<AS employee_count> into the SQL
3301 statement produced, it is used for internal access only. Thus
3302 attempting to use the accessor in an C<order_by> clause or similar
3303 will fail miserably.
3304
3305 To get around this limitation, you can supply literal SQL to your
3306 C<select> attibute that contains the C<AS alias> text, eg:
3307
3308   select => [\'myfield AS alias']
3309
3310 =head2 join
3311
3312 =over 4
3313
3314 =item Value: ($rel_name | \@rel_names | \%rel_names)
3315
3316 =back
3317
3318 Contains a list of relationships that should be joined for this query.  For
3319 example:
3320
3321   # Get CDs by Nine Inch Nails
3322   my $rs = $schema->resultset('CD')->search(
3323     { 'artist.name' => 'Nine Inch Nails' },
3324     { join => 'artist' }
3325   );
3326
3327 Can also contain a hash reference to refer to the other relation's relations.
3328 For example:
3329
3330   package MyApp::Schema::Track;
3331   use base qw/DBIx::Class/;
3332   __PACKAGE__->table('track');
3333   __PACKAGE__->add_columns(qw/trackid cd position title/);
3334   __PACKAGE__->set_primary_key('trackid');
3335   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3336   1;
3337
3338   # In your application
3339   my $rs = $schema->resultset('Artist')->search(
3340     { 'track.title' => 'Teardrop' },
3341     {
3342       join     => { cd => 'track' },
3343       order_by => 'artist.name',
3344     }
3345   );
3346
3347 You need to use the relationship (not the table) name in  conditions,
3348 because they are aliased as such. The current table is aliased as "me", so
3349 you need to use me.column_name in order to avoid ambiguity. For example:
3350
3351   # Get CDs from 1984 with a 'Foo' track
3352   my $rs = $schema->resultset('CD')->search(
3353     {
3354       'me.year' => 1984,
3355       'tracks.name' => 'Foo'
3356     },
3357     { join => 'tracks' }
3358   );
3359
3360 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3361 similarly for a third time). For e.g.
3362
3363   my $rs = $schema->resultset('Artist')->search({
3364     'cds.title'   => 'Down to Earth',
3365     'cds_2.title' => 'Popular',
3366   }, {
3367     join => [ qw/cds cds/ ],
3368   });
3369
3370 will return a set of all artists that have both a cd with title 'Down
3371 to Earth' and a cd with title 'Popular'.
3372
3373 If you want to fetch related objects from other tables as well, see C<prefetch>
3374 below.
3375
3376 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3377
3378 =head2 prefetch
3379
3380 =over 4
3381
3382 =item Value: ($rel_name | \@rel_names | \%rel_names)
3383
3384 =back
3385
3386 Contains one or more relationships that should be fetched along with
3387 the main query (when they are accessed afterwards the data will
3388 already be available, without extra queries to the database).  This is
3389 useful for when you know you will need the related objects, because it
3390 saves at least one query:
3391
3392   my $rs = $schema->resultset('Tag')->search(
3393     undef,
3394     {
3395       prefetch => {
3396         cd => 'artist'
3397       }
3398     }
3399   );
3400
3401 The initial search results in SQL like the following:
3402
3403   SELECT tag.*, cd.*, artist.* FROM tag
3404   JOIN cd ON tag.cd = cd.cdid
3405   JOIN artist ON cd.artist = artist.artistid
3406
3407 L<DBIx::Class> has no need to go back to the database when we access the
3408 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3409 case.
3410
3411 Simple prefetches will be joined automatically, so there is no need
3412 for a C<join> attribute in the above search.
3413
3414 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3415 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3416 with an accessor type of 'single' or 'filter'). A more complex example that
3417 prefetches an artists cds, the tracks on those cds, and the tags associted
3418 with that artist is given below (assuming many-to-many from artists to tags):
3419
3420  my $rs = $schema->resultset('Artist')->search(
3421    undef,
3422    {
3423      prefetch => [
3424        { cds => 'tracks' },
3425        { artist_tags => 'tags' }
3426      ]
3427    }
3428  );
3429
3430
3431 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3432 attributes will be ignored.
3433
3434 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3435 exactly as you might expect.
3436
3437 =over 4
3438
3439 =item *
3440
3441 Prefetch uses the L</cache> to populate the prefetched relationships. This
3442 may or may not be what you want.
3443
3444 =item *
3445
3446 If you specify a condition on a prefetched relationship, ONLY those
3447 rows that match the prefetched condition will be fetched into that relationship.
3448 This means that adding prefetch to a search() B<may alter> what is returned by
3449 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3450
3451   my $artist_rs = $schema->resultset('Artist')->search({
3452       'cds.year' => 2008,
3453   }, {
3454       join => 'cds',
3455   });
3456
3457   my $count = $artist_rs->first->cds->count;
3458
3459   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3460
3461   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3462
3463   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3464
3465 that cmp_ok() may or may not pass depending on the datasets involved. This
3466 behavior may or may not survive the 0.09 transition.
3467
3468 =back
3469
3470 =head2 page
3471
3472 =over 4
3473
3474 =item Value: $page
3475
3476 =back
3477
3478 Makes the resultset paged and specifies the page to retrieve. Effectively
3479 identical to creating a non-pages resultset and then calling ->page($page)
3480 on it.
3481
3482 If L<rows> attribute is not specified it defaults to 10 rows per page.
3483
3484 When you have a paged resultset, L</count> will only return the number
3485 of rows in the page. To get the total, use the L</pager> and call
3486 C<total_entries> on it.
3487
3488 =head2 rows
3489
3490 =over 4
3491
3492 =item Value: $rows
3493
3494 =back
3495
3496 Specifes the maximum number of rows for direct retrieval or the number of
3497 rows per page if the page attribute or method is used.
3498
3499 =head2 offset
3500
3501 =over 4
3502
3503 =item Value: $offset
3504
3505 =back
3506
3507 Specifies the (zero-based) row number for the  first row to be returned, or the
3508 of the first row of the first page if paging is used.
3509
3510 =head2 group_by
3511
3512 =over 4
3513
3514 =item Value: \@columns
3515
3516 =back
3517
3518 A arrayref of columns to group by. Can include columns of joined tables.
3519
3520   group_by => [qw/ column1 column2 ... /]
3521
3522 =head2 having
3523
3524 =over 4
3525
3526 =item Value: $condition
3527
3528 =back
3529
3530 HAVING is a select statement attribute that is applied between GROUP BY and
3531 ORDER BY. It is applied to the after the grouping calculations have been
3532 done.
3533
3534   having => { 'count(employee)' => { '>=', 100 } }
3535
3536 =head2 distinct
3537
3538 =over 4
3539
3540 =item Value: (0 | 1)
3541
3542 =back
3543
3544 Set to 1 to group by all columns. If the resultset already has a group_by
3545 attribute, this setting is ignored and an appropriate warning is issued.
3546
3547 =head2 where
3548
3549 =over 4
3550
3551 Adds to the WHERE clause.
3552
3553   # only return rows WHERE deleted IS NULL for all searches
3554   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3555
3556 Can be overridden by passing C<{ where => undef }> as an attribute
3557 to a resulset.
3558
3559 =back
3560
3561 =head2 cache
3562
3563 Set to 1 to cache search results. This prevents extra SQL queries if you
3564 revisit rows in your ResultSet:
3565
3566   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3567
3568   while( my $artist = $resultset->next ) {
3569     ... do stuff ...
3570   }
3571
3572   $rs->first; # without cache, this would issue a query
3573
3574 By default, searches are not cached.
3575
3576 For more examples of using these attributes, see
3577 L<DBIx::Class::Manual::Cookbook>.
3578
3579 =head2 from
3580
3581 =over 4
3582
3583 =item Value: \@from_clause
3584
3585 =back
3586
3587 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3588 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3589 clauses.
3590
3591 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3592
3593 C<join> will usually do what you need and it is strongly recommended that you
3594 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3595 And we really do mean "cannot", not just tried and failed. Attempting to use
3596 this because you're having problems with C<join> is like trying to use x86
3597 ASM because you've got a syntax error in your C. Trust us on this.
3598
3599 Now, if you're still really, really sure you need to use this (and if you're
3600 not 100% sure, ask the mailing list first), here's an explanation of how this
3601 works.
3602
3603 The syntax is as follows -
3604
3605   [
3606     { <alias1> => <table1> },
3607     [
3608       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3609       [], # nested JOIN (optional)
3610       { <table1.column1> => <table2.column2>, ... (more conditions) },
3611     ],
3612     # More of the above [ ] may follow for additional joins
3613   ]
3614
3615   <table1> <alias1>
3616   JOIN
3617     <table2> <alias2>
3618     [JOIN ...]
3619   ON <table1.column1> = <table2.column2>
3620   <more joins may follow>
3621
3622 An easy way to follow the examples below is to remember the following:
3623
3624     Anything inside "[]" is a JOIN
3625     Anything inside "{}" is a condition for the enclosing JOIN
3626
3627 The following examples utilize a "person" table in a family tree application.
3628 In order to express parent->child relationships, this table is self-joined:
3629
3630     # Person->belongs_to('father' => 'Person');
3631     # Person->belongs_to('mother' => 'Person');
3632
3633 C<from> can be used to nest joins. Here we return all children with a father,
3634 then search against all mothers of those children:
3635
3636   $rs = $schema->resultset('Person')->search(
3637       undef,
3638       {
3639           alias => 'mother', # alias columns in accordance with "from"
3640           from => [
3641               { mother => 'person' },
3642               [
3643                   [
3644                       { child => 'person' },
3645                       [
3646                           { father => 'person' },
3647                           { 'father.person_id' => 'child.father_id' }
3648                       ]
3649                   ],
3650                   { 'mother.person_id' => 'child.mother_id' }
3651               ],
3652           ]
3653       },
3654   );
3655
3656   # Equivalent SQL:
3657   # SELECT mother.* FROM person mother
3658   # JOIN (
3659   #   person child
3660   #   JOIN person father
3661   #   ON ( father.person_id = child.father_id )
3662   # )
3663   # ON ( mother.person_id = child.mother_id )
3664
3665 The type of any join can be controlled manually. To search against only people
3666 with a father in the person table, we could explicitly use C<INNER JOIN>:
3667
3668     $rs = $schema->resultset('Person')->search(
3669         undef,
3670         {
3671             alias => 'child', # alias columns in accordance with "from"
3672             from => [
3673                 { child => 'person' },
3674                 [
3675                     { father => 'person', -join_type => 'inner' },
3676                     { 'father.id' => 'child.father_id' }
3677                 ],
3678             ]
3679         },
3680     );
3681
3682     # Equivalent SQL:
3683     # SELECT child.* FROM person child
3684     # INNER JOIN person father ON child.father_id = father.id
3685
3686 You can select from a subquery by passing a resultset to from as follows.
3687
3688     $schema->resultset('Artist')->search(
3689         undef,
3690         {   alias => 'artist2',
3691             from  => [ { artist2 => $artist_rs->as_query } ],
3692         } );
3693
3694     # and you'll get sql like this..
3695     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3696     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3697
3698 If you need to express really complex joins, you
3699 can supply literal SQL to C<from> via a scalar reference. In this case
3700 the contents of the scalar will replace the table name associated with the
3701 resultsource.
3702
3703 WARNING: This technique might very well not work as expected on chained
3704 searches - you have been warned.
3705
3706     # Assuming the Event resultsource is defined as:
3707
3708         MySchema::Event->add_columns (
3709             sequence => {
3710                 data_type => 'INT',
3711                 is_auto_increment => 1,
3712             },
3713             location => {
3714                 data_type => 'INT',
3715             },
3716             type => {
3717                 data_type => 'INT',
3718             },
3719         );
3720         MySchema::Event->set_primary_key ('sequence');
3721
3722     # This will get back the latest event for every location. The column
3723     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3724     # combo to limit the resultset
3725
3726     $rs = $schema->resultset('Event');
3727     $table = $rs->result_source->name;
3728     $latest = $rs->search (
3729         undef,
3730         { from => \ "
3731             (SELECT e1.* FROM $table e1
3732                 JOIN $table e2
3733                     ON e1.location = e2.location
3734                     AND e1.sequence < e2.sequence
3735                 WHERE e2.sequence is NULL
3736             ) me",
3737         },
3738     );
3739
3740     # Equivalent SQL (with the DBIC chunks added):
3741
3742     SELECT me.sequence, me.location, me.type FROM
3743        (SELECT e1.* FROM events e1
3744            JOIN events e2
3745                ON e1.location = e2.location
3746                AND e1.sequence < e2.sequence
3747            WHERE e2.sequence is NULL
3748        ) me;
3749
3750 =head2 for
3751
3752 =over 4
3753
3754 =item Value: ( 'update' | 'shared' )
3755
3756 =back
3757
3758 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3759 ... FOR SHARED.
3760
3761 =cut
3762
3763 1;