lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799 #      warn "ARRAY: " . Dumper $subquery;
 800       $collapsed = $self->_collapse_query($subquery, $collapsed);
 801     }
 802   }
 803   elsif (ref $query eq 'HASH') {
 804     if (keys %$query and (keys %$query)[0] eq '-and') {
 805       foreach my $subquery (@{$query->{-and}}) {
 806 #        warn "HASH: " . Dumper $subquery;
 807         $collapsed = $self->_collapse_query($subquery, $collapsed);
 808       }
 809     }
 810     else {
 811 #      warn "LEAF: " . Dumper $query;
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 868   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 869   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 870   return $class->search($query, { %$attrs });
 871 }
 872
 873 =head2 slice
 874
 875 =over 4
 876
 877 =item Arguments: $first, $last
 878
 879 =item Return Value: $resultset (scalar context), @row_objs (list context)
 880
 881 =back
 882
 883 Returns a resultset or object list representing a subset of elements from the
 884 resultset slice is called on. Indexes are from 0, i.e., to get the first
 885 three records, call:
 886
 887   my ($one, $two, $three) = $rs->slice(0, 2);
 888
 889 =cut
 890
 891 sub slice {
 892   my ($self, $min, $max) = @_;
 893   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 894   $attrs->{offset} = $self->{attrs}{offset} || 0;
 895   $attrs->{offset} += $min;
 896   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 897   return $self->search(undef(), $attrs);
 898   #my $slice = (ref $self)->new($self->result_source, $attrs);
 899   #return (wantarray ? $slice->all : $slice);
 900 }
 901
 902 =head2 next
 903
 904 =over 4
 905
 906 =item Arguments: none
 907
 908 =item Return Value: $result?
 909
 910 =back
 911
 912 Returns the next element in the resultset (C<undef> is there is none).
 913
 914 Can be used to efficiently iterate over records in the resultset:
 915
 916   my $rs = $schema->resultset('CD')->search;
 917   while (my $cd = $rs->next) {
 918     print $cd->title;
 919   }
 920
 921 Note that you need to store the resultset object, and call C<next> on it.
 922 Calling C<< resultset('Table')->next >> repeatedly will always return the
 923 first record from the resultset.
 924
 925 =cut
 926
 927 sub next {
 928   my ($self) = @_;
 929   if (my $cache = $self->get_cache) {
 930     $self->{all_cache_position} ||= 0;
 931     return $cache->[$self->{all_cache_position}++];
 932   }
 933   if ($self->{attrs}{cache}) {
 934     $self->{all_cache_position} = 1;
 935     return ($self->all)[0];
 936   }
 937   if ($self->{stashed_objects}) {
 938     my $obj = shift(@{$self->{stashed_objects}});
 939     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 940     return $obj;
 941   }
 942   my @row = (
 943     exists $self->{stashed_row}
 944       ? @{delete $self->{stashed_row}}
 945       : $self->cursor->next
 946   );
 947   return undef unless (@row);
 948   my ($row, @more) = $self->_construct_object(@row);
 949   $self->{stashed_objects} = \@more if @more;
 950   return $row;
 951 }
 952
 953 sub _construct_object {
 954   my ($self, @row) = @_;
 955   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 956   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 957   @new = $self->{_attrs}{record_filter}->(@new)
 958     if exists $self->{_attrs}{record_filter};
 959   return @new;
 960 }
 961
 962 sub _collapse_result {
 963   my ($self, $as_proto, $row) = @_;
 964
 965   my @copy = @$row;
 966
 967   # 'foo'         => [ undef, 'foo' ]
 968   # 'foo.bar'     => [ 'foo', 'bar' ]
 969   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 970
 971   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 972
 973   my %collapse = %{$self->{_attrs}{collapse}||{}};
 974
 975   my @pri_index;
 976
 977   # if we're doing collapsing (has_many prefetch) we need to grab records
 978   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 979   # we know we don't have to bother.
 980
 981   # the reason for not using the collapse stuff directly is because if you
 982   # had for e.g. two artists in a row with no cds, the collapse info for
 983   # both would be NULL (undef) so you'd lose the second artist
 984
 985   # store just the index so we can check the array positions from the row
 986   # without having to contruct the full hash
 987
 988   if (keys %collapse) {
 989     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 990     foreach my $i (0 .. $#construct_as) {
 991       next if defined($construct_as[$i][0]); # only self table
 992       if (delete $pri{$construct_as[$i][1]}) {
 993         push(@pri_index, $i);
 994       }
 995       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 996     }
 997   }
 998
 999   # no need to do an if, it'll be empty if @pri_index is empty anyway
1000
1001   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1002
1003   my @const_rows;
1004
1005   do { # no need to check anything at the front, we always want the first row
1006
1007     my %const;
1008
1009     foreach my $this_as (@construct_as) {
1010       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1011     }
1012
1013     push(@const_rows, \%const);
1014
1015   } until ( # no pri_index => no collapse => drop straight out
1016       !@pri_index
1017     or
1018       do { # get another row, stash it, drop out if different PK
1019
1020         @copy = $self->cursor->next;
1021         $self->{stashed_row} = \@copy;
1022
1023         # last thing in do block, counts as true if anything doesn't match
1024
1025         # check xor defined first for NULL vs. NOT NULL then if one is
1026         # defined the other must be so check string equality
1027
1028         grep {
1029           (defined $pri_vals{$_} ^ defined $copy[$_])
1030           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1031         } @pri_index;
1032       }
1033   );
1034
1035   my $alias = $self->{attrs}{alias};
1036   my $info = [];
1037
1038   my %collapse_pos;
1039
1040   my @const_keys;
1041
1042   foreach my $const (@const_rows) {
1043     scalar @const_keys or do {
1044       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1045     };
1046     foreach my $key (@const_keys) {
1047       if (length $key) {
1048         my $target = $info;
1049         my @parts = split(/\./, $key);
1050         my $cur = '';
1051         my $data = $const->{$key};
1052         foreach my $p (@parts) {
1053           $target = $target->[1]->{$p} ||= [];
1054           $cur .= ".${p}";
1055           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1056             # collapsing at this point and on final part
1057             my $pos = $collapse_pos{$cur};
1058             CK: foreach my $ck (@ckey) {
1059               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1060                 $collapse_pos{$cur} = $data;
1061                 delete @collapse_pos{ # clear all positioning for sub-entries
1062                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1063                 };
1064                 push(@$target, []);
1065                 last CK;
1066               }
1067             }
1068           }
1069           if (exists $collapse{$cur}) {
1070             $target = $target->[-1];
1071           }
1072         }
1073         $target->[0] = $data;
1074       } else {
1075         $info->[0] = $const->{$key};
1076       }
1077     }
1078   }
1079
1080   return $info;
1081 }
1082
1083 =head2 result_source
1084
1085 =over 4
1086
1087 =item Arguments: $result_source?
1088
1089 =item Return Value: $result_source
1090
1091 =back
1092
1093 An accessor for the primary ResultSource object from which this ResultSet
1094 is derived.
1095
1096 =head2 result_class
1097
1098 =over 4
1099
1100 =item Arguments: $result_class?
1101
1102 =item Return Value: $result_class
1103
1104 =back
1105
1106 An accessor for the class to use when creating row objects. Defaults to
1107 C<< result_source->result_class >> - which in most cases is the name of the
1108 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1109
1110 =cut
1111
1112 sub result_class {
1113   my ($self, $result_class) = @_;
1114   if ($result_class) {
1115     $self->ensure_class_loaded($result_class);
1116     $self->_result_class($result_class);
1117   }
1118   $self->_result_class;
1119 }
1120
1121 =head2 count
1122
1123 =over 4
1124
1125 =item Arguments: $cond, \%attrs??
1126
1127 =item Return Value: $count
1128
1129 =back
1130
1131 Performs an SQL C<COUNT> with the same query as the resultset was built
1132 with to find the number of elements. If passed arguments, does a search
1133 on the resultset and counts the results of that.
1134
1135 Note: When using C<count> with C<group_by>, L<DBIx::Class> emulates C<GROUP BY>
1136 using C<COUNT( DISTINCT( columns ) )>. Some databases (notably SQLite) do
1137 not support C<DISTINCT> with multiple columns. If you are using such a
1138 database, you should only use columns from the main table in your C<group_by>
1139 clause.
1140
1141 =cut
1142
1143 sub count {
1144   my $self = shift;
1145   return $self->search(@_)->count if @_ and defined $_[0];
1146   return scalar @{ $self->get_cache } if $self->get_cache;
1147   my $count = $self->_count;
1148   return 0 unless $count;
1149
1150   # need to take offset from resolved attrs
1151
1152   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1153   $count = $self->{attrs}{rows} if
1154     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1155   $count = 0 if ($count < 0);
1156   return $count;
1157 }
1158
1159 sub _count { # Separated out so pager can get the full count
1160   my $self = shift;
1161   my $select = { count => '*' };
1162
1163   my $attrs = { %{$self->_resolved_attrs} };
1164   if (my $group_by = delete $attrs->{group_by}) {
1165     delete $attrs->{having};
1166     my @distinct = (ref $group_by ?  @$group_by : ($group_by));
1167     # todo: try CONCAT for multi-column pk
1168     my @pk = $self->result_source->primary_columns;
1169     if (@pk == 1) {
1170       my $alias = $attrs->{alias};
1171       foreach my $column (@distinct) {
1172         if ($column =~ qr/^(?:\Q${alias}.\E)?$pk[0]$/) {
1173           @distinct = ($column);
1174           last;
1175         }
1176       }
1177     }
1178
1179     $select = { count => { distinct => \@distinct } };
1180   }
1181
1182   $attrs->{select} = $select;
1183   $attrs->{as} = [qw/count/];
1184
1185   # offset, order by and page are not needed to count. record_filter is cdbi
1186   delete $attrs->{$_} for qw/rows offset order_by page pager record_filter/;
1187
1188   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1189   my ($count) = $tmp_rs->cursor->next;
1190   return $count;
1191 }
1192
1193 sub _bool {
1194   return 1;
1195 }
1196
1197 =head2 count_literal
1198
1199 =over 4
1200
1201 =item Arguments: $sql_fragment, @bind_values
1202
1203 =item Return Value: $count
1204
1205 =back
1206
1207 Counts the results in a literal query. Equivalent to calling L</search_literal>
1208 with the passed arguments, then L</count>.
1209
1210 =cut
1211
1212 sub count_literal { shift->search_literal(@_)->count; }
1213
1214 =head2 all
1215
1216 =over 4
1217
1218 =item Arguments: none
1219
1220 =item Return Value: @objects
1221
1222 =back
1223
1224 Returns all elements in the resultset. Called implicitly if the resultset
1225 is returned in list context.
1226
1227 =cut
1228
1229 sub all {
1230   my $self = shift;
1231   if(@_) {
1232       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1233   }
1234
1235   return @{ $self->get_cache } if $self->get_cache;
1236
1237   my @obj;
1238
1239   # TODO: don't call resolve here
1240   if (keys %{$self->_resolved_attrs->{collapse}}) {
1241 #  if ($self->{attrs}{prefetch}) {
1242       # Using $self->cursor->all is really just an optimisation.
1243       # If we're collapsing has_many prefetches it probably makes
1244       # very little difference, and this is cleaner than hacking
1245       # _construct_object to survive the approach
1246     my @row = $self->cursor->next;
1247     while (@row) {
1248       push(@obj, $self->_construct_object(@row));
1249       @row = (exists $self->{stashed_row}
1250                ? @{delete $self->{stashed_row}}
1251                : $self->cursor->next);
1252     }
1253   } else {
1254     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1255   }
1256
1257   $self->set_cache(\@obj) if $self->{attrs}{cache};
1258   return @obj;
1259 }
1260
1261 =head2 reset
1262
1263 =over 4
1264
1265 =item Arguments: none
1266
1267 =item Return Value: $self
1268
1269 =back
1270
1271 Resets the resultset's cursor, so you can iterate through the elements again.
1272
1273 =cut
1274
1275 sub reset {
1276   my ($self) = @_;
1277   delete $self->{_attrs} if exists $self->{_attrs};
1278   $self->{all_cache_position} = 0;
1279   $self->cursor->reset;
1280   return $self;
1281 }
1282
1283 =head2 first
1284
1285 =over 4
1286
1287 =item Arguments: none
1288
1289 =item Return Value: $object?
1290
1291 =back
1292
1293 Resets the resultset and returns an object for the first result (if the
1294 resultset returns anything).
1295
1296 =cut
1297
1298 sub first {
1299   return $_[0]->reset->next;
1300 }
1301
1302 # _cond_for_update_delete
1303 #
1304 # update/delete require the condition to be modified to handle
1305 # the differing SQL syntax available.  This transforms the $self->{cond}
1306 # appropriately, returning the new condition.
1307
1308 sub _cond_for_update_delete {
1309   my ($self, $full_cond) = @_;
1310   my $cond = {};
1311
1312   $full_cond ||= $self->{cond};
1313   # No-op. No condition, we're updating/deleting everything
1314   return $cond unless ref $full_cond;
1315
1316   if (ref $full_cond eq 'ARRAY') {
1317     $cond = [
1318       map {
1319         my %hash;
1320         foreach my $key (keys %{$_}) {
1321           $key =~ /([^.]+)$/;
1322           $hash{$1} = $_->{$key};
1323         }
1324         \%hash;
1325       } @{$full_cond}
1326     ];
1327   }
1328   elsif (ref $full_cond eq 'HASH') {
1329     if ((keys %{$full_cond})[0] eq '-and') {
1330       $cond->{-and} = [];
1331
1332       my @cond = @{$full_cond->{-and}};
1333       for (my $i = 0; $i < @cond; $i++) {
1334         my $entry = $cond[$i];
1335
1336         my $hash;
1337         if (ref $entry eq 'HASH') {
1338           $hash = $self->_cond_for_update_delete($entry);
1339         }
1340         else {
1341           $entry =~ /([^.]+)$/;
1342           $hash->{$1} = $cond[++$i];
1343         }
1344
1345         push @{$cond->{-and}}, $hash;
1346       }
1347     }
1348     else {
1349       foreach my $key (keys %{$full_cond}) {
1350         $key =~ /([^.]+)$/;
1351         $cond->{$1} = $full_cond->{$key};
1352       }
1353     }
1354   }
1355   else {
1356     $self->throw_exception(
1357       "Can't update/delete on resultset with condition unless hash or array"
1358     );
1359   }
1360
1361   return $cond;
1362 }
1363
1364
1365 =head2 update
1366
1367 =over 4
1368
1369 =item Arguments: \%values
1370
1371 =item Return Value: $storage_rv
1372
1373 =back
1374
1375 Sets the specified columns in the resultset to the supplied values in a
1376 single query. Return value will be true if the update succeeded or false
1377 if no records were updated; exact type of success value is storage-dependent.
1378
1379 =cut
1380
1381 sub update {
1382   my ($self, $values) = @_;
1383   $self->throw_exception("Values for update must be a hash")
1384     unless ref $values eq 'HASH';
1385
1386   carp(   'WARNING! Currently $rs->update() does not generate proper SQL'
1387         . ' on joined resultsets, and may affect rows well outside of the'
1388         . ' contents of $rs. Use at your own risk' )
1389     if ( $self->{attrs}{seen_join} );
1390
1391   my $cond = $self->_cond_for_update_delete;
1392
1393   return $self->result_source->storage->update(
1394     $self->result_source, $values, $cond
1395   );
1396 }
1397
1398 =head2 update_all
1399
1400 =over 4
1401
1402 =item Arguments: \%values
1403
1404 =item Return Value: 1
1405
1406 =back
1407
1408 Fetches all objects and updates them one at a time. Note that C<update_all>
1409 will run DBIC cascade triggers, while L</update> will not.
1410
1411 =cut
1412
1413 sub update_all {
1414   my ($self, $values) = @_;
1415   $self->throw_exception("Values for update must be a hash")
1416     unless ref $values eq 'HASH';
1417   foreach my $obj ($self->all) {
1418     $obj->set_columns($values)->update;
1419   }
1420   return 1;
1421 }
1422
1423 =head2 delete
1424
1425 =over 4
1426
1427 =item Arguments: none
1428
1429 =item Return Value: 1
1430
1431 =back
1432
1433 Deletes the contents of the resultset from its result source. Note that this
1434 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1435 to run. See also L<DBIx::Class::Row/delete>.
1436
1437 delete may not generate correct SQL for a query with joins or a resultset
1438 chained from a related resultset.  In this case it will generate a warning:-
1439
1440   WARNING! Currently $rs->delete() does not generate proper SQL on
1441   joined resultsets, and may delete rows well outside of the contents
1442   of $rs. Use at your own risk
1443
1444 In these cases you may find that delete_all is more appropriate, or you
1445 need to respecify your query in a way that can be expressed without a join.
1446
1447 =cut
1448
1449 sub delete {
1450   my ($self) = @_;
1451   $self->throw_exception("Delete should not be passed any arguments")
1452     if $_[1];
1453   carp(   'WARNING! Currently $rs->delete() does not generate proper SQL'
1454         . ' on joined resultsets, and may delete rows well outside of the'
1455         . ' contents of $rs. Use at your own risk' )
1456     if ( $self->{attrs}{seen_join} );
1457   my $cond = $self->_cond_for_update_delete;
1458
1459   $self->result_source->storage->delete($self->result_source, $cond);
1460   return 1;
1461 }
1462
1463 =head2 delete_all
1464
1465 =over 4
1466
1467 =item Arguments: none
1468
1469 =item Return Value: 1
1470
1471 =back
1472
1473 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1474 will run DBIC cascade triggers, while L</delete> will not.
1475
1476 =cut
1477
1478 sub delete_all {
1479   my ($self) = @_;
1480   $_->delete for $self->all;
1481   return 1;
1482 }
1483
1484 =head2 populate
1485
1486 =over 4
1487
1488 =item Arguments: \@data;
1489
1490 =back
1491
1492 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1493 For the arrayref of hashrefs style each hashref should be a structure suitable
1494 forsubmitting to a $resultset->create(...) method.
1495
1496 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1497 to insert the data, as this is a faster method.
1498
1499 Otherwise, each set of data is inserted into the database using
1500 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1501 objects is returned.
1502
1503 Example:  Assuming an Artist Class that has many CDs Classes relating:
1504
1505   my $Artist_rs = $schema->resultset("Artist");
1506
1507   ## Void Context Example
1508   $Artist_rs->populate([
1509      { artistid => 4, name => 'Manufactured Crap', cds => [
1510         { title => 'My First CD', year => 2006 },
1511         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1512       ],
1513      },
1514      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1515         { title => 'My parents sold me to a record company' ,year => 2005 },
1516         { title => 'Why Am I So Ugly?', year => 2006 },
1517         { title => 'I Got Surgery and am now Popular', year => 2007 }
1518       ],
1519      },
1520   ]);
1521
1522   ## Array Context Example
1523   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1524     { name => "Artist One"},
1525     { name => "Artist Two"},
1526     { name => "Artist Three", cds=> [
1527     { title => "First CD", year => 2007},
1528     { title => "Second CD", year => 2008},
1529   ]}
1530   ]);
1531
1532   print $ArtistOne->name; ## response is 'Artist One'
1533   print $ArtistThree->cds->count ## reponse is '2'
1534
1535 For the arrayref of arrayrefs style,  the first element should be a list of the
1536 fieldsnames to which the remaining elements are rows being inserted.  For
1537 example:
1538
1539   $Arstist_rs->populate([
1540     [qw/artistid name/],
1541     [100, 'A Formally Unknown Singer'],
1542     [101, 'A singer that jumped the shark two albums ago'],
1543     [102, 'An actually cool singer.'],
1544   ]);
1545
1546 Please note an important effect on your data when choosing between void and
1547 wantarray context. Since void context goes straight to C<insert_bulk> in
1548 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1549 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1550 create primary keys for you, you will find that your PKs are empty.  In this
1551 case you will have to use the wantarray context in order to create those
1552 values.
1553
1554 =cut
1555
1556 sub populate {
1557   my $self = shift @_;
1558   my $data = ref $_[0][0] eq 'HASH'
1559     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1560     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1561
1562   if(defined wantarray) {
1563     my @created;
1564     foreach my $item (@$data) {
1565       push(@created, $self->create($item));
1566     }
1567     return @created;
1568   } else {
1569     my ($first, @rest) = @$data;
1570
1571     my @names = grep {!ref $first->{$_}} keys %$first;
1572     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1573     my @pks = $self->result_source->primary_columns;
1574
1575     ## do the belongs_to relationships
1576     foreach my $index (0..$#$data) {
1577       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1578         my @ret = $self->populate($data);
1579         return;
1580       }
1581
1582       foreach my $rel (@rels) {
1583         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1584         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1585         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1586         my $related = $result->result_source->resolve_condition(
1587           $result->result_source->relationship_info($reverse)->{cond},
1588           $self,
1589           $result,
1590         );
1591
1592         delete $data->[$index]->{$rel};
1593         $data->[$index] = {%{$data->[$index]}, %$related};
1594
1595         push @names, keys %$related if $index == 0;
1596       }
1597     }
1598
1599     ## do bulk insert on current row
1600     my @values = map { [ @$_{@names} ] } @$data;
1601
1602     $self->result_source->storage->insert_bulk(
1603       $self->result_source,
1604       \@names,
1605       \@values,
1606     );
1607
1608     ## do the has_many relationships
1609     foreach my $item (@$data) {
1610
1611       foreach my $rel (@rels) {
1612         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1613
1614         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1615      || $self->throw_exception('Cannot find the relating object.');
1616
1617         my $child = $parent->$rel;
1618
1619         my $related = $child->result_source->resolve_condition(
1620           $parent->result_source->relationship_info($rel)->{cond},
1621           $child,
1622           $parent,
1623         );
1624
1625         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1626         my @populate = map { {%$_, %$related} } @rows_to_add;
1627
1628         $child->populate( \@populate );
1629       }
1630     }
1631   }
1632 }
1633
1634 =head2 _normalize_populate_args ($args)
1635
1636 Private method used by L</populate> to normalize its incoming arguments.  Factored
1637 out in case you want to subclass and accept new argument structures to the
1638 L</populate> method.
1639
1640 =cut
1641
1642 sub _normalize_populate_args {
1643   my ($self, $data) = @_;
1644   my @names = @{shift(@$data)};
1645   my @results_to_create;
1646   foreach my $datum (@$data) {
1647     my %result_to_create;
1648     foreach my $index (0..$#names) {
1649       $result_to_create{$names[$index]} = $$datum[$index];
1650     }
1651     push @results_to_create, \%result_to_create;
1652   }
1653   return \@results_to_create;
1654 }
1655
1656 =head2 pager
1657
1658 =over 4
1659
1660 =item Arguments: none
1661
1662 =item Return Value: $pager
1663
1664 =back
1665
1666 Return Value a L<Data::Page> object for the current resultset. Only makes
1667 sense for queries with a C<page> attribute.
1668
1669 To get the full count of entries for a paged resultset, call
1670 C<total_entries> on the L<Data::Page> object.
1671
1672 =cut
1673
1674 sub pager {
1675   my ($self) = @_;
1676   my $attrs = $self->{attrs};
1677   $self->throw_exception("Can't create pager for non-paged rs")
1678     unless $self->{attrs}{page};
1679   $attrs->{rows} ||= 10;
1680   return $self->{pager} ||= Data::Page->new(
1681     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1682 }
1683
1684 =head2 page
1685
1686 =over 4
1687
1688 =item Arguments: $page_number
1689
1690 =item Return Value: $rs
1691
1692 =back
1693
1694 Returns a resultset for the $page_number page of the resultset on which page
1695 is called, where each page contains a number of rows equal to the 'rows'
1696 attribute set on the resultset (10 by default).
1697
1698 =cut
1699
1700 sub page {
1701   my ($self, $page) = @_;
1702   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1703 }
1704
1705 =head2 new_result
1706
1707 =over 4
1708
1709 =item Arguments: \%vals
1710
1711 =item Return Value: $rowobject
1712
1713 =back
1714
1715 Creates a new row object in the resultset's result class and returns
1716 it. The row is not inserted into the database at this point, call
1717 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1718 will tell you whether the row object has been inserted or not.
1719
1720 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1721
1722 =cut
1723
1724 sub new_result {
1725   my ($self, $values) = @_;
1726   $self->throw_exception( "new_result needs a hash" )
1727     unless (ref $values eq 'HASH');
1728
1729   my %new;
1730   my $alias = $self->{attrs}{alias};
1731
1732   if (
1733     defined $self->{cond}
1734     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1735   ) {
1736     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1737     $new{-from_resultset} = [ keys %new ] if keys %new;
1738   } else {
1739     $self->throw_exception(
1740       "Can't abstract implicit construct, condition not a hash"
1741     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1742
1743     my $collapsed_cond = (
1744       $self->{cond}
1745         ? $self->_collapse_cond($self->{cond})
1746         : {}
1747     );
1748
1749     # precendence must be given to passed values over values inherited from
1750     # the cond, so the order here is important.
1751     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1752     while( my($col,$value) = each %implied ){
1753       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1754         $new{$col} = $value->{'='};
1755         next;
1756       }
1757       $new{$col} = $value if $self->_is_deterministic_value($value);
1758     }
1759   }
1760
1761   %new = (
1762     %new,
1763     %{ $self->_remove_alias($values, $alias) },
1764     -source_handle => $self->_source_handle,
1765     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1766   );
1767
1768   return $self->result_class->new(\%new);
1769 }
1770
1771 # _is_deterministic_value
1772 #
1773 # Make an effor to strip non-deterministic values from the condition,
1774 # to make sure new_result chokes less
1775
1776 sub _is_deterministic_value {
1777   my $self = shift;
1778   my $value = shift;
1779   my $ref_type = ref $value;
1780   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1781   return 1 if Scalar::Util::blessed($value);
1782   return 0;
1783 }
1784
1785 # _collapse_cond
1786 #
1787 # Recursively collapse the condition.
1788
1789 sub _collapse_cond {
1790   my ($self, $cond, $collapsed) = @_;
1791
1792   $collapsed ||= {};
1793
1794   if (ref $cond eq 'ARRAY') {
1795     foreach my $subcond (@$cond) {
1796       next unless ref $subcond;  # -or
1797 #      warn "ARRAY: " . Dumper $subcond;
1798       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1799     }
1800   }
1801   elsif (ref $cond eq 'HASH') {
1802     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1803       foreach my $subcond (@{$cond->{-and}}) {
1804 #        warn "HASH: " . Dumper $subcond;
1805         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1806       }
1807     }
1808     else {
1809 #      warn "LEAF: " . Dumper $cond;
1810       foreach my $col (keys %$cond) {
1811         my $value = $cond->{$col};
1812         $collapsed->{$col} = $value;
1813       }
1814     }
1815   }
1816
1817   return $collapsed;
1818 }
1819
1820 # _remove_alias
1821 #
1822 # Remove the specified alias from the specified query hash. A copy is made so
1823 # the original query is not modified.
1824
1825 sub _remove_alias {
1826   my ($self, $query, $alias) = @_;
1827
1828   my %orig = %{ $query || {} };
1829   my %unaliased;
1830
1831   foreach my $key (keys %orig) {
1832     if ($key !~ /\./) {
1833       $unaliased{$key} = $orig{$key};
1834       next;
1835     }
1836     $unaliased{$1} = $orig{$key}
1837       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1838   }
1839
1840   return \%unaliased;
1841 }
1842
1843 =head2 as_query (EXPERIMENTAL)
1844
1845 =over 4
1846
1847 =item Arguments: none
1848
1849 =item Return Value: \[ $sql, @bind ]
1850
1851 =back
1852
1853 Returns the SQL query and bind vars associated with the invocant.
1854
1855 This is generally used as the RHS for a subquery.
1856
1857 B<NOTE>: This feature is still experimental.
1858
1859 =cut
1860
1861 sub as_query { return shift->cursor->as_query(@_) }
1862
1863 =head2 find_or_new
1864
1865 =over 4
1866
1867 =item Arguments: \%vals, \%attrs?
1868
1869 =item Return Value: $rowobject
1870
1871 =back
1872
1873   my $artist = $schema->resultset('Artist')->find_or_new(
1874     { artist => 'fred' }, { key => 'artists' });
1875
1876   $cd->cd_to_producer->find_or_new({ producer => $producer },
1877                                    { key => 'primary });
1878
1879 Find an existing record from this resultset, based on its primary
1880 key, or a unique constraint. If none exists, instantiate a new result
1881 object and return it. The object will not be saved into your storage
1882 until you call L<DBIx::Class::Row/insert> on it.
1883
1884 You most likely want this method when looking for existing rows using
1885 a unique constraint that is not the primary key, or looking for
1886 related rows.
1887
1888 If you want objects to be saved immediately, use L</find_or_create> instead.
1889
1890 B<Note>: C<find_or_new> is probably not what you want when creating a
1891 new row in a table that uses primary keys supplied by the
1892 database. Passing in a primary key column with a value of I<undef>
1893 will cause L</find> to attempt to search for a row with a value of
1894 I<NULL>.
1895
1896 =cut
1897
1898 sub find_or_new {
1899   my $self     = shift;
1900   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1901   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1902   my $exists   = $self->find($hash, $attrs);
1903   return defined $exists ? $exists : $self->new_result($hash);
1904 }
1905
1906 =head2 create
1907
1908 =over 4
1909
1910 =item Arguments: \%vals
1911
1912 =item Return Value: a L<DBIx::Class::Row> $object
1913
1914 =back
1915
1916 Attempt to create a single new row or a row with multiple related rows
1917 in the table represented by the resultset (and related tables). This
1918 will not check for duplicate rows before inserting, use
1919 L</find_or_create> to do that.
1920
1921 To create one row for this resultset, pass a hashref of key/value
1922 pairs representing the columns of the table and the values you wish to
1923 store. If the appropriate relationships are set up, foreign key fields
1924 can also be passed an object representing the foreign row, and the
1925 value will be set to its primary key.
1926
1927 To create related objects, pass a hashref for the value if the related
1928 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1929 and use the name of the relationship as the key. (NOT the name of the field,
1930 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1931 of hashrefs containing the data for each of the rows to create in the foreign
1932 tables, again using the relationship name as the key.
1933
1934 Instead of hashrefs of plain related data (key/value pairs), you may
1935 also pass new or inserted objects. New objects (not inserted yet, see
1936 L</new>), will be inserted into their appropriate tables.
1937
1938 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1939
1940 Example of creating a new row.
1941
1942   $person_rs->create({
1943     name=>"Some Person",
1944     email=>"somebody@someplace.com"
1945   });
1946
1947 Example of creating a new row and also creating rows in a related C<has_many>
1948 or C<has_one> resultset.  Note Arrayref.
1949
1950   $artist_rs->create(
1951      { artistid => 4, name => 'Manufactured Crap', cds => [
1952         { title => 'My First CD', year => 2006 },
1953         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1954       ],
1955      },
1956   );
1957
1958 Example of creating a new row and also creating a row in a related
1959 C<belongs_to>resultset. Note Hashref.
1960
1961   $cd_rs->create({
1962     title=>"Music for Silly Walks",
1963     year=>2000,
1964     artist => {
1965       name=>"Silly Musician",
1966     }
1967   });
1968
1969 =cut
1970
1971 sub create {
1972   my ($self, $attrs) = @_;
1973   $self->throw_exception( "create needs a hashref" )
1974     unless ref $attrs eq 'HASH';
1975   return $self->new_result($attrs)->insert;
1976 }
1977
1978 =head2 find_or_create
1979
1980 =over 4
1981
1982 =item Arguments: \%vals, \%attrs?
1983
1984 =item Return Value: $rowobject
1985
1986 =back
1987
1988   $cd->cd_to_producer->find_or_create({ producer => $producer },
1989                                       { key => 'primary });
1990
1991 Tries to find a record based on its primary key or unique constraints; if none
1992 is found, creates one and returns that instead.
1993
1994   my $cd = $schema->resultset('CD')->find_or_create({
1995     cdid   => 5,
1996     artist => 'Massive Attack',
1997     title  => 'Mezzanine',
1998     year   => 2005,
1999   });
2000
2001 Also takes an optional C<key> attribute, to search by a specific key or unique
2002 constraint. For example:
2003
2004   my $cd = $schema->resultset('CD')->find_or_create(
2005     {
2006       artist => 'Massive Attack',
2007       title  => 'Mezzanine',
2008     },
2009     { key => 'cd_artist_title' }
2010   );
2011
2012 B<Note>: Because find_or_create() reads from the database and then
2013 possibly inserts based on the result, this method is subject to a race
2014 condition. Another process could create a record in the table after
2015 the find has completed and before the create has started. To avoid
2016 this problem, use find_or_create() inside a transaction.
2017
2018 B<Note>: C<find_or_create> is probably not what you want when creating
2019 a new row in a table that uses primary keys supplied by the
2020 database. Passing in a primary key column with a value of I<undef>
2021 will cause L</find> to attempt to search for a row with a value of
2022 I<NULL>.
2023
2024 See also L</find> and L</update_or_create>. For information on how to declare
2025 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2026
2027 =cut
2028
2029 sub find_or_create {
2030   my $self     = shift;
2031   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2032   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2033   my $exists   = $self->find($hash, $attrs);
2034   return defined $exists ? $exists : $self->create($hash);
2035 }
2036
2037 =head2 update_or_create
2038
2039 =over 4
2040
2041 =item Arguments: \%col_values, { key => $unique_constraint }?
2042
2043 =item Return Value: $rowobject
2044
2045 =back
2046
2047   $resultset->update_or_create({ col => $val, ... });
2048
2049 First, searches for an existing row matching one of the unique constraints
2050 (including the primary key) on the source of this resultset. If a row is
2051 found, updates it with the other given column values. Otherwise, creates a new
2052 row.
2053
2054 Takes an optional C<key> attribute to search on a specific unique constraint.
2055 For example:
2056
2057   # In your application
2058   my $cd = $schema->resultset('CD')->update_or_create(
2059     {
2060       artist => 'Massive Attack',
2061       title  => 'Mezzanine',
2062       year   => 1998,
2063     },
2064     { key => 'cd_artist_title' }
2065   );
2066
2067   $cd->cd_to_producer->update_or_create({
2068     producer => $producer,
2069     name => 'harry',
2070   }, {
2071     key => 'primary,
2072   });
2073
2074
2075 If no C<key> is specified, it searches on all unique constraints defined on the
2076 source, including the primary key.
2077
2078 If the C<key> is specified as C<primary>, it searches only on the primary key.
2079
2080 See also L</find> and L</find_or_create>. For information on how to declare
2081 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2082
2083 B<Note>: C<update_or_create> is probably not what you want when
2084 looking for a row in a table that uses primary keys supplied by the
2085 database, unless you actually have a key value. Passing in a primary
2086 key column with a value of I<undef> will cause L</find> to attempt to
2087 search for a row with a value of I<NULL>.
2088
2089 =cut
2090
2091 sub update_or_create {
2092   my $self = shift;
2093   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2094   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2095
2096   my $row = $self->find($cond, $attrs);
2097   if (defined $row) {
2098     $row->update($cond);
2099     return $row;
2100   }
2101
2102   return $self->create($cond);
2103 }
2104
2105 =head2 get_cache
2106
2107 =over 4
2108
2109 =item Arguments: none
2110
2111 =item Return Value: \@cache_objects?
2112
2113 =back
2114
2115 Gets the contents of the cache for the resultset, if the cache is set.
2116
2117 The cache is populated either by using the L</prefetch> attribute to
2118 L</search> or by calling L</set_cache>.
2119
2120 =cut
2121
2122 sub get_cache {
2123   shift->{all_cache};
2124 }
2125
2126 =head2 set_cache
2127
2128 =over 4
2129
2130 =item Arguments: \@cache_objects
2131
2132 =item Return Value: \@cache_objects
2133
2134 =back
2135
2136 Sets the contents of the cache for the resultset. Expects an arrayref
2137 of objects of the same class as those produced by the resultset. Note that
2138 if the cache is set the resultset will return the cached objects rather
2139 than re-querying the database even if the cache attr is not set.
2140
2141 The contents of the cache can also be populated by using the
2142 L</prefetch> attribute to L</search>.
2143
2144 =cut
2145
2146 sub set_cache {
2147   my ( $self, $data ) = @_;
2148   $self->throw_exception("set_cache requires an arrayref")
2149       if defined($data) && (ref $data ne 'ARRAY');
2150   $self->{all_cache} = $data;
2151 }
2152
2153 =head2 clear_cache
2154
2155 =over 4
2156
2157 =item Arguments: none
2158
2159 =item Return Value: []
2160
2161 =back
2162
2163 Clears the cache for the resultset.
2164
2165 =cut
2166
2167 sub clear_cache {
2168   shift->set_cache(undef);
2169 }
2170
2171 =head2 related_resultset
2172
2173 =over 4
2174
2175 =item Arguments: $relationship_name
2176
2177 =item Return Value: $resultset
2178
2179 =back
2180
2181 Returns a related resultset for the supplied relationship name.
2182
2183   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2184
2185 =cut
2186
2187 sub related_resultset {
2188   my ($self, $rel) = @_;
2189
2190   $self->{related_resultsets} ||= {};
2191   return $self->{related_resultsets}{$rel} ||= do {
2192     my $rel_obj = $self->result_source->relationship_info($rel);
2193
2194     $self->throw_exception(
2195       "search_related: result source '" . $self->result_source->source_name .
2196         "' has no such relationship $rel")
2197       unless $rel_obj;
2198
2199     my ($from,$seen) = $self->_resolve_from($rel);
2200
2201     my $join_count = $seen->{$rel};
2202     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2203
2204     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2205     my %attrs = %{$self->{attrs}||{}};
2206     delete @attrs{qw(result_class alias)};
2207
2208     my $new_cache;
2209
2210     if (my $cache = $self->get_cache) {
2211       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2212         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2213                         @$cache ];
2214       }
2215     }
2216
2217     my $rel_source = $self->result_source->related_source($rel);
2218
2219     my $new = do {
2220
2221       # The reason we do this now instead of passing the alias to the
2222       # search_rs below is that if you wrap/overload resultset on the
2223       # source you need to know what alias it's -going- to have for things
2224       # to work sanely (e.g. RestrictWithObject wants to be able to add
2225       # extra query restrictions, and these may need to be $alias.)
2226
2227       my $attrs = $rel_source->resultset_attributes;
2228       local $attrs->{alias} = $alias;
2229
2230       $rel_source->resultset
2231                  ->search_rs(
2232                      undef, {
2233                        %attrs,
2234                        join => undef,
2235                        prefetch => undef,
2236                        select => undef,
2237                        as => undef,
2238                        where => $self->{cond},
2239                        seen_join => $seen,
2240                        from => $from,
2241                    });
2242     };
2243     $new->set_cache($new_cache) if $new_cache;
2244     $new;
2245   };
2246 }
2247
2248 =head2 current_source_alias
2249
2250 =over 4
2251
2252 =item Arguments: none
2253
2254 =item Return Value: $source_alias
2255
2256 =back
2257
2258 Returns the current table alias for the result source this resultset is built
2259 on, that will be used in the SQL query. Usually it is C<me>.
2260
2261 Currently the source alias that refers to the result set returned by a
2262 L</search>/L</find> family method depends on how you got to the resultset: it's
2263 C<me> by default, but eg. L</search_related> aliases it to the related result
2264 source name (and keeps C<me> referring to the original result set). The long
2265 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2266 (and make this method unnecessary).
2267
2268 Thus it's currently necessary to use this method in predefined queries (see
2269 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2270 source alias of the current result set:
2271
2272   # in a result set class
2273   sub modified_by {
2274     my ($self, $user) = @_;
2275
2276     my $me = $self->current_source_alias;
2277
2278     return $self->search(
2279       "$me.modified" => $user->id,
2280     );
2281   }
2282
2283 =cut
2284
2285 sub current_source_alias {
2286   my ($self) = @_;
2287
2288   return ($self->{attrs} || {})->{alias} || 'me';
2289 }
2290
2291 sub _resolve_from {
2292   my ($self, $extra_join) = @_;
2293   my $source = $self->result_source;
2294   my $attrs = $self->{attrs};
2295
2296   my $from = $attrs->{from}
2297     || [ { $attrs->{alias} => $source->from } ];
2298
2299   my $seen = { %{$attrs->{seen_join}||{}} };
2300
2301   my $join = ($attrs->{join}
2302                ? [ $attrs->{join}, $extra_join ]
2303                : $extra_join);
2304
2305   # we need to take the prefetch the attrs into account before we
2306   # ->resolve_join as otherwise they get lost - captainL
2307   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2308
2309   $from = [
2310     @$from,
2311     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2312   ];
2313
2314   return ($from,$seen);
2315 }
2316
2317 sub _resolved_attrs {
2318   my $self = shift;
2319   return $self->{_attrs} if $self->{_attrs};
2320
2321   my $attrs  = { %{ $self->{attrs} || {} } };
2322   my $source = $self->result_source;
2323   my $alias  = $attrs->{alias};
2324
2325   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2326   my @colbits;
2327
2328   # build columns (as long as select isn't set) into a set of as/select hashes
2329   unless ( $attrs->{select} ) {
2330       @colbits = map {
2331           ( ref($_) eq 'HASH' ) ? $_
2332             : {
2333               (
2334                   /^\Q${alias}.\E(.+)$/ ? $1
2335                   : $_
2336                 ) => ( /\./ ? $_ : "${alias}.$_" )
2337             }
2338       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2339   }
2340   # add the additional columns on
2341   foreach ( 'include_columns', '+columns' ) {
2342       push @colbits, map {
2343           ( ref($_) eq 'HASH' )
2344             ? $_
2345             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2346       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2347   }
2348
2349   # start with initial select items
2350   if ( $attrs->{select} ) {
2351     $attrs->{select} =
2352         ( ref $attrs->{select} eq 'ARRAY' )
2353       ? [ @{ $attrs->{select} } ]
2354       : [ $attrs->{select} ];
2355     $attrs->{as} = (
2356       $attrs->{as}
2357       ? (
2358         ref $attrs->{as} eq 'ARRAY'
2359         ? [ @{ $attrs->{as} } ]
2360         : [ $attrs->{as} ]
2361         )
2362       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2363     );
2364   }
2365   else {
2366
2367     # otherwise we intialise select & as to empty
2368     $attrs->{select} = [];
2369     $attrs->{as}     = [];
2370   }
2371
2372   # now add colbits to select/as
2373   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2374   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2375
2376   my $adds;
2377   if ( $adds = delete $attrs->{'+select'} ) {
2378     $adds = [$adds] unless ref $adds eq 'ARRAY';
2379     push(
2380       @{ $attrs->{select} },
2381       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2382     );
2383   }
2384   if ( $adds = delete $attrs->{'+as'} ) {
2385     $adds = [$adds] unless ref $adds eq 'ARRAY';
2386     push( @{ $attrs->{as} }, @$adds );
2387   }
2388
2389   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2390
2391   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2392     my $join = delete $attrs->{join} || {};
2393
2394     if ( defined $attrs->{prefetch} ) {
2395       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2396
2397     }
2398
2399     $attrs->{from} =    # have to copy here to avoid corrupting the original
2400       [
2401       @{ $attrs->{from} },
2402       $source->resolve_join(
2403         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2404       )
2405       ];
2406
2407   }
2408
2409   $attrs->{group_by} ||= $attrs->{select}
2410     if delete $attrs->{distinct};
2411   if ( $attrs->{order_by} ) {
2412     $attrs->{order_by} = (
2413       ref( $attrs->{order_by} ) eq 'ARRAY'
2414       ? [ @{ $attrs->{order_by} } ]
2415       : [ $attrs->{order_by} ]
2416     );
2417   }
2418   else {
2419     $attrs->{order_by} = [];
2420   }
2421
2422   my $collapse = $attrs->{collapse} || {};
2423   if ( my $prefetch = delete $attrs->{prefetch} ) {
2424     $prefetch = $self->_merge_attr( {}, $prefetch );
2425     my @pre_order;
2426     my $seen = { %{ $attrs->{seen_join} || {} } };
2427     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2428
2429       # bring joins back to level of current class
2430       my @prefetch =
2431         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2432       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2433       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2434     }
2435     push( @{ $attrs->{order_by} }, @pre_order );
2436   }
2437   $attrs->{collapse} = $collapse;
2438
2439   if ( $attrs->{page} ) {
2440     $attrs->{offset} ||= 0;
2441     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2442   }
2443
2444   return $self->{_attrs} = $attrs;
2445 }
2446
2447 sub _rollout_attr {
2448   my ($self, $attr) = @_;
2449
2450   if (ref $attr eq 'HASH') {
2451     return $self->_rollout_hash($attr);
2452   } elsif (ref $attr eq 'ARRAY') {
2453     return $self->_rollout_array($attr);
2454   } else {
2455     return [$attr];
2456   }
2457 }
2458
2459 sub _rollout_array {
2460   my ($self, $attr) = @_;
2461
2462   my @rolled_array;
2463   foreach my $element (@{$attr}) {
2464     if (ref $element eq 'HASH') {
2465       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2466     } elsif (ref $element eq 'ARRAY') {
2467       #  XXX - should probably recurse here
2468       push( @rolled_array, @{$self->_rollout_array($element)} );
2469     } else {
2470       push( @rolled_array, $element );
2471     }
2472   }
2473   return \@rolled_array;
2474 }
2475
2476 sub _rollout_hash {
2477   my ($self, $attr) = @_;
2478
2479   my @rolled_array;
2480   foreach my $key (keys %{$attr}) {
2481     push( @rolled_array, { $key => $attr->{$key} } );
2482   }
2483   return \@rolled_array;
2484 }
2485
2486 sub _calculate_score {
2487   my ($self, $a, $b) = @_;
2488
2489   if (ref $b eq 'HASH') {
2490     my ($b_key) = keys %{$b};
2491     if (ref $a eq 'HASH') {
2492       my ($a_key) = keys %{$a};
2493       if ($a_key eq $b_key) {
2494         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2495       } else {
2496         return 0;
2497       }
2498     } else {
2499       return ($a eq $b_key) ? 1 : 0;
2500     }
2501   } else {
2502     if (ref $a eq 'HASH') {
2503       my ($a_key) = keys %{$a};
2504       return ($b eq $a_key) ? 1 : 0;
2505     } else {
2506       return ($b eq $a) ? 1 : 0;
2507     }
2508   }
2509 }
2510
2511 sub _merge_attr {
2512   my ($self, $orig, $import) = @_;
2513
2514   return $import unless defined($orig);
2515   return $orig unless defined($import);
2516
2517   $orig = $self->_rollout_attr($orig);
2518   $import = $self->_rollout_attr($import);
2519
2520   my $seen_keys;
2521   foreach my $import_element ( @{$import} ) {
2522     # find best candidate from $orig to merge $b_element into
2523     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2524     foreach my $orig_element ( @{$orig} ) {
2525       my $score = $self->_calculate_score( $orig_element, $import_element );
2526       if ($score > $best_candidate->{score}) {
2527         $best_candidate->{position} = $position;
2528         $best_candidate->{score} = $score;
2529       }
2530       $position++;
2531     }
2532     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2533
2534     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2535       push( @{$orig}, $import_element );
2536     } else {
2537       my $orig_best = $orig->[$best_candidate->{position}];
2538       # merge orig_best and b_element together and replace original with merged
2539       if (ref $orig_best ne 'HASH') {
2540         $orig->[$best_candidate->{position}] = $import_element;
2541       } elsif (ref $import_element eq 'HASH') {
2542         my ($key) = keys %{$orig_best};
2543         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2544       }
2545     }
2546     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2547   }
2548
2549   return $orig;
2550 }
2551
2552 sub result_source {
2553     my $self = shift;
2554
2555     if (@_) {
2556         $self->_source_handle($_[0]->handle);
2557     } else {
2558         $self->_source_handle->resolve;
2559     }
2560 }
2561
2562 =head2 throw_exception
2563
2564 See L<DBIx::Class::Schema/throw_exception> for details.
2565
2566 =cut
2567
2568 sub throw_exception {
2569   my $self=shift;
2570   if (ref $self && $self->_source_handle->schema) {
2571     $self->_source_handle->schema->throw_exception(@_)
2572   } else {
2573     croak(@_);
2574   }
2575
2576 }
2577
2578 # XXX: FIXME: Attributes docs need clearing up
2579
2580 =head1 ATTRIBUTES
2581
2582 Attributes are used to refine a ResultSet in various ways when
2583 searching for data. They can be passed to any method which takes an
2584 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2585 L</count>.
2586
2587 These are in no particular order:
2588
2589 =head2 order_by
2590
2591 =over 4
2592
2593 =item Value: ( $order_by | \@order_by | \%order_by )
2594
2595 =back
2596
2597 Which column(s) to order the results by. If a single column name, or
2598 an arrayref of names is supplied, the argument is passed through
2599 directly to SQL. The hashref syntax allows for connection-agnostic
2600 specification of ordering direction:
2601
2602  For descending order:
2603
2604   order_by => { -desc => [qw/col1 col2 col3/] }
2605
2606  For explicit ascending order:
2607
2608   order_by => { -asc => 'col' }
2609
2610 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2611 supported, although you are strongly encouraged to use the hashref
2612 syntax as outlined above.
2613
2614 =head2 columns
2615
2616 =over 4
2617
2618 =item Value: \@columns
2619
2620 =back
2621
2622 Shortcut to request a particular set of columns to be retrieved. Each
2623 column spec may be a string (a table column name), or a hash (in which
2624 case the key is the C<as> value, and the value is used as the C<select>
2625 expression). Adds C<me.> onto the start of any column without a C<.> in
2626 it and sets C<select> from that, then auto-populates C<as> from
2627 C<select> as normal. (You may also use the C<cols> attribute, as in
2628 earlier versions of DBIC.)
2629
2630 =head2 +columns
2631
2632 =over 4
2633
2634 =item Value: \@columns
2635
2636 =back
2637
2638 Indicates additional columns to be selected from storage. Works the same
2639 as L</columns> but adds columns to the selection. (You may also use the
2640 C<include_columns> attribute, as in earlier versions of DBIC). For
2641 example:-
2642
2643   $schema->resultset('CD')->search(undef, {
2644     '+columns' => ['artist.name'],
2645     join => ['artist']
2646   });
2647
2648 would return all CDs and include a 'name' column to the information
2649 passed to object inflation. Note that the 'artist' is the name of the
2650 column (or relationship) accessor, and 'name' is the name of the column
2651 accessor in the related table.
2652
2653 =head2 include_columns
2654
2655 =over 4
2656
2657 =item Value: \@columns
2658
2659 =back
2660
2661 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2662
2663 =head2 select
2664
2665 =over 4
2666
2667 =item Value: \@select_columns
2668
2669 =back
2670
2671 Indicates which columns should be selected from the storage. You can use
2672 column names, or in the case of RDBMS back ends, function or stored procedure
2673 names:
2674
2675   $rs = $schema->resultset('Employee')->search(undef, {
2676     select => [
2677       'name',
2678       { count => 'employeeid' },
2679       { sum => 'salary' }
2680     ]
2681   });
2682
2683 When you use function/stored procedure names and do not supply an C<as>
2684 attribute, the column names returned are storage-dependent. E.g. MySQL would
2685 return a column named C<count(employeeid)> in the above example.
2686
2687 =head2 +select
2688
2689 =over 4
2690
2691 Indicates additional columns to be selected from storage.  Works the same as
2692 L</select> but adds columns to the selection.
2693
2694 =back
2695
2696 =head2 +as
2697
2698 =over 4
2699
2700 Indicates additional column names for those added via L</+select>. See L</as>.
2701
2702 =back
2703
2704 =head2 as
2705
2706 =over 4
2707
2708 =item Value: \@inflation_names
2709
2710 =back
2711
2712 Indicates column names for object inflation. That is, C<as>
2713 indicates the name that the column can be accessed as via the
2714 C<get_column> method (or via the object accessor, B<if one already
2715 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2716
2717 The C<as> attribute is used in conjunction with C<select>,
2718 usually when C<select> contains one or more function or stored
2719 procedure names:
2720
2721   $rs = $schema->resultset('Employee')->search(undef, {
2722     select => [
2723       'name',
2724       { count => 'employeeid' }
2725     ],
2726     as => ['name', 'employee_count'],
2727   });
2728
2729   my $employee = $rs->first(); # get the first Employee
2730
2731 If the object against which the search is performed already has an accessor
2732 matching a column name specified in C<as>, the value can be retrieved using
2733 the accessor as normal:
2734
2735   my $name = $employee->name();
2736
2737 If on the other hand an accessor does not exist in the object, you need to
2738 use C<get_column> instead:
2739
2740   my $employee_count = $employee->get_column('employee_count');
2741
2742 You can create your own accessors if required - see
2743 L<DBIx::Class::Manual::Cookbook> for details.
2744
2745 Please note: This will NOT insert an C<AS employee_count> into the SQL
2746 statement produced, it is used for internal access only. Thus
2747 attempting to use the accessor in an C<order_by> clause or similar
2748 will fail miserably.
2749
2750 To get around this limitation, you can supply literal SQL to your
2751 C<select> attibute that contains the C<AS alias> text, eg:
2752
2753   select => [\'myfield AS alias']
2754
2755 =head2 join
2756
2757 =over 4
2758
2759 =item Value: ($rel_name | \@rel_names | \%rel_names)
2760
2761 =back
2762
2763 Contains a list of relationships that should be joined for this query.  For
2764 example:
2765
2766   # Get CDs by Nine Inch Nails
2767   my $rs = $schema->resultset('CD')->search(
2768     { 'artist.name' => 'Nine Inch Nails' },
2769     { join => 'artist' }
2770   );
2771
2772 Can also contain a hash reference to refer to the other relation's relations.
2773 For example:
2774
2775   package MyApp::Schema::Track;
2776   use base qw/DBIx::Class/;
2777   __PACKAGE__->table('track');
2778   __PACKAGE__->add_columns(qw/trackid cd position title/);
2779   __PACKAGE__->set_primary_key('trackid');
2780   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2781   1;
2782
2783   # In your application
2784   my $rs = $schema->resultset('Artist')->search(
2785     { 'track.title' => 'Teardrop' },
2786     {
2787       join     => { cd => 'track' },
2788       order_by => 'artist.name',
2789     }
2790   );
2791
2792 You need to use the relationship (not the table) name in  conditions,
2793 because they are aliased as such. The current table is aliased as "me", so
2794 you need to use me.column_name in order to avoid ambiguity. For example:
2795
2796   # Get CDs from 1984 with a 'Foo' track
2797   my $rs = $schema->resultset('CD')->search(
2798     {
2799       'me.year' => 1984,
2800       'tracks.name' => 'Foo'
2801     },
2802     { join => 'tracks' }
2803   );
2804
2805 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2806 similarly for a third time). For e.g.
2807
2808   my $rs = $schema->resultset('Artist')->search({
2809     'cds.title'   => 'Down to Earth',
2810     'cds_2.title' => 'Popular',
2811   }, {
2812     join => [ qw/cds cds/ ],
2813   });
2814
2815 will return a set of all artists that have both a cd with title 'Down
2816 to Earth' and a cd with title 'Popular'.
2817
2818 If you want to fetch related objects from other tables as well, see C<prefetch>
2819 below.
2820
2821 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2822
2823 =head2 prefetch
2824
2825 =over 4
2826
2827 =item Value: ($rel_name | \@rel_names | \%rel_names)
2828
2829 =back
2830
2831 Contains one or more relationships that should be fetched along with
2832 the main query (when they are accessed afterwards the data will
2833 already be available, without extra queries to the database).  This is
2834 useful for when you know you will need the related objects, because it
2835 saves at least one query:
2836
2837   my $rs = $schema->resultset('Tag')->search(
2838     undef,
2839     {
2840       prefetch => {
2841         cd => 'artist'
2842       }
2843     }
2844   );
2845
2846 The initial search results in SQL like the following:
2847
2848   SELECT tag.*, cd.*, artist.* FROM tag
2849   JOIN cd ON tag.cd = cd.cdid
2850   JOIN artist ON cd.artist = artist.artistid
2851
2852 L<DBIx::Class> has no need to go back to the database when we access the
2853 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2854 case.
2855
2856 Simple prefetches will be joined automatically, so there is no need
2857 for a C<join> attribute in the above search.
2858
2859 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2860 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2861 with an accessor type of 'single' or 'filter'). A more complex example that
2862 prefetches an artists cds, the tracks on those cds, and the tags associted
2863 with that artist is given below (assuming many-to-many from artists to tags):
2864
2865  my $rs = $schema->resultset('Artist')->search(
2866    undef,
2867    {
2868      prefetch => [
2869        { cds => 'tracks' },
2870        { artist_tags => 'tags' }
2871      ]
2872    }
2873  );
2874
2875
2876 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2877 attributes will be ignored.
2878
2879 =head2 page
2880
2881 =over 4
2882
2883 =item Value: $page
2884
2885 =back
2886
2887 Makes the resultset paged and specifies the page to retrieve. Effectively
2888 identical to creating a non-pages resultset and then calling ->page($page)
2889 on it.
2890
2891 If L<rows> attribute is not specified it defualts to 10 rows per page.
2892
2893 When you have a paged resultset, L</count> will only return the number
2894 of rows in the page. To get the total, use the L</pager> and call
2895 C<total_entries> on it.
2896
2897 =head2 rows
2898
2899 =over 4
2900
2901 =item Value: $rows
2902
2903 =back
2904
2905 Specifes the maximum number of rows for direct retrieval or the number of
2906 rows per page if the page attribute or method is used.
2907
2908 =head2 offset
2909
2910 =over 4
2911
2912 =item Value: $offset
2913
2914 =back
2915
2916 Specifies the (zero-based) row number for the  first row to be returned, or the
2917 of the first row of the first page if paging is used.
2918
2919 =head2 group_by
2920
2921 =over 4
2922
2923 =item Value: \@columns
2924
2925 =back
2926
2927 A arrayref of columns to group by. Can include columns of joined tables.
2928
2929   group_by => [qw/ column1 column2 ... /]
2930
2931 =head2 having
2932
2933 =over 4
2934
2935 =item Value: $condition
2936
2937 =back
2938
2939 HAVING is a select statement attribute that is applied between GROUP BY and
2940 ORDER BY. It is applied to the after the grouping calculations have been
2941 done.
2942
2943   having => { 'count(employee)' => { '>=', 100 } }
2944
2945 =head2 distinct
2946
2947 =over 4
2948
2949 =item Value: (0 | 1)
2950
2951 =back
2952
2953 Set to 1 to group by all columns.
2954
2955 =head2 where
2956
2957 =over 4
2958
2959 Adds to the WHERE clause.
2960
2961   # only return rows WHERE deleted IS NULL for all searches
2962   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2963
2964 Can be overridden by passing C<{ where => undef }> as an attribute
2965 to a resulset.
2966
2967 =back
2968
2969 =head2 cache
2970
2971 Set to 1 to cache search results. This prevents extra SQL queries if you
2972 revisit rows in your ResultSet:
2973
2974   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2975
2976   while( my $artist = $resultset->next ) {
2977     ... do stuff ...
2978   }
2979
2980   $rs->first; # without cache, this would issue a query
2981
2982 By default, searches are not cached.
2983
2984 For more examples of using these attributes, see
2985 L<DBIx::Class::Manual::Cookbook>.
2986
2987 =head2 from
2988
2989 =over 4
2990
2991 =item Value: \@from_clause
2992
2993 =back
2994
2995 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
2996 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
2997 clauses.
2998
2999 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3000
3001 C<join> will usually do what you need and it is strongly recommended that you
3002 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3003 And we really do mean "cannot", not just tried and failed. Attempting to use
3004 this because you're having problems with C<join> is like trying to use x86
3005 ASM because you've got a syntax error in your C. Trust us on this.
3006
3007 Now, if you're still really, really sure you need to use this (and if you're
3008 not 100% sure, ask the mailing list first), here's an explanation of how this
3009 works.
3010
3011 The syntax is as follows -
3012
3013   [
3014     { <alias1> => <table1> },
3015     [
3016       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3017       [], # nested JOIN (optional)
3018       { <table1.column1> => <table2.column2>, ... (more conditions) },
3019     ],
3020     # More of the above [ ] may follow for additional joins
3021   ]
3022
3023   <table1> <alias1>
3024   JOIN
3025     <table2> <alias2>
3026     [JOIN ...]
3027   ON <table1.column1> = <table2.column2>
3028   <more joins may follow>
3029
3030 An easy way to follow the examples below is to remember the following:
3031
3032     Anything inside "[]" is a JOIN
3033     Anything inside "{}" is a condition for the enclosing JOIN
3034
3035 The following examples utilize a "person" table in a family tree application.
3036 In order to express parent->child relationships, this table is self-joined:
3037
3038     # Person->belongs_to('father' => 'Person');
3039     # Person->belongs_to('mother' => 'Person');
3040
3041 C<from> can be used to nest joins. Here we return all children with a father,
3042 then search against all mothers of those children:
3043
3044   $rs = $schema->resultset('Person')->search(
3045       undef,
3046       {
3047           alias => 'mother', # alias columns in accordance with "from"
3048           from => [
3049               { mother => 'person' },
3050               [
3051                   [
3052                       { child => 'person' },
3053                       [
3054                           { father => 'person' },
3055                           { 'father.person_id' => 'child.father_id' }
3056                       ]
3057                   ],
3058                   { 'mother.person_id' => 'child.mother_id' }
3059               ],
3060           ]
3061       },
3062   );
3063
3064   # Equivalent SQL:
3065   # SELECT mother.* FROM person mother
3066   # JOIN (
3067   #   person child
3068   #   JOIN person father
3069   #   ON ( father.person_id = child.father_id )
3070   # )
3071   # ON ( mother.person_id = child.mother_id )
3072
3073 The type of any join can be controlled manually. To search against only people
3074 with a father in the person table, we could explicitly use C<INNER JOIN>:
3075
3076     $rs = $schema->resultset('Person')->search(
3077         undef,
3078         {
3079             alias => 'child', # alias columns in accordance with "from"
3080             from => [
3081                 { child => 'person' },
3082                 [
3083                     { father => 'person', -join_type => 'inner' },
3084                     { 'father.id' => 'child.father_id' }
3085                 ],
3086             ]
3087         },
3088     );
3089
3090     # Equivalent SQL:
3091     # SELECT child.* FROM person child
3092     # INNER JOIN person father ON child.father_id = father.id
3093
3094 If you need to express really complex joins or you need a subselect, you
3095 can supply literal SQL to C<from> via a scalar reference. In this case
3096 the contents of the scalar will replace the table name asscoiated with the
3097 resultsource.
3098
3099 WARNING: This technique might very well not work as expected on chained
3100 searches - you have been warned.
3101
3102     # Assuming the Event resultsource is defined as:
3103
3104         MySchema::Event->add_columns (
3105             sequence => {
3106                 data_type => 'INT',
3107                 is_auto_increment => 1,
3108             },
3109             location => {
3110                 data_type => 'INT',
3111             },
3112             type => {
3113                 data_type => 'INT',
3114             },
3115         );
3116         MySchema::Event->set_primary_key ('sequence');
3117
3118     # This will get back the latest event for every location. The column
3119     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3120     # combo to limit the resultset
3121
3122     $rs = $schema->resultset('Event');
3123     $table = $rs->result_source->name;
3124     $latest = $rs->search (
3125         undef,
3126         { from => \ "
3127             (SELECT e1.* FROM $table e1
3128                 JOIN $table e2
3129                     ON e1.location = e2.location
3130                     AND e1.sequence < e2.sequence
3131                 WHERE e2.sequence is NULL
3132             ) me",
3133         },
3134     );
3135
3136     # Equivalent SQL (with the DBIC chunks added):
3137
3138     SELECT me.sequence, me.location, me.type FROM
3139        (SELECT e1.* FROM events e1
3140            JOIN events e2
3141                ON e1.location = e2.location
3142                AND e1.sequence < e2.sequence
3143            WHERE e2.sequence is NULL
3144        ) me;
3145
3146 =head2 for
3147
3148 =over 4
3149
3150 =item Value: ( 'update' | 'shared' )
3151
3152 =back
3153
3154 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3155 ... FOR SHARED.
3156
3157 =cut
3158
3159 1;