lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 961   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 962   @new = $self->{_attrs}{record_filter}->(@new)
 963     if exists $self->{_attrs}{record_filter};
 964   return @new;
 965 }
 966
 967 sub _collapse_result {
 968   my ($self, $as_proto, $row) = @_;
 969
 970   my @copy = @$row;
 971
 972   # 'foo'         => [ undef, 'foo' ]
 973   # 'foo.bar'     => [ 'foo', 'bar' ]
 974   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 975
 976   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 977
 978   my %collapse = %{$self->{_attrs}{collapse}||{}};
 979
 980   my @pri_index;
 981
 982   # if we're doing collapsing (has_many prefetch) we need to grab records
 983   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 984   # we know we don't have to bother.
 985
 986   # the reason for not using the collapse stuff directly is because if you
 987   # had for e.g. two artists in a row with no cds, the collapse info for
 988   # both would be NULL (undef) so you'd lose the second artist
 989
 990   # store just the index so we can check the array positions from the row
 991   # without having to contruct the full hash
 992
 993   if (keys %collapse) {
 994     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 995     foreach my $i (0 .. $#construct_as) {
 996       next if defined($construct_as[$i][0]); # only self table
 997       if (delete $pri{$construct_as[$i][1]}) {
 998         push(@pri_index, $i);
 999       }
1000       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1001     }
1002   }
1003
1004   # no need to do an if, it'll be empty if @pri_index is empty anyway
1005
1006   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1007
1008   my @const_rows;
1009
1010   do { # no need to check anything at the front, we always want the first row
1011
1012     my %const;
1013
1014     foreach my $this_as (@construct_as) {
1015       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1016     }
1017
1018     push(@const_rows, \%const);
1019
1020   } until ( # no pri_index => no collapse => drop straight out
1021       !@pri_index
1022     or
1023       do { # get another row, stash it, drop out if different PK
1024
1025         @copy = $self->cursor->next;
1026         $self->{stashed_row} = \@copy;
1027
1028         # last thing in do block, counts as true if anything doesn't match
1029
1030         # check xor defined first for NULL vs. NOT NULL then if one is
1031         # defined the other must be so check string equality
1032
1033         grep {
1034           (defined $pri_vals{$_} ^ defined $copy[$_])
1035           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1036         } @pri_index;
1037       }
1038   );
1039
1040   my $alias = $self->{attrs}{alias};
1041   my $info = [];
1042
1043   my %collapse_pos;
1044
1045   my @const_keys;
1046
1047   foreach my $const (@const_rows) {
1048     scalar @const_keys or do {
1049       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1050     };
1051     foreach my $key (@const_keys) {
1052       if (length $key) {
1053         my $target = $info;
1054         my @parts = split(/\./, $key);
1055         my $cur = '';
1056         my $data = $const->{$key};
1057         foreach my $p (@parts) {
1058           $target = $target->[1]->{$p} ||= [];
1059           $cur .= ".${p}";
1060           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1061             # collapsing at this point and on final part
1062             my $pos = $collapse_pos{$cur};
1063             CK: foreach my $ck (@ckey) {
1064               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1065                 $collapse_pos{$cur} = $data;
1066                 delete @collapse_pos{ # clear all positioning for sub-entries
1067                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1068                 };
1069                 push(@$target, []);
1070                 last CK;
1071               }
1072             }
1073           }
1074           if (exists $collapse{$cur}) {
1075             $target = $target->[-1];
1076           }
1077         }
1078         $target->[0] = $data;
1079       } else {
1080         $info->[0] = $const->{$key};
1081       }
1082     }
1083   }
1084
1085   return $info;
1086 }
1087
1088 =head2 result_source
1089
1090 =over 4
1091
1092 =item Arguments: $result_source?
1093
1094 =item Return Value: $result_source
1095
1096 =back
1097
1098 An accessor for the primary ResultSource object from which this ResultSet
1099 is derived.
1100
1101 =head2 result_class
1102
1103 =over 4
1104
1105 =item Arguments: $result_class?
1106
1107 =item Return Value: $result_class
1108
1109 =back
1110
1111 An accessor for the class to use when creating row objects. Defaults to
1112 C<< result_source->result_class >> - which in most cases is the name of the
1113 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1114
1115 Note that changing the result_class will also remove any components
1116 that were originally loaded in the source class via
1117 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1118 in the original source class will not run.
1119
1120 =cut
1121
1122 sub result_class {
1123   my ($self, $result_class) = @_;
1124   if ($result_class) {
1125     $self->ensure_class_loaded($result_class);
1126     $self->_result_class($result_class);
1127   }
1128   $self->_result_class;
1129 }
1130
1131 =head2 count
1132
1133 =over 4
1134
1135 =item Arguments: $cond, \%attrs??
1136
1137 =item Return Value: $count
1138
1139 =back
1140
1141 Performs an SQL C<COUNT> with the same query as the resultset was built
1142 with to find the number of elements. Passing arguments is equivalent to
1143 C<< $rs->search ($cond, \%attrs)->count >>
1144
1145 =cut
1146
1147 sub count {
1148   my $self = shift;
1149   return $self->search(@_)->count if @_ and defined $_[0];
1150   return scalar @{ $self->get_cache } if $self->get_cache;
1151
1152   my $attrs = $self->_resolved_attrs_copy;
1153
1154   # this is a little optimization - it is faster to do the limit
1155   # adjustments in software, instead of a subquery
1156   my $rows = delete $attrs->{rows};
1157   my $offset = delete $attrs->{offset};
1158
1159   my $crs;
1160   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1161     $crs = $self->_count_subq_rs ($attrs);
1162   }
1163   else {
1164     $crs = $self->_count_rs ($attrs);
1165   }
1166   my $count = $crs->next;
1167
1168   $count -= $offset if $offset;
1169   $count = $rows if $rows and $rows < $count;
1170   $count = 0 if ($count < 0);
1171
1172   return $count;
1173 }
1174
1175 =head2 count_rs
1176
1177 =over 4
1178
1179 =item Arguments: $cond, \%attrs??
1180
1181 =item Return Value: $count_rs
1182
1183 =back
1184
1185 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1186 This can be very handy for subqueries:
1187
1188   ->search( { amount => $some_rs->count_rs->as_query } )
1189
1190 As with regular resultsets the SQL query will be executed only after
1191 the resultset is accessed via L</next> or L</all>. That would return
1192 the same single value obtainable via L</count>.
1193
1194 =cut
1195
1196 sub count_rs {
1197   my $self = shift;
1198   return $self->search(@_)->count_rs if @_;
1199
1200   # this may look like a lack of abstraction (count() does about the same)
1201   # but in fact an _rs *must* use a subquery for the limits, as the
1202   # software based limiting can not be ported if this $rs is to be used
1203   # in a subquery itself (i.e. ->as_query)
1204   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1205     return $self->_count_subq_rs;
1206   }
1207   else {
1208     return $self->_count_rs;
1209   }
1210 }
1211
1212 #
1213 # returns a ResultSetColumn object tied to the count query
1214 #
1215 sub _count_rs {
1216   my ($self, $attrs) = @_;
1217
1218   my $rsrc = $self->result_source;
1219   $attrs ||= $self->_resolved_attrs;
1220
1221   my $tmp_attrs = { %$attrs };
1222
1223   # take off any limits, record_filter is cdbi, and no point of ordering a count
1224   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1225
1226   # overwrite the selector (supplied by the storage)
1227   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1228   $tmp_attrs->{as} = 'count';
1229
1230   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1231
1232   return $tmp_rs;
1233 }
1234
1235 #
1236 # same as above but uses a subquery
1237 #
1238 sub _count_subq_rs {
1239   my ($self, $attrs) = @_;
1240
1241   my $rsrc = $self->result_source;
1242   $attrs ||= $self->_resolved_attrs_copy;
1243
1244   my $sub_attrs = { %$attrs };
1245
1246   # these can not go in the subquery, and there is no point of ordering it
1247   delete $sub_attrs->{$_} for qw/collapse select as order_by/;
1248
1249   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1250   # clobber old group_by regardless
1251   if ( keys %{$attrs->{collapse}} ) {
1252     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1253   }
1254
1255   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1256
1257   # this is so that ordering can be thrown away in things like Top limit
1258   $sub_attrs->{-for_count_only} = 1;
1259
1260   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1261   $attrs->{from} = [{
1262     -alias => 'count_subq',
1263     -source_handle => $rsrc->handle,
1264     count_subq => $sub_rs->as_query,
1265   }];
1266
1267   # the subquery replaces this
1268   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1269
1270   return $self->_count_rs ($attrs);
1271 }
1272
1273
1274 sub _bool {
1275   return 1;
1276 }
1277
1278 =head2 count_literal
1279
1280 =over 4
1281
1282 =item Arguments: $sql_fragment, @bind_values
1283
1284 =item Return Value: $count
1285
1286 =back
1287
1288 Counts the results in a literal query. Equivalent to calling L</search_literal>
1289 with the passed arguments, then L</count>.
1290
1291 =cut
1292
1293 sub count_literal { shift->search_literal(@_)->count; }
1294
1295 =head2 all
1296
1297 =over 4
1298
1299 =item Arguments: none
1300
1301 =item Return Value: @objects
1302
1303 =back
1304
1305 Returns all elements in the resultset. Called implicitly if the resultset
1306 is returned in list context.
1307
1308 =cut
1309
1310 sub all {
1311   my $self = shift;
1312   if(@_) {
1313       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1314   }
1315
1316   return @{ $self->get_cache } if $self->get_cache;
1317
1318   my @obj;
1319
1320   # TODO: don't call resolve here
1321   if (keys %{$self->_resolved_attrs->{collapse}}) {
1322 #  if ($self->{attrs}{prefetch}) {
1323       # Using $self->cursor->all is really just an optimisation.
1324       # If we're collapsing has_many prefetches it probably makes
1325       # very little difference, and this is cleaner than hacking
1326       # _construct_object to survive the approach
1327     my @row = $self->cursor->next;
1328     while (@row) {
1329       push(@obj, $self->_construct_object(@row));
1330       @row = (exists $self->{stashed_row}
1331                ? @{delete $self->{stashed_row}}
1332                : $self->cursor->next);
1333     }
1334   } else {
1335     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1336   }
1337
1338   $self->set_cache(\@obj) if $self->{attrs}{cache};
1339   return @obj;
1340 }
1341
1342 =head2 reset
1343
1344 =over 4
1345
1346 =item Arguments: none
1347
1348 =item Return Value: $self
1349
1350 =back
1351
1352 Resets the resultset's cursor, so you can iterate through the elements again.
1353
1354 =cut
1355
1356 sub reset {
1357   my ($self) = @_;
1358   delete $self->{_attrs} if exists $self->{_attrs};
1359   $self->{all_cache_position} = 0;
1360   $self->cursor->reset;
1361   return $self;
1362 }
1363
1364 =head2 first
1365
1366 =over 4
1367
1368 =item Arguments: none
1369
1370 =item Return Value: $object?
1371
1372 =back
1373
1374 Resets the resultset and returns an object for the first result (if the
1375 resultset returns anything).
1376
1377 =cut
1378
1379 sub first {
1380   return $_[0]->reset->next;
1381 }
1382
1383
1384 # _rs_update_delete
1385 #
1386 # Determines whether and what type of subquery is required for the $rs operation.
1387 # If grouping is necessary either supplies its own, or verifies the current one
1388 # After all is done delegates to the proper storage method.
1389
1390 sub _rs_update_delete {
1391   my ($self, $op, $values) = @_;
1392
1393   my $rsrc = $self->result_source;
1394
1395   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1396   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1397
1398   if ($needs_group_by_subq or $needs_subq) {
1399
1400     # make a new $rs selecting only the PKs (that's all we really need)
1401     my $attrs = $self->_resolved_attrs_copy;
1402
1403     delete $attrs->{$_} for qw/collapse select as/;
1404     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1405
1406     if ($needs_group_by_subq) {
1407       # make sure no group_by was supplied, or if there is one - make sure it matches
1408       # the columns compiled above perfectly. Anything else can not be sanely executed
1409       # on most databases so croak right then and there
1410
1411       if (my $g = $attrs->{group_by}) {
1412         my @current_group_by = map
1413           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1414           (ref $g eq 'ARRAY' ? @$g : $g );
1415
1416         if (
1417           join ("\x00", sort @current_group_by)
1418             ne
1419           join ("\x00", sort @{$attrs->{columns}} )
1420         ) {
1421           $self->throw_exception (
1422             "You have just attempted a $op operation on a resultset which does group_by"
1423             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1424             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1425             . ' kind of queries. Please retry the operation with a modified group_by or'
1426             . ' without using one at all.'
1427           );
1428         }
1429       }
1430       else {
1431         $attrs->{group_by} = $attrs->{columns};
1432       }
1433     }
1434
1435     my $subrs = (ref $self)->new($rsrc, $attrs);
1436
1437     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1438   }
1439   else {
1440     return $rsrc->storage->$op(
1441       $rsrc,
1442       $op eq 'update' ? $values : (),
1443       $self->_cond_for_update_delete,
1444     );
1445   }
1446 }
1447
1448
1449 # _cond_for_update_delete
1450 #
1451 # update/delete require the condition to be modified to handle
1452 # the differing SQL syntax available.  This transforms the $self->{cond}
1453 # appropriately, returning the new condition.
1454
1455 sub _cond_for_update_delete {
1456   my ($self, $full_cond) = @_;
1457   my $cond = {};
1458
1459   $full_cond ||= $self->{cond};
1460   # No-op. No condition, we're updating/deleting everything
1461   return $cond unless ref $full_cond;
1462
1463   if (ref $full_cond eq 'ARRAY') {
1464     $cond = [
1465       map {
1466         my %hash;
1467         foreach my $key (keys %{$_}) {
1468           $key =~ /([^.]+)$/;
1469           $hash{$1} = $_->{$key};
1470         }
1471         \%hash;
1472       } @{$full_cond}
1473     ];
1474   }
1475   elsif (ref $full_cond eq 'HASH') {
1476     if ((keys %{$full_cond})[0] eq '-and') {
1477       $cond->{-and} = [];
1478       my @cond = @{$full_cond->{-and}};
1479        for (my $i = 0; $i < @cond; $i++) {
1480         my $entry = $cond[$i];
1481         my $hash;
1482         if (ref $entry eq 'HASH') {
1483           $hash = $self->_cond_for_update_delete($entry);
1484         }
1485         else {
1486           $entry =~ /([^.]+)$/;
1487           $hash->{$1} = $cond[++$i];
1488         }
1489         push @{$cond->{-and}}, $hash;
1490       }
1491     }
1492     else {
1493       foreach my $key (keys %{$full_cond}) {
1494         $key =~ /([^.]+)$/;
1495         $cond->{$1} = $full_cond->{$key};
1496       }
1497     }
1498   }
1499   else {
1500     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1501   }
1502
1503   return $cond;
1504 }
1505
1506
1507 =head2 update
1508
1509 =over 4
1510
1511 =item Arguments: \%values
1512
1513 =item Return Value: $storage_rv
1514
1515 =back
1516
1517 Sets the specified columns in the resultset to the supplied values in a
1518 single query. Return value will be true if the update succeeded or false
1519 if no records were updated; exact type of success value is storage-dependent.
1520
1521 =cut
1522
1523 sub update {
1524   my ($self, $values) = @_;
1525   $self->throw_exception('Values for update must be a hash')
1526     unless ref $values eq 'HASH';
1527
1528   return $self->_rs_update_delete ('update', $values);
1529 }
1530
1531 =head2 update_all
1532
1533 =over 4
1534
1535 =item Arguments: \%values
1536
1537 =item Return Value: 1
1538
1539 =back
1540
1541 Fetches all objects and updates them one at a time. Note that C<update_all>
1542 will run DBIC cascade triggers, while L</update> will not.
1543
1544 =cut
1545
1546 sub update_all {
1547   my ($self, $values) = @_;
1548   $self->throw_exception('Values for update_all must be a hash')
1549     unless ref $values eq 'HASH';
1550   foreach my $obj ($self->all) {
1551     $obj->set_columns($values)->update;
1552   }
1553   return 1;
1554 }
1555
1556 =head2 delete
1557
1558 =over 4
1559
1560 =item Arguments: none
1561
1562 =item Return Value: $storage_rv
1563
1564 =back
1565
1566 Deletes the contents of the resultset from its result source. Note that this
1567 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1568 to run. See also L<DBIx::Class::Row/delete>.
1569
1570 Return value will be the amount of rows deleted; exact type of return value
1571 is storage-dependent.
1572
1573 =cut
1574
1575 sub delete {
1576   my $self = shift;
1577   $self->throw_exception('delete does not accept any arguments')
1578     if @_;
1579
1580   return $self->_rs_update_delete ('delete');
1581 }
1582
1583 =head2 delete_all
1584
1585 =over 4
1586
1587 =item Arguments: none
1588
1589 =item Return Value: 1
1590
1591 =back
1592
1593 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1594 will run DBIC cascade triggers, while L</delete> will not.
1595
1596 =cut
1597
1598 sub delete_all {
1599   my $self = shift;
1600   $self->throw_exception('delete_all does not accept any arguments')
1601     if @_;
1602
1603   $_->delete for $self->all;
1604   return 1;
1605 }
1606
1607 =head2 populate
1608
1609 =over 4
1610
1611 =item Arguments: \@data;
1612
1613 =back
1614
1615 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1616 For the arrayref of hashrefs style each hashref should be a structure suitable
1617 forsubmitting to a $resultset->create(...) method.
1618
1619 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1620 to insert the data, as this is a faster method.
1621
1622 Otherwise, each set of data is inserted into the database using
1623 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1624 accumulated into an array. The array itself, or an array reference
1625 is returned depending on scalar or list context.
1626
1627 Example:  Assuming an Artist Class that has many CDs Classes relating:
1628
1629   my $Artist_rs = $schema->resultset("Artist");
1630
1631   ## Void Context Example
1632   $Artist_rs->populate([
1633      { artistid => 4, name => 'Manufactured Crap', cds => [
1634         { title => 'My First CD', year => 2006 },
1635         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1636       ],
1637      },
1638      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1639         { title => 'My parents sold me to a record company' ,year => 2005 },
1640         { title => 'Why Am I So Ugly?', year => 2006 },
1641         { title => 'I Got Surgery and am now Popular', year => 2007 }
1642       ],
1643      },
1644   ]);
1645
1646   ## Array Context Example
1647   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1648     { name => "Artist One"},
1649     { name => "Artist Two"},
1650     { name => "Artist Three", cds=> [
1651     { title => "First CD", year => 2007},
1652     { title => "Second CD", year => 2008},
1653   ]}
1654   ]);
1655
1656   print $ArtistOne->name; ## response is 'Artist One'
1657   print $ArtistThree->cds->count ## reponse is '2'
1658
1659 For the arrayref of arrayrefs style,  the first element should be a list of the
1660 fieldsnames to which the remaining elements are rows being inserted.  For
1661 example:
1662
1663   $Arstist_rs->populate([
1664     [qw/artistid name/],
1665     [100, 'A Formally Unknown Singer'],
1666     [101, 'A singer that jumped the shark two albums ago'],
1667     [102, 'An actually cool singer.'],
1668   ]);
1669
1670 Please note an important effect on your data when choosing between void and
1671 wantarray context. Since void context goes straight to C<insert_bulk> in
1672 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1673 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1674 create primary keys for you, you will find that your PKs are empty.  In this
1675 case you will have to use the wantarray context in order to create those
1676 values.
1677
1678 =cut
1679
1680 sub populate {
1681   my $self = shift @_;
1682   my $data = ref $_[0][0] eq 'HASH'
1683     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1684     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1685
1686   if(defined wantarray) {
1687     my @created;
1688     foreach my $item (@$data) {
1689       push(@created, $self->create($item));
1690     }
1691     return wantarray ? @created : \@created;
1692   } else {
1693     my ($first, @rest) = @$data;
1694
1695     my @names = grep {!ref $first->{$_}} keys %$first;
1696     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1697     my @pks = $self->result_source->primary_columns;
1698
1699     ## do the belongs_to relationships
1700     foreach my $index (0..$#$data) {
1701
1702       # delegate to create() for any dataset without primary keys with specified relationships
1703       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1704         for my $r (@rels) {
1705           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1706             my @ret = $self->populate($data);
1707             return;
1708           }
1709         }
1710       }
1711
1712       foreach my $rel (@rels) {
1713         next unless ref $data->[$index]->{$rel} eq "HASH";
1714         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1715         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1716         my $related = $result->result_source->_resolve_condition(
1717           $result->result_source->relationship_info($reverse)->{cond},
1718           $self,
1719           $result,
1720         );
1721
1722         delete $data->[$index]->{$rel};
1723         $data->[$index] = {%{$data->[$index]}, %$related};
1724
1725         push @names, keys %$related if $index == 0;
1726       }
1727     }
1728
1729     ## do bulk insert on current row
1730     my @values = map { [ @$_{@names} ] } @$data;
1731
1732     $self->result_source->storage->insert_bulk(
1733       $self->result_source,
1734       \@names,
1735       \@values,
1736     );
1737
1738     ## do the has_many relationships
1739     foreach my $item (@$data) {
1740
1741       foreach my $rel (@rels) {
1742         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1743
1744         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1745      || $self->throw_exception('Cannot find the relating object.');
1746
1747         my $child = $parent->$rel;
1748
1749         my $related = $child->result_source->_resolve_condition(
1750           $parent->result_source->relationship_info($rel)->{cond},
1751           $child,
1752           $parent,
1753         );
1754
1755         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1756         my @populate = map { {%$_, %$related} } @rows_to_add;
1757
1758         $child->populate( \@populate );
1759       }
1760     }
1761   }
1762 }
1763
1764 =head2 _normalize_populate_args ($args)
1765
1766 Private method used by L</populate> to normalize its incoming arguments.  Factored
1767 out in case you want to subclass and accept new argument structures to the
1768 L</populate> method.
1769
1770 =cut
1771
1772 sub _normalize_populate_args {
1773   my ($self, $data) = @_;
1774   my @names = @{shift(@$data)};
1775   my @results_to_create;
1776   foreach my $datum (@$data) {
1777     my %result_to_create;
1778     foreach my $index (0..$#names) {
1779       $result_to_create{$names[$index]} = $$datum[$index];
1780     }
1781     push @results_to_create, \%result_to_create;
1782   }
1783   return \@results_to_create;
1784 }
1785
1786 =head2 pager
1787
1788 =over 4
1789
1790 =item Arguments: none
1791
1792 =item Return Value: $pager
1793
1794 =back
1795
1796 Return Value a L<Data::Page> object for the current resultset. Only makes
1797 sense for queries with a C<page> attribute.
1798
1799 To get the full count of entries for a paged resultset, call
1800 C<total_entries> on the L<Data::Page> object.
1801
1802 =cut
1803
1804 sub pager {
1805   my ($self) = @_;
1806
1807   return $self->{pager} if $self->{pager};
1808
1809   my $attrs = $self->{attrs};
1810   $self->throw_exception("Can't create pager for non-paged rs")
1811     unless $self->{attrs}{page};
1812   $attrs->{rows} ||= 10;
1813
1814   # throw away the paging flags and re-run the count (possibly
1815   # with a subselect) to get the real total count
1816   my $count_attrs = { %$attrs };
1817   delete $count_attrs->{$_} for qw/rows offset page pager/;
1818   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1819
1820   return $self->{pager} = Data::Page->new(
1821     $total_count,
1822     $attrs->{rows},
1823     $self->{attrs}{page}
1824   );
1825 }
1826
1827 =head2 page
1828
1829 =over 4
1830
1831 =item Arguments: $page_number
1832
1833 =item Return Value: $rs
1834
1835 =back
1836
1837 Returns a resultset for the $page_number page of the resultset on which page
1838 is called, where each page contains a number of rows equal to the 'rows'
1839 attribute set on the resultset (10 by default).
1840
1841 =cut
1842
1843 sub page {
1844   my ($self, $page) = @_;
1845   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1846 }
1847
1848 =head2 new_result
1849
1850 =over 4
1851
1852 =item Arguments: \%vals
1853
1854 =item Return Value: $rowobject
1855
1856 =back
1857
1858 Creates a new row object in the resultset's result class and returns
1859 it. The row is not inserted into the database at this point, call
1860 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1861 will tell you whether the row object has been inserted or not.
1862
1863 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1864
1865 =cut
1866
1867 sub new_result {
1868   my ($self, $values) = @_;
1869   $self->throw_exception( "new_result needs a hash" )
1870     unless (ref $values eq 'HASH');
1871
1872   my %new;
1873   my $alias = $self->{attrs}{alias};
1874
1875   if (
1876     defined $self->{cond}
1877     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1878   ) {
1879     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1880     $new{-from_resultset} = [ keys %new ] if keys %new;
1881   } else {
1882     $self->throw_exception(
1883       "Can't abstract implicit construct, condition not a hash"
1884     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1885
1886     my $collapsed_cond = (
1887       $self->{cond}
1888         ? $self->_collapse_cond($self->{cond})
1889         : {}
1890     );
1891
1892     # precendence must be given to passed values over values inherited from
1893     # the cond, so the order here is important.
1894     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1895     while( my($col,$value) = each %implied ){
1896       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1897         $new{$col} = $value->{'='};
1898         next;
1899       }
1900       $new{$col} = $value if $self->_is_deterministic_value($value);
1901     }
1902   }
1903
1904   %new = (
1905     %new,
1906     %{ $self->_remove_alias($values, $alias) },
1907     -source_handle => $self->_source_handle,
1908     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1909   );
1910
1911   return $self->result_class->new(\%new);
1912 }
1913
1914 # _is_deterministic_value
1915 #
1916 # Make an effor to strip non-deterministic values from the condition,
1917 # to make sure new_result chokes less
1918
1919 sub _is_deterministic_value {
1920   my $self = shift;
1921   my $value = shift;
1922   my $ref_type = ref $value;
1923   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1924   return 1 if Scalar::Util::blessed($value);
1925   return 0;
1926 }
1927
1928 # _has_resolved_attr
1929 #
1930 # determines if the resultset defines at least one
1931 # of the attributes supplied
1932 #
1933 # used to determine if a subquery is neccessary
1934
1935 sub _has_resolved_attr {
1936   my ($self, @attr_names) = @_;
1937
1938   my $attrs = $self->_resolved_attrs;
1939
1940   my $join_check_req;
1941
1942   for my $n (@attr_names) {
1943     ++$join_check_req if $n eq '-join';
1944
1945     my $attr =  $attrs->{$n};
1946
1947     next if not defined $attr;
1948
1949     if (ref $attr eq 'HASH') {
1950       return 1 if keys %$attr;
1951     }
1952     elsif (ref $attr eq 'ARRAY') {
1953       return 1 if @$attr;
1954     }
1955     else {
1956       return 1 if $attr;
1957     }
1958   }
1959
1960   # a resolved join is expressed as a multi-level from
1961   return 1 if (
1962     $join_check_req
1963       and
1964     ref $attrs->{from} eq 'ARRAY'
1965       and
1966     @{$attrs->{from}} > 1
1967   );
1968
1969   return 0;
1970 }
1971
1972 # _collapse_cond
1973 #
1974 # Recursively collapse the condition.
1975
1976 sub _collapse_cond {
1977   my ($self, $cond, $collapsed) = @_;
1978
1979   $collapsed ||= {};
1980
1981   if (ref $cond eq 'ARRAY') {
1982     foreach my $subcond (@$cond) {
1983       next unless ref $subcond;  # -or
1984       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1985     }
1986   }
1987   elsif (ref $cond eq 'HASH') {
1988     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1989       foreach my $subcond (@{$cond->{-and}}) {
1990         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1991       }
1992     }
1993     else {
1994       foreach my $col (keys %$cond) {
1995         my $value = $cond->{$col};
1996         $collapsed->{$col} = $value;
1997       }
1998     }
1999   }
2000
2001   return $collapsed;
2002 }
2003
2004 # _remove_alias
2005 #
2006 # Remove the specified alias from the specified query hash. A copy is made so
2007 # the original query is not modified.
2008
2009 sub _remove_alias {
2010   my ($self, $query, $alias) = @_;
2011
2012   my %orig = %{ $query || {} };
2013   my %unaliased;
2014
2015   foreach my $key (keys %orig) {
2016     if ($key !~ /\./) {
2017       $unaliased{$key} = $orig{$key};
2018       next;
2019     }
2020     $unaliased{$1} = $orig{$key}
2021       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2022   }
2023
2024   return \%unaliased;
2025 }
2026
2027 =head2 as_query (EXPERIMENTAL)
2028
2029 =over 4
2030
2031 =item Arguments: none
2032
2033 =item Return Value: \[ $sql, @bind ]
2034
2035 =back
2036
2037 Returns the SQL query and bind vars associated with the invocant.
2038
2039 This is generally used as the RHS for a subquery.
2040
2041 B<NOTE>: This feature is still experimental.
2042
2043 =cut
2044
2045 sub as_query {
2046   my $self = shift;
2047
2048   my $attrs = $self->_resolved_attrs_copy;
2049
2050   # For future use:
2051   #
2052   # in list ctx:
2053   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2054   # $sql also has no wrapping parenthesis in list ctx
2055   #
2056   my $sqlbind = $self->result_source->storage
2057     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2058
2059   return $sqlbind;
2060 }
2061
2062 =head2 find_or_new
2063
2064 =over 4
2065
2066 =item Arguments: \%vals, \%attrs?
2067
2068 =item Return Value: $rowobject
2069
2070 =back
2071
2072   my $artist = $schema->resultset('Artist')->find_or_new(
2073     { artist => 'fred' }, { key => 'artists' });
2074
2075   $cd->cd_to_producer->find_or_new({ producer => $producer },
2076                                    { key => 'primary });
2077
2078 Find an existing record from this resultset, based on its primary
2079 key, or a unique constraint. If none exists, instantiate a new result
2080 object and return it. The object will not be saved into your storage
2081 until you call L<DBIx::Class::Row/insert> on it.
2082
2083 You most likely want this method when looking for existing rows using
2084 a unique constraint that is not the primary key, or looking for
2085 related rows.
2086
2087 If you want objects to be saved immediately, use L</find_or_create> instead.
2088
2089 B<Note>: C<find_or_new> is probably not what you want when creating a
2090 new row in a table that uses primary keys supplied by the
2091 database. Passing in a primary key column with a value of I<undef>
2092 will cause L</find> to attempt to search for a row with a value of
2093 I<NULL>.
2094
2095 =cut
2096
2097 sub find_or_new {
2098   my $self     = shift;
2099   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2100   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2101   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2102     return $row;
2103   }
2104   return $self->new_result($hash);
2105 }
2106
2107 =head2 create
2108
2109 =over 4
2110
2111 =item Arguments: \%vals
2112
2113 =item Return Value: a L<DBIx::Class::Row> $object
2114
2115 =back
2116
2117 Attempt to create a single new row or a row with multiple related rows
2118 in the table represented by the resultset (and related tables). This
2119 will not check for duplicate rows before inserting, use
2120 L</find_or_create> to do that.
2121
2122 To create one row for this resultset, pass a hashref of key/value
2123 pairs representing the columns of the table and the values you wish to
2124 store. If the appropriate relationships are set up, foreign key fields
2125 can also be passed an object representing the foreign row, and the
2126 value will be set to its primary key.
2127
2128 To create related objects, pass a hashref for the value if the related
2129 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2130 and use the name of the relationship as the key. (NOT the name of the field,
2131 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2132 of hashrefs containing the data for each of the rows to create in the foreign
2133 tables, again using the relationship name as the key.
2134
2135 Instead of hashrefs of plain related data (key/value pairs), you may
2136 also pass new or inserted objects. New objects (not inserted yet, see
2137 L</new>), will be inserted into their appropriate tables.
2138
2139 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2140
2141 Example of creating a new row.
2142
2143   $person_rs->create({
2144     name=>"Some Person",
2145     email=>"somebody@someplace.com"
2146   });
2147
2148 Example of creating a new row and also creating rows in a related C<has_many>
2149 or C<has_one> resultset.  Note Arrayref.
2150
2151   $artist_rs->create(
2152      { artistid => 4, name => 'Manufactured Crap', cds => [
2153         { title => 'My First CD', year => 2006 },
2154         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2155       ],
2156      },
2157   );
2158
2159 Example of creating a new row and also creating a row in a related
2160 C<belongs_to>resultset. Note Hashref.
2161
2162   $cd_rs->create({
2163     title=>"Music for Silly Walks",
2164     year=>2000,
2165     artist => {
2166       name=>"Silly Musician",
2167     }
2168   });
2169
2170 =cut
2171
2172 sub create {
2173   my ($self, $attrs) = @_;
2174   $self->throw_exception( "create needs a hashref" )
2175     unless ref $attrs eq 'HASH';
2176   return $self->new_result($attrs)->insert;
2177 }
2178
2179 =head2 find_or_create
2180
2181 =over 4
2182
2183 =item Arguments: \%vals, \%attrs?
2184
2185 =item Return Value: $rowobject
2186
2187 =back
2188
2189   $cd->cd_to_producer->find_or_create({ producer => $producer },
2190                                       { key => 'primary' });
2191
2192 Tries to find a record based on its primary key or unique constraints; if none
2193 is found, creates one and returns that instead.
2194
2195   my $cd = $schema->resultset('CD')->find_or_create({
2196     cdid   => 5,
2197     artist => 'Massive Attack',
2198     title  => 'Mezzanine',
2199     year   => 2005,
2200   });
2201
2202 Also takes an optional C<key> attribute, to search by a specific key or unique
2203 constraint. For example:
2204
2205   my $cd = $schema->resultset('CD')->find_or_create(
2206     {
2207       artist => 'Massive Attack',
2208       title  => 'Mezzanine',
2209     },
2210     { key => 'cd_artist_title' }
2211   );
2212
2213 B<Note>: Because find_or_create() reads from the database and then
2214 possibly inserts based on the result, this method is subject to a race
2215 condition. Another process could create a record in the table after
2216 the find has completed and before the create has started. To avoid
2217 this problem, use find_or_create() inside a transaction.
2218
2219 B<Note>: C<find_or_create> is probably not what you want when creating
2220 a new row in a table that uses primary keys supplied by the
2221 database. Passing in a primary key column with a value of I<undef>
2222 will cause L</find> to attempt to search for a row with a value of
2223 I<NULL>.
2224
2225 See also L</find> and L</update_or_create>. For information on how to declare
2226 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2227
2228 =cut
2229
2230 sub find_or_create {
2231   my $self     = shift;
2232   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2233   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2234   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2235     return $row;
2236   }
2237   return $self->create($hash);
2238 }
2239
2240 =head2 update_or_create
2241
2242 =over 4
2243
2244 =item Arguments: \%col_values, { key => $unique_constraint }?
2245
2246 =item Return Value: $rowobject
2247
2248 =back
2249
2250   $resultset->update_or_create({ col => $val, ... });
2251
2252 First, searches for an existing row matching one of the unique constraints
2253 (including the primary key) on the source of this resultset. If a row is
2254 found, updates it with the other given column values. Otherwise, creates a new
2255 row.
2256
2257 Takes an optional C<key> attribute to search on a specific unique constraint.
2258 For example:
2259
2260   # In your application
2261   my $cd = $schema->resultset('CD')->update_or_create(
2262     {
2263       artist => 'Massive Attack',
2264       title  => 'Mezzanine',
2265       year   => 1998,
2266     },
2267     { key => 'cd_artist_title' }
2268   );
2269
2270   $cd->cd_to_producer->update_or_create({
2271     producer => $producer,
2272     name => 'harry',
2273   }, {
2274     key => 'primary,
2275   });
2276
2277
2278 If no C<key> is specified, it searches on all unique constraints defined on the
2279 source, including the primary key.
2280
2281 If the C<key> is specified as C<primary>, it searches only on the primary key.
2282
2283 See also L</find> and L</find_or_create>. For information on how to declare
2284 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2285
2286 B<Note>: C<update_or_create> is probably not what you want when
2287 looking for a row in a table that uses primary keys supplied by the
2288 database, unless you actually have a key value. Passing in a primary
2289 key column with a value of I<undef> will cause L</find> to attempt to
2290 search for a row with a value of I<NULL>.
2291
2292 =cut
2293
2294 sub update_or_create {
2295   my $self = shift;
2296   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2297   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2298
2299   my $row = $self->find($cond, $attrs);
2300   if (defined $row) {
2301     $row->update($cond);
2302     return $row;
2303   }
2304
2305   return $self->create($cond);
2306 }
2307
2308 =head2 update_or_new
2309
2310 =over 4
2311
2312 =item Arguments: \%col_values, { key => $unique_constraint }?
2313
2314 =item Return Value: $rowobject
2315
2316 =back
2317
2318   $resultset->update_or_new({ col => $val, ... });
2319
2320 First, searches for an existing row matching one of the unique constraints
2321 (including the primary key) on the source of this resultset. If a row is
2322 found, updates it with the other given column values. Otherwise, instantiate
2323 a new result object and return it. The object will not be saved into your storage
2324 until you call L<DBIx::Class::Row/insert> on it.
2325
2326 Takes an optional C<key> attribute to search on a specific unique constraint.
2327 For example:
2328
2329   # In your application
2330   my $cd = $schema->resultset('CD')->update_or_new(
2331     {
2332       artist => 'Massive Attack',
2333       title  => 'Mezzanine',
2334       year   => 1998,
2335     },
2336     { key => 'cd_artist_title' }
2337   );
2338
2339   if ($cd->in_storage) {
2340       # the cd was updated
2341   }
2342   else {
2343       # the cd is not yet in the database, let's insert it
2344       $cd->insert;
2345   }
2346
2347 See also L</find>, L</find_or_create> and L<find_or_new>.
2348
2349 =cut
2350
2351 sub update_or_new {
2352     my $self  = shift;
2353     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2354     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2355
2356     my $row = $self->find( $cond, $attrs );
2357     if ( defined $row ) {
2358         $row->update($cond);
2359         return $row;
2360     }
2361
2362     return $self->new_result($cond);
2363 }
2364
2365 =head2 get_cache
2366
2367 =over 4
2368
2369 =item Arguments: none
2370
2371 =item Return Value: \@cache_objects?
2372
2373 =back
2374
2375 Gets the contents of the cache for the resultset, if the cache is set.
2376
2377 The cache is populated either by using the L</prefetch> attribute to
2378 L</search> or by calling L</set_cache>.
2379
2380 =cut
2381
2382 sub get_cache {
2383   shift->{all_cache};
2384 }
2385
2386 =head2 set_cache
2387
2388 =over 4
2389
2390 =item Arguments: \@cache_objects
2391
2392 =item Return Value: \@cache_objects
2393
2394 =back
2395
2396 Sets the contents of the cache for the resultset. Expects an arrayref
2397 of objects of the same class as those produced by the resultset. Note that
2398 if the cache is set the resultset will return the cached objects rather
2399 than re-querying the database even if the cache attr is not set.
2400
2401 The contents of the cache can also be populated by using the
2402 L</prefetch> attribute to L</search>.
2403
2404 =cut
2405
2406 sub set_cache {
2407   my ( $self, $data ) = @_;
2408   $self->throw_exception("set_cache requires an arrayref")
2409       if defined($data) && (ref $data ne 'ARRAY');
2410   $self->{all_cache} = $data;
2411 }
2412
2413 =head2 clear_cache
2414
2415 =over 4
2416
2417 =item Arguments: none
2418
2419 =item Return Value: []
2420
2421 =back
2422
2423 Clears the cache for the resultset.
2424
2425 =cut
2426
2427 sub clear_cache {
2428   shift->set_cache(undef);
2429 }
2430
2431 =head2 related_resultset
2432
2433 =over 4
2434
2435 =item Arguments: $relationship_name
2436
2437 =item Return Value: $resultset
2438
2439 =back
2440
2441 Returns a related resultset for the supplied relationship name.
2442
2443   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2444
2445 =cut
2446
2447 sub related_resultset {
2448   my ($self, $rel) = @_;
2449
2450   $self->{related_resultsets} ||= {};
2451   return $self->{related_resultsets}{$rel} ||= do {
2452     my $rel_info = $self->result_source->relationship_info($rel);
2453
2454     $self->throw_exception(
2455       "search_related: result source '" . $self->result_source->source_name .
2456         "' has no such relationship $rel")
2457       unless $rel_info;
2458
2459     my ($from,$seen) = $self->_resolve_from($rel);
2460
2461     my $join_count = $seen->{$rel};
2462     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2463
2464     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2465     my %attrs = %{$self->{attrs}||{}};
2466     delete @attrs{qw(result_class alias)};
2467
2468     my $new_cache;
2469
2470     if (my $cache = $self->get_cache) {
2471       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2472         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2473                         @$cache ];
2474       }
2475     }
2476
2477     my $rel_source = $self->result_source->related_source($rel);
2478
2479     my $new = do {
2480
2481       # The reason we do this now instead of passing the alias to the
2482       # search_rs below is that if you wrap/overload resultset on the
2483       # source you need to know what alias it's -going- to have for things
2484       # to work sanely (e.g. RestrictWithObject wants to be able to add
2485       # extra query restrictions, and these may need to be $alias.)
2486
2487       my $attrs = $rel_source->resultset_attributes;
2488       local $attrs->{alias} = $alias;
2489
2490       $rel_source->resultset
2491                  ->search_rs(
2492                      undef, {
2493                        %attrs,
2494                        join => undef,
2495                        prefetch => undef,
2496                        select => undef,
2497                        as => undef,
2498                        where => $self->{cond},
2499                        seen_join => $seen,
2500                        from => $from,
2501                    });
2502     };
2503     $new->set_cache($new_cache) if $new_cache;
2504     $new;
2505   };
2506 }
2507
2508 =head2 current_source_alias
2509
2510 =over 4
2511
2512 =item Arguments: none
2513
2514 =item Return Value: $source_alias
2515
2516 =back
2517
2518 Returns the current table alias for the result source this resultset is built
2519 on, that will be used in the SQL query. Usually it is C<me>.
2520
2521 Currently the source alias that refers to the result set returned by a
2522 L</search>/L</find> family method depends on how you got to the resultset: it's
2523 C<me> by default, but eg. L</search_related> aliases it to the related result
2524 source name (and keeps C<me> referring to the original result set). The long
2525 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2526 (and make this method unnecessary).
2527
2528 Thus it's currently necessary to use this method in predefined queries (see
2529 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2530 source alias of the current result set:
2531
2532   # in a result set class
2533   sub modified_by {
2534     my ($self, $user) = @_;
2535
2536     my $me = $self->current_source_alias;
2537
2538     return $self->search(
2539       "$me.modified" => $user->id,
2540     );
2541   }
2542
2543 =cut
2544
2545 sub current_source_alias {
2546   my ($self) = @_;
2547
2548   return ($self->{attrs} || {})->{alias} || 'me';
2549 }
2550
2551 # This code is called by search_related, and makes sure there
2552 # is clear separation between the joins before, during, and
2553 # after the relationship. This information is needed later
2554 # in order to properly resolve prefetch aliases (any alias
2555 # with a relation_chain_depth less than the depth of the
2556 # current prefetch is not considered)
2557 sub _resolve_from {
2558   my ($self, $rel) = @_;
2559   my $source = $self->result_source;
2560   my $attrs = $self->{attrs};
2561
2562   my $from = [ @{
2563       $attrs->{from}
2564         ||
2565       [{
2566         -source_handle => $source->handle,
2567         -alias => $attrs->{alias},
2568         $attrs->{alias} => $source->from,
2569       }]
2570   }];
2571
2572   my $seen = { %{$attrs->{seen_join} || {} } };
2573
2574   # we need to take the prefetch the attrs into account before we
2575   # ->_resolve_join as otherwise they get lost - captainL
2576   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2577
2578   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2579
2580   ++$seen->{-relation_chain_depth};
2581
2582   push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2583
2584   ++$seen->{-relation_chain_depth};
2585
2586   return ($from,$seen);
2587 }
2588
2589 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2590 sub _resolved_attrs_copy {
2591   my $self = shift;
2592   return { %{$self->_resolved_attrs (@_)} };
2593 }
2594
2595 sub _resolved_attrs {
2596   my $self = shift;
2597   return $self->{_attrs} if $self->{_attrs};
2598
2599   my $attrs  = { %{ $self->{attrs} || {} } };
2600   my $source = $self->result_source;
2601   my $alias  = $attrs->{alias};
2602
2603   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2604   my @colbits;
2605
2606   # build columns (as long as select isn't set) into a set of as/select hashes
2607   unless ( $attrs->{select} ) {
2608       @colbits = map {
2609           ( ref($_) eq 'HASH' )
2610               ? $_
2611               : {
2612                   (
2613                     /^\Q${alias}.\E(.+)$/
2614                       ? "$1"
2615                       : "$_"
2616                   )
2617                 =>
2618                   (
2619                     /\./
2620                       ? "$_"
2621                       : "${alias}.$_"
2622                   )
2623             }
2624       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2625   }
2626   # add the additional columns on
2627   foreach ( 'include_columns', '+columns' ) {
2628       push @colbits, map {
2629           ( ref($_) eq 'HASH' )
2630             ? $_
2631             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2632       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2633   }
2634
2635   # start with initial select items
2636   if ( $attrs->{select} ) {
2637     $attrs->{select} =
2638         ( ref $attrs->{select} eq 'ARRAY' )
2639       ? [ @{ $attrs->{select} } ]
2640       : [ $attrs->{select} ];
2641     $attrs->{as} = (
2642       $attrs->{as}
2643       ? (
2644         ref $attrs->{as} eq 'ARRAY'
2645         ? [ @{ $attrs->{as} } ]
2646         : [ $attrs->{as} ]
2647         )
2648       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2649     );
2650   }
2651   else {
2652
2653     # otherwise we intialise select & as to empty
2654     $attrs->{select} = [];
2655     $attrs->{as}     = [];
2656   }
2657
2658   # now add colbits to select/as
2659   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2660   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2661
2662   my $adds;
2663   if ( $adds = delete $attrs->{'+select'} ) {
2664     $adds = [$adds] unless ref $adds eq 'ARRAY';
2665     push(
2666       @{ $attrs->{select} },
2667       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2668     );
2669   }
2670   if ( $adds = delete $attrs->{'+as'} ) {
2671     $adds = [$adds] unless ref $adds eq 'ARRAY';
2672     push( @{ $attrs->{as} }, @$adds );
2673   }
2674
2675   $attrs->{from} ||= [ {
2676     -source_handle => $source->handle,
2677     -alias => $self->{attrs}{alias},
2678     $self->{attrs}{alias} => $source->from,
2679   } ];
2680
2681   if ( $attrs->{join} || $attrs->{prefetch} ) {
2682
2683     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2684       if ref $attrs->{from} ne 'ARRAY';
2685
2686     my $join = delete $attrs->{join} || {};
2687
2688     if ( defined $attrs->{prefetch} ) {
2689       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2690     }
2691
2692     $attrs->{from} =    # have to copy here to avoid corrupting the original
2693       [
2694         @{ $attrs->{from} },
2695         $source->_resolve_join(
2696           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2697         )
2698       ];
2699   }
2700
2701   if ( $attrs->{order_by} ) {
2702     $attrs->{order_by} = (
2703       ref( $attrs->{order_by} ) eq 'ARRAY'
2704       ? [ @{ $attrs->{order_by} } ]
2705       : [ $attrs->{order_by} ]
2706     );
2707   }
2708   else {
2709     $attrs->{order_by} = [];
2710   }
2711
2712   # If the order_by is otherwise empty - we will use this for TOP limit
2713   # emulation and the like.
2714   # Although this is needed only if the order_by is not defined, it is
2715   # actually cheaper to just populate this rather than properly examining
2716   # order_by (stuf like [ {} ] and the like)
2717   my $prefix = $alias . ($source->schema->storage->sql_maker->{name_sep} || '.');
2718   $attrs->{_virtual_order_by} = [
2719     map { $prefix . $_ } ($source->primary_columns)
2720   ];
2721
2722   $attrs->{collapse} ||= {};
2723   if ( my $prefetch = delete $attrs->{prefetch} ) {
2724     $prefetch = $self->_merge_attr( {}, $prefetch );
2725
2726     my $prefetch_ordering = [];
2727
2728     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2729
2730     my @prefetch =
2731       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2732
2733     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2734     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2735
2736     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2737     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2738   }
2739
2740
2741   if (delete $attrs->{distinct}) {
2742     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2743   }
2744
2745   # if both page and offset are specified, produce a combined offset
2746   # even though it doesn't make much sense, this is what pre 081xx has
2747   # been doing
2748   if (my $page = delete $attrs->{page}) {
2749     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2750       ($attrs->{offset} || 0);
2751   }
2752
2753   return $self->{_attrs} = $attrs;
2754 }
2755
2756 sub _joinpath_aliases {
2757   my ($self, $fromspec, $seen) = @_;
2758
2759   my $paths = {};
2760   return $paths unless ref $fromspec eq 'ARRAY';
2761
2762   for my $j (@$fromspec) {
2763
2764     next if ref $j ne 'ARRAY';
2765     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2766
2767     my $p = $paths;
2768     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2769     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2770   }
2771
2772   return $paths;
2773 }
2774
2775 sub _rollout_attr {
2776   my ($self, $attr) = @_;
2777
2778   if (ref $attr eq 'HASH') {
2779     return $self->_rollout_hash($attr);
2780   } elsif (ref $attr eq 'ARRAY') {
2781     return $self->_rollout_array($attr);
2782   } else {
2783     return [$attr];
2784   }
2785 }
2786
2787 sub _rollout_array {
2788   my ($self, $attr) = @_;
2789
2790   my @rolled_array;
2791   foreach my $element (@{$attr}) {
2792     if (ref $element eq 'HASH') {
2793       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2794     } elsif (ref $element eq 'ARRAY') {
2795       #  XXX - should probably recurse here
2796       push( @rolled_array, @{$self->_rollout_array($element)} );
2797     } else {
2798       push( @rolled_array, $element );
2799     }
2800   }
2801   return \@rolled_array;
2802 }
2803
2804 sub _rollout_hash {
2805   my ($self, $attr) = @_;
2806
2807   my @rolled_array;
2808   foreach my $key (keys %{$attr}) {
2809     push( @rolled_array, { $key => $attr->{$key} } );
2810   }
2811   return \@rolled_array;
2812 }
2813
2814 sub _calculate_score {
2815   my ($self, $a, $b) = @_;
2816
2817   if (ref $b eq 'HASH') {
2818     my ($b_key) = keys %{$b};
2819     if (ref $a eq 'HASH') {
2820       my ($a_key) = keys %{$a};
2821       if ($a_key eq $b_key) {
2822         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2823       } else {
2824         return 0;
2825       }
2826     } else {
2827       return ($a eq $b_key) ? 1 : 0;
2828     }
2829   } else {
2830     if (ref $a eq 'HASH') {
2831       my ($a_key) = keys %{$a};
2832       return ($b eq $a_key) ? 1 : 0;
2833     } else {
2834       return ($b eq $a) ? 1 : 0;
2835     }
2836   }
2837 }
2838
2839 sub _merge_attr {
2840   my ($self, $orig, $import) = @_;
2841
2842   return $import unless defined($orig);
2843   return $orig unless defined($import);
2844
2845   $orig = $self->_rollout_attr($orig);
2846   $import = $self->_rollout_attr($import);
2847
2848   my $seen_keys;
2849   foreach my $import_element ( @{$import} ) {
2850     # find best candidate from $orig to merge $b_element into
2851     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2852     foreach my $orig_element ( @{$orig} ) {
2853       my $score = $self->_calculate_score( $orig_element, $import_element );
2854       if ($score > $best_candidate->{score}) {
2855         $best_candidate->{position} = $position;
2856         $best_candidate->{score} = $score;
2857       }
2858       $position++;
2859     }
2860     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2861
2862     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2863       push( @{$orig}, $import_element );
2864     } else {
2865       my $orig_best = $orig->[$best_candidate->{position}];
2866       # merge orig_best and b_element together and replace original with merged
2867       if (ref $orig_best ne 'HASH') {
2868         $orig->[$best_candidate->{position}] = $import_element;
2869       } elsif (ref $import_element eq 'HASH') {
2870         my ($key) = keys %{$orig_best};
2871         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2872       }
2873     }
2874     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2875   }
2876
2877   return $orig;
2878 }
2879
2880 sub result_source {
2881     my $self = shift;
2882
2883     if (@_) {
2884         $self->_source_handle($_[0]->handle);
2885     } else {
2886         $self->_source_handle->resolve;
2887     }
2888 }
2889
2890 =head2 throw_exception
2891
2892 See L<DBIx::Class::Schema/throw_exception> for details.
2893
2894 =cut
2895
2896 sub throw_exception {
2897   my $self=shift;
2898   if (ref $self && $self->_source_handle->schema) {
2899     $self->_source_handle->schema->throw_exception(@_)
2900   } else {
2901     croak(@_);
2902   }
2903
2904 }
2905
2906 # XXX: FIXME: Attributes docs need clearing up
2907
2908 =head1 ATTRIBUTES
2909
2910 Attributes are used to refine a ResultSet in various ways when
2911 searching for data. They can be passed to any method which takes an
2912 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2913 L</count>.
2914
2915 These are in no particular order:
2916
2917 =head2 order_by
2918
2919 =over 4
2920
2921 =item Value: ( $order_by | \@order_by | \%order_by )
2922
2923 =back
2924
2925 Which column(s) to order the results by. If a single column name, or
2926 an arrayref of names is supplied, the argument is passed through
2927 directly to SQL. The hashref syntax allows for connection-agnostic
2928 specification of ordering direction:
2929
2930  For descending order:
2931
2932   order_by => { -desc => [qw/col1 col2 col3/] }
2933
2934  For explicit ascending order:
2935
2936   order_by => { -asc => 'col' }
2937
2938 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2939 supported, although you are strongly encouraged to use the hashref
2940 syntax as outlined above.
2941
2942 =head2 columns
2943
2944 =over 4
2945
2946 =item Value: \@columns
2947
2948 =back
2949
2950 Shortcut to request a particular set of columns to be retrieved. Each
2951 column spec may be a string (a table column name), or a hash (in which
2952 case the key is the C<as> value, and the value is used as the C<select>
2953 expression). Adds C<me.> onto the start of any column without a C<.> in
2954 it and sets C<select> from that, then auto-populates C<as> from
2955 C<select> as normal. (You may also use the C<cols> attribute, as in
2956 earlier versions of DBIC.)
2957
2958 =head2 +columns
2959
2960 =over 4
2961
2962 =item Value: \@columns
2963
2964 =back
2965
2966 Indicates additional columns to be selected from storage. Works the same
2967 as L</columns> but adds columns to the selection. (You may also use the
2968 C<include_columns> attribute, as in earlier versions of DBIC). For
2969 example:-
2970
2971   $schema->resultset('CD')->search(undef, {
2972     '+columns' => ['artist.name'],
2973     join => ['artist']
2974   });
2975
2976 would return all CDs and include a 'name' column to the information
2977 passed to object inflation. Note that the 'artist' is the name of the
2978 column (or relationship) accessor, and 'name' is the name of the column
2979 accessor in the related table.
2980
2981 =head2 include_columns
2982
2983 =over 4
2984
2985 =item Value: \@columns
2986
2987 =back
2988
2989 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2990
2991 =head2 select
2992
2993 =over 4
2994
2995 =item Value: \@select_columns
2996
2997 =back
2998
2999 Indicates which columns should be selected from the storage. You can use
3000 column names, or in the case of RDBMS back ends, function or stored procedure
3001 names:
3002
3003   $rs = $schema->resultset('Employee')->search(undef, {
3004     select => [
3005       'name',
3006       { count => 'employeeid' },
3007       { sum => 'salary' }
3008     ]
3009   });
3010
3011 When you use function/stored procedure names and do not supply an C<as>
3012 attribute, the column names returned are storage-dependent. E.g. MySQL would
3013 return a column named C<count(employeeid)> in the above example.
3014
3015 =head2 +select
3016
3017 =over 4
3018
3019 Indicates additional columns to be selected from storage.  Works the same as
3020 L</select> but adds columns to the selection.
3021
3022 =back
3023
3024 =head2 +as
3025
3026 =over 4
3027
3028 Indicates additional column names for those added via L</+select>. See L</as>.
3029
3030 =back
3031
3032 =head2 as
3033
3034 =over 4
3035
3036 =item Value: \@inflation_names
3037
3038 =back
3039
3040 Indicates column names for object inflation. That is, C<as>
3041 indicates the name that the column can be accessed as via the
3042 C<get_column> method (or via the object accessor, B<if one already
3043 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3044
3045 The C<as> attribute is used in conjunction with C<select>,
3046 usually when C<select> contains one or more function or stored
3047 procedure names:
3048
3049   $rs = $schema->resultset('Employee')->search(undef, {
3050     select => [
3051       'name',
3052       { count => 'employeeid' }
3053     ],
3054     as => ['name', 'employee_count'],
3055   });
3056
3057   my $employee = $rs->first(); # get the first Employee
3058
3059 If the object against which the search is performed already has an accessor
3060 matching a column name specified in C<as>, the value can be retrieved using
3061 the accessor as normal:
3062
3063   my $name = $employee->name();
3064
3065 If on the other hand an accessor does not exist in the object, you need to
3066 use C<get_column> instead:
3067
3068   my $employee_count = $employee->get_column('employee_count');
3069
3070 You can create your own accessors if required - see
3071 L<DBIx::Class::Manual::Cookbook> for details.
3072
3073 Please note: This will NOT insert an C<AS employee_count> into the SQL
3074 statement produced, it is used for internal access only. Thus
3075 attempting to use the accessor in an C<order_by> clause or similar
3076 will fail miserably.
3077
3078 To get around this limitation, you can supply literal SQL to your
3079 C<select> attibute that contains the C<AS alias> text, eg:
3080
3081   select => [\'myfield AS alias']
3082
3083 =head2 join
3084
3085 =over 4
3086
3087 =item Value: ($rel_name | \@rel_names | \%rel_names)
3088
3089 =back
3090
3091 Contains a list of relationships that should be joined for this query.  For
3092 example:
3093
3094   # Get CDs by Nine Inch Nails
3095   my $rs = $schema->resultset('CD')->search(
3096     { 'artist.name' => 'Nine Inch Nails' },
3097     { join => 'artist' }
3098   );
3099
3100 Can also contain a hash reference to refer to the other relation's relations.
3101 For example:
3102
3103   package MyApp::Schema::Track;
3104   use base qw/DBIx::Class/;
3105   __PACKAGE__->table('track');
3106   __PACKAGE__->add_columns(qw/trackid cd position title/);
3107   __PACKAGE__->set_primary_key('trackid');
3108   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3109   1;
3110
3111   # In your application
3112   my $rs = $schema->resultset('Artist')->search(
3113     { 'track.title' => 'Teardrop' },
3114     {
3115       join     => { cd => 'track' },
3116       order_by => 'artist.name',
3117     }
3118   );
3119
3120 You need to use the relationship (not the table) name in  conditions,
3121 because they are aliased as such. The current table is aliased as "me", so
3122 you need to use me.column_name in order to avoid ambiguity. For example:
3123
3124   # Get CDs from 1984 with a 'Foo' track
3125   my $rs = $schema->resultset('CD')->search(
3126     {
3127       'me.year' => 1984,
3128       'tracks.name' => 'Foo'
3129     },
3130     { join => 'tracks' }
3131   );
3132
3133 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3134 similarly for a third time). For e.g.
3135
3136   my $rs = $schema->resultset('Artist')->search({
3137     'cds.title'   => 'Down to Earth',
3138     'cds_2.title' => 'Popular',
3139   }, {
3140     join => [ qw/cds cds/ ],
3141   });
3142
3143 will return a set of all artists that have both a cd with title 'Down
3144 to Earth' and a cd with title 'Popular'.
3145
3146 If you want to fetch related objects from other tables as well, see C<prefetch>
3147 below.
3148
3149 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3150
3151 =head2 prefetch
3152
3153 =over 4
3154
3155 =item Value: ($rel_name | \@rel_names | \%rel_names)
3156
3157 =back
3158
3159 Contains one or more relationships that should be fetched along with
3160 the main query (when they are accessed afterwards the data will
3161 already be available, without extra queries to the database).  This is
3162 useful for when you know you will need the related objects, because it
3163 saves at least one query:
3164
3165   my $rs = $schema->resultset('Tag')->search(
3166     undef,
3167     {
3168       prefetch => {
3169         cd => 'artist'
3170       }
3171     }
3172   );
3173
3174 The initial search results in SQL like the following:
3175
3176   SELECT tag.*, cd.*, artist.* FROM tag
3177   JOIN cd ON tag.cd = cd.cdid
3178   JOIN artist ON cd.artist = artist.artistid
3179
3180 L<DBIx::Class> has no need to go back to the database when we access the
3181 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3182 case.
3183
3184 Simple prefetches will be joined automatically, so there is no need
3185 for a C<join> attribute in the above search.
3186
3187 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3188 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3189 with an accessor type of 'single' or 'filter'). A more complex example that
3190 prefetches an artists cds, the tracks on those cds, and the tags associted
3191 with that artist is given below (assuming many-to-many from artists to tags):
3192
3193  my $rs = $schema->resultset('Artist')->search(
3194    undef,
3195    {
3196      prefetch => [
3197        { cds => 'tracks' },
3198        { artist_tags => 'tags' }
3199      ]
3200    }
3201  );
3202
3203
3204 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3205 attributes will be ignored.
3206
3207 =head2 page
3208
3209 =over 4
3210
3211 =item Value: $page
3212
3213 =back
3214
3215 Makes the resultset paged and specifies the page to retrieve. Effectively
3216 identical to creating a non-pages resultset and then calling ->page($page)
3217 on it.
3218
3219 If L<rows> attribute is not specified it defaults to 10 rows per page.
3220
3221 When you have a paged resultset, L</count> will only return the number
3222 of rows in the page. To get the total, use the L</pager> and call
3223 C<total_entries> on it.
3224
3225 =head2 rows
3226
3227 =over 4
3228
3229 =item Value: $rows
3230
3231 =back
3232
3233 Specifes the maximum number of rows for direct retrieval or the number of
3234 rows per page if the page attribute or method is used.
3235
3236 =head2 offset
3237
3238 =over 4
3239
3240 =item Value: $offset
3241
3242 =back
3243
3244 Specifies the (zero-based) row number for the  first row to be returned, or the
3245 of the first row of the first page if paging is used.
3246
3247 =head2 group_by
3248
3249 =over 4
3250
3251 =item Value: \@columns
3252
3253 =back
3254
3255 A arrayref of columns to group by. Can include columns of joined tables.
3256
3257   group_by => [qw/ column1 column2 ... /]
3258
3259 =head2 having
3260
3261 =over 4
3262
3263 =item Value: $condition
3264
3265 =back
3266
3267 HAVING is a select statement attribute that is applied between GROUP BY and
3268 ORDER BY. It is applied to the after the grouping calculations have been
3269 done.
3270
3271   having => { 'count(employee)' => { '>=', 100 } }
3272
3273 =head2 distinct
3274
3275 =over 4
3276
3277 =item Value: (0 | 1)
3278
3279 =back
3280
3281 Set to 1 to group by all columns.
3282
3283 =head2 where
3284
3285 =over 4
3286
3287 Adds to the WHERE clause.
3288
3289   # only return rows WHERE deleted IS NULL for all searches
3290   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3291
3292 Can be overridden by passing C<{ where => undef }> as an attribute
3293 to a resulset.
3294
3295 =back
3296
3297 =head2 cache
3298
3299 Set to 1 to cache search results. This prevents extra SQL queries if you
3300 revisit rows in your ResultSet:
3301
3302   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3303
3304   while( my $artist = $resultset->next ) {
3305     ... do stuff ...
3306   }
3307
3308   $rs->first; # without cache, this would issue a query
3309
3310 By default, searches are not cached.
3311
3312 For more examples of using these attributes, see
3313 L<DBIx::Class::Manual::Cookbook>.
3314
3315 =head2 from
3316
3317 =over 4
3318
3319 =item Value: \@from_clause
3320
3321 =back
3322
3323 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3324 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3325 clauses.
3326
3327 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3328
3329 C<join> will usually do what you need and it is strongly recommended that you
3330 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3331 And we really do mean "cannot", not just tried and failed. Attempting to use
3332 this because you're having problems with C<join> is like trying to use x86
3333 ASM because you've got a syntax error in your C. Trust us on this.
3334
3335 Now, if you're still really, really sure you need to use this (and if you're
3336 not 100% sure, ask the mailing list first), here's an explanation of how this
3337 works.
3338
3339 The syntax is as follows -
3340
3341   [
3342     { <alias1> => <table1> },
3343     [
3344       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3345       [], # nested JOIN (optional)
3346       { <table1.column1> => <table2.column2>, ... (more conditions) },
3347     ],
3348     # More of the above [ ] may follow for additional joins
3349   ]
3350
3351   <table1> <alias1>
3352   JOIN
3353     <table2> <alias2>
3354     [JOIN ...]
3355   ON <table1.column1> = <table2.column2>
3356   <more joins may follow>
3357
3358 An easy way to follow the examples below is to remember the following:
3359
3360     Anything inside "[]" is a JOIN
3361     Anything inside "{}" is a condition for the enclosing JOIN
3362
3363 The following examples utilize a "person" table in a family tree application.
3364 In order to express parent->child relationships, this table is self-joined:
3365
3366     # Person->belongs_to('father' => 'Person');
3367     # Person->belongs_to('mother' => 'Person');
3368
3369 C<from> can be used to nest joins. Here we return all children with a father,
3370 then search against all mothers of those children:
3371
3372   $rs = $schema->resultset('Person')->search(
3373       undef,
3374       {
3375           alias => 'mother', # alias columns in accordance with "from"
3376           from => [
3377               { mother => 'person' },
3378               [
3379                   [
3380                       { child => 'person' },
3381                       [
3382                           { father => 'person' },
3383                           { 'father.person_id' => 'child.father_id' }
3384                       ]
3385                   ],
3386                   { 'mother.person_id' => 'child.mother_id' }
3387               ],
3388           ]
3389       },
3390   );
3391
3392   # Equivalent SQL:
3393   # SELECT mother.* FROM person mother
3394   # JOIN (
3395   #   person child
3396   #   JOIN person father
3397   #   ON ( father.person_id = child.father_id )
3398   # )
3399   # ON ( mother.person_id = child.mother_id )
3400
3401 The type of any join can be controlled manually. To search against only people
3402 with a father in the person table, we could explicitly use C<INNER JOIN>:
3403
3404     $rs = $schema->resultset('Person')->search(
3405         undef,
3406         {
3407             alias => 'child', # alias columns in accordance with "from"
3408             from => [
3409                 { child => 'person' },
3410                 [
3411                     { father => 'person', -join_type => 'inner' },
3412                     { 'father.id' => 'child.father_id' }
3413                 ],
3414             ]
3415         },
3416     );
3417
3418     # Equivalent SQL:
3419     # SELECT child.* FROM person child
3420     # INNER JOIN person father ON child.father_id = father.id
3421
3422 You can select from a subquery by passing a resultset to from as follows.
3423
3424     $schema->resultset('Artist')->search(
3425         undef,
3426         {   alias => 'artist2',
3427             from  => [ { artist2 => $artist_rs->as_query } ],
3428         } );
3429
3430     # and you'll get sql like this..
3431     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3432     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3433
3434 If you need to express really complex joins, you
3435 can supply literal SQL to C<from> via a scalar reference. In this case
3436 the contents of the scalar will replace the table name associated with the
3437 resultsource.
3438
3439 WARNING: This technique might very well not work as expected on chained
3440 searches - you have been warned.
3441
3442     # Assuming the Event resultsource is defined as:
3443
3444         MySchema::Event->add_columns (
3445             sequence => {
3446                 data_type => 'INT',
3447                 is_auto_increment => 1,
3448             },
3449             location => {
3450                 data_type => 'INT',
3451             },
3452             type => {
3453                 data_type => 'INT',
3454             },
3455         );
3456         MySchema::Event->set_primary_key ('sequence');
3457
3458     # This will get back the latest event for every location. The column
3459     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3460     # combo to limit the resultset
3461
3462     $rs = $schema->resultset('Event');
3463     $table = $rs->result_source->name;
3464     $latest = $rs->search (
3465         undef,
3466         { from => \ "
3467             (SELECT e1.* FROM $table e1
3468                 JOIN $table e2
3469                     ON e1.location = e2.location
3470                     AND e1.sequence < e2.sequence
3471                 WHERE e2.sequence is NULL
3472             ) me",
3473         },
3474     );
3475
3476     # Equivalent SQL (with the DBIC chunks added):
3477
3478     SELECT me.sequence, me.location, me.type FROM
3479        (SELECT e1.* FROM events e1
3480            JOIN events e2
3481                ON e1.location = e2.location
3482                AND e1.sequence < e2.sequence
3483            WHERE e2.sequence is NULL
3484        ) me;
3485
3486 =head2 for
3487
3488 =over 4
3489
3490 =item Value: ( 'update' | 'shared' )
3491
3492 =back
3493
3494 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3495 ... FOR SHARED.
3496
3497 =cut
3498
3499 1;