lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960
 961   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 962     or return ();
 963   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 964   @new = $self->{_attrs}{record_filter}->(@new)
 965     if exists $self->{_attrs}{record_filter};
 966   return @new;
 967 }
 968
 969 sub _collapse_result {
 970   my ($self, $as_proto, $row) = @_;
 971
 972   # if the first row that ever came in is totally empty - this means we got
 973   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 974   # instead of producing a {}
 975   #
 976   my $has_def;
 977   for (@$row) {
 978     if (defined $_) {
 979       $has_def++;
 980       last;
 981     }
 982   }
 983   return undef unless $has_def;
 984
 985   my @copy = @$row;
 986
 987   # 'foo'         => [ undef, 'foo' ]
 988   # 'foo.bar'     => [ 'foo', 'bar' ]
 989   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 990
 991   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 992
 993   my %collapse = %{$self->{_attrs}{collapse}||{}};
 994
 995   my @pri_index;
 996
 997   # if we're doing collapsing (has_many prefetch) we need to grab records
 998   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 999   # we know we don't have to bother.
1000
1001   # the reason for not using the collapse stuff directly is because if you
1002   # had for e.g. two artists in a row with no cds, the collapse info for
1003   # both would be NULL (undef) so you'd lose the second artist
1004
1005   # store just the index so we can check the array positions from the row
1006   # without having to contruct the full hash
1007
1008   if (keys %collapse) {
1009     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1010     foreach my $i (0 .. $#construct_as) {
1011       next if defined($construct_as[$i][0]); # only self table
1012       if (delete $pri{$construct_as[$i][1]}) {
1013         push(@pri_index, $i);
1014       }
1015       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1016     }
1017   }
1018
1019   # no need to do an if, it'll be empty if @pri_index is empty anyway
1020
1021   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1022
1023   my @const_rows;
1024
1025   do { # no need to check anything at the front, we always want the first row
1026
1027     my %const;
1028
1029     foreach my $this_as (@construct_as) {
1030       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1031     }
1032
1033     push(@const_rows, \%const);
1034
1035   } until ( # no pri_index => no collapse => drop straight out
1036       !@pri_index
1037     or
1038       do { # get another row, stash it, drop out if different PK
1039
1040         @copy = $self->cursor->next;
1041         $self->{stashed_row} = \@copy;
1042
1043         # last thing in do block, counts as true if anything doesn't match
1044
1045         # check xor defined first for NULL vs. NOT NULL then if one is
1046         # defined the other must be so check string equality
1047
1048         grep {
1049           (defined $pri_vals{$_} ^ defined $copy[$_])
1050           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1051         } @pri_index;
1052       }
1053   );
1054
1055   my $alias = $self->{attrs}{alias};
1056   my $info = [];
1057
1058   my %collapse_pos;
1059
1060   my @const_keys;
1061
1062   foreach my $const (@const_rows) {
1063     scalar @const_keys or do {
1064       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1065     };
1066     foreach my $key (@const_keys) {
1067       if (length $key) {
1068         my $target = $info;
1069         my @parts = split(/\./, $key);
1070         my $cur = '';
1071         my $data = $const->{$key};
1072         foreach my $p (@parts) {
1073           $target = $target->[1]->{$p} ||= [];
1074           $cur .= ".${p}";
1075           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1076             # collapsing at this point and on final part
1077             my $pos = $collapse_pos{$cur};
1078             CK: foreach my $ck (@ckey) {
1079               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1080                 $collapse_pos{$cur} = $data;
1081                 delete @collapse_pos{ # clear all positioning for sub-entries
1082                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1083                 };
1084                 push(@$target, []);
1085                 last CK;
1086               }
1087             }
1088           }
1089           if (exists $collapse{$cur}) {
1090             $target = $target->[-1];
1091           }
1092         }
1093         $target->[0] = $data;
1094       } else {
1095         $info->[0] = $const->{$key};
1096       }
1097     }
1098   }
1099
1100   return $info;
1101 }
1102
1103 =head2 result_source
1104
1105 =over 4
1106
1107 =item Arguments: $result_source?
1108
1109 =item Return Value: $result_source
1110
1111 =back
1112
1113 An accessor for the primary ResultSource object from which this ResultSet
1114 is derived.
1115
1116 =head2 result_class
1117
1118 =over 4
1119
1120 =item Arguments: $result_class?
1121
1122 =item Return Value: $result_class
1123
1124 =back
1125
1126 An accessor for the class to use when creating row objects. Defaults to
1127 C<< result_source->result_class >> - which in most cases is the name of the
1128 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1129
1130 Note that changing the result_class will also remove any components
1131 that were originally loaded in the source class via
1132 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1133 in the original source class will not run.
1134
1135 =cut
1136
1137 sub result_class {
1138   my ($self, $result_class) = @_;
1139   if ($result_class) {
1140     $self->ensure_class_loaded($result_class);
1141     $self->_result_class($result_class);
1142   }
1143   $self->_result_class;
1144 }
1145
1146 =head2 count
1147
1148 =over 4
1149
1150 =item Arguments: $cond, \%attrs??
1151
1152 =item Return Value: $count
1153
1154 =back
1155
1156 Performs an SQL C<COUNT> with the same query as the resultset was built
1157 with to find the number of elements. Passing arguments is equivalent to
1158 C<< $rs->search ($cond, \%attrs)->count >>
1159
1160 =cut
1161
1162 sub count {
1163   my $self = shift;
1164   return $self->search(@_)->count if @_ and defined $_[0];
1165   return scalar @{ $self->get_cache } if $self->get_cache;
1166
1167   my $attrs = $self->_resolved_attrs_copy;
1168
1169   # this is a little optimization - it is faster to do the limit
1170   # adjustments in software, instead of a subquery
1171   my $rows = delete $attrs->{rows};
1172   my $offset = delete $attrs->{offset};
1173
1174   my $crs;
1175   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1176     $crs = $self->_count_subq_rs ($attrs);
1177   }
1178   else {
1179     $crs = $self->_count_rs ($attrs);
1180   }
1181   my $count = $crs->next;
1182
1183   $count -= $offset if $offset;
1184   $count = $rows if $rows and $rows < $count;
1185   $count = 0 if ($count < 0);
1186
1187   return $count;
1188 }
1189
1190 =head2 count_rs
1191
1192 =over 4
1193
1194 =item Arguments: $cond, \%attrs??
1195
1196 =item Return Value: $count_rs
1197
1198 =back
1199
1200 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1201 This can be very handy for subqueries:
1202
1203   ->search( { amount => $some_rs->count_rs->as_query } )
1204
1205 As with regular resultsets the SQL query will be executed only after
1206 the resultset is accessed via L</next> or L</all>. That would return
1207 the same single value obtainable via L</count>.
1208
1209 =cut
1210
1211 sub count_rs {
1212   my $self = shift;
1213   return $self->search(@_)->count_rs if @_;
1214
1215   # this may look like a lack of abstraction (count() does about the same)
1216   # but in fact an _rs *must* use a subquery for the limits, as the
1217   # software based limiting can not be ported if this $rs is to be used
1218   # in a subquery itself (i.e. ->as_query)
1219   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1220     return $self->_count_subq_rs;
1221   }
1222   else {
1223     return $self->_count_rs;
1224   }
1225 }
1226
1227 #
1228 # returns a ResultSetColumn object tied to the count query
1229 #
1230 sub _count_rs {
1231   my ($self, $attrs) = @_;
1232
1233   my $rsrc = $self->result_source;
1234   $attrs ||= $self->_resolved_attrs;
1235
1236   my $tmp_attrs = { %$attrs };
1237
1238   # take off any limits, record_filter is cdbi, and no point of ordering a count
1239   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1240
1241   # overwrite the selector (supplied by the storage)
1242   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1243   $tmp_attrs->{as} = 'count';
1244
1245   # read the comment on top of the actual function to see what this does
1246   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1247     $tmp_attrs->{from}, $tmp_attrs->{alias}
1248   );
1249
1250   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1251
1252   return $tmp_rs;
1253 }
1254
1255 #
1256 # same as above but uses a subquery
1257 #
1258 sub _count_subq_rs {
1259   my ($self, $attrs) = @_;
1260
1261   my $rsrc = $self->result_source;
1262   $attrs ||= $self->_resolved_attrs_copy;
1263
1264   my $sub_attrs = { %$attrs };
1265
1266   # extra selectors do not go in the subquery and there is no point of ordering it
1267   delete $sub_attrs->{$_} for qw/collapse prefetch_select select as order_by/;
1268
1269   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1270   # clobber old group_by regardless
1271   if ( keys %{$attrs->{collapse}} ) {
1272     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1273   }
1274
1275   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1276
1277   # read the comment on top of the actual function to see what this does
1278   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1279     $sub_attrs->{from}, $sub_attrs->{alias}
1280   );
1281
1282   $attrs->{from} = [{
1283     count_subq => $rsrc->resultset_class->new ($rsrc, $sub_attrs )->as_query
1284   }];
1285
1286   # the subquery replaces this
1287   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1288
1289   return $self->_count_rs ($attrs);
1290 }
1291
1292
1293 # The DBIC relationship chaining implementation is pretty simple - every
1294 # new related_relationship is pushed onto the {from} stack, and the {select}
1295 # window simply slides further in. This means that when we count somewhere
1296 # in the middle, we got to make sure that everything in the join chain is an
1297 # actual inner join, otherwise the count will come back with unpredictable
1298 # results (a resultset may be generated with _some_ rows regardless of if
1299 # the relation which the $rs currently selects has rows or not). E.g.
1300 # $artist_rs->cds->count - normally generates:
1301 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1302 # which actually returns the number of artists * (number of cds || 1)
1303 #
1304 # So what we do here is crawl {from}, determine if the current alias is at
1305 # the top of the stack, and if not - make sure the chain is inner-joined down
1306 # to the root.
1307 #
1308 sub _switch_to_inner_join_if_needed {
1309   my ($self, $from, $alias) = @_;
1310
1311   return $from if (
1312     ref $from ne 'ARRAY'
1313       ||
1314     ref $from->[0] ne 'HASH'
1315       ||
1316     ! $from->[0]{-alias}
1317       ||
1318     $from->[0]{-alias} eq $alias
1319   );
1320
1321   # this would be the case with a subquery - we'll never find
1322   # the target as it is not in the parseable part of {from}
1323   return $from if @$from == 1;
1324
1325   my $switch_branch;
1326   JOINSCAN:
1327   for my $j (@{$from}[1 .. $#$from]) {
1328     if ($j->[0]{-alias} eq $alias) {
1329       $switch_branch = $j->[0]{-join_path};
1330       last JOINSCAN;
1331     }
1332   }
1333
1334   # something else went wrong
1335   return $from unless $switch_branch;
1336
1337   # So it looks like we will have to switch some stuff around.
1338   # local() is useless here as we will be leaving the scope
1339   # anyway, and deep cloning is just too fucking expensive
1340   # So replace the inner hashref manually
1341   my @new_from = ($from->[0]);
1342   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1343
1344   for my $j (@{$from}[1 .. $#$from]) {
1345     my $jalias = $j->[0]{-alias};
1346
1347     if ($sw_idx->{$jalias}) {
1348       my %attrs = %{$j->[0]};
1349       delete $attrs{-join_type};
1350       push @new_from, [
1351         \%attrs,
1352         @{$j}[ 1 .. $#$j ],
1353       ];
1354     }
1355     else {
1356       push @new_from, $j;
1357     }
1358   }
1359
1360   return \@new_from;
1361 }
1362
1363
1364 sub _bool {
1365   return 1;
1366 }
1367
1368 =head2 count_literal
1369
1370 =over 4
1371
1372 =item Arguments: $sql_fragment, @bind_values
1373
1374 =item Return Value: $count
1375
1376 =back
1377
1378 Counts the results in a literal query. Equivalent to calling L</search_literal>
1379 with the passed arguments, then L</count>.
1380
1381 =cut
1382
1383 sub count_literal { shift->search_literal(@_)->count; }
1384
1385 =head2 all
1386
1387 =over 4
1388
1389 =item Arguments: none
1390
1391 =item Return Value: @objects
1392
1393 =back
1394
1395 Returns all elements in the resultset. Called implicitly if the resultset
1396 is returned in list context.
1397
1398 =cut
1399
1400 sub all {
1401   my $self = shift;
1402   if(@_) {
1403       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1404   }
1405
1406   return @{ $self->get_cache } if $self->get_cache;
1407
1408   my @obj;
1409
1410   if (keys %{$self->_resolved_attrs->{collapse}}) {
1411     # Using $self->cursor->all is really just an optimisation.
1412     # If we're collapsing has_many prefetches it probably makes
1413     # very little difference, and this is cleaner than hacking
1414     # _construct_object to survive the approach
1415     $self->cursor->reset;
1416     my @row = $self->cursor->next;
1417     while (@row) {
1418       push(@obj, $self->_construct_object(@row));
1419       @row = (exists $self->{stashed_row}
1420                ? @{delete $self->{stashed_row}}
1421                : $self->cursor->next);
1422     }
1423   } else {
1424     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1425   }
1426
1427   $self->set_cache(\@obj) if $self->{attrs}{cache};
1428
1429   return @obj;
1430 }
1431
1432 =head2 reset
1433
1434 =over 4
1435
1436 =item Arguments: none
1437
1438 =item Return Value: $self
1439
1440 =back
1441
1442 Resets the resultset's cursor, so you can iterate through the elements again.
1443 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1444 another query.
1445
1446 =cut
1447
1448 sub reset {
1449   my ($self) = @_;
1450   delete $self->{_attrs} if exists $self->{_attrs};
1451   $self->{all_cache_position} = 0;
1452   $self->cursor->reset;
1453   return $self;
1454 }
1455
1456 =head2 first
1457
1458 =over 4
1459
1460 =item Arguments: none
1461
1462 =item Return Value: $object?
1463
1464 =back
1465
1466 Resets the resultset and returns an object for the first result (if the
1467 resultset returns anything).
1468
1469 =cut
1470
1471 sub first {
1472   return $_[0]->reset->next;
1473 }
1474
1475
1476 # _rs_update_delete
1477 #
1478 # Determines whether and what type of subquery is required for the $rs operation.
1479 # If grouping is necessary either supplies its own, or verifies the current one
1480 # After all is done delegates to the proper storage method.
1481
1482 sub _rs_update_delete {
1483   my ($self, $op, $values) = @_;
1484
1485   my $rsrc = $self->result_source;
1486
1487   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1488   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1489
1490   if ($needs_group_by_subq or $needs_subq) {
1491
1492     # make a new $rs selecting only the PKs (that's all we really need)
1493     my $attrs = $self->_resolved_attrs_copy;
1494
1495     delete $attrs->{$_} for qw/collapse select as/;
1496     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1497
1498     if ($needs_group_by_subq) {
1499       # make sure no group_by was supplied, or if there is one - make sure it matches
1500       # the columns compiled above perfectly. Anything else can not be sanely executed
1501       # on most databases so croak right then and there
1502
1503       if (my $g = $attrs->{group_by}) {
1504         my @current_group_by = map
1505           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1506           (ref $g eq 'ARRAY' ? @$g : $g );
1507
1508         if (
1509           join ("\x00", sort @current_group_by)
1510             ne
1511           join ("\x00", sort @{$attrs->{columns}} )
1512         ) {
1513           $self->throw_exception (
1514             "You have just attempted a $op operation on a resultset which does group_by"
1515             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1516             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1517             . ' kind of queries. Please retry the operation with a modified group_by or'
1518             . ' without using one at all.'
1519           );
1520         }
1521       }
1522       else {
1523         $attrs->{group_by} = $attrs->{columns};
1524       }
1525     }
1526
1527     my $subrs = (ref $self)->new($rsrc, $attrs);
1528
1529     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1530   }
1531   else {
1532     return $rsrc->storage->$op(
1533       $rsrc,
1534       $op eq 'update' ? $values : (),
1535       $self->_cond_for_update_delete,
1536     );
1537   }
1538 }
1539
1540
1541 # _cond_for_update_delete
1542 #
1543 # update/delete require the condition to be modified to handle
1544 # the differing SQL syntax available.  This transforms the $self->{cond}
1545 # appropriately, returning the new condition.
1546
1547 sub _cond_for_update_delete {
1548   my ($self, $full_cond) = @_;
1549   my $cond = {};
1550
1551   $full_cond ||= $self->{cond};
1552   # No-op. No condition, we're updating/deleting everything
1553   return $cond unless ref $full_cond;
1554
1555   if (ref $full_cond eq 'ARRAY') {
1556     $cond = [
1557       map {
1558         my %hash;
1559         foreach my $key (keys %{$_}) {
1560           $key =~ /([^.]+)$/;
1561           $hash{$1} = $_->{$key};
1562         }
1563         \%hash;
1564       } @{$full_cond}
1565     ];
1566   }
1567   elsif (ref $full_cond eq 'HASH') {
1568     if ((keys %{$full_cond})[0] eq '-and') {
1569       $cond->{-and} = [];
1570       my @cond = @{$full_cond->{-and}};
1571        for (my $i = 0; $i < @cond; $i++) {
1572         my $entry = $cond[$i];
1573         my $hash;
1574         if (ref $entry eq 'HASH') {
1575           $hash = $self->_cond_for_update_delete($entry);
1576         }
1577         else {
1578           $entry =~ /([^.]+)$/;
1579           $hash->{$1} = $cond[++$i];
1580         }
1581         push @{$cond->{-and}}, $hash;
1582       }
1583     }
1584     else {
1585       foreach my $key (keys %{$full_cond}) {
1586         $key =~ /([^.]+)$/;
1587         $cond->{$1} = $full_cond->{$key};
1588       }
1589     }
1590   }
1591   else {
1592     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1593   }
1594
1595   return $cond;
1596 }
1597
1598
1599 =head2 update
1600
1601 =over 4
1602
1603 =item Arguments: \%values
1604
1605 =item Return Value: $storage_rv
1606
1607 =back
1608
1609 Sets the specified columns in the resultset to the supplied values in a
1610 single query. Return value will be true if the update succeeded or false
1611 if no records were updated; exact type of success value is storage-dependent.
1612
1613 =cut
1614
1615 sub update {
1616   my ($self, $values) = @_;
1617   $self->throw_exception('Values for update must be a hash')
1618     unless ref $values eq 'HASH';
1619
1620   return $self->_rs_update_delete ('update', $values);
1621 }
1622
1623 =head2 update_all
1624
1625 =over 4
1626
1627 =item Arguments: \%values
1628
1629 =item Return Value: 1
1630
1631 =back
1632
1633 Fetches all objects and updates them one at a time. Note that C<update_all>
1634 will run DBIC cascade triggers, while L</update> will not.
1635
1636 =cut
1637
1638 sub update_all {
1639   my ($self, $values) = @_;
1640   $self->throw_exception('Values for update_all must be a hash')
1641     unless ref $values eq 'HASH';
1642   foreach my $obj ($self->all) {
1643     $obj->set_columns($values)->update;
1644   }
1645   return 1;
1646 }
1647
1648 =head2 delete
1649
1650 =over 4
1651
1652 =item Arguments: none
1653
1654 =item Return Value: $storage_rv
1655
1656 =back
1657
1658 Deletes the contents of the resultset from its result source. Note that this
1659 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1660 to run. See also L<DBIx::Class::Row/delete>.
1661
1662 Return value will be the amount of rows deleted; exact type of return value
1663 is storage-dependent.
1664
1665 =cut
1666
1667 sub delete {
1668   my $self = shift;
1669   $self->throw_exception('delete does not accept any arguments')
1670     if @_;
1671
1672   return $self->_rs_update_delete ('delete');
1673 }
1674
1675 =head2 delete_all
1676
1677 =over 4
1678
1679 =item Arguments: none
1680
1681 =item Return Value: 1
1682
1683 =back
1684
1685 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1686 will run DBIC cascade triggers, while L</delete> will not.
1687
1688 =cut
1689
1690 sub delete_all {
1691   my $self = shift;
1692   $self->throw_exception('delete_all does not accept any arguments')
1693     if @_;
1694
1695   $_->delete for $self->all;
1696   return 1;
1697 }
1698
1699 =head2 populate
1700
1701 =over 4
1702
1703 =item Arguments: \@data;
1704
1705 =back
1706
1707 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1708 For the arrayref of hashrefs style each hashref should be a structure suitable
1709 forsubmitting to a $resultset->create(...) method.
1710
1711 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1712 to insert the data, as this is a faster method.
1713
1714 Otherwise, each set of data is inserted into the database using
1715 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1716 accumulated into an array. The array itself, or an array reference
1717 is returned depending on scalar or list context.
1718
1719 Example:  Assuming an Artist Class that has many CDs Classes relating:
1720
1721   my $Artist_rs = $schema->resultset("Artist");
1722
1723   ## Void Context Example
1724   $Artist_rs->populate([
1725      { artistid => 4, name => 'Manufactured Crap', cds => [
1726         { title => 'My First CD', year => 2006 },
1727         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1728       ],
1729      },
1730      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1731         { title => 'My parents sold me to a record company' ,year => 2005 },
1732         { title => 'Why Am I So Ugly?', year => 2006 },
1733         { title => 'I Got Surgery and am now Popular', year => 2007 }
1734       ],
1735      },
1736   ]);
1737
1738   ## Array Context Example
1739   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1740     { name => "Artist One"},
1741     { name => "Artist Two"},
1742     { name => "Artist Three", cds=> [
1743     { title => "First CD", year => 2007},
1744     { title => "Second CD", year => 2008},
1745   ]}
1746   ]);
1747
1748   print $ArtistOne->name; ## response is 'Artist One'
1749   print $ArtistThree->cds->count ## reponse is '2'
1750
1751 For the arrayref of arrayrefs style,  the first element should be a list of the
1752 fieldsnames to which the remaining elements are rows being inserted.  For
1753 example:
1754
1755   $Arstist_rs->populate([
1756     [qw/artistid name/],
1757     [100, 'A Formally Unknown Singer'],
1758     [101, 'A singer that jumped the shark two albums ago'],
1759     [102, 'An actually cool singer.'],
1760   ]);
1761
1762 Please note an important effect on your data when choosing between void and
1763 wantarray context. Since void context goes straight to C<insert_bulk> in
1764 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1765 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1766 create primary keys for you, you will find that your PKs are empty.  In this
1767 case you will have to use the wantarray context in order to create those
1768 values.
1769
1770 =cut
1771
1772 sub populate {
1773   my $self = shift @_;
1774   my $data = ref $_[0][0] eq 'HASH'
1775     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1776     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1777
1778   if(defined wantarray) {
1779     my @created;
1780     foreach my $item (@$data) {
1781       push(@created, $self->create($item));
1782     }
1783     return wantarray ? @created : \@created;
1784   } else {
1785     my ($first, @rest) = @$data;
1786
1787     my @names = grep {!ref $first->{$_}} keys %$first;
1788     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1789     my @pks = $self->result_source->primary_columns;
1790
1791     ## do the belongs_to relationships
1792     foreach my $index (0..$#$data) {
1793
1794       # delegate to create() for any dataset without primary keys with specified relationships
1795       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1796         for my $r (@rels) {
1797           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1798             my @ret = $self->populate($data);
1799             return;
1800           }
1801         }
1802       }
1803
1804       foreach my $rel (@rels) {
1805         next unless ref $data->[$index]->{$rel} eq "HASH";
1806         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1807         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1808         my $related = $result->result_source->_resolve_condition(
1809           $result->result_source->relationship_info($reverse)->{cond},
1810           $self,
1811           $result,
1812         );
1813
1814         delete $data->[$index]->{$rel};
1815         $data->[$index] = {%{$data->[$index]}, %$related};
1816
1817         push @names, keys %$related if $index == 0;
1818       }
1819     }
1820
1821     ## do bulk insert on current row
1822     my @values = map { [ @$_{@names} ] } @$data;
1823
1824     $self->result_source->storage->insert_bulk(
1825       $self->result_source,
1826       \@names,
1827       \@values,
1828     );
1829
1830     ## do the has_many relationships
1831     foreach my $item (@$data) {
1832
1833       foreach my $rel (@rels) {
1834         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1835
1836         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1837      || $self->throw_exception('Cannot find the relating object.');
1838
1839         my $child = $parent->$rel;
1840
1841         my $related = $child->result_source->_resolve_condition(
1842           $parent->result_source->relationship_info($rel)->{cond},
1843           $child,
1844           $parent,
1845         );
1846
1847         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1848         my @populate = map { {%$_, %$related} } @rows_to_add;
1849
1850         $child->populate( \@populate );
1851       }
1852     }
1853   }
1854 }
1855
1856 =head2 _normalize_populate_args ($args)
1857
1858 Private method used by L</populate> to normalize its incoming arguments.  Factored
1859 out in case you want to subclass and accept new argument structures to the
1860 L</populate> method.
1861
1862 =cut
1863
1864 sub _normalize_populate_args {
1865   my ($self, $data) = @_;
1866   my @names = @{shift(@$data)};
1867   my @results_to_create;
1868   foreach my $datum (@$data) {
1869     my %result_to_create;
1870     foreach my $index (0..$#names) {
1871       $result_to_create{$names[$index]} = $$datum[$index];
1872     }
1873     push @results_to_create, \%result_to_create;
1874   }
1875   return \@results_to_create;
1876 }
1877
1878 =head2 pager
1879
1880 =over 4
1881
1882 =item Arguments: none
1883
1884 =item Return Value: $pager
1885
1886 =back
1887
1888 Return Value a L<Data::Page> object for the current resultset. Only makes
1889 sense for queries with a C<page> attribute.
1890
1891 To get the full count of entries for a paged resultset, call
1892 C<total_entries> on the L<Data::Page> object.
1893
1894 =cut
1895
1896 sub pager {
1897   my ($self) = @_;
1898
1899   return $self->{pager} if $self->{pager};
1900
1901   my $attrs = $self->{attrs};
1902   $self->throw_exception("Can't create pager for non-paged rs")
1903     unless $self->{attrs}{page};
1904   $attrs->{rows} ||= 10;
1905
1906   # throw away the paging flags and re-run the count (possibly
1907   # with a subselect) to get the real total count
1908   my $count_attrs = { %$attrs };
1909   delete $count_attrs->{$_} for qw/rows offset page pager/;
1910   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1911
1912   return $self->{pager} = Data::Page->new(
1913     $total_count,
1914     $attrs->{rows},
1915     $self->{attrs}{page}
1916   );
1917 }
1918
1919 =head2 page
1920
1921 =over 4
1922
1923 =item Arguments: $page_number
1924
1925 =item Return Value: $rs
1926
1927 =back
1928
1929 Returns a resultset for the $page_number page of the resultset on which page
1930 is called, where each page contains a number of rows equal to the 'rows'
1931 attribute set on the resultset (10 by default).
1932
1933 =cut
1934
1935 sub page {
1936   my ($self, $page) = @_;
1937   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1938 }
1939
1940 =head2 new_result
1941
1942 =over 4
1943
1944 =item Arguments: \%vals
1945
1946 =item Return Value: $rowobject
1947
1948 =back
1949
1950 Creates a new row object in the resultset's result class and returns
1951 it. The row is not inserted into the database at this point, call
1952 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1953 will tell you whether the row object has been inserted or not.
1954
1955 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1956
1957 =cut
1958
1959 sub new_result {
1960   my ($self, $values) = @_;
1961   $self->throw_exception( "new_result needs a hash" )
1962     unless (ref $values eq 'HASH');
1963
1964   my %new;
1965   my $alias = $self->{attrs}{alias};
1966
1967   if (
1968     defined $self->{cond}
1969     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1970   ) {
1971     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1972     $new{-from_resultset} = [ keys %new ] if keys %new;
1973   } else {
1974     $self->throw_exception(
1975       "Can't abstract implicit construct, condition not a hash"
1976     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1977
1978     my $collapsed_cond = (
1979       $self->{cond}
1980         ? $self->_collapse_cond($self->{cond})
1981         : {}
1982     );
1983
1984     # precendence must be given to passed values over values inherited from
1985     # the cond, so the order here is important.
1986     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1987     while( my($col,$value) = each %implied ){
1988       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1989         $new{$col} = $value->{'='};
1990         next;
1991       }
1992       $new{$col} = $value if $self->_is_deterministic_value($value);
1993     }
1994   }
1995
1996   %new = (
1997     %new,
1998     %{ $self->_remove_alias($values, $alias) },
1999     -source_handle => $self->_source_handle,
2000     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2001   );
2002
2003   return $self->result_class->new(\%new);
2004 }
2005
2006 # _is_deterministic_value
2007 #
2008 # Make an effor to strip non-deterministic values from the condition,
2009 # to make sure new_result chokes less
2010
2011 sub _is_deterministic_value {
2012   my $self = shift;
2013   my $value = shift;
2014   my $ref_type = ref $value;
2015   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2016   return 1 if Scalar::Util::blessed($value);
2017   return 0;
2018 }
2019
2020 # _has_resolved_attr
2021 #
2022 # determines if the resultset defines at least one
2023 # of the attributes supplied
2024 #
2025 # used to determine if a subquery is neccessary
2026 #
2027 # supports some virtual attributes:
2028 #   -join
2029 #     This will scan for any joins being present on the resultset.
2030 #     It is not a mere key-search but a deep inspection of {from}
2031 #
2032
2033 sub _has_resolved_attr {
2034   my ($self, @attr_names) = @_;
2035
2036   my $attrs = $self->_resolved_attrs;
2037
2038   my %extra_checks;
2039
2040   for my $n (@attr_names) {
2041     if (grep { $n eq $_ } (qw/-join/) ) {
2042       $extra_checks{$n}++;
2043       next;
2044     }
2045
2046     my $attr =  $attrs->{$n};
2047
2048     next if not defined $attr;
2049
2050     if (ref $attr eq 'HASH') {
2051       return 1 if keys %$attr;
2052     }
2053     elsif (ref $attr eq 'ARRAY') {
2054       return 1 if @$attr;
2055     }
2056     else {
2057       return 1 if $attr;
2058     }
2059   }
2060
2061   # a resolved join is expressed as a multi-level from
2062   return 1 if (
2063     $extra_checks{-join}
2064       and
2065     ref $attrs->{from} eq 'ARRAY'
2066       and
2067     @{$attrs->{from}} > 1
2068   );
2069
2070   return 0;
2071 }
2072
2073 # _collapse_cond
2074 #
2075 # Recursively collapse the condition.
2076
2077 sub _collapse_cond {
2078   my ($self, $cond, $collapsed) = @_;
2079
2080   $collapsed ||= {};
2081
2082   if (ref $cond eq 'ARRAY') {
2083     foreach my $subcond (@$cond) {
2084       next unless ref $subcond;  # -or
2085       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2086     }
2087   }
2088   elsif (ref $cond eq 'HASH') {
2089     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2090       foreach my $subcond (@{$cond->{-and}}) {
2091         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2092       }
2093     }
2094     else {
2095       foreach my $col (keys %$cond) {
2096         my $value = $cond->{$col};
2097         $collapsed->{$col} = $value;
2098       }
2099     }
2100   }
2101
2102   return $collapsed;
2103 }
2104
2105 # _remove_alias
2106 #
2107 # Remove the specified alias from the specified query hash. A copy is made so
2108 # the original query is not modified.
2109
2110 sub _remove_alias {
2111   my ($self, $query, $alias) = @_;
2112
2113   my %orig = %{ $query || {} };
2114   my %unaliased;
2115
2116   foreach my $key (keys %orig) {
2117     if ($key !~ /\./) {
2118       $unaliased{$key} = $orig{$key};
2119       next;
2120     }
2121     $unaliased{$1} = $orig{$key}
2122       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2123   }
2124
2125   return \%unaliased;
2126 }
2127
2128 =head2 as_query (EXPERIMENTAL)
2129
2130 =over 4
2131
2132 =item Arguments: none
2133
2134 =item Return Value: \[ $sql, @bind ]
2135
2136 =back
2137
2138 Returns the SQL query and bind vars associated with the invocant.
2139
2140 This is generally used as the RHS for a subquery.
2141
2142 B<NOTE>: This feature is still experimental.
2143
2144 =cut
2145
2146 sub as_query {
2147   my $self = shift;
2148
2149   my $attrs = $self->_resolved_attrs_copy;
2150
2151   # For future use:
2152   #
2153   # in list ctx:
2154   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2155   # $sql also has no wrapping parenthesis in list ctx
2156   #
2157   my $sqlbind = $self->result_source->storage
2158     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2159
2160   return $sqlbind;
2161 }
2162
2163 =head2 find_or_new
2164
2165 =over 4
2166
2167 =item Arguments: \%vals, \%attrs?
2168
2169 =item Return Value: $rowobject
2170
2171 =back
2172
2173   my $artist = $schema->resultset('Artist')->find_or_new(
2174     { artist => 'fred' }, { key => 'artists' });
2175
2176   $cd->cd_to_producer->find_or_new({ producer => $producer },
2177                                    { key => 'primary });
2178
2179 Find an existing record from this resultset, based on its primary
2180 key, or a unique constraint. If none exists, instantiate a new result
2181 object and return it. The object will not be saved into your storage
2182 until you call L<DBIx::Class::Row/insert> on it.
2183
2184 You most likely want this method when looking for existing rows using
2185 a unique constraint that is not the primary key, or looking for
2186 related rows.
2187
2188 If you want objects to be saved immediately, use L</find_or_create> instead.
2189
2190 B<Note>: C<find_or_new> is probably not what you want when creating a
2191 new row in a table that uses primary keys supplied by the
2192 database. Passing in a primary key column with a value of I<undef>
2193 will cause L</find> to attempt to search for a row with a value of
2194 I<NULL>.
2195
2196 =cut
2197
2198 sub find_or_new {
2199   my $self     = shift;
2200   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2201   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2202   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2203     return $row;
2204   }
2205   return $self->new_result($hash);
2206 }
2207
2208 =head2 create
2209
2210 =over 4
2211
2212 =item Arguments: \%vals
2213
2214 =item Return Value: a L<DBIx::Class::Row> $object
2215
2216 =back
2217
2218 Attempt to create a single new row or a row with multiple related rows
2219 in the table represented by the resultset (and related tables). This
2220 will not check for duplicate rows before inserting, use
2221 L</find_or_create> to do that.
2222
2223 To create one row for this resultset, pass a hashref of key/value
2224 pairs representing the columns of the table and the values you wish to
2225 store. If the appropriate relationships are set up, foreign key fields
2226 can also be passed an object representing the foreign row, and the
2227 value will be set to its primary key.
2228
2229 To create related objects, pass a hashref for the value if the related
2230 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2231 and use the name of the relationship as the key. (NOT the name of the field,
2232 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2233 of hashrefs containing the data for each of the rows to create in the foreign
2234 tables, again using the relationship name as the key.
2235
2236 Instead of hashrefs of plain related data (key/value pairs), you may
2237 also pass new or inserted objects. New objects (not inserted yet, see
2238 L</new>), will be inserted into their appropriate tables.
2239
2240 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2241
2242 Example of creating a new row.
2243
2244   $person_rs->create({
2245     name=>"Some Person",
2246     email=>"somebody@someplace.com"
2247   });
2248
2249 Example of creating a new row and also creating rows in a related C<has_many>
2250 or C<has_one> resultset.  Note Arrayref.
2251
2252   $artist_rs->create(
2253      { artistid => 4, name => 'Manufactured Crap', cds => [
2254         { title => 'My First CD', year => 2006 },
2255         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2256       ],
2257      },
2258   );
2259
2260 Example of creating a new row and also creating a row in a related
2261 C<belongs_to>resultset. Note Hashref.
2262
2263   $cd_rs->create({
2264     title=>"Music for Silly Walks",
2265     year=>2000,
2266     artist => {
2267       name=>"Silly Musician",
2268     }
2269   });
2270
2271 =cut
2272
2273 sub create {
2274   my ($self, $attrs) = @_;
2275   $self->throw_exception( "create needs a hashref" )
2276     unless ref $attrs eq 'HASH';
2277   return $self->new_result($attrs)->insert;
2278 }
2279
2280 =head2 find_or_create
2281
2282 =over 4
2283
2284 =item Arguments: \%vals, \%attrs?
2285
2286 =item Return Value: $rowobject
2287
2288 =back
2289
2290   $cd->cd_to_producer->find_or_create({ producer => $producer },
2291                                       { key => 'primary' });
2292
2293 Tries to find a record based on its primary key or unique constraints; if none
2294 is found, creates one and returns that instead.
2295
2296   my $cd = $schema->resultset('CD')->find_or_create({
2297     cdid   => 5,
2298     artist => 'Massive Attack',
2299     title  => 'Mezzanine',
2300     year   => 2005,
2301   });
2302
2303 Also takes an optional C<key> attribute, to search by a specific key or unique
2304 constraint. For example:
2305
2306   my $cd = $schema->resultset('CD')->find_or_create(
2307     {
2308       artist => 'Massive Attack',
2309       title  => 'Mezzanine',
2310     },
2311     { key => 'cd_artist_title' }
2312   );
2313
2314 B<Note>: Because find_or_create() reads from the database and then
2315 possibly inserts based on the result, this method is subject to a race
2316 condition. Another process could create a record in the table after
2317 the find has completed and before the create has started. To avoid
2318 this problem, use find_or_create() inside a transaction.
2319
2320 B<Note>: C<find_or_create> is probably not what you want when creating
2321 a new row in a table that uses primary keys supplied by the
2322 database. Passing in a primary key column with a value of I<undef>
2323 will cause L</find> to attempt to search for a row with a value of
2324 I<NULL>.
2325
2326 See also L</find> and L</update_or_create>. For information on how to declare
2327 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2328
2329 =cut
2330
2331 sub find_or_create {
2332   my $self     = shift;
2333   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2334   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2335   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2336     return $row;
2337   }
2338   return $self->create($hash);
2339 }
2340
2341 =head2 update_or_create
2342
2343 =over 4
2344
2345 =item Arguments: \%col_values, { key => $unique_constraint }?
2346
2347 =item Return Value: $rowobject
2348
2349 =back
2350
2351   $resultset->update_or_create({ col => $val, ... });
2352
2353 First, searches for an existing row matching one of the unique constraints
2354 (including the primary key) on the source of this resultset. If a row is
2355 found, updates it with the other given column values. Otherwise, creates a new
2356 row.
2357
2358 Takes an optional C<key> attribute to search on a specific unique constraint.
2359 For example:
2360
2361   # In your application
2362   my $cd = $schema->resultset('CD')->update_or_create(
2363     {
2364       artist => 'Massive Attack',
2365       title  => 'Mezzanine',
2366       year   => 1998,
2367     },
2368     { key => 'cd_artist_title' }
2369   );
2370
2371   $cd->cd_to_producer->update_or_create({
2372     producer => $producer,
2373     name => 'harry',
2374   }, {
2375     key => 'primary,
2376   });
2377
2378
2379 If no C<key> is specified, it searches on all unique constraints defined on the
2380 source, including the primary key.
2381
2382 If the C<key> is specified as C<primary>, it searches only on the primary key.
2383
2384 See also L</find> and L</find_or_create>. For information on how to declare
2385 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2386
2387 B<Note>: C<update_or_create> is probably not what you want when
2388 looking for a row in a table that uses primary keys supplied by the
2389 database, unless you actually have a key value. Passing in a primary
2390 key column with a value of I<undef> will cause L</find> to attempt to
2391 search for a row with a value of I<NULL>.
2392
2393 =cut
2394
2395 sub update_or_create {
2396   my $self = shift;
2397   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2398   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2399
2400   my $row = $self->find($cond, $attrs);
2401   if (defined $row) {
2402     $row->update($cond);
2403     return $row;
2404   }
2405
2406   return $self->create($cond);
2407 }
2408
2409 =head2 update_or_new
2410
2411 =over 4
2412
2413 =item Arguments: \%col_values, { key => $unique_constraint }?
2414
2415 =item Return Value: $rowobject
2416
2417 =back
2418
2419   $resultset->update_or_new({ col => $val, ... });
2420
2421 First, searches for an existing row matching one of the unique constraints
2422 (including the primary key) on the source of this resultset. If a row is
2423 found, updates it with the other given column values. Otherwise, instantiate
2424 a new result object and return it. The object will not be saved into your storage
2425 until you call L<DBIx::Class::Row/insert> on it.
2426
2427 Takes an optional C<key> attribute to search on a specific unique constraint.
2428 For example:
2429
2430   # In your application
2431   my $cd = $schema->resultset('CD')->update_or_new(
2432     {
2433       artist => 'Massive Attack',
2434       title  => 'Mezzanine',
2435       year   => 1998,
2436     },
2437     { key => 'cd_artist_title' }
2438   );
2439
2440   if ($cd->in_storage) {
2441       # the cd was updated
2442   }
2443   else {
2444       # the cd is not yet in the database, let's insert it
2445       $cd->insert;
2446   }
2447
2448 See also L</find>, L</find_or_create> and L<find_or_new>.
2449
2450 =cut
2451
2452 sub update_or_new {
2453     my $self  = shift;
2454     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2455     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2456
2457     my $row = $self->find( $cond, $attrs );
2458     if ( defined $row ) {
2459         $row->update($cond);
2460         return $row;
2461     }
2462
2463     return $self->new_result($cond);
2464 }
2465
2466 =head2 get_cache
2467
2468 =over 4
2469
2470 =item Arguments: none
2471
2472 =item Return Value: \@cache_objects?
2473
2474 =back
2475
2476 Gets the contents of the cache for the resultset, if the cache is set.
2477
2478 The cache is populated either by using the L</prefetch> attribute to
2479 L</search> or by calling L</set_cache>.
2480
2481 =cut
2482
2483 sub get_cache {
2484   shift->{all_cache};
2485 }
2486
2487 =head2 set_cache
2488
2489 =over 4
2490
2491 =item Arguments: \@cache_objects
2492
2493 =item Return Value: \@cache_objects
2494
2495 =back
2496
2497 Sets the contents of the cache for the resultset. Expects an arrayref
2498 of objects of the same class as those produced by the resultset. Note that
2499 if the cache is set the resultset will return the cached objects rather
2500 than re-querying the database even if the cache attr is not set.
2501
2502 The contents of the cache can also be populated by using the
2503 L</prefetch> attribute to L</search>.
2504
2505 =cut
2506
2507 sub set_cache {
2508   my ( $self, $data ) = @_;
2509   $self->throw_exception("set_cache requires an arrayref")
2510       if defined($data) && (ref $data ne 'ARRAY');
2511   $self->{all_cache} = $data;
2512 }
2513
2514 =head2 clear_cache
2515
2516 =over 4
2517
2518 =item Arguments: none
2519
2520 =item Return Value: []
2521
2522 =back
2523
2524 Clears the cache for the resultset.
2525
2526 =cut
2527
2528 sub clear_cache {
2529   shift->set_cache(undef);
2530 }
2531
2532 =head2 related_resultset
2533
2534 =over 4
2535
2536 =item Arguments: $relationship_name
2537
2538 =item Return Value: $resultset
2539
2540 =back
2541
2542 Returns a related resultset for the supplied relationship name.
2543
2544   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2545
2546 =cut
2547
2548 sub related_resultset {
2549   my ($self, $rel) = @_;
2550
2551   $self->{related_resultsets} ||= {};
2552   return $self->{related_resultsets}{$rel} ||= do {
2553     my $rel_info = $self->result_source->relationship_info($rel);
2554
2555     $self->throw_exception(
2556       "search_related: result source '" . $self->result_source->source_name .
2557         "' has no such relationship $rel")
2558       unless $rel_info;
2559
2560     my ($from,$seen) = $self->_chain_relationship($rel);
2561
2562     my $join_count = $seen->{$rel};
2563     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2564
2565     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2566     my %attrs = %{$self->{attrs}||{}};
2567     delete @attrs{qw(result_class alias)};
2568
2569     my $new_cache;
2570
2571     if (my $cache = $self->get_cache) {
2572       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2573         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2574                         @$cache ];
2575       }
2576     }
2577
2578     my $rel_source = $self->result_source->related_source($rel);
2579
2580     my $new = do {
2581
2582       # The reason we do this now instead of passing the alias to the
2583       # search_rs below is that if you wrap/overload resultset on the
2584       # source you need to know what alias it's -going- to have for things
2585       # to work sanely (e.g. RestrictWithObject wants to be able to add
2586       # extra query restrictions, and these may need to be $alias.)
2587
2588       my $attrs = $rel_source->resultset_attributes;
2589       local $attrs->{alias} = $alias;
2590
2591       $rel_source->resultset
2592                  ->search_rs(
2593                      undef, {
2594                        %attrs,
2595                        join => undef,
2596                        prefetch => undef,
2597                        select => undef,
2598                        as => undef,
2599                        where => $self->{cond},
2600                        seen_join => $seen,
2601                        from => $from,
2602                    });
2603     };
2604     $new->set_cache($new_cache) if $new_cache;
2605     $new;
2606   };
2607 }
2608
2609 =head2 current_source_alias
2610
2611 =over 4
2612
2613 =item Arguments: none
2614
2615 =item Return Value: $source_alias
2616
2617 =back
2618
2619 Returns the current table alias for the result source this resultset is built
2620 on, that will be used in the SQL query. Usually it is C<me>.
2621
2622 Currently the source alias that refers to the result set returned by a
2623 L</search>/L</find> family method depends on how you got to the resultset: it's
2624 C<me> by default, but eg. L</search_related> aliases it to the related result
2625 source name (and keeps C<me> referring to the original result set). The long
2626 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2627 (and make this method unnecessary).
2628
2629 Thus it's currently necessary to use this method in predefined queries (see
2630 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2631 source alias of the current result set:
2632
2633   # in a result set class
2634   sub modified_by {
2635     my ($self, $user) = @_;
2636
2637     my $me = $self->current_source_alias;
2638
2639     return $self->search(
2640       "$me.modified" => $user->id,
2641     );
2642   }
2643
2644 =cut
2645
2646 sub current_source_alias {
2647   my ($self) = @_;
2648
2649   return ($self->{attrs} || {})->{alias} || 'me';
2650 }
2651
2652 # This code is called by search_related, and makes sure there
2653 # is clear separation between the joins before, during, and
2654 # after the relationship. This information is needed later
2655 # in order to properly resolve prefetch aliases (any alias
2656 # with a relation_chain_depth less than the depth of the
2657 # current prefetch is not considered)
2658 sub _chain_relationship {
2659   my ($self, $rel) = @_;
2660   my $source = $self->result_source;
2661   my $attrs = $self->{attrs};
2662
2663   my $from = [ @{
2664       $attrs->{from}
2665         ||
2666       [{
2667         -source_handle => $source->handle,
2668         -alias => $attrs->{alias},
2669         $attrs->{alias} => $source->from,
2670       }]
2671   }];
2672
2673   my $seen = { %{$attrs->{seen_join} || {} } };
2674
2675   # we need to take the prefetch the attrs into account before we
2676   # ->_resolve_join as otherwise they get lost - captainL
2677   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2678
2679   my @requested_joins = $source->_resolve_join($merged, $attrs->{alias}, $seen);
2680
2681   push @$from, @requested_joins;
2682
2683   ++$seen->{-relation_chain_depth};
2684
2685   # if $self already had a join/prefetch specified on it, the requested
2686   # $rel might very well be already included. What we do in this case
2687   # is effectively a no-op (except that we bump up the chain_depth on
2688   # the join in question so we could tell it *is* the search_related)
2689   my $already_joined;
2690
2691
2692   # we consider the last one thus reverse
2693   for my $j (reverse @requested_joins) {
2694     if ($rel eq $j->[0]{-join_path}[-1]) {
2695       $j->[0]{-relation_chain_depth}++;
2696       $already_joined++;
2697       last;
2698     }
2699   }
2700
2701 # alternative way to scan the entire chain - not backwards compatible
2702 #  for my $j (reverse @$from) {
2703 #    next unless ref $j eq 'ARRAY';
2704 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2705 #      $j->[0]{-relation_chain_depth}++;
2706 #      $already_joined++;
2707 #      last;
2708 #    }
2709 #  }
2710
2711   unless ($already_joined) {
2712     push @$from, $source->_resolve_join($rel, $attrs->{alias}, $seen);
2713   }
2714
2715   ++$seen->{-relation_chain_depth};
2716
2717   return ($from,$seen);
2718 }
2719
2720 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2721 sub _resolved_attrs_copy {
2722   my $self = shift;
2723   return { %{$self->_resolved_attrs (@_)} };
2724 }
2725
2726 sub _resolved_attrs {
2727   my $self = shift;
2728   return $self->{_attrs} if $self->{_attrs};
2729
2730   my $attrs  = { %{ $self->{attrs} || {} } };
2731   my $source = $self->result_source;
2732   my $alias  = $attrs->{alias};
2733
2734   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2735   my @colbits;
2736
2737   # build columns (as long as select isn't set) into a set of as/select hashes
2738   unless ( $attrs->{select} ) {
2739       @colbits = map {
2740           ( ref($_) eq 'HASH' )
2741               ? $_
2742               : {
2743                   (
2744                     /^\Q${alias}.\E(.+)$/
2745                       ? "$1"
2746                       : "$_"
2747                   )
2748                 =>
2749                   (
2750                     /\./
2751                       ? "$_"
2752                       : "${alias}.$_"
2753                   )
2754             }
2755       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2756   }
2757   # add the additional columns on
2758   foreach ( 'include_columns', '+columns' ) {
2759       push @colbits, map {
2760           ( ref($_) eq 'HASH' )
2761             ? $_
2762             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2763       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2764   }
2765
2766   # start with initial select items
2767   if ( $attrs->{select} ) {
2768     $attrs->{select} =
2769         ( ref $attrs->{select} eq 'ARRAY' )
2770       ? [ @{ $attrs->{select} } ]
2771       : [ $attrs->{select} ];
2772     $attrs->{as} = (
2773       $attrs->{as}
2774       ? (
2775         ref $attrs->{as} eq 'ARRAY'
2776         ? [ @{ $attrs->{as} } ]
2777         : [ $attrs->{as} ]
2778         )
2779       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2780     );
2781   }
2782   else {
2783
2784     # otherwise we intialise select & as to empty
2785     $attrs->{select} = [];
2786     $attrs->{as}     = [];
2787   }
2788
2789   # now add colbits to select/as
2790   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2791   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2792
2793   my $adds;
2794   if ( $adds = delete $attrs->{'+select'} ) {
2795     $adds = [$adds] unless ref $adds eq 'ARRAY';
2796     push(
2797       @{ $attrs->{select} },
2798       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2799     );
2800   }
2801   if ( $adds = delete $attrs->{'+as'} ) {
2802     $adds = [$adds] unless ref $adds eq 'ARRAY';
2803     push( @{ $attrs->{as} }, @$adds );
2804   }
2805
2806   $attrs->{from} ||= [ {
2807     -source_handle => $source->handle,
2808     -alias => $self->{attrs}{alias},
2809     $self->{attrs}{alias} => $source->from,
2810   } ];
2811
2812   if ( $attrs->{join} || $attrs->{prefetch} ) {
2813
2814     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2815       if ref $attrs->{from} ne 'ARRAY';
2816
2817     my $join = delete $attrs->{join} || {};
2818
2819     if ( defined $attrs->{prefetch} ) {
2820       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2821     }
2822
2823     $attrs->{from} =    # have to copy here to avoid corrupting the original
2824       [
2825         @{ $attrs->{from} },
2826         $source->_resolve_join(
2827           $join, $alias, { %{ $attrs->{seen_join} || {} } }
2828         )
2829       ];
2830   }
2831
2832   if ( $attrs->{order_by} ) {
2833     $attrs->{order_by} = (
2834       ref( $attrs->{order_by} ) eq 'ARRAY'
2835       ? [ @{ $attrs->{order_by} } ]
2836       : [ $attrs->{order_by} ]
2837     );
2838   }
2839
2840   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2841     $attrs->{group_by} = [ $attrs->{group_by} ];
2842   }
2843
2844   # If the order_by is otherwise empty - we will use this for TOP limit
2845   # emulation and the like.
2846   # Although this is needed only if the order_by is not defined, it is
2847   # actually cheaper to just populate this rather than properly examining
2848   # order_by (stuf like [ {} ] and the like)
2849   $attrs->{_virtual_order_by} = [ $self->result_source->primary_columns ];
2850
2851
2852   $attrs->{collapse} ||= {};
2853   if ( my $prefetch = delete $attrs->{prefetch} ) {
2854     $prefetch = $self->_merge_attr( {}, $prefetch );
2855
2856     my $prefetch_ordering = [];
2857
2858     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2859
2860     my @prefetch =
2861       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2862
2863     $attrs->{prefetch_select} = [ map { $_->[0] } @prefetch ];
2864     push @{ $attrs->{select} }, @{$attrs->{prefetch_select}};
2865     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2866
2867     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2868     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2869   }
2870
2871
2872   if (delete $attrs->{distinct}) {
2873     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2874   }
2875
2876   # if both page and offset are specified, produce a combined offset
2877   # even though it doesn't make much sense, this is what pre 081xx has
2878   # been doing
2879   if (my $page = delete $attrs->{page}) {
2880     $attrs->{offset} = ($attrs->{rows} * ($page - 1)) +
2881       ($attrs->{offset} || 0);
2882   }
2883
2884   return $self->{_attrs} = $attrs;
2885 }
2886
2887 sub _joinpath_aliases {
2888   my ($self, $fromspec, $seen) = @_;
2889
2890   my $paths = {};
2891   return $paths unless ref $fromspec eq 'ARRAY';
2892
2893   for my $j (@$fromspec) {
2894
2895     next if ref $j ne 'ARRAY';
2896     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2897
2898     my $p = $paths;
2899     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2900     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2901   }
2902
2903   return $paths;
2904 }
2905
2906 sub _rollout_attr {
2907   my ($self, $attr) = @_;
2908
2909   if (ref $attr eq 'HASH') {
2910     return $self->_rollout_hash($attr);
2911   } elsif (ref $attr eq 'ARRAY') {
2912     return $self->_rollout_array($attr);
2913   } else {
2914     return [$attr];
2915   }
2916 }
2917
2918 sub _rollout_array {
2919   my ($self, $attr) = @_;
2920
2921   my @rolled_array;
2922   foreach my $element (@{$attr}) {
2923     if (ref $element eq 'HASH') {
2924       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2925     } elsif (ref $element eq 'ARRAY') {
2926       #  XXX - should probably recurse here
2927       push( @rolled_array, @{$self->_rollout_array($element)} );
2928     } else {
2929       push( @rolled_array, $element );
2930     }
2931   }
2932   return \@rolled_array;
2933 }
2934
2935 sub _rollout_hash {
2936   my ($self, $attr) = @_;
2937
2938   my @rolled_array;
2939   foreach my $key (keys %{$attr}) {
2940     push( @rolled_array, { $key => $attr->{$key} } );
2941   }
2942   return \@rolled_array;
2943 }
2944
2945 sub _calculate_score {
2946   my ($self, $a, $b) = @_;
2947
2948   if (ref $b eq 'HASH') {
2949     my ($b_key) = keys %{$b};
2950     if (ref $a eq 'HASH') {
2951       my ($a_key) = keys %{$a};
2952       if ($a_key eq $b_key) {
2953         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2954       } else {
2955         return 0;
2956       }
2957     } else {
2958       return ($a eq $b_key) ? 1 : 0;
2959     }
2960   } else {
2961     if (ref $a eq 'HASH') {
2962       my ($a_key) = keys %{$a};
2963       return ($b eq $a_key) ? 1 : 0;
2964     } else {
2965       return ($b eq $a) ? 1 : 0;
2966     }
2967   }
2968 }
2969
2970 sub _merge_attr {
2971   my ($self, $orig, $import) = @_;
2972
2973   return $import unless defined($orig);
2974   return $orig unless defined($import);
2975
2976   $orig = $self->_rollout_attr($orig);
2977   $import = $self->_rollout_attr($import);
2978
2979   my $seen_keys;
2980   foreach my $import_element ( @{$import} ) {
2981     # find best candidate from $orig to merge $b_element into
2982     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2983     foreach my $orig_element ( @{$orig} ) {
2984       my $score = $self->_calculate_score( $orig_element, $import_element );
2985       if ($score > $best_candidate->{score}) {
2986         $best_candidate->{position} = $position;
2987         $best_candidate->{score} = $score;
2988       }
2989       $position++;
2990     }
2991     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2992
2993     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2994       push( @{$orig}, $import_element );
2995     } else {
2996       my $orig_best = $orig->[$best_candidate->{position}];
2997       # merge orig_best and b_element together and replace original with merged
2998       if (ref $orig_best ne 'HASH') {
2999         $orig->[$best_candidate->{position}] = $import_element;
3000       } elsif (ref $import_element eq 'HASH') {
3001         my ($key) = keys %{$orig_best};
3002         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3003       }
3004     }
3005     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3006   }
3007
3008   return $orig;
3009 }
3010
3011 sub result_source {
3012     my $self = shift;
3013
3014     if (@_) {
3015         $self->_source_handle($_[0]->handle);
3016     } else {
3017         $self->_source_handle->resolve;
3018     }
3019 }
3020
3021 =head2 throw_exception
3022
3023 See L<DBIx::Class::Schema/throw_exception> for details.
3024
3025 =cut
3026
3027 sub throw_exception {
3028   my $self=shift;
3029   if (ref $self && $self->_source_handle->schema) {
3030     $self->_source_handle->schema->throw_exception(@_)
3031   } else {
3032     croak(@_);
3033   }
3034
3035 }
3036
3037 # XXX: FIXME: Attributes docs need clearing up
3038
3039 =head1 ATTRIBUTES
3040
3041 Attributes are used to refine a ResultSet in various ways when
3042 searching for data. They can be passed to any method which takes an
3043 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3044 L</count>.
3045
3046 These are in no particular order:
3047
3048 =head2 order_by
3049
3050 =over 4
3051
3052 =item Value: ( $order_by | \@order_by | \%order_by )
3053
3054 =back
3055
3056 Which column(s) to order the results by. If a single column name, or
3057 an arrayref of names is supplied, the argument is passed through
3058 directly to SQL. The hashref syntax allows for connection-agnostic
3059 specification of ordering direction:
3060
3061  For descending order:
3062
3063   order_by => { -desc => [qw/col1 col2 col3/] }
3064
3065  For explicit ascending order:
3066
3067   order_by => { -asc => 'col' }
3068
3069 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3070 supported, although you are strongly encouraged to use the hashref
3071 syntax as outlined above.
3072
3073 =head2 columns
3074
3075 =over 4
3076
3077 =item Value: \@columns
3078
3079 =back
3080
3081 Shortcut to request a particular set of columns to be retrieved. Each
3082 column spec may be a string (a table column name), or a hash (in which
3083 case the key is the C<as> value, and the value is used as the C<select>
3084 expression). Adds C<me.> onto the start of any column without a C<.> in
3085 it and sets C<select> from that, then auto-populates C<as> from
3086 C<select> as normal. (You may also use the C<cols> attribute, as in
3087 earlier versions of DBIC.)
3088
3089 =head2 +columns
3090
3091 =over 4
3092
3093 =item Value: \@columns
3094
3095 =back
3096
3097 Indicates additional columns to be selected from storage. Works the same
3098 as L</columns> but adds columns to the selection. (You may also use the
3099 C<include_columns> attribute, as in earlier versions of DBIC). For
3100 example:-
3101
3102   $schema->resultset('CD')->search(undef, {
3103     '+columns' => ['artist.name'],
3104     join => ['artist']
3105   });
3106
3107 would return all CDs and include a 'name' column to the information
3108 passed to object inflation. Note that the 'artist' is the name of the
3109 column (or relationship) accessor, and 'name' is the name of the column
3110 accessor in the related table.
3111
3112 =head2 include_columns
3113
3114 =over 4
3115
3116 =item Value: \@columns
3117
3118 =back
3119
3120 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3121
3122 =head2 select
3123
3124 =over 4
3125
3126 =item Value: \@select_columns
3127
3128 =back
3129
3130 Indicates which columns should be selected from the storage. You can use
3131 column names, or in the case of RDBMS back ends, function or stored procedure
3132 names:
3133
3134   $rs = $schema->resultset('Employee')->search(undef, {
3135     select => [
3136       'name',
3137       { count => 'employeeid' },
3138       { sum => 'salary' }
3139     ]
3140   });
3141
3142 When you use function/stored procedure names and do not supply an C<as>
3143 attribute, the column names returned are storage-dependent. E.g. MySQL would
3144 return a column named C<count(employeeid)> in the above example.
3145
3146 =head2 +select
3147
3148 =over 4
3149
3150 Indicates additional columns to be selected from storage.  Works the same as
3151 L</select> but adds columns to the selection.
3152
3153 =back
3154
3155 =head2 +as
3156
3157 =over 4
3158
3159 Indicates additional column names for those added via L</+select>. See L</as>.
3160
3161 =back
3162
3163 =head2 as
3164
3165 =over 4
3166
3167 =item Value: \@inflation_names
3168
3169 =back
3170
3171 Indicates column names for object inflation. That is, C<as>
3172 indicates the name that the column can be accessed as via the
3173 C<get_column> method (or via the object accessor, B<if one already
3174 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3175
3176 The C<as> attribute is used in conjunction with C<select>,
3177 usually when C<select> contains one or more function or stored
3178 procedure names:
3179
3180   $rs = $schema->resultset('Employee')->search(undef, {
3181     select => [
3182       'name',
3183       { count => 'employeeid' }
3184     ],
3185     as => ['name', 'employee_count'],
3186   });
3187
3188   my $employee = $rs->first(); # get the first Employee
3189
3190 If the object against which the search is performed already has an accessor
3191 matching a column name specified in C<as>, the value can be retrieved using
3192 the accessor as normal:
3193
3194   my $name = $employee->name();
3195
3196 If on the other hand an accessor does not exist in the object, you need to
3197 use C<get_column> instead:
3198
3199   my $employee_count = $employee->get_column('employee_count');
3200
3201 You can create your own accessors if required - see
3202 L<DBIx::Class::Manual::Cookbook> for details.
3203
3204 Please note: This will NOT insert an C<AS employee_count> into the SQL
3205 statement produced, it is used for internal access only. Thus
3206 attempting to use the accessor in an C<order_by> clause or similar
3207 will fail miserably.
3208
3209 To get around this limitation, you can supply literal SQL to your
3210 C<select> attibute that contains the C<AS alias> text, eg:
3211
3212   select => [\'myfield AS alias']
3213
3214 =head2 join
3215
3216 =over 4
3217
3218 =item Value: ($rel_name | \@rel_names | \%rel_names)
3219
3220 =back
3221
3222 Contains a list of relationships that should be joined for this query.  For
3223 example:
3224
3225   # Get CDs by Nine Inch Nails
3226   my $rs = $schema->resultset('CD')->search(
3227     { 'artist.name' => 'Nine Inch Nails' },
3228     { join => 'artist' }
3229   );
3230
3231 Can also contain a hash reference to refer to the other relation's relations.
3232 For example:
3233
3234   package MyApp::Schema::Track;
3235   use base qw/DBIx::Class/;
3236   __PACKAGE__->table('track');
3237   __PACKAGE__->add_columns(qw/trackid cd position title/);
3238   __PACKAGE__->set_primary_key('trackid');
3239   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3240   1;
3241
3242   # In your application
3243   my $rs = $schema->resultset('Artist')->search(
3244     { 'track.title' => 'Teardrop' },
3245     {
3246       join     => { cd => 'track' },
3247       order_by => 'artist.name',
3248     }
3249   );
3250
3251 You need to use the relationship (not the table) name in  conditions,
3252 because they are aliased as such. The current table is aliased as "me", so
3253 you need to use me.column_name in order to avoid ambiguity. For example:
3254
3255   # Get CDs from 1984 with a 'Foo' track
3256   my $rs = $schema->resultset('CD')->search(
3257     {
3258       'me.year' => 1984,
3259       'tracks.name' => 'Foo'
3260     },
3261     { join => 'tracks' }
3262   );
3263
3264 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3265 similarly for a third time). For e.g.
3266
3267   my $rs = $schema->resultset('Artist')->search({
3268     'cds.title'   => 'Down to Earth',
3269     'cds_2.title' => 'Popular',
3270   }, {
3271     join => [ qw/cds cds/ ],
3272   });
3273
3274 will return a set of all artists that have both a cd with title 'Down
3275 to Earth' and a cd with title 'Popular'.
3276
3277 If you want to fetch related objects from other tables as well, see C<prefetch>
3278 below.
3279
3280 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3281
3282 =head2 prefetch
3283
3284 =over 4
3285
3286 =item Value: ($rel_name | \@rel_names | \%rel_names)
3287
3288 =back
3289
3290 Contains one or more relationships that should be fetched along with
3291 the main query (when they are accessed afterwards the data will
3292 already be available, without extra queries to the database).  This is
3293 useful for when you know you will need the related objects, because it
3294 saves at least one query:
3295
3296   my $rs = $schema->resultset('Tag')->search(
3297     undef,
3298     {
3299       prefetch => {
3300         cd => 'artist'
3301       }
3302     }
3303   );
3304
3305 The initial search results in SQL like the following:
3306
3307   SELECT tag.*, cd.*, artist.* FROM tag
3308   JOIN cd ON tag.cd = cd.cdid
3309   JOIN artist ON cd.artist = artist.artistid
3310
3311 L<DBIx::Class> has no need to go back to the database when we access the
3312 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3313 case.
3314
3315 Simple prefetches will be joined automatically, so there is no need
3316 for a C<join> attribute in the above search.
3317
3318 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3319 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3320 with an accessor type of 'single' or 'filter'). A more complex example that
3321 prefetches an artists cds, the tracks on those cds, and the tags associted
3322 with that artist is given below (assuming many-to-many from artists to tags):
3323
3324  my $rs = $schema->resultset('Artist')->search(
3325    undef,
3326    {
3327      prefetch => [
3328        { cds => 'tracks' },
3329        { artist_tags => 'tags' }
3330      ]
3331    }
3332  );
3333
3334
3335 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3336 attributes will be ignored.
3337
3338 =head2 page
3339
3340 =over 4
3341
3342 =item Value: $page
3343
3344 =back
3345
3346 Makes the resultset paged and specifies the page to retrieve. Effectively
3347 identical to creating a non-pages resultset and then calling ->page($page)
3348 on it.
3349
3350 If L<rows> attribute is not specified it defaults to 10 rows per page.
3351
3352 When you have a paged resultset, L</count> will only return the number
3353 of rows in the page. To get the total, use the L</pager> and call
3354 C<total_entries> on it.
3355
3356 =head2 rows
3357
3358 =over 4
3359
3360 =item Value: $rows
3361
3362 =back
3363
3364 Specifes the maximum number of rows for direct retrieval or the number of
3365 rows per page if the page attribute or method is used.
3366
3367 =head2 offset
3368
3369 =over 4
3370
3371 =item Value: $offset
3372
3373 =back
3374
3375 Specifies the (zero-based) row number for the  first row to be returned, or the
3376 of the first row of the first page if paging is used.
3377
3378 =head2 group_by
3379
3380 =over 4
3381
3382 =item Value: \@columns
3383
3384 =back
3385
3386 A arrayref of columns to group by. Can include columns of joined tables.
3387
3388   group_by => [qw/ column1 column2 ... /]
3389
3390 =head2 having
3391
3392 =over 4
3393
3394 =item Value: $condition
3395
3396 =back
3397
3398 HAVING is a select statement attribute that is applied between GROUP BY and
3399 ORDER BY. It is applied to the after the grouping calculations have been
3400 done.
3401
3402   having => { 'count(employee)' => { '>=', 100 } }
3403
3404 =head2 distinct
3405
3406 =over 4
3407
3408 =item Value: (0 | 1)
3409
3410 =back
3411
3412 Set to 1 to group by all columns.
3413
3414 =head2 where
3415
3416 =over 4
3417
3418 Adds to the WHERE clause.
3419
3420   # only return rows WHERE deleted IS NULL for all searches
3421   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3422
3423 Can be overridden by passing C<{ where => undef }> as an attribute
3424 to a resulset.
3425
3426 =back
3427
3428 =head2 cache
3429
3430 Set to 1 to cache search results. This prevents extra SQL queries if you
3431 revisit rows in your ResultSet:
3432
3433   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3434
3435   while( my $artist = $resultset->next ) {
3436     ... do stuff ...
3437   }
3438
3439   $rs->first; # without cache, this would issue a query
3440
3441 By default, searches are not cached.
3442
3443 For more examples of using these attributes, see
3444 L<DBIx::Class::Manual::Cookbook>.
3445
3446 =head2 from
3447
3448 =over 4
3449
3450 =item Value: \@from_clause
3451
3452 =back
3453
3454 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3455 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3456 clauses.
3457
3458 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3459
3460 C<join> will usually do what you need and it is strongly recommended that you
3461 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3462 And we really do mean "cannot", not just tried and failed. Attempting to use
3463 this because you're having problems with C<join> is like trying to use x86
3464 ASM because you've got a syntax error in your C. Trust us on this.
3465
3466 Now, if you're still really, really sure you need to use this (and if you're
3467 not 100% sure, ask the mailing list first), here's an explanation of how this
3468 works.
3469
3470 The syntax is as follows -
3471
3472   [
3473     { <alias1> => <table1> },
3474     [
3475       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3476       [], # nested JOIN (optional)
3477       { <table1.column1> => <table2.column2>, ... (more conditions) },
3478     ],
3479     # More of the above [ ] may follow for additional joins
3480   ]
3481
3482   <table1> <alias1>
3483   JOIN
3484     <table2> <alias2>
3485     [JOIN ...]
3486   ON <table1.column1> = <table2.column2>
3487   <more joins may follow>
3488
3489 An easy way to follow the examples below is to remember the following:
3490
3491     Anything inside "[]" is a JOIN
3492     Anything inside "{}" is a condition for the enclosing JOIN
3493
3494 The following examples utilize a "person" table in a family tree application.
3495 In order to express parent->child relationships, this table is self-joined:
3496
3497     # Person->belongs_to('father' => 'Person');
3498     # Person->belongs_to('mother' => 'Person');
3499
3500 C<from> can be used to nest joins. Here we return all children with a father,
3501 then search against all mothers of those children:
3502
3503   $rs = $schema->resultset('Person')->search(
3504       undef,
3505       {
3506           alias => 'mother', # alias columns in accordance with "from"
3507           from => [
3508               { mother => 'person' },
3509               [
3510                   [
3511                       { child => 'person' },
3512                       [
3513                           { father => 'person' },
3514                           { 'father.person_id' => 'child.father_id' }
3515                       ]
3516                   ],
3517                   { 'mother.person_id' => 'child.mother_id' }
3518               ],
3519           ]
3520       },
3521   );
3522
3523   # Equivalent SQL:
3524   # SELECT mother.* FROM person mother
3525   # JOIN (
3526   #   person child
3527   #   JOIN person father
3528   #   ON ( father.person_id = child.father_id )
3529   # )
3530   # ON ( mother.person_id = child.mother_id )
3531
3532 The type of any join can be controlled manually. To search against only people
3533 with a father in the person table, we could explicitly use C<INNER JOIN>:
3534
3535     $rs = $schema->resultset('Person')->search(
3536         undef,
3537         {
3538             alias => 'child', # alias columns in accordance with "from"
3539             from => [
3540                 { child => 'person' },
3541                 [
3542                     { father => 'person', -join_type => 'inner' },
3543                     { 'father.id' => 'child.father_id' }
3544                 ],
3545             ]
3546         },
3547     );
3548
3549     # Equivalent SQL:
3550     # SELECT child.* FROM person child
3551     # INNER JOIN person father ON child.father_id = father.id
3552
3553 You can select from a subquery by passing a resultset to from as follows.
3554
3555     $schema->resultset('Artist')->search(
3556         undef,
3557         {   alias => 'artist2',
3558             from  => [ { artist2 => $artist_rs->as_query } ],
3559         } );
3560
3561     # and you'll get sql like this..
3562     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3563     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3564
3565 If you need to express really complex joins, you
3566 can supply literal SQL to C<from> via a scalar reference. In this case
3567 the contents of the scalar will replace the table name associated with the
3568 resultsource.
3569
3570 WARNING: This technique might very well not work as expected on chained
3571 searches - you have been warned.
3572
3573     # Assuming the Event resultsource is defined as:
3574
3575         MySchema::Event->add_columns (
3576             sequence => {
3577                 data_type => 'INT',
3578                 is_auto_increment => 1,
3579             },
3580             location => {
3581                 data_type => 'INT',
3582             },
3583             type => {
3584                 data_type => 'INT',
3585             },
3586         );
3587         MySchema::Event->set_primary_key ('sequence');
3588
3589     # This will get back the latest event for every location. The column
3590     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3591     # combo to limit the resultset
3592
3593     $rs = $schema->resultset('Event');
3594     $table = $rs->result_source->name;
3595     $latest = $rs->search (
3596         undef,
3597         { from => \ "
3598             (SELECT e1.* FROM $table e1
3599                 JOIN $table e2
3600                     ON e1.location = e2.location
3601                     AND e1.sequence < e2.sequence
3602                 WHERE e2.sequence is NULL
3603             ) me",
3604         },
3605     );
3606
3607     # Equivalent SQL (with the DBIC chunks added):
3608
3609     SELECT me.sequence, me.location, me.type FROM
3610        (SELECT e1.* FROM events e1
3611            JOIN events e2
3612                ON e1.location = e2.location
3613                AND e1.sequence < e2.sequence
3614            WHERE e2.sequence is NULL
3615        ) me;
3616
3617 =head2 for
3618
3619 =over 4
3620
3621 =item Value: ( 'update' | 'shared' )
3622
3623 =back
3624
3625 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3626 ... FOR SHARED.
3627
3628 =cut
3629
3630 1;