lib/DBIx/Class/ResultSet.pm

   1 package DBIx::Class::ResultSet;
   2
   3 use strict;
   4 use warnings;
   5 use overload
   6         '0+'     => "count",
   7         'bool'   => "_bool",
   8         fallback => 1;
   9 use Carp::Clan qw/^DBIx::Class/;
  10 use Data::Page;
  11 use Storable;
  12 use DBIx::Class::ResultSetColumn;
  13 use DBIx::Class::ResultSourceHandle;
  14 use List::Util ();
  15 use Scalar::Util ();
  16 use base qw/DBIx::Class/;
  17
  18 __PACKAGE__->mk_group_accessors('simple' => qw/_result_class _source_handle/);
  19
  20 =head1 NAME
  21
  22 DBIx::Class::ResultSet - Represents a query used for fetching a set of results.
  23
  24 =head1 SYNOPSIS
  25
  26   my $users_rs   = $schema->resultset('User');
  27   my $registered_users_rs   = $schema->resultset('User')->search({ registered => 1 });
  28   my @cds_in_2005 = $schema->resultset('CD')->search({ year => 2005 })->all();
  29
  30 =head1 DESCRIPTION
  31
  32 A ResultSet is an object which stores a set of conditions representing
  33 a query. It is the backbone of DBIx::Class (i.e. the really
  34 important/useful bit).
  35
  36 No SQL is executed on the database when a ResultSet is created, it
  37 just stores all the conditions needed to create the query.
  38
  39 A basic ResultSet representing the data of an entire table is returned
  40 by calling C<resultset> on a L<DBIx::Class::Schema> and passing in a
  41 L<Source|DBIx::Class::Manual::Glossary/Source> name.
  42
  43   my $users_rs = $schema->resultset('User');
  44
  45 A new ResultSet is returned from calling L</search> on an existing
  46 ResultSet. The new one will contain all the conditions of the
  47 original, plus any new conditions added in the C<search> call.
  48
  49 A ResultSet is also an iterator. L</next> is used to return all the
  50 L<DBIx::Class::Row>s the ResultSet represents.
  51
  52 The query that the ResultSet represents is B<only> executed against
  53 the database when these methods are called:
  54
  55 =over
  56
  57 =item L</find>
  58
  59 =item L</next>
  60
  61 =item L</all>
  62
  63 =item L</count>
  64
  65 =item L</single>
  66
  67 =item L</first>
  68
  69 =back
  70
  71 =head1 EXAMPLES
  72
  73 =head2 Chaining resultsets
  74
  75 Let's say you've got a query that needs to be run to return some data
  76 to the user. But, you have an authorization system in place that
  77 prevents certain users from seeing certain information. So, you want
  78 to construct the basic query in one method, but add constraints to it in
  79 another.
  80
  81   sub get_data {
  82     my $self = shift;
  83     my $request = $self->get_request; # Get a request object somehow.
  84     my $schema = $self->get_schema;   # Get the DBIC schema object somehow.
  85
  86     my $cd_rs = $schema->resultset('CD')->search({
  87       title => $request->param('title'),
  88       year => $request->param('year'),
  89     });
  90
  91     $self->apply_security_policy( $cd_rs );
  92
  93     return $cd_rs->all();
  94   }
  95
  96   sub apply_security_policy {
  97     my $self = shift;
  98     my ($rs) = @_;
  99
 100     return $rs->search({
 101       subversive => 0,
 102     });
 103   }
 104
 105 =head3 Resolving conditions and attributes
 106
 107 When a resultset is chained from another resultset, conditions and
 108 attributes with the same keys need resolving.
 109
 110 L</join>, L</prefetch>, L</+select>, L</+as> attributes are merged
 111 into the existing ones from the original resultset.
 112
 113 The L</where>, L</having> attribute, and any search conditions are
 114 merged with an SQL C<AND> to the existing condition from the original
 115 resultset.
 116
 117 All other attributes are overridden by any new ones supplied in the
 118 search attributes.
 119
 120 =head2 Multiple queries
 121
 122 Since a resultset just defines a query, you can do all sorts of
 123 things with it with the same object.
 124
 125   # Don't hit the DB yet.
 126   my $cd_rs = $schema->resultset('CD')->search({
 127     title => 'something',
 128     year => 2009,
 129   });
 130
 131   # Each of these hits the DB individually.
 132   my $count = $cd_rs->count;
 133   my $most_recent = $cd_rs->get_column('date_released')->max();
 134   my @records = $cd_rs->all;
 135
 136 And it's not just limited to SELECT statements.
 137
 138   $cd_rs->delete();
 139
 140 This is even cooler:
 141
 142   $cd_rs->create({ artist => 'Fred' });
 143
 144 Which is the same as:
 145
 146   $schema->resultset('CD')->create({
 147     title => 'something',
 148     year => 2009,
 149     artist => 'Fred'
 150   });
 151
 152 See: L</search>, L</count>, L</get_column>, L</all>, L</create>.
 153
 154 =head1 OVERLOADING
 155
 156 If a resultset is used in a numeric context it returns the L</count>.
 157 However, if it is used in a booleand context it is always true.  So if
 158 you want to check if a resultset has any results use C<if $rs != 0>.
 159 C<if $rs> will always be true.
 160
 161 =head1 METHODS
 162
 163 =head2 new
 164
 165 =over 4
 166
 167 =item Arguments: $source, \%$attrs
 168
 169 =item Return Value: $rs
 170
 171 =back
 172
 173 The resultset constructor. Takes a source object (usually a
 174 L<DBIx::Class::ResultSourceProxy::Table>) and an attribute hash (see
 175 L</ATTRIBUTES> below).  Does not perform any queries -- these are
 176 executed as needed by the other methods.
 177
 178 Generally you won't need to construct a resultset manually.  You'll
 179 automatically get one from e.g. a L</search> called in scalar context:
 180
 181   my $rs = $schema->resultset('CD')->search({ title => '100th Window' });
 182
 183 IMPORTANT: If called on an object, proxies to new_result instead so
 184
 185   my $cd = $schema->resultset('CD')->new({ title => 'Spoon' });
 186
 187 will return a CD object, not a ResultSet.
 188
 189 =cut
 190
 191 sub new {
 192   my $class = shift;
 193   return $class->new_result(@_) if ref $class;
 194
 195   my ($source, $attrs) = @_;
 196   $source = $source->handle
 197     unless $source->isa('DBIx::Class::ResultSourceHandle');
 198   $attrs = { %{$attrs||{}} };
 199
 200   if ($attrs->{page}) {
 201     $attrs->{rows} ||= 10;
 202   }
 203
 204   $attrs->{alias} ||= 'me';
 205
 206   # Creation of {} and bless separated to mitigate RH perl bug
 207   # see https://bugzilla.redhat.com/show_bug.cgi?id=196836
 208   my $self = {
 209     _source_handle => $source,
 210     cond => $attrs->{where},
 211     count => undef,
 212     pager => undef,
 213     attrs => $attrs
 214   };
 215
 216   bless $self, $class;
 217
 218   $self->result_class(
 219     $attrs->{result_class} || $source->resolve->result_class
 220   );
 221
 222   return $self;
 223 }
 224
 225 =head2 search
 226
 227 =over 4
 228
 229 =item Arguments: $cond, \%attrs?
 230
 231 =item Return Value: $resultset (scalar context), @row_objs (list context)
 232
 233 =back
 234
 235   my @cds    = $cd_rs->search({ year => 2001 }); # "... WHERE year = 2001"
 236   my $new_rs = $cd_rs->search({ year => 2005 });
 237
 238   my $new_rs = $cd_rs->search([ { year => 2005 }, { year => 2004 } ]);
 239                  # year = 2005 OR year = 2004
 240
 241 If you need to pass in additional attributes but no additional condition,
 242 call it as C<search(undef, \%attrs)>.
 243
 244   # "SELECT name, artistid FROM $artist_table"
 245   my @all_artists = $schema->resultset('Artist')->search(undef, {
 246     columns => [qw/name artistid/],
 247   });
 248
 249 For a list of attributes that can be passed to C<search>, see
 250 L</ATTRIBUTES>. For more examples of using this function, see
 251 L<Searching|DBIx::Class::Manual::Cookbook/Searching>. For a complete
 252 documentation for the first argument, see L<SQL::Abstract>.
 253
 254 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
 255
 256 =cut
 257
 258 sub search {
 259   my $self = shift;
 260   my $rs = $self->search_rs( @_ );
 261   return (wantarray ? $rs->all : $rs);
 262 }
 263
 264 =head2 search_rs
 265
 266 =over 4
 267
 268 =item Arguments: $cond, \%attrs?
 269
 270 =item Return Value: $resultset
 271
 272 =back
 273
 274 This method does the same exact thing as search() except it will
 275 always return a resultset, even in list context.
 276
 277 =cut
 278
 279 sub search_rs {
 280   my $self = shift;
 281
 282   # Special-case handling for (undef, undef).
 283   if ( @_ == 2 && !defined $_[1] && !defined $_[0] ) {
 284     pop(@_); pop(@_);
 285   }
 286
 287   my $attrs = {};
 288   $attrs = pop(@_) if @_ > 1 and ref $_[$#_] eq 'HASH';
 289   my $our_attrs = { %{$self->{attrs}} };
 290   my $having = delete $our_attrs->{having};
 291   my $where = delete $our_attrs->{where};
 292
 293   my $rows;
 294
 295   my %safe = (alias => 1, cache => 1);
 296
 297   unless (
 298     (@_ && defined($_[0])) # @_ == () or (undef)
 299     ||
 300     (keys %$attrs # empty attrs or only 'safe' attrs
 301     && List::Util::first { !$safe{$_} } keys %$attrs)
 302   ) {
 303     # no search, effectively just a clone
 304     $rows = $self->get_cache;
 305   }
 306
 307   my $new_attrs = { %{$our_attrs}, %{$attrs} };
 308
 309   # merge new attrs into inherited
 310   foreach my $key (qw/join prefetch +select +as bind/) {
 311     next unless exists $attrs->{$key};
 312     $new_attrs->{$key} = $self->_merge_attr($our_attrs->{$key}, $attrs->{$key});
 313   }
 314
 315   my $cond = (@_
 316     ? (
 317         (@_ == 1 || ref $_[0] eq "HASH")
 318           ? (
 319               (ref $_[0] eq 'HASH')
 320                 ? (
 321                     (keys %{ $_[0] }  > 0)
 322                       ? shift
 323                       : undef
 324                    )
 325                 :  shift
 326              )
 327           : (
 328               (@_ % 2)
 329                 ? $self->throw_exception("Odd number of arguments to search")
 330                 : {@_}
 331              )
 332       )
 333     : undef
 334   );
 335
 336   if (defined $where) {
 337     $new_attrs->{where} = (
 338       defined $new_attrs->{where}
 339         ? { '-and' => [
 340               map {
 341                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 342               } $where, $new_attrs->{where}
 343             ]
 344           }
 345         : $where);
 346   }
 347
 348   if (defined $cond) {
 349     $new_attrs->{where} = (
 350       defined $new_attrs->{where}
 351         ? { '-and' => [
 352               map {
 353                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 354               } $cond, $new_attrs->{where}
 355             ]
 356           }
 357         : $cond);
 358   }
 359
 360   if (defined $having) {
 361     $new_attrs->{having} = (
 362       defined $new_attrs->{having}
 363         ? { '-and' => [
 364               map {
 365                 ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_
 366               } $having, $new_attrs->{having}
 367             ]
 368           }
 369         : $having);
 370   }
 371
 372   my $rs = (ref $self)->new($self->result_source, $new_attrs);
 373   if ($rows) {
 374     $rs->set_cache($rows);
 375   }
 376   return $rs;
 377 }
 378
 379 =head2 search_literal
 380
 381 =over 4
 382
 383 =item Arguments: $sql_fragment, @bind_values
 384
 385 =item Return Value: $resultset (scalar context), @row_objs (list context)
 386
 387 =back
 388
 389   my @cds   = $cd_rs->search_literal('year = ? AND title = ?', qw/2001 Reload/);
 390   my $newrs = $artist_rs->search_literal('name = ?', 'Metallica');
 391
 392 Pass a literal chunk of SQL to be added to the conditional part of the
 393 resultset query.
 394
 395 CAVEAT: C<search_literal> is provided for Class::DBI compatibility and should
 396 only be used in that context. C<search_literal> is a convenience method.
 397 It is equivalent to calling $schema->search(\[]), but if you want to ensure
 398 columns are bound correctly, use C<search>.
 399
 400 Example of how to use C<search> instead of C<search_literal>
 401
 402   my @cds = $cd_rs->search_literal('cdid = ? AND (artist = ? OR artist = ?)', (2, 1, 2));
 403   my @cds = $cd_rs->search(\[ 'cdid = ? AND (artist = ? OR artist = ?)', [ 'cdid', 2 ], [ 'artist', 1 ], [ 'artist', 2 ] ]);
 404
 405
 406 See L<DBIx::Class::Manual::Cookbook/Searching> and
 407 L<DBIx::Class::Manual::FAQ/Searching> for searching techniques that do not
 408 require C<search_literal>.
 409
 410 =cut
 411
 412 sub search_literal {
 413   my ($self, $sql, @bind) = @_;
 414   my $attr;
 415   if ( @bind && ref($bind[-1]) eq 'HASH' ) {
 416     $attr = pop @bind;
 417   }
 418   return $self->search(\[ $sql, map [ __DUMMY__ => $_ ], @bind ], ($attr || () ));
 419 }
 420
 421 =head2 find
 422
 423 =over 4
 424
 425 =item Arguments: @values | \%cols, \%attrs?
 426
 427 =item Return Value: $row_object | undef
 428
 429 =back
 430
 431 Finds a row based on its primary key or unique constraint. For example, to find
 432 a row by its primary key:
 433
 434   my $cd = $schema->resultset('CD')->find(5);
 435
 436 You can also find a row by a specific unique constraint using the C<key>
 437 attribute. For example:
 438
 439   my $cd = $schema->resultset('CD')->find('Massive Attack', 'Mezzanine', {
 440     key => 'cd_artist_title'
 441   });
 442
 443 Additionally, you can specify the columns explicitly by name:
 444
 445   my $cd = $schema->resultset('CD')->find(
 446     {
 447       artist => 'Massive Attack',
 448       title  => 'Mezzanine',
 449     },
 450     { key => 'cd_artist_title' }
 451   );
 452
 453 If the C<key> is specified as C<primary>, it searches only on the primary key.
 454
 455 If no C<key> is specified, it searches on all unique constraints defined on the
 456 source for which column data is provided, including the primary key.
 457
 458 If your table does not have a primary key, you B<must> provide a value for the
 459 C<key> attribute matching one of the unique constraints on the source.
 460
 461 In addition to C<key>, L</find> recognizes and applies standard
 462 L<resultset attributes|/ATTRIBUTES> in the same way as L</search> does.
 463
 464 Note: If your query does not return only one row, a warning is generated:
 465
 466   Query returned more than one row
 467
 468 See also L</find_or_create> and L</update_or_create>. For information on how to
 469 declare unique constraints, see
 470 L<DBIx::Class::ResultSource/add_unique_constraint>.
 471
 472 =cut
 473
 474 sub find {
 475   my $self = shift;
 476   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 477
 478   # Default to the primary key, but allow a specific key
 479   my @cols = exists $attrs->{key}
 480     ? $self->result_source->unique_constraint_columns($attrs->{key})
 481     : $self->result_source->primary_columns;
 482   $self->throw_exception(
 483     "Can't find unless a primary key is defined or unique constraint is specified"
 484   ) unless @cols;
 485
 486   # Parse out a hashref from input
 487   my $input_query;
 488   if (ref $_[0] eq 'HASH') {
 489     $input_query = { %{$_[0]} };
 490   }
 491   elsif (@_ == @cols) {
 492     $input_query = {};
 493     @{$input_query}{@cols} = @_;
 494   }
 495   else {
 496     # Compatibility: Allow e.g. find(id => $value)
 497     carp "Find by key => value deprecated; please use a hashref instead";
 498     $input_query = {@_};
 499   }
 500
 501   my (%related, $info);
 502
 503   KEY: foreach my $key (keys %$input_query) {
 504     if (ref($input_query->{$key})
 505         && ($info = $self->result_source->relationship_info($key))) {
 506       my $val = delete $input_query->{$key};
 507       next KEY if (ref($val) eq 'ARRAY'); # has_many for multi_create
 508       my $rel_q = $self->result_source->resolve_condition(
 509                     $info->{cond}, $val, $key
 510                   );
 511       die "Can't handle OR join condition in find" if ref($rel_q) eq 'ARRAY';
 512       @related{keys %$rel_q} = values %$rel_q;
 513     }
 514   }
 515   if (my @keys = keys %related) {
 516     @{$input_query}{@keys} = values %related;
 517   }
 518
 519
 520   # Build the final query: Default to the disjunction of the unique queries,
 521   # but allow the input query in case the ResultSet defines the query or the
 522   # user is abusing find
 523   my $alias = exists $attrs->{alias} ? $attrs->{alias} : $self->{attrs}{alias};
 524   my $query;
 525   if (exists $attrs->{key}) {
 526     my @unique_cols = $self->result_source->unique_constraint_columns($attrs->{key});
 527     my $unique_query = $self->_build_unique_query($input_query, \@unique_cols);
 528     $query = $self->_add_alias($unique_query, $alias);
 529   }
 530   else {
 531     my @unique_queries = $self->_unique_queries($input_query, $attrs);
 532     $query = @unique_queries
 533       ? [ map { $self->_add_alias($_, $alias) } @unique_queries ]
 534       : $self->_add_alias($input_query, $alias);
 535   }
 536
 537   # Run the query
 538   if (keys %$attrs) {
 539     my $rs = $self->search($query, $attrs);
 540     if (keys %{$rs->_resolved_attrs->{collapse}}) {
 541       my $row = $rs->next;
 542       carp "Query returned more than one row" if $rs->next;
 543       return $row;
 544     }
 545     else {
 546       return $rs->single;
 547     }
 548   }
 549   else {
 550     if (keys %{$self->_resolved_attrs->{collapse}}) {
 551       my $rs = $self->search($query);
 552       my $row = $rs->next;
 553       carp "Query returned more than one row" if $rs->next;
 554       return $row;
 555     }
 556     else {
 557       return $self->single($query);
 558     }
 559   }
 560 }
 561
 562 # _add_alias
 563 #
 564 # Add the specified alias to the specified query hash. A copy is made so the
 565 # original query is not modified.
 566
 567 sub _add_alias {
 568   my ($self, $query, $alias) = @_;
 569
 570   my %aliased = %$query;
 571   foreach my $col (grep { ! m/\./ } keys %aliased) {
 572     $aliased{"$alias.$col"} = delete $aliased{$col};
 573   }
 574
 575   return \%aliased;
 576 }
 577
 578 # _unique_queries
 579 #
 580 # Build a list of queries which satisfy unique constraints.
 581
 582 sub _unique_queries {
 583   my ($self, $query, $attrs) = @_;
 584
 585   my @constraint_names = exists $attrs->{key}
 586     ? ($attrs->{key})
 587     : $self->result_source->unique_constraint_names;
 588
 589   my $where = $self->_collapse_cond($self->{attrs}{where} || {});
 590   my $num_where = scalar keys %$where;
 591
 592   my @unique_queries;
 593   foreach my $name (@constraint_names) {
 594     my @unique_cols = $self->result_source->unique_constraint_columns($name);
 595     my $unique_query = $self->_build_unique_query($query, \@unique_cols);
 596
 597     my $num_cols = scalar @unique_cols;
 598     my $num_query = scalar keys %$unique_query;
 599
 600     my $total = $num_query + $num_where;
 601     if ($num_query && ($num_query == $num_cols || $total == $num_cols)) {
 602       # The query is either unique on its own or is unique in combination with
 603       # the existing where clause
 604       push @unique_queries, $unique_query;
 605     }
 606   }
 607
 608   return @unique_queries;
 609 }
 610
 611 # _build_unique_query
 612 #
 613 # Constrain the specified query hash based on the specified column names.
 614
 615 sub _build_unique_query {
 616   my ($self, $query, $unique_cols) = @_;
 617
 618   return {
 619     map  { $_ => $query->{$_} }
 620     grep { exists $query->{$_} }
 621       @$unique_cols
 622   };
 623 }
 624
 625 =head2 search_related
 626
 627 =over 4
 628
 629 =item Arguments: $rel, $cond, \%attrs?
 630
 631 =item Return Value: $new_resultset
 632
 633 =back
 634
 635   $new_rs = $cd_rs->search_related('artist', {
 636     name => 'Emo-R-Us',
 637   });
 638
 639 Searches the specified relationship, optionally specifying a condition and
 640 attributes for matching records. See L</ATTRIBUTES> for more information.
 641
 642 =cut
 643
 644 sub search_related {
 645   return shift->related_resultset(shift)->search(@_);
 646 }
 647
 648 =head2 search_related_rs
 649
 650 This method works exactly the same as search_related, except that
 651 it guarantees a restultset, even in list context.
 652
 653 =cut
 654
 655 sub search_related_rs {
 656   return shift->related_resultset(shift)->search_rs(@_);
 657 }
 658
 659 =head2 cursor
 660
 661 =over 4
 662
 663 =item Arguments: none
 664
 665 =item Return Value: $cursor
 666
 667 =back
 668
 669 Returns a storage-driven cursor to the given resultset. See
 670 L<DBIx::Class::Cursor> for more information.
 671
 672 =cut
 673
 674 sub cursor {
 675   my ($self) = @_;
 676
 677   my $attrs = { %{$self->_resolved_attrs} };
 678   return $self->{cursor}
 679     ||= $self->result_source->storage->select($attrs->{from}, $attrs->{select},
 680           $attrs->{where},$attrs);
 681 }
 682
 683 =head2 single
 684
 685 =over 4
 686
 687 =item Arguments: $cond?
 688
 689 =item Return Value: $row_object?
 690
 691 =back
 692
 693   my $cd = $schema->resultset('CD')->single({ year => 2001 });
 694
 695 Inflates the first result without creating a cursor if the resultset has
 696 any records in it; if not returns nothing. Used by L</find> as a lean version of
 697 L</search>.
 698
 699 While this method can take an optional search condition (just like L</search>)
 700 being a fast-code-path it does not recognize search attributes. If you need to
 701 add extra joins or similar, call L</search> and then chain-call L</single> on the
 702 L<DBIx::Class::ResultSet> returned.
 703
 704 =over
 705
 706 =item B<Note>
 707
 708 As of 0.08100, this method enforces the assumption that the preceeding
 709 query returns only one row. If more than one row is returned, you will receive
 710 a warning:
 711
 712   Query returned more than one row
 713
 714 In this case, you should be using L</first> or L</find> instead, or if you really
 715 know what you are doing, use the L</rows> attribute to explicitly limit the size
 716 of the resultset.
 717
 718 =back
 719
 720 =cut
 721
 722 sub single {
 723   my ($self, $where) = @_;
 724   if(@_ > 2) {
 725       $self->throw_exception('single() only takes search conditions, no attributes. You want ->search( $cond, $attrs )->single()');
 726   }
 727
 728   my $attrs = { %{$self->_resolved_attrs} };
 729   if ($where) {
 730     if (defined $attrs->{where}) {
 731       $attrs->{where} = {
 732         '-and' =>
 733             [ map { ref $_ eq 'ARRAY' ? [ -or => $_ ] : $_ }
 734                $where, delete $attrs->{where} ]
 735       };
 736     } else {
 737       $attrs->{where} = $where;
 738     }
 739   }
 740
 741 #  XXX: Disabled since it doesn't infer uniqueness in all cases
 742 #  unless ($self->_is_unique_query($attrs->{where})) {
 743 #    carp "Query not guaranteed to return a single row"
 744 #      . "; please declare your unique constraints or use search instead";
 745 #  }
 746
 747   my @data = $self->result_source->storage->select_single(
 748     $attrs->{from}, $attrs->{select},
 749     $attrs->{where}, $attrs
 750   );
 751
 752   return (@data ? ($self->_construct_object(@data))[0] : undef);
 753 }
 754
 755 # _is_unique_query
 756 #
 757 # Try to determine if the specified query is guaranteed to be unique, based on
 758 # the declared unique constraints.
 759
 760 sub _is_unique_query {
 761   my ($self, $query) = @_;
 762
 763   my $collapsed = $self->_collapse_query($query);
 764   my $alias = $self->{attrs}{alias};
 765
 766   foreach my $name ($self->result_source->unique_constraint_names) {
 767     my @unique_cols = map {
 768       "$alias.$_"
 769     } $self->result_source->unique_constraint_columns($name);
 770
 771     # Count the values for each unique column
 772     my %seen = map { $_ => 0 } @unique_cols;
 773
 774     foreach my $key (keys %$collapsed) {
 775       my $aliased = $key =~ /\./ ? $key : "$alias.$key";
 776       next unless exists $seen{$aliased};  # Additional constraints are okay
 777       $seen{$aliased} = scalar keys %{ $collapsed->{$key} };
 778     }
 779
 780     # If we get 0 or more than 1 value for a column, it's not necessarily unique
 781     return 1 unless grep { $_ != 1 } values %seen;
 782   }
 783
 784   return 0;
 785 }
 786
 787 # _collapse_query
 788 #
 789 # Recursively collapse the query, accumulating values for each column.
 790
 791 sub _collapse_query {
 792   my ($self, $query, $collapsed) = @_;
 793
 794   $collapsed ||= {};
 795
 796   if (ref $query eq 'ARRAY') {
 797     foreach my $subquery (@$query) {
 798       next unless ref $subquery;  # -or
 799       $collapsed = $self->_collapse_query($subquery, $collapsed);
 800     }
 801   }
 802   elsif (ref $query eq 'HASH') {
 803     if (keys %$query and (keys %$query)[0] eq '-and') {
 804       foreach my $subquery (@{$query->{-and}}) {
 805         $collapsed = $self->_collapse_query($subquery, $collapsed);
 806       }
 807     }
 808     else {
 809       foreach my $col (keys %$query) {
 810         my $value = $query->{$col};
 811         $collapsed->{$col}{$value}++;
 812       }
 813     }
 814   }
 815
 816   return $collapsed;
 817 }
 818
 819 =head2 get_column
 820
 821 =over 4
 822
 823 =item Arguments: $cond?
 824
 825 =item Return Value: $resultsetcolumn
 826
 827 =back
 828
 829   my $max_length = $rs->get_column('length')->max;
 830
 831 Returns a L<DBIx::Class::ResultSetColumn> instance for a column of the ResultSet.
 832
 833 =cut
 834
 835 sub get_column {
 836   my ($self, $column) = @_;
 837   my $new = DBIx::Class::ResultSetColumn->new($self, $column);
 838   return $new;
 839 }
 840
 841 =head2 search_like
 842
 843 =over 4
 844
 845 =item Arguments: $cond, \%attrs?
 846
 847 =item Return Value: $resultset (scalar context), @row_objs (list context)
 848
 849 =back
 850
 851   # WHERE title LIKE '%blue%'
 852   $cd_rs = $rs->search_like({ title => '%blue%'});
 853
 854 Performs a search, but uses C<LIKE> instead of C<=> as the condition. Note
 855 that this is simply a convenience method retained for ex Class::DBI users.
 856 You most likely want to use L</search> with specific operators.
 857
 858 For more information, see L<DBIx::Class::Manual::Cookbook>.
 859
 860 This method is deprecated and will be removed in 0.09. Use L</search()>
 861 instead. An example conversion is:
 862
 863   ->search_like({ foo => 'bar' });
 864
 865   # Becomes
 866
 867   ->search({ foo => { like => 'bar' } });
 868
 869 =cut
 870
 871 sub search_like {
 872   my $class = shift;
 873   carp join ("\n",
 874     'search_like() is deprecated and will be removed in 0.09.',
 875     'Instead use ->search({ x => { -like => "y%" } })',
 876     '(note the outer pair of {}s - they are important!)'
 877   );
 878   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
 879   my $query = ref $_[0] eq 'HASH' ? { %{shift()} }: {@_};
 880   $query->{$_} = { 'like' => $query->{$_} } for keys %$query;
 881   return $class->search($query, { %$attrs });
 882 }
 883
 884 =head2 slice
 885
 886 =over 4
 887
 888 =item Arguments: $first, $last
 889
 890 =item Return Value: $resultset (scalar context), @row_objs (list context)
 891
 892 =back
 893
 894 Returns a resultset or object list representing a subset of elements from the
 895 resultset slice is called on. Indexes are from 0, i.e., to get the first
 896 three records, call:
 897
 898   my ($one, $two, $three) = $rs->slice(0, 2);
 899
 900 =cut
 901
 902 sub slice {
 903   my ($self, $min, $max) = @_;
 904   my $attrs = {}; # = { %{ $self->{attrs} || {} } };
 905   $attrs->{offset} = $self->{attrs}{offset} || 0;
 906   $attrs->{offset} += $min;
 907   $attrs->{rows} = ($max ? ($max - $min + 1) : 1);
 908   return $self->search(undef(), $attrs);
 909   #my $slice = (ref $self)->new($self->result_source, $attrs);
 910   #return (wantarray ? $slice->all : $slice);
 911 }
 912
 913 =head2 next
 914
 915 =over 4
 916
 917 =item Arguments: none
 918
 919 =item Return Value: $result?
 920
 921 =back
 922
 923 Returns the next element in the resultset (C<undef> is there is none).
 924
 925 Can be used to efficiently iterate over records in the resultset:
 926
 927   my $rs = $schema->resultset('CD')->search;
 928   while (my $cd = $rs->next) {
 929     print $cd->title;
 930   }
 931
 932 Note that you need to store the resultset object, and call C<next> on it.
 933 Calling C<< resultset('Table')->next >> repeatedly will always return the
 934 first record from the resultset.
 935
 936 =cut
 937
 938 sub next {
 939   my ($self) = @_;
 940   if (my $cache = $self->get_cache) {
 941     $self->{all_cache_position} ||= 0;
 942     return $cache->[$self->{all_cache_position}++];
 943   }
 944   if ($self->{attrs}{cache}) {
 945     $self->{all_cache_position} = 1;
 946     return ($self->all)[0];
 947   }
 948   if ($self->{stashed_objects}) {
 949     my $obj = shift(@{$self->{stashed_objects}});
 950     delete $self->{stashed_objects} unless @{$self->{stashed_objects}};
 951     return $obj;
 952   }
 953   my @row = (
 954     exists $self->{stashed_row}
 955       ? @{delete $self->{stashed_row}}
 956       : $self->cursor->next
 957   );
 958   return undef unless (@row);
 959   my ($row, @more) = $self->_construct_object(@row);
 960   $self->{stashed_objects} = \@more if @more;
 961   return $row;
 962 }
 963
 964 sub _construct_object {
 965   my ($self, @row) = @_;
 966   my $info = $self->_collapse_result($self->{_attrs}{as}, \@row);
 967   my @new = $self->result_class->inflate_result($self->result_source, @$info);
 968   @new = $self->{_attrs}{record_filter}->(@new)
 969     if exists $self->{_attrs}{record_filter};
 970   return @new;
 971 }
 972
 973 sub _collapse_result {
 974   my ($self, $as_proto, $row) = @_;
 975
 976   my @copy = @$row;
 977
 978   # 'foo'         => [ undef, 'foo' ]
 979   # 'foo.bar'     => [ 'foo', 'bar' ]
 980   # 'foo.bar.baz' => [ 'foo.bar', 'baz' ]
 981
 982   my @construct_as = map { [ (/^(?:(.*)\.)?([^.]+)$/) ] } @$as_proto;
 983
 984   my %collapse = %{$self->{_attrs}{collapse}||{}};
 985
 986   my @pri_index;
 987
 988   # if we're doing collapsing (has_many prefetch) we need to grab records
 989   # until the PK changes, so fill @pri_index. if not, we leave it empty so
 990   # we know we don't have to bother.
 991
 992   # the reason for not using the collapse stuff directly is because if you
 993   # had for e.g. two artists in a row with no cds, the collapse info for
 994   # both would be NULL (undef) so you'd lose the second artist
 995
 996   # store just the index so we can check the array positions from the row
 997   # without having to contruct the full hash
 998
 999   if (keys %collapse) {
1000     my %pri = map { ($_ => 1) } $self->result_source->primary_columns;
1001     foreach my $i (0 .. $#construct_as) {
1002       next if defined($construct_as[$i][0]); # only self table
1003       if (delete $pri{$construct_as[$i][1]}) {
1004         push(@pri_index, $i);
1005       }
1006       last unless keys %pri; # short circuit (Johnny Five Is Alive!)
1007     }
1008   }
1009
1010   # no need to do an if, it'll be empty if @pri_index is empty anyway
1011
1012   my %pri_vals = map { ($_ => $copy[$_]) } @pri_index;
1013
1014   my @const_rows;
1015
1016   do { # no need to check anything at the front, we always want the first row
1017
1018     my %const;
1019
1020     foreach my $this_as (@construct_as) {
1021       $const{$this_as->[0]||''}{$this_as->[1]} = shift(@copy);
1022     }
1023
1024     push(@const_rows, \%const);
1025
1026   } until ( # no pri_index => no collapse => drop straight out
1027       !@pri_index
1028     or
1029       do { # get another row, stash it, drop out if different PK
1030
1031         @copy = $self->cursor->next;
1032         $self->{stashed_row} = \@copy;
1033
1034         # last thing in do block, counts as true if anything doesn't match
1035
1036         # check xor defined first for NULL vs. NOT NULL then if one is
1037         # defined the other must be so check string equality
1038
1039         grep {
1040           (defined $pri_vals{$_} ^ defined $copy[$_])
1041           || (defined $pri_vals{$_} && ($pri_vals{$_} ne $copy[$_]))
1042         } @pri_index;
1043       }
1044   );
1045
1046   my $alias = $self->{attrs}{alias};
1047   my $info = [];
1048
1049   my %collapse_pos;
1050
1051   my @const_keys;
1052
1053   foreach my $const (@const_rows) {
1054     scalar @const_keys or do {
1055       @const_keys = sort { length($a) <=> length($b) } keys %$const;
1056     };
1057     foreach my $key (@const_keys) {
1058       if (length $key) {
1059         my $target = $info;
1060         my @parts = split(/\./, $key);
1061         my $cur = '';
1062         my $data = $const->{$key};
1063         foreach my $p (@parts) {
1064           $target = $target->[1]->{$p} ||= [];
1065           $cur .= ".${p}";
1066           if ($cur eq ".${key}" && (my @ckey = @{$collapse{$cur}||[]})) {
1067             # collapsing at this point and on final part
1068             my $pos = $collapse_pos{$cur};
1069             CK: foreach my $ck (@ckey) {
1070               if (!defined $pos->{$ck} || $pos->{$ck} ne $data->{$ck}) {
1071                 $collapse_pos{$cur} = $data;
1072                 delete @collapse_pos{ # clear all positioning for sub-entries
1073                   grep { m/^\Q${cur}.\E/ } keys %collapse_pos
1074                 };
1075                 push(@$target, []);
1076                 last CK;
1077               }
1078             }
1079           }
1080           if (exists $collapse{$cur}) {
1081             $target = $target->[-1];
1082           }
1083         }
1084         $target->[0] = $data;
1085       } else {
1086         $info->[0] = $const->{$key};
1087       }
1088     }
1089   }
1090
1091   return $info;
1092 }
1093
1094 =head2 result_source
1095
1096 =over 4
1097
1098 =item Arguments: $result_source?
1099
1100 =item Return Value: $result_source
1101
1102 =back
1103
1104 An accessor for the primary ResultSource object from which this ResultSet
1105 is derived.
1106
1107 =head2 result_class
1108
1109 =over 4
1110
1111 =item Arguments: $result_class?
1112
1113 =item Return Value: $result_class
1114
1115 =back
1116
1117 An accessor for the class to use when creating row objects. Defaults to
1118 C<< result_source->result_class >> - which in most cases is the name of the
1119 L<"table"|DBIx::Class::Manual::Glossary/"ResultSource"> class.
1120
1121 Note that changing the result_class will also remove any components
1122 that were originally loaded in the source class via
1123 L<DBIx::Class::ResultSource/load_components>. Any overloaded methods
1124 in the original source class will not run.
1125
1126 =cut
1127
1128 sub result_class {
1129   my ($self, $result_class) = @_;
1130   if ($result_class) {
1131     $self->ensure_class_loaded($result_class);
1132     $self->_result_class($result_class);
1133   }
1134   $self->_result_class;
1135 }
1136
1137 =head2 count
1138
1139 =over 4
1140
1141 =item Arguments: $cond, \%attrs??
1142
1143 =item Return Value: $count
1144
1145 =back
1146
1147 Performs an SQL C<COUNT> with the same query as the resultset was built
1148 with to find the number of elements. If passed arguments, does a search
1149 on the resultset and counts the results of that.
1150
1151 =cut
1152
1153 my @count_via_subq_attrs = qw/join seen_join group_by/;
1154 sub count {
1155   my $self = shift;
1156   return $self->search(@_)->count if @_ and defined $_[0];
1157   return scalar @{ $self->get_cache } if $self->get_cache;
1158
1159   my @check_attrs = @count_via_subq_attrs;
1160
1161   # if we are not paged - we are simply asking for a limit
1162   if (not $self->{attrs}{page} and not $self->{attrs}{software_limit}) {
1163     push @check_attrs, qw/rows offset/;
1164   }
1165
1166   return $self->_has_attr (@check_attrs)
1167     ? $self->_count_subq
1168     : $self->_count_simple
1169 }
1170
1171 sub _count_subq {
1172   my $self = shift;
1173
1174   my $attrs = { %{$self->_resolved_attrs} };
1175
1176   my $select_cols = $attrs->{group_by} || [ map { "$attrs->{alias}.$_" } ($self->result_source->primary_columns) ];
1177   $attrs->{from} = [{
1178     count_subq => $self->search ({}, { columns => $select_cols, group_by => $select_cols })
1179                          ->as_query
1180   }];
1181
1182   # the subquery above will integrate everything, including 'where' and any pagers
1183   delete $attrs->{$_} for (@count_via_subq_attrs, qw/where rows offset pager page/ );
1184
1185   return $self->__count ($attrs);
1186 }
1187
1188 sub _count_simple {
1189   my $self = shift;
1190
1191   my $count = $self->__count;
1192   return 0 unless $count;
1193
1194   # need to take offset from resolved attrs
1195
1196   $count -= $self->{_attrs}{offset} if $self->{_attrs}{offset};
1197   $count = $self->{attrs}{rows} if
1198     $self->{attrs}{rows} and $self->{attrs}{rows} < $count;
1199   $count = 0 if ($count < 0);
1200   return $count;
1201 }
1202
1203 sub __count {
1204   my ($self, $attrs) = @_;
1205
1206   $attrs ||= { %{$self->{attrs}} };
1207
1208   $attrs->{select} = { count => '*' };
1209   $attrs->{as} = [qw/count/];
1210
1211   # take off any pagers, record_filter is cdbi, and no point of ordering a count
1212   delete $attrs->{$_} for qw/rows offset page pager order_by record_filter/;
1213
1214   my $tmp_rs = (ref $self)->new($self->result_source, $attrs);
1215   my ($count) = $tmp_rs->cursor->next;
1216
1217   return $count;
1218 }
1219
1220 sub _bool {
1221   return 1;
1222 }
1223
1224 =head2 count_literal
1225
1226 =over 4
1227
1228 =item Arguments: $sql_fragment, @bind_values
1229
1230 =item Return Value: $count
1231
1232 =back
1233
1234 Counts the results in a literal query. Equivalent to calling L</search_literal>
1235 with the passed arguments, then L</count>.
1236
1237 =cut
1238
1239 sub count_literal { shift->search_literal(@_)->count; }
1240
1241 =head2 all
1242
1243 =over 4
1244
1245 =item Arguments: none
1246
1247 =item Return Value: @objects
1248
1249 =back
1250
1251 Returns all elements in the resultset. Called implicitly if the resultset
1252 is returned in list context.
1253
1254 =cut
1255
1256 sub all {
1257   my $self = shift;
1258   if(@_) {
1259       $self->throw_exception("all() doesn't take any arguments, you probably wanted ->search(...)->all()");
1260   }
1261
1262   return @{ $self->get_cache } if $self->get_cache;
1263
1264   my @obj;
1265
1266   # TODO: don't call resolve here
1267   if (keys %{$self->_resolved_attrs->{collapse}}) {
1268 #  if ($self->{attrs}{prefetch}) {
1269       # Using $self->cursor->all is really just an optimisation.
1270       # If we're collapsing has_many prefetches it probably makes
1271       # very little difference, and this is cleaner than hacking
1272       # _construct_object to survive the approach
1273     my @row = $self->cursor->next;
1274     while (@row) {
1275       push(@obj, $self->_construct_object(@row));
1276       @row = (exists $self->{stashed_row}
1277                ? @{delete $self->{stashed_row}}
1278                : $self->cursor->next);
1279     }
1280   } else {
1281     @obj = map { $self->_construct_object(@$_) } $self->cursor->all;
1282   }
1283
1284   $self->set_cache(\@obj) if $self->{attrs}{cache};
1285   return @obj;
1286 }
1287
1288 =head2 reset
1289
1290 =over 4
1291
1292 =item Arguments: none
1293
1294 =item Return Value: $self
1295
1296 =back
1297
1298 Resets the resultset's cursor, so you can iterate through the elements again.
1299
1300 =cut
1301
1302 sub reset {
1303   my ($self) = @_;
1304   delete $self->{_attrs} if exists $self->{_attrs};
1305   $self->{all_cache_position} = 0;
1306   $self->cursor->reset;
1307   return $self;
1308 }
1309
1310 =head2 first
1311
1312 =over 4
1313
1314 =item Arguments: none
1315
1316 =item Return Value: $object?
1317
1318 =back
1319
1320 Resets the resultset and returns an object for the first result (if the
1321 resultset returns anything).
1322
1323 =cut
1324
1325 sub first {
1326   return $_[0]->reset->next;
1327 }
1328
1329 # _cond_for_update_delete
1330 #
1331 # update/delete require the condition to be modified to handle
1332 # the differing SQL syntax available.  This transforms the $self->{cond}
1333 # appropriately, returning the new condition.
1334
1335 sub _cond_for_update_delete {
1336   my ($self, $full_cond) = @_;
1337   my $cond = {};
1338
1339   $full_cond ||= $self->{cond};
1340   # No-op. No condition, we're updating/deleting everything
1341   return $cond unless ref $full_cond;
1342
1343   # Some attributes when present require a subquery
1344   # This might not work on some database (mysql), but...
1345   # it won't work without the subquery either so who cares
1346   if ($self->_has_attr (qw/join seen_join group_by row offset page/) ) {
1347
1348     foreach my $pk ($self->result_source->primary_columns) {
1349       $cond->{$pk} = { -in => $self->get_column($pk)->as_query };
1350     }
1351
1352     return $cond;
1353   }
1354
1355   if (ref $full_cond eq 'ARRAY') {
1356     $cond = [
1357       map {
1358         my %hash;
1359         foreach my $key (keys %{$_}) {
1360           $key =~ /([^.]+)$/;
1361           $hash{$1} = $_->{$key};
1362         }
1363         \%hash;
1364       } @{$full_cond}
1365     ];
1366   }
1367   elsif (ref $full_cond eq 'HASH') {
1368     if ((keys %{$full_cond})[0] eq '-and') {
1369       $cond->{-and} = [];
1370       my @cond = @{$full_cond->{-and}};
1371        for (my $i = 0; $i < @cond; $i++) {
1372         my $entry = $cond[$i];
1373         my $hash;
1374         if (ref $entry eq 'HASH') {
1375           $hash = $self->_cond_for_update_delete($entry);
1376         }
1377         else {
1378           $entry =~ /([^.]+)$/;
1379           $hash->{$1} = $cond[++$i];
1380         }
1381         push @{$cond->{-and}}, $hash;
1382       }
1383     }
1384     else {
1385       foreach my $key (keys %{$full_cond}) {
1386         $key =~ /([^.]+)$/;
1387         $cond->{$1} = $full_cond->{$key};
1388       }
1389     }
1390   }
1391   else {
1392     $self->throw_exception("Can't update/delete on resultset with condition unless hash or array");
1393   }
1394
1395   return $cond;
1396 }
1397
1398
1399 =head2 update
1400
1401 =over 4
1402
1403 =item Arguments: \%values
1404
1405 =item Return Value: $storage_rv
1406
1407 =back
1408
1409 Sets the specified columns in the resultset to the supplied values in a
1410 single query. Return value will be true if the update succeeded or false
1411 if no records were updated; exact type of success value is storage-dependent.
1412
1413 =cut
1414
1415 sub update {
1416   my ($self, $values) = @_;
1417   $self->throw_exception("Values for update must be a hash")
1418     unless ref $values eq 'HASH';
1419
1420   my $cond = $self->_cond_for_update_delete;
1421
1422   return $self->result_source->storage->update(
1423     $self->result_source, $values, $cond
1424   );
1425 }
1426
1427 =head2 update_all
1428
1429 =over 4
1430
1431 =item Arguments: \%values
1432
1433 =item Return Value: 1
1434
1435 =back
1436
1437 Fetches all objects and updates them one at a time. Note that C<update_all>
1438 will run DBIC cascade triggers, while L</update> will not.
1439
1440 =cut
1441
1442 sub update_all {
1443   my ($self, $values) = @_;
1444   $self->throw_exception("Values for update must be a hash")
1445     unless ref $values eq 'HASH';
1446   foreach my $obj ($self->all) {
1447     $obj->set_columns($values)->update;
1448   }
1449   return 1;
1450 }
1451
1452 =head2 delete
1453
1454 =over 4
1455
1456 =item Arguments: none
1457
1458 =item Return Value: 1
1459
1460 =back
1461
1462 Deletes the contents of the resultset from its result source. Note that this
1463 will not run DBIC cascade triggers. See L</delete_all> if you need triggers
1464 to run. See also L<DBIx::Class::Row/delete>.
1465
1466 delete may not generate correct SQL for a query with joins or a resultset
1467 chained from a related resultset.  In this case it will generate a warning:-
1468
1469 In these cases you may find that delete_all is more appropriate, or you
1470 need to respecify your query in a way that can be expressed without a join.
1471
1472 =cut
1473
1474 sub delete {
1475   my ($self) = @_;
1476   $self->throw_exception("Delete should not be passed any arguments")
1477     if $_[1];
1478
1479   my $cond = $self->_cond_for_update_delete;
1480
1481   $self->result_source->storage->delete($self->result_source, $cond);
1482   return 1;
1483 }
1484
1485 =head2 delete_all
1486
1487 =over 4
1488
1489 =item Arguments: none
1490
1491 =item Return Value: 1
1492
1493 =back
1494
1495 Fetches all objects and deletes them one at a time. Note that C<delete_all>
1496 will run DBIC cascade triggers, while L</delete> will not.
1497
1498 =cut
1499
1500 sub delete_all {
1501   my ($self) = @_;
1502   $_->delete for $self->all;
1503   return 1;
1504 }
1505
1506 =head2 populate
1507
1508 =over 4
1509
1510 =item Arguments: \@data;
1511
1512 =back
1513
1514 Accepts either an arrayref of hashrefs or alternatively an arrayref of arrayrefs.
1515 For the arrayref of hashrefs style each hashref should be a structure suitable
1516 forsubmitting to a $resultset->create(...) method.
1517
1518 In void context, C<insert_bulk> in L<DBIx::Class::Storage::DBI> is used
1519 to insert the data, as this is a faster method.
1520
1521 Otherwise, each set of data is inserted into the database using
1522 L<DBIx::Class::ResultSet/create>, and a arrayref of the resulting row
1523 objects is returned.
1524
1525 Example:  Assuming an Artist Class that has many CDs Classes relating:
1526
1527   my $Artist_rs = $schema->resultset("Artist");
1528
1529   ## Void Context Example
1530   $Artist_rs->populate([
1531      { artistid => 4, name => 'Manufactured Crap', cds => [
1532         { title => 'My First CD', year => 2006 },
1533         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
1534       ],
1535      },
1536      { artistid => 5, name => 'Angsty-Whiny Girl', cds => [
1537         { title => 'My parents sold me to a record company' ,year => 2005 },
1538         { title => 'Why Am I So Ugly?', year => 2006 },
1539         { title => 'I Got Surgery and am now Popular', year => 2007 }
1540       ],
1541      },
1542   ]);
1543
1544   ## Array Context Example
1545   my ($ArtistOne, $ArtistTwo, $ArtistThree) = $Artist_rs->populate([
1546     { name => "Artist One"},
1547     { name => "Artist Two"},
1548     { name => "Artist Three", cds=> [
1549     { title => "First CD", year => 2007},
1550     { title => "Second CD", year => 2008},
1551   ]}
1552   ]);
1553
1554   print $ArtistOne->name; ## response is 'Artist One'
1555   print $ArtistThree->cds->count ## reponse is '2'
1556
1557 For the arrayref of arrayrefs style,  the first element should be a list of the
1558 fieldsnames to which the remaining elements are rows being inserted.  For
1559 example:
1560
1561   $Arstist_rs->populate([
1562     [qw/artistid name/],
1563     [100, 'A Formally Unknown Singer'],
1564     [101, 'A singer that jumped the shark two albums ago'],
1565     [102, 'An actually cool singer.'],
1566   ]);
1567
1568 Please note an important effect on your data when choosing between void and
1569 wantarray context. Since void context goes straight to C<insert_bulk> in
1570 L<DBIx::Class::Storage::DBI> this will skip any component that is overriding
1571 c<insert>.  So if you are using something like L<DBIx-Class-UUIDColumns> to
1572 create primary keys for you, you will find that your PKs are empty.  In this
1573 case you will have to use the wantarray context in order to create those
1574 values.
1575
1576 =cut
1577
1578 sub populate {
1579   my $self = shift @_;
1580   my $data = ref $_[0][0] eq 'HASH'
1581     ? $_[0] : ref $_[0][0] eq 'ARRAY' ? $self->_normalize_populate_args($_[0]) :
1582     $self->throw_exception('Populate expects an arrayref of hashes or arrayref of arrayrefs');
1583
1584   if(defined wantarray) {
1585     my @created;
1586     foreach my $item (@$data) {
1587       push(@created, $self->create($item));
1588     }
1589     return @created;
1590   } else {
1591     my ($first, @rest) = @$data;
1592
1593     my @names = grep {!ref $first->{$_}} keys %$first;
1594     my @rels = grep { $self->result_source->has_relationship($_) } keys %$first;
1595     my @pks = $self->result_source->primary_columns;
1596
1597     ## do the belongs_to relationships
1598     foreach my $index (0..$#$data) {
1599       if( grep { !defined $data->[$index]->{$_} } @pks ) {
1600         my @ret = $self->populate($data);
1601         return;
1602       }
1603
1604       foreach my $rel (@rels) {
1605         next unless $data->[$index]->{$rel} && ref $data->[$index]->{$rel} eq "HASH";
1606         my $result = $self->related_resultset($rel)->create($data->[$index]->{$rel});
1607         my ($reverse) = keys %{$self->result_source->reverse_relationship_info($rel)};
1608         my $related = $result->result_source->resolve_condition(
1609           $result->result_source->relationship_info($reverse)->{cond},
1610           $self,
1611           $result,
1612         );
1613
1614         delete $data->[$index]->{$rel};
1615         $data->[$index] = {%{$data->[$index]}, %$related};
1616
1617         push @names, keys %$related if $index == 0;
1618       }
1619     }
1620
1621     ## do bulk insert on current row
1622     my @values = map { [ @$_{@names} ] } @$data;
1623
1624     $self->result_source->storage->insert_bulk(
1625       $self->result_source,
1626       \@names,
1627       \@values,
1628     );
1629
1630     ## do the has_many relationships
1631     foreach my $item (@$data) {
1632
1633       foreach my $rel (@rels) {
1634         next unless $item->{$rel} && ref $item->{$rel} eq "ARRAY";
1635
1636         my $parent = $self->find(map {{$_=>$item->{$_}} } @pks)
1637      || $self->throw_exception('Cannot find the relating object.');
1638
1639         my $child = $parent->$rel;
1640
1641         my $related = $child->result_source->resolve_condition(
1642           $parent->result_source->relationship_info($rel)->{cond},
1643           $child,
1644           $parent,
1645         );
1646
1647         my @rows_to_add = ref $item->{$rel} eq 'ARRAY' ? @{$item->{$rel}} : ($item->{$rel});
1648         my @populate = map { {%$_, %$related} } @rows_to_add;
1649
1650         $child->populate( \@populate );
1651       }
1652     }
1653   }
1654 }
1655
1656 =head2 _normalize_populate_args ($args)
1657
1658 Private method used by L</populate> to normalize its incoming arguments.  Factored
1659 out in case you want to subclass and accept new argument structures to the
1660 L</populate> method.
1661
1662 =cut
1663
1664 sub _normalize_populate_args {
1665   my ($self, $data) = @_;
1666   my @names = @{shift(@$data)};
1667   my @results_to_create;
1668   foreach my $datum (@$data) {
1669     my %result_to_create;
1670     foreach my $index (0..$#names) {
1671       $result_to_create{$names[$index]} = $$datum[$index];
1672     }
1673     push @results_to_create, \%result_to_create;
1674   }
1675   return \@results_to_create;
1676 }
1677
1678 =head2 pager
1679
1680 =over 4
1681
1682 =item Arguments: none
1683
1684 =item Return Value: $pager
1685
1686 =back
1687
1688 Return Value a L<Data::Page> object for the current resultset. Only makes
1689 sense for queries with a C<page> attribute.
1690
1691 To get the full count of entries for a paged resultset, call
1692 C<total_entries> on the L<Data::Page> object.
1693
1694 =cut
1695
1696 sub pager {
1697   my ($self) = @_;
1698   my $attrs = $self->{attrs};
1699   $self->throw_exception("Can't create pager for non-paged rs")
1700     unless $self->{attrs}{page};
1701   $attrs->{rows} ||= 10;
1702   return $self->{pager} ||= Data::Page->new(
1703     $self->__count, $attrs->{rows}, $self->{attrs}{page});
1704 }
1705
1706 =head2 page
1707
1708 =over 4
1709
1710 =item Arguments: $page_number
1711
1712 =item Return Value: $rs
1713
1714 =back
1715
1716 Returns a resultset for the $page_number page of the resultset on which page
1717 is called, where each page contains a number of rows equal to the 'rows'
1718 attribute set on the resultset (10 by default).
1719
1720 =cut
1721
1722 sub page {
1723   my ($self, $page) = @_;
1724   return (ref $self)->new($self->result_source, { %{$self->{attrs}}, page => $page });
1725 }
1726
1727 =head2 new_result
1728
1729 =over 4
1730
1731 =item Arguments: \%vals
1732
1733 =item Return Value: $rowobject
1734
1735 =back
1736
1737 Creates a new row object in the resultset's result class and returns
1738 it. The row is not inserted into the database at this point, call
1739 L<DBIx::Class::Row/insert> to do that. Calling L<DBIx::Class::Row/in_storage>
1740 will tell you whether the row object has been inserted or not.
1741
1742 Passes the hashref of input on to L<DBIx::Class::Row/new>.
1743
1744 =cut
1745
1746 sub new_result {
1747   my ($self, $values) = @_;
1748   $self->throw_exception( "new_result needs a hash" )
1749     unless (ref $values eq 'HASH');
1750
1751   my %new;
1752   my $alias = $self->{attrs}{alias};
1753
1754   if (
1755     defined $self->{cond}
1756     && $self->{cond} eq $DBIx::Class::ResultSource::UNRESOLVABLE_CONDITION
1757   ) {
1758     %new = %{ $self->{attrs}{related_objects} || {} };  # nothing might have been inserted yet
1759     $new{-from_resultset} = [ keys %new ] if keys %new;
1760   } else {
1761     $self->throw_exception(
1762       "Can't abstract implicit construct, condition not a hash"
1763     ) if ($self->{cond} && !(ref $self->{cond} eq 'HASH'));
1764
1765     my $collapsed_cond = (
1766       $self->{cond}
1767         ? $self->_collapse_cond($self->{cond})
1768         : {}
1769     );
1770
1771     # precendence must be given to passed values over values inherited from
1772     # the cond, so the order here is important.
1773     my %implied =  %{$self->_remove_alias($collapsed_cond, $alias)};
1774     while( my($col,$value) = each %implied ){
1775       if(ref($value) eq 'HASH' && keys(%$value) && (keys %$value)[0] eq '='){
1776         $new{$col} = $value->{'='};
1777         next;
1778       }
1779       $new{$col} = $value if $self->_is_deterministic_value($value);
1780     }
1781   }
1782
1783   %new = (
1784     %new,
1785     %{ $self->_remove_alias($values, $alias) },
1786     -source_handle => $self->_source_handle,
1787     -result_source => $self->result_source, # DO NOT REMOVE THIS, REQUIRED
1788   );
1789
1790   return $self->result_class->new(\%new);
1791 }
1792
1793 # _is_deterministic_value
1794 #
1795 # Make an effor to strip non-deterministic values from the condition,
1796 # to make sure new_result chokes less
1797
1798 sub _is_deterministic_value {
1799   my $self = shift;
1800   my $value = shift;
1801   my $ref_type = ref $value;
1802   return 1 if $ref_type eq '' || $ref_type eq 'SCALAR';
1803   return 1 if Scalar::Util::blessed($value);
1804   return 0;
1805 }
1806
1807 # _has_attr
1808 #
1809 # determines if the resultset defines at least one
1810 # of the attributes supplied
1811 #
1812 # used to determine if a subquery is neccessary
1813
1814 sub _has_attr {
1815   my ($self, @attr_names) = @_;
1816
1817   my $attrs = $self->_resolved_attrs;
1818
1819   my $join_check_req;
1820
1821   for my $n (@attr_names) {
1822     return 1 if defined $attrs->{$n};
1823     ++$join_check_req if $n =~ /join/;
1824   }
1825
1826   # a join can be expressed as a multi-level from
1827   return 1 if (
1828     $join_check_req
1829       and
1830     ref $attrs->{from} eq 'ARRAY'
1831       and
1832     @{$attrs->{from}} > 1
1833   );
1834
1835   return 0;
1836 }
1837
1838 # _collapse_cond
1839 #
1840 # Recursively collapse the condition.
1841
1842 sub _collapse_cond {
1843   my ($self, $cond, $collapsed) = @_;
1844
1845   $collapsed ||= {};
1846
1847   if (ref $cond eq 'ARRAY') {
1848     foreach my $subcond (@$cond) {
1849       next unless ref $subcond;  # -or
1850       $collapsed = $self->_collapse_cond($subcond, $collapsed);
1851     }
1852   }
1853   elsif (ref $cond eq 'HASH') {
1854     if (keys %$cond and (keys %$cond)[0] eq '-and') {
1855       foreach my $subcond (@{$cond->{-and}}) {
1856         $collapsed = $self->_collapse_cond($subcond, $collapsed);
1857       }
1858     }
1859     else {
1860       foreach my $col (keys %$cond) {
1861         my $value = $cond->{$col};
1862         $collapsed->{$col} = $value;
1863       }
1864     }
1865   }
1866
1867   return $collapsed;
1868 }
1869
1870 # _remove_alias
1871 #
1872 # Remove the specified alias from the specified query hash. A copy is made so
1873 # the original query is not modified.
1874
1875 sub _remove_alias {
1876   my ($self, $query, $alias) = @_;
1877
1878   my %orig = %{ $query || {} };
1879   my %unaliased;
1880
1881   foreach my $key (keys %orig) {
1882     if ($key !~ /\./) {
1883       $unaliased{$key} = $orig{$key};
1884       next;
1885     }
1886     $unaliased{$1} = $orig{$key}
1887       if $key =~ m/^(?:\Q$alias\E\.)?([^.]+)$/;
1888   }
1889
1890   return \%unaliased;
1891 }
1892
1893 =head2 as_query (EXPERIMENTAL)
1894
1895 =over 4
1896
1897 =item Arguments: none
1898
1899 =item Return Value: \[ $sql, @bind ]
1900
1901 =back
1902
1903 Returns the SQL query and bind vars associated with the invocant.
1904
1905 This is generally used as the RHS for a subquery.
1906
1907 B<NOTE>: This feature is still experimental.
1908
1909 =cut
1910
1911 sub as_query { return shift->cursor->as_query(@_) }
1912
1913 =head2 find_or_new
1914
1915 =over 4
1916
1917 =item Arguments: \%vals, \%attrs?
1918
1919 =item Return Value: $rowobject
1920
1921 =back
1922
1923   my $artist = $schema->resultset('Artist')->find_or_new(
1924     { artist => 'fred' }, { key => 'artists' });
1925
1926   $cd->cd_to_producer->find_or_new({ producer => $producer },
1927                                    { key => 'primary });
1928
1929 Find an existing record from this resultset, based on its primary
1930 key, or a unique constraint. If none exists, instantiate a new result
1931 object and return it. The object will not be saved into your storage
1932 until you call L<DBIx::Class::Row/insert> on it.
1933
1934 You most likely want this method when looking for existing rows using
1935 a unique constraint that is not the primary key, or looking for
1936 related rows.
1937
1938 If you want objects to be saved immediately, use L</find_or_create> instead.
1939
1940 B<Note>: C<find_or_new> is probably not what you want when creating a
1941 new row in a table that uses primary keys supplied by the
1942 database. Passing in a primary key column with a value of I<undef>
1943 will cause L</find> to attempt to search for a row with a value of
1944 I<NULL>.
1945
1946 =cut
1947
1948 sub find_or_new {
1949   my $self     = shift;
1950   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
1951   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
1952   my $exists   = $self->find($hash, $attrs);
1953   return defined $exists ? $exists : $self->new_result($hash);
1954 }
1955
1956 =head2 create
1957
1958 =over 4
1959
1960 =item Arguments: \%vals
1961
1962 =item Return Value: a L<DBIx::Class::Row> $object
1963
1964 =back
1965
1966 Attempt to create a single new row or a row with multiple related rows
1967 in the table represented by the resultset (and related tables). This
1968 will not check for duplicate rows before inserting, use
1969 L</find_or_create> to do that.
1970
1971 To create one row for this resultset, pass a hashref of key/value
1972 pairs representing the columns of the table and the values you wish to
1973 store. If the appropriate relationships are set up, foreign key fields
1974 can also be passed an object representing the foreign row, and the
1975 value will be set to its primary key.
1976
1977 To create related objects, pass a hashref for the value if the related
1978 item is a foreign key relationship (L<DBIx::Class::Relationship/belongs_to>),
1979 and use the name of the relationship as the key. (NOT the name of the field,
1980 necessarily). For C<has_many> and C<has_one> relationships, pass an arrayref
1981 of hashrefs containing the data for each of the rows to create in the foreign
1982 tables, again using the relationship name as the key.
1983
1984 Instead of hashrefs of plain related data (key/value pairs), you may
1985 also pass new or inserted objects. New objects (not inserted yet, see
1986 L</new>), will be inserted into their appropriate tables.
1987
1988 Effectively a shortcut for C<< ->new_result(\%vals)->insert >>.
1989
1990 Example of creating a new row.
1991
1992   $person_rs->create({
1993     name=>"Some Person",
1994     email=>"somebody@someplace.com"
1995   });
1996
1997 Example of creating a new row and also creating rows in a related C<has_many>
1998 or C<has_one> resultset.  Note Arrayref.
1999
2000   $artist_rs->create(
2001      { artistid => 4, name => 'Manufactured Crap', cds => [
2002         { title => 'My First CD', year => 2006 },
2003         { title => 'Yet More Tweeny-Pop crap', year => 2007 },
2004       ],
2005      },
2006   );
2007
2008 Example of creating a new row and also creating a row in a related
2009 C<belongs_to>resultset. Note Hashref.
2010
2011   $cd_rs->create({
2012     title=>"Music for Silly Walks",
2013     year=>2000,
2014     artist => {
2015       name=>"Silly Musician",
2016     }
2017   });
2018
2019 =cut
2020
2021 sub create {
2022   my ($self, $attrs) = @_;
2023   $self->throw_exception( "create needs a hashref" )
2024     unless ref $attrs eq 'HASH';
2025   return $self->new_result($attrs)->insert;
2026 }
2027
2028 =head2 find_or_create
2029
2030 =over 4
2031
2032 =item Arguments: \%vals, \%attrs?
2033
2034 =item Return Value: $rowobject
2035
2036 =back
2037
2038   $cd->cd_to_producer->find_or_create({ producer => $producer },
2039                                       { key => 'primary });
2040
2041 Tries to find a record based on its primary key or unique constraints; if none
2042 is found, creates one and returns that instead.
2043
2044   my $cd = $schema->resultset('CD')->find_or_create({
2045     cdid   => 5,
2046     artist => 'Massive Attack',
2047     title  => 'Mezzanine',
2048     year   => 2005,
2049   });
2050
2051 Also takes an optional C<key> attribute, to search by a specific key or unique
2052 constraint. For example:
2053
2054   my $cd = $schema->resultset('CD')->find_or_create(
2055     {
2056       artist => 'Massive Attack',
2057       title  => 'Mezzanine',
2058     },
2059     { key => 'cd_artist_title' }
2060   );
2061
2062 B<Note>: Because find_or_create() reads from the database and then
2063 possibly inserts based on the result, this method is subject to a race
2064 condition. Another process could create a record in the table after
2065 the find has completed and before the create has started. To avoid
2066 this problem, use find_or_create() inside a transaction.
2067
2068 B<Note>: C<find_or_create> is probably not what you want when creating
2069 a new row in a table that uses primary keys supplied by the
2070 database. Passing in a primary key column with a value of I<undef>
2071 will cause L</find> to attempt to search for a row with a value of
2072 I<NULL>.
2073
2074 See also L</find> and L</update_or_create>. For information on how to declare
2075 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2076
2077 =cut
2078
2079 sub find_or_create {
2080   my $self     = shift;
2081   my $attrs    = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2082   my $hash     = ref $_[0] eq 'HASH' ? shift : {@_};
2083   my $exists   = $self->find($hash, $attrs);
2084   return defined $exists ? $exists : $self->create($hash);
2085 }
2086
2087 =head2 update_or_create
2088
2089 =over 4
2090
2091 =item Arguments: \%col_values, { key => $unique_constraint }?
2092
2093 =item Return Value: $rowobject
2094
2095 =back
2096
2097   $resultset->update_or_create({ col => $val, ... });
2098
2099 First, searches for an existing row matching one of the unique constraints
2100 (including the primary key) on the source of this resultset. If a row is
2101 found, updates it with the other given column values. Otherwise, creates a new
2102 row.
2103
2104 Takes an optional C<key> attribute to search on a specific unique constraint.
2105 For example:
2106
2107   # In your application
2108   my $cd = $schema->resultset('CD')->update_or_create(
2109     {
2110       artist => 'Massive Attack',
2111       title  => 'Mezzanine',
2112       year   => 1998,
2113     },
2114     { key => 'cd_artist_title' }
2115   );
2116
2117   $cd->cd_to_producer->update_or_create({
2118     producer => $producer,
2119     name => 'harry',
2120   }, {
2121     key => 'primary,
2122   });
2123
2124
2125 If no C<key> is specified, it searches on all unique constraints defined on the
2126 source, including the primary key.
2127
2128 If the C<key> is specified as C<primary>, it searches only on the primary key.
2129
2130 See also L</find> and L</find_or_create>. For information on how to declare
2131 unique constraints, see L<DBIx::Class::ResultSource/add_unique_constraint>.
2132
2133 B<Note>: C<update_or_create> is probably not what you want when
2134 looking for a row in a table that uses primary keys supplied by the
2135 database, unless you actually have a key value. Passing in a primary
2136 key column with a value of I<undef> will cause L</find> to attempt to
2137 search for a row with a value of I<NULL>.
2138
2139 =cut
2140
2141 sub update_or_create {
2142   my $self = shift;
2143   my $attrs = (@_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {});
2144   my $cond = ref $_[0] eq 'HASH' ? shift : {@_};
2145
2146   my $row = $self->find($cond, $attrs);
2147   if (defined $row) {
2148     $row->update($cond);
2149     return $row;
2150   }
2151
2152   return $self->create($cond);
2153 }
2154
2155 =head2 update_or_new
2156
2157 =over 4
2158
2159 =item Arguments: \%col_values, { key => $unique_constraint }?
2160
2161 =item Return Value: $rowobject
2162
2163 =back
2164
2165   $resultset->update_or_new({ col => $val, ... });
2166
2167 First, searches for an existing row matching one of the unique constraints
2168 (including the primary key) on the source of this resultset. If a row is
2169 found, updates it with the other given column values. Otherwise, instantiate
2170 a new result object and return it. The object will not be saved into your storage
2171 until you call L<DBIx::Class::Row/insert> on it.
2172
2173 Takes an optional C<key> attribute to search on a specific unique constraint.
2174 For example:
2175
2176   # In your application
2177   my $cd = $schema->resultset('CD')->update_or_new(
2178     {
2179       artist => 'Massive Attack',
2180       title  => 'Mezzanine',
2181       year   => 1998,
2182     },
2183     { key => 'cd_artist_title' }
2184   );
2185
2186   if ($cd->in_storage) {
2187       # the cd was updated
2188   }
2189   else {
2190       # the cd is not yet in the database, let's insert it
2191       $cd->insert;
2192   }
2193
2194 See also L</find>, L</find_or_create> and L<find_or_new>.
2195
2196 =cut
2197
2198 sub update_or_new {
2199     my $self  = shift;
2200     my $attrs = ( @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {} );
2201     my $cond  = ref $_[0] eq 'HASH' ? shift : {@_};
2202
2203     my $row = $self->find( $cond, $attrs );
2204     if ( defined $row ) {
2205         $row->update($cond);
2206         return $row;
2207     }
2208
2209     return $self->new_result($cond);
2210 }
2211
2212 =head2 get_cache
2213
2214 =over 4
2215
2216 =item Arguments: none
2217
2218 =item Return Value: \@cache_objects?
2219
2220 =back
2221
2222 Gets the contents of the cache for the resultset, if the cache is set.
2223
2224 The cache is populated either by using the L</prefetch> attribute to
2225 L</search> or by calling L</set_cache>.
2226
2227 =cut
2228
2229 sub get_cache {
2230   shift->{all_cache};
2231 }
2232
2233 =head2 set_cache
2234
2235 =over 4
2236
2237 =item Arguments: \@cache_objects
2238
2239 =item Return Value: \@cache_objects
2240
2241 =back
2242
2243 Sets the contents of the cache for the resultset. Expects an arrayref
2244 of objects of the same class as those produced by the resultset. Note that
2245 if the cache is set the resultset will return the cached objects rather
2246 than re-querying the database even if the cache attr is not set.
2247
2248 The contents of the cache can also be populated by using the
2249 L</prefetch> attribute to L</search>.
2250
2251 =cut
2252
2253 sub set_cache {
2254   my ( $self, $data ) = @_;
2255   $self->throw_exception("set_cache requires an arrayref")
2256       if defined($data) && (ref $data ne 'ARRAY');
2257   $self->{all_cache} = $data;
2258 }
2259
2260 =head2 clear_cache
2261
2262 =over 4
2263
2264 =item Arguments: none
2265
2266 =item Return Value: []
2267
2268 =back
2269
2270 Clears the cache for the resultset.
2271
2272 =cut
2273
2274 sub clear_cache {
2275   shift->set_cache(undef);
2276 }
2277
2278 =head2 related_resultset
2279
2280 =over 4
2281
2282 =item Arguments: $relationship_name
2283
2284 =item Return Value: $resultset
2285
2286 =back
2287
2288 Returns a related resultset for the supplied relationship name.
2289
2290   $artist_rs = $schema->resultset('CD')->related_resultset('Artist');
2291
2292 =cut
2293
2294 sub related_resultset {
2295   my ($self, $rel) = @_;
2296
2297   $self->{related_resultsets} ||= {};
2298   return $self->{related_resultsets}{$rel} ||= do {
2299     my $rel_obj = $self->result_source->relationship_info($rel);
2300
2301     $self->throw_exception(
2302       "search_related: result source '" . $self->result_source->source_name .
2303         "' has no such relationship $rel")
2304       unless $rel_obj;
2305
2306     my ($from,$seen) = $self->_resolve_from($rel);
2307
2308     my $join_count = $seen->{$rel};
2309     my $alias = ($join_count > 1 ? join('_', $rel, $join_count) : $rel);
2310
2311     #XXX - temp fix for result_class bug. There likely is a more elegant fix -groditi
2312     my %attrs = %{$self->{attrs}||{}};
2313     delete @attrs{qw(result_class alias)};
2314
2315     my $new_cache;
2316
2317     if (my $cache = $self->get_cache) {
2318       if ($cache->[0] && $cache->[0]->related_resultset($rel)->get_cache) {
2319         $new_cache = [ map { @{$_->related_resultset($rel)->get_cache} }
2320                         @$cache ];
2321       }
2322     }
2323
2324     my $rel_source = $self->result_source->related_source($rel);
2325
2326     my $new = do {
2327
2328       # The reason we do this now instead of passing the alias to the
2329       # search_rs below is that if you wrap/overload resultset on the
2330       # source you need to know what alias it's -going- to have for things
2331       # to work sanely (e.g. RestrictWithObject wants to be able to add
2332       # extra query restrictions, and these may need to be $alias.)
2333
2334       my $attrs = $rel_source->resultset_attributes;
2335       local $attrs->{alias} = $alias;
2336
2337       $rel_source->resultset
2338                  ->search_rs(
2339                      undef, {
2340                        %attrs,
2341                        join => undef,
2342                        prefetch => undef,
2343                        select => undef,
2344                        as => undef,
2345                        where => $self->{cond},
2346                        seen_join => $seen,
2347                        from => $from,
2348                    });
2349     };
2350     $new->set_cache($new_cache) if $new_cache;
2351     $new;
2352   };
2353 }
2354
2355 =head2 current_source_alias
2356
2357 =over 4
2358
2359 =item Arguments: none
2360
2361 =item Return Value: $source_alias
2362
2363 =back
2364
2365 Returns the current table alias for the result source this resultset is built
2366 on, that will be used in the SQL query. Usually it is C<me>.
2367
2368 Currently the source alias that refers to the result set returned by a
2369 L</search>/L</find> family method depends on how you got to the resultset: it's
2370 C<me> by default, but eg. L</search_related> aliases it to the related result
2371 source name (and keeps C<me> referring to the original result set). The long
2372 term goal is to make L<DBIx::Class> always alias the current resultset as C<me>
2373 (and make this method unnecessary).
2374
2375 Thus it's currently necessary to use this method in predefined queries (see
2376 L<DBIx::Class::Manual::Cookbook/Predefined searches>) when referring to the
2377 source alias of the current result set:
2378
2379   # in a result set class
2380   sub modified_by {
2381     my ($self, $user) = @_;
2382
2383     my $me = $self->current_source_alias;
2384
2385     return $self->search(
2386       "$me.modified" => $user->id,
2387     );
2388   }
2389
2390 =cut
2391
2392 sub current_source_alias {
2393   my ($self) = @_;
2394
2395   return ($self->{attrs} || {})->{alias} || 'me';
2396 }
2397
2398 sub _resolve_from {
2399   my ($self, $extra_join) = @_;
2400   my $source = $self->result_source;
2401   my $attrs = $self->{attrs};
2402
2403   my $from = $attrs->{from}
2404     || [ { $attrs->{alias} => $source->from } ];
2405
2406   my $seen = { %{$attrs->{seen_join}||{}} };
2407
2408   my $join = ($attrs->{join}
2409                ? [ $attrs->{join}, $extra_join ]
2410                : $extra_join);
2411
2412   # we need to take the prefetch the attrs into account before we
2413   # ->resolve_join as otherwise they get lost - captainL
2414   my $merged = $self->_merge_attr( $join, $attrs->{prefetch} );
2415
2416   $from = [
2417     @$from,
2418     ($join ? $source->resolve_join($merged, $attrs->{alias}, $seen) : ()),
2419   ];
2420
2421   return ($from,$seen);
2422 }
2423
2424 sub _resolved_attrs {
2425   my $self = shift;
2426   return $self->{_attrs} if $self->{_attrs};
2427
2428   my $attrs  = { %{ $self->{attrs} || {} } };
2429   my $source = $self->result_source;
2430   my $alias  = $attrs->{alias};
2431
2432   $attrs->{columns} ||= delete $attrs->{cols} if exists $attrs->{cols};
2433   my @colbits;
2434
2435   # build columns (as long as select isn't set) into a set of as/select hashes
2436   unless ( $attrs->{select} ) {
2437       @colbits = map {
2438           ( ref($_) eq 'HASH' )
2439               ? $_
2440               : {
2441                   (
2442                     /^\Q${alias}.\E(.+)$/
2443                       ? "$1"
2444                       : "$_"
2445                   )
2446                 =>
2447                   (
2448                     /\./
2449                       ? "$_"
2450                       : "${alias}.$_"
2451                   )
2452             }
2453       } ( ref($attrs->{columns}) eq 'ARRAY' ) ? @{ delete $attrs->{columns}} : (delete $attrs->{columns} || $source->columns );
2454   }
2455   # add the additional columns on
2456   foreach ( 'include_columns', '+columns' ) {
2457       push @colbits, map {
2458           ( ref($_) eq 'HASH' )
2459             ? $_
2460             : { ( split( /\./, $_ ) )[-1] => ( /\./ ? $_ : "${alias}.$_" ) }
2461       } ( ref($attrs->{$_}) eq 'ARRAY' ) ? @{ delete $attrs->{$_} } : delete $attrs->{$_} if ( $attrs->{$_} );
2462   }
2463
2464   # start with initial select items
2465   if ( $attrs->{select} ) {
2466     $attrs->{select} =
2467         ( ref $attrs->{select} eq 'ARRAY' )
2468       ? [ @{ $attrs->{select} } ]
2469       : [ $attrs->{select} ];
2470     $attrs->{as} = (
2471       $attrs->{as}
2472       ? (
2473         ref $attrs->{as} eq 'ARRAY'
2474         ? [ @{ $attrs->{as} } ]
2475         : [ $attrs->{as} ]
2476         )
2477       : [ map { m/^\Q${alias}.\E(.+)$/ ? $1 : $_ } @{ $attrs->{select} } ]
2478     );
2479   }
2480   else {
2481
2482     # otherwise we intialise select & as to empty
2483     $attrs->{select} = [];
2484     $attrs->{as}     = [];
2485   }
2486
2487   # now add colbits to select/as
2488   push( @{ $attrs->{select} }, map { values( %{$_} ) } @colbits );
2489   push( @{ $attrs->{as} },     map { keys( %{$_} ) } @colbits );
2490
2491   my $adds;
2492   if ( $adds = delete $attrs->{'+select'} ) {
2493     $adds = [$adds] unless ref $adds eq 'ARRAY';
2494     push(
2495       @{ $attrs->{select} },
2496       map { /\./ || ref $_ ? $_ : "${alias}.$_" } @$adds
2497     );
2498   }
2499   if ( $adds = delete $attrs->{'+as'} ) {
2500     $adds = [$adds] unless ref $adds eq 'ARRAY';
2501     push( @{ $attrs->{as} }, @$adds );
2502   }
2503
2504   $attrs->{from} ||= [ { $self->{attrs}{alias} => $source->from } ];
2505
2506   if ( exists $attrs->{join} || exists $attrs->{prefetch} ) {
2507     my $join = delete $attrs->{join} || {};
2508
2509     if ( defined $attrs->{prefetch} ) {
2510       $join = $self->_merge_attr( $join, $attrs->{prefetch} );
2511
2512     }
2513
2514     $attrs->{from} =    # have to copy here to avoid corrupting the original
2515       [
2516       @{ $attrs->{from} },
2517       $source->resolve_join(
2518         $join, $alias, { %{ $attrs->{seen_join} || {} } }
2519       )
2520       ];
2521
2522   }
2523
2524   $attrs->{group_by} ||= $attrs->{select}
2525     if delete $attrs->{distinct};
2526   if ( $attrs->{order_by} ) {
2527     $attrs->{order_by} = (
2528       ref( $attrs->{order_by} ) eq 'ARRAY'
2529       ? [ @{ $attrs->{order_by} } ]
2530       : [ $attrs->{order_by} ]
2531     );
2532   }
2533   else {
2534     $attrs->{order_by} = [];
2535   }
2536
2537   my $collapse = $attrs->{collapse} || {};
2538   if ( my $prefetch = delete $attrs->{prefetch} ) {
2539     $prefetch = $self->_merge_attr( {}, $prefetch );
2540     my @pre_order;
2541     my $seen = { %{ $attrs->{seen_join} || {} } };
2542     foreach my $p ( ref $prefetch eq 'ARRAY' ? @$prefetch : ($prefetch) ) {
2543
2544       # bring joins back to level of current class
2545       my @prefetch =
2546         $source->resolve_prefetch( $p, $alias, $seen, \@pre_order, $collapse );
2547       push( @{ $attrs->{select} }, map { $_->[0] } @prefetch );
2548       push( @{ $attrs->{as} },     map { $_->[1] } @prefetch );
2549     }
2550     push( @{ $attrs->{order_by} }, @pre_order );
2551   }
2552   $attrs->{collapse} = $collapse;
2553
2554   if ( $attrs->{page} ) {
2555     $attrs->{offset} ||= 0;
2556     $attrs->{offset} += ( $attrs->{rows} * ( $attrs->{page} - 1 ) );
2557   }
2558
2559   return $self->{_attrs} = $attrs;
2560 }
2561
2562 sub _rollout_attr {
2563   my ($self, $attr) = @_;
2564
2565   if (ref $attr eq 'HASH') {
2566     return $self->_rollout_hash($attr);
2567   } elsif (ref $attr eq 'ARRAY') {
2568     return $self->_rollout_array($attr);
2569   } else {
2570     return [$attr];
2571   }
2572 }
2573
2574 sub _rollout_array {
2575   my ($self, $attr) = @_;
2576
2577   my @rolled_array;
2578   foreach my $element (@{$attr}) {
2579     if (ref $element eq 'HASH') {
2580       push( @rolled_array, @{ $self->_rollout_hash( $element ) } );
2581     } elsif (ref $element eq 'ARRAY') {
2582       #  XXX - should probably recurse here
2583       push( @rolled_array, @{$self->_rollout_array($element)} );
2584     } else {
2585       push( @rolled_array, $element );
2586     }
2587   }
2588   return \@rolled_array;
2589 }
2590
2591 sub _rollout_hash {
2592   my ($self, $attr) = @_;
2593
2594   my @rolled_array;
2595   foreach my $key (keys %{$attr}) {
2596     push( @rolled_array, { $key => $attr->{$key} } );
2597   }
2598   return \@rolled_array;
2599 }
2600
2601 sub _calculate_score {
2602   my ($self, $a, $b) = @_;
2603
2604   if (ref $b eq 'HASH') {
2605     my ($b_key) = keys %{$b};
2606     if (ref $a eq 'HASH') {
2607       my ($a_key) = keys %{$a};
2608       if ($a_key eq $b_key) {
2609         return (1 + $self->_calculate_score( $a->{$a_key}, $b->{$b_key} ));
2610       } else {
2611         return 0;
2612       }
2613     } else {
2614       return ($a eq $b_key) ? 1 : 0;
2615     }
2616   } else {
2617     if (ref $a eq 'HASH') {
2618       my ($a_key) = keys %{$a};
2619       return ($b eq $a_key) ? 1 : 0;
2620     } else {
2621       return ($b eq $a) ? 1 : 0;
2622     }
2623   }
2624 }
2625
2626 sub _merge_attr {
2627   my ($self, $orig, $import) = @_;
2628
2629   return $import unless defined($orig);
2630   return $orig unless defined($import);
2631
2632   $orig = $self->_rollout_attr($orig);
2633   $import = $self->_rollout_attr($import);
2634
2635   my $seen_keys;
2636   foreach my $import_element ( @{$import} ) {
2637     # find best candidate from $orig to merge $b_element into
2638     my $best_candidate = { position => undef, score => 0 }; my $position = 0;
2639     foreach my $orig_element ( @{$orig} ) {
2640       my $score = $self->_calculate_score( $orig_element, $import_element );
2641       if ($score > $best_candidate->{score}) {
2642         $best_candidate->{position} = $position;
2643         $best_candidate->{score} = $score;
2644       }
2645       $position++;
2646     }
2647     my ($import_key) = ( ref $import_element eq 'HASH' ) ? keys %{$import_element} : ($import_element);
2648
2649     if ($best_candidate->{score} == 0 || exists $seen_keys->{$import_key}) {
2650       push( @{$orig}, $import_element );
2651     } else {
2652       my $orig_best = $orig->[$best_candidate->{position}];
2653       # merge orig_best and b_element together and replace original with merged
2654       if (ref $orig_best ne 'HASH') {
2655         $orig->[$best_candidate->{position}] = $import_element;
2656       } elsif (ref $import_element eq 'HASH') {
2657         my ($key) = keys %{$orig_best};
2658         $orig->[$best_candidate->{position}] = { $key => $self->_merge_attr($orig_best->{$key}, $import_element->{$key}) };
2659       }
2660     }
2661     $seen_keys->{$import_key} = 1; # don't merge the same key twice
2662   }
2663
2664   return $orig;
2665 }
2666
2667 sub result_source {
2668     my $self = shift;
2669
2670     if (@_) {
2671         $self->_source_handle($_[0]->handle);
2672     } else {
2673         $self->_source_handle->resolve;
2674     }
2675 }
2676
2677 =head2 throw_exception
2678
2679 See L<DBIx::Class::Schema/throw_exception> for details.
2680
2681 =cut
2682
2683 sub throw_exception {
2684   my $self=shift;
2685   if (ref $self && $self->_source_handle->schema) {
2686     $self->_source_handle->schema->throw_exception(@_)
2687   } else {
2688     croak(@_);
2689   }
2690
2691 }
2692
2693 # XXX: FIXME: Attributes docs need clearing up
2694
2695 =head1 ATTRIBUTES
2696
2697 Attributes are used to refine a ResultSet in various ways when
2698 searching for data. They can be passed to any method which takes an
2699 C<\%attrs> argument. See L</search>, L</search_rs>, L</find>,
2700 L</count>.
2701
2702 These are in no particular order:
2703
2704 =head2 order_by
2705
2706 =over 4
2707
2708 =item Value: ( $order_by | \@order_by | \%order_by )
2709
2710 =back
2711
2712 Which column(s) to order the results by. If a single column name, or
2713 an arrayref of names is supplied, the argument is passed through
2714 directly to SQL. The hashref syntax allows for connection-agnostic
2715 specification of ordering direction:
2716
2717  For descending order:
2718
2719   order_by => { -desc => [qw/col1 col2 col3/] }
2720
2721  For explicit ascending order:
2722
2723   order_by => { -asc => 'col' }
2724
2725 The old scalarref syntax (i.e. order_by => \'year DESC') is still
2726 supported, although you are strongly encouraged to use the hashref
2727 syntax as outlined above.
2728
2729 =head2 columns
2730
2731 =over 4
2732
2733 =item Value: \@columns
2734
2735 =back
2736
2737 Shortcut to request a particular set of columns to be retrieved. Each
2738 column spec may be a string (a table column name), or a hash (in which
2739 case the key is the C<as> value, and the value is used as the C<select>
2740 expression). Adds C<me.> onto the start of any column without a C<.> in
2741 it and sets C<select> from that, then auto-populates C<as> from
2742 C<select> as normal. (You may also use the C<cols> attribute, as in
2743 earlier versions of DBIC.)
2744
2745 =head2 +columns
2746
2747 =over 4
2748
2749 =item Value: \@columns
2750
2751 =back
2752
2753 Indicates additional columns to be selected from storage. Works the same
2754 as L</columns> but adds columns to the selection. (You may also use the
2755 C<include_columns> attribute, as in earlier versions of DBIC). For
2756 example:-
2757
2758   $schema->resultset('CD')->search(undef, {
2759     '+columns' => ['artist.name'],
2760     join => ['artist']
2761   });
2762
2763 would return all CDs and include a 'name' column to the information
2764 passed to object inflation. Note that the 'artist' is the name of the
2765 column (or relationship) accessor, and 'name' is the name of the column
2766 accessor in the related table.
2767
2768 =head2 include_columns
2769
2770 =over 4
2771
2772 =item Value: \@columns
2773
2774 =back
2775
2776 Deprecated.  Acts as a synonym for L</+columns> for backward compatibility.
2777
2778 =head2 select
2779
2780 =over 4
2781
2782 =item Value: \@select_columns
2783
2784 =back
2785
2786 Indicates which columns should be selected from the storage. You can use
2787 column names, or in the case of RDBMS back ends, function or stored procedure
2788 names:
2789
2790   $rs = $schema->resultset('Employee')->search(undef, {
2791     select => [
2792       'name',
2793       { count => 'employeeid' },
2794       { sum => 'salary' }
2795     ]
2796   });
2797
2798 When you use function/stored procedure names and do not supply an C<as>
2799 attribute, the column names returned are storage-dependent. E.g. MySQL would
2800 return a column named C<count(employeeid)> in the above example.
2801
2802 =head2 +select
2803
2804 =over 4
2805
2806 Indicates additional columns to be selected from storage.  Works the same as
2807 L</select> but adds columns to the selection.
2808
2809 =back
2810
2811 =head2 +as
2812
2813 =over 4
2814
2815 Indicates additional column names for those added via L</+select>. See L</as>.
2816
2817 =back
2818
2819 =head2 as
2820
2821 =over 4
2822
2823 =item Value: \@inflation_names
2824
2825 =back
2826
2827 Indicates column names for object inflation. That is, C<as>
2828 indicates the name that the column can be accessed as via the
2829 C<get_column> method (or via the object accessor, B<if one already
2830 exists>).  It has nothing to do with the SQL code C<SELECT foo AS bar>.
2831
2832 The C<as> attribute is used in conjunction with C<select>,
2833 usually when C<select> contains one or more function or stored
2834 procedure names:
2835
2836   $rs = $schema->resultset('Employee')->search(undef, {
2837     select => [
2838       'name',
2839       { count => 'employeeid' }
2840     ],
2841     as => ['name', 'employee_count'],
2842   });
2843
2844   my $employee = $rs->first(); # get the first Employee
2845
2846 If the object against which the search is performed already has an accessor
2847 matching a column name specified in C<as>, the value can be retrieved using
2848 the accessor as normal:
2849
2850   my $name = $employee->name();
2851
2852 If on the other hand an accessor does not exist in the object, you need to
2853 use C<get_column> instead:
2854
2855   my $employee_count = $employee->get_column('employee_count');
2856
2857 You can create your own accessors if required - see
2858 L<DBIx::Class::Manual::Cookbook> for details.
2859
2860 Please note: This will NOT insert an C<AS employee_count> into the SQL
2861 statement produced, it is used for internal access only. Thus
2862 attempting to use the accessor in an C<order_by> clause or similar
2863 will fail miserably.
2864
2865 To get around this limitation, you can supply literal SQL to your
2866 C<select> attibute that contains the C<AS alias> text, eg:
2867
2868   select => [\'myfield AS alias']
2869
2870 =head2 join
2871
2872 =over 4
2873
2874 =item Value: ($rel_name | \@rel_names | \%rel_names)
2875
2876 =back
2877
2878 Contains a list of relationships that should be joined for this query.  For
2879 example:
2880
2881   # Get CDs by Nine Inch Nails
2882   my $rs = $schema->resultset('CD')->search(
2883     { 'artist.name' => 'Nine Inch Nails' },
2884     { join => 'artist' }
2885   );
2886
2887 Can also contain a hash reference to refer to the other relation's relations.
2888 For example:
2889
2890   package MyApp::Schema::Track;
2891   use base qw/DBIx::Class/;
2892   __PACKAGE__->table('track');
2893   __PACKAGE__->add_columns(qw/trackid cd position title/);
2894   __PACKAGE__->set_primary_key('trackid');
2895   __PACKAGE__->belongs_to(cd => 'MyApp::Schema::CD');
2896   1;
2897
2898   # In your application
2899   my $rs = $schema->resultset('Artist')->search(
2900     { 'track.title' => 'Teardrop' },
2901     {
2902       join     => { cd => 'track' },
2903       order_by => 'artist.name',
2904     }
2905   );
2906
2907 You need to use the relationship (not the table) name in  conditions,
2908 because they are aliased as such. The current table is aliased as "me", so
2909 you need to use me.column_name in order to avoid ambiguity. For example:
2910
2911   # Get CDs from 1984 with a 'Foo' track
2912   my $rs = $schema->resultset('CD')->search(
2913     {
2914       'me.year' => 1984,
2915       'tracks.name' => 'Foo'
2916     },
2917     { join => 'tracks' }
2918   );
2919
2920 If the same join is supplied twice, it will be aliased to <rel>_2 (and
2921 similarly for a third time). For e.g.
2922
2923   my $rs = $schema->resultset('Artist')->search({
2924     'cds.title'   => 'Down to Earth',
2925     'cds_2.title' => 'Popular',
2926   }, {
2927     join => [ qw/cds cds/ ],
2928   });
2929
2930 will return a set of all artists that have both a cd with title 'Down
2931 to Earth' and a cd with title 'Popular'.
2932
2933 If you want to fetch related objects from other tables as well, see C<prefetch>
2934 below.
2935
2936 For more help on using joins with search, see L<DBIx::Class::Manual::Joining>.
2937
2938 =head2 prefetch
2939
2940 =over 4
2941
2942 =item Value: ($rel_name | \@rel_names | \%rel_names)
2943
2944 =back
2945
2946 Contains one or more relationships that should be fetched along with
2947 the main query (when they are accessed afterwards the data will
2948 already be available, without extra queries to the database).  This is
2949 useful for when you know you will need the related objects, because it
2950 saves at least one query:
2951
2952   my $rs = $schema->resultset('Tag')->search(
2953     undef,
2954     {
2955       prefetch => {
2956         cd => 'artist'
2957       }
2958     }
2959   );
2960
2961 The initial search results in SQL like the following:
2962
2963   SELECT tag.*, cd.*, artist.* FROM tag
2964   JOIN cd ON tag.cd = cd.cdid
2965   JOIN artist ON cd.artist = artist.artistid
2966
2967 L<DBIx::Class> has no need to go back to the database when we access the
2968 C<cd> or C<artist> relationships, which saves us two SQL statements in this
2969 case.
2970
2971 Simple prefetches will be joined automatically, so there is no need
2972 for a C<join> attribute in the above search.
2973
2974 C<prefetch> can be used with the following relationship types: C<belongs_to>,
2975 C<has_one> (or if you're using C<add_relationship>, any relationship declared
2976 with an accessor type of 'single' or 'filter'). A more complex example that
2977 prefetches an artists cds, the tracks on those cds, and the tags associted
2978 with that artist is given below (assuming many-to-many from artists to tags):
2979
2980  my $rs = $schema->resultset('Artist')->search(
2981    undef,
2982    {
2983      prefetch => [
2984        { cds => 'tracks' },
2985        { artist_tags => 'tags' }
2986      ]
2987    }
2988  );
2989
2990
2991 B<NOTE:> If you specify a C<prefetch> attribute, the C<join> and C<select>
2992 attributes will be ignored.
2993
2994 =head2 page
2995
2996 =over 4
2997
2998 =item Value: $page
2999
3000 =back
3001
3002 Makes the resultset paged and specifies the page to retrieve. Effectively
3003 identical to creating a non-pages resultset and then calling ->page($page)
3004 on it.
3005
3006 If L<rows> attribute is not specified it defualts to 10 rows per page.
3007
3008 When you have a paged resultset, L</count> will only return the number
3009 of rows in the page. To get the total, use the L</pager> and call
3010 C<total_entries> on it.
3011
3012 =head2 rows
3013
3014 =over 4
3015
3016 =item Value: $rows
3017
3018 =back
3019
3020 Specifes the maximum number of rows for direct retrieval or the number of
3021 rows per page if the page attribute or method is used.
3022
3023 =head2 offset
3024
3025 =over 4
3026
3027 =item Value: $offset
3028
3029 =back
3030
3031 Specifies the (zero-based) row number for the  first row to be returned, or the
3032 of the first row of the first page if paging is used.
3033
3034 =head2 group_by
3035
3036 =over 4
3037
3038 =item Value: \@columns
3039
3040 =back
3041
3042 A arrayref of columns to group by. Can include columns of joined tables.
3043
3044   group_by => [qw/ column1 column2 ... /]
3045
3046 =head2 having
3047
3048 =over 4
3049
3050 =item Value: $condition
3051
3052 =back
3053
3054 HAVING is a select statement attribute that is applied between GROUP BY and
3055 ORDER BY. It is applied to the after the grouping calculations have been
3056 done.
3057
3058   having => { 'count(employee)' => { '>=', 100 } }
3059
3060 =head2 distinct
3061
3062 =over 4
3063
3064 =item Value: (0 | 1)
3065
3066 =back
3067
3068 Set to 1 to group by all columns.
3069
3070 =head2 where
3071
3072 =over 4
3073
3074 Adds to the WHERE clause.
3075
3076   # only return rows WHERE deleted IS NULL for all searches
3077   __PACKAGE__->resultset_attributes({ where => { deleted => undef } }); )
3078
3079 Can be overridden by passing C<{ where => undef }> as an attribute
3080 to a resulset.
3081
3082 =back
3083
3084 =head2 cache
3085
3086 Set to 1 to cache search results. This prevents extra SQL queries if you
3087 revisit rows in your ResultSet:
3088
3089   my $resultset = $schema->resultset('Artist')->search( undef, { cache => 1 } );
3090
3091   while( my $artist = $resultset->next ) {
3092     ... do stuff ...
3093   }
3094
3095   $rs->first; # without cache, this would issue a query
3096
3097 By default, searches are not cached.
3098
3099 For more examples of using these attributes, see
3100 L<DBIx::Class::Manual::Cookbook>.
3101
3102 =head2 from
3103
3104 =over 4
3105
3106 =item Value: \@from_clause
3107
3108 =back
3109
3110 The C<from> attribute gives you manual control over the C<FROM> clause of SQL
3111 statements generated by L<DBIx::Class>, allowing you to express custom C<JOIN>
3112 clauses.
3113
3114 NOTE: Use this on your own risk.  This allows you to shoot off your foot!
3115
3116 C<join> will usually do what you need and it is strongly recommended that you
3117 avoid using C<from> unless you cannot achieve the desired result using C<join>.
3118 And we really do mean "cannot", not just tried and failed. Attempting to use
3119 this because you're having problems with C<join> is like trying to use x86
3120 ASM because you've got a syntax error in your C. Trust us on this.
3121
3122 Now, if you're still really, really sure you need to use this (and if you're
3123 not 100% sure, ask the mailing list first), here's an explanation of how this
3124 works.
3125
3126 The syntax is as follows -
3127
3128   [
3129     { <alias1> => <table1> },
3130     [
3131       { <alias2> => <table2>, -join_type => 'inner|left|right' },
3132       [], # nested JOIN (optional)
3133       { <table1.column1> => <table2.column2>, ... (more conditions) },
3134     ],
3135     # More of the above [ ] may follow for additional joins
3136   ]
3137
3138   <table1> <alias1>
3139   JOIN
3140     <table2> <alias2>
3141     [JOIN ...]
3142   ON <table1.column1> = <table2.column2>
3143   <more joins may follow>
3144
3145 An easy way to follow the examples below is to remember the following:
3146
3147     Anything inside "[]" is a JOIN
3148     Anything inside "{}" is a condition for the enclosing JOIN
3149
3150 The following examples utilize a "person" table in a family tree application.
3151 In order to express parent->child relationships, this table is self-joined:
3152
3153     # Person->belongs_to('father' => 'Person');
3154     # Person->belongs_to('mother' => 'Person');
3155
3156 C<from> can be used to nest joins. Here we return all children with a father,
3157 then search against all mothers of those children:
3158
3159   $rs = $schema->resultset('Person')->search(
3160       undef,
3161       {
3162           alias => 'mother', # alias columns in accordance with "from"
3163           from => [
3164               { mother => 'person' },
3165               [
3166                   [
3167                       { child => 'person' },
3168                       [
3169                           { father => 'person' },
3170                           { 'father.person_id' => 'child.father_id' }
3171                       ]
3172                   ],
3173                   { 'mother.person_id' => 'child.mother_id' }
3174               ],
3175           ]
3176       },
3177   );
3178
3179   # Equivalent SQL:
3180   # SELECT mother.* FROM person mother
3181   # JOIN (
3182   #   person child
3183   #   JOIN person father
3184   #   ON ( father.person_id = child.father_id )
3185   # )
3186   # ON ( mother.person_id = child.mother_id )
3187
3188 The type of any join can be controlled manually. To search against only people
3189 with a father in the person table, we could explicitly use C<INNER JOIN>:
3190
3191     $rs = $schema->resultset('Person')->search(
3192         undef,
3193         {
3194             alias => 'child', # alias columns in accordance with "from"
3195             from => [
3196                 { child => 'person' },
3197                 [
3198                     { father => 'person', -join_type => 'inner' },
3199                     { 'father.id' => 'child.father_id' }
3200                 ],
3201             ]
3202         },
3203     );
3204
3205     # Equivalent SQL:
3206     # SELECT child.* FROM person child
3207     # INNER JOIN person father ON child.father_id = father.id
3208
3209 If you need to express really complex joins or you need a subselect, you
3210 can supply literal SQL to C<from> via a scalar reference. In this case
3211 the contents of the scalar will replace the table name asscoiated with the
3212 resultsource.
3213
3214 WARNING: This technique might very well not work as expected on chained
3215 searches - you have been warned.
3216
3217     # Assuming the Event resultsource is defined as:
3218
3219         MySchema::Event->add_columns (
3220             sequence => {
3221                 data_type => 'INT',
3222                 is_auto_increment => 1,
3223             },
3224             location => {
3225                 data_type => 'INT',
3226             },
3227             type => {
3228                 data_type => 'INT',
3229             },
3230         );
3231         MySchema::Event->set_primary_key ('sequence');
3232
3233     # This will get back the latest event for every location. The column
3234     # selector is still provided by DBIC, all we do is add a JOIN/WHERE
3235     # combo to limit the resultset
3236
3237     $rs = $schema->resultset('Event');
3238     $table = $rs->result_source->name;
3239     $latest = $rs->search (
3240         undef,
3241         { from => \ "
3242             (SELECT e1.* FROM $table e1
3243                 JOIN $table e2
3244                     ON e1.location = e2.location
3245                     AND e1.sequence < e2.sequence
3246                 WHERE e2.sequence is NULL
3247             ) me",
3248         },
3249     );
3250
3251     # Equivalent SQL (with the DBIC chunks added):
3252
3253     SELECT me.sequence, me.location, me.type FROM
3254        (SELECT e1.* FROM events e1
3255            JOIN events e2
3256                ON e1.location = e2.location
3257                AND e1.sequence < e2.sequence
3258            WHERE e2.sequence is NULL
3259        ) me;
3260
3261 =head2 for
3262
3263 =over 4
3264
3265 =item Value: ( 'update' | 'shared' )
3266
3267 =back
3268
3269 Set to 'update' for a SELECT ... FOR UPDATE or 'shared' for a SELECT
3270 ... FOR SHARED.
3271
3272 =cut
3273
3274 1;