lib/DBIx/Class/Relationship/Accessor.pm

   1 package DBIx::Class::Relationship::Accessor;
   2
   3 use strict;
   4 use warnings;
   5
   6 sub add_relationship {
   7   my ($class, $rel, @rest) = @_;
   8   my $ret = $class->NEXT::ACTUAL::add_relationship($rel => @rest);
   9   my $rel_obj = $class->_relationships->{$rel};
  10   if (my $acc_type = $rel_obj->{attrs}{accessor}) {
  11     $class->_add_relationship_accessor($rel => $acc_type);
  12   }
  13   return $ret;
  14 }
  15
  16 sub _add_relationship_accessor {
  17   my ($class, $rel, $acc_type) = @_;
  18   my %meth;
  19   if ($acc_type eq 'single') {
  20     $meth{$rel} = sub {
  21       my $self = shift;
  22       if (@_) {
  23         $self->set_from_related($rel, @_);
  24         return $self->{_relationship_data}{$rel} = $_[0];
  25       } elsif (exists $self->{_relationship_data}{$rel}) {
  26         return $self->{_relationship_data}{$rel};
  27       } else {
  28         return $self->{_relationship_data}{$rel}
  29                  = $self->find_or_create_related($rel, {}, {});
  30       }
  31     };
  32   } elsif ($acc_type eq 'filter') {
  33     $class->throw("No such column $rel to filter")
  34        unless exists $class->_columns->{$rel};
  35     my $f_class = $class->_relationships->{$rel}{class};
  36     $class->inflate_column($rel,
  37       { inflate => sub {
  38           my ($val, $self) = @_;
  39           return $self->find_or_create_related($rel, {}, {});
  40         },
  41         deflate => sub {
  42           my ($val, $self) = @_;
  43           $self->throw("$val isn't a $f_class") unless $val->isa($f_class);
  44           return ($val->_ident_values)[0];
  45             # WARNING: probably breaks for multi-pri sometimes. FIXME
  46         }
  47       }
  48     );
  49   } elsif ($acc_type eq 'multi') {
  50     $meth{$rel} = sub { shift->search_related($rel, @_) };
  51     $meth{"add_to_${rel}"} = sub { shift->create_related($rel, @_); };
  52   } else {
  53     $class->throw("No such relationship accessor type $acc_type");
  54   }
  55   {
  56     no strict 'refs';
  57     no warnings 'redefine';
  58     foreach my $meth (keys %meth) {
  59       *{"${class}::${meth}"} = $meth{$meth};
  60     }
  61   }
  62 }
  63
  64 1;