lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799 #      warn "ARRAY: " . Dumper $subquery;
 800       $collapsed = $self->_collapse_query($subquery, $collapsed);
 801     }
 802   }
 803   elsif (ref $query eq 'HASH') {
 804     if (keys %$query and (keys %$query)[0] eq '-and') {
 805       foreach my $subquery (@{$query->{-and}}) {
 806 #        warn "HASH: " . Dumper $subquery;
 807         $collapsed = $self->_collapse_query($subquery, $collapsed);
 808       }
 809     }
 810     else {
 811 #      warn "LEAF: " . Dumper $query;
 812       foreach my $col (keys %$query) {
 813         my $value = $query->{$col};
 814         $collapsed->{$col}{$value}++;
 815       }
 816     }
 817   }
 818
 819   return $collapsed;
 820 }
 821
 822 =head2 get_column
 823
 824 =over 4
 825
 826 =item Arguments: $cond?
 827
 828 =item Return Value: $resultsetcolumn
 829
 830 =back
 831
 832   my $max_length = $rs->get_column('length')->max;
 833
 834 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 835
 836 =cut
 837
 838 sub get_column {
 839   my ($self, $column) = @_;
 840   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 841   return $new;
 842 }
 843
 844 =head2 search_like
 845
 846 =over 4
 847
 848 =item Arguments: $cond, \%attrs?
 849
 850 =item Return Value: $resultset (scalar context), @row_objs (list context)
 851
 852 =back
 853
 854   # WHERE title LIKE '%blue%'
 855   $cd_rs = $rs->search_like({ title => '%blue%'});
 856
 857 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 858 that this is simply a convenience method retained for ex Class::DBI users.
 859 You most likely want to use L</search> with specific operators.
 860
 861 For more information, see L<DBIx::Class::Manual::Cookbook>.
 862
 863 This method is deprecated and will be removed in 0.09. Use L</search()>
 864 instead. An example conversion is:
 865
 866   ->search_like({ foo => 'bar' });
 867
 868   # Becomes
 869
 870   ->search({ foo => { like => 'bar' } });
 871
 872 =cut
 873
 874 sub search_like {
 875   my $class = shift;
 876   carp join ("\n",
 877     'search_like() is deprecated and will be removed in 0.09.',
 878     'Instead use ->search({ x => { -like => "y%" } })',
 879     '(note the outer pair of {}s - they are important!)'
 880   );
 881   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 882   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 883   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 884   return $class->search($query, { %$attrs });
 885 }
 886
 887 =head2 slice
 888
 889 =over 4
 890
 891 =item Arguments: $first, $last
 892
 893 =item Return Value: $resultset (scalar context), @row_objs (list context)
 894
 895 =back
 896
 897 Returns a resultset or object list representing a subset of elements from the
 898 resultset slice is called on. Indexes are from 0, i.e., to get the first
 899 three records, call:
 900
 901   my ($one, $two, $three) = $rs->slice(0, 2);
 902
 903 =cut
 904
 905 sub slice {
 906   my ($self, $min, $max) = @_;
 907   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 908   $attrs->{offset} = $self->{attrs}{offset} || 0;
 909   $attrs->{offset} += $min;
 910   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 911   return $self->search(undef(), $attrs);
 912   #my $slice = (ref $self)->new($self->result_source, $attrs);
 913   #return (wantarray ? $slice->all : $slice);
 914 }
 915
 916 =head2 next
 917
 918 =over 4
 919
 920 =item Arguments: none
 921
 922 =item Return Value: $result?
 923
 924 =back
 925
 926 Returns the next element in the resultset (C<undef> is there is none).
 927
 928 Can be used to efficiently iterate over records in the resultset:
 929
 930   my $rs = $schema->resultset('CD')->search;
 931   while (my $cd = $rs->next) {
 932     print $cd->title;
 933   }
 934
 935 Note that you need to store the resultset object, and call C<next> on it.
 936 Calling C<< resultset('Table')->next >> repeatedly will always return the
 937 first record from the resultset.
 938
 939 =cut
 940
 941 sub next {
 942   my ($self) = @_;
 943   if (my $cache = $self->get_cache) {
 944     $self->{all_cache_position} ||= 0;
 945     return $cache->[$self->{all_cache_position}++];
 946   }
 947   if ($self->{attrs}{cache}) {
 948     $self->{all_cache_position} = 1;
 949     return ($self->all)[0];
 950   }
 951   if ($self->{stashed_objects}) {
 952     my $obj = shift(@{$self->{stashed_objects}});
 953     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 954     return $obj;
 955   }
 956   my @row = (
 957     exists $self->{stashed_row}
 958       ? @{delete $self->{stashed_row}}
 959       : $self->cursor->next
 960   );
 961   return undef unless (@row);
 962   my ($row, @more) = $self->_construct_object(@row);
 963   $self->{stashed_objects} = \@more if @more;
 964   return $row;
 965 }
 966
 967 sub _construct_object {
 968   my ($self, @row) = @_;
 969   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 970   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 971   @new = $self->{_attrs}{record_filter}->(@new)
 972     if exists $self->{_attrs}{record_filter};
 973   return @new;
 974 }
 975
 976 sub _collapse_result {
 977   my ($self, $as_proto, $row) = @_;
 978
 979   my @copy = @$row;
 980
 981   # 'foo'         => [ undef, 'foo' ]
 982   # 'foo.bar'     => [ 'foo', 'bar' ]
 983   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 984
 985   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 986
 987   my %collapse = %{$self->{_attrs}{collapse}||{}};
 988
 989   my @pri_index;
 990
 991   # if we're doing collapsing (has_many prefetch) we need to grab records
 992   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 993   # we know we don't have to bother.
 994
 995   # the reason for not using the collapse stuff directly is because if you
 996   # had for e.g. two artists in a row with no cds, the collapse info for
 997   # both would be NULL (undef) so you'd lose the second artist
 998
 999   # store just the index so we can check the array positions from the row
1000   # without having to contruct the full hash
1001
1002   if (keys %collapse) {
1003     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1004     foreach my $i (0 .. $#construct_as) {
1005       next if defined($construct_as[$i][0]); # only self table
1006       if (delete $pri{$construct_as[$i][1]}) {
1007         push(@pri_index, $i);
1008       }
1009       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1010     }
1011   }
1012
1013   # no need to do an if, it'll be empty if @pri_index is empty anyway
1014
1015   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1016
1017   my @const_rows;
1018
1019   do { # no need to check anything at the front, we always want the first row
1020
1021     my %const;
1022
1023     foreach my $this_as (@construct_as) {
1024       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1025     }
1026
1027     push(@const_rows, \%const);
1028
1029   } until ( # no pri_index => no collapse => drop straight out
1030       !@pri_index
1031     or
1032       do { # get another row, stash it, drop out if different PK
1033
1034         @copy = $self->cursor->next;
1035         $self->{stashed_row} = \@copy;
1036
1037         # last thing in do block, counts as true if anything doesn't match
1038
1039         # check xor defined first for NULL vs. NOT NULL then if one is
1040         # defined the other must be so check string equality
1041
1042         grep {
1043           (defined $pri_vals{$_} ^ defined $copy[$_])
1044           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1045         } @pri_index;
1046       }
1047   );
1048
1049   my $alias = $self->{attrs}{alias};
1050   my $info = [];
1051
1052   my %collapse_pos;
1053
1054   my @const_keys;
1055
1056   foreach my $const (@const_rows) {
1057     scalar @const_keys or do {
1058       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1059     };
1060     foreach my $key (@const_keys) {
1061       if (length $key) {
1062         my $target = $info;
1063         my @parts = split(/\./, $key);
1064         my $cur = '';
1065         my $data = $const->{$key};
1066         foreach my $p (@parts) {
1067           $target = $target->[1]->{$p} ||= [];
1068           $cur .= ".${p}";
1069           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1070             # collapsing at this point and on final part
1071             my $pos = $collapse_pos{$cur};
1072             CK: foreach my $ck (@ckey) {
1073               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1074                 $collapse_pos{$cur} = $data;
1075                 delete @collapse_pos{ # clear all positioning for sub-entries
1076                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1077                 };
1078                 push(@$target, []);
1079                 last CK;
1080               }
1081             }
1082           }
1083           if (exists $collapse{$cur}) {
1084             $target = $target->[-1];
1085           }
1086         }
1087         $target->[0] = $data;
1088       } else {
1089         $info->[0] = $const->{$key};
1090       }
1091     }
1092   }
1093
1094   return $info;
1095 }
1096
1097 =head2 result_source
1098
1099 =over 4
1100
1101 =item Arguments: $result_source?
1102
1103 =item Return Value: $result_source
1104
1105 =back
1106
1107 An accessor for the primary ResultSource object from which this ResultSet
1108 is derived.
1109
1110 =head2 result_class
1111
1112 =over 4
1113
1114 =item Arguments: $result_class?
1115
1116 =item Return Value: $result_class
1117
1118 =back
1119
1120 An accessor for the class to use when creating row objects. Defaults to
1121 C<< result_source->result_class >> - which in most cases is the name of the
1122 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1123
1124 Note that changing the result_class will also remove any components
1125 that were originally loaded in the source class via
1126 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1127 in the original source class will not run.
1128
1129 =cut
1130
1131 sub result_class {
1132   my ($self, $result_class) = @_;
1133   if ($result_class) {
1134     $self->ensure_class_loaded($result_class);
1135     $self->_result_class($result_class);
1136   }
1137   $self->_result_class;
1138 }
1139
1140 =head2 count
1141
1142 =over 4
1143
1144 =item Arguments: $cond, \%attrs??
1145
1146 =item Return Value: $count
1147
1148 =back
1149
1150 Performs an SQL C<COUNT> with the same query as the resultset was built
1151 with to find the number of elements. If passed arguments, does a search
1152 on the resultset and counts the results of that.
1153
1154 =cut
1155
1156 sub count {
1157   my $self = shift;
1158   return $self->search(@_)->count if @_ and defined $_[0];
1159   return scalar @{ $self->get_cache } if $self->get_cache;
1160   my $count = $self->_count;
1161   return 0 unless $count;
1162
1163   # need to take offset from resolved attrs
1164
1165   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1166   $count = $self->{attrs}{rows} if
1167     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1168   $count = 0 if ($count < 0);
1169   return $count;
1170 }
1171
1172 sub _count { # Separated out so pager can get the full count
1173   my $self = shift;
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   if (my $group_by = $attrs->{group_by}) {
1177     delete $attrs->{order_by};
1178
1179     $attrs->{select} = $group_by;
1180     $attrs->{from} = [ { 'mesub' => (ref $self)->new($self->result_source, $attrs)->cursor->as_query } ];
1181     delete $attrs->{where};
1182   }
1183
1184   $attrs->{select} = { count => '*' };
1185   $attrs->{as} = [qw/count/];
1186
1187   # offset, order by, group by, where and page are not needed to count. record_filter is cdbi
1188   delete $attrs->{$_} for qw/rows offset order_by group_by page pager record_filter/;
1189
1190   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1191   my ($count) = $tmp_rs->cursor->next;
1192   return $count;
1193 }
1194
1195 sub _bool {
1196   return 1;
1197 }
1198
1199 =head2 count_literal
1200
1201 =over 4
1202
1203 =item Arguments: $sql_fragment, @bind_values
1204
1205 =item Return Value: $count
1206
1207 =back
1208
1209 Counts the results in a literal query. Equivalent to calling L</search_literal>
1210 with the passed arguments, then L</count>.
1211
1212 =cut
1213
1214 sub count_literal { shift->search_literal(@_)->count; }
1215
1216 =head2 all
1217
1218 =over 4
1219
1220 =item Arguments: none
1221
1222 =item Return Value: @objects
1223
1224 =back
1225
1226 Returns all elements in the resultset. Called implicitly if the resultset
1227 is returned in list context.
1228
1229 =cut
1230
1231 sub all {
1232   my $self = shift;
1233   if(@_) {
1234       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1235   }
1236
1237   return @{ $self->get_cache } if $self->get_cache;
1238
1239   my @obj;
1240
1241   # TODO: don't call resolve here
1242   if (keys %{$self->_resolved_attrs->{collapse}}) {
1243 #  if ($self->{attrs}{prefetch}) {
1244       # Using $self->cursor->all is really just an optimisation.
1245       # If we're collapsing has_many prefetches it probably makes
1246       # very little difference, and this is cleaner than hacking
1247       # _construct_object to survive the approach
1248     my @row = $self->cursor->next;
1249     while (@row) {
1250       push(@obj, $self->_construct_object(@row));
1251       @row = (exists $self->{stashed_row}
1252                ? @{delete $self->{stashed_row}}
1253                : $self->cursor->next);
1254     }
1255   } else {
1256     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1257   }
1258
1259   $self->set_cache(\@obj) if $self->{attrs}{cache};
1260   return @obj;
1261 }
1262
1263 =head2 reset
1264
1265 =over 4
1266
1267 =item Arguments: none
1268
1269 =item Return Value: $self
1270
1271 =back
1272
1273 Resets the resultset's cursor, so you can iterate through the elements again.
1274
1275 =cut
1276
1277 sub reset {
1278   my ($self) = @_;
1279   delete $self->{_attrs} if exists $self->{_attrs};
1280   $self->{all_cache_position} = 0;
1281   $self->cursor->reset;
1282   return $self;
1283 }
1284
1285 =head2 first
1286
1287 =over 4
1288
1289 =item Arguments: none
1290
1291 =item Return Value: $object?
1292
1293 =back
1294
1295 Resets the resultset and returns an object for the first result (if the
1296 resultset returns anything).
1297
1298 =cut
1299
1300 sub first {
1301   return $_[0]->reset->next;
1302 }
1303
1304 # _cond_for_update_delete
1305 #
1306 # update/delete require the condition to be modified to handle
1307 # the differing SQL syntax available.  This transforms the $self->{cond}
1308 # appropriately, returning the new condition.
1309
1310 sub _cond_for_update_delete {
1311   my ($self, $full_cond) = @_;
1312   my $cond = {};
1313
1314   $full_cond ||= $self->{cond};
1315   # No-op. No condition, we're updating/deleting everything
1316   return $cond unless ref $full_cond;
1317
1318   foreach my $pk ($self->result_source->primary_columns) {
1319       $cond->{$pk} = { -in => $self->get_column($pk)->as_query };
1320   }
1321
1322   return $cond;
1323 }
1324
1325
1326 =head2 update
1327
1328 =over 4
1329
1330 =item Arguments: \%values
1331
1332 =item Return Value: $storage_rv
1333
1334 =back
1335
1336 Sets the specified columns in the resultset to the supplied values in a
1337 single query. Return value will be true if the update succeeded or false
1338 if no records were updated; exact type of success value is storage-dependent.
1339
1340 =cut
1341
1342 sub update {
1343   my ($self, $values) = @_;
1344   $self->throw_exception("Values for update must be a hash")
1345     unless ref $values eq 'HASH';
1346
1347   my $cond = $self->_cond_for_update_delete;
1348
1349   return $self->result_source->storage->update(
1350     $self->result_source, $values, $cond
1351   );
1352 }
1353
1354 =head2 update_all
1355
1356 =over 4
1357
1358 =item Arguments: \%values
1359
1360 =item Return Value: 1
1361
1362 =back
1363
1364 Fetches all objects and updates them one at a time. Note that C<update_all>
1365 will run DBIC cascade triggers, while L</update> will not.
1366
1367 =cut
1368
1369 sub update_all {
1370   my ($self, $values) = @_;
1371   $self->throw_exception("Values for update must be a hash")
1372     unless ref $values eq 'HASH';
1373   foreach my $obj ($self->all) {
1374     $obj->set_columns($values)->update;
1375   }
1376   return 1;
1377 }
1378
1379 =head2 delete
1380
1381 =over 4
1382
1383 =item Arguments: none
1384
1385 =item Return Value: 1
1386
1387 =back
1388
1389 Deletes the contents of the resultset from its result source. Note that this
1390 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1391 to run. See also L<DBIx::Class::Row/delete>.
1392
1393 delete may not generate correct SQL for a query with joins or a resultset
1394 chained from a related resultset.  In this case it will generate a warning:-
1395
1396 In these cases you may find that delete_all is more appropriate, or you
1397 need to respecify your query in a way that can be expressed without a join.
1398
1399 =cut
1400
1401 sub delete {
1402   my ($self) = @_;
1403   $self->throw_exception("Delete should not be passed any arguments")
1404     if $_[1];
1405
1406   my $cond = $self->_cond_for_update_delete;
1407
1408   $self->result_source->storage->delete($self->result_source, $cond);
1409   return 1;
1410 }
1411
1412 =head2 delete_all
1413
1414 =over 4
1415
1416 =item Arguments: none
1417
1418 =item Return Value: 1
1419
1420 =back
1421
1422 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1423 will run DBIC cascade triggers, while L</delete> will not.
1424
1425 =cut
1426
1427 sub delete_all {
1428   my ($self) = @_;
1429   $_->delete for $self->all;
1430   return 1;
1431 }
1432
1433 =head2 populate
1434
1435 =over 4
1436
1437 =item Arguments: \@data;
1438
1439 =back
1440
1441 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1442 For the arrayref of hashrefs style each hashref should be a structure suitable
1443 forsubmitting to a $resultset->create(...) method.
1444
1445 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1446 to insert the data, as this is a faster method.
1447
1448 Otherwise, each set of data is inserted into the database using
1449 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1450 objects is returned.
1451
1452 Example:  Assuming an Artist Class that has many CDs Classes relating:
1453
1454   my $Artist_rs = $schema->resultset("Artist");
1455
1456   ## Void Context Example
1457   $Artist_rs->populate([
1458      { artistid => 4, name => 'Manufactured Crap', cds => [
1459         { title => 'My First CD', year => 2006 },
1460         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1461       ],
1462      },
1463      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1464         { title => 'My parents sold me to a record company' ,year => 2005 },
1465         { title => 'Why Am I So Ugly?', year => 2006 },
1466         { title => 'I Got Surgery and am now Popular', year => 2007 }
1467       ],
1468      },
1469   ]);
1470
1471   ## Array Context Example
1472   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1473     { name => "Artist One"},
1474     { name => "Artist Two"},
1475     { name => "Artist Three", cds=> [
1476     { title => "First CD", year => 2007},
1477     { title => "Second CD", year => 2008},
1478   ]}
1479   ]);
1480
1481   print $ArtistOne->name; ## response is 'Artist One'
1482   print $ArtistThree->cds->count ## reponse is '2'
1483
1484 For the arrayref of arrayrefs style,  the first element should be a list of the
1485 fieldsnames to which the remaining elements are rows being inserted.  For
1486 example:
1487
1488   $Arstist_rs->populate([
1489     [qw/artistid name/],
1490     [100, 'A Formally Unknown Singer'],
1491     [101, 'A singer that jumped the shark two albums ago'],
1492     [102, 'An actually cool singer.'],
1493   ]);
1494
1495 Please note an important effect on your data when choosing between void and
1496 wantarray context. Since void context goes straight to C<insert_bulk> in
1497 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1498 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1499 create primary keys for you, you will find that your PKs are empty.  In this
1500 case you will have to use the wantarray context in order to create those
1501 values.
1502
1503 =cut
1504
1505 sub populate {
1506   my $self = shift @_;
1507   my $data = ref $_[0][0] eq 'HASH'
1508     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1509     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1510
1511   if(defined wantarray) {
1512     my @created;
1513     foreach my $item (@$data) {
1514       push(@created, $self->create($item));
1515     }
1516     return @created;
1517   } else {
1518     my ($first, @rest) = @$data;
1519
1520     my @names = grep {!ref $first->{$_}} keys %$first;
1521     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1522     my @pks = $self->result_source->primary_columns;
1523
1524     ## do the belongs_to relationships
1525     foreach my $index (0..$#$data) {
1526       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1527         my @ret = $self->populate($data);
1528         return;
1529       }
1530
1531       foreach my $rel (@rels) {
1532         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1533         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1534         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1535         my $related = $result->result_source->resolve_condition(
1536           $result->result_source->relationship_info($reverse)->{cond},
1537           $self,
1538           $result,
1539         );
1540
1541         delete $data->[$index]->{$rel};
1542         $data->[$index] = {%{$data->[$index]}, %$related};
1543
1544         push @names, keys %$related if $index == 0;
1545       }
1546     }
1547
1548     ## do bulk insert on current row
1549     my @values = map { [ @$_{@names} ] } @$data;
1550
1551     $self->result_source->storage->insert_bulk(
1552       $self->result_source,
1553       \@names,
1554       \@values,
1555     );
1556
1557     ## do the has_many relationships
1558     foreach my $item (@$data) {
1559
1560       foreach my $rel (@rels) {
1561         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1562
1563         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1564      || $self->throw_exception('Cannot find the relating object.');
1565
1566         my $child = $parent->$rel;
1567
1568         my $related = $child->result_source->resolve_condition(
1569           $parent->result_source->relationship_info($rel)->{cond},
1570           $child,
1571           $parent,
1572         );
1573
1574         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1575         my @populate = map { {%$_, %$related} } @rows_to_add;
1576
1577         $child->populate( \@populate );
1578       }
1579     }
1580   }
1581 }
1582
1583 =head2 _normalize_populate_args ($args)
1584
1585 Private method used by L</populate> to normalize its incoming arguments.  Factored
1586 out in case you want to subclass and accept new argument structures to the
1587 L</populate> method.
1588
1589 =cut
1590
1591 sub _normalize_populate_args {
1592   my ($self, $data) = @_;
1593   my @names = @{shift(@$data)};
1594   my @results_to_create;
1595   foreach my $datum (@$data) {
1596     my %result_to_create;
1597     foreach my $index (0..$#names) {
1598       $result_to_create{$names[$index]} = $$datum[$index];
1599     }
1600     push @results_to_create, \%result_to_create;
1601   }
1602   return \@results_to_create;
1603 }
1604
1605 =head2 pager
1606
1607 =over 4
1608
1609 =item Arguments: none
1610
1611 =item Return Value: $pager
1612
1613 =back
1614
1615 Return Value a L<Data::Page> object for the current resultset. Only makes
1616 sense for queries with a C<page> attribute.
1617
1618 To get the full count of entries for a paged resultset, call
1619 C<total_entries> on the L<Data::Page> object.
1620
1621 =cut
1622
1623 sub pager {
1624   my ($self) = @_;
1625   my $attrs = $self->{attrs};
1626   $self->throw_exception("Can't create pager for non-paged rs")
1627     unless $self->{attrs}{page};
1628   $attrs->{rows} ||= 10;
1629   return $self->{pager} ||= Data::Page->new(
1630     $self->_count, $attrs->{rows}, $self->{attrs}{page});
1631 }
1632
1633 =head2 page
1634
1635 =over 4
1636
1637 =item Arguments: $page_number
1638
1639 =item Return Value: $rs
1640
1641 =back
1642
1643 Returns a resultset for the $page_number page of the resultset on which page
1644 is called, where each page contains a number of rows equal to the 'rows'
1645 attribute set on the resultset (10 by default).
1646
1647 =cut
1648
1649 sub page {
1650   my ($self, $page) = @_;
1651   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1652 }
1653
1654 =head2 new_result
1655
1656 =over 4
1657
1658 =item Arguments: \%vals
1659
1660 =item Return Value: $rowobject
1661
1662 =back
1663
1664 Creates a new row object in the resultset's result class and returns
1665 it. The row is not inserted into the database at this point, call
1666 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1667 will tell you whether the row object has been inserted or not.
1668
1669 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1670
1671 =cut
1672
1673 sub new_result {
1674   my ($self, $values) = @_;
1675   $self->throw_exception( "new_result needs a hash" )
1676     unless (ref $values eq 'HASH');
1677
1678   my %new;
1679   my $alias = $self->{attrs}{alias};
1680
1681   if (
1682     defined $self->{cond}
1683     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1684   ) {
1685     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1686     $new{-from_resultset} = [ keys %new ] if keys %new;
1687   } else {
1688     $self->throw_exception(
1689       "Can't abstract implicit construct, condition not a hash"
1690     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1691
1692     my $collapsed_cond = (
1693       $self->{cond}
1694         ? $self->_collapse_cond($self->{cond})
1695         : {}
1696     );
1697
1698     # precendence must be given to passed values over values inherited from
1699     # the cond, so the order here is important.
1700     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1701     while( my($col,$value) = each %implied ){
1702       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1703         $new{$col} = $value->{'='};
1704         next;
1705       }
1706       $new{$col} = $value if $self->_is_deterministic_value($value);
1707     }
1708   }
1709
1710   %new = (
1711     %new,
1712     %{ $self->_remove_alias($values, $alias) },
1713     -source_handle => $self->_source_handle,
1714     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1715   );
1716
1717   return $self->result_class->new(\%new);
1718 }
1719
1720 # _is_deterministic_value
1721 #
1722 # Make an effor to strip non-deterministic values from the condition,
1723 # to make sure new_result chokes less
1724
1725 sub _is_deterministic_value {
1726   my $self = shift;
1727   my $value = shift;
1728   my $ref_type = ref $value;
1729   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1730   return 1 if Scalar::Util::blessed($value);
1731   return 0;
1732 }
1733
1734 # _collapse_cond
1735 #
1736 # Recursively collapse the condition.
1737
1738 sub _collapse_cond {
1739   my ($self, $cond, $collapsed) = @_;
1740
1741   $collapsed ||= {};
1742
1743   if (ref $cond eq 'ARRAY') {
1744     foreach my $subcond (@$cond) {
1745       next unless ref $subcond;  # -or
1746 #      warn "ARRAY: " . Dumper $subcond;
1747       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1748     }
1749   }
1750   elsif (ref $cond eq 'HASH') {
1751     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1752       foreach my $subcond (@{$cond->{-and}}) {
1753 #        warn "HASH: " . Dumper $subcond;
1754         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1755       }
1756     }
1757     else {
1758 #      warn "LEAF: " . Dumper $cond;
1759       foreach my $col (keys %$cond) {
1760         my $value = $cond->{$col};
1761         $collapsed->{$col} = $value;
1762       }
1763     }
1764   }
1765
1766   return $collapsed;
1767 }
1768
1769 # _remove_alias
1770 #
1771 # Remove the specified alias from the specified query hash. A copy is made so
1772 # the original query is not modified.
1773
1774 sub _remove_alias {
1775   my ($self, $query, $alias) = @_;
1776
1777   my %orig = %{ $query || {} };
1778   my %unaliased;
1779
1780   foreach my $key (keys %orig) {
1781     if ($key !~ /\./) {
1782       $unaliased{$key} = $orig{$key};
1783       next;
1784     }
1785     $unaliased{$1} = $orig{$key}
1786       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1787   }
1788
1789   return \%unaliased;
1790 }
1791
1792 =head2 as_query (EXPERIMENTAL)
1793
1794 =over 4
1795
1796 =item Arguments: none
1797
1798 =item Return Value: \[ $sql, @bind ]
1799
1800 =back
1801
1802 Returns the SQL query and bind vars associated with the invocant.
1803
1804 This is generally used as the RHS for a subquery.
1805
1806 B<NOTE>: This feature is still experimental.
1807
1808 =cut
1809
1810 sub as_query { return shift->cursor->as_query(@_) }
1811
1812 =head2 find_or_new
1813
1814 =over 4
1815
1816 =item Arguments: \%vals, \%attrs?
1817
1818 =item Return Value: $rowobject
1819
1820 =back
1821
1822   my $artist = $schema->resultset('Artist')->find_or_new(
1823     { artist => 'fred' }, { key => 'artists' });
1824
1825   $cd->cd_to_producer->find_or_new({ producer => $producer },
1826                                    { key => 'primary });
1827
1828 Find an existing record from this resultset, based on its primary
1829 key, or a unique constraint. If none exists, instantiate a new result
1830 object and return it. The object will not be saved into your storage
1831 until you call L<DBIx::Class::Row/insert> on it.
1832
1833 You most likely want this method when looking for existing rows using
1834 a unique constraint that is not the primary key, or looking for
1835 related rows.
1836
1837 If you want objects to be saved immediately, use L</find_or_create> instead.
1838
1839 B<Note>: C<find_or_new> is probably not what you want when creating a
1840 new row in a table that uses primary keys supplied by the
1841 database. Passing in a primary key column with a value of I<undef>
1842 will cause L</find> to attempt to search for a row with a value of
1843 I<NULL>.
1844
1845 =cut
1846
1847 sub find_or_new {
1848   my $self     = shift;
1849   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1850   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1851   my $exists   = $self->find($hash, $attrs);
1852   return defined $exists ? $exists : $self->new_result($hash);
1853 }
1854
1855 =head2 create
1856
1857 =over 4
1858
1859 =item Arguments: \%vals
1860
1861 =item Return Value: a L<DBIx::Class::Row> $object
1862
1863 =back
1864
1865 Attempt to create a single new row or a row with multiple related rows
1866 in the table represented by the resultset (and related tables). This
1867 will not check for duplicate rows before inserting, use
1868 L</find_or_create> to do that.
1869
1870 To create one row for this resultset, pass a hashref of key/value
1871 pairs representing the columns of the table and the values you wish to
1872 store. If the appropriate relationships are set up, foreign key fields
1873 can also be passed an object representing the foreign row, and the
1874 value will be set to its primary key.
1875
1876 To create related objects, pass a hashref for the value if the related
1877 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1878 and use the name of the relationship as the key. (NOT the name of the field,
1879 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1880 of hashrefs containing the data for each of the rows to create in the foreign
1881 tables, again using the relationship name as the key.
1882
1883 Instead of hashrefs of plain related data (key/value pairs), you may
1884 also pass new or inserted objects. New objects (not inserted yet, see
1885 L</new>), will be inserted into their appropriate tables.
1886
1887 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1888
1889 Example of creating a new row.
1890
1891   $person_rs->create({
1892     name=>"Some Person",
1893     email=>"somebody@someplace.com"
1894   });
1895
1896 Example of creating a new row and also creating rows in a related C<has_many>
1897 or C<has_one> resultset.  Note Arrayref.
1898
1899   $artist_rs->create(
1900      { artistid => 4, name => 'Manufactured Crap', cds => [
1901         { title => 'My First CD', year => 2006 },
1902         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1903       ],
1904      },
1905   );
1906
1907 Example of creating a new row and also creating a row in a related
1908 C<belongs_to>resultset. Note Hashref.
1909
1910   $cd_rs->create({
1911     title=>"Music for Silly Walks",
1912     year=>2000,
1913     artist => {
1914       name=>"Silly Musician",
1915     }
1916   });
1917
1918 =cut
1919
1920 sub create {
1921   my ($self, $attrs) = @_;
1922   $self->throw_exception( "create needs a hashref" )
1923     unless ref $attrs eq 'HASH';
1924   return $self->new_result($attrs)->insert;
1925 }
1926
1927 =head2 find_or_create
1928
1929 =over 4
1930
1931 =item Arguments: \%vals, \%attrs?
1932
1933 =item Return Value: $rowobject
1934
1935 =back
1936
1937   $cd->cd_to_producer->find_or_create({ producer => $producer },
1938                                       { key => 'primary });
1939
1940 Tries to find a record based on its primary key or unique constraints; if none
1941 is found, creates one and returns that instead.
1942
1943   my $cd = $schema->resultset('CD')->find_or_create({
1944     cdid   => 5,
1945     artist => 'Massive Attack',
1946     title  => 'Mezzanine',
1947     year   => 2005,
1948   });
1949
1950 Also takes an optional C<key> attribute, to search by a specific key or unique
1951 constraint. For example:
1952
1953   my $cd = $schema->resultset('CD')->find_or_create(
1954     {
1955       artist => 'Massive Attack',
1956       title  => 'Mezzanine',
1957     },
1958     { key => 'cd_artist_title' }
1959   );
1960
1961 B<Note>: Because find_or_create() reads from the database and then
1962 possibly inserts based on the result, this method is subject to a race
1963 condition. Another process could create a record in the table after
1964 the find has completed and before the create has started. To avoid
1965 this problem, use find_or_create() inside a transaction.
1966
1967 B<Note>: C<find_or_create> is probably not what you want when creating
1968 a new row in a table that uses primary keys supplied by the
1969 database. Passing in a primary key column with a value of I<undef>
1970 will cause L</find> to attempt to search for a row with a value of
1971 I<NULL>.
1972
1973 See also L</find> and L</update_or_create>. For information on how to declare
1974 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
1975
1976 =cut
1977
1978 sub find_or_create {
1979   my $self     = shift;
1980   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1981   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1982   my $exists   = $self->find($hash, $attrs);
1983   return defined $exists ? $exists : $self->create($hash);
1984 }
1985
1986 =head2 update_or_create
1987
1988 =over 4
1989
1990 =item Arguments: \%col_values, { key => $unique_constraint }?
1991
1992 =item Return Value: $rowobject
1993
1994 =back
1995
1996   $resultset->update_or_create({ col => $val, ... });
1997
1998 First, searches for an existing row matching one of the unique constraints
1999 (including the primary key) on the source of this resultset. If a row is
2000 found, updates it with the other given column values. Otherwise, creates a new
2001 row.
2002
2003 Takes an optional C<key> attribute to search on a specific unique constraint.
2004 For example:
2005
2006   # In your application
2007   my $cd = $schema->resultset('CD')->update_or_create(
2008     {
2009       artist => 'Massive Attack',
2010       title  => 'Mezzanine',
2011       year   => 1998,
2012     },
2013     { key => 'cd_artist_title' }
2014   );
2015
2016   $cd->cd_to_producer->update_or_create({
2017     producer => $producer,
2018     name => 'harry',
2019   }, {
2020     key => 'primary,
2021   });
2022
2023
2024 If no C<key> is specified, it searches on all unique constraints defined on the
2025 source, including the primary key.
2026
2027 If the C<key> is specified as C<primary>, it searches only on the primary key.
2028
2029 See also L</find> and L</find_or_create>. For information on how to declare
2030 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2031
2032 B<Note>: C<update_or_create> is probably not what you want when
2033 looking for a row in a table that uses primary keys supplied by the
2034 database, unless you actually have a key value. Passing in a primary
2035 key column with a value of I<undef> will cause L</find> to attempt to
2036 search for a row with a value of I<NULL>.
2037
2038 =cut
2039
2040 sub update_or_create {
2041   my $self = shift;
2042   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2043   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2044
2045   my $row = $self->find($cond, $attrs);
2046   if (defined $row) {
2047     $row->update($cond);
2048     return $row;
2049   }
2050
2051   return $self->create($cond);
2052 }
2053
2054 =head2 update_or_new
2055
2056 =over 4
2057
2058 =item Arguments: \%col_values, { key => $unique_constraint }?
2059
2060 =item Return Value: $rowobject
2061
2062 =back
2063
2064   $resultset->update_or_new({ col => $val, ... });
2065
2066 First, searches for an existing row matching one of the unique constraints
2067 (including the primary key) on the source of this resultset. If a row is
2068 found, updates it with the other given column values. Otherwise, instantiate
2069 a new result object and return it. The object will not be saved into your storage
2070 until you call L<DBIx::Class::Row/insert> on it.
2071
2072 Takes an optional C<key> attribute to search on a specific unique constraint.
2073 For example:
2074
2075   # In your application
2076   my $cd = $schema->resultset('CD')->update_or_new(
2077     {
2078       artist => 'Massive Attack',
2079       title  => 'Mezzanine',
2080       year   => 1998,
2081     },
2082     { key => 'cd_artist_title' }
2083   );
2084
2085   if ($cd->in_storage) {
2086       # the cd was updated
2087   }
2088   else {
2089       # the cd is not yet in the database, let's insert it
2090       $cd->insert;
2091   }
2092
2093 See also L</find>, L</find_or_create> and L<find_or_new>.
2094
2095 =cut
2096
2097 sub update_or_new {
2098     my $self  = shift;
2099     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2100     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2101
2102     my $row = $self->find( $cond, $attrs );
2103     if ( defined $row ) {
2104         $row->update($cond);
2105         return $row;
2106     }
2107
2108     return $self->new_result($cond);
2109 }
2110
2111 =head2 get_cache
2112
2113 =over 4
2114
2115 =item Arguments: none
2116
2117 =item Return Value: \@cache_objects?
2118
2119 =back
2120
2121 Gets the contents of the cache for the resultset, if the cache is set.
2122
2123 The cache is populated either by using the L</prefetch> attribute to
2124 L</search> or by calling L</set_cache>.
2125
2126 =cut
2127
2128 sub get_cache {
2129   shift->{all_cache};
2130 }
2131
2132 =head2 set_cache
2133
2134 =over 4
2135
2136 =item Arguments: \@cache_objects
2137
2138 =item Return Value: \@cache_objects
2139
2140 =back
2141
2142 Sets the contents of the cache for the resultset. Expects an arrayref
2143 of objects of the same class as those produced by the resultset. Note that
2144 if the cache is set the resultset will return the cached objects rather
2145 than re-querying the database even if the cache attr is not set.
2146
2147 The contents of the cache can also be populated by using the
2148 L</prefetch> attribute to L</search>.
2149
2150 =cut
2151
2152 sub set_cache {
2153   my ( $self, $data ) = @_;
2154   $self->throw_exception("set_cache requires an arrayref")
2155       if defined($data) && (ref $data ne 'ARRAY');
2156   $self->{all_cache} = $data;
2157 }
2158
2159 =head2 clear_cache
2160
2161 =over 4
2162
2163 =item Arguments: none
2164
2165 =item Return Value: []
2166
2167 =back
2168
2169 Clears the cache for the resultset.
2170
2171 =cut
2172
2173 sub clear_cache {
2174   shift->set_cache(undef);
2175 }
2176
2177 =head2 related_resultset
2178
2179 =over 4
2180
2181 =item Arguments: $relationship_name
2182
2183 =item Return Value: $resultset
2184
2185 =back
2186
2187 Returns a related resultset for the supplied relationship name.
2188
2189   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2190
2191 =cut
2192
2193 sub related_resultset {
2194   my ($self, $rel) = @_;
2195
2196   $self->{related_resultsets} ||= {};
2197   return $self->{related_resultsets}{$rel} ||= do {
2198     my $rel_obj = $self->result_source->relationship_info($rel);
2199
2200     $self->throw_exception(
2201       "search_related: result source '" . $self->result_source->source_name .
2202         "' has no such relationship $rel")
2203       unless $rel_obj;
2204
2205     my ($from,$seen) = $self->_resolve_from($rel);
2206
2207     my $join_count = $seen->{$rel};
2208     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2209
2210     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2211     my %attrs = %{$self->{attrs}||{}};
2212     delete @attrs{qw(result_class alias)};
2213
2214     my $new_cache;
2215
2216     if (my $cache = $self->get_cache) {
2217       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2218         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2219                         @$cache ];
2220       }
2221     }
2222
2223     my $rel_source = $self->result_source->related_source($rel);
2224
2225     my $new = do {
2226
2227       # The reason we do this now instead of passing the alias to the
2228       # search_rs below is that if you wrap/overload resultset on the
2229       # source you need to know what alias it's -going- to have for things
2230       # to work sanely (e.g. RestrictWithObject wants to be able to add
2231       # extra query restrictions, and these may need to be $alias.)
2232
2233       my $attrs = $rel_source->resultset_attributes;
2234       local $attrs->{alias} = $alias;
2235
2236       $rel_source->resultset
2237                  ->search_rs(
2238                      undef, {
2239                        %attrs,
2240                        join => undef,
2241                        prefetch => undef,
2242                        select => undef,
2243                        as => undef,
2244                        where => $self->{cond},
2245                        seen_join => $seen,
2246                        from => $from,
2247                    });
2248     };
2249     $new->set_cache($new_cache) if $new_cache;
2250     $new;
2251   };
2252 }
2253
2254 =head2 current_source_alias
2255
2256 =over 4
2257
2258 =item Arguments: none
2259
2260 =item Return Value: $source_alias
2261
2262 =back
2263
2264 Returns the current table alias for the result source this resultset is built
2265 on, that will be used in the SQL query. Usually it is C<me>.
2266
2267 Currently the source alias that refers to the result set returned by a
2268 L</search>/L</find> family method depends on how you got to the resultset: it's
2269 C<me> by default, but eg. L</search_related> aliases it to the related result
2270 source name (and keeps C<me> referring to the original result set). The long
2271 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2272 (and make this method unnecessary).
2273
2274 Thus it's currently necessary to use this method in predefined queries (see
2275 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2276 source alias of the current result set:
2277
2278   # in a result set class
2279   sub modified_by {
2280     my ($self, $user) = @_;
2281
2282     my $me = $self->current_source_alias;
2283
2284     return $self->search(
2285       "$me.modified" => $user->id,
2286     );
2287   }
2288
2289 =cut
2290
2291 sub current_source_alias {
2292   my ($self) = @_;
2293
2294   return ($self->{attrs} || {})->{alias} || 'me';
2295 }
2296
2297 sub _resolve_from {
2298   my ($self, $extra_join) = @_;
2299   my $source = $self->result_source;
2300   my $attrs = $self->{attrs};
2301
2302   my $from = $attrs->{from}
2303     || [ { $attrs->{alias} => $source->from } ];
2304
2305   my $seen = { %{$attrs->{seen_join}||{}} };
2306
2307   my $join = ($attrs->{join}
2308                ? [ $attrs->{join}, $extra_join ]
2309                : $extra_join);
2310
2311   # we need to take the prefetch the attrs into account before we
2312   # ->resolve_join as otherwise they get lost - captainL
2313   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2314
2315   $from = [
2316     @$from,
2317     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2318   ];
2319
2320   return ($from,$seen);
2321 }
2322
2323 sub _resolved_attrs {
2324   my $self = shift;
2325   return $self->{_attrs} if $self->{_attrs};
2326
2327   my $attrs  = { %{ $self->{attrs} || {} } };
2328   my $source = $self->result_source;
2329   my $alias  = $attrs->{alias};
2330
2331   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2332   my @colbits;
2333
2334   # build columns (as long as select isn't set) into a set of as/select hashes
2335   unless ( $attrs->{select} ) {
2336       @colbits = map {
2337           ( ref($_) eq 'HASH' )
2338               ? $_
2339               : {
2340                   (
2341                     /^\Q${alias}.\E(.+)$/
2342                       ? "$1"
2343                       : "$_"
2344                   )
2345                 =>
2346                   (
2347                     /\./
2348                       ? "$_"
2349                       : "${alias}.$_"
2350                   )
2351             }
2352       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2353   }
2354   # add the additional columns on
2355   foreach ( 'include_columns', '+columns' ) {
2356       push @colbits, map {
2357           ( ref($_) eq 'HASH' )
2358             ? $_
2359             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2360       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2361   }
2362
2363   # start with initial select items
2364   if ( $attrs->{select} ) {
2365     $attrs->{select} =
2366         ( ref $attrs->{select} eq 'ARRAY' )
2367       ? [ @{ $attrs->{select} } ]
2368       : [ $attrs->{select} ];
2369     $attrs->{as} = (
2370       $attrs->{as}
2371       ? (
2372         ref $attrs->{as} eq 'ARRAY'
2373         ? [ @{ $attrs->{as} } ]
2374         : [ $attrs->{as} ]
2375         )
2376       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2377     );
2378   }
2379   else {
2380
2381     # otherwise we intialise select & as to empty
2382     $attrs->{select} = [];
2383     $attrs->{as}     = [];
2384   }
2385
2386   # now add colbits to select/as
2387   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2388   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2389
2390   my $adds;
2391   if ( $adds = delete $attrs->{'+select'} ) {
2392     $adds = [$adds] unless ref $adds eq 'ARRAY';
2393     push(
2394       @{ $attrs->{select} },
2395       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2396     );
2397   }
2398   if ( $adds = delete $attrs->{'+as'} ) {
2399     $adds = [$adds] unless ref $adds eq 'ARRAY';
2400     push( @{ $attrs->{as} }, @$adds );
2401   }
2402
2403   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2404
2405   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2406     my $join = delete $attrs->{join} || {};
2407
2408     if ( defined $attrs->{prefetch} ) {
2409       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2410
2411     }
2412
2413     $attrs->{from} =    # have to copy here to avoid corrupting the original
2414       [
2415       @{ $attrs->{from} },
2416       $source->resolve_join(
2417         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2418       )
2419       ];
2420
2421   }
2422
2423   $attrs->{group_by} ||= $attrs->{select}
2424     if delete $attrs->{distinct};
2425   if ( $attrs->{order_by} ) {
2426     $attrs->{order_by} = (
2427       ref( $attrs->{order_by} ) eq 'ARRAY'
2428       ? [ @{ $attrs->{order_by} } ]
2429       : [ $attrs->{order_by} ]
2430     );
2431   }
2432   else {
2433     $attrs->{order_by} = [];
2434   }
2435
2436   my $collapse = $attrs->{collapse} || {};
2437   if ( my $prefetch = delete $attrs->{prefetch} ) {
2438     $prefetch = $self->_merge_attr( {}, $prefetch );
2439     my @pre_order;
2440     my $seen = { %{ $attrs->{seen_join} || {} } };
2441     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2442
2443       # bring joins back to level of current class
2444       my @prefetch =
2445         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2446       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2447       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2448     }
2449     push( @{ $attrs->{order_by} }, @pre_order );
2450   }
2451   $attrs->{collapse} = $collapse;
2452
2453   if ( $attrs->{page} ) {
2454     $attrs->{offset} ||= 0;
2455     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2456   }
2457
2458   return $self->{_attrs} = $attrs;
2459 }
2460
2461 sub _rollout_attr {
2462   my ($self, $attr) = @_;
2463
2464   if (ref $attr eq 'HASH') {
2465     return $self->_rollout_hash($attr);
2466   } elsif (ref $attr eq 'ARRAY') {
2467     return $self->_rollout_array($attr);
2468   } else {
2469     return [$attr];
2470   }
2471 }
2472
2473 sub _rollout_array {
2474   my ($self, $attr) = @_;
2475
2476   my @rolled_array;
2477   foreach my $element (@{$attr}) {
2478     if (ref $element eq 'HASH') {
2479       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2480     } elsif (ref $element eq 'ARRAY') {
2481       #  XXX - should probably recurse here
2482       push( @rolled_array, @{$self->_rollout_array($element)} );
2483     } else {
2484       push( @rolled_array, $element );
2485     }
2486   }
2487   return \@rolled_array;
2488 }
2489
2490 sub _rollout_hash {
2491   my ($self, $attr) = @_;
2492
2493   my @rolled_array;
2494   foreach my $key (keys %{$attr}) {
2495     push( @rolled_array, { $key => $attr->{$key} } );
2496   }
2497   return \@rolled_array;
2498 }
2499
2500 sub _calculate_score {
2501   my ($self, $a, $b) = @_;
2502
2503   if (ref $b eq 'HASH') {
2504     my ($b_key) = keys %{$b};
2505     if (ref $a eq 'HASH') {
2506       my ($a_key) = keys %{$a};
2507       if ($a_key eq $b_key) {
2508         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2509       } else {
2510         return 0;
2511       }
2512     } else {
2513       return ($a eq $b_key) ? 1 : 0;
2514     }
2515   } else {
2516     if (ref $a eq 'HASH') {
2517       my ($a_key) = keys %{$a};
2518       return ($b eq $a_key) ? 1 : 0;
2519     } else {
2520       return ($b eq $a) ? 1 : 0;
2521     }
2522   }
2523 }
2524
2525 sub _merge_attr {
2526   my ($self, $orig, $import) = @_;
2527
2528   return $import unless defined($orig);
2529   return $orig unless defined($import);
2530
2531   $orig = $self->_rollout_attr($orig);
2532   $import = $self->_rollout_attr($import);
2533
2534   my $seen_keys;
2535   foreach my $import_element ( @{$import} ) {
2536     # find best candidate from $orig to merge $b_element into
2537     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2538     foreach my $orig_element ( @{$orig} ) {
2539       my $score = $self->_calculate_score( $orig_element, $import_element );
2540       if ($score > $best_candidate->{score}) {
2541         $best_candidate->{position} = $position;
2542         $best_candidate->{score} = $score;
2543       }
2544       $position++;
2545     }
2546     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2547
2548     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2549       push( @{$orig}, $import_element );
2550     } else {
2551       my $orig_best = $orig->[$best_candidate->{position}];
2552       # merge orig_best and b_element together and replace original with merged
2553       if (ref $orig_best ne 'HASH') {
2554         $orig->[$best_candidate->{position}] = $import_element;
2555       } elsif (ref $import_element eq 'HASH') {
2556         my ($key) = keys %{$orig_best};
2557         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2558       }
2559     }
2560     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2561   }
2562
2563   return $orig;
2564 }
2565
2566 sub result_source {
2567     my $self = shift;
2568
2569     if (@_) {
2570         $self->_source_handle($_[0]->handle);
2571     } else {
2572         $self->_source_handle->resolve;
2573     }
2574 }
2575
2576 =head2 throw_exception
2577
2578 See L<DBIx::Class::Schema/throw_exception> for details.
2579
2580 =cut
2581
2582 sub throw_exception {
2583   my $self=shift;
2584   if (ref $self && $self->_source_handle->schema) {
2585     $self->_source_handle->schema->throw_exception(@_)
2586   } else {
2587     croak(@_);
2588   }
2589
2590 }
2591
2592 # XXX: FIXME: Attributes docs need clearing up
2593
2594 =head1 ATTRIBUTES
2595
2596 Attributes are used to refine a ResultSet in various ways when
2597 searching for data. They can be passed to any method which takes an
2598 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2599 L</count>.
2600
2601 These are in no particular order:
2602
2603 =head2 order_by
2604
2605 =over 4
2606
2607 =item Value: ( $order_by | \@order_by | \%order_by )
2608
2609 =back
2610
2611 Which column(s) to order the results by. If a single column name, or
2612 an arrayref of names is supplied, the argument is passed through
2613 directly to SQL. The hashref syntax allows for connection-agnostic
2614 specification of ordering direction:
2615
2616  For descending order:
2617
2618   order_by => { -desc => [qw/col1 col2 col3/] }
2619
2620  For explicit ascending order:
2621
2622   order_by => { -asc => 'col' }
2623
2624 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2625 supported, although you are strongly encouraged to use the hashref
2626 syntax as outlined above.
2627
2628 =head2 columns
2629
2630 =over 4
2631
2632 =item Value: \@columns
2633
2634 =back
2635
2636 Shortcut to request a particular set of columns to be retrieved. Each
2637 column spec may be a string (a table column name), or a hash (in which
2638 case the key is the C<as> value, and the value is used as the C<select>
2639 expression). Adds C<me.> onto the start of any column without a C<.> in
2640 it and sets C<select> from that, then auto-populates C<as> from
2641 C<select> as normal. (You may also use the C<cols> attribute, as in
2642 earlier versions of DBIC.)
2643
2644 =head2 +columns
2645
2646 =over 4
2647
2648 =item Value: \@columns
2649
2650 =back
2651
2652 Indicates additional columns to be selected from storage. Works the same
2653 as L</columns> but adds columns to the selection. (You may also use the
2654 C<include_columns> attribute, as in earlier versions of DBIC). For
2655 example:-
2656
2657   $schema->resultset('CD')->search(undef, {
2658     '+columns' => ['artist.name'],
2659     join => ['artist']
2660   });
2661
2662 would return all CDs and include a 'name' column to the information
2663 passed to object inflation. Note that the 'artist' is the name of the
2664 column (or relationship) accessor, and 'name' is the name of the column
2665 accessor in the related table.
2666
2667 =head2 include_columns
2668
2669 =over 4
2670
2671 =item Value: \@columns
2672
2673 =back
2674
2675 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2676
2677 =head2 select
2678
2679 =over 4
2680
2681 =item Value: \@select_columns
2682
2683 =back
2684
2685 Indicates which columns should be selected from the storage. You can use
2686 column names, or in the case of RDBMS back ends, function or stored procedure
2687 names:
2688
2689   $rs = $schema->resultset('Employee')->search(undef, {
2690     select => [
2691       'name',
2692       { count => 'employeeid' },
2693       { sum => 'salary' }
2694     ]
2695   });
2696
2697 When you use function/stored procedure names and do not supply an C<as>
2698 attribute, the column names returned are storage-dependent. E.g. MySQL would
2699 return a column named C<count(employeeid)> in the above example.
2700
2701 =head2 +select
2702
2703 =over 4
2704
2705 Indicates additional columns to be selected from storage.  Works the same as
2706 L</select> but adds columns to the selection.
2707
2708 =back
2709
2710 =head2 +as
2711
2712 =over 4
2713
2714 Indicates additional column names for those added via L</+select>. See L</as>.
2715
2716 =back
2717
2718 =head2 as
2719
2720 =over 4
2721
2722 =item Value: \@inflation_names
2723
2724 =back
2725
2726 Indicates column names for object inflation. That is, C<as>
2727 indicates the name that the column can be accessed as via the
2728 C<get_column> method (or via the object accessor, B<if one already
2729 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2730
2731 The C<as> attribute is used in conjunction with C<select>,
2732 usually when C<select> contains one or more function or stored
2733 procedure names:
2734
2735   $rs = $schema->resultset('Employee')->search(undef, {
2736     select => [
2737       'name',
2738       { count => 'employeeid' }
2739     ],
2740     as => ['name', 'employee_count'],
2741   });
2742
2743   my $employee = $rs->first(); # get the first Employee
2744
2745 If the object against which the search is performed already has an accessor
2746 matching a column name specified in C<as>, the value can be retrieved using
2747 the accessor as normal:
2748
2749   my $name = $employee->name();
2750
2751 If on the other hand an accessor does not exist in the object, you need to
2752 use C<get_column> instead:
2753
2754   my $employee_count = $employee->get_column('employee_count');
2755
2756 You can create your own accessors if required - see
2757 L<DBIx::Class::Manual::Cookbook> for details.
2758
2759 Please note: This will NOT insert an C<AS employee_count> into the SQL
2760 statement produced, it is used for internal access only. Thus
2761 attempting to use the accessor in an C<order_by> clause or similar
2762 will fail miserably.
2763
2764 To get around this limitation, you can supply literal SQL to your
2765 C<select> attibute that contains the C<AS alias> text, eg:
2766
2767   select => [\'myfield AS alias']
2768
2769 =head2 join
2770
2771 =over 4
2772
2773 =item Value: ($rel_name | \@rel_names | \%rel_names)
2774
2775 =back
2776
2777 Contains a list of relationships that should be joined for this query.  For
2778 example:
2779
2780   # Get CDs by Nine Inch Nails
2781   my $rs = $schema->resultset('CD')->search(
2782     { 'artist.name' => 'Nine Inch Nails' },
2783     { join => 'artist' }
2784   );
2785
2786 Can also contain a hash reference to refer to the other relation's relations.
2787 For example:
2788
2789   package MyApp::Schema::Track;
2790   use base qw/DBIx::Class/;
2791   __PACKAGE__->table('track');
2792   __PACKAGE__->add_columns(qw/trackid cd position title/);
2793   __PACKAGE__->set_primary_key('trackid');
2794   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2795   1;
2796
2797   # In your application
2798   my $rs = $schema->resultset('Artist')->search(
2799     { 'track.title' => 'Teardrop' },
2800     {
2801       join     => { cd => 'track' },
2802       order_by => 'artist.name',
2803     }
2804   );
2805
2806 You need to use the relationship (not the table) name in  conditions,
2807 because they are aliased as such. The current table is aliased as "me", so
2808 you need to use me.column_name in order to avoid ambiguity. For example:
2809
2810   # Get CDs from 1984 with a 'Foo' track
2811   my $rs = $schema->resultset('CD')->search(
2812     {
2813       'me.year' => 1984,
2814       'tracks.name' => 'Foo'
2815     },
2816     { join => 'tracks' }
2817   );
2818
2819 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2820 similarly for a third time). For e.g.
2821
2822   my $rs = $schema->resultset('Artist')->search({
2823     'cds.title'   => 'Down to Earth',
2824     'cds_2.title' => 'Popular',
2825   }, {
2826     join => [ qw/cds cds/ ],
2827   });
2828
2829 will return a set of all artists that have both a cd with title 'Down
2830 to Earth' and a cd with title 'Popular'.
2831
2832 If you want to fetch related objects from other tables as well, see C<prefetch>
2833 below.
2834
2835 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2836
2837 =head2 prefetch
2838
2839 =over 4
2840
2841 =item Value: ($rel_name | \@rel_names | \%rel_names)
2842
2843 =back
2844
2845 Contains one or more relationships that should be fetched along with
2846 the main query (when they are accessed afterwards the data will
2847 already be available, without extra queries to the database).  This is
2848 useful for when you know you will need the related objects, because it
2849 saves at least one query:
2850
2851   my $rs = $schema->resultset('Tag')->search(
2852     undef,
2853     {
2854       prefetch => {
2855         cd => 'artist'
2856       }
2857     }
2858   );
2859
2860 The initial search results in SQL like the following:
2861
2862   SELECT tag.*, cd.*, artist.* FROM tag
2863   JOIN cd ON tag.cd = cd.cdid
2864   JOIN artist ON cd.artist = artist.artistid
2865
2866 L<DBIx::Class> has no need to go back to the database when we access the
2867 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2868 case.
2869
2870 Simple prefetches will be joined automatically, so there is no need
2871 for a C<join> attribute in the above search.
2872
2873 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2874 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2875 with an accessor type of 'single' or 'filter'). A more complex example that
2876 prefetches an artists cds, the tracks on those cds, and the tags associted
2877 with that artist is given below (assuming many-to-many from artists to tags):
2878
2879  my $rs = $schema->resultset('Artist')->search(
2880    undef,
2881    {
2882      prefetch => [
2883        { cds => 'tracks' },
2884        { artist_tags => 'tags' }
2885      ]
2886    }
2887  );
2888
2889
2890 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2891 attributes will be ignored.
2892
2893 =head2 page
2894
2895 =over 4
2896
2897 =item Value: $page
2898
2899 =back
2900
2901 Makes the resultset paged and specifies the page to retrieve. Effectively
2902 identical to creating a non-pages resultset and then calling ->page($page)
2903 on it.
2904
2905 If L<rows> attribute is not specified it defualts to 10 rows per page.
2906
2907 When you have a paged resultset, L</count> will only return the number
2908 of rows in the page. To get the total, use the L</pager> and call
2909 C<total_entries> on it.
2910
2911 =head2 rows
2912
2913 =over 4
2914
2915 =item Value: $rows
2916
2917 =back
2918
2919 Specifes the maximum number of rows for direct retrieval or the number of
2920 rows per page if the page attribute or method is used.
2921
2922 =head2 offset
2923
2924 =over 4
2925
2926 =item Value: $offset
2927
2928 =back
2929
2930 Specifies the (zero-based) row number for the  first row to be returned, or the
2931 of the first row of the first page if paging is used.
2932
2933 =head2 group_by
2934
2935 =over 4
2936
2937 =item Value: \@columns
2938
2939 =back
2940
2941 A arrayref of columns to group by. Can include columns of joined tables.
2942
2943   group_by => [qw/ column1 column2 ... /]
2944
2945 =head2 having
2946
2947 =over 4
2948
2949 =item Value: $condition
2950
2951 =back
2952
2953 HAVING is a select statement attribute that is applied between GROUP BY and
2954 ORDER BY. It is applied to the after the grouping calculations have been
2955 done.
2956
2957   having => { 'count(employee)' => { '>=', 100 } }
2958
2959 =head2 distinct
2960
2961 =over 4
2962
2963 =item Value: (0 | 1)
2964
2965 =back
2966
2967 Set to 1 to group by all columns.
2968
2969 =head2 where
2970
2971 =over 4
2972
2973 Adds to the WHERE clause.
2974
2975   # only return rows WHERE deleted IS NULL for all searches
2976   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
2977
2978 Can be overridden by passing C<{ where => undef }> as an attribute
2979 to a resulset.
2980
2981 =back
2982
2983 =head2 cache
2984
2985 Set to 1 to cache search results. This prevents extra SQL queries if you
2986 revisit rows in your ResultSet:
2987
2988   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
2989
2990   while( my $artist = $resultset->next ) {
2991     ... do stuff ...
2992   }
2993
2994   $rs->first; # without cache, this would issue a query
2995
2996 By default, searches are not cached.
2997
2998 For more examples of using these attributes, see
2999 L<DBIx::Class::Manual::Cookbook>.
3000
3001 =head2 from
3002
3003 =over 4
3004
3005 =item Value: \@from_clause
3006
3007 =back
3008
3009 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3010 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3011 clauses.
3012
3013 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3014
3015 C<join> will usually do what you need and it is strongly recommended that you
3016 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3017 And we really do mean "cannot", not just tried and failed. Attempting to use
3018 this because you're having problems with C<join> is like trying to use x86
3019 ASM because you've got a syntax error in your C. Trust us on this.
3020
3021 Now, if you're still really, really sure you need to use this (and if you're
3022 not 100% sure, ask the mailing list first), here's an explanation of how this
3023 works.
3024
3025 The syntax is as follows -
3026
3027   [
3028     { <alias1> => <table1> },
3029     [
3030       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3031       [], # nested JOIN (optional)
3032       { <table1.column1> => <table2.column2>, ... (more conditions) },
3033     ],
3034     # More of the above [ ] may follow for additional joins
3035   ]
3036
3037   <table1> <alias1>
3038   JOIN
3039     <table2> <alias2>
3040     [JOIN ...]
3041   ON <table1.column1> = <table2.column2>
3042   <more joins may follow>
3043
3044 An easy way to follow the examples below is to remember the following:
3045
3046     Anything inside "[]" is a JOIN
3047     Anything inside "{}" is a condition for the enclosing JOIN
3048
3049 The following examples utilize a "person" table in a family tree application.
3050 In order to express parent->child relationships, this table is self-joined:
3051
3052     # Person->belongs_to('father' => 'Person');
3053     # Person->belongs_to('mother' => 'Person');
3054
3055 C<from> can be used to nest joins. Here we return all children with a father,
3056 then search against all mothers of those children:
3057
3058   $rs = $schema->resultset('Person')->search(
3059       undef,
3060       {
3061           alias => 'mother', # alias columns in accordance with "from"
3062           from => [
3063               { mother => 'person' },
3064               [
3065                   [
3066                       { child => 'person' },
3067                       [
3068                           { father => 'person' },
3069                           { 'father.person_id' => 'child.father_id' }
3070                       ]
3071                   ],
3072                   { 'mother.person_id' => 'child.mother_id' }
3073               ],
3074           ]
3075       },
3076   );
3077
3078   # Equivalent SQL:
3079   # SELECT mother.* FROM person mother
3080   # JOIN (
3081   #   person child
3082   #   JOIN person father
3083   #   ON ( father.person_id = child.father_id )
3084   # )
3085   # ON ( mother.person_id = child.mother_id )
3086
3087 The type of any join can be controlled manually. To search against only people
3088 with a father in the person table, we could explicitly use C<INNER JOIN>:
3089
3090     $rs = $schema->resultset('Person')->search(
3091         undef,
3092         {
3093             alias => 'child', # alias columns in accordance with "from"
3094             from => [
3095                 { child => 'person' },
3096                 [
3097                     { father => 'person', -join_type => 'inner' },
3098                     { 'father.id' => 'child.father_id' }
3099                 ],
3100             ]
3101         },
3102     );
3103
3104     # Equivalent SQL:
3105     # SELECT child.* FROM person child
3106     # INNER JOIN person father ON child.father_id = father.id
3107
3108 If you need to express really complex joins or you need a subselect, you
3109 can supply literal SQL to C<from> via a scalar reference. In this case
3110 the contents of the scalar will replace the table name asscoiated with the
3111 resultsource.
3112
3113 WARNING: This technique might very well not work as expected on chained
3114 searches - you have been warned.
3115
3116     # Assuming the Event resultsource is defined as:
3117
3118         MySchema::Event->add_columns (
3119             sequence => {
3120                 data_type => 'INT',
3121                 is_auto_increment => 1,
3122             },
3123             location => {
3124                 data_type => 'INT',
3125             },
3126             type => {
3127                 data_type => 'INT',
3128             },
3129         );
3130         MySchema::Event->set_primary_key ('sequence');
3131
3132     # This will get back the latest event for every location. The column
3133     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3134     # combo to limit the resultset
3135
3136     $rs = $schema->resultset('Event');
3137     $table = $rs->result_source->name;
3138     $latest = $rs->search (
3139         undef,
3140         { from => \ "
3141             (SELECT e1.* FROM $table e1
3142                 JOIN $table e2
3143                     ON e1.location = e2.location
3144                     AND e1.sequence < e2.sequence
3145                 WHERE e2.sequence is NULL
3146             ) me",
3147         },
3148     );
3149
3150     # Equivalent SQL (with the DBIC chunks added):
3151
3152     SELECT me.sequence, me.location, me.type FROM
3153        (SELECT e1.* FROM events e1
3154            JOIN events e2
3155                ON e1.location = e2.location
3156                AND e1.sequence < e2.sequence
3157            WHERE e2.sequence is NULL
3158        ) me;
3159
3160 =head2 for
3161
3162 =over 4
3163
3164 =item Value: ( 'update' | 'shared' )
3165
3166 =back
3167
3168 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3169 ... FOR SHARED.
3170
3171 =cut
3172
3173 1;