lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use DBIx::Class::Exception;
  11 use Data::Page;
  12 use Storable;
  13 use DBIx::Class::ResultSetColumn;
  14 use DBIx::Class::ResultSourceHandle;
  15 use List::Util ();
  16 use Scalar::Util ();
  17 use base qw/DBIx::Class/;
  18
  19 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  20
  21 =head1 NAME
  22
  23 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  24
  25 =head1 SYNOPSIS
  26
  27   my $users_rs   = $schema->resultset('User');
  28   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  29   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  30
  31 =head1 DESCRIPTION
  32
  33 A ResultSet is an object which stores a set of conditions representing
  34 a query. It is the backbone of DBIx::Class (i.e. the really
  35 important/useful bit).
  36
  37 No SQL is executed on the database when a ResultSet is created, it
  38 just stores all the conditions needed to create the query.
  39
  40 A basic ResultSet representing the data of an entire table is returned
  41 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  42 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  43
  44   my $users_rs = $schema->resultset('User');
  45
  46 A new ResultSet is returned from calling L</search> on an existing
  47 ResultSet. The new one will contain all the conditions of the
  48 original, plus any new conditions added in the C<search> call.
  49
  50 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  51 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  52 represents.
  53
  54 The query that the ResultSet represents is B<only> executed against
  55 the database when these methods are called:
  56 L</find> L</next> L</all> L</first> L</single> L</count>
  57
  58 =head1 EXAMPLES
  59
  60 =head2 Chaining resultsets
  61
  62 Let's say you've got a query that needs to be run to return some data
  63 to the user. But, you have an authorization system in place that
  64 prevents certain users from seeing certain information. So, you want
  65 to construct the basic query in one method, but add constraints to it in
  66 another.
  67
  68   sub get_data {
  69     my $self = shift;
  70     my $request = $self->get_request; # Get a request object somehow.
  71     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  72
  73     my $cd_rs = $schema->resultset('CD')->search({
  74       title => $request->param('title'),
  75       year => $request->param('year'),
  76     });
  77
  78     $self->apply_security_policy( $cd_rs );
  79
  80     return $cd_rs->all();
  81   }
  82
  83   sub apply_security_policy {
  84     my $self = shift;
  85     my ($rs) = @_;
  86
  87     return $rs->search({
  88       subversive => 0,
  89     });
  90   }
  91
  92 =head3 Resolving conditions and attributes
  93
  94 When a resultset is chained from another resultset, conditions and
  95 attributes with the same keys need resolving.
  96
  97 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  98 into the existing ones from the original resultset.
  99
 100 The L</where>, L</having> attribute, and any search conditions are
 101 merged with an SQL C<AND> to the existing condition from the original
 102 resultset.
 103
 104 All other attributes are overridden by any new ones supplied in the
 105 search attributes.
 106
 107 =head2 Multiple queries
 108
 109 Since a resultset just defines a query, you can do all sorts of
 110 things with it with the same object.
 111
 112   # Don't hit the DB yet.
 113   my $cd_rs = $schema->resultset('CD')->search({
 114     title => 'something',
 115     year => 2009,
 116   });
 117
 118   # Each of these hits the DB individually.
 119   my $count = $cd_rs->count;
 120   my $most_recent = $cd_rs->get_column('date_released')->max();
 121   my @records = $cd_rs->all;
 122
 123 And it's not just limited to SELECT statements.
 124
 125   $cd_rs->delete();
 126
 127 This is even cooler:
 128
 129   $cd_rs->create({ artist => 'Fred' });
 130
 131 Which is the same as:
 132
 133   $schema->resultset('CD')->create({
 134     title => 'something',
 135     year => 2009,
 136     artist => 'Fred'
 137   });
 138
 139 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 140
 141 =head1 OVERLOADING
 142
 143 If a resultset is used in a numeric context it returns the L</count>.
 144 However, if it is used in a booleand context it is always true.  So if
 145 you want to check if a resultset has any results use C<if $rs != 0>.
 146 C<if $rs> will always be true.
 147
 148 =head1 METHODS
 149
 150 =head2 new
 151
 152 =over 4
 153
 154 =item Arguments: $source, \%$attrs
 155
 156 =item Return Value: $rs
 157
 158 =back
 159
 160 The resultset constructor. Takes a source object (usually a
 161 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 162 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 163 executed as needed by the other methods.
 164
 165 Generally you won't need to construct a resultset manually.  You'll
 166 automatically get one from e.g. a L</search> called in scalar context:
 167
 168   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 169
 170 IMPORTANT: If called on an object, proxies to new_result instead so
 171
 172   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 173
 174 will return a CD object, not a ResultSet.
 175
 176 =cut
 177
 178 sub new {
 179   my $class = shift;
 180   return $class->new_result(@_) if ref $class;
 181
 182   my ($source, $attrs) = @_;
 183   $source = $source->handle
 184     unless $source->isa('DBIx::Class::ResultSourceHandle');
 185   $attrs = { %{$attrs||{}} };
 186
 187   if ($attrs->{page}) {
 188     $attrs->{rows} ||= 10;
 189   }
 190
 191   $attrs->{alias} ||= 'me';
 192
 193   # Creation of {} and bless separated to mitigate RH perl bug
 194   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 195   my $self = {
 196     _source_handle => $source,
 197     cond => $attrs->{where},
 198     count => undef,
 199     pager => undef,
 200     attrs => $attrs
 201   };
 202
 203   bless $self, $class;
 204
 205   $self->result_class(
 206     $attrs->{result_class} || $source->resolve->result_class
 207   );
 208
 209   return $self;
 210 }
 211
 212 =head2 search
 213
 214 =over 4
 215
 216 =item Arguments: $cond, \%attrs?
 217
 218 =item Return Value: $resultset (scalar context), @row_objs (list context)
 219
 220 =back
 221
 222   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 223   my $new_rs = $cd_rs->search({ year => 2005 });
 224
 225   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 226                  # year = 2005 OR year = 2004
 227
 228 If you need to pass in additional attributes but no additional condition,
 229 call it as C<search(undef, \%attrs)>.
 230
 231   # "SELECT name, artistid FROM $artist_table"
 232   my @all_artists = $schema->resultset('Artist')->search(undef, {
 233     columns => [qw/name artistid/],
 234   });
 235
 236 For a list of attributes that can be passed to C<search>, see
 237 L</ATTRIBUTES>. For more examples of using this function, see
 238 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 239 documentation for the first argument, see L<SQL::Abstract>.
 240
 241 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 242
 243 =cut
 244
 245 sub search {
 246   my $self = shift;
 247   my $rs = $self->search_rs( @_ );
 248   return (wantarray ? $rs->all : $rs);
 249 }
 250
 251 =head2 search_rs
 252
 253 =over 4
 254
 255 =item Arguments: $cond, \%attrs?
 256
 257 =item Return Value: $resultset
 258
 259 =back
 260
 261 This method does the same exact thing as search() except it will
 262 always return a resultset, even in list context.
 263
 264 =cut
 265
 266 sub search_rs {
 267   my $self = shift;
 268
 269   # Special-case handling for (undef, undef).
 270   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 271     pop(@_); pop(@_);
 272   }
 273
 274   my $attrs = {};
 275   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 276   my $our_attrs = { %{$self->{attrs}} };
 277   my $having = delete $our_attrs->{having};
 278   my $where = delete $our_attrs->{where};
 279
 280   my $rows;
 281
 282   my %safe = (alias => 1, cache => 1);
 283
 284   unless (
 285     (@_ && defined($_[0])) # @_ == () or (undef)
 286     ||
 287     (keys %$attrs # empty attrs or only 'safe' attrs
 288     && List::Util::first { !$safe{$_} } keys %$attrs)
 289   ) {
 290     # no search, effectively just a clone
 291     $rows = $self->get_cache;
 292   }
 293
 294   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 295
 296   # merge new attrs into inherited
 297   foreach my $key (qw/join prefetch +select +as bind/) {
 298     next unless exists $attrs->{$key};
 299     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 300   }
 301
 302   my $cond = (@_
 303     ? (
 304         (@_ == 1 || ref $_[0] eq "HASH")
 305           ? (
 306               (ref $_[0] eq 'HASH')
 307                 ? (
 308                     (keys %{ $_[0] }  > 0)
 309                       ? shift
 310                       : undef
 311                    )
 312                 :  shift
 313              )
 314           : (
 315               (@_ % 2)
 316                 ? $self->throw_exception("Odd number of arguments to search")
 317                 : {@_}
 318              )
 319       )
 320     : undef
 321   );
 322
 323   if (defined $where) {
 324     $new_attrs->{where} = (
 325       defined $new_attrs->{where}
 326         ? { '-and' => [
 327               map {
 328                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 329               } $where, $new_attrs->{where}
 330             ]
 331           }
 332         : $where);
 333   }
 334
 335   if (defined $cond) {
 336     $new_attrs->{where} = (
 337       defined $new_attrs->{where}
 338         ? { '-and' => [
 339               map {
 340                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 341               } $cond, $new_attrs->{where}
 342             ]
 343           }
 344         : $cond);
 345   }
 346
 347   if (defined $having) {
 348     $new_attrs->{having} = (
 349       defined $new_attrs->{having}
 350         ? { '-and' => [
 351               map {
 352                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 353               } $having, $new_attrs->{having}
 354             ]
 355           }
 356         : $having);
 357   }
 358
 359   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 360   if ($rows) {
 361     $rs->set_cache($rows);
 362   }
 363   return $rs;
 364 }
 365
 366 =head2 search_literal
 367
 368 =over 4
 369
 370 =item Arguments: $sql_fragment, @bind_values
 371
 372 =item Return Value: $resultset (scalar context), @row_objs (list context)
 373
 374 =back
 375
 376   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 377   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 378
 379 Pass a literal chunk of SQL to be added to the conditional part of the
 380 resultset query.
 381
 382 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 383 only be used in that context. C<search_literal> is a convenience method.
 384 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 385 columns are bound correctly, use C<search>.
 386
 387 Example of how to use C<search> instead of C<search_literal>
 388
 389   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 390   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 391
 392
 393 See L<DBIx::Class::Manual::Cookbook/Searching> and
 394 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 395 require C<search_literal>.
 396
 397 =cut
 398
 399 sub search_literal {
 400   my ($self, $sql, @bind) = @_;
 401   my $attr;
 402   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 403     $attr = pop @bind;
 404   }
 405   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 406 }
 407
 408 =head2 find
 409
 410 =over 4
 411
 412 =item Arguments: @values | \%cols, \%attrs?
 413
 414 =item Return Value: $row_object | undef
 415
 416 =back
 417
 418 Finds a row based on its primary key or unique constraint. For example, to find
 419 a row by its primary key:
 420
 421   my $cd = $schema->resultset('CD')->find(5);
 422
 423 You can also find a row by a specific unique constraint using the C<key>
 424 attribute. For example:
 425
 426   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 427     key => 'cd_artist_title'
 428   });
 429
 430 Additionally, you can specify the columns explicitly by name:
 431
 432   my $cd = $schema->resultset('CD')->find(
 433     {
 434       artist => 'Massive Attack',
 435       title  => 'Mezzanine',
 436     },
 437     { key => 'cd_artist_title' }
 438   );
 439
 440 If the C<key> is specified as C<primary>, it searches only on the primary key.
 441
 442 If no C<key> is specified, it searches on all unique constraints defined on the
 443 source for which column data is provided, including the primary key.
 444
 445 If your table does not have a primary key, you B<must> provide a value for the
 446 C<key> attribute matching one of the unique constraints on the source.
 447
 448 In addition to C<key>, L</find> recognizes and applies standard
 449 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 450
 451 Note: If your query does not return only one row, a warning is generated:
 452
 453   Query returned more than one row
 454
 455 See also L</find_or_create> and L</update_or_create>. For information on how to
 456 declare unique constraints, see
 457 L<DBIx::Class::ResultSource/add_unique_constraint>.
 458
 459 =cut
 460
 461 sub find {
 462   my $self = shift;
 463   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 464
 465   # Default to the primary key, but allow a specific key
 466   my @cols = exists $attrs->{key}
 467     ? $self->result_source->unique_constraint_columns($attrs->{key})
 468     : $self->result_source->primary_columns;
 469   $self->throw_exception(
 470     "Can't find unless a primary key is defined or unique constraint is specified"
 471   ) unless @cols;
 472
 473   # Parse out a hashref from input
 474   my $input_query;
 475   if (ref $_[0] eq 'HASH') {
 476     $input_query = { %{$_[0]} };
 477   }
 478   elsif (@_ == @cols) {
 479     $input_query = {};
 480     @{$input_query}{@cols} = @_;
 481   }
 482   else {
 483     # Compatibility: Allow e.g. find(id => $value)
 484     carp "Find by key => value deprecated; please use a hashref instead";
 485     $input_query = {@_};
 486   }
 487
 488   my (%related, $info);
 489
 490   KEY: foreach my $key (keys %$input_query) {
 491     if (ref($input_query->{$key})
 492         && ($info = $self->result_source->relationship_info($key))) {
 493       my $val = delete $input_query->{$key};
 494       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 495       my $rel_q = $self->result_source->_resolve_condition(
 496                     $info->{cond}, $val, $key
 497                   );
 498       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 499       @related{keys %$rel_q} = values %$rel_q;
 500     }
 501   }
 502   if (my @keys = keys %related) {
 503     @{$input_query}{@keys} = values %related;
 504   }
 505
 506
 507   # Build the final query: Default to the disjunction of the unique queries,
 508   # but allow the input query in case the ResultSet defines the query or the
 509   # user is abusing find
 510   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 511   my $query;
 512   if (exists $attrs->{key}) {
 513     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 514     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 515     $query = $self->_add_alias($unique_query, $alias);
 516   }
 517   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 518     # This means that we got here after a merger of relationship conditions
 519     # in ::Relationship::Base::search_related (the row method), and furthermore
 520     # the relationship is of the 'single' type. This means that the condition
 521     # provided by the relationship (already attached to $self) is sufficient,
 522     # as there can be only one row in the databse that would satisfy the
 523     # relationship
 524   }
 525   else {
 526     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 527     $query = @unique_queries
 528       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 529       : $self->_add_alias($input_query, $alias);
 530   }
 531
 532   # Run the query
 533   my $rs = $self->search ($query, $attrs);
 534   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 535     my $row = $rs->next;
 536     carp "Query returned more than one row" if $rs->next;
 537     return $row;
 538   }
 539   else {
 540     return $rs->single;
 541   }
 542 }
 543
 544 # _add_alias
 545 #
 546 # Add the specified alias to the specified query hash. A copy is made so the
 547 # original query is not modified.
 548
 549 sub _add_alias {
 550   my ($self, $query, $alias) = @_;
 551
 552   my %aliased = %$query;
 553   foreach my $col (grep { ! m/\./ } keys %aliased) {
 554     $aliased{"$alias.$col"} = delete $aliased{$col};
 555   }
 556
 557   return \%aliased;
 558 }
 559
 560 # _unique_queries
 561 #
 562 # Build a list of queries which satisfy unique constraints.
 563
 564 sub _unique_queries {
 565   my ($self, $query, $attrs) = @_;
 566
 567   my @constraint_names = exists $attrs->{key}
 568     ? ($attrs->{key})
 569     : $self->result_source->unique_constraint_names;
 570
 571   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 572   my $num_where = scalar keys %$where;
 573
 574   my (@unique_queries, %seen_column_combinations);
 575   foreach my $name (@constraint_names) {
 576     my @constraint_cols = $self->result_source->unique_constraint_columns($name);
 577
 578     my $constraint_sig = join "\x00", sort @constraint_cols;
 579     next if $seen_column_combinations{$constraint_sig}++;
 580
 581     my $unique_query = $self->_build_unique_query($query, \@constraint_cols);
 582
 583     my $num_cols = scalar @constraint_cols;
 584     my $num_query = scalar keys %$unique_query;
 585
 586     my $total = $num_query + $num_where;
 587     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 588       # The query is either unique on its own or is unique in combination with
 589       # the existing where clause
 590       push @unique_queries, $unique_query;
 591     }
 592   }
 593
 594   return @unique_queries;
 595 }
 596
 597 # _build_unique_query
 598 #
 599 # Constrain the specified query hash based on the specified column names.
 600
 601 sub _build_unique_query {
 602   my ($self, $query, $unique_cols) = @_;
 603
 604   return {
 605     map  { $_ => $query->{$_} }
 606     grep { exists $query->{$_} }
 607       @$unique_cols
 608   };
 609 }
 610
 611 =head2 search_related
 612
 613 =over 4
 614
 615 =item Arguments: $rel, $cond, \%attrs?
 616
 617 =item Return Value: $new_resultset
 618
 619 =back
 620
 621   $new_rs = $cd_rs->search_related('artist', {
 622     name => 'Emo-R-Us',
 623   });
 624
 625 Searches the specified relationship, optionally specifying a condition and
 626 attributes for matching records. See L</ATTRIBUTES> for more information.
 627
 628 =cut
 629
 630 sub search_related {
 631   return shift->related_resultset(shift)->search(@_);
 632 }
 633
 634 =head2 search_related_rs
 635
 636 This method works exactly the same as search_related, except that
 637 it guarantees a restultset, even in list context.
 638
 639 =cut
 640
 641 sub search_related_rs {
 642   return shift->related_resultset(shift)->search_rs(@_);
 643 }
 644
 645 =head2 cursor
 646
 647 =over 4
 648
 649 =item Arguments: none
 650
 651 =item Return Value: $cursor
 652
 653 =back
 654
 655 Returns a storage-driven cursor to the given resultset. See
 656 L<DBIx::Class::Cursor> for more information.
 657
 658 =cut
 659
 660 sub cursor {
 661   my ($self) = @_;
 662
 663   my $attrs = $self->_resolved_attrs_copy;
 664
 665   return $self->{cursor}
 666     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 667           $attrs->{where},$attrs);
 668 }
 669
 670 =head2 single
 671
 672 =over 4
 673
 674 =item Arguments: $cond?
 675
 676 =item Return Value: $row_object?
 677
 678 =back
 679
 680   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 681
 682 Inflates the first result without creating a cursor if the resultset has
 683 any records in it; if not returns nothing. Used by L</find> as a lean version of
 684 L</search>.
 685
 686 While this method can take an optional search condition (just like L</search>)
 687 being a fast-code-path it does not recognize search attributes. If you need to
 688 add extra joins or similar, call L</search> and then chain-call L</single> on the
 689 L<DBIx::Class::ResultSet> returned.
 690
 691 =over
 692
 693 =item B<Note>
 694
 695 As of 0.08100, this method enforces the assumption that the preceeding
 696 query returns only one row. If more than one row is returned, you will receive
 697 a warning:
 698
 699   Query returned more than one row
 700
 701 In this case, you should be using L</next> or L</find> instead, or if you really
 702 know what you are doing, use the L</rows> attribute to explicitly limit the size
 703 of the resultset.
 704
 705 This method will also throw an exception if it is called on a resultset prefetching
 706 has_many, as such a prefetch implies fetching multiple rows from the database in
 707 order to assemble the resulting object.
 708
 709 =back
 710
 711 =cut
 712
 713 sub single {
 714   my ($self, $where) = @_;
 715   if(@_ > 2) {
 716       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 717   }
 718
 719   my $attrs = $self->_resolved_attrs_copy;
 720
 721   if (keys %{$attrs->{collapse}}) {
 722     $self->throw_exception(
 723       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 724     );
 725   }
 726
 727   if ($where) {
 728     if (defined $attrs->{where}) {
 729       $attrs->{where} = {
 730         '-and' =>
 731             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 732                $where, delete $attrs->{where} ]
 733       };
 734     } else {
 735       $attrs->{where} = $where;
 736     }
 737   }
 738
 739 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 740 #  unless ($self->_is_unique_query($attrs->{where})) {
 741 #    carp "Query not guaranteed to return a single row"
 742 #      . "; please declare your unique constraints or use search instead";
 743 #  }
 744
 745   my @data = $self->result_source->storage->select_single(
 746     $attrs->{from}, $attrs->{select},
 747     $attrs->{where}, $attrs
 748   );
 749
 750   return (@data ? ($self->_construct_object(@data))[0] : undef);
 751 }
 752
 753
 754 # _is_unique_query
 755 #
 756 # Try to determine if the specified query is guaranteed to be unique, based on
 757 # the declared unique constraints.
 758
 759 sub _is_unique_query {
 760   my ($self, $query) = @_;
 761
 762   my $collapsed = $self->_collapse_query($query);
 763   my $alias = $self->{attrs}{alias};
 764
 765   foreach my $name ($self->result_source->unique_constraint_names) {
 766     my @unique_cols = map {
 767       "$alias.$_"
 768     } $self->result_source->unique_constraint_columns($name);
 769
 770     # Count the values for each unique column
 771     my %seen = map { $_ => 0 } @unique_cols;
 772
 773     foreach my $key (keys %$collapsed) {
 774       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 775       next unless exists $seen{$aliased};  # Additional constraints are okay
 776       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 777     }
 778
 779     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 780     return 1 unless grep { $_ != 1 } values %seen;
 781   }
 782
 783   return 0;
 784 }
 785
 786 # _collapse_query
 787 #
 788 # Recursively collapse the query, accumulating values for each column.
 789
 790 sub _collapse_query {
 791   my ($self, $query, $collapsed) = @_;
 792
 793   $collapsed ||= {};
 794
 795   if (ref $query eq 'ARRAY') {
 796     foreach my $subquery (@$query) {
 797       next unless ref $subquery;  # -or
 798       $collapsed = $self->_collapse_query($subquery, $collapsed);
 799     }
 800   }
 801   elsif (ref $query eq 'HASH') {
 802     if (keys %$query and (keys %$query)[0] eq '-and') {
 803       foreach my $subquery (@{$query->{-and}}) {
 804         $collapsed = $self->_collapse_query($subquery, $collapsed);
 805       }
 806     }
 807     else {
 808       foreach my $col (keys %$query) {
 809         my $value = $query->{$col};
 810         $collapsed->{$col}{$value}++;
 811       }
 812     }
 813   }
 814
 815   return $collapsed;
 816 }
 817
 818 =head2 get_column
 819
 820 =over 4
 821
 822 =item Arguments: $cond?
 823
 824 =item Return Value: $resultsetcolumn
 825
 826 =back
 827
 828   my $max_length = $rs->get_column('length')->max;
 829
 830 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 831
 832 =cut
 833
 834 sub get_column {
 835   my ($self, $column) = @_;
 836   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 837   return $new;
 838 }
 839
 840 =head2 search_like
 841
 842 =over 4
 843
 844 =item Arguments: $cond, \%attrs?
 845
 846 =item Return Value: $resultset (scalar context), @row_objs (list context)
 847
 848 =back
 849
 850   # WHERE title LIKE '%blue%'
 851   $cd_rs = $rs->search_like({ title => '%blue%'});
 852
 853 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 854 that this is simply a convenience method retained for ex Class::DBI users.
 855 You most likely want to use L</search> with specific operators.
 856
 857 For more information, see L<DBIx::Class::Manual::Cookbook>.
 858
 859 This method is deprecated and will be removed in 0.09. Use L</search()>
 860 instead. An example conversion is:
 861
 862   ->search_like({ foo => 'bar' });
 863
 864   # Becomes
 865
 866   ->search({ foo => { like => 'bar' } });
 867
 868 =cut
 869
 870 sub search_like {
 871   my $class = shift;
 872   carp (
 873     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 874    .' Instead use ->search({ x => { -like => "y%" } })'
 875    .' (note the outer pair of {}s - they are important!)'
 876   );
 877   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 878   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 879   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 880   return $class->search($query, { %$attrs });
 881 }
 882
 883 =head2 slice
 884
 885 =over 4
 886
 887 =item Arguments: $first, $last
 888
 889 =item Return Value: $resultset (scalar context), @row_objs (list context)
 890
 891 =back
 892
 893 Returns a resultset or object list representing a subset of elements from the
 894 resultset slice is called on. Indexes are from 0, i.e., to get the first
 895 three records, call:
 896
 897   my ($one, $two, $three) = $rs->slice(0, 2);
 898
 899 =cut
 900
 901 sub slice {
 902   my ($self, $min, $max) = @_;
 903   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 904   $attrs->{offset} = $self->{attrs}{offset} || 0;
 905   $attrs->{offset} += $min;
 906   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 907   return $self->search(undef(), $attrs);
 908   #my $slice = (ref $self)->new($self->result_source, $attrs);
 909   #return (wantarray ? $slice->all : $slice);
 910 }
 911
 912 =head2 next
 913
 914 =over 4
 915
 916 =item Arguments: none
 917
 918 =item Return Value: $result?
 919
 920 =back
 921
 922 Returns the next element in the resultset (C<undef> is there is none).
 923
 924 Can be used to efficiently iterate over records in the resultset:
 925
 926   my $rs = $schema->resultset('CD')->search;
 927   while (my $cd = $rs->next) {
 928     print $cd->title;
 929   }
 930
 931 Note that you need to store the resultset object, and call C<next> on it.
 932 Calling C<< resultset('Table')->next >> repeatedly will always return the
 933 first record from the resultset.
 934
 935 =cut
 936
 937 sub next {
 938   my ($self) = @_;
 939   if (my $cache = $self->get_cache) {
 940     $self->{all_cache_position} ||= 0;
 941     return $cache->[$self->{all_cache_position}++];
 942   }
 943   if ($self->{attrs}{cache}) {
 944     $self->{all_cache_position} = 1;
 945     return ($self->all)[0];
 946   }
 947   if ($self->{stashed_objects}) {
 948     my $obj = shift(@{$self->{stashed_objects}});
 949     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 950     return $obj;
 951   }
 952   my @row = (
 953     exists $self->{stashed_row}
 954       ? @{delete $self->{stashed_row}}
 955       : $self->cursor->next
 956   );
 957   return undef unless (@row);
 958   my ($row, @more) = $self->_construct_object(@row);
 959   $self->{stashed_objects} = \@more if @more;
 960   return $row;
 961 }
 962
 963 sub _construct_object {
 964   my ($self, @row) = @_;
 965
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 967     or return ();
 968   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 969   @new = $self->{_attrs}{record_filter}->(@new)
 970     if exists $self->{_attrs}{record_filter};
 971   return @new;
 972 }
 973
 974
 975 # two arguments: $as_proto is an arrayref of column names,
 976 # $row_ref is an arrayref of the data. If none of the row data
 977 # is defined we return undef (that's copied from the old
 978 # _collapse_result). Next we decide whether we need to collapse
 979 # the resultset (i.e. we prefetch something) or not. $collapse
 980 # indicates that. The do-while loop will run once if we do not need
 981 # to collapse the result and will run as long as _merge_result returns
 982 # a true value. It will return undef if the current added row does not
 983 # match the previous row. A bit of stashing and cursor magic is
 984 # required so that the cursor is not mixed up.
 985
 986 # "$rows" is a bit misleading. In the end, there should only be one
 987 # element in this arrayref.
 988
 989 sub _collapse_result {
 990     my ( $self, $as_proto, $row_ref ) = @_;
 991     my $has_def;
 992     for (@$row_ref) {
 993         if ( defined $_ ) {
 994             $has_def++;
 995             last;
 996         }
 997     }
 998     return undef unless $has_def;
 999
1000     my $collapse = keys %{ $self->{_attrs}{collapse} || {} };
1001     my $rows     = [];
1002     my @row      = @$row_ref;
1003     do {
1004         my $i = 0;
1005         my $row = { map { $_ => $row[ $i++ ] } @$as_proto };
1006         $row = $self->result_source->_parse_row($row, $collapse);
1007         unless ( scalar @$rows ) {
1008             push( @$rows, $row );
1009         }
1010         $collapse = undef unless ( $self->_merge_result( $rows, $row ) );
1011       } while (
1012         $collapse
1013         && do { @row = $self->cursor->next; $self->{stashed_row} = \@row if @row; }
1014       );
1015
1016     return $rows->[0];
1017
1018 }
1019
1020 # _merge_result accepts an arrayref of rows objects (again, an arrayref of two elements)
1021 # and a row object which should be merged into the first object.
1022 # First we try to find out whether $row is already in $rows. If this is the case
1023 # we try to merge them by iteration through their relationship data. We call
1024 # _merge_result again on them, so they get merged.
1025
1026 # If we don't find the $row in $rows, we append it to $rows and return undef.
1027 # _merge_result returns 1 otherwise (i.e. $row has been found in $rows).
1028
1029 sub _merge_result {
1030     my ( $self, $rows, $row ) = @_;
1031     my ( $columns, $rels ) = @$row;
1032     my $found = undef;
1033     foreach my $seen (@$rows) {
1034         my $match = 1;
1035         foreach my $column ( keys %$columns ) {
1036             if (   defined $seen->[0]->{$column} ^ defined $columns->{$column}
1037                 or defined $columns->{$column}
1038                 && $seen->[0]->{$column} ne $columns->{$column} )
1039             {
1040
1041                 $match = 0;
1042                 last;
1043             }
1044         }
1045         if ($match) {
1046             $found = $seen;
1047             last;
1048         }
1049     }
1050     if ($found) {
1051         foreach my $rel ( keys %$rels ) {
1052             my $old_rows = $found->[1]->{$rel};
1053             $self->_merge_result(
1054                 ref $found->[1]->{$rel}->[0] eq 'HASH' ? [ $found->[1]->{$rel} ]
1055                 : $found->[1]->{$rel},
1056                 ref $rels->{$rel}->[0] eq 'HASH' ? [ $rels->{$rel}->[0], $rels->{$rel}->[1] ]
1057                 : $rels->{$rel}->[0]
1058             );
1059
1060         }
1061
1062     }
1063     else {
1064         push( @$rows, $row );
1065         return undef;
1066     }
1067
1068     return 1;
1069 }
1070
1071
1072 =head2 result_source
1073
1074 =over 4
1075
1076 =item Arguments: $result_source?
1077
1078 =item Return Value: $result_source
1079
1080 =back
1081
1082 An accessor for the primary ResultSource object from which this ResultSet
1083 is derived.
1084
1085 =head2 result_class
1086
1087 =over 4
1088
1089 =item Arguments: $result_class?
1090
1091 =item Return Value: $result_class
1092
1093 =back
1094
1095 An accessor for the class to use when creating row objects. Defaults to
1096 C<< result_source->result_class >> - which in most cases is the name of the
1097 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1098
1099 Note that changing the result_class will also remove any components
1100 that were originally loaded in the source class via
1101 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1102 in the original source class will not run.
1103
1104 =cut
1105
1106 sub result_class {
1107   my ($self, $result_class) = @_;
1108   if ($result_class) {
1109     $self->ensure_class_loaded($result_class);
1110     $self->_result_class($result_class);
1111   }
1112   $self->_result_class;
1113 }
1114
1115 =head2 count
1116
1117 =over 4
1118
1119 =item Arguments: $cond, \%attrs??
1120
1121 =item Return Value: $count
1122
1123 =back
1124
1125 Performs an SQL C<COUNT> with the same query as the resultset was built
1126 with to find the number of elements. Passing arguments is equivalent to
1127 C<< $rs->search ($cond, \%attrs)->count >>
1128
1129 =cut
1130
1131 sub count {
1132   my $self = shift;
1133   return $self->search(@_)->count if @_ and defined $_[0];
1134   return scalar @{ $self->get_cache } if $self->get_cache;
1135
1136   my $attrs = $self->_resolved_attrs_copy;
1137
1138   # this is a little optimization - it is faster to do the limit
1139   # adjustments in software, instead of a subquery
1140   my $rows = delete $attrs->{rows};
1141   my $offset = delete $attrs->{offset};
1142
1143   my $crs;
1144   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1145     $crs = $self->_count_subq_rs ($attrs);
1146   }
1147   else {
1148     $crs = $self->_count_rs ($attrs);
1149   }
1150   my $count = $crs->next;
1151
1152   $count -= $offset if $offset;
1153   $count = $rows if $rows and $rows < $count;
1154   $count = 0 if ($count < 0);
1155
1156   return $count;
1157 }
1158
1159 =head2 count_rs
1160
1161 =over 4
1162
1163 =item Arguments: $cond, \%attrs??
1164
1165 =item Return Value: $count_rs
1166
1167 =back
1168
1169 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1170 This can be very handy for subqueries:
1171
1172   ->search( { amount => $some_rs->count_rs->as_query } )
1173
1174 As with regular resultsets the SQL query will be executed only after
1175 the resultset is accessed via L</next> or L</all>. That would return
1176 the same single value obtainable via L</count>.
1177
1178 =cut
1179
1180 sub count_rs {
1181   my $self = shift;
1182   return $self->search(@_)->count_rs if @_;
1183
1184   # this may look like a lack of abstraction (count() does about the same)
1185   # but in fact an _rs *must* use a subquery for the limits, as the
1186   # software based limiting can not be ported if this $rs is to be used
1187   # in a subquery itself (i.e. ->as_query)
1188   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1189     return $self->_count_subq_rs;
1190   }
1191   else {
1192     return $self->_count_rs;
1193   }
1194 }
1195
1196 #
1197 # returns a ResultSetColumn object tied to the count query
1198 #
1199 sub _count_rs {
1200   my ($self, $attrs) = @_;
1201
1202   my $rsrc = $self->result_source;
1203   $attrs ||= $self->_resolved_attrs;
1204
1205   my $tmp_attrs = { %$attrs };
1206
1207   # take off any limits, record_filter is cdbi, and no point of ordering a count
1208   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1209
1210   # overwrite the selector (supplied by the storage)
1211   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1212   $tmp_attrs->{as} = 'count';
1213
1214   # read the comment on top of the actual function to see what this does
1215   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1216     $tmp_attrs->{from}, $tmp_attrs->{alias}
1217   );
1218
1219   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1220
1221   return $tmp_rs;
1222 }
1223
1224 #
1225 # same as above but uses a subquery
1226 #
1227 sub _count_subq_rs {
1228   my ($self, $attrs) = @_;
1229
1230   my $rsrc = $self->result_source;
1231   $attrs ||= $self->_resolved_attrs_copy;
1232
1233   my $sub_attrs = { %$attrs };
1234
1235   # extra selectors do not go in the subquery and there is no point of ordering it
1236   delete $sub_attrs->{$_} for qw/collapse select _prefetch_select as order_by/;
1237
1238   # if we prefetch, we group_by primary keys only as this is what we would get out
1239   # of the rs via ->next/->all. We DO WANT to clobber old group_by regardless
1240   if ( keys %{$attrs->{collapse}} ) {
1241     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1242   }
1243
1244   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1245
1246   # read the comment on top of the actual function to see what this does
1247   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1248     $sub_attrs->{from}, $sub_attrs->{alias}
1249   );
1250
1251   # this is so that ordering can be thrown away in things like Top limit
1252   $sub_attrs->{-for_count_only} = 1;
1253
1254   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1255
1256   $attrs->{from} = [{
1257     -alias => 'count_subq',
1258     -source_handle => $rsrc->handle,
1259     count_subq => $sub_rs->as_query,
1260   }];
1261
1262   # the subquery replaces this
1263   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1264
1265   return $self->_count_rs ($attrs);
1266 }
1267
1268
1269 # The DBIC relationship chaining implementation is pretty simple - every
1270 # new related_relationship is pushed onto the {from} stack, and the {select}
1271 # window simply slides further in. This means that when we count somewhere
1272 # in the middle, we got to make sure that everything in the join chain is an
1273 # actual inner join, otherwise the count will come back with unpredictable
1274 # results (a resultset may be generated with _some_ rows regardless of if
1275 # the relation which the $rs currently selects has rows or not). E.g.
1276 # $artist_rs->cds->count - normally generates:
1277 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1278 # which actually returns the number of artists * (number of cds || 1)
1279 #
1280 # So what we do here is crawl {from}, determine if the current alias is at
1281 # the top of the stack, and if not - make sure the chain is inner-joined down
1282 # to the root.
1283 #
1284 sub _switch_to_inner_join_if_needed {
1285   my ($self, $from, $alias) = @_;
1286
1287   # subqueries and other oddness is naturally not supported
1288   return $from if (
1289     ref $from ne 'ARRAY'
1290       ||
1291     @$from <= 1
1292       ||
1293     ref $from->[0] ne 'HASH'
1294       ||
1295     ! $from->[0]{-alias}
1296       ||
1297     $from->[0]{-alias} eq $alias
1298   );
1299
1300   my $switch_branch;
1301   JOINSCAN:
1302   for my $j (@{$from}[1 .. $#$from]) {
1303     if ($j->[0]{-alias} eq $alias) {
1304       $switch_branch = $j->[0]{-join_path};
1305       last JOINSCAN;
1306     }
1307   }
1308
1309   # something else went wrong
1310   return $from unless $switch_branch;
1311
1312   # So it looks like we will have to switch some stuff around.
1313   # local() is useless here as we will be leaving the scope
1314   # anyway, and deep cloning is just too fucking expensive
1315   # So replace the inner hashref manually
1316   my @new_from = ($from->[0]);
1317   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1318
1319   for my $j (@{$from}[1 .. $#$from]) {
1320     my $jalias = $j->[0]{-alias};
1321
1322     if ($sw_idx->{$jalias}) {
1323       my %attrs = %{$j->[0]};
1324       delete $attrs{-join_type};
1325       push @new_from, [
1326         \%attrs,
1327         @{$j}[ 1 .. $#$j ],
1328       ];
1329     }
1330     else {
1331       push @new_from, $j;
1332     }
1333   }
1334
1335   return \@new_from;
1336 }
1337
1338
1339 sub _bool {
1340   return 1;
1341 }
1342
1343 =head2 count_literal
1344
1345 =over 4
1346
1347 =item Arguments: $sql_fragment, @bind_values
1348
1349 =item Return Value: $count
1350
1351 =back
1352
1353 Counts the results in a literal query. Equivalent to calling L</search_literal>
1354 with the passed arguments, then L</count>.
1355
1356 =cut
1357
1358 sub count_literal { shift->search_literal(@_)->count; }
1359
1360 =head2 all
1361
1362 =over 4
1363
1364 =item Arguments: none
1365
1366 =item Return Value: @objects
1367
1368 =back
1369
1370 Returns all elements in the resultset. Called implicitly if the resultset
1371 is returned in list context.
1372
1373 =cut
1374
1375 sub all {
1376   my $self = shift;
1377   if(@_) {
1378       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1379   }
1380
1381   return @{ $self->get_cache } if $self->get_cache;
1382
1383   my @obj;
1384
1385   if (keys %{$self->_resolved_attrs->{collapse}}) {
1386     # Using $self->cursor->all is really just an optimisation.
1387     # If we're collapsing has_many prefetches it probably makes
1388     # very little difference, and this is cleaner than hacking
1389     # _construct_object to survive the approach
1390     $self->cursor->reset;
1391     my @row = $self->cursor->next;
1392     while (@row) {
1393       push(@obj, $self->_construct_object(@row));
1394       @row = (exists $self->{stashed_row}
1395                ? @{delete $self->{stashed_row}}
1396                : $self->cursor->next);
1397     }
1398   } else {
1399     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1400   }
1401
1402   $self->set_cache(\@obj) if $self->{attrs}{cache};
1403
1404   return @obj;
1405 }
1406
1407 =head2 reset
1408
1409 =over 4
1410
1411 =item Arguments: none
1412
1413 =item Return Value: $self
1414
1415 =back
1416
1417 Resets the resultset's cursor, so you can iterate through the elements again.
1418 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1419 another query.
1420
1421 =cut
1422
1423 sub reset {
1424   my ($self) = @_;
1425   delete $self->{_attrs} if exists $self->{_attrs};
1426   $self->{all_cache_position} = 0;
1427   $self->cursor->reset;
1428   return $self;
1429 }
1430
1431 =head2 first
1432
1433 =over 4
1434
1435 =item Arguments: none
1436
1437 =item Return Value: $object?
1438
1439 =back
1440
1441 Resets the resultset and returns an object for the first result (if the
1442 resultset returns anything).
1443
1444 =cut
1445
1446 sub first {
1447   return $_[0]->reset->next;
1448 }
1449
1450
1451 # _rs_update_delete
1452 #
1453 # Determines whether and what type of subquery is required for the $rs operation.
1454 # If grouping is necessary either supplies its own, or verifies the current one
1455 # After all is done delegates to the proper storage method.
1456
1457 sub _rs_update_delete {
1458   my ($self, $op, $values) = @_;
1459
1460   my $rsrc = $self->result_source;
1461
1462   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1463   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1464
1465   if ($needs_group_by_subq or $needs_subq) {
1466
1467     # make a new $rs selecting only the PKs (that's all we really need)
1468     my $attrs = $self->_resolved_attrs_copy;
1469
1470     delete $attrs->{$_} for qw/collapse select as/;
1471     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1472
1473     if ($needs_group_by_subq) {
1474       # make sure no group_by was supplied, or if there is one - make sure it matches
1475       # the columns compiled above perfectly. Anything else can not be sanely executed
1476       # on most databases so croak right then and there
1477
1478       if (my $g = $attrs->{group_by}) {
1479         my @current_group_by = map
1480           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1481           @$g
1482         ;
1483
1484         if (
1485           join ("\x00", sort @current_group_by)
1486             ne
1487           join ("\x00", sort @{$attrs->{columns}} )
1488         ) {
1489           $self->throw_exception (
1490             "You have just attempted a $op operation on a resultset which does group_by"
1491             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1492             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1493             . ' kind of queries. Please retry the operation with a modified group_by or'
1494             . ' without using one at all.'
1495           );
1496         }
1497       }
1498       else {
1499         $attrs->{group_by} = $attrs->{columns};
1500       }
1501     }
1502
1503     my $subrs = (ref $self)->new($rsrc, $attrs);
1504
1505     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1506   }
1507   else {
1508     return $rsrc->storage->$op(
1509       $rsrc,
1510       $op eq 'update' ? $values : (),
1511       $self->_cond_for_update_delete,
1512     );
1513   }
1514 }
1515
1516
1517 # _cond_for_update_delete
1518 #
1519 # update/delete require the condition to be modified to handle
1520 # the differing SQL syntax available.  This transforms the $self->{cond}
1521 # appropriately, returning the new condition.
1522
1523 sub _cond_for_update_delete {
1524   my ($self, $full_cond) = @_;
1525   my $cond = {};
1526
1527   $full_cond ||= $self->{cond};
1528   # No-op. No condition, we're updating/deleting everything
1529   return $cond unless ref $full_cond;
1530
1531   if (ref $full_cond eq 'ARRAY') {
1532     $cond = [
1533       map {
1534         my %hash;
1535         foreach my $key (keys %{$_}) {
1536           $key =~ /([^.]+)$/;
1537           $hash{$1} = $_->{$key};
1538         }
1539         \%hash;
1540       } @{$full_cond}
1541     ];
1542   }
1543   elsif (ref $full_cond eq 'HASH') {
1544     if ((keys %{$full_cond})[0] eq '-and') {
1545       $cond->{-and} = [];
1546       my @cond = @{$full_cond->{-and}};
1547        for (my $i = 0; $i < @cond; $i++) {
1548         my $entry = $cond[$i];
1549         my $hash;
1550         if (ref $entry eq 'HASH') {
1551           $hash = $self->_cond_for_update_delete($entry);
1552         }
1553         else {
1554           $entry =~ /([^.]+)$/;
1555           $hash->{$1} = $cond[++$i];
1556         }
1557         push @{$cond->{-and}}, $hash;
1558       }
1559     }
1560     else {
1561       foreach my $key (keys %{$full_cond}) {
1562         $key =~ /([^.]+)$/;
1563         $cond->{$1} = $full_cond->{$key};
1564       }
1565     }
1566   }
1567   else {
1568     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1569   }
1570
1571   return $cond;
1572 }
1573
1574
1575 =head2 update
1576
1577 =over 4
1578
1579 =item Arguments: \%values
1580
1581 =item Return Value: $storage_rv
1582
1583 =back
1584
1585 Sets the specified columns in the resultset to the supplied values in a
1586 single query. Return value will be true if the update succeeded or false
1587 if no records were updated; exact type of success value is storage-dependent.
1588
1589 =cut
1590
1591 sub update {
1592   my ($self, $values) = @_;
1593   $self->throw_exception('Values for update must be a hash')
1594     unless ref $values eq 'HASH';
1595
1596   return $self->_rs_update_delete ('update', $values);
1597 }
1598
1599 =head2 update_all
1600
1601 =over 4
1602
1603 =item Arguments: \%values
1604
1605 =item Return Value: 1
1606
1607 =back
1608
1609 Fetches all objects and updates them one at a time. Note that C<update_all>
1610 will run DBIC cascade triggers, while L</update> will not.
1611
1612 =cut
1613
1614 sub update_all {
1615   my ($self, $values) = @_;
1616   $self->throw_exception('Values for update_all must be a hash')
1617     unless ref $values eq 'HASH';
1618   foreach my $obj ($self->all) {
1619     $obj->set_columns($values)->update;
1620   }
1621   return 1;
1622 }
1623
1624 =head2 delete
1625
1626 =over 4
1627
1628 =item Arguments: none
1629
1630 =item Return Value: $storage_rv
1631
1632 =back
1633
1634 Deletes the contents of the resultset from its result source. Note that this
1635 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1636 to run. See also L<DBIx::Class::Row/delete>.
1637
1638 Return value will be the amount of rows deleted; exact type of return value
1639 is storage-dependent.
1640
1641 =cut
1642
1643 sub delete {
1644   my $self = shift;
1645   $self->throw_exception('delete does not accept any arguments')
1646     if @_;
1647
1648   return $self->_rs_update_delete ('delete');
1649 }
1650
1651 =head2 delete_all
1652
1653 =over 4
1654
1655 =item Arguments: none
1656
1657 =item Return Value: 1
1658
1659 =back
1660
1661 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1662 will run DBIC cascade triggers, while L</delete> will not.
1663
1664 =cut
1665
1666 sub delete_all {
1667   my $self = shift;
1668   $self->throw_exception('delete_all does not accept any arguments')
1669     if @_;
1670
1671   $_->delete for $self->all;
1672   return 1;
1673 }
1674
1675 =head2 populate
1676
1677 =over 4
1678
1679 =item Arguments: \@data;
1680
1681 =back
1682
1683 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1684 For the arrayref of hashrefs style each hashref should be a structure suitable
1685 forsubmitting to a $resultset->create(...) method.
1686
1687 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1688 to insert the data, as this is a faster method.
1689
1690 Otherwise, each set of data is inserted into the database using
1691 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1692 accumulated into an array. The array itself, or an array reference
1693 is returned depending on scalar or list context.
1694
1695 Example:  Assuming an Artist Class that has many CDs Classes relating:
1696
1697   my $Artist_rs = $schema->resultset("Artist");
1698
1699   ## Void Context Example
1700   $Artist_rs->populate([
1701      { artistid => 4, name => 'Manufactured Crap', cds => [
1702         { title => 'My First CD', year => 2006 },
1703         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1704       ],
1705      },
1706      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1707         { title => 'My parents sold me to a record company' ,year => 2005 },
1708         { title => 'Why Am I So Ugly?', year => 2006 },
1709         { title => 'I Got Surgery and am now Popular', year => 2007 }
1710       ],
1711      },
1712   ]);
1713
1714   ## Array Context Example
1715   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1716     { name => "Artist One"},
1717     { name => "Artist Two"},
1718     { name => "Artist Three", cds=> [
1719     { title => "First CD", year => 2007},
1720     { title => "Second CD", year => 2008},
1721   ]}
1722   ]);
1723
1724   print $ArtistOne->name; ## response is 'Artist One'
1725   print $ArtistThree->cds->count ## reponse is '2'
1726
1727 For the arrayref of arrayrefs style,  the first element should be a list of the
1728 fieldsnames to which the remaining elements are rows being inserted.  For
1729 example:
1730
1731   $Arstist_rs->populate([
1732     [qw/artistid name/],
1733     [100, 'A Formally Unknown Singer'],
1734     [101, 'A singer that jumped the shark two albums ago'],
1735     [102, 'An actually cool singer.'],
1736   ]);
1737
1738 Please note an important effect on your data when choosing between void and
1739 wantarray context. Since void context goes straight to C<insert_bulk> in
1740 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1741 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1742 create primary keys for you, you will find that your PKs are empty.  In this
1743 case you will have to use the wantarray context in order to create those
1744 values.
1745
1746 =cut
1747
1748 sub populate {
1749   my $self = shift @_;
1750   my $data = ref $_[0][0] eq 'HASH'
1751     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1752     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1753
1754   if(defined wantarray) {
1755     my @created;
1756     foreach my $item (@$data) {
1757       push(@created, $self->create($item));
1758     }
1759     return wantarray ? @created : \@created;
1760   } else {
1761     my ($first, @rest) = @$data;
1762
1763     my @names = grep {!ref $first->{$_}} keys %$first;
1764     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1765     my @pks = $self->result_source->primary_columns;
1766
1767     ## do the belongs_to relationships
1768     foreach my $index (0..$#$data) {
1769
1770       # delegate to create() for any dataset without primary keys with specified relationships
1771       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1772         for my $r (@rels) {
1773           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1774             my @ret = $self->populate($data);
1775             return;
1776           }
1777         }
1778       }
1779
1780       foreach my $rel (@rels) {
1781         next unless ref $data->[$index]->{$rel} eq "HASH";
1782         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1783         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1784         my $related = $result->result_source->_resolve_condition(
1785           $result->result_source->relationship_info($reverse)->{cond},
1786           $self,
1787           $result,
1788         );
1789
1790         delete $data->[$index]->{$rel};
1791         $data->[$index] = {%{$data->[$index]}, %$related};
1792
1793         push @names, keys %$related if $index == 0;
1794       }
1795     }
1796
1797     ## do bulk insert on current row
1798     my @values = map { [ @$_{@names} ] } @$data;
1799
1800     $self->result_source->storage->insert_bulk(
1801       $self->result_source,
1802       \@names,
1803       \@values,
1804     );
1805
1806     ## do the has_many relationships
1807     foreach my $item (@$data) {
1808
1809       foreach my $rel (@rels) {
1810         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1811
1812         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1813      || $self->throw_exception('Cannot find the relating object.');
1814
1815         my $child = $parent->$rel;
1816
1817         my $related = $child->result_source->_resolve_condition(
1818           $parent->result_source->relationship_info($rel)->{cond},
1819           $child,
1820           $parent,
1821         );
1822
1823         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1824         my @populate = map { {%$_, %$related} } @rows_to_add;
1825
1826         $child->populate( \@populate );
1827       }
1828     }
1829   }
1830 }
1831
1832 =head2 _normalize_populate_args ($args)
1833
1834 Private method used by L</populate> to normalize its incoming arguments.  Factored
1835 out in case you want to subclass and accept new argument structures to the
1836 L</populate> method.
1837
1838 =cut
1839
1840 sub _normalize_populate_args {
1841   my ($self, $data) = @_;
1842   my @names = @{shift(@$data)};
1843   my @results_to_create;
1844   foreach my $datum (@$data) {
1845     my %result_to_create;
1846     foreach my $index (0..$#names) {
1847       $result_to_create{$names[$index]} = $$datum[$index];
1848     }
1849     push @results_to_create, \%result_to_create;
1850   }
1851   return \@results_to_create;
1852 }
1853
1854 =head2 pager
1855
1856 =over 4
1857
1858 =item Arguments: none
1859
1860 =item Return Value: $pager
1861
1862 =back
1863
1864 Return Value a L<Data::Page> object for the current resultset. Only makes
1865 sense for queries with a C<page> attribute.
1866
1867 To get the full count of entries for a paged resultset, call
1868 C<total_entries> on the L<Data::Page> object.
1869
1870 =cut
1871
1872 sub pager {
1873   my ($self) = @_;
1874
1875   return $self->{pager} if $self->{pager};
1876
1877   my $attrs = $self->{attrs};
1878   $self->throw_exception("Can't create pager for non-paged rs")
1879     unless $self->{attrs}{page};
1880   $attrs->{rows} ||= 10;
1881
1882   # throw away the paging flags and re-run the count (possibly
1883   # with a subselect) to get the real total count
1884   my $count_attrs = { %$attrs };
1885   delete $count_attrs->{$_} for qw/rows offset page pager/;
1886   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1887
1888   return $self->{pager} = Data::Page->new(
1889     $total_count,
1890     $attrs->{rows},
1891     $self->{attrs}{page}
1892   );
1893 }
1894
1895 =head2 page
1896
1897 =over 4
1898
1899 =item Arguments: $page_number
1900
1901 =item Return Value: $rs
1902
1903 =back
1904
1905 Returns a resultset for the $page_number page of the resultset on which page
1906 is called, where each page contains a number of rows equal to the 'rows'
1907 attribute set on the resultset (10 by default).
1908
1909 =cut
1910
1911 sub page {
1912   my ($self, $page) = @_;
1913   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1914 }
1915
1916 =head2 new_result
1917
1918 =over 4
1919
1920 =item Arguments: \%vals
1921
1922 =item Return Value: $rowobject
1923
1924 =back
1925
1926 Creates a new row object in the resultset's result class and returns
1927 it. The row is not inserted into the database at this point, call
1928 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1929 will tell you whether the row object has been inserted or not.
1930
1931 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1932
1933 =cut
1934
1935 sub new_result {
1936   my ($self, $values) = @_;
1937   $self->throw_exception( "new_result needs a hash" )
1938     unless (ref $values eq 'HASH');
1939
1940   my %new;
1941   my $alias = $self->{attrs}{alias};
1942
1943   if (
1944     defined $self->{cond}
1945     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1946   ) {
1947     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1948     $new{-from_resultset} = [ keys %new ] if keys %new;
1949   } else {
1950     $self->throw_exception(
1951       "Can't abstract implicit construct, condition not a hash"
1952     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1953
1954     my $collapsed_cond = (
1955       $self->{cond}
1956         ? $self->_collapse_cond($self->{cond})
1957         : {}
1958     );
1959
1960     # precendence must be given to passed values over values inherited from
1961     # the cond, so the order here is important.
1962     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1963     while( my($col,$value) = each %implied ){
1964       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1965         $new{$col} = $value->{'='};
1966         next;
1967       }
1968       $new{$col} = $value if $self->_is_deterministic_value($value);
1969     }
1970   }
1971
1972   %new = (
1973     %new,
1974     %{ $self->_remove_alias($values, $alias) },
1975     -source_handle => $self->_source_handle,
1976     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1977   );
1978
1979   return $self->result_class->new(\%new);
1980 }
1981
1982 # _is_deterministic_value
1983 #
1984 # Make an effor to strip non-deterministic values from the condition,
1985 # to make sure new_result chokes less
1986
1987 sub _is_deterministic_value {
1988   my $self = shift;
1989   my $value = shift;
1990   my $ref_type = ref $value;
1991   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1992   return 1 if Scalar::Util::blessed($value);
1993   return 0;
1994 }
1995
1996 # _has_resolved_attr
1997 #
1998 # determines if the resultset defines at least one
1999 # of the attributes supplied
2000 #
2001 # used to determine if a subquery is neccessary
2002 #
2003 # supports some virtual attributes:
2004 #   -join
2005 #     This will scan for any joins being present on the resultset.
2006 #     It is not a mere key-search but a deep inspection of {from}
2007 #
2008
2009 sub _has_resolved_attr {
2010   my ($self, @attr_names) = @_;
2011
2012   my $attrs = $self->_resolved_attrs;
2013
2014   my %extra_checks;
2015
2016   for my $n (@attr_names) {
2017     if (grep { $n eq $_ } (qw/-join/) ) {
2018       $extra_checks{$n}++;
2019       next;
2020     }
2021
2022     my $attr =  $attrs->{$n};
2023
2024     next if not defined $attr;
2025
2026     if (ref $attr eq 'HASH') {
2027       return 1 if keys %$attr;
2028     }
2029     elsif (ref $attr eq 'ARRAY') {
2030       return 1 if @$attr;
2031     }
2032     else {
2033       return 1 if $attr;
2034     }
2035   }
2036
2037   # a resolved join is expressed as a multi-level from
2038   return 1 if (
2039     $extra_checks{-join}
2040       and
2041     ref $attrs->{from} eq 'ARRAY'
2042       and
2043     @{$attrs->{from}} > 1
2044   );
2045
2046   return 0;
2047 }
2048
2049 # _collapse_cond
2050 #
2051 # Recursively collapse the condition.
2052
2053 sub _collapse_cond {
2054   my ($self, $cond, $collapsed) = @_;
2055
2056   $collapsed ||= {};
2057
2058   if (ref $cond eq 'ARRAY') {
2059     foreach my $subcond (@$cond) {
2060       next unless ref $subcond;  # -or
2061       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2062     }
2063   }
2064   elsif (ref $cond eq 'HASH') {
2065     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2066       foreach my $subcond (@{$cond->{-and}}) {
2067         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2068       }
2069     }
2070     else {
2071       foreach my $col (keys %$cond) {
2072         my $value = $cond->{$col};
2073         $collapsed->{$col} = $value;
2074       }
2075     }
2076   }
2077
2078   return $collapsed;
2079 }
2080
2081 # _remove_alias
2082 #
2083 # Remove the specified alias from the specified query hash. A copy is made so
2084 # the original query is not modified.
2085
2086 sub _remove_alias {
2087   my ($self, $query, $alias) = @_;
2088
2089   my %orig = %{ $query || {} };
2090   my %unaliased;
2091
2092   foreach my $key (keys %orig) {
2093     if ($key !~ /\./) {
2094       $unaliased{$key} = $orig{$key};
2095       next;
2096     }
2097     $unaliased{$1} = $orig{$key}
2098       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2099   }
2100
2101   return \%unaliased;
2102 }
2103
2104 =head2 as_query (EXPERIMENTAL)
2105
2106 =over 4
2107
2108 =item Arguments: none
2109
2110 =item Return Value: \[ $sql, @bind ]
2111
2112 =back
2113
2114 Returns the SQL query and bind vars associated with the invocant.
2115
2116 This is generally used as the RHS for a subquery.
2117
2118 B<NOTE>: This feature is still experimental.
2119
2120 =cut
2121
2122 sub as_query {
2123   my $self = shift;
2124
2125   my $attrs = $self->_resolved_attrs_copy;
2126
2127   # For future use:
2128   #
2129   # in list ctx:
2130   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2131   # $sql also has no wrapping parenthesis in list ctx
2132   #
2133   my $sqlbind = $self->result_source->storage
2134     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2135
2136   return $sqlbind;
2137 }
2138
2139 =head2 find_or_new
2140
2141 =over 4
2142
2143 =item Arguments: \%vals, \%attrs?
2144
2145 =item Return Value: $rowobject
2146
2147 =back
2148
2149   my $artist = $schema->resultset('Artist')->find_or_new(
2150     { artist => 'fred' }, { key => 'artists' });
2151
2152   $cd->cd_to_producer->find_or_new({ producer => $producer },
2153                                    { key => 'primary });
2154
2155 Find an existing record from this resultset, based on its primary
2156 key, or a unique constraint. If none exists, instantiate a new result
2157 object and return it. The object will not be saved into your storage
2158 until you call L<DBIx::Class::Row/insert> on it.
2159
2160 You most likely want this method when looking for existing rows using
2161 a unique constraint that is not the primary key, or looking for
2162 related rows.
2163
2164 If you want objects to be saved immediately, use L</find_or_create>
2165 instead.
2166
2167 B<Note>: Take care when using C<find_or_new> with a table having
2168 columns with default values that you intend to be automatically
2169 supplied by the database (e.g. an auto_increment primary key column).
2170 In normal usage, the value of such columns should NOT be included at
2171 all in the call to C<find_or_new>, even when set to C<undef>.
2172
2173 =cut
2174
2175 sub find_or_new {
2176   my $self     = shift;
2177   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2178   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2179   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2180     return $row;
2181   }
2182   return $self->new_result($hash);
2183 }
2184
2185 =head2 create
2186
2187 =over 4
2188
2189 =item Arguments: \%vals
2190
2191 =item Return Value: a L<DBIx::Class::Row> $object
2192
2193 =back
2194
2195 Attempt to create a single new row or a row with multiple related rows
2196 in the table represented by the resultset (and related tables). This
2197 will not check for duplicate rows before inserting, use
2198 L</find_or_create> to do that.
2199
2200 To create one row for this resultset, pass a hashref of key/value
2201 pairs representing the columns of the table and the values you wish to
2202 store. If the appropriate relationships are set up, foreign key fields
2203 can also be passed an object representing the foreign row, and the
2204 value will be set to its primary key.
2205
2206 To create related objects, pass a hashref of related-object column values
2207 B<keyed on the relationship name>. If the relationship is of type C<multi>
2208 (L<DBIx::Class::Relationship/has_many>) - pass an arrayref of hashrefs.
2209 The process will correctly identify columns holding foreign keys, and will
2210 transparrently populate them from the keys of the corresponding relation.
2211 This can be applied recursively, and will work correctly for a structure
2212 with an arbitrary depth and width, as long as the relationships actually
2213 exists and the correct column data has been supplied.
2214
2215
2216 Instead of hashrefs of plain related data (key/value pairs), you may
2217 also pass new or inserted objects. New objects (not inserted yet, see
2218 L</new>), will be inserted into their appropriate tables.
2219
2220 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2221
2222 Example of creating a new row.
2223
2224   $person_rs->create({
2225     name=>"Some Person",
2226     email=>"somebody@someplace.com"
2227   });
2228
2229 Example of creating a new row and also creating rows in a related C<has_many>
2230 or C<has_one> resultset.  Note Arrayref.
2231
2232   $artist_rs->create(
2233      { artistid => 4, name => 'Manufactured Crap', cds => [
2234         { title => 'My First CD', year => 2006 },
2235         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2236       ],
2237      },
2238   );
2239
2240 Example of creating a new row and also creating a row in a related
2241 C<belongs_to>resultset. Note Hashref.
2242
2243   $cd_rs->create({
2244     title=>"Music for Silly Walks",
2245     year=>2000,
2246     artist => {
2247       name=>"Silly Musician",
2248     }
2249   });
2250
2251 =over
2252
2253 =item WARNING
2254
2255 When subclassing ResultSet never attempt to override this method. Since
2256 it is a simple shortcut for C<< $self->new_result($attrs)->insert >>, a
2257 lot of the internals simply never call it, so your override will be
2258 bypassed more often than not. Override either L<new|DBIx::Class::Row/new>
2259 or L<insert|DBIx::Class::Row/insert> depending on how early in the
2260 L</create> process you need to intervene.
2261
2262 =back
2263
2264 =cut
2265
2266 sub create {
2267   my ($self, $attrs) = @_;
2268   $self->throw_exception( "create needs a hashref" )
2269     unless ref $attrs eq 'HASH';
2270   return $self->new_result($attrs)->insert;
2271 }
2272
2273 =head2 find_or_create
2274
2275 =over 4
2276
2277 =item Arguments: \%vals, \%attrs?
2278
2279 =item Return Value: $rowobject
2280
2281 =back
2282
2283   $cd->cd_to_producer->find_or_create({ producer => $producer },
2284                                       { key => 'primary' });
2285
2286 Tries to find a record based on its primary key or unique constraints; if none
2287 is found, creates one and returns that instead.
2288
2289   my $cd = $schema->resultset('CD')->find_or_create({
2290     cdid   => 5,
2291     artist => 'Massive Attack',
2292     title  => 'Mezzanine',
2293     year   => 2005,
2294   });
2295
2296 Also takes an optional C<key> attribute, to search by a specific key or unique
2297 constraint. For example:
2298
2299   my $cd = $schema->resultset('CD')->find_or_create(
2300     {
2301       artist => 'Massive Attack',
2302       title  => 'Mezzanine',
2303     },
2304     { key => 'cd_artist_title' }
2305   );
2306
2307 B<Note>: Because find_or_create() reads from the database and then
2308 possibly inserts based on the result, this method is subject to a race
2309 condition. Another process could create a record in the table after
2310 the find has completed and before the create has started. To avoid
2311 this problem, use find_or_create() inside a transaction.
2312
2313 B<Note>: Take care when using C<find_or_create> with a table having
2314 columns with default values that you intend to be automatically
2315 supplied by the database (e.g. an auto_increment primary key column).
2316 In normal usage, the value of such columns should NOT be included at
2317 all in the call to C<find_or_create>, even when set to C<undef>.
2318
2319 See also L</find> and L</update_or_create>. For information on how to declare
2320 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2321
2322 =cut
2323
2324 sub find_or_create {
2325   my $self     = shift;
2326   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2327   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2328   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2329     return $row;
2330   }
2331   return $self->create($hash);
2332 }
2333
2334 =head2 update_or_create
2335
2336 =over 4
2337
2338 =item Arguments: \%col_values, { key => $unique_constraint }?
2339
2340 =item Return Value: $rowobject
2341
2342 =back
2343
2344   $resultset->update_or_create({ col => $val, ... });
2345
2346 First, searches for an existing row matching one of the unique constraints
2347 (including the primary key) on the source of this resultset. If a row is
2348 found, updates it with the other given column values. Otherwise, creates a new
2349 row.
2350
2351 Takes an optional C<key> attribute to search on a specific unique constraint.
2352 For example:
2353
2354   # In your application
2355   my $cd = $schema->resultset('CD')->update_or_create(
2356     {
2357       artist => 'Massive Attack',
2358       title  => 'Mezzanine',
2359       year   => 1998,
2360     },
2361     { key => 'cd_artist_title' }
2362   );
2363
2364   $cd->cd_to_producer->update_or_create({
2365     producer => $producer,
2366     name => 'harry',
2367   }, {
2368     key => 'primary,
2369   });
2370
2371
2372 If no C<key> is specified, it searches on all unique constraints defined on the
2373 source, including the primary key.
2374
2375 If the C<key> is specified as C<primary>, it searches only on the primary key.
2376
2377 See also L</find> and L</find_or_create>. For information on how to declare
2378 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2379
2380 B<Note>: Take care when using C<update_or_create> with a table having
2381 columns with default values that you intend to be automatically
2382 supplied by the database (e.g. an auto_increment primary key column).
2383 In normal usage, the value of such columns should NOT be included at
2384 all in the call to C<update_or_create>, even when set to C<undef>.
2385
2386 =cut
2387
2388 sub update_or_create {
2389   my $self = shift;
2390   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2391   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2392
2393   my $row = $self->find($cond, $attrs);
2394   if (defined $row) {
2395     $row->update($cond);
2396     return $row;
2397   }
2398
2399   return $self->create($cond);
2400 }
2401
2402 =head2 update_or_new
2403
2404 =over 4
2405
2406 =item Arguments: \%col_values, { key => $unique_constraint }?
2407
2408 =item Return Value: $rowobject
2409
2410 =back
2411
2412   $resultset->update_or_new({ col => $val, ... });
2413
2414 First, searches for an existing row matching one of the unique constraints
2415 (including the primary key) on the source of this resultset. If a row is
2416 found, updates it with the other given column values. Otherwise, instantiate
2417 a new result object and return it. The object will not be saved into your storage
2418 until you call L<DBIx::Class::Row/insert> on it.
2419
2420 Takes an optional C<key> attribute to search on a specific unique constraint.
2421 For example:
2422
2423   # In your application
2424   my $cd = $schema->resultset('CD')->update_or_new(
2425     {
2426       artist => 'Massive Attack',
2427       title  => 'Mezzanine',
2428       year   => 1998,
2429     },
2430     { key => 'cd_artist_title' }
2431   );
2432
2433   if ($cd->in_storage) {
2434       # the cd was updated
2435   }
2436   else {
2437       # the cd is not yet in the database, let's insert it
2438       $cd->insert;
2439   }
2440
2441 B<Note>: Take care when using C<update_or_new> with a table having
2442 columns with default values that you intend to be automatically
2443 supplied by the database (e.g. an auto_increment primary key column).
2444 In normal usage, the value of such columns should NOT be included at
2445 all in the call to C<update_or_new>, even when set to C<undef>.
2446
2447 See also L</find>, L</find_or_create> and L</find_or_new>.
2448
2449 =cut
2450
2451 sub update_or_new {
2452     my $self  = shift;
2453     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2454     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2455
2456     my $row = $self->find( $cond, $attrs );
2457     if ( defined $row ) {
2458         $row->update($cond);
2459         return $row;
2460     }
2461
2462     return $self->new_result($cond);
2463 }
2464
2465 =head2 get_cache
2466
2467 =over 4
2468
2469 =item Arguments: none
2470
2471 =item Return Value: \@cache_objects?
2472
2473 =back
2474
2475 Gets the contents of the cache for the resultset, if the cache is set.
2476
2477 The cache is populated either by using the L</prefetch> attribute to
2478 L</search> or by calling L</set_cache>.
2479
2480 =cut
2481
2482 sub get_cache {
2483   shift->{all_cache};
2484 }
2485
2486 =head2 set_cache
2487
2488 =over 4
2489
2490 =item Arguments: \@cache_objects
2491
2492 =item Return Value: \@cache_objects
2493
2494 =back
2495
2496 Sets the contents of the cache for the resultset. Expects an arrayref
2497 of objects of the same class as those produced by the resultset. Note that
2498 if the cache is set the resultset will return the cached objects rather
2499 than re-querying the database even if the cache attr is not set.
2500
2501 The contents of the cache can also be populated by using the
2502 L</prefetch> attribute to L</search>.
2503
2504 =cut
2505
2506 sub set_cache {
2507   my ( $self, $data ) = @_;
2508   $self->throw_exception("set_cache requires an arrayref")
2509       if defined($data) && (ref $data ne 'ARRAY');
2510   $self->{all_cache} = $data;
2511 }
2512
2513 =head2 clear_cache
2514
2515 =over 4
2516
2517 =item Arguments: none
2518
2519 =item Return Value: []
2520
2521 =back
2522
2523 Clears the cache for the resultset.
2524
2525 =cut
2526
2527 sub clear_cache {
2528   shift->set_cache(undef);
2529 }
2530
2531 =head2 related_resultset
2532
2533 =over 4
2534
2535 =item Arguments: $relationship_name
2536
2537 =item Return Value: $resultset
2538
2539 =back
2540
2541 Returns a related resultset for the supplied relationship name.
2542
2543   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2544
2545 =cut
2546
2547 sub related_resultset {
2548   my ($self, $rel) = @_;
2549
2550   $self->{related_resultsets} ||= {};
2551   return $self->{related_resultsets}{$rel} ||= do {
2552     my $rel_info = $self->result_source->relationship_info($rel);
2553
2554     $self->throw_exception(
2555       "search_related: result source '" . $self->result_source->source_name .
2556         "' has no such relationship $rel")
2557       unless $rel_info;
2558
2559     my ($from,$seen) = $self->_chain_relationship($rel);
2560
2561     my $join_count = $seen->{$rel};
2562     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2563
2564     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2565     my %attrs = %{$self->{attrs}||{}};
2566     delete @attrs{qw(result_class alias)};
2567
2568     my $new_cache;
2569
2570     if (my $cache = $self->get_cache) {
2571       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2572         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2573                         @$cache ];
2574       }
2575     }
2576
2577     my $rel_source = $self->result_source->related_source($rel);
2578
2579     my $new = do {
2580
2581       # The reason we do this now instead of passing the alias to the
2582       # search_rs below is that if you wrap/overload resultset on the
2583       # source you need to know what alias it's -going- to have for things
2584       # to work sanely (e.g. RestrictWithObject wants to be able to add
2585       # extra query restrictions, and these may need to be $alias.)
2586
2587       my $attrs = $rel_source->resultset_attributes;
2588       local $attrs->{alias} = $alias;
2589
2590       $rel_source->resultset
2591                  ->search_rs(
2592                      undef, {
2593                        %attrs,
2594                        join => undef,
2595                        prefetch => undef,
2596                        select => undef,
2597                        as => undef,
2598                        where => $self->{cond},
2599                        seen_join => $seen,
2600                        from => $from,
2601                    });
2602     };
2603     $new->set_cache($new_cache) if $new_cache;
2604     $new;
2605   };
2606 }
2607
2608 =head2 current_source_alias
2609
2610 =over 4
2611
2612 =item Arguments: none
2613
2614 =item Return Value: $source_alias
2615
2616 =back
2617
2618 Returns the current table alias for the result source this resultset is built
2619 on, that will be used in the SQL query. Usually it is C<me>.
2620
2621 Currently the source alias that refers to the result set returned by a
2622 L</search>/L</find> family method depends on how you got to the resultset: it's
2623 C<me> by default, but eg. L</search_related> aliases it to the related result
2624 source name (and keeps C<me> referring to the original result set). The long
2625 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2626 (and make this method unnecessary).
2627
2628 Thus it's currently necessary to use this method in predefined queries (see
2629 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2630 source alias of the current result set:
2631
2632   # in a result set class
2633   sub modified_by {
2634     my ($self, $user) = @_;
2635
2636     my $me = $self->current_source_alias;
2637
2638     return $self->search(
2639       "$me.modified" => $user->id,
2640     );
2641   }
2642
2643 =cut
2644
2645 sub current_source_alias {
2646   my ($self) = @_;
2647
2648   return ($self->{attrs} || {})->{alias} || 'me';
2649 }
2650
2651 # This code is called by search_related, and makes sure there
2652 # is clear separation between the joins before, during, and
2653 # after the relationship. This information is needed later
2654 # in order to properly resolve prefetch aliases (any alias
2655 # with a relation_chain_depth less than the depth of the
2656 # current prefetch is not considered)
2657 #
2658 # The increments happen in 1/2s to make it easier to correlate the
2659 # join depth with the join path. An integer means a relationship
2660 # specified via a search_related, whereas a fraction means an added
2661 # join/prefetch via attributes
2662 sub _chain_relationship {
2663   my ($self, $rel) = @_;
2664   my $source = $self->result_source;
2665   my $attrs = $self->{attrs};
2666
2667   my $from = [ @{
2668       $attrs->{from}
2669         ||
2670       [{
2671         -source_handle => $source->handle,
2672         -alias => $attrs->{alias},
2673         $attrs->{alias} => $source->from,
2674       }]
2675   }];
2676
2677   my $seen = { %{$attrs->{seen_join} || {} } };
2678   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2679     ? $from->[-1][0]{-join_path}
2680     : [];
2681
2682
2683   # we need to take the prefetch the attrs into account before we
2684   # ->_resolve_join as otherwise they get lost - captainL
2685   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2686
2687   my @requested_joins = $source->_resolve_join(
2688     $merged,
2689     $attrs->{alias},
2690     $seen,
2691     $jpath,
2692   );
2693
2694   push @$from, @requested_joins;
2695
2696   $seen->{-relation_chain_depth} += 0.5;
2697
2698   # if $self already had a join/prefetch specified on it, the requested
2699   # $rel might very well be already included. What we do in this case
2700   # is effectively a no-op (except that we bump up the chain_depth on
2701   # the join in question so we could tell it *is* the search_related)
2702   my $already_joined;
2703
2704
2705   # we consider the last one thus reverse
2706   for my $j (reverse @requested_joins) {
2707     if ($rel eq $j->[0]{-join_path}[-1]) {
2708       $j->[0]{-relation_chain_depth} += 0.5;
2709       $already_joined++;
2710       last;
2711     }
2712   }
2713
2714 # alternative way to scan the entire chain - not backwards compatible
2715 #  for my $j (reverse @$from) {
2716 #    next unless ref $j eq 'ARRAY';
2717 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2718 #      $j->[0]{-relation_chain_depth} += 0.5;
2719 #      $already_joined++;
2720 #      last;
2721 #    }
2722 #  }
2723
2724   unless ($already_joined) {
2725     push @$from, $source->_resolve_join(
2726       $rel,
2727       $attrs->{alias},
2728       $seen,
2729       $jpath,
2730     );
2731   }
2732
2733   $seen->{-relation_chain_depth} += 0.5;
2734
2735   return ($from,$seen);
2736 }
2737
2738 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2739 sub _resolved_attrs_copy {
2740   my $self = shift;
2741   return { %{$self->_resolved_attrs (@_)} };
2742 }
2743
2744 sub _resolved_attrs {
2745   my $self = shift;
2746   return $self->{_attrs} if $self->{_attrs};
2747
2748   my $attrs  = { %{ $self->{attrs} || {} } };
2749   my $source = $self->result_source;
2750   my $alias  = $attrs->{alias};
2751
2752   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2753   my @colbits;
2754
2755   # build columns (as long as select isn't set) into a set of as/select hashes
2756   unless ( $attrs->{select} ) {
2757
2758     my @cols = ( ref($attrs->{columns}) eq 'ARRAY' )
2759       ? @{ delete $attrs->{columns}}
2760       : (
2761           ( delete $attrs->{columns} )
2762             ||
2763           $source->columns
2764         )
2765     ;
2766
2767     @colbits = map {
2768       ( ref($_) eq 'HASH' )
2769       ? $_
2770       : {
2771           (
2772             /^\Q${alias}.\E(.+)$/
2773               ? "$1"
2774               : "$_"
2775           )
2776             =>
2777           (
2778             /\./
2779               ? "$_"
2780               : "${alias}.$_"
2781           )
2782         }
2783     } @cols;
2784   }
2785
2786   # add the additional columns on
2787   foreach ( 'include_columns', '+columns' ) {
2788       push @colbits, map {
2789           ( ref($_) eq 'HASH' )
2790             ? $_
2791             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2792       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2793   }
2794
2795   # start with initial select items
2796   if ( $attrs->{select} ) {
2797     $attrs->{select} =
2798         ( ref $attrs->{select} eq 'ARRAY' )
2799       ? [ @{ $attrs->{select} } ]
2800       : [ $attrs->{select} ];
2801     $attrs->{as} = (
2802       $attrs->{as}
2803       ? (
2804         ref $attrs->{as} eq 'ARRAY'
2805         ? [ @{ $attrs->{as} } ]
2806         : [ $attrs->{as} ]
2807         )
2808       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2809     );
2810   }
2811   else {
2812
2813     # otherwise we intialise select & as to empty
2814     $attrs->{select} = [];
2815     $attrs->{as}     = [];
2816   }
2817
2818   # now add colbits to select/as
2819   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2820   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2821
2822   my $adds;
2823   if ( $adds = delete $attrs->{'+select'} ) {
2824     $adds = [$adds] unless ref $adds eq 'ARRAY';
2825     push(
2826       @{ $attrs->{select} },
2827       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2828     );
2829   }
2830   if ( $adds = delete $attrs->{'+as'} ) {
2831     $adds = [$adds] unless ref $adds eq 'ARRAY';
2832     push( @{ $attrs->{as} }, @$adds );
2833   }
2834
2835   $attrs->{from} ||= [ {
2836     -source_handle => $source->handle,
2837     -alias => $self->{attrs}{alias},
2838     $self->{attrs}{alias} => $source->from,
2839   } ];
2840
2841   if ( $attrs->{join} || $attrs->{prefetch} ) {
2842
2843     $self->throw_exception ('join/prefetch can not be used with a custom {from}')
2844       if ref $attrs->{from} ne 'ARRAY';
2845
2846     my $join = delete $attrs->{join} || {};
2847
2848     if ( defined $attrs->{prefetch} ) {
2849       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2850     }
2851
2852     $attrs->{from} =    # have to copy here to avoid corrupting the original
2853       [
2854         @{ $attrs->{from} },
2855         $source->_resolve_join(
2856           $join,
2857           $alias,
2858           { %{ $attrs->{seen_join} || {} } },
2859           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2860             ? $attrs->{from}[-1][0]{-join_path}
2861             : []
2862           ,
2863         )
2864       ];
2865   }
2866
2867   if ( defined $attrs->{order_by} ) {
2868     $attrs->{order_by} = (
2869       ref( $attrs->{order_by} ) eq 'ARRAY'
2870       ? [ @{ $attrs->{order_by} } ]
2871       : [ $attrs->{order_by} || () ]
2872     );
2873   }
2874
2875   if ($attrs->{group_by} and ref $attrs->{group_by} ne 'ARRAY') {
2876     $attrs->{group_by} = [ $attrs->{group_by} ];
2877   }
2878
2879   # generate the distinct induced group_by early, as prefetch will be carried via a
2880   # subquery (since a group_by is present)
2881   if (delete $attrs->{distinct}) {
2882     if ($attrs->{group_by}) {
2883       carp ("Useless use of distinct on a grouped resultset ('distinct' is ignored when a 'group_by' is present)");
2884     }
2885     else {
2886       $attrs->{group_by} = [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2887     }
2888   }
2889
2890   $attrs->{collapse} ||= {};
2891   if ( my $prefetch = delete $attrs->{prefetch} ) {
2892     $prefetch = $self->_merge_attr( {}, $prefetch );
2893
2894     my $prefetch_ordering = [];
2895
2896     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2897
2898     my @prefetch =
2899       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2900
2901     # we need to somehow mark which columns came from prefetch
2902     $attrs->{_prefetch_select} = [ map { $_->[0] } @prefetch ];
2903
2904     push @{ $attrs->{select} }, @{$attrs->{_prefetch_select}};
2905     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2906
2907     push( @{$attrs->{order_by}}, @$prefetch_ordering );
2908     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2909   }
2910
2911   # if both page and offset are specified, produce a combined offset
2912   # even though it doesn't make much sense, this is what pre 081xx has
2913   # been doing
2914   if (my $page = delete $attrs->{page}) {
2915     $attrs->{offset} =
2916       ($attrs->{rows} * ($page - 1))
2917             +
2918       ($attrs->{offset} || 0)
2919     ;
2920   }
2921
2922   return $self->{_attrs} = $attrs;
2923 }
2924
2925 sub _joinpath_aliases {
2926   my ($self, $fromspec, $seen) = @_;
2927
2928   my $paths = {};
2929   return $paths unless ref $fromspec eq 'ARRAY';
2930
2931   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2932
2933   if (int ($cur_depth) != $cur_depth) {
2934     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2935   }
2936
2937   for my $j (@$fromspec) {
2938
2939     next if ref $j ne 'ARRAY';
2940     next if ($j->[0]{-relation_chain_depth} || 0) < $cur_depth;
2941
2942     my $jpath = $j->[0]{-join_path};
2943
2944     my $p = $paths;
2945     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2946     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2947   }
2948
2949   return $paths;
2950 }
2951
2952 sub _rollout_attr {
2953   my ($self, $attr) = @_;
2954
2955   if (ref $attr eq 'HASH') {
2956     return $self->_rollout_hash($attr);
2957   } elsif (ref $attr eq 'ARRAY') {
2958     return $self->_rollout_array($attr);
2959   } else {
2960     return [$attr];
2961   }
2962 }
2963
2964 sub _rollout_array {
2965   my ($self, $attr) = @_;
2966
2967   my @rolled_array;
2968   foreach my $element (@{$attr}) {
2969     if (ref $element eq 'HASH') {
2970       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2971     } elsif (ref $element eq 'ARRAY') {
2972       #  XXX - should probably recurse here
2973       push( @rolled_array, @{$self->_rollout_array($element)} );
2974     } else {
2975       push( @rolled_array, $element );
2976     }
2977   }
2978   return \@rolled_array;
2979 }
2980
2981 sub _rollout_hash {
2982   my ($self, $attr) = @_;
2983
2984   my @rolled_array;
2985   foreach my $key (keys %{$attr}) {
2986     push( @rolled_array, { $key => $attr->{$key} } );
2987   }
2988   return \@rolled_array;
2989 }
2990
2991 sub _calculate_score {
2992   my ($self, $a, $b) = @_;
2993
2994   if (defined $a xor defined $b) {
2995     return 0;
2996   }
2997   elsif (not defined $a) {
2998     return 1;
2999   }
3000
3001   if (ref $b eq 'HASH') {
3002     my ($b_key) = keys %{$b};
3003     if (ref $a eq 'HASH') {
3004       my ($a_key) = keys %{$a};
3005       if ($a_key eq $b_key) {
3006         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
3007       } else {
3008         return 0;
3009       }
3010     } else {
3011       return ($a eq $b_key) ? 1 : 0;
3012     }
3013   } else {
3014     if (ref $a eq 'HASH') {
3015       my ($a_key) = keys %{$a};
3016       return ($b eq $a_key) ? 1 : 0;
3017     } else {
3018       return ($b eq $a) ? 1 : 0;
3019     }
3020   }
3021 }
3022
3023 sub _merge_attr {
3024   my ($self, $orig, $import) = @_;
3025
3026   return $import unless defined($orig);
3027   return $orig unless defined($import);
3028
3029   $orig = $self->_rollout_attr($orig);
3030   $import = $self->_rollout_attr($import);
3031
3032   my $seen_keys;
3033   foreach my $import_element ( @{$import} ) {
3034     # find best candidate from $orig to merge $b_element into
3035     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3036     foreach my $orig_element ( @{$orig} ) {
3037       my $score = $self->_calculate_score( $orig_element, $import_element );
3038       if ($score > $best_candidate->{score}) {
3039         $best_candidate->{position} = $position;
3040         $best_candidate->{score} = $score;
3041       }
3042       $position++;
3043     }
3044     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3045
3046     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3047       push( @{$orig}, $import_element );
3048     } else {
3049       my $orig_best = $orig->[$best_candidate->{position}];
3050       # merge orig_best and b_element together and replace original with merged
3051       if (ref $orig_best ne 'HASH') {
3052         $orig->[$best_candidate->{position}] = $import_element;
3053       } elsif (ref $import_element eq 'HASH') {
3054         my ($key) = keys %{$orig_best};
3055         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3056       }
3057     }
3058     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3059   }
3060
3061   return $orig;
3062 }
3063
3064 sub result_source {
3065     my $self = shift;
3066
3067     if (@_) {
3068         $self->_source_handle($_[0]->handle);
3069     } else {
3070         $self->_source_handle->resolve;
3071     }
3072 }
3073
3074 =head2 throw_exception
3075
3076 See L<DBIx::Class::Schema/throw_exception> for details.
3077
3078 =cut
3079
3080 sub throw_exception {
3081   my $self=shift;
3082
3083   if (ref $self && $self->_source_handle->schema) {
3084     $self->_source_handle->schema->throw_exception(@_)
3085   }
3086   else {
3087     DBIx::Class::Exception->throw(@_);
3088   }
3089 }
3090
3091 # XXX: FIXME: Attributes docs need clearing up
3092
3093 =head1 ATTRIBUTES
3094
3095 Attributes are used to refine a ResultSet in various ways when
3096 searching for data. They can be passed to any method which takes an
3097 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3098 L</count>.
3099
3100 These are in no particular order:
3101
3102 =head2 order_by
3103
3104 =over 4
3105
3106 =item Value: ( $order_by | \@order_by | \%order_by )
3107
3108 =back
3109
3110 Which column(s) to order the results by.
3111
3112 [The full list of suitable values is documented in
3113 L<SQL::Abstract/"ORDER BY CLAUSES">; the following is a summary of
3114 common options.]
3115
3116 If a single column name, or an arrayref of names is supplied, the
3117 argument is passed through directly to SQL. The hashref syntax allows
3118 for connection-agnostic specification of ordering direction:
3119
3120  For descending order:
3121
3122   order_by => { -desc => [qw/col1 col2 col3/] }
3123
3124  For explicit ascending order:
3125
3126   order_by => { -asc => 'col' }
3127
3128 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3129 supported, although you are strongly encouraged to use the hashref
3130 syntax as outlined above.
3131
3132 =head2 columns
3133
3134 =over 4
3135
3136 =item Value: \@columns
3137
3138 =back
3139
3140 Shortcut to request a particular set of columns to be retrieved. Each
3141 column spec may be a string (a table column name), or a hash (in which
3142 case the key is the C<as> value, and the value is used as the C<select>
3143 expression). Adds C<me.> onto the start of any column without a C<.> in
3144 it and sets C<select> from that, then auto-populates C<as> from
3145 C<select> as normal. (You may also use the C<cols> attribute, as in
3146 earlier versions of DBIC.)
3147
3148 =head2 +columns
3149
3150 =over 4
3151
3152 =item Value: \@columns
3153
3154 =back
3155
3156 Indicates additional columns to be selected from storage. Works the same
3157 as L</columns> but adds columns to the selection. (You may also use the
3158 C<include_columns> attribute, as in earlier versions of DBIC). For
3159 example:-
3160
3161   $schema->resultset('CD')->search(undef, {
3162     '+columns' => ['artist.name'],
3163     join => ['artist']
3164   });
3165
3166 would return all CDs and include a 'name' column to the information
3167 passed to object inflation. Note that the 'artist' is the name of the
3168 column (or relationship) accessor, and 'name' is the name of the column
3169 accessor in the related table.
3170
3171 =head2 include_columns
3172
3173 =over 4
3174
3175 =item Value: \@columns
3176
3177 =back
3178
3179 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3180
3181 =head2 select
3182
3183 =over 4
3184
3185 =item Value: \@select_columns
3186
3187 =back
3188
3189 Indicates which columns should be selected from the storage. You can use
3190 column names, or in the case of RDBMS back ends, function or stored procedure
3191 names:
3192
3193   $rs = $schema->resultset('Employee')->search(undef, {
3194     select => [
3195       'name',
3196       { count => 'employeeid' },
3197       { sum => 'salary' }
3198     ]
3199   });
3200
3201 When you use function/stored procedure names and do not supply an C<as>
3202 attribute, the column names returned are storage-dependent. E.g. MySQL would
3203 return a column named C<count(employeeid)> in the above example.
3204
3205 =head2 +select
3206
3207 =over 4
3208
3209 Indicates additional columns to be selected from storage.  Works the same as
3210 L</select> but adds columns to the selection.
3211
3212 =back
3213
3214 =head2 +as
3215
3216 =over 4
3217
3218 Indicates additional column names for those added via L</+select>. See L</as>.
3219
3220 =back
3221
3222 =head2 as
3223
3224 =over 4
3225
3226 =item Value: \@inflation_names
3227
3228 =back
3229
3230 Indicates column names for object inflation. That is, C<as>
3231 indicates the name that the column can be accessed as via the
3232 C<get_column> method (or via the object accessor, B<if one already
3233 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3234
3235 The C<as> attribute is used in conjunction with C<select>,
3236 usually when C<select> contains one or more function or stored
3237 procedure names:
3238
3239   $rs = $schema->resultset('Employee')->search(undef, {
3240     select => [
3241       'name',
3242       { count => 'employeeid' }
3243     ],
3244     as => ['name', 'employee_count'],
3245   });
3246
3247   my $employee = $rs->first(); # get the first Employee
3248
3249 If the object against which the search is performed already has an accessor
3250 matching a column name specified in C<as>, the value can be retrieved using
3251 the accessor as normal:
3252
3253   my $name = $employee->name();
3254
3255 If on the other hand an accessor does not exist in the object, you need to
3256 use C<get_column> instead:
3257
3258   my $employee_count = $employee->get_column('employee_count');
3259
3260 You can create your own accessors if required - see
3261 L<DBIx::Class::Manual::Cookbook> for details.
3262
3263 Please note: This will NOT insert an C<AS employee_count> into the SQL
3264 statement produced, it is used for internal access only. Thus
3265 attempting to use the accessor in an C<order_by> clause or similar
3266 will fail miserably.
3267
3268 To get around this limitation, you can supply literal SQL to your
3269 C<select> attibute that contains the C<AS alias> text, eg:
3270
3271   select => [\'myfield AS alias']
3272
3273 =head2 join
3274
3275 =over 4
3276
3277 =item Value: ($rel_name | \@rel_names | \%rel_names)
3278
3279 =back
3280
3281 Contains a list of relationships that should be joined for this query.  For
3282 example:
3283
3284   # Get CDs by Nine Inch Nails
3285   my $rs = $schema->resultset('CD')->search(
3286     { 'artist.name' => 'Nine Inch Nails' },
3287     { join => 'artist' }
3288   );
3289
3290 Can also contain a hash reference to refer to the other relation's relations.
3291 For example:
3292
3293   package MyApp::Schema::Track;
3294   use base qw/DBIx::Class/;
3295   __PACKAGE__->table('track');
3296   __PACKAGE__->add_columns(qw/trackid cd position title/);
3297   __PACKAGE__->set_primary_key('trackid');
3298   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3299   1;
3300
3301   # In your application
3302   my $rs = $schema->resultset('Artist')->search(
3303     { 'track.title' => 'Teardrop' },
3304     {
3305       join     => { cd => 'track' },
3306       order_by => 'artist.name',
3307     }
3308   );
3309
3310 You need to use the relationship (not the table) name in  conditions,
3311 because they are aliased as such. The current table is aliased as "me", so
3312 you need to use me.column_name in order to avoid ambiguity. For example:
3313
3314   # Get CDs from 1984 with a 'Foo' track
3315   my $rs = $schema->resultset('CD')->search(
3316     {
3317       'me.year' => 1984,
3318       'tracks.name' => 'Foo'
3319     },
3320     { join => 'tracks' }
3321   );
3322
3323 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3324 similarly for a third time). For e.g.
3325
3326   my $rs = $schema->resultset('Artist')->search({
3327     'cds.title'   => 'Down to Earth',
3328     'cds_2.title' => 'Popular',
3329   }, {
3330     join => [ qw/cds cds/ ],
3331   });
3332
3333 will return a set of all artists that have both a cd with title 'Down
3334 to Earth' and a cd with title 'Popular'.
3335
3336 If you want to fetch related objects from other tables as well, see C<prefetch>
3337 below.
3338
3339 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3340
3341 =head2 prefetch
3342
3343 =over 4
3344
3345 =item Value: ($rel_name | \@rel_names | \%rel_names)
3346
3347 =back
3348
3349 Contains one or more relationships that should be fetched along with
3350 the main query (when they are accessed afterwards the data will
3351 already be available, without extra queries to the database).  This is
3352 useful for when you know you will need the related objects, because it
3353 saves at least one query:
3354
3355   my $rs = $schema->resultset('Tag')->search(
3356     undef,
3357     {
3358       prefetch => {
3359         cd => 'artist'
3360       }
3361     }
3362   );
3363
3364 The initial search results in SQL like the following:
3365
3366   SELECT tag.*, cd.*, artist.* FROM tag
3367   JOIN cd ON tag.cd = cd.cdid
3368   JOIN artist ON cd.artist = artist.artistid
3369
3370 L<DBIx::Class> has no need to go back to the database when we access the
3371 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3372 case.
3373
3374 Simple prefetches will be joined automatically, so there is no need
3375 for a C<join> attribute in the above search.
3376
3377 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3378 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3379 with an accessor type of 'single' or 'filter'). A more complex example that
3380 prefetches an artists cds, the tracks on those cds, and the tags associted
3381 with that artist is given below (assuming many-to-many from artists to tags):
3382
3383  my $rs = $schema->resultset('Artist')->search(
3384    undef,
3385    {
3386      prefetch => [
3387        { cds => 'tracks' },
3388        { artist_tags => 'tags' }
3389      ]
3390    }
3391  );
3392
3393
3394 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3395 attributes will be ignored.
3396
3397 B<CAVEATs>: Prefetch does a lot of deep magic. As such, it may not behave
3398 exactly as you might expect.
3399
3400 =over 4
3401
3402 =item *
3403
3404 Prefetch uses the L</cache> to populate the prefetched relationships. This
3405 may or may not be what you want.
3406
3407 =item *
3408
3409 If you specify a condition on a prefetched relationship, ONLY those
3410 rows that match the prefetched condition will be fetched into that relationship.
3411 This means that adding prefetch to a search() B<may alter> what is returned by
3412 traversing a relationship. So, if you have C<< Artist->has_many(CDs) >> and you do
3413
3414   my $artist_rs = $schema->resultset('Artist')->search({
3415       'cds.year' => 2008,
3416   }, {
3417       join => 'cds',
3418   });
3419
3420   my $count = $artist_rs->first->cds->count;
3421
3422   my $artist_rs_prefetch = $artist_rs->search( {}, { prefetch => 'cds' } );
3423
3424   my $prefetch_count = $artist_rs_prefetch->first->cds->count;
3425
3426   cmp_ok( $count, '==', $prefetch_count, "Counts should be the same" );
3427
3428 that cmp_ok() may or may not pass depending on the datasets involved. This
3429 behavior may or may not survive the 0.09 transition.
3430
3431 =back
3432
3433 =head2 page
3434
3435 =over 4
3436
3437 =item Value: $page
3438
3439 =back
3440
3441 Makes the resultset paged and specifies the page to retrieve. Effectively
3442 identical to creating a non-pages resultset and then calling ->page($page)
3443 on it.
3444
3445 If L<rows> attribute is not specified it defaults to 10 rows per page.
3446
3447 When you have a paged resultset, L</count> will only return the number
3448 of rows in the page. To get the total, use the L</pager> and call
3449 C<total_entries> on it.
3450
3451 =head2 rows
3452
3453 =over 4
3454
3455 =item Value: $rows
3456
3457 =back
3458
3459 Specifes the maximum number of rows for direct retrieval or the number of
3460 rows per page if the page attribute or method is used.
3461
3462 =head2 offset
3463
3464 =over 4
3465
3466 =item Value: $offset
3467
3468 =back
3469
3470 Specifies the (zero-based) row number for the  first row to be returned, or the
3471 of the first row of the first page if paging is used.
3472
3473 =head2 group_by
3474
3475 =over 4
3476
3477 =item Value: \@columns
3478
3479 =back
3480
3481 A arrayref of columns to group by. Can include columns of joined tables.
3482
3483   group_by => [qw/ column1 column2 ... /]
3484
3485 =head2 having
3486
3487 =over 4
3488
3489 =item Value: $condition
3490
3491 =back
3492
3493 HAVING is a select statement attribute that is applied between GROUP BY and
3494 ORDER BY. It is applied to the after the grouping calculations have been
3495 done.
3496
3497   having => { 'count(employee)' => { '>=', 100 } }
3498
3499 =head2 distinct
3500
3501 =over 4
3502
3503 =item Value: (0 | 1)
3504
3505 =back
3506
3507 Set to 1 to group by all columns. If the resultset already has a group_by
3508 attribute, this setting is ignored and an appropriate warning is issued.
3509
3510 =head2 where
3511
3512 =over 4
3513
3514 Adds to the WHERE clause.
3515
3516   # only return rows WHERE deleted IS NULL for all searches
3517   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3518
3519 Can be overridden by passing C<{ where => undef }> as an attribute
3520 to a resulset.
3521
3522 =back
3523
3524 =head2 cache
3525
3526 Set to 1 to cache search results. This prevents extra SQL queries if you
3527 revisit rows in your ResultSet:
3528
3529   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3530
3531   while( my $artist = $resultset->next ) {
3532     ... do stuff ...
3533   }
3534
3535   $rs->first; # without cache, this would issue a query
3536
3537 By default, searches are not cached.
3538
3539 For more examples of using these attributes, see
3540 L<DBIx::Class::Manual::Cookbook>.
3541
3542 =head2 for
3543
3544 =over 4
3545
3546 =item Value: ( 'update' | 'shared' )
3547
3548 =back
3549
3550 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3551 ... FOR SHARED.
3552
3553 =cut
3554
3555 1;