lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 961   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 962   @new = $self->{_attrs}{record_filter}->(@new)
 963     if exists $self->{_attrs}{record_filter};
 964   return @new;
 965 }
 966
 967 sub _collapse_result {
 968   my ($self, $as_proto, $row) = @_;
 969
 970   my @copy = @$row;
 971
 972   # 'foo'         => [ undef, 'foo' ]
 973   # 'foo.bar'     => [ 'foo', 'bar' ]
 974   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 975
 976   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 977
 978   my %collapse = %{$self->{_attrs}{collapse}||{}};
 979
 980   my @pri_index;
 981
 982   # if we're doing collapsing (has_many prefetch) we need to grab records
 983   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 984   # we know we don't have to bother.
 985
 986   # the reason for not using the collapse stuff directly is because if you
 987   # had for e.g. two artists in a row with no cds, the collapse info for
 988   # both would be NULL (undef) so you'd lose the second artist
 989
 990   # store just the index so we can check the array positions from the row
 991   # without having to contruct the full hash
 992
 993   if (keys %collapse) {
 994     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 995     foreach my $i (0 .. $#construct_as) {
 996       next if defined($construct_as[$i][0]); # only self table
 997       if (delete $pri{$construct_as[$i][1]}) {
 998         push(@pri_index, $i);
 999       }
1000       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1001     }
1002   }
1003
1004   # no need to do an if, it'll be empty if @pri_index is empty anyway
1005
1006   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1007
1008   my @const_rows;
1009
1010   do { # no need to check anything at the front, we always want the first row
1011
1012     my %const;
1013
1014     foreach my $this_as (@construct_as) {
1015       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1016     }
1017
1018     push(@const_rows, \%const);
1019
1020   } until ( # no pri_index => no collapse => drop straight out
1021       !@pri_index
1022     or
1023       do { # get another row, stash it, drop out if different PK
1024
1025         @copy = $self->cursor->next;
1026         $self->{stashed_row} = \@copy;
1027
1028         # last thing in do block, counts as true if anything doesn't match
1029
1030         # check xor defined first for NULL vs. NOT NULL then if one is
1031         # defined the other must be so check string equality
1032
1033         grep {
1034           (defined $pri_vals{$_} ^ defined $copy[$_])
1035           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1036         } @pri_index;
1037       }
1038   );
1039
1040   my $alias = $self->{attrs}{alias};
1041   my $info = [];
1042
1043   my %collapse_pos;
1044
1045   my @const_keys;
1046
1047   foreach my $const (@const_rows) {
1048     scalar @const_keys or do {
1049       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1050     };
1051     foreach my $key (@const_keys) {
1052       if (length $key) {
1053         my $target = $info;
1054         my @parts = split(/\./, $key);
1055         my $cur = '';
1056         my $data = $const->{$key};
1057         foreach my $p (@parts) {
1058           $target = $target->[1]->{$p} ||= [];
1059           $cur .= ".${p}";
1060           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1061             # collapsing at this point and on final part
1062             my $pos = $collapse_pos{$cur};
1063             CK: foreach my $ck (@ckey) {
1064               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1065                 $collapse_pos{$cur} = $data;
1066                 delete @collapse_pos{ # clear all positioning for sub-entries
1067                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1068                 };
1069                 push(@$target, []);
1070                 last CK;
1071               }
1072             }
1073           }
1074           if (exists $collapse{$cur}) {
1075             $target = $target->[-1];
1076           }
1077         }
1078         $target->[0] = $data;
1079       } else {
1080         $info->[0] = $const->{$key};
1081       }
1082     }
1083   }
1084
1085   return $info;
1086 }
1087
1088 =head2 result_source
1089
1090 =over 4
1091
1092 =item Arguments: $result_source?
1093
1094 =item Return Value: $result_source
1095
1096 =back
1097
1098 An accessor for the primary ResultSource object from which this ResultSet
1099 is derived.
1100
1101 =head2 result_class
1102
1103 =over 4
1104
1105 =item Arguments: $result_class?
1106
1107 =item Return Value: $result_class
1108
1109 =back
1110
1111 An accessor for the class to use when creating row objects. Defaults to
1112 C<< result_source->result_class >> - which in most cases is the name of the
1113 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1114
1115 Note that changing the result_class will also remove any components
1116 that were originally loaded in the source class via
1117 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1118 in the original source class will not run.
1119
1120 =cut
1121
1122 sub result_class {
1123   my ($self, $result_class) = @_;
1124   if ($result_class) {
1125     $self->ensure_class_loaded($result_class);
1126     $self->_result_class($result_class);
1127   }
1128   $self->_result_class;
1129 }
1130
1131 =head2 count
1132
1133 =over 4
1134
1135 =item Arguments: $cond, \%attrs??
1136
1137 =item Return Value: $count
1138
1139 =back
1140
1141 Performs an SQL C<COUNT> with the same query as the resultset was built
1142 with to find the number of elements. Passing arguments is equivalent to
1143 C<< $rs->search ($cond, \%attrs)->count >>
1144
1145 =cut
1146
1147 sub count {
1148   my $self = shift;
1149   return $self->search(@_)->count if @_ and defined $_[0];
1150   return scalar @{ $self->get_cache } if $self->get_cache;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153
1154   # this is a little optimization - it is faster to do the limit
1155   # adjustments in software, instead of a subquery
1156   my $rows = delete $attrs->{rows};
1157   my $offset = delete $attrs->{offset};
1158
1159   my $crs;
1160   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1161     $crs = $self->_count_subq_rs ($attrs);
1162   }
1163   else {
1164     $crs = $self->_count_rs ($attrs);
1165   }
1166   my $count = $crs->next;
1167
1168   $count -= $offset if $offset;
1169   $count = $rows if $rows and $rows < $count;
1170   $count = 0 if ($count < 0);
1171
1172   return $count;
1173 }
1174
1175 =head2 count_rs
1176
1177 =over 4
1178
1179 =item Arguments: $cond, \%attrs??
1180
1181 =item Return Value: $count_rs
1182
1183 =back
1184
1185 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1186 This can be very handy for subqueries:
1187
1188   ->search( { amount => $some_rs->count_rs->as_query } )
1189
1190 As with regular resultsets the SQL query will be executed only after
1191 the resultset is accessed via L</next> or L</all>. That would return
1192 the same single value obtainable via L</count>.
1193
1194 =cut
1195
1196 sub count_rs {
1197   my $self = shift;
1198   return $self->search(@_)->count_rs if @_;
1199
1200   # this may look like a lack of abstraction (count() does about the same)
1201   # but in fact an _rs *must* use a subquery for the limits, as the
1202   # software based limiting can not be ported if this $rs is to be used
1203   # in a subquery itself (i.e. ->as_query)
1204   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1205     return $self->_count_subq_rs;
1206   }
1207   else {
1208     return $self->_count_rs;
1209   }
1210 }
1211
1212 #
1213 # returns a ResultSetColumn object tied to the count query
1214 #
1215 sub _count_rs {
1216   my ($self, $attrs) = @_;
1217
1218   my $rsrc = $self->result_source;
1219   $attrs ||= $self->_resolved_attrs;
1220
1221   my $tmp_attrs = { %$attrs };
1222
1223   # take off any limits, record_filter is cdbi, and no point of ordering a count
1224   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1225
1226   # overwrite the selector (supplied by the storage)
1227   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1228   $tmp_attrs->{as} = 'count';
1229
1230   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1231
1232   return $tmp_rs;
1233 }
1234
1235 #
1236 # same as above but uses a subquery
1237 #
1238 sub _count_subq_rs {
1239   my ($self, $attrs) = @_;
1240
1241   my $rsrc = $self->result_source;
1242   $attrs ||= $self->_resolved_attrs_copy;
1243
1244   my $sub_attrs = { %$attrs };
1245
1246   # these can not go in the subquery, and there is no point of ordering it
1247   delete $sub_attrs->{$_} for qw/collapse select as order_by/;
1248
1249   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1250   # clobber old group_by regardless
1251   if ( keys %{$attrs->{collapse}} ) {
1252     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1253   }
1254
1255   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1256
1257   # this is so that ordering can be thrown away in things like Top limit
1258   $sub_attrs->{-for_count_only} = 1;
1259
1260   $attrs->{from} = [{
1261     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1262   }];
1263
1264   # the subquery replaces this
1265   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1266
1267   return $self->_count_rs ($attrs);
1268 }
1269
1270
1271 sub _bool {
1272   return 1;
1273 }
1274
1275 =head2 count_literal
1276
1277 =over 4
1278
1279 =item Arguments: $sql_fragment, @bind_values
1280
1281 =item Return Value: $count
1282
1283 =back
1284
1285 Counts the results in a literal query. Equivalent to calling L</search_literal>
1286 with the passed arguments, then L</count>.
1287
1288 =cut
1289
1290 sub count_literal { shift->search_literal(@_)->count; }
1291
1292 =head2 all
1293
1294 =over 4
1295
1296 =item Arguments: none
1297
1298 =item Return Value: @objects
1299
1300 =back
1301
1302 Returns all elements in the resultset. Called implicitly if the resultset
1303 is returned in list context.
1304
1305 =cut
1306
1307 sub all {
1308   my $self = shift;
1309   if(@_) {
1310       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1311   }
1312
1313   return @{ $self->get_cache } if $self->get_cache;
1314
1315   my @obj;
1316
1317   # TODO: don't call resolve here
1318   if (keys %{$self->_resolved_attrs->{collapse}}) {
1319 #  if ($self->{attrs}{prefetch}) {
1320       # Using $self->cursor->all is really just an optimisation.
1321       # If we're collapsing has_many prefetches it probably makes
1322       # very little difference, and this is cleaner than hacking
1323       # _construct_object to survive the approach
1324     my @row = $self->cursor->next;
1325     while (@row) {
1326       push(@obj, $self->_construct_object(@row));
1327       @row = (exists $self->{stashed_row}
1328                ? @{delete $self->{stashed_row}}
1329                : $self->cursor->next);
1330     }
1331   } else {
1332     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1333   }
1334
1335   $self->set_cache(\@obj) if $self->{attrs}{cache};
1336   return @obj;
1337 }
1338
1339 =head2 reset
1340
1341 =over 4
1342
1343 =item Arguments: none
1344
1345 =item Return Value: $self
1346
1347 =back
1348
1349 Resets the resultset's cursor, so you can iterate through the elements again.
1350
1351 =cut
1352
1353 sub reset {
1354   my ($self) = @_;
1355   delete $self->{_attrs} if exists $self->{_attrs};
1356   $self->{all_cache_position} = 0;
1357   $self->cursor->reset;
1358   return $self;
1359 }
1360
1361 =head2 first
1362
1363 =over 4
1364
1365 =item Arguments: none
1366
1367 =item Return Value: $object?
1368
1369 =back
1370
1371 Resets the resultset and returns an object for the first result (if the
1372 resultset returns anything).
1373
1374 =cut
1375
1376 sub first {
1377   return $_[0]->reset->next;
1378 }
1379
1380
1381 # _rs_update_delete
1382 #
1383 # Determines whether and what type of subquery is required for the $rs operation.
1384 # If grouping is necessary either supplies its own, or verifies the current one
1385 # After all is done delegates to the proper storage method.
1386
1387 sub _rs_update_delete {
1388   my ($self, $op, $values) = @_;
1389
1390   my $rsrc = $self->result_source;
1391
1392   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1393   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1394
1395   if ($needs_group_by_subq or $needs_subq) {
1396
1397     # make a new $rs selecting only the PKs (that's all we really need)
1398     my $attrs = $self->_resolved_attrs_copy;
1399
1400     delete $attrs->{$_} for qw/collapse select as/;
1401     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1402
1403     if ($needs_group_by_subq) {
1404       # make sure no group_by was supplied, or if there is one - make sure it matches
1405       # the columns compiled above perfectly. Anything else can not be sanely executed
1406       # on most databases so croak right then and there
1407
1408       if (my $g = $attrs->{group_by}) {
1409         my @current_group_by = map
1410           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1411           (ref $g eq 'ARRAY' ? @$g : $g );
1412
1413         if (
1414           join ("\x00", sort @current_group_by)
1415             ne
1416           join ("\x00", sort @{$attrs->{columns}} )
1417         ) {
1418           $self->throw_exception (
1419             "You have just attempted a $op operation on a resultset which does group_by"
1420             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1421             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1422             . ' kind of queries. Please retry the operation with a modified group_by or'
1423             . ' without using one at all.'
1424           );
1425         }
1426       }
1427       else {
1428         $attrs->{group_by} = $attrs->{columns};
1429       }
1430     }
1431
1432     my $subrs = (ref $self)->new($rsrc, $attrs);
1433
1434     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1435   }
1436   else {
1437     return $rsrc->storage->$op(
1438       $rsrc,
1439       $op eq 'update' ? $values : (),
1440       $self->_cond_for_update_delete,
1441     );
1442   }
1443 }
1444
1445
1446 # _cond_for_update_delete
1447 #
1448 # update/delete require the condition to be modified to handle
1449 # the differing SQL syntax available.  This transforms the $self->{cond}
1450 # appropriately, returning the new condition.
1451
1452 sub _cond_for_update_delete {
1453   my ($self, $full_cond) = @_;
1454   my $cond = {};
1455
1456   $full_cond ||= $self->{cond};
1457   # No-op. No condition, we're updating/deleting everything
1458   return $cond unless ref $full_cond;
1459
1460   if (ref $full_cond eq 'ARRAY') {
1461     $cond = [
1462       map {
1463         my %hash;
1464         foreach my $key (keys %{$_}) {
1465           $key =~ /([^.]+)$/;
1466           $hash{$1} = $_->{$key};
1467         }
1468         \%hash;
1469       } @{$full_cond}
1470     ];
1471   }
1472   elsif (ref $full_cond eq 'HASH') {
1473     if ((keys %{$full_cond})[0] eq '-and') {
1474       $cond->{-and} = [];
1475       my @cond = @{$full_cond->{-and}};
1476        for (my $i = 0; $i < @cond; $i++) {
1477         my $entry = $cond[$i];
1478         my $hash;
1479         if (ref $entry eq 'HASH') {
1480           $hash = $self->_cond_for_update_delete($entry);
1481         }
1482         else {
1483           $entry =~ /([^.]+)$/;
1484           $hash->{$1} = $cond[++$i];
1485         }
1486         push @{$cond->{-and}}, $hash;
1487       }
1488     }
1489     else {
1490       foreach my $key (keys %{$full_cond}) {
1491         $key =~ /([^.]+)$/;
1492         $cond->{$1} = $full_cond->{$key};
1493       }
1494     }
1495   }
1496   else {
1497     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1498   }
1499
1500   return $cond;
1501 }
1502
1503
1504 =head2 update
1505
1506 =over 4
1507
1508 =item Arguments: \%values
1509
1510 =item Return Value: $storage_rv
1511
1512 =back
1513
1514 Sets the specified columns in the resultset to the supplied values in a
1515 single query. Return value will be true if the update succeeded or false
1516 if no records were updated; exact type of success value is storage-dependent.
1517
1518 =cut
1519
1520 sub update {
1521   my ($self, $values) = @_;
1522   $self->throw_exception('Values for update must be a hash')
1523     unless ref $values eq 'HASH';
1524
1525   return $self->_rs_update_delete ('update', $values);
1526 }
1527
1528 =head2 update_all
1529
1530 =over 4
1531
1532 =item Arguments: \%values
1533
1534 =item Return Value: 1
1535
1536 =back
1537
1538 Fetches all objects and updates them one at a time. Note that C<update_all>
1539 will run DBIC cascade triggers, while L</update> will not.
1540
1541 =cut
1542
1543 sub update_all {
1544   my ($self, $values) = @_;
1545   $self->throw_exception('Values for update_all must be a hash')
1546     unless ref $values eq 'HASH';
1547   foreach my $obj ($self->all) {
1548     $obj->set_columns($values)->update;
1549   }
1550   return 1;
1551 }
1552
1553 =head2 delete
1554
1555 =over 4
1556
1557 =item Arguments: none
1558
1559 =item Return Value: $storage_rv
1560
1561 =back
1562
1563 Deletes the contents of the resultset from its result source. Note that this
1564 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1565 to run. See also L<DBIx::Class::Row/delete>.
1566
1567 Return value will be the amount of rows deleted; exact type of return value
1568 is storage-dependent.
1569
1570 =cut
1571
1572 sub delete {
1573   my $self = shift;
1574   $self->throw_exception('delete does not accept any arguments')
1575     if @_;
1576
1577   return $self->_rs_update_delete ('delete');
1578 }
1579
1580 =head2 delete_all
1581
1582 =over 4
1583
1584 =item Arguments: none
1585
1586 =item Return Value: 1
1587
1588 =back
1589
1590 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1591 will run DBIC cascade triggers, while L</delete> will not.
1592
1593 =cut
1594
1595 sub delete_all {
1596   my $self = shift;
1597   $self->throw_exception('delete_all does not accept any arguments')
1598     if @_;
1599
1600   $_->delete for $self->all;
1601   return 1;
1602 }
1603
1604 =head2 populate
1605
1606 =over 4
1607
1608 =item Arguments: \@data;
1609
1610 =back
1611
1612 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1613 For the arrayref of hashrefs style each hashref should be a structure suitable
1614 forsubmitting to a $resultset->create(...) method.
1615
1616 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1617 to insert the data, as this is a faster method.
1618
1619 Otherwise, each set of data is inserted into the database using
1620 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1621 accumulated into an array. The array itself, or an array reference
1622 is returned depending on scalar or list context.
1623
1624 Example:  Assuming an Artist Class that has many CDs Classes relating:
1625
1626   my $Artist_rs = $schema->resultset("Artist");
1627
1628   ## Void Context Example
1629   $Artist_rs->populate([
1630      { artistid => 4, name => 'Manufactured Crap', cds => [
1631         { title => 'My First CD', year => 2006 },
1632         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1633       ],
1634      },
1635      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1636         { title => 'My parents sold me to a record company' ,year => 2005 },
1637         { title => 'Why Am I So Ugly?', year => 2006 },
1638         { title => 'I Got Surgery and am now Popular', year => 2007 }
1639       ],
1640      },
1641   ]);
1642
1643   ## Array Context Example
1644   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1645     { name => "Artist One"},
1646     { name => "Artist Two"},
1647     { name => "Artist Three", cds=> [
1648     { title => "First CD", year => 2007},
1649     { title => "Second CD", year => 2008},
1650   ]}
1651   ]);
1652
1653   print $ArtistOne->name; ## response is 'Artist One'
1654   print $ArtistThree->cds->count ## reponse is '2'
1655
1656 For the arrayref of arrayrefs style,  the first element should be a list of the
1657 fieldsnames to which the remaining elements are rows being inserted.  For
1658 example:
1659
1660   $Arstist_rs->populate([
1661     [qw/artistid name/],
1662     [100, 'A Formally Unknown Singer'],
1663     [101, 'A singer that jumped the shark two albums ago'],
1664     [102, 'An actually cool singer.'],
1665   ]);
1666
1667 Please note an important effect on your data when choosing between void and
1668 wantarray context. Since void context goes straight to C<insert_bulk> in
1669 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1670 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1671 create primary keys for you, you will find that your PKs are empty.  In this
1672 case you will have to use the wantarray context in order to create those
1673 values.
1674
1675 =cut
1676
1677 sub populate {
1678   my $self = shift @_;
1679   my $data = ref $_[0][0] eq 'HASH'
1680     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1681     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1682
1683   if(defined wantarray) {
1684     my @created;
1685     foreach my $item (@$data) {
1686       push(@created, $self->create($item));
1687     }
1688     return wantarray ? @created : \@created;
1689   } else {
1690     my ($first, @rest) = @$data;
1691
1692     my @names = grep {!ref $first->{$_}} keys %$first;
1693     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1694     my @pks = $self->result_source->primary_columns;
1695
1696     ## do the belongs_to relationships
1697     foreach my $index (0..$#$data) {
1698
1699       # delegate to create() for any dataset without primary keys with specified relationships
1700       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1701         for my $r (@rels) {
1702           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1703             my @ret = $self->populate($data);
1704             return;
1705           }
1706         }
1707       }
1708
1709       foreach my $rel (@rels) {
1710         next unless ref $data->[$index]->{$rel} eq "HASH";
1711         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1712         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1713         my $related = $result->result_source->_resolve_condition(
1714           $result->result_source->relationship_info($reverse)->{cond},
1715           $self,
1716           $result,
1717         );
1718
1719         delete $data->[$index]->{$rel};
1720         $data->[$index] = {%{$data->[$index]}, %$related};
1721
1722         push @names, keys %$related if $index == 0;
1723       }
1724     }
1725
1726     ## do bulk insert on current row
1727     my @values = map { [ @$_{@names} ] } @$data;
1728
1729     $self->result_source->storage->insert_bulk(
1730       $self->result_source,
1731       \@names,
1732       \@values,
1733     );
1734
1735     ## do the has_many relationships
1736     foreach my $item (@$data) {
1737
1738       foreach my $rel (@rels) {
1739         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1740
1741         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1742      || $self->throw_exception('Cannot find the relating object.');
1743
1744         my $child = $parent->$rel;
1745
1746         my $related = $child->result_source->_resolve_condition(
1747           $parent->result_source->relationship_info($rel)->{cond},
1748           $child,
1749           $parent,
1750         );
1751
1752         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1753         my @populate = map { {%$_, %$related} } @rows_to_add;
1754
1755         $child->populate( \@populate );
1756       }
1757     }
1758   }
1759 }
1760
1761 =head2 _normalize_populate_args ($args)
1762
1763 Private method used by L</populate> to normalize its incoming arguments.  Factored
1764 out in case you want to subclass and accept new argument structures to the
1765 L</populate> method.
1766
1767 =cut
1768
1769 sub _normalize_populate_args {
1770   my ($self, $data) = @_;
1771   my @names = @{shift(@$data)};
1772   my @results_to_create;
1773   foreach my $datum (@$data) {
1774     my %result_to_create;
1775     foreach my $index (0..$#names) {
1776       $result_to_create{$names[$index]} = $$datum[$index];
1777     }
1778     push @results_to_create, \%result_to_create;
1779   }
1780   return \@results_to_create;
1781 }
1782
1783 =head2 pager
1784
1785 =over 4
1786
1787 =item Arguments: none
1788
1789 =item Return Value: $pager
1790
1791 =back
1792
1793 Return Value a L<Data::Page> object for the current resultset. Only makes
1794 sense for queries with a C<page> attribute.
1795
1796 To get the full count of entries for a paged resultset, call
1797 C<total_entries> on the L<Data::Page> object.
1798
1799 =cut
1800
1801 sub pager {
1802   my ($self) = @_;
1803
1804   return $self->{pager} if $self->{pager};
1805
1806   my $attrs = $self->{attrs};
1807   $self->throw_exception("Can't create pager for non-paged rs")
1808     unless $self->{attrs}{page};
1809   $attrs->{rows} ||= 10;
1810
1811   # throw away the paging flags and re-run the count (possibly
1812   # with a subselect) to get the real total count
1813   my $count_attrs = { %$attrs };
1814   delete $count_attrs->{$_} for qw/rows offset page pager/;
1815   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1816
1817   return $self->{pager} = Data::Page->new(
1818     $total_count,
1819     $attrs->{rows},
1820     $self->{attrs}{page}
1821   );
1822 }
1823
1824 =head2 page
1825
1826 =over 4
1827
1828 =item Arguments: $page_number
1829
1830 =item Return Value: $rs
1831
1832 =back
1833
1834 Returns a resultset for the $page_number page of the resultset on which page
1835 is called, where each page contains a number of rows equal to the 'rows'
1836 attribute set on the resultset (10 by default).
1837
1838 =cut
1839
1840 sub page {
1841   my ($self, $page) = @_;
1842   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1843 }
1844
1845 =head2 new_result
1846
1847 =over 4
1848
1849 =item Arguments: \%vals
1850
1851 =item Return Value: $rowobject
1852
1853 =back
1854
1855 Creates a new row object in the resultset's result class and returns
1856 it. The row is not inserted into the database at this point, call
1857 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1858 will tell you whether the row object has been inserted or not.
1859
1860 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1861
1862 =cut
1863
1864 sub new_result {
1865   my ($self, $values) = @_;
1866   $self->throw_exception( "new_result needs a hash" )
1867     unless (ref $values eq 'HASH');
1868
1869   my %new;
1870   my $alias = $self->{attrs}{alias};
1871
1872   if (
1873     defined $self->{cond}
1874     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1875   ) {
1876     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1877     $new{-from_resultset} = [ keys %new ] if keys %new;
1878   } else {
1879     $self->throw_exception(
1880       "Can't abstract implicit construct, condition not a hash"
1881     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1882
1883     my $collapsed_cond = (
1884       $self->{cond}
1885         ? $self->_collapse_cond($self->{cond})
1886         : {}
1887     );
1888
1889     # precendence must be given to passed values over values inherited from
1890     # the cond, so the order here is important.
1891     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1892     while( my($col,$value) = each %implied ){
1893       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1894         $new{$col} = $value->{'='};
1895         next;
1896       }
1897       $new{$col} = $value if $self->_is_deterministic_value($value);
1898     }
1899   }
1900
1901   %new = (
1902     %new,
1903     %{ $self->_remove_alias($values, $alias) },
1904     -source_handle => $self->_source_handle,
1905     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1906   );
1907
1908   return $self->result_class->new(\%new);
1909 }
1910
1911 # _is_deterministic_value
1912 #
1913 # Make an effor to strip non-deterministic values from the condition,
1914 # to make sure new_result chokes less
1915
1916 sub _is_deterministic_value {
1917   my $self = shift;
1918   my $value = shift;
1919   my $ref_type = ref $value;
1920   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1921   return 1 if Scalar::Util::blessed($value);
1922   return 0;
1923 }
1924
1925 # _has_resolved_attr
1926 #
1927 # determines if the resultset defines at least one
1928 # of the attributes supplied
1929 #
1930 # used to determine if a subquery is neccessary
1931
1932 sub _has_resolved_attr {
1933   my ($self, @attr_names) = @_;
1934
1935   my $attrs = $self->_resolved_attrs;
1936
1937   my $join_check_req;
1938
1939   for my $n (@attr_names) {
1940     ++$join_check_req if $n eq '-join';
1941
1942     my $attr =  $attrs->{$n};
1943
1944     next if not defined $attr;
1945
1946     if (ref $attr eq 'HASH') {
1947       return 1 if keys %$attr;
1948     }
1949     elsif (ref $attr eq 'ARRAY') {
1950       return 1 if @$attr;
1951     }
1952     else {
1953       return 1 if $attr;
1954     }
1955   }
1956
1957   # a resolved join is expressed as a multi-level from
1958   return 1 if (
1959     $join_check_req
1960       and
1961     ref $attrs->{from} eq 'ARRAY'
1962       and
1963     @{$attrs->{from}} > 1
1964   );
1965
1966   return 0;
1967 }
1968
1969 # _collapse_cond
1970 #
1971 # Recursively collapse the condition.
1972
1973 sub _collapse_cond {
1974   my ($self, $cond, $collapsed) = @_;
1975
1976   $collapsed ||= {};
1977
1978   if (ref $cond eq 'ARRAY') {
1979     foreach my $subcond (@$cond) {
1980       next unless ref $subcond;  # -or
1981       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1982     }
1983   }
1984   elsif (ref $cond eq 'HASH') {
1985     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1986       foreach my $subcond (@{$cond->{-and}}) {
1987         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1988       }
1989     }
1990     else {
1991       foreach my $col (keys %$cond) {
1992         my $value = $cond->{$col};
1993         $collapsed->{$col} = $value;
1994       }
1995     }
1996   }
1997
1998   return $collapsed;
1999 }
2000
2001 # _remove_alias
2002 #
2003 # Remove the specified alias from the specified query hash. A copy is made so
2004 # the original query is not modified.
2005
2006 sub _remove_alias {
2007   my ($self, $query, $alias) = @_;
2008
2009   my %orig = %{ $query || {} };
2010   my %unaliased;
2011
2012   foreach my $key (keys %orig) {
2013     if ($key !~ /\./) {
2014       $unaliased{$key} = $orig{$key};
2015       next;
2016     }
2017     $unaliased{$1} = $orig{$key}
2018       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2019   }
2020
2021   return \%unaliased;
2022 }
2023
2024 =head2 as_query (EXPERIMENTAL)
2025
2026 =over 4
2027
2028 =item Arguments: none
2029
2030 =item Return Value: \[ $sql, @bind ]
2031
2032 =back
2033
2034 Returns the SQL query and bind vars associated with the invocant.
2035
2036 This is generally used as the RHS for a subquery.
2037
2038 B<NOTE>: This feature is still experimental.
2039
2040 =cut
2041
2042 sub as_query {
2043   my $self = shift;
2044
2045   my $attrs = $self->_resolved_attrs_copy;
2046
2047   # For future use:
2048   #
2049   # in list ctx:
2050   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2051   # $sql also has no wrapping parenthesis in list ctx
2052   #
2053   my $sqlbind = $self->result_source->storage
2054     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2055
2056   return $sqlbind;
2057 }
2058
2059 =head2 find_or_new
2060
2061 =over 4
2062
2063 =item Arguments: \%vals, \%attrs?
2064
2065 =item Return Value: $rowobject
2066
2067 =back
2068
2069   my $artist = $schema->resultset('Artist')->find_or_new(
2070     { artist => 'fred' }, { key => 'artists' });
2071
2072   $cd->cd_to_producer->find_or_new({ producer => $producer },
2073                                    { key => 'primary });
2074
2075 Find an existing record from this resultset, based on its primary
2076 key, or a unique constraint. If none exists, instantiate a new result
2077 object and return it. The object will not be saved into your storage
2078 until you call L<DBIx::Class::Row/insert> on it.
2079
2080 You most likely want this method when looking for existing rows using
2081 a unique constraint that is not the primary key, or looking for
2082 related rows.
2083
2084 If you want objects to be saved immediately, use L</find_or_create> instead.
2085
2086 B<Note>: C<find_or_new> is probably not what you want when creating a
2087 new row in a table that uses primary keys supplied by the
2088 database. Passing in a primary key column with a value of I<undef>
2089 will cause L</find> to attempt to search for a row with a value of
2090 I<NULL>.
2091
2092 =cut
2093
2094 sub find_or_new {
2095   my $self     = shift;
2096   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2097   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2098   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2099     return $row;
2100   }
2101   return $self->new_result($hash);
2102 }
2103
2104 =head2 create
2105
2106 =over 4
2107
2108 =item Arguments: \%vals
2109
2110 =item Return Value: a L<DBIx::Class::Row> $object
2111
2112 =back
2113
2114 Attempt to create a single new row or a row with multiple related rows
2115 in the table represented by the resultset (and related tables). This
2116 will not check for duplicate rows before inserting, use
2117 L</find_or_create> to do that.
2118
2119 To create one row for this resultset, pass a hashref of key/value
2120 pairs representing the columns of the table and the values you wish to
2121 store. If the appropriate relationships are set up, foreign key fields
2122 can also be passed an object representing the foreign row, and the
2123 value will be set to its primary key.
2124
2125 To create related objects, pass a hashref for the value if the related
2126 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2127 and use the name of the relationship as the key. (NOT the name of the field,
2128 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2129 of hashrefs containing the data for each of the rows to create in the foreign
2130 tables, again using the relationship name as the key.
2131
2132 Instead of hashrefs of plain related data (key/value pairs), you may
2133 also pass new or inserted objects. New objects (not inserted yet, see
2134 L</new>), will be inserted into their appropriate tables.
2135
2136 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2137
2138 Example of creating a new row.
2139
2140   $person_rs->create({
2141     name=>"Some Person",
2142     email=>"somebody@someplace.com"
2143   });
2144
2145 Example of creating a new row and also creating rows in a related C<has_many>
2146 or C<has_one> resultset.  Note Arrayref.
2147
2148   $artist_rs->create(
2149      { artistid => 4, name => 'Manufactured Crap', cds => [
2150         { title => 'My First CD', year => 2006 },
2151         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2152       ],
2153      },
2154   );
2155
2156 Example of creating a new row and also creating a row in a related
2157 C<belongs_to>resultset. Note Hashref.
2158
2159   $cd_rs->create({
2160     title=>"Music for Silly Walks",
2161     year=>2000,
2162     artist => {
2163       name=>"Silly Musician",
2164     }
2165   });
2166
2167 =cut
2168
2169 sub create {
2170   my ($self, $attrs) = @_;
2171   $self->throw_exception( "create needs a hashref" )
2172     unless ref $attrs eq 'HASH';
2173   return $self->new_result($attrs)->insert;
2174 }
2175
2176 =head2 find_or_create
2177
2178 =over 4
2179
2180 =item Arguments: \%vals, \%attrs?
2181
2182 =item Return Value: $rowobject
2183
2184 =back
2185
2186   $cd->cd_to_producer->find_or_create({ producer => $producer },
2187                                       { key => 'primary' });
2188
2189 Tries to find a record based on its primary key or unique constraints; if none
2190 is found, creates one and returns that instead.
2191
2192   my $cd = $schema->resultset('CD')->find_or_create({
2193     cdid   => 5,
2194     artist => 'Massive Attack',
2195     title  => 'Mezzanine',
2196     year   => 2005,
2197   });
2198
2199 Also takes an optional C<key> attribute, to search by a specific key or unique
2200 constraint. For example:
2201
2202   my $cd = $schema->resultset('CD')->find_or_create(
2203     {
2204       artist => 'Massive Attack',
2205       title  => 'Mezzanine',
2206     },
2207     { key => 'cd_artist_title' }
2208   );
2209
2210 B<Note>: Because find_or_create() reads from the database and then
2211 possibly inserts based on the result, this method is subject to a race
2212 condition. Another process could create a record in the table after
2213 the find has completed and before the create has started. To avoid
2214 this problem, use find_or_create() inside a transaction.
2215
2216 B<Note>: C<find_or_create> is probably not what you want when creating
2217 a new row in a table that uses primary keys supplied by the
2218 database. Passing in a primary key column with a value of I<undef>
2219 will cause L</find> to attempt to search for a row with a value of
2220 I<NULL>.
2221
2222 See also L</find> and L</update_or_create>. For information on how to declare
2223 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2224
2225 =cut
2226
2227 sub find_or_create {
2228   my $self     = shift;
2229   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2230   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2231   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2232     return $row;
2233   }
2234   return $self->create($hash);
2235 }
2236
2237 =head2 update_or_create
2238
2239 =over 4
2240
2241 =item Arguments: \%col_values, { key => $unique_constraint }?
2242
2243 =item Return Value: $rowobject
2244
2245 =back
2246
2247   $resultset->update_or_create({ col => $val, ... });
2248
2249 First, searches for an existing row matching one of the unique constraints
2250 (including the primary key) on the source of this resultset. If a row is
2251 found, updates it with the other given column values. Otherwise, creates a new
2252 row.
2253
2254 Takes an optional C<key> attribute to search on a specific unique constraint.
2255 For example:
2256
2257   # In your application
2258   my $cd = $schema->resultset('CD')->update_or_create(
2259     {
2260       artist => 'Massive Attack',
2261       title  => 'Mezzanine',
2262       year   => 1998,
2263     },
2264     { key => 'cd_artist_title' }
2265   );
2266
2267   $cd->cd_to_producer->update_or_create({
2268     producer => $producer,
2269     name => 'harry',
2270   }, {
2271     key => 'primary,
2272   });
2273
2274
2275 If no C<key> is specified, it searches on all unique constraints defined on the
2276 source, including the primary key.
2277
2278 If the C<key> is specified as C<primary>, it searches only on the primary key.
2279
2280 See also L</find> and L</find_or_create>. For information on how to declare
2281 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2282
2283 B<Note>: C<update_or_create> is probably not what you want when
2284 looking for a row in a table that uses primary keys supplied by the
2285 database, unless you actually have a key value. Passing in a primary
2286 key column with a value of I<undef> will cause L</find> to attempt to
2287 search for a row with a value of I<NULL>.
2288
2289 =cut
2290
2291 sub update_or_create {
2292   my $self = shift;
2293   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2294   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2295
2296   my $row = $self->find($cond, $attrs);
2297   if (defined $row) {
2298     $row->update($cond);
2299     return $row;
2300   }
2301
2302   return $self->create($cond);
2303 }
2304
2305 =head2 update_or_new
2306
2307 =over 4
2308
2309 =item Arguments: \%col_values, { key => $unique_constraint }?
2310
2311 =item Return Value: $rowobject
2312
2313 =back
2314
2315   $resultset->update_or_new({ col => $val, ... });
2316
2317 First, searches for an existing row matching one of the unique constraints
2318 (including the primary key) on the source of this resultset. If a row is
2319 found, updates it with the other given column values. Otherwise, instantiate
2320 a new result object and return it. The object will not be saved into your storage
2321 until you call L<DBIx::Class::Row/insert> on it.
2322
2323 Takes an optional C<key> attribute to search on a specific unique constraint.
2324 For example:
2325
2326   # In your application
2327   my $cd = $schema->resultset('CD')->update_or_new(
2328     {
2329       artist => 'Massive Attack',
2330       title  => 'Mezzanine',
2331       year   => 1998,
2332     },
2333     { key => 'cd_artist_title' }
2334   );
2335
2336   if ($cd->in_storage) {
2337       # the cd was updated
2338   }
2339   else {
2340       # the cd is not yet in the database, let's insert it
2341       $cd->insert;
2342   }
2343
2344 See also L</find>, L</find_or_create> and L<find_or_new>.
2345
2346 =cut
2347
2348 sub update_or_new {
2349     my $self  = shift;
2350     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2351     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2352
2353     my $row = $self->find( $cond, $attrs );
2354     if ( defined $row ) {
2355         $row->update($cond);
2356         return $row;
2357     }
2358
2359     return $self->new_result($cond);
2360 }
2361
2362 =head2 get_cache
2363
2364 =over 4
2365
2366 =item Arguments: none
2367
2368 =item Return Value: \@cache_objects?
2369
2370 =back
2371
2372 Gets the contents of the cache for the resultset, if the cache is set.
2373
2374 The cache is populated either by using the L</prefetch> attribute to
2375 L</search> or by calling L</set_cache>.
2376
2377 =cut
2378
2379 sub get_cache {
2380   shift->{all_cache};
2381 }
2382
2383 =head2 set_cache
2384
2385 =over 4
2386
2387 =item Arguments: \@cache_objects
2388
2389 =item Return Value: \@cache_objects
2390
2391 =back
2392
2393 Sets the contents of the cache for the resultset. Expects an arrayref
2394 of objects of the same class as those produced by the resultset. Note that
2395 if the cache is set the resultset will return the cached objects rather
2396 than re-querying the database even if the cache attr is not set.
2397
2398 The contents of the cache can also be populated by using the
2399 L</prefetch> attribute to L</search>.
2400
2401 =cut
2402
2403 sub set_cache {
2404   my ( $self, $data ) = @_;
2405   $self->throw_exception("set_cache requires an arrayref")
2406       if defined($data) && (ref $data ne 'ARRAY');
2407   $self->{all_cache} = $data;
2408 }
2409
2410 =head2 clear_cache
2411
2412 =over 4
2413
2414 =item Arguments: none
2415
2416 =item Return Value: []
2417
2418 =back
2419
2420 Clears the cache for the resultset.
2421
2422 =cut
2423
2424 sub clear_cache {
2425   shift->set_cache(undef);
2426 }
2427
2428 =head2 related_resultset
2429
2430 =over 4
2431
2432 =item Arguments: $relationship_name
2433
2434 =item Return Value: $resultset
2435
2436 =back
2437
2438 Returns a related resultset for the supplied relationship name.
2439
2440   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2441
2442 =cut
2443
2444 sub related_resultset {
2445   my ($self, $rel) = @_;
2446
2447   $self->{related_resultsets} ||= {};
2448   return $self->{related_resultsets}{$rel} ||= do {
2449     my $rel_info = $self->result_source->relationship_info($rel);
2450
2451     $self->throw_exception(
2452       "search_related: result source '" . $self->result_source->source_name .
2453         "' has no such relationship $rel")
2454       unless $rel_info;
2455
2456     my ($from,$seen) = $self->_resolve_from($rel);
2457
2458     my $join_count = $seen->{$rel};
2459     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2460
2461     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2462     my %attrs = %{$self->{attrs}||{}};
2463     delete @attrs{qw(result_class alias)};
2464
2465     my $new_cache;
2466
2467     if (my $cache = $self->get_cache) {
2468       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2469         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2470                         @$cache ];
2471       }
2472     }
2473
2474     my $rel_source = $self->result_source->related_source($rel);
2475
2476     my $new = do {
2477
2478       # The reason we do this now instead of passing the alias to the
2479       # search_rs below is that if you wrap/overload resultset on the
2480       # source you need to know what alias it's -going- to have for things
2481       # to work sanely (e.g. RestrictWithObject wants to be able to add
2482       # extra query restrictions, and these may need to be $alias.)
2483
2484       my $attrs = $rel_source->resultset_attributes;
2485       local $attrs->{alias} = $alias;
2486
2487       $rel_source->resultset
2488                  ->search_rs(
2489                      undef, {
2490                        %attrs,
2491                        join => undef,
2492                        prefetch => undef,
2493                        select => undef,
2494                        as => undef,
2495                        where => $self->{cond},
2496                        seen_join => $seen,
2497                        from => $from,
2498                    });
2499     };
2500     $new->set_cache($new_cache) if $new_cache;
2501     $new;
2502   };
2503 }
2504
2505 =head2 current_source_alias
2506
2507 =over 4
2508
2509 =item Arguments: none
2510
2511 =item Return Value: $source_alias
2512
2513 =back
2514
2515 Returns the current table alias for the result source this resultset is built
2516 on, that will be used in the SQL query. Usually it is C<me>.
2517
2518 Currently the source alias that refers to the result set returned by a
2519 L</search>/L</find> family method depends on how you got to the resultset: it's
2520 C<me> by default, but eg. L</search_related> aliases it to the related result
2521 source name (and keeps C<me> referring to the original result set). The long
2522 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2523 (and make this method unnecessary).
2524
2525 Thus it's currently necessary to use this method in predefined queries (see
2526 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2527 source alias of the current result set:
2528
2529   # in a result set class
2530   sub modified_by {
2531     my ($self, $user) = @_;
2532
2533     my $me = $self->current_source_alias;
2534
2535     return $self->search(
2536       "$me.modified" => $user->id,
2537     );
2538   }
2539
2540 =cut
2541
2542 sub current_source_alias {
2543   my ($self) = @_;
2544
2545   return ($self->{attrs} || {})->{alias} || 'me';
2546 }
2547
2548 # This code is called by search_related, and makes sure there
2549 # is clear separation between the joins before, during, and
2550 # after the relationship. This information is needed later
2551 # in order to properly resolve prefetch aliases (any alias
2552 # with a relation_chain_depth less than the depth of the
2553 # current prefetch is not considered)
2554 sub _resolve_from {
2555   my ($self, $rel) = @_;
2556   my $source = $self->result_source;
2557   my $attrs = $self->{attrs};
2558
2559   my $from = [ @{
2560       $attrs->{from}
2561         ||
2562       [{
2563         -source_handle => $source->handle,
2564         -alias => $attrs->{alias},
2565         $attrs->{alias} => $source->from,
2566       }]
2567   }];
2568
2569   my $seen = { %{$attrs->{seen_join} || {} } };
2570
2571   # we need to take the prefetch the attrs into account before we
2572   # ->_resolve_join as otherwise they get lost - captainL
2573   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2574
2575   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2576
2577   ++$seen->{-relation_chain_depth};
2578
2579   push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2580
2581   ++$seen->{-relation_chain_depth};
2582
2583   return ($from,$seen);
2584 }
2585
2586 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2587 sub _resolved_attrs_copy {
2588   my $self = shift;
2589   return { %{$self->_resolved_attrs (@_)} };
2590 }
2591
2592 sub _resolved_attrs {
2593   my $self = shift;
2594   return $self->{_attrs} if $self->{_attrs};
2595
2596   my $attrs  = { %{ $self->{attrs} || {} } };
2597   my $source = $self->result_source;
2598   my $alias  = $attrs->{alias};
2599
2600   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2601   my @colbits;
2602
2603   # build columns (as long as select isn't set) into a set of as/select hashes
2604   unless ( $attrs->{select} ) {
2605       @colbits = map {
2606           ( ref($_) eq 'HASH' )
2607               ? $_
2608               : {
2609                   (
2610                     /^\Q${alias}.\E(.+)$/
2611                       ? "$1"
2612                       : "$_"
2613                   )
2614                 =>
2615                   (
2616                     /\./
2617                       ? "$_"
2618                       : "${alias}.$_"
2619                   )
2620             }
2621       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2622   }
2623   # add the additional columns on
2624   foreach ( 'include_columns', '+columns' ) {
2625       push @colbits, map {
2626           ( ref($_) eq 'HASH' )
2627             ? $_
2628             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2629       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2630   }
2631
2632   # start with initial select items
2633   if ( $attrs->{select} ) {
2634     $attrs->{select} =
2635         ( ref $attrs->{select} eq 'ARRAY' )
2636       ? [ @{ $attrs->{select} } ]
2637       : [ $attrs->{select} ];
2638     $attrs->{as} = (
2639       $attrs->{as}
2640       ? (
2641         ref $attrs->{as} eq 'ARRAY'
2642         ? [ @{ $attrs->{as} } ]
2643         : [ $attrs->{as} ]
2644         )
2645       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2646     );
2647   }
2648   else {
2649
2650     # otherwise we intialise select & as to empty
2651     $attrs->{select} = [];
2652     $attrs->{as}     = [];
2653   }
2654
2655   # now add colbits to select/as
2656   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2657   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2658
2659   my $adds;
2660   if ( $adds = delete $attrs->{'+select'} ) {
2661     $adds = [$adds] unless ref $adds eq 'ARRAY';
2662     push(
2663       @{ $attrs->{select} },
2664       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2665     );
2666   }
2667   if ( $adds = delete $attrs->{'+as'} ) {
2668     $adds = [$adds] unless ref $adds eq 'ARRAY';
2669     push( @{ $attrs->{as} }, @$adds );
2670   }
2671
2672   $attrs->{from} ||= [ {
2673     -source_handle => $source->handle,
2674     -alias => $self->{attrs}{alias},
2675     $self->{attrs}{alias} => $source->from,
2676   } ];
2677
2678   if ( $attrs->{join} || $attrs->{prefetch} ) {
2679
2680     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2681       if ref $attrs->{from} ne 'ARRAY';
2682
2683     my $join = delete $attrs->{join} || {};
2684
2685     if ( defined $attrs->{prefetch} ) {
2686       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2687     }
2688
2689     $attrs->{from} =    # have to copy here to avoid corrupting the original
2690       [
2691         @{ $attrs->{from} },
2692         $source->_resolve_join(
2693           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2694         )
2695       ];
2696   }
2697
2698   if ( $attrs->{order_by} ) {
2699     $attrs->{order_by} = (
2700       ref( $attrs->{order_by} ) eq 'ARRAY'
2701       ? [ @{ $attrs->{order_by} } ]
2702       : [ $attrs->{order_by} ]
2703     );
2704   }
2705   else {
2706     $attrs->{order_by} = [];
2707   }
2708
2709   # If the order_by is otherwise empty - we will use this for TOP limit
2710   # emulation and the like.
2711   # Although this is needed only if the order_by is not defined, it is
2712   # actually cheaper to just populate this rather than properly examining
2713   # order_by (stuf like [ {} ] and the like)
2714   my $prefix = $alias . ($source->schema->storage->sql_maker->{name_sep} || '.');
2715   $attrs->{_virtual_order_by} = [
2716     map { $prefix . $_ } ($source->primary_columns)
2717   ];
2718
2719   $attrs->{collapse} ||= {};
2720   if ( my $prefetch = delete $attrs->{prefetch} ) {
2721     $prefetch = $self->_merge_attr( {}, $prefetch );
2722
2723     my $prefetch_ordering = [];
2724
2725     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2726
2727     my @prefetch =
2728       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2729
2730     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2731     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2732
2733     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2734     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2735   }
2736
2737
2738   if (delete $attrs->{distinct}) {
2739     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2740   }
2741
2742   # if both page and offset are specified, produce a combined offset
2743   # even though it doesn't make much sense, this is what pre 081xx has
2744   # been doing
2745   if (my $page = delete $attrs->{page}) {
2746     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2747       ($attrs->{offset} || 0);
2748   }
2749
2750   return $self->{_attrs} = $attrs;
2751 }
2752
2753 sub _joinpath_aliases {
2754   my ($self, $fromspec, $seen) = @_;
2755
2756   my $paths = {};
2757   return $paths unless ref $fromspec eq 'ARRAY';
2758
2759   for my $j (@$fromspec) {
2760
2761     next if ref $j ne 'ARRAY';
2762     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2763
2764     my $p = $paths;
2765     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2766     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2767   }
2768
2769   return $paths;
2770 }
2771
2772 sub _rollout_attr {
2773   my ($self, $attr) = @_;
2774
2775   if (ref $attr eq 'HASH') {
2776     return $self->_rollout_hash($attr);
2777   } elsif (ref $attr eq 'ARRAY') {
2778     return $self->_rollout_array($attr);
2779   } else {
2780     return [$attr];
2781   }
2782 }
2783
2784 sub _rollout_array {
2785   my ($self, $attr) = @_;
2786
2787   my @rolled_array;
2788   foreach my $element (@{$attr}) {
2789     if (ref $element eq 'HASH') {
2790       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2791     } elsif (ref $element eq 'ARRAY') {
2792       #  XXX - should probably recurse here
2793       push( @rolled_array, @{$self->_rollout_array($element)} );
2794     } else {
2795       push( @rolled_array, $element );
2796     }
2797   }
2798   return \@rolled_array;
2799 }
2800
2801 sub _rollout_hash {
2802   my ($self, $attr) = @_;
2803
2804   my @rolled_array;
2805   foreach my $key (keys %{$attr}) {
2806     push( @rolled_array, { $key => $attr->{$key} } );
2807   }
2808   return \@rolled_array;
2809 }
2810
2811 sub _calculate_score {
2812   my ($self, $a, $b) = @_;
2813
2814   if (ref $b eq 'HASH') {
2815     my ($b_key) = keys %{$b};
2816     if (ref $a eq 'HASH') {
2817       my ($a_key) = keys %{$a};
2818       if ($a_key eq $b_key) {
2819         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2820       } else {
2821         return 0;
2822       }
2823     } else {
2824       return ($a eq $b_key) ? 1 : 0;
2825     }
2826   } else {
2827     if (ref $a eq 'HASH') {
2828       my ($a_key) = keys %{$a};
2829       return ($b eq $a_key) ? 1 : 0;
2830     } else {
2831       return ($b eq $a) ? 1 : 0;
2832     }
2833   }
2834 }
2835
2836 sub _merge_attr {
2837   my ($self, $orig, $import) = @_;
2838
2839   return $import unless defined($orig);
2840   return $orig unless defined($import);
2841
2842   $orig = $self->_rollout_attr($orig);
2843   $import = $self->_rollout_attr($import);
2844
2845   my $seen_keys;
2846   foreach my $import_element ( @{$import} ) {
2847     # find best candidate from $orig to merge $b_element into
2848     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2849     foreach my $orig_element ( @{$orig} ) {
2850       my $score = $self->_calculate_score( $orig_element, $import_element );
2851       if ($score > $best_candidate->{score}) {
2852         $best_candidate->{position} = $position;
2853         $best_candidate->{score} = $score;
2854       }
2855       $position++;
2856     }
2857     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2858
2859     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2860       push( @{$orig}, $import_element );
2861     } else {
2862       my $orig_best = $orig->[$best_candidate->{position}];
2863       # merge orig_best and b_element together and replace original with merged
2864       if (ref $orig_best ne 'HASH') {
2865         $orig->[$best_candidate->{position}] = $import_element;
2866       } elsif (ref $import_element eq 'HASH') {
2867         my ($key) = keys %{$orig_best};
2868         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2869       }
2870     }
2871     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2872   }
2873
2874   return $orig;
2875 }
2876
2877 sub result_source {
2878     my $self = shift;
2879
2880     if (@_) {
2881         $self->_source_handle($_[0]->handle);
2882     } else {
2883         $self->_source_handle->resolve;
2884     }
2885 }
2886
2887 =head2 throw_exception
2888
2889 See L<DBIx::Class::Schema/throw_exception> for details.
2890
2891 =cut
2892
2893 sub throw_exception {
2894   my $self=shift;
2895   if (ref $self && $self->_source_handle->schema) {
2896     $self->_source_handle->schema->throw_exception(@_)
2897   } else {
2898     croak(@_);
2899   }
2900
2901 }
2902
2903 # XXX: FIXME: Attributes docs need clearing up
2904
2905 =head1 ATTRIBUTES
2906
2907 Attributes are used to refine a ResultSet in various ways when
2908 searching for data. They can be passed to any method which takes an
2909 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2910 L</count>.
2911
2912 These are in no particular order:
2913
2914 =head2 order_by
2915
2916 =over 4
2917
2918 =item Value: ( $order_by | \@order_by | \%order_by )
2919
2920 =back
2921
2922 Which column(s) to order the results by. If a single column name, or
2923 an arrayref of names is supplied, the argument is passed through
2924 directly to SQL. The hashref syntax allows for connection-agnostic
2925 specification of ordering direction:
2926
2927  For descending order:
2928
2929   order_by => { -desc => [qw/col1 col2 col3/] }
2930
2931  For explicit ascending order:
2932
2933   order_by => { -asc => 'col' }
2934
2935 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2936 supported, although you are strongly encouraged to use the hashref
2937 syntax as outlined above.
2938
2939 =head2 columns
2940
2941 =over 4
2942
2943 =item Value: \@columns
2944
2945 =back
2946
2947 Shortcut to request a particular set of columns to be retrieved. Each
2948 column spec may be a string (a table column name), or a hash (in which
2949 case the key is the C<as> value, and the value is used as the C<select>
2950 expression). Adds C<me.> onto the start of any column without a C<.> in
2951 it and sets C<select> from that, then auto-populates C<as> from
2952 C<select> as normal. (You may also use the C<cols> attribute, as in
2953 earlier versions of DBIC.)
2954
2955 =head2 +columns
2956
2957 =over 4
2958
2959 =item Value: \@columns
2960
2961 =back
2962
2963 Indicates additional columns to be selected from storage. Works the same
2964 as L</columns> but adds columns to the selection. (You may also use the
2965 C<include_columns> attribute, as in earlier versions of DBIC). For
2966 example:-
2967
2968   $schema->resultset('CD')->search(undef, {
2969     '+columns' => ['artist.name'],
2970     join => ['artist']
2971   });
2972
2973 would return all CDs and include a 'name' column to the information
2974 passed to object inflation. Note that the 'artist' is the name of the
2975 column (or relationship) accessor, and 'name' is the name of the column
2976 accessor in the related table.
2977
2978 =head2 include_columns
2979
2980 =over 4
2981
2982 =item Value: \@columns
2983
2984 =back
2985
2986 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2987
2988 =head2 select
2989
2990 =over 4
2991
2992 =item Value: \@select_columns
2993
2994 =back
2995
2996 Indicates which columns should be selected from the storage. You can use
2997 column names, or in the case of RDBMS back ends, function or stored procedure
2998 names:
2999
3000   $rs = $schema->resultset('Employee')->search(undef, {
3001     select => [
3002       'name',
3003       { count => 'employeeid' },
3004       { sum => 'salary' }
3005     ]
3006   });
3007
3008 When you use function/stored procedure names and do not supply an C<as>
3009 attribute, the column names returned are storage-dependent. E.g. MySQL would
3010 return a column named C<count(employeeid)> in the above example.
3011
3012 =head2 +select
3013
3014 =over 4
3015
3016 Indicates additional columns to be selected from storage.  Works the same as
3017 L</select> but adds columns to the selection.
3018
3019 =back
3020
3021 =head2 +as
3022
3023 =over 4
3024
3025 Indicates additional column names for those added via L</+select>. See L</as>.
3026
3027 =back
3028
3029 =head2 as
3030
3031 =over 4
3032
3033 =item Value: \@inflation_names
3034
3035 =back
3036
3037 Indicates column names for object inflation. That is, C<as>
3038 indicates the name that the column can be accessed as via the
3039 C<get_column> method (or via the object accessor, B<if one already
3040 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3041
3042 The C<as> attribute is used in conjunction with C<select>,
3043 usually when C<select> contains one or more function or stored
3044 procedure names:
3045
3046   $rs = $schema->resultset('Employee')->search(undef, {
3047     select => [
3048       'name',
3049       { count => 'employeeid' }
3050     ],
3051     as => ['name', 'employee_count'],
3052   });
3053
3054   my $employee = $rs->first(); # get the first Employee
3055
3056 If the object against which the search is performed already has an accessor
3057 matching a column name specified in C<as>, the value can be retrieved using
3058 the accessor as normal:
3059
3060   my $name = $employee->name();
3061
3062 If on the other hand an accessor does not exist in the object, you need to
3063 use C<get_column> instead:
3064
3065   my $employee_count = $employee->get_column('employee_count');
3066
3067 You can create your own accessors if required - see
3068 L<DBIx::Class::Manual::Cookbook> for details.
3069
3070 Please note: This will NOT insert an C<AS employee_count> into the SQL
3071 statement produced, it is used for internal access only. Thus
3072 attempting to use the accessor in an C<order_by> clause or similar
3073 will fail miserably.
3074
3075 To get around this limitation, you can supply literal SQL to your
3076 C<select> attibute that contains the C<AS alias> text, eg:
3077
3078   select => [\'myfield AS alias']
3079
3080 =head2 join
3081
3082 =over 4
3083
3084 =item Value: ($rel_name | \@rel_names | \%rel_names)
3085
3086 =back
3087
3088 Contains a list of relationships that should be joined for this query.  For
3089 example:
3090
3091   # Get CDs by Nine Inch Nails
3092   my $rs = $schema->resultset('CD')->search(
3093     { 'artist.name' => 'Nine Inch Nails' },
3094     { join => 'artist' }
3095   );
3096
3097 Can also contain a hash reference to refer to the other relation's relations.
3098 For example:
3099
3100   package MyApp::Schema::Track;
3101   use base qw/DBIx::Class/;
3102   __PACKAGE__->table('track');
3103   __PACKAGE__->add_columns(qw/trackid cd position title/);
3104   __PACKAGE__->set_primary_key('trackid');
3105   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3106   1;
3107
3108   # In your application
3109   my $rs = $schema->resultset('Artist')->search(
3110     { 'track.title' => 'Teardrop' },
3111     {
3112       join     => { cd => 'track' },
3113       order_by => 'artist.name',
3114     }
3115   );
3116
3117 You need to use the relationship (not the table) name in  conditions,
3118 because they are aliased as such. The current table is aliased as "me", so
3119 you need to use me.column_name in order to avoid ambiguity. For example:
3120
3121   # Get CDs from 1984 with a 'Foo' track
3122   my $rs = $schema->resultset('CD')->search(
3123     {
3124       'me.year' => 1984,
3125       'tracks.name' => 'Foo'
3126     },
3127     { join => 'tracks' }
3128   );
3129
3130 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3131 similarly for a third time). For e.g.
3132
3133   my $rs = $schema->resultset('Artist')->search({
3134     'cds.title'   => 'Down to Earth',
3135     'cds_2.title' => 'Popular',
3136   }, {
3137     join => [ qw/cds cds/ ],
3138   });
3139
3140 will return a set of all artists that have both a cd with title 'Down
3141 to Earth' and a cd with title 'Popular'.
3142
3143 If you want to fetch related objects from other tables as well, see C<prefetch>
3144 below.
3145
3146 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3147
3148 =head2 prefetch
3149
3150 =over 4
3151
3152 =item Value: ($rel_name | \@rel_names | \%rel_names)
3153
3154 =back
3155
3156 Contains one or more relationships that should be fetched along with
3157 the main query (when they are accessed afterwards the data will
3158 already be available, without extra queries to the database).  This is
3159 useful for when you know you will need the related objects, because it
3160 saves at least one query:
3161
3162   my $rs = $schema->resultset('Tag')->search(
3163     undef,
3164     {
3165       prefetch => {
3166         cd => 'artist'
3167       }
3168     }
3169   );
3170
3171 The initial search results in SQL like the following:
3172
3173   SELECT tag.*, cd.*, artist.* FROM tag
3174   JOIN cd ON tag.cd = cd.cdid
3175   JOIN artist ON cd.artist = artist.artistid
3176
3177 L<DBIx::Class> has no need to go back to the database when we access the
3178 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3179 case.
3180
3181 Simple prefetches will be joined automatically, so there is no need
3182 for a C<join> attribute in the above search.
3183
3184 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3185 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3186 with an accessor type of 'single' or 'filter'). A more complex example that
3187 prefetches an artists cds, the tracks on those cds, and the tags associted
3188 with that artist is given below (assuming many-to-many from artists to tags):
3189
3190  my $rs = $schema->resultset('Artist')->search(
3191    undef,
3192    {
3193      prefetch => [
3194        { cds => 'tracks' },
3195        { artist_tags => 'tags' }
3196      ]
3197    }
3198  );
3199
3200
3201 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3202 attributes will be ignored.
3203
3204 =head2 page
3205
3206 =over 4
3207
3208 =item Value: $page
3209
3210 =back
3211
3212 Makes the resultset paged and specifies the page to retrieve. Effectively
3213 identical to creating a non-pages resultset and then calling ->page($page)
3214 on it.
3215
3216 If L<rows> attribute is not specified it defaults to 10 rows per page.
3217
3218 When you have a paged resultset, L</count> will only return the number
3219 of rows in the page. To get the total, use the L</pager> and call
3220 C<total_entries> on it.
3221
3222 =head2 rows
3223
3224 =over 4
3225
3226 =item Value: $rows
3227
3228 =back
3229
3230 Specifes the maximum number of rows for direct retrieval or the number of
3231 rows per page if the page attribute or method is used.
3232
3233 =head2 offset
3234
3235 =over 4
3236
3237 =item Value: $offset
3238
3239 =back
3240
3241 Specifies the (zero-based) row number for the  first row to be returned, or the
3242 of the first row of the first page if paging is used.
3243
3244 =head2 group_by
3245
3246 =over 4
3247
3248 =item Value: \@columns
3249
3250 =back
3251
3252 A arrayref of columns to group by. Can include columns of joined tables.
3253
3254   group_by => [qw/ column1 column2 ... /]
3255
3256 =head2 having
3257
3258 =over 4
3259
3260 =item Value: $condition
3261
3262 =back
3263
3264 HAVING is a select statement attribute that is applied between GROUP BY and
3265 ORDER BY. It is applied to the after the grouping calculations have been
3266 done.
3267
3268   having => { 'count(employee)' => { '>=', 100 } }
3269
3270 =head2 distinct
3271
3272 =over 4
3273
3274 =item Value: (0 | 1)
3275
3276 =back
3277
3278 Set to 1 to group by all columns.
3279
3280 =head2 where
3281
3282 =over 4
3283
3284 Adds to the WHERE clause.
3285
3286   # only return rows WHERE deleted IS NULL for all searches
3287   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3288
3289 Can be overridden by passing C<{ where => undef }> as an attribute
3290 to a resulset.
3291
3292 =back
3293
3294 =head2 cache
3295
3296 Set to 1 to cache search results. This prevents extra SQL queries if you
3297 revisit rows in your ResultSet:
3298
3299   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3300
3301   while( my $artist = $resultset->next ) {
3302     ... do stuff ...
3303   }
3304
3305   $rs->first; # without cache, this would issue a query
3306
3307 By default, searches are not cached.
3308
3309 For more examples of using these attributes, see
3310 L<DBIx::Class::Manual::Cookbook>.
3311
3312 =head2 from
3313
3314 =over 4
3315
3316 =item Value: \@from_clause
3317
3318 =back
3319
3320 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3321 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3322 clauses.
3323
3324 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3325
3326 C<join> will usually do what you need and it is strongly recommended that you
3327 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3328 And we really do mean "cannot", not just tried and failed. Attempting to use
3329 this because you're having problems with C<join> is like trying to use x86
3330 ASM because you've got a syntax error in your C. Trust us on this.
3331
3332 Now, if you're still really, really sure you need to use this (and if you're
3333 not 100% sure, ask the mailing list first), here's an explanation of how this
3334 works.
3335
3336 The syntax is as follows -
3337
3338   [
3339     { <alias1> => <table1> },
3340     [
3341       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3342       [], # nested JOIN (optional)
3343       { <table1.column1> => <table2.column2>, ... (more conditions) },
3344     ],
3345     # More of the above [ ] may follow for additional joins
3346   ]
3347
3348   <table1> <alias1>
3349   JOIN
3350     <table2> <alias2>
3351     [JOIN ...]
3352   ON <table1.column1> = <table2.column2>
3353   <more joins may follow>
3354
3355 An easy way to follow the examples below is to remember the following:
3356
3357     Anything inside "[]" is a JOIN
3358     Anything inside "{}" is a condition for the enclosing JOIN
3359
3360 The following examples utilize a "person" table in a family tree application.
3361 In order to express parent->child relationships, this table is self-joined:
3362
3363     # Person->belongs_to('father' => 'Person');
3364     # Person->belongs_to('mother' => 'Person');
3365
3366 C<from> can be used to nest joins. Here we return all children with a father,
3367 then search against all mothers of those children:
3368
3369   $rs = $schema->resultset('Person')->search(
3370       undef,
3371       {
3372           alias => 'mother', # alias columns in accordance with "from"
3373           from => [
3374               { mother => 'person' },
3375               [
3376                   [
3377                       { child => 'person' },
3378                       [
3379                           { father => 'person' },
3380                           { 'father.person_id' => 'child.father_id' }
3381                       ]
3382                   ],
3383                   { 'mother.person_id' => 'child.mother_id' }
3384               ],
3385           ]
3386       },
3387   );
3388
3389   # Equivalent SQL:
3390   # SELECT mother.* FROM person mother
3391   # JOIN (
3392   #   person child
3393   #   JOIN person father
3394   #   ON ( father.person_id = child.father_id )
3395   # )
3396   # ON ( mother.person_id = child.mother_id )
3397
3398 The type of any join can be controlled manually. To search against only people
3399 with a father in the person table, we could explicitly use C<INNER JOIN>:
3400
3401     $rs = $schema->resultset('Person')->search(
3402         undef,
3403         {
3404             alias => 'child', # alias columns in accordance with "from"
3405             from => [
3406                 { child => 'person' },
3407                 [
3408                     { father => 'person', -join_type => 'inner' },
3409                     { 'father.id' => 'child.father_id' }
3410                 ],
3411             ]
3412         },
3413     );
3414
3415     # Equivalent SQL:
3416     # SELECT child.* FROM person child
3417     # INNER JOIN person father ON child.father_id = father.id
3418
3419 You can select from a subquery by passing a resultset to from as follows.
3420
3421     $schema->resultset('Artist')->search(
3422         undef,
3423         {   alias => 'artist2',
3424             from  => [ { artist2 => $artist_rs->as_query } ],
3425         } );
3426
3427     # and you'll get sql like this..
3428     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3429     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3430
3431 If you need to express really complex joins, you
3432 can supply literal SQL to C<from> via a scalar reference. In this case
3433 the contents of the scalar will replace the table name associated with the
3434 resultsource.
3435
3436 WARNING: This technique might very well not work as expected on chained
3437 searches - you have been warned.
3438
3439     # Assuming the Event resultsource is defined as:
3440
3441         MySchema::Event->add_columns (
3442             sequence => {
3443                 data_type => 'INT',
3444                 is_auto_increment => 1,
3445             },
3446             location => {
3447                 data_type => 'INT',
3448             },
3449             type => {
3450                 data_type => 'INT',
3451             },
3452         );
3453         MySchema::Event->set_primary_key ('sequence');
3454
3455     # This will get back the latest event for every location. The column
3456     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3457     # combo to limit the resultset
3458
3459     $rs = $schema->resultset('Event');
3460     $table = $rs->result_source->name;
3461     $latest = $rs->search (
3462         undef,
3463         { from => \ "
3464             (SELECT e1.* FROM $table e1
3465                 JOIN $table e2
3466                     ON e1.location = e2.location
3467                     AND e1.sequence < e2.sequence
3468                 WHERE e2.sequence is NULL
3469             ) me",
3470         },
3471     );
3472
3473     # Equivalent SQL (with the DBIC chunks added):
3474
3475     SELECT me.sequence, me.location, me.type FROM
3476        (SELECT e1.* FROM events e1
3477            JOIN events e2
3478                ON e1.location = e2.location
3479                AND e1.sequence < e2.sequence
3480            WHERE e2.sequence is NULL
3481        ) me;
3482
3483 =head2 for
3484
3485 =over 4
3486
3487 =item Value: ( 'update' | 'shared' )
3488
3489 =back
3490
3491 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3492 ... FOR SHARED.
3493
3494 =cut
3495
3496 1;