lib/DBIx/Class/ResultClass/HashRefInflator.pm

   1 package DBIx::Class::ResultClass::HashRefInflator;
   2
   3 use strict;
   4 use warnings;
   5
   6 =head1 NAME
   7
   8 DBIx::Class::ResultClass::HashRefInflator - Get raw hashrefs from a resultset
   9
  10 =head1 SYNOPSIS
  11
  12  use DBIx::Class::ResultClass::HashRefInflator;
  13
  14  my $rs = $schema->resultset('CD');
  15  $rs->result_class('DBIx::Class::ResultClass::HashRefInflator');
  16  while (my $hashref = $rs->next) {
  17     ...
  18  }
  19
  20 =head1 DESCRIPTION
  21
  22 DBIx::Class is faster than older ORMs like Class::DBI but it still isn't
  23 designed primarily for speed. Sometimes you need to quickly retrieve the data
  24 from a massive resultset, while skipping the creation of fancy row objects.
  25 Specifying this class as a C<result_class> for a resultset will change C<< $rs->next >>
  26 to return a plain data hash-ref (or a list of such hash-refs if C<< $rs->all >> is used).
  27
  28 There are two ways of applying this class to a resultset:
  29
  30 =over
  31
  32 =item *
  33
  34 Specify C<< $rs->result_class >> on a specific resultset to affect only that
  35 resultset (and any chained off of it); or
  36
  37 =item *
  38
  39 Specify C<< __PACKAGE__->result_class >> on your source object to force all
  40 uses of that result source to be inflated to hash-refs - this approach is not
  41 recommended.
  42
  43 =back
  44
  45 =cut
  46
  47 ##############
  48 # NOTE
  49 #
  50 # Generally people use this to gain as much speed as possible. If a new &mk_hash is
  51 # implemented, it should be benchmarked using the maint/benchmark_hashrefinflator.pl
  52 # script (in addition to passing all tests of course :). Additional instructions are
  53 # provided in the script itself.
  54 #
  55
  56 # This coderef is a simple recursive function
  57 # Arguments: ($me, $prefetch) from inflate_result() below
  58 my $mk_hash;
  59 $mk_hash = sub {
  60     if (ref $_[0] eq 'ARRAY') {     # multi relationship
  61         return [ map { $mk_hash->(@$_) || () } (@_) ];
  62     }
  63     else {
  64         my $hash = {
  65             # the main hash could be an undef if we are processing a skipped-over join
  66             $_[0] ? %{$_[0]} : (),
  67
  68             # the second arg is a hash of arrays for each prefetched relation
  69             map
  70                 { $_ => $mk_hash->( @{$_[1]->{$_}} ) }
  71                 ( $_[1] ? (keys %{$_[1]}) : () )
  72         };
  73
  74         # if there is at least one defined column consider the resultset real
  75         # (and not an emtpy has_many rel containing one empty hashref)
  76         for (values %$hash) {
  77             return $hash if defined $_;
  78         }
  79
  80         return undef;
  81     }
  82 };
  83
  84 =head1 METHODS
  85
  86 =head2 inflate_result
  87
  88 Inflates the result and prefetched data into a hash-ref (invoked by L<DBIx::Class::ResultSet>)
  89
  90 =cut
  91
  92 ##################################################################################
  93 # inflate_result is invoked as:
  94 # HRI->inflate_result ($resultsource_instance, $main_data_hashref, $prefetch_data_hashref)
  95 sub inflate_result {
  96     return $mk_hash->($_[2], $_[3]);
  97 }
  98
  99
 100 =head1 CAVEATS
 101
 102 =over
 103
 104 =item *
 105
 106 This will not work for relationships that have been prefetched. Consider the
 107 following:
 108
 109  my $artist = $artitsts_rs->search({}, {prefetch => 'cds' })->first;
 110
 111  my $cds = $artist->cds;
 112  $cds->result_class('DBIx::Class::ResultClass::HashRefInflator');
 113  my $first = $cds->first;
 114
 115 C<$first> will B<not> be a hashref, it will be a normal CD row since
 116 HashRefInflator only affects resultsets at inflation time, and prefetch causes
 117 relations to be inflated when the master C<$artist> row is inflated.
 118
 119 =back
 120
 121 =cut
 122
 123 1;