lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as +columns bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359
 360   $rs->set_cache($rows) if ($rows);
 361
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, {result_class => $self->result_class, %$attrs});
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my (@unique_queries, %seen_column_combinations);
 574   foreach my $name (@constraint_names) {
 575     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 576
 577     my $constraint_sig = join "\x00", sort @constraint_cols;
 578     next if $seen_column_combinations{$constraint_sig}++;
 579
 580     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 581
 582     my $num_cols = scalar @constraint_cols;
 583     my $num_query = scalar keys %$unique_query;
 584
 585     my $total = $num_query + $num_where;
 586     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 587       # The query is either unique on its own or is unique in combination with
 588       # the existing where clause
 589       push @unique_queries, $unique_query;
 590     }
 591   }
 592
 593   return @unique_queries;
 594 }
 595
 596 # _build_unique_query
 597 #
 598 # Constrain the specified query hash based on the specified column names.
 599
 600 sub _build_unique_query {
 601   my ($self, $query, $unique_cols) = @_;
 602
 603   return {
 604     map  { $_ => $query->{$_} }
 605     grep { exists $query->{$_} }
 606       @$unique_cols
 607   };
 608 }
 609
 610 =head2 search_related
 611
 612 =over 4
 613
 614 =item Arguments: $rel, $cond, \%attrs?
 615
 616 =item Return Value: $new_resultset
 617
 618 =back
 619
 620   $new_rs = $cd_rs->search_related('artist', {
 621     name => 'Emo-R-Us',
 622   });
 623
 624 Searches the specified relationship, optionally specifying a condition and
 625 attributes for matching records. See L</ATTRIBUTES> for more information.
 626
 627 =cut
 628
 629 sub search_related {
 630   return shift->related_resultset(shift)->search(@_);
 631 }
 632
 633 =head2 search_related_rs
 634
 635 This method works exactly the same as search_related, except that
 636 it guarantees a restultset, even in list context.
 637
 638 =cut
 639
 640 sub search_related_rs {
 641   return shift->related_resultset(shift)->search_rs(@_);
 642 }
 643
 644 =head2 cursor
 645
 646 =over 4
 647
 648 =item Arguments: none
 649
 650 =item Return Value: $cursor
 651
 652 =back
 653
 654 Returns a storage-driven cursor to the given resultset. See
 655 L<DBIx::Class::Cursor> for more information.
 656
 657 =cut
 658
 659 sub cursor {
 660   my ($self) = @_;
 661
 662   my $attrs = $self->_resolved_attrs_copy;
 663
 664   return $self->{cursor}
 665     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 666           $attrs->{where},$attrs);
 667 }
 668
 669 =head2 single
 670
 671 =over 4
 672
 673 =item Arguments: $cond?
 674
 675 =item Return Value: $row_object?
 676
 677 =back
 678
 679   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 680
 681 Inflates the first result without creating a cursor if the resultset has
 682 any records in it; if not returns nothing. Used by L</find> as a lean version of
 683 L</search>.
 684
 685 While this method can take an optional search condition (just like L</search>)
 686 being a fast-code-path it does not recognize search attributes. If you need to
 687 add extra joins or similar, call L</search> and then chain-call L</single> on the
 688 L<DBIx::Class::ResultSet> returned.
 689
 690 =over
 691
 692 =item B<Note>
 693
 694 As of 0.08100, this method enforces the assumption that the preceeding
 695 query returns only one row. If more than one row is returned, you will receive
 696 a warning:
 697
 698   Query returned more than one row
 699
 700 In this case, you should be using L</next> or L</find> instead, or if you really
 701 know what you are doing, use the L</rows> attribute to explicitly limit the size
 702 of the resultset.
 703
 704 This method will also throw an exception if it is called on a resultset prefetching
 705 has_many, as such a prefetch implies fetching multiple rows from the database in
 706 order to assemble the resulting object.
 707
 708 =back
 709
 710 =cut
 711
 712 sub single {
 713   my ($self, $where) = @_;
 714   if(@_ > 2) {
 715       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 716   }
 717
 718   my $attrs = $self->_resolved_attrs_copy;
 719
 720   if (keys %{$attrs->{collapse}}) {
 721     $self->throw_exception(
 722       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 723     );
 724   }
 725
 726   if ($where) {
 727     if (defined $attrs->{where}) {
 728       $attrs->{where} = {
 729         '-and' =>
 730             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 731                $where, delete $attrs->{where} ]
 732       };
 733     } else {
 734       $attrs->{where} = $where;
 735     }
 736   }
 737
 738 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 739 #  unless ($self->_is_unique_query($attrs->{where})) {
 740 #    carp "Query not guaranteed to return a single row"
 741 #      . "; please declare your unique constraints or use search instead";
 742 #  }
 743
 744   my @data = $self->result_source->storage->select_single(
 745     $attrs->{from}, $attrs->{select},
 746     $attrs->{where}, $attrs
 747   );
 748
 749   return (@data ? ($self->_construct_object(@data))[0] : undef);
 750 }
 751
 752
 753 # _is_unique_query
 754 #
 755 # Try to determine if the specified query is guaranteed to be unique, based on
 756 # the declared unique constraints.
 757
 758 sub _is_unique_query {
 759   my ($self, $query) = @_;
 760
 761   my $collapsed = $self->_collapse_query($query);
 762   my $alias = $self->{attrs}{alias};
 763
 764   foreach my $name ($self->result_source->unique_constraint_names) {
 765     my @unique_cols = map {
 766       "$alias.$_"
 767     } $self->result_source->unique_constraint_columns($name);
 768
 769     # Count the values for each unique column
 770     my %seen = map { $_ => 0 } @unique_cols;
 771
 772     foreach my $key (keys %$collapsed) {
 773       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 774       next unless exists $seen{$aliased};  # Additional constraints are okay
 775       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 776     }
 777
 778     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 779     return 1 unless grep { $_ != 1 } values %seen;
 780   }
 781
 782   return 0;
 783 }
 784
 785 # _collapse_query
 786 #
 787 # Recursively collapse the query, accumulating values for each column.
 788
 789 sub _collapse_query {
 790   my ($self, $query, $collapsed) = @_;
 791
 792   $collapsed ||= {};
 793
 794   if (ref $query eq 'ARRAY') {
 795     foreach my $subquery (@$query) {
 796       next unless ref $subquery;  # -or
 797       $collapsed = $self->_collapse_query($subquery, $collapsed);
 798     }
 799   }
 800   elsif (ref $query eq 'HASH') {
 801     if (keys %$query and (keys %$query)[0] eq '-and') {
 802       foreach my $subquery (@{$query->{-and}}) {
 803         $collapsed = $self->_collapse_query($subquery, $collapsed);
 804       }
 805     }
 806     else {
 807       foreach my $col (keys %$query) {
 808         my $value = $query->{$col};
 809         $collapsed->{$col}{$value}++;
 810       }
 811     }
 812   }
 813
 814   return $collapsed;
 815 }
 816
 817 =head2 get_column
 818
 819 =over 4
 820
 821 =item Arguments: $cond?
 822
 823 =item Return Value: $resultsetcolumn
 824
 825 =back
 826
 827   my $max_length = $rs->get_column('length')->max;
 828
 829 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 830
 831 =cut
 832
 833 sub get_column {
 834   my ($self, $column) = @_;
 835   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 836   return $new;
 837 }
 838
 839 =head2 search_like
 840
 841 =over 4
 842
 843 =item Arguments: $cond, \%attrs?
 844
 845 =item Return Value: $resultset (scalar context), @row_objs (list context)
 846
 847 =back
 848
 849   # WHERE title LIKE '%blue%'
 850   $cd_rs = $rs->search_like({ title => '%blue%'});
 851
 852 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 853 that this is simply a convenience method retained for ex Class::DBI users.
 854 You most likely want to use L</search> with specific operators.
 855
 856 For more information, see L<DBIx::Class::Manual::Cookbook>.
 857
 858 This method is deprecated and will be removed in 0.09. Use L</search()>
 859 instead. An example conversion is:
 860
 861   ->search_like({ foo => 'bar' });
 862
 863   # Becomes
 864
 865   ->search({ foo => { like => 'bar' } });
 866
 867 =cut
 868
 869 sub search_like {
 870   my $class = shift;
 871   carp (
 872     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 873    .' Instead use ->search({ x => { -like => "y%" } })'
 874    .' (note the outer pair of {}s - they are important!)'
 875   );
 876   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 877   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 878   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 879   return $class->search($query, { %$attrs });
 880 }
 881
 882 =head2 slice
 883
 884 =over 4
 885
 886 =item Arguments: $first, $last
 887
 888 =item Return Value: $resultset (scalar context), @row_objs (list context)
 889
 890 =back
 891
 892 Returns a resultset or object list representing a subset of elements from the
 893 resultset slice is called on. Indexes are from 0, i.e., to get the first
 894 three records, call:
 895
 896   my ($one, $two, $three) = $rs->slice(0, 2);
 897
 898 =cut
 899
 900 sub slice {
 901   my ($self, $min, $max) = @_;
 902   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 903   $attrs->{offset} = $self->{attrs}{offset} || 0;
 904   $attrs->{offset} += $min;
 905   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 906   return $self->search(undef(), $attrs);
 907   #my $slice = (ref $self)->new($self->result_source, $attrs);
 908   #return (wantarray ? $slice->all : $slice);
 909 }
 910
 911 =head2 next
 912
 913 =over 4
 914
 915 =item Arguments: none
 916
 917 =item Return Value: $result?
 918
 919 =back
 920
 921 Returns the next element in the resultset (C<undef> is there is none).
 922
 923 Can be used to efficiently iterate over records in the resultset:
 924
 925   my $rs = $schema->resultset('CD')->search;
 926   while (my $cd = $rs->next) {
 927     print $cd->title;
 928   }
 929
 930 Note that you need to store the resultset object, and call C<next> on it.
 931 Calling C<< resultset('Table')->next >> repeatedly will always return the
 932 first record from the resultset.
 933
 934 =cut
 935
 936 sub next {
 937   my ($self) = @_;
 938   if (my $cache = $self->get_cache) {
 939     $self->{all_cache_position} ||= 0;
 940     return $cache->[$self->{all_cache_position}++];
 941   }
 942   if ($self->{attrs}{cache}) {
 943     $self->{all_cache_position} = 1;
 944     return ($self->all)[0];
 945   }
 946   if ($self->{stashed_objects}) {
 947     my $obj = shift(@{$self->{stashed_objects}});
 948     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 949     return $obj;
 950   }
 951   my @row = (
 952     exists $self->{stashed_row}
 953       ? @{delete $self->{stashed_row}}
 954       : $self->cursor->next
 955   );
 956   return undef unless (@row);
 957   my ($row, @more) = $self->_construct_object(@row);
 958   $self->{stashed_objects} = \@more if @more;
 959   return $row;
 960 }
 961
 962 sub _construct_object {
 963   my ($self, @row) = @_;
 964
 965   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 966     or return ();
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. Passing arguments is equivalent to
1149 C<< $rs->search ($cond, \%attrs)->count >>
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my $attrs = $self->_resolved_attrs_copy;
1159
1160   # this is a little optimization - it is faster to do the limit
1161   # adjustments in software, instead of a subquery
1162   my $rows = delete $attrs->{rows};
1163   my $offset = delete $attrs->{offset};
1164
1165   my $crs;
1166   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1167     $crs = $self->_count_subq_rs ($attrs);
1168   }
1169   else {
1170     $crs = $self->_count_rs ($attrs);
1171   }
1172   my $count = $crs->next;
1173
1174   $count -= $offset if $offset;
1175   $count = $rows if $rows and $rows < $count;
1176   $count = 0 if ($count < 0);
1177
1178   return $count;
1179 }
1180
1181 =head2 count_rs
1182
1183 =over 4
1184
1185 =item Arguments: $cond, \%attrs??
1186
1187 =item Return Value: $count_rs
1188
1189 =back
1190
1191 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1192 This can be very handy for subqueries:
1193
1194   ->search( { amount => $some_rs->count_rs->as_query } )
1195
1196 As with regular resultsets the SQL query will be executed only after
1197 the resultset is accessed via L</next> or L</all>. That would return
1198 the same single value obtainable via L</count>.
1199
1200 =cut
1201
1202 sub count_rs {
1203   my $self = shift;
1204   return $self->search(@_)->count_rs if @_;
1205
1206   # this may look like a lack of abstraction (count() does about the same)
1207   # but in fact an _rs *must* use a subquery for the limits, as the
1208   # software based limiting can not be ported if this $rs is to be used
1209   # in a subquery itself (i.e. ->as_query)
1210   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1211     return $self->_count_subq_rs;
1212   }
1213   else {
1214     return $self->_count_rs;
1215   }
1216 }
1217
1218 #
1219 # returns a ResultSetColumn object tied to the count query
1220 #
1221 sub _count_rs {
1222   my ($self, $attrs) = @_;
1223
1224   my $rsrc = $self->result_source;
1225   $attrs ||= $self->_resolved_attrs;
1226
1227   my $tmp_attrs = { %$attrs };
1228
1229   # take off any limits, record_filter is cdbi, and no point of ordering a count
1230   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1231
1232   # overwrite the selector (supplied by the storage)
1233   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1234   $tmp_attrs->{as} = 'count';
1235
1236   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1237
1238   return $tmp_rs;
1239 }
1240
1241 #
1242 # same as above but uses a subquery
1243 #
1244 sub _count_subq_rs {
1245   my ($self, $attrs) = @_;
1246
1247   my $rsrc = $self->result_source;
1248   $attrs ||= $self->_resolved_attrs_copy;
1249
1250   my $sub_attrs = { %$attrs };
1251
1252   # extra selectors do not go in the subquery and there is no point of ordering it
1253   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1254
1255   # if we multi-prefetch we group_by primary keys only as this is what we would
1256   # get out of the rs via ->next/->all. We *DO WANT* to clobber old group_by regardless
1257   if ( keys %{$attrs->{collapse}}  ) {
1258     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1259   }
1260
1261   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1262
1263   # this is so that the query can be simplified e.g.
1264   # * ordering can be thrown away in things like Top limit
1265   $sub_attrs->{-for_count_only} = 1;
1266
1267   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1268
1269   $attrs->{from} = [{
1270     -alias => 'count_subq',
1271     -source_handle => $rsrc->handle,
1272     count_subq => $sub_rs->as_query,
1273   }];
1274
1275   # the subquery replaces this
1276   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1277
1278   return $self->_count_rs ($attrs);
1279 }
1280
1281 sub _bool {
1282   return 1;
1283 }
1284
1285 =head2 count_literal
1286
1287 =over 4
1288
1289 =item Arguments: $sql_fragment, @bind_values
1290
1291 =item Return Value: $count
1292
1293 =back
1294
1295 Counts the results in a literal query. Equivalent to calling L</search_literal>
1296 with the passed arguments, then L</count>.
1297
1298 =cut
1299
1300 sub count_literal { shift->search_literal(@_)->count; }
1301
1302 =head2 all
1303
1304 =over 4
1305
1306 =item Arguments: none
1307
1308 =item Return Value: @objects
1309
1310 =back
1311
1312 Returns all elements in the resultset. Called implicitly if the resultset
1313 is returned in list context.
1314
1315 =cut
1316
1317 sub all {
1318   my $self = shift;
1319   if(@_) {
1320       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1321   }
1322
1323   return @{ $self->get_cache } if $self->get_cache;
1324
1325   my @obj;
1326
1327   if (keys %{$self->_resolved_attrs->{collapse}}) {
1328     # Using $self->cursor->all is really just an optimisation.
1329     # If we're collapsing has_many prefetches it probably makes
1330     # very little difference, and this is cleaner than hacking
1331     # _construct_object to survive the approach
1332     $self->cursor->reset;
1333     my @row = $self->cursor->next;
1334     while (@row) {
1335       push(@obj, $self->_construct_object(@row));
1336       @row = (exists $self->{stashed_row}
1337                ? @{delete $self->{stashed_row}}
1338                : $self->cursor->next);
1339     }
1340   } else {
1341     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1342   }
1343
1344   $self->set_cache(\@obj) if $self->{attrs}{cache};
1345
1346   return @obj;
1347 }
1348
1349 =head2 reset
1350
1351 =over 4
1352
1353 =item Arguments: none
1354
1355 =item Return Value: $self
1356
1357 =back
1358
1359 Resets the resultset's cursor, so you can iterate through the elements again.
1360 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1361 another query.
1362
1363 =cut
1364
1365 sub reset {
1366   my ($self) = @_;
1367   delete $self->{_attrs} if exists $self->{_attrs};
1368   $self->{all_cache_position} = 0;
1369   $self->cursor->reset;
1370   return $self;
1371 }
1372
1373 =head2 first
1374
1375 =over 4
1376
1377 =item Arguments: none
1378
1379 =item Return Value: $object?
1380
1381 =back
1382
1383 Resets the resultset and returns an object for the first result (if the
1384 resultset returns anything).
1385
1386 =cut
1387
1388 sub first {
1389   return $_[0]->reset->next;
1390 }
1391
1392
1393 # _rs_update_delete
1394 #
1395 # Determines whether and what type of subquery is required for the $rs operation.
1396 # If grouping is necessary either supplies its own, or verifies the current one
1397 # After all is done delegates to the proper storage method.
1398
1399 sub _rs_update_delete {
1400   my ($self, $op, $values) = @_;
1401
1402   my $rsrc = $self->result_source;
1403
1404   # if a condition exists we need to strip all table qualifiers
1405   # if this is not possible we'll force a subquery below
1406   my $cond = $rsrc->schema->storage->_strip_cond_qualifiers ($self->{cond});
1407
1408   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1409   my $needs_subq = $needs_group_by_subq || (not defined $cond) || $self->_has_resolved_attr(qw/row offset/);
1410
1411   if ($needs_group_by_subq or $needs_subq) {
1412
1413     # make a new $rs selecting only the PKs (that's all we really need)
1414     my $attrs = $self->_resolved_attrs_copy;
1415
1416     delete $attrs->{$_} for qw/collapse select as/;
1417     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1418
1419     if ($needs_group_by_subq) {
1420       # make sure no group_by was supplied, or if there is one - make sure it matches
1421       # the columns compiled above perfectly. Anything else can not be sanely executed
1422       # on most databases so croak right then and there
1423
1424       if (my $g = $attrs->{group_by}) {
1425         my @current_group_by = map
1426           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1427           @$g
1428         ;
1429
1430         if (
1431           join ("\x00", sort @current_group_by)
1432             ne
1433           join ("\x00", sort @{$attrs->{columns}} )
1434         ) {
1435           $self->throw_exception (
1436             "You have just attempted a $op operation on a resultset which does group_by"
1437             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1438             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1439             . ' kind of queries. Please retry the operation with a modified group_by or'
1440             . ' without using one at all.'
1441           );
1442         }
1443       }
1444       else {
1445         $attrs->{group_by} = $attrs->{columns};
1446       }
1447     }
1448
1449     my $subrs = (ref $self)->new($rsrc, $attrs);
1450
1451     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1452   }
1453   else {
1454     return $rsrc->storage->$op(
1455       $rsrc,
1456       $op eq 'update' ? $values : (),
1457       $cond,
1458     );
1459   }
1460 }
1461
1462 =head2 update
1463
1464 =over 4
1465
1466 =item Arguments: \%values
1467
1468 =item Return Value: $storage_rv
1469
1470 =back
1471
1472 Sets the specified columns in the resultset to the supplied values in a
1473 single query. Return value will be true if the update succeeded or false
1474 if no records were updated; exact type of success value is storage-dependent.
1475
1476 =cut
1477
1478 sub update {
1479   my ($self, $values) = @_;
1480   $self->throw_exception('Values for update must be a hash')
1481     unless ref $values eq 'HASH';
1482
1483   return $self->_rs_update_delete ('update', $values);
1484 }
1485
1486 =head2 update_all
1487
1488 =over 4
1489
1490 =item Arguments: \%values
1491
1492 =item Return Value: 1
1493
1494 =back
1495
1496 Fetches all objects and updates them one at a time. Note that C<update_all>
1497 will run DBIC cascade triggers, while L</update> will not.
1498
1499 =cut
1500
1501 sub update_all {
1502   my ($self, $values) = @_;
1503   $self->throw_exception('Values for update_all must be a hash')
1504     unless ref $values eq 'HASH';
1505   foreach my $obj ($self->all) {
1506     $obj->set_columns($values)->update;
1507   }
1508   return 1;
1509 }
1510
1511 =head2 delete
1512
1513 =over 4
1514
1515 =item Arguments: none
1516
1517 =item Return Value: $storage_rv
1518
1519 =back
1520
1521 Deletes the contents of the resultset from its result source. Note that this
1522 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1523 to run. See also L<DBIx::Class::Row/delete>.
1524
1525 Return value will be the amount of rows deleted; exact type of return value
1526 is storage-dependent.
1527
1528 =cut
1529
1530 sub delete {
1531   my $self = shift;
1532   $self->throw_exception('delete does not accept any arguments')
1533     if @_;
1534
1535   return $self->_rs_update_delete ('delete');
1536 }
1537
1538 =head2 delete_all
1539
1540 =over 4
1541
1542 =item Arguments: none
1543
1544 =item Return Value: 1
1545
1546 =back
1547
1548 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1549 will run DBIC cascade triggers, while L</delete> will not.
1550
1551 =cut
1552
1553 sub delete_all {
1554   my $self = shift;
1555   $self->throw_exception('delete_all does not accept any arguments')
1556     if @_;
1557
1558   $_->delete for $self->all;
1559   return 1;
1560 }
1561
1562 =head2 populate
1563
1564 =over 4
1565
1566 =item Arguments: \@data;
1567
1568 =back
1569
1570 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1571 For the arrayref of hashrefs style each hashref should be a structure suitable
1572 forsubmitting to a $resultset->create(...) method.
1573
1574 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1575 to insert the data, as this is a faster method.
1576
1577 Otherwise, each set of data is inserted into the database using
1578 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1579 accumulated into an array. The array itself, or an array reference
1580 is returned depending on scalar or list context.
1581
1582 Example:  Assuming an Artist Class that has many CDs Classes relating:
1583
1584   my $Artist_rs = $schema->resultset("Artist");
1585
1586   ## Void Context Example
1587   $Artist_rs->populate([
1588      { artistid => 4, name => 'Manufactured Crap', cds => [
1589         { title => 'My First CD', year => 2006 },
1590         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1591       ],
1592      },
1593      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1594         { title => 'My parents sold me to a record company' ,year => 2005 },
1595         { title => 'Why Am I So Ugly?', year => 2006 },
1596         { title => 'I Got Surgery and am now Popular', year => 2007 }
1597       ],
1598      },
1599   ]);
1600
1601   ## Array Context Example
1602   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1603     { name => "Artist One"},
1604     { name => "Artist Two"},
1605     { name => "Artist Three", cds=> [
1606     { title => "First CD", year => 2007},
1607     { title => "Second CD", year => 2008},
1608   ]}
1609   ]);
1610
1611   print $ArtistOne->name; ## response is 'Artist One'
1612   print $ArtistThree->cds->count ## reponse is '2'
1613
1614 For the arrayref of arrayrefs style,  the first element should be a list of the
1615 fieldsnames to which the remaining elements are rows being inserted.  For
1616 example:
1617
1618   $Arstist_rs->populate([
1619     [qw/artistid name/],
1620     [100, 'A Formally Unknown Singer'],
1621     [101, 'A singer that jumped the shark two albums ago'],
1622     [102, 'An actually cool singer.'],
1623   ]);
1624
1625 Please note an important effect on your data when choosing between void and
1626 wantarray context. Since void context goes straight to C<insert_bulk> in
1627 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1628 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1629 create primary keys for you, you will find that your PKs are empty.  In this
1630 case you will have to use the wantarray context in order to create those
1631 values.
1632
1633 =cut
1634
1635 sub populate {
1636   my $self = shift;
1637
1638   # cruft placed in standalone method
1639   my $data = $self->_normalize_populate_args(@_);
1640
1641   if(defined wantarray) {
1642     my @created;
1643     foreach my $item (@$data) {
1644       push(@created, $self->create($item));
1645     }
1646     return wantarray ? @created : \@created;
1647   } else {
1648     my $first = $data->[0];
1649
1650     # if a column is a registered relationship, and is a non-blessed hash/array, consider
1651     # it relationship data
1652     my (@rels, @columns);
1653     for (keys %$first) {
1654       my $ref = ref $first->{$_};
1655       $self->result_source->has_relationship($_) && ($ref eq 'ARRAY' or $ref eq 'HASH')
1656         ? push @rels, $_
1657         : push @columns, $_
1658       ;
1659     }
1660
1661     my @pks = $self->result_source->primary_columns;
1662
1663     ## do the belongs_to relationships
1664     foreach my $index (0..$#$data) {
1665
1666       # delegate to create() for any dataset without primary keys with specified relationships
1667       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1668         for my $r (@rels) {
1669           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1670             my @ret = $self->populate($data);
1671             return;
1672           }
1673         }
1674       }
1675
1676       foreach my $rel (@rels) {
1677         next unless ref $data->[$index]->{$rel} eq "HASH";
1678         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1679         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1680         my $related = $result->result_source->_resolve_condition(
1681           $result->result_source->relationship_info($reverse)->{cond},
1682           $self,
1683           $result,
1684         );
1685
1686         delete $data->[$index]->{$rel};
1687         $data->[$index] = {%{$data->[$index]}, %$related};
1688
1689         push @columns, keys %$related if $index == 0;
1690       }
1691     }
1692
1693     ## inherit the data locked in the conditions of the resultset
1694     my ($rs_data) = $self->_merge_cond_with_data({});
1695     delete @{$rs_data}{@columns};
1696     my @inherit_cols = keys %$rs_data;
1697     my @inherit_data = values %$rs_data;
1698
1699     ## do bulk insert on current row
1700     $self->result_source->storage->insert_bulk(
1701       $self->result_source,
1702       [@columns, @inherit_cols],
1703       [ map { [ @$_{@columns}, @inherit_data ] } @$data ],
1704     );
1705
1706     ## do the has_many relationships
1707     foreach my $item (@$data) {
1708
1709       foreach my $rel (@rels) {
1710         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1711
1712         my $parent = $self->find({map { $_ => $item->{$_} } @pks})
1713      || $self->throw_exception('Cannot find the relating object.');
1714
1715         my $child = $parent->$rel;
1716
1717         my $related = $child->result_source->_resolve_condition(
1718           $parent->result_source->relationship_info($rel)->{cond},
1719           $child,
1720           $parent,
1721         );
1722
1723         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1724         my @populate = map { {%$_, %$related} } @rows_to_add;
1725
1726         $child->populate( \@populate );
1727       }
1728     }
1729   }
1730 }
1731
1732
1733 # populate() argumnets went over several incarnations
1734 # What we ultimately support is AoH
1735 sub _normalize_populate_args {
1736   my ($self, $arg) = @_;
1737
1738   if (ref $arg eq 'ARRAY') {
1739     if (ref $arg->[0] eq 'HASH') {
1740       return $arg;
1741     }
1742     elsif (ref $arg->[0] eq 'ARRAY') {
1743       my @ret;
1744       my @colnames = @{$arg->[0]};
1745       foreach my $values (@{$arg}[1 .. $#$arg]) {
1746         push @ret, { map { $colnames[$_] => $values->[$_] } (0 .. $#colnames) };
1747       }
1748       return \@ret;
1749     }
1750   }
1751
1752   $self->throw_exception('Populate expects an arrayref of hashrefs or arrayref of arrayrefs');
1753 }
1754
1755 =head2 pager
1756
1757 =over 4
1758
1759 =item Arguments: none
1760
1761 =item Return Value: $pager
1762
1763 =back
1764
1765 Return Value a L<Data::Page> object for the current resultset. Only makes
1766 sense for queries with a C<page> attribute.
1767
1768 To get the full count of entries for a paged resultset, call
1769 C<total_entries> on the L<Data::Page> object.
1770
1771 =cut
1772
1773 sub pager {
1774   my ($self) = @_;
1775
1776   return $self->{pager} if $self->{pager};
1777
1778   my $attrs = $self->{attrs};
1779   $self->throw_exception("Can't create pager for non-paged rs")
1780     unless $self->{attrs}{page};
1781   $attrs->{rows} ||= 10;
1782
1783   # throw away the paging flags and re-run the count (possibly
1784   # with a subselect) to get the real total count
1785   my $count_attrs = { %$attrs };
1786   delete $count_attrs->{$_} for qw/rows offset page pager/;
1787   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1788
1789   return $self->{pager} = Data::Page->new(
1790     $total_count,
1791     $attrs->{rows},
1792     $self->{attrs}{page}
1793   );
1794 }
1795
1796 =head2 page
1797
1798 =over 4
1799
1800 =item Arguments: $page_number
1801
1802 =item Return Value: $rs
1803
1804 =back
1805
1806 Returns a resultset for the $page_number page of the resultset on which page
1807 is called, where each page contains a number of rows equal to the 'rows'
1808 attribute set on the resultset (10 by default).
1809
1810 =cut
1811
1812 sub page {
1813   my ($self, $page) = @_;
1814   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1815 }
1816
1817 =head2 new_result
1818
1819 =over 4
1820
1821 =item Arguments: \%vals
1822
1823 =item Return Value: $rowobject
1824
1825 =back
1826
1827 Creates a new row object in the resultset's result class and returns
1828 it. The row is not inserted into the database at this point, call
1829 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1830 will tell you whether the row object has been inserted or not.
1831
1832 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1833
1834 =cut
1835
1836 sub new_result {
1837   my ($self, $values) = @_;
1838   $self->throw_exception( "new_result needs a hash" )
1839     unless (ref $values eq 'HASH');
1840
1841   my ($merged_cond, $cols_from_relations) = $self->_merge_cond_with_data($values);
1842
1843   my %new = (
1844     %$merged_cond,
1845     @$cols_from_relations
1846       ? (-cols_from_relations => $cols_from_relations)
1847       : (),
1848     -source_handle => $self->_source_handle,
1849     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1850   );
1851
1852   return $self->result_class->new(\%new);
1853 }
1854
1855 # _merge_cond_with_data
1856 #
1857 # Takes a simple hash of K/V data and returns its copy merged with the
1858 # condition already present on the resultset. Additionally returns an
1859 # arrayref of value/condition names, which were inferred from related
1860 # objects (this is needed for in-memory related objects)
1861 sub _merge_cond_with_data {
1862   my ($self, $data) = @_;
1863
1864   my (%new_data, @cols_from_relations);
1865
1866   my $alias = $self->{attrs}{alias};
1867
1868   if (! defined $self->{cond}) {
1869     # just massage $data below
1870   }
1871   elsif ($self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION) {
1872     %new_data = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1873     @cols_from_relations = keys %new_data;
1874   }
1875   elsif (ref $self->{cond} ne 'HASH') {
1876     $self->throw_exception(
1877       "Can't abstract implicit construct, resultset condition not a hash"
1878     );
1879   }
1880   else {
1881     # precendence must be given to passed values over values inherited from
1882     # the cond, so the order here is important.
1883     my $collapsed_cond = $self->_collapse_cond($self->{cond});
1884     my %implied = %{$self->_remove_alias($collapsed_cond, $alias)};
1885
1886     while ( my($col, $value) = each %implied ) {
1887       if (ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '=') {
1888         $new_data{$col} = $value->{'='};
1889         next;
1890       }
1891       $new_data{$col} = $value if $self->_is_deterministic_value($value);
1892     }
1893   }
1894
1895   %new_data = (
1896     %new_data,
1897     %{ $self->_remove_alias($data, $alias) },
1898   );
1899
1900   return (\%new_data, \@cols_from_relations);
1901 }
1902
1903 # _is_deterministic_value
1904 #
1905 # Make an effor to strip non-deterministic values from the condition,
1906 # to make sure new_result chokes less
1907
1908 sub _is_deterministic_value {
1909   my $self = shift;
1910   my $value = shift;
1911   my $ref_type = ref $value;
1912   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1913   return 1 if Scalar::Util::blessed($value);
1914   return 0;
1915 }
1916
1917 # _has_resolved_attr
1918 #
1919 # determines if the resultset defines at least one
1920 # of the attributes supplied
1921 #
1922 # used to determine if a subquery is neccessary
1923 #
1924 # supports some virtual attributes:
1925 #   -join
1926 #     This will scan for any joins being present on the resultset.
1927 #     It is not a mere key-search but a deep inspection of {from}
1928 #
1929
1930 sub _has_resolved_attr {
1931   my ($self, @attr_names) = @_;
1932
1933   my $attrs = $self->_resolved_attrs;
1934
1935   my %extra_checks;
1936
1937   for my $n (@attr_names) {
1938     if (grep { $n eq $_ } (qw/-join/) ) {
1939       $extra_checks{$n}++;
1940       next;
1941     }
1942
1943     my $attr =  $attrs->{$n};
1944
1945     next if not defined $attr;
1946
1947     if (ref $attr eq 'HASH') {
1948       return 1 if keys %$attr;
1949     }
1950     elsif (ref $attr eq 'ARRAY') {
1951       return 1 if @$attr;
1952     }
1953     else {
1954       return 1 if $attr;
1955     }
1956   }
1957
1958   # a resolved join is expressed as a multi-level from
1959   return 1 if (
1960     $extra_checks{-join}
1961       and
1962     ref $attrs->{from} eq 'ARRAY'
1963       and
1964     @{$attrs->{from}} > 1
1965   );
1966
1967   return 0;
1968 }
1969
1970 # _collapse_cond
1971 #
1972 # Recursively collapse the condition.
1973
1974 sub _collapse_cond {
1975   my ($self, $cond, $collapsed) = @_;
1976
1977   $collapsed ||= {};
1978
1979   if (ref $cond eq 'ARRAY') {
1980     foreach my $subcond (@$cond) {
1981       next unless ref $subcond;  # -or
1982       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1983     }
1984   }
1985   elsif (ref $cond eq 'HASH') {
1986     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1987       foreach my $subcond (@{$cond->{-and}}) {
1988         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1989       }
1990     }
1991     else {
1992       foreach my $col (keys %$cond) {
1993         my $value = $cond->{$col};
1994         $collapsed->{$col} = $value;
1995       }
1996     }
1997   }
1998
1999   return $collapsed;
2000 }
2001
2002 # _remove_alias
2003 #
2004 # Remove the specified alias from the specified query hash. A copy is made so
2005 # the original query is not modified.
2006
2007 sub _remove_alias {
2008   my ($self, $query, $alias) = @_;
2009
2010   my %orig = %{ $query || {} };
2011   my %unaliased;
2012
2013   foreach my $key (keys %orig) {
2014     if ($key !~ /\./) {
2015       $unaliased{$key} = $orig{$key};
2016       next;
2017     }
2018     $unaliased{$1} = $orig{$key}
2019       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2020   }
2021
2022   return \%unaliased;
2023 }
2024
2025 =head2 as_query
2026
2027 =over 4
2028
2029 =item Arguments: none
2030
2031 =item Return Value: \[ $sql, @bind ]
2032
2033 =back
2034
2035 Returns the SQL query and bind vars associated with the invocant.
2036
2037 This is generally used as the RHS for a subquery.
2038
2039 =cut
2040
2041 sub as_query {
2042   my $self = shift;
2043
2044   my $attrs = $self->_resolved_attrs_copy;
2045
2046   # For future use:
2047   #
2048   # in list ctx:
2049   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2050   # $sql also has no wrapping parenthesis in list ctx
2051   #
2052   my $sqlbind = $self->result_source->storage
2053     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2054
2055   return $sqlbind;
2056 }
2057
2058 =head2 find_or_new
2059
2060 =over 4
2061
2062 =item Arguments: \%vals, \%attrs?
2063
2064 =item Return Value: $rowobject
2065
2066 =back
2067
2068   my $artist = $schema->resultset('Artist')->find_or_new(
2069     { artist => 'fred' }, { key => 'artists' });
2070
2071   $cd->cd_to_producer->find_or_new({ producer => $producer },
2072                                    { key => 'primary });
2073
2074 Find an existing record from this resultset, based on its primary
2075 key, or a unique constraint. If none exists, instantiate a new result
2076 object and return it. The object will not be saved into your storage
2077 until you call L<DBIx::Class::Row/insert> on it.
2078
2079 You most likely want this method when looking for existing rows using
2080 a unique constraint that is not the primary key, or looking for
2081 related rows.
2082
2083 If you want objects to be saved immediately, use L</find_or_create>
2084 instead.
2085
2086 B<Note>: Take care when using C<find_or_new> with a table having
2087 columns with default values that you intend to be automatically
2088 supplied by the database (e.g. an auto_increment primary key column).
2089 In normal usage, the value of such columns should NOT be included at
2090 all in the call to C<find_or_new>, even when set to C<undef>.
2091
2092 =cut
2093
2094 sub find_or_new {
2095   my $self     = shift;
2096   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2097   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2098   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2099     return $row;
2100   }
2101   return $self->new_result($hash);
2102 }
2103
2104 =head2 create
2105
2106 =over 4
2107
2108 =item Arguments: \%vals
2109
2110 =item Return Value: a L<DBIx::Class::Row> $object
2111
2112 =back
2113
2114 Attempt to create a single new row or a row with multiple related rows
2115 in the table represented by the resultset (and related tables). This
2116 will not check for duplicate rows before inserting, use
2117 L</find_or_create> to do that.
2118
2119 To create one row for this resultset, pass a hashref of key/value
2120 pairs representing the columns of the table and the values you wish to
2121 store. If the appropriate relationships are set up, foreign key fields
2122 can also be passed an object representing the foreign row, and the
2123 value will be set to its primary key.
2124
2125 To create related objects, pass a hashref of related-object column values
2126 B<keyed on the relationship name>. If the relationship is of type C<multi>
2127 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2128 The process will correctly identify columns holding foreign keys, and will
2129 transparrently populate them from the keys of the corresponding relation.
2130 This can be applied recursively, and will work correctly for a structure
2131 with an arbitrary depth and width, as long as the relationships actually
2132 exists and the correct column data has been supplied.
2133
2134
2135 Instead of hashrefs of plain related data (key/value pairs), you may
2136 also pass new or inserted objects. New objects (not inserted yet, see
2137 L</new>), will be inserted into their appropriate tables.
2138
2139 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2140
2141 Example of creating a new row.
2142
2143   $person_rs->create({
2144     name=>"Some Person",
2145     email=>"somebody@someplace.com"
2146   });
2147
2148 Example of creating a new row and also creating rows in a related C<has_many>
2149 or C<has_one> resultset.  Note Arrayref.
2150
2151   $artist_rs->create(
2152      { artistid => 4, name => 'Manufactured Crap', cds => [
2153         { title => 'My First CD', year => 2006 },
2154         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2155       ],
2156      },
2157   );
2158
2159 Example of creating a new row and also creating a row in a related
2160 C<belongs_to>resultset. Note Hashref.
2161
2162   $cd_rs->create({
2163     title=>"Music for Silly Walks",
2164     year=>2000,
2165     artist => {
2166       name=>"Silly Musician",
2167     }
2168   });
2169
2170 =over
2171
2172 =item WARNING
2173
2174 When subclassing ResultSet never attempt to override this method. Since
2175 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2176 lot of the internals simply never call it, so your override will be
2177 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2178 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2179 L</create> process you need to intervene.
2180
2181 =back
2182
2183 =cut
2184
2185 sub create {
2186   my ($self, $attrs) = @_;
2187   $self->throw_exception( "create needs a hashref" )
2188     unless ref $attrs eq 'HASH';
2189   return $self->new_result($attrs)->insert;
2190 }
2191
2192 =head2 find_or_create
2193
2194 =over 4
2195
2196 =item Arguments: \%vals, \%attrs?
2197
2198 =item Return Value: $rowobject
2199
2200 =back
2201
2202   $cd->cd_to_producer->find_or_create({ producer => $producer },
2203                                       { key => 'primary' });
2204
2205 Tries to find a record based on its primary key or unique constraints; if none
2206 is found, creates one and returns that instead.
2207
2208   my $cd = $schema->resultset('CD')->find_or_create({
2209     cdid   => 5,
2210     artist => 'Massive Attack',
2211     title  => 'Mezzanine',
2212     year   => 2005,
2213   });
2214
2215 Also takes an optional C<key> attribute, to search by a specific key or unique
2216 constraint. For example:
2217
2218   my $cd = $schema->resultset('CD')->find_or_create(
2219     {
2220       artist => 'Massive Attack',
2221       title  => 'Mezzanine',
2222     },
2223     { key => 'cd_artist_title' }
2224   );
2225
2226 B<Note>: Because find_or_create() reads from the database and then
2227 possibly inserts based on the result, this method is subject to a race
2228 condition. Another process could create a record in the table after
2229 the find has completed and before the create has started. To avoid
2230 this problem, use find_or_create() inside a transaction.
2231
2232 B<Note>: Take care when using C<find_or_create> with a table having
2233 columns with default values that you intend to be automatically
2234 supplied by the database (e.g. an auto_increment primary key column).
2235 In normal usage, the value of such columns should NOT be included at
2236 all in the call to C<find_or_create>, even when set to C<undef>.
2237
2238 See also L</find> and L</update_or_create>. For information on how to declare
2239 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2240
2241 =cut
2242
2243 sub find_or_create {
2244   my $self     = shift;
2245   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2246   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2247   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2248     return $row;
2249   }
2250   return $self->create($hash);
2251 }
2252
2253 =head2 update_or_create
2254
2255 =over 4
2256
2257 =item Arguments: \%col_values, { key => $unique_constraint }?
2258
2259 =item Return Value: $rowobject
2260
2261 =back
2262
2263   $resultset->update_or_create({ col => $val, ... });
2264
2265 First, searches for an existing row matching one of the unique constraints
2266 (including the primary key) on the source of this resultset. If a row is
2267 found, updates it with the other given column values. Otherwise, creates a new
2268 row.
2269
2270 Takes an optional C<key> attribute to search on a specific unique constraint.
2271 For example:
2272
2273   # In your application
2274   my $cd = $schema->resultset('CD')->update_or_create(
2275     {
2276       artist => 'Massive Attack',
2277       title  => 'Mezzanine',
2278       year   => 1998,
2279     },
2280     { key => 'cd_artist_title' }
2281   );
2282
2283   $cd->cd_to_producer->update_or_create({
2284     producer => $producer,
2285     name => 'harry',
2286   }, {
2287     key => 'primary,
2288   });
2289
2290
2291 If no C<key> is specified, it searches on all unique constraints defined on the
2292 source, including the primary key.
2293
2294 If the C<key> is specified as C<primary>, it searches only on the primary key.
2295
2296 See also L</find> and L</find_or_create>. For information on how to declare
2297 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2298
2299 B<Note>: Take care when using C<update_or_create> with a table having
2300 columns with default values that you intend to be automatically
2301 supplied by the database (e.g. an auto_increment primary key column).
2302 In normal usage, the value of such columns should NOT be included at
2303 all in the call to C<update_or_create>, even when set to C<undef>.
2304
2305 =cut
2306
2307 sub update_or_create {
2308   my $self = shift;
2309   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2310   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2311
2312   my $row = $self->find($cond, $attrs);
2313   if (defined $row) {
2314     $row->update($cond);
2315     return $row;
2316   }
2317
2318   return $self->create($cond);
2319 }
2320
2321 =head2 update_or_new
2322
2323 =over 4
2324
2325 =item Arguments: \%col_values, { key => $unique_constraint }?
2326
2327 =item Return Value: $rowobject
2328
2329 =back
2330
2331   $resultset->update_or_new({ col => $val, ... });
2332
2333 First, searches for an existing row matching one of the unique constraints
2334 (including the primary key) on the source of this resultset. If a row is
2335 found, updates it with the other given column values. Otherwise, instantiate
2336 a new result object and return it. The object will not be saved into your storage
2337 until you call L<DBIx::Class::Row/insert> on it.
2338
2339 Takes an optional C<key> attribute to search on a specific unique constraint.
2340 For example:
2341
2342   # In your application
2343   my $cd = $schema->resultset('CD')->update_or_new(
2344     {
2345       artist => 'Massive Attack',
2346       title  => 'Mezzanine',
2347       year   => 1998,
2348     },
2349     { key => 'cd_artist_title' }
2350   );
2351
2352   if ($cd->in_storage) {
2353       # the cd was updated
2354   }
2355   else {
2356       # the cd is not yet in the database, let's insert it
2357       $cd->insert;
2358   }
2359
2360 B<Note>: Take care when using C<update_or_new> with a table having
2361 columns with default values that you intend to be automatically
2362 supplied by the database (e.g. an auto_increment primary key column).
2363 In normal usage, the value of such columns should NOT be included at
2364 all in the call to C<update_or_new>, even when set to C<undef>.
2365
2366 See also L</find>, L</find_or_create> and L</find_or_new>.
2367
2368 =cut
2369
2370 sub update_or_new {
2371     my $self  = shift;
2372     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2373     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2374
2375     my $row = $self->find( $cond, $attrs );
2376     if ( defined $row ) {
2377         $row->update($cond);
2378         return $row;
2379     }
2380
2381     return $self->new_result($cond);
2382 }
2383
2384 =head2 get_cache
2385
2386 =over 4
2387
2388 =item Arguments: none
2389
2390 =item Return Value: \@cache_objects?
2391
2392 =back
2393
2394 Gets the contents of the cache for the resultset, if the cache is set.
2395
2396 The cache is populated either by using the L</prefetch> attribute to
2397 L</search> or by calling L</set_cache>.
2398
2399 =cut
2400
2401 sub get_cache {
2402   shift->{all_cache};
2403 }
2404
2405 =head2 set_cache
2406
2407 =over 4
2408
2409 =item Arguments: \@cache_objects
2410
2411 =item Return Value: \@cache_objects
2412
2413 =back
2414
2415 Sets the contents of the cache for the resultset. Expects an arrayref
2416 of objects of the same class as those produced by the resultset. Note that
2417 if the cache is set the resultset will return the cached objects rather
2418 than re-querying the database even if the cache attr is not set.
2419
2420 The contents of the cache can also be populated by using the
2421 L</prefetch> attribute to L</search>.
2422
2423 =cut
2424
2425 sub set_cache {
2426   my ( $self, $data ) = @_;
2427   $self->throw_exception("set_cache requires an arrayref")
2428       if defined($data) && (ref $data ne 'ARRAY');
2429   $self->{all_cache} = $data;
2430 }
2431
2432 =head2 clear_cache
2433
2434 =over 4
2435
2436 =item Arguments: none
2437
2438 =item Return Value: []
2439
2440 =back
2441
2442 Clears the cache for the resultset.
2443
2444 =cut
2445
2446 sub clear_cache {
2447   shift->set_cache(undef);
2448 }
2449
2450 =head2 is_paged
2451
2452 =over 4
2453
2454 =item Arguments: none
2455
2456 =item Return Value: true, if the resultset has been paginated
2457
2458 =back
2459
2460 =cut
2461
2462 sub is_paged {
2463   my ($self) = @_;
2464   return !!$self->{attrs}{page};
2465 }
2466
2467 =head2 related_resultset
2468
2469 =over 4
2470
2471 =item Arguments: $relationship_name
2472
2473 =item Return Value: $resultset
2474
2475 =back
2476
2477 Returns a related resultset for the supplied relationship name.
2478
2479   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2480
2481 =cut
2482
2483 sub related_resultset {
2484   my ($self, $rel) = @_;
2485
2486   $self->{related_resultsets} ||= {};
2487   return $self->{related_resultsets}{$rel} ||= do {
2488     my $rsrc = $self->result_source;
2489     my $rel_info = $rsrc->relationship_info($rel);
2490
2491     $self->throw_exception(
2492       "search_related: result source '" . $rsrc->source_name .
2493         "' has no such relationship $rel")
2494       unless $rel_info;
2495
2496     my $attrs = $self->_chain_relationship($rel);
2497
2498     my $join_count = $attrs->{seen_join}{$rel};
2499
2500     my $alias = $self->result_source->storage
2501         ->relname_to_table_alias($rel, $join_count);
2502
2503     # since this is search_related, and we already slid the select window inwards
2504     # (the select/as attrs were deleted in the beginning), we need to flip all
2505     # left joins to inner, so we get the expected results
2506     # read the comment on top of the actual function to see what this does
2507     $attrs->{from} = $rsrc->schema->storage->_straight_join_to_node ($attrs->{from}, $alias);
2508
2509
2510     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2511     delete @{$attrs}{qw(result_class alias)};
2512
2513     my $new_cache;
2514
2515     if (my $cache = $self->get_cache) {
2516       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2517         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2518                         @$cache ];
2519       }
2520     }
2521
2522     my $rel_source = $rsrc->related_source($rel);
2523
2524     my $new = do {
2525
2526       # The reason we do this now instead of passing the alias to the
2527       # search_rs below is that if you wrap/overload resultset on the
2528       # source you need to know what alias it's -going- to have for things
2529       # to work sanely (e.g. RestrictWithObject wants to be able to add
2530       # extra query restrictions, and these may need to be $alias.)
2531
2532       my $rel_attrs = $rel_source->resultset_attributes;
2533       local $rel_attrs->{alias} = $alias;
2534
2535       $rel_source->resultset
2536                  ->search_rs(
2537                      undef, {
2538                        %$attrs,
2539                        where => $attrs->{where},
2540                    });
2541     };
2542     $new->set_cache($new_cache) if $new_cache;
2543     $new;
2544   };
2545 }
2546
2547 =head2 current_source_alias
2548
2549 =over 4
2550
2551 =item Arguments: none
2552
2553 =item Return Value: $source_alias
2554
2555 =back
2556
2557 Returns the current table alias for the result source this resultset is built
2558 on, that will be used in the SQL query. Usually it is C<me>.
2559
2560 Currently the source alias that refers to the result set returned by a
2561 L</search>/L</find> family method depends on how you got to the resultset: it's
2562 C<me> by default, but eg. L</search_related> aliases it to the related result
2563 source name (and keeps C<me> referring to the original result set). The long
2564 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2565 (and make this method unnecessary).
2566
2567 Thus it's currently necessary to use this method in predefined queries (see
2568 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2569 source alias of the current result set:
2570
2571   # in a result set class
2572   sub modified_by {
2573     my ($self, $user) = @_;
2574
2575     my $me = $self->current_source_alias;
2576
2577     return $self->search(
2578       "$me.modified" => $user->id,
2579     );
2580   }
2581
2582 =cut
2583
2584 sub current_source_alias {
2585   my ($self) = @_;
2586
2587   return ($self->{attrs} || {})->{alias} || 'me';
2588 }
2589
2590 # This code is called by search_related, and makes sure there
2591 # is clear separation between the joins before, during, and
2592 # after the relationship. This information is needed later
2593 # in order to properly resolve prefetch aliases (any alias
2594 # with a relation_chain_depth less than the depth of the
2595 # current prefetch is not considered)
2596 #
2597 # The increments happen twice per join. An even number means a
2598 # relationship specified via a search_related, whereas an odd
2599 # number indicates a join/prefetch added via attributes
2600 #
2601 # Also this code will wrap the current resultset (the one we
2602 # chain to) in a subselect IFF it contains limiting attributes
2603 sub _chain_relationship {
2604   my ($self, $rel) = @_;
2605   my $source = $self->result_source;
2606   my $attrs = { %{$self->{attrs}||{}} };
2607
2608   # we need to take the prefetch the attrs into account before we
2609   # ->_resolve_join as otherwise they get lost - captainL
2610   my $join = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2611
2612   delete @{$attrs}{qw/join prefetch collapse distinct select as columns +select +as +columns/};
2613
2614   my $seen = { %{ (delete $attrs->{seen_join}) || {} } };
2615
2616   my $from;
2617   my @force_subq_attrs = qw/offset rows group_by having/;
2618
2619   if (
2620     ($attrs->{from} && ref $attrs->{from} ne 'ARRAY')
2621       ||
2622     $self->_has_resolved_attr (@force_subq_attrs)
2623   ) {
2624     # Nuke the prefetch (if any) before the new $rs attrs
2625     # are resolved (prefetch is useless - we are wrapping
2626     # a subquery anyway).
2627     my $rs_copy = $self->search;
2628     $rs_copy->{attrs}{join} = $self->_merge_attr (
2629       $rs_copy->{attrs}{join},
2630       delete $rs_copy->{attrs}{prefetch},
2631     );
2632
2633     $from = [{
2634       -source_handle => $source->handle,
2635       -alias => $attrs->{alias},
2636       $attrs->{alias} => $rs_copy->as_query,
2637     }];
2638     delete @{$attrs}{@force_subq_attrs, 'where'};
2639     $seen->{-relation_chain_depth} = 0;
2640   }
2641   elsif ($attrs->{from}) {  #shallow copy suffices
2642     $from = [ @{$attrs->{from}} ];
2643   }
2644   else {
2645     $from = [{
2646       -source_handle => $source->handle,
2647       -alias => $attrs->{alias},
2648       $attrs->{alias} => $source->from,
2649     }];
2650   }
2651
2652   my $jpath = ($seen->{-relation_chain_depth})
2653     ? $from->[-1][0]{-join_path}
2654     : [];
2655
2656   my @requested_joins = $source->_resolve_join(
2657     $join,
2658     $attrs->{alias},
2659     $seen,
2660     $jpath,
2661   );
2662
2663   push @$from, @requested_joins;
2664
2665   $seen->{-relation_chain_depth}++;
2666
2667   # if $self already had a join/prefetch specified on it, the requested
2668   # $rel might very well be already included. What we do in this case
2669   # is effectively a no-op (except that we bump up the chain_depth on
2670   # the join in question so we could tell it *is* the search_related)
2671   my $already_joined;
2672
2673   # we consider the last one thus reverse
2674   for my $j (reverse @requested_joins) {
2675     my ($last_j) = keys %{$j->[0]{-join_path}[-1]};
2676     if ($rel eq $last_j) {
2677       $j->[0]{-relation_chain_depth}++;
2678       $already_joined++;
2679       last;
2680     }
2681   }
2682
2683   unless ($already_joined) {
2684     push @$from, $source->_resolve_join(
2685       $rel,
2686       $attrs->{alias},
2687       $seen,
2688       $jpath,
2689     );
2690   }
2691
2692   $seen->{-relation_chain_depth}++;
2693
2694   return {%$attrs, from => $from, seen_join => $seen};
2695 }
2696
2697 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2698 sub _resolved_attrs_copy {
2699   my $self = shift;
2700   return { %{$self->_resolved_attrs (@_)} };
2701 }
2702
2703 sub _resolved_attrs {
2704   my $self = shift;
2705   return $self->{_attrs} if $self->{_attrs};
2706
2707   my $attrs  = { %{ $self->{attrs} || {} } };
2708   my $source = $self->result_source;
2709   my $alias  = $attrs->{alias};
2710
2711   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2712   my @colbits;
2713
2714   # build columns (as long as select isn't set) into a set of as/select hashes
2715   unless ( $attrs->{select} ) {
2716
2717     my @cols;
2718     if ( ref $attrs->{columns} eq 'ARRAY' ) {
2719       @cols = @{ delete $attrs->{columns}}
2720     } elsif ( defined $attrs->{columns} ) {
2721       @cols = delete $attrs->{columns}
2722     } else {
2723       @cols = $source->columns
2724     }
2725
2726     for (@cols) {
2727       if ( ref $_ eq 'HASH' ) {
2728         push @colbits, $_
2729       } else {
2730         my $key = /^\Q${alias}.\E(.+)$/
2731           ? "$1"
2732           : "$_";
2733         my $value = /\./
2734           ? "$_"
2735           : "${alias}.$_";
2736         push @colbits, { $key => $value };
2737       }
2738     }
2739   }
2740
2741   # add the additional columns on
2742   foreach (qw{include_columns +columns}) {
2743     if ( $attrs->{$_} ) {
2744       my @list = ( ref($attrs->{$_}) eq 'ARRAY' )
2745         ? @{ delete $attrs->{$_} }
2746         : delete $attrs->{$_};
2747       for (@list) {
2748         if ( ref($_) eq 'HASH' ) {
2749           push @colbits, $_
2750         } else {
2751           my $key = ( split /\./, $_ )[-1];
2752           my $value = ( /\./ ? $_ : "$alias.$_" );
2753           push @colbits, { $key => $value };
2754         }
2755       }
2756     }
2757   }
2758
2759   # start with initial select items
2760   if ( $attrs->{select} ) {
2761     $attrs->{select} =
2762         ( ref $attrs->{select} eq 'ARRAY' )
2763       ? [ @{ $attrs->{select} } ]
2764       : [ $attrs->{select} ];
2765
2766     if ( $attrs->{as} ) {
2767       $attrs->{as} =
2768         (
2769           ref $attrs->{as} eq 'ARRAY'
2770             ? [ @{ $attrs->{as} } ]
2771             : [ $attrs->{as} ]
2772         )
2773     } else {
2774       $attrs->{as} = [ map {
2775          m/^\Q${alias}.\E(.+)$/
2776            ? $1
2777            : $_
2778          } @{ $attrs->{select} }
2779       ]
2780     }
2781   }
2782   else {
2783
2784     # otherwise we intialise select & as to empty
2785     $attrs->{select} = [];
2786     $attrs->{as}     = [];
2787   }
2788
2789   # now add colbits to select/as
2790   push @{ $attrs->{select} }, map values %{$_}, @colbits;
2791   push @{ $attrs->{as}     }, map keys   %{$_}, @colbits;
2792
2793   if ( my $adds = $attrs->{'+select'} ) {
2794     $adds = [$adds] unless ref $adds eq 'ARRAY';
2795     push @{ $attrs->{select} },
2796       map { /\./ || ref $_ ? $_ : "$alias.$_" } @$adds;
2797   }
2798   if ( my $adds = $attrs->{'+as'} ) {
2799     $adds = [$adds] unless ref $adds eq 'ARRAY';
2800     push @{ $attrs->{as} }, @$adds;
2801   }
2802
2803   $attrs->{from} ||= [{
2804     -source_handle => $source->handle,
2805     -alias => $self->{attrs}{alias},
2806     $self->{attrs}{alias} => $source->from,
2807   }];
2808
2809   if ( $attrs->{join} || $attrs->{prefetch} ) {
2810
2811     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2812       if ref $attrs->{from} ne 'ARRAY';
2813
2814     my $join = delete $attrs->{join} || {};
2815
2816     if ( defined $attrs->{prefetch} ) {
2817       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2818     }
2819
2820     $attrs->{from} =    # have to copy here to avoid corrupting the original
2821       [
2822         @{ $attrs->{from} },
2823         $source->_resolve_join(
2824           $join,
2825           $alias,
2826           { %{ $attrs->{seen_join} || {} } },
2827           ( $attrs->{seen_join} && keys %{$attrs->{seen_join}})
2828             ? $attrs->{from}[-1][0]{-join_path}
2829             : []
2830           ,
2831         )
2832       ];
2833   }
2834
2835   if ( defined $attrs->{order_by} ) {
2836     $attrs->{order_by} = (
2837       ref( $attrs->{order_by} ) eq 'ARRAY'
2838       ? [ @{ $attrs->{order_by} } ]
2839       : [ $attrs->{order_by} || () ]
2840     );
2841   }
2842
2843   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2844     $attrs->{group_by} = [ $attrs->{group_by} ];
2845   }
2846
2847   # generate the distinct induced group_by early, as prefetch will be carried via a
2848   # subquery (since a group_by is present)
2849   if (delete $attrs->{distinct}) {
2850     if ($attrs->{group_by}) {
2851       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2852     }
2853     else {
2854       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2855
2856       # add any order_by parts that are not already present in the group_by
2857       # we need to be careful not to add any named functions/aggregates
2858       # i.e. select => [ ... { count => 'foo', -as 'foocount' } ... ]
2859       my %already_grouped = map { $_ => 1 } (@{$attrs->{group_by}});
2860
2861       my $storage = $self->result_source->schema->storage;
2862
2863       my $rs_column_list = $storage->_resolve_column_info ($attrs->{from});
2864
2865       for my $chunk ($storage->_parse_order_by($attrs->{order_by})) {
2866         if ($rs_column_list->{$chunk} && not $already_grouped{$chunk}++) {
2867           push @{$attrs->{group_by}}, $chunk;
2868         }
2869       }
2870     }
2871   }
2872
2873   $attrs->{collapse} ||= {};
2874   if ( my $prefetch = delete $attrs->{prefetch} ) {
2875     $prefetch = $self->_merge_attr( {}, $prefetch );
2876
2877     my $prefetch_ordering = [];
2878
2879     # this is a separate structure (we don't look in {from} directly)
2880     # as the resolver needs to shift things off the lists to work
2881     # properly (identical-prefetches on different branches)
2882     my $join_map = {};
2883     if (ref $attrs->{from} eq 'ARRAY') {
2884
2885       my $start_depth = $attrs->{seen_join}{-relation_chain_depth} || 0;
2886
2887       for my $j ( @{$attrs->{from}}[1 .. $#{$attrs->{from}} ] ) {
2888         next unless $j->[0]{-alias};
2889         next unless $j->[0]{-join_path};
2890         next if ($j->[0]{-relation_chain_depth} || 0) < $start_depth;
2891
2892         my @jpath = map { keys %$_ } @{$j->[0]{-join_path}};
2893
2894         my $p = $join_map;
2895         $p = $p->{$_} ||= {} for @jpath[ ($start_depth/2) .. $#jpath]; #only even depths are actual jpath boundaries
2896         push @{$p->{-join_aliases} }, $j->[0]{-alias};
2897       }
2898     }
2899
2900     my @prefetch =
2901       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2902
2903     # we need to somehow mark which columns came from prefetch
2904     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2905
2906     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2907     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2908
2909     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2910     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2911   }
2912
2913   # if both page and offset are specified, produce a combined offset
2914   # even though it doesn't make much sense, this is what pre 081xx has
2915   # been doing
2916   if (my $page = delete $attrs->{page}) {
2917     $attrs->{offset} =
2918       ($attrs->{rows} * ($page - 1))
2919             +
2920       ($attrs->{offset} || 0)
2921     ;
2922   }
2923
2924   return $self->{_attrs} = $attrs;
2925 }
2926
2927 sub _rollout_attr {
2928   my ($self, $attr) = @_;
2929
2930   if (ref $attr eq 'HASH') {
2931     return $self->_rollout_hash($attr);
2932   } elsif (ref $attr eq 'ARRAY') {
2933     return $self->_rollout_array($attr);
2934   } else {
2935     return [$attr];
2936   }
2937 }
2938
2939 sub _rollout_array {
2940   my ($self, $attr) = @_;
2941
2942   my @rolled_array;
2943   foreach my $element (@{$attr}) {
2944     if (ref $element eq 'HASH') {
2945       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2946     } elsif (ref $element eq 'ARRAY') {
2947       #  XXX - should probably recurse here
2948       push( @rolled_array, @{$self->_rollout_array($element)} );
2949     } else {
2950       push( @rolled_array, $element );
2951     }
2952   }
2953   return \@rolled_array;
2954 }
2955
2956 sub _rollout_hash {
2957   my ($self, $attr) = @_;
2958
2959   my @rolled_array;
2960   foreach my $key (keys %{$attr}) {
2961     push( @rolled_array, { $key => $attr->{$key} } );
2962   }
2963   return \@rolled_array;
2964 }
2965
2966 sub _calculate_score {
2967   my ($self, $a, $b) = @_;
2968
2969   if (defined $a xor defined $b) {
2970     return 0;
2971   }
2972   elsif (not defined $a) {
2973     return 1;
2974   }
2975
2976   if (ref $b eq 'HASH') {
2977     my ($b_key) = keys %{$b};
2978     if (ref $a eq 'HASH') {
2979       my ($a_key) = keys %{$a};
2980       if ($a_key eq $b_key) {
2981         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2982       } else {
2983         return 0;
2984       }
2985     } else {
2986       return ($a eq $b_key) ? 1 : 0;
2987     }
2988   } else {
2989     if (ref $a eq 'HASH') {
2990       my ($a_key) = keys %{$a};
2991       return ($b eq $a_key) ? 1 : 0;
2992     } else {
2993       return ($b eq $a) ? 1 : 0;
2994     }
2995   }
2996 }
2997
2998 sub _merge_attr {
2999   my ($self, $orig, $import) = @_;
3000
3001   return $import unless defined($orig);
3002   return $orig unless defined($import);
3003
3004   $orig = $self->_rollout_attr($orig);
3005   $import = $self->_rollout_attr($import);
3006
3007   my $seen_keys;
3008   foreach my $import_element ( @{$import} ) {
3009     # find best candidate from $orig to merge $b_element into
3010     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3011     foreach my $orig_element ( @{$orig} ) {
3012       my $score = $self->_calculate_score( $orig_element, $import_element );
3013       if ($score > $best_candidate->{score}) {
3014         $best_candidate->{position} = $position;
3015         $best_candidate->{score} = $score;
3016       }
3017       $position++;
3018     }
3019     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3020
3021     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3022       push( @{$orig}, $import_element );
3023     } else {
3024       my $orig_best = $orig->[$best_candidate->{position}];
3025       # merge orig_best and b_element together and replace original with merged
3026       if (ref $orig_best ne 'HASH') {
3027         $orig->[$best_candidate->{position}] = $import_element;
3028       } elsif (ref $import_element eq 'HASH') {
3029         my ($key) = keys %{$orig_best};
3030         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3031       }
3032     }
3033     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3034   }
3035
3036   return $orig;
3037 }
3038
3039 sub result_source {
3040     my $self = shift;
3041
3042     if (@_) {
3043         $self->_source_handle($_[0]->handle);
3044     } else {
3045         $self->_source_handle->resolve;
3046     }
3047 }
3048
3049 =head2 throw_exception
3050
3051 See L<DBIx::Class::Schema/throw_exception> for details.
3052
3053 =cut
3054
3055 sub throw_exception {
3056   my $self=shift;
3057
3058   if (ref $self && $self->_source_handle->schema) {
3059     $self->_source_handle->schema->throw_exception(@_)
3060   }
3061   else {
3062     DBIx::Class::Exception->throw(@_);
3063   }
3064 }
3065
3066 # XXX: FIXME: Attributes docs need clearing up
3067
3068 =head1 ATTRIBUTES
3069
3070 Attributes are used to refine a ResultSet in various ways when
3071 searching for data. They can be passed to any method which takes an
3072 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3073 L</count>.
3074
3075 These are in no particular order:
3076
3077 =head2 order_by
3078
3079 =over 4
3080
3081 =item Value: ( $order_by | \@order_by | \%order_by )
3082
3083 =back
3084
3085 Which column(s) to order the results by.
3086
3087 [The full list of suitable values is documented in
3088 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3089 common options.]
3090
3091 If a single column name, or an arrayref of names is supplied, the
3092 argument is passed through directly to SQL. The hashref syntax allows
3093 for connection-agnostic specification of ordering direction:
3094
3095  For descending order:
3096
3097   order_by => { -desc => [qw/col1 col2 col3/] }
3098
3099  For explicit ascending order:
3100
3101   order_by => { -asc => 'col' }
3102
3103 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3104 supported, although you are strongly encouraged to use the hashref
3105 syntax as outlined above.
3106
3107 =head2 columns
3108
3109 =over 4
3110
3111 =item Value: \@columns
3112
3113 =back
3114
3115 Shortcut to request a particular set of columns to be retrieved. Each
3116 column spec may be a string (a table column name), or a hash (in which
3117 case the key is the C<as> value, and the value is used as the C<select>
3118 expression). Adds C<me.> onto the start of any column without a C<.> in
3119 it and sets C<select> from that, then auto-populates C<as> from
3120 C<select> as normal. (You may also use the C<cols> attribute, as in
3121 earlier versions of DBIC.)
3122
3123 =head2 +columns
3124
3125 =over 4
3126
3127 =item Value: \@columns
3128
3129 =back
3130
3131 Indicates additional columns to be selected from storage. Works the same
3132 as L</columns> but adds columns to the selection. (You may also use the
3133 C<include_columns> attribute, as in earlier versions of DBIC). For
3134 example:-
3135
3136   $schema->resultset('CD')->search(undef, {
3137     '+columns' => ['artist.name'],
3138     join => ['artist']
3139   });
3140
3141 would return all CDs and include a 'name' column to the information
3142 passed to object inflation. Note that the 'artist' is the name of the
3143 column (or relationship) accessor, and 'name' is the name of the column
3144 accessor in the related table.
3145
3146 =head2 include_columns
3147
3148 =over 4
3149
3150 =item Value: \@columns
3151
3152 =back
3153
3154 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3155
3156 =head2 select
3157
3158 =over 4
3159
3160 =item Value: \@select_columns
3161
3162 =back
3163
3164 Indicates which columns should be selected from the storage. You can use
3165 column names, or in the case of RDBMS back ends, function or stored procedure
3166 names:
3167
3168   $rs = $schema->resultset('Employee')->search(undef, {
3169     select => [
3170       'name',
3171       { count => 'employeeid' },
3172       { sum => 'salary' }
3173     ]
3174   });
3175
3176 When you use function/stored procedure names and do not supply an C<as>
3177 attribute, the column names returned are storage-dependent. E.g. MySQL would
3178 return a column named C<count(employeeid)> in the above example.
3179
3180 B<NOTE:> You will almost always need a corresponding 'as' entry when you use
3181 'select'.
3182
3183 =head2 +select
3184
3185 =over 4
3186
3187 Indicates additional columns to be selected from storage.  Works the same as
3188 L</select> but adds columns to the selection.
3189
3190 =back
3191
3192 =head2 +as
3193
3194 =over 4
3195
3196 Indicates additional column names for those added via L</+select>. See L</as>.
3197
3198 =back
3199
3200 =head2 as
3201
3202 =over 4
3203
3204 =item Value: \@inflation_names
3205
3206 =back
3207
3208 Indicates column names for object inflation. That is, C<as>
3209 indicates the name that the column can be accessed as via the
3210 C<get_column> method (or via the object accessor, B<if one already
3211 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3212
3213 The C<as> attribute is used in conjunction with C<select>,
3214 usually when C<select> contains one or more function or stored
3215 procedure names:
3216
3217   $rs = $schema->resultset('Employee')->search(undef, {
3218     select => [
3219       'name',
3220       { count => 'employeeid' }
3221     ],
3222     as => ['name', 'employee_count'],
3223   });
3224
3225   my $employee = $rs->first(); # get the first Employee
3226
3227 If the object against which the search is performed already has an accessor
3228 matching a column name specified in C<as>, the value can be retrieved using
3229 the accessor as normal:
3230
3231   my $name = $employee->name();
3232
3233 If on the other hand an accessor does not exist in the object, you need to
3234 use C<get_column> instead:
3235
3236   my $employee_count = $employee->get_column('employee_count');
3237
3238 You can create your own accessors if required - see
3239 L<DBIx::Class::Manual::Cookbook> for details.
3240
3241 Please note: This will NOT insert an C<AS employee_count> into the SQL
3242 statement produced, it is used for internal access only. Thus
3243 attempting to use the accessor in an C<order_by> clause or similar
3244 will fail miserably.
3245
3246 To get around this limitation, you can supply literal SQL to your
3247 C<select> attibute that contains the C<AS alias> text, eg:
3248
3249   select => [\'myfield AS alias']
3250
3251 =head2 join
3252
3253 =over 4
3254
3255 =item Value: ($rel_name | \@rel_names | \%rel_names)
3256
3257 =back
3258
3259 Contains a list of relationships that should be joined for this query.  For
3260 example:
3261
3262   # Get CDs by Nine Inch Nails
3263   my $rs = $schema->resultset('CD')->search(
3264     { 'artist.name' => 'Nine Inch Nails' },
3265     { join => 'artist' }
3266   );
3267
3268 Can also contain a hash reference to refer to the other relation's relations.
3269 For example:
3270
3271   package MyApp::Schema::Track;
3272   use base qw/DBIx::Class/;
3273   __PACKAGE__->table('track');
3274   __PACKAGE__->add_columns(qw/trackid cd position title/);
3275   __PACKAGE__->set_primary_key('trackid');
3276   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3277   1;
3278
3279   # In your application
3280   my $rs = $schema->resultset('Artist')->search(
3281     { 'track.title' => 'Teardrop' },
3282     {
3283       join     => { cd => 'track' },
3284       order_by => 'artist.name',
3285     }
3286   );
3287
3288 You need to use the relationship (not the table) name in  conditions,
3289 because they are aliased as such. The current table is aliased as "me", so
3290 you need to use me.column_name in order to avoid ambiguity. For example:
3291
3292   # Get CDs from 1984 with a 'Foo' track
3293   my $rs = $schema->resultset('CD')->search(
3294     {
3295       'me.year' => 1984,
3296       'tracks.name' => 'Foo'
3297     },
3298     { join => 'tracks' }
3299   );
3300
3301 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3302 similarly for a third time). For e.g.
3303
3304   my $rs = $schema->resultset('Artist')->search({
3305     'cds.title'   => 'Down to Earth',
3306     'cds_2.title' => 'Popular',
3307   }, {
3308     join => [ qw/cds cds/ ],
3309   });
3310
3311 will return a set of all artists that have both a cd with title 'Down
3312 to Earth' and a cd with title 'Popular'.
3313
3314 If you want to fetch related objects from other tables as well, see C<prefetch>
3315 below.
3316
3317 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3318
3319 =head2 prefetch
3320
3321 =over 4
3322
3323 =item Value: ($rel_name | \@rel_names | \%rel_names)
3324
3325 =back
3326
3327 Contains one or more relationships that should be fetched along with
3328 the main query (when they are accessed afterwards the data will
3329 already be available, without extra queries to the database).  This is
3330 useful for when you know you will need the related objects, because it
3331 saves at least one query:
3332
3333   my $rs = $schema->resultset('Tag')->search(
3334     undef,
3335     {
3336       prefetch => {
3337         cd => 'artist'
3338       }
3339     }
3340   );
3341
3342 The initial search results in SQL like the following:
3343
3344   SELECT tag.*, cd.*, artist.* FROM tag
3345   JOIN cd ON tag.cd = cd.cdid
3346   JOIN artist ON cd.artist = artist.artistid
3347
3348 L<DBIx::Class> has no need to go back to the database when we access the
3349 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3350 case.
3351
3352 Simple prefetches will be joined automatically, so there is no need
3353 for a C<join> attribute in the above search.
3354
3355 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3356 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3357 with an accessor type of 'single' or 'filter'). A more complex example that
3358 prefetches an artists cds, the tracks on those cds, and the tags associted
3359 with that artist is given below (assuming many-to-many from artists to tags):
3360
3361  my $rs = $schema->resultset('Artist')->search(
3362    undef,
3363    {
3364      prefetch => [
3365        { cds => 'tracks' },
3366        { artist_tags => 'tags' }
3367      ]
3368    }
3369  );
3370
3371
3372 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3373 attributes will be ignored.
3374
3375 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3376 exactly as you might expect.
3377
3378 =over 4
3379
3380 =item *
3381
3382 Prefetch uses the L</cache> to populate the prefetched relationships. This
3383 may or may not be what you want.
3384
3385 =item *
3386
3387 If you specify a condition on a prefetched relationship, ONLY those
3388 rows that match the prefetched condition will be fetched into that relationship.
3389 This means that adding prefetch to a search() B<may alter> what is returned by
3390 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3391
3392   my $artist_rs = $schema->resultset('Artist')->search({
3393       'cds.year' => 2008,
3394   }, {
3395       join => 'cds',
3396   });
3397
3398   my $count = $artist_rs->first->cds->count;
3399
3400   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3401
3402   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3403
3404   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3405
3406 that cmp_ok() may or may not pass depending on the datasets involved. This
3407 behavior may or may not survive the 0.09 transition.
3408
3409 =back
3410
3411 =head2 page
3412
3413 =over 4
3414
3415 =item Value: $page
3416
3417 =back
3418
3419 Makes the resultset paged and specifies the page to retrieve. Effectively
3420 identical to creating a non-pages resultset and then calling ->page($page)
3421 on it.
3422
3423 If L<rows> attribute is not specified it defaults to 10 rows per page.
3424
3425 When you have a paged resultset, L</count> will only return the number
3426 of rows in the page. To get the total, use the L</pager> and call
3427 C<total_entries> on it.
3428
3429 =head2 rows
3430
3431 =over 4
3432
3433 =item Value: $rows
3434
3435 =back
3436
3437 Specifes the maximum number of rows for direct retrieval or the number of
3438 rows per page if the page attribute or method is used.
3439
3440 =head2 offset
3441
3442 =over 4
3443
3444 =item Value: $offset
3445
3446 =back
3447
3448 Specifies the (zero-based) row number for the  first row to be returned, or the
3449 of the first row of the first page if paging is used.
3450
3451 =head2 group_by
3452
3453 =over 4
3454
3455 =item Value: \@columns
3456
3457 =back
3458
3459 A arrayref of columns to group by. Can include columns of joined tables.
3460
3461   group_by => [qw/ column1 column2 ... /]
3462
3463 =head2 having
3464
3465 =over 4
3466
3467 =item Value: $condition
3468
3469 =back
3470
3471 HAVING is a select statement attribute that is applied between GROUP BY and
3472 ORDER BY. It is applied to the after the grouping calculations have been
3473 done.
3474
3475   having => { 'count(employee)' => { '>=', 100 } }
3476
3477 =head2 distinct
3478
3479 =over 4
3480
3481 =item Value: (0 | 1)
3482
3483 =back
3484
3485 Set to 1 to group by all columns. If the resultset already has a group_by
3486 attribute, this setting is ignored and an appropriate warning is issued.
3487
3488 =head2 where
3489
3490 =over 4
3491
3492 Adds to the WHERE clause.
3493
3494   # only return rows WHERE deleted IS NULL for all searches
3495   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3496
3497 Can be overridden by passing C<< { where => undef } >> as an attribute
3498 to a resultset.
3499
3500 =back
3501
3502 =head2 cache
3503
3504 Set to 1 to cache search results. This prevents extra SQL queries if you
3505 revisit rows in your ResultSet:
3506
3507   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3508
3509   while( my $artist = $resultset->next ) {
3510     ... do stuff ...
3511   }
3512
3513   $rs->first; # without cache, this would issue a query
3514
3515 By default, searches are not cached.
3516
3517 For more examples of using these attributes, see
3518 L<DBIx::Class::Manual::Cookbook>.
3519
3520 =head2 for
3521
3522 =over 4
3523
3524 =item Value: ( 'update' | 'shared' )
3525
3526 =back
3527
3528 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3529 ... FOR SHARED.
3530
3531 =cut
3532
3533 1;