lib/DBIx/Class/PK/Auto.pm

   1 package DBIx::Class::PK::Auto;
   2
   3 #use base qw/DBIx::Class::PK/;
   4 use base qw/DBIx::Class/;
   5 use strict;
   6 use warnings;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::PK::Auto - Automatic primary key class
  11
  12 =head1 SYNOPSIS
  13
  14   # In your table classes (replace PK::Auto::SQLite with your database)
  15   __PACKAGE__->load_components(qw/PK::Auto::SQLite Core/);
  16   __PACKAGE__->set_primary_key('id');
  17
  18 =head1 DESCRIPTION
  19
  20 This class overrides the insert method to get automatically incremented primary
  21 keys.
  22
  23 You don't want to be using this directly - instead load the appropriate one for
  24 your database, e.g. C<PK::Auto::SQLite>, in your table classes:
  25
  26   __PACKAGE__->load_components(qw/PK::Auto::SQLite Core/);
  27
  28 Note that C<PK::Auto::SQLite> is specified as the leftmost argument.
  29
  30 Alternatively, you can load the components separately:
  31
  32   __PACKAGE__->load_components(qw/Core/);
  33   __PACKAGE__->load_components(qw/PK::Auto::SQLite/);
  34
  35 This can be used, for example, if you have different databases and need to
  36 determine the appropriate C<PK::Auto> class at runtime.
  37
  38 =head1 LOGIC
  39
  40 C<PK::Auto> does this by letting the database assign the primary key field and
  41 fetching the assigned value afterwards.
  42
  43 =head1 METHODS
  44
  45 =head2 insert
  46
  47 Overrides C<insert> so that it will get the value of autoincremented primary
  48 keys.
  49
  50 =cut
  51
  52 sub insert {
  53   my ($self, @rest) = @_;
  54   my $ret = $self->next::method(@rest);
  55
  56   # if all primaries are already populated, skip auto-inc
  57   my $populated = 0;
  58   map { $populated++ if defined $self->get_column($_) } $self->primary_columns;
  59   return $ret if ( $populated == scalar $self->primary_columns );
  60
  61   my ($pri, $too_many) =
  62     (grep { $self->column_info($_)->{'auto_increment'} }
  63        $self->primary_columns)
  64     || $self->primary_columns;
  65   $self->throw_exception( "More than one possible key found for auto-inc on ".ref $self )
  66     if $too_many;
  67   unless (defined $self->get_column($pri)) {
  68 #     $self->throw_exception( "Can't auto-inc for $pri on ".ref $self.": no _last_insert_id method" )
  69 #       unless $self->can('last_insert_id');
  70     my $id = $self->result_source->storage->last_insert_id($self->result_source);
  71     $self->throw_exception( "Can't get last insert id" ) unless $id;
  72     $self->store_column($pri => $id);
  73   }
  74   return $ret;
  75 }
  76
  77 =head2 sequence
  78
  79 Manually define the correct sequence for your table, to avoid the overhead
  80 associated with looking up the sequence automatically.
  81
  82 =cut
  83
  84 __PACKAGE__->mk_classdata('sequence');
  85
  86 1;
  87
  88 =head1 AUTHORS
  89
  90 Matt S. Trout <mst@shadowcatsystems.co.uk>
  91
  92 =head1 LICENSE
  93
  94 You may distribute this code under the same terms as Perl itself.
  95
  96 =cut