lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet also incorporates an implicit iterator. L</next> and L</reset>
  50 can be used to walk through all the L<DBIx::Class::Row>s the ResultSet
  51 represents.
  52
  53 The query that the ResultSet represents is B<only> executed against
  54 the database when these methods are called:
  55 L</find> L</next> L</all> L</first> L</single> L</count>
  56
  57 =head1 EXAMPLES
  58
  59 =head2 Chaining resultsets
  60
  61 Let's say you've got a query that needs to be run to return some data
  62 to the user. But, you have an authorization system in place that
  63 prevents certain users from seeing certain information. So, you want
  64 to construct the basic query in one method, but add constraints to it in
  65 another.
  66
  67   sub get_data {
  68     my $self = shift;
  69     my $request = $self->get_request; # Get a request object somehow.
  70     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  71
  72     my $cd_rs = $schema->resultset('CD')->search({
  73       title => $request->param('title'),
  74       year => $request->param('year'),
  75     });
  76
  77     $self->apply_security_policy( $cd_rs );
  78
  79     return $cd_rs->all();
  80   }
  81
  82   sub apply_security_policy {
  83     my $self = shift;
  84     my ($rs) = @_;
  85
  86     return $rs->search({
  87       subversive => 0,
  88     });
  89   }
  90
  91 =head3 Resolving conditions and attributes
  92
  93 When a resultset is chained from another resultset, conditions and
  94 attributes with the same keys need resolving.
  95
  96 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
  97 into the existing ones from the original resultset.
  98
  99 The L</where>, L</having> attribute, and any search conditions are
 100 merged with an SQL C<AND> to the existing condition from the original
 101 resultset.
 102
 103 All other attributes are overridden by any new ones supplied in the
 104 search attributes.
 105
 106 =head2 Multiple queries
 107
 108 Since a resultset just defines a query, you can do all sorts of
 109 things with it with the same object.
 110
 111   # Don't hit the DB yet.
 112   my $cd_rs = $schema->resultset('CD')->search({
 113     title => 'something',
 114     year => 2009,
 115   });
 116
 117   # Each of these hits the DB individually.
 118   my $count = $cd_rs->count;
 119   my $most_recent = $cd_rs->get_column('date_released')->max();
 120   my @records = $cd_rs->all;
 121
 122 And it's not just limited to SELECT statements.
 123
 124   $cd_rs->delete();
 125
 126 This is even cooler:
 127
 128   $cd_rs->create({ artist => 'Fred' });
 129
 130 Which is the same as:
 131
 132   $schema->resultset('CD')->create({
 133     title => 'something',
 134     year => 2009,
 135     artist => 'Fred'
 136   });
 137
 138 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 139
 140 =head1 OVERLOADING
 141
 142 If a resultset is used in a numeric context it returns the L</count>.
 143 However, if it is used in a booleand context it is always true.  So if
 144 you want to check if a resultset has any results use C<if $rs != 0>.
 145 C<if $rs> will always be true.
 146
 147 =head1 METHODS
 148
 149 =head2 new
 150
 151 =over 4
 152
 153 =item Arguments: $source, \%$attrs
 154
 155 =item Return Value: $rs
 156
 157 =back
 158
 159 The resultset constructor. Takes a source object (usually a
 160 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 161 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 162 executed as needed by the other methods.
 163
 164 Generally you won't need to construct a resultset manually.  You'll
 165 automatically get one from e.g. a L</search> called in scalar context:
 166
 167   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 168
 169 IMPORTANT: If called on an object, proxies to new_result instead so
 170
 171   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 172
 173 will return a CD object, not a ResultSet.
 174
 175 =cut
 176
 177 sub new {
 178   my $class = shift;
 179   return $class->new_result(@_) if ref $class;
 180
 181   my ($source, $attrs) = @_;
 182   $source = $source->handle
 183     unless $source->isa('DBIx::Class::ResultSourceHandle');
 184   $attrs = { %{$attrs||{}} };
 185
 186   if ($attrs->{page}) {
 187     $attrs->{rows} ||= 10;
 188   }
 189
 190   $attrs->{alias} ||= 'me';
 191
 192   # Creation of {} and bless separated to mitigate RH perl bug
 193   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 194   my $self = {
 195     _source_handle => $source,
 196     cond => $attrs->{where},
 197     count => undef,
 198     pager => undef,
 199     attrs => $attrs
 200   };
 201
 202   bless $self, $class;
 203
 204   $self->result_class(
 205     $attrs->{result_class} || $source->resolve->result_class
 206   );
 207
 208   return $self;
 209 }
 210
 211 =head2 search
 212
 213 =over 4
 214
 215 =item Arguments: $cond, \%attrs?
 216
 217 =item Return Value: $resultset (scalar context), @row_objs (list context)
 218
 219 =back
 220
 221   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 222   my $new_rs = $cd_rs->search({ year => 2005 });
 223
 224   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 225                  # year = 2005 OR year = 2004
 226
 227 If you need to pass in additional attributes but no additional condition,
 228 call it as C<search(undef, \%attrs)>.
 229
 230   # "SELECT name, artistid FROM $artist_table"
 231   my @all_artists = $schema->resultset('Artist')->search(undef, {
 232     columns => [qw/name artistid/],
 233   });
 234
 235 For a list of attributes that can be passed to C<search>, see
 236 L</ATTRIBUTES>. For more examples of using this function, see
 237 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 238 documentation for the first argument, see L<SQL::Abstract>.
 239
 240 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 241
 242 =cut
 243
 244 sub search {
 245   my $self = shift;
 246   my $rs = $self->search_rs( @_ );
 247   return (wantarray ? $rs->all : $rs);
 248 }
 249
 250 =head2 search_rs
 251
 252 =over 4
 253
 254 =item Arguments: $cond, \%attrs?
 255
 256 =item Return Value: $resultset
 257
 258 =back
 259
 260 This method does the same exact thing as search() except it will
 261 always return a resultset, even in list context.
 262
 263 =cut
 264
 265 sub search_rs {
 266   my $self = shift;
 267
 268   # Special-case handling for (undef, undef).
 269   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 270     pop(@_); pop(@_);
 271   }
 272
 273   my $attrs = {};
 274   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 275   my $our_attrs = { %{$self->{attrs}} };
 276   my $having = delete $our_attrs->{having};
 277   my $where = delete $our_attrs->{where};
 278
 279   my $rows;
 280
 281   my %safe = (alias => 1, cache => 1);
 282
 283   unless (
 284     (@_ && defined($_[0])) # @_ == () or (undef)
 285     ||
 286     (keys %$attrs # empty attrs or only 'safe' attrs
 287     && List::Util::first { !$safe{$_} } keys %$attrs)
 288   ) {
 289     # no search, effectively just a clone
 290     $rows = $self->get_cache;
 291   }
 292
 293   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 294
 295   # merge new attrs into inherited
 296   foreach my $key (qw/join prefetch +select +as bind/) {
 297     next unless exists $attrs->{$key};
 298     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 299   }
 300
 301   my $cond = (@_
 302     ? (
 303         (@_ == 1 || ref $_[0] eq "HASH")
 304           ? (
 305               (ref $_[0] eq 'HASH')
 306                 ? (
 307                     (keys %{ $_[0] }  > 0)
 308                       ? shift
 309                       : undef
 310                    )
 311                 :  shift
 312              )
 313           : (
 314               (@_ % 2)
 315                 ? $self->throw_exception("Odd number of arguments to search")
 316                 : {@_}
 317              )
 318       )
 319     : undef
 320   );
 321
 322   if (defined $where) {
 323     $new_attrs->{where} = (
 324       defined $new_attrs->{where}
 325         ? { '-and' => [
 326               map {
 327                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 328               } $where, $new_attrs->{where}
 329             ]
 330           }
 331         : $where);
 332   }
 333
 334   if (defined $cond) {
 335     $new_attrs->{where} = (
 336       defined $new_attrs->{where}
 337         ? { '-and' => [
 338               map {
 339                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 340               } $cond, $new_attrs->{where}
 341             ]
 342           }
 343         : $cond);
 344   }
 345
 346   if (defined $having) {
 347     $new_attrs->{having} = (
 348       defined $new_attrs->{having}
 349         ? { '-and' => [
 350               map {
 351                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 352               } $having, $new_attrs->{having}
 353             ]
 354           }
 355         : $having);
 356   }
 357
 358   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 359   if ($rows) {
 360     $rs->set_cache($rows);
 361   }
 362   return $rs;
 363 }
 364
 365 =head2 search_literal
 366
 367 =over 4
 368
 369 =item Arguments: $sql_fragment, @bind_values
 370
 371 =item Return Value: $resultset (scalar context), @row_objs (list context)
 372
 373 =back
 374
 375   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 376   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 377
 378 Pass a literal chunk of SQL to be added to the conditional part of the
 379 resultset query.
 380
 381 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 382 only be used in that context. C<search_literal> is a convenience method.
 383 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 384 columns are bound correctly, use C<search>.
 385
 386 Example of how to use C<search> instead of C<search_literal>
 387
 388   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 389   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 390
 391
 392 See L<DBIx::Class::Manual::Cookbook/Searching> and
 393 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 394 require C<search_literal>.
 395
 396 =cut
 397
 398 sub search_literal {
 399   my ($self, $sql, @bind) = @_;
 400   my $attr;
 401   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 402     $attr = pop @bind;
 403   }
 404   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 405 }
 406
 407 =head2 find
 408
 409 =over 4
 410
 411 =item Arguments: @values | \%cols, \%attrs?
 412
 413 =item Return Value: $row_object | undef
 414
 415 =back
 416
 417 Finds a row based on its primary key or unique constraint. For example, to find
 418 a row by its primary key:
 419
 420   my $cd = $schema->resultset('CD')->find(5);
 421
 422 You can also find a row by a specific unique constraint using the C<key>
 423 attribute. For example:
 424
 425   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 426     key => 'cd_artist_title'
 427   });
 428
 429 Additionally, you can specify the columns explicitly by name:
 430
 431   my $cd = $schema->resultset('CD')->find(
 432     {
 433       artist => 'Massive Attack',
 434       title  => 'Mezzanine',
 435     },
 436     { key => 'cd_artist_title' }
 437   );
 438
 439 If the C<key> is specified as C<primary>, it searches only on the primary key.
 440
 441 If no C<key> is specified, it searches on all unique constraints defined on the
 442 source for which column data is provided, including the primary key.
 443
 444 If your table does not have a primary key, you B<must> provide a value for the
 445 C<key> attribute matching one of the unique constraints on the source.
 446
 447 In addition to C<key>, L</find> recognizes and applies standard
 448 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 449
 450 Note: If your query does not return only one row, a warning is generated:
 451
 452   Query returned more than one row
 453
 454 See also L</find_or_create> and L</update_or_create>. For information on how to
 455 declare unique constraints, see
 456 L<DBIx::Class::ResultSource/add_unique_constraint>.
 457
 458 =cut
 459
 460 sub find {
 461   my $self = shift;
 462   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 463
 464   # Default to the primary key, but allow a specific key
 465   my @cols = exists $attrs->{key}
 466     ? $self->result_source->unique_constraint_columns($attrs->{key})
 467     : $self->result_source->primary_columns;
 468   $self->throw_exception(
 469     "Can't find unless a primary key is defined or unique constraint is specified"
 470   ) unless @cols;
 471
 472   # Parse out a hashref from input
 473   my $input_query;
 474   if (ref $_[0] eq 'HASH') {
 475     $input_query = { %{$_[0]} };
 476   }
 477   elsif (@_ == @cols) {
 478     $input_query = {};
 479     @{$input_query}{@cols} = @_;
 480   }
 481   else {
 482     # Compatibility: Allow e.g. find(id => $value)
 483     carp "Find by key => value deprecated; please use a hashref instead";
 484     $input_query = {@_};
 485   }
 486
 487   my (%related, $info);
 488
 489   KEY: foreach my $key (keys %$input_query) {
 490     if (ref($input_query->{$key})
 491         && ($info = $self->result_source->relationship_info($key))) {
 492       my $val = delete $input_query->{$key};
 493       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 494       my $rel_q = $self->result_source->_resolve_condition(
 495                     $info->{cond}, $val, $key
 496                   );
 497       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 498       @related{keys %$rel_q} = values %$rel_q;
 499     }
 500   }
 501   if (my @keys = keys %related) {
 502     @{$input_query}{@keys} = values %related;
 503   }
 504
 505
 506   # Build the final query: Default to the disjunction of the unique queries,
 507   # but allow the input query in case the ResultSet defines the query or the
 508   # user is abusing find
 509   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 510   my $query;
 511   if (exists $attrs->{key}) {
 512     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 513     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 514     $query = $self->_add_alias($unique_query, $alias);
 515   }
 516   elsif ($self->{attrs}{accessor} and $self->{attrs}{accessor} eq 'single') {
 517     # This means that we got here after a merger of relationship conditions
 518     # in ::Relationship::Base::search_related (the row method), and furthermore
 519     # the relationship is of the 'single' type. This means that the condition
 520     # provided by the relationship (already attached to $self) is sufficient,
 521     # as there can be only one row in the databse that would satisfy the
 522     # relationship
 523   }
 524   else {
 525     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 526     $query = @unique_queries
 527       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 528       : $self->_add_alias($input_query, $alias);
 529   }
 530
 531   # Run the query
 532   my $rs = $self->search ($query, $attrs);
 533   if (keys %{$rs->_resolved_attrs->{collapse}}) {
 534     my $row = $rs->next;
 535     carp "Query returned more than one row" if $rs->next;
 536     return $row;
 537   }
 538   else {
 539     return $rs->single;
 540   }
 541 }
 542
 543 # _add_alias
 544 #
 545 # Add the specified alias to the specified query hash. A copy is made so the
 546 # original query is not modified.
 547
 548 sub _add_alias {
 549   my ($self, $query, $alias) = @_;
 550
 551   my %aliased = %$query;
 552   foreach my $col (grep { ! m/\./ } keys %aliased) {
 553     $aliased{"$alias.$col"} = delete $aliased{$col};
 554   }
 555
 556   return \%aliased;
 557 }
 558
 559 # _unique_queries
 560 #
 561 # Build a list of queries which satisfy unique constraints.
 562
 563 sub _unique_queries {
 564   my ($self, $query, $attrs) = @_;
 565
 566   my @constraint_names = exists $attrs->{key}
 567     ? ($attrs->{key})
 568     : $self->result_source->unique_constraint_names;
 569
 570   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 571   my $num_where = scalar keys %$where;
 572
 573   my @unique_queries;
 574   foreach my $name (@constraint_names) {
 575     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 576     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 577
 578     my $num_cols = scalar @unique_cols;
 579     my $num_query = scalar keys %$unique_query;
 580
 581     my $total = $num_query + $num_where;
 582     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 583       # The query is either unique on its own or is unique in combination with
 584       # the existing where clause
 585       push @unique_queries, $unique_query;
 586     }
 587   }
 588
 589   return @unique_queries;
 590 }
 591
 592 # _build_unique_query
 593 #
 594 # Constrain the specified query hash based on the specified column names.
 595
 596 sub _build_unique_query {
 597   my ($self, $query, $unique_cols) = @_;
 598
 599   return {
 600     map  { $_ => $query->{$_} }
 601     grep { exists $query->{$_} }
 602       @$unique_cols
 603   };
 604 }
 605
 606 =head2 search_related
 607
 608 =over 4
 609
 610 =item Arguments: $rel, $cond, \%attrs?
 611
 612 =item Return Value: $new_resultset
 613
 614 =back
 615
 616   $new_rs = $cd_rs->search_related('artist', {
 617     name => 'Emo-R-Us',
 618   });
 619
 620 Searches the specified relationship, optionally specifying a condition and
 621 attributes for matching records. See L</ATTRIBUTES> for more information.
 622
 623 =cut
 624
 625 sub search_related {
 626   return shift->related_resultset(shift)->search(@_);
 627 }
 628
 629 =head2 search_related_rs
 630
 631 This method works exactly the same as search_related, except that
 632 it guarantees a restultset, even in list context.
 633
 634 =cut
 635
 636 sub search_related_rs {
 637   return shift->related_resultset(shift)->search_rs(@_);
 638 }
 639
 640 =head2 cursor
 641
 642 =over 4
 643
 644 =item Arguments: none
 645
 646 =item Return Value: $cursor
 647
 648 =back
 649
 650 Returns a storage-driven cursor to the given resultset. See
 651 L<DBIx::Class::Cursor> for more information.
 652
 653 =cut
 654
 655 sub cursor {
 656   my ($self) = @_;
 657
 658   my $attrs = $self->_resolved_attrs_copy;
 659
 660   return $self->{cursor}
 661     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 662           $attrs->{where},$attrs);
 663 }
 664
 665 =head2 single
 666
 667 =over 4
 668
 669 =item Arguments: $cond?
 670
 671 =item Return Value: $row_object?
 672
 673 =back
 674
 675   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 676
 677 Inflates the first result without creating a cursor if the resultset has
 678 any records in it; if not returns nothing. Used by L</find> as a lean version of
 679 L</search>.
 680
 681 While this method can take an optional search condition (just like L</search>)
 682 being a fast-code-path it does not recognize search attributes. If you need to
 683 add extra joins or similar, call L</search> and then chain-call L</single> on the
 684 L<DBIx::Class::ResultSet> returned.
 685
 686 =over
 687
 688 =item B<Note>
 689
 690 As of 0.08100, this method enforces the assumption that the preceeding
 691 query returns only one row. If more than one row is returned, you will receive
 692 a warning:
 693
 694   Query returned more than one row
 695
 696 In this case, you should be using L</next> or L</find> instead, or if you really
 697 know what you are doing, use the L</rows> attribute to explicitly limit the size
 698 of the resultset.
 699
 700 This method will also throw an exception if it is called on a resultset prefetching
 701 has_many, as such a prefetch implies fetching multiple rows from the database in
 702 order to assemble the resulting object.
 703
 704 =back
 705
 706 =cut
 707
 708 sub single {
 709   my ($self, $where) = @_;
 710   if(@_ > 2) {
 711       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 712   }
 713
 714   my $attrs = $self->_resolved_attrs_copy;
 715
 716   if (keys %{$attrs->{collapse}}) {
 717     $self->throw_exception(
 718       'single() can not be used on resultsets prefetching has_many. Use find( \%cond ) or next() instead'
 719     );
 720   }
 721
 722   if ($where) {
 723     if (defined $attrs->{where}) {
 724       $attrs->{where} = {
 725         '-and' =>
 726             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 727                $where, delete $attrs->{where} ]
 728       };
 729     } else {
 730       $attrs->{where} = $where;
 731     }
 732   }
 733
 734 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 735 #  unless ($self->_is_unique_query($attrs->{where})) {
 736 #    carp "Query not guaranteed to return a single row"
 737 #      . "; please declare your unique constraints or use search instead";
 738 #  }
 739
 740   my @data = $self->result_source->storage->select_single(
 741     $attrs->{from}, $attrs->{select},
 742     $attrs->{where}, $attrs
 743   );
 744
 745   return (@data ? ($self->_construct_object(@data))[0] : undef);
 746 }
 747
 748
 749 # _is_unique_query
 750 #
 751 # Try to determine if the specified query is guaranteed to be unique, based on
 752 # the declared unique constraints.
 753
 754 sub _is_unique_query {
 755   my ($self, $query) = @_;
 756
 757   my $collapsed = $self->_collapse_query($query);
 758   my $alias = $self->{attrs}{alias};
 759
 760   foreach my $name ($self->result_source->unique_constraint_names) {
 761     my @unique_cols = map {
 762       "$alias.$_"
 763     } $self->result_source->unique_constraint_columns($name);
 764
 765     # Count the values for each unique column
 766     my %seen = map { $_ => 0 } @unique_cols;
 767
 768     foreach my $key (keys %$collapsed) {
 769       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 770       next unless exists $seen{$aliased};  # Additional constraints are okay
 771       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 772     }
 773
 774     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 775     return 1 unless grep { $_ != 1 } values %seen;
 776   }
 777
 778   return 0;
 779 }
 780
 781 # _collapse_query
 782 #
 783 # Recursively collapse the query, accumulating values for each column.
 784
 785 sub _collapse_query {
 786   my ($self, $query, $collapsed) = @_;
 787
 788   $collapsed ||= {};
 789
 790   if (ref $query eq 'ARRAY') {
 791     foreach my $subquery (@$query) {
 792       next unless ref $subquery;  # -or
 793       $collapsed = $self->_collapse_query($subquery, $collapsed);
 794     }
 795   }
 796   elsif (ref $query eq 'HASH') {
 797     if (keys %$query and (keys %$query)[0] eq '-and') {
 798       foreach my $subquery (@{$query->{-and}}) {
 799         $collapsed = $self->_collapse_query($subquery, $collapsed);
 800       }
 801     }
 802     else {
 803       foreach my $col (keys %$query) {
 804         my $value = $query->{$col};
 805         $collapsed->{$col}{$value}++;
 806       }
 807     }
 808   }
 809
 810   return $collapsed;
 811 }
 812
 813 =head2 get_column
 814
 815 =over 4
 816
 817 =item Arguments: $cond?
 818
 819 =item Return Value: $resultsetcolumn
 820
 821 =back
 822
 823   my $max_length = $rs->get_column('length')->max;
 824
 825 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 826
 827 =cut
 828
 829 sub get_column {
 830   my ($self, $column) = @_;
 831   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 832   return $new;
 833 }
 834
 835 =head2 search_like
 836
 837 =over 4
 838
 839 =item Arguments: $cond, \%attrs?
 840
 841 =item Return Value: $resultset (scalar context), @row_objs (list context)
 842
 843 =back
 844
 845   # WHERE title LIKE '%blue%'
 846   $cd_rs = $rs->search_like({ title => '%blue%'});
 847
 848 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 849 that this is simply a convenience method retained for ex Class::DBI users.
 850 You most likely want to use L</search> with specific operators.
 851
 852 For more information, see L<DBIx::Class::Manual::Cookbook>.
 853
 854 This method is deprecated and will be removed in 0.09. Use L</search()>
 855 instead. An example conversion is:
 856
 857   ->search_like({ foo => 'bar' });
 858
 859   # Becomes
 860
 861   ->search({ foo => { like => 'bar' } });
 862
 863 =cut
 864
 865 sub search_like {
 866   my $class = shift;
 867   carp (
 868     'search_like() is deprecated and will be removed in DBIC version 0.09.'
 869    .' Instead use ->search({ x => { -like => "y%" } })'
 870    .' (note the outer pair of {}s - they are important!)'
 871   );
 872   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 873   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 874   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 875   return $class->search($query, { %$attrs });
 876 }
 877
 878 =head2 slice
 879
 880 =over 4
 881
 882 =item Arguments: $first, $last
 883
 884 =item Return Value: $resultset (scalar context), @row_objs (list context)
 885
 886 =back
 887
 888 Returns a resultset or object list representing a subset of elements from the
 889 resultset slice is called on. Indexes are from 0, i.e., to get the first
 890 three records, call:
 891
 892   my ($one, $two, $three) = $rs->slice(0, 2);
 893
 894 =cut
 895
 896 sub slice {
 897   my ($self, $min, $max) = @_;
 898   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 899   $attrs->{offset} = $self->{attrs}{offset} || 0;
 900   $attrs->{offset} += $min;
 901   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 902   return $self->search(undef(), $attrs);
 903   #my $slice = (ref $self)->new($self->result_source, $attrs);
 904   #return (wantarray ? $slice->all : $slice);
 905 }
 906
 907 =head2 next
 908
 909 =over 4
 910
 911 =item Arguments: none
 912
 913 =item Return Value: $result?
 914
 915 =back
 916
 917 Returns the next element in the resultset (C<undef> is there is none).
 918
 919 Can be used to efficiently iterate over records in the resultset:
 920
 921   my $rs = $schema->resultset('CD')->search;
 922   while (my $cd = $rs->next) {
 923     print $cd->title;
 924   }
 925
 926 Note that you need to store the resultset object, and call C<next> on it.
 927 Calling C<< resultset('Table')->next >> repeatedly will always return the
 928 first record from the resultset.
 929
 930 =cut
 931
 932 sub next {
 933   my ($self) = @_;
 934   if (my $cache = $self->get_cache) {
 935     $self->{all_cache_position} ||= 0;
 936     return $cache->[$self->{all_cache_position}++];
 937   }
 938   if ($self->{attrs}{cache}) {
 939     $self->{all_cache_position} = 1;
 940     return ($self->all)[0];
 941   }
 942   if ($self->{stashed_objects}) {
 943     my $obj = shift(@{$self->{stashed_objects}});
 944     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 945     return $obj;
 946   }
 947   my @row = (
 948     exists $self->{stashed_row}
 949       ? @{delete $self->{stashed_row}}
 950       : $self->cursor->next
 951   );
 952   return undef unless (@row);
 953   my ($row, @more) = $self->_construct_object(@row);
 954   $self->{stashed_objects} = \@more if @more;
 955   return $row;
 956 }
 957
 958 sub _construct_object {
 959   my ($self, @row) = @_;
 960
 961   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row)
 962     or return ();
 963   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 964   @new = $self->{_attrs}{record_filter}->(@new)
 965     if exists $self->{_attrs}{record_filter};
 966   return @new;
 967 }
 968
 969 sub _collapse_result {
 970   my ($self, $as_proto, $row) = @_;
 971
 972   # if the first row that ever came in is totally empty - this means we got
 973   # hit by a smooth^Wempty left-joined resultset. Just noop in that case
 974   # instead of producing a {}
 975   #
 976   my $has_def;
 977   for (@$row) {
 978     if (defined $_) {
 979       $has_def++;
 980       last;
 981     }
 982   }
 983   return undef unless $has_def;
 984
 985   my @copy = @$row;
 986
 987   # 'foo'         => [ undef, 'foo' ]
 988   # 'foo.bar'     => [ 'foo', 'bar' ]
 989   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 990
 991   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 992
 993   my %collapse = %{$self->{_attrs}{collapse}||{}};
 994
 995   my @pri_index;
 996
 997   # if we're doing collapsing (has_many prefetch) we need to grab records
 998   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 999   # we know we don't have to bother.
1000
1001   # the reason for not using the collapse stuff directly is because if you
1002   # had for e.g. two artists in a row with no cds, the collapse info for
1003   # both would be NULL (undef) so you'd lose the second artist
1004
1005   # store just the index so we can check the array positions from the row
1006   # without having to contruct the full hash
1007
1008   if (keys %collapse) {
1009     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1010     foreach my $i (0 .. $#construct_as) {
1011       next if defined($construct_as[$i][0]); # only self table
1012       if (delete $pri{$construct_as[$i][1]}) {
1013         push(@pri_index, $i);
1014       }
1015       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1016     }
1017   }
1018
1019   # no need to do an if, it'll be empty if @pri_index is empty anyway
1020
1021   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1022
1023   my @const_rows;
1024
1025   do { # no need to check anything at the front, we always want the first row
1026
1027     my %const;
1028
1029     foreach my $this_as (@construct_as) {
1030       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1031     }
1032
1033     push(@const_rows, \%const);
1034
1035   } until ( # no pri_index => no collapse => drop straight out
1036       !@pri_index
1037     or
1038       do { # get another row, stash it, drop out if different PK
1039
1040         @copy = $self->cursor->next;
1041         $self->{stashed_row} = \@copy;
1042
1043         # last thing in do block, counts as true if anything doesn't match
1044
1045         # check xor defined first for NULL vs. NOT NULL then if one is
1046         # defined the other must be so check string equality
1047
1048         grep {
1049           (defined $pri_vals{$_} ^ defined $copy[$_])
1050           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1051         } @pri_index;
1052       }
1053   );
1054
1055   my $alias = $self->{attrs}{alias};
1056   my $info = [];
1057
1058   my %collapse_pos;
1059
1060   my @const_keys;
1061
1062   foreach my $const (@const_rows) {
1063     scalar @const_keys or do {
1064       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1065     };
1066     foreach my $key (@const_keys) {
1067       if (length $key) {
1068         my $target = $info;
1069         my @parts = split(/\./, $key);
1070         my $cur = '';
1071         my $data = $const->{$key};
1072         foreach my $p (@parts) {
1073           $target = $target->[1]->{$p} ||= [];
1074           $cur .= ".${p}";
1075           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1076             # collapsing at this point and on final part
1077             my $pos = $collapse_pos{$cur};
1078             CK: foreach my $ck (@ckey) {
1079               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1080                 $collapse_pos{$cur} = $data;
1081                 delete @collapse_pos{ # clear all positioning for sub-entries
1082                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1083                 };
1084                 push(@$target, []);
1085                 last CK;
1086               }
1087             }
1088           }
1089           if (exists $collapse{$cur}) {
1090             $target = $target->[-1];
1091           }
1092         }
1093         $target->[0] = $data;
1094       } else {
1095         $info->[0] = $const->{$key};
1096       }
1097     }
1098   }
1099
1100   return $info;
1101 }
1102
1103 =head2 result_source
1104
1105 =over 4
1106
1107 =item Arguments: $result_source?
1108
1109 =item Return Value: $result_source
1110
1111 =back
1112
1113 An accessor for the primary ResultSource object from which this ResultSet
1114 is derived.
1115
1116 =head2 result_class
1117
1118 =over 4
1119
1120 =item Arguments: $result_class?
1121
1122 =item Return Value: $result_class
1123
1124 =back
1125
1126 An accessor for the class to use when creating row objects. Defaults to
1127 C<< result_source->result_class >> - which in most cases is the name of the
1128 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1129
1130 Note that changing the result_class will also remove any components
1131 that were originally loaded in the source class via
1132 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1133 in the original source class will not run.
1134
1135 =cut
1136
1137 sub result_class {
1138   my ($self, $result_class) = @_;
1139   if ($result_class) {
1140     $self->ensure_class_loaded($result_class);
1141     $self->_result_class($result_class);
1142   }
1143   $self->_result_class;
1144 }
1145
1146 =head2 count
1147
1148 =over 4
1149
1150 =item Arguments: $cond, \%attrs??
1151
1152 =item Return Value: $count
1153
1154 =back
1155
1156 Performs an SQL C<COUNT> with the same query as the resultset was built
1157 with to find the number of elements. Passing arguments is equivalent to
1158 C<< $rs->search ($cond, \%attrs)->count >>
1159
1160 =cut
1161
1162 sub count {
1163   my $self = shift;
1164   return $self->search(@_)->count if @_ and defined $_[0];
1165   return scalar @{ $self->get_cache } if $self->get_cache;
1166
1167   my $attrs = $self->_resolved_attrs_copy;
1168
1169   # this is a little optimization - it is faster to do the limit
1170   # adjustments in software, instead of a subquery
1171   my $rows = delete $attrs->{rows};
1172   my $offset = delete $attrs->{offset};
1173
1174   my $crs;
1175   if ($self->_has_resolved_attr (qw/collapse group_by/)) {
1176     $crs = $self->_count_subq_rs ($attrs);
1177   }
1178   else {
1179     $crs = $self->_count_rs ($attrs);
1180   }
1181   my $count = $crs->next;
1182
1183   $count -= $offset if $offset;
1184   $count = $rows if $rows and $rows < $count;
1185   $count = 0 if ($count < 0);
1186
1187   return $count;
1188 }
1189
1190 =head2 count_rs
1191
1192 =over 4
1193
1194 =item Arguments: $cond, \%attrs??
1195
1196 =item Return Value: $count_rs
1197
1198 =back
1199
1200 Same as L</count> but returns a L<DBIx::Class::ResultSetColumn> object.
1201 This can be very handy for subqueries:
1202
1203   ->search( { amount => $some_rs->count_rs->as_query } )
1204
1205 As with regular resultsets the SQL query will be executed only after
1206 the resultset is accessed via L</next> or L</all>. That would return
1207 the same single value obtainable via L</count>.
1208
1209 =cut
1210
1211 sub count_rs {
1212   my $self = shift;
1213   return $self->search(@_)->count_rs if @_;
1214
1215   # this may look like a lack of abstraction (count() does about the same)
1216   # but in fact an _rs *must* use a subquery for the limits, as the
1217   # software based limiting can not be ported if this $rs is to be used
1218   # in a subquery itself (i.e. ->as_query)
1219   if ($self->_has_resolved_attr (qw/collapse group_by offset rows/)) {
1220     return $self->_count_subq_rs;
1221   }
1222   else {
1223     return $self->_count_rs;
1224   }
1225 }
1226
1227 #
1228 # returns a ResultSetColumn object tied to the count query
1229 #
1230 sub _count_rs {
1231   my ($self, $attrs) = @_;
1232
1233   my $rsrc = $self->result_source;
1234   $attrs ||= $self->_resolved_attrs;
1235
1236   my $tmp_attrs = { %$attrs };
1237
1238   # take off any limits, record_filter is cdbi, and no point of ordering a count
1239   delete $tmp_attrs->{$_} for (qw/select as rows offset order_by record_filter/);
1240
1241   # overwrite the selector (supplied by the storage)
1242   $tmp_attrs->{select} = $rsrc->storage->_count_select ($rsrc, $tmp_attrs);
1243   $tmp_attrs->{as} = 'count';
1244
1245   # read the comment on top of the actual function to see what this does
1246   $tmp_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1247     $tmp_attrs->{from}, $tmp_attrs->{alias}
1248   );
1249
1250   my $tmp_rs = $rsrc->resultset_class->new($rsrc, $tmp_attrs)->get_column ('count');
1251
1252   return $tmp_rs;
1253 }
1254
1255 #
1256 # same as above but uses a subquery
1257 #
1258 sub _count_subq_rs {
1259   my ($self, $attrs) = @_;
1260
1261   my $rsrc = $self->result_source;
1262   $attrs ||= $self->_resolved_attrs_copy;
1263
1264   my $sub_attrs = { %$attrs };
1265
1266   # extra selectors do not go in the subquery and there is no point of ordering it
1267   delete $sub_attrs->{$_} for qw/collapse prefetch_select select as order_by/;
1268
1269   # if we prefetch, we group_by primary keys only as this is what we would get out of the rs via ->next/->all
1270   # clobber old group_by regardless
1271   if ( keys %{$attrs->{collapse}} ) {
1272     $sub_attrs->{group_by} = [ map { "$attrs->{alias}.$_" } ($rsrc->primary_columns) ]
1273   }
1274
1275   $sub_attrs->{select} = $rsrc->storage->_subq_count_select ($rsrc, $sub_attrs);
1276
1277   # read the comment on top of the actual function to see what this does
1278   $sub_attrs->{from} = $self->_switch_to_inner_join_if_needed (
1279     $sub_attrs->{from}, $sub_attrs->{alias}
1280   );
1281
1282   # this is so that ordering can be thrown away in things like Top limit
1283   $sub_attrs->{-for_count_only} = 1;
1284
1285   my $sub_rs = $rsrc->resultset_class->new ($rsrc, $sub_attrs);
1286
1287   $attrs->{from} = [{
1288     -alias => 'count_subq',
1289     -source_handle => $rsrc->handle,
1290     count_subq => $sub_rs->as_query,
1291   }];
1292
1293   # the subquery replaces this
1294   delete $attrs->{$_} for qw/where bind collapse group_by having having_bind rows offset/;
1295
1296   return $self->_count_rs ($attrs);
1297 }
1298
1299
1300 # The DBIC relationship chaining implementation is pretty simple - every
1301 # new related_relationship is pushed onto the {from} stack, and the {select}
1302 # window simply slides further in. This means that when we count somewhere
1303 # in the middle, we got to make sure that everything in the join chain is an
1304 # actual inner join, otherwise the count will come back with unpredictable
1305 # results (a resultset may be generated with _some_ rows regardless of if
1306 # the relation which the $rs currently selects has rows or not). E.g.
1307 # $artist_rs->cds->count - normally generates:
1308 # SELECT COUNT( * ) FROM artist me LEFT JOIN cd cds ON cds.artist = me.artistid
1309 # which actually returns the number of artists * (number of cds || 1)
1310 #
1311 # So what we do here is crawl {from}, determine if the current alias is at
1312 # the top of the stack, and if not - make sure the chain is inner-joined down
1313 # to the root.
1314 #
1315 sub _switch_to_inner_join_if_needed {
1316   my ($self, $from, $alias) = @_;
1317
1318   return $from if (
1319     ref $from ne 'ARRAY'
1320       ||
1321     ref $from->[0] ne 'HASH'
1322       ||
1323     ! $from->[0]{-alias}
1324       ||
1325     $from->[0]{-alias} eq $alias
1326   );
1327
1328   # this would be the case with a subquery - we'll never find
1329   # the target as it is not in the parseable part of {from}
1330   return $from if @$from == 1;
1331
1332   my $switch_branch;
1333   JOINSCAN:
1334   for my $j (@{$from}[1 .. $#$from]) {
1335     if ($j->[0]{-alias} eq $alias) {
1336       $switch_branch = $j->[0]{-join_path};
1337       last JOINSCAN;
1338     }
1339   }
1340
1341   # something else went wrong
1342   return $from unless $switch_branch;
1343
1344   # So it looks like we will have to switch some stuff around.
1345   # local() is useless here as we will be leaving the scope
1346   # anyway, and deep cloning is just too fucking expensive
1347   # So replace the inner hashref manually
1348   my @new_from = ($from->[0]);
1349   my $sw_idx = { map { $_ => 1 } @$switch_branch };
1350
1351   for my $j (@{$from}[1 .. $#$from]) {
1352     my $jalias = $j->[0]{-alias};
1353
1354     if ($sw_idx->{$jalias}) {
1355       my %attrs = %{$j->[0]};
1356       delete $attrs{-join_type};
1357       push @new_from, [
1358         \%attrs,
1359         @{$j}[ 1 .. $#$j ],
1360       ];
1361     }
1362     else {
1363       push @new_from, $j;
1364     }
1365   }
1366
1367   return \@new_from;
1368 }
1369
1370
1371 sub _bool {
1372   return 1;
1373 }
1374
1375 =head2 count_literal
1376
1377 =over 4
1378
1379 =item Arguments: $sql_fragment, @bind_values
1380
1381 =item Return Value: $count
1382
1383 =back
1384
1385 Counts the results in a literal query. Equivalent to calling L</search_literal>
1386 with the passed arguments, then L</count>.
1387
1388 =cut
1389
1390 sub count_literal { shift->search_literal(@_)->count; }
1391
1392 =head2 all
1393
1394 =over 4
1395
1396 =item Arguments: none
1397
1398 =item Return Value: @objects
1399
1400 =back
1401
1402 Returns all elements in the resultset. Called implicitly if the resultset
1403 is returned in list context.
1404
1405 =cut
1406
1407 sub all {
1408   my $self = shift;
1409   if(@_) {
1410       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1411   }
1412
1413   return @{ $self->get_cache } if $self->get_cache;
1414
1415   my @obj;
1416
1417   if (keys %{$self->_resolved_attrs->{collapse}}) {
1418     # Using $self->cursor->all is really just an optimisation.
1419     # If we're collapsing has_many prefetches it probably makes
1420     # very little difference, and this is cleaner than hacking
1421     # _construct_object to survive the approach
1422     $self->cursor->reset;
1423     my @row = $self->cursor->next;
1424     while (@row) {
1425       push(@obj, $self->_construct_object(@row));
1426       @row = (exists $self->{stashed_row}
1427                ? @{delete $self->{stashed_row}}
1428                : $self->cursor->next);
1429     }
1430   } else {
1431     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1432   }
1433
1434   $self->set_cache(\@obj) if $self->{attrs}{cache};
1435
1436   return @obj;
1437 }
1438
1439 =head2 reset
1440
1441 =over 4
1442
1443 =item Arguments: none
1444
1445 =item Return Value: $self
1446
1447 =back
1448
1449 Resets the resultset's cursor, so you can iterate through the elements again.
1450 Implicitly resets the storage cursor, so a subsequent L</next> will trigger
1451 another query.
1452
1453 =cut
1454
1455 sub reset {
1456   my ($self) = @_;
1457   delete $self->{_attrs} if exists $self->{_attrs};
1458   $self->{all_cache_position} = 0;
1459   $self->cursor->reset;
1460   return $self;
1461 }
1462
1463 =head2 first
1464
1465 =over 4
1466
1467 =item Arguments: none
1468
1469 =item Return Value: $object?
1470
1471 =back
1472
1473 Resets the resultset and returns an object for the first result (if the
1474 resultset returns anything).
1475
1476 =cut
1477
1478 sub first {
1479   return $_[0]->reset->next;
1480 }
1481
1482
1483 # _rs_update_delete
1484 #
1485 # Determines whether and what type of subquery is required for the $rs operation.
1486 # If grouping is necessary either supplies its own, or verifies the current one
1487 # After all is done delegates to the proper storage method.
1488
1489 sub _rs_update_delete {
1490   my ($self, $op, $values) = @_;
1491
1492   my $rsrc = $self->result_source;
1493
1494   my $needs_group_by_subq = $self->_has_resolved_attr (qw/collapse group_by -join/);
1495   my $needs_subq = $self->_has_resolved_attr (qw/row offset/);
1496
1497   if ($needs_group_by_subq or $needs_subq) {
1498
1499     # make a new $rs selecting only the PKs (that's all we really need)
1500     my $attrs = $self->_resolved_attrs_copy;
1501
1502     delete $attrs->{$_} for qw/collapse select as/;
1503     $attrs->{columns} = [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1504
1505     if ($needs_group_by_subq) {
1506       # make sure no group_by was supplied, or if there is one - make sure it matches
1507       # the columns compiled above perfectly. Anything else can not be sanely executed
1508       # on most databases so croak right then and there
1509
1510       if (my $g = $attrs->{group_by}) {
1511         my @current_group_by = map
1512           { $_ =~ /\./ ? $_ : "$attrs->{alias}.$_" }
1513           (ref $g eq 'ARRAY' ? @$g : $g );
1514
1515         if (
1516           join ("\x00", sort @current_group_by)
1517             ne
1518           join ("\x00", sort @{$attrs->{columns}} )
1519         ) {
1520           $self->throw_exception (
1521             "You have just attempted a $op operation on a resultset which does group_by"
1522             . ' on columns other than the primary keys, while DBIC internally needs to retrieve'
1523             . ' the primary keys in a subselect. All sane RDBMS engines do not support this'
1524             . ' kind of queries. Please retry the operation with a modified group_by or'
1525             . ' without using one at all.'
1526           );
1527         }
1528       }
1529       else {
1530         $attrs->{group_by} = $attrs->{columns};
1531       }
1532     }
1533
1534     my $subrs = (ref $self)->new($rsrc, $attrs);
1535
1536     return $self->result_source->storage->_subq_update_delete($subrs, $op, $values);
1537   }
1538   else {
1539     return $rsrc->storage->$op(
1540       $rsrc,
1541       $op eq 'update' ? $values : (),
1542       $self->_cond_for_update_delete,
1543     );
1544   }
1545 }
1546
1547
1548 # _cond_for_update_delete
1549 #
1550 # update/delete require the condition to be modified to handle
1551 # the differing SQL syntax available.  This transforms the $self->{cond}
1552 # appropriately, returning the new condition.
1553
1554 sub _cond_for_update_delete {
1555   my ($self, $full_cond) = @_;
1556   my $cond = {};
1557
1558   $full_cond ||= $self->{cond};
1559   # No-op. No condition, we're updating/deleting everything
1560   return $cond unless ref $full_cond;
1561
1562   if (ref $full_cond eq 'ARRAY') {
1563     $cond = [
1564       map {
1565         my %hash;
1566         foreach my $key (keys %{$_}) {
1567           $key =~ /([^.]+)$/;
1568           $hash{$1} = $_->{$key};
1569         }
1570         \%hash;
1571       } @{$full_cond}
1572     ];
1573   }
1574   elsif (ref $full_cond eq 'HASH') {
1575     if ((keys %{$full_cond})[0] eq '-and') {
1576       $cond->{-and} = [];
1577       my @cond = @{$full_cond->{-and}};
1578        for (my $i = 0; $i < @cond; $i++) {
1579         my $entry = $cond[$i];
1580         my $hash;
1581         if (ref $entry eq 'HASH') {
1582           $hash = $self->_cond_for_update_delete($entry);
1583         }
1584         else {
1585           $entry =~ /([^.]+)$/;
1586           $hash->{$1} = $cond[++$i];
1587         }
1588         push @{$cond->{-and}}, $hash;
1589       }
1590     }
1591     else {
1592       foreach my $key (keys %{$full_cond}) {
1593         $key =~ /([^.]+)$/;
1594         $cond->{$1} = $full_cond->{$key};
1595       }
1596     }
1597   }
1598   else {
1599     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1600   }
1601
1602   return $cond;
1603 }
1604
1605
1606 =head2 update
1607
1608 =over 4
1609
1610 =item Arguments: \%values
1611
1612 =item Return Value: $storage_rv
1613
1614 =back
1615
1616 Sets the specified columns in the resultset to the supplied values in a
1617 single query. Return value will be true if the update succeeded or false
1618 if no records were updated; exact type of success value is storage-dependent.
1619
1620 =cut
1621
1622 sub update {
1623   my ($self, $values) = @_;
1624   $self->throw_exception('Values for update must be a hash')
1625     unless ref $values eq 'HASH';
1626
1627   return $self->_rs_update_delete ('update', $values);
1628 }
1629
1630 =head2 update_all
1631
1632 =over 4
1633
1634 =item Arguments: \%values
1635
1636 =item Return Value: 1
1637
1638 =back
1639
1640 Fetches all objects and updates them one at a time. Note that C<update_all>
1641 will run DBIC cascade triggers, while L</update> will not.
1642
1643 =cut
1644
1645 sub update_all {
1646   my ($self, $values) = @_;
1647   $self->throw_exception('Values for update_all must be a hash')
1648     unless ref $values eq 'HASH';
1649   foreach my $obj ($self->all) {
1650     $obj->set_columns($values)->update;
1651   }
1652   return 1;
1653 }
1654
1655 =head2 delete
1656
1657 =over 4
1658
1659 =item Arguments: none
1660
1661 =item Return Value: $storage_rv
1662
1663 =back
1664
1665 Deletes the contents of the resultset from its result source. Note that this
1666 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1667 to run. See also L<DBIx::Class::Row/delete>.
1668
1669 Return value will be the amount of rows deleted; exact type of return value
1670 is storage-dependent.
1671
1672 =cut
1673
1674 sub delete {
1675   my $self = shift;
1676   $self->throw_exception('delete does not accept any arguments')
1677     if @_;
1678
1679   return $self->_rs_update_delete ('delete');
1680 }
1681
1682 =head2 delete_all
1683
1684 =over 4
1685
1686 =item Arguments: none
1687
1688 =item Return Value: 1
1689
1690 =back
1691
1692 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1693 will run DBIC cascade triggers, while L</delete> will not.
1694
1695 =cut
1696
1697 sub delete_all {
1698   my $self = shift;
1699   $self->throw_exception('delete_all does not accept any arguments')
1700     if @_;
1701
1702   $_->delete for $self->all;
1703   return 1;
1704 }
1705
1706 =head2 populate
1707
1708 =over 4
1709
1710 =item Arguments: \@data;
1711
1712 =back
1713
1714 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1715 For the arrayref of hashrefs style each hashref should be a structure suitable
1716 forsubmitting to a $resultset->create(...) method.
1717
1718 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1719 to insert the data, as this is a faster method.
1720
1721 Otherwise, each set of data is inserted into the database using
1722 L<DBIx::Class::ResultSet/create>, and the resulting objects are
1723 accumulated into an array. The array itself, or an array reference
1724 is returned depending on scalar or list context.
1725
1726 Example:  Assuming an Artist Class that has many CDs Classes relating:
1727
1728   my $Artist_rs = $schema->resultset("Artist");
1729
1730   ## Void Context Example
1731   $Artist_rs->populate([
1732      { artistid => 4, name => 'Manufactured Crap', cds => [
1733         { title => 'My First CD', year => 2006 },
1734         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1735       ],
1736      },
1737      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1738         { title => 'My parents sold me to a record company' ,year => 2005 },
1739         { title => 'Why Am I So Ugly?', year => 2006 },
1740         { title => 'I Got Surgery and am now Popular', year => 2007 }
1741       ],
1742      },
1743   ]);
1744
1745   ## Array Context Example
1746   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1747     { name => "Artist One"},
1748     { name => "Artist Two"},
1749     { name => "Artist Three", cds=> [
1750     { title => "First CD", year => 2007},
1751     { title => "Second CD", year => 2008},
1752   ]}
1753   ]);
1754
1755   print $ArtistOne->name; ## response is 'Artist One'
1756   print $ArtistThree->cds->count ## reponse is '2'
1757
1758 For the arrayref of arrayrefs style,  the first element should be a list of the
1759 fieldsnames to which the remaining elements are rows being inserted.  For
1760 example:
1761
1762   $Arstist_rs->populate([
1763     [qw/artistid name/],
1764     [100, 'A Formally Unknown Singer'],
1765     [101, 'A singer that jumped the shark two albums ago'],
1766     [102, 'An actually cool singer.'],
1767   ]);
1768
1769 Please note an important effect on your data when choosing between void and
1770 wantarray context. Since void context goes straight to C<insert_bulk> in
1771 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1772 C<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1773 create primary keys for you, you will find that your PKs are empty.  In this
1774 case you will have to use the wantarray context in order to create those
1775 values.
1776
1777 =cut
1778
1779 sub populate {
1780   my $self = shift @_;
1781   my $data = ref $_[0][0] eq 'HASH'
1782     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1783     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1784
1785   if(defined wantarray) {
1786     my @created;
1787     foreach my $item (@$data) {
1788       push(@created, $self->create($item));
1789     }
1790     return wantarray ? @created : \@created;
1791   } else {
1792     my ($first, @rest) = @$data;
1793
1794     my @names = grep {!ref $first->{$_}} keys %$first;
1795     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1796     my @pks = $self->result_source->primary_columns;
1797
1798     ## do the belongs_to relationships
1799     foreach my $index (0..$#$data) {
1800
1801       # delegate to create() for any dataset without primary keys with specified relationships
1802       if (grep { !defined $data->[$index]->{$_} } @pks ) {
1803         for my $r (@rels) {
1804           if (grep { ref $data->[$index]{$r} eq $_ } qw/HASH ARRAY/) {  # a related set must be a HASH or AoH
1805             my @ret = $self->populate($data);
1806             return;
1807           }
1808         }
1809       }
1810
1811       foreach my $rel (@rels) {
1812         next unless ref $data->[$index]->{$rel} eq "HASH";
1813         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1814         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1815         my $related = $result->result_source->_resolve_condition(
1816           $result->result_source->relationship_info($reverse)->{cond},
1817           $self,
1818           $result,
1819         );
1820
1821         delete $data->[$index]->{$rel};
1822         $data->[$index] = {%{$data->[$index]}, %$related};
1823
1824         push @names, keys %$related if $index == 0;
1825       }
1826     }
1827
1828     ## do bulk insert on current row
1829     my @values = map { [ @$_{@names} ] } @$data;
1830
1831     $self->result_source->storage->insert_bulk(
1832       $self->result_source,
1833       \@names,
1834       \@values,
1835     );
1836
1837     ## do the has_many relationships
1838     foreach my $item (@$data) {
1839
1840       foreach my $rel (@rels) {
1841         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1842
1843         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1844      || $self->throw_exception('Cannot find the relating object.');
1845
1846         my $child = $parent->$rel;
1847
1848         my $related = $child->result_source->_resolve_condition(
1849           $parent->result_source->relationship_info($rel)->{cond},
1850           $child,
1851           $parent,
1852         );
1853
1854         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1855         my @populate = map { {%$_, %$related} } @rows_to_add;
1856
1857         $child->populate( \@populate );
1858       }
1859     }
1860   }
1861 }
1862
1863 =head2 _normalize_populate_args ($args)
1864
1865 Private method used by L</populate> to normalize its incoming arguments.  Factored
1866 out in case you want to subclass and accept new argument structures to the
1867 L</populate> method.
1868
1869 =cut
1870
1871 sub _normalize_populate_args {
1872   my ($self, $data) = @_;
1873   my @names = @{shift(@$data)};
1874   my @results_to_create;
1875   foreach my $datum (@$data) {
1876     my %result_to_create;
1877     foreach my $index (0..$#names) {
1878       $result_to_create{$names[$index]} = $$datum[$index];
1879     }
1880     push @results_to_create, \%result_to_create;
1881   }
1882   return \@results_to_create;
1883 }
1884
1885 =head2 pager
1886
1887 =over 4
1888
1889 =item Arguments: none
1890
1891 =item Return Value: $pager
1892
1893 =back
1894
1895 Return Value a L<Data::Page> object for the current resultset. Only makes
1896 sense for queries with a C<page> attribute.
1897
1898 To get the full count of entries for a paged resultset, call
1899 C<total_entries> on the L<Data::Page> object.
1900
1901 =cut
1902
1903 sub pager {
1904   my ($self) = @_;
1905
1906   return $self->{pager} if $self->{pager};
1907
1908   my $attrs = $self->{attrs};
1909   $self->throw_exception("Can't create pager for non-paged rs")
1910     unless $self->{attrs}{page};
1911   $attrs->{rows} ||= 10;
1912
1913   # throw away the paging flags and re-run the count (possibly
1914   # with a subselect) to get the real total count
1915   my $count_attrs = { %$attrs };
1916   delete $count_attrs->{$_} for qw/rows offset page pager/;
1917   my $total_count = (ref $self)->new($self->result_source, $count_attrs)->count;
1918
1919   return $self->{pager} = Data::Page->new(
1920     $total_count,
1921     $attrs->{rows},
1922     $self->{attrs}{page}
1923   );
1924 }
1925
1926 =head2 page
1927
1928 =over 4
1929
1930 =item Arguments: $page_number
1931
1932 =item Return Value: $rs
1933
1934 =back
1935
1936 Returns a resultset for the $page_number page of the resultset on which page
1937 is called, where each page contains a number of rows equal to the 'rows'
1938 attribute set on the resultset (10 by default).
1939
1940 =cut
1941
1942 sub page {
1943   my ($self, $page) = @_;
1944   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1945 }
1946
1947 =head2 new_result
1948
1949 =over 4
1950
1951 =item Arguments: \%vals
1952
1953 =item Return Value: $rowobject
1954
1955 =back
1956
1957 Creates a new row object in the resultset's result class and returns
1958 it. The row is not inserted into the database at this point, call
1959 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1960 will tell you whether the row object has been inserted or not.
1961
1962 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1963
1964 =cut
1965
1966 sub new_result {
1967   my ($self, $values) = @_;
1968   $self->throw_exception( "new_result needs a hash" )
1969     unless (ref $values eq 'HASH');
1970
1971   my %new;
1972   my $alias = $self->{attrs}{alias};
1973
1974   if (
1975     defined $self->{cond}
1976     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1977   ) {
1978     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1979     $new{-from_resultset} = [ keys %new ] if keys %new;
1980   } else {
1981     $self->throw_exception(
1982       "Can't abstract implicit construct, condition not a hash"
1983     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1984
1985     my $collapsed_cond = (
1986       $self->{cond}
1987         ? $self->_collapse_cond($self->{cond})
1988         : {}
1989     );
1990
1991     # precendence must be given to passed values over values inherited from
1992     # the cond, so the order here is important.
1993     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1994     while( my($col,$value) = each %implied ){
1995       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1996         $new{$col} = $value->{'='};
1997         next;
1998       }
1999       $new{$col} = $value if $self->_is_deterministic_value($value);
2000     }
2001   }
2002
2003   %new = (
2004     %new,
2005     %{ $self->_remove_alias($values, $alias) },
2006     -source_handle => $self->_source_handle,
2007     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
2008   );
2009
2010   return $self->result_class->new(\%new);
2011 }
2012
2013 # _is_deterministic_value
2014 #
2015 # Make an effor to strip non-deterministic values from the condition,
2016 # to make sure new_result chokes less
2017
2018 sub _is_deterministic_value {
2019   my $self = shift;
2020   my $value = shift;
2021   my $ref_type = ref $value;
2022   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
2023   return 1 if Scalar::Util::blessed($value);
2024   return 0;
2025 }
2026
2027 # _has_resolved_attr
2028 #
2029 # determines if the resultset defines at least one
2030 # of the attributes supplied
2031 #
2032 # used to determine if a subquery is neccessary
2033 #
2034 # supports some virtual attributes:
2035 #   -join
2036 #     This will scan for any joins being present on the resultset.
2037 #     It is not a mere key-search but a deep inspection of {from}
2038 #
2039
2040 sub _has_resolved_attr {
2041   my ($self, @attr_names) = @_;
2042
2043   my $attrs = $self->_resolved_attrs;
2044
2045   my %extra_checks;
2046
2047   for my $n (@attr_names) {
2048     if (grep { $n eq $_ } (qw/-join/) ) {
2049       $extra_checks{$n}++;
2050       next;
2051     }
2052
2053     my $attr =  $attrs->{$n};
2054
2055     next if not defined $attr;
2056
2057     if (ref $attr eq 'HASH') {
2058       return 1 if keys %$attr;
2059     }
2060     elsif (ref $attr eq 'ARRAY') {
2061       return 1 if @$attr;
2062     }
2063     else {
2064       return 1 if $attr;
2065     }
2066   }
2067
2068   # a resolved join is expressed as a multi-level from
2069   return 1 if (
2070     $extra_checks{-join}
2071       and
2072     ref $attrs->{from} eq 'ARRAY'
2073       and
2074     @{$attrs->{from}} > 1
2075   );
2076
2077   return 0;
2078 }
2079
2080 # _collapse_cond
2081 #
2082 # Recursively collapse the condition.
2083
2084 sub _collapse_cond {
2085   my ($self, $cond, $collapsed) = @_;
2086
2087   $collapsed ||= {};
2088
2089   if (ref $cond eq 'ARRAY') {
2090     foreach my $subcond (@$cond) {
2091       next unless ref $subcond;  # -or
2092       $collapsed = $self->_collapse_cond($subcond, $collapsed);
2093     }
2094   }
2095   elsif (ref $cond eq 'HASH') {
2096     if (keys %$cond and (keys %$cond)[0] eq '-and') {
2097       foreach my $subcond (@{$cond->{-and}}) {
2098         $collapsed = $self->_collapse_cond($subcond, $collapsed);
2099       }
2100     }
2101     else {
2102       foreach my $col (keys %$cond) {
2103         my $value = $cond->{$col};
2104         $collapsed->{$col} = $value;
2105       }
2106     }
2107   }
2108
2109   return $collapsed;
2110 }
2111
2112 # _remove_alias
2113 #
2114 # Remove the specified alias from the specified query hash. A copy is made so
2115 # the original query is not modified.
2116
2117 sub _remove_alias {
2118   my ($self, $query, $alias) = @_;
2119
2120   my %orig = %{ $query || {} };
2121   my %unaliased;
2122
2123   foreach my $key (keys %orig) {
2124     if ($key !~ /\./) {
2125       $unaliased{$key} = $orig{$key};
2126       next;
2127     }
2128     $unaliased{$1} = $orig{$key}
2129       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
2130   }
2131
2132   return \%unaliased;
2133 }
2134
2135 =head2 as_query (EXPERIMENTAL)
2136
2137 =over 4
2138
2139 =item Arguments: none
2140
2141 =item Return Value: \[ $sql, @bind ]
2142
2143 =back
2144
2145 Returns the SQL query and bind vars associated with the invocant.
2146
2147 This is generally used as the RHS for a subquery.
2148
2149 B<NOTE>: This feature is still experimental.
2150
2151 =cut
2152
2153 sub as_query {
2154   my $self = shift;
2155
2156   my $attrs = $self->_resolved_attrs_copy;
2157
2158   # For future use:
2159   #
2160   # in list ctx:
2161   # my ($sql, \@bind, \%dbi_bind_attrs) = _select_args_to_query (...)
2162   # $sql also has no wrapping parenthesis in list ctx
2163   #
2164   my $sqlbind = $self->result_source->storage
2165     ->_select_args_to_query ($attrs->{from}, $attrs->{select}, $attrs->{where}, $attrs);
2166
2167   return $sqlbind;
2168 }
2169
2170 =head2 find_or_new
2171
2172 =over 4
2173
2174 =item Arguments: \%vals, \%attrs?
2175
2176 =item Return Value: $rowobject
2177
2178 =back
2179
2180   my $artist = $schema->resultset('Artist')->find_or_new(
2181     { artist => 'fred' }, { key => 'artists' });
2182
2183   $cd->cd_to_producer->find_or_new({ producer => $producer },
2184                                    { key => 'primary });
2185
2186 Find an existing record from this resultset, based on its primary
2187 key, or a unique constraint. If none exists, instantiate a new result
2188 object and return it. The object will not be saved into your storage
2189 until you call L<DBIx::Class::Row/insert> on it.
2190
2191 You most likely want this method when looking for existing rows using
2192 a unique constraint that is not the primary key, or looking for
2193 related rows.
2194
2195 If you want objects to be saved immediately, use L</find_or_create> instead.
2196
2197 B<Note>: C<find_or_new> is probably not what you want when creating a
2198 new row in a table that uses primary keys supplied by the
2199 database. Passing in a primary key column with a value of I<undef>
2200 will cause L</find> to attempt to search for a row with a value of
2201 I<NULL>.
2202
2203 =cut
2204
2205 sub find_or_new {
2206   my $self     = shift;
2207   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2208   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2209   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2210     return $row;
2211   }
2212   return $self->new_result($hash);
2213 }
2214
2215 =head2 create
2216
2217 =over 4
2218
2219 =item Arguments: \%vals
2220
2221 =item Return Value: a L<DBIx::Class::Row> $object
2222
2223 =back
2224
2225 Attempt to create a single new row or a row with multiple related rows
2226 in the table represented by the resultset (and related tables). This
2227 will not check for duplicate rows before inserting, use
2228 L</find_or_create> to do that.
2229
2230 To create one row for this resultset, pass a hashref of key/value
2231 pairs representing the columns of the table and the values you wish to
2232 store. If the appropriate relationships are set up, foreign key fields
2233 can also be passed an object representing the foreign row, and the
2234 value will be set to its primary key.
2235
2236 To create related objects, pass a hashref for the value if the related
2237 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
2238 and use the name of the relationship as the key. (NOT the name of the field,
2239 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
2240 of hashrefs containing the data for each of the rows to create in the foreign
2241 tables, again using the relationship name as the key.
2242
2243 Instead of hashrefs of plain related data (key/value pairs), you may
2244 also pass new or inserted objects. New objects (not inserted yet, see
2245 L</new>), will be inserted into their appropriate tables.
2246
2247 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
2248
2249 Example of creating a new row.
2250
2251   $person_rs->create({
2252     name=>"Some Person",
2253     email=>"somebody@someplace.com"
2254   });
2255
2256 Example of creating a new row and also creating rows in a related C<has_many>
2257 or C<has_one> resultset.  Note Arrayref.
2258
2259   $artist_rs->create(
2260      { artistid => 4, name => 'Manufactured Crap', cds => [
2261         { title => 'My First CD', year => 2006 },
2262         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2263       ],
2264      },
2265   );
2266
2267 Example of creating a new row and also creating a row in a related
2268 C<belongs_to>resultset. Note Hashref.
2269
2270   $cd_rs->create({
2271     title=>"Music for Silly Walks",
2272     year=>2000,
2273     artist => {
2274       name=>"Silly Musician",
2275     }
2276   });
2277
2278 =cut
2279
2280 sub create {
2281   my ($self, $attrs) = @_;
2282   $self->throw_exception( "create needs a hashref" )
2283     unless ref $attrs eq 'HASH';
2284   return $self->new_result($attrs)->insert;
2285 }
2286
2287 =head2 find_or_create
2288
2289 =over 4
2290
2291 =item Arguments: \%vals, \%attrs?
2292
2293 =item Return Value: $rowobject
2294
2295 =back
2296
2297   $cd->cd_to_producer->find_or_create({ producer => $producer },
2298                                       { key => 'primary' });
2299
2300 Tries to find a record based on its primary key or unique constraints; if none
2301 is found, creates one and returns that instead.
2302
2303   my $cd = $schema->resultset('CD')->find_or_create({
2304     cdid   => 5,
2305     artist => 'Massive Attack',
2306     title  => 'Mezzanine',
2307     year   => 2005,
2308   });
2309
2310 Also takes an optional C<key> attribute, to search by a specific key or unique
2311 constraint. For example:
2312
2313   my $cd = $schema->resultset('CD')->find_or_create(
2314     {
2315       artist => 'Massive Attack',
2316       title  => 'Mezzanine',
2317     },
2318     { key => 'cd_artist_title' }
2319   );
2320
2321 B<Note>: Because find_or_create() reads from the database and then
2322 possibly inserts based on the result, this method is subject to a race
2323 condition. Another process could create a record in the table after
2324 the find has completed and before the create has started. To avoid
2325 this problem, use find_or_create() inside a transaction.
2326
2327 B<Note>: C<find_or_create> is probably not what you want when creating
2328 a new row in a table that uses primary keys supplied by the
2329 database. Passing in a primary key column with a value of I<undef>
2330 will cause L</find> to attempt to search for a row with a value of
2331 I<NULL>.
2332
2333 See also L</find> and L</update_or_create>. For information on how to declare
2334 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2335
2336 =cut
2337
2338 sub find_or_create {
2339   my $self     = shift;
2340   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2341   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2342   if (keys %$hash and my $row = $self->find($hash, $attrs) ) {
2343     return $row;
2344   }
2345   return $self->create($hash);
2346 }
2347
2348 =head2 update_or_create
2349
2350 =over 4
2351
2352 =item Arguments: \%col_values, { key => $unique_constraint }?
2353
2354 =item Return Value: $rowobject
2355
2356 =back
2357
2358   $resultset->update_or_create({ col => $val, ... });
2359
2360 First, searches for an existing row matching one of the unique constraints
2361 (including the primary key) on the source of this resultset. If a row is
2362 found, updates it with the other given column values. Otherwise, creates a new
2363 row.
2364
2365 Takes an optional C<key> attribute to search on a specific unique constraint.
2366 For example:
2367
2368   # In your application
2369   my $cd = $schema->resultset('CD')->update_or_create(
2370     {
2371       artist => 'Massive Attack',
2372       title  => 'Mezzanine',
2373       year   => 1998,
2374     },
2375     { key => 'cd_artist_title' }
2376   );
2377
2378   $cd->cd_to_producer->update_or_create({
2379     producer => $producer,
2380     name => 'harry',
2381   }, {
2382     key => 'primary,
2383   });
2384
2385
2386 If no C<key> is specified, it searches on all unique constraints defined on the
2387 source, including the primary key.
2388
2389 If the C<key> is specified as C<primary>, it searches only on the primary key.
2390
2391 See also L</find> and L</find_or_create>. For information on how to declare
2392 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2393
2394 B<Note>: C<update_or_create> is probably not what you want when
2395 looking for a row in a table that uses primary keys supplied by the
2396 database, unless you actually have a key value. Passing in a primary
2397 key column with a value of I<undef> will cause L</find> to attempt to
2398 search for a row with a value of I<NULL>.
2399
2400 =cut
2401
2402 sub update_or_create {
2403   my $self = shift;
2404   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2405   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2406
2407   my $row = $self->find($cond, $attrs);
2408   if (defined $row) {
2409     $row->update($cond);
2410     return $row;
2411   }
2412
2413   return $self->create($cond);
2414 }
2415
2416 =head2 update_or_new
2417
2418 =over 4
2419
2420 =item Arguments: \%col_values, { key => $unique_constraint }?
2421
2422 =item Return Value: $rowobject
2423
2424 =back
2425
2426   $resultset->update_or_new({ col => $val, ... });
2427
2428 First, searches for an existing row matching one of the unique constraints
2429 (including the primary key) on the source of this resultset. If a row is
2430 found, updates it with the other given column values. Otherwise, instantiate
2431 a new result object and return it. The object will not be saved into your storage
2432 until you call L<DBIx::Class::Row/insert> on it.
2433
2434 Takes an optional C<key> attribute to search on a specific unique constraint.
2435 For example:
2436
2437   # In your application
2438   my $cd = $schema->resultset('CD')->update_or_new(
2439     {
2440       artist => 'Massive Attack',
2441       title  => 'Mezzanine',
2442       year   => 1998,
2443     },
2444     { key => 'cd_artist_title' }
2445   );
2446
2447   if ($cd->in_storage) {
2448       # the cd was updated
2449   }
2450   else {
2451       # the cd is not yet in the database, let's insert it
2452       $cd->insert;
2453   }
2454
2455 See also L</find>, L</find_or_create> and L<find_or_new>.
2456
2457 =cut
2458
2459 sub update_or_new {
2460     my $self  = shift;
2461     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2462     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2463
2464     my $row = $self->find( $cond, $attrs );
2465     if ( defined $row ) {
2466         $row->update($cond);
2467         return $row;
2468     }
2469
2470     return $self->new_result($cond);
2471 }
2472
2473 =head2 get_cache
2474
2475 =over 4
2476
2477 =item Arguments: none
2478
2479 =item Return Value: \@cache_objects?
2480
2481 =back
2482
2483 Gets the contents of the cache for the resultset, if the cache is set.
2484
2485 The cache is populated either by using the L</prefetch> attribute to
2486 L</search> or by calling L</set_cache>.
2487
2488 =cut
2489
2490 sub get_cache {
2491   shift->{all_cache};
2492 }
2493
2494 =head2 set_cache
2495
2496 =over 4
2497
2498 =item Arguments: \@cache_objects
2499
2500 =item Return Value: \@cache_objects
2501
2502 =back
2503
2504 Sets the contents of the cache for the resultset. Expects an arrayref
2505 of objects of the same class as those produced by the resultset. Note that
2506 if the cache is set the resultset will return the cached objects rather
2507 than re-querying the database even if the cache attr is not set.
2508
2509 The contents of the cache can also be populated by using the
2510 L</prefetch> attribute to L</search>.
2511
2512 =cut
2513
2514 sub set_cache {
2515   my ( $self, $data ) = @_;
2516   $self->throw_exception("set_cache requires an arrayref")
2517       if defined($data) && (ref $data ne 'ARRAY');
2518   $self->{all_cache} = $data;
2519 }
2520
2521 =head2 clear_cache
2522
2523 =over 4
2524
2525 =item Arguments: none
2526
2527 =item Return Value: []
2528
2529 =back
2530
2531 Clears the cache for the resultset.
2532
2533 =cut
2534
2535 sub clear_cache {
2536   shift->set_cache(undef);
2537 }
2538
2539 =head2 related_resultset
2540
2541 =over 4
2542
2543 =item Arguments: $relationship_name
2544
2545 =item Return Value: $resultset
2546
2547 =back
2548
2549 Returns a related resultset for the supplied relationship name.
2550
2551   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2552
2553 =cut
2554
2555 sub related_resultset {
2556   my ($self, $rel) = @_;
2557
2558   $self->{related_resultsets} ||= {};
2559   return $self->{related_resultsets}{$rel} ||= do {
2560     my $rel_info = $self->result_source->relationship_info($rel);
2561
2562     $self->throw_exception(
2563       "search_related: result source '" . $self->result_source->source_name .
2564         "' has no such relationship $rel")
2565       unless $rel_info;
2566
2567     my ($from,$seen) = $self->_chain_relationship($rel);
2568
2569     my $join_count = $seen->{$rel};
2570     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2571
2572     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2573     my %attrs = %{$self->{attrs}||{}};
2574     delete @attrs{qw(result_class alias)};
2575
2576     my $new_cache;
2577
2578     if (my $cache = $self->get_cache) {
2579       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2580         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2581                         @$cache ];
2582       }
2583     }
2584
2585     my $rel_source = $self->result_source->related_source($rel);
2586
2587     my $new = do {
2588
2589       # The reason we do this now instead of passing the alias to the
2590       # search_rs below is that if you wrap/overload resultset on the
2591       # source you need to know what alias it's -going- to have for things
2592       # to work sanely (e.g. RestrictWithObject wants to be able to add
2593       # extra query restrictions, and these may need to be $alias.)
2594
2595       my $attrs = $rel_source->resultset_attributes;
2596       local $attrs->{alias} = $alias;
2597
2598       $rel_source->resultset
2599                  ->search_rs(
2600                      undef, {
2601                        %attrs,
2602                        join => undef,
2603                        prefetch => undef,
2604                        select => undef,
2605                        as => undef,
2606                        where => $self->{cond},
2607                        seen_join => $seen,
2608                        from => $from,
2609                    });
2610     };
2611     $new->set_cache($new_cache) if $new_cache;
2612     $new;
2613   };
2614 }
2615
2616 =head2 current_source_alias
2617
2618 =over 4
2619
2620 =item Arguments: none
2621
2622 =item Return Value: $source_alias
2623
2624 =back
2625
2626 Returns the current table alias for the result source this resultset is built
2627 on, that will be used in the SQL query. Usually it is C<me>.
2628
2629 Currently the source alias that refers to the result set returned by a
2630 L</search>/L</find> family method depends on how you got to the resultset: it's
2631 C<me> by default, but eg. L</search_related> aliases it to the related result
2632 source name (and keeps C<me> referring to the original result set). The long
2633 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2634 (and make this method unnecessary).
2635
2636 Thus it's currently necessary to use this method in predefined queries (see
2637 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2638 source alias of the current result set:
2639
2640   # in a result set class
2641   sub modified_by {
2642     my ($self, $user) = @_;
2643
2644     my $me = $self->current_source_alias;
2645
2646     return $self->search(
2647       "$me.modified" => $user->id,
2648     );
2649   }
2650
2651 =cut
2652
2653 sub current_source_alias {
2654   my ($self) = @_;
2655
2656   return ($self->{attrs} || {})->{alias} || 'me';
2657 }
2658
2659 # This code is called by search_related, and makes sure there
2660 # is clear separation between the joins before, during, and
2661 # after the relationship. This information is needed later
2662 # in order to properly resolve prefetch aliases (any alias
2663 # with a relation_chain_depth less than the depth of the
2664 # current prefetch is not considered)
2665 #
2666 # The increments happen in 1/2s to make it easier to correlate the
2667 # join depth with the join path. An integer means a relationship
2668 # specified via a search_related, whereas a fraction means an added
2669 # join/prefetch via attributes
2670 sub _chain_relationship {
2671   my ($self, $rel) = @_;
2672   my $source = $self->result_source;
2673   my $attrs = $self->{attrs};
2674
2675   my $from = [ @{
2676       $attrs->{from}
2677         ||
2678       [{
2679         -source_handle => $source->handle,
2680         -alias => $attrs->{alias},
2681         $attrs->{alias} => $source->from,
2682       }]
2683   }];
2684
2685   my $seen = { %{$attrs->{seen_join} || {} } };
2686   my $jpath = ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2687     ? $from->[-1][0]{-join_path}
2688     : [];
2689
2690
2691   # we need to take the prefetch the attrs into account before we
2692   # ->_resolve_join as otherwise they get lost - captainL
2693   my $merged = $self->_merge_attr( $attrs->{join}, $attrs->{prefetch} );
2694
2695   my @requested_joins = $source->_resolve_join(
2696     $merged,
2697     $attrs->{alias},
2698     $seen,
2699     $jpath,
2700   );
2701
2702   push @$from, @requested_joins;
2703
2704   $seen->{-relation_chain_depth} += 0.5;
2705
2706   # if $self already had a join/prefetch specified on it, the requested
2707   # $rel might very well be already included. What we do in this case
2708   # is effectively a no-op (except that we bump up the chain_depth on
2709   # the join in question so we could tell it *is* the search_related)
2710   my $already_joined;
2711
2712
2713   # we consider the last one thus reverse
2714   for my $j (reverse @requested_joins) {
2715     if ($rel eq $j->[0]{-join_path}[-1]) {
2716       $j->[0]{-relation_chain_depth} += 0.5;
2717       $already_joined++;
2718       last;
2719     }
2720   }
2721
2722 # alternative way to scan the entire chain - not backwards compatible
2723 #  for my $j (reverse @$from) {
2724 #    next unless ref $j eq 'ARRAY';
2725 #    if ($j->[0]{-join_path} && $j->[0]{-join_path}[-1] eq $rel) {
2726 #      $j->[0]{-relation_chain_depth} += 0.5;
2727 #      $already_joined++;
2728 #      last;
2729 #    }
2730 #  }
2731
2732   unless ($already_joined) {
2733     push @$from, $source->_resolve_join(
2734       $rel,
2735       $attrs->{alias},
2736       $seen,
2737       $jpath,
2738     );
2739   }
2740
2741   $seen->{-relation_chain_depth} += 0.5;
2742
2743   return ($from,$seen);
2744 }
2745
2746 # too many times we have to do $attrs = { %{$self->_resolved_attrs} }
2747 sub _resolved_attrs_copy {
2748   my $self = shift;
2749   return { %{$self->_resolved_attrs (@_)} };
2750 }
2751
2752 sub _resolved_attrs {
2753   my $self = shift;
2754   return $self->{_attrs} if $self->{_attrs};
2755
2756   my $attrs  = { %{ $self->{attrs} || {} } };
2757   my $source = $self->result_source;
2758   my $alias  = $attrs->{alias};
2759
2760   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2761   my @colbits;
2762
2763   # build columns (as long as select isn't set) into a set of as/select hashes
2764   unless ( $attrs->{select} ) {
2765       @colbits = map {
2766           ( ref($_) eq 'HASH' )
2767               ? $_
2768               : {
2769                   (
2770                     /^\Q${alias}.\E(.+)$/
2771                       ? "$1"
2772                       : "$_"
2773                   )
2774                 =>
2775                   (
2776                     /\./
2777                       ? "$_"
2778                       : "${alias}.$_"
2779                   )
2780             }
2781       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2782   }
2783   # add the additional columns on
2784   foreach ( 'include_columns', '+columns' ) {
2785       push @colbits, map {
2786           ( ref($_) eq 'HASH' )
2787             ? $_
2788             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2789       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2790   }
2791
2792   # start with initial select items
2793   if ( $attrs->{select} ) {
2794     $attrs->{select} =
2795         ( ref $attrs->{select} eq 'ARRAY' )
2796       ? [ @{ $attrs->{select} } ]
2797       : [ $attrs->{select} ];
2798     $attrs->{as} = (
2799       $attrs->{as}
2800       ? (
2801         ref $attrs->{as} eq 'ARRAY'
2802         ? [ @{ $attrs->{as} } ]
2803         : [ $attrs->{as} ]
2804         )
2805       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2806     );
2807   }
2808   else {
2809
2810     # otherwise we intialise select & as to empty
2811     $attrs->{select} = [];
2812     $attrs->{as}     = [];
2813   }
2814
2815   # now add colbits to select/as
2816   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2817   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2818
2819   my $adds;
2820   if ( $adds = delete $attrs->{'+select'} ) {
2821     $adds = [$adds] unless ref $adds eq 'ARRAY';
2822     push(
2823       @{ $attrs->{select} },
2824       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2825     );
2826   }
2827   if ( $adds = delete $attrs->{'+as'} ) {
2828     $adds = [$adds] unless ref $adds eq 'ARRAY';
2829     push( @{ $attrs->{as} }, @$adds );
2830   }
2831
2832   $attrs->{from} ||= [ {
2833     -source_handle => $source->handle,
2834     -alias => $self->{attrs}{alias},
2835     $self->{attrs}{alias} => $source->from,
2836   } ];
2837
2838   if ( $attrs->{join} || $attrs->{prefetch} ) {
2839
2840     $self->throw_exception ('join/prefetch can not be used with a literal scalarref {from}')
2841       if ref $attrs->{from} ne 'ARRAY';
2842
2843     my $join = delete $attrs->{join} || {};
2844
2845     if ( defined $attrs->{prefetch} ) {
2846       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2847     }
2848
2849     $attrs->{from} =    # have to copy here to avoid corrupting the original
2850       [
2851         @{ $attrs->{from} },
2852         $source->_resolve_join(
2853           $join,
2854           $alias,
2855           { %{ $attrs->{seen_join} || {} } },
2856           ($attrs->{seen_join} && keys %{$attrs->{seen_join}})
2857             ? $attrs->{from}[-1][0]{-join_path}
2858             : []
2859           ,
2860         )
2861       ];
2862   }
2863
2864   if ( $attrs->{order_by} ) {
2865     $attrs->{order_by} = (
2866       ref( $attrs->{order_by} ) eq 'ARRAY'
2867       ? [ @{ $attrs->{order_by} } ]
2868       : [ $attrs->{order_by} ]
2869     );
2870   }
2871
2872   if ($attrs->{group_by} and ! ref $attrs->{group_by}) {
2873     $attrs->{group_by} = [ $attrs->{group_by} ];
2874   }
2875
2876   # If the order_by is otherwise empty - we will use this for TOP limit
2877   # emulation and the like.
2878   # Although this is needed only if the order_by is not defined, it is
2879   # actually cheaper to just populate this rather than properly examining
2880   # order_by (stuf like [ {} ] and the like)
2881   my $prefix = $alias . ($source->schema->storage->sql_maker->{name_sep} || '.');
2882   $attrs->{_virtual_order_by} = [
2883     map { $prefix . $_ } ($source->primary_columns)
2884   ];
2885
2886   $attrs->{collapse} ||= {};
2887   if ( my $prefetch = delete $attrs->{prefetch} ) {
2888     $prefetch = $self->_merge_attr( {}, $prefetch );
2889
2890     my $prefetch_ordering = [];
2891
2892     my $join_map = $self->_joinpath_aliases ($attrs->{from}, $attrs->{seen_join});
2893
2894     my @prefetch =
2895       $source->_resolve_prefetch( $prefetch, $alias, $join_map, $prefetch_ordering, $attrs->{collapse} );
2896
2897     $attrs->{prefetch_select} = [ map { $_->[0] } @prefetch ];
2898     push @{ $attrs->{select} }, @{$attrs->{prefetch_select}};
2899     push @{ $attrs->{as} }, (map { $_->[1] } @prefetch);
2900
2901     push( @{ $attrs->{order_by} }, @$prefetch_ordering );
2902     $attrs->{_collapse_order_by} = \@$prefetch_ordering;
2903   }
2904
2905
2906   if (delete $attrs->{distinct}) {
2907     $attrs->{group_by} ||= [ grep { !ref($_) || (ref($_) ne 'HASH') } @{$attrs->{select}} ];
2908   }
2909
2910   # if both page and offset are specified, produce a combined offset
2911   # even though it doesn't make much sense, this is what pre 081xx has
2912   # been doing
2913   if (my $page = delete $attrs->{page}) {
2914     $attrs->{offset} =
2915       ($attrs->{rows} * ($page - 1))
2916             +
2917       ($attrs->{offset} || 0)
2918     ;
2919   }
2920
2921   return $self->{_attrs} = $attrs;
2922 }
2923
2924 sub _joinpath_aliases {
2925   my ($self, $fromspec, $seen) = @_;
2926
2927   my $paths = {};
2928   return $paths unless ref $fromspec eq 'ARRAY';
2929
2930   my $cur_depth = $seen->{-relation_chain_depth} || 0;
2931
2932   if (int ($cur_depth) != $cur_depth) {
2933     $self->throw_exception ("-relation_chain_depth is not an integer, something went horribly wrong ($cur_depth)");
2934   }
2935
2936   for my $j (@$fromspec) {
2937
2938     next if ref $j ne 'ARRAY';
2939     next if $j->[0]{-relation_chain_depth} < $cur_depth;
2940
2941     my $jpath = $j->[0]{-join_path};
2942
2943     my $p = $paths;
2944     $p = $p->{$_} ||= {} for @{$jpath}[$cur_depth .. $#$jpath];
2945     push @{$p->{-join_aliases} }, $j->[0]{-alias};
2946   }
2947
2948   return $paths;
2949 }
2950
2951 sub _rollout_attr {
2952   my ($self, $attr) = @_;
2953
2954   if (ref $attr eq 'HASH') {
2955     return $self->_rollout_hash($attr);
2956   } elsif (ref $attr eq 'ARRAY') {
2957     return $self->_rollout_array($attr);
2958   } else {
2959     return [$attr];
2960   }
2961 }
2962
2963 sub _rollout_array {
2964   my ($self, $attr) = @_;
2965
2966   my @rolled_array;
2967   foreach my $element (@{$attr}) {
2968     if (ref $element eq 'HASH') {
2969       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2970     } elsif (ref $element eq 'ARRAY') {
2971       #  XXX - should probably recurse here
2972       push( @rolled_array, @{$self->_rollout_array($element)} );
2973     } else {
2974       push( @rolled_array, $element );
2975     }
2976   }
2977   return \@rolled_array;
2978 }
2979
2980 sub _rollout_hash {
2981   my ($self, $attr) = @_;
2982
2983   my @rolled_array;
2984   foreach my $key (keys %{$attr}) {
2985     push( @rolled_array, { $key => $attr->{$key} } );
2986   }
2987   return \@rolled_array;
2988 }
2989
2990 sub _calculate_score {
2991   my ($self, $a, $b) = @_;
2992
2993   if (ref $b eq 'HASH') {
2994     my ($b_key) = keys %{$b};
2995     if (ref $a eq 'HASH') {
2996       my ($a_key) = keys %{$a};
2997       if ($a_key eq $b_key) {
2998         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2999       } else {
3000         return 0;
3001       }
3002     } else {
3003       return ($a eq $b_key) ? 1 : 0;
3004     }
3005   } else {
3006     if (ref $a eq 'HASH') {
3007       my ($a_key) = keys %{$a};
3008       return ($b eq $a_key) ? 1 : 0;
3009     } else {
3010       return ($b eq $a) ? 1 : 0;
3011     }
3012   }
3013 }
3014
3015 sub _merge_attr {
3016   my ($self, $orig, $import) = @_;
3017
3018   return $import unless defined($orig);
3019   return $orig unless defined($import);
3020
3021   $orig = $self->_rollout_attr($orig);
3022   $import = $self->_rollout_attr($import);
3023
3024   my $seen_keys;
3025   foreach my $import_element ( @{$import} ) {
3026     # find best candidate from $orig to merge $b_element into
3027     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
3028     foreach my $orig_element ( @{$orig} ) {
3029       my $score = $self->_calculate_score( $orig_element, $import_element );
3030       if ($score > $best_candidate->{score}) {
3031         $best_candidate->{position} = $position;
3032         $best_candidate->{score} = $score;
3033       }
3034       $position++;
3035     }
3036     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
3037
3038     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
3039       push( @{$orig}, $import_element );
3040     } else {
3041       my $orig_best = $orig->[$best_candidate->{position}];
3042       # merge orig_best and b_element together and replace original with merged
3043       if (ref $orig_best ne 'HASH') {
3044         $orig->[$best_candidate->{position}] = $import_element;
3045       } elsif (ref $import_element eq 'HASH') {
3046         my ($key) = keys %{$orig_best};
3047         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
3048       }
3049     }
3050     $seen_keys->{$import_key} = 1; # don't merge the same key twice
3051   }
3052
3053   return $orig;
3054 }
3055
3056 sub result_source {
3057     my $self = shift;
3058
3059     if (@_) {
3060         $self->_source_handle($_[0]->handle);
3061     } else {
3062         $self->_source_handle->resolve;
3063     }
3064 }
3065
3066 =head2 throw_exception
3067
3068 See L<DBIx::Class::Schema/throw_exception> for details.
3069
3070 =cut
3071
3072 sub throw_exception {
3073   my $self=shift;
3074   if (ref $self && $self->_source_handle->schema) {
3075     $self->_source_handle->schema->throw_exception(@_)
3076   } else {
3077     croak(@_);
3078   }
3079
3080 }
3081
3082 # XXX: FIXME: Attributes docs need clearing up
3083
3084 =head1 ATTRIBUTES
3085
3086 Attributes are used to refine a ResultSet in various ways when
3087 searching for data. They can be passed to any method which takes an
3088 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
3089 L</count>.
3090
3091 These are in no particular order:
3092
3093 =head2 order_by
3094
3095 =over 4
3096
3097 =item Value: ( $order_by | \@order_by | \%order_by )
3098
3099 =back
3100
3101 Which column(s) to order the results by. If a single column name, or
3102 an arrayref of names is supplied, the argument is passed through
3103 directly to SQL. The hashref syntax allows for connection-agnostic
3104 specification of ordering direction:
3105
3106  For descending order:
3107
3108   order_by => { -desc => [qw/col1 col2 col3/] }
3109
3110  For explicit ascending order:
3111
3112   order_by => { -asc => 'col' }
3113
3114 The old scalarref syntax (i.e. order_by => \'year DESC') is still
3115 supported, although you are strongly encouraged to use the hashref
3116 syntax as outlined above.
3117
3118 =head2 columns
3119
3120 =over 4
3121
3122 =item Value: \@columns
3123
3124 =back
3125
3126 Shortcut to request a particular set of columns to be retrieved. Each
3127 column spec may be a string (a table column name), or a hash (in which
3128 case the key is the C<as> value, and the value is used as the C<select>
3129 expression). Adds C<me.> onto the start of any column without a C<.> in
3130 it and sets C<select> from that, then auto-populates C<as> from
3131 C<select> as normal. (You may also use the C<cols> attribute, as in
3132 earlier versions of DBIC.)
3133
3134 =head2 +columns
3135
3136 =over 4
3137
3138 =item Value: \@columns
3139
3140 =back
3141
3142 Indicates additional columns to be selected from storage. Works the same
3143 as L</columns> but adds columns to the selection. (You may also use the
3144 C<include_columns> attribute, as in earlier versions of DBIC). For
3145 example:-
3146
3147   $schema->resultset('CD')->search(undef, {
3148     '+columns' => ['artist.name'],
3149     join => ['artist']
3150   });
3151
3152 would return all CDs and include a 'name' column to the information
3153 passed to object inflation. Note that the 'artist' is the name of the
3154 column (or relationship) accessor, and 'name' is the name of the column
3155 accessor in the related table.
3156
3157 =head2 include_columns
3158
3159 =over 4
3160
3161 =item Value: \@columns
3162
3163 =back
3164
3165 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
3166
3167 =head2 select
3168
3169 =over 4
3170
3171 =item Value: \@select_columns
3172
3173 =back
3174
3175 Indicates which columns should be selected from the storage. You can use
3176 column names, or in the case of RDBMS back ends, function or stored procedure
3177 names:
3178
3179   $rs = $schema->resultset('Employee')->search(undef, {
3180     select => [
3181       'name',
3182       { count => 'employeeid' },
3183       { sum => 'salary' }
3184     ]
3185   });
3186
3187 When you use function/stored procedure names and do not supply an C<as>
3188 attribute, the column names returned are storage-dependent. E.g. MySQL would
3189 return a column named C<count(employeeid)> in the above example.
3190
3191 =head2 +select
3192
3193 =over 4
3194
3195 Indicates additional columns to be selected from storage.  Works the same as
3196 L</select> but adds columns to the selection.
3197
3198 =back
3199
3200 =head2 +as
3201
3202 =over 4
3203
3204 Indicates additional column names for those added via L</+select>. See L</as>.
3205
3206 =back
3207
3208 =head2 as
3209
3210 =over 4
3211
3212 =item Value: \@inflation_names
3213
3214 =back
3215
3216 Indicates column names for object inflation. That is, C<as>
3217 indicates the name that the column can be accessed as via the
3218 C<get_column> method (or via the object accessor, B<if one already
3219 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
3220
3221 The C<as> attribute is used in conjunction with C<select>,
3222 usually when C<select> contains one or more function or stored
3223 procedure names:
3224
3225   $rs = $schema->resultset('Employee')->search(undef, {
3226     select => [
3227       'name',
3228       { count => 'employeeid' }
3229     ],
3230     as => ['name', 'employee_count'],
3231   });
3232
3233   my $employee = $rs->first(); # get the first Employee
3234
3235 If the object against which the search is performed already has an accessor
3236 matching a column name specified in C<as>, the value can be retrieved using
3237 the accessor as normal:
3238
3239   my $name = $employee->name();
3240
3241 If on the other hand an accessor does not exist in the object, you need to
3242 use C<get_column> instead:
3243
3244   my $employee_count = $employee->get_column('employee_count');
3245
3246 You can create your own accessors if required - see
3247 L<DBIx::Class::Manual::Cookbook> for details.
3248
3249 Please note: This will NOT insert an C<AS employee_count> into the SQL
3250 statement produced, it is used for internal access only. Thus
3251 attempting to use the accessor in an C<order_by> clause or similar
3252 will fail miserably.
3253
3254 To get around this limitation, you can supply literal SQL to your
3255 C<select> attibute that contains the C<AS alias> text, eg:
3256
3257   select => [\'myfield AS alias']
3258
3259 =head2 join
3260
3261 =over 4
3262
3263 =item Value: ($rel_name | \@rel_names | \%rel_names)
3264
3265 =back
3266
3267 Contains a list of relationships that should be joined for this query.  For
3268 example:
3269
3270   # Get CDs by Nine Inch Nails
3271   my $rs = $schema->resultset('CD')->search(
3272     { 'artist.name' => 'Nine Inch Nails' },
3273     { join => 'artist' }
3274   );
3275
3276 Can also contain a hash reference to refer to the other relation's relations.
3277 For example:
3278
3279   package MyApp::Schema::Track;
3280   use base qw/DBIx::Class/;
3281   __PACKAGE__->table('track');
3282   __PACKAGE__->add_columns(qw/trackid cd position title/);
3283   __PACKAGE__->set_primary_key('trackid');
3284   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
3285   1;
3286
3287   # In your application
3288   my $rs = $schema->resultset('Artist')->search(
3289     { 'track.title' => 'Teardrop' },
3290     {
3291       join     => { cd => 'track' },
3292       order_by => 'artist.name',
3293     }
3294   );
3295
3296 You need to use the relationship (not the table) name in  conditions,
3297 because they are aliased as such. The current table is aliased as "me", so
3298 you need to use me.column_name in order to avoid ambiguity. For example:
3299
3300   # Get CDs from 1984 with a 'Foo' track
3301   my $rs = $schema->resultset('CD')->search(
3302     {
3303       'me.year' => 1984,
3304       'tracks.name' => 'Foo'
3305     },
3306     { join => 'tracks' }
3307   );
3308
3309 If the same join is supplied twice, it will be aliased to <rel>_2 (and
3310 similarly for a third time). For e.g.
3311
3312   my $rs = $schema->resultset('Artist')->search({
3313     'cds.title'   => 'Down to Earth',
3314     'cds_2.title' => 'Popular',
3315   }, {
3316     join => [ qw/cds cds/ ],
3317   });
3318
3319 will return a set of all artists that have both a cd with title 'Down
3320 to Earth' and a cd with title 'Popular'.
3321
3322 If you want to fetch related objects from other tables as well, see C<prefetch>
3323 below.
3324
3325 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
3326
3327 =head2 prefetch
3328
3329 =over 4
3330
3331 =item Value: ($rel_name | \@rel_names | \%rel_names)
3332
3333 =back
3334
3335 Contains one or more relationships that should be fetched along with
3336 the main query (when they are accessed afterwards the data will
3337 already be available, without extra queries to the database).  This is
3338 useful for when you know you will need the related objects, because it
3339 saves at least one query:
3340
3341   my $rs = $schema->resultset('Tag')->search(
3342     undef,
3343     {
3344       prefetch => {
3345         cd => 'artist'
3346       }
3347     }
3348   );
3349
3350 The initial search results in SQL like the following:
3351
3352   SELECT tag.*, cd.*, artist.* FROM tag
3353   JOIN cd ON tag.cd = cd.cdid
3354   JOIN artist ON cd.artist = artist.artistid
3355
3356 L<DBIx::Class> has no need to go back to the database when we access the
3357 C<cd> or C<artist> relationships, which saves us two SQL statements in this
3358 case.
3359
3360 Simple prefetches will be joined automatically, so there is no need
3361 for a C<join> attribute in the above search.
3362
3363 C<prefetch> can be used with the following relationship types: C<belongs_to>,
3364 C<has_one> (or if you're using C<add_relationship>, any relationship declared
3365 with an accessor type of 'single' or 'filter'). A more complex example that
3366 prefetches an artists cds, the tracks on those cds, and the tags associted
3367 with that artist is given below (assuming many-to-many from artists to tags):
3368
3369  my $rs = $schema->resultset('Artist')->search(
3370    undef,
3371    {
3372      prefetch => [
3373        { cds => 'tracks' },
3374        { artist_tags => 'tags' }
3375      ]
3376    }
3377  );
3378
3379
3380 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
3381 attributes will be ignored.
3382
3383 =head2 page
3384
3385 =over 4
3386
3387 =item Value: $page
3388
3389 =back
3390
3391 Makes the resultset paged and specifies the page to retrieve. Effectively
3392 identical to creating a non-pages resultset and then calling ->page($page)
3393 on it.
3394
3395 If L<rows> attribute is not specified it defaults to 10 rows per page.
3396
3397 When you have a paged resultset, L</count> will only return the number
3398 of rows in the page. To get the total, use the L</pager> and call
3399 C<total_entries> on it.
3400
3401 =head2 rows
3402
3403 =over 4
3404
3405 =item Value: $rows
3406
3407 =back
3408
3409 Specifes the maximum number of rows for direct retrieval or the number of
3410 rows per page if the page attribute or method is used.
3411
3412 =head2 offset
3413
3414 =over 4
3415
3416 =item Value: $offset
3417
3418 =back
3419
3420 Specifies the (zero-based) row number for the  first row to be returned, or the
3421 of the first row of the first page if paging is used.
3422
3423 =head2 group_by
3424
3425 =over 4
3426
3427 =item Value: \@columns
3428
3429 =back
3430
3431 A arrayref of columns to group by. Can include columns of joined tables.
3432
3433   group_by => [qw/ column1 column2 ... /]
3434
3435 =head2 having
3436
3437 =over 4
3438
3439 =item Value: $condition
3440
3441 =back
3442
3443 HAVING is a select statement attribute that is applied between GROUP BY and
3444 ORDER BY. It is applied to the after the grouping calculations have been
3445 done.
3446
3447   having => { 'count(employee)' => { '>=', 100 } }
3448
3449 =head2 distinct
3450
3451 =over 4
3452
3453 =item Value: (0 | 1)
3454
3455 =back
3456
3457 Set to 1 to group by all columns.
3458
3459 =head2 where
3460
3461 =over 4
3462
3463 Adds to the WHERE clause.
3464
3465   # only return rows WHERE deleted IS NULL for all searches
3466   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3467
3468 Can be overridden by passing C<{ where => undef }> as an attribute
3469 to a resulset.
3470
3471 =back
3472
3473 =head2 cache
3474
3475 Set to 1 to cache search results. This prevents extra SQL queries if you
3476 revisit rows in your ResultSet:
3477
3478   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3479
3480   while( my $artist = $resultset->next ) {
3481     ... do stuff ...
3482   }
3483
3484   $rs->first; # without cache, this would issue a query
3485
3486 By default, searches are not cached.
3487
3488 For more examples of using these attributes, see
3489 L<DBIx::Class::Manual::Cookbook>.
3490
3491 =head2 from
3492
3493 =over 4
3494
3495 =item Value: \@from_clause
3496
3497 =back
3498
3499 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3500 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3501 clauses.
3502
3503 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3504
3505 C<join> will usually do what you need and it is strongly recommended that you
3506 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3507 And we really do mean "cannot", not just tried and failed. Attempting to use
3508 this because you're having problems with C<join> is like trying to use x86
3509 ASM because you've got a syntax error in your C. Trust us on this.
3510
3511 Now, if you're still really, really sure you need to use this (and if you're
3512 not 100% sure, ask the mailing list first), here's an explanation of how this
3513 works.
3514
3515 The syntax is as follows -
3516
3517   [
3518     { <alias1> => <table1> },
3519     [
3520       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3521       [], # nested JOIN (optional)
3522       { <table1.column1> => <table2.column2>, ... (more conditions) },
3523     ],
3524     # More of the above [ ] may follow for additional joins
3525   ]
3526
3527   <table1> <alias1>
3528   JOIN
3529     <table2> <alias2>
3530     [JOIN ...]
3531   ON <table1.column1> = <table2.column2>
3532   <more joins may follow>
3533
3534 An easy way to follow the examples below is to remember the following:
3535
3536     Anything inside "[]" is a JOIN
3537     Anything inside "{}" is a condition for the enclosing JOIN
3538
3539 The following examples utilize a "person" table in a family tree application.
3540 In order to express parent->child relationships, this table is self-joined:
3541
3542     # Person->belongs_to('father' => 'Person');
3543     # Person->belongs_to('mother' => 'Person');
3544
3545 C<from> can be used to nest joins. Here we return all children with a father,
3546 then search against all mothers of those children:
3547
3548   $rs = $schema->resultset('Person')->search(
3549       undef,
3550       {
3551           alias => 'mother', # alias columns in accordance with "from"
3552           from => [
3553               { mother => 'person' },
3554               [
3555                   [
3556                       { child => 'person' },
3557                       [
3558                           { father => 'person' },
3559                           { 'father.person_id' => 'child.father_id' }
3560                       ]
3561                   ],
3562                   { 'mother.person_id' => 'child.mother_id' }
3563               ],
3564           ]
3565       },
3566   );
3567
3568   # Equivalent SQL:
3569   # SELECT mother.* FROM person mother
3570   # JOIN (
3571   #   person child
3572   #   JOIN person father
3573   #   ON ( father.person_id = child.father_id )
3574   # )
3575   # ON ( mother.person_id = child.mother_id )
3576
3577 The type of any join can be controlled manually. To search against only people
3578 with a father in the person table, we could explicitly use C<INNER JOIN>:
3579
3580     $rs = $schema->resultset('Person')->search(
3581         undef,
3582         {
3583             alias => 'child', # alias columns in accordance with "from"
3584             from => [
3585                 { child => 'person' },
3586                 [
3587                     { father => 'person', -join_type => 'inner' },
3588                     { 'father.id' => 'child.father_id' }
3589                 ],
3590             ]
3591         },
3592     );
3593
3594     # Equivalent SQL:
3595     # SELECT child.* FROM person child
3596     # INNER JOIN person father ON child.father_id = father.id
3597
3598 You can select from a subquery by passing a resultset to from as follows.
3599
3600     $schema->resultset('Artist')->search(
3601         undef,
3602         {   alias => 'artist2',
3603             from  => [ { artist2 => $artist_rs->as_query } ],
3604         } );
3605
3606     # and you'll get sql like this..
3607     # SELECT artist2.artistid, artist2.name, artist2.rank, artist2.charfield FROM
3608     #   ( SELECT me.artistid, me.name, me.rank, me.charfield FROM artists me ) artist2
3609
3610 If you need to express really complex joins, you
3611 can supply literal SQL to C<from> via a scalar reference. In this case
3612 the contents of the scalar will replace the table name associated with the
3613 resultsource.
3614
3615 WARNING: This technique might very well not work as expected on chained
3616 searches - you have been warned.
3617
3618     # Assuming the Event resultsource is defined as:
3619
3620         MySchema::Event->add_columns (
3621             sequence => {
3622                 data_type => 'INT',
3623                 is_auto_increment => 1,
3624             },
3625             location => {
3626                 data_type => 'INT',
3627             },
3628             type => {
3629                 data_type => 'INT',
3630             },
3631         );
3632         MySchema::Event->set_primary_key ('sequence');
3633
3634     # This will get back the latest event for every location. The column
3635     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3636     # combo to limit the resultset
3637
3638     $rs = $schema->resultset('Event');
3639     $table = $rs->result_source->name;
3640     $latest = $rs->search (
3641         undef,
3642         { from => \ "
3643             (SELECT e1.* FROM $table e1
3644                 JOIN $table e2
3645                     ON e1.location = e2.location
3646                     AND e1.sequence < e2.sequence
3647                 WHERE e2.sequence is NULL
3648             ) me",
3649         },
3650     );
3651
3652     # Equivalent SQL (with the DBIC chunks added):
3653
3654     SELECT me.sequence, me.location, me.type FROM
3655        (SELECT e1.* FROM events e1
3656            JOIN events e2
3657                ON e1.location = e2.location
3658                AND e1.sequence < e2.sequence
3659            WHERE e2.sequence is NULL
3660        ) me;
3661
3662 =head2 for
3663
3664 =over 4
3665
3666 =item Value: ( 'update' | 'shared' )
3667
3668 =back
3669
3670 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3671 ... FOR SHARED.
3672
3673 =cut
3674
3675 1;