lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799 #      warn "ARRAY: " . Dumper $subquery;
 800       $collapsed = $self->_collapse_query($subquery, $collapsed);
 801     }
 802   }
 803   elsif (ref $query eq 'HASH') {
 804     if (keys %$query and (keys %$query)[0] eq '-and') {
 805       foreach my $subquery (@{$query->{-and}}) {
 806 #        warn "HASH: " . Dumper $subquery;
 807         $collapsed = $self->_collapse_query($subquery, $collapsed);
 808       }
 809     }
 810     else {
 811 #      warn "LEAF: " . Dumper $query;
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 This method is deprecated and will be removed in 0.09. Use L</search()>
 864 instead. An example conversion is:
 865
 866   ->search_like({ foo => 'bar' });
 867
 868   # Becomes
 869
 870   ->search({ foo => { like => 'bar' } });
 871
 872 =cut
 873
 874 sub search_like {
 875   my $class = shift;
 876   carp join ("\n",
 877     'search_like() is deprecated and will be removed in 0.09.',
 878     'Instead use ->search({ x => { -like => "y%" } })',
 879     '(note the outer pair of {}s - they are important!)'
 880   );
 881   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 882   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 883   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 884   return $class->search($query, { %$attrs });
 885 }
 886
 887 =head2 slice
 888
 889 =over 4
 890
 891 =item Arguments: $first, $last
 892
 893 =item Return Value: $resultset (scalar context), @row_objs (list context)
 894
 895 =back
 896
 897 Returns a resultset or object list representing a subset of elements from the
 898 resultset slice is called on. Indexes are from 0, i.e., to get the first
 899 three records, call:
 900
 901   my ($one, $two, $three) = $rs->slice(0, 2);
 902
 903 =cut
 904
 905 sub slice {
 906   my ($self, $min, $max) = @_;
 907   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 908   $attrs->{offset} = $self->{attrs}{offset} || 0;
 909   $attrs->{offset} += $min;
 910   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 911   return $self->search(undef(), $attrs);
 912   #my $slice = (ref $self)->new($self->result_source, $attrs);
 913   #return (wantarray ? $slice->all : $slice);
 914 }
 915
 916 =head2 next
 917
 918 =over 4
 919
 920 =item Arguments: none
 921
 922 =item Return Value: $result?
 923
 924 =back
 925
 926 Returns the next element in the resultset (C<undef> is there is none).
 927
 928 Can be used to efficiently iterate over records in the resultset:
 929
 930   my $rs = $schema->resultset('CD')->search;
 931   while (my $cd = $rs->next) {
 932     print $cd->title;
 933   }
 934
 935 Note that you need to store the resultset object, and call C<next> on it.
 936 Calling C<< resultset('Table')->next >> repeatedly will always return the
 937 first record from the resultset.
 938
 939 =cut
 940
 941 sub next {
 942   my ($self) = @_;
 943   if (my $cache = $self->get_cache) {
 944     $self->{all_cache_position} ||= 0;
 945     return $cache->[$self->{all_cache_position}++];
 946   }
 947   if ($self->{attrs}{cache}) {
 948     $self->{all_cache_position} = 1;
 949     return ($self->all)[0];
 950   }
 951   if ($self->{stashed_objects}) {
 952     my $obj = shift(@{$self->{stashed_objects}});
 953     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 954     return $obj;
 955   }
 956   my @row = (
 957     exists $self->{stashed_row}
 958       ? @{delete $self->{stashed_row}}
 959       : $self->cursor->next
 960   );
 961   return undef unless (@row);
 962   my ($row, @more) = $self->_construct_object(@row);
 963   $self->{stashed_objects} = \@more if @more;
 964   return $row;
 965 }
 966
 967 sub _construct_object {
 968   my ($self, @row) = @_;
 969   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 970   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 971   @new = $self->{_attrs}{record_filter}->(@new)
 972     if exists $self->{_attrs}{record_filter};
 973   return @new;
 974 }
 975
 976 sub _collapse_result {
 977   my ($self, $as_proto, $row) = @_;
 978
 979   my @copy = @$row;
 980
 981   # 'foo'         => [ undef, 'foo' ]
 982   # 'foo.bar'     => [ 'foo', 'bar' ]
 983   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 984
 985   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 986
 987   my %collapse = %{$self->{_attrs}{collapse}||{}};
 988
 989   my @pri_index;
 990
 991   # if we're doing collapsing (has_many prefetch) we need to grab records
 992   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 993   # we know we don't have to bother.
 994
 995   # the reason for not using the collapse stuff directly is because if you
 996   # had for e.g. two artists in a row with no cds, the collapse info for
 997   # both would be NULL (undef) so you'd lose the second artist
 998
 999   # store just the index so we can check the array positions from the row
1000   # without having to contruct the full hash
1001
1002   if (keys %collapse) {
1003     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1004     foreach my $i (0 .. $#construct_as) {
1005       next if defined($construct_as[$i][0]); # only self table
1006       if (delete $pri{$construct_as[$i][1]}) {
1007         push(@pri_index, $i);
1008       }
1009       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1010     }
1011   }
1012
1013   # no need to do an if, it'll be empty if @pri_index is empty anyway
1014
1015   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1016
1017   my @const_rows;
1018
1019   do { # no need to check anything at the front, we always want the first row
1020
1021     my %const;
1022
1023     foreach my $this_as (@construct_as) {
1024       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1025     }
1026
1027     push(@const_rows, \%const);
1028
1029   } until ( # no pri_index => no collapse => drop straight out
1030       !@pri_index
1031     or
1032       do { # get another row, stash it, drop out if different PK
1033
1034         @copy = $self->cursor->next;
1035         $self->{stashed_row} = \@copy;
1036
1037         # last thing in do block, counts as true if anything doesn't match
1038
1039         # check xor defined first for NULL vs. NOT NULL then if one is
1040         # defined the other must be so check string equality
1041
1042         grep {
1043           (defined $pri_vals{$_} ^ defined $copy[$_])
1044           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1045         } @pri_index;
1046       }
1047   );
1048
1049   my $alias = $self->{attrs}{alias};
1050   my $info = [];
1051
1052   my %collapse_pos;
1053
1054   my @const_keys;
1055
1056   foreach my $const (@const_rows) {
1057     scalar @const_keys or do {
1058       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1059     };
1060     foreach my $key (@const_keys) {
1061       if (length $key) {
1062         my $target = $info;
1063         my @parts = split(/\./, $key);
1064         my $cur = '';
1065         my $data = $const->{$key};
1066         foreach my $p (@parts) {
1067           $target = $target->[1]->{$p} ||= [];
1068           $cur .= ".${p}";
1069           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1070             # collapsing at this point and on final part
1071             my $pos = $collapse_pos{$cur};
1072             CK: foreach my $ck (@ckey) {
1073               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1074                 $collapse_pos{$cur} = $data;
1075                 delete @collapse_pos{ # clear all positioning for sub-entries
1076                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1077                 };
1078                 push(@$target, []);
1079                 last CK;
1080               }
1081             }
1082           }
1083           if (exists $collapse{$cur}) {
1084             $target = $target->[-1];
1085           }
1086         }
1087         $target->[0] = $data;
1088       } else {
1089         $info->[0] = $const->{$key};
1090       }
1091     }
1092   }
1093
1094   return $info;
1095 }
1096
1097 =head2 result_source
1098
1099 =over 4
1100
1101 =item Arguments: $result_source?
1102
1103 =item Return Value: $result_source
1104
1105 =back
1106
1107 An accessor for the primary ResultSource object from which this ResultSet
1108 is derived.
1109
1110 =head2 result_class
1111
1112 =over 4
1113
1114 =item Arguments: $result_class?
1115
1116 =item Return Value: $result_class
1117
1118 =back
1119
1120 An accessor for the class to use when creating row objects. Defaults to
1121 C<< result_source->result_class >> - which in most cases is the name of the
1122 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1123
1124 Note that changing the result_class will also remove any components
1125 that were originally loaded in the source class via
1126 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1127 in the original source class will not run.
1128
1129 =cut
1130
1131 sub result_class {
1132   my ($self, $result_class) = @_;
1133   if ($result_class) {
1134     $self->ensure_class_loaded($result_class);
1135     $self->_result_class($result_class);
1136   }
1137   $self->_result_class;
1138 }
1139
1140 =head2 count
1141
1142 =over 4
1143
1144 =item Arguments: $cond, \%attrs??
1145
1146 =item Return Value: $count
1147
1148 =back
1149
1150 Performs an SQL C<COUNT> with the same query as the resultset was built
1151 with to find the number of elements. If passed arguments, does a search
1152 on the resultset and counts the results of that.
1153
1154 =cut
1155
1156 sub count {
1157   my $self = shift;
1158   return $self->search(@_)->count if @_ and defined $_[0];
1159   return scalar @{ $self->get_cache } if $self->get_cache;
1160   my $count = $self->_count;
1161   return 0 unless $count;
1162
1163   # need to take offset from resolved attrs
1164
1165   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1166   $count = $self->{attrs}{rows} if
1167     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1168   $count = 0 if ($count < 0);
1169   return $count;
1170 }
1171
1172 sub _count { # Separated out so pager can get the full count
1173   my $self = shift;
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   if (my $group_by = $attrs->{group_by}) {
1177     delete $attrs->{order_by};
1178
1179     $attrs->{select} = $group_by;
1180     $attrs->{from} = [ { 'mesub' => (ref $self)->new($self->result_source, $attrs)->cursor->as_query } ];
1181     delete $attrs->{where};
1182   }
1183
1184   $attrs->{select} = { count => '*' };
1185   $attrs->{as} = [qw/count/];
1186
1187   # offset, order by, group by, where and page are not needed to count. record_filter is cdbi
1188   delete $attrs->{$_} for qw/rows offset order_by group_by page pager record_filter/;
1189
1190   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1191   my ($count) = $tmp_rs->cursor->next;
1192   return $count;
1193 }
1194
1195 sub _bool {
1196   return 1;
1197 }
1198
1199 =head2 count_literal
1200
1201 =over 4
1202
1203 =item Arguments: $sql_fragment, @bind_values
1204
1205 =item Return Value: $count
1206
1207 =back
1208
1209 Counts the results in a literal query. Equivalent to calling L</search_literal>
1210 with the passed arguments, then L</count>.
1211
1212 =cut
1213
1214 sub count_literal { shift->search_literal(@_)->count; }
1215
1216 =head2 all
1217
1218 =over 4
1219
1220 =item Arguments: none
1221
1222 =item Return Value: @objects
1223
1224 =back
1225
1226 Returns all elements in the resultset. Called implicitly if the resultset
1227 is returned in list context.
1228
1229 =cut
1230
1231 sub all {
1232   my $self = shift;
1233   if(@_) {
1234       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1235   }
1236
1237   return @{ $self->get_cache } if $self->get_cache;
1238
1239   my @obj;
1240
1241   # TODO: don't call resolve here
1242   if (keys %{$self->_resolved_attrs->{collapse}}) {
1243 #  if ($self->{attrs}{prefetch}) {
1244       # Using $self->cursor->all is really just an optimisation.
1245       # If we're collapsing has_many prefetches it probably makes
1246       # very little difference, and this is cleaner than hacking
1247       # _construct_object to survive the approach
1248     my @row = $self->cursor->next;
1249     while (@row) {
1250       push(@obj, $self->_construct_object(@row));
1251       @row = (exists $self->{stashed_row}
1252                ? @{delete $self->{stashed_row}}
1253                : $self->cursor->next);
1254     }
1255   } else {
1256     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1257   }
1258
1259   $self->set_cache(\@obj) if $self->{attrs}{cache};
1260   return @obj;
1261 }
1262
1263 =head2 reset
1264
1265 =over 4
1266
1267 =item Arguments: none
1268
1269 =item Return Value: $self
1270
1271 =back
1272
1273 Resets the resultset's cursor, so you can iterate through the elements again.
1274
1275 =cut
1276
1277 sub reset {
1278   my ($self) = @_;
1279   delete $self->{_attrs} if exists $self->{_attrs};
1280   $self->{all_cache_position} = 0;
1281   $self->cursor->reset;
1282   return $self;
1283 }
1284
1285 =head2 first
1286
1287 =over 4
1288
1289 =item Arguments: none
1290
1291 =item Return Value: $object?
1292
1293 =back
1294
1295 Resets the resultset and returns an object for the first result (if the
1296 resultset returns anything).
1297
1298 =cut
1299
1300 sub first {
1301   return $_[0]->reset->next;
1302 }
1303
1304 # _cond_for_update_delete
1305 #
1306 # update/delete require the condition to be modified to handle
1307 # the differing SQL syntax available.  This transforms the $self->{cond}
1308 # appropriately, returning the new condition.
1309
1310 sub _cond_for_update_delete {
1311   my ($self, $full_cond) = @_;
1312   my $cond = {};
1313
1314   $full_cond ||= $self->{cond};
1315   # No-op. No condition, we're updating/deleting everything
1316   return $cond unless ref $full_cond;
1317
1318   if (ref $full_cond eq 'ARRAY') {
1319     $cond = [
1320       map {
1321         my %hash;
1322         foreach my $key (keys %{$_}) {
1323           $key =~ /([^.]+)$/;
1324           $hash{$1} = $_->{$key};
1325         }
1326         \%hash;
1327       } @{$full_cond}
1328     ];
1329   }
1330   elsif (ref $full_cond eq 'HASH') {
1331     if ((keys %{$full_cond})[0] eq '-and') {
1332       $cond->{-and} = [];
1333
1334       my @cond = @{$full_cond->{-and}};
1335       for (my $i = 0; $i < @cond; $i++) {
1336         my $entry = $cond[$i];
1337
1338         my $hash;
1339         if (ref $entry eq 'HASH') {
1340           $hash = $self->_cond_for_update_delete($entry);
1341         }
1342         else {
1343           $entry =~ /([^.]+)$/;
1344           $hash->{$1} = $cond[++$i];
1345         }
1346
1347         push @{$cond->{-and}}, $hash;
1348       }
1349     }
1350     else {
1351       foreach my $key (keys %{$full_cond}) {
1352         $key =~ /([^.]+)$/;
1353         $cond->{$1} = $full_cond->{$key};
1354       }
1355     }
1356   }
1357   else {
1358     $self->throw_exception(
1359       "Can't update/delete on resultset with condition unless hash or array"
1360     );
1361   }
1362
1363   return $cond;
1364 }
1365
1366
1367 =head2 update
1368
1369 =over 4
1370
1371 =item Arguments: \%values
1372
1373 =item Return Value: $storage_rv
1374
1375 =back
1376
1377 Sets the specified columns in the resultset to the supplied values in a
1378 single query. Return value will be true if the update succeeded or false
1379 if no records were updated; exact type of success value is storage-dependent.
1380
1381 =cut
1382
1383 sub update {
1384   my ($self, $values) = @_;
1385   $self->throw_exception("Values for update must be a hash")
1386     unless ref $values eq 'HASH';
1387
1388   carp(   'WARNING! Currently $rs->update() does not generate proper SQL'
1389         . ' on joined resultsets, and may affect rows well outside of the'
1390         . ' contents of $rs. Use at your own risk' )
1391     if ( $self->{attrs}{seen_join} );
1392
1393   my $cond = $self->_cond_for_update_delete;
1394
1395   return $self->result_source->storage->update(
1396     $self->result_source, $values, $cond
1397   );
1398 }
1399
1400 =head2 update_all
1401
1402 =over 4
1403
1404 =item Arguments: \%values
1405
1406 =item Return Value: 1
1407
1408 =back
1409
1410 Fetches all objects and updates them one at a time. Note that C<update_all>
1411 will run DBIC cascade triggers, while L</update> will not.
1412
1413 =cut
1414
1415 sub update_all {
1416   my ($self, $values) = @_;
1417   $self->throw_exception("Values for update must be a hash")
1418     unless ref $values eq 'HASH';
1419   foreach my $obj ($self->all) {
1420     $obj->set_columns($values)->update;
1421   }
1422   return 1;
1423 }
1424
1425 =head2 delete
1426
1427 =over 4
1428
1429 =item Arguments: none
1430
1431 =item Return Value: 1
1432
1433 =back
1434
1435 Deletes the contents of the resultset from its result source. Note that this
1436 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1437 to run. See also L<DBIx::Class::Row/delete>.
1438
1439 delete may not generate correct SQL for a query with joins or a resultset
1440 chained from a related resultset.  In this case it will generate a warning:-
1441
1442   WARNING! Currently $rs->delete() does not generate proper SQL on
1443   joined resultsets, and may delete rows well outside of the contents
1444   of $rs. Use at your own risk
1445
1446 In these cases you may find that delete_all is more appropriate, or you
1447 need to respecify your query in a way that can be expressed without a join.
1448
1449 =cut
1450
1451 sub delete {
1452   my ($self) = @_;
1453   $self->throw_exception("Delete should not be passed any arguments")
1454     if $_[1];
1455   carp(   'WARNING! Currently $rs->delete() does not generate proper SQL'
1456         . ' on joined resultsets, and may delete rows well outside of the'
1457         . ' contents of $rs. Use at your own risk' )
1458     if ( $self->{attrs}{seen_join} );
1459   my $cond = $self->_cond_for_update_delete;
1460
1461   $self->result_source->storage->delete($self->result_source, $cond);
1462   return 1;
1463 }
1464
1465 =head2 delete_all
1466
1467 =over 4
1468
1469 =item Arguments: none
1470
1471 =item Return Value: 1
1472
1473 =back
1474
1475 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1476 will run DBIC cascade triggers, while L</delete> will not.
1477
1478 =cut
1479
1480 sub delete_all {
1481   my ($self) = @_;
1482   $_->delete for $self->all;
1483   return 1;
1484 }
1485
1486 =head2 populate
1487
1488 =over 4
1489
1490 =item Arguments: \@data;
1491
1492 =back
1493
1494 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1495 For the arrayref of hashrefs style each hashref should be a structure suitable
1496 forsubmitting to a $resultset->create(...) method.
1497
1498 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1499 to insert the data, as this is a faster method.
1500
1501 Otherwise, each set of data is inserted into the database using
1502 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1503 objects is returned.
1504
1505 Example:  Assuming an Artist Class that has many CDs Classes relating:
1506
1507   my $Artist_rs = $schema->resultset("Artist");
1508
1509   ## Void Context Example
1510   $Artist_rs->populate([
1511      { artistid => 4, name => 'Manufactured Crap', cds => [
1512         { title => 'My First CD', year => 2006 },
1513         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1514       ],
1515      },
1516      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1517         { title => 'My parents sold me to a record company' ,year => 2005 },
1518         { title => 'Why Am I So Ugly?', year => 2006 },
1519         { title => 'I Got Surgery and am now Popular', year => 2007 }
1520       ],
1521      },
1522   ]);
1523
1524   ## Array Context Example
1525   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1526     { name => "Artist One"},
1527     { name => "Artist Two"},
1528     { name => "Artist Three", cds=> [
1529     { title => "First CD", year => 2007},
1530     { title => "Second CD", year => 2008},
1531   ]}
1532   ]);
1533
1534   print $ArtistOne->name; ## response is 'Artist One'
1535   print $ArtistThree->cds->count ## reponse is '2'
1536
1537 For the arrayref of arrayrefs style,  the first element should be a list of the
1538 fieldsnames to which the remaining elements are rows being inserted.  For
1539 example:
1540
1541   $Arstist_rs->populate([
1542     [qw/artistid name/],
1543     [100, 'A Formally Unknown Singer'],
1544     [101, 'A singer that jumped the shark two albums ago'],
1545     [102, 'An actually cool singer.'],
1546   ]);
1547
1548 Please note an important effect on your data when choosing between void and
1549 wantarray context. Since void context goes straight to C<insert_bulk> in
1550 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1551 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1552 create primary keys for you, you will find that your PKs are empty.  In this
1553 case you will have to use the wantarray context in order to create those
1554 values.
1555
1556 =cut
1557
1558 sub populate {
1559   my $self = shift @_;
1560   my $data = ref $_[0][0] eq 'HASH'
1561     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1562     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1563
1564   if(defined wantarray) {
1565     my @created;
1566     foreach my $item (@$data) {
1567       push(@created, $self->create($item));
1568     }
1569     return @created;
1570   } else {
1571     my ($first, @rest) = @$data;
1572
1573     my @names = grep {!ref $first->{$_}} keys %$first;
1574     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1575     my @pks = $self->result_source->primary_columns;
1576
1577     ## do the belongs_to relationships
1578     foreach my $index (0..$#$data) {
1579       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1580         my @ret = $self->populate($data);
1581         return;
1582       }
1583
1584       foreach my $rel (@rels) {
1585         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1586         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1587         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1588         my $related = $result->result_source->resolve_condition(
1589           $result->result_source->relationship_info($reverse)->{cond},
1590           $self,
1591           $result,
1592         );
1593
1594         delete $data->[$index]->{$rel};
1595         $data->[$index] = {%{$data->[$index]}, %$related};
1596
1597         push @names, keys %$related if $index == 0;
1598       }
1599     }
1600
1601     ## do bulk insert on current row
1602     my @values = map { [ @$_{@names} ] } @$data;
1603
1604     $self->result_source->storage->insert_bulk(
1605       $self->result_source,
1606       \@names,
1607       \@values,
1608     );
1609
1610     ## do the has_many relationships
1611     foreach my $item (@$data) {
1612
1613       foreach my $rel (@rels) {
1614         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1615
1616         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1617      || $self->throw_exception('Cannot find the relating object.');
1618
1619         my $child = $parent->$rel;
1620
1621         my $related = $child->result_source->resolve_condition(
1622           $parent->result_source->relationship_info($rel)->{cond},
1623           $child,
1624           $parent,
1625         );
1626
1627         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1628         my @populate = map { {%$_, %$related} } @rows_to_add;
1629
1630         $child->populate( \@populate );
1631       }
1632     }
1633   }
1634 }
1635
1636 =head2 _normalize_populate_args ($args)
1637
1638 Private method used by L</populate> to normalize its incoming arguments.  Factored
1639 out in case you want to subclass and accept new argument structures to the
1640 L</populate> method.
1641
1642 =cut
1643
1644 sub _normalize_populate_args {
1645   my ($self, $data) = @_;
1646   my @names = @{shift(@$data)};
1647   my @results_to_create;
1648   foreach my $datum (@$data) {
1649     my %result_to_create;
1650     foreach my $index (0..$#names) {
1651       $result_to_create{$names[$index]} = $$datum[$index];
1652     }
1653     push @results_to_create, \%result_to_create;
1654   }
1655   return \@results_to_create;
1656 }
1657
1658 =head2 pager
1659
1660 =over 4
1661
1662 =item Arguments: none
1663
1664 =item Return Value: $pager
1665
1666 =back
1667
1668 Return Value a L<Data::Page> object for the current resultset. Only makes
1669 sense for queries with a C<page> attribute.
1670
1671 To get the full count of entries for a paged resultset, call
1672 C<total_entries> on the L<Data::Page> object.
1673
1674 =cut
1675
1676 sub pager {
1677   my ($self) = @_;
1678   my $attrs = $self->{attrs};
1679   $self->throw_exception("Can't create pager for non-paged rs")
1680     unless $self->{attrs}{page};
1681   $attrs->{rows} ||= 10;
1682   return $self->{pager} ||= Data::Page->new(
1683     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1684 }
1685
1686 =head2 page
1687
1688 =over 4
1689
1690 =item Arguments: $page_number
1691
1692 =item Return Value: $rs
1693
1694 =back
1695
1696 Returns a resultset for the $page_number page of the resultset on which page
1697 is called, where each page contains a number of rows equal to the 'rows'
1698 attribute set on the resultset (10 by default).
1699
1700 =cut
1701
1702 sub page {
1703   my ($self, $page) = @_;
1704   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1705 }
1706
1707 =head2 new_result
1708
1709 =over 4
1710
1711 =item Arguments: \%vals
1712
1713 =item Return Value: $rowobject
1714
1715 =back
1716
1717 Creates a new row object in the resultset's result class and returns
1718 it. The row is not inserted into the database at this point, call
1719 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1720 will tell you whether the row object has been inserted or not.
1721
1722 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1723
1724 =cut
1725
1726 sub new_result {
1727   my ($self, $values) = @_;
1728   $self->throw_exception( "new_result needs a hash" )
1729     unless (ref $values eq 'HASH');
1730
1731   my %new;
1732   my $alias = $self->{attrs}{alias};
1733
1734   if (
1735     defined $self->{cond}
1736     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1737   ) {
1738     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1739     $new{-from_resultset} = [ keys %new ] if keys %new;
1740   } else {
1741     $self->throw_exception(
1742       "Can't abstract implicit construct, condition not a hash"
1743     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1744
1745     my $collapsed_cond = (
1746       $self->{cond}
1747         ? $self->_collapse_cond($self->{cond})
1748         : {}
1749     );
1750
1751     # precendence must be given to passed values over values inherited from
1752     # the cond, so the order here is important.
1753     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1754     while( my($col,$value) = each %implied ){
1755       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1756         $new{$col} = $value->{'='};
1757         next;
1758       }
1759       $new{$col} = $value if $self->_is_deterministic_value($value);
1760     }
1761   }
1762
1763   %new = (
1764     %new,
1765     %{ $self->_remove_alias($values, $alias) },
1766     -source_handle => $self->_source_handle,
1767     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1768   );
1769
1770   return $self->result_class->new(\%new);
1771 }
1772
1773 # _is_deterministic_value
1774 #
1775 # Make an effor to strip non-deterministic values from the condition,
1776 # to make sure new_result chokes less
1777
1778 sub _is_deterministic_value {
1779   my $self = shift;
1780   my $value = shift;
1781   my $ref_type = ref $value;
1782   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1783   return 1 if Scalar::Util::blessed($value);
1784   return 0;
1785 }
1786
1787 # _collapse_cond
1788 #
1789 # Recursively collapse the condition.
1790
1791 sub _collapse_cond {
1792   my ($self, $cond, $collapsed) = @_;
1793
1794   $collapsed ||= {};
1795
1796   if (ref $cond eq 'ARRAY') {
1797     foreach my $subcond (@$cond) {
1798       next unless ref $subcond;  # -or
1799 #      warn "ARRAY: " . Dumper $subcond;
1800       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1801     }
1802   }
1803   elsif (ref $cond eq 'HASH') {
1804     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1805       foreach my $subcond (@{$cond->{-and}}) {
1806 #        warn "HASH: " . Dumper $subcond;
1807         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1808       }
1809     }
1810     else {
1811 #      warn "LEAF: " . Dumper $cond;
1812       foreach my $col (keys %$cond) {
1813         my $value = $cond->{$col};
1814         $collapsed->{$col} = $value;
1815       }
1816     }
1817   }
1818
1819   return $collapsed;
1820 }
1821
1822 # _remove_alias
1823 #
1824 # Remove the specified alias from the specified query hash. A copy is made so
1825 # the original query is not modified.
1826
1827 sub _remove_alias {
1828   my ($self, $query, $alias) = @_;
1829
1830   my %orig = %{ $query || {} };
1831   my %unaliased;
1832
1833   foreach my $key (keys %orig) {
1834     if ($key !~ /\./) {
1835       $unaliased{$key} = $orig{$key};
1836       next;
1837     }
1838     $unaliased{$1} = $orig{$key}
1839       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1840   }
1841
1842   return \%unaliased;
1843 }
1844
1845 =head2 as_query (EXPERIMENTAL)
1846
1847 =over 4
1848
1849 =item Arguments: none
1850
1851 =item Return Value: \[ $sql, @bind ]
1852
1853 =back
1854
1855 Returns the SQL query and bind vars associated with the invocant.
1856
1857 This is generally used as the RHS for a subquery.
1858
1859 B<NOTE>: This feature is still experimental.
1860
1861 =cut
1862
1863 sub as_query { return shift->cursor->as_query(@_) }
1864
1865 =head2 find_or_new
1866
1867 =over 4
1868
1869 =item Arguments: \%vals, \%attrs?
1870
1871 =item Return Value: $rowobject
1872
1873 =back
1874
1875   my $artist = $schema->resultset('Artist')->find_or_new(
1876     { artist => 'fred' }, { key => 'artists' });
1877
1878   $cd->cd_to_producer->find_or_new({ producer => $producer },
1879                                    { key => 'primary });
1880
1881 Find an existing record from this resultset, based on its primary
1882 key, or a unique constraint. If none exists, instantiate a new result
1883 object and return it. The object will not be saved into your storage
1884 until you call L<DBIx::Class::Row/insert> on it.
1885
1886 You most likely want this method when looking for existing rows using
1887 a unique constraint that is not the primary key, or looking for
1888 related rows.
1889
1890 If you want objects to be saved immediately, use L</find_or_create> instead.
1891
1892 B<Note>: C<find_or_new> is probably not what you want when creating a
1893 new row in a table that uses primary keys supplied by the
1894 database. Passing in a primary key column with a value of I<undef>
1895 will cause L</find> to attempt to search for a row with a value of
1896 I<NULL>.
1897
1898 =cut
1899
1900 sub find_or_new {
1901   my $self     = shift;
1902   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1903   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1904   my $exists   = $self->find($hash, $attrs);
1905   return defined $exists ? $exists : $self->new_result($hash);
1906 }
1907
1908 =head2 create
1909
1910 =over 4
1911
1912 =item Arguments: \%vals
1913
1914 =item Return Value: a L<DBIx::Class::Row> $object
1915
1916 =back
1917
1918 Attempt to create a single new row or a row with multiple related rows
1919 in the table represented by the resultset (and related tables). This
1920 will not check for duplicate rows before inserting, use
1921 L</find_or_create> to do that.
1922
1923 To create one row for this resultset, pass a hashref of key/value
1924 pairs representing the columns of the table and the values you wish to
1925 store. If the appropriate relationships are set up, foreign key fields
1926 can also be passed an object representing the foreign row, and the
1927 value will be set to its primary key.
1928
1929 To create related objects, pass a hashref for the value if the related
1930 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1931 and use the name of the relationship as the key. (NOT the name of the field,
1932 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1933 of hashrefs containing the data for each of the rows to create in the foreign
1934 tables, again using the relationship name as the key.
1935
1936 Instead of hashrefs of plain related data (key/value pairs), you may
1937 also pass new or inserted objects. New objects (not inserted yet, see
1938 L</new>), will be inserted into their appropriate tables.
1939
1940 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1941
1942 Example of creating a new row.
1943
1944   $person_rs->create({
1945     name=>"Some Person",
1946     email=>"somebody@someplace.com"
1947   });
1948
1949 Example of creating a new row and also creating rows in a related C<has_many>
1950 or C<has_one> resultset.  Note Arrayref.
1951
1952   $artist_rs->create(
1953      { artistid => 4, name => 'Manufactured Crap', cds => [
1954         { title => 'My First CD', year => 2006 },
1955         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1956       ],
1957      },
1958   );
1959
1960 Example of creating a new row and also creating a row in a related
1961 C<belongs_to>resultset. Note Hashref.
1962
1963   $cd_rs->create({
1964     title=>"Music for Silly Walks",
1965     year=>2000,
1966     artist => {
1967       name=>"Silly Musician",
1968     }
1969   });
1970
1971 =cut
1972
1973 sub create {
1974   my ($self, $attrs) = @_;
1975   $self->throw_exception( "create needs a hashref" )
1976     unless ref $attrs eq 'HASH';
1977   return $self->new_result($attrs)->insert;
1978 }
1979
1980 =head2 find_or_create
1981
1982 =over 4
1983
1984 =item Arguments: \%vals, \%attrs?
1985
1986 =item Return Value: $rowobject
1987
1988 =back
1989
1990   $cd->cd_to_producer->find_or_create({ producer => $producer },
1991                                       { key => 'primary });
1992
1993 Tries to find a record based on its primary key or unique constraints; if none
1994 is found, creates one and returns that instead.
1995
1996   my $cd = $schema->resultset('CD')->find_or_create({
1997     cdid   => 5,
1998     artist => 'Massive Attack',
1999     title  => 'Mezzanine',
2000     year   => 2005,
2001   });
2002
2003 Also takes an optional C<key> attribute, to search by a specific key or unique
2004 constraint. For example:
2005
2006   my $cd = $schema->resultset('CD')->find_or_create(
2007     {
2008       artist => 'Massive Attack',
2009       title  => 'Mezzanine',
2010     },
2011     { key => 'cd_artist_title' }
2012   );
2013
2014 B<Note>: Because find_or_create() reads from the database and then
2015 possibly inserts based on the result, this method is subject to a race
2016 condition. Another process could create a record in the table after
2017 the find has completed and before the create has started. To avoid
2018 this problem, use find_or_create() inside a transaction.
2019
2020 B<Note>: C<find_or_create> is probably not what you want when creating
2021 a new row in a table that uses primary keys supplied by the
2022 database. Passing in a primary key column with a value of I<undef>
2023 will cause L</find> to attempt to search for a row with a value of
2024 I<NULL>.
2025
2026 See also L</find> and L</update_or_create>. For information on how to declare
2027 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2028
2029 =cut
2030
2031 sub find_or_create {
2032   my $self     = shift;
2033   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2034   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2035   my $exists   = $self->find($hash, $attrs);
2036   return defined $exists ? $exists : $self->create($hash);
2037 }
2038
2039 =head2 update_or_create
2040
2041 =over 4
2042
2043 =item Arguments: \%col_values, { key => $unique_constraint }?
2044
2045 =item Return Value: $rowobject
2046
2047 =back
2048
2049   $resultset->update_or_create({ col => $val, ... });
2050
2051 First, searches for an existing row matching one of the unique constraints
2052 (including the primary key) on the source of this resultset. If a row is
2053 found, updates it with the other given column values. Otherwise, creates a new
2054 row.
2055
2056 Takes an optional C<key> attribute to search on a specific unique constraint.
2057 For example:
2058
2059   # In your application
2060   my $cd = $schema->resultset('CD')->update_or_create(
2061     {
2062       artist => 'Massive Attack',
2063       title  => 'Mezzanine',
2064       year   => 1998,
2065     },
2066     { key => 'cd_artist_title' }
2067   );
2068
2069   $cd->cd_to_producer->update_or_create({
2070     producer => $producer,
2071     name => 'harry',
2072   }, {
2073     key => 'primary,
2074   });
2075
2076
2077 If no C<key> is specified, it searches on all unique constraints defined on the
2078 source, including the primary key.
2079
2080 If the C<key> is specified as C<primary>, it searches only on the primary key.
2081
2082 See also L</find> and L</find_or_create>. For information on how to declare
2083 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2084
2085 B<Note>: C<update_or_create> is probably not what you want when
2086 looking for a row in a table that uses primary keys supplied by the
2087 database, unless you actually have a key value. Passing in a primary
2088 key column with a value of I<undef> will cause L</find> to attempt to
2089 search for a row with a value of I<NULL>.
2090
2091 =cut
2092
2093 sub update_or_create {
2094   my $self = shift;
2095   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2096   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2097
2098   my $row = $self->find($cond, $attrs);
2099   if (defined $row) {
2100     $row->update($cond);
2101     return $row;
2102   }
2103
2104   return $self->create($cond);
2105 }
2106
2107 =head2 update_or_new
2108
2109 =over 4
2110
2111 =item Arguments: \%col_values, { key => $unique_constraint }?
2112
2113 =item Return Value: $rowobject
2114
2115 =back
2116
2117   $resultset->update_or_new({ col => $val, ... });
2118
2119 First, searches for an existing row matching one of the unique constraints
2120 (including the primary key) on the source of this resultset. If a row is
2121 found, updates it with the other given column values. Otherwise, instantiate
2122 a new result object and return it. The object will not be saved into your storage
2123 until you call L<DBIx::Class::Row/insert> on it.
2124
2125 Takes an optional C<key> attribute to search on a specific unique constraint.
2126 For example:
2127
2128   # In your application
2129   my $cd = $schema->resultset('CD')->update_or_new(
2130     {
2131       artist => 'Massive Attack',
2132       title  => 'Mezzanine',
2133       year   => 1998,
2134     },
2135     { key => 'cd_artist_title' }
2136   );
2137
2138   if ($cd->in_storage) {
2139       # the cd was updated
2140   }
2141   else {
2142       # the cd is not yet in the database, let's insert it
2143       $cd->insert;
2144   }
2145
2146 See also L</find>, L</find_or_create> and L<find_or_new>.
2147
2148 =cut
2149
2150 sub update_or_new {
2151     my $self  = shift;
2152     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2153     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2154
2155     my $row = $self->find( $cond, $attrs );
2156     if ( defined $row ) {
2157         $row->update($cond);
2158         return $row;
2159     }
2160
2161     return $self->new_result($cond);
2162 }
2163
2164 =head2 get_cache
2165
2166 =over 4
2167
2168 =item Arguments: none
2169
2170 =item Return Value: \@cache_objects?
2171
2172 =back
2173
2174 Gets the contents of the cache for the resultset, if the cache is set.
2175
2176 The cache is populated either by using the L</prefetch> attribute to
2177 L</search> or by calling L</set_cache>.
2178
2179 =cut
2180
2181 sub get_cache {
2182   shift->{all_cache};
2183 }
2184
2185 =head2 set_cache
2186
2187 =over 4
2188
2189 =item Arguments: \@cache_objects
2190
2191 =item Return Value: \@cache_objects
2192
2193 =back
2194
2195 Sets the contents of the cache for the resultset. Expects an arrayref
2196 of objects of the same class as those produced by the resultset. Note that
2197 if the cache is set the resultset will return the cached objects rather
2198 than re-querying the database even if the cache attr is not set.
2199
2200 The contents of the cache can also be populated by using the
2201 L</prefetch> attribute to L</search>.
2202
2203 =cut
2204
2205 sub set_cache {
2206   my ( $self, $data ) = @_;
2207   $self->throw_exception("set_cache requires an arrayref")
2208       if defined($data) && (ref $data ne 'ARRAY');
2209   $self->{all_cache} = $data;
2210 }
2211
2212 =head2 clear_cache
2213
2214 =over 4
2215
2216 =item Arguments: none
2217
2218 =item Return Value: []
2219
2220 =back
2221
2222 Clears the cache for the resultset.
2223
2224 =cut
2225
2226 sub clear_cache {
2227   shift->set_cache(undef);
2228 }
2229
2230 =head2 related_resultset
2231
2232 =over 4
2233
2234 =item Arguments: $relationship_name
2235
2236 =item Return Value: $resultset
2237
2238 =back
2239
2240 Returns a related resultset for the supplied relationship name.
2241
2242   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2243
2244 =cut
2245
2246 sub related_resultset {
2247   my ($self, $rel) = @_;
2248
2249   $self->{related_resultsets} ||= {};
2250   return $self->{related_resultsets}{$rel} ||= do {
2251     my $rel_obj = $self->result_source->relationship_info($rel);
2252
2253     $self->throw_exception(
2254       "search_related: result source '" . $self->result_source->source_name .
2255         "' has no such relationship $rel")
2256       unless $rel_obj;
2257
2258     my ($from,$seen) = $self->_resolve_from($rel);
2259
2260     my $join_count = $seen->{$rel};
2261     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2262
2263     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2264     my %attrs = %{$self->{attrs}||{}};
2265     delete @attrs{qw(result_class alias)};
2266
2267     my $new_cache;
2268
2269     if (my $cache = $self->get_cache) {
2270       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2271         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2272                         @$cache ];
2273       }
2274     }
2275
2276     my $rel_source = $self->result_source->related_source($rel);
2277
2278     my $new = do {
2279
2280       # The reason we do this now instead of passing the alias to the
2281       # search_rs below is that if you wrap/overload resultset on the
2282       # source you need to know what alias it's -going- to have for things
2283       # to work sanely (e.g. RestrictWithObject wants to be able to add
2284       # extra query restrictions, and these may need to be $alias.)
2285
2286       my $attrs = $rel_source->resultset_attributes;
2287       local $attrs->{alias} = $alias;
2288
2289       $rel_source->resultset
2290                  ->search_rs(
2291                      undef, {
2292                        %attrs,
2293                        join => undef,
2294                        prefetch => undef,
2295                        select => undef,
2296                        as => undef,
2297                        where => $self->{cond},
2298                        seen_join => $seen,
2299                        from => $from,
2300                    });
2301     };
2302     $new->set_cache($new_cache) if $new_cache;
2303     $new;
2304   };
2305 }
2306
2307 =head2 current_source_alias
2308
2309 =over 4
2310
2311 =item Arguments: none
2312
2313 =item Return Value: $source_alias
2314
2315 =back
2316
2317 Returns the current table alias for the result source this resultset is built
2318 on, that will be used in the SQL query. Usually it is C<me>.
2319
2320 Currently the source alias that refers to the result set returned by a
2321 L</search>/L</find> family method depends on how you got to the resultset: it's
2322 C<me> by default, but eg. L</search_related> aliases it to the related result
2323 source name (and keeps C<me> referring to the original result set). The long
2324 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2325 (and make this method unnecessary).
2326
2327 Thus it's currently necessary to use this method in predefined queries (see
2328 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2329 source alias of the current result set:
2330
2331   # in a result set class
2332   sub modified_by {
2333     my ($self, $user) = @_;
2334
2335     my $me = $self->current_source_alias;
2336
2337     return $self->search(
2338       "$me.modified" => $user->id,
2339     );
2340   }
2341
2342 =cut
2343
2344 sub current_source_alias {
2345   my ($self) = @_;
2346
2347   return ($self->{attrs} || {})->{alias} || 'me';
2348 }
2349
2350 sub _resolve_from {
2351   my ($self, $extra_join) = @_;
2352   my $source = $self->result_source;
2353   my $attrs = $self->{attrs};
2354
2355   my $from = $attrs->{from}
2356     || [ { $attrs->{alias} => $source->from } ];
2357
2358   my $seen = { %{$attrs->{seen_join}||{}} };
2359
2360   my $join = ($attrs->{join}
2361                ? [ $attrs->{join}, $extra_join ]
2362                : $extra_join);
2363
2364   # we need to take the prefetch the attrs into account before we
2365   # ->resolve_join as otherwise they get lost - captainL
2366   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2367
2368   $from = [
2369     @$from,
2370     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2371   ];
2372
2373   return ($from,$seen);
2374 }
2375
2376 sub _resolved_attrs {
2377   my $self = shift;
2378   return $self->{_attrs} if $self->{_attrs};
2379
2380   my $attrs  = { %{ $self->{attrs} || {} } };
2381   my $source = $self->result_source;
2382   my $alias  = $attrs->{alias};
2383
2384   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2385   my @colbits;
2386
2387   # build columns (as long as select isn't set) into a set of as/select hashes
2388   unless ( $attrs->{select} ) {
2389       @colbits = map {
2390           ( ref($_) eq 'HASH' )
2391               ? $_
2392               : {
2393                   (
2394                     /^\Q${alias}.\E(.+)$/
2395                       ? "$1"
2396                       : "$_"
2397                   )
2398                 =>
2399                   (
2400                     /\./
2401                       ? "$_"
2402                       : "${alias}.$_"
2403                   )
2404             }
2405       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2406   }
2407   # add the additional columns on
2408   foreach ( 'include_columns', '+columns' ) {
2409       push @colbits, map {
2410           ( ref($_) eq 'HASH' )
2411             ? $_
2412             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2413       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2414   }
2415
2416   # start with initial select items
2417   if ( $attrs->{select} ) {
2418     $attrs->{select} =
2419         ( ref $attrs->{select} eq 'ARRAY' )
2420       ? [ @{ $attrs->{select} } ]
2421       : [ $attrs->{select} ];
2422     $attrs->{as} = (
2423       $attrs->{as}
2424       ? (
2425         ref $attrs->{as} eq 'ARRAY'
2426         ? [ @{ $attrs->{as} } ]
2427         : [ $attrs->{as} ]
2428         )
2429       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2430     );
2431   }
2432   else {
2433
2434     # otherwise we intialise select & as to empty
2435     $attrs->{select} = [];
2436     $attrs->{as}     = [];
2437   }
2438
2439   # now add colbits to select/as
2440   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2441   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2442
2443   my $adds;
2444   if ( $adds = delete $attrs->{'+select'} ) {
2445     $adds = [$adds] unless ref $adds eq 'ARRAY';
2446     push(
2447       @{ $attrs->{select} },
2448       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2449     );
2450   }
2451   if ( $adds = delete $attrs->{'+as'} ) {
2452     $adds = [$adds] unless ref $adds eq 'ARRAY';
2453     push( @{ $attrs->{as} }, @$adds );
2454   }
2455
2456   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2457
2458   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2459     my $join = delete $attrs->{join} || {};
2460
2461     if ( defined $attrs->{prefetch} ) {
2462       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2463
2464     }
2465
2466     $attrs->{from} =    # have to copy here to avoid corrupting the original
2467       [
2468       @{ $attrs->{from} },
2469       $source->resolve_join(
2470         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2471       )
2472       ];
2473
2474   }
2475
2476   $attrs->{group_by} ||= $attrs->{select}
2477     if delete $attrs->{distinct};
2478   if ( $attrs->{order_by} ) {
2479     $attrs->{order_by} = (
2480       ref( $attrs->{order_by} ) eq 'ARRAY'
2481       ? [ @{ $attrs->{order_by} } ]
2482       : [ $attrs->{order_by} ]
2483     );
2484   }
2485   else {
2486     $attrs->{order_by} = [];
2487   }
2488
2489   my $collapse = $attrs->{collapse} || {};
2490   if ( my $prefetch = delete $attrs->{prefetch} ) {
2491     $prefetch = $self->_merge_attr( {}, $prefetch );
2492     my @pre_order;
2493     my $seen = { %{ $attrs->{seen_join} || {} } };
2494     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2495
2496       # bring joins back to level of current class
2497       my @prefetch =
2498         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2499       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2500       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2501     }
2502     push( @{ $attrs->{order_by} }, @pre_order );
2503   }
2504   $attrs->{collapse} = $collapse;
2505
2506   if ( $attrs->{page} ) {
2507     $attrs->{offset} ||= 0;
2508     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2509   }
2510
2511   return $self->{_attrs} = $attrs;
2512 }
2513
2514 sub _rollout_attr {
2515   my ($self, $attr) = @_;
2516
2517   if (ref $attr eq 'HASH') {
2518     return $self->_rollout_hash($attr);
2519   } elsif (ref $attr eq 'ARRAY') {
2520     return $self->_rollout_array($attr);
2521   } else {
2522     return [$attr];
2523   }
2524 }
2525
2526 sub _rollout_array {
2527   my ($self, $attr) = @_;
2528
2529   my @rolled_array;
2530   foreach my $element (@{$attr}) {
2531     if (ref $element eq 'HASH') {
2532       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2533     } elsif (ref $element eq 'ARRAY') {
2534       #  XXX - should probably recurse here
2535       push( @rolled_array, @{$self->_rollout_array($element)} );
2536     } else {
2537       push( @rolled_array, $element );
2538     }
2539   }
2540   return \@rolled_array;
2541 }
2542
2543 sub _rollout_hash {
2544   my ($self, $attr) = @_;
2545
2546   my @rolled_array;
2547   foreach my $key (keys %{$attr}) {
2548     push( @rolled_array, { $key => $attr->{$key} } );
2549   }
2550   return \@rolled_array;
2551 }
2552
2553 sub _calculate_score {
2554   my ($self, $a, $b) = @_;
2555
2556   if (ref $b eq 'HASH') {
2557     my ($b_key) = keys %{$b};
2558     if (ref $a eq 'HASH') {
2559       my ($a_key) = keys %{$a};
2560       if ($a_key eq $b_key) {
2561         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2562       } else {
2563         return 0;
2564       }
2565     } else {
2566       return ($a eq $b_key) ? 1 : 0;
2567     }
2568   } else {
2569     if (ref $a eq 'HASH') {
2570       my ($a_key) = keys %{$a};
2571       return ($b eq $a_key) ? 1 : 0;
2572     } else {
2573       return ($b eq $a) ? 1 : 0;
2574     }
2575   }
2576 }
2577
2578 sub _merge_attr {
2579   my ($self, $orig, $import) = @_;
2580
2581   return $import unless defined($orig);
2582   return $orig unless defined($import);
2583
2584   $orig = $self->_rollout_attr($orig);
2585   $import = $self->_rollout_attr($import);
2586
2587   my $seen_keys;
2588   foreach my $import_element ( @{$import} ) {
2589     # find best candidate from $orig to merge $b_element into
2590     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2591     foreach my $orig_element ( @{$orig} ) {
2592       my $score = $self->_calculate_score( $orig_element, $import_element );
2593       if ($score > $best_candidate->{score}) {
2594         $best_candidate->{position} = $position;
2595         $best_candidate->{score} = $score;
2596       }
2597       $position++;
2598     }
2599     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2600
2601     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2602       push( @{$orig}, $import_element );
2603     } else {
2604       my $orig_best = $orig->[$best_candidate->{position}];
2605       # merge orig_best and b_element together and replace original with merged
2606       if (ref $orig_best ne 'HASH') {
2607         $orig->[$best_candidate->{position}] = $import_element;
2608       } elsif (ref $import_element eq 'HASH') {
2609         my ($key) = keys %{$orig_best};
2610         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2611       }
2612     }
2613     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2614   }
2615
2616   return $orig;
2617 }
2618
2619 sub result_source {
2620     my $self = shift;
2621
2622     if (@_) {
2623         $self->_source_handle($_[0]->handle);
2624     } else {
2625         $self->_source_handle->resolve;
2626     }
2627 }
2628
2629 =head2 throw_exception
2630
2631 See L<DBIx::Class::Schema/throw_exception> for details.
2632
2633 =cut
2634
2635 sub throw_exception {
2636   my $self=shift;
2637   if (ref $self && $self->_source_handle->schema) {
2638     $self->_source_handle->schema->throw_exception(@_)
2639   } else {
2640     croak(@_);
2641   }
2642
2643 }
2644
2645 # XXX: FIXME: Attributes docs need clearing up
2646
2647 =head1 ATTRIBUTES
2648
2649 Attributes are used to refine a ResultSet in various ways when
2650 searching for data. They can be passed to any method which takes an
2651 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2652 L</count>.
2653
2654 These are in no particular order:
2655
2656 =head2 order_by
2657
2658 =over 4
2659
2660 =item Value: ( $order_by | \@order_by | \%order_by )
2661
2662 =back
2663
2664 Which column(s) to order the results by. If a single column name, or
2665 an arrayref of names is supplied, the argument is passed through
2666 directly to SQL. The hashref syntax allows for connection-agnostic
2667 specification of ordering direction:
2668
2669  For descending order:
2670
2671   order_by => { -desc => [qw/col1 col2 col3/] }
2672
2673  For explicit ascending order:
2674
2675   order_by => { -asc => 'col' }
2676
2677 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2678 supported, although you are strongly encouraged to use the hashref
2679 syntax as outlined above.
2680
2681 =head2 columns
2682
2683 =over 4
2684
2685 =item Value: \@columns
2686
2687 =back
2688
2689 Shortcut to request a particular set of columns to be retrieved. Each
2690 column spec may be a string (a table column name), or a hash (in which
2691 case the key is the C<as> value, and the value is used as the C<select>
2692 expression). Adds C<me.> onto the start of any column without a C<.> in
2693 it and sets C<select> from that, then auto-populates C<as> from
2694 C<select> as normal. (You may also use the C<cols> attribute, as in
2695 earlier versions of DBIC.)
2696
2697 =head2 +columns
2698
2699 =over 4
2700
2701 =item Value: \@columns
2702
2703 =back
2704
2705 Indicates additional columns to be selected from storage. Works the same
2706 as L</columns> but adds columns to the selection. (You may also use the
2707 C<include_columns> attribute, as in earlier versions of DBIC). For
2708 example:-
2709
2710   $schema->resultset('CD')->search(undef, {
2711     '+columns' => ['artist.name'],
2712     join => ['artist']
2713   });
2714
2715 would return all CDs and include a 'name' column to the information
2716 passed to object inflation. Note that the 'artist' is the name of the
2717 column (or relationship) accessor, and 'name' is the name of the column
2718 accessor in the related table.
2719
2720 =head2 include_columns
2721
2722 =over 4
2723
2724 =item Value: \@columns
2725
2726 =back
2727
2728 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2729
2730 =head2 select
2731
2732 =over 4
2733
2734 =item Value: \@select_columns
2735
2736 =back
2737
2738 Indicates which columns should be selected from the storage. You can use
2739 column names, or in the case of RDBMS back ends, function or stored procedure
2740 names:
2741
2742   $rs = $schema->resultset('Employee')->search(undef, {
2743     select => [
2744       'name',
2745       { count => 'employeeid' },
2746       { sum => 'salary' }
2747     ]
2748   });
2749
2750 When you use function/stored procedure names and do not supply an C<as>
2751 attribute, the column names returned are storage-dependent. E.g. MySQL would
2752 return a column named C<count(employeeid)> in the above example.
2753
2754 =head2 +select
2755
2756 =over 4
2757
2758 Indicates additional columns to be selected from storage.  Works the same as
2759 L</select> but adds columns to the selection.
2760
2761 =back
2762
2763 =head2 +as
2764
2765 =over 4
2766
2767 Indicates additional column names for those added via L</+select>. See L</as>.
2768
2769 =back
2770
2771 =head2 as
2772
2773 =over 4
2774
2775 =item Value: \@inflation_names
2776
2777 =back
2778
2779 Indicates column names for object inflation. That is, C<as>
2780 indicates the name that the column can be accessed as via the
2781 C<get_column> method (or via the object accessor, B<if one already
2782 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2783
2784 The C<as> attribute is used in conjunction with C<select>,
2785 usually when C<select> contains one or more function or stored
2786 procedure names:
2787
2788   $rs = $schema->resultset('Employee')->search(undef, {
2789     select => [
2790       'name',
2791       { count => 'employeeid' }
2792     ],
2793     as => ['name', 'employee_count'],
2794   });
2795
2796   my $employee = $rs->first(); # get the first Employee
2797
2798 If the object against which the search is performed already has an accessor
2799 matching a column name specified in C<as>, the value can be retrieved using
2800 the accessor as normal:
2801
2802   my $name = $employee->name();
2803
2804 If on the other hand an accessor does not exist in the object, you need to
2805 use C<get_column> instead:
2806
2807   my $employee_count = $employee->get_column('employee_count');
2808
2809 You can create your own accessors if required - see
2810 L<DBIx::Class::Manual::Cookbook> for details.
2811
2812 Please note: This will NOT insert an C<AS employee_count> into the SQL
2813 statement produced, it is used for internal access only. Thus
2814 attempting to use the accessor in an C<order_by> clause or similar
2815 will fail miserably.
2816
2817 To get around this limitation, you can supply literal SQL to your
2818 C<select> attibute that contains the C<AS alias> text, eg:
2819
2820   select => [\'myfield AS alias']
2821
2822 =head2 join
2823
2824 =over 4
2825
2826 =item Value: ($rel_name | \@rel_names | \%rel_names)
2827
2828 =back
2829
2830 Contains a list of relationships that should be joined for this query.  For
2831 example:
2832
2833   # Get CDs by Nine Inch Nails
2834   my $rs = $schema->resultset('CD')->search(
2835     { 'artist.name' => 'Nine Inch Nails' },
2836     { join => 'artist' }
2837   );
2838
2839 Can also contain a hash reference to refer to the other relation's relations.
2840 For example:
2841
2842   package MyApp::Schema::Track;
2843   use base qw/DBIx::Class/;
2844   __PACKAGE__->table('track');
2845   __PACKAGE__->add_columns(qw/trackid cd position title/);
2846   __PACKAGE__->set_primary_key('trackid');
2847   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2848   1;
2849
2850   # In your application
2851   my $rs = $schema->resultset('Artist')->search(
2852     { 'track.title' => 'Teardrop' },
2853     {
2854       join     => { cd => 'track' },
2855       order_by => 'artist.name',
2856     }
2857   );
2858
2859 You need to use the relationship (not the table) name in  conditions,
2860 because they are aliased as such. The current table is aliased as "me", so
2861 you need to use me.column_name in order to avoid ambiguity. For example:
2862
2863   # Get CDs from 1984 with a 'Foo' track
2864   my $rs = $schema->resultset('CD')->search(
2865     {
2866       'me.year' => 1984,
2867       'tracks.name' => 'Foo'
2868     },
2869     { join => 'tracks' }
2870   );
2871
2872 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2873 similarly for a third time). For e.g.
2874
2875   my $rs = $schema->resultset('Artist')->search({
2876     'cds.title'   => 'Down to Earth',
2877     'cds_2.title' => 'Popular',
2878   }, {
2879     join => [ qw/cds cds/ ],
2880   });
2881
2882 will return a set of all artists that have both a cd with title 'Down
2883 to Earth' and a cd with title 'Popular'.
2884
2885 If you want to fetch related objects from other tables as well, see C<prefetch>
2886 below.
2887
2888 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2889
2890 =head2 prefetch
2891
2892 =over 4
2893
2894 =item Value: ($rel_name | \@rel_names | \%rel_names)
2895
2896 =back
2897
2898 Contains one or more relationships that should be fetched along with
2899 the main query (when they are accessed afterwards the data will
2900 already be available, without extra queries to the database).  This is
2901 useful for when you know you will need the related objects, because it
2902 saves at least one query:
2903
2904   my $rs = $schema->resultset('Tag')->search(
2905     undef,
2906     {
2907       prefetch => {
2908         cd => 'artist'
2909       }
2910     }
2911   );
2912
2913 The initial search results in SQL like the following:
2914
2915   SELECT tag.*, cd.*, artist.* FROM tag
2916   JOIN cd ON tag.cd = cd.cdid
2917   JOIN artist ON cd.artist = artist.artistid
2918
2919 L<DBIx::Class> has no need to go back to the database when we access the
2920 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2921 case.
2922
2923 Simple prefetches will be joined automatically, so there is no need
2924 for a C<join> attribute in the above search.
2925
2926 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2927 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2928 with an accessor type of 'single' or 'filter'). A more complex example that
2929 prefetches an artists cds, the tracks on those cds, and the tags associted
2930 with that artist is given below (assuming many-to-many from artists to tags):
2931
2932  my $rs = $schema->resultset('Artist')->search(
2933    undef,
2934    {
2935      prefetch => [
2936        { cds => 'tracks' },
2937        { artist_tags => 'tags' }
2938      ]
2939    }
2940  );
2941
2942
2943 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2944 attributes will be ignored.
2945
2946 =head2 page
2947
2948 =over 4
2949
2950 =item Value: $page
2951
2952 =back
2953
2954 Makes the resultset paged and specifies the page to retrieve. Effectively
2955 identical to creating a non-pages resultset and then calling ->page($page)
2956 on it.
2957
2958 If L<rows> attribute is not specified it defualts to 10 rows per page.
2959
2960 When you have a paged resultset, L</count> will only return the number
2961 of rows in the page. To get the total, use the L</pager> and call
2962 C<total_entries> on it.
2963
2964 =head2 rows
2965
2966 =over 4
2967
2968 =item Value: $rows
2969
2970 =back
2971
2972 Specifes the maximum number of rows for direct retrieval or the number of
2973 rows per page if the page attribute or method is used.
2974
2975 =head2 offset
2976
2977 =over 4
2978
2979 =item Value: $offset
2980
2981 =back
2982
2983 Specifies the (zero-based) row number for the  first row to be returned, or the
2984 of the first row of the first page if paging is used.
2985
2986 =head2 group_by
2987
2988 =over 4
2989
2990 =item Value: \@columns
2991
2992 =back
2993
2994 A arrayref of columns to group by. Can include columns of joined tables.
2995
2996   group_by => [qw/ column1 column2 ... /]
2997
2998 =head2 having
2999
3000 =over 4
3001
3002 =item Value: $condition
3003
3004 =back
3005
3006 HAVING is a select statement attribute that is applied between GROUP BY and
3007 ORDER BY. It is applied to the after the grouping calculations have been
3008 done.
3009
3010   having => { 'count(employee)' => { '>=', 100 } }
3011
3012 =head2 distinct
3013
3014 =over 4
3015
3016 =item Value: (0 | 1)
3017
3018 =back
3019
3020 Set to 1 to group by all columns.
3021
3022 =head2 where
3023
3024 =over 4
3025
3026 Adds to the WHERE clause.
3027
3028   # only return rows WHERE deleted IS NULL for all searches
3029   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3030
3031 Can be overridden by passing C<{ where => undef }> as an attribute
3032 to a resulset.
3033
3034 =back
3035
3036 =head2 cache
3037
3038 Set to 1 to cache search results. This prevents extra SQL queries if you
3039 revisit rows in your ResultSet:
3040
3041   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3042
3043   while( my $artist = $resultset->next ) {
3044     ... do stuff ...
3045   }
3046
3047   $rs->first; # without cache, this would issue a query
3048
3049 By default, searches are not cached.
3050
3051 For more examples of using these attributes, see
3052 L<DBIx::Class::Manual::Cookbook>.
3053
3054 =head2 from
3055
3056 =over 4
3057
3058 =item Value: \@from_clause
3059
3060 =back
3061
3062 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3063 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3064 clauses.
3065
3066 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3067
3068 C<join> will usually do what you need and it is strongly recommended that you
3069 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3070 And we really do mean "cannot", not just tried and failed. Attempting to use
3071 this because you're having problems with C<join> is like trying to use x86
3072 ASM because you've got a syntax error in your C. Trust us on this.
3073
3074 Now, if you're still really, really sure you need to use this (and if you're
3075 not 100% sure, ask the mailing list first), here's an explanation of how this
3076 works.
3077
3078 The syntax is as follows -
3079
3080   [
3081     { <alias1> => <table1> },
3082     [
3083       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3084       [], # nested JOIN (optional)
3085       { <table1.column1> => <table2.column2>, ... (more conditions) },
3086     ],
3087     # More of the above [ ] may follow for additional joins
3088   ]
3089
3090   <table1> <alias1>
3091   JOIN
3092     <table2> <alias2>
3093     [JOIN ...]
3094   ON <table1.column1> = <table2.column2>
3095   <more joins may follow>
3096
3097 An easy way to follow the examples below is to remember the following:
3098
3099     Anything inside "[]" is a JOIN
3100     Anything inside "{}" is a condition for the enclosing JOIN
3101
3102 The following examples utilize a "person" table in a family tree application.
3103 In order to express parent->child relationships, this table is self-joined:
3104
3105     # Person->belongs_to('father' => 'Person');
3106     # Person->belongs_to('mother' => 'Person');
3107
3108 C<from> can be used to nest joins. Here we return all children with a father,
3109 then search against all mothers of those children:
3110
3111   $rs = $schema->resultset('Person')->search(
3112       undef,
3113       {
3114           alias => 'mother', # alias columns in accordance with "from"
3115           from => [
3116               { mother => 'person' },
3117               [
3118                   [
3119                       { child => 'person' },
3120                       [
3121                           { father => 'person' },
3122                           { 'father.person_id' => 'child.father_id' }
3123                       ]
3124                   ],
3125                   { 'mother.person_id' => 'child.mother_id' }
3126               ],
3127           ]
3128       },
3129   );
3130
3131   # Equivalent SQL:
3132   # SELECT mother.* FROM person mother
3133   # JOIN (
3134   #   person child
3135   #   JOIN person father
3136   #   ON ( father.person_id = child.father_id )
3137   # )
3138   # ON ( mother.person_id = child.mother_id )
3139
3140 The type of any join can be controlled manually. To search against only people
3141 with a father in the person table, we could explicitly use C<INNER JOIN>:
3142
3143     $rs = $schema->resultset('Person')->search(
3144         undef,
3145         {
3146             alias => 'child', # alias columns in accordance with "from"
3147             from => [
3148                 { child => 'person' },
3149                 [
3150                     { father => 'person', -join_type => 'inner' },
3151                     { 'father.id' => 'child.father_id' }
3152                 ],
3153             ]
3154         },
3155     );
3156
3157     # Equivalent SQL:
3158     # SELECT child.* FROM person child
3159     # INNER JOIN person father ON child.father_id = father.id
3160
3161 If you need to express really complex joins or you need a subselect, you
3162 can supply literal SQL to C<from> via a scalar reference. In this case
3163 the contents of the scalar will replace the table name asscoiated with the
3164 resultsource.
3165
3166 WARNING: This technique might very well not work as expected on chained
3167 searches - you have been warned.
3168
3169     # Assuming the Event resultsource is defined as:
3170
3171         MySchema::Event->add_columns (
3172             sequence => {
3173                 data_type => 'INT',
3174                 is_auto_increment => 1,
3175             },
3176             location => {
3177                 data_type => 'INT',
3178             },
3179             type => {
3180                 data_type => 'INT',
3181             },
3182         );
3183         MySchema::Event->set_primary_key ('sequence');
3184
3185     # This will get back the latest event for every location. The column
3186     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3187     # combo to limit the resultset
3188
3189     $rs = $schema->resultset('Event');
3190     $table = $rs->result_source->name;
3191     $latest = $rs->search (
3192         undef,
3193         { from => \ "
3194             (SELECT e1.* FROM $table e1
3195                 JOIN $table e2
3196                     ON e1.location = e2.location
3197                     AND e1.sequence < e2.sequence
3198                 WHERE e2.sequence is NULL
3199             ) me",
3200         },
3201     );
3202
3203     # Equivalent SQL (with the DBIC chunks added):
3204
3205     SELECT me.sequence, me.location, me.type FROM
3206        (SELECT e1.* FROM events e1
3207            JOIN events e2
3208                ON e1.location = e2.location
3209                AND e1.sequence < e2.sequence
3210            WHERE e2.sequence is NULL
3211        ) me;
3212
3213 =head2 for
3214
3215 =over 4
3216
3217 =item Value: ( 'update' | 'shared' )
3218
3219 =back
3220
3221 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3222 ... FOR SHARED.
3223
3224 =cut
3225
3226 1;