lib/DBIx/Class/Relationship/HasMany.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::HasMany;
   3
   4 use strict;
   5 use warnings;
   6
   7 sub has_many {
   8   my ($class, $rel, $f_class, $cond, $attrs) = @_;
   9
  10   eval "require $f_class";
  11   if ($@) {
  12     $class->throw_exception($@) unless $@ =~ /Can't locate/;
  13   }
  14
  15   unless (ref $cond) {
  16     my ($pri, $too_many) = $class->primary_columns;
  17     $class->throw_exception( "has_many can only infer join for a single primary key; ${class} has more" )
  18       if $too_many;
  19
  20     my ($f_key,$guess);
  21     if (defined $cond && length $cond) {
  22       $f_key = $cond;
  23       $guess = "caller specified foreign key '$f_key'";
  24     } else {
  25       $class =~ /([^\:]+)$/;
  26       $f_key = lc $1; # go ahead and guess; best we can do
  27       $guess = "using our class name '$class' as foreign key";
  28     }
  29
  30     my $f_class_loaded = eval { $f_class->columns };
  31     $class->throw_exception("No such column ${f_key} on foreign class ${f_class} ($guess)")
  32       if $f_class_loaded && !$f_class->has_column($f_key);
  33
  34     $cond = { "foreign.${f_key}" => "self.${pri}" };
  35   }
  36
  37   $class->add_relationship($rel, $f_class, $cond,
  38                             { accessor => 'multi',
  39                               join_type => 'LEFT',
  40                               cascade_delete => 1,
  41                               cascade_copy => 1,
  42                               %{$attrs||{}} } );
  43 }
  44
  45 1;