lib/DBIx/Class/Relationship/BelongsTo.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::BelongsTo;
   3
   4 # Documentation for these methods can be found in
   5 # DBIx::Class::Relationship
   6
   7 use strict;
   8 use warnings;
   9 use Try::Tiny;
  10 use namespace::clean;
  11
  12 our %_pod_inherit_config =
  13   (
  14    class_map => { 'DBIx::Class::Relationship::BelongsTo' => 'DBIx::Class::Relationship' }
  15   );
  16
  17 sub belongs_to  { goto \&refers_to }
  18
  19 sub refers_to {
  20   my ($class, $rel, $f_class, $cond, $attrs) = @_;
  21
  22   # assume a foreign key contraint unless defined otherwise
  23   $attrs->{is_foreign_key_constraint} = 1
  24     if not exists $attrs->{is_foreign_key_constraint};
  25   $attrs->{undef_on_null_fk} = 1
  26     if not exists $attrs->{undef_on_null_fk};
  27
  28   # no join condition or just a column name
  29   if (!ref $cond) {
  30     $class->ensure_class_loaded($f_class);
  31     my %f_primaries = map { $_ => 1 } try { $f_class->_pri_cols }
  32       catch {
  33         $class->throw_exception( "Can't infer join condition for '$rel' on ${class}: $_");
  34       };
  35
  36     my ($pri, $too_many) = keys %f_primaries;
  37     $class->throw_exception(
  38       "Can't infer join condition for '$rel' on ${class}: "
  39     . "${f_class} has multiple primary keys"
  40     ) if $too_many;
  41
  42     my $fk = defined $cond ? $cond : $rel;
  43     $class->throw_exception(
  44       "Can't infer join condition for '$rel' on ${class}: "
  45     . "'$fk' is not a column of $class"
  46     ) unless $class->has_column($fk);
  47
  48     $cond = { "foreign.${pri}" => "self.${fk}" };
  49
  50   }
  51   # explicit join condition
  52   elsif (ref $cond) {
  53     if (ref $cond eq 'HASH') { # ARRAY is also valid
  54       my $cond_rel;
  55       for (keys %$cond) {
  56         if (m/\./) { # Explicit join condition
  57           $cond_rel = $cond;
  58           last;
  59         }
  60         $cond_rel->{"foreign.$_"} = "self.".$cond->{$_};
  61       }
  62       $cond = $cond_rel;
  63     }
  64   }
  65   # dunno
  66   else {
  67     $class->throw_exception(
  68       'third argument for refers_to must be undef, a column name, '.
  69       'or a join condition'
  70     );
  71   }
  72
  73   my $acc_type = (
  74     ref $cond eq 'HASH'
  75       and
  76     keys %$cond == 1
  77       and
  78     $class->has_column($rel)
  79   ) ? 'filter' : 'single';
  80
  81   my $fk_columns = ($acc_type eq 'single' and ref $cond eq 'HASH')
  82     ? { map { $_ =~ /^self\.(.+)/ ? ( $1 => 1 ) : () } (values %$cond ) }
  83     : undef
  84   ;
  85
  86   $class->add_relationship($rel, $f_class,
  87     $cond,
  88     {
  89       accessor => $acc_type,
  90       $fk_columns ? ( fk_columns => $fk_columns ) : (),
  91       %{$attrs || {}}
  92     }
  93   );
  94
  95   return 1;
  96 }
  97
  98 # Attempt to remove the POD so it (maybe) falls off the indexer
  99
 100 #=head1 AUTHORS
 101 #
 102 #Alexander Hartmaier <Alexander.Hartmaier@t-systems.at>
 103 #
 104 #Matt S. Trout <mst@shadowcatsystems.co.uk>
 105 #
 106 #=cut
 107
 108 1;