lib/DBIx/Class/Relationship/Accessor.pm

   1 package # hide from PAUSE
   2     DBIx::Class::Relationship::Accessor;
   3
   4 use strict;
   5 use warnings;
   6 use DBIx::Class::Carp;
   7 use DBIx::Class::_Util qw(quote_sub perlstring);
   8 use namespace::clean;
   9
  10 our %_pod_inherit_config =
  11   (
  12    class_map => { 'DBIx::Class::Relationship::Accessor' => 'DBIx::Class::Relationship' }
  13   );
  14
  15 sub register_relationship {
  16   my ($class, $rel, $info) = @_;
  17   if (my $acc_type = $info->{attrs}{accessor}) {
  18     $class->add_relationship_accessor($rel => $acc_type);
  19   }
  20   $class->next::method($rel => $info);
  21 }
  22
  23 sub add_relationship_accessor {
  24   my ($class, $rel, $acc_type) = @_;
  25
  26   if ($acc_type eq 'single') {
  27
  28     my @qsub_args = ( {}, {
  29       attributes => [qw(
  30         DBIC_method_is_single_relationship_accessor
  31         DBIC_method_is_generated_from_resultsource_metadata
  32       )]
  33     });
  34
  35
  36     quote_sub "${class}::${rel}" => sprintf(<<'EOC', perlstring $rel), @qsub_args;
  37       my $self = shift;
  38
  39       if (@_) {
  40         $self->set_from_related( %1$s => @_ );
  41         return $self->{_relationship_data}{%1$s} = $_[0];
  42       }
  43       elsif (exists $self->{_relationship_data}{%1$s}) {
  44         return $self->{_relationship_data}{%1$s};
  45       }
  46       else {
  47         my $rsrc = $self->result_source;
  48
  49         my $jfc;
  50
  51         return undef if (
  52
  53           $rsrc->relationship_info(%1$s)->{attrs}{undef_on_null_fk}
  54
  55             and
  56
  57           $jfc = ( $rsrc->_resolve_relationship_condition(
  58             rel_name => %1$s,
  59             foreign_alias => %1$s,
  60             self_alias => 'me',
  61             self_result_object => $self,
  62           )->{join_free_condition} || {} )
  63
  64             and
  65
  66           $jfc ne DBIx::Class::_Util::UNRESOLVABLE_CONDITION
  67
  68             and
  69
  70           grep { not defined $_ } values %%$jfc
  71         );
  72
  73         my $val = $self->related_resultset( %1$s )->single;
  74         return $val unless $val;  # $val instead of undef so that null-objects can go through
  75
  76         return $self->{_relationship_data}{%1$s} = $val;
  77       }
  78 EOC
  79   }
  80   elsif ($acc_type eq 'filter') {
  81
  82     my $rsrc = $class->result_source_instance;
  83
  84     $rsrc->throw_exception("No such column '$rel' to filter")
  85        unless $rsrc->has_column($rel);
  86
  87     my $f_class = $rsrc->relationship_info($rel)->{class};
  88
  89     $class->inflate_column($rel, {
  90       inflate => sub {
  91         my ($val, $self) = @_;
  92         return $self->find_or_new_related($rel, {});
  93       },
  94       deflate => sub {
  95         my ($val, $self) = @_;
  96         $self->throw_exception("'$val' isn't a $f_class") unless $val->isa($f_class);
  97
  98         # MASSIVE FIXME - this code assumes we pointed at the PK, but the belongs_to
  99         # helper does not check any of this
 100         # fixup the code a bit to make things saner, but ideally 'filter' needs to
 101         # be deprecated ASAP and removed shortly after
 102         # Not doing so before 0.08250 however, too many things in motion already
 103         my ($pk_col, @rest) = $val->result_source->_pri_cols_or_die;
 104         $self->throw_exception(
 105           "Relationship '$rel' of type 'filter' can not work with a multicolumn primary key on source '$f_class'"
 106         ) if @rest;
 107
 108         my $pk_val = $val->get_column($pk_col);
 109         carp_unique (
 110           "Unable to deflate 'filter'-type relationship '$rel' (related object "
 111         . "primary key not retrieved), assuming undef instead"
 112         ) if ( ! defined $pk_val and $val->in_storage );
 113
 114         return $pk_val;
 115       },
 116     });
 117
 118
 119     # god this is horrible...
 120     my $acc =
 121       $rsrc->columns_info->{$rel}{accessor}
 122         ||
 123       $rel
 124     ;
 125
 126     # because CDBI may elect to never make an accessor at all...
 127     if( my $main_cref = $class->can($acc) ) {
 128
 129       attributes->import(
 130         $class,
 131         $main_cref,
 132         qw(
 133           DBIC_method_is_filter_relationship_accessor
 134           DBIC_method_is_generated_from_resultsource_metadata
 135         ),
 136       );
 137
 138       if( my $extra_cref = $class->can("_${acc}_accessor") ) {
 139         attributes->import(
 140           $class,
 141           $extra_cref,
 142           qw(
 143             DBIC_method_is_filter_relationship_extra_accessor
 144             DBIC_method_is_generated_from_resultsource_metadata
 145           ),
 146         );
 147       }
 148     }
 149   }
 150   elsif ($acc_type eq 'multi') {
 151
 152
 153     my @qsub_args = (
 154       {},
 155       {
 156         attributes => [qw(
 157           DBIC_method_is_multi_relationship_accessor
 158           DBIC_method_is_generated_from_resultsource_metadata
 159           DBIC_method_is_indirect_sugar
 160         )]
 161       },
 162     );
 163
 164
 165     quote_sub "${class}::${rel}", sprintf( <<'EOC', perlstring $rel ), @qsub_args;
 166       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and DBIx::Class::_Util::fail_on_internal_call;
 167       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_WANTARRAY and my $sog = DBIx::Class::_Util::fail_on_internal_wantarray;
 168       shift->related_resultset(%s)->search( @_ )
 169 EOC
 170
 171
 172     $qsub_args[1]{attributes}[0]
 173       =~ s/^DBIC_method_is_multi_relationship_accessor$/DBIC_method_is_multi_relationship_extra_accessor/
 174     or die "Unexpected attr '$qsub_args[1]{attributes}[0]' ...";
 175
 176
 177     quote_sub "${class}::${rel}_rs", sprintf( <<'EOC', perlstring $rel ), @qsub_args;
 178       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and DBIx::Class::_Util::fail_on_internal_call;
 179       shift->related_resultset(%s)->search_rs( @_ )
 180 EOC
 181
 182
 183     quote_sub "${class}::add_to_${rel}", sprintf( <<'EOC', perlstring $rel ), @qsub_args;
 184       DBIx::Class::_ENV_::ASSERT_NO_INTERNAL_INDIRECT_CALLS and DBIx::Class::_Util::fail_on_internal_call;
 185       shift->create_related( %s => @_ );
 186 EOC
 187
 188   }
 189   else {
 190     $class->throw_exception("No such relationship accessor type '$acc_type'");
 191   }
 192
 193 }
 194
 195 1;