lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  11
  12 =head1 SYNOPSIS
  13
  14 Load this component and then declare one or more
  15 columns to be of the datetime, timestamp or date datatype.
  16
  17   package Event;
  18   use base 'DBIx::Class::Core';
  19
  20   __PACKAGE__->load_components(qw/InflateColumn::DateTime/);
  21   __PACKAGE__->add_columns(
  22     starts_when => { data_type => 'datetime' }
  23     create_date => { data_type => 'date' }
  24   );
  25
  26 Then you can treat the specified column as a L<DateTime> object.
  27
  28   print "This event starts the month of ".
  29     $event->starts_when->month_name();
  30
  31 If you want to set a specific timezone and locale for that field, use:
  32
  33   __PACKAGE__->add_columns(
  34     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  35   );
  36
  37 If you want to inflate no matter what data_type your column is,
  38 use inflate_datetime or inflate_date:
  39
  40   __PACKAGE__->add_columns(
  41     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  42   );
  43
  44   __PACKAGE__->add_columns(
  45     starts_when => { data_type => 'varchar', inflate_date => 1 }
  46   );
  47
  48 It's also possible to explicitly skip inflation:
  49
  50   __PACKAGE__->add_columns(
  51     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  52   );
  53
  54 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
  55 The column is set directly for any non-references and C<InflateColumn::DateTime>
  56 is completely bypassed.  Instead, use an input parser to create a DateTime
  57 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
  58 use C<DateTime::Format::ISO8601> thusly:
  59
  60   use DateTime::Format::ISO8601;
  61   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  62
  63 =head1 DESCRIPTION
  64
  65 This module figures out the type of DateTime::Format::* class to
  66 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  67 that you are using.  If you switch from one database to a different
  68 one your code should continue to work without modification (though note
  69 that this feature is new as of 0.07, so it may not be perfect yet - bug
  70 reports to the list very much welcome).
  71
  72 If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
  73 a derivative of these datatypes, e.g. C<timestamp with timezone>), this
  74 module will automatically call the appropriate parse/format method for
  75 deflation/inflation as defined in the storage class. For instance, for
  76 a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
  77 would be called on deflation/inflation. If the storage class does not
  78 provide a specialized inflator/deflator, C<[parse|format]_datetime> will
  79 be used as a fallback. See L<DateTime::Format> for more information on
  80 date formatting.
  81
  82 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  83
  84 =cut
  85
  86 __PACKAGE__->load_components(qw/InflateColumn/);
  87
  88 =head2 register_column
  89
  90 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  91 up datetime columns appropriately.  This would not normally be
  92 directly called by end users.
  93
  94 In the case of an invalid date, L<DateTime> will throw an exception.  To
  95 bypass these exceptions and just have the inflation return undef, use
  96 the C<datetime_undef_if_invalid> option in the column info:
  97
  98     "broken_date",
  99     {
 100         data_type => "datetime",
 101         default_value => '0000-00-00',
 102         is_nullable => 1,
 103         datetime_undef_if_invalid => 1
 104     }
 105
 106 =cut
 107
 108 sub register_column {
 109   my ($self, $column, $info, @rest) = @_;
 110   $self->next::method($column, $info, @rest);
 111   return unless defined($info->{data_type});
 112
 113   my $type;
 114
 115   for (qw/date datetime timestamp/) {
 116     my $key = "inflate_${_}";
 117
 118     next unless exists $info->{$key};
 119     return unless $info->{$key};
 120
 121     $type = $_;
 122     last;
 123   }
 124
 125   unless ($type) {
 126     $type = lc($info->{data_type});
 127     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 128       $type = "timestamp";
 129       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 130     } elsif ($type eq "timestamp without time zone") {
 131       $type = "timestamp";
 132       $info->{_ic_dt_method} ||= "timestamp_without_timezone";
 133     } elsif ($type eq "smalldatetime") {
 134       $type = "datetime";
 135       $info->{_ic_dt_method} ||= "datetime";
 136     }
 137   }
 138
 139   my $timezone;
 140   if ( defined $info->{extra}{timezone} ) {
 141     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 142          "please put it directly into the '$column' column definition.";
 143     $timezone = $info->{extra}{timezone};
 144   }
 145
 146   my $locale;
 147   if ( defined $info->{extra}{locale} ) {
 148     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 149          "please put it directly into the '$column' column definition.";
 150     $locale = $info->{extra}{locale};
 151   }
 152
 153   $locale   = $info->{locale}   if defined $info->{locale};
 154   $timezone = $info->{timezone} if defined $info->{timezone};
 155
 156   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 157
 158   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 159     # This shallow copy of %info avoids t/52_cycle.t treating
 160     # the resulting deflator as a circular reference.
 161     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 162
 163     if (defined $info->{extra}{floating_tz_ok}) {
 164       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 165            "please put it directly into the '$column' column definition.";
 166       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 167     }
 168
 169     $self->inflate_column(
 170       $column =>
 171         {
 172           inflate => sub {
 173             my ($value, $obj) = @_;
 174
 175             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 176             if (my $err = $@ ) {
 177               return undef if ($undef_if_invalid);
 178               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $err");
 179             }
 180
 181             $dt->set_time_zone($timezone) if $timezone;
 182             $dt->set_locale($locale) if $locale;
 183             return $dt;
 184           },
 185           deflate => sub {
 186             my ($value, $obj) = @_;
 187             if ($timezone) {
 188                 carp "You're using a floating timezone, please see the documentation of"
 189                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
 190                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
 191                       and not $info{floating_tz_ok}
 192                       and not $ENV{DBIC_FLOATING_TZ_OK};
 193                 $value->set_time_zone($timezone);
 194                 $value->set_locale($locale) if $locale;
 195             }
 196             $obj->_deflate_from_datetime( $value, \%info );
 197           },
 198         }
 199     );
 200   }
 201 }
 202
 203 sub _flate_or_fallback
 204 {
 205   my( $self, $value, $info, $method_fmt ) = @_;
 206
 207   my $parser = $self->_datetime_parser;
 208   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 209   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 210   return $parser->$method($value);
 211 }
 212
 213 sub _inflate_to_datetime {
 214   my( $self, $value, $info ) = @_;
 215   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 216 }
 217
 218 sub _deflate_from_datetime {
 219   my( $self, $value, $info ) = @_;
 220   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 221 }
 222
 223 sub _datetime_parser {
 224   shift->result_source->storage->datetime_parser (@_);
 225 }
 226
 227 1;
 228 __END__
 229
 230 =head1 USAGE NOTES
 231
 232 If you have a datetime column with an associated C<timezone>, and subsequently
 233 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 234 timezone, you will get a warning (as there is a very good chance this will not have the
 235 result you expect). For example:
 236
 237   __PACKAGE__->add_columns(
 238     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 239   );
 240
 241   my $event = $schema->resultset('EventTZ')->create({
 242     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 243   });
 244
 245 The warning can be avoided in several ways:
 246
 247 =over
 248
 249 =item Fix your broken code
 250
 251 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 252 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 253 to be supply explicit times to the database:
 254
 255   my $event = $schema->resultset('EventTZ')->create({
 256     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 257   });
 258
 259 =item Suppress the check on per-column basis
 260
 261   __PACKAGE__->add_columns(
 262     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 263   );
 264
 265 =item Suppress the check globally
 266
 267 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 268
 269 =back
 270
 271 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 272 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 273 Instead put it directly into the columns definition like in the examples above. If you still
 274 use the old way you'll see a warning - please fix your code then!
 275
 276 =head1 SEE ALSO
 277
 278 =over 4
 279
 280 =item More information about the add_columns method, and column metadata,
 281       can be found in the documentation for L<DBIx::Class::ResultSource>.
 282
 283 =item Further discussion of problems inherent to the Floating timezone:
 284       L<Floating DateTimes|DateTime/Floating_DateTimes>
 285       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 286
 287 =back
 288
 289 =head1 AUTHOR
 290
 291 Matt S. Trout <mst@shadowcatsystems.co.uk>
 292
 293 =head1 CONTRIBUTORS
 294
 295 Aran Deltac <bluefeet@cpan.org>
 296
 297 =head1 LICENSE
 298
 299 You may distribute this code under the same terms as Perl itself.
 300