lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   return $self->{cursor}
 665     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 666           $attrs->{where},$attrs);
 667 }
 668
 669 =head2 single
 670
 671 =over 4
 672
 673 =item Arguments: $cond?
 674
 675 =item Return Value: $row_object?
 676
 677 =back
 678
 679   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 680
 681 Inflates the first result without creating a cursor if the resultset has
 682 any records in it; if not returns nothing. Used by L</find> as a lean version of
 683 L</search>.
 684
 685 While this method can take an optional search condition (just like L</search>)
 686 being a fast-code-path it does not recognize search attributes. If you need to
 687 add extra joins or similar, call L</search> and then chain-call L</single> on the
 688 L<DBIx::Class::ResultSet> returned.
 689
 690 =over
 691
 692 =item B<Note>
 693
 694 As of 0.08100, this method enforces the assumption that the preceeding
 695 query returns only one row. If more than one row is returned, you will receive
 696 a warning:
 697
 698   Query returned more than one row
 699
 700 In this case, you should be using L</first> or L</find> instead, or if you really
 701 know what you are doing, use the L</rows> attribute to explicitly limit the size
 702 of the resultset.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715   if ($where) {
 716     if (defined $attrs->{where}) {
 717       $attrs->{where} = {
 718         '-and' =>
 719             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 720                $where, delete $attrs->{where} ]
 721       };
 722     } else {
 723       $attrs->{where} = $where;
 724     }
 725   }
 726
 727 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 728 #  unless ($self->_is_unique_query($attrs->{where})) {
 729 #    carp "Query not guaranteed to return a single row"
 730 #      . "; please declare your unique constraints or use search instead";
 731 #  }
 732
 733   my @data = $self->result_source->storage->select_single(
 734     $attrs->{from}, $attrs->{select},
 735     $attrs->{where}, $attrs
 736   );
 737
 738   return (@data ? ($self->_construct_object(@data))[0] : undef);
 739 }
 740
 741 # _is_unique_query
 742 #
 743 # Try to determine if the specified query is guaranteed to be unique, based on
 744 # the declared unique constraints.
 745
 746 sub _is_unique_query {
 747   my ($self, $query) = @_;
 748
 749   my $collapsed = $self->_collapse_query($query);
 750   my $alias = $self->{attrs}{alias};
 751
 752   foreach my $name ($self->result_source->unique_constraint_names) {
 753     my @unique_cols = map {
 754       "$alias.$_"
 755     } $self->result_source->unique_constraint_columns($name);
 756
 757     # Count the values for each unique column
 758     my %seen = map { $_ => 0 } @unique_cols;
 759
 760     foreach my $key (keys %$collapsed) {
 761       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 762       next unless exists $seen{$aliased};  # Additional constraints are okay
 763       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 764     }
 765
 766     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 767     return 1 unless grep { $_ != 1 } values %seen;
 768   }
 769
 770   return 0;
 771 }
 772
 773 # _collapse_query
 774 #
 775 # Recursively collapse the query, accumulating values for each column.
 776
 777 sub _collapse_query {
 778   my ($self, $query, $collapsed) = @_;
 779
 780   $collapsed ||= {};
 781
 782   if (ref $query eq 'ARRAY') {
 783     foreach my $subquery (@$query) {
 784       next unless ref $subquery;  # -or
 785       $collapsed = $self->_collapse_query($subquery, $collapsed);
 786     }
 787   }
 788   elsif (ref $query eq 'HASH') {
 789     if (keys %$query and (keys %$query)[0] eq '-and') {
 790       foreach my $subquery (@{$query->{-and}}) {
 791         $collapsed = $self->_collapse_query($subquery, $collapsed);
 792       }
 793     }
 794     else {
 795       foreach my $col (keys %$query) {
 796         my $value = $query->{$col};
 797         $collapsed->{$col}{$value}++;
 798       }
 799     }
 800   }
 801
 802   return $collapsed;
 803 }
 804
 805 =head2 get_column
 806
 807 =over 4
 808
 809 =item Arguments: $cond?
 810
 811 =item Return Value: $resultsetcolumn
 812
 813 =back
 814
 815   my $max_length = $rs->get_column('length')->max;
 816
 817 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 818
 819 =cut
 820
 821 sub get_column {
 822   my ($self, $column) = @_;
 823   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 824   return $new;
 825 }
 826
 827 =head2 search_like
 828
 829 =over 4
 830
 831 =item Arguments: $cond, \%attrs?
 832
 833 =item Return Value: $resultset (scalar context), @row_objs (list context)
 834
 835 =back
 836
 837   # WHERE title LIKE '%blue%'
 838   $cd_rs = $rs->search_like({ title => '%blue%'});
 839
 840 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 841 that this is simply a convenience method retained for ex Class::DBI users.
 842 You most likely want to use L</search> with specific operators.
 843
 844 For more information, see L<DBIx::Class::Manual::Cookbook>.
 845
 846 This method is deprecated and will be removed in 0.09. Use L</search()>
 847 instead. An example conversion is:
 848
 849   ->search_like({ foo => 'bar' });
 850
 851   # Becomes
 852
 853   ->search({ foo => { like => 'bar' } });
 854
 855 =cut
 856
 857 sub search_like {
 858   my $class = shift;
 859   carp join ("\n",
 860     'search_like() is deprecated and will be removed in 0.09.',
 861     'Instead use ->search({ x => { -like => "y%" } })',
 862     '(note the outer pair of {}s - they are important!)'
 863   );
 864   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 865   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 866   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 867   return $class->search($query, { %$attrs });
 868 }
 869
 870 =head2 slice
 871
 872 =over 4
 873
 874 =item Arguments: $first, $last
 875
 876 =item Return Value: $resultset (scalar context), @row_objs (list context)
 877
 878 =back
 879
 880 Returns a resultset or object list representing a subset of elements from the
 881 resultset slice is called on. Indexes are from 0, i.e., to get the first
 882 three records, call:
 883
 884   my ($one, $two, $three) = $rs->slice(0, 2);
 885
 886 =cut
 887
 888 sub slice {
 889   my ($self, $min, $max) = @_;
 890   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 891   $attrs->{offset} = $self->{attrs}{offset} || 0;
 892   $attrs->{offset} += $min;
 893   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 894   return $self->search(undef(), $attrs);
 895   #my $slice = (ref $self)->new($self->result_source, $attrs);
 896   #return (wantarray ? $slice->all : $slice);
 897 }
 898
 899 =head2 next
 900
 901 =over 4
 902
 903 =item Arguments: none
 904
 905 =item Return Value: $result?
 906
 907 =back
 908
 909 Returns the next element in the resultset (C<undef> is there is none).
 910
 911 Can be used to efficiently iterate over records in the resultset:
 912
 913   my $rs = $schema->resultset('CD')->search;
 914   while (my $cd = $rs->next) {
 915     print $cd->title;
 916   }
 917
 918 Note that you need to store the resultset object, and call C<next> on it.
 919 Calling C<< resultset('Table')->next >> repeatedly will always return the
 920 first record from the resultset.
 921
 922 =cut
 923
 924 sub next {
 925   my ($self) = @_;
 926   if (my $cache = $self->get_cache) {
 927     $self->{all_cache_position} ||= 0;
 928     return $cache->[$self->{all_cache_position}++];
 929   }
 930   if ($self->{attrs}{cache}) {
 931     $self->{all_cache_position} = 1;
 932     return ($self->all)[0];
 933   }
 934   if ($self->{stashed_objects}) {
 935     my $obj = shift(@{$self->{stashed_objects}});
 936     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 937     return $obj;
 938   }
 939   my @row = (
 940     exists $self->{stashed_row}
 941       ? @{delete $self->{stashed_row}}
 942       : $self->cursor->next
 943   );
 944   return undef unless (@row);
 945   my ($row, @more) = $self->_construct_object(@row);
 946   $self->{stashed_objects} = \@more if @more;
 947   return $row;
 948 }
 949
 950 sub _construct_object {
 951   my ($self, @row) = @_;
 952   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 953   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 954   @new = $self->{_attrs}{record_filter}->(@new)
 955     if exists $self->{_attrs}{record_filter};
 956   return @new;
 957 }
 958
 959 sub _collapse_result {
 960   my ($self, $as_proto, $row) = @_;
 961
 962   my @copy = @$row;
 963
 964   # 'foo'         => [ undef, 'foo' ]
 965   # 'foo.bar'     => [ 'foo', 'bar' ]
 966   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 967
 968   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 969
 970   my %collapse = %{$self->{_attrs}{collapse}||{}};
 971
 972   my @pri_index;
 973
 974   # if we're doing collapsing (has_many prefetch) we need to grab records
 975   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 976   # we know we don't have to bother.
 977
 978   # the reason for not using the collapse stuff directly is because if you
 979   # had for e.g. two artists in a row with no cds, the collapse info for
 980   # both would be NULL (undef) so you'd lose the second artist
 981
 982   # store just the index so we can check the array positions from the row
 983   # without having to contruct the full hash
 984
 985   if (keys %collapse) {
 986     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
 987     foreach my $i (0 .. $#construct_as) {
 988       next if defined($construct_as[$i][0]); # only self table
 989       if (delete $pri{$construct_as[$i][1]}) {
 990         push(@pri_index, $i);
 991       }
 992       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
 993     }
 994   }
 995
 996   # no need to do an if, it'll be empty if @pri_index is empty anyway
 997
 998   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
 999
1000   my @const_rows;
1001
1002   do { # no need to check anything at the front, we always want the first row
1003
1004     my %const;
1005
1006     foreach my $this_as (@construct_as) {
1007       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1008     }
1009
1010     push(@const_rows, \%const);
1011
1012   } until ( # no pri_index => no collapse => drop straight out
1013       !@pri_index
1014     or
1015       do { # get another row, stash it, drop out if different PK
1016
1017         @copy = $self->cursor->next;
1018         $self->{stashed_row} = \@copy;
1019
1020         # last thing in do block, counts as true if anything doesn't match
1021
1022         # check xor defined first for NULL vs. NOT NULL then if one is
1023         # defined the other must be so check string equality
1024
1025         grep {
1026           (defined $pri_vals{$_} ^ defined $copy[$_])
1027           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1028         } @pri_index;
1029       }
1030   );
1031
1032   my $alias = $self->{attrs}{alias};
1033   my $info = [];
1034
1035   my %collapse_pos;
1036
1037   my @const_keys;
1038
1039   foreach my $const (@const_rows) {
1040     scalar @const_keys or do {
1041       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1042     };
1043     foreach my $key (@const_keys) {
1044       if (length $key) {
1045         my $target = $info;
1046         my @parts = split(/\./, $key);
1047         my $cur = '';
1048         my $data = $const->{$key};
1049         foreach my $p (@parts) {
1050           $target = $target->[1]->{$p} ||= [];
1051           $cur .= ".${p}";
1052           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1053             # collapsing at this point and on final part
1054             my $pos = $collapse_pos{$cur};
1055             CK: foreach my $ck (@ckey) {
1056               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1057                 $collapse_pos{$cur} = $data;
1058                 delete @collapse_pos{ # clear all positioning for sub-entries
1059                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1060                 };
1061                 push(@$target, []);
1062                 last CK;
1063               }
1064             }
1065           }
1066           if (exists $collapse{$cur}) {
1067             $target = $target->[-1];
1068           }
1069         }
1070         $target->[0] = $data;
1071       } else {
1072         $info->[0] = $const->{$key};
1073       }
1074     }
1075   }
1076
1077   return $info;
1078 }
1079
1080 =head2 result_source
1081
1082 =over 4
1083
1084 =item Arguments: $result_source?
1085
1086 =item Return Value: $result_source
1087
1088 =back
1089
1090 An accessor for the primary ResultSource object from which this ResultSet
1091 is derived.
1092
1093 =head2 result_class
1094
1095 =over 4
1096
1097 =item Arguments: $result_class?
1098
1099 =item Return Value: $result_class
1100
1101 =back
1102
1103 An accessor for the class to use when creating row objects. Defaults to
1104 C<< result_source->result_class >> - which in most cases is the name of the
1105 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1106
1107 Note that changing the result_class will also remove any components
1108 that were originally loaded in the source class via
1109 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1110 in the original source class will not run.
1111
1112 =cut
1113
1114 sub result_class {
1115   my ($self, $result_class) = @_;
1116   if ($result_class) {
1117     $self->ensure_class_loaded($result_class);
1118     $self->_result_class($result_class);
1119   }
1120   $self->_result_class;
1121 }
1122
1123 =head2 count
1124
1125 =over 4
1126
1127 =item Arguments: $cond, \%attrs??
1128
1129 =item Return Value: $count
1130
1131 =back
1132
1133 Performs an SQL C<COUNT> with the same query as the resultset was built
1134 with to find the number of elements. Passing arguments is equivalent to
1135 C<< $rs->search ($cond, \%attrs)->count >>
1136
1137 =cut
1138
1139 sub count {
1140   my $self = shift;
1141   return $self->search(@_)->count if @_ and defined $_[0];
1142   return scalar @{ $self->get_cache } if $self->get_cache;
1143
1144   my @grouped_subq_attrs = qw/prefetch collapse distinct group_by having/;
1145   my @subq_attrs = ();
1146
1147   my $attrs = $self->_resolved_attrs;
1148   # if we are not paged - we are simply asking for a limit
1149   if (not $attrs->{page} and not $attrs->{software_limit}) {
1150     push @subq_attrs, qw/rows offset/;
1151   }
1152
1153   my $need_subq = $self->_has_attr (@subq_attrs);
1154   my $need_group_subq = $self->_has_attr (@grouped_subq_attrs);
1155
1156   return ($need_subq || $need_group_subq)
1157     ? $self->_count_subq ($need_group_subq)
1158     : $self->_count_simple
1159 }
1160
1161 sub _count_subq {
1162   my ($self, $add_group_by) = @_;
1163
1164   my $attrs = $self->_resolved_attrs_copy;
1165
1166   # copy for the subquery, we need to do some adjustments to it too
1167   my $sub_attrs = { %$attrs };
1168
1169   # these can not go in the subquery, and there is no point of ordering it
1170   delete $sub_attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns order_by/;
1171
1172   # if needed force a group_by and the same set of columns (most databases require this)
1173   if ($add_group_by) {
1174     $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1175   }
1176
1177   $attrs->{from} = [{
1178     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1179   }];
1180
1181   # the subquery replaces this
1182   delete $attrs->{$_} for qw/where bind prefetch collapse distinct group_by having having_bind/;
1183
1184   return $self->__count ($attrs);
1185 }
1186
1187 sub _count_simple {
1188   my $self = shift;
1189
1190   my $count = $self->__count;
1191   return 0 unless $count;
1192
1193   # need to take offset from resolved attrs
1194
1195   my $attrs = $self->_resolved_attrs;
1196
1197   $count -= $attrs->{offset} if $attrs->{offset};
1198   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1199   $count = 0 if ($count < 0);
1200   return $count;
1201 }
1202
1203 sub __count {
1204   my ($self, $attrs) = @_;
1205
1206   $attrs ||= $self->_resolved_attrs_copy;
1207
1208   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1209   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1210
1211   $attrs->{select} = { count => '*' };
1212   $attrs->{as} = [qw/count/];
1213
1214   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1215   my ($count) = $tmp_rs->cursor->next;
1216
1217   return $count;
1218 }
1219
1220 sub _bool {
1221   return 1;
1222 }
1223
1224 =head2 count_literal
1225
1226 =over 4
1227
1228 =item Arguments: $sql_fragment, @bind_values
1229
1230 =item Return Value: $count
1231
1232 =back
1233
1234 Counts the results in a literal query. Equivalent to calling L</search_literal>
1235 with the passed arguments, then L</count>.
1236
1237 =cut
1238
1239 sub count_literal { shift->search_literal(@_)->count; }
1240
1241 =head2 all
1242
1243 =over 4
1244
1245 =item Arguments: none
1246
1247 =item Return Value: @objects
1248
1249 =back
1250
1251 Returns all elements in the resultset. Called implicitly if the resultset
1252 is returned in list context.
1253
1254 =cut
1255
1256 sub all {
1257   my $self = shift;
1258   if(@_) {
1259       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1260   }
1261
1262   return @{ $self->get_cache } if $self->get_cache;
1263
1264   my @obj;
1265
1266   # TODO: don't call resolve here
1267   if (keys %{$self->_resolved_attrs->{collapse}}) {
1268 #  if ($self->{attrs}{prefetch}) {
1269       # Using $self->cursor->all is really just an optimisation.
1270       # If we're collapsing has_many prefetches it probably makes
1271       # very little difference, and this is cleaner than hacking
1272       # _construct_object to survive the approach
1273     my @row = $self->cursor->next;
1274     while (@row) {
1275       push(@obj, $self->_construct_object(@row));
1276       @row = (exists $self->{stashed_row}
1277                ? @{delete $self->{stashed_row}}
1278                : $self->cursor->next);
1279     }
1280   } else {
1281     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1282   }
1283
1284   $self->set_cache(\@obj) if $self->{attrs}{cache};
1285   return @obj;
1286 }
1287
1288 =head2 reset
1289
1290 =over 4
1291
1292 =item Arguments: none
1293
1294 =item Return Value: $self
1295
1296 =back
1297
1298 Resets the resultset's cursor, so you can iterate through the elements again.
1299
1300 =cut
1301
1302 sub reset {
1303   my ($self) = @_;
1304   delete $self->{_attrs} if exists $self->{_attrs};
1305   $self->{all_cache_position} = 0;
1306   $self->cursor->reset;
1307   return $self;
1308 }
1309
1310 =head2 first
1311
1312 =over 4
1313
1314 =item Arguments: none
1315
1316 =item Return Value: $object?
1317
1318 =back
1319
1320 Resets the resultset and returns an object for the first result (if the
1321 resultset returns anything).
1322
1323 =cut
1324
1325 sub first {
1326   return $_[0]->reset->next;
1327 }
1328
1329
1330 # _rs_update_delete
1331 #
1332 # Determines whether and what type of subquery is required for the $rs operation.
1333 # If grouping is necessary either supplies its own, or verifies the current one
1334 # After all is done delegates to the proper storage method.
1335
1336 sub _rs_update_delete {
1337   my ($self, $op, $values) = @_;
1338
1339   my $rsrc = $self->result_source;
1340
1341   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1342   my $needs_subq = $self->_has_attr (qw/row offset page/);
1343
1344   if ($needs_group_by_subq or $needs_subq) {
1345
1346     # make a new $rs selecting only the PKs (that's all we really need)
1347     my $attrs = $self->_resolved_attrs_copy;
1348
1349     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1350     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1351
1352     if ($needs_group_by_subq) {
1353       # make sure no group_by was supplied, or if there is one - make sure it matches
1354       # the columns compiled above perfectly. Anything else can not be sanely executed
1355       # on most databases so croak right then and there
1356
1357       if (my $g = $attrs->{group_by}) {
1358         my @current_group_by = map
1359           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1360           (ref $g eq 'ARRAY' ? @$g : $g );
1361
1362         if (
1363           join ("\x00", sort @current_group_by)
1364             ne
1365           join ("\x00", sort @{$attrs->{columns}} )
1366         ) {
1367           $self->throw_exception (
1368             "You have just attempted a $op operation on a resultset which does group_by"
1369             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1370             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1371             . ' kind of queries. Please retry the operation with a modified group_by or'
1372             . ' without using one at all.'
1373           );
1374         }
1375       }
1376       else {
1377         $attrs->{group_by} = $attrs->{columns};
1378       }
1379     }
1380
1381     my $subrs = (ref $self)->new($rsrc, $attrs);
1382
1383     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1384   }
1385   else {
1386     return $rsrc->storage->$op(
1387       $rsrc,
1388       $op eq 'update' ? $values : (),
1389       $self->_cond_for_update_delete,
1390     );
1391   }
1392 }
1393
1394
1395 # _cond_for_update_delete
1396 #
1397 # update/delete require the condition to be modified to handle
1398 # the differing SQL syntax available.  This transforms the $self->{cond}
1399 # appropriately, returning the new condition.
1400
1401 sub _cond_for_update_delete {
1402   my ($self, $full_cond) = @_;
1403   my $cond = {};
1404
1405   $full_cond ||= $self->{cond};
1406   # No-op. No condition, we're updating/deleting everything
1407   return $cond unless ref $full_cond;
1408
1409   if (ref $full_cond eq 'ARRAY') {
1410     $cond = [
1411       map {
1412         my %hash;
1413         foreach my $key (keys %{$_}) {
1414           $key =~ /([^.]+)$/;
1415           $hash{$1} = $_->{$key};
1416         }
1417         \%hash;
1418       } @{$full_cond}
1419     ];
1420   }
1421   elsif (ref $full_cond eq 'HASH') {
1422     if ((keys %{$full_cond})[0] eq '-and') {
1423       $cond->{-and} = [];
1424       my @cond = @{$full_cond->{-and}};
1425        for (my $i = 0; $i < @cond; $i++) {
1426         my $entry = $cond[$i];
1427         my $hash;
1428         if (ref $entry eq 'HASH') {
1429           $hash = $self->_cond_for_update_delete($entry);
1430         }
1431         else {
1432           $entry =~ /([^.]+)$/;
1433           $hash->{$1} = $cond[++$i];
1434         }
1435         push @{$cond->{-and}}, $hash;
1436       }
1437     }
1438     else {
1439       foreach my $key (keys %{$full_cond}) {
1440         $key =~ /([^.]+)$/;
1441         $cond->{$1} = $full_cond->{$key};
1442       }
1443     }
1444   }
1445   else {
1446     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1447   }
1448
1449   return $cond;
1450 }
1451
1452
1453 =head2 update
1454
1455 =over 4
1456
1457 =item Arguments: \%values
1458
1459 =item Return Value: $storage_rv
1460
1461 =back
1462
1463 Sets the specified columns in the resultset to the supplied values in a
1464 single query. Return value will be true if the update succeeded or false
1465 if no records were updated; exact type of success value is storage-dependent.
1466
1467 =cut
1468
1469 sub update {
1470   my ($self, $values) = @_;
1471   $self->throw_exception('Values for update must be a hash')
1472     unless ref $values eq 'HASH';
1473
1474   return $self->_rs_update_delete ('update', $values);
1475 }
1476
1477 =head2 update_all
1478
1479 =over 4
1480
1481 =item Arguments: \%values
1482
1483 =item Return Value: 1
1484
1485 =back
1486
1487 Fetches all objects and updates them one at a time. Note that C<update_all>
1488 will run DBIC cascade triggers, while L</update> will not.
1489
1490 =cut
1491
1492 sub update_all {
1493   my ($self, $values) = @_;
1494   $self->throw_exception('Values for update_all must be a hash')
1495     unless ref $values eq 'HASH';
1496   foreach my $obj ($self->all) {
1497     $obj->set_columns($values)->update;
1498   }
1499   return 1;
1500 }
1501
1502 =head2 delete
1503
1504 =over 4
1505
1506 =item Arguments: none
1507
1508 =item Return Value: 1
1509
1510 =back
1511
1512 Deletes the contents of the resultset from its result source. Note that this
1513 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1514 to run. See also L<DBIx::Class::Row/delete>.
1515
1516 delete may not generate correct SQL for a query with joins or a resultset
1517 chained from a related resultset.  In this case it will generate a warning:-
1518
1519 In these cases you may find that delete_all is more appropriate, or you
1520 need to respecify your query in a way that can be expressed without a join.
1521
1522 =cut
1523
1524 sub delete {
1525   my $self = shift;
1526   $self->throw_exception('delete does not accept any arguments')
1527     if @_;
1528
1529   return $self->_rs_update_delete ('delete');
1530 }
1531
1532 =head2 delete_all
1533
1534 =over 4
1535
1536 =item Arguments: none
1537
1538 =item Return Value: 1
1539
1540 =back
1541
1542 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1543 will run DBIC cascade triggers, while L</delete> will not.
1544
1545 =cut
1546
1547 sub delete_all {
1548   my $self = shift;
1549   $self->throw_exception('delete_all does not accept any arguments')
1550     if @_;
1551
1552   $_->delete for $self->all;
1553   return 1;
1554 }
1555
1556 =head2 populate
1557
1558 =over 4
1559
1560 =item Arguments: \@data;
1561
1562 =back
1563
1564 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1565 For the arrayref of hashrefs style each hashref should be a structure suitable
1566 forsubmitting to a $resultset->create(...) method.
1567
1568 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1569 to insert the data, as this is a faster method.
1570
1571 Otherwise, each set of data is inserted into the database using
1572 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1573 objects is returned.
1574
1575 Example:  Assuming an Artist Class that has many CDs Classes relating:
1576
1577   my $Artist_rs = $schema->resultset("Artist");
1578
1579   ## Void Context Example
1580   $Artist_rs->populate([
1581      { artistid => 4, name => 'Manufactured Crap', cds => [
1582         { title => 'My First CD', year => 2006 },
1583         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1584       ],
1585      },
1586      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1587         { title => 'My parents sold me to a record company' ,year => 2005 },
1588         { title => 'Why Am I So Ugly?', year => 2006 },
1589         { title => 'I Got Surgery and am now Popular', year => 2007 }
1590       ],
1591      },
1592   ]);
1593
1594   ## Array Context Example
1595   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1596     { name => "Artist One"},
1597     { name => "Artist Two"},
1598     { name => "Artist Three", cds=> [
1599     { title => "First CD", year => 2007},
1600     { title => "Second CD", year => 2008},
1601   ]}
1602   ]);
1603
1604   print $ArtistOne->name; ## response is 'Artist One'
1605   print $ArtistThree->cds->count ## reponse is '2'
1606
1607 For the arrayref of arrayrefs style,  the first element should be a list of the
1608 fieldsnames to which the remaining elements are rows being inserted.  For
1609 example:
1610
1611   $Arstist_rs->populate([
1612     [qw/artistid name/],
1613     [100, 'A Formally Unknown Singer'],
1614     [101, 'A singer that jumped the shark two albums ago'],
1615     [102, 'An actually cool singer.'],
1616   ]);
1617
1618 Please note an important effect on your data when choosing between void and
1619 wantarray context. Since void context goes straight to C<insert_bulk> in
1620 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1621 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1622 create primary keys for you, you will find that your PKs are empty.  In this
1623 case you will have to use the wantarray context in order to create those
1624 values.
1625
1626 =cut
1627
1628 sub populate {
1629   my $self = shift @_;
1630   my $data = ref $_[0][0] eq 'HASH'
1631     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1632     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1633
1634   if(defined wantarray) {
1635     my @created;
1636     foreach my $item (@$data) {
1637       push(@created, $self->create($item));
1638     }
1639     return @created;
1640   } else {
1641     my ($first, @rest) = @$data;
1642
1643     my @names = grep {!ref $first->{$_}} keys %$first;
1644     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1645     my @pks = $self->result_source->primary_columns;
1646
1647     ## do the belongs_to relationships
1648     foreach my $index (0..$#$data) {
1649       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1650         my @ret = $self->populate($data);
1651         return;
1652       }
1653
1654       foreach my $rel (@rels) {
1655         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1656         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1657         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1658         my $related = $result->result_source->_resolve_condition(
1659           $result->result_source->relationship_info($reverse)->{cond},
1660           $self,
1661           $result,
1662         );
1663
1664         delete $data->[$index]->{$rel};
1665         $data->[$index] = {%{$data->[$index]}, %$related};
1666
1667         push @names, keys %$related if $index == 0;
1668       }
1669     }
1670
1671     ## do bulk insert on current row
1672     my @values = map { [ @$_{@names} ] } @$data;
1673
1674     $self->result_source->storage->insert_bulk(
1675       $self->result_source,
1676       \@names,
1677       \@values,
1678     );
1679
1680     ## do the has_many relationships
1681     foreach my $item (@$data) {
1682
1683       foreach my $rel (@rels) {
1684         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1685
1686         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1687      || $self->throw_exception('Cannot find the relating object.');
1688
1689         my $child = $parent->$rel;
1690
1691         my $related = $child->result_source->_resolve_condition(
1692           $parent->result_source->relationship_info($rel)->{cond},
1693           $child,
1694           $parent,
1695         );
1696
1697         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1698         my @populate = map { {%$_, %$related} } @rows_to_add;
1699
1700         $child->populate( \@populate );
1701       }
1702     }
1703   }
1704 }
1705
1706 =head2 _normalize_populate_args ($args)
1707
1708 Private method used by L</populate> to normalize its incoming arguments.  Factored
1709 out in case you want to subclass and accept new argument structures to the
1710 L</populate> method.
1711
1712 =cut
1713
1714 sub _normalize_populate_args {
1715   my ($self, $data) = @_;
1716   my @names = @{shift(@$data)};
1717   my @results_to_create;
1718   foreach my $datum (@$data) {
1719     my %result_to_create;
1720     foreach my $index (0..$#names) {
1721       $result_to_create{$names[$index]} = $$datum[$index];
1722     }
1723     push @results_to_create, \%result_to_create;
1724   }
1725   return \@results_to_create;
1726 }
1727
1728 =head2 pager
1729
1730 =over 4
1731
1732 =item Arguments: none
1733
1734 =item Return Value: $pager
1735
1736 =back
1737
1738 Return Value a L<Data::Page> object for the current resultset. Only makes
1739 sense for queries with a C<page> attribute.
1740
1741 To get the full count of entries for a paged resultset, call
1742 C<total_entries> on the L<Data::Page> object.
1743
1744 =cut
1745
1746 sub pager {
1747   my ($self) = @_;
1748
1749   return $self->{pager} if $self->{pager};
1750
1751   my $attrs = $self->{attrs};
1752   $self->throw_exception("Can't create pager for non-paged rs")
1753     unless $self->{attrs}{page};
1754   $attrs->{rows} ||= 10;
1755
1756   # throw away the paging flags and re-run the count (possibly
1757   # with a subselect) to get the real total count
1758   my $count_attrs = { %$attrs };
1759   delete $count_attrs->{$_} for qw/rows offset page pager/;
1760   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1761
1762   return $self->{pager} = Data::Page->new(
1763     $total_count,
1764     $attrs->{rows},
1765     $self->{attrs}{page}
1766   );
1767 }
1768
1769 =head2 page
1770
1771 =over 4
1772
1773 =item Arguments: $page_number
1774
1775 =item Return Value: $rs
1776
1777 =back
1778
1779 Returns a resultset for the $page_number page of the resultset on which page
1780 is called, where each page contains a number of rows equal to the 'rows'
1781 attribute set on the resultset (10 by default).
1782
1783 =cut
1784
1785 sub page {
1786   my ($self, $page) = @_;
1787   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1788 }
1789
1790 =head2 new_result
1791
1792 =over 4
1793
1794 =item Arguments: \%vals
1795
1796 =item Return Value: $rowobject
1797
1798 =back
1799
1800 Creates a new row object in the resultset's result class and returns
1801 it. The row is not inserted into the database at this point, call
1802 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1803 will tell you whether the row object has been inserted or not.
1804
1805 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1806
1807 =cut
1808
1809 sub new_result {
1810   my ($self, $values) = @_;
1811   $self->throw_exception( "new_result needs a hash" )
1812     unless (ref $values eq 'HASH');
1813
1814   my %new;
1815   my $alias = $self->{attrs}{alias};
1816
1817   if (
1818     defined $self->{cond}
1819     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1820   ) {
1821     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1822     $new{-from_resultset} = [ keys %new ] if keys %new;
1823   } else {
1824     $self->throw_exception(
1825       "Can't abstract implicit construct, condition not a hash"
1826     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1827
1828     my $collapsed_cond = (
1829       $self->{cond}
1830         ? $self->_collapse_cond($self->{cond})
1831         : {}
1832     );
1833
1834     # precendence must be given to passed values over values inherited from
1835     # the cond, so the order here is important.
1836     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1837     while( my($col,$value) = each %implied ){
1838       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1839         $new{$col} = $value->{'='};
1840         next;
1841       }
1842       $new{$col} = $value if $self->_is_deterministic_value($value);
1843     }
1844   }
1845
1846   %new = (
1847     %new,
1848     %{ $self->_remove_alias($values, $alias) },
1849     -source_handle => $self->_source_handle,
1850     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1851   );
1852
1853   return $self->result_class->new(\%new);
1854 }
1855
1856 # _is_deterministic_value
1857 #
1858 # Make an effor to strip non-deterministic values from the condition,
1859 # to make sure new_result chokes less
1860
1861 sub _is_deterministic_value {
1862   my $self = shift;
1863   my $value = shift;
1864   my $ref_type = ref $value;
1865   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1866   return 1 if Scalar::Util::blessed($value);
1867   return 0;
1868 }
1869
1870 # _has_attr
1871 #
1872 # determines if the resultset defines at least one
1873 # of the attributes supplied
1874 #
1875 # used to determine if a subquery is neccessary
1876
1877 sub _has_attr {
1878   my ($self, @attr_names) = @_;
1879
1880   my $attrs = $self->_resolved_attrs;
1881
1882   my $join_check_req;
1883
1884   for my $n (@attr_names) {
1885     ++$join_check_req if $n =~ /join/;
1886
1887     my $attr =  $attrs->{$n};
1888
1889     next if not defined $attr;
1890
1891     if (ref $attr eq 'HASH') {
1892       return 1 if keys %$attr;
1893     }
1894     elsif (ref $attr eq 'ARRAY') {
1895       return 1 if @$attr;
1896     }
1897     else {
1898       return 1 if $attr;
1899     }
1900   }
1901
1902   # a join can be expressed as a multi-level from
1903   return 1 if (
1904     $join_check_req
1905       and
1906     ref $attrs->{from} eq 'ARRAY'
1907       and
1908     @{$attrs->{from}} > 1
1909   );
1910
1911   return 0;
1912 }
1913
1914 # _collapse_cond
1915 #
1916 # Recursively collapse the condition.
1917
1918 sub _collapse_cond {
1919   my ($self, $cond, $collapsed) = @_;
1920
1921   $collapsed ||= {};
1922
1923   if (ref $cond eq 'ARRAY') {
1924     foreach my $subcond (@$cond) {
1925       next unless ref $subcond;  # -or
1926       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1927     }
1928   }
1929   elsif (ref $cond eq 'HASH') {
1930     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1931       foreach my $subcond (@{$cond->{-and}}) {
1932         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1933       }
1934     }
1935     else {
1936       foreach my $col (keys %$cond) {
1937         my $value = $cond->{$col};
1938         $collapsed->{$col} = $value;
1939       }
1940     }
1941   }
1942
1943   return $collapsed;
1944 }
1945
1946 # _remove_alias
1947 #
1948 # Remove the specified alias from the specified query hash. A copy is made so
1949 # the original query is not modified.
1950
1951 sub _remove_alias {
1952   my ($self, $query, $alias) = @_;
1953
1954   my %orig = %{ $query || {} };
1955   my %unaliased;
1956
1957   foreach my $key (keys %orig) {
1958     if ($key !~ /\./) {
1959       $unaliased{$key} = $orig{$key};
1960       next;
1961     }
1962     $unaliased{$1} = $orig{$key}
1963       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1964   }
1965
1966   return \%unaliased;
1967 }
1968
1969 =head2 as_query (EXPERIMENTAL)
1970
1971 =over 4
1972
1973 =item Arguments: none
1974
1975 =item Return Value: \[ $sql, @bind ]
1976
1977 =back
1978
1979 Returns the SQL query and bind vars associated with the invocant.
1980
1981 This is generally used as the RHS for a subquery.
1982
1983 B<NOTE>: This feature is still experimental.
1984
1985 =cut
1986
1987 sub as_query { return shift->cursor->as_query(@_) }
1988
1989 =head2 find_or_new
1990
1991 =over 4
1992
1993 =item Arguments: \%vals, \%attrs?
1994
1995 =item Return Value: $rowobject
1996
1997 =back
1998
1999   my $artist = $schema->resultset('Artist')->find_or_new(
2000     { artist => 'fred' }, { key => 'artists' });
2001
2002   $cd->cd_to_producer->find_or_new({ producer => $producer },
2003                                    { key => 'primary });
2004
2005 Find an existing record from this resultset, based on its primary
2006 key, or a unique constraint. If none exists, instantiate a new result
2007 object and return it. The object will not be saved into your storage
2008 until you call L<DBIx::Class::Row/insert> on it.
2009
2010 You most likely want this method when looking for existing rows using
2011 a unique constraint that is not the primary key, or looking for
2012 related rows.
2013
2014 If you want objects to be saved immediately, use L</find_or_create> instead.
2015
2016 B<Note>: C<find_or_new> is probably not what you want when creating a
2017 new row in a table that uses primary keys supplied by the
2018 database. Passing in a primary key column with a value of I<undef>
2019 will cause L</find> to attempt to search for a row with a value of
2020 I<NULL>.
2021
2022 =cut
2023
2024 sub find_or_new {
2025   my $self     = shift;
2026   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2027   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2028   my $exists   = $self->find($hash, $attrs);
2029   return defined $exists ? $exists : $self->new_result($hash);
2030 }
2031
2032 =head2 create
2033
2034 =over 4
2035
2036 =item Arguments: \%vals
2037
2038 =item Return Value: a L<DBIx::Class::Row> $object
2039
2040 =back
2041
2042 Attempt to create a single new row or a row with multiple related rows
2043 in the table represented by the resultset (and related tables). This
2044 will not check for duplicate rows before inserting, use
2045 L</find_or_create> to do that.
2046
2047 To create one row for this resultset, pass a hashref of key/value
2048 pairs representing the columns of the table and the values you wish to
2049 store. If the appropriate relationships are set up, foreign key fields
2050 can also be passed an object representing the foreign row, and the
2051 value will be set to its primary key.
2052
2053 To create related objects, pass a hashref for the value if the related
2054 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2055 and use the name of the relationship as the key. (NOT the name of the field,
2056 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2057 of hashrefs containing the data for each of the rows to create in the foreign
2058 tables, again using the relationship name as the key.
2059
2060 Instead of hashrefs of plain related data (key/value pairs), you may
2061 also pass new or inserted objects. New objects (not inserted yet, see
2062 L</new>), will be inserted into their appropriate tables.
2063
2064 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2065
2066 Example of creating a new row.
2067
2068   $person_rs->create({
2069     name=>"Some Person",
2070     email=>"somebody@someplace.com"
2071   });
2072
2073 Example of creating a new row and also creating rows in a related C<has_many>
2074 or C<has_one> resultset.  Note Arrayref.
2075
2076   $artist_rs->create(
2077      { artistid => 4, name => 'Manufactured Crap', cds => [
2078         { title => 'My First CD', year => 2006 },
2079         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2080       ],
2081      },
2082   );
2083
2084 Example of creating a new row and also creating a row in a related
2085 C<belongs_to>resultset. Note Hashref.
2086
2087   $cd_rs->create({
2088     title=>"Music for Silly Walks",
2089     year=>2000,
2090     artist => {
2091       name=>"Silly Musician",
2092     }
2093   });
2094
2095 =cut
2096
2097 sub create {
2098   my ($self, $attrs) = @_;
2099   $self->throw_exception( "create needs a hashref" )
2100     unless ref $attrs eq 'HASH';
2101   return $self->new_result($attrs)->insert;
2102 }
2103
2104 =head2 find_or_create
2105
2106 =over 4
2107
2108 =item Arguments: \%vals, \%attrs?
2109
2110 =item Return Value: $rowobject
2111
2112 =back
2113
2114   $cd->cd_to_producer->find_or_create({ producer => $producer },
2115                                       { key => 'primary });
2116
2117 Tries to find a record based on its primary key or unique constraints; if none
2118 is found, creates one and returns that instead.
2119
2120   my $cd = $schema->resultset('CD')->find_or_create({
2121     cdid   => 5,
2122     artist => 'Massive Attack',
2123     title  => 'Mezzanine',
2124     year   => 2005,
2125   });
2126
2127 Also takes an optional C<key> attribute, to search by a specific key or unique
2128 constraint. For example:
2129
2130   my $cd = $schema->resultset('CD')->find_or_create(
2131     {
2132       artist => 'Massive Attack',
2133       title  => 'Mezzanine',
2134     },
2135     { key => 'cd_artist_title' }
2136   );
2137
2138 B<Note>: Because find_or_create() reads from the database and then
2139 possibly inserts based on the result, this method is subject to a race
2140 condition. Another process could create a record in the table after
2141 the find has completed and before the create has started. To avoid
2142 this problem, use find_or_create() inside a transaction.
2143
2144 B<Note>: C<find_or_create> is probably not what you want when creating
2145 a new row in a table that uses primary keys supplied by the
2146 database. Passing in a primary key column with a value of I<undef>
2147 will cause L</find> to attempt to search for a row with a value of
2148 I<NULL>.
2149
2150 See also L</find> and L</update_or_create>. For information on how to declare
2151 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2152
2153 =cut
2154
2155 sub find_or_create {
2156   my $self     = shift;
2157   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2158   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2159   my $exists   = $self->find($hash, $attrs);
2160   return defined $exists ? $exists : $self->create($hash);
2161 }
2162
2163 =head2 update_or_create
2164
2165 =over 4
2166
2167 =item Arguments: \%col_values, { key => $unique_constraint }?
2168
2169 =item Return Value: $rowobject
2170
2171 =back
2172
2173   $resultset->update_or_create({ col => $val, ... });
2174
2175 First, searches for an existing row matching one of the unique constraints
2176 (including the primary key) on the source of this resultset. If a row is
2177 found, updates it with the other given column values. Otherwise, creates a new
2178 row.
2179
2180 Takes an optional C<key> attribute to search on a specific unique constraint.
2181 For example:
2182
2183   # In your application
2184   my $cd = $schema->resultset('CD')->update_or_create(
2185     {
2186       artist => 'Massive Attack',
2187       title  => 'Mezzanine',
2188       year   => 1998,
2189     },
2190     { key => 'cd_artist_title' }
2191   );
2192
2193   $cd->cd_to_producer->update_or_create({
2194     producer => $producer,
2195     name => 'harry',
2196   }, {
2197     key => 'primary,
2198   });
2199
2200
2201 If no C<key> is specified, it searches on all unique constraints defined on the
2202 source, including the primary key.
2203
2204 If the C<key> is specified as C<primary>, it searches only on the primary key.
2205
2206 See also L</find> and L</find_or_create>. For information on how to declare
2207 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2208
2209 B<Note>: C<update_or_create> is probably not what you want when
2210 looking for a row in a table that uses primary keys supplied by the
2211 database, unless you actually have a key value. Passing in a primary
2212 key column with a value of I<undef> will cause L</find> to attempt to
2213 search for a row with a value of I<NULL>.
2214
2215 =cut
2216
2217 sub update_or_create {
2218   my $self = shift;
2219   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2220   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2221
2222   my $row = $self->find($cond, $attrs);
2223   if (defined $row) {
2224     $row->update($cond);
2225     return $row;
2226   }
2227
2228   return $self->create($cond);
2229 }
2230
2231 =head2 update_or_new
2232
2233 =over 4
2234
2235 =item Arguments: \%col_values, { key => $unique_constraint }?
2236
2237 =item Return Value: $rowobject
2238
2239 =back
2240
2241   $resultset->update_or_new({ col => $val, ... });
2242
2243 First, searches for an existing row matching one of the unique constraints
2244 (including the primary key) on the source of this resultset. If a row is
2245 found, updates it with the other given column values. Otherwise, instantiate
2246 a new result object and return it. The object will not be saved into your storage
2247 until you call L<DBIx::Class::Row/insert> on it.
2248
2249 Takes an optional C<key> attribute to search on a specific unique constraint.
2250 For example:
2251
2252   # In your application
2253   my $cd = $schema->resultset('CD')->update_or_new(
2254     {
2255       artist => 'Massive Attack',
2256       title  => 'Mezzanine',
2257       year   => 1998,
2258     },
2259     { key => 'cd_artist_title' }
2260   );
2261
2262   if ($cd->in_storage) {
2263       # the cd was updated
2264   }
2265   else {
2266       # the cd is not yet in the database, let's insert it
2267       $cd->insert;
2268   }
2269
2270 See also L</find>, L</find_or_create> and L<find_or_new>.
2271
2272 =cut
2273
2274 sub update_or_new {
2275     my $self  = shift;
2276     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2277     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2278
2279     my $row = $self->find( $cond, $attrs );
2280     if ( defined $row ) {
2281         $row->update($cond);
2282         return $row;
2283     }
2284
2285     return $self->new_result($cond);
2286 }
2287
2288 =head2 get_cache
2289
2290 =over 4
2291
2292 =item Arguments: none
2293
2294 =item Return Value: \@cache_objects?
2295
2296 =back
2297
2298 Gets the contents of the cache for the resultset, if the cache is set.
2299
2300 The cache is populated either by using the L</prefetch> attribute to
2301 L</search> or by calling L</set_cache>.
2302
2303 =cut
2304
2305 sub get_cache {
2306   shift->{all_cache};
2307 }
2308
2309 =head2 set_cache
2310
2311 =over 4
2312
2313 =item Arguments: \@cache_objects
2314
2315 =item Return Value: \@cache_objects
2316
2317 =back
2318
2319 Sets the contents of the cache for the resultset. Expects an arrayref
2320 of objects of the same class as those produced by the resultset. Note that
2321 if the cache is set the resultset will return the cached objects rather
2322 than re-querying the database even if the cache attr is not set.
2323
2324 The contents of the cache can also be populated by using the
2325 L</prefetch> attribute to L</search>.
2326
2327 =cut
2328
2329 sub set_cache {
2330   my ( $self, $data ) = @_;
2331   $self->throw_exception("set_cache requires an arrayref")
2332       if defined($data) && (ref $data ne 'ARRAY');
2333   $self->{all_cache} = $data;
2334 }
2335
2336 =head2 clear_cache
2337
2338 =over 4
2339
2340 =item Arguments: none
2341
2342 =item Return Value: []
2343
2344 =back
2345
2346 Clears the cache for the resultset.
2347
2348 =cut
2349
2350 sub clear_cache {
2351   shift->set_cache(undef);
2352 }
2353
2354 =head2 related_resultset
2355
2356 =over 4
2357
2358 =item Arguments: $relationship_name
2359
2360 =item Return Value: $resultset
2361
2362 =back
2363
2364 Returns a related resultset for the supplied relationship name.
2365
2366   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2367
2368 =cut
2369
2370 sub related_resultset {
2371   my ($self, $rel) = @_;
2372
2373   $self->{related_resultsets} ||= {};
2374   return $self->{related_resultsets}{$rel} ||= do {
2375     my $rel_obj = $self->result_source->relationship_info($rel);
2376
2377     $self->throw_exception(
2378       "search_related: result source '" . $self->result_source->source_name .
2379         "' has no such relationship $rel")
2380       unless $rel_obj;
2381
2382     my ($from,$seen) = $self->_resolve_from($rel);
2383
2384     my $join_count = $seen->{$rel};
2385     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2386
2387     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2388     my %attrs = %{$self->{attrs}||{}};
2389     delete @attrs{qw(result_class alias)};
2390
2391     my $new_cache;
2392
2393     if (my $cache = $self->get_cache) {
2394       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2395         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2396                         @$cache ];
2397       }
2398     }
2399
2400     my $rel_source = $self->result_source->related_source($rel);
2401
2402     my $new = do {
2403
2404       # The reason we do this now instead of passing the alias to the
2405       # search_rs below is that if you wrap/overload resultset on the
2406       # source you need to know what alias it's -going- to have for things
2407       # to work sanely (e.g. RestrictWithObject wants to be able to add
2408       # extra query restrictions, and these may need to be $alias.)
2409
2410       my $attrs = $rel_source->resultset_attributes;
2411       local $attrs->{alias} = $alias;
2412
2413       $rel_source->resultset
2414                  ->search_rs(
2415                      undef, {
2416                        %attrs,
2417                        join => undef,
2418                        prefetch => undef,
2419                        select => undef,
2420                        as => undef,
2421                        where => $self->{cond},
2422                        seen_join => $seen,
2423                        from => $from,
2424                    });
2425     };
2426     $new->set_cache($new_cache) if $new_cache;
2427     $new;
2428   };
2429 }
2430
2431 =head2 current_source_alias
2432
2433 =over 4
2434
2435 =item Arguments: none
2436
2437 =item Return Value: $source_alias
2438
2439 =back
2440
2441 Returns the current table alias for the result source this resultset is built
2442 on, that will be used in the SQL query. Usually it is C<me>.
2443
2444 Currently the source alias that refers to the result set returned by a
2445 L</search>/L</find> family method depends on how you got to the resultset: it's
2446 C<me> by default, but eg. L</search_related> aliases it to the related result
2447 source name (and keeps C<me> referring to the original result set). The long
2448 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2449 (and make this method unnecessary).
2450
2451 Thus it's currently necessary to use this method in predefined queries (see
2452 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2453 source alias of the current result set:
2454
2455   # in a result set class
2456   sub modified_by {
2457     my ($self, $user) = @_;
2458
2459     my $me = $self->current_source_alias;
2460
2461     return $self->search(
2462       "$me.modified" => $user->id,
2463     );
2464   }
2465
2466 =cut
2467
2468 sub current_source_alias {
2469   my ($self) = @_;
2470
2471   return ($self->{attrs} || {})->{alias} || 'me';
2472 }
2473
2474 # This code is called by search_related, and makes sure there
2475 # is clear separation between the joins before, during, and
2476 # after the relationship. This information is needed later
2477 # in order to properly resolve prefetch aliases (any alias
2478 # with a relation_chain_depth less than the depth of the
2479 # current prefetch is not considered)
2480 sub _resolve_from {
2481   my ($self, $extra_join) = @_;
2482   my $source = $self->result_source;
2483   my $attrs = $self->{attrs};
2484
2485   my $from = $attrs->{from}
2486     || [ { $attrs->{alias} => $source->from } ];
2487
2488   my $seen = { %{$attrs->{seen_join}||{}} };
2489
2490   # we need to take the prefetch the attrs into account before we
2491   # ->_resolve_join as otherwise they get lost - captainL
2492   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2493
2494   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2495
2496   ++$seen->{-relation_chain_depth};
2497
2498   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2499
2500   ++$seen->{-relation_chain_depth};
2501
2502   return ($from,$seen);
2503 }
2504
2505 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2506 sub _resolved_attrs_copy {
2507   my $self = shift;
2508   return { %{$self->_resolved_attrs (@_)} };
2509 }
2510
2511 sub _resolved_attrs {
2512   my $self = shift;
2513   return $self->{_attrs} if $self->{_attrs};
2514
2515   my $attrs  = { %{ $self->{attrs} || {} } };
2516   my $source = $self->result_source;
2517   my $alias  = $attrs->{alias};
2518
2519   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2520   my @colbits;
2521
2522   # build columns (as long as select isn't set) into a set of as/select hashes
2523   unless ( $attrs->{select} ) {
2524       @colbits = map {
2525           ( ref($_) eq 'HASH' )
2526               ? $_
2527               : {
2528                   (
2529                     /^\Q${alias}.\E(.+)$/
2530                       ? "$1"
2531                       : "$_"
2532                   )
2533                 =>
2534                   (
2535                     /\./
2536                       ? "$_"
2537                       : "${alias}.$_"
2538                   )
2539             }
2540       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2541   }
2542   # add the additional columns on
2543   foreach ( 'include_columns', '+columns' ) {
2544       push @colbits, map {
2545           ( ref($_) eq 'HASH' )
2546             ? $_
2547             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2548       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2549   }
2550
2551   # start with initial select items
2552   if ( $attrs->{select} ) {
2553     $attrs->{select} =
2554         ( ref $attrs->{select} eq 'ARRAY' )
2555       ? [ @{ $attrs->{select} } ]
2556       : [ $attrs->{select} ];
2557     $attrs->{as} = (
2558       $attrs->{as}
2559       ? (
2560         ref $attrs->{as} eq 'ARRAY'
2561         ? [ @{ $attrs->{as} } ]
2562         : [ $attrs->{as} ]
2563         )
2564       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2565     );
2566   }
2567   else {
2568
2569     # otherwise we intialise select & as to empty
2570     $attrs->{select} = [];
2571     $attrs->{as}     = [];
2572   }
2573
2574   # now add colbits to select/as
2575   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2576   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2577
2578   my $adds;
2579   if ( $adds = delete $attrs->{'+select'} ) {
2580     $adds = [$adds] unless ref $adds eq 'ARRAY';
2581     push(
2582       @{ $attrs->{select} },
2583       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2584     );
2585   }
2586   if ( $adds = delete $attrs->{'+as'} ) {
2587     $adds = [$adds] unless ref $adds eq 'ARRAY';
2588     push( @{ $attrs->{as} }, @$adds );
2589   }
2590
2591   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2592
2593   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2594     my $join = delete $attrs->{join} || {};
2595
2596     if ( defined $attrs->{prefetch} ) {
2597       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2598
2599     }
2600
2601     $attrs->{from} =    # have to copy here to avoid corrupting the original
2602       [
2603       @{ $attrs->{from} },
2604       $source->_resolve_join(
2605         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2606       )
2607       ];
2608
2609   }
2610
2611   if ( $attrs->{order_by} ) {
2612     $attrs->{order_by} = (
2613       ref( $attrs->{order_by} ) eq 'ARRAY'
2614       ? [ @{ $attrs->{order_by} } ]
2615       : [ $attrs->{order_by} ]
2616     );
2617   }
2618   else {
2619     $attrs->{order_by} = [];
2620   }
2621
2622   my $collapse = $attrs->{collapse} || {};
2623   if ( my $prefetch = delete $attrs->{prefetch} ) {
2624     $prefetch = $self->_merge_attr( {}, $prefetch );
2625     my @pre_order;
2626     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2627
2628       # bring joins back to level of current class
2629       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2630       my @prefetch =
2631         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2632       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2633       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2634     }
2635     push( @{ $attrs->{order_by} }, @pre_order );
2636   }
2637
2638   if (delete $attrs->{distinct}) {
2639     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2640   }
2641
2642   $attrs->{collapse} = $collapse;
2643
2644   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2645     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2646   }
2647
2648   return $self->{_attrs} = $attrs;
2649 }
2650
2651 sub _joinpath_aliases {
2652   my ($self, $fromspec, $seen) = @_;
2653
2654   my $paths = {};
2655   return $paths unless ref $fromspec eq 'ARRAY';
2656
2657   for my $j (@$fromspec) {
2658
2659     next if ref $j ne 'ARRAY';
2660     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2661
2662     my $p = $paths;
2663     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2664     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2665   }
2666
2667   return $paths;
2668 }
2669
2670 sub _rollout_attr {
2671   my ($self, $attr) = @_;
2672
2673   if (ref $attr eq 'HASH') {
2674     return $self->_rollout_hash($attr);
2675   } elsif (ref $attr eq 'ARRAY') {
2676     return $self->_rollout_array($attr);
2677   } else {
2678     return [$attr];
2679   }
2680 }
2681
2682 sub _rollout_array {
2683   my ($self, $attr) = @_;
2684
2685   my @rolled_array;
2686   foreach my $element (@{$attr}) {
2687     if (ref $element eq 'HASH') {
2688       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2689     } elsif (ref $element eq 'ARRAY') {
2690       #  XXX - should probably recurse here
2691       push( @rolled_array, @{$self->_rollout_array($element)} );
2692     } else {
2693       push( @rolled_array, $element );
2694     }
2695   }
2696   return \@rolled_array;
2697 }
2698
2699 sub _rollout_hash {
2700   my ($self, $attr) = @_;
2701
2702   my @rolled_array;
2703   foreach my $key (keys %{$attr}) {
2704     push( @rolled_array, { $key => $attr->{$key} } );
2705   }
2706   return \@rolled_array;
2707 }
2708
2709 sub _calculate_score {
2710   my ($self, $a, $b) = @_;
2711
2712   if (ref $b eq 'HASH') {
2713     my ($b_key) = keys %{$b};
2714     if (ref $a eq 'HASH') {
2715       my ($a_key) = keys %{$a};
2716       if ($a_key eq $b_key) {
2717         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2718       } else {
2719         return 0;
2720       }
2721     } else {
2722       return ($a eq $b_key) ? 1 : 0;
2723     }
2724   } else {
2725     if (ref $a eq 'HASH') {
2726       my ($a_key) = keys %{$a};
2727       return ($b eq $a_key) ? 1 : 0;
2728     } else {
2729       return ($b eq $a) ? 1 : 0;
2730     }
2731   }
2732 }
2733
2734 sub _merge_attr {
2735   my ($self, $orig, $import) = @_;
2736
2737   return $import unless defined($orig);
2738   return $orig unless defined($import);
2739
2740   $orig = $self->_rollout_attr($orig);
2741   $import = $self->_rollout_attr($import);
2742
2743   my $seen_keys;
2744   foreach my $import_element ( @{$import} ) {
2745     # find best candidate from $orig to merge $b_element into
2746     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2747     foreach my $orig_element ( @{$orig} ) {
2748       my $score = $self->_calculate_score( $orig_element, $import_element );
2749       if ($score > $best_candidate->{score}) {
2750         $best_candidate->{position} = $position;
2751         $best_candidate->{score} = $score;
2752       }
2753       $position++;
2754     }
2755     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2756
2757     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2758       push( @{$orig}, $import_element );
2759     } else {
2760       my $orig_best = $orig->[$best_candidate->{position}];
2761       # merge orig_best and b_element together and replace original with merged
2762       if (ref $orig_best ne 'HASH') {
2763         $orig->[$best_candidate->{position}] = $import_element;
2764       } elsif (ref $import_element eq 'HASH') {
2765         my ($key) = keys %{$orig_best};
2766         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2767       }
2768     }
2769     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2770   }
2771
2772   return $orig;
2773 }
2774
2775 sub result_source {
2776     my $self = shift;
2777
2778     if (@_) {
2779         $self->_source_handle($_[0]->handle);
2780     } else {
2781         $self->_source_handle->resolve;
2782     }
2783 }
2784
2785 =head2 throw_exception
2786
2787 See L<DBIx::Class::Schema/throw_exception> for details.
2788
2789 =cut
2790
2791 sub throw_exception {
2792   my $self=shift;
2793   if (ref $self && $self->_source_handle->schema) {
2794     $self->_source_handle->schema->throw_exception(@_)
2795   } else {
2796     croak(@_);
2797   }
2798
2799 }
2800
2801 # XXX: FIXME: Attributes docs need clearing up
2802
2803 =head1 ATTRIBUTES
2804
2805 Attributes are used to refine a ResultSet in various ways when
2806 searching for data. They can be passed to any method which takes an
2807 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2808 L</count>.
2809
2810 These are in no particular order:
2811
2812 =head2 order_by
2813
2814 =over 4
2815
2816 =item Value: ( $order_by | \@order_by | \%order_by )
2817
2818 =back
2819
2820 Which column(s) to order the results by. If a single column name, or
2821 an arrayref of names is supplied, the argument is passed through
2822 directly to SQL. The hashref syntax allows for connection-agnostic
2823 specification of ordering direction:
2824
2825  For descending order:
2826
2827   order_by => { -desc => [qw/col1 col2 col3/] }
2828
2829  For explicit ascending order:
2830
2831   order_by => { -asc => 'col' }
2832
2833 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2834 supported, although you are strongly encouraged to use the hashref
2835 syntax as outlined above.
2836
2837 =head2 columns
2838
2839 =over 4
2840
2841 =item Value: \@columns
2842
2843 =back
2844
2845 Shortcut to request a particular set of columns to be retrieved. Each
2846 column spec may be a string (a table column name), or a hash (in which
2847 case the key is the C<as> value, and the value is used as the C<select>
2848 expression). Adds C<me.> onto the start of any column without a C<.> in
2849 it and sets C<select> from that, then auto-populates C<as> from
2850 C<select> as normal. (You may also use the C<cols> attribute, as in
2851 earlier versions of DBIC.)
2852
2853 =head2 +columns
2854
2855 =over 4
2856
2857 =item Value: \@columns
2858
2859 =back
2860
2861 Indicates additional columns to be selected from storage. Works the same
2862 as L</columns> but adds columns to the selection. (You may also use the
2863 C<include_columns> attribute, as in earlier versions of DBIC). For
2864 example:-
2865
2866   $schema->resultset('CD')->search(undef, {
2867     '+columns' => ['artist.name'],
2868     join => ['artist']
2869   });
2870
2871 would return all CDs and include a 'name' column to the information
2872 passed to object inflation. Note that the 'artist' is the name of the
2873 column (or relationship) accessor, and 'name' is the name of the column
2874 accessor in the related table.
2875
2876 =head2 include_columns
2877
2878 =over 4
2879
2880 =item Value: \@columns
2881
2882 =back
2883
2884 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2885
2886 =head2 select
2887
2888 =over 4
2889
2890 =item Value: \@select_columns
2891
2892 =back
2893
2894 Indicates which columns should be selected from the storage. You can use
2895 column names, or in the case of RDBMS back ends, function or stored procedure
2896 names:
2897
2898   $rs = $schema->resultset('Employee')->search(undef, {
2899     select => [
2900       'name',
2901       { count => 'employeeid' },
2902       { sum => 'salary' }
2903     ]
2904   });
2905
2906 When you use function/stored procedure names and do not supply an C<as>
2907 attribute, the column names returned are storage-dependent. E.g. MySQL would
2908 return a column named C<count(employeeid)> in the above example.
2909
2910 =head2 +select
2911
2912 =over 4
2913
2914 Indicates additional columns to be selected from storage.  Works the same as
2915 L</select> but adds columns to the selection.
2916
2917 =back
2918
2919 =head2 +as
2920
2921 =over 4
2922
2923 Indicates additional column names for those added via L</+select>. See L</as>.
2924
2925 =back
2926
2927 =head2 as
2928
2929 =over 4
2930
2931 =item Value: \@inflation_names
2932
2933 =back
2934
2935 Indicates column names for object inflation. That is, C<as>
2936 indicates the name that the column can be accessed as via the
2937 C<get_column> method (or via the object accessor, B<if one already
2938 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2939
2940 The C<as> attribute is used in conjunction with C<select>,
2941 usually when C<select> contains one or more function or stored
2942 procedure names:
2943
2944   $rs = $schema->resultset('Employee')->search(undef, {
2945     select => [
2946       'name',
2947       { count => 'employeeid' }
2948     ],
2949     as => ['name', 'employee_count'],
2950   });
2951
2952   my $employee = $rs->first(); # get the first Employee
2953
2954 If the object against which the search is performed already has an accessor
2955 matching a column name specified in C<as>, the value can be retrieved using
2956 the accessor as normal:
2957
2958   my $name = $employee->name();
2959
2960 If on the other hand an accessor does not exist in the object, you need to
2961 use C<get_column> instead:
2962
2963   my $employee_count = $employee->get_column('employee_count');
2964
2965 You can create your own accessors if required - see
2966 L<DBIx::Class::Manual::Cookbook> for details.
2967
2968 Please note: This will NOT insert an C<AS employee_count> into the SQL
2969 statement produced, it is used for internal access only. Thus
2970 attempting to use the accessor in an C<order_by> clause or similar
2971 will fail miserably.
2972
2973 To get around this limitation, you can supply literal SQL to your
2974 C<select> attibute that contains the C<AS alias> text, eg:
2975
2976   select => [\'myfield AS alias']
2977
2978 =head2 join
2979
2980 =over 4
2981
2982 =item Value: ($rel_name | \@rel_names | \%rel_names)
2983
2984 =back
2985
2986 Contains a list of relationships that should be joined for this query.  For
2987 example:
2988
2989   # Get CDs by Nine Inch Nails
2990   my $rs = $schema->resultset('CD')->search(
2991     { 'artist.name' => 'Nine Inch Nails' },
2992     { join => 'artist' }
2993   );
2994
2995 Can also contain a hash reference to refer to the other relation's relations.
2996 For example:
2997
2998   package MyApp::Schema::Track;
2999   use base qw/DBIx::Class/;
3000   __PACKAGE__->table('track');
3001   __PACKAGE__->add_columns(qw/trackid cd position title/);
3002   __PACKAGE__->set_primary_key('trackid');
3003   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3004   1;
3005
3006   # In your application
3007   my $rs = $schema->resultset('Artist')->search(
3008     { 'track.title' => 'Teardrop' },
3009     {
3010       join     => { cd => 'track' },
3011       order_by => 'artist.name',
3012     }
3013   );
3014
3015 You need to use the relationship (not the table) name in  conditions,
3016 because they are aliased as such. The current table is aliased as "me", so
3017 you need to use me.column_name in order to avoid ambiguity. For example:
3018
3019   # Get CDs from 1984 with a 'Foo' track
3020   my $rs = $schema->resultset('CD')->search(
3021     {
3022       'me.year' => 1984,
3023       'tracks.name' => 'Foo'
3024     },
3025     { join => 'tracks' }
3026   );
3027
3028 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3029 similarly for a third time). For e.g.
3030
3031   my $rs = $schema->resultset('Artist')->search({
3032     'cds.title'   => 'Down to Earth',
3033     'cds_2.title' => 'Popular',
3034   }, {
3035     join => [ qw/cds cds/ ],
3036   });
3037
3038 will return a set of all artists that have both a cd with title 'Down
3039 to Earth' and a cd with title 'Popular'.
3040
3041 If you want to fetch related objects from other tables as well, see C<prefetch>
3042 below.
3043
3044 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3045
3046 =head2 prefetch
3047
3048 =over 4
3049
3050 =item Value: ($rel_name | \@rel_names | \%rel_names)
3051
3052 =back
3053
3054 Contains one or more relationships that should be fetched along with
3055 the main query (when they are accessed afterwards the data will
3056 already be available, without extra queries to the database).  This is
3057 useful for when you know you will need the related objects, because it
3058 saves at least one query:
3059
3060   my $rs = $schema->resultset('Tag')->search(
3061     undef,
3062     {
3063       prefetch => {
3064         cd => 'artist'
3065       }
3066     }
3067   );
3068
3069 The initial search results in SQL like the following:
3070
3071   SELECT tag.*, cd.*, artist.* FROM tag
3072   JOIN cd ON tag.cd = cd.cdid
3073   JOIN artist ON cd.artist = artist.artistid
3074
3075 L<DBIx::Class> has no need to go back to the database when we access the
3076 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3077 case.
3078
3079 Simple prefetches will be joined automatically, so there is no need
3080 for a C<join> attribute in the above search.
3081
3082 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3083 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3084 with an accessor type of 'single' or 'filter'). A more complex example that
3085 prefetches an artists cds, the tracks on those cds, and the tags associted
3086 with that artist is given below (assuming many-to-many from artists to tags):
3087
3088  my $rs = $schema->resultset('Artist')->search(
3089    undef,
3090    {
3091      prefetch => [
3092        { cds => 'tracks' },
3093        { artist_tags => 'tags' }
3094      ]
3095    }
3096  );
3097
3098
3099 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3100 attributes will be ignored.
3101
3102 =head2 page
3103
3104 =over 4
3105
3106 =item Value: $page
3107
3108 =back
3109
3110 Makes the resultset paged and specifies the page to retrieve. Effectively
3111 identical to creating a non-pages resultset and then calling ->page($page)
3112 on it.
3113
3114 If L<rows> attribute is not specified it defualts to 10 rows per page.
3115
3116 When you have a paged resultset, L</count> will only return the number
3117 of rows in the page. To get the total, use the L</pager> and call
3118 C<total_entries> on it.
3119
3120 =head2 rows
3121
3122 =over 4
3123
3124 =item Value: $rows
3125
3126 =back
3127
3128 Specifes the maximum number of rows for direct retrieval or the number of
3129 rows per page if the page attribute or method is used.
3130
3131 =head2 offset
3132
3133 =over 4
3134
3135 =item Value: $offset
3136
3137 =back
3138
3139 Specifies the (zero-based) row number for the  first row to be returned, or the
3140 of the first row of the first page if paging is used.
3141
3142 =head2 group_by
3143
3144 =over 4
3145
3146 =item Value: \@columns
3147
3148 =back
3149
3150 A arrayref of columns to group by. Can include columns of joined tables.
3151
3152   group_by => [qw/ column1 column2 ... /]
3153
3154 =head2 having
3155
3156 =over 4
3157
3158 =item Value: $condition
3159
3160 =back
3161
3162 HAVING is a select statement attribute that is applied between GROUP BY and
3163 ORDER BY. It is applied to the after the grouping calculations have been
3164 done.
3165
3166   having => { 'count(employee)' => { '>=', 100 } }
3167
3168 =head2 distinct
3169
3170 =over 4
3171
3172 =item Value: (0 | 1)
3173
3174 =back
3175
3176 Set to 1 to group by all columns.
3177
3178 =head2 where
3179
3180 =over 4
3181
3182 Adds to the WHERE clause.
3183
3184   # only return rows WHERE deleted IS NULL for all searches
3185   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3186
3187 Can be overridden by passing C<{ where => undef }> as an attribute
3188 to a resulset.
3189
3190 =back
3191
3192 =head2 cache
3193
3194 Set to 1 to cache search results. This prevents extra SQL queries if you
3195 revisit rows in your ResultSet:
3196
3197   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3198
3199   while( my $artist = $resultset->next ) {
3200     ... do stuff ...
3201   }
3202
3203   $rs->first; # without cache, this would issue a query
3204
3205 By default, searches are not cached.
3206
3207 For more examples of using these attributes, see
3208 L<DBIx::Class::Manual::Cookbook>.
3209
3210 =head2 from
3211
3212 =over 4
3213
3214 =item Value: \@from_clause
3215
3216 =back
3217
3218 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3219 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3220 clauses.
3221
3222 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3223
3224 C<join> will usually do what you need and it is strongly recommended that you
3225 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3226 And we really do mean "cannot", not just tried and failed. Attempting to use
3227 this because you're having problems with C<join> is like trying to use x86
3228 ASM because you've got a syntax error in your C. Trust us on this.
3229
3230 Now, if you're still really, really sure you need to use this (and if you're
3231 not 100% sure, ask the mailing list first), here's an explanation of how this
3232 works.
3233
3234 The syntax is as follows -
3235
3236   [
3237     { <alias1> => <table1> },
3238     [
3239       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3240       [], # nested JOIN (optional)
3241       { <table1.column1> => <table2.column2>, ... (more conditions) },
3242     ],
3243     # More of the above [ ] may follow for additional joins
3244   ]
3245
3246   <table1> <alias1>
3247   JOIN
3248     <table2> <alias2>
3249     [JOIN ...]
3250   ON <table1.column1> = <table2.column2>
3251   <more joins may follow>
3252
3253 An easy way to follow the examples below is to remember the following:
3254
3255     Anything inside "[]" is a JOIN
3256     Anything inside "{}" is a condition for the enclosing JOIN
3257
3258 The following examples utilize a "person" table in a family tree application.
3259 In order to express parent->child relationships, this table is self-joined:
3260
3261     # Person->belongs_to('father' => 'Person');
3262     # Person->belongs_to('mother' => 'Person');
3263
3264 C<from> can be used to nest joins. Here we return all children with a father,
3265 then search against all mothers of those children:
3266
3267   $rs = $schema->resultset('Person')->search(
3268       undef,
3269       {
3270           alias => 'mother', # alias columns in accordance with "from"
3271           from => [
3272               { mother => 'person' },
3273               [
3274                   [
3275                       { child => 'person' },
3276                       [
3277                           { father => 'person' },
3278                           { 'father.person_id' => 'child.father_id' }
3279                       ]
3280                   ],
3281                   { 'mother.person_id' => 'child.mother_id' }
3282               ],
3283           ]
3284       },
3285   );
3286
3287   # Equivalent SQL:
3288   # SELECT mother.* FROM person mother
3289   # JOIN (
3290   #   person child
3291   #   JOIN person father
3292   #   ON ( father.person_id = child.father_id )
3293   # )
3294   # ON ( mother.person_id = child.mother_id )
3295
3296 The type of any join can be controlled manually. To search against only people
3297 with a father in the person table, we could explicitly use C<INNER JOIN>:
3298
3299     $rs = $schema->resultset('Person')->search(
3300         undef,
3301         {
3302             alias => 'child', # alias columns in accordance with "from"
3303             from => [
3304                 { child => 'person' },
3305                 [
3306                     { father => 'person', -join_type => 'inner' },
3307                     { 'father.id' => 'child.father_id' }
3308                 ],
3309             ]
3310         },
3311     );
3312
3313     # Equivalent SQL:
3314     # SELECT child.* FROM person child
3315     # INNER JOIN person father ON child.father_id = father.id
3316
3317 If you need to express really complex joins or you need a subselect, you
3318 can supply literal SQL to C<from> via a scalar reference. In this case
3319 the contents of the scalar will replace the table name asscoiated with the
3320 resultsource.
3321
3322 WARNING: This technique might very well not work as expected on chained
3323 searches - you have been warned.
3324
3325     # Assuming the Event resultsource is defined as:
3326
3327         MySchema::Event->add_columns (
3328             sequence => {
3329                 data_type => 'INT',
3330                 is_auto_increment => 1,
3331             },
3332             location => {
3333                 data_type => 'INT',
3334             },
3335             type => {
3336                 data_type => 'INT',
3337             },
3338         );
3339         MySchema::Event->set_primary_key ('sequence');
3340
3341     # This will get back the latest event for every location. The column
3342     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3343     # combo to limit the resultset
3344
3345     $rs = $schema->resultset('Event');
3346     $table = $rs->result_source->name;
3347     $latest = $rs->search (
3348         undef,
3349         { from => \ "
3350             (SELECT e1.* FROM $table e1
3351                 JOIN $table e2
3352                     ON e1.location = e2.location
3353                     AND e1.sequence < e2.sequence
3354                 WHERE e2.sequence is NULL
3355             ) me",
3356         },
3357     );
3358
3359     # Equivalent SQL (with the DBIC chunks added):
3360
3361     SELECT me.sequence, me.location, me.type FROM
3362        (SELECT e1.* FROM events e1
3363            JOIN events e2
3364                ON e1.location = e2.location
3365                AND e1.sequence < e2.sequence
3366            WHERE e2.sequence is NULL
3367        ) me;
3368
3369 =head2 for
3370
3371 =over 4
3372
3373 =item Value: ( 'update' | 'shared' )
3374
3375 =back
3376
3377 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3378 ... FOR SHARED.
3379
3380 =cut
3381
3382 1;