lib/DBIx/Class/Relationship/ManyToMany.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::ManyToMany;
   3
   4 use strict;
   5 use warnings;
   6
   7 sub many_to_many {
   8   my ($class, $meth, $rel, $f_rel, $rel_attrs) = @_;
   9
  10   $class->throw_exception(
  11     "missing relation in many-to-many"
  12   ) unless $rel;
  13
  14   $class->throw_exception(
  15     "missing foreign relation in many-to-many"
  16   ) unless $f_rel;
  17
  18   {
  19     no strict 'refs';
  20     no warnings 'redefine';
  21
  22     my $add_meth = "add_to_${meth}";
  23     my $remove_meth = "remove_from_${meth}";
  24     my $set_meth = "set_${meth}";
  25     my $rs_meth = "${meth}_rs";
  26
  27     $rel_attrs->{alias} ||= $f_rel;
  28
  29     *{"${class}::${meth}_rs"} = sub {
  30       my $self = shift;
  31       my $attrs = @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {};
  32       my @args = ($f_rel, @_ > 0 ? @_ : undef, { %{$rel_attrs||{}}, %$attrs });
  33       my $rs = $self->search_related($rel)->search_related(
  34         $f_rel, @_ > 0 ? @_ : undef, { %{$rel_attrs||{}}, %$attrs }
  35       );
  36           return $rs;
  37     };
  38
  39         *{"${class}::${meth}"} = sub {
  40                 my $self = shift;
  41                 my $rs = $self->$rs_meth( @_ );
  42                 return (wantarray ? $rs->all : $rs);
  43         };
  44
  45     *{"${class}::${add_meth}"} = sub {
  46       my $self = shift;
  47       @_ > 0 or $self->throw_exception(
  48         "${add_meth} needs an object or hashref"
  49       );
  50       my $source = $self->result_source;
  51       my $schema = $source->schema;
  52       my $rel_source_name = $source->relationship_info($rel)->{source};
  53       my $rel_source = $schema->resultset($rel_source_name)->result_source;
  54       my $f_rel_source_name = $rel_source->relationship_info($f_rel)->{source};
  55       my $f_rel_rs = $schema->resultset($f_rel_source_name)->search({}, $rel_attrs||{});
  56
  57       my $obj;
  58       if (ref $_[0]) {
  59         if (ref $_[0] eq 'HASH') {
  60           $obj = $f_rel_rs->create($_[0]);
  61         } else {
  62           $obj = $_[0];
  63         }
  64       } else {
  65         $obj = $f_rel_rs->create({@_});
  66       }
  67
  68       my $link_vals = @_ > 1 && ref $_[$#_] eq 'HASH' ? pop(@_) : {};
  69       my $link = $self->search_related($rel)->new_result({});
  70       $link->set_from_related($f_rel, $obj);
  71       $link->set_columns($link_vals);
  72       $link->insert();
  73           return $obj;
  74     };
  75
  76     *{"${class}::${set_meth}"} = sub {
  77       my $self = shift;
  78       @_ > 0 or $self->throw_exception(
  79         "{$set_meth} needs a list of objects or hashrefs"
  80       );
  81       my @to_set = (ref($_[0]) eq 'ARRAY' ? @{ $_[0] } : @_);
  82       $self->search_related($rel, {})->delete;
  83       $self->$add_meth($_) for (@to_set);
  84     };
  85
  86     *{"${class}::${remove_meth}"} = sub {
  87       my $self = shift;
  88       @_ > 0 && ref $_[0] ne 'HASH'
  89         or $self->throw_exception("${remove_meth} needs an object");
  90       my $obj = shift;
  91       my $rel_source = $self->search_related($rel)->result_source;
  92       my $cond = $rel_source->relationship_info($f_rel)->{cond};
  93       my $link_cond = $rel_source->resolve_condition(
  94         $cond, $obj, $f_rel
  95       );
  96       $self->search_related($rel, $link_cond)->delete;
  97     };
  98
  99   }
 100 }
 101
 102 1;