lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 966   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 967   @new = $self->{_attrs}{record_filter}->(@new)
 968     if exists $self->{_attrs}{record_filter};
 969   return @new;
 970 }
 971
 972 sub _collapse_result {
 973   my ($self, $as_proto, $row) = @_;
 974
 975   my @copy = @$row;
 976
 977   # 'foo'         => [ undef, 'foo' ]
 978   # 'foo.bar'     => [ 'foo', 'bar' ]
 979   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 980
 981   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 982
 983   my %collapse = %{$self->{_attrs}{collapse}||{}};
 984
 985   my @pri_index;
 986
 987   # if we're doing collapsing (has_many prefetch) we need to grab records
 988   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 989   # we know we don't have to bother.
 990
 991   # the reason for not using the collapse stuff directly is because if you
 992   # had for e.g. two artists in a row with no cds, the collapse info for
 993   # both would be NULL (undef) so you'd lose the second artist
 994
 995   # store just the index so we can check the array positions from the row
 996   # without having to contruct the full hash
 997
 998   if (keys %collapse) {
 999     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1000     foreach my $i (0 .. $#construct_as) {
1001       next if defined($construct_as[$i][0]); # only self table
1002       if (delete $pri{$construct_as[$i][1]}) {
1003         push(@pri_index, $i);
1004       }
1005       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1006     }
1007   }
1008
1009   # no need to do an if, it'll be empty if @pri_index is empty anyway
1010
1011   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1012
1013   my @const_rows;
1014
1015   do { # no need to check anything at the front, we always want the first row
1016
1017     my %const;
1018
1019     foreach my $this_as (@construct_as) {
1020       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1021     }
1022
1023     push(@const_rows, \%const);
1024
1025   } until ( # no pri_index => no collapse => drop straight out
1026       !@pri_index
1027     or
1028       do { # get another row, stash it, drop out if different PK
1029
1030         @copy = $self->cursor->next;
1031         $self->{stashed_row} = \@copy;
1032
1033         # last thing in do block, counts as true if anything doesn't match
1034
1035         # check xor defined first for NULL vs. NOT NULL then if one is
1036         # defined the other must be so check string equality
1037
1038         grep {
1039           (defined $pri_vals{$_} ^ defined $copy[$_])
1040           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1041         } @pri_index;
1042       }
1043   );
1044
1045   my $alias = $self->{attrs}{alias};
1046   my $info = [];
1047
1048   my %collapse_pos;
1049
1050   my @const_keys;
1051
1052   foreach my $const (@const_rows) {
1053     scalar @const_keys or do {
1054       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1055     };
1056     foreach my $key (@const_keys) {
1057       if (length $key) {
1058         my $target = $info;
1059         my @parts = split(/\./, $key);
1060         my $cur = '';
1061         my $data = $const->{$key};
1062         foreach my $p (@parts) {
1063           $target = $target->[1]->{$p} ||= [];
1064           $cur .= ".${p}";
1065           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1066             # collapsing at this point and on final part
1067             my $pos = $collapse_pos{$cur};
1068             CK: foreach my $ck (@ckey) {
1069               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1070                 $collapse_pos{$cur} = $data;
1071                 delete @collapse_pos{ # clear all positioning for sub-entries
1072                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1073                 };
1074                 push(@$target, []);
1075                 last CK;
1076               }
1077             }
1078           }
1079           if (exists $collapse{$cur}) {
1080             $target = $target->[-1];
1081           }
1082         }
1083         $target->[0] = $data;
1084       } else {
1085         $info->[0] = $const->{$key};
1086       }
1087     }
1088   }
1089
1090   return $info;
1091 }
1092
1093 =head2 result_source
1094
1095 =over 4
1096
1097 =item Arguments: $result_source?
1098
1099 =item Return Value: $result_source
1100
1101 =back
1102
1103 An accessor for the primary ResultSource object from which this ResultSet
1104 is derived.
1105
1106 =head2 result_class
1107
1108 =over 4
1109
1110 =item Arguments: $result_class?
1111
1112 =item Return Value: $result_class
1113
1114 =back
1115
1116 An accessor for the class to use when creating row objects. Defaults to
1117 C<< result_source->result_class >> - which in most cases is the name of the
1118 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1119
1120 Note that changing the result_class will also remove any components
1121 that were originally loaded in the source class via
1122 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1123 in the original source class will not run.
1124
1125 =cut
1126
1127 sub result_class {
1128   my ($self, $result_class) = @_;
1129   if ($result_class) {
1130     $self->ensure_class_loaded($result_class);
1131     $self->_result_class($result_class);
1132   }
1133   $self->_result_class;
1134 }
1135
1136 =head2 count
1137
1138 =over 4
1139
1140 =item Arguments: $cond, \%attrs??
1141
1142 =item Return Value: $count
1143
1144 =back
1145
1146 Performs an SQL C<COUNT> with the same query as the resultset was built
1147 with to find the number of elements. Passing arguments is equivalent to
1148 C<< $rs->search ($cond, \%attrs)->count >>
1149
1150 =cut
1151
1152 sub count {
1153   my $self = shift;
1154   return $self->search(@_)->count if @_ and defined $_[0];
1155   return scalar @{ $self->get_cache } if $self->get_cache;
1156
1157   my $meth = $self->_has_resolved_attr (qw/collapse group_by/)
1158     ? 'count_grouped'
1159     : 'count'
1160   ;
1161
1162   my $attrs = $self->_resolved_attrs_copy;
1163   my $rsrc = $self->result_source;
1164
1165   return $rsrc->storage->$meth ($rsrc, $attrs);
1166 }
1167
1168 sub _bool {
1169   return 1;
1170 }
1171
1172 =head2 count_literal
1173
1174 =over 4
1175
1176 =item Arguments: $sql_fragment, @bind_values
1177
1178 =item Return Value: $count
1179
1180 =back
1181
1182 Counts the results in a literal query. Equivalent to calling L</search_literal>
1183 with the passed arguments, then L</count>.
1184
1185 =cut
1186
1187 sub count_literal { shift->search_literal(@_)->count; }
1188
1189 =head2 all
1190
1191 =over 4
1192
1193 =item Arguments: none
1194
1195 =item Return Value: @objects
1196
1197 =back
1198
1199 Returns all elements in the resultset. Called implicitly if the resultset
1200 is returned in list context.
1201
1202 =cut
1203
1204 sub all {
1205   my $self = shift;
1206   if(@_) {
1207       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1208   }
1209
1210   return @{ $self->get_cache } if $self->get_cache;
1211
1212   my @obj;
1213
1214   # TODO: don't call resolve here
1215   if (keys %{$self->_resolved_attrs->{collapse}}) {
1216 #  if ($self->{attrs}{prefetch}) {
1217       # Using $self->cursor->all is really just an optimisation.
1218       # If we're collapsing has_many prefetches it probably makes
1219       # very little difference, and this is cleaner than hacking
1220       # _construct_object to survive the approach
1221     my @row = $self->cursor->next;
1222     while (@row) {
1223       push(@obj, $self->_construct_object(@row));
1224       @row = (exists $self->{stashed_row}
1225                ? @{delete $self->{stashed_row}}
1226                : $self->cursor->next);
1227     }
1228   } else {
1229     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1230   }
1231
1232   $self->set_cache(\@obj) if $self->{attrs}{cache};
1233   return @obj;
1234 }
1235
1236 =head2 reset
1237
1238 =over 4
1239
1240 =item Arguments: none
1241
1242 =item Return Value: $self
1243
1244 =back
1245
1246 Resets the resultset's cursor, so you can iterate through the elements again.
1247
1248 =cut
1249
1250 sub reset {
1251   my ($self) = @_;
1252   delete $self->{_attrs} if exists $self->{_attrs};
1253   $self->{all_cache_position} = 0;
1254   $self->cursor->reset;
1255   return $self;
1256 }
1257
1258 =head2 first
1259
1260 =over 4
1261
1262 =item Arguments: none
1263
1264 =item Return Value: $object?
1265
1266 =back
1267
1268 Resets the resultset and returns an object for the first result (if the
1269 resultset returns anything).
1270
1271 =cut
1272
1273 sub first {
1274   return $_[0]->reset->next;
1275 }
1276
1277
1278 # _rs_update_delete
1279 #
1280 # Determines whether and what type of subquery is required for the $rs operation.
1281 # If grouping is necessary either supplies its own, or verifies the current one
1282 # After all is done delegates to the proper storage method.
1283
1284 sub _rs_update_delete {
1285   my ($self, $op, $values) = @_;
1286
1287   my $rsrc = $self->result_source;
1288
1289   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1290   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1291
1292   if ($needs_group_by_subq or $needs_subq) {
1293
1294     # make a new $rs selecting only the PKs (that's all we really need)
1295     my $attrs = $self->_resolved_attrs_copy;
1296
1297     delete $attrs->{$_} for qw/collapse select as/;
1298     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1299
1300     if ($needs_group_by_subq) {
1301       # make sure no group_by was supplied, or if there is one - make sure it matches
1302       # the columns compiled above perfectly. Anything else can not be sanely executed
1303       # on most databases so croak right then and there
1304
1305       if (my $g = $attrs->{group_by}) {
1306         my @current_group_by = map
1307           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1308           (ref $g eq 'ARRAY' ? @$g : $g );
1309
1310         if (
1311           join ("\x00", sort @current_group_by)
1312             ne
1313           join ("\x00", sort @{$attrs->{columns}} )
1314         ) {
1315           $self->throw_exception (
1316             "You have just attempted a $op operation on a resultset which does group_by"
1317             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1318             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1319             . ' kind of queries. Please retry the operation with a modified group_by or'
1320             . ' without using one at all.'
1321           );
1322         }
1323       }
1324       else {
1325         $attrs->{group_by} = $attrs->{columns};
1326       }
1327     }
1328
1329     my $subrs = (ref $self)->new($rsrc, $attrs);
1330
1331     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1332   }
1333   else {
1334     return $rsrc->storage->$op(
1335       $rsrc,
1336       $op eq 'update' ? $values : (),
1337       $self->_cond_for_update_delete,
1338     );
1339   }
1340 }
1341
1342
1343 # _cond_for_update_delete
1344 #
1345 # update/delete require the condition to be modified to handle
1346 # the differing SQL syntax available.  This transforms the $self->{cond}
1347 # appropriately, returning the new condition.
1348
1349 sub _cond_for_update_delete {
1350   my ($self, $full_cond) = @_;
1351   my $cond = {};
1352
1353   $full_cond ||= $self->{cond};
1354   # No-op. No condition, we're updating/deleting everything
1355   return $cond unless ref $full_cond;
1356
1357   if (ref $full_cond eq 'ARRAY') {
1358     $cond = [
1359       map {
1360         my %hash;
1361         foreach my $key (keys %{$_}) {
1362           $key =~ /([^.]+)$/;
1363           $hash{$1} = $_->{$key};
1364         }
1365         \%hash;
1366       } @{$full_cond}
1367     ];
1368   }
1369   elsif (ref $full_cond eq 'HASH') {
1370     if ((keys %{$full_cond})[0] eq '-and') {
1371       $cond->{-and} = [];
1372       my @cond = @{$full_cond->{-and}};
1373        for (my $i = 0; $i < @cond; $i++) {
1374         my $entry = $cond[$i];
1375         my $hash;
1376         if (ref $entry eq 'HASH') {
1377           $hash = $self->_cond_for_update_delete($entry);
1378         }
1379         else {
1380           $entry =~ /([^.]+)$/;
1381           $hash->{$1} = $cond[++$i];
1382         }
1383         push @{$cond->{-and}}, $hash;
1384       }
1385     }
1386     else {
1387       foreach my $key (keys %{$full_cond}) {
1388         $key =~ /([^.]+)$/;
1389         $cond->{$1} = $full_cond->{$key};
1390       }
1391     }
1392   }
1393   else {
1394     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1395   }
1396
1397   return $cond;
1398 }
1399
1400
1401 =head2 update
1402
1403 =over 4
1404
1405 =item Arguments: \%values
1406
1407 =item Return Value: $storage_rv
1408
1409 =back
1410
1411 Sets the specified columns in the resultset to the supplied values in a
1412 single query. Return value will be true if the update succeeded or false
1413 if no records were updated; exact type of success value is storage-dependent.
1414
1415 =cut
1416
1417 sub update {
1418   my ($self, $values) = @_;
1419   $self->throw_exception('Values for update must be a hash')
1420     unless ref $values eq 'HASH';
1421
1422   return $self->_rs_update_delete ('update', $values);
1423 }
1424
1425 =head2 update_all
1426
1427 =over 4
1428
1429 =item Arguments: \%values
1430
1431 =item Return Value: 1
1432
1433 =back
1434
1435 Fetches all objects and updates them one at a time. Note that C<update_all>
1436 will run DBIC cascade triggers, while L</update> will not.
1437
1438 =cut
1439
1440 sub update_all {
1441   my ($self, $values) = @_;
1442   $self->throw_exception('Values for update_all must be a hash')
1443     unless ref $values eq 'HASH';
1444   foreach my $obj ($self->all) {
1445     $obj->set_columns($values)->update;
1446   }
1447   return 1;
1448 }
1449
1450 =head2 delete
1451
1452 =over 4
1453
1454 =item Arguments: none
1455
1456 =item Return Value: $storage_rv
1457
1458 =back
1459
1460 Deletes the contents of the resultset from its result source. Note that this
1461 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1462 to run. See also L<DBIx::Class::Row/delete>.
1463
1464 Return value will be the amount of rows deleted; exact type of return value
1465 is storage-dependent.
1466
1467 =cut
1468
1469 sub delete {
1470   my $self = shift;
1471   $self->throw_exception('delete does not accept any arguments')
1472     if @_;
1473
1474   return $self->_rs_update_delete ('delete');
1475 }
1476
1477 =head2 delete_all
1478
1479 =over 4
1480
1481 =item Arguments: none
1482
1483 =item Return Value: 1
1484
1485 =back
1486
1487 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1488 will run DBIC cascade triggers, while L</delete> will not.
1489
1490 =cut
1491
1492 sub delete_all {
1493   my $self = shift;
1494   $self->throw_exception('delete_all does not accept any arguments')
1495     if @_;
1496
1497   $_->delete for $self->all;
1498   return 1;
1499 }
1500
1501 =head2 populate
1502
1503 =over 4
1504
1505 =item Arguments: \@data;
1506
1507 =back
1508
1509 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1510 For the arrayref of hashrefs style each hashref should be a structure suitable
1511 forsubmitting to a $resultset->create(...) method.
1512
1513 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1514 to insert the data, as this is a faster method.
1515
1516 Otherwise, each set of data is inserted into the database using
1517 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1518 objects is returned.
1519
1520 Example:  Assuming an Artist Class that has many CDs Classes relating:
1521
1522   my $Artist_rs = $schema->resultset("Artist");
1523
1524   ## Void Context Example
1525   $Artist_rs->populate([
1526      { artistid => 4, name => 'Manufactured Crap', cds => [
1527         { title => 'My First CD', year => 2006 },
1528         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1529       ],
1530      },
1531      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1532         { title => 'My parents sold me to a record company' ,year => 2005 },
1533         { title => 'Why Am I So Ugly?', year => 2006 },
1534         { title => 'I Got Surgery and am now Popular', year => 2007 }
1535       ],
1536      },
1537   ]);
1538
1539   ## Array Context Example
1540   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1541     { name => "Artist One"},
1542     { name => "Artist Two"},
1543     { name => "Artist Three", cds=> [
1544     { title => "First CD", year => 2007},
1545     { title => "Second CD", year => 2008},
1546   ]}
1547   ]);
1548
1549   print $ArtistOne->name; ## response is 'Artist One'
1550   print $ArtistThree->cds->count ## reponse is '2'
1551
1552 For the arrayref of arrayrefs style,  the first element should be a list of the
1553 fieldsnames to which the remaining elements are rows being inserted.  For
1554 example:
1555
1556   $Arstist_rs->populate([
1557     [qw/artistid name/],
1558     [100, 'A Formally Unknown Singer'],
1559     [101, 'A singer that jumped the shark two albums ago'],
1560     [102, 'An actually cool singer.'],
1561   ]);
1562
1563 Please note an important effect on your data when choosing between void and
1564 wantarray context. Since void context goes straight to C<insert_bulk> in
1565 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1566 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1567 create primary keys for you, you will find that your PKs are empty.  In this
1568 case you will have to use the wantarray context in order to create those
1569 values.
1570
1571 =cut
1572
1573 sub populate {
1574   my $self = shift @_;
1575   my $data = ref $_[0][0] eq 'HASH'
1576     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1577     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1578
1579   if(defined wantarray) {
1580     my @created;
1581     foreach my $item (@$data) {
1582       push(@created, $self->create($item));
1583     }
1584     return @created;
1585   } else {
1586     my ($first, @rest) = @$data;
1587
1588     my @names = grep {!ref $first->{$_}} keys %$first;
1589     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1590     my @pks = $self->result_source->primary_columns;
1591
1592     ## do the belongs_to relationships
1593     foreach my $index (0..$#$data) {
1594
1595       # delegate to create() for any dataset without primary keys with specified relationships
1596       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1597         for my $r (@rels) {
1598           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1599             my @ret = $self->populate($data);
1600             return;
1601           }
1602         }
1603       }
1604
1605       foreach my $rel (@rels) {
1606         next unless ref $data->[$index]->{$rel} eq "HASH";
1607         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1608         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1609         my $related = $result->result_source->_resolve_condition(
1610           $result->result_source->relationship_info($reverse)->{cond},
1611           $self,
1612           $result,
1613         );
1614
1615         delete $data->[$index]->{$rel};
1616         $data->[$index] = {%{$data->[$index]}, %$related};
1617
1618         push @names, keys %$related if $index == 0;
1619       }
1620     }
1621
1622     ## do bulk insert on current row
1623     my @values = map { [ @$_{@names} ] } @$data;
1624
1625     $self->result_source->storage->insert_bulk(
1626       $self->result_source,
1627       \@names,
1628       \@values,
1629     );
1630
1631     ## do the has_many relationships
1632     foreach my $item (@$data) {
1633
1634       foreach my $rel (@rels) {
1635         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1636
1637         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1638      || $self->throw_exception('Cannot find the relating object.');
1639
1640         my $child = $parent->$rel;
1641
1642         my $related = $child->result_source->_resolve_condition(
1643           $parent->result_source->relationship_info($rel)->{cond},
1644           $child,
1645           $parent,
1646         );
1647
1648         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1649         my @populate = map { {%$_, %$related} } @rows_to_add;
1650
1651         $child->populate( \@populate );
1652       }
1653     }
1654   }
1655 }
1656
1657 =head2 _normalize_populate_args ($args)
1658
1659 Private method used by L</populate> to normalize its incoming arguments.  Factored
1660 out in case you want to subclass and accept new argument structures to the
1661 L</populate> method.
1662
1663 =cut
1664
1665 sub _normalize_populate_args {
1666   my ($self, $data) = @_;
1667   my @names = @{shift(@$data)};
1668   my @results_to_create;
1669   foreach my $datum (@$data) {
1670     my %result_to_create;
1671     foreach my $index (0..$#names) {
1672       $result_to_create{$names[$index]} = $$datum[$index];
1673     }
1674     push @results_to_create, \%result_to_create;
1675   }
1676   return \@results_to_create;
1677 }
1678
1679 =head2 pager
1680
1681 =over 4
1682
1683 =item Arguments: none
1684
1685 =item Return Value: $pager
1686
1687 =back
1688
1689 Return Value a L<Data::Page> object for the current resultset. Only makes
1690 sense for queries with a C<page> attribute.
1691
1692 To get the full count of entries for a paged resultset, call
1693 C<total_entries> on the L<Data::Page> object.
1694
1695 =cut
1696
1697 sub pager {
1698   my ($self) = @_;
1699
1700   return $self->{pager} if $self->{pager};
1701
1702   my $attrs = $self->{attrs};
1703   $self->throw_exception("Can't create pager for non-paged rs")
1704     unless $self->{attrs}{page};
1705   $attrs->{rows} ||= 10;
1706
1707   # throw away the paging flags and re-run the count (possibly
1708   # with a subselect) to get the real total count
1709   my $count_attrs = { %$attrs };
1710   delete $count_attrs->{$_} for qw/rows offset page pager/;
1711   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1712
1713   return $self->{pager} = Data::Page->new(
1714     $total_count,
1715     $attrs->{rows},
1716     $self->{attrs}{page}
1717   );
1718 }
1719
1720 =head2 page
1721
1722 =over 4
1723
1724 =item Arguments: $page_number
1725
1726 =item Return Value: $rs
1727
1728 =back
1729
1730 Returns a resultset for the $page_number page of the resultset on which page
1731 is called, where each page contains a number of rows equal to the 'rows'
1732 attribute set on the resultset (10 by default).
1733
1734 =cut
1735
1736 sub page {
1737   my ($self, $page) = @_;
1738   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1739 }
1740
1741 =head2 new_result
1742
1743 =over 4
1744
1745 =item Arguments: \%vals
1746
1747 =item Return Value: $rowobject
1748
1749 =back
1750
1751 Creates a new row object in the resultset's result class and returns
1752 it. The row is not inserted into the database at this point, call
1753 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1754 will tell you whether the row object has been inserted or not.
1755
1756 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1757
1758 =cut
1759
1760 sub new_result {
1761   my ($self, $values) = @_;
1762   $self->throw_exception( "new_result needs a hash" )
1763     unless (ref $values eq 'HASH');
1764
1765   my %new;
1766   my $alias = $self->{attrs}{alias};
1767
1768   if (
1769     defined $self->{cond}
1770     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1771   ) {
1772     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1773     $new{-from_resultset} = [ keys %new ] if keys %new;
1774   } else {
1775     $self->throw_exception(
1776       "Can't abstract implicit construct, condition not a hash"
1777     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1778
1779     my $collapsed_cond = (
1780       $self->{cond}
1781         ? $self->_collapse_cond($self->{cond})
1782         : {}
1783     );
1784
1785     # precendence must be given to passed values over values inherited from
1786     # the cond, so the order here is important.
1787     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1788     while( my($col,$value) = each %implied ){
1789       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1790         $new{$col} = $value->{'='};
1791         next;
1792       }
1793       $new{$col} = $value if $self->_is_deterministic_value($value);
1794     }
1795   }
1796
1797   %new = (
1798     %new,
1799     %{ $self->_remove_alias($values, $alias) },
1800     -source_handle => $self->_source_handle,
1801     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1802   );
1803
1804   return $self->result_class->new(\%new);
1805 }
1806
1807 # _is_deterministic_value
1808 #
1809 # Make an effor to strip non-deterministic values from the condition,
1810 # to make sure new_result chokes less
1811
1812 sub _is_deterministic_value {
1813   my $self = shift;
1814   my $value = shift;
1815   my $ref_type = ref $value;
1816   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1817   return 1 if Scalar::Util::blessed($value);
1818   return 0;
1819 }
1820
1821 # _has_resolved_attr
1822 #
1823 # determines if the resultset defines at least one
1824 # of the attributes supplied
1825 #
1826 # used to determine if a subquery is neccessary
1827
1828 sub _has_resolved_attr {
1829   my ($self, @attr_names) = @_;
1830
1831   my $attrs = $self->_resolved_attrs;
1832
1833   my $join_check_req;
1834
1835   for my $n (@attr_names) {
1836     ++$join_check_req if $n eq '-join';
1837
1838     my $attr =  $attrs->{$n};
1839
1840     next if not defined $attr;
1841
1842     if (ref $attr eq 'HASH') {
1843       return 1 if keys %$attr;
1844     }
1845     elsif (ref $attr eq 'ARRAY') {
1846       return 1 if @$attr;
1847     }
1848     else {
1849       return 1 if $attr;
1850     }
1851   }
1852
1853   # a resolved join is expressed as a multi-level from
1854   return 1 if (
1855     $join_check_req
1856       and
1857     ref $attrs->{from} eq 'ARRAY'
1858       and
1859     @{$attrs->{from}} > 1
1860   );
1861
1862   return 0;
1863 }
1864
1865 # _collapse_cond
1866 #
1867 # Recursively collapse the condition.
1868
1869 sub _collapse_cond {
1870   my ($self, $cond, $collapsed) = @_;
1871
1872   $collapsed ||= {};
1873
1874   if (ref $cond eq 'ARRAY') {
1875     foreach my $subcond (@$cond) {
1876       next unless ref $subcond;  # -or
1877       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1878     }
1879   }
1880   elsif (ref $cond eq 'HASH') {
1881     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1882       foreach my $subcond (@{$cond->{-and}}) {
1883         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1884       }
1885     }
1886     else {
1887       foreach my $col (keys %$cond) {
1888         my $value = $cond->{$col};
1889         $collapsed->{$col} = $value;
1890       }
1891     }
1892   }
1893
1894   return $collapsed;
1895 }
1896
1897 # _remove_alias
1898 #
1899 # Remove the specified alias from the specified query hash. A copy is made so
1900 # the original query is not modified.
1901
1902 sub _remove_alias {
1903   my ($self, $query, $alias) = @_;
1904
1905   my %orig = %{ $query || {} };
1906   my %unaliased;
1907
1908   foreach my $key (keys %orig) {
1909     if ($key !~ /\./) {
1910       $unaliased{$key} = $orig{$key};
1911       next;
1912     }
1913     $unaliased{$1} = $orig{$key}
1914       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1915   }
1916
1917   return \%unaliased;
1918 }
1919
1920 =head2 as_query (EXPERIMENTAL)
1921
1922 =over 4
1923
1924 =item Arguments: none
1925
1926 =item Return Value: \[ $sql, @bind ]
1927
1928 =back
1929
1930 Returns the SQL query and bind vars associated with the invocant.
1931
1932 This is generally used as the RHS for a subquery.
1933
1934 B<NOTE>: This feature is still experimental.
1935
1936 =cut
1937
1938 sub as_query {
1939   my $self = shift;
1940
1941   my $attrs = $self->_resolved_attrs_copy;
1942
1943   # For future use:
1944   #
1945   # in list ctx:
1946   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
1947   # $sql also has no wrapping parenthesis in list ctx
1948   #
1949   my $sqlbind = $self->result_source->storage
1950     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
1951
1952   return $sqlbind;
1953 }
1954
1955 =head2 find_or_new
1956
1957 =over 4
1958
1959 =item Arguments: \%vals, \%attrs?
1960
1961 =item Return Value: $rowobject
1962
1963 =back
1964
1965   my $artist = $schema->resultset('Artist')->find_or_new(
1966     { artist => 'fred' }, { key => 'artists' });
1967
1968   $cd->cd_to_producer->find_or_new({ producer => $producer },
1969                                    { key => 'primary });
1970
1971 Find an existing record from this resultset, based on its primary
1972 key, or a unique constraint. If none exists, instantiate a new result
1973 object and return it. The object will not be saved into your storage
1974 until you call L<DBIx::Class::Row/insert> on it.
1975
1976 You most likely want this method when looking for existing rows using
1977 a unique constraint that is not the primary key, or looking for
1978 related rows.
1979
1980 If you want objects to be saved immediately, use L</find_or_create> instead.
1981
1982 B<Note>: C<find_or_new> is probably not what you want when creating a
1983 new row in a table that uses primary keys supplied by the
1984 database. Passing in a primary key column with a value of I<undef>
1985 will cause L</find> to attempt to search for a row with a value of
1986 I<NULL>.
1987
1988 =cut
1989
1990 sub find_or_new {
1991   my $self     = shift;
1992   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1993   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1994   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
1995     return $row;
1996   }
1997   return $self->new_result($hash);
1998 }
1999
2000 =head2 create
2001
2002 =over 4
2003
2004 =item Arguments: \%vals
2005
2006 =item Return Value: a L<DBIx::Class::Row> $object
2007
2008 =back
2009
2010 Attempt to create a single new row or a row with multiple related rows
2011 in the table represented by the resultset (and related tables). This
2012 will not check for duplicate rows before inserting, use
2013 L</find_or_create> to do that.
2014
2015 To create one row for this resultset, pass a hashref of key/value
2016 pairs representing the columns of the table and the values you wish to
2017 store. If the appropriate relationships are set up, foreign key fields
2018 can also be passed an object representing the foreign row, and the
2019 value will be set to its primary key.
2020
2021 To create related objects, pass a hashref for the value if the related
2022 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2023 and use the name of the relationship as the key. (NOT the name of the field,
2024 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2025 of hashrefs containing the data for each of the rows to create in the foreign
2026 tables, again using the relationship name as the key.
2027
2028 Instead of hashrefs of plain related data (key/value pairs), you may
2029 also pass new or inserted objects. New objects (not inserted yet, see
2030 L</new>), will be inserted into their appropriate tables.
2031
2032 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2033
2034 Example of creating a new row.
2035
2036   $person_rs->create({
2037     name=>"Some Person",
2038     email=>"somebody@someplace.com"
2039   });
2040
2041 Example of creating a new row and also creating rows in a related C<has_many>
2042 or C<has_one> resultset.  Note Arrayref.
2043
2044   $artist_rs->create(
2045      { artistid => 4, name => 'Manufactured Crap', cds => [
2046         { title => 'My First CD', year => 2006 },
2047         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2048       ],
2049      },
2050   );
2051
2052 Example of creating a new row and also creating a row in a related
2053 C<belongs_to>resultset. Note Hashref.
2054
2055   $cd_rs->create({
2056     title=>"Music for Silly Walks",
2057     year=>2000,
2058     artist => {
2059       name=>"Silly Musician",
2060     }
2061   });
2062
2063 =cut
2064
2065 sub create {
2066   my ($self, $attrs) = @_;
2067   $self->throw_exception( "create needs a hashref" )
2068     unless ref $attrs eq 'HASH';
2069   return $self->new_result($attrs)->insert;
2070 }
2071
2072 =head2 find_or_create
2073
2074 =over 4
2075
2076 =item Arguments: \%vals, \%attrs?
2077
2078 =item Return Value: $rowobject
2079
2080 =back
2081
2082   $cd->cd_to_producer->find_or_create({ producer => $producer },
2083                                       { key => 'primary });
2084
2085 Tries to find a record based on its primary key or unique constraints; if none
2086 is found, creates one and returns that instead.
2087
2088   my $cd = $schema->resultset('CD')->find_or_create({
2089     cdid   => 5,
2090     artist => 'Massive Attack',
2091     title  => 'Mezzanine',
2092     year   => 2005,
2093   });
2094
2095 Also takes an optional C<key> attribute, to search by a specific key or unique
2096 constraint. For example:
2097
2098   my $cd = $schema->resultset('CD')->find_or_create(
2099     {
2100       artist => 'Massive Attack',
2101       title  => 'Mezzanine',
2102     },
2103     { key => 'cd_artist_title' }
2104   );
2105
2106 B<Note>: Because find_or_create() reads from the database and then
2107 possibly inserts based on the result, this method is subject to a race
2108 condition. Another process could create a record in the table after
2109 the find has completed and before the create has started. To avoid
2110 this problem, use find_or_create() inside a transaction.
2111
2112 B<Note>: C<find_or_create> is probably not what you want when creating
2113 a new row in a table that uses primary keys supplied by the
2114 database. Passing in a primary key column with a value of I<undef>
2115 will cause L</find> to attempt to search for a row with a value of
2116 I<NULL>.
2117
2118 See also L</find> and L</update_or_create>. For information on how to declare
2119 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2120
2121 =cut
2122
2123 sub find_or_create {
2124   my $self     = shift;
2125   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2126   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2127   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2128     return $row;
2129   }
2130   return $self->create($hash);
2131 }
2132
2133 =head2 update_or_create
2134
2135 =over 4
2136
2137 =item Arguments: \%col_values, { key => $unique_constraint }?
2138
2139 =item Return Value: $rowobject
2140
2141 =back
2142
2143   $resultset->update_or_create({ col => $val, ... });
2144
2145 First, searches for an existing row matching one of the unique constraints
2146 (including the primary key) on the source of this resultset. If a row is
2147 found, updates it with the other given column values. Otherwise, creates a new
2148 row.
2149
2150 Takes an optional C<key> attribute to search on a specific unique constraint.
2151 For example:
2152
2153   # In your application
2154   my $cd = $schema->resultset('CD')->update_or_create(
2155     {
2156       artist => 'Massive Attack',
2157       title  => 'Mezzanine',
2158       year   => 1998,
2159     },
2160     { key => 'cd_artist_title' }
2161   );
2162
2163   $cd->cd_to_producer->update_or_create({
2164     producer => $producer,
2165     name => 'harry',
2166   }, {
2167     key => 'primary,
2168   });
2169
2170
2171 If no C<key> is specified, it searches on all unique constraints defined on the
2172 source, including the primary key.
2173
2174 If the C<key> is specified as C<primary>, it searches only on the primary key.
2175
2176 See also L</find> and L</find_or_create>. For information on how to declare
2177 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2178
2179 B<Note>: C<update_or_create> is probably not what you want when
2180 looking for a row in a table that uses primary keys supplied by the
2181 database, unless you actually have a key value. Passing in a primary
2182 key column with a value of I<undef> will cause L</find> to attempt to
2183 search for a row with a value of I<NULL>.
2184
2185 =cut
2186
2187 sub update_or_create {
2188   my $self = shift;
2189   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2190   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2191
2192   my $row = $self->find($cond, $attrs);
2193   if (defined $row) {
2194     $row->update($cond);
2195     return $row;
2196   }
2197
2198   return $self->create($cond);
2199 }
2200
2201 =head2 update_or_new
2202
2203 =over 4
2204
2205 =item Arguments: \%col_values, { key => $unique_constraint }?
2206
2207 =item Return Value: $rowobject
2208
2209 =back
2210
2211   $resultset->update_or_new({ col => $val, ... });
2212
2213 First, searches for an existing row matching one of the unique constraints
2214 (including the primary key) on the source of this resultset. If a row is
2215 found, updates it with the other given column values. Otherwise, instantiate
2216 a new result object and return it. The object will not be saved into your storage
2217 until you call L<DBIx::Class::Row/insert> on it.
2218
2219 Takes an optional C<key> attribute to search on a specific unique constraint.
2220 For example:
2221
2222   # In your application
2223   my $cd = $schema->resultset('CD')->update_or_new(
2224     {
2225       artist => 'Massive Attack',
2226       title  => 'Mezzanine',
2227       year   => 1998,
2228     },
2229     { key => 'cd_artist_title' }
2230   );
2231
2232   if ($cd->in_storage) {
2233       # the cd was updated
2234   }
2235   else {
2236       # the cd is not yet in the database, let's insert it
2237       $cd->insert;
2238   }
2239
2240 See also L</find>, L</find_or_create> and L<find_or_new>.
2241
2242 =cut
2243
2244 sub update_or_new {
2245     my $self  = shift;
2246     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2247     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2248
2249     my $row = $self->find( $cond, $attrs );
2250     if ( defined $row ) {
2251         $row->update($cond);
2252         return $row;
2253     }
2254
2255     return $self->new_result($cond);
2256 }
2257
2258 =head2 get_cache
2259
2260 =over 4
2261
2262 =item Arguments: none
2263
2264 =item Return Value: \@cache_objects?
2265
2266 =back
2267
2268 Gets the contents of the cache for the resultset, if the cache is set.
2269
2270 The cache is populated either by using the L</prefetch> attribute to
2271 L</search> or by calling L</set_cache>.
2272
2273 =cut
2274
2275 sub get_cache {
2276   shift->{all_cache};
2277 }
2278
2279 =head2 set_cache
2280
2281 =over 4
2282
2283 =item Arguments: \@cache_objects
2284
2285 =item Return Value: \@cache_objects
2286
2287 =back
2288
2289 Sets the contents of the cache for the resultset. Expects an arrayref
2290 of objects of the same class as those produced by the resultset. Note that
2291 if the cache is set the resultset will return the cached objects rather
2292 than re-querying the database even if the cache attr is not set.
2293
2294 The contents of the cache can also be populated by using the
2295 L</prefetch> attribute to L</search>.
2296
2297 =cut
2298
2299 sub set_cache {
2300   my ( $self, $data ) = @_;
2301   $self->throw_exception("set_cache requires an arrayref")
2302       if defined($data) && (ref $data ne 'ARRAY');
2303   $self->{all_cache} = $data;
2304 }
2305
2306 =head2 clear_cache
2307
2308 =over 4
2309
2310 =item Arguments: none
2311
2312 =item Return Value: []
2313
2314 =back
2315
2316 Clears the cache for the resultset.
2317
2318 =cut
2319
2320 sub clear_cache {
2321   shift->set_cache(undef);
2322 }
2323
2324 =head2 related_resultset
2325
2326 =over 4
2327
2328 =item Arguments: $relationship_name
2329
2330 =item Return Value: $resultset
2331
2332 =back
2333
2334 Returns a related resultset for the supplied relationship name.
2335
2336   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2337
2338 =cut
2339
2340 sub related_resultset {
2341   my ($self, $rel) = @_;
2342
2343   $self->{related_resultsets} ||= {};
2344   return $self->{related_resultsets}{$rel} ||= do {
2345     my $rel_obj = $self->result_source->relationship_info($rel);
2346
2347     $self->throw_exception(
2348       "search_related: result source '" . $self->result_source->source_name .
2349         "' has no such relationship $rel")
2350       unless $rel_obj;
2351
2352     my ($from,$seen) = $self->_resolve_from($rel);
2353
2354     my $join_count = $seen->{$rel};
2355     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2356
2357     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2358     my %attrs = %{$self->{attrs}||{}};
2359     delete @attrs{qw(result_class alias)};
2360
2361     my $new_cache;
2362
2363     if (my $cache = $self->get_cache) {
2364       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2365         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2366                         @$cache ];
2367       }
2368     }
2369
2370     my $rel_source = $self->result_source->related_source($rel);
2371
2372     my $new = do {
2373
2374       # The reason we do this now instead of passing the alias to the
2375       # search_rs below is that if you wrap/overload resultset on the
2376       # source you need to know what alias it's -going- to have for things
2377       # to work sanely (e.g. RestrictWithObject wants to be able to add
2378       # extra query restrictions, and these may need to be $alias.)
2379
2380       my $attrs = $rel_source->resultset_attributes;
2381       local $attrs->{alias} = $alias;
2382
2383       $rel_source->resultset
2384                  ->search_rs(
2385                      undef, {
2386                        %attrs,
2387                        join => undef,
2388                        prefetch => undef,
2389                        select => undef,
2390                        as => undef,
2391                        where => $self->{cond},
2392                        seen_join => $seen,
2393                        from => $from,
2394                    });
2395     };
2396     $new->set_cache($new_cache) if $new_cache;
2397     $new;
2398   };
2399 }
2400
2401 =head2 current_source_alias
2402
2403 =over 4
2404
2405 =item Arguments: none
2406
2407 =item Return Value: $source_alias
2408
2409 =back
2410
2411 Returns the current table alias for the result source this resultset is built
2412 on, that will be used in the SQL query. Usually it is C<me>.
2413
2414 Currently the source alias that refers to the result set returned by a
2415 L</search>/L</find> family method depends on how you got to the resultset: it's
2416 C<me> by default, but eg. L</search_related> aliases it to the related result
2417 source name (and keeps C<me> referring to the original result set). The long
2418 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2419 (and make this method unnecessary).
2420
2421 Thus it's currently necessary to use this method in predefined queries (see
2422 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2423 source alias of the current result set:
2424
2425   # in a result set class
2426   sub modified_by {
2427     my ($self, $user) = @_;
2428
2429     my $me = $self->current_source_alias;
2430
2431     return $self->search(
2432       "$me.modified" => $user->id,
2433     );
2434   }
2435
2436 =cut
2437
2438 sub current_source_alias {
2439   my ($self) = @_;
2440
2441   return ($self->{attrs} || {})->{alias} || 'me';
2442 }
2443
2444 # This code is called by search_related, and makes sure there
2445 # is clear separation between the joins before, during, and
2446 # after the relationship. This information is needed later
2447 # in order to properly resolve prefetch aliases (any alias
2448 # with a relation_chain_depth less than the depth of the
2449 # current prefetch is not considered)
2450 sub _resolve_from {
2451   my ($self, $extra_join) = @_;
2452   my $source = $self->result_source;
2453   my $attrs = $self->{attrs};
2454
2455   my $from = [ @{
2456       $attrs->{from}
2457         ||
2458       [{
2459         -source_handle => $source->handle,
2460         -alias => $attrs->{alias},
2461         $attrs->{alias} => $source->from,
2462       }]
2463   }];
2464
2465   my $seen = { %{$attrs->{seen_join} || {} } };
2466
2467   # we need to take the prefetch the attrs into account before we
2468   # ->_resolve_join as otherwise they get lost - captainL
2469   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2470
2471   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2472
2473   ++$seen->{-relation_chain_depth};
2474
2475   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2476
2477   ++$seen->{-relation_chain_depth};
2478
2479   return ($from,$seen);
2480 }
2481
2482 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2483 sub _resolved_attrs_copy {
2484   my $self = shift;
2485   return { %{$self->_resolved_attrs (@_)} };
2486 }
2487
2488 sub _resolved_attrs {
2489   my $self = shift;
2490   return $self->{_attrs} if $self->{_attrs};
2491
2492   my $attrs  = { %{ $self->{attrs} || {} } };
2493   my $source = $self->result_source;
2494   my $alias  = $attrs->{alias};
2495
2496   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2497   my @colbits;
2498
2499   # build columns (as long as select isn't set) into a set of as/select hashes
2500   unless ( $attrs->{select} ) {
2501       @colbits = map {
2502           ( ref($_) eq 'HASH' )
2503               ? $_
2504               : {
2505                   (
2506                     /^\Q${alias}.\E(.+)$/
2507                       ? "$1"
2508                       : "$_"
2509                   )
2510                 =>
2511                   (
2512                     /\./
2513                       ? "$_"
2514                       : "${alias}.$_"
2515                   )
2516             }
2517       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2518   }
2519   # add the additional columns on
2520   foreach ( 'include_columns', '+columns' ) {
2521       push @colbits, map {
2522           ( ref($_) eq 'HASH' )
2523             ? $_
2524             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2525       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2526   }
2527
2528   # start with initial select items
2529   if ( $attrs->{select} ) {
2530     $attrs->{select} =
2531         ( ref $attrs->{select} eq 'ARRAY' )
2532       ? [ @{ $attrs->{select} } ]
2533       : [ $attrs->{select} ];
2534     $attrs->{as} = (
2535       $attrs->{as}
2536       ? (
2537         ref $attrs->{as} eq 'ARRAY'
2538         ? [ @{ $attrs->{as} } ]
2539         : [ $attrs->{as} ]
2540         )
2541       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2542     );
2543   }
2544   else {
2545
2546     # otherwise we intialise select & as to empty
2547     $attrs->{select} = [];
2548     $attrs->{as}     = [];
2549   }
2550
2551   # now add colbits to select/as
2552   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2553   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2554
2555   my $adds;
2556   if ( $adds = delete $attrs->{'+select'} ) {
2557     $adds = [$adds] unless ref $adds eq 'ARRAY';
2558     push(
2559       @{ $attrs->{select} },
2560       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2561     );
2562   }
2563   if ( $adds = delete $attrs->{'+as'} ) {
2564     $adds = [$adds] unless ref $adds eq 'ARRAY';
2565     push( @{ $attrs->{as} }, @$adds );
2566   }
2567
2568   $attrs->{from} ||= [ {
2569     -source_handle => $source->handle,
2570     -alias => $self->{attrs}{alias},
2571     $self->{attrs}{alias} => $source->from,
2572   } ];
2573
2574   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2575     my $join = delete $attrs->{join} || {};
2576
2577     if ( defined $attrs->{prefetch} ) {
2578       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2579
2580     }
2581
2582     $attrs->{from} =    # have to copy here to avoid corrupting the original
2583       [
2584       @{ $attrs->{from} },
2585       $source->_resolve_join(
2586         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2587       )
2588       ];
2589
2590   }
2591
2592   if ( $attrs->{order_by} ) {
2593     $attrs->{order_by} = (
2594       ref( $attrs->{order_by} ) eq 'ARRAY'
2595       ? [ @{ $attrs->{order_by} } ]
2596       : [ $attrs->{order_by} ]
2597     );
2598   }
2599   else {
2600     $attrs->{order_by} = [];
2601   }
2602
2603   # If the order_by is otherwise empty - we will use this for TOP limit
2604   # emulation and the like.
2605   # Although this is needed only if the order_by is not defined, it is
2606   # actually cheaper to just populate this rather than properly examining
2607   # order_by (stuf like [ {} ] and the like)
2608   my $prefix = $alias . ($source->schema->storage->_sql_maker_opts->{name_sep} || '.');
2609   $attrs->{_virtual_order_by} = [
2610     map { $prefix . $_ } ($source->primary_columns)
2611   ];
2612
2613   $attrs->{collapse} ||= {};
2614   if ( my $prefetch = delete $attrs->{prefetch} ) {
2615     $prefetch = $self->_merge_attr( {}, $prefetch );
2616
2617     my $prefetch_ordering = [];
2618
2619     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2620
2621     my @prefetch =
2622       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2623
2624     push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2625     push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2626
2627     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2628     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2629   }
2630
2631
2632   if (delete $attrs->{distinct}) {
2633     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2634   }
2635
2636   # if both page and offset are specified, produce a combined offset
2637   # even though it doesn't make much sense, this is what pre 081xx has
2638   # been doing
2639   if (my $page = delete $attrs->{page}) {
2640     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2641       ($attrs->{offset} || 0);
2642   }
2643
2644   return $self->{_attrs} = $attrs;
2645 }
2646
2647 sub _joinpath_aliases {
2648   my ($self, $fromspec, $seen) = @_;
2649
2650   my $paths = {};
2651   return $paths unless ref $fromspec eq 'ARRAY';
2652
2653   for my $j (@$fromspec) {
2654
2655     next if ref $j ne 'ARRAY';
2656     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2657
2658     my $p = $paths;
2659     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2660     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2661   }
2662
2663   return $paths;
2664 }
2665
2666 sub _rollout_attr {
2667   my ($self, $attr) = @_;
2668
2669   if (ref $attr eq 'HASH') {
2670     return $self->_rollout_hash($attr);
2671   } elsif (ref $attr eq 'ARRAY') {
2672     return $self->_rollout_array($attr);
2673   } else {
2674     return [$attr];
2675   }
2676 }
2677
2678 sub _rollout_array {
2679   my ($self, $attr) = @_;
2680
2681   my @rolled_array;
2682   foreach my $element (@{$attr}) {
2683     if (ref $element eq 'HASH') {
2684       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2685     } elsif (ref $element eq 'ARRAY') {
2686       #  XXX - should probably recurse here
2687       push( @rolled_array, @{$self->_rollout_array($element)} );
2688     } else {
2689       push( @rolled_array, $element );
2690     }
2691   }
2692   return \@rolled_array;
2693 }
2694
2695 sub _rollout_hash {
2696   my ($self, $attr) = @_;
2697
2698   my @rolled_array;
2699   foreach my $key (keys %{$attr}) {
2700     push( @rolled_array, { $key => $attr->{$key} } );
2701   }
2702   return \@rolled_array;
2703 }
2704
2705 sub _calculate_score {
2706   my ($self, $a, $b) = @_;
2707
2708   if (ref $b eq 'HASH') {
2709     my ($b_key) = keys %{$b};
2710     if (ref $a eq 'HASH') {
2711       my ($a_key) = keys %{$a};
2712       if ($a_key eq $b_key) {
2713         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2714       } else {
2715         return 0;
2716       }
2717     } else {
2718       return ($a eq $b_key) ? 1 : 0;
2719     }
2720   } else {
2721     if (ref $a eq 'HASH') {
2722       my ($a_key) = keys %{$a};
2723       return ($b eq $a_key) ? 1 : 0;
2724     } else {
2725       return ($b eq $a) ? 1 : 0;
2726     }
2727   }
2728 }
2729
2730 sub _merge_attr {
2731   my ($self, $orig, $import) = @_;
2732
2733   return $import unless defined($orig);
2734   return $orig unless defined($import);
2735
2736   $orig = $self->_rollout_attr($orig);
2737   $import = $self->_rollout_attr($import);
2738
2739   my $seen_keys;
2740   foreach my $import_element ( @{$import} ) {
2741     # find best candidate from $orig to merge $b_element into
2742     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2743     foreach my $orig_element ( @{$orig} ) {
2744       my $score = $self->_calculate_score( $orig_element, $import_element );
2745       if ($score > $best_candidate->{score}) {
2746         $best_candidate->{position} = $position;
2747         $best_candidate->{score} = $score;
2748       }
2749       $position++;
2750     }
2751     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2752
2753     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2754       push( @{$orig}, $import_element );
2755     } else {
2756       my $orig_best = $orig->[$best_candidate->{position}];
2757       # merge orig_best and b_element together and replace original with merged
2758       if (ref $orig_best ne 'HASH') {
2759         $orig->[$best_candidate->{position}] = $import_element;
2760       } elsif (ref $import_element eq 'HASH') {
2761         my ($key) = keys %{$orig_best};
2762         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2763       }
2764     }
2765     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2766   }
2767
2768   return $orig;
2769 }
2770
2771 sub result_source {
2772     my $self = shift;
2773
2774     if (@_) {
2775         $self->_source_handle($_[0]->handle);
2776     } else {
2777         $self->_source_handle->resolve;
2778     }
2779 }
2780
2781 =head2 throw_exception
2782
2783 See L<DBIx::Class::Schema/throw_exception> for details.
2784
2785 =cut
2786
2787 sub throw_exception {
2788   my $self=shift;
2789   if (ref $self && $self->_source_handle->schema) {
2790     $self->_source_handle->schema->throw_exception(@_)
2791   } else {
2792     croak(@_);
2793   }
2794
2795 }
2796
2797 # XXX: FIXME: Attributes docs need clearing up
2798
2799 =head1 ATTRIBUTES
2800
2801 Attributes are used to refine a ResultSet in various ways when
2802 searching for data. They can be passed to any method which takes an
2803 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2804 L</count>.
2805
2806 These are in no particular order:
2807
2808 =head2 order_by
2809
2810 =over 4
2811
2812 =item Value: ( $order_by | \@order_by | \%order_by )
2813
2814 =back
2815
2816 Which column(s) to order the results by. If a single column name, or
2817 an arrayref of names is supplied, the argument is passed through
2818 directly to SQL. The hashref syntax allows for connection-agnostic
2819 specification of ordering direction:
2820
2821  For descending order:
2822
2823   order_by => { -desc => [qw/col1 col2 col3/] }
2824
2825  For explicit ascending order:
2826
2827   order_by => { -asc => 'col' }
2828
2829 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2830 supported, although you are strongly encouraged to use the hashref
2831 syntax as outlined above.
2832
2833 =head2 columns
2834
2835 =over 4
2836
2837 =item Value: \@columns
2838
2839 =back
2840
2841 Shortcut to request a particular set of columns to be retrieved. Each
2842 column spec may be a string (a table column name), or a hash (in which
2843 case the key is the C<as> value, and the value is used as the C<select>
2844 expression). Adds C<me.> onto the start of any column without a C<.> in
2845 it and sets C<select> from that, then auto-populates C<as> from
2846 C<select> as normal. (You may also use the C<cols> attribute, as in
2847 earlier versions of DBIC.)
2848
2849 =head2 +columns
2850
2851 =over 4
2852
2853 =item Value: \@columns
2854
2855 =back
2856
2857 Indicates additional columns to be selected from storage. Works the same
2858 as L</columns> but adds columns to the selection. (You may also use the
2859 C<include_columns> attribute, as in earlier versions of DBIC). For
2860 example:-
2861
2862   $schema->resultset('CD')->search(undef, {
2863     '+columns' => ['artist.name'],
2864     join => ['artist']
2865   });
2866
2867 would return all CDs and include a 'name' column to the information
2868 passed to object inflation. Note that the 'artist' is the name of the
2869 column (or relationship) accessor, and 'name' is the name of the column
2870 accessor in the related table.
2871
2872 =head2 include_columns
2873
2874 =over 4
2875
2876 =item Value: \@columns
2877
2878 =back
2879
2880 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2881
2882 =head2 select
2883
2884 =over 4
2885
2886 =item Value: \@select_columns
2887
2888 =back
2889
2890 Indicates which columns should be selected from the storage. You can use
2891 column names, or in the case of RDBMS back ends, function or stored procedure
2892 names:
2893
2894   $rs = $schema->resultset('Employee')->search(undef, {
2895     select => [
2896       'name',
2897       { count => 'employeeid' },
2898       { sum => 'salary' }
2899     ]
2900   });
2901
2902 When you use function/stored procedure names and do not supply an C<as>
2903 attribute, the column names returned are storage-dependent. E.g. MySQL would
2904 return a column named C<count(employeeid)> in the above example.
2905
2906 =head2 +select
2907
2908 =over 4
2909
2910 Indicates additional columns to be selected from storage.  Works the same as
2911 L</select> but adds columns to the selection.
2912
2913 =back
2914
2915 =head2 +as
2916
2917 =over 4
2918
2919 Indicates additional column names for those added via L</+select>. See L</as>.
2920
2921 =back
2922
2923 =head2 as
2924
2925 =over 4
2926
2927 =item Value: \@inflation_names
2928
2929 =back
2930
2931 Indicates column names for object inflation. That is, C<as>
2932 indicates the name that the column can be accessed as via the
2933 C<get_column> method (or via the object accessor, B<if one already
2934 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2935
2936 The C<as> attribute is used in conjunction with C<select>,
2937 usually when C<select> contains one or more function or stored
2938 procedure names:
2939
2940   $rs = $schema->resultset('Employee')->search(undef, {
2941     select => [
2942       'name',
2943       { count => 'employeeid' }
2944     ],
2945     as => ['name', 'employee_count'],
2946   });
2947
2948   my $employee = $rs->first(); # get the first Employee
2949
2950 If the object against which the search is performed already has an accessor
2951 matching a column name specified in C<as>, the value can be retrieved using
2952 the accessor as normal:
2953
2954   my $name = $employee->name();
2955
2956 If on the other hand an accessor does not exist in the object, you need to
2957 use C<get_column> instead:
2958
2959   my $employee_count = $employee->get_column('employee_count');
2960
2961 You can create your own accessors if required - see
2962 L<DBIx::Class::Manual::Cookbook> for details.
2963
2964 Please note: This will NOT insert an C<AS employee_count> into the SQL
2965 statement produced, it is used for internal access only. Thus
2966 attempting to use the accessor in an C<order_by> clause or similar
2967 will fail miserably.
2968
2969 To get around this limitation, you can supply literal SQL to your
2970 C<select> attibute that contains the C<AS alias> text, eg:
2971
2972   select => [\'myfield AS alias']
2973
2974 =head2 join
2975
2976 =over 4
2977
2978 =item Value: ($rel_name | \@rel_names | \%rel_names)
2979
2980 =back
2981
2982 Contains a list of relationships that should be joined for this query.  For
2983 example:
2984
2985   # Get CDs by Nine Inch Nails
2986   my $rs = $schema->resultset('CD')->search(
2987     { 'artist.name' => 'Nine Inch Nails' },
2988     { join => 'artist' }
2989   );
2990
2991 Can also contain a hash reference to refer to the other relation's relations.
2992 For example:
2993
2994   package MyApp::Schema::Track;
2995   use base qw/DBIx::Class/;
2996   __PACKAGE__->table('track');
2997   __PACKAGE__->add_columns(qw/trackid cd position title/);
2998   __PACKAGE__->set_primary_key('trackid');
2999   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3000   1;
3001
3002   # In your application
3003   my $rs = $schema->resultset('Artist')->search(
3004     { 'track.title' => 'Teardrop' },
3005     {
3006       join     => { cd => 'track' },
3007       order_by => 'artist.name',
3008     }
3009   );
3010
3011 You need to use the relationship (not the table) name in  conditions,
3012 because they are aliased as such. The current table is aliased as "me", so
3013 you need to use me.column_name in order to avoid ambiguity. For example:
3014
3015   # Get CDs from 1984 with a 'Foo' track
3016   my $rs = $schema->resultset('CD')->search(
3017     {
3018       'me.year' => 1984,
3019       'tracks.name' => 'Foo'
3020     },
3021     { join => 'tracks' }
3022   );
3023
3024 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3025 similarly for a third time). For e.g.
3026
3027   my $rs = $schema->resultset('Artist')->search({
3028     'cds.title'   => 'Down to Earth',
3029     'cds_2.title' => 'Popular',
3030   }, {
3031     join => [ qw/cds cds/ ],
3032   });
3033
3034 will return a set of all artists that have both a cd with title 'Down
3035 to Earth' and a cd with title 'Popular'.
3036
3037 If you want to fetch related objects from other tables as well, see C<prefetch>
3038 below.
3039
3040 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3041
3042 =head2 prefetch
3043
3044 =over 4
3045
3046 =item Value: ($rel_name | \@rel_names | \%rel_names)
3047
3048 =back
3049
3050 Contains one or more relationships that should be fetched along with
3051 the main query (when they are accessed afterwards the data will
3052 already be available, without extra queries to the database).  This is
3053 useful for when you know you will need the related objects, because it
3054 saves at least one query:
3055
3056   my $rs = $schema->resultset('Tag')->search(
3057     undef,
3058     {
3059       prefetch => {
3060         cd => 'artist'
3061       }
3062     }
3063   );
3064
3065 The initial search results in SQL like the following:
3066
3067   SELECT tag.*, cd.*, artist.* FROM tag
3068   JOIN cd ON tag.cd = cd.cdid
3069   JOIN artist ON cd.artist = artist.artistid
3070
3071 L<DBIx::Class> has no need to go back to the database when we access the
3072 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3073 case.
3074
3075 Simple prefetches will be joined automatically, so there is no need
3076 for a C<join> attribute in the above search.
3077
3078 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3079 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3080 with an accessor type of 'single' or 'filter'). A more complex example that
3081 prefetches an artists cds, the tracks on those cds, and the tags associted
3082 with that artist is given below (assuming many-to-many from artists to tags):
3083
3084  my $rs = $schema->resultset('Artist')->search(
3085    undef,
3086    {
3087      prefetch => [
3088        { cds => 'tracks' },
3089        { artist_tags => 'tags' }
3090      ]
3091    }
3092  );
3093
3094
3095 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3096 attributes will be ignored.
3097
3098 =head2 page
3099
3100 =over 4
3101
3102 =item Value: $page
3103
3104 =back
3105
3106 Makes the resultset paged and specifies the page to retrieve. Effectively
3107 identical to creating a non-pages resultset and then calling ->page($page)
3108 on it.
3109
3110 If L<rows> attribute is not specified it defualts to 10 rows per page.
3111
3112 When you have a paged resultset, L</count> will only return the number
3113 of rows in the page. To get the total, use the L</pager> and call
3114 C<total_entries> on it.
3115
3116 =head2 rows
3117
3118 =over 4
3119
3120 =item Value: $rows
3121
3122 =back
3123
3124 Specifes the maximum number of rows for direct retrieval or the number of
3125 rows per page if the page attribute or method is used.
3126
3127 =head2 offset
3128
3129 =over 4
3130
3131 =item Value: $offset
3132
3133 =back
3134
3135 Specifies the (zero-based) row number for the  first row to be returned, or the
3136 of the first row of the first page if paging is used.
3137
3138 =head2 group_by
3139
3140 =over 4
3141
3142 =item Value: \@columns
3143
3144 =back
3145
3146 A arrayref of columns to group by. Can include columns of joined tables.
3147
3148   group_by => [qw/ column1 column2 ... /]
3149
3150 =head2 having
3151
3152 =over 4
3153
3154 =item Value: $condition
3155
3156 =back
3157
3158 HAVING is a select statement attribute that is applied between GROUP BY and
3159 ORDER BY. It is applied to the after the grouping calculations have been
3160 done.
3161
3162   having => { 'count(employee)' => { '>=', 100 } }
3163
3164 =head2 distinct
3165
3166 =over 4
3167
3168 =item Value: (0 | 1)
3169
3170 =back
3171
3172 Set to 1 to group by all columns.
3173
3174 =head2 where
3175
3176 =over 4
3177
3178 Adds to the WHERE clause.
3179
3180   # only return rows WHERE deleted IS NULL for all searches
3181   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3182
3183 Can be overridden by passing C<{ where => undef }> as an attribute
3184 to a resulset.
3185
3186 =back
3187
3188 =head2 cache
3189
3190 Set to 1 to cache search results. This prevents extra SQL queries if you
3191 revisit rows in your ResultSet:
3192
3193   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3194
3195   while( my $artist = $resultset->next ) {
3196     ... do stuff ...
3197   }
3198
3199   $rs->first; # without cache, this would issue a query
3200
3201 By default, searches are not cached.
3202
3203 For more examples of using these attributes, see
3204 L<DBIx::Class::Manual::Cookbook>.
3205
3206 =head2 from
3207
3208 =over 4
3209
3210 =item Value: \@from_clause
3211
3212 =back
3213
3214 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3215 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3216 clauses.
3217
3218 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3219
3220 C<join> will usually do what you need and it is strongly recommended that you
3221 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3222 And we really do mean "cannot", not just tried and failed. Attempting to use
3223 this because you're having problems with C<join> is like trying to use x86
3224 ASM because you've got a syntax error in your C. Trust us on this.
3225
3226 Now, if you're still really, really sure you need to use this (and if you're
3227 not 100% sure, ask the mailing list first), here's an explanation of how this
3228 works.
3229
3230 The syntax is as follows -
3231
3232   [
3233     { <alias1> => <table1> },
3234     [
3235       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3236       [], # nested JOIN (optional)
3237       { <table1.column1> => <table2.column2>, ... (more conditions) },
3238     ],
3239     # More of the above [ ] may follow for additional joins
3240   ]
3241
3242   <table1> <alias1>
3243   JOIN
3244     <table2> <alias2>
3245     [JOIN ...]
3246   ON <table1.column1> = <table2.column2>
3247   <more joins may follow>
3248
3249 An easy way to follow the examples below is to remember the following:
3250
3251     Anything inside "[]" is a JOIN
3252     Anything inside "{}" is a condition for the enclosing JOIN
3253
3254 The following examples utilize a "person" table in a family tree application.
3255 In order to express parent->child relationships, this table is self-joined:
3256
3257     # Person->belongs_to('father' => 'Person');
3258     # Person->belongs_to('mother' => 'Person');
3259
3260 C<from> can be used to nest joins. Here we return all children with a father,
3261 then search against all mothers of those children:
3262
3263   $rs = $schema->resultset('Person')->search(
3264       undef,
3265       {
3266           alias => 'mother', # alias columns in accordance with "from"
3267           from => [
3268               { mother => 'person' },
3269               [
3270                   [
3271                       { child => 'person' },
3272                       [
3273                           { father => 'person' },
3274                           { 'father.person_id' => 'child.father_id' }
3275                       ]
3276                   ],
3277                   { 'mother.person_id' => 'child.mother_id' }
3278               ],
3279           ]
3280       },
3281   );
3282
3283   # Equivalent SQL:
3284   # SELECT mother.* FROM person mother
3285   # JOIN (
3286   #   person child
3287   #   JOIN person father
3288   #   ON ( father.person_id = child.father_id )
3289   # )
3290   # ON ( mother.person_id = child.mother_id )
3291
3292 The type of any join can be controlled manually. To search against only people
3293 with a father in the person table, we could explicitly use C<INNER JOIN>:
3294
3295     $rs = $schema->resultset('Person')->search(
3296         undef,
3297         {
3298             alias => 'child', # alias columns in accordance with "from"
3299             from => [
3300                 { child => 'person' },
3301                 [
3302                     { father => 'person', -join_type => 'inner' },
3303                     { 'father.id' => 'child.father_id' }
3304                 ],
3305             ]
3306         },
3307     );
3308
3309     # Equivalent SQL:
3310     # SELECT child.* FROM person child
3311     # INNER JOIN person father ON child.father_id = father.id
3312
3313 You can select from a subquery by passing a resultset to from as follows.
3314
3315     $schema->resultset('Artist')->search(
3316         undef,
3317         {   alias => 'artist2',
3318             from  => [ { artist2 => $artist_rs->as_query } ],
3319         } );
3320
3321     # and you'll get sql like this..
3322     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3323     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3324
3325 If you need to express really complex joins, you
3326 can supply literal SQL to C<from> via a scalar reference. In this case
3327 the contents of the scalar will replace the table name associated with the
3328 resultsource.
3329
3330 WARNING: This technique might very well not work as expected on chained
3331 searches - you have been warned.
3332
3333     # Assuming the Event resultsource is defined as:
3334
3335         MySchema::Event->add_columns (
3336             sequence => {
3337                 data_type => 'INT',
3338                 is_auto_increment => 1,
3339             },
3340             location => {
3341                 data_type => 'INT',
3342             },
3343             type => {
3344                 data_type => 'INT',
3345             },
3346         );
3347         MySchema::Event->set_primary_key ('sequence');
3348
3349     # This will get back the latest event for every location. The column
3350     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3351     # combo to limit the resultset
3352
3353     $rs = $schema->resultset('Event');
3354     $table = $rs->result_source->name;
3355     $latest = $rs->search (
3356         undef,
3357         { from => \ "
3358             (SELECT e1.* FROM $table e1
3359                 JOIN $table e2
3360                     ON e1.location = e2.location
3361                     AND e1.sequence < e2.sequence
3362                 WHERE e2.sequence is NULL
3363             ) me",
3364         },
3365     );
3366
3367     # Equivalent SQL (with the DBIC chunks added):
3368
3369     SELECT me.sequence, me.location, me.type FROM
3370        (SELECT e1.* FROM events e1
3371            JOIN events e2
3372                ON e1.location = e2.location
3373                AND e1.sequence < e2.sequence
3374            WHERE e2.sequence is NULL
3375        ) me;
3376
3377 =head2 for
3378
3379 =over 4
3380
3381 =item Value: ( 'update' | 'shared' )
3382
3383 =back
3384
3385 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3386 ... FOR SHARED.
3387
3388 =cut
3389
3390 1;