lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 665
 666   return $self->{cursor}
 667     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 668           $attrs->{where},$attrs);
 669 }
 670
 671 =head2 single
 672
 673 =over 4
 674
 675 =item Arguments: $cond?
 676
 677 =item Return Value: $row_object?
 678
 679 =back
 680
 681   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 682
 683 Inflates the first result without creating a cursor if the resultset has
 684 any records in it; if not returns nothing. Used by L</find> as a lean version of
 685 L</search>.
 686
 687 While this method can take an optional search condition (just like L</search>)
 688 being a fast-code-path it does not recognize search attributes. If you need to
 689 add extra joins or similar, call L</search> and then chain-call L</single> on the
 690 L<DBIx::Class::ResultSet> returned.
 691
 692 =over
 693
 694 =item B<Note>
 695
 696 As of 0.08100, this method enforces the assumption that the preceeding
 697 query returns only one row. If more than one row is returned, you will receive
 698 a warning:
 699
 700   Query returned more than one row
 701
 702 In this case, you should be using L</first> or L</find> instead, or if you really
 703 know what you are doing, use the L</rows> attribute to explicitly limit the size
 704 of the resultset.
 705
 706 =back
 707
 708 =cut
 709
 710 sub single {
 711   my ($self, $where) = @_;
 712   if(@_ > 2) {
 713       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 714   }
 715
 716   my $attrs = $self->_resolved_attrs_copy;
 717   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 718
 719   if ($where) {
 720     if (defined $attrs->{where}) {
 721       $attrs->{where} = {
 722         '-and' =>
 723             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 724                $where, delete $attrs->{where} ]
 725       };
 726     } else {
 727       $attrs->{where} = $where;
 728     }
 729   }
 730
 731 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 732 #  unless ($self->_is_unique_query($attrs->{where})) {
 733 #    carp "Query not guaranteed to return a single row"
 734 #      . "; please declare your unique constraints or use search instead";
 735 #  }
 736
 737   my @data = $self->result_source->storage->select_single(
 738     $attrs->{from}, $attrs->{select},
 739     $attrs->{where}, $attrs
 740   );
 741
 742   return (@data ? ($self->_construct_object(@data))[0] : undef);
 743 }
 744
 745 # _gen_virtual_order
 746 #
 747 # This is a horrble hack, but seems like the best we can do at this point
 748 # Some limit emulations (Top) require an ordered resultset in order to
 749 # function at all. So supply a PK order to be used if necessary
 750
 751 sub _gen_virtual_order {
 752   return [ shift->result_source->primary_columns ];
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp (
 874     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 875    .' Instead use ->search({ x => { -like => "y%" } })'
 876    .' (note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. Passing arguments is equivalent to
1149 C<< $rs->search ($cond, \%attrs)->count >>
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my @grouped_subq_attrs = qw/prefetch collapse distinct group_by having/;
1159   my @subq_attrs = ();
1160
1161   my $attrs = $self->_resolved_attrs;
1162   # if we are not paged - we are simply asking for a limit
1163   if (not $attrs->{page} and not $attrs->{software_limit}) {
1164     push @subq_attrs, qw/rows offset/;
1165   }
1166
1167   my $need_subq = $self->_has_attr (@subq_attrs);
1168   my $need_group_subq = $self->_has_attr (@grouped_subq_attrs);
1169
1170   return ($need_subq || $need_group_subq)
1171     ? $self->_count_subq ($need_group_subq)
1172     : $self->_count_simple
1173 }
1174
1175 sub _count_subq {
1176   my ($self, $add_group_by) = @_;
1177
1178   my $attrs = $self->_resolved_attrs_copy;
1179
1180   # copy for the subquery, we need to do some adjustments to it too
1181   my $sub_attrs = { %$attrs };
1182
1183   # these can not go in the subquery, and there is no point of ordering it
1184   delete $sub_attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns order_by/;
1185
1186   # if needed force a group_by and the same set of columns (most databases require this)
1187   if ($add_group_by) {
1188
1189     # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1190     # simply deleting group_by suffices, as the code below will re-fill it
1191     # Note: we check $attrs, as $sub_attrs has collapse deleted
1192     if (ref $attrs->{collapse} and keys %{$attrs->{collapse}} ) {
1193       delete $sub_attrs->{group_by};
1194     }
1195
1196     $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1197   }
1198
1199   $attrs->{from} = [{
1200     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1201   }];
1202
1203   # the subquery replaces this
1204   delete $attrs->{$_} for qw/where bind prefetch collapse distinct group_by having having_bind/;
1205
1206   return $self->__count ($attrs);
1207 }
1208
1209 sub _count_simple {
1210   my $self = shift;
1211
1212   my $count = $self->__count;
1213   return 0 unless $count;
1214
1215   # need to take offset from resolved attrs
1216
1217   my $attrs = $self->_resolved_attrs;
1218
1219   $count -= $attrs->{offset} if $attrs->{offset};
1220   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1221   $count = 0 if ($count < 0);
1222   return $count;
1223 }
1224
1225 sub __count {
1226   my ($self, $attrs) = @_;
1227
1228   $attrs ||= $self->_resolved_attrs_copy;
1229
1230   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1231   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1232
1233   $attrs->{select} = { count => '*' };
1234   $attrs->{as} = [qw/count/];
1235
1236   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1237   my ($count) = $tmp_rs->cursor->next;
1238
1239   return $count;
1240 }
1241
1242 sub _bool {
1243   return 1;
1244 }
1245
1246 =head2 count_literal
1247
1248 =over 4
1249
1250 =item Arguments: $sql_fragment, @bind_values
1251
1252 =item Return Value: $count
1253
1254 =back
1255
1256 Counts the results in a literal query. Equivalent to calling L</search_literal>
1257 with the passed arguments, then L</count>.
1258
1259 =cut
1260
1261 sub count_literal { shift->search_literal(@_)->count; }
1262
1263 =head2 all
1264
1265 =over 4
1266
1267 =item Arguments: none
1268
1269 =item Return Value: @objects
1270
1271 =back
1272
1273 Returns all elements in the resultset. Called implicitly if the resultset
1274 is returned in list context.
1275
1276 =cut
1277
1278 sub all {
1279   my $self = shift;
1280   if(@_) {
1281       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1282   }
1283
1284   return @{ $self->get_cache } if $self->get_cache;
1285
1286   my @obj;
1287
1288   # TODO: don't call resolve here
1289   if (keys %{$self->_resolved_attrs->{collapse}}) {
1290 #  if ($self->{attrs}{prefetch}) {
1291       # Using $self->cursor->all is really just an optimisation.
1292       # If we're collapsing has_many prefetches it probably makes
1293       # very little difference, and this is cleaner than hacking
1294       # _construct_object to survive the approach
1295     my @row = $self->cursor->next;
1296     while (@row) {
1297       push(@obj, $self->_construct_object(@row));
1298       @row = (exists $self->{stashed_row}
1299                ? @{delete $self->{stashed_row}}
1300                : $self->cursor->next);
1301     }
1302   } else {
1303     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1304   }
1305
1306   $self->set_cache(\@obj) if $self->{attrs}{cache};
1307   return @obj;
1308 }
1309
1310 =head2 reset
1311
1312 =over 4
1313
1314 =item Arguments: none
1315
1316 =item Return Value: $self
1317
1318 =back
1319
1320 Resets the resultset's cursor, so you can iterate through the elements again.
1321
1322 =cut
1323
1324 sub reset {
1325   my ($self) = @_;
1326   delete $self->{_attrs} if exists $self->{_attrs};
1327   $self->{all_cache_position} = 0;
1328   $self->cursor->reset;
1329   return $self;
1330 }
1331
1332 =head2 first
1333
1334 =over 4
1335
1336 =item Arguments: none
1337
1338 =item Return Value: $object?
1339
1340 =back
1341
1342 Resets the resultset and returns an object for the first result (if the
1343 resultset returns anything).
1344
1345 =cut
1346
1347 sub first {
1348   return $_[0]->reset->next;
1349 }
1350
1351
1352 # _rs_update_delete
1353 #
1354 # Determines whether and what type of subquery is required for the $rs operation.
1355 # If grouping is necessary either supplies its own, or verifies the current one
1356 # After all is done delegates to the proper storage method.
1357
1358 sub _rs_update_delete {
1359   my ($self, $op, $values) = @_;
1360
1361   my $rsrc = $self->result_source;
1362
1363   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1364   my $needs_subq = $self->_has_attr (qw/row offset page/);
1365
1366   if ($needs_group_by_subq or $needs_subq) {
1367
1368     # make a new $rs selecting only the PKs (that's all we really need)
1369     my $attrs = $self->_resolved_attrs_copy;
1370
1371     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1372     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1373
1374     if ($needs_group_by_subq) {
1375       # make sure no group_by was supplied, or if there is one - make sure it matches
1376       # the columns compiled above perfectly. Anything else can not be sanely executed
1377       # on most databases so croak right then and there
1378
1379       if (my $g = $attrs->{group_by}) {
1380         my @current_group_by = map
1381           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1382           (ref $g eq 'ARRAY' ? @$g : $g );
1383
1384         if (
1385           join ("\x00", sort @current_group_by)
1386             ne
1387           join ("\x00", sort @{$attrs->{columns}} )
1388         ) {
1389           $self->throw_exception (
1390             "You have just attempted a $op operation on a resultset which does group_by"
1391             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1392             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1393             . ' kind of queries. Please retry the operation with a modified group_by or'
1394             . ' without using one at all.'
1395           );
1396         }
1397       }
1398       else {
1399         $attrs->{group_by} = $attrs->{columns};
1400       }
1401     }
1402
1403     my $subrs = (ref $self)->new($rsrc, $attrs);
1404
1405     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1406   }
1407   else {
1408     return $rsrc->storage->$op(
1409       $rsrc,
1410       $op eq 'update' ? $values : (),
1411       $self->_cond_for_update_delete,
1412     );
1413   }
1414 }
1415
1416
1417 # _cond_for_update_delete
1418 #
1419 # update/delete require the condition to be modified to handle
1420 # the differing SQL syntax available.  This transforms the $self->{cond}
1421 # appropriately, returning the new condition.
1422
1423 sub _cond_for_update_delete {
1424   my ($self, $full_cond) = @_;
1425   my $cond = {};
1426
1427   $full_cond ||= $self->{cond};
1428   # No-op. No condition, we're updating/deleting everything
1429   return $cond unless ref $full_cond;
1430
1431   if (ref $full_cond eq 'ARRAY') {
1432     $cond = [
1433       map {
1434         my %hash;
1435         foreach my $key (keys %{$_}) {
1436           $key =~ /([^.]+)$/;
1437           $hash{$1} = $_->{$key};
1438         }
1439         \%hash;
1440       } @{$full_cond}
1441     ];
1442   }
1443   elsif (ref $full_cond eq 'HASH') {
1444     if ((keys %{$full_cond})[0] eq '-and') {
1445       $cond->{-and} = [];
1446       my @cond = @{$full_cond->{-and}};
1447        for (my $i = 0; $i < @cond; $i++) {
1448         my $entry = $cond[$i];
1449         my $hash;
1450         if (ref $entry eq 'HASH') {
1451           $hash = $self->_cond_for_update_delete($entry);
1452         }
1453         else {
1454           $entry =~ /([^.]+)$/;
1455           $hash->{$1} = $cond[++$i];
1456         }
1457         push @{$cond->{-and}}, $hash;
1458       }
1459     }
1460     else {
1461       foreach my $key (keys %{$full_cond}) {
1462         $key =~ /([^.]+)$/;
1463         $cond->{$1} = $full_cond->{$key};
1464       }
1465     }
1466   }
1467   else {
1468     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1469   }
1470
1471   return $cond;
1472 }
1473
1474
1475 =head2 update
1476
1477 =over 4
1478
1479 =item Arguments: \%values
1480
1481 =item Return Value: $storage_rv
1482
1483 =back
1484
1485 Sets the specified columns in the resultset to the supplied values in a
1486 single query. Return value will be true if the update succeeded or false
1487 if no records were updated; exact type of success value is storage-dependent.
1488
1489 =cut
1490
1491 sub update {
1492   my ($self, $values) = @_;
1493   $self->throw_exception('Values for update must be a hash')
1494     unless ref $values eq 'HASH';
1495
1496   return $self->_rs_update_delete ('update', $values);
1497 }
1498
1499 =head2 update_all
1500
1501 =over 4
1502
1503 =item Arguments: \%values
1504
1505 =item Return Value: 1
1506
1507 =back
1508
1509 Fetches all objects and updates them one at a time. Note that C<update_all>
1510 will run DBIC cascade triggers, while L</update> will not.
1511
1512 =cut
1513
1514 sub update_all {
1515   my ($self, $values) = @_;
1516   $self->throw_exception('Values for update_all must be a hash')
1517     unless ref $values eq 'HASH';
1518   foreach my $obj ($self->all) {
1519     $obj->set_columns($values)->update;
1520   }
1521   return 1;
1522 }
1523
1524 =head2 delete
1525
1526 =over 4
1527
1528 =item Arguments: none
1529
1530 =item Return Value: $storage_rv
1531
1532 =back
1533
1534 Deletes the contents of the resultset from its result source. Note that this
1535 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1536 to run. See also L<DBIx::Class::Row/delete>.
1537
1538 Return value will be the amount of rows deleted; exact type of return value
1539 is storage-dependent.
1540
1541 =cut
1542
1543 sub delete {
1544   my $self = shift;
1545   $self->throw_exception('delete does not accept any arguments')
1546     if @_;
1547
1548   return $self->_rs_update_delete ('delete');
1549 }
1550
1551 =head2 delete_all
1552
1553 =over 4
1554
1555 =item Arguments: none
1556
1557 =item Return Value: 1
1558
1559 =back
1560
1561 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1562 will run DBIC cascade triggers, while L</delete> will not.
1563
1564 =cut
1565
1566 sub delete_all {
1567   my $self = shift;
1568   $self->throw_exception('delete_all does not accept any arguments')
1569     if @_;
1570
1571   $_->delete for $self->all;
1572   return 1;
1573 }
1574
1575 =head2 populate
1576
1577 =over 4
1578
1579 =item Arguments: \@data;
1580
1581 =back
1582
1583 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1584 For the arrayref of hashrefs style each hashref should be a structure suitable
1585 forsubmitting to a $resultset->create(...) method.
1586
1587 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1588 to insert the data, as this is a faster method.
1589
1590 Otherwise, each set of data is inserted into the database using
1591 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1592 objects is returned.
1593
1594 Example:  Assuming an Artist Class that has many CDs Classes relating:
1595
1596   my $Artist_rs = $schema->resultset("Artist");
1597
1598   ## Void Context Example
1599   $Artist_rs->populate([
1600      { artistid => 4, name => 'Manufactured Crap', cds => [
1601         { title => 'My First CD', year => 2006 },
1602         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1603       ],
1604      },
1605      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1606         { title => 'My parents sold me to a record company' ,year => 2005 },
1607         { title => 'Why Am I So Ugly?', year => 2006 },
1608         { title => 'I Got Surgery and am now Popular', year => 2007 }
1609       ],
1610      },
1611   ]);
1612
1613   ## Array Context Example
1614   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1615     { name => "Artist One"},
1616     { name => "Artist Two"},
1617     { name => "Artist Three", cds=> [
1618     { title => "First CD", year => 2007},
1619     { title => "Second CD", year => 2008},
1620   ]}
1621   ]);
1622
1623   print $ArtistOne->name; ## response is 'Artist One'
1624   print $ArtistThree->cds->count ## reponse is '2'
1625
1626 For the arrayref of arrayrefs style,  the first element should be a list of the
1627 fieldsnames to which the remaining elements are rows being inserted.  For
1628 example:
1629
1630   $Arstist_rs->populate([
1631     [qw/artistid name/],
1632     [100, 'A Formally Unknown Singer'],
1633     [101, 'A singer that jumped the shark two albums ago'],
1634     [102, 'An actually cool singer.'],
1635   ]);
1636
1637 Please note an important effect on your data when choosing between void and
1638 wantarray context. Since void context goes straight to C<insert_bulk> in
1639 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1640 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1641 create primary keys for you, you will find that your PKs are empty.  In this
1642 case you will have to use the wantarray context in order to create those
1643 values.
1644
1645 =cut
1646
1647 sub populate {
1648   my $self = shift @_;
1649   my $data = ref $_[0][0] eq 'HASH'
1650     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1651     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1652
1653   if(defined wantarray) {
1654     my @created;
1655     foreach my $item (@$data) {
1656       push(@created, $self->create($item));
1657     }
1658     return @created;
1659   } else {
1660     my ($first, @rest) = @$data;
1661
1662     my @names = grep {!ref $first->{$_}} keys %$first;
1663     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1664     my @pks = $self->result_source->primary_columns;
1665
1666     ## do the belongs_to relationships
1667     foreach my $index (0..$#$data) {
1668
1669       # delegate to create() for any dataset without primary keys with specified relationships
1670       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1671         for my $r (@rels) {
1672           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1673             my @ret = $self->populate($data);
1674             return;
1675           }
1676         }
1677       }
1678
1679       foreach my $rel (@rels) {
1680         next unless ref $data->[$index]->{$rel} eq "HASH";
1681         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1682         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1683         my $related = $result->result_source->_resolve_condition(
1684           $result->result_source->relationship_info($reverse)->{cond},
1685           $self,
1686           $result,
1687         );
1688
1689         delete $data->[$index]->{$rel};
1690         $data->[$index] = {%{$data->[$index]}, %$related};
1691
1692         push @names, keys %$related if $index == 0;
1693       }
1694     }
1695
1696     ## do bulk insert on current row
1697     my @values = map { [ @$_{@names} ] } @$data;
1698
1699     $self->result_source->storage->insert_bulk(
1700       $self->result_source,
1701       \@names,
1702       \@values,
1703     );
1704
1705     ## do the has_many relationships
1706     foreach my $item (@$data) {
1707
1708       foreach my $rel (@rels) {
1709         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1710
1711         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1712      || $self->throw_exception('Cannot find the relating object.');
1713
1714         my $child = $parent->$rel;
1715
1716         my $related = $child->result_source->_resolve_condition(
1717           $parent->result_source->relationship_info($rel)->{cond},
1718           $child,
1719           $parent,
1720         );
1721
1722         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1723         my @populate = map { {%$_, %$related} } @rows_to_add;
1724
1725         $child->populate( \@populate );
1726       }
1727     }
1728   }
1729 }
1730
1731 =head2 _normalize_populate_args ($args)
1732
1733 Private method used by L</populate> to normalize its incoming arguments.  Factored
1734 out in case you want to subclass and accept new argument structures to the
1735 L</populate> method.
1736
1737 =cut
1738
1739 sub _normalize_populate_args {
1740   my ($self, $data) = @_;
1741   my @names = @{shift(@$data)};
1742   my @results_to_create;
1743   foreach my $datum (@$data) {
1744     my %result_to_create;
1745     foreach my $index (0..$#names) {
1746       $result_to_create{$names[$index]} = $$datum[$index];
1747     }
1748     push @results_to_create, \%result_to_create;
1749   }
1750   return \@results_to_create;
1751 }
1752
1753 =head2 pager
1754
1755 =over 4
1756
1757 =item Arguments: none
1758
1759 =item Return Value: $pager
1760
1761 =back
1762
1763 Return Value a L<Data::Page> object for the current resultset. Only makes
1764 sense for queries with a C<page> attribute.
1765
1766 To get the full count of entries for a paged resultset, call
1767 C<total_entries> on the L<Data::Page> object.
1768
1769 =cut
1770
1771 sub pager {
1772   my ($self) = @_;
1773
1774   return $self->{pager} if $self->{pager};
1775
1776   my $attrs = $self->{attrs};
1777   $self->throw_exception("Can't create pager for non-paged rs")
1778     unless $self->{attrs}{page};
1779   $attrs->{rows} ||= 10;
1780
1781   # throw away the paging flags and re-run the count (possibly
1782   # with a subselect) to get the real total count
1783   my $count_attrs = { %$attrs };
1784   delete $count_attrs->{$_} for qw/rows offset page pager/;
1785   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1786
1787   return $self->{pager} = Data::Page->new(
1788     $total_count,
1789     $attrs->{rows},
1790     $self->{attrs}{page}
1791   );
1792 }
1793
1794 =head2 page
1795
1796 =over 4
1797
1798 =item Arguments: $page_number
1799
1800 =item Return Value: $rs
1801
1802 =back
1803
1804 Returns a resultset for the $page_number page of the resultset on which page
1805 is called, where each page contains a number of rows equal to the 'rows'
1806 attribute set on the resultset (10 by default).
1807
1808 =cut
1809
1810 sub page {
1811   my ($self, $page) = @_;
1812   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1813 }
1814
1815 =head2 new_result
1816
1817 =over 4
1818
1819 =item Arguments: \%vals
1820
1821 =item Return Value: $rowobject
1822
1823 =back
1824
1825 Creates a new row object in the resultset's result class and returns
1826 it. The row is not inserted into the database at this point, call
1827 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1828 will tell you whether the row object has been inserted or not.
1829
1830 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1831
1832 =cut
1833
1834 sub new_result {
1835   my ($self, $values) = @_;
1836   $self->throw_exception( "new_result needs a hash" )
1837     unless (ref $values eq 'HASH');
1838
1839   my %new;
1840   my $alias = $self->{attrs}{alias};
1841
1842   if (
1843     defined $self->{cond}
1844     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1845   ) {
1846     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1847     $new{-from_resultset} = [ keys %new ] if keys %new;
1848   } else {
1849     $self->throw_exception(
1850       "Can't abstract implicit construct, condition not a hash"
1851     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1852
1853     my $collapsed_cond = (
1854       $self->{cond}
1855         ? $self->_collapse_cond($self->{cond})
1856         : {}
1857     );
1858
1859     # precendence must be given to passed values over values inherited from
1860     # the cond, so the order here is important.
1861     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1862     while( my($col,$value) = each %implied ){
1863       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1864         $new{$col} = $value->{'='};
1865         next;
1866       }
1867       $new{$col} = $value if $self->_is_deterministic_value($value);
1868     }
1869   }
1870
1871   %new = (
1872     %new,
1873     %{ $self->_remove_alias($values, $alias) },
1874     -source_handle => $self->_source_handle,
1875     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1876   );
1877
1878   return $self->result_class->new(\%new);
1879 }
1880
1881 # _is_deterministic_value
1882 #
1883 # Make an effor to strip non-deterministic values from the condition,
1884 # to make sure new_result chokes less
1885
1886 sub _is_deterministic_value {
1887   my $self = shift;
1888   my $value = shift;
1889   my $ref_type = ref $value;
1890   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1891   return 1 if Scalar::Util::blessed($value);
1892   return 0;
1893 }
1894
1895 # _has_attr
1896 #
1897 # determines if the resultset defines at least one
1898 # of the attributes supplied
1899 #
1900 # used to determine if a subquery is neccessary
1901
1902 sub _has_attr {
1903   my ($self, @attr_names) = @_;
1904
1905   my $attrs = $self->_resolved_attrs;
1906
1907   my $join_check_req;
1908
1909   for my $n (@attr_names) {
1910     ++$join_check_req if $n =~ /join/;
1911
1912     my $attr =  $attrs->{$n};
1913
1914     next if not defined $attr;
1915
1916     if (ref $attr eq 'HASH') {
1917       return 1 if keys %$attr;
1918     }
1919     elsif (ref $attr eq 'ARRAY') {
1920       return 1 if @$attr;
1921     }
1922     else {
1923       return 1 if $attr;
1924     }
1925   }
1926
1927   # a join can be expressed as a multi-level from
1928   return 1 if (
1929     $join_check_req
1930       and
1931     ref $attrs->{from} eq 'ARRAY'
1932       and
1933     @{$attrs->{from}} > 1
1934   );
1935
1936   return 0;
1937 }
1938
1939 # _collapse_cond
1940 #
1941 # Recursively collapse the condition.
1942
1943 sub _collapse_cond {
1944   my ($self, $cond, $collapsed) = @_;
1945
1946   $collapsed ||= {};
1947
1948   if (ref $cond eq 'ARRAY') {
1949     foreach my $subcond (@$cond) {
1950       next unless ref $subcond;  # -or
1951       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1952     }
1953   }
1954   elsif (ref $cond eq 'HASH') {
1955     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1956       foreach my $subcond (@{$cond->{-and}}) {
1957         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1958       }
1959     }
1960     else {
1961       foreach my $col (keys %$cond) {
1962         my $value = $cond->{$col};
1963         $collapsed->{$col} = $value;
1964       }
1965     }
1966   }
1967
1968   return $collapsed;
1969 }
1970
1971 # _remove_alias
1972 #
1973 # Remove the specified alias from the specified query hash. A copy is made so
1974 # the original query is not modified.
1975
1976 sub _remove_alias {
1977   my ($self, $query, $alias) = @_;
1978
1979   my %orig = %{ $query || {} };
1980   my %unaliased;
1981
1982   foreach my $key (keys %orig) {
1983     if ($key !~ /\./) {
1984       $unaliased{$key} = $orig{$key};
1985       next;
1986     }
1987     $unaliased{$1} = $orig{$key}
1988       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1989   }
1990
1991   return \%unaliased;
1992 }
1993
1994 =head2 as_query (EXPERIMENTAL)
1995
1996 =over 4
1997
1998 =item Arguments: none
1999
2000 =item Return Value: \[ $sql, @bind ]
2001
2002 =back
2003
2004 Returns the SQL query and bind vars associated with the invocant.
2005
2006 This is generally used as the RHS for a subquery.
2007
2008 B<NOTE>: This feature is still experimental.
2009
2010 =cut
2011
2012 sub as_query { return shift->cursor->as_query(@_) }
2013
2014 =head2 find_or_new
2015
2016 =over 4
2017
2018 =item Arguments: \%vals, \%attrs?
2019
2020 =item Return Value: $rowobject
2021
2022 =back
2023
2024   my $artist = $schema->resultset('Artist')->find_or_new(
2025     { artist => 'fred' }, { key => 'artists' });
2026
2027   $cd->cd_to_producer->find_or_new({ producer => $producer },
2028                                    { key => 'primary });
2029
2030 Find an existing record from this resultset, based on its primary
2031 key, or a unique constraint. If none exists, instantiate a new result
2032 object and return it. The object will not be saved into your storage
2033 until you call L<DBIx::Class::Row/insert> on it.
2034
2035 You most likely want this method when looking for existing rows using
2036 a unique constraint that is not the primary key, or looking for
2037 related rows.
2038
2039 If you want objects to be saved immediately, use L</find_or_create> instead.
2040
2041 B<Note>: C<find_or_new> is probably not what you want when creating a
2042 new row in a table that uses primary keys supplied by the
2043 database. Passing in a primary key column with a value of I<undef>
2044 will cause L</find> to attempt to search for a row with a value of
2045 I<NULL>.
2046
2047 =cut
2048
2049 sub find_or_new {
2050   my $self     = shift;
2051   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2052   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2053   my $exists   = $self->find($hash, $attrs);
2054   return defined $exists ? $exists : $self->new_result($hash);
2055 }
2056
2057 =head2 create
2058
2059 =over 4
2060
2061 =item Arguments: \%vals
2062
2063 =item Return Value: a L<DBIx::Class::Row> $object
2064
2065 =back
2066
2067 Attempt to create a single new row or a row with multiple related rows
2068 in the table represented by the resultset (and related tables). This
2069 will not check for duplicate rows before inserting, use
2070 L</find_or_create> to do that.
2071
2072 To create one row for this resultset, pass a hashref of key/value
2073 pairs representing the columns of the table and the values you wish to
2074 store. If the appropriate relationships are set up, foreign key fields
2075 can also be passed an object representing the foreign row, and the
2076 value will be set to its primary key.
2077
2078 To create related objects, pass a hashref for the value if the related
2079 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2080 and use the name of the relationship as the key. (NOT the name of the field,
2081 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2082 of hashrefs containing the data for each of the rows to create in the foreign
2083 tables, again using the relationship name as the key.
2084
2085 Instead of hashrefs of plain related data (key/value pairs), you may
2086 also pass new or inserted objects. New objects (not inserted yet, see
2087 L</new>), will be inserted into their appropriate tables.
2088
2089 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2090
2091 Example of creating a new row.
2092
2093   $person_rs->create({
2094     name=>"Some Person",
2095     email=>"somebody@someplace.com"
2096   });
2097
2098 Example of creating a new row and also creating rows in a related C<has_many>
2099 or C<has_one> resultset.  Note Arrayref.
2100
2101   $artist_rs->create(
2102      { artistid => 4, name => 'Manufactured Crap', cds => [
2103         { title => 'My First CD', year => 2006 },
2104         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2105       ],
2106      },
2107   );
2108
2109 Example of creating a new row and also creating a row in a related
2110 C<belongs_to>resultset. Note Hashref.
2111
2112   $cd_rs->create({
2113     title=>"Music for Silly Walks",
2114     year=>2000,
2115     artist => {
2116       name=>"Silly Musician",
2117     }
2118   });
2119
2120 =cut
2121
2122 sub create {
2123   my ($self, $attrs) = @_;
2124   $self->throw_exception( "create needs a hashref" )
2125     unless ref $attrs eq 'HASH';
2126   return $self->new_result($attrs)->insert;
2127 }
2128
2129 =head2 find_or_create
2130
2131 =over 4
2132
2133 =item Arguments: \%vals, \%attrs?
2134
2135 =item Return Value: $rowobject
2136
2137 =back
2138
2139   $cd->cd_to_producer->find_or_create({ producer => $producer },
2140                                       { key => 'primary });
2141
2142 Tries to find a record based on its primary key or unique constraints; if none
2143 is found, creates one and returns that instead.
2144
2145   my $cd = $schema->resultset('CD')->find_or_create({
2146     cdid   => 5,
2147     artist => 'Massive Attack',
2148     title  => 'Mezzanine',
2149     year   => 2005,
2150   });
2151
2152 Also takes an optional C<key> attribute, to search by a specific key or unique
2153 constraint. For example:
2154
2155   my $cd = $schema->resultset('CD')->find_or_create(
2156     {
2157       artist => 'Massive Attack',
2158       title  => 'Mezzanine',
2159     },
2160     { key => 'cd_artist_title' }
2161   );
2162
2163 B<Note>: Because find_or_create() reads from the database and then
2164 possibly inserts based on the result, this method is subject to a race
2165 condition. Another process could create a record in the table after
2166 the find has completed and before the create has started. To avoid
2167 this problem, use find_or_create() inside a transaction.
2168
2169 B<Note>: C<find_or_create> is probably not what you want when creating
2170 a new row in a table that uses primary keys supplied by the
2171 database. Passing in a primary key column with a value of I<undef>
2172 will cause L</find> to attempt to search for a row with a value of
2173 I<NULL>.
2174
2175 See also L</find> and L</update_or_create>. For information on how to declare
2176 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2177
2178 =cut
2179
2180 sub find_or_create {
2181   my $self     = shift;
2182   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2183   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2184   my $exists   = $self->find($hash, $attrs);
2185   return defined $exists ? $exists : $self->create($hash);
2186 }
2187
2188 =head2 update_or_create
2189
2190 =over 4
2191
2192 =item Arguments: \%col_values, { key => $unique_constraint }?
2193
2194 =item Return Value: $rowobject
2195
2196 =back
2197
2198   $resultset->update_or_create({ col => $val, ... });
2199
2200 First, searches for an existing row matching one of the unique constraints
2201 (including the primary key) on the source of this resultset. If a row is
2202 found, updates it with the other given column values. Otherwise, creates a new
2203 row.
2204
2205 Takes an optional C<key> attribute to search on a specific unique constraint.
2206 For example:
2207
2208   # In your application
2209   my $cd = $schema->resultset('CD')->update_or_create(
2210     {
2211       artist => 'Massive Attack',
2212       title  => 'Mezzanine',
2213       year   => 1998,
2214     },
2215     { key => 'cd_artist_title' }
2216   );
2217
2218   $cd->cd_to_producer->update_or_create({
2219     producer => $producer,
2220     name => 'harry',
2221   }, {
2222     key => 'primary,
2223   });
2224
2225
2226 If no C<key> is specified, it searches on all unique constraints defined on the
2227 source, including the primary key.
2228
2229 If the C<key> is specified as C<primary>, it searches only on the primary key.
2230
2231 See also L</find> and L</find_or_create>. For information on how to declare
2232 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2233
2234 B<Note>: C<update_or_create> is probably not what you want when
2235 looking for a row in a table that uses primary keys supplied by the
2236 database, unless you actually have a key value. Passing in a primary
2237 key column with a value of I<undef> will cause L</find> to attempt to
2238 search for a row with a value of I<NULL>.
2239
2240 =cut
2241
2242 sub update_or_create {
2243   my $self = shift;
2244   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2245   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2246
2247   my $row = $self->find($cond, $attrs);
2248   if (defined $row) {
2249     $row->update($cond);
2250     return $row;
2251   }
2252
2253   return $self->create($cond);
2254 }
2255
2256 =head2 update_or_new
2257
2258 =over 4
2259
2260 =item Arguments: \%col_values, { key => $unique_constraint }?
2261
2262 =item Return Value: $rowobject
2263
2264 =back
2265
2266   $resultset->update_or_new({ col => $val, ... });
2267
2268 First, searches for an existing row matching one of the unique constraints
2269 (including the primary key) on the source of this resultset. If a row is
2270 found, updates it with the other given column values. Otherwise, instantiate
2271 a new result object and return it. The object will not be saved into your storage
2272 until you call L<DBIx::Class::Row/insert> on it.
2273
2274 Takes an optional C<key> attribute to search on a specific unique constraint.
2275 For example:
2276
2277   # In your application
2278   my $cd = $schema->resultset('CD')->update_or_new(
2279     {
2280       artist => 'Massive Attack',
2281       title  => 'Mezzanine',
2282       year   => 1998,
2283     },
2284     { key => 'cd_artist_title' }
2285   );
2286
2287   if ($cd->in_storage) {
2288       # the cd was updated
2289   }
2290   else {
2291       # the cd is not yet in the database, let's insert it
2292       $cd->insert;
2293   }
2294
2295 See also L</find>, L</find_or_create> and L<find_or_new>.
2296
2297 =cut
2298
2299 sub update_or_new {
2300     my $self  = shift;
2301     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2302     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2303
2304     my $row = $self->find( $cond, $attrs );
2305     if ( defined $row ) {
2306         $row->update($cond);
2307         return $row;
2308     }
2309
2310     return $self->new_result($cond);
2311 }
2312
2313 =head2 get_cache
2314
2315 =over 4
2316
2317 =item Arguments: none
2318
2319 =item Return Value: \@cache_objects?
2320
2321 =back
2322
2323 Gets the contents of the cache for the resultset, if the cache is set.
2324
2325 The cache is populated either by using the L</prefetch> attribute to
2326 L</search> or by calling L</set_cache>.
2327
2328 =cut
2329
2330 sub get_cache {
2331   shift->{all_cache};
2332 }
2333
2334 =head2 set_cache
2335
2336 =over 4
2337
2338 =item Arguments: \@cache_objects
2339
2340 =item Return Value: \@cache_objects
2341
2342 =back
2343
2344 Sets the contents of the cache for the resultset. Expects an arrayref
2345 of objects of the same class as those produced by the resultset. Note that
2346 if the cache is set the resultset will return the cached objects rather
2347 than re-querying the database even if the cache attr is not set.
2348
2349 The contents of the cache can also be populated by using the
2350 L</prefetch> attribute to L</search>.
2351
2352 =cut
2353
2354 sub set_cache {
2355   my ( $self, $data ) = @_;
2356   $self->throw_exception("set_cache requires an arrayref")
2357       if defined($data) && (ref $data ne 'ARRAY');
2358   $self->{all_cache} = $data;
2359 }
2360
2361 =head2 clear_cache
2362
2363 =over 4
2364
2365 =item Arguments: none
2366
2367 =item Return Value: []
2368
2369 =back
2370
2371 Clears the cache for the resultset.
2372
2373 =cut
2374
2375 sub clear_cache {
2376   shift->set_cache(undef);
2377 }
2378
2379 =head2 related_resultset
2380
2381 =over 4
2382
2383 =item Arguments: $relationship_name
2384
2385 =item Return Value: $resultset
2386
2387 =back
2388
2389 Returns a related resultset for the supplied relationship name.
2390
2391   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2392
2393 =cut
2394
2395 sub related_resultset {
2396   my ($self, $rel) = @_;
2397
2398   $self->{related_resultsets} ||= {};
2399   return $self->{related_resultsets}{$rel} ||= do {
2400     my $rel_obj = $self->result_source->relationship_info($rel);
2401
2402     $self->throw_exception(
2403       "search_related: result source '" . $self->result_source->source_name .
2404         "' has no such relationship $rel")
2405       unless $rel_obj;
2406
2407     my ($from,$seen) = $self->_resolve_from($rel);
2408
2409     my $join_count = $seen->{$rel};
2410     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2411
2412     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2413     my %attrs = %{$self->{attrs}||{}};
2414     delete @attrs{qw(result_class alias)};
2415
2416     my $new_cache;
2417
2418     if (my $cache = $self->get_cache) {
2419       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2420         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2421                         @$cache ];
2422       }
2423     }
2424
2425     my $rel_source = $self->result_source->related_source($rel);
2426
2427     my $new = do {
2428
2429       # The reason we do this now instead of passing the alias to the
2430       # search_rs below is that if you wrap/overload resultset on the
2431       # source you need to know what alias it's -going- to have for things
2432       # to work sanely (e.g. RestrictWithObject wants to be able to add
2433       # extra query restrictions, and these may need to be $alias.)
2434
2435       my $attrs = $rel_source->resultset_attributes;
2436       local $attrs->{alias} = $alias;
2437
2438       $rel_source->resultset
2439                  ->search_rs(
2440                      undef, {
2441                        %attrs,
2442                        join => undef,
2443                        prefetch => undef,
2444                        select => undef,
2445                        as => undef,
2446                        where => $self->{cond},
2447                        seen_join => $seen,
2448                        from => $from,
2449                    });
2450     };
2451     $new->set_cache($new_cache) if $new_cache;
2452     $new;
2453   };
2454 }
2455
2456 =head2 current_source_alias
2457
2458 =over 4
2459
2460 =item Arguments: none
2461
2462 =item Return Value: $source_alias
2463
2464 =back
2465
2466 Returns the current table alias for the result source this resultset is built
2467 on, that will be used in the SQL query. Usually it is C<me>.
2468
2469 Currently the source alias that refers to the result set returned by a
2470 L</search>/L</find> family method depends on how you got to the resultset: it's
2471 C<me> by default, but eg. L</search_related> aliases it to the related result
2472 source name (and keeps C<me> referring to the original result set). The long
2473 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2474 (and make this method unnecessary).
2475
2476 Thus it's currently necessary to use this method in predefined queries (see
2477 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2478 source alias of the current result set:
2479
2480   # in a result set class
2481   sub modified_by {
2482     my ($self, $user) = @_;
2483
2484     my $me = $self->current_source_alias;
2485
2486     return $self->search(
2487       "$me.modified" => $user->id,
2488     );
2489   }
2490
2491 =cut
2492
2493 sub current_source_alias {
2494   my ($self) = @_;
2495
2496   return ($self->{attrs} || {})->{alias} || 'me';
2497 }
2498
2499 # This code is called by search_related, and makes sure there
2500 # is clear separation between the joins before, during, and
2501 # after the relationship. This information is needed later
2502 # in order to properly resolve prefetch aliases (any alias
2503 # with a relation_chain_depth less than the depth of the
2504 # current prefetch is not considered)
2505 sub _resolve_from {
2506   my ($self, $extra_join) = @_;
2507   my $source = $self->result_source;
2508   my $attrs = $self->{attrs};
2509
2510   my $from = $attrs->{from}
2511     || [ { $attrs->{alias} => $source->from } ];
2512
2513   my $seen = { %{$attrs->{seen_join}||{}} };
2514
2515   # we need to take the prefetch the attrs into account before we
2516   # ->_resolve_join as otherwise they get lost - captainL
2517   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2518
2519   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2520
2521   ++$seen->{-relation_chain_depth};
2522
2523   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2524
2525   ++$seen->{-relation_chain_depth};
2526
2527   return ($from,$seen);
2528 }
2529
2530 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2531 sub _resolved_attrs_copy {
2532   my $self = shift;
2533   return { %{$self->_resolved_attrs (@_)} };
2534 }
2535
2536 sub _resolved_attrs {
2537   my $self = shift;
2538   return $self->{_attrs} if $self->{_attrs};
2539
2540   my $attrs  = { %{ $self->{attrs} || {} } };
2541   my $source = $self->result_source;
2542   my $alias  = $attrs->{alias};
2543
2544   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2545   my @colbits;
2546
2547   # build columns (as long as select isn't set) into a set of as/select hashes
2548   unless ( $attrs->{select} ) {
2549       @colbits = map {
2550           ( ref($_) eq 'HASH' )
2551               ? $_
2552               : {
2553                   (
2554                     /^\Q${alias}.\E(.+)$/
2555                       ? "$1"
2556                       : "$_"
2557                   )
2558                 =>
2559                   (
2560                     /\./
2561                       ? "$_"
2562                       : "${alias}.$_"
2563                   )
2564             }
2565       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2566   }
2567   # add the additional columns on
2568   foreach ( 'include_columns', '+columns' ) {
2569       push @colbits, map {
2570           ( ref($_) eq 'HASH' )
2571             ? $_
2572             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2573       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2574   }
2575
2576   # start with initial select items
2577   if ( $attrs->{select} ) {
2578     $attrs->{select} =
2579         ( ref $attrs->{select} eq 'ARRAY' )
2580       ? [ @{ $attrs->{select} } ]
2581       : [ $attrs->{select} ];
2582     $attrs->{as} = (
2583       $attrs->{as}
2584       ? (
2585         ref $attrs->{as} eq 'ARRAY'
2586         ? [ @{ $attrs->{as} } ]
2587         : [ $attrs->{as} ]
2588         )
2589       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2590     );
2591   }
2592   else {
2593
2594     # otherwise we intialise select & as to empty
2595     $attrs->{select} = [];
2596     $attrs->{as}     = [];
2597   }
2598
2599   # now add colbits to select/as
2600   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2601   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2602
2603   my $adds;
2604   if ( $adds = delete $attrs->{'+select'} ) {
2605     $adds = [$adds] unless ref $adds eq 'ARRAY';
2606     push(
2607       @{ $attrs->{select} },
2608       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2609     );
2610   }
2611   if ( $adds = delete $attrs->{'+as'} ) {
2612     $adds = [$adds] unless ref $adds eq 'ARRAY';
2613     push( @{ $attrs->{as} }, @$adds );
2614   }
2615
2616   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2617
2618   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2619     my $join = delete $attrs->{join} || {};
2620
2621     if ( defined $attrs->{prefetch} ) {
2622       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2623
2624     }
2625
2626     $attrs->{from} =    # have to copy here to avoid corrupting the original
2627       [
2628       @{ $attrs->{from} },
2629       $source->_resolve_join(
2630         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2631       )
2632       ];
2633
2634   }
2635
2636   if ( $attrs->{order_by} ) {
2637     $attrs->{order_by} = (
2638       ref( $attrs->{order_by} ) eq 'ARRAY'
2639       ? [ @{ $attrs->{order_by} } ]
2640       : [ $attrs->{order_by} ]
2641     );
2642   }
2643   else {
2644     $attrs->{order_by} = [];
2645   }
2646
2647   my $collapse = $attrs->{collapse} || {};
2648   if ( my $prefetch = delete $attrs->{prefetch} ) {
2649     $prefetch = $self->_merge_attr( {}, $prefetch );
2650     my @pre_order;
2651     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2652
2653       # bring joins back to level of current class
2654       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2655       my @prefetch =
2656         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2657       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2658       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2659     }
2660     push( @{ $attrs->{order_by} }, @pre_order );
2661   }
2662
2663   if (delete $attrs->{distinct}) {
2664     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2665   }
2666
2667   $attrs->{collapse} = $collapse;
2668
2669   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2670     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2671   }
2672
2673   return $self->{_attrs} = $attrs;
2674 }
2675
2676 sub _joinpath_aliases {
2677   my ($self, $fromspec, $seen) = @_;
2678
2679   my $paths = {};
2680   return $paths unless ref $fromspec eq 'ARRAY';
2681
2682   for my $j (@$fromspec) {
2683
2684     next if ref $j ne 'ARRAY';
2685     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2686
2687     my $p = $paths;
2688     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2689     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2690   }
2691
2692   return $paths;
2693 }
2694
2695 sub _rollout_attr {
2696   my ($self, $attr) = @_;
2697
2698   if (ref $attr eq 'HASH') {
2699     return $self->_rollout_hash($attr);
2700   } elsif (ref $attr eq 'ARRAY') {
2701     return $self->_rollout_array($attr);
2702   } else {
2703     return [$attr];
2704   }
2705 }
2706
2707 sub _rollout_array {
2708   my ($self, $attr) = @_;
2709
2710   my @rolled_array;
2711   foreach my $element (@{$attr}) {
2712     if (ref $element eq 'HASH') {
2713       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2714     } elsif (ref $element eq 'ARRAY') {
2715       #  XXX - should probably recurse here
2716       push( @rolled_array, @{$self->_rollout_array($element)} );
2717     } else {
2718       push( @rolled_array, $element );
2719     }
2720   }
2721   return \@rolled_array;
2722 }
2723
2724 sub _rollout_hash {
2725   my ($self, $attr) = @_;
2726
2727   my @rolled_array;
2728   foreach my $key (keys %{$attr}) {
2729     push( @rolled_array, { $key => $attr->{$key} } );
2730   }
2731   return \@rolled_array;
2732 }
2733
2734 sub _calculate_score {
2735   my ($self, $a, $b) = @_;
2736
2737   if (ref $b eq 'HASH') {
2738     my ($b_key) = keys %{$b};
2739     if (ref $a eq 'HASH') {
2740       my ($a_key) = keys %{$a};
2741       if ($a_key eq $b_key) {
2742         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2743       } else {
2744         return 0;
2745       }
2746     } else {
2747       return ($a eq $b_key) ? 1 : 0;
2748     }
2749   } else {
2750     if (ref $a eq 'HASH') {
2751       my ($a_key) = keys %{$a};
2752       return ($b eq $a_key) ? 1 : 0;
2753     } else {
2754       return ($b eq $a) ? 1 : 0;
2755     }
2756   }
2757 }
2758
2759 sub _merge_attr {
2760   my ($self, $orig, $import) = @_;
2761
2762   return $import unless defined($orig);
2763   return $orig unless defined($import);
2764
2765   $orig = $self->_rollout_attr($orig);
2766   $import = $self->_rollout_attr($import);
2767
2768   my $seen_keys;
2769   foreach my $import_element ( @{$import} ) {
2770     # find best candidate from $orig to merge $b_element into
2771     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2772     foreach my $orig_element ( @{$orig} ) {
2773       my $score = $self->_calculate_score( $orig_element, $import_element );
2774       if ($score > $best_candidate->{score}) {
2775         $best_candidate->{position} = $position;
2776         $best_candidate->{score} = $score;
2777       }
2778       $position++;
2779     }
2780     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2781
2782     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2783       push( @{$orig}, $import_element );
2784     } else {
2785       my $orig_best = $orig->[$best_candidate->{position}];
2786       # merge orig_best and b_element together and replace original with merged
2787       if (ref $orig_best ne 'HASH') {
2788         $orig->[$best_candidate->{position}] = $import_element;
2789       } elsif (ref $import_element eq 'HASH') {
2790         my ($key) = keys %{$orig_best};
2791         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2792       }
2793     }
2794     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2795   }
2796
2797   return $orig;
2798 }
2799
2800 sub result_source {
2801     my $self = shift;
2802
2803     if (@_) {
2804         $self->_source_handle($_[0]->handle);
2805     } else {
2806         $self->_source_handle->resolve;
2807     }
2808 }
2809
2810 =head2 throw_exception
2811
2812 See L<DBIx::Class::Schema/throw_exception> for details.
2813
2814 =cut
2815
2816 sub throw_exception {
2817   my $self=shift;
2818   if (ref $self && $self->_source_handle->schema) {
2819     $self->_source_handle->schema->throw_exception(@_)
2820   } else {
2821     croak(@_);
2822   }
2823
2824 }
2825
2826 # XXX: FIXME: Attributes docs need clearing up
2827
2828 =head1 ATTRIBUTES
2829
2830 Attributes are used to refine a ResultSet in various ways when
2831 searching for data. They can be passed to any method which takes an
2832 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2833 L</count>.
2834
2835 These are in no particular order:
2836
2837 =head2 order_by
2838
2839 =over 4
2840
2841 =item Value: ( $order_by | \@order_by | \%order_by )
2842
2843 =back
2844
2845 Which column(s) to order the results by. If a single column name, or
2846 an arrayref of names is supplied, the argument is passed through
2847 directly to SQL. The hashref syntax allows for connection-agnostic
2848 specification of ordering direction:
2849
2850  For descending order:
2851
2852   order_by => { -desc => [qw/col1 col2 col3/] }
2853
2854  For explicit ascending order:
2855
2856   order_by => { -asc => 'col' }
2857
2858 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2859 supported, although you are strongly encouraged to use the hashref
2860 syntax as outlined above.
2861
2862 =head2 columns
2863
2864 =over 4
2865
2866 =item Value: \@columns
2867
2868 =back
2869
2870 Shortcut to request a particular set of columns to be retrieved. Each
2871 column spec may be a string (a table column name), or a hash (in which
2872 case the key is the C<as> value, and the value is used as the C<select>
2873 expression). Adds C<me.> onto the start of any column without a C<.> in
2874 it and sets C<select> from that, then auto-populates C<as> from
2875 C<select> as normal. (You may also use the C<cols> attribute, as in
2876 earlier versions of DBIC.)
2877
2878 =head2 +columns
2879
2880 =over 4
2881
2882 =item Value: \@columns
2883
2884 =back
2885
2886 Indicates additional columns to be selected from storage. Works the same
2887 as L</columns> but adds columns to the selection. (You may also use the
2888 C<include_columns> attribute, as in earlier versions of DBIC). For
2889 example:-
2890
2891   $schema->resultset('CD')->search(undef, {
2892     '+columns' => ['artist.name'],
2893     join => ['artist']
2894   });
2895
2896 would return all CDs and include a 'name' column to the information
2897 passed to object inflation. Note that the 'artist' is the name of the
2898 column (or relationship) accessor, and 'name' is the name of the column
2899 accessor in the related table.
2900
2901 =head2 include_columns
2902
2903 =over 4
2904
2905 =item Value: \@columns
2906
2907 =back
2908
2909 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2910
2911 =head2 select
2912
2913 =over 4
2914
2915 =item Value: \@select_columns
2916
2917 =back
2918
2919 Indicates which columns should be selected from the storage. You can use
2920 column names, or in the case of RDBMS back ends, function or stored procedure
2921 names:
2922
2923   $rs = $schema->resultset('Employee')->search(undef, {
2924     select => [
2925       'name',
2926       { count => 'employeeid' },
2927       { sum => 'salary' }
2928     ]
2929   });
2930
2931 When you use function/stored procedure names and do not supply an C<as>
2932 attribute, the column names returned are storage-dependent. E.g. MySQL would
2933 return a column named C<count(employeeid)> in the above example.
2934
2935 =head2 +select
2936
2937 =over 4
2938
2939 Indicates additional columns to be selected from storage.  Works the same as
2940 L</select> but adds columns to the selection.
2941
2942 =back
2943
2944 =head2 +as
2945
2946 =over 4
2947
2948 Indicates additional column names for those added via L</+select>. See L</as>.
2949
2950 =back
2951
2952 =head2 as
2953
2954 =over 4
2955
2956 =item Value: \@inflation_names
2957
2958 =back
2959
2960 Indicates column names for object inflation. That is, C<as>
2961 indicates the name that the column can be accessed as via the
2962 C<get_column> method (or via the object accessor, B<if one already
2963 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2964
2965 The C<as> attribute is used in conjunction with C<select>,
2966 usually when C<select> contains one or more function or stored
2967 procedure names:
2968
2969   $rs = $schema->resultset('Employee')->search(undef, {
2970     select => [
2971       'name',
2972       { count => 'employeeid' }
2973     ],
2974     as => ['name', 'employee_count'],
2975   });
2976
2977   my $employee = $rs->first(); # get the first Employee
2978
2979 If the object against which the search is performed already has an accessor
2980 matching a column name specified in C<as>, the value can be retrieved using
2981 the accessor as normal:
2982
2983   my $name = $employee->name();
2984
2985 If on the other hand an accessor does not exist in the object, you need to
2986 use C<get_column> instead:
2987
2988   my $employee_count = $employee->get_column('employee_count');
2989
2990 You can create your own accessors if required - see
2991 L<DBIx::Class::Manual::Cookbook> for details.
2992
2993 Please note: This will NOT insert an C<AS employee_count> into the SQL
2994 statement produced, it is used for internal access only. Thus
2995 attempting to use the accessor in an C<order_by> clause or similar
2996 will fail miserably.
2997
2998 To get around this limitation, you can supply literal SQL to your
2999 C<select> attibute that contains the C<AS alias> text, eg:
3000
3001   select => [\'myfield AS alias']
3002
3003 =head2 join
3004
3005 =over 4
3006
3007 =item Value: ($rel_name | \@rel_names | \%rel_names)
3008
3009 =back
3010
3011 Contains a list of relationships that should be joined for this query.  For
3012 example:
3013
3014   # Get CDs by Nine Inch Nails
3015   my $rs = $schema->resultset('CD')->search(
3016     { 'artist.name' => 'Nine Inch Nails' },
3017     { join => 'artist' }
3018   );
3019
3020 Can also contain a hash reference to refer to the other relation's relations.
3021 For example:
3022
3023   package MyApp::Schema::Track;
3024   use base qw/DBIx::Class/;
3025   __PACKAGE__->table('track');
3026   __PACKAGE__->add_columns(qw/trackid cd position title/);
3027   __PACKAGE__->set_primary_key('trackid');
3028   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3029   1;
3030
3031   # In your application
3032   my $rs = $schema->resultset('Artist')->search(
3033     { 'track.title' => 'Teardrop' },
3034     {
3035       join     => { cd => 'track' },
3036       order_by => 'artist.name',
3037     }
3038   );
3039
3040 You need to use the relationship (not the table) name in  conditions,
3041 because they are aliased as such. The current table is aliased as "me", so
3042 you need to use me.column_name in order to avoid ambiguity. For example:
3043
3044   # Get CDs from 1984 with a 'Foo' track
3045   my $rs = $schema->resultset('CD')->search(
3046     {
3047       'me.year' => 1984,
3048       'tracks.name' => 'Foo'
3049     },
3050     { join => 'tracks' }
3051   );
3052
3053 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3054 similarly for a third time). For e.g.
3055
3056   my $rs = $schema->resultset('Artist')->search({
3057     'cds.title'   => 'Down to Earth',
3058     'cds_2.title' => 'Popular',
3059   }, {
3060     join => [ qw/cds cds/ ],
3061   });
3062
3063 will return a set of all artists that have both a cd with title 'Down
3064 to Earth' and a cd with title 'Popular'.
3065
3066 If you want to fetch related objects from other tables as well, see C<prefetch>
3067 below.
3068
3069 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3070
3071 =head2 prefetch
3072
3073 =over 4
3074
3075 =item Value: ($rel_name | \@rel_names | \%rel_names)
3076
3077 =back
3078
3079 Contains one or more relationships that should be fetched along with
3080 the main query (when they are accessed afterwards the data will
3081 already be available, without extra queries to the database).  This is
3082 useful for when you know you will need the related objects, because it
3083 saves at least one query:
3084
3085   my $rs = $schema->resultset('Tag')->search(
3086     undef,
3087     {
3088       prefetch => {
3089         cd => 'artist'
3090       }
3091     }
3092   );
3093
3094 The initial search results in SQL like the following:
3095
3096   SELECT tag.*, cd.*, artist.* FROM tag
3097   JOIN cd ON tag.cd = cd.cdid
3098   JOIN artist ON cd.artist = artist.artistid
3099
3100 L<DBIx::Class> has no need to go back to the database when we access the
3101 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3102 case.
3103
3104 Simple prefetches will be joined automatically, so there is no need
3105 for a C<join> attribute in the above search.
3106
3107 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3108 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3109 with an accessor type of 'single' or 'filter'). A more complex example that
3110 prefetches an artists cds, the tracks on those cds, and the tags associted
3111 with that artist is given below (assuming many-to-many from artists to tags):
3112
3113  my $rs = $schema->resultset('Artist')->search(
3114    undef,
3115    {
3116      prefetch => [
3117        { cds => 'tracks' },
3118        { artist_tags => 'tags' }
3119      ]
3120    }
3121  );
3122
3123
3124 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3125 attributes will be ignored.
3126
3127 =head2 page
3128
3129 =over 4
3130
3131 =item Value: $page
3132
3133 =back
3134
3135 Makes the resultset paged and specifies the page to retrieve. Effectively
3136 identical to creating a non-pages resultset and then calling ->page($page)
3137 on it.
3138
3139 If L<rows> attribute is not specified it defualts to 10 rows per page.
3140
3141 When you have a paged resultset, L</count> will only return the number
3142 of rows in the page. To get the total, use the L</pager> and call
3143 C<total_entries> on it.
3144
3145 =head2 rows
3146
3147 =over 4
3148
3149 =item Value: $rows
3150
3151 =back
3152
3153 Specifes the maximum number of rows for direct retrieval or the number of
3154 rows per page if the page attribute or method is used.
3155
3156 =head2 offset
3157
3158 =over 4
3159
3160 =item Value: $offset
3161
3162 =back
3163
3164 Specifies the (zero-based) row number for the  first row to be returned, or the
3165 of the first row of the first page if paging is used.
3166
3167 =head2 group_by
3168
3169 =over 4
3170
3171 =item Value: \@columns
3172
3173 =back
3174
3175 A arrayref of columns to group by. Can include columns of joined tables.
3176
3177   group_by => [qw/ column1 column2 ... /]
3178
3179 =head2 having
3180
3181 =over 4
3182
3183 =item Value: $condition
3184
3185 =back
3186
3187 HAVING is a select statement attribute that is applied between GROUP BY and
3188 ORDER BY. It is applied to the after the grouping calculations have been
3189 done.
3190
3191   having => { 'count(employee)' => { '>=', 100 } }
3192
3193 =head2 distinct
3194
3195 =over 4
3196
3197 =item Value: (0 | 1)
3198
3199 =back
3200
3201 Set to 1 to group by all columns.
3202
3203 =head2 where
3204
3205 =over 4
3206
3207 Adds to the WHERE clause.
3208
3209   # only return rows WHERE deleted IS NULL for all searches
3210   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3211
3212 Can be overridden by passing C<{ where => undef }> as an attribute
3213 to a resulset.
3214
3215 =back
3216
3217 =head2 cache
3218
3219 Set to 1 to cache search results. This prevents extra SQL queries if you
3220 revisit rows in your ResultSet:
3221
3222   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3223
3224   while( my $artist = $resultset->next ) {
3225     ... do stuff ...
3226   }
3227
3228   $rs->first; # without cache, this would issue a query
3229
3230 By default, searches are not cached.
3231
3232 For more examples of using these attributes, see
3233 L<DBIx::Class::Manual::Cookbook>.
3234
3235 =head2 from
3236
3237 =over 4
3238
3239 =item Value: \@from_clause
3240
3241 =back
3242
3243 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3244 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3245 clauses.
3246
3247 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3248
3249 C<join> will usually do what you need and it is strongly recommended that you
3250 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3251 And we really do mean "cannot", not just tried and failed. Attempting to use
3252 this because you're having problems with C<join> is like trying to use x86
3253 ASM because you've got a syntax error in your C. Trust us on this.
3254
3255 Now, if you're still really, really sure you need to use this (and if you're
3256 not 100% sure, ask the mailing list first), here's an explanation of how this
3257 works.
3258
3259 The syntax is as follows -
3260
3261   [
3262     { <alias1> => <table1> },
3263     [
3264       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3265       [], # nested JOIN (optional)
3266       { <table1.column1> => <table2.column2>, ... (more conditions) },
3267     ],
3268     # More of the above [ ] may follow for additional joins
3269   ]
3270
3271   <table1> <alias1>
3272   JOIN
3273     <table2> <alias2>
3274     [JOIN ...]
3275   ON <table1.column1> = <table2.column2>
3276   <more joins may follow>
3277
3278 An easy way to follow the examples below is to remember the following:
3279
3280     Anything inside "[]" is a JOIN
3281     Anything inside "{}" is a condition for the enclosing JOIN
3282
3283 The following examples utilize a "person" table in a family tree application.
3284 In order to express parent->child relationships, this table is self-joined:
3285
3286     # Person->belongs_to('father' => 'Person');
3287     # Person->belongs_to('mother' => 'Person');
3288
3289 C<from> can be used to nest joins. Here we return all children with a father,
3290 then search against all mothers of those children:
3291
3292   $rs = $schema->resultset('Person')->search(
3293       undef,
3294       {
3295           alias => 'mother', # alias columns in accordance with "from"
3296           from => [
3297               { mother => 'person' },
3298               [
3299                   [
3300                       { child => 'person' },
3301                       [
3302                           { father => 'person' },
3303                           { 'father.person_id' => 'child.father_id' }
3304                       ]
3305                   ],
3306                   { 'mother.person_id' => 'child.mother_id' }
3307               ],
3308           ]
3309       },
3310   );
3311
3312   # Equivalent SQL:
3313   # SELECT mother.* FROM person mother
3314   # JOIN (
3315   #   person child
3316   #   JOIN person father
3317   #   ON ( father.person_id = child.father_id )
3318   # )
3319   # ON ( mother.person_id = child.mother_id )
3320
3321 The type of any join can be controlled manually. To search against only people
3322 with a father in the person table, we could explicitly use C<INNER JOIN>:
3323
3324     $rs = $schema->resultset('Person')->search(
3325         undef,
3326         {
3327             alias => 'child', # alias columns in accordance with "from"
3328             from => [
3329                 { child => 'person' },
3330                 [
3331                     { father => 'person', -join_type => 'inner' },
3332                     { 'father.id' => 'child.father_id' }
3333                 ],
3334             ]
3335         },
3336     );
3337
3338     # Equivalent SQL:
3339     # SELECT child.* FROM person child
3340     # INNER JOIN person father ON child.father_id = father.id
3341
3342 If you need to express really complex joins or you need a subselect, you
3343 can supply literal SQL to C<from> via a scalar reference. In this case
3344 the contents of the scalar will replace the table name asscoiated with the
3345 resultsource.
3346
3347 WARNING: This technique might very well not work as expected on chained
3348 searches - you have been warned.
3349
3350     # Assuming the Event resultsource is defined as:
3351
3352         MySchema::Event->add_columns (
3353             sequence => {
3354                 data_type => 'INT',
3355                 is_auto_increment => 1,
3356             },
3357             location => {
3358                 data_type => 'INT',
3359             },
3360             type => {
3361                 data_type => 'INT',
3362             },
3363         );
3364         MySchema::Event->set_primary_key ('sequence');
3365
3366     # This will get back the latest event for every location. The column
3367     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3368     # combo to limit the resultset
3369
3370     $rs = $schema->resultset('Event');
3371     $table = $rs->result_source->name;
3372     $latest = $rs->search (
3373         undef,
3374         { from => \ "
3375             (SELECT e1.* FROM $table e1
3376                 JOIN $table e2
3377                     ON e1.location = e2.location
3378                     AND e1.sequence < e2.sequence
3379                 WHERE e2.sequence is NULL
3380             ) me",
3381         },
3382     );
3383
3384     # Equivalent SQL (with the DBIC chunks added):
3385
3386     SELECT me.sequence, me.location, me.type FROM
3387        (SELECT e1.* FROM events e1
3388            JOIN events e2
3389                ON e1.location = e2.location
3390                AND e1.sequence < e2.sequence
3391            WHERE e2.sequence is NULL
3392        ) me;
3393
3394 =head2 for
3395
3396 =over 4
3397
3398 =item Value: ( 'update' | 'shared' )
3399
3400 =back
3401
3402 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3403 ... FOR SHARED.
3404
3405 =cut
3406
3407 1;