lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   else {
 517     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 518     $query = @unique_queries
 519       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 520       : $self->_add_alias($input_query, $alias);
 521   }
 522
 523   # Run the query
 524   if (keys %$attrs) {
 525     my $rs = $self->search($query, $attrs);
 526     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 527       my $row = $rs->next;
 528       carp "Query returned more than one row" if $rs->next;
 529       return $row;
 530     }
 531     else {
 532       return $rs->single;
 533     }
 534   }
 535   else {
 536     if (keys %{$self->_resolved_attrs->{collapse}}) {
 537       my $rs = $self->search($query);
 538       my $row = $rs->next;
 539       carp "Query returned more than one row" if $rs->next;
 540       return $row;
 541     }
 542     else {
 543       return $self->single($query);
 544     }
 545   }
 546 }
 547
 548 # _add_alias
 549 #
 550 # Add the specified alias to the specified query hash. A copy is made so the
 551 # original query is not modified.
 552
 553 sub _add_alias {
 554   my ($self, $query, $alias) = @_;
 555
 556   my %aliased = %$query;
 557   foreach my $col (grep { ! m/\./ } keys %aliased) {
 558     $aliased{"$alias.$col"} = delete $aliased{$col};
 559   }
 560
 561   return \%aliased;
 562 }
 563
 564 # _unique_queries
 565 #
 566 # Build a list of queries which satisfy unique constraints.
 567
 568 sub _unique_queries {
 569   my ($self, $query, $attrs) = @_;
 570
 571   my @constraint_names = exists $attrs->{key}
 572     ? ($attrs->{key})
 573     : $self->result_source->unique_constraint_names;
 574
 575   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 576   my $num_where = scalar keys %$where;
 577
 578   my @unique_queries;
 579   foreach my $name (@constraint_names) {
 580     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 581     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 582
 583     my $num_cols = scalar @unique_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 665
 666   return $self->{cursor}
 667     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 668           $attrs->{where},$attrs);
 669 }
 670
 671 =head2 single
 672
 673 =over 4
 674
 675 =item Arguments: $cond?
 676
 677 =item Return Value: $row_object?
 678
 679 =back
 680
 681   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 682
 683 Inflates the first result without creating a cursor if the resultset has
 684 any records in it; if not returns nothing. Used by L</find> as a lean version of
 685 L</search>.
 686
 687 While this method can take an optional search condition (just like L</search>)
 688 being a fast-code-path it does not recognize search attributes. If you need to
 689 add extra joins or similar, call L</search> and then chain-call L</single> on the
 690 L<DBIx::Class::ResultSet> returned.
 691
 692 =over
 693
 694 =item B<Note>
 695
 696 As of 0.08100, this method enforces the assumption that the preceeding
 697 query returns only one row. If more than one row is returned, you will receive
 698 a warning:
 699
 700   Query returned more than one row
 701
 702 In this case, you should be using L</first> or L</find> instead, or if you really
 703 know what you are doing, use the L</rows> attribute to explicitly limit the size
 704 of the resultset.
 705
 706 =back
 707
 708 =cut
 709
 710 sub single {
 711   my ($self, $where) = @_;
 712   if(@_ > 2) {
 713       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 714   }
 715
 716   my $attrs = $self->_resolved_attrs_copy;
 717   $attrs->{_virtual_order_by} = $self->_gen_virtual_order;
 718
 719   if ($where) {
 720     if (defined $attrs->{where}) {
 721       $attrs->{where} = {
 722         '-and' =>
 723             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 724                $where, delete $attrs->{where} ]
 725       };
 726     } else {
 727       $attrs->{where} = $where;
 728     }
 729   }
 730
 731 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 732 #  unless ($self->_is_unique_query($attrs->{where})) {
 733 #    carp "Query not guaranteed to return a single row"
 734 #      . "; please declare your unique constraints or use search instead";
 735 #  }
 736
 737   my @data = $self->result_source->storage->select_single(
 738     $attrs->{from}, $attrs->{select},
 739     $attrs->{where}, $attrs
 740   );
 741
 742   return (@data ? ($self->_construct_object(@data))[0] : undef);
 743 }
 744
 745 # _gen_virtual_order
 746 #
 747 # This is a horrble hack, but seems like the best we can do at this point
 748 # Some limit emulations (Top) require an ordered resultset in order to
 749 # function at all. So supply a PK order to be used if necessary
 750
 751 sub _gen_virtual_order {
 752   return [ shift->result_source->primary_columns ];
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp (
 874     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 875    .' Instead use ->search({ x => { -like => "y%" } })'
 876    .' (note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. Passing arguments is equivalent to
1149 C<< $rs->search ($cond, \%attrs)->count >>
1150
1151 =cut
1152
1153 sub count {
1154   my $self = shift;
1155   return $self->search(@_)->count if @_ and defined $_[0];
1156   return scalar @{ $self->get_cache } if $self->get_cache;
1157
1158   my @grouped_subq_attrs = qw/prefetch collapse distinct group_by having/;
1159   my @subq_attrs = ();
1160
1161   my $attrs = $self->_resolved_attrs;
1162   # if we are not paged - we are simply asking for a limit
1163   if (not $attrs->{page} and not $attrs->{software_limit}) {
1164     push @subq_attrs, qw/rows offset/;
1165   }
1166
1167   my $need_subq = $self->_has_attr (@subq_attrs);
1168   my $need_group_subq = $self->_has_attr (@grouped_subq_attrs);
1169
1170   return ($need_subq || $need_group_subq)
1171     ? $self->_count_subq ($need_group_subq)
1172     : $self->_count_simple
1173 }
1174
1175 sub _count_subq {
1176   my ($self, $add_group_by) = @_;
1177
1178   my $attrs = $self->_resolved_attrs_copy;
1179
1180   # copy for the subquery, we need to do some adjustments to it too
1181   my $sub_attrs = { %$attrs };
1182
1183   # these can not go in the subquery, and there is no point of ordering it
1184   delete $sub_attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns order_by/;
1185
1186   # if needed force a group_by and the same set of columns (most databases require this)
1187   if ($add_group_by) {
1188
1189     # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1190     # simply deleting group_by suffices, as the code below will re-fill it
1191     # Note: we check $attrs, as $sub_attrs has collapse deleted
1192     if (ref $attrs->{collapse} and keys %{$attrs->{collapse}} ) {
1193       delete $sub_attrs->{group_by};
1194     }
1195
1196     $sub_attrs->{columns} = $sub_attrs->{group_by} ||= [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1197   }
1198
1199   $attrs->{from} = [{
1200     count_subq => (ref $self)->new ($self->result_source, $sub_attrs )->as_query
1201   }];
1202
1203   # the subquery replaces this
1204   delete $attrs->{$_} for qw/where bind prefetch collapse distinct group_by having having_bind/;
1205
1206   return $self->__count ($attrs);
1207 }
1208
1209 sub _count_simple {
1210   my $self = shift;
1211
1212   my $count = $self->__count;
1213   return 0 unless $count;
1214
1215   # need to take offset from resolved attrs
1216
1217   my $attrs = $self->_resolved_attrs;
1218
1219   $count -= $attrs->{offset} if $attrs->{offset};
1220   $count = $attrs->{rows} if $attrs->{rows} and $attrs->{rows} < $count;
1221   $count = 0 if ($count < 0);
1222   return $count;
1223 }
1224
1225 sub __count {
1226   my ($self, $attrs) = @_;
1227
1228   $attrs ||= $self->_resolved_attrs_copy;
1229
1230   # take off any column specs, any pagers, record_filter is cdbi, and no point of ordering a count
1231   delete $attrs->{$_} for (qw/columns +columns select +select as +as rows offset page pager order_by record_filter/);
1232
1233   $attrs->{select} = { count => '*' };
1234   $attrs->{as} = [qw/count/];
1235
1236   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1237   my ($count) = $tmp_rs->cursor->next;
1238
1239   return $count;
1240 }
1241
1242 sub _bool {
1243   return 1;
1244 }
1245
1246 =head2 count_literal
1247
1248 =over 4
1249
1250 =item Arguments: $sql_fragment, @bind_values
1251
1252 =item Return Value: $count
1253
1254 =back
1255
1256 Counts the results in a literal query. Equivalent to calling L</search_literal>
1257 with the passed arguments, then L</count>.
1258
1259 =cut
1260
1261 sub count_literal { shift->search_literal(@_)->count; }
1262
1263 =head2 all
1264
1265 =over 4
1266
1267 =item Arguments: none
1268
1269 =item Return Value: @objects
1270
1271 =back
1272
1273 Returns all elements in the resultset. Called implicitly if the resultset
1274 is returned in list context.
1275
1276 =cut
1277
1278 sub all {
1279   my $self = shift;
1280   if(@_) {
1281       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1282   }
1283
1284   return @{ $self->get_cache } if $self->get_cache;
1285
1286   my @obj;
1287
1288   # TODO: don't call resolve here
1289   if (keys %{$self->_resolved_attrs->{collapse}}) {
1290 #  if ($self->{attrs}{prefetch}) {
1291       # Using $self->cursor->all is really just an optimisation.
1292       # If we're collapsing has_many prefetches it probably makes
1293       # very little difference, and this is cleaner than hacking
1294       # _construct_object to survive the approach
1295     my @row = $self->cursor->next;
1296     while (@row) {
1297       push(@obj, $self->_construct_object(@row));
1298       @row = (exists $self->{stashed_row}
1299                ? @{delete $self->{stashed_row}}
1300                : $self->cursor->next);
1301     }
1302   } else {
1303     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1304   }
1305
1306   $self->set_cache(\@obj) if $self->{attrs}{cache};
1307   return @obj;
1308 }
1309
1310 =head2 reset
1311
1312 =over 4
1313
1314 =item Arguments: none
1315
1316 =item Return Value: $self
1317
1318 =back
1319
1320 Resets the resultset's cursor, so you can iterate through the elements again.
1321
1322 =cut
1323
1324 sub reset {
1325   my ($self) = @_;
1326   delete $self->{_attrs} if exists $self->{_attrs};
1327   $self->{all_cache_position} = 0;
1328   $self->cursor->reset;
1329   return $self;
1330 }
1331
1332 =head2 first
1333
1334 =over 4
1335
1336 =item Arguments: none
1337
1338 =item Return Value: $object?
1339
1340 =back
1341
1342 Resets the resultset and returns an object for the first result (if the
1343 resultset returns anything).
1344
1345 =cut
1346
1347 sub first {
1348   return $_[0]->reset->next;
1349 }
1350
1351
1352 # _rs_update_delete
1353 #
1354 # Determines whether and what type of subquery is required for the $rs operation.
1355 # If grouping is necessary either supplies its own, or verifies the current one
1356 # After all is done delegates to the proper storage method.
1357
1358 sub _rs_update_delete {
1359   my ($self, $op, $values) = @_;
1360
1361   my $rsrc = $self->result_source;
1362
1363   my $needs_group_by_subq = $self->_has_attr (qw/prefetch distinct join seen_join group_by/);
1364   my $needs_subq = $self->_has_attr (qw/row offset page/);
1365
1366   if ($needs_group_by_subq or $needs_subq) {
1367
1368     # make a new $rs selecting only the PKs (that's all we really need)
1369     my $attrs = $self->_resolved_attrs_copy;
1370
1371     delete $attrs->{$_} for qw/prefetch collapse select +select as +as columns +columns/;
1372     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1373
1374     if ($needs_group_by_subq) {
1375       # make sure no group_by was supplied, or if there is one - make sure it matches
1376       # the columns compiled above perfectly. Anything else can not be sanely executed
1377       # on most databases so croak right then and there
1378
1379       if (my $g = $attrs->{group_by}) {
1380         my @current_group_by = map
1381           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1382           (ref $g eq 'ARRAY' ? @$g : $g );
1383
1384         if (
1385           join ("\x00", sort @current_group_by)
1386             ne
1387           join ("\x00", sort @{$attrs->{columns}} )
1388         ) {
1389           $self->throw_exception (
1390             "You have just attempted a $op operation on a resultset which does group_by"
1391             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1392             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1393             . ' kind of queries. Please retry the operation with a modified group_by or'
1394             . ' without using one at all.'
1395           );
1396         }
1397       }
1398       else {
1399         $attrs->{group_by} = $attrs->{columns};
1400       }
1401     }
1402
1403     my $subrs = (ref $self)->new($rsrc, $attrs);
1404
1405     return $self->result_source->storage->subq_update_delete($subrs, $op, $values);
1406   }
1407   else {
1408     return $rsrc->storage->$op(
1409       $rsrc,
1410       $op eq 'update' ? $values : (),
1411       $self->_cond_for_update_delete,
1412     );
1413   }
1414 }
1415
1416
1417 # _cond_for_update_delete
1418 #
1419 # update/delete require the condition to be modified to handle
1420 # the differing SQL syntax available.  This transforms the $self->{cond}
1421 # appropriately, returning the new condition.
1422
1423 sub _cond_for_update_delete {
1424   my ($self, $full_cond) = @_;
1425   my $cond = {};
1426
1427   $full_cond ||= $self->{cond};
1428   # No-op. No condition, we're updating/deleting everything
1429   return $cond unless ref $full_cond;
1430
1431   if (ref $full_cond eq 'ARRAY') {
1432     $cond = [
1433       map {
1434         my %hash;
1435         foreach my $key (keys %{$_}) {
1436           $key =~ /([^.]+)$/;
1437           $hash{$1} = $_->{$key};
1438         }
1439         \%hash;
1440       } @{$full_cond}
1441     ];
1442   }
1443   elsif (ref $full_cond eq 'HASH') {
1444     if ((keys %{$full_cond})[0] eq '-and') {
1445       $cond->{-and} = [];
1446       my @cond = @{$full_cond->{-and}};
1447        for (my $i = 0; $i < @cond; $i++) {
1448         my $entry = $cond[$i];
1449         my $hash;
1450         if (ref $entry eq 'HASH') {
1451           $hash = $self->_cond_for_update_delete($entry);
1452         }
1453         else {
1454           $entry =~ /([^.]+)$/;
1455           $hash->{$1} = $cond[++$i];
1456         }
1457         push @{$cond->{-and}}, $hash;
1458       }
1459     }
1460     else {
1461       foreach my $key (keys %{$full_cond}) {
1462         $key =~ /([^.]+)$/;
1463         $cond->{$1} = $full_cond->{$key};
1464       }
1465     }
1466   }
1467   else {
1468     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1469   }
1470
1471   return $cond;
1472 }
1473
1474
1475 =head2 update
1476
1477 =over 4
1478
1479 =item Arguments: \%values
1480
1481 =item Return Value: $storage_rv
1482
1483 =back
1484
1485 Sets the specified columns in the resultset to the supplied values in a
1486 single query. Return value will be true if the update succeeded or false
1487 if no records were updated; exact type of success value is storage-dependent.
1488
1489 =cut
1490
1491 sub update {
1492   my ($self, $values) = @_;
1493   $self->throw_exception('Values for update must be a hash')
1494     unless ref $values eq 'HASH';
1495
1496   return $self->_rs_update_delete ('update', $values);
1497 }
1498
1499 =head2 update_all
1500
1501 =over 4
1502
1503 =item Arguments: \%values
1504
1505 =item Return Value: 1
1506
1507 =back
1508
1509 Fetches all objects and updates them one at a time. Note that C<update_all>
1510 will run DBIC cascade triggers, while L</update> will not.
1511
1512 =cut
1513
1514 sub update_all {
1515   my ($self, $values) = @_;
1516   $self->throw_exception('Values for update_all must be a hash')
1517     unless ref $values eq 'HASH';
1518   foreach my $obj ($self->all) {
1519     $obj->set_columns($values)->update;
1520   }
1521   return 1;
1522 }
1523
1524 =head2 delete
1525
1526 =over 4
1527
1528 =item Arguments: none
1529
1530 =item Return Value: 1
1531
1532 =back
1533
1534 Deletes the contents of the resultset from its result source. Note that this
1535 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1536 to run. See also L<DBIx::Class::Row/delete>.
1537
1538 delete may not generate correct SQL for a query with joins or a resultset
1539 chained from a related resultset.  In this case it will generate a warning:-
1540
1541 In these cases you may find that delete_all is more appropriate, or you
1542 need to respecify your query in a way that can be expressed without a join.
1543
1544 =cut
1545
1546 sub delete {
1547   my $self = shift;
1548   $self->throw_exception('delete does not accept any arguments')
1549     if @_;
1550
1551   return $self->_rs_update_delete ('delete');
1552 }
1553
1554 =head2 delete_all
1555
1556 =over 4
1557
1558 =item Arguments: none
1559
1560 =item Return Value: 1
1561
1562 =back
1563
1564 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1565 will run DBIC cascade triggers, while L</delete> will not.
1566
1567 =cut
1568
1569 sub delete_all {
1570   my $self = shift;
1571   $self->throw_exception('delete_all does not accept any arguments')
1572     if @_;
1573
1574   $_->delete for $self->all;
1575   return 1;
1576 }
1577
1578 =head2 populate
1579
1580 =over 4
1581
1582 =item Arguments: \@data;
1583
1584 =back
1585
1586 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1587 For the arrayref of hashrefs style each hashref should be a structure suitable
1588 forsubmitting to a $resultset->create(...) method.
1589
1590 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1591 to insert the data, as this is a faster method.
1592
1593 Otherwise, each set of data is inserted into the database using
1594 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1595 objects is returned.
1596
1597 Example:  Assuming an Artist Class that has many CDs Classes relating:
1598
1599   my $Artist_rs = $schema->resultset("Artist");
1600
1601   ## Void Context Example
1602   $Artist_rs->populate([
1603      { artistid => 4, name => 'Manufactured Crap', cds => [
1604         { title => 'My First CD', year => 2006 },
1605         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1606       ],
1607      },
1608      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1609         { title => 'My parents sold me to a record company' ,year => 2005 },
1610         { title => 'Why Am I So Ugly?', year => 2006 },
1611         { title => 'I Got Surgery and am now Popular', year => 2007 }
1612       ],
1613      },
1614   ]);
1615
1616   ## Array Context Example
1617   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1618     { name => "Artist One"},
1619     { name => "Artist Two"},
1620     { name => "Artist Three", cds=> [
1621     { title => "First CD", year => 2007},
1622     { title => "Second CD", year => 2008},
1623   ]}
1624   ]);
1625
1626   print $ArtistOne->name; ## response is 'Artist One'
1627   print $ArtistThree->cds->count ## reponse is '2'
1628
1629 For the arrayref of arrayrefs style,  the first element should be a list of the
1630 fieldsnames to which the remaining elements are rows being inserted.  For
1631 example:
1632
1633   $Arstist_rs->populate([
1634     [qw/artistid name/],
1635     [100, 'A Formally Unknown Singer'],
1636     [101, 'A singer that jumped the shark two albums ago'],
1637     [102, 'An actually cool singer.'],
1638   ]);
1639
1640 Please note an important effect on your data when choosing between void and
1641 wantarray context. Since void context goes straight to C<insert_bulk> in
1642 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1643 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1644 create primary keys for you, you will find that your PKs are empty.  In this
1645 case you will have to use the wantarray context in order to create those
1646 values.
1647
1648 =cut
1649
1650 sub populate {
1651   my $self = shift @_;
1652   my $data = ref $_[0][0] eq 'HASH'
1653     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1654     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1655
1656   if(defined wantarray) {
1657     my @created;
1658     foreach my $item (@$data) {
1659       push(@created, $self->create($item));
1660     }
1661     return @created;
1662   } else {
1663     my ($first, @rest) = @$data;
1664
1665     my @names = grep {!ref $first->{$_}} keys %$first;
1666     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1667     my @pks = $self->result_source->primary_columns;
1668
1669     ## do the belongs_to relationships
1670     foreach my $index (0..$#$data) {
1671       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1672         my @ret = $self->populate($data);
1673         return;
1674       }
1675
1676       foreach my $rel (@rels) {
1677         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1678         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1679         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1680         my $related = $result->result_source->_resolve_condition(
1681           $result->result_source->relationship_info($reverse)->{cond},
1682           $self,
1683           $result,
1684         );
1685
1686         delete $data->[$index]->{$rel};
1687         $data->[$index] = {%{$data->[$index]}, %$related};
1688
1689         push @names, keys %$related if $index == 0;
1690       }
1691     }
1692
1693     ## do bulk insert on current row
1694     my @values = map { [ @$_{@names} ] } @$data;
1695
1696     $self->result_source->storage->insert_bulk(
1697       $self->result_source,
1698       \@names,
1699       \@values,
1700     );
1701
1702     ## do the has_many relationships
1703     foreach my $item (@$data) {
1704
1705       foreach my $rel (@rels) {
1706         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1707
1708         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1709      || $self->throw_exception('Cannot find the relating object.');
1710
1711         my $child = $parent->$rel;
1712
1713         my $related = $child->result_source->_resolve_condition(
1714           $parent->result_source->relationship_info($rel)->{cond},
1715           $child,
1716           $parent,
1717         );
1718
1719         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1720         my @populate = map { {%$_, %$related} } @rows_to_add;
1721
1722         $child->populate( \@populate );
1723       }
1724     }
1725   }
1726 }
1727
1728 =head2 _normalize_populate_args ($args)
1729
1730 Private method used by L</populate> to normalize its incoming arguments.  Factored
1731 out in case you want to subclass and accept new argument structures to the
1732 L</populate> method.
1733
1734 =cut
1735
1736 sub _normalize_populate_args {
1737   my ($self, $data) = @_;
1738   my @names = @{shift(@$data)};
1739   my @results_to_create;
1740   foreach my $datum (@$data) {
1741     my %result_to_create;
1742     foreach my $index (0..$#names) {
1743       $result_to_create{$names[$index]} = $$datum[$index];
1744     }
1745     push @results_to_create, \%result_to_create;
1746   }
1747   return \@results_to_create;
1748 }
1749
1750 =head2 pager
1751
1752 =over 4
1753
1754 =item Arguments: none
1755
1756 =item Return Value: $pager
1757
1758 =back
1759
1760 Return Value a L<Data::Page> object for the current resultset. Only makes
1761 sense for queries with a C<page> attribute.
1762
1763 To get the full count of entries for a paged resultset, call
1764 C<total_entries> on the L<Data::Page> object.
1765
1766 =cut
1767
1768 sub pager {
1769   my ($self) = @_;
1770
1771   return $self->{pager} if $self->{pager};
1772
1773   my $attrs = $self->{attrs};
1774   $self->throw_exception("Can't create pager for non-paged rs")
1775     unless $self->{attrs}{page};
1776   $attrs->{rows} ||= 10;
1777
1778   # throw away the paging flags and re-run the count (possibly
1779   # with a subselect) to get the real total count
1780   my $count_attrs = { %$attrs };
1781   delete $count_attrs->{$_} for qw/rows offset page pager/;
1782   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1783
1784   return $self->{pager} = Data::Page->new(
1785     $total_count,
1786     $attrs->{rows},
1787     $self->{attrs}{page}
1788   );
1789 }
1790
1791 =head2 page
1792
1793 =over 4
1794
1795 =item Arguments: $page_number
1796
1797 =item Return Value: $rs
1798
1799 =back
1800
1801 Returns a resultset for the $page_number page of the resultset on which page
1802 is called, where each page contains a number of rows equal to the 'rows'
1803 attribute set on the resultset (10 by default).
1804
1805 =cut
1806
1807 sub page {
1808   my ($self, $page) = @_;
1809   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1810 }
1811
1812 =head2 new_result
1813
1814 =over 4
1815
1816 =item Arguments: \%vals
1817
1818 =item Return Value: $rowobject
1819
1820 =back
1821
1822 Creates a new row object in the resultset's result class and returns
1823 it. The row is not inserted into the database at this point, call
1824 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1825 will tell you whether the row object has been inserted or not.
1826
1827 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1828
1829 =cut
1830
1831 sub new_result {
1832   my ($self, $values) = @_;
1833   $self->throw_exception( "new_result needs a hash" )
1834     unless (ref $values eq 'HASH');
1835
1836   my %new;
1837   my $alias = $self->{attrs}{alias};
1838
1839   if (
1840     defined $self->{cond}
1841     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1842   ) {
1843     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1844     $new{-from_resultset} = [ keys %new ] if keys %new;
1845   } else {
1846     $self->throw_exception(
1847       "Can't abstract implicit construct, condition not a hash"
1848     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1849
1850     my $collapsed_cond = (
1851       $self->{cond}
1852         ? $self->_collapse_cond($self->{cond})
1853         : {}
1854     );
1855
1856     # precendence must be given to passed values over values inherited from
1857     # the cond, so the order here is important.
1858     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1859     while( my($col,$value) = each %implied ){
1860       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1861         $new{$col} = $value->{'='};
1862         next;
1863       }
1864       $new{$col} = $value if $self->_is_deterministic_value($value);
1865     }
1866   }
1867
1868   %new = (
1869     %new,
1870     %{ $self->_remove_alias($values, $alias) },
1871     -source_handle => $self->_source_handle,
1872     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1873   );
1874
1875   return $self->result_class->new(\%new);
1876 }
1877
1878 # _is_deterministic_value
1879 #
1880 # Make an effor to strip non-deterministic values from the condition,
1881 # to make sure new_result chokes less
1882
1883 sub _is_deterministic_value {
1884   my $self = shift;
1885   my $value = shift;
1886   my $ref_type = ref $value;
1887   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1888   return 1 if Scalar::Util::blessed($value);
1889   return 0;
1890 }
1891
1892 # _has_attr
1893 #
1894 # determines if the resultset defines at least one
1895 # of the attributes supplied
1896 #
1897 # used to determine if a subquery is neccessary
1898
1899 sub _has_attr {
1900   my ($self, @attr_names) = @_;
1901
1902   my $attrs = $self->_resolved_attrs;
1903
1904   my $join_check_req;
1905
1906   for my $n (@attr_names) {
1907     ++$join_check_req if $n =~ /join/;
1908
1909     my $attr =  $attrs->{$n};
1910
1911     next if not defined $attr;
1912
1913     if (ref $attr eq 'HASH') {
1914       return 1 if keys %$attr;
1915     }
1916     elsif (ref $attr eq 'ARRAY') {
1917       return 1 if @$attr;
1918     }
1919     else {
1920       return 1 if $attr;
1921     }
1922   }
1923
1924   # a join can be expressed as a multi-level from
1925   return 1 if (
1926     $join_check_req
1927       and
1928     ref $attrs->{from} eq 'ARRAY'
1929       and
1930     @{$attrs->{from}} > 1
1931   );
1932
1933   return 0;
1934 }
1935
1936 # _collapse_cond
1937 #
1938 # Recursively collapse the condition.
1939
1940 sub _collapse_cond {
1941   my ($self, $cond, $collapsed) = @_;
1942
1943   $collapsed ||= {};
1944
1945   if (ref $cond eq 'ARRAY') {
1946     foreach my $subcond (@$cond) {
1947       next unless ref $subcond;  # -or
1948       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1949     }
1950   }
1951   elsif (ref $cond eq 'HASH') {
1952     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1953       foreach my $subcond (@{$cond->{-and}}) {
1954         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1955       }
1956     }
1957     else {
1958       foreach my $col (keys %$cond) {
1959         my $value = $cond->{$col};
1960         $collapsed->{$col} = $value;
1961       }
1962     }
1963   }
1964
1965   return $collapsed;
1966 }
1967
1968 # _remove_alias
1969 #
1970 # Remove the specified alias from the specified query hash. A copy is made so
1971 # the original query is not modified.
1972
1973 sub _remove_alias {
1974   my ($self, $query, $alias) = @_;
1975
1976   my %orig = %{ $query || {} };
1977   my %unaliased;
1978
1979   foreach my $key (keys %orig) {
1980     if ($key !~ /\./) {
1981       $unaliased{$key} = $orig{$key};
1982       next;
1983     }
1984     $unaliased{$1} = $orig{$key}
1985       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1986   }
1987
1988   return \%unaliased;
1989 }
1990
1991 =head2 as_query (EXPERIMENTAL)
1992
1993 =over 4
1994
1995 =item Arguments: none
1996
1997 =item Return Value: \[ $sql, @bind ]
1998
1999 =back
2000
2001 Returns the SQL query and bind vars associated with the invocant.
2002
2003 This is generally used as the RHS for a subquery.
2004
2005 B<NOTE>: This feature is still experimental.
2006
2007 =cut
2008
2009 sub as_query { return shift->cursor->as_query(@_) }
2010
2011 =head2 find_or_new
2012
2013 =over 4
2014
2015 =item Arguments: \%vals, \%attrs?
2016
2017 =item Return Value: $rowobject
2018
2019 =back
2020
2021   my $artist = $schema->resultset('Artist')->find_or_new(
2022     { artist => 'fred' }, { key => 'artists' });
2023
2024   $cd->cd_to_producer->find_or_new({ producer => $producer },
2025                                    { key => 'primary });
2026
2027 Find an existing record from this resultset, based on its primary
2028 key, or a unique constraint. If none exists, instantiate a new result
2029 object and return it. The object will not be saved into your storage
2030 until you call L<DBIx::Class::Row/insert> on it.
2031
2032 You most likely want this method when looking for existing rows using
2033 a unique constraint that is not the primary key, or looking for
2034 related rows.
2035
2036 If you want objects to be saved immediately, use L</find_or_create> instead.
2037
2038 B<Note>: C<find_or_new> is probably not what you want when creating a
2039 new row in a table that uses primary keys supplied by the
2040 database. Passing in a primary key column with a value of I<undef>
2041 will cause L</find> to attempt to search for a row with a value of
2042 I<NULL>.
2043
2044 =cut
2045
2046 sub find_or_new {
2047   my $self     = shift;
2048   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2049   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2050   my $exists   = $self->find($hash, $attrs);
2051   return defined $exists ? $exists : $self->new_result($hash);
2052 }
2053
2054 =head2 create
2055
2056 =over 4
2057
2058 =item Arguments: \%vals
2059
2060 =item Return Value: a L<DBIx::Class::Row> $object
2061
2062 =back
2063
2064 Attempt to create a single new row or a row with multiple related rows
2065 in the table represented by the resultset (and related tables). This
2066 will not check for duplicate rows before inserting, use
2067 L</find_or_create> to do that.
2068
2069 To create one row for this resultset, pass a hashref of key/value
2070 pairs representing the columns of the table and the values you wish to
2071 store. If the appropriate relationships are set up, foreign key fields
2072 can also be passed an object representing the foreign row, and the
2073 value will be set to its primary key.
2074
2075 To create related objects, pass a hashref for the value if the related
2076 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2077 and use the name of the relationship as the key. (NOT the name of the field,
2078 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2079 of hashrefs containing the data for each of the rows to create in the foreign
2080 tables, again using the relationship name as the key.
2081
2082 Instead of hashrefs of plain related data (key/value pairs), you may
2083 also pass new or inserted objects. New objects (not inserted yet, see
2084 L</new>), will be inserted into their appropriate tables.
2085
2086 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2087
2088 Example of creating a new row.
2089
2090   $person_rs->create({
2091     name=>"Some Person",
2092     email=>"somebody@someplace.com"
2093   });
2094
2095 Example of creating a new row and also creating rows in a related C<has_many>
2096 or C<has_one> resultset.  Note Arrayref.
2097
2098   $artist_rs->create(
2099      { artistid => 4, name => 'Manufactured Crap', cds => [
2100         { title => 'My First CD', year => 2006 },
2101         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2102       ],
2103      },
2104   );
2105
2106 Example of creating a new row and also creating a row in a related
2107 C<belongs_to>resultset. Note Hashref.
2108
2109   $cd_rs->create({
2110     title=>"Music for Silly Walks",
2111     year=>2000,
2112     artist => {
2113       name=>"Silly Musician",
2114     }
2115   });
2116
2117 =cut
2118
2119 sub create {
2120   my ($self, $attrs) = @_;
2121   $self->throw_exception( "create needs a hashref" )
2122     unless ref $attrs eq 'HASH';
2123   return $self->new_result($attrs)->insert;
2124 }
2125
2126 =head2 find_or_create
2127
2128 =over 4
2129
2130 =item Arguments: \%vals, \%attrs?
2131
2132 =item Return Value: $rowobject
2133
2134 =back
2135
2136   $cd->cd_to_producer->find_or_create({ producer => $producer },
2137                                       { key => 'primary });
2138
2139 Tries to find a record based on its primary key or unique constraints; if none
2140 is found, creates one and returns that instead.
2141
2142   my $cd = $schema->resultset('CD')->find_or_create({
2143     cdid   => 5,
2144     artist => 'Massive Attack',
2145     title  => 'Mezzanine',
2146     year   => 2005,
2147   });
2148
2149 Also takes an optional C<key> attribute, to search by a specific key or unique
2150 constraint. For example:
2151
2152   my $cd = $schema->resultset('CD')->find_or_create(
2153     {
2154       artist => 'Massive Attack',
2155       title  => 'Mezzanine',
2156     },
2157     { key => 'cd_artist_title' }
2158   );
2159
2160 B<Note>: Because find_or_create() reads from the database and then
2161 possibly inserts based on the result, this method is subject to a race
2162 condition. Another process could create a record in the table after
2163 the find has completed and before the create has started. To avoid
2164 this problem, use find_or_create() inside a transaction.
2165
2166 B<Note>: C<find_or_create> is probably not what you want when creating
2167 a new row in a table that uses primary keys supplied by the
2168 database. Passing in a primary key column with a value of I<undef>
2169 will cause L</find> to attempt to search for a row with a value of
2170 I<NULL>.
2171
2172 See also L</find> and L</update_or_create>. For information on how to declare
2173 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2174
2175 =cut
2176
2177 sub find_or_create {
2178   my $self     = shift;
2179   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2180   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2181   my $exists   = $self->find($hash, $attrs);
2182   return defined $exists ? $exists : $self->create($hash);
2183 }
2184
2185 =head2 update_or_create
2186
2187 =over 4
2188
2189 =item Arguments: \%col_values, { key => $unique_constraint }?
2190
2191 =item Return Value: $rowobject
2192
2193 =back
2194
2195   $resultset->update_or_create({ col => $val, ... });
2196
2197 First, searches for an existing row matching one of the unique constraints
2198 (including the primary key) on the source of this resultset. If a row is
2199 found, updates it with the other given column values. Otherwise, creates a new
2200 row.
2201
2202 Takes an optional C<key> attribute to search on a specific unique constraint.
2203 For example:
2204
2205   # In your application
2206   my $cd = $schema->resultset('CD')->update_or_create(
2207     {
2208       artist => 'Massive Attack',
2209       title  => 'Mezzanine',
2210       year   => 1998,
2211     },
2212     { key => 'cd_artist_title' }
2213   );
2214
2215   $cd->cd_to_producer->update_or_create({
2216     producer => $producer,
2217     name => 'harry',
2218   }, {
2219     key => 'primary,
2220   });
2221
2222
2223 If no C<key> is specified, it searches on all unique constraints defined on the
2224 source, including the primary key.
2225
2226 If the C<key> is specified as C<primary>, it searches only on the primary key.
2227
2228 See also L</find> and L</find_or_create>. For information on how to declare
2229 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2230
2231 B<Note>: C<update_or_create> is probably not what you want when
2232 looking for a row in a table that uses primary keys supplied by the
2233 database, unless you actually have a key value. Passing in a primary
2234 key column with a value of I<undef> will cause L</find> to attempt to
2235 search for a row with a value of I<NULL>.
2236
2237 =cut
2238
2239 sub update_or_create {
2240   my $self = shift;
2241   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2242   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2243
2244   my $row = $self->find($cond, $attrs);
2245   if (defined $row) {
2246     $row->update($cond);
2247     return $row;
2248   }
2249
2250   return $self->create($cond);
2251 }
2252
2253 =head2 update_or_new
2254
2255 =over 4
2256
2257 =item Arguments: \%col_values, { key => $unique_constraint }?
2258
2259 =item Return Value: $rowobject
2260
2261 =back
2262
2263   $resultset->update_or_new({ col => $val, ... });
2264
2265 First, searches for an existing row matching one of the unique constraints
2266 (including the primary key) on the source of this resultset. If a row is
2267 found, updates it with the other given column values. Otherwise, instantiate
2268 a new result object and return it. The object will not be saved into your storage
2269 until you call L<DBIx::Class::Row/insert> on it.
2270
2271 Takes an optional C<key> attribute to search on a specific unique constraint.
2272 For example:
2273
2274   # In your application
2275   my $cd = $schema->resultset('CD')->update_or_new(
2276     {
2277       artist => 'Massive Attack',
2278       title  => 'Mezzanine',
2279       year   => 1998,
2280     },
2281     { key => 'cd_artist_title' }
2282   );
2283
2284   if ($cd->in_storage) {
2285       # the cd was updated
2286   }
2287   else {
2288       # the cd is not yet in the database, let's insert it
2289       $cd->insert;
2290   }
2291
2292 See also L</find>, L</find_or_create> and L<find_or_new>.
2293
2294 =cut
2295
2296 sub update_or_new {
2297     my $self  = shift;
2298     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2299     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2300
2301     my $row = $self->find( $cond, $attrs );
2302     if ( defined $row ) {
2303         $row->update($cond);
2304         return $row;
2305     }
2306
2307     return $self->new_result($cond);
2308 }
2309
2310 =head2 get_cache
2311
2312 =over 4
2313
2314 =item Arguments: none
2315
2316 =item Return Value: \@cache_objects?
2317
2318 =back
2319
2320 Gets the contents of the cache for the resultset, if the cache is set.
2321
2322 The cache is populated either by using the L</prefetch> attribute to
2323 L</search> or by calling L</set_cache>.
2324
2325 =cut
2326
2327 sub get_cache {
2328   shift->{all_cache};
2329 }
2330
2331 =head2 set_cache
2332
2333 =over 4
2334
2335 =item Arguments: \@cache_objects
2336
2337 =item Return Value: \@cache_objects
2338
2339 =back
2340
2341 Sets the contents of the cache for the resultset. Expects an arrayref
2342 of objects of the same class as those produced by the resultset. Note that
2343 if the cache is set the resultset will return the cached objects rather
2344 than re-querying the database even if the cache attr is not set.
2345
2346 The contents of the cache can also be populated by using the
2347 L</prefetch> attribute to L</search>.
2348
2349 =cut
2350
2351 sub set_cache {
2352   my ( $self, $data ) = @_;
2353   $self->throw_exception("set_cache requires an arrayref")
2354       if defined($data) && (ref $data ne 'ARRAY');
2355   $self->{all_cache} = $data;
2356 }
2357
2358 =head2 clear_cache
2359
2360 =over 4
2361
2362 =item Arguments: none
2363
2364 =item Return Value: []
2365
2366 =back
2367
2368 Clears the cache for the resultset.
2369
2370 =cut
2371
2372 sub clear_cache {
2373   shift->set_cache(undef);
2374 }
2375
2376 =head2 related_resultset
2377
2378 =over 4
2379
2380 =item Arguments: $relationship_name
2381
2382 =item Return Value: $resultset
2383
2384 =back
2385
2386 Returns a related resultset for the supplied relationship name.
2387
2388   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2389
2390 =cut
2391
2392 sub related_resultset {
2393   my ($self, $rel) = @_;
2394
2395   $self->{related_resultsets} ||= {};
2396   return $self->{related_resultsets}{$rel} ||= do {
2397     my $rel_obj = $self->result_source->relationship_info($rel);
2398
2399     $self->throw_exception(
2400       "search_related: result source '" . $self->result_source->source_name .
2401         "' has no such relationship $rel")
2402       unless $rel_obj;
2403
2404     my ($from,$seen) = $self->_resolve_from($rel);
2405
2406     my $join_count = $seen->{$rel};
2407     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2408
2409     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2410     my %attrs = %{$self->{attrs}||{}};
2411     delete @attrs{qw(result_class alias)};
2412
2413     my $new_cache;
2414
2415     if (my $cache = $self->get_cache) {
2416       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2417         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2418                         @$cache ];
2419       }
2420     }
2421
2422     my $rel_source = $self->result_source->related_source($rel);
2423
2424     my $new = do {
2425
2426       # The reason we do this now instead of passing the alias to the
2427       # search_rs below is that if you wrap/overload resultset on the
2428       # source you need to know what alias it's -going- to have for things
2429       # to work sanely (e.g. RestrictWithObject wants to be able to add
2430       # extra query restrictions, and these may need to be $alias.)
2431
2432       my $attrs = $rel_source->resultset_attributes;
2433       local $attrs->{alias} = $alias;
2434
2435       $rel_source->resultset
2436                  ->search_rs(
2437                      undef, {
2438                        %attrs,
2439                        join => undef,
2440                        prefetch => undef,
2441                        select => undef,
2442                        as => undef,
2443                        where => $self->{cond},
2444                        seen_join => $seen,
2445                        from => $from,
2446                    });
2447     };
2448     $new->set_cache($new_cache) if $new_cache;
2449     $new;
2450   };
2451 }
2452
2453 =head2 current_source_alias
2454
2455 =over 4
2456
2457 =item Arguments: none
2458
2459 =item Return Value: $source_alias
2460
2461 =back
2462
2463 Returns the current table alias for the result source this resultset is built
2464 on, that will be used in the SQL query. Usually it is C<me>.
2465
2466 Currently the source alias that refers to the result set returned by a
2467 L</search>/L</find> family method depends on how you got to the resultset: it's
2468 C<me> by default, but eg. L</search_related> aliases it to the related result
2469 source name (and keeps C<me> referring to the original result set). The long
2470 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2471 (and make this method unnecessary).
2472
2473 Thus it's currently necessary to use this method in predefined queries (see
2474 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2475 source alias of the current result set:
2476
2477   # in a result set class
2478   sub modified_by {
2479     my ($self, $user) = @_;
2480
2481     my $me = $self->current_source_alias;
2482
2483     return $self->search(
2484       "$me.modified" => $user->id,
2485     );
2486   }
2487
2488 =cut
2489
2490 sub current_source_alias {
2491   my ($self) = @_;
2492
2493   return ($self->{attrs} || {})->{alias} || 'me';
2494 }
2495
2496 # This code is called by search_related, and makes sure there
2497 # is clear separation between the joins before, during, and
2498 # after the relationship. This information is needed later
2499 # in order to properly resolve prefetch aliases (any alias
2500 # with a relation_chain_depth less than the depth of the
2501 # current prefetch is not considered)
2502 sub _resolve_from {
2503   my ($self, $extra_join) = @_;
2504   my $source = $self->result_source;
2505   my $attrs = $self->{attrs};
2506
2507   my $from = $attrs->{from}
2508     || [ { $attrs->{alias} => $source->from } ];
2509
2510   my $seen = { %{$attrs->{seen_join}||{}} };
2511
2512   # we need to take the prefetch the attrs into account before we
2513   # ->_resolve_join as otherwise they get lost - captainL
2514   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2515
2516   push @$from, $source->_resolve_join($merged, $attrs->{alias}, $seen) if ($merged);
2517
2518   ++$seen->{-relation_chain_depth};
2519
2520   push @$from, $source->_resolve_join($extra_join, $attrs->{alias}, $seen);
2521
2522   ++$seen->{-relation_chain_depth};
2523
2524   return ($from,$seen);
2525 }
2526
2527 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2528 sub _resolved_attrs_copy {
2529   my $self = shift;
2530   return { %{$self->_resolved_attrs (@_)} };
2531 }
2532
2533 sub _resolved_attrs {
2534   my $self = shift;
2535   return $self->{_attrs} if $self->{_attrs};
2536
2537   my $attrs  = { %{ $self->{attrs} || {} } };
2538   my $source = $self->result_source;
2539   my $alias  = $attrs->{alias};
2540
2541   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2542   my @colbits;
2543
2544   # build columns (as long as select isn't set) into a set of as/select hashes
2545   unless ( $attrs->{select} ) {
2546       @colbits = map {
2547           ( ref($_) eq 'HASH' )
2548               ? $_
2549               : {
2550                   (
2551                     /^\Q${alias}.\E(.+)$/
2552                       ? "$1"
2553                       : "$_"
2554                   )
2555                 =>
2556                   (
2557                     /\./
2558                       ? "$_"
2559                       : "${alias}.$_"
2560                   )
2561             }
2562       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2563   }
2564   # add the additional columns on
2565   foreach ( 'include_columns', '+columns' ) {
2566       push @colbits, map {
2567           ( ref($_) eq 'HASH' )
2568             ? $_
2569             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2570       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2571   }
2572
2573   # start with initial select items
2574   if ( $attrs->{select} ) {
2575     $attrs->{select} =
2576         ( ref $attrs->{select} eq 'ARRAY' )
2577       ? [ @{ $attrs->{select} } ]
2578       : [ $attrs->{select} ];
2579     $attrs->{as} = (
2580       $attrs->{as}
2581       ? (
2582         ref $attrs->{as} eq 'ARRAY'
2583         ? [ @{ $attrs->{as} } ]
2584         : [ $attrs->{as} ]
2585         )
2586       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2587     );
2588   }
2589   else {
2590
2591     # otherwise we intialise select & as to empty
2592     $attrs->{select} = [];
2593     $attrs->{as}     = [];
2594   }
2595
2596   # now add colbits to select/as
2597   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2598   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2599
2600   my $adds;
2601   if ( $adds = delete $attrs->{'+select'} ) {
2602     $adds = [$adds] unless ref $adds eq 'ARRAY';
2603     push(
2604       @{ $attrs->{select} },
2605       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2606     );
2607   }
2608   if ( $adds = delete $attrs->{'+as'} ) {
2609     $adds = [$adds] unless ref $adds eq 'ARRAY';
2610     push( @{ $attrs->{as} }, @$adds );
2611   }
2612
2613   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2614
2615   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2616     my $join = delete $attrs->{join} || {};
2617
2618     if ( defined $attrs->{prefetch} ) {
2619       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2620
2621     }
2622
2623     $attrs->{from} =    # have to copy here to avoid corrupting the original
2624       [
2625       @{ $attrs->{from} },
2626       $source->_resolve_join(
2627         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2628       )
2629       ];
2630
2631   }
2632
2633   if ( $attrs->{order_by} ) {
2634     $attrs->{order_by} = (
2635       ref( $attrs->{order_by} ) eq 'ARRAY'
2636       ? [ @{ $attrs->{order_by} } ]
2637       : [ $attrs->{order_by} ]
2638     );
2639   }
2640   else {
2641     $attrs->{order_by} = [];
2642   }
2643
2644   my $collapse = $attrs->{collapse} || {};
2645   if ( my $prefetch = delete $attrs->{prefetch} ) {
2646     $prefetch = $self->_merge_attr( {}, $prefetch );
2647     my @pre_order;
2648     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2649
2650       # bring joins back to level of current class
2651       my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2652       my @prefetch =
2653         $source->_resolve_prefetch( $p, $alias, $join_map, \@pre_order, $collapse );
2654       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2655       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2656     }
2657     push( @{ $attrs->{order_by} }, @pre_order );
2658   }
2659
2660   if (delete $attrs->{distinct}) {
2661     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2662   }
2663
2664   $attrs->{collapse} = $collapse;
2665
2666   if ( $attrs->{page} and not defined $attrs->{offset} ) {
2667     $attrs->{offset} = ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2668   }
2669
2670   return $self->{_attrs} = $attrs;
2671 }
2672
2673 sub _joinpath_aliases {
2674   my ($self, $fromspec, $seen) = @_;
2675
2676   my $paths = {};
2677   return $paths unless ref $fromspec eq 'ARRAY';
2678
2679   for my $j (@$fromspec) {
2680
2681     next if ref $j ne 'ARRAY';
2682     next if $j->[0]{-relation_chain_depth} < ( $seen->{-relation_chain_depth} || 0);
2683
2684     my $p = $paths;
2685     $p = $p->{$_} ||= {} for @{$j->[0]{-join_path}};
2686     push @{$p->{-join_aliases} }, $j->[0]{-join_alias};
2687   }
2688
2689   return $paths;
2690 }
2691
2692 sub _rollout_attr {
2693   my ($self, $attr) = @_;
2694
2695   if (ref $attr eq 'HASH') {
2696     return $self->_rollout_hash($attr);
2697   } elsif (ref $attr eq 'ARRAY') {
2698     return $self->_rollout_array($attr);
2699   } else {
2700     return [$attr];
2701   }
2702 }
2703
2704 sub _rollout_array {
2705   my ($self, $attr) = @_;
2706
2707   my @rolled_array;
2708   foreach my $element (@{$attr}) {
2709     if (ref $element eq 'HASH') {
2710       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2711     } elsif (ref $element eq 'ARRAY') {
2712       #  XXX - should probably recurse here
2713       push( @rolled_array, @{$self->_rollout_array($element)} );
2714     } else {
2715       push( @rolled_array, $element );
2716     }
2717   }
2718   return \@rolled_array;
2719 }
2720
2721 sub _rollout_hash {
2722   my ($self, $attr) = @_;
2723
2724   my @rolled_array;
2725   foreach my $key (keys %{$attr}) {
2726     push( @rolled_array, { $key => $attr->{$key} } );
2727   }
2728   return \@rolled_array;
2729 }
2730
2731 sub _calculate_score {
2732   my ($self, $a, $b) = @_;
2733
2734   if (ref $b eq 'HASH') {
2735     my ($b_key) = keys %{$b};
2736     if (ref $a eq 'HASH') {
2737       my ($a_key) = keys %{$a};
2738       if ($a_key eq $b_key) {
2739         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2740       } else {
2741         return 0;
2742       }
2743     } else {
2744       return ($a eq $b_key) ? 1 : 0;
2745     }
2746   } else {
2747     if (ref $a eq 'HASH') {
2748       my ($a_key) = keys %{$a};
2749       return ($b eq $a_key) ? 1 : 0;
2750     } else {
2751       return ($b eq $a) ? 1 : 0;
2752     }
2753   }
2754 }
2755
2756 sub _merge_attr {
2757   my ($self, $orig, $import) = @_;
2758
2759   return $import unless defined($orig);
2760   return $orig unless defined($import);
2761
2762   $orig = $self->_rollout_attr($orig);
2763   $import = $self->_rollout_attr($import);
2764
2765   my $seen_keys;
2766   foreach my $import_element ( @{$import} ) {
2767     # find best candidate from $orig to merge $b_element into
2768     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2769     foreach my $orig_element ( @{$orig} ) {
2770       my $score = $self->_calculate_score( $orig_element, $import_element );
2771       if ($score > $best_candidate->{score}) {
2772         $best_candidate->{position} = $position;
2773         $best_candidate->{score} = $score;
2774       }
2775       $position++;
2776     }
2777     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2778
2779     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2780       push( @{$orig}, $import_element );
2781     } else {
2782       my $orig_best = $orig->[$best_candidate->{position}];
2783       # merge orig_best and b_element together and replace original with merged
2784       if (ref $orig_best ne 'HASH') {
2785         $orig->[$best_candidate->{position}] = $import_element;
2786       } elsif (ref $import_element eq 'HASH') {
2787         my ($key) = keys %{$orig_best};
2788         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2789       }
2790     }
2791     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2792   }
2793
2794   return $orig;
2795 }
2796
2797 sub result_source {
2798     my $self = shift;
2799
2800     if (@_) {
2801         $self->_source_handle($_[0]->handle);
2802     } else {
2803         $self->_source_handle->resolve;
2804     }
2805 }
2806
2807 =head2 throw_exception
2808
2809 See L<DBIx::Class::Schema/throw_exception> for details.
2810
2811 =cut
2812
2813 sub throw_exception {
2814   my $self=shift;
2815   if (ref $self && $self->_source_handle->schema) {
2816     $self->_source_handle->schema->throw_exception(@_)
2817   } else {
2818     croak(@_);
2819   }
2820
2821 }
2822
2823 # XXX: FIXME: Attributes docs need clearing up
2824
2825 =head1 ATTRIBUTES
2826
2827 Attributes are used to refine a ResultSet in various ways when
2828 searching for data. They can be passed to any method which takes an
2829 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2830 L</count>.
2831
2832 These are in no particular order:
2833
2834 =head2 order_by
2835
2836 =over 4
2837
2838 =item Value: ( $order_by | \@order_by | \%order_by )
2839
2840 =back
2841
2842 Which column(s) to order the results by. If a single column name, or
2843 an arrayref of names is supplied, the argument is passed through
2844 directly to SQL. The hashref syntax allows for connection-agnostic
2845 specification of ordering direction:
2846
2847  For descending order:
2848
2849   order_by => { -desc => [qw/col1 col2 col3/] }
2850
2851  For explicit ascending order:
2852
2853   order_by => { -asc => 'col' }
2854
2855 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2856 supported, although you are strongly encouraged to use the hashref
2857 syntax as outlined above.
2858
2859 =head2 columns
2860
2861 =over 4
2862
2863 =item Value: \@columns
2864
2865 =back
2866
2867 Shortcut to request a particular set of columns to be retrieved. Each
2868 column spec may be a string (a table column name), or a hash (in which
2869 case the key is the C<as> value, and the value is used as the C<select>
2870 expression). Adds C<me.> onto the start of any column without a C<.> in
2871 it and sets C<select> from that, then auto-populates C<as> from
2872 C<select> as normal. (You may also use the C<cols> attribute, as in
2873 earlier versions of DBIC.)
2874
2875 =head2 +columns
2876
2877 =over 4
2878
2879 =item Value: \@columns
2880
2881 =back
2882
2883 Indicates additional columns to be selected from storage. Works the same
2884 as L</columns> but adds columns to the selection. (You may also use the
2885 C<include_columns> attribute, as in earlier versions of DBIC). For
2886 example:-
2887
2888   $schema->resultset('CD')->search(undef, {
2889     '+columns' => ['artist.name'],
2890     join => ['artist']
2891   });
2892
2893 would return all CDs and include a 'name' column to the information
2894 passed to object inflation. Note that the 'artist' is the name of the
2895 column (or relationship) accessor, and 'name' is the name of the column
2896 accessor in the related table.
2897
2898 =head2 include_columns
2899
2900 =over 4
2901
2902 =item Value: \@columns
2903
2904 =back
2905
2906 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2907
2908 =head2 select
2909
2910 =over 4
2911
2912 =item Value: \@select_columns
2913
2914 =back
2915
2916 Indicates which columns should be selected from the storage. You can use
2917 column names, or in the case of RDBMS back ends, function or stored procedure
2918 names:
2919
2920   $rs = $schema->resultset('Employee')->search(undef, {
2921     select => [
2922       'name',
2923       { count => 'employeeid' },
2924       { sum => 'salary' }
2925     ]
2926   });
2927
2928 When you use function/stored procedure names and do not supply an C<as>
2929 attribute, the column names returned are storage-dependent. E.g. MySQL would
2930 return a column named C<count(employeeid)> in the above example.
2931
2932 =head2 +select
2933
2934 =over 4
2935
2936 Indicates additional columns to be selected from storage.  Works the same as
2937 L</select> but adds columns to the selection.
2938
2939 =back
2940
2941 =head2 +as
2942
2943 =over 4
2944
2945 Indicates additional column names for those added via L</+select>. See L</as>.
2946
2947 =back
2948
2949 =head2 as
2950
2951 =over 4
2952
2953 =item Value: \@inflation_names
2954
2955 =back
2956
2957 Indicates column names for object inflation. That is, C<as>
2958 indicates the name that the column can be accessed as via the
2959 C<get_column> method (or via the object accessor, B<if one already
2960 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2961
2962 The C<as> attribute is used in conjunction with C<select>,
2963 usually when C<select> contains one or more function or stored
2964 procedure names:
2965
2966   $rs = $schema->resultset('Employee')->search(undef, {
2967     select => [
2968       'name',
2969       { count => 'employeeid' }
2970     ],
2971     as => ['name', 'employee_count'],
2972   });
2973
2974   my $employee = $rs->first(); # get the first Employee
2975
2976 If the object against which the search is performed already has an accessor
2977 matching a column name specified in C<as>, the value can be retrieved using
2978 the accessor as normal:
2979
2980   my $name = $employee->name();
2981
2982 If on the other hand an accessor does not exist in the object, you need to
2983 use C<get_column> instead:
2984
2985   my $employee_count = $employee->get_column('employee_count');
2986
2987 You can create your own accessors if required - see
2988 L<DBIx::Class::Manual::Cookbook> for details.
2989
2990 Please note: This will NOT insert an C<AS employee_count> into the SQL
2991 statement produced, it is used for internal access only. Thus
2992 attempting to use the accessor in an C<order_by> clause or similar
2993 will fail miserably.
2994
2995 To get around this limitation, you can supply literal SQL to your
2996 C<select> attibute that contains the C<AS alias> text, eg:
2997
2998   select => [\'myfield AS alias']
2999
3000 =head2 join
3001
3002 =over 4
3003
3004 =item Value: ($rel_name | \@rel_names | \%rel_names)
3005
3006 =back
3007
3008 Contains a list of relationships that should be joined for this query.  For
3009 example:
3010
3011   # Get CDs by Nine Inch Nails
3012   my $rs = $schema->resultset('CD')->search(
3013     { 'artist.name' => 'Nine Inch Nails' },
3014     { join => 'artist' }
3015   );
3016
3017 Can also contain a hash reference to refer to the other relation's relations.
3018 For example:
3019
3020   package MyApp::Schema::Track;
3021   use base qw/DBIx::Class/;
3022   __PACKAGE__->table('track');
3023   __PACKAGE__->add_columns(qw/trackid cd position title/);
3024   __PACKAGE__->set_primary_key('trackid');
3025   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3026   1;
3027
3028   # In your application
3029   my $rs = $schema->resultset('Artist')->search(
3030     { 'track.title' => 'Teardrop' },
3031     {
3032       join     => { cd => 'track' },
3033       order_by => 'artist.name',
3034     }
3035   );
3036
3037 You need to use the relationship (not the table) name in  conditions,
3038 because they are aliased as such. The current table is aliased as "me", so
3039 you need to use me.column_name in order to avoid ambiguity. For example:
3040
3041   # Get CDs from 1984 with a 'Foo' track
3042   my $rs = $schema->resultset('CD')->search(
3043     {
3044       'me.year' => 1984,
3045       'tracks.name' => 'Foo'
3046     },
3047     { join => 'tracks' }
3048   );
3049
3050 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3051 similarly for a third time). For e.g.
3052
3053   my $rs = $schema->resultset('Artist')->search({
3054     'cds.title'   => 'Down to Earth',
3055     'cds_2.title' => 'Popular',
3056   }, {
3057     join => [ qw/cds cds/ ],
3058   });
3059
3060 will return a set of all artists that have both a cd with title 'Down
3061 to Earth' and a cd with title 'Popular'.
3062
3063 If you want to fetch related objects from other tables as well, see C<prefetch>
3064 below.
3065
3066 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3067
3068 =head2 prefetch
3069
3070 =over 4
3071
3072 =item Value: ($rel_name | \@rel_names | \%rel_names)
3073
3074 =back
3075
3076 Contains one or more relationships that should be fetched along with
3077 the main query (when they are accessed afterwards the data will
3078 already be available, without extra queries to the database).  This is
3079 useful for when you know you will need the related objects, because it
3080 saves at least one query:
3081
3082   my $rs = $schema->resultset('Tag')->search(
3083     undef,
3084     {
3085       prefetch => {
3086         cd => 'artist'
3087       }
3088     }
3089   );
3090
3091 The initial search results in SQL like the following:
3092
3093   SELECT tag.*, cd.*, artist.* FROM tag
3094   JOIN cd ON tag.cd = cd.cdid
3095   JOIN artist ON cd.artist = artist.artistid
3096
3097 L<DBIx::Class> has no need to go back to the database when we access the
3098 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3099 case.
3100
3101 Simple prefetches will be joined automatically, so there is no need
3102 for a C<join> attribute in the above search.
3103
3104 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3105 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3106 with an accessor type of 'single' or 'filter'). A more complex example that
3107 prefetches an artists cds, the tracks on those cds, and the tags associted
3108 with that artist is given below (assuming many-to-many from artists to tags):
3109
3110  my $rs = $schema->resultset('Artist')->search(
3111    undef,
3112    {
3113      prefetch => [
3114        { cds => 'tracks' },
3115        { artist_tags => 'tags' }
3116      ]
3117    }
3118  );
3119
3120
3121 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3122 attributes will be ignored.
3123
3124 =head2 page
3125
3126 =over 4
3127
3128 =item Value: $page
3129
3130 =back
3131
3132 Makes the resultset paged and specifies the page to retrieve. Effectively
3133 identical to creating a non-pages resultset and then calling ->page($page)
3134 on it.
3135
3136 If L<rows> attribute is not specified it defualts to 10 rows per page.
3137
3138 When you have a paged resultset, L</count> will only return the number
3139 of rows in the page. To get the total, use the L</pager> and call
3140 C<total_entries> on it.
3141
3142 =head2 rows
3143
3144 =over 4
3145
3146 =item Value: $rows
3147
3148 =back
3149
3150 Specifes the maximum number of rows for direct retrieval or the number of
3151 rows per page if the page attribute or method is used.
3152
3153 =head2 offset
3154
3155 =over 4
3156
3157 =item Value: $offset
3158
3159 =back
3160
3161 Specifies the (zero-based) row number for the  first row to be returned, or the
3162 of the first row of the first page if paging is used.
3163
3164 =head2 group_by
3165
3166 =over 4
3167
3168 =item Value: \@columns
3169
3170 =back
3171
3172 A arrayref of columns to group by. Can include columns of joined tables.
3173
3174   group_by => [qw/ column1 column2 ... /]
3175
3176 =head2 having
3177
3178 =over 4
3179
3180 =item Value: $condition
3181
3182 =back
3183
3184 HAVING is a select statement attribute that is applied between GROUP BY and
3185 ORDER BY. It is applied to the after the grouping calculations have been
3186 done.
3187
3188   having => { 'count(employee)' => { '>=', 100 } }
3189
3190 =head2 distinct
3191
3192 =over 4
3193
3194 =item Value: (0 | 1)
3195
3196 =back
3197
3198 Set to 1 to group by all columns.
3199
3200 =head2 where
3201
3202 =over 4
3203
3204 Adds to the WHERE clause.
3205
3206   # only return rows WHERE deleted IS NULL for all searches
3207   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3208
3209 Can be overridden by passing C<{ where => undef }> as an attribute
3210 to a resulset.
3211
3212 =back
3213
3214 =head2 cache
3215
3216 Set to 1 to cache search results. This prevents extra SQL queries if you
3217 revisit rows in your ResultSet:
3218
3219   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3220
3221   while( my $artist = $resultset->next ) {
3222     ... do stuff ...
3223   }
3224
3225   $rs->first; # without cache, this would issue a query
3226
3227 By default, searches are not cached.
3228
3229 For more examples of using these attributes, see
3230 L<DBIx::Class::Manual::Cookbook>.
3231
3232 =head2 from
3233
3234 =over 4
3235
3236 =item Value: \@from_clause
3237
3238 =back
3239
3240 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3241 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3242 clauses.
3243
3244 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3245
3246 C<join> will usually do what you need and it is strongly recommended that you
3247 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3248 And we really do mean "cannot", not just tried and failed. Attempting to use
3249 this because you're having problems with C<join> is like trying to use x86
3250 ASM because you've got a syntax error in your C. Trust us on this.
3251
3252 Now, if you're still really, really sure you need to use this (and if you're
3253 not 100% sure, ask the mailing list first), here's an explanation of how this
3254 works.
3255
3256 The syntax is as follows -
3257
3258   [
3259     { <alias1> => <table1> },
3260     [
3261       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3262       [], # nested JOIN (optional)
3263       { <table1.column1> => <table2.column2>, ... (more conditions) },
3264     ],
3265     # More of the above [ ] may follow for additional joins
3266   ]
3267
3268   <table1> <alias1>
3269   JOIN
3270     <table2> <alias2>
3271     [JOIN ...]
3272   ON <table1.column1> = <table2.column2>
3273   <more joins may follow>
3274
3275 An easy way to follow the examples below is to remember the following:
3276
3277     Anything inside "[]" is a JOIN
3278     Anything inside "{}" is a condition for the enclosing JOIN
3279
3280 The following examples utilize a "person" table in a family tree application.
3281 In order to express parent->child relationships, this table is self-joined:
3282
3283     # Person->belongs_to('father' => 'Person');
3284     # Person->belongs_to('mother' => 'Person');
3285
3286 C<from> can be used to nest joins. Here we return all children with a father,
3287 then search against all mothers of those children:
3288
3289   $rs = $schema->resultset('Person')->search(
3290       undef,
3291       {
3292           alias => 'mother', # alias columns in accordance with "from"
3293           from => [
3294               { mother => 'person' },
3295               [
3296                   [
3297                       { child => 'person' },
3298                       [
3299                           { father => 'person' },
3300                           { 'father.person_id' => 'child.father_id' }
3301                       ]
3302                   ],
3303                   { 'mother.person_id' => 'child.mother_id' }
3304               ],
3305           ]
3306       },
3307   );
3308
3309   # Equivalent SQL:
3310   # SELECT mother.* FROM person mother
3311   # JOIN (
3312   #   person child
3313   #   JOIN person father
3314   #   ON ( father.person_id = child.father_id )
3315   # )
3316   # ON ( mother.person_id = child.mother_id )
3317
3318 The type of any join can be controlled manually. To search against only people
3319 with a father in the person table, we could explicitly use C<INNER JOIN>:
3320
3321     $rs = $schema->resultset('Person')->search(
3322         undef,
3323         {
3324             alias => 'child', # alias columns in accordance with "from"
3325             from => [
3326                 { child => 'person' },
3327                 [
3328                     { father => 'person', -join_type => 'inner' },
3329                     { 'father.id' => 'child.father_id' }
3330                 ],
3331             ]
3332         },
3333     );
3334
3335     # Equivalent SQL:
3336     # SELECT child.* FROM person child
3337     # INNER JOIN person father ON child.father_id = father.id
3338
3339 If you need to express really complex joins or you need a subselect, you
3340 can supply literal SQL to C<from> via a scalar reference. In this case
3341 the contents of the scalar will replace the table name asscoiated with the
3342 resultsource.
3343
3344 WARNING: This technique might very well not work as expected on chained
3345 searches - you have been warned.
3346
3347     # Assuming the Event resultsource is defined as:
3348
3349         MySchema::Event->add_columns (
3350             sequence => {
3351                 data_type => 'INT',
3352                 is_auto_increment => 1,
3353             },
3354             location => {
3355                 data_type => 'INT',
3356             },
3357             type => {
3358                 data_type => 'INT',
3359             },
3360         );
3361         MySchema::Event->set_primary_key ('sequence');
3362
3363     # This will get back the latest event for every location. The column
3364     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3365     # combo to limit the resultset
3366
3367     $rs = $schema->resultset('Event');
3368     $table = $rs->result_source->name;
3369     $latest = $rs->search (
3370         undef,
3371         { from => \ "
3372             (SELECT e1.* FROM $table e1
3373                 JOIN $table e2
3374                     ON e1.location = e2.location
3375                     AND e1.sequence < e2.sequence
3376                 WHERE e2.sequence is NULL
3377             ) me",
3378         },
3379     );
3380
3381     # Equivalent SQL (with the DBIC chunks added):
3382
3383     SELECT me.sequence, me.location, me.type FROM
3384        (SELECT e1.* FROM events e1
3385            JOIN events e2
3386                ON e1.location = e2.location
3387                AND e1.sequence < e2.sequence
3388            WHERE e2.sequence is NULL
3389        ) me;
3390
3391 =head2 for
3392
3393 =over 4
3394
3395 =item Value: ( 'update' | 'shared' )
3396
3397 =back
3398
3399 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3400 ... FOR SHARED.
3401
3402 =cut
3403
3404 1;