lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360   if ($rows) {
 361     $rs->set_cache($rows);
 362   }
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, $attrs);
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974 sub _collapse_result {
 975   my ($self, $as_proto, $row) = @_;
 976
 977   # if the first row that ever came in is totally empty - this means we got
 978   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 979   # instead of producing a {}
 980   #
 981   my $has_def;
 982   for (@$row) {
 983     if (defined $_) {
 984       $has_def++;
 985       last;
 986     }
 987   }
 988   return undef unless $has_def;
 989
 990   my @copy = @$row;
 991
 992   # 'foo'         => [ undef, 'foo' ]
 993   # 'foo.bar'     => [ 'foo', 'bar' ]
 994   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 995
 996   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 997
 998   my %collapse = %{$self->{_attrs}{collapse}||{}};
 999
1000   my @pri_index;
1001
1002   # if we're doing collapsing (has_many prefetch) we need to grab records
1003   # until the PK changes, so fill @pri_index. if not, we leave it empty so
1004   # we know we don't have to bother.
1005
1006   # the reason for not using the collapse stuff directly is because if you
1007   # had for e.g. two artists in a row with no cds, the collapse info for
1008   # both would be NULL (undef) so you'd lose the second artist
1009
1010   # store just the index so we can check the array positions from the row
1011   # without having to contruct the full hash
1012
1013   if (keys %collapse) {
1014     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1015     foreach my $i (0 .. $#construct_as) {
1016       next if defined($construct_as[$i][0]); # only self table
1017       if (delete $pri{$construct_as[$i][1]}) {
1018         push(@pri_index, $i);
1019       }
1020       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1021     }
1022   }
1023
1024   # no need to do an if, it'll be empty if @pri_index is empty anyway
1025
1026   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1027
1028   my @const_rows;
1029
1030   do { # no need to check anything at the front, we always want the first row
1031
1032     my %const;
1033
1034     foreach my $this_as (@construct_as) {
1035       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1036     }
1037
1038     push(@const_rows, \%const);
1039
1040   } until ( # no pri_index => no collapse => drop straight out
1041       !@pri_index
1042     or
1043       do { # get another row, stash it, drop out if different PK
1044
1045         @copy = $self->cursor->next;
1046         $self->{stashed_row} = \@copy;
1047
1048         # last thing in do block, counts as true if anything doesn't match
1049
1050         # check xor defined first for NULL vs. NOT NULL then if one is
1051         # defined the other must be so check string equality
1052
1053         grep {
1054           (defined $pri_vals{$_} ^ defined $copy[$_])
1055           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1056         } @pri_index;
1057       }
1058   );
1059
1060   my $alias = $self->{attrs}{alias};
1061   my $info = [];
1062
1063   my %collapse_pos;
1064
1065   my @const_keys;
1066
1067   foreach my $const (@const_rows) {
1068     scalar @const_keys or do {
1069       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1070     };
1071     foreach my $key (@const_keys) {
1072       if (length $key) {
1073         my $target = $info;
1074         my @parts = split(/\./, $key);
1075         my $cur = '';
1076         my $data = $const->{$key};
1077         foreach my $p (@parts) {
1078           $target = $target->[1]->{$p} ||= [];
1079           $cur .= ".${p}";
1080           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1081             # collapsing at this point and on final part
1082             my $pos = $collapse_pos{$cur};
1083             CK: foreach my $ck (@ckey) {
1084               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1085                 $collapse_pos{$cur} = $data;
1086                 delete @collapse_pos{ # clear all positioning for sub-entries
1087                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1088                 };
1089                 push(@$target, []);
1090                 last CK;
1091               }
1092             }
1093           }
1094           if (exists $collapse{$cur}) {
1095             $target = $target->[-1];
1096           }
1097         }
1098         $target->[0] = $data;
1099       } else {
1100         $info->[0] = $const->{$key};
1101       }
1102     }
1103   }
1104
1105   return $info;
1106 }
1107
1108 =head2 result_source
1109
1110 =over 4
1111
1112 =item Arguments: $result_source?
1113
1114 =item Return Value: $result_source
1115
1116 =back
1117
1118 An accessor for the primary ResultSource object from which this ResultSet
1119 is derived.
1120
1121 =head2 result_class
1122
1123 =over 4
1124
1125 =item Arguments: $result_class?
1126
1127 =item Return Value: $result_class
1128
1129 =back
1130
1131 An accessor for the class to use when creating row objects. Defaults to
1132 C<< result_source->result_class >> - which in most cases is the name of the
1133 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1134
1135 Note that changing the result_class will also remove any components
1136 that were originally loaded in the source class via
1137 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1138 in the original source class will not run.
1139
1140 =cut
1141
1142 sub result_class {
1143   my ($self, $result_class) = @_;
1144   if ($result_class) {
1145     $self->ensure_class_loaded($result_class);
1146     $self->_result_class($result_class);
1147   }
1148   $self->_result_class;
1149 }
1150
1151 =head2 count
1152
1153 =over 4
1154
1155 =item Arguments: $cond, \%attrs??
1156
1157 =item Return Value: $count
1158
1159 =back
1160
1161 Performs an SQL C<COUNT> with the same query as the resultset was built
1162 with to find the number of elements. Passing arguments is equivalent to
1163 C<< $rs->search ($cond, \%attrs)->count >>
1164
1165 =cut
1166
1167 sub count {
1168   my $self = shift;
1169   return $self->search(@_)->count if @_ and defined $_[0];
1170   return scalar @{ $self->get_cache } if $self->get_cache;
1171
1172   my $attrs = $self->_resolved_attrs_copy;
1173
1174   # this is a little optimization - it is faster to do the limit
1175   # adjustments in software, instead of a subquery
1176   my $rows = delete $attrs->{rows};
1177   my $offset = delete $attrs->{offset};
1178
1179   my $crs;
1180   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1181     $crs = $self->_count_subq_rs ($attrs);
1182   }
1183   else {
1184     $crs = $self->_count_rs ($attrs);
1185   }
1186   my $count = $crs->next;
1187
1188   $count -= $offset if $offset;
1189   $count = $rows if $rows and $rows < $count;
1190   $count = 0 if ($count < 0);
1191
1192   return $count;
1193 }
1194
1195 =head2 count_rs
1196
1197 =over 4
1198
1199 =item Arguments: $cond, \%attrs??
1200
1201 =item Return Value: $count_rs
1202
1203 =back
1204
1205 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1206 This can be very handy for subqueries:
1207
1208   ->search( { amount => $some_rs->count_rs->as_query } )
1209
1210 As with regular resultsets the SQL query will be executed only after
1211 the resultset is accessed via L</next> or L</all>. That would return
1212 the same single value obtainable via L</count>.
1213
1214 =cut
1215
1216 sub count_rs {
1217   my $self = shift;
1218   return $self->search(@_)->count_rs if @_;
1219
1220   # this may look like a lack of abstraction (count() does about the same)
1221   # but in fact an _rs *must* use a subquery for the limits, as the
1222   # software based limiting can not be ported if this $rs is to be used
1223   # in a subquery itself (i.e. ->as_query)
1224   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1225     return $self->_count_subq_rs;
1226   }
1227   else {
1228     return $self->_count_rs;
1229   }
1230 }
1231
1232 #
1233 # returns a ResultSetColumn object tied to the count query
1234 #
1235 sub _count_rs {
1236   my ($self, $attrs) = @_;
1237
1238   my $rsrc = $self->result_source;
1239   $attrs ||= $self->_resolved_attrs;
1240
1241   my $tmp_attrs = { %$attrs };
1242
1243   # take off any limits, record_filter is cdbi, and no point of ordering a count
1244   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1245
1246   # overwrite the selector (supplied by the storage)
1247   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1248   $tmp_attrs->{as} = 'count';
1249
1250   # read the comment on top of the actual function to see what this does
1251   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1252     $tmp_attrs->{from}, $tmp_attrs->{alias}
1253   );
1254
1255   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1256
1257   return $tmp_rs;
1258 }
1259
1260 #
1261 # same as above but uses a subquery
1262 #
1263 sub _count_subq_rs {
1264   my ($self, $attrs) = @_;
1265
1266   my $rsrc = $self->result_source;
1267   $attrs ||= $self->_resolved_attrs_copy;
1268
1269   my $sub_attrs = { %$attrs };
1270
1271   # extra selectors do not go in the subquery and there is no point of ordering it
1272   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1273
1274   # if we prefetch, we group_by primary keys only as this is what we would get out
1275   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1276   if ( keys %{$attrs->{collapse}} ) {
1277     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1278   }
1279
1280   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1281
1282   # read the comment on top of the actual function to see what this does
1283   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1284     $sub_attrs->{from}, $sub_attrs->{alias}
1285   );
1286
1287   # this is so that ordering can be thrown away in things like Top limit
1288   $sub_attrs->{-for_count_only} = 1;
1289
1290   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1291
1292   $attrs->{from} = [{
1293     -alias => 'count_subq',
1294     -source_handle => $rsrc->handle,
1295     count_subq => $sub_rs->as_query,
1296   }];
1297
1298   # the subquery replaces this
1299   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1300
1301   return $self->_count_rs ($attrs);
1302 }
1303
1304
1305 # The DBIC relationship chaining implementation is pretty simple - every
1306 # new related_relationship is pushed onto the {from} stack, and the {select}
1307 # window simply slides further in. This means that when we count somewhere
1308 # in the middle, we got to make sure that everything in the join chain is an
1309 # actual inner join, otherwise the count will come back with unpredictable
1310 # results (a resultset may be generated with _some_ rows regardless of if
1311 # the relation which the $rs currently selects has rows or not). E.g.
1312 # $artist_rs->cds->count - normally generates:
1313 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1314 # which actually returns the number of artists * (number of cds || 1)
1315 #
1316 # So what we do here is crawl {from}, determine if the current alias is at
1317 # the top of the stack, and if not - make sure the chain is inner-joined down
1318 # to the root.
1319 #
1320 sub _switch_to_inner_join_if_needed {
1321   my ($self, $from, $alias) = @_;
1322
1323   # subqueries and other oddness is naturally not supported
1324   return $from if (
1325     ref $from ne 'ARRAY'
1326       ||
1327     @$from <= 1
1328       ||
1329     ref $from->[0] ne 'HASH'
1330       ||
1331     ! $from->[0]{-alias}
1332       ||
1333     $from->[0]{-alias} eq $alias
1334   );
1335
1336   my $switch_branch;
1337   JOINSCAN:
1338   for my $j (@{$from}[1 .. $#$from]) {
1339     if ($j->[0]{-alias} eq $alias) {
1340       $switch_branch = $j->[0]{-join_path};
1341       last JOINSCAN;
1342     }
1343   }
1344
1345   # something else went wrong
1346   return $from unless $switch_branch;
1347
1348   # So it looks like we will have to switch some stuff around.
1349   # local() is useless here as we will be leaving the scope
1350   # anyway, and deep cloning is just too fucking expensive
1351   # So replace the inner hashref manually
1352   my @new_from = ($from->[0]);
1353   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1354
1355   for my $j (@{$from}[1 .. $#$from]) {
1356     my $jalias = $j->[0]{-alias};
1357
1358     if ($sw_idx->{$jalias}) {
1359       my %attrs = %{$j->[0]};
1360       delete $attrs{-join_type};
1361       push @new_from, [
1362         \%attrs,
1363         @{$j}[ 1 .. $#$j ],
1364       ];
1365     }
1366     else {
1367       push @new_from, $j;
1368     }
1369   }
1370
1371   return \@new_from;
1372 }
1373
1374
1375 sub _bool {
1376   return 1;
1377 }
1378
1379 =head2 count_literal
1380
1381 =over 4
1382
1383 =item Arguments: $sql_fragment, @bind_values
1384
1385 =item Return Value: $count
1386
1387 =back
1388
1389 Counts the results in a literal query. Equivalent to calling L</search_literal>
1390 with the passed arguments, then L</count>.
1391
1392 =cut
1393
1394 sub count_literal { shift->search_literal(@_)->count; }
1395
1396 =head2 all
1397
1398 =over 4
1399
1400 =item Arguments: none
1401
1402 =item Return Value: @objects
1403
1404 =back
1405
1406 Returns all elements in the resultset. Called implicitly if the resultset
1407 is returned in list context.
1408
1409 =cut
1410
1411 sub all {
1412   my $self = shift;
1413   if(@_) {
1414       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1415   }
1416
1417   return @{ $self->get_cache } if $self->get_cache;
1418
1419   my @obj;
1420
1421   if (keys %{$self->_resolved_attrs->{collapse}}) {
1422     # Using $self->cursor->all is really just an optimisation.
1423     # If we're collapsing has_many prefetches it probably makes
1424     # very little difference, and this is cleaner than hacking
1425     # _construct_object to survive the approach
1426     $self->cursor->reset;
1427     my @row = $self->cursor->next;
1428     while (@row) {
1429       push(@obj, $self->_construct_object(@row));
1430       @row = (exists $self->{stashed_row}
1431                ? @{delete $self->{stashed_row}}
1432                : $self->cursor->next);
1433     }
1434   } else {
1435     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1436   }
1437
1438   $self->set_cache(\@obj) if $self->{attrs}{cache};
1439
1440   return @obj;
1441 }
1442
1443 =head2 reset
1444
1445 =over 4
1446
1447 =item Arguments: none
1448
1449 =item Return Value: $self
1450
1451 =back
1452
1453 Resets the resultset's cursor, so you can iterate through the elements again.
1454 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1455 another query.
1456
1457 =cut
1458
1459 sub reset {
1460   my ($self) = @_;
1461   delete $self->{_attrs} if exists $self->{_attrs};
1462   $self->{all_cache_position} = 0;
1463   $self->cursor->reset;
1464   return $self;
1465 }
1466
1467 =head2 first
1468
1469 =over 4
1470
1471 =item Arguments: none
1472
1473 =item Return Value: $object?
1474
1475 =back
1476
1477 Resets the resultset and returns an object for the first result (if the
1478 resultset returns anything).
1479
1480 =cut
1481
1482 sub first {
1483   return $_[0]->reset->next;
1484 }
1485
1486
1487 # _rs_update_delete
1488 #
1489 # Determines whether and what type of subquery is required for the $rs operation.
1490 # If grouping is necessary either supplies its own, or verifies the current one
1491 # After all is done delegates to the proper storage method.
1492
1493 sub _rs_update_delete {
1494   my ($self, $op, $values) = @_;
1495
1496   my $rsrc = $self->result_source;
1497
1498   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1499   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1500
1501   if ($needs_group_by_subq or $needs_subq) {
1502
1503     # make a new $rs selecting only the PKs (that's all we really need)
1504     my $attrs = $self->_resolved_attrs_copy;
1505
1506     delete $attrs->{$_} for qw/collapse select as/;
1507     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1508
1509     if ($needs_group_by_subq) {
1510       # make sure no group_by was supplied, or if there is one - make sure it matches
1511       # the columns compiled above perfectly. Anything else can not be sanely executed
1512       # on most databases so croak right then and there
1513
1514       if (my $g = $attrs->{group_by}) {
1515         my @current_group_by = map
1516           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1517           @$g
1518         ;
1519
1520         if (
1521           join ("\x00", sort @current_group_by)
1522             ne
1523           join ("\x00", sort @{$attrs->{columns}} )
1524         ) {
1525           $self->throw_exception (
1526             "You have just attempted a $op operation on a resultset which does group_by"
1527             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1528             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1529             . ' kind of queries. Please retry the operation with a modified group_by or'
1530             . ' without using one at all.'
1531           );
1532         }
1533       }
1534       else {
1535         $attrs->{group_by} = $attrs->{columns};
1536       }
1537     }
1538
1539     my $subrs = (ref $self)->new($rsrc, $attrs);
1540
1541     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1542   }
1543   else {
1544     return $rsrc->storage->$op(
1545       $rsrc,
1546       $op eq 'update' ? $values : (),
1547       $self->_cond_for_update_delete,
1548     );
1549   }
1550 }
1551
1552
1553 # _cond_for_update_delete
1554 #
1555 # update/delete require the condition to be modified to handle
1556 # the differing SQL syntax available.  This transforms the $self->{cond}
1557 # appropriately, returning the new condition.
1558
1559 sub _cond_for_update_delete {
1560   my ($self, $full_cond) = @_;
1561   my $cond = {};
1562
1563   $full_cond ||= $self->{cond};
1564   # No-op. No condition, we're updating/deleting everything
1565   return $cond unless ref $full_cond;
1566
1567   if (ref $full_cond eq 'ARRAY') {
1568     $cond = [
1569       map {
1570         my %hash;
1571         foreach my $key (keys %{$_}) {
1572           $key =~ /([^.]+)$/;
1573           $hash{$1} = $_->{$key};
1574         }
1575         \%hash;
1576       } @{$full_cond}
1577     ];
1578   }
1579   elsif (ref $full_cond eq 'HASH') {
1580     if ((keys %{$full_cond})[0] eq '-and') {
1581       $cond->{-and} = [];
1582       my @cond = @{$full_cond->{-and}};
1583        for (my $i = 0; $i < @cond; $i++) {
1584         my $entry = $cond[$i];
1585         my $hash;
1586         if (ref $entry eq 'HASH') {
1587           $hash = $self->_cond_for_update_delete($entry);
1588         }
1589         else {
1590           $entry =~ /([^.]+)$/;
1591           $hash->{$1} = $cond[++$i];
1592         }
1593         push @{$cond->{-and}}, $hash;
1594       }
1595     }
1596     else {
1597       foreach my $key (keys %{$full_cond}) {
1598         $key =~ /([^.]+)$/;
1599         $cond->{$1} = $full_cond->{$key};
1600       }
1601     }
1602   }
1603   else {
1604     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1605   }
1606
1607   return $cond;
1608 }
1609
1610
1611 =head2 update
1612
1613 =over 4
1614
1615 =item Arguments: \%values
1616
1617 =item Return Value: $storage_rv
1618
1619 =back
1620
1621 Sets the specified columns in the resultset to the supplied values in a
1622 single query. Return value will be true if the update succeeded or false
1623 if no records were updated; exact type of success value is storage-dependent.
1624
1625 =cut
1626
1627 sub update {
1628   my ($self, $values) = @_;
1629   $self->throw_exception('Values for update must be a hash')
1630     unless ref $values eq 'HASH';
1631
1632   return $self->_rs_update_delete ('update', $values);
1633 }
1634
1635 =head2 update_all
1636
1637 =over 4
1638
1639 =item Arguments: \%values
1640
1641 =item Return Value: 1
1642
1643 =back
1644
1645 Fetches all objects and updates them one at a time. Note that C<update_all>
1646 will run DBIC cascade triggers, while L</update> will not.
1647
1648 =cut
1649
1650 sub update_all {
1651   my ($self, $values) = @_;
1652   $self->throw_exception('Values for update_all must be a hash')
1653     unless ref $values eq 'HASH';
1654   foreach my $obj ($self->all) {
1655     $obj->set_columns($values)->update;
1656   }
1657   return 1;
1658 }
1659
1660 =head2 delete
1661
1662 =over 4
1663
1664 =item Arguments: none
1665
1666 =item Return Value: $storage_rv
1667
1668 =back
1669
1670 Deletes the contents of the resultset from its result source. Note that this
1671 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1672 to run. See also L<DBIx::Class::Row/delete>.
1673
1674 Return value will be the amount of rows deleted; exact type of return value
1675 is storage-dependent.
1676
1677 =cut
1678
1679 sub delete {
1680   my $self = shift;
1681   $self->throw_exception('delete does not accept any arguments')
1682     if @_;
1683
1684   return $self->_rs_update_delete ('delete');
1685 }
1686
1687 =head2 delete_all
1688
1689 =over 4
1690
1691 =item Arguments: none
1692
1693 =item Return Value: 1
1694
1695 =back
1696
1697 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1698 will run DBIC cascade triggers, while L</delete> will not.
1699
1700 =cut
1701
1702 sub delete_all {
1703   my $self = shift;
1704   $self->throw_exception('delete_all does not accept any arguments')
1705     if @_;
1706
1707   $_->delete for $self->all;
1708   return 1;
1709 }
1710
1711 =head2 populate
1712
1713 =over 4
1714
1715 =item Arguments: \@data;
1716
1717 =back
1718
1719 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1720 For the arrayref of hashrefs style each hashref should be a structure suitable
1721 forsubmitting to a $resultset->create(...) method.
1722
1723 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1724 to insert the data, as this is a faster method.
1725
1726 Otherwise, each set of data is inserted into the database using
1727 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1728 accumulated into an array. The array itself, or an array reference
1729 is returned depending on scalar or list context.
1730
1731 Example:  Assuming an Artist Class that has many CDs Classes relating:
1732
1733   my $Artist_rs = $schema->resultset("Artist");
1734
1735   ## Void Context Example
1736   $Artist_rs->populate([
1737      { artistid => 4, name => 'Manufactured Crap', cds => [
1738         { title => 'My First CD', year => 2006 },
1739         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1740       ],
1741      },
1742      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1743         { title => 'My parents sold me to a record company' ,year => 2005 },
1744         { title => 'Why Am I So Ugly?', year => 2006 },
1745         { title => 'I Got Surgery and am now Popular', year => 2007 }
1746       ],
1747      },
1748   ]);
1749
1750   ## Array Context Example
1751   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1752     { name => "Artist One"},
1753     { name => "Artist Two"},
1754     { name => "Artist Three", cds=> [
1755     { title => "First CD", year => 2007},
1756     { title => "Second CD", year => 2008},
1757   ]}
1758   ]);
1759
1760   print $ArtistOne->name; ## response is 'Artist One'
1761   print $ArtistThree->cds->count ## reponse is '2'
1762
1763 For the arrayref of arrayrefs style,  the first element should be a list of the
1764 fieldsnames to which the remaining elements are rows being inserted.  For
1765 example:
1766
1767   $Arstist_rs->populate([
1768     [qw/artistid name/],
1769     [100, 'A Formally Unknown Singer'],
1770     [101, 'A singer that jumped the shark two albums ago'],
1771     [102, 'An actually cool singer.'],
1772   ]);
1773
1774 Please note an important effect on your data when choosing between void and
1775 wantarray context. Since void context goes straight to C<insert_bulk> in
1776 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1777 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1778 create primary keys for you, you will find that your PKs are empty.  In this
1779 case you will have to use the wantarray context in order to create those
1780 values.
1781
1782 =cut
1783
1784 sub populate {
1785   my $self = shift @_;
1786   my $data = ref $_[0][0] eq 'HASH'
1787     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1788     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1789
1790   if(defined wantarray) {
1791     my @created;
1792     foreach my $item (@$data) {
1793       push(@created, $self->create($item));
1794     }
1795     return wantarray ? @created : \@created;
1796   } else {
1797     my ($first, @rest) = @$data;
1798
1799     my @names = grep {!ref $first->{$_}} keys %$first;
1800     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1801     my @pks = $self->result_source->primary_columns;
1802
1803     ## do the belongs_to relationships
1804     foreach my $index (0..$#$data) {
1805
1806       # delegate to create() for any dataset without primary keys with specified relationships
1807       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1808         for my $r (@rels) {
1809           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1810             my @ret = $self->populate($data);
1811             return;
1812           }
1813         }
1814       }
1815
1816       foreach my $rel (@rels) {
1817         next unless ref $data->[$index]->{$rel} eq "HASH";
1818         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1819         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1820         my $related = $result->result_source->_resolve_condition(
1821           $result->result_source->relationship_info($reverse)->{cond},
1822           $self,
1823           $result,
1824         );
1825
1826         delete $data->[$index]->{$rel};
1827         $data->[$index] = {%{$data->[$index]}, %$related};
1828
1829         push @names, keys %$related if $index == 0;
1830       }
1831     }
1832
1833     ## merge with the conditions from $self (inherited conditions)
1834     my ($inherited_cond) = $self->_merge_with_cond({});
1835     delete @{$inherited_cond}{@names};
1836     my @inherited_names = keys %$inherited_cond;
1837     my @values;
1838     foreach my $row (@$data) {
1839       my %row_data;
1840       @row_data{@names} = @{$row}{@names};
1841       my ($merged_cond) = $self->_merge_with_cond(\%row_data);
1842       push @values, [ @{$merged_cond}{@names, @inherited_names} ];
1843     }
1844     push @names, @inherited_names;
1845
1846     ## do bulk insert on current row
1847     $self->result_source->storage->insert_bulk(
1848       $self->result_source,
1849       \@names,
1850       \@values,
1851     );
1852
1853     ## do the has_many relationships
1854     foreach my $item (@$data) {
1855
1856       foreach my $rel (@rels) {
1857         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1858
1859         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1860      || $self->throw_exception('Cannot find the relating object.');
1861
1862         my $child = $parent->$rel;
1863
1864         my $related = $child->result_source->_resolve_condition(
1865           $parent->result_source->relationship_info($rel)->{cond},
1866           $child,
1867           $parent,
1868         );
1869
1870         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1871         my @populate = map { {%$_, %$related} } @rows_to_add;
1872
1873         $child->populate( \@populate );
1874       }
1875     }
1876   }
1877 }
1878
1879 =head2 _normalize_populate_args ($args)
1880
1881 Private method used by L</populate> to normalize its incoming arguments.  Factored
1882 out in case you want to subclass and accept new argument structures to the
1883 L</populate> method.
1884
1885 =cut
1886
1887 sub _normalize_populate_args {
1888   my ($self, $data) = @_;
1889   my @names = @{shift(@$data)};
1890   my @results_to_create;
1891   foreach my $datum (@$data) {
1892     my %result_to_create;
1893     foreach my $index (0..$#names) {
1894       $result_to_create{$names[$index]} = $$datum[$index];
1895     }
1896     push @results_to_create, \%result_to_create;
1897   }
1898   return \@results_to_create;
1899 }
1900
1901 =head2 pager
1902
1903 =over 4
1904
1905 =item Arguments: none
1906
1907 =item Return Value: $pager
1908
1909 =back
1910
1911 Return Value a L<Data::Page> object for the current resultset. Only makes
1912 sense for queries with a C<page> attribute.
1913
1914 To get the full count of entries for a paged resultset, call
1915 C<total_entries> on the L<Data::Page> object.
1916
1917 =cut
1918
1919 sub pager {
1920   my ($self) = @_;
1921
1922   return $self->{pager} if $self->{pager};
1923
1924   my $attrs = $self->{attrs};
1925   $self->throw_exception("Can't create pager for non-paged rs")
1926     unless $self->{attrs}{page};
1927   $attrs->{rows} ||= 10;
1928
1929   # throw away the paging flags and re-run the count (possibly
1930   # with a subselect) to get the real total count
1931   my $count_attrs = { %$attrs };
1932   delete $count_attrs->{$_} for qw/rows offset page pager/;
1933   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1934
1935   return $self->{pager} = Data::Page->new(
1936     $total_count,
1937     $attrs->{rows},
1938     $self->{attrs}{page}
1939   );
1940 }
1941
1942 =head2 page
1943
1944 =over 4
1945
1946 =item Arguments: $page_number
1947
1948 =item Return Value: $rs
1949
1950 =back
1951
1952 Returns a resultset for the $page_number page of the resultset on which page
1953 is called, where each page contains a number of rows equal to the 'rows'
1954 attribute set on the resultset (10 by default).
1955
1956 =cut
1957
1958 sub page {
1959   my ($self, $page) = @_;
1960   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1961 }
1962
1963 =head2 new_result
1964
1965 =over 4
1966
1967 =item Arguments: \%vals
1968
1969 =item Return Value: $rowobject
1970
1971 =back
1972
1973 Creates a new row object in the resultset's result class and returns
1974 it. The row is not inserted into the database at this point, call
1975 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1976 will tell you whether the row object has been inserted or not.
1977
1978 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1979
1980 =cut
1981
1982 sub new_result {
1983   my ($self, $values) = @_;
1984   $self->throw_exception( "new_result needs a hash" )
1985     unless (ref $values eq 'HASH');
1986
1987   my ($merged_cond, $from_resultset) = $self->_merge_with_cond($values);
1988
1989   my %new = (
1990     %$merged_cond,
1991     @$from_resultset
1992       ? (-from_resultset => $from_resultset)
1993       : (),
1994     -source_handle => $self->_source_handle,
1995     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1996   );
1997
1998   return $self->result_class->new(\%new);
1999 }
2000
2001 # _merge_with_cond
2002 #
2003 # Merges $values (a hashref) with the condition in the resultset and returns
2004 # the resulting hashref and an arrayref that contains the keys that are coming
2005 # from related resultsets.
2006
2007 sub _merge_with_cond {
2008   my ($self, $values) = @_;
2009
2010   my (%merged_cond, @from_resultset);
2011
2012   my $alias = $self->{attrs}{alias};
2013
2014   if (
2015     defined $self->{cond}
2016     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
2017   ) {
2018     %merged_cond = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
2019     @from_resultset = keys %merged_cond;
2020   } else {
2021     $self->throw_exception(
2022       "Can't abstract implicit construct, condition not a hash"
2023     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
2024
2025     my $collapsed_cond = (
2026       $self->{cond}
2027         ? $self->_collapse_cond($self->{cond})
2028         : {}
2029     );
2030
2031     # precendence must be given to passed values over values inherited from
2032     # the cond, so the order here is important.
2033     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
2034     while ( my($col, $value) = each %implied ) {
2035       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
2036         $merged_cond{$col} = $value->{'='};
2037         next;
2038       }
2039       $merged_cond{$col} = $value if $self->_is_deterministic_value($value);
2040     }
2041   }
2042
2043   %merged_cond = (
2044     %merged_cond,
2045     %{ $self->_remove_alias($values, $alias) },
2046   );
2047
2048   return (\%merged_cond, \@from_resultset);
2049 }
2050
2051 # _is_deterministic_value
2052 #
2053 # Make an effor to strip non-deterministic values from the condition,
2054 # to make sure new_result chokes less
2055
2056 sub _is_deterministic_value {
2057   my $self = shift;
2058   my $value = shift;
2059   my $ref_type = ref $value;
2060   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2061   return 1 if Scalar::Util::blessed($value);
2062   return 0;
2063 }
2064
2065 # _has_resolved_attr
2066 #
2067 # determines if the resultset defines at least one
2068 # of the attributes supplied
2069 #
2070 # used to determine if a subquery is neccessary
2071 #
2072 # supports some virtual attributes:
2073 #   -join
2074 #     This will scan for any joins being present on the resultset.
2075 #     It is not a mere key-search but a deep inspection of {from}
2076 #
2077
2078 sub _has_resolved_attr {
2079   my ($self, @attr_names) = @_;
2080
2081   my $attrs = $self->_resolved_attrs;
2082
2083   my %extra_checks;
2084
2085   for my $n (@attr_names) {
2086     if (grep { $n eq $_ } (qw/-join/) ) {
2087       $extra_checks{$n}++;
2088       next;
2089     }
2090
2091     my $attr =  $attrs->{$n};
2092
2093     next if not defined $attr;
2094
2095     if (ref $attr eq 'HASH') {
2096       return 1 if keys %$attr;
2097     }
2098     elsif (ref $attr eq 'ARRAY') {
2099       return 1 if @$attr;
2100     }
2101     else {
2102       return 1 if $attr;
2103     }
2104   }
2105
2106   # a resolved join is expressed as a multi-level from
2107   return 1 if (
2108     $extra_checks{-join}
2109       and
2110     ref $attrs->{from} eq 'ARRAY'
2111       and
2112     @{$attrs->{from}} > 1
2113   );
2114
2115   return 0;
2116 }
2117
2118 # _collapse_cond
2119 #
2120 # Recursively collapse the condition.
2121
2122 sub _collapse_cond {
2123   my ($self, $cond, $collapsed) = @_;
2124
2125   $collapsed ||= {};
2126
2127   if (ref $cond eq 'ARRAY') {
2128     foreach my $subcond (@$cond) {
2129       next unless ref $subcond;  # -or
2130       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2131     }
2132   }
2133   elsif (ref $cond eq 'HASH') {
2134     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2135       foreach my $subcond (@{$cond->{-and}}) {
2136         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2137       }
2138     }
2139     else {
2140       foreach my $col (keys %$cond) {
2141         my $value = $cond->{$col};
2142         $collapsed->{$col} = $value;
2143       }
2144     }
2145   }
2146
2147   return $collapsed;
2148 }
2149
2150 # _remove_alias
2151 #
2152 # Remove the specified alias from the specified query hash. A copy is made so
2153 # the original query is not modified.
2154
2155 sub _remove_alias {
2156   my ($self, $query, $alias) = @_;
2157
2158   my %orig = %{ $query || {} };
2159   my %unaliased;
2160
2161   foreach my $key (keys %orig) {
2162     if ($key !~ /\./) {
2163       $unaliased{$key} = $orig{$key};
2164       next;
2165     }
2166     $unaliased{$1} = $orig{$key}
2167       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2168   }
2169
2170   return \%unaliased;
2171 }
2172
2173 =head2 as_query (EXPERIMENTAL)
2174
2175 =over 4
2176
2177 =item Arguments: none
2178
2179 =item Return Value: \[ $sql, @bind ]
2180
2181 =back
2182
2183 Returns the SQL query and bind vars associated with the invocant.
2184
2185 This is generally used as the RHS for a subquery.
2186
2187 B<NOTE>: This feature is still experimental.
2188
2189 =cut
2190
2191 sub as_query {
2192   my $self = shift;
2193
2194   my $attrs = $self->_resolved_attrs_copy;
2195
2196   # For future use:
2197   #
2198   # in list ctx:
2199   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2200   # $sql also has no wrapping parenthesis in list ctx
2201   #
2202   my $sqlbind = $self->result_source->storage
2203     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2204
2205   return $sqlbind;
2206 }
2207
2208 =head2 find_or_new
2209
2210 =over 4
2211
2212 =item Arguments: \%vals, \%attrs?
2213
2214 =item Return Value: $rowobject
2215
2216 =back
2217
2218   my $artist = $schema->resultset('Artist')->find_or_new(
2219     { artist => 'fred' }, { key => 'artists' });
2220
2221   $cd->cd_to_producer->find_or_new({ producer => $producer },
2222                                    { key => 'primary });
2223
2224 Find an existing record from this resultset, based on its primary
2225 key, or a unique constraint. If none exists, instantiate a new result
2226 object and return it. The object will not be saved into your storage
2227 until you call L<DBIx::Class::Row/insert> on it.
2228
2229 You most likely want this method when looking for existing rows using
2230 a unique constraint that is not the primary key, or looking for
2231 related rows.
2232
2233 If you want objects to be saved immediately, use L</find_or_create>
2234 instead.
2235
2236 B<Note>: Take care when using C<find_or_new> with a table having
2237 columns with default values that you intend to be automatically
2238 supplied by the database (e.g. an auto_increment primary key column).
2239 In normal usage, the value of such columns should NOT be included at
2240 all in the call to C<find_or_new>, even when set to C<undef>.
2241
2242 =cut
2243
2244 sub find_or_new {
2245   my $self     = shift;
2246   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2247   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2248   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2249     return $row;
2250   }
2251   return $self->new_result($hash);
2252 }
2253
2254 =head2 create
2255
2256 =over 4
2257
2258 =item Arguments: \%vals
2259
2260 =item Return Value: a L<DBIx::Class::Row> $object
2261
2262 =back
2263
2264 Attempt to create a single new row or a row with multiple related rows
2265 in the table represented by the resultset (and related tables). This
2266 will not check for duplicate rows before inserting, use
2267 L</find_or_create> to do that.
2268
2269 To create one row for this resultset, pass a hashref of key/value
2270 pairs representing the columns of the table and the values you wish to
2271 store. If the appropriate relationships are set up, foreign key fields
2272 can also be passed an object representing the foreign row, and the
2273 value will be set to its primary key.
2274
2275 To create related objects, pass a hashref of related-object column values
2276 B<keyed on the relationship name>. If the relationship is of type C<multi>
2277 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2278 The process will correctly identify columns holding foreign keys, and will
2279 transparrently populate them from the keys of the corresponding relation.
2280 This can be applied recursively, and will work correctly for a structure
2281 with an arbitrary depth and width, as long as the relationships actually
2282 exists and the correct column data has been supplied.
2283
2284
2285 Instead of hashrefs of plain related data (key/value pairs), you may
2286 also pass new or inserted objects. New objects (not inserted yet, see
2287 L</new>), will be inserted into their appropriate tables.
2288
2289 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2290
2291 Example of creating a new row.
2292
2293   $person_rs->create({
2294     name=>"Some Person",
2295     email=>"somebody@someplace.com"
2296   });
2297
2298 Example of creating a new row and also creating rows in a related C<has_many>
2299 or C<has_one> resultset.  Note Arrayref.
2300
2301   $artist_rs->create(
2302      { artistid => 4, name => 'Manufactured Crap', cds => [
2303         { title => 'My First CD', year => 2006 },
2304         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2305       ],
2306      },
2307   );
2308
2309 Example of creating a new row and also creating a row in a related
2310 C<belongs_to>resultset. Note Hashref.
2311
2312   $cd_rs->create({
2313     title=>"Music for Silly Walks",
2314     year=>2000,
2315     artist => {
2316       name=>"Silly Musician",
2317     }
2318   });
2319
2320 =over
2321
2322 =item WARNING
2323
2324 When subclassing ResultSet never attempt to override this method. Since
2325 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2326 lot of the internals simply never call it, so your override will be
2327 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2328 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2329 L</create> process you need to intervene.
2330
2331 =back
2332
2333 =cut
2334
2335 sub create {
2336   my ($self, $attrs) = @_;
2337   $self->throw_exception( "create needs a hashref" )
2338     unless ref $attrs eq 'HASH';
2339   return $self->new_result($attrs)->insert;
2340 }
2341
2342 =head2 find_or_create
2343
2344 =over 4
2345
2346 =item Arguments: \%vals, \%attrs?
2347
2348 =item Return Value: $rowobject
2349
2350 =back
2351
2352   $cd->cd_to_producer->find_or_create({ producer => $producer },
2353                                       { key => 'primary' });
2354
2355 Tries to find a record based on its primary key or unique constraints; if none
2356 is found, creates one and returns that instead.
2357
2358   my $cd = $schema->resultset('CD')->find_or_create({
2359     cdid   => 5,
2360     artist => 'Massive Attack',
2361     title  => 'Mezzanine',
2362     year   => 2005,
2363   });
2364
2365 Also takes an optional C<key> attribute, to search by a specific key or unique
2366 constraint. For example:
2367
2368   my $cd = $schema->resultset('CD')->find_or_create(
2369     {
2370       artist => 'Massive Attack',
2371       title  => 'Mezzanine',
2372     },
2373     { key => 'cd_artist_title' }
2374   );
2375
2376 B<Note>: Because find_or_create() reads from the database and then
2377 possibly inserts based on the result, this method is subject to a race
2378 condition. Another process could create a record in the table after
2379 the find has completed and before the create has started. To avoid
2380 this problem, use find_or_create() inside a transaction.
2381
2382 B<Note>: Take care when using C<find_or_create> with a table having
2383 columns with default values that you intend to be automatically
2384 supplied by the database (e.g. an auto_increment primary key column).
2385 In normal usage, the value of such columns should NOT be included at
2386 all in the call to C<find_or_create>, even when set to C<undef>.
2387
2388 See also L</find> and L</update_or_create>. For information on how to declare
2389 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2390
2391 =cut
2392
2393 sub find_or_create {
2394   my $self     = shift;
2395   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2396   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2397   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2398     return $row;
2399   }
2400   return $self->create($hash);
2401 }
2402
2403 =head2 update_or_create
2404
2405 =over 4
2406
2407 =item Arguments: \%col_values, { key => $unique_constraint }?
2408
2409 =item Return Value: $rowobject
2410
2411 =back
2412
2413   $resultset->update_or_create({ col => $val, ... });
2414
2415 First, searches for an existing row matching one of the unique constraints
2416 (including the primary key) on the source of this resultset. If a row is
2417 found, updates it with the other given column values. Otherwise, creates a new
2418 row.
2419
2420 Takes an optional C<key> attribute to search on a specific unique constraint.
2421 For example:
2422
2423   # In your application
2424   my $cd = $schema->resultset('CD')->update_or_create(
2425     {
2426       artist => 'Massive Attack',
2427       title  => 'Mezzanine',
2428       year   => 1998,
2429     },
2430     { key => 'cd_artist_title' }
2431   );
2432
2433   $cd->cd_to_producer->update_or_create({
2434     producer => $producer,
2435     name => 'harry',
2436   }, {
2437     key => 'primary,
2438   });
2439
2440
2441 If no C<key> is specified, it searches on all unique constraints defined on the
2442 source, including the primary key.
2443
2444 If the C<key> is specified as C<primary>, it searches only on the primary key.
2445
2446 See also L</find> and L</find_or_create>. For information on how to declare
2447 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2448
2449 B<Note>: Take care when using C<update_or_create> with a table having
2450 columns with default values that you intend to be automatically
2451 supplied by the database (e.g. an auto_increment primary key column).
2452 In normal usage, the value of such columns should NOT be included at
2453 all in the call to C<update_or_create>, even when set to C<undef>.
2454
2455 =cut
2456
2457 sub update_or_create {
2458   my $self = shift;
2459   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2460   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2461
2462   my $row = $self->find($cond, $attrs);
2463   if (defined $row) {
2464     $row->update($cond);
2465     return $row;
2466   }
2467
2468   return $self->create($cond);
2469 }
2470
2471 =head2 update_or_new
2472
2473 =over 4
2474
2475 =item Arguments: \%col_values, { key => $unique_constraint }?
2476
2477 =item Return Value: $rowobject
2478
2479 =back
2480
2481   $resultset->update_or_new({ col => $val, ... });
2482
2483 First, searches for an existing row matching one of the unique constraints
2484 (including the primary key) on the source of this resultset. If a row is
2485 found, updates it with the other given column values. Otherwise, instantiate
2486 a new result object and return it. The object will not be saved into your storage
2487 until you call L<DBIx::Class::Row/insert> on it.
2488
2489 Takes an optional C<key> attribute to search on a specific unique constraint.
2490 For example:
2491
2492   # In your application
2493   my $cd = $schema->resultset('CD')->update_or_new(
2494     {
2495       artist => 'Massive Attack',
2496       title  => 'Mezzanine',
2497       year   => 1998,
2498     },
2499     { key => 'cd_artist_title' }
2500   );
2501
2502   if ($cd->in_storage) {
2503       # the cd was updated
2504   }
2505   else {
2506       # the cd is not yet in the database, let's insert it
2507       $cd->insert;
2508   }
2509
2510 B<Note>: Take care when using C<update_or_new> with a table having
2511 columns with default values that you intend to be automatically
2512 supplied by the database (e.g. an auto_increment primary key column).
2513 In normal usage, the value of such columns should NOT be included at
2514 all in the call to C<update_or_new>, even when set to C<undef>.
2515
2516 See also L</find>, L</find_or_create> and L</find_or_new>.
2517
2518 =cut
2519
2520 sub update_or_new {
2521     my $self  = shift;
2522     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2523     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2524
2525     my $row = $self->find( $cond, $attrs );
2526     if ( defined $row ) {
2527         $row->update($cond);
2528         return $row;
2529     }
2530
2531     return $self->new_result($cond);
2532 }
2533
2534 =head2 get_cache
2535
2536 =over 4
2537
2538 =item Arguments: none
2539
2540 =item Return Value: \@cache_objects?
2541
2542 =back
2543
2544 Gets the contents of the cache for the resultset, if the cache is set.
2545
2546 The cache is populated either by using the L</prefetch> attribute to
2547 L</search> or by calling L</set_cache>.
2548
2549 =cut
2550
2551 sub get_cache {
2552   shift->{all_cache};
2553 }
2554
2555 =head2 set_cache
2556
2557 =over 4
2558
2559 =item Arguments: \@cache_objects
2560
2561 =item Return Value: \@cache_objects
2562
2563 =back
2564
2565 Sets the contents of the cache for the resultset. Expects an arrayref
2566 of objects of the same class as those produced by the resultset. Note that
2567 if the cache is set the resultset will return the cached objects rather
2568 than re-querying the database even if the cache attr is not set.
2569
2570 The contents of the cache can also be populated by using the
2571 L</prefetch> attribute to L</search>.
2572
2573 =cut
2574
2575 sub set_cache {
2576   my ( $self, $data ) = @_;
2577   $self->throw_exception("set_cache requires an arrayref")
2578       if defined($data) && (ref $data ne 'ARRAY');
2579   $self->{all_cache} = $data;
2580 }
2581
2582 =head2 clear_cache
2583
2584 =over 4
2585
2586 =item Arguments: none
2587
2588 =item Return Value: []
2589
2590 =back
2591
2592 Clears the cache for the resultset.
2593
2594 =cut
2595
2596 sub clear_cache {
2597   shift->set_cache(undef);
2598 }
2599
2600 =head2 related_resultset
2601
2602 =over 4
2603
2604 =item Arguments: $relationship_name
2605
2606 =item Return Value: $resultset
2607
2608 =back
2609
2610 Returns a related resultset for the supplied relationship name.
2611
2612   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2613
2614 =cut
2615
2616 sub related_resultset {
2617   my ($self, $rel) = @_;
2618
2619   $self->{related_resultsets} ||= {};
2620   return $self->{related_resultsets}{$rel} ||= do {
2621     my $rel_info = $self->result_source->relationship_info($rel);
2622
2623     $self->throw_exception(
2624       "search_related: result source '" . $self->result_source->source_name .
2625         "' has no such relationship $rel")
2626       unless $rel_info;
2627
2628     my ($from,$seen) = $self->_chain_relationship($rel);
2629
2630     my $join_count = $seen->{$rel};
2631     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2632
2633     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2634     my %attrs = %{$self->{attrs}||{}};
2635     delete @attrs{qw(result_class alias)};
2636
2637     my $new_cache;
2638
2639     if (my $cache = $self->get_cache) {
2640       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2641         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2642                         @$cache ];
2643       }
2644     }
2645
2646     my $rel_source = $self->result_source->related_source($rel);
2647
2648     my $new = do {
2649
2650       # The reason we do this now instead of passing the alias to the
2651       # search_rs below is that if you wrap/overload resultset on the
2652       # source you need to know what alias it's -going- to have for things
2653       # to work sanely (e.g. RestrictWithObject wants to be able to add
2654       # extra query restrictions, and these may need to be $alias.)
2655
2656       my $attrs = $rel_source->resultset_attributes;
2657       local $attrs->{alias} = $alias;
2658
2659       $rel_source->resultset
2660                  ->search_rs(
2661                      undef, {
2662                        %attrs,
2663                        join => undef,
2664                        prefetch => undef,
2665                        select => undef,
2666                        as => undef,
2667                        where => $self->{cond},
2668                        seen_join => $seen,
2669                        from => $from,
2670                    });
2671     };
2672     $new->set_cache($new_cache) if $new_cache;
2673     $new;
2674   };
2675 }
2676
2677 =head2 current_source_alias
2678
2679 =over 4
2680
2681 =item Arguments: none
2682
2683 =item Return Value: $source_alias
2684
2685 =back
2686
2687 Returns the current table alias for the result source this resultset is built
2688 on, that will be used in the SQL query. Usually it is C<me>.
2689
2690 Currently the source alias that refers to the result set returned by a
2691 L</search>/L</find> family method depends on how you got to the resultset: it's
2692 C<me> by default, but eg. L</search_related> aliases it to the related result
2693 source name (and keeps C<me> referring to the original result set). The long
2694 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2695 (and make this method unnecessary).
2696
2697 Thus it's currently necessary to use this method in predefined queries (see
2698 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2699 source alias of the current result set:
2700
2701   # in a result set class
2702   sub modified_by {
2703     my ($self, $user) = @_;
2704
2705     my $me = $self->current_source_alias;
2706
2707     return $self->search(
2708       "$me.modified" => $user->id,
2709     );
2710   }
2711
2712 =cut
2713
2714 sub current_source_alias {
2715   my ($self) = @_;
2716
2717   return ($self->{attrs} || {})->{alias} || 'me';
2718 }
2719
2720 # This code is called by search_related, and makes sure there
2721 # is clear separation between the joins before, during, and
2722 # after the relationship. This information is needed later
2723 # in order to properly resolve prefetch aliases (any alias
2724 # with a relation_chain_depth less than the depth of the
2725 # current prefetch is not considered)
2726 #
2727 # The increments happen in 1/2s to make it easier to correlate the
2728 # join depth with the join path. An integer means a relationship
2729 # specified via a search_related, whereas a fraction means an added
2730 # join/prefetch via attributes
2731 sub _chain_relationship {
2732   my ($self, $rel) = @_;
2733   my $source = $self->result_source;
2734   my $attrs = $self->{attrs};
2735
2736   my $from = [ @{
2737       $attrs->{from}
2738         ||
2739       [{
2740         -source_handle => $source->handle,
2741         -alias => $attrs->{alias},
2742         $attrs->{alias} => $source->from,
2743       }]
2744   }];
2745
2746   my $seen = { %{$attrs->{seen_join} || {} } };
2747   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2748     ? $from->[-1][0]{-join_path}
2749     : [];
2750
2751
2752   # we need to take the prefetch the attrs into account before we
2753   # ->_resolve_join as otherwise they get lost - captainL
2754   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2755
2756   my @requested_joins = $source->_resolve_join(
2757     $merged,
2758     $attrs->{alias},
2759     $seen,
2760     $jpath,
2761   );
2762
2763   push @$from, @requested_joins;
2764
2765   $seen->{-relation_chain_depth} += 0.5;
2766
2767   # if $self already had a join/prefetch specified on it, the requested
2768   # $rel might very well be already included. What we do in this case
2769   # is effectively a no-op (except that we bump up the chain_depth on
2770   # the join in question so we could tell it *is* the search_related)
2771   my $already_joined;
2772
2773
2774   # we consider the last one thus reverse
2775   for my $j (reverse @requested_joins) {
2776     if ($rel eq $j->[0]{-join_path}[-1]) {
2777       $j->[0]{-relation_chain_depth} += 0.5;
2778       $already_joined++;
2779       last;
2780     }
2781   }
2782
2783 # alternative way to scan the entire chain - not backwards compatible
2784 #  for my $j (reverse @$from) {
2785 #    next unless ref $j eq 'ARRAY';
2786 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2787 #      $j->[0]{-relation_chain_depth} += 0.5;
2788 #      $already_joined++;
2789 #      last;
2790 #    }
2791 #  }
2792
2793   unless ($already_joined) {
2794     push @$from, $source->_resolve_join(
2795       $rel,
2796       $attrs->{alias},
2797       $seen,
2798       $jpath,
2799     );
2800   }
2801
2802   $seen->{-relation_chain_depth} += 0.5;
2803
2804   return ($from,$seen);
2805 }
2806
2807 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2808 sub _resolved_attrs_copy {
2809   my $self = shift;
2810   return { %{$self->_resolved_attrs (@_)} };
2811 }
2812
2813 sub _resolved_attrs {
2814   my $self = shift;
2815   return $self->{_attrs} if $self->{_attrs};
2816
2817   my $attrs  = { %{ $self->{attrs} || {} } };
2818   my $source = $self->result_source;
2819   my $alias  = $attrs->{alias};
2820
2821   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2822   my @colbits;
2823
2824   # build columns (as long as select isn't set) into a set of as/select hashes
2825   unless ( $attrs->{select} ) {
2826
2827     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2828       ? @{ delete $attrs->{columns}}
2829       : (
2830           ( delete $attrs->{columns} )
2831             ||
2832           $source->columns
2833         )
2834     ;
2835
2836     @colbits = map {
2837       ( ref($_) eq 'HASH' )
2838       ? $_
2839       : {
2840           (
2841             /^\Q${alias}.\E(.+)$/
2842               ? "$1"
2843               : "$_"
2844           )
2845             =>
2846           (
2847             /\./
2848               ? "$_"
2849               : "${alias}.$_"
2850           )
2851         }
2852     } @cols;
2853   }
2854
2855   # add the additional columns on
2856   foreach ( 'include_columns', '+columns' ) {
2857       push @colbits, map {
2858           ( ref($_) eq 'HASH' )
2859             ? $_
2860             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2861       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2862   }
2863
2864   # start with initial select items
2865   if ( $attrs->{select} ) {
2866     $attrs->{select} =
2867         ( ref $attrs->{select} eq 'ARRAY' )
2868       ? [ @{ $attrs->{select} } ]
2869       : [ $attrs->{select} ];
2870     $attrs->{as} = (
2871       $attrs->{as}
2872       ? (
2873         ref $attrs->{as} eq 'ARRAY'
2874         ? [ @{ $attrs->{as} } ]
2875         : [ $attrs->{as} ]
2876         )
2877       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2878     );
2879   }
2880   else {
2881
2882     # otherwise we intialise select & as to empty
2883     $attrs->{select} = [];
2884     $attrs->{as}     = [];
2885   }
2886
2887   # now add colbits to select/as
2888   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2889   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2890
2891   my $adds;
2892   if ( $adds = delete $attrs->{'+select'} ) {
2893     $adds = [$adds] unless ref $adds eq 'ARRAY';
2894     push(
2895       @{ $attrs->{select} },
2896       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2897     );
2898   }
2899   if ( $adds = delete $attrs->{'+as'} ) {
2900     $adds = [$adds] unless ref $adds eq 'ARRAY';
2901     push( @{ $attrs->{as} }, @$adds );
2902   }
2903
2904   $attrs->{from} ||= [ {
2905     -source_handle => $source->handle,
2906     -alias => $self->{attrs}{alias},
2907     $self->{attrs}{alias} => $source->from,
2908   } ];
2909
2910   if ( $attrs->{join} || $attrs->{prefetch} ) {
2911
2912     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2913       if ref $attrs->{from} ne 'ARRAY';
2914
2915     my $join = delete $attrs->{join} || {};
2916
2917     if ( defined $attrs->{prefetch} ) {
2918       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2919     }
2920
2921     $attrs->{from} =    # have to copy here to avoid corrupting the original
2922       [
2923         @{ $attrs->{from} },
2924         $source->_resolve_join(
2925           $join,
2926           $alias,
2927           { %{ $attrs->{seen_join} || {} } },
2928           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2929             ? $attrs->{from}[-1][0]{-join_path}
2930             : []
2931           ,
2932         )
2933       ];
2934   }
2935
2936   if ( defined $attrs->{order_by} ) {
2937     $attrs->{order_by} = (
2938       ref( $attrs->{order_by} ) eq 'ARRAY'
2939       ? [ @{ $attrs->{order_by} } ]
2940       : [ $attrs->{order_by} || () ]
2941     );
2942   }
2943
2944   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2945     $attrs->{group_by} = [ $attrs->{group_by} ];
2946   }
2947
2948   # generate the distinct induced group_by early, as prefetch will be carried via a
2949   # subquery (since a group_by is present)
2950   if (delete $attrs->{distinct}) {
2951     if ($attrs->{group_by}) {
2952       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2953     }
2954     else {
2955       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2956     }
2957   }
2958
2959   $attrs->{collapse} ||= {};
2960   if ( my $prefetch = delete $attrs->{prefetch} ) {
2961     $prefetch = $self->_merge_attr( {}, $prefetch );
2962
2963     my $prefetch_ordering = [];
2964
2965     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2966
2967     my @prefetch =
2968       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2969
2970     # we need to somehow mark which columns came from prefetch
2971     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2972
2973     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2974     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2975
2976     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2977     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2978   }
2979
2980   # if both page and offset are specified, produce a combined offset
2981   # even though it doesn't make much sense, this is what pre 081xx has
2982   # been doing
2983   if (my $page = delete $attrs->{page}) {
2984     $attrs->{offset} =
2985       ($attrs->{rows} * ($page - 1))
2986             +
2987       ($attrs->{offset} || 0)
2988     ;
2989   }
2990
2991   return $self->{_attrs} = $attrs;
2992 }
2993
2994 sub _joinpath_aliases {
2995   my ($self, $fromspec, $seen) = @_;
2996
2997   my $paths = {};
2998   return $paths unless ref $fromspec eq 'ARRAY';
2999
3000   my $cur_depth = $seen->{-relation_chain_depth} || 0;
3001
3002   if (int ($cur_depth) != $cur_depth) {
3003     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
3004   }
3005
3006   for my $j (@$fromspec) {
3007
3008     next if ref $j ne 'ARRAY';
3009     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
3010
3011     my $jpath = $j->[0]{-join_path};
3012
3013     my $p = $paths;
3014     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
3015     push @{$p->{-join_aliases} }, $j->[0]{-alias};
3016   }
3017
3018   return $paths;
3019 }
3020
3021 sub _rollout_attr {
3022   my ($self, $attr) = @_;
3023
3024   if (ref $attr eq 'HASH') {
3025     return $self->_rollout_hash($attr);
3026   } elsif (ref $attr eq 'ARRAY') {
3027     return $self->_rollout_array($attr);
3028   } else {
3029     return [$attr];
3030   }
3031 }
3032
3033 sub _rollout_array {
3034   my ($self, $attr) = @_;
3035
3036   my @rolled_array;
3037   foreach my $element (@{$attr}) {
3038     if (ref $element eq 'HASH') {
3039       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
3040     } elsif (ref $element eq 'ARRAY') {
3041       #  XXX - should probably recurse here
3042       push( @rolled_array, @{$self->_rollout_array($element)} );
3043     } else {
3044       push( @rolled_array, $element );
3045     }
3046   }
3047   return \@rolled_array;
3048 }
3049
3050 sub _rollout_hash {
3051   my ($self, $attr) = @_;
3052
3053   my @rolled_array;
3054   foreach my $key (keys %{$attr}) {
3055     push( @rolled_array, { $key => $attr->{$key} } );
3056   }
3057   return \@rolled_array;
3058 }
3059
3060 sub _calculate_score {
3061   my ($self, $a, $b) = @_;
3062
3063   if (defined $a xor defined $b) {
3064     return 0;
3065   }
3066   elsif (not defined $a) {
3067     return 1;
3068   }
3069
3070   if (ref $b eq 'HASH') {
3071     my ($b_key) = keys %{$b};
3072     if (ref $a eq 'HASH') {
3073       my ($a_key) = keys %{$a};
3074       if ($a_key eq $b_key) {
3075         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3076       } else {
3077         return 0;
3078       }
3079     } else {
3080       return ($a eq $b_key) ? 1 : 0;
3081     }
3082   } else {
3083     if (ref $a eq 'HASH') {
3084       my ($a_key) = keys %{$a};
3085       return ($b eq $a_key) ? 1 : 0;
3086     } else {
3087       return ($b eq $a) ? 1 : 0;
3088     }
3089   }
3090 }
3091
3092 sub _merge_attr {
3093   my ($self, $orig, $import) = @_;
3094
3095   return $import unless defined($orig);
3096   return $orig unless defined($import);
3097
3098   $orig = $self->_rollout_attr($orig);
3099   $import = $self->_rollout_attr($import);
3100
3101   my $seen_keys;
3102   foreach my $import_element ( @{$import} ) {
3103     # find best candidate from $orig to merge $b_element into
3104     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3105     foreach my $orig_element ( @{$orig} ) {
3106       my $score = $self->_calculate_score( $orig_element, $import_element );
3107       if ($score > $best_candidate->{score}) {
3108         $best_candidate->{position} = $position;
3109         $best_candidate->{score} = $score;
3110       }
3111       $position++;
3112     }
3113     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3114
3115     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3116       push( @{$orig}, $import_element );
3117     } else {
3118       my $orig_best = $orig->[$best_candidate->{position}];
3119       # merge orig_best and b_element together and replace original with merged
3120       if (ref $orig_best ne 'HASH') {
3121         $orig->[$best_candidate->{position}] = $import_element;
3122       } elsif (ref $import_element eq 'HASH') {
3123         my ($key) = keys %{$orig_best};
3124         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3125       }
3126     }
3127     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3128   }
3129
3130   return $orig;
3131 }
3132
3133 sub result_source {
3134     my $self = shift;
3135
3136     if (@_) {
3137         $self->_source_handle($_[0]->handle);
3138     } else {
3139         $self->_source_handle->resolve;
3140     }
3141 }
3142
3143 =head2 throw_exception
3144
3145 See L<DBIx::Class::Schema/throw_exception> for details.
3146
3147 =cut
3148
3149 sub throw_exception {
3150   my $self=shift;
3151
3152   if (ref $self && $self->_source_handle->schema) {
3153     $self->_source_handle->schema->throw_exception(@_)
3154   }
3155   else {
3156     DBIx::Class::Exception->throw(@_);
3157   }
3158 }
3159
3160 # XXX: FIXME: Attributes docs need clearing up
3161
3162 =head1 ATTRIBUTES
3163
3164 Attributes are used to refine a ResultSet in various ways when
3165 searching for data. They can be passed to any method which takes an
3166 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3167 L</count>.
3168
3169 These are in no particular order:
3170
3171 =head2 order_by
3172
3173 =over 4
3174
3175 =item Value: ( $order_by | \@order_by | \%order_by )
3176
3177 =back
3178
3179 Which column(s) to order the results by.
3180
3181 [The full list of suitable values is documented in
3182 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3183 common options.]
3184
3185 If a single column name, or an arrayref of names is supplied, the
3186 argument is passed through directly to SQL. The hashref syntax allows
3187 for connection-agnostic specification of ordering direction:
3188
3189  For descending order:
3190
3191   order_by => { -desc => [qw/col1 col2 col3/] }
3192
3193  For explicit ascending order:
3194
3195   order_by => { -asc => 'col' }
3196
3197 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3198 supported, although you are strongly encouraged to use the hashref
3199 syntax as outlined above.
3200
3201 =head2 columns
3202
3203 =over 4
3204
3205 =item Value: \@columns
3206
3207 =back
3208
3209 Shortcut to request a particular set of columns to be retrieved. Each
3210 column spec may be a string (a table column name), or a hash (in which
3211 case the key is the C<as> value, and the value is used as the C<select>
3212 expression). Adds C<me.> onto the start of any column without a C<.> in
3213 it and sets C<select> from that, then auto-populates C<as> from
3214 C<select> as normal. (You may also use the C<cols> attribute, as in
3215 earlier versions of DBIC.)
3216
3217 =head2 +columns
3218
3219 =over 4
3220
3221 =item Value: \@columns
3222
3223 =back
3224
3225 Indicates additional columns to be selected from storage. Works the same
3226 as L</columns> but adds columns to the selection. (You may also use the
3227 C<include_columns> attribute, as in earlier versions of DBIC). For
3228 example:-
3229
3230   $schema->resultset('CD')->search(undef, {
3231     '+columns' => ['artist.name'],
3232     join => ['artist']
3233   });
3234
3235 would return all CDs and include a 'name' column to the information
3236 passed to object inflation. Note that the 'artist' is the name of the
3237 column (or relationship) accessor, and 'name' is the name of the column
3238 accessor in the related table.
3239
3240 =head2 include_columns
3241
3242 =over 4
3243
3244 =item Value: \@columns
3245
3246 =back
3247
3248 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3249
3250 =head2 select
3251
3252 =over 4
3253
3254 =item Value: \@select_columns
3255
3256 =back
3257
3258 Indicates which columns should be selected from the storage. You can use
3259 column names, or in the case of RDBMS back ends, function or stored procedure
3260 names:
3261
3262   $rs = $schema->resultset('Employee')->search(undef, {
3263     select => [
3264       'name',
3265       { count => 'employeeid' },
3266       { sum => 'salary' }
3267     ]
3268   });
3269
3270 When you use function/stored procedure names and do not supply an C<as>
3271 attribute, the column names returned are storage-dependent. E.g. MySQL would
3272 return a column named C<count(employeeid)> in the above example.
3273
3274 =head2 +select
3275
3276 =over 4
3277
3278 Indicates additional columns to be selected from storage.  Works the same as
3279 L</select> but adds columns to the selection.
3280
3281 =back
3282
3283 =head2 +as
3284
3285 =over 4
3286
3287 Indicates additional column names for those added via L</+select>. See L</as>.
3288
3289 =back
3290
3291 =head2 as
3292
3293 =over 4
3294
3295 =item Value: \@inflation_names
3296
3297 =back
3298
3299 Indicates column names for object inflation. That is, C<as>
3300 indicates the name that the column can be accessed as via the
3301 C<get_column> method (or via the object accessor, B<if one already
3302 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3303
3304 The C<as> attribute is used in conjunction with C<select>,
3305 usually when C<select> contains one or more function or stored
3306 procedure names:
3307
3308   $rs = $schema->resultset('Employee')->search(undef, {
3309     select => [
3310       'name',
3311       { count => 'employeeid' }
3312     ],
3313     as => ['name', 'employee_count'],
3314   });
3315
3316   my $employee = $rs->first(); # get the first Employee
3317
3318 If the object against which the search is performed already has an accessor
3319 matching a column name specified in C<as>, the value can be retrieved using
3320 the accessor as normal:
3321
3322   my $name = $employee->name();
3323
3324 If on the other hand an accessor does not exist in the object, you need to
3325 use C<get_column> instead:
3326
3327   my $employee_count = $employee->get_column('employee_count');
3328
3329 You can create your own accessors if required - see
3330 L<DBIx::Class::Manual::Cookbook> for details.
3331
3332 Please note: This will NOT insert an C<AS employee_count> into the SQL
3333 statement produced, it is used for internal access only. Thus
3334 attempting to use the accessor in an C<order_by> clause or similar
3335 will fail miserably.
3336
3337 To get around this limitation, you can supply literal SQL to your
3338 C<select> attibute that contains the C<AS alias> text, eg:
3339
3340   select => [\'myfield AS alias']
3341
3342 =head2 join
3343
3344 =over 4
3345
3346 =item Value: ($rel_name | \@rel_names | \%rel_names)
3347
3348 =back
3349
3350 Contains a list of relationships that should be joined for this query.  For
3351 example:
3352
3353   # Get CDs by Nine Inch Nails
3354   my $rs = $schema->resultset('CD')->search(
3355     { 'artist.name' => 'Nine Inch Nails' },
3356     { join => 'artist' }
3357   );
3358
3359 Can also contain a hash reference to refer to the other relation's relations.
3360 For example:
3361
3362   package MyApp::Schema::Track;
3363   use base qw/DBIx::Class/;
3364   __PACKAGE__->table('track');
3365   __PACKAGE__->add_columns(qw/trackid cd position title/);
3366   __PACKAGE__->set_primary_key('trackid');
3367   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3368   1;
3369
3370   # In your application
3371   my $rs = $schema->resultset('Artist')->search(
3372     { 'track.title' => 'Teardrop' },
3373     {
3374       join     => { cd => 'track' },
3375       order_by => 'artist.name',
3376     }
3377   );
3378
3379 You need to use the relationship (not the table) name in  conditions,
3380 because they are aliased as such. The current table is aliased as "me", so
3381 you need to use me.column_name in order to avoid ambiguity. For example:
3382
3383   # Get CDs from 1984 with a 'Foo' track
3384   my $rs = $schema->resultset('CD')->search(
3385     {
3386       'me.year' => 1984,
3387       'tracks.name' => 'Foo'
3388     },
3389     { join => 'tracks' }
3390   );
3391
3392 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3393 similarly for a third time). For e.g.
3394
3395   my $rs = $schema->resultset('Artist')->search({
3396     'cds.title'   => 'Down to Earth',
3397     'cds_2.title' => 'Popular',
3398   }, {
3399     join => [ qw/cds cds/ ],
3400   });
3401
3402 will return a set of all artists that have both a cd with title 'Down
3403 to Earth' and a cd with title 'Popular'.
3404
3405 If you want to fetch related objects from other tables as well, see C<prefetch>
3406 below.
3407
3408 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3409
3410 =head2 prefetch
3411
3412 =over 4
3413
3414 =item Value: ($rel_name | \@rel_names | \%rel_names)
3415
3416 =back
3417
3418 Contains one or more relationships that should be fetched along with
3419 the main query (when they are accessed afterwards the data will
3420 already be available, without extra queries to the database).  This is
3421 useful for when you know you will need the related objects, because it
3422 saves at least one query:
3423
3424   my $rs = $schema->resultset('Tag')->search(
3425     undef,
3426     {
3427       prefetch => {
3428         cd => 'artist'
3429       }
3430     }
3431   );
3432
3433 The initial search results in SQL like the following:
3434
3435   SELECT tag.*, cd.*, artist.* FROM tag
3436   JOIN cd ON tag.cd = cd.cdid
3437   JOIN artist ON cd.artist = artist.artistid
3438
3439 L<DBIx::Class> has no need to go back to the database when we access the
3440 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3441 case.
3442
3443 Simple prefetches will be joined automatically, so there is no need
3444 for a C<join> attribute in the above search.
3445
3446 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3447 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3448 with an accessor type of 'single' or 'filter'). A more complex example that
3449 prefetches an artists cds, the tracks on those cds, and the tags associted
3450 with that artist is given below (assuming many-to-many from artists to tags):
3451
3452  my $rs = $schema->resultset('Artist')->search(
3453    undef,
3454    {
3455      prefetch => [
3456        { cds => 'tracks' },
3457        { artist_tags => 'tags' }
3458      ]
3459    }
3460  );
3461
3462
3463 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3464 attributes will be ignored.
3465
3466 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3467 exactly as you might expect.
3468
3469 =over 4
3470
3471 =item *
3472
3473 Prefetch uses the L</cache> to populate the prefetched relationships. This
3474 may or may not be what you want.
3475
3476 =item *
3477
3478 If you specify a condition on a prefetched relationship, ONLY those
3479 rows that match the prefetched condition will be fetched into that relationship.
3480 This means that adding prefetch to a search() B<may alter> what is returned by
3481 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3482
3483   my $artist_rs = $schema->resultset('Artist')->search({
3484       'cds.year' => 2008,
3485   }, {
3486       join => 'cds',
3487   });
3488
3489   my $count = $artist_rs->first->cds->count;
3490
3491   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3492
3493   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3494
3495   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3496
3497 that cmp_ok() may or may not pass depending on the datasets involved. This
3498 behavior may or may not survive the 0.09 transition.
3499
3500 =back
3501
3502 =head2 page
3503
3504 =over 4
3505
3506 =item Value: $page
3507
3508 =back
3509
3510 Makes the resultset paged and specifies the page to retrieve. Effectively
3511 identical to creating a non-pages resultset and then calling ->page($page)
3512 on it.
3513
3514 If L<rows> attribute is not specified it defaults to 10 rows per page.
3515
3516 When you have a paged resultset, L</count> will only return the number
3517 of rows in the page. To get the total, use the L</pager> and call
3518 C<total_entries> on it.
3519
3520 =head2 rows
3521
3522 =over 4
3523
3524 =item Value: $rows
3525
3526 =back
3527
3528 Specifes the maximum number of rows for direct retrieval or the number of
3529 rows per page if the page attribute or method is used.
3530
3531 =head2 offset
3532
3533 =over 4
3534
3535 =item Value: $offset
3536
3537 =back
3538
3539 Specifies the (zero-based) row number for the  first row to be returned, or the
3540 of the first row of the first page if paging is used.
3541
3542 =head2 group_by
3543
3544 =over 4
3545
3546 =item Value: \@columns
3547
3548 =back
3549
3550 A arrayref of columns to group by. Can include columns of joined tables.
3551
3552   group_by => [qw/ column1 column2 ... /]
3553
3554 =head2 having
3555
3556 =over 4
3557
3558 =item Value: $condition
3559
3560 =back
3561
3562 HAVING is a select statement attribute that is applied between GROUP BY and
3563 ORDER BY. It is applied to the after the grouping calculations have been
3564 done.
3565
3566   having => { 'count(employee)' => { '>=', 100 } }
3567
3568 =head2 distinct
3569
3570 =over 4
3571
3572 =item Value: (0 | 1)
3573
3574 =back
3575
3576 Set to 1 to group by all columns. If the resultset already has a group_by
3577 attribute, this setting is ignored and an appropriate warning is issued.
3578
3579 =head2 where
3580
3581 =over 4
3582
3583 Adds to the WHERE clause.
3584
3585   # only return rows WHERE deleted IS NULL for all searches
3586   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3587
3588 Can be overridden by passing C<{ where => undef }> as an attribute
3589 to a resulset.
3590
3591 =back
3592
3593 =head2 cache
3594
3595 Set to 1 to cache search results. This prevents extra SQL queries if you
3596 revisit rows in your ResultSet:
3597
3598   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3599
3600   while( my $artist = $resultset->next ) {
3601     ... do stuff ...
3602   }
3603
3604   $rs->first; # without cache, this would issue a query
3605
3606 By default, searches are not cached.
3607
3608 For more examples of using these attributes, see
3609 L<DBIx::Class::Manual::Cookbook>.
3610
3611 =head2 for
3612
3613 =over 4
3614
3615 =item Value: ( 'update' | 'shared' )
3616
3617 =back
3618
3619 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3620 ... FOR SHARED.
3621
3622 =cut
3623
3624 1;