lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   return $self->{cursor}
 665     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 666           $attrs->{where},$attrs);
 667 }
 668
 669 =head2 single
 670
 671 =over 4
 672
 673 =item Arguments: $cond?
 674
 675 =item Return Value: $row_object?
 676
 677 =back
 678
 679   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 680
 681 Inflates the first result without creating a cursor if the resultset has
 682 any records in it; if not returns nothing. Used by L</find> as a lean version of
 683 L</search>.
 684
 685 While this method can take an optional search condition (just like L</search>)
 686 being a fast-code-path it does not recognize search attributes. If you need to
 687 add extra joins or similar, call L</search> and then chain-call L</single> on the
 688 L<DBIx::Class::ResultSet> returned.
 689
 690 =over
 691
 692 =item B<Note>
 693
 694 As of 0.08100, this method enforces the assumption that the preceeding
 695 query returns only one row. If more than one row is returned, you will receive
 696 a warning:
 697
 698   Query returned more than one row
 699
 700 In this case, you should be using L</first> or L</find> instead, or if you really
 701 know what you are doing, use the L</rows> attribute to explicitly limit the size
 702 of the resultset.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715   if ($where) {
 716     if (defined $attrs->{where}) {
 717       $attrs->{where} = {
 718         '-and' =>
 719             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 720                $where, delete $attrs->{where} ]
 721       };
 722     } else {
 723       $attrs->{where} = $where;
 724     }
 725   }
 726
 727 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 728 #  unless ($self->_is_unique_query($attrs->{where})) {
 729 #    carp "Query not guaranteed to return a single row"
 730 #      . "; please declare your unique constraints or use search instead";
 731 #  }
 732
 733   my @data = $self->result_source->storage->select_single(
 734     $attrs->{from}, $attrs->{select},
 735     $attrs->{where}, $attrs
 736   );
 737
 738   return (@data ? ($self->_construct_object(@data))[0] : undef);
 739 }
 740
 741 # _is_unique_query
 742 #
 743 # Try to determine if the specified query is guaranteed to be unique, based on
 744 # the declared unique constraints.
 745
 746 sub _is_unique_query {
 747   my ($self, $query) = @_;
 748
 749   my $collapsed = $self->_collapse_query($query);
 750   my $alias = $self->{attrs}{alias};
 751
 752   foreach my $name ($self->result_source->unique_constraint_names) {
 753     my @unique_cols = map {
 754       "$alias.$_"
 755     } $self->result_source->unique_constraint_columns($name);
 756
 757     # Count the values for each unique column
 758     my %seen = map { $_ => 0 } @unique_cols;
 759
 760     foreach my $key (keys %$collapsed) {
 761       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 762       next unless exists $seen{$aliased};  # Additional constraints are okay
 763       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 764     }
 765
 766     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 767     return 1 unless grep { $_ != 1 } values %seen;
 768   }
 769
 770   return 0;
 771 }
 772
 773 # _collapse_query
 774 #
 775 # Recursively collapse the query, accumulating values for each column.
 776
 777 sub _collapse_query {
 778   my ($self, $query, $collapsed) = @_;
 779
 780   $collapsed ||= {};
 781
 782   if (ref $query eq 'ARRAY') {
 783     foreach my $subquery (@$query) {
 784       next unless ref $subquery;  # -or
 785       $collapsed = $self->_collapse_query($subquery, $collapsed);
 786     }
 787   }
 788   elsif (ref $query eq 'HASH') {
 789     if (keys %$query and (keys %$query)[0] eq '-and') {
 790       foreach my $subquery (@{$query->{-and}}) {
 791         $collapsed = $self->_collapse_query($subquery, $collapsed);
 792       }
 793     }
 794     else {
 795       foreach my $col (keys %$query) {
 796         my $value = $query->{$col};
 797         $collapsed->{$col}{$value}++;
 798       }
 799     }
 800   }
 801
 802   return $collapsed;
 803 }
 804
 805 =head2 get_column
 806
 807 =over 4
 808
 809 =item Arguments: $cond?
 810
 811 =item Return Value: $resultsetcolumn
 812
 813 =back
 814
 815   my $max_length = $rs->get_column('length')->max;
 816
 817 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 818
 819 =cut
 820
 821 sub get_column {
 822   my ($self, $column) = @_;
 823   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 824   return $new;
 825 }
 826
 827 =head2 search_like
 828
 829 =over 4
 830
 831 =item Arguments: $cond, \%attrs?
 832
 833 =item Return Value: $resultset (scalar context), @row_objs (list context)
 834
 835 =back
 836
 837   # WHERE title LIKE '%blue%'
 838   $cd_rs = $rs->search_like({ title => '%blue%'});
 839
 840 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 841 that this is simply a convenience method retained for ex Class::DBI users.
 842 You most likely want to use L</search> with specific operators.
 843
 844 For more information, see L<DBIx::Class::Manual::Cookbook>.
 845
 846 This method is deprecated and will be removed in 0.09. Use L</search()>
 847 instead. An example conversion is:
 848
 849   ->search_like({ foo => 'bar' });
 850
 851   # Becomes
 852
 853   ->search({ foo => { like => 'bar' } });
 854
 855 =cut
 856
 857 sub search_like {
 858   my $class = shift;
 859   carp (
 860     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 861    .' Instead use ->search({ x => { -like => "y%" } })'
 862    .' (note the outer pair of {}s - they are important!)'
 863   );
 864   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 865   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 866   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 867   return $class->search($query, { %$attrs });
 868 }
 869
 870 =head2 slice
 871
 872 =over 4
 873
 874 =item Arguments: $first, $last
 875
 876 =item Return Value: $resultset (scalar context), @row_objs (list context)
 877
 878 =back
 879
 880 Returns a resultset or object list representing a subset of elements from the
 881 resultset slice is called on. Indexes are from 0, i.e., to get the first
 882 three records, call:
 883
 884   my ($one, $two, $three) = $rs->slice(0, 2);
 885
 886 =cut
 887
 888 sub slice {
 889   my ($self, $min, $max) = @_;
 890   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 891   $attrs->{offset} = $self->{attrs}{offset} || 0;
 892   $attrs->{offset} += $min;
 893   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 894   return $self->search(undef(), $attrs);
 895   #my $slice = (ref $self)->new($self->result_source, $attrs);
 896   #return (wantarray ? $slice->all : $slice);
 897 }
 898
 899 =head2 next
 900
 901 =over 4
 902
 903 =item Arguments: none
 904
 905 =item Return Value: $result?
 906
 907 =back
 908
 909 Returns the next element in the resultset (C<undef> is there is none).
 910
 911 Can be used to efficiently iterate over records in the resultset:
 912
 913   my $rs = $schema->resultset('CD')->search;
 914   while (my $cd = $rs->next) {
 915     print $cd->title;
 916   }
 917
 918 Note that you need to store the resultset object, and call C<next> on it.
 919 Calling C<< resultset('Table')->next >> repeatedly will always return the
 920 first record from the resultset.
 921
 922 =cut
 923
 924 sub next {
 925   my ($self) = @_;
 926   if (my $cache = $self->get_cache) {
 927     $self->{all_cache_position} ||= 0;
 928     return $cache->[$self->{all_cache_position}++];
 929   }
 930   if ($self->{attrs}{cache}) {
 931     $self->{all_cache_position} = 1;
 932     return ($self->all)[0];
 933   }
 934   if ($self->{stashed_objects}) {
 935     my $obj = shift(@{$self->{stashed_objects}});
 936     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 937     return $obj;
 938   }
 939   my @row = (
 940     exists $self->{stashed_row}
 941       ? @{delete $self->{stashed_row}}
 942       : $self->cursor->next
 943   );
 944   return undef unless (@row);
 945   my ($row, @more) = $self->_construct_object(@row);
 946   $self->{stashed_objects} = \@more if @more;
 947   return $row;
 948 }
 949
 950 sub _construct_object {
 951   my ($self, @row) = @_;
 952   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 953   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 954   @new = $self->{_attrs}{record_filter}->(@new)
 955     if exists $self->{_attrs}{record_filter};
 956   return @new;
 957 }
 958
 959 sub _collapse_result {
 960   my ($self, $as_proto, $row) = @_;
 961
 962   my @copy = @$row;
 963
 964   # 'foo'         => [ undef, 'foo' ]
 965   # 'foo.bar'     => [ 'foo', 'bar' ]
 966   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 967
 968   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 969
 970   my %collapse = %{$self->{_attrs}{collapse}||{}};
 971
 972   my @pri_index;
 973
 974   # if we're doing collapsing (has_many prefetch) we need to grab records
 975   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 976   # we know we don't have to bother.
 977
 978   # the reason for not using the collapse stuff directly is because if you
 979   # had for e.g. two artists in a row with no cds, the collapse info for
 980   # both would be NULL (undef) so you'd lose the second artist
 981
 982   # store just the index so we can check the array positions from the row
 983   # without having to contruct the full hash
 984
 985   if (keys %collapse) {
 986     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 987     foreach my $i (0 .. $#construct_as) {
 988       next if defined($construct_as[$i][0]); # only self table
 989       if (delete $pri{$construct_as[$i][1]}) {
 990         push(@pri_index, $i);
 991       }
 992       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 993     }
 994   }
 995
 996   # no need to do an if, it'll be empty if @pri_index is empty anyway
 997
 998   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 999
1000   my @const_rows;
1001
1002   do { # no need to check anything at the front, we always want the first row
1003
1004     my %const;
1005
1006     foreach my $this_as (@construct_as) {
1007       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1008     }
1009
1010     push(@const_rows, \%const);
1011
1012   } until ( # no pri_index => no collapse => drop straight out
1013       !@pri_index
1014     or
1015       do { # get another row, stash it, drop out if different PK
1016
1017         @copy = $self->cursor->next;
1018         $self->{stashed_row} = \@copy;
1019
1020         # last thing in do block, counts as true if anything doesn't match
1021
1022         # check xor defined first for NULL vs. NOT NULL then if one is
1023         # defined the other must be so check string equality
1024
1025         grep {
1026           (defined $pri_vals{$_} ^ defined $copy[$_])
1027           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1028         } @pri_index;
1029       }
1030   );
1031
1032   my $alias = $self->{attrs}{alias};
1033   my $info = [];
1034
1035   my %collapse_pos;
1036
1037   my @const_keys;
1038
1039   foreach my $const (@const_rows) {
1040     scalar @const_keys or do {
1041       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1042     };
1043     foreach my $key (@const_keys) {
1044       if (length $key) {
1045         my $target = $info;
1046         my @parts = split(/\./, $key);
1047         my $cur = '';
1048         my $data = $const->{$key};
1049         foreach my $p (@parts) {
1050           $target = $target->[1]->{$p} ||= [];
1051           $cur .= ".${p}";
1052           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1053             # collapsing at this point and on final part
1054             my $pos = $collapse_pos{$cur};
1055             CK: foreach my $ck (@ckey) {
1056               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1057                 $collapse_pos{$cur} = $data;
1058                 delete @collapse_pos{ # clear all positioning for sub-entries
1059                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1060                 };
1061                 push(@$target, []);
1062                 last CK;
1063               }
1064             }
1065           }
1066           if (exists $collapse{$cur}) {
1067             $target = $target->[-1];
1068           }
1069         }
1070         $target->[0] = $data;
1071       } else {
1072         $info->[0] = $const->{$key};
1073       }
1074     }
1075   }
1076
1077   return $info;
1078 }
1079
1080 =head2 result_source
1081
1082 =over 4
1083
1084 =item Arguments: $result_source?
1085
1086 =item Return Value: $result_source
1087
1088 =back
1089
1090 An accessor for the primary ResultSource object from which this ResultSet
1091 is derived.
1092
1093 =head2 result_class
1094
1095 =over 4
1096
1097 =item Arguments: $result_class?
1098
1099 =item Return Value: $result_class
1100
1101 =back
1102
1103 An accessor for the class to use when creating row objects. Defaults to
1104 C<< result_source->result_class >> - which in most cases is the name of the
1105 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1106
1107 Note that changing the result_class will also remove any components
1108 that were originally loaded in the source class via
1109 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1110 in the original source class will not run.
1111
1112 =cut
1113
1114 sub result_class {
1115   my ($self, $result_class) = @_;
1116   if ($result_class) {
1117     $self->ensure_class_loaded($result_class);
1118     $self->_result_class($result_class);
1119   }
1120   $self->_result_class;
1121 }
1122
1123 =head2 count
1124
1125 =over 4
1126
1127 =item Arguments: $cond, \%attrs??
1128
1129 =item Return Value: $count
1130
1131 =back
1132
1133 Performs an SQL C<COUNT> with the same query as the resultset was built
1134 with to find the number of elements. Passing arguments is equivalent to
1135 C<< $rs->search ($cond, \%attrs)->count >>
1136
1137 =cut
1138
1139 sub count {
1140   my $self = shift;
1141   return $self->search(@_)->count if @_ and defined $_[0];
1142   return scalar @{ $self->get_cache } if $self->get_cache;
1143
1144   my @grouped_subq_attrs = qw/prefetch collapse distinct group_by having/;
1145   my @subq_attrs = ();
1146
1147   my $attrs = $self->_resolved_attrs;
1148   # if we are not paged - we are simply asking for a limit
1149   if (not $attrs->{page} and not $attrs->{software_limit}) {
1150     push @subq_attrs, qw/rows offset/;
1151   }
1152
1153   my $need_subq = $self->_has_attr (@subq_attrs);
1154   my $need_group_subq = $self->_has_attr (@grouped_subq_attrs);
1155
1156   return ($need_subq || $need_group_subq)
1157     ? $self->_count_subq ($need_group_subq)
1158     : $self->_count_simple
1159 }
1160
1161 sub _count_subq {
1162   my ($self, $add_group_by) = @_;
1163
1164   my $attrs = $self->_resolved_attrs_copy;
1165
1166   # copy for the subquery, we need to do some adjustments to it too
1167   my $sub_attrs = { %$attrs };
1168
1169   # these can not go in the subquery, and there is no point of ordering it
1170   delete $sub_attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns order_by/;
1171
1172   # if needed force a group_by and the same set of columns (most databases require this)
1173   if ($add_group_by) {
1174
1175     # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1176     # simply deleting group_by suffices, as the code below will re-fill it
1177     # Note: we check $attrs, as $sub_attrs has collapse deleted
1178     if (ref $attrs->{collapse} and keys %{$attrs->{collapse}} ) {
1179       delete $sub_attrs->{group_by};
1180     }
1181
1182     $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1183   }
1184
1185   $attrs->{from} = [{
1186     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1187   }];
1188
1189   # the subquery replaces this
1190   delete $attrs->{$_} for qw/where bind prefetch collapse distinct group_by having having_bind/;
1191
1192   return $self->__count ($attrs);
1193 }
1194
1195 sub _count_simple {
1196   my $self = shift;
1197
1198   my $count = $self->__count;
1199   return 0 unless $count;
1200
1201   # need to take offset from resolved attrs
1202
1203   my $attrs = $self->_resolved_attrs;
1204
1205   $count -= $attrs->{offset} if $attrs->{offset};
1206   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1207   $count = 0 if ($count < 0);
1208   return $count;
1209 }
1210
1211 sub __count {
1212   my ($self, $attrs) = @_;
1213
1214   $attrs ||= $self->_resolved_attrs_copy;
1215
1216   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1217   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1218
1219   $attrs->{select} = { count => '*' };
1220   $attrs->{as} = [qw/count/];
1221
1222   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1223   my ($count) = $tmp_rs->cursor->next;
1224
1225   return $count;
1226 }
1227
1228 sub _bool {
1229   return 1;
1230 }
1231
1232 =head2 count_literal
1233
1234 =over 4
1235
1236 =item Arguments: $sql_fragment, @bind_values
1237
1238 =item Return Value: $count
1239
1240 =back
1241
1242 Counts the results in a literal query. Equivalent to calling L</search_literal>
1243 with the passed arguments, then L</count>.
1244
1245 =cut
1246
1247 sub count_literal { shift->search_literal(@_)->count; }
1248
1249 =head2 all
1250
1251 =over 4
1252
1253 =item Arguments: none
1254
1255 =item Return Value: @objects
1256
1257 =back
1258
1259 Returns all elements in the resultset. Called implicitly if the resultset
1260 is returned in list context.
1261
1262 =cut
1263
1264 sub all {
1265   my $self = shift;
1266   if(@_) {
1267       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1268   }
1269
1270   return @{ $self->get_cache } if $self->get_cache;
1271
1272   my @obj;
1273
1274   # TODO: don't call resolve here
1275   if (keys %{$self->_resolved_attrs->{collapse}}) {
1276 #  if ($self->{attrs}{prefetch}) {
1277       # Using $self->cursor->all is really just an optimisation.
1278       # If we're collapsing has_many prefetches it probably makes
1279       # very little difference, and this is cleaner than hacking
1280       # _construct_object to survive the approach
1281     my @row = $self->cursor->next;
1282     while (@row) {
1283       push(@obj, $self->_construct_object(@row));
1284       @row = (exists $self->{stashed_row}
1285                ? @{delete $self->{stashed_row}}
1286                : $self->cursor->next);
1287     }
1288   } else {
1289     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1290   }
1291
1292   $self->set_cache(\@obj) if $self->{attrs}{cache};
1293   return @obj;
1294 }
1295
1296 =head2 reset
1297
1298 =over 4
1299
1300 =item Arguments: none
1301
1302 =item Return Value: $self
1303
1304 =back
1305
1306 Resets the resultset's cursor, so you can iterate through the elements again.
1307
1308 =cut
1309
1310 sub reset {
1311   my ($self) = @_;
1312   delete $self->{_attrs} if exists $self->{_attrs};
1313   $self->{all_cache_position} = 0;
1314   $self->cursor->reset;
1315   return $self;
1316 }
1317
1318 =head2 first
1319
1320 =over 4
1321
1322 =item Arguments: none
1323
1324 =item Return Value: $object?
1325
1326 =back
1327
1328 Resets the resultset and returns an object for the first result (if the
1329 resultset returns anything).
1330
1331 =cut
1332
1333 sub first {
1334   return $_[0]->reset->next;
1335 }
1336
1337
1338 # _rs_update_delete
1339 #
1340 # Determines whether and what type of subquery is required for the $rs operation.
1341 # If grouping is necessary either supplies its own, or verifies the current one
1342 # After all is done delegates to the proper storage method.
1343
1344 sub _rs_update_delete {
1345   my ($self, $op, $values) = @_;
1346
1347   my $rsrc = $self->result_source;
1348
1349   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1350   my $needs_subq = $self->_has_attr (qw/row offset page/);
1351
1352   if ($needs_group_by_subq or $needs_subq) {
1353
1354     # make a new $rs selecting only the PKs (that's all we really need)
1355     my $attrs = $self->_resolved_attrs_copy;
1356
1357     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1358     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1359
1360     if ($needs_group_by_subq) {
1361       # make sure no group_by was supplied, or if there is one - make sure it matches
1362       # the columns compiled above perfectly. Anything else can not be sanely executed
1363       # on most databases so croak right then and there
1364
1365       if (my $g = $attrs->{group_by}) {
1366         my @current_group_by = map
1367           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1368           (ref $g eq 'ARRAY' ? @$g : $g );
1369
1370         if (
1371           join ("\x00", sort @current_group_by)
1372             ne
1373           join ("\x00", sort @{$attrs->{columns}} )
1374         ) {
1375           $self->throw_exception (
1376             "You have just attempted a $op operation on a resultset which does group_by"
1377             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1378             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1379             . ' kind of queries. Please retry the operation with a modified group_by or'
1380             . ' without using one at all.'
1381           );
1382         }
1383       }
1384       else {
1385         $attrs->{group_by} = $attrs->{columns};
1386       }
1387     }
1388
1389     my $subrs = (ref $self)->new($rsrc, $attrs);
1390
1391     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1392   }
1393   else {
1394     return $rsrc->storage->$op(
1395       $rsrc,
1396       $op eq 'update' ? $values : (),
1397       $self->_cond_for_update_delete,
1398     );
1399   }
1400 }
1401
1402
1403 # _cond_for_update_delete
1404 #
1405 # update/delete require the condition to be modified to handle
1406 # the differing SQL syntax available.  This transforms the $self->{cond}
1407 # appropriately, returning the new condition.
1408
1409 sub _cond_for_update_delete {
1410   my ($self, $full_cond) = @_;
1411   my $cond = {};
1412
1413   $full_cond ||= $self->{cond};
1414   # No-op. No condition, we're updating/deleting everything
1415   return $cond unless ref $full_cond;
1416
1417   if (ref $full_cond eq 'ARRAY') {
1418     $cond = [
1419       map {
1420         my %hash;
1421         foreach my $key (keys %{$_}) {
1422           $key =~ /([^.]+)$/;
1423           $hash{$1} = $_->{$key};
1424         }
1425         \%hash;
1426       } @{$full_cond}
1427     ];
1428   }
1429   elsif (ref $full_cond eq 'HASH') {
1430     if ((keys %{$full_cond})[0] eq '-and') {
1431       $cond->{-and} = [];
1432       my @cond = @{$full_cond->{-and}};
1433        for (my $i = 0; $i < @cond; $i++) {
1434         my $entry = $cond[$i];
1435         my $hash;
1436         if (ref $entry eq 'HASH') {
1437           $hash = $self->_cond_for_update_delete($entry);
1438         }
1439         else {
1440           $entry =~ /([^.]+)$/;
1441           $hash->{$1} = $cond[++$i];
1442         }
1443         push @{$cond->{-and}}, $hash;
1444       }
1445     }
1446     else {
1447       foreach my $key (keys %{$full_cond}) {
1448         $key =~ /([^.]+)$/;
1449         $cond->{$1} = $full_cond->{$key};
1450       }
1451     }
1452   }
1453   else {
1454     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1455   }
1456
1457   return $cond;
1458 }
1459
1460
1461 =head2 update
1462
1463 =over 4
1464
1465 =item Arguments: \%values
1466
1467 =item Return Value: $storage_rv
1468
1469 =back
1470
1471 Sets the specified columns in the resultset to the supplied values in a
1472 single query. Return value will be true if the update succeeded or false
1473 if no records were updated; exact type of success value is storage-dependent.
1474
1475 =cut
1476
1477 sub update {
1478   my ($self, $values) = @_;
1479   $self->throw_exception('Values for update must be a hash')
1480     unless ref $values eq 'HASH';
1481
1482   return $self->_rs_update_delete ('update', $values);
1483 }
1484
1485 =head2 update_all
1486
1487 =over 4
1488
1489 =item Arguments: \%values
1490
1491 =item Return Value: 1
1492
1493 =back
1494
1495 Fetches all objects and updates them one at a time. Note that C<update_all>
1496 will run DBIC cascade triggers, while L</update> will not.
1497
1498 =cut
1499
1500 sub update_all {
1501   my ($self, $values) = @_;
1502   $self->throw_exception('Values for update_all must be a hash')
1503     unless ref $values eq 'HASH';
1504   foreach my $obj ($self->all) {
1505     $obj->set_columns($values)->update;
1506   }
1507   return 1;
1508 }
1509
1510 =head2 delete
1511
1512 =over 4
1513
1514 =item Arguments: none
1515
1516 =item Return Value: 1
1517
1518 =back
1519
1520 Deletes the contents of the resultset from its result source. Note that this
1521 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1522 to run. See also L<DBIx::Class::Row/delete>.
1523
1524 delete may not generate correct SQL for a query with joins or a resultset
1525 chained from a related resultset.  In this case it will generate a warning:-
1526
1527 In these cases you may find that delete_all is more appropriate, or you
1528 need to respecify your query in a way that can be expressed without a join.
1529
1530 =cut
1531
1532 sub delete {
1533   my $self = shift;
1534   $self->throw_exception('delete does not accept any arguments')
1535     if @_;
1536
1537   return $self->_rs_update_delete ('delete');
1538 }
1539
1540 =head2 delete_all
1541
1542 =over 4
1543
1544 =item Arguments: none
1545
1546 =item Return Value: 1
1547
1548 =back
1549
1550 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1551 will run DBIC cascade triggers, while L</delete> will not.
1552
1553 =cut
1554
1555 sub delete_all {
1556   my $self = shift;
1557   $self->throw_exception('delete_all does not accept any arguments')
1558     if @_;
1559
1560   $_->delete for $self->all;
1561   return 1;
1562 }
1563
1564 =head2 populate
1565
1566 =over 4
1567
1568 =item Arguments: \@data;
1569
1570 =back
1571
1572 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1573 For the arrayref of hashrefs style each hashref should be a structure suitable
1574 forsubmitting to a $resultset->create(...) method.
1575
1576 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1577 to insert the data, as this is a faster method.
1578
1579 Otherwise, each set of data is inserted into the database using
1580 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1581 objects is returned.
1582
1583 Example:  Assuming an Artist Class that has many CDs Classes relating:
1584
1585   my $Artist_rs = $schema->resultset("Artist");
1586
1587   ## Void Context Example
1588   $Artist_rs->populate([
1589      { artistid => 4, name => 'Manufactured Crap', cds => [
1590         { title => 'My First CD', year => 2006 },
1591         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1592       ],
1593      },
1594      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1595         { title => 'My parents sold me to a record company' ,year => 2005 },
1596         { title => 'Why Am I So Ugly?', year => 2006 },
1597         { title => 'I Got Surgery and am now Popular', year => 2007 }
1598       ],
1599      },
1600   ]);
1601
1602   ## Array Context Example
1603   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1604     { name => "Artist One"},
1605     { name => "Artist Two"},
1606     { name => "Artist Three", cds=> [
1607     { title => "First CD", year => 2007},
1608     { title => "Second CD", year => 2008},
1609   ]}
1610   ]);
1611
1612   print $ArtistOne->name; ## response is 'Artist One'
1613   print $ArtistThree->cds->count ## reponse is '2'
1614
1615 For the arrayref of arrayrefs style,  the first element should be a list of the
1616 fieldsnames to which the remaining elements are rows being inserted.  For
1617 example:
1618
1619   $Arstist_rs->populate([
1620     [qw/artistid name/],
1621     [100, 'A Formally Unknown Singer'],
1622     [101, 'A singer that jumped the shark two albums ago'],
1623     [102, 'An actually cool singer.'],
1624   ]);
1625
1626 Please note an important effect on your data when choosing between void and
1627 wantarray context. Since void context goes straight to C<insert_bulk> in
1628 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1629 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1630 create primary keys for you, you will find that your PKs are empty.  In this
1631 case you will have to use the wantarray context in order to create those
1632 values.
1633
1634 =cut
1635
1636 sub populate {
1637   my $self = shift @_;
1638   my $data = ref $_[0][0] eq 'HASH'
1639     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1640     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1641
1642   if(defined wantarray) {
1643     my @created;
1644     foreach my $item (@$data) {
1645       push(@created, $self->create($item));
1646     }
1647     return @created;
1648   } else {
1649     my ($first, @rest) = @$data;
1650
1651     my @names = grep {!ref $first->{$_}} keys %$first;
1652     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1653     my @pks = $self->result_source->primary_columns;
1654
1655     ## do the belongs_to relationships
1656     foreach my $index (0..$#$data) {
1657       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1658         my @ret = $self->populate($data);
1659         return;
1660       }
1661
1662       foreach my $rel (@rels) {
1663         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1664         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1665         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1666         my $related = $result->result_source->_resolve_condition(
1667           $result->result_source->relationship_info($reverse)->{cond},
1668           $self,
1669           $result,
1670         );
1671
1672         delete $data->[$index]->{$rel};
1673         $data->[$index] = {%{$data->[$index]}, %$related};
1674
1675         push @names, keys %$related if $index == 0;
1676       }
1677     }
1678
1679     ## do bulk insert on current row
1680     my @values = map { [ @$_{@names} ] } @$data;
1681
1682     $self->result_source->storage->insert_bulk(
1683       $self->result_source,
1684       \@names,
1685       \@values,
1686     );
1687
1688     ## do the has_many relationships
1689     foreach my $item (@$data) {
1690
1691       foreach my $rel (@rels) {
1692         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1693
1694         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1695      || $self->throw_exception('Cannot find the relating object.');
1696
1697         my $child = $parent->$rel;
1698
1699         my $related = $child->result_source->_resolve_condition(
1700           $parent->result_source->relationship_info($rel)->{cond},
1701           $child,
1702           $parent,
1703         );
1704
1705         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1706         my @populate = map { {%$_, %$related} } @rows_to_add;
1707
1708         $child->populate( \@populate );
1709       }
1710     }
1711   }
1712 }
1713
1714 =head2 _normalize_populate_args ($args)
1715
1716 Private method used by L</populate> to normalize its incoming arguments.  Factored
1717 out in case you want to subclass and accept new argument structures to the
1718 L</populate> method.
1719
1720 =cut
1721
1722 sub _normalize_populate_args {
1723   my ($self, $data) = @_;
1724   my @names = @{shift(@$data)};
1725   my @results_to_create;
1726   foreach my $datum (@$data) {
1727     my %result_to_create;
1728     foreach my $index (0..$#names) {
1729       $result_to_create{$names[$index]} = $$datum[$index];
1730     }
1731     push @results_to_create, \%result_to_create;
1732   }
1733   return \@results_to_create;
1734 }
1735
1736 =head2 pager
1737
1738 =over 4
1739
1740 =item Arguments: none
1741
1742 =item Return Value: $pager
1743
1744 =back
1745
1746 Return Value a L<Data::Page> object for the current resultset. Only makes
1747 sense for queries with a C<page> attribute.
1748
1749 To get the full count of entries for a paged resultset, call
1750 C<total_entries> on the L<Data::Page> object.
1751
1752 =cut
1753
1754 sub pager {
1755   my ($self) = @_;
1756
1757   return $self->{pager} if $self->{pager};
1758
1759   my $attrs = $self->{attrs};
1760   $self->throw_exception("Can't create pager for non-paged rs")
1761     unless $self->{attrs}{page};
1762   $attrs->{rows} ||= 10;
1763
1764   # throw away the paging flags and re-run the count (possibly
1765   # with a subselect) to get the real total count
1766   my $count_attrs = { %$attrs };
1767   delete $count_attrs->{$_} for qw/rows offset page pager/;
1768   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1769
1770   return $self->{pager} = Data::Page->new(
1771     $total_count,
1772     $attrs->{rows},
1773     $self->{attrs}{page}
1774   );
1775 }
1776
1777 =head2 page
1778
1779 =over 4
1780
1781 =item Arguments: $page_number
1782
1783 =item Return Value: $rs
1784
1785 =back
1786
1787 Returns a resultset for the $page_number page of the resultset on which page
1788 is called, where each page contains a number of rows equal to the 'rows'
1789 attribute set on the resultset (10 by default).
1790
1791 =cut
1792
1793 sub page {
1794   my ($self, $page) = @_;
1795   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1796 }
1797
1798 =head2 new_result
1799
1800 =over 4
1801
1802 =item Arguments: \%vals
1803
1804 =item Return Value: $rowobject
1805
1806 =back
1807
1808 Creates a new row object in the resultset's result class and returns
1809 it. The row is not inserted into the database at this point, call
1810 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1811 will tell you whether the row object has been inserted or not.
1812
1813 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1814
1815 =cut
1816
1817 sub new_result {
1818   my ($self, $values) = @_;
1819   $self->throw_exception( "new_result needs a hash" )
1820     unless (ref $values eq 'HASH');
1821
1822   my %new;
1823   my $alias = $self->{attrs}{alias};
1824
1825   if (
1826     defined $self->{cond}
1827     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1828   ) {
1829     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1830     $new{-from_resultset} = [ keys %new ] if keys %new;
1831   } else {
1832     $self->throw_exception(
1833       "Can't abstract implicit construct, condition not a hash"
1834     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1835
1836     my $collapsed_cond = (
1837       $self->{cond}
1838         ? $self->_collapse_cond($self->{cond})
1839         : {}
1840     );
1841
1842     # precendence must be given to passed values over values inherited from
1843     # the cond, so the order here is important.
1844     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1845     while( my($col,$value) = each %implied ){
1846       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1847         $new{$col} = $value->{'='};
1848         next;
1849       }
1850       $new{$col} = $value if $self->_is_deterministic_value($value);
1851     }
1852   }
1853
1854   %new = (
1855     %new,
1856     %{ $self->_remove_alias($values, $alias) },
1857     -source_handle => $self->_source_handle,
1858     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1859   );
1860
1861   return $self->result_class->new(\%new);
1862 }
1863
1864 # _is_deterministic_value
1865 #
1866 # Make an effor to strip non-deterministic values from the condition,
1867 # to make sure new_result chokes less
1868
1869 sub _is_deterministic_value {
1870   my $self = shift;
1871   my $value = shift;
1872   my $ref_type = ref $value;
1873   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1874   return 1 if Scalar::Util::blessed($value);
1875   return 0;
1876 }
1877
1878 # _has_attr
1879 #
1880 # determines if the resultset defines at least one
1881 # of the attributes supplied
1882 #
1883 # used to determine if a subquery is neccessary
1884
1885 sub _has_attr {
1886   my ($self, @attr_names) = @_;
1887
1888   my $attrs = $self->_resolved_attrs;
1889
1890   my $join_check_req;
1891
1892   for my $n (@attr_names) {
1893     ++$join_check_req if $n =~ /join/;
1894
1895     my $attr =  $attrs->{$n};
1896
1897     next if not defined $attr;
1898
1899     if (ref $attr eq 'HASH') {
1900       return 1 if keys %$attr;
1901     }
1902     elsif (ref $attr eq 'ARRAY') {
1903       return 1 if @$attr;
1904     }
1905     else {
1906       return 1 if $attr;
1907     }
1908   }
1909
1910   # a join can be expressed as a multi-level from
1911   return 1 if (
1912     $join_check_req
1913       and
1914     ref $attrs->{from} eq 'ARRAY'
1915       and
1916     @{$attrs->{from}} > 1
1917   );
1918
1919   return 0;
1920 }
1921
1922 # _collapse_cond
1923 #
1924 # Recursively collapse the condition.
1925
1926 sub _collapse_cond {
1927   my ($self, $cond, $collapsed) = @_;
1928
1929   $collapsed ||= {};
1930
1931   if (ref $cond eq 'ARRAY') {
1932     foreach my $subcond (@$cond) {
1933       next unless ref $subcond;  # -or
1934       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1935     }
1936   }
1937   elsif (ref $cond eq 'HASH') {
1938     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1939       foreach my $subcond (@{$cond->{-and}}) {
1940         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1941       }
1942     }
1943     else {
1944       foreach my $col (keys %$cond) {
1945         my $value = $cond->{$col};
1946         $collapsed->{$col} = $value;
1947       }
1948     }
1949   }
1950
1951   return $collapsed;
1952 }
1953
1954 # _remove_alias
1955 #
1956 # Remove the specified alias from the specified query hash. A copy is made so
1957 # the original query is not modified.
1958
1959 sub _remove_alias {
1960   my ($self, $query, $alias) = @_;
1961
1962   my %orig = %{ $query || {} };
1963   my %unaliased;
1964
1965   foreach my $key (keys %orig) {
1966     if ($key !~ /\./) {
1967       $unaliased{$key} = $orig{$key};
1968       next;
1969     }
1970     $unaliased{$1} = $orig{$key}
1971       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1972   }
1973
1974   return \%unaliased;
1975 }
1976
1977 =head2 as_query (EXPERIMENTAL)
1978
1979 =over 4
1980
1981 =item Arguments: none
1982
1983 =item Return Value: \[ $sql, @bind ]
1984
1985 =back
1986
1987 Returns the SQL query and bind vars associated with the invocant.
1988
1989 This is generally used as the RHS for a subquery.
1990
1991 B<NOTE>: This feature is still experimental.
1992
1993 =cut
1994
1995 sub as_query { return shift->cursor->as_query(@_) }
1996
1997 =head2 find_or_new
1998
1999 =over 4
2000
2001 =item Arguments: \%vals, \%attrs?
2002
2003 =item Return Value: $rowobject
2004
2005 =back
2006
2007   my $artist = $schema->resultset('Artist')->find_or_new(
2008     { artist => 'fred' }, { key => 'artists' });
2009
2010   $cd->cd_to_producer->find_or_new({ producer => $producer },
2011                                    { key => 'primary });
2012
2013 Find an existing record from this resultset, based on its primary
2014 key, or a unique constraint. If none exists, instantiate a new result
2015 object and return it. The object will not be saved into your storage
2016 until you call L<DBIx::Class::Row/insert> on it.
2017
2018 You most likely want this method when looking for existing rows using
2019 a unique constraint that is not the primary key, or looking for
2020 related rows.
2021
2022 If you want objects to be saved immediately, use L</find_or_create> instead.
2023
2024 B<Note>: C<find_or_new> is probably not what you want when creating a
2025 new row in a table that uses primary keys supplied by the
2026 database. Passing in a primary key column with a value of I<undef>
2027 will cause L</find> to attempt to search for a row with a value of
2028 I<NULL>.
2029
2030 =cut
2031
2032 sub find_or_new {
2033   my $self     = shift;
2034   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2035   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2036   my $exists   = $self->find($hash, $attrs);
2037   return defined $exists ? $exists : $self->new_result($hash);
2038 }
2039
2040 =head2 create
2041
2042 =over 4
2043
2044 =item Arguments: \%vals
2045
2046 =item Return Value: a L<DBIx::Class::Row> $object
2047
2048 =back
2049
2050 Attempt to create a single new row or a row with multiple related rows
2051 in the table represented by the resultset (and related tables). This
2052 will not check for duplicate rows before inserting, use
2053 L</find_or_create> to do that.
2054
2055 To create one row for this resultset, pass a hashref of key/value
2056 pairs representing the columns of the table and the values you wish to
2057 store. If the appropriate relationships are set up, foreign key fields
2058 can also be passed an object representing the foreign row, and the
2059 value will be set to its primary key.
2060
2061 To create related objects, pass a hashref for the value if the related
2062 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2063 and use the name of the relationship as the key. (NOT the name of the field,
2064 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2065 of hashrefs containing the data for each of the rows to create in the foreign
2066 tables, again using the relationship name as the key.
2067
2068 Instead of hashrefs of plain related data (key/value pairs), you may
2069 also pass new or inserted objects. New objects (not inserted yet, see
2070 L</new>), will be inserted into their appropriate tables.
2071
2072 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2073
2074 Example of creating a new row.
2075
2076   $person_rs->create({
2077     name=>"Some Person",
2078     email=>"somebody@someplace.com"
2079   });
2080
2081 Example of creating a new row and also creating rows in a related C<has_many>
2082 or C<has_one> resultset.  Note Arrayref.
2083
2084   $artist_rs->create(
2085      { artistid => 4, name => 'Manufactured Crap', cds => [
2086         { title => 'My First CD', year => 2006 },
2087         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2088       ],
2089      },
2090   );
2091
2092 Example of creating a new row and also creating a row in a related
2093 C<belongs_to>resultset. Note Hashref.
2094
2095   $cd_rs->create({
2096     title=>"Music for Silly Walks",
2097     year=>2000,
2098     artist => {
2099       name=>"Silly Musician",
2100     }
2101   });
2102
2103 =cut
2104
2105 sub create {
2106   my ($self, $attrs) = @_;
2107   $self->throw_exception( "create needs a hashref" )
2108     unless ref $attrs eq 'HASH';
2109   return $self->new_result($attrs)->insert;
2110 }
2111
2112 =head2 find_or_create
2113
2114 =over 4
2115
2116 =item Arguments: \%vals, \%attrs?
2117
2118 =item Return Value: $rowobject
2119
2120 =back
2121
2122   $cd->cd_to_producer->find_or_create({ producer => $producer },
2123                                       { key => 'primary });
2124
2125 Tries to find a record based on its primary key or unique constraints; if none
2126 is found, creates one and returns that instead.
2127
2128   my $cd = $schema->resultset('CD')->find_or_create({
2129     cdid   => 5,
2130     artist => 'Massive Attack',
2131     title  => 'Mezzanine',
2132     year   => 2005,
2133   });
2134
2135 Also takes an optional C<key> attribute, to search by a specific key or unique
2136 constraint. For example:
2137
2138   my $cd = $schema->resultset('CD')->find_or_create(
2139     {
2140       artist => 'Massive Attack',
2141       title  => 'Mezzanine',
2142     },
2143     { key => 'cd_artist_title' }
2144   );
2145
2146 B<Note>: Because find_or_create() reads from the database and then
2147 possibly inserts based on the result, this method is subject to a race
2148 condition. Another process could create a record in the table after
2149 the find has completed and before the create has started. To avoid
2150 this problem, use find_or_create() inside a transaction.
2151
2152 B<Note>: C<find_or_create> is probably not what you want when creating
2153 a new row in a table that uses primary keys supplied by the
2154 database. Passing in a primary key column with a value of I<undef>
2155 will cause L</find> to attempt to search for a row with a value of
2156 I<NULL>.
2157
2158 See also L</find> and L</update_or_create>. For information on how to declare
2159 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2160
2161 =cut
2162
2163 sub find_or_create {
2164   my $self     = shift;
2165   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2166   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2167   my $exists   = $self->find($hash, $attrs);
2168   return defined $exists ? $exists : $self->create($hash);
2169 }
2170
2171 =head2 update_or_create
2172
2173 =over 4
2174
2175 =item Arguments: \%col_values, { key => $unique_constraint }?
2176
2177 =item Return Value: $rowobject
2178
2179 =back
2180
2181   $resultset->update_or_create({ col => $val, ... });
2182
2183 First, searches for an existing row matching one of the unique constraints
2184 (including the primary key) on the source of this resultset. If a row is
2185 found, updates it with the other given column values. Otherwise, creates a new
2186 row.
2187
2188 Takes an optional C<key> attribute to search on a specific unique constraint.
2189 For example:
2190
2191   # In your application
2192   my $cd = $schema->resultset('CD')->update_or_create(
2193     {
2194       artist => 'Massive Attack',
2195       title  => 'Mezzanine',
2196       year   => 1998,
2197     },
2198     { key => 'cd_artist_title' }
2199   );
2200
2201   $cd->cd_to_producer->update_or_create({
2202     producer => $producer,
2203     name => 'harry',
2204   }, {
2205     key => 'primary,
2206   });
2207
2208
2209 If no C<key> is specified, it searches on all unique constraints defined on the
2210 source, including the primary key.
2211
2212 If the C<key> is specified as C<primary>, it searches only on the primary key.
2213
2214 See also L</find> and L</find_or_create>. For information on how to declare
2215 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2216
2217 B<Note>: C<update_or_create> is probably not what you want when
2218 looking for a row in a table that uses primary keys supplied by the
2219 database, unless you actually have a key value. Passing in a primary
2220 key column with a value of I<undef> will cause L</find> to attempt to
2221 search for a row with a value of I<NULL>.
2222
2223 =cut
2224
2225 sub update_or_create {
2226   my $self = shift;
2227   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2228   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2229
2230   my $row = $self->find($cond, $attrs);
2231   if (defined $row) {
2232     $row->update($cond);
2233     return $row;
2234   }
2235
2236   return $self->create($cond);
2237 }
2238
2239 =head2 update_or_new
2240
2241 =over 4
2242
2243 =item Arguments: \%col_values, { key => $unique_constraint }?
2244
2245 =item Return Value: $rowobject
2246
2247 =back
2248
2249   $resultset->update_or_new({ col => $val, ... });
2250
2251 First, searches for an existing row matching one of the unique constraints
2252 (including the primary key) on the source of this resultset. If a row is
2253 found, updates it with the other given column values. Otherwise, instantiate
2254 a new result object and return it. The object will not be saved into your storage
2255 until you call L<DBIx::Class::Row/insert> on it.
2256
2257 Takes an optional C<key> attribute to search on a specific unique constraint.
2258 For example:
2259
2260   # In your application
2261   my $cd = $schema->resultset('CD')->update_or_new(
2262     {
2263       artist => 'Massive Attack',
2264       title  => 'Mezzanine',
2265       year   => 1998,
2266     },
2267     { key => 'cd_artist_title' }
2268   );
2269
2270   if ($cd->in_storage) {
2271       # the cd was updated
2272   }
2273   else {
2274       # the cd is not yet in the database, let's insert it
2275       $cd->insert;
2276   }
2277
2278 See also L</find>, L</find_or_create> and L<find_or_new>.
2279
2280 =cut
2281
2282 sub update_or_new {
2283     my $self  = shift;
2284     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2285     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2286
2287     my $row = $self->find( $cond, $attrs );
2288     if ( defined $row ) {
2289         $row->update($cond);
2290         return $row;
2291     }
2292
2293     return $self->new_result($cond);
2294 }
2295
2296 =head2 get_cache
2297
2298 =over 4
2299
2300 =item Arguments: none
2301
2302 =item Return Value: \@cache_objects?
2303
2304 =back
2305
2306 Gets the contents of the cache for the resultset, if the cache is set.
2307
2308 The cache is populated either by using the L</prefetch> attribute to
2309 L</search> or by calling L</set_cache>.
2310
2311 =cut
2312
2313 sub get_cache {
2314   shift->{all_cache};
2315 }
2316
2317 =head2 set_cache
2318
2319 =over 4
2320
2321 =item Arguments: \@cache_objects
2322
2323 =item Return Value: \@cache_objects
2324
2325 =back
2326
2327 Sets the contents of the cache for the resultset. Expects an arrayref
2328 of objects of the same class as those produced by the resultset. Note that
2329 if the cache is set the resultset will return the cached objects rather
2330 than re-querying the database even if the cache attr is not set.
2331
2332 The contents of the cache can also be populated by using the
2333 L</prefetch> attribute to L</search>.
2334
2335 =cut
2336
2337 sub set_cache {
2338   my ( $self, $data ) = @_;
2339   $self->throw_exception("set_cache requires an arrayref")
2340       if defined($data) && (ref $data ne 'ARRAY');
2341   $self->{all_cache} = $data;
2342 }
2343
2344 =head2 clear_cache
2345
2346 =over 4
2347
2348 =item Arguments: none
2349
2350 =item Return Value: []
2351
2352 =back
2353
2354 Clears the cache for the resultset.
2355
2356 =cut
2357
2358 sub clear_cache {
2359   shift->set_cache(undef);
2360 }
2361
2362 =head2 related_resultset
2363
2364 =over 4
2365
2366 =item Arguments: $relationship_name
2367
2368 =item Return Value: $resultset
2369
2370 =back
2371
2372 Returns a related resultset for the supplied relationship name.
2373
2374   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2375
2376 =cut
2377
2378 sub related_resultset {
2379   my ($self, $rel) = @_;
2380
2381   $self->{related_resultsets} ||= {};
2382   return $self->{related_resultsets}{$rel} ||= do {
2383     my $rel_obj = $self->result_source->relationship_info($rel);
2384
2385     $self->throw_exception(
2386       "search_related: result source '" . $self->result_source->source_name .
2387         "' has no such relationship $rel")
2388       unless $rel_obj;
2389
2390     my ($from,$seen) = $self->_resolve_from($rel);
2391
2392     my $join_count = $seen->{$rel};
2393     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2394
2395     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2396     my %attrs = %{$self->{attrs}||{}};
2397     delete @attrs{qw(result_class alias)};
2398
2399     my $new_cache;
2400
2401     if (my $cache = $self->get_cache) {
2402       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2403         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2404                         @$cache ];
2405       }
2406     }
2407
2408     my $rel_source = $self->result_source->related_source($rel);
2409
2410     my $new = do {
2411
2412       # The reason we do this now instead of passing the alias to the
2413       # search_rs below is that if you wrap/overload resultset on the
2414       # source you need to know what alias it's -going- to have for things
2415       # to work sanely (e.g. RestrictWithObject wants to be able to add
2416       # extra query restrictions, and these may need to be $alias.)
2417
2418       my $attrs = $rel_source->resultset_attributes;
2419       local $attrs->{alias} = $alias;
2420
2421       $rel_source->resultset
2422                  ->search_rs(
2423                      undef, {
2424                        %attrs,
2425                        join => undef,
2426                        prefetch => undef,
2427                        select => undef,
2428                        as => undef,
2429                        where => $self->{cond},
2430                        seen_join => $seen,
2431                        from => $from,
2432                    });
2433     };
2434     $new->set_cache($new_cache) if $new_cache;
2435     $new;
2436   };
2437 }
2438
2439 =head2 current_source_alias
2440
2441 =over 4
2442
2443 =item Arguments: none
2444
2445 =item Return Value: $source_alias
2446
2447 =back
2448
2449 Returns the current table alias for the result source this resultset is built
2450 on, that will be used in the SQL query. Usually it is C<me>.
2451
2452 Currently the source alias that refers to the result set returned by a
2453 L</search>/L</find> family method depends on how you got to the resultset: it's
2454 C<me> by default, but eg. L</search_related> aliases it to the related result
2455 source name (and keeps C<me> referring to the original result set). The long
2456 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2457 (and make this method unnecessary).
2458
2459 Thus it's currently necessary to use this method in predefined queries (see
2460 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2461 source alias of the current result set:
2462
2463   # in a result set class
2464   sub modified_by {
2465     my ($self, $user) = @_;
2466
2467     my $me = $self->current_source_alias;
2468
2469     return $self->search(
2470       "$me.modified" => $user->id,
2471     );
2472   }
2473
2474 =cut
2475
2476 sub current_source_alias {
2477   my ($self) = @_;
2478
2479   return ($self->{attrs} || {})->{alias} || 'me';
2480 }
2481
2482 # This code is called by search_related, and makes sure there
2483 # is clear separation between the joins before, during, and
2484 # after the relationship. This information is needed later
2485 # in order to properly resolve prefetch aliases (any alias
2486 # with a relation_chain_depth less than the depth of the
2487 # current prefetch is not considered)
2488 sub _resolve_from {
2489   my ($self, $extra_join) = @_;
2490   my $source = $self->result_source;
2491   my $attrs = $self->{attrs};
2492
2493   my $from = $attrs->{from}
2494     || [ { $attrs->{alias} => $source->from } ];
2495
2496   my $seen = { %{$attrs->{seen_join}||{}} };
2497
2498   # we need to take the prefetch the attrs into account before we
2499   # ->_resolve_join as otherwise they get lost - captainL
2500   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2501
2502   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2503
2504   ++$seen->{-relation_chain_depth};
2505
2506   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2507
2508   ++$seen->{-relation_chain_depth};
2509
2510   return ($from,$seen);
2511 }
2512
2513 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2514 sub _resolved_attrs_copy {
2515   my $self = shift;
2516   return { %{$self->_resolved_attrs (@_)} };
2517 }
2518
2519 sub _resolved_attrs {
2520   my $self = shift;
2521   return $self->{_attrs} if $self->{_attrs};
2522
2523   my $attrs  = { %{ $self->{attrs} || {} } };
2524   my $source = $self->result_source;
2525   my $alias  = $attrs->{alias};
2526
2527   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2528   my @colbits;
2529
2530   # build columns (as long as select isn't set) into a set of as/select hashes
2531   unless ( $attrs->{select} ) {
2532       @colbits = map {
2533           ( ref($_) eq 'HASH' )
2534               ? $_
2535               : {
2536                   (
2537                     /^\Q${alias}.\E(.+)$/
2538                       ? "$1"
2539                       : "$_"
2540                   )
2541                 =>
2542                   (
2543                     /\./
2544                       ? "$_"
2545                       : "${alias}.$_"
2546                   )
2547             }
2548       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2549   }
2550   # add the additional columns on
2551   foreach ( 'include_columns', '+columns' ) {
2552       push @colbits, map {
2553           ( ref($_) eq 'HASH' )
2554             ? $_
2555             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2556       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2557   }
2558
2559   # start with initial select items
2560   if ( $attrs->{select} ) {
2561     $attrs->{select} =
2562         ( ref $attrs->{select} eq 'ARRAY' )
2563       ? [ @{ $attrs->{select} } ]
2564       : [ $attrs->{select} ];
2565     $attrs->{as} = (
2566       $attrs->{as}
2567       ? (
2568         ref $attrs->{as} eq 'ARRAY'
2569         ? [ @{ $attrs->{as} } ]
2570         : [ $attrs->{as} ]
2571         )
2572       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2573     );
2574   }
2575   else {
2576
2577     # otherwise we intialise select & as to empty
2578     $attrs->{select} = [];
2579     $attrs->{as}     = [];
2580   }
2581
2582   # now add colbits to select/as
2583   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2584   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2585
2586   my $adds;
2587   if ( $adds = delete $attrs->{'+select'} ) {
2588     $adds = [$adds] unless ref $adds eq 'ARRAY';
2589     push(
2590       @{ $attrs->{select} },
2591       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2592     );
2593   }
2594   if ( $adds = delete $attrs->{'+as'} ) {
2595     $adds = [$adds] unless ref $adds eq 'ARRAY';
2596     push( @{ $attrs->{as} }, @$adds );
2597   }
2598
2599   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2600
2601   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2602     my $join = delete $attrs->{join} || {};
2603
2604     if ( defined $attrs->{prefetch} ) {
2605       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2606
2607     }
2608
2609     $attrs->{from} =    # have to copy here to avoid corrupting the original
2610       [
2611       @{ $attrs->{from} },
2612       $source->_resolve_join(
2613         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2614       )
2615       ];
2616
2617   }
2618
2619   if ( $attrs->{order_by} ) {
2620     $attrs->{order_by} = (
2621       ref( $attrs->{order_by} ) eq 'ARRAY'
2622       ? [ @{ $attrs->{order_by} } ]
2623       : [ $attrs->{order_by} ]
2624     );
2625   }
2626   else {
2627     $attrs->{order_by} = [];
2628   }
2629
2630   my $collapse = $attrs->{collapse} || {};
2631   if ( my $prefetch = delete $attrs->{prefetch} ) {
2632     $prefetch = $self->_merge_attr( {}, $prefetch );
2633     my @pre_order;
2634     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2635
2636       # bring joins back to level of current class
2637       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2638       my @prefetch =
2639         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2640       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2641       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2642     }
2643     push( @{ $attrs->{order_by} }, @pre_order );
2644   }
2645
2646   if (delete $attrs->{distinct}) {
2647     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2648   }
2649
2650   $attrs->{collapse} = $collapse;
2651
2652   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2653     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2654   }
2655
2656   return $self->{_attrs} = $attrs;
2657 }
2658
2659 sub _joinpath_aliases {
2660   my ($self, $fromspec, $seen) = @_;
2661
2662   my $paths = {};
2663   return $paths unless ref $fromspec eq 'ARRAY';
2664
2665   for my $j (@$fromspec) {
2666
2667     next if ref $j ne 'ARRAY';
2668     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2669
2670     my $p = $paths;
2671     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2672     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2673   }
2674
2675   return $paths;
2676 }
2677
2678 sub _rollout_attr {
2679   my ($self, $attr) = @_;
2680
2681   if (ref $attr eq 'HASH') {
2682     return $self->_rollout_hash($attr);
2683   } elsif (ref $attr eq 'ARRAY') {
2684     return $self->_rollout_array($attr);
2685   } else {
2686     return [$attr];
2687   }
2688 }
2689
2690 sub _rollout_array {
2691   my ($self, $attr) = @_;
2692
2693   my @rolled_array;
2694   foreach my $element (@{$attr}) {
2695     if (ref $element eq 'HASH') {
2696       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2697     } elsif (ref $element eq 'ARRAY') {
2698       #  XXX - should probably recurse here
2699       push( @rolled_array, @{$self->_rollout_array($element)} );
2700     } else {
2701       push( @rolled_array, $element );
2702     }
2703   }
2704   return \@rolled_array;
2705 }
2706
2707 sub _rollout_hash {
2708   my ($self, $attr) = @_;
2709
2710   my @rolled_array;
2711   foreach my $key (keys %{$attr}) {
2712     push( @rolled_array, { $key => $attr->{$key} } );
2713   }
2714   return \@rolled_array;
2715 }
2716
2717 sub _calculate_score {
2718   my ($self, $a, $b) = @_;
2719
2720   if (ref $b eq 'HASH') {
2721     my ($b_key) = keys %{$b};
2722     if (ref $a eq 'HASH') {
2723       my ($a_key) = keys %{$a};
2724       if ($a_key eq $b_key) {
2725         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2726       } else {
2727         return 0;
2728       }
2729     } else {
2730       return ($a eq $b_key) ? 1 : 0;
2731     }
2732   } else {
2733     if (ref $a eq 'HASH') {
2734       my ($a_key) = keys %{$a};
2735       return ($b eq $a_key) ? 1 : 0;
2736     } else {
2737       return ($b eq $a) ? 1 : 0;
2738     }
2739   }
2740 }
2741
2742 sub _merge_attr {
2743   my ($self, $orig, $import) = @_;
2744
2745   return $import unless defined($orig);
2746   return $orig unless defined($import);
2747
2748   $orig = $self->_rollout_attr($orig);
2749   $import = $self->_rollout_attr($import);
2750
2751   my $seen_keys;
2752   foreach my $import_element ( @{$import} ) {
2753     # find best candidate from $orig to merge $b_element into
2754     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2755     foreach my $orig_element ( @{$orig} ) {
2756       my $score = $self->_calculate_score( $orig_element, $import_element );
2757       if ($score > $best_candidate->{score}) {
2758         $best_candidate->{position} = $position;
2759         $best_candidate->{score} = $score;
2760       }
2761       $position++;
2762     }
2763     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2764
2765     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2766       push( @{$orig}, $import_element );
2767     } else {
2768       my $orig_best = $orig->[$best_candidate->{position}];
2769       # merge orig_best and b_element together and replace original with merged
2770       if (ref $orig_best ne 'HASH') {
2771         $orig->[$best_candidate->{position}] = $import_element;
2772       } elsif (ref $import_element eq 'HASH') {
2773         my ($key) = keys %{$orig_best};
2774         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2775       }
2776     }
2777     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2778   }
2779
2780   return $orig;
2781 }
2782
2783 sub result_source {
2784     my $self = shift;
2785
2786     if (@_) {
2787         $self->_source_handle($_[0]->handle);
2788     } else {
2789         $self->_source_handle->resolve;
2790     }
2791 }
2792
2793 =head2 throw_exception
2794
2795 See L<DBIx::Class::Schema/throw_exception> for details.
2796
2797 =cut
2798
2799 sub throw_exception {
2800   my $self=shift;
2801   if (ref $self && $self->_source_handle->schema) {
2802     $self->_source_handle->schema->throw_exception(@_)
2803   } else {
2804     croak(@_);
2805   }
2806
2807 }
2808
2809 # XXX: FIXME: Attributes docs need clearing up
2810
2811 =head1 ATTRIBUTES
2812
2813 Attributes are used to refine a ResultSet in various ways when
2814 searching for data. They can be passed to any method which takes an
2815 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2816 L</count>.
2817
2818 These are in no particular order:
2819
2820 =head2 order_by
2821
2822 =over 4
2823
2824 =item Value: ( $order_by | \@order_by | \%order_by )
2825
2826 =back
2827
2828 Which column(s) to order the results by. If a single column name, or
2829 an arrayref of names is supplied, the argument is passed through
2830 directly to SQL. The hashref syntax allows for connection-agnostic
2831 specification of ordering direction:
2832
2833  For descending order:
2834
2835   order_by => { -desc => [qw/col1 col2 col3/] }
2836
2837  For explicit ascending order:
2838
2839   order_by => { -asc => 'col' }
2840
2841 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2842 supported, although you are strongly encouraged to use the hashref
2843 syntax as outlined above.
2844
2845 =head2 columns
2846
2847 =over 4
2848
2849 =item Value: \@columns
2850
2851 =back
2852
2853 Shortcut to request a particular set of columns to be retrieved. Each
2854 column spec may be a string (a table column name), or a hash (in which
2855 case the key is the C<as> value, and the value is used as the C<select>
2856 expression). Adds C<me.> onto the start of any column without a C<.> in
2857 it and sets C<select> from that, then auto-populates C<as> from
2858 C<select> as normal. (You may also use the C<cols> attribute, as in
2859 earlier versions of DBIC.)
2860
2861 =head2 +columns
2862
2863 =over 4
2864
2865 =item Value: \@columns
2866
2867 =back
2868
2869 Indicates additional columns to be selected from storage. Works the same
2870 as L</columns> but adds columns to the selection. (You may also use the
2871 C<include_columns> attribute, as in earlier versions of DBIC). For
2872 example:-
2873
2874   $schema->resultset('CD')->search(undef, {
2875     '+columns' => ['artist.name'],
2876     join => ['artist']
2877   });
2878
2879 would return all CDs and include a 'name' column to the information
2880 passed to object inflation. Note that the 'artist' is the name of the
2881 column (or relationship) accessor, and 'name' is the name of the column
2882 accessor in the related table.
2883
2884 =head2 include_columns
2885
2886 =over 4
2887
2888 =item Value: \@columns
2889
2890 =back
2891
2892 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2893
2894 =head2 select
2895
2896 =over 4
2897
2898 =item Value: \@select_columns
2899
2900 =back
2901
2902 Indicates which columns should be selected from the storage. You can use
2903 column names, or in the case of RDBMS back ends, function or stored procedure
2904 names:
2905
2906   $rs = $schema->resultset('Employee')->search(undef, {
2907     select => [
2908       'name',
2909       { count => 'employeeid' },
2910       { sum => 'salary' }
2911     ]
2912   });
2913
2914 When you use function/stored procedure names and do not supply an C<as>
2915 attribute, the column names returned are storage-dependent. E.g. MySQL would
2916 return a column named C<count(employeeid)> in the above example.
2917
2918 =head2 +select
2919
2920 =over 4
2921
2922 Indicates additional columns to be selected from storage.  Works the same as
2923 L</select> but adds columns to the selection.
2924
2925 =back
2926
2927 =head2 +as
2928
2929 =over 4
2930
2931 Indicates additional column names for those added via L</+select>. See L</as>.
2932
2933 =back
2934
2935 =head2 as
2936
2937 =over 4
2938
2939 =item Value: \@inflation_names
2940
2941 =back
2942
2943 Indicates column names for object inflation. That is, C<as>
2944 indicates the name that the column can be accessed as via the
2945 C<get_column> method (or via the object accessor, B<if one already
2946 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2947
2948 The C<as> attribute is used in conjunction with C<select>,
2949 usually when C<select> contains one or more function or stored
2950 procedure names:
2951
2952   $rs = $schema->resultset('Employee')->search(undef, {
2953     select => [
2954       'name',
2955       { count => 'employeeid' }
2956     ],
2957     as => ['name', 'employee_count'],
2958   });
2959
2960   my $employee = $rs->first(); # get the first Employee
2961
2962 If the object against which the search is performed already has an accessor
2963 matching a column name specified in C<as>, the value can be retrieved using
2964 the accessor as normal:
2965
2966   my $name = $employee->name();
2967
2968 If on the other hand an accessor does not exist in the object, you need to
2969 use C<get_column> instead:
2970
2971   my $employee_count = $employee->get_column('employee_count');
2972
2973 You can create your own accessors if required - see
2974 L<DBIx::Class::Manual::Cookbook> for details.
2975
2976 Please note: This will NOT insert an C<AS employee_count> into the SQL
2977 statement produced, it is used for internal access only. Thus
2978 attempting to use the accessor in an C<order_by> clause or similar
2979 will fail miserably.
2980
2981 To get around this limitation, you can supply literal SQL to your
2982 C<select> attibute that contains the C<AS alias> text, eg:
2983
2984   select => [\'myfield AS alias']
2985
2986 =head2 join
2987
2988 =over 4
2989
2990 =item Value: ($rel_name | \@rel_names | \%rel_names)
2991
2992 =back
2993
2994 Contains a list of relationships that should be joined for this query.  For
2995 example:
2996
2997   # Get CDs by Nine Inch Nails
2998   my $rs = $schema->resultset('CD')->search(
2999     { 'artist.name' => 'Nine Inch Nails' },
3000     { join => 'artist' }
3001   );
3002
3003 Can also contain a hash reference to refer to the other relation's relations.
3004 For example:
3005
3006   package MyApp::Schema::Track;
3007   use base qw/DBIx::Class/;
3008   __PACKAGE__->table('track');
3009   __PACKAGE__->add_columns(qw/trackid cd position title/);
3010   __PACKAGE__->set_primary_key('trackid');
3011   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3012   1;
3013
3014   # In your application
3015   my $rs = $schema->resultset('Artist')->search(
3016     { 'track.title' => 'Teardrop' },
3017     {
3018       join     => { cd => 'track' },
3019       order_by => 'artist.name',
3020     }
3021   );
3022
3023 You need to use the relationship (not the table) name in  conditions,
3024 because they are aliased as such. The current table is aliased as "me", so
3025 you need to use me.column_name in order to avoid ambiguity. For example:
3026
3027   # Get CDs from 1984 with a 'Foo' track
3028   my $rs = $schema->resultset('CD')->search(
3029     {
3030       'me.year' => 1984,
3031       'tracks.name' => 'Foo'
3032     },
3033     { join => 'tracks' }
3034   );
3035
3036 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3037 similarly for a third time). For e.g.
3038
3039   my $rs = $schema->resultset('Artist')->search({
3040     'cds.title'   => 'Down to Earth',
3041     'cds_2.title' => 'Popular',
3042   }, {
3043     join => [ qw/cds cds/ ],
3044   });
3045
3046 will return a set of all artists that have both a cd with title 'Down
3047 to Earth' and a cd with title 'Popular'.
3048
3049 If you want to fetch related objects from other tables as well, see C<prefetch>
3050 below.
3051
3052 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3053
3054 =head2 prefetch
3055
3056 =over 4
3057
3058 =item Value: ($rel_name | \@rel_names | \%rel_names)
3059
3060 =back
3061
3062 Contains one or more relationships that should be fetched along with
3063 the main query (when they are accessed afterwards the data will
3064 already be available, without extra queries to the database).  This is
3065 useful for when you know you will need the related objects, because it
3066 saves at least one query:
3067
3068   my $rs = $schema->resultset('Tag')->search(
3069     undef,
3070     {
3071       prefetch => {
3072         cd => 'artist'
3073       }
3074     }
3075   );
3076
3077 The initial search results in SQL like the following:
3078
3079   SELECT tag.*, cd.*, artist.* FROM tag
3080   JOIN cd ON tag.cd = cd.cdid
3081   JOIN artist ON cd.artist = artist.artistid
3082
3083 L<DBIx::Class> has no need to go back to the database when we access the
3084 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3085 case.
3086
3087 Simple prefetches will be joined automatically, so there is no need
3088 for a C<join> attribute in the above search.
3089
3090 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3091 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3092 with an accessor type of 'single' or 'filter'). A more complex example that
3093 prefetches an artists cds, the tracks on those cds, and the tags associted
3094 with that artist is given below (assuming many-to-many from artists to tags):
3095
3096  my $rs = $schema->resultset('Artist')->search(
3097    undef,
3098    {
3099      prefetch => [
3100        { cds => 'tracks' },
3101        { artist_tags => 'tags' }
3102      ]
3103    }
3104  );
3105
3106
3107 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3108 attributes will be ignored.
3109
3110 =head2 page
3111
3112 =over 4
3113
3114 =item Value: $page
3115
3116 =back
3117
3118 Makes the resultset paged and specifies the page to retrieve. Effectively
3119 identical to creating a non-pages resultset and then calling ->page($page)
3120 on it.
3121
3122 If L<rows> attribute is not specified it defualts to 10 rows per page.
3123
3124 When you have a paged resultset, L</count> will only return the number
3125 of rows in the page. To get the total, use the L</pager> and call
3126 C<total_entries> on it.
3127
3128 =head2 rows
3129
3130 =over 4
3131
3132 =item Value: $rows
3133
3134 =back
3135
3136 Specifes the maximum number of rows for direct retrieval or the number of
3137 rows per page if the page attribute or method is used.
3138
3139 =head2 offset
3140
3141 =over 4
3142
3143 =item Value: $offset
3144
3145 =back
3146
3147 Specifies the (zero-based) row number for the  first row to be returned, or the
3148 of the first row of the first page if paging is used.
3149
3150 =head2 group_by
3151
3152 =over 4
3153
3154 =item Value: \@columns
3155
3156 =back
3157
3158 A arrayref of columns to group by. Can include columns of joined tables.
3159
3160   group_by => [qw/ column1 column2 ... /]
3161
3162 =head2 having
3163
3164 =over 4
3165
3166 =item Value: $condition
3167
3168 =back
3169
3170 HAVING is a select statement attribute that is applied between GROUP BY and
3171 ORDER BY. It is applied to the after the grouping calculations have been
3172 done.
3173
3174   having => { 'count(employee)' => { '>=', 100 } }
3175
3176 =head2 distinct
3177
3178 =over 4
3179
3180 =item Value: (0 | 1)
3181
3182 =back
3183
3184 Set to 1 to group by all columns.
3185
3186 =head2 where
3187
3188 =over 4
3189
3190 Adds to the WHERE clause.
3191
3192   # only return rows WHERE deleted IS NULL for all searches
3193   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3194
3195 Can be overridden by passing C<{ where => undef }> as an attribute
3196 to a resulset.
3197
3198 =back
3199
3200 =head2 cache
3201
3202 Set to 1 to cache search results. This prevents extra SQL queries if you
3203 revisit rows in your ResultSet:
3204
3205   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3206
3207   while( my $artist = $resultset->next ) {
3208     ... do stuff ...
3209   }
3210
3211   $rs->first; # without cache, this would issue a query
3212
3213 By default, searches are not cached.
3214
3215 For more examples of using these attributes, see
3216 L<DBIx::Class::Manual::Cookbook>.
3217
3218 =head2 from
3219
3220 =over 4
3221
3222 =item Value: \@from_clause
3223
3224 =back
3225
3226 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3227 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3228 clauses.
3229
3230 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3231
3232 C<join> will usually do what you need and it is strongly recommended that you
3233 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3234 And we really do mean "cannot", not just tried and failed. Attempting to use
3235 this because you're having problems with C<join> is like trying to use x86
3236 ASM because you've got a syntax error in your C. Trust us on this.
3237
3238 Now, if you're still really, really sure you need to use this (and if you're
3239 not 100% sure, ask the mailing list first), here's an explanation of how this
3240 works.
3241
3242 The syntax is as follows -
3243
3244   [
3245     { <alias1> => <table1> },
3246     [
3247       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3248       [], # nested JOIN (optional)
3249       { <table1.column1> => <table2.column2>, ... (more conditions) },
3250     ],
3251     # More of the above [ ] may follow for additional joins
3252   ]
3253
3254   <table1> <alias1>
3255   JOIN
3256     <table2> <alias2>
3257     [JOIN ...]
3258   ON <table1.column1> = <table2.column2>
3259   <more joins may follow>
3260
3261 An easy way to follow the examples below is to remember the following:
3262
3263     Anything inside "[]" is a JOIN
3264     Anything inside "{}" is a condition for the enclosing JOIN
3265
3266 The following examples utilize a "person" table in a family tree application.
3267 In order to express parent->child relationships, this table is self-joined:
3268
3269     # Person->belongs_to('father' => 'Person');
3270     # Person->belongs_to('mother' => 'Person');
3271
3272 C<from> can be used to nest joins. Here we return all children with a father,
3273 then search against all mothers of those children:
3274
3275   $rs = $schema->resultset('Person')->search(
3276       undef,
3277       {
3278           alias => 'mother', # alias columns in accordance with "from"
3279           from => [
3280               { mother => 'person' },
3281               [
3282                   [
3283                       { child => 'person' },
3284                       [
3285                           { father => 'person' },
3286                           { 'father.person_id' => 'child.father_id' }
3287                       ]
3288                   ],
3289                   { 'mother.person_id' => 'child.mother_id' }
3290               ],
3291           ]
3292       },
3293   );
3294
3295   # Equivalent SQL:
3296   # SELECT mother.* FROM person mother
3297   # JOIN (
3298   #   person child
3299   #   JOIN person father
3300   #   ON ( father.person_id = child.father_id )
3301   # )
3302   # ON ( mother.person_id = child.mother_id )
3303
3304 The type of any join can be controlled manually. To search against only people
3305 with a father in the person table, we could explicitly use C<INNER JOIN>:
3306
3307     $rs = $schema->resultset('Person')->search(
3308         undef,
3309         {
3310             alias => 'child', # alias columns in accordance with "from"
3311             from => [
3312                 { child => 'person' },
3313                 [
3314                     { father => 'person', -join_type => 'inner' },
3315                     { 'father.id' => 'child.father_id' }
3316                 ],
3317             ]
3318         },
3319     );
3320
3321     # Equivalent SQL:
3322     # SELECT child.* FROM person child
3323     # INNER JOIN person father ON child.father_id = father.id
3324
3325 If you need to express really complex joins or you need a subselect, you
3326 can supply literal SQL to C<from> via a scalar reference. In this case
3327 the contents of the scalar will replace the table name asscoiated with the
3328 resultsource.
3329
3330 WARNING: This technique might very well not work as expected on chained
3331 searches - you have been warned.
3332
3333     # Assuming the Event resultsource is defined as:
3334
3335         MySchema::Event->add_columns (
3336             sequence => {
3337                 data_type => 'INT',
3338                 is_auto_increment => 1,
3339             },
3340             location => {
3341                 data_type => 'INT',
3342             },
3343             type => {
3344                 data_type => 'INT',
3345             },
3346         );
3347         MySchema::Event->set_primary_key ('sequence');
3348
3349     # This will get back the latest event for every location. The column
3350     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3351     # combo to limit the resultset
3352
3353     $rs = $schema->resultset('Event');
3354     $table = $rs->result_source->name;
3355     $latest = $rs->search (
3356         undef,
3357         { from => \ "
3358             (SELECT e1.* FROM $table e1
3359                 JOIN $table e2
3360                     ON e1.location = e2.location
3361                     AND e1.sequence < e2.sequence
3362                 WHERE e2.sequence is NULL
3363             ) me",
3364         },
3365     );
3366
3367     # Equivalent SQL (with the DBIC chunks added):
3368
3369     SELECT me.sequence, me.location, me.type FROM
3370        (SELECT e1.* FROM events e1
3371            JOIN events e2
3372                ON e1.location = e2.location
3373                AND e1.sequence < e2.sequence
3374            WHERE e2.sequence is NULL
3375        ) me;
3376
3377 =head2 for
3378
3379 =over 4
3380
3381 =item Value: ( 'update' | 'shared' )
3382
3383 =back
3384
3385 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3386 ... FOR SHARED.
3387
3388 =cut
3389
3390 1;