lib/DBIx/Class/InflateColumn.pm

   1 package DBIx::Class::InflateColumn;
   2
   3 use strict;
   4 use warnings;
   5 use Scalar::Util qw/blessed/;
   6
   7 use base qw/DBIx::Class::Row/;
   8
   9 =head1 NAME
  10
  11 DBIx::Class::InflateColumn - Automatically create references from column data
  12
  13 =head1 SYNOPSIS
  14
  15     # In your table classes
  16     __PACKAGE__->inflate_column('column_name', {
  17         inflate => sub { ... },
  18         deflate => sub { ... },
  19     });
  20
  21 =head1 DESCRIPTION
  22
  23 This component translates column data into references, i.e. "inflating"
  24 the column data. It also "deflates" references into an appropriate format
  25 for the database.
  26
  27 It can be used, for example, to automatically convert to and from
  28 L<DateTime> objects for your date and time fields. There's a
  29 convenience component to actually do that though, try
  30 L<DBIx::Class::InflateColumn::DateTime>.
  31
  32 It will handle all types of references except scalar references. It
  33 will not handle scalar values, these are ignored and thus passed
  34 through to L<SQL::Abstract>. This is to allow setting raw values to
  35 "just work". Scalar references are passed through to the database to
  36 deal with, to allow such settings as C< \'year + 1'> and C< \'DEFAULT' >
  37 to work.
  38
  39 If you want to filter plain scalar values and replace them with
  40 something else, see L<DBIx::Class::FilterColumn>.
  41
  42 =head1 METHODS
  43
  44 =head2 inflate_column
  45
  46 Instruct L<DBIx::Class> to inflate the given column.
  47
  48 In addition to the column name, you must provide C<inflate> and
  49 C<deflate> methods. The C<inflate> method is called when you access
  50 the field, while the C<deflate> method is called when the field needs
  51 to used by the database.
  52
  53 For example, if you have a table C<events> with a timestamp field
  54 named C<insert_time>, you could inflate the column in the
  55 corresponding table class using something like:
  56
  57     __PACKAGE__->inflate_column('insert_time', {
  58         inflate => sub { DateTime::Format::Pg->parse_datetime(shift); },
  59         deflate => sub { DateTime::Format::Pg->format_datetime(shift); },
  60     });
  61
  62 (Replace L<DateTime::Format::Pg> with the appropriate module for your
  63 database, or consider L<DateTime::Format::DBI>.)
  64
  65 The coderefs you set for inflate and deflate are called with two parameters,
  66 the first is the value of the column to be inflated/deflated, the second is the
  67 row object itself. Thus you can call C<< ->result_source->schema->storage->dbh >> in your inflate/defalte subs, to feed to L<DateTime::Format::DBI>.
  68
  69 In this example, calls to an event's C<insert_time> accessor return a
  70 L<DateTime> object. This L<DateTime> object is later "deflated" when
  71 used in the database layer.
  72
  73 =cut
  74
  75 sub inflate_column {
  76   my ($self, $col, $attrs) = @_;
  77
  78   my $colinfo = $self->column_info($col);
  79
  80   $self->throw_exception("InflateColumn does not work with FilterColumn")
  81     if $self->isa('DBIx::Class::FilterColumn') &&
  82       defined $colinfo->{_filter_info};
  83
  84   $self->throw_exception("No such column $col to inflate")
  85     unless $self->has_column($col);
  86   $self->throw_exception("inflate_column needs attr hashref")
  87     unless ref $attrs eq 'HASH';
  88   $colinfo->{_inflate_info} = $attrs;
  89   my $acc = $colinfo->{accessor};
  90   $self->mk_group_accessors('inflated_column' => [ (defined $acc ? $acc : $col), $col]);
  91   return 1;
  92 }
  93
  94 sub _inflated_column {
  95   my ($self, $col, $value) = @_;
  96   return $value unless defined $value; # NULL is NULL is NULL
  97   my $info = $self->column_info($col)
  98     or $self->throw_exception("No column info for $col");
  99   return $value unless exists $info->{_inflate_info};
 100   my $inflate = $info->{_inflate_info}{inflate};
 101   $self->throw_exception("No inflator for $col") unless defined $inflate;
 102   return $inflate->($value, $self);
 103 }
 104
 105 sub _deflated_column {
 106   my ($self, $col, $value) = @_;
 107 #  return $value unless ref $value && blessed($value); # If it's not an object, don't touch it
 108   ## Leave scalar refs (ala SQL::Abstract literal SQL), untouched, deflate all other refs
 109   return $value unless (ref $value && ref($value) ne 'SCALAR');
 110   my $info = $self->column_info($col) or
 111     $self->throw_exception("No column info for $col");
 112   return $value unless exists $info->{_inflate_info};
 113   my $deflate = $info->{_inflate_info}{deflate};
 114   $self->throw_exception("No deflator for $col") unless defined $deflate;
 115   return $deflate->($value, $self);
 116 }
 117
 118 =head2 get_inflated_column
 119
 120   my $val = $obj->get_inflated_column($col);
 121
 122 Fetch a column value in its inflated state.  This is directly
 123 analogous to L<DBIx::Class::Row/get_column> in that it only fetches a
 124 column already retrieved from the database, and then inflates it.
 125 Throws an exception if the column requested is not an inflated column.
 126
 127 =cut
 128
 129 sub get_inflated_column {
 130   my ($self, $col) = @_;
 131   $self->throw_exception("$col is not an inflated column")
 132     unless exists $self->column_info($col)->{_inflate_info};
 133   return $self->{_inflated_column}{$col}
 134     if exists $self->{_inflated_column}{$col};
 135
 136   my $val = $self->get_column($col);
 137   return $val if ref $val eq 'SCALAR';  #that would be a not-yet-reloaded sclarref update
 138
 139   return $self->{_inflated_column}{$col} = $self->_inflated_column($col, $val);
 140 }
 141
 142 =head2 set_inflated_column
 143
 144   my $copy = $obj->set_inflated_column($col => $val);
 145
 146 Sets a column value from an inflated value.  This is directly
 147 analogous to L<DBIx::Class::Row/set_column>.
 148
 149 =cut
 150
 151 sub set_inflated_column {
 152   my ($self, $col, $inflated) = @_;
 153   $self->set_column($col, $self->_deflated_column($col, $inflated));
 154 #  if (blessed $inflated) {
 155   if (ref $inflated && ref($inflated) ne 'SCALAR') {
 156     $self->{_inflated_column}{$col} = $inflated;
 157   } else {
 158     delete $self->{_inflated_column}{$col};
 159   }
 160   return $inflated;
 161 }
 162
 163 =head2 store_inflated_column
 164
 165   my $copy = $obj->store_inflated_column($col => $val);
 166
 167 Sets a column value from an inflated value without marking the column
 168 as dirty. This is directly analogous to L<DBIx::Class::Row/store_column>.
 169
 170 =cut
 171
 172 sub store_inflated_column {
 173   my ($self, $col, $inflated) = @_;
 174 #  unless (blessed $inflated) {
 175   unless (ref $inflated && ref($inflated) ne 'SCALAR') {
 176       delete $self->{_inflated_column}{$col};
 177       $self->store_column($col => $inflated);
 178       return $inflated;
 179   }
 180   delete $self->{_column_data}{$col};
 181   return $self->{_inflated_column}{$col} = $inflated;
 182 }
 183
 184 =head1 SEE ALSO
 185
 186 =over 4
 187
 188 =item L<DBIx::Class::Core> - This component is loaded as part of the
 189       C<core> L<DBIx::Class> components; generally there is no need to
 190       load it directly
 191
 192 =back
 193
 194 =head1 AUTHOR
 195
 196 Matt S. Trout <mst@shadowcatsystems.co.uk>
 197
 198 =head1 CONTRIBUTORS
 199
 200 Daniel Westermann-Clark <danieltwc@cpan.org> (documentation)
 201
 202 Jess Robinson <cpan@desert-island.demon.co.uk>
 203
 204 =head1 LICENSE
 205
 206 You may distribute this code under the same terms as Perl itself.
 207
 208 =cut
 209
 210 1;