lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  11
  12 =head1 SYNOPSIS
  13
  14 Load this component and then declare one or more
  15 columns to be of the datetime, timestamp or date datatype.
  16
  17   package Event;
  18   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
  19   __PACKAGE__->add_columns(
  20     starts_when => { data_type => 'datetime' }
  21   );
  22
  23 NOTE: You B<must> load C<InflateColumn::DateTime> B<before> C<Core>. See
  24 L<DBIx::Class::Manual::Component> for details.
  25
  26 Then you can treat the specified column as a L<DateTime> object.
  27
  28   print "This event starts the month of ".
  29     $event->starts_when->month_name();
  30
  31 If you want to set a specific timezone and locale for that field, use:
  32
  33   __PACKAGE__->add_columns(
  34     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  35   );
  36
  37 If you want to inflate no matter what data_type your column is,
  38 use inflate_datetime or inflate_date:
  39
  40   __PACKAGE__->add_columns(
  41     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  42   );
  43
  44   __PACKAGE__->add_columns(
  45     starts_when => { data_type => 'varchar', inflate_date => 1 }
  46   );
  47
  48 It's also possible to explicitly skip inflation:
  49
  50   __PACKAGE__->add_columns(
  51     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  52   );
  53
  54 =head1 DESCRIPTION
  55
  56 This module figures out the type of DateTime::Format::* class to
  57 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  58 that you are using.  If you switch from one database to a different
  59 one your code should continue to work without modification (though note
  60 that this feature is new as of 0.07, so it may not be perfect yet - bug
  61 reports to the list very much welcome).
  62
  63 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  64
  65 =cut
  66
  67 __PACKAGE__->load_components(qw/InflateColumn/);
  68
  69 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  70
  71 =head2 register_column
  72
  73 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  74 up datetime columns appropriately.  This would not normally be
  75 directly called by end users.
  76
  77 In the case of an invalid date, L<DateTime> will throw an exception.  To
  78 bypass these exceptions and just have the inflation return undef, use
  79 the C<datetime_undef_if_invalid> option in the column info:
  80
  81     "broken_date",
  82     {
  83         data_type => "datetime",
  84         default_value => '0000-00-00',
  85         is_nullable => 1,
  86         datetime_undef_if_invalid => 1
  87     }
  88
  89 =cut
  90
  91 sub register_column {
  92   my ($self, $column, $info, @rest) = @_;
  93   $self->next::method($column, $info, @rest);
  94   return unless defined($info->{data_type});
  95
  96   my $type;
  97
  98   for (qw/date datetime timestamp/) {
  99     my $key = "inflate_${_}";
 100
 101     next unless exists $info->{$key};
 102     return unless $info->{$key};
 103
 104     $type = $_;
 105     last;
 106   }
 107
 108   unless ($type) {
 109     $type = lc($info->{data_type});
 110     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 111       $type = "timestamp";
 112       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 113     }
 114   }
 115
 116   my $timezone;
 117   if ( defined $info->{extra}{timezone} ) {
 118     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 119          "please put it directly into the '$column' column definition.";
 120     $timezone = $info->{extra}{timezone};
 121   }
 122
 123   my $locale;
 124   if ( defined $info->{extra}{locale} ) {
 125     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 126          "please put it directly into the '$column' column definition.";
 127     $locale = $info->{extra}{locale};
 128   }
 129
 130   $locale   = $info->{locale}   if defined $info->{locale};
 131   $timezone = $info->{timezone} if defined $info->{timezone};
 132
 133   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 134
 135   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 136     # This shallow copy of %info avoids t/52_cycle.t treating
 137     # the resulting deflator as a circular reference.
 138     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 139
 140     if (defined $info->{extra}{floating_tz_ok}) {
 141       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 142            "please put it directly into the '$column' column definition.";
 143       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 144     }
 145
 146     $self->inflate_column(
 147       $column =>
 148         {
 149           inflate => sub {
 150             my ($value, $obj) = @_;
 151
 152             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 153             if (my $err = $@ ) {
 154               return undef if ($undef_if_invalid);
 155               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $err");
 156             }
 157
 158             $dt->set_time_zone($timezone) if $timezone;
 159             $dt->set_locale($locale) if $locale;
 160             return $dt;
 161           },
 162           deflate => sub {
 163             my ($value, $obj) = @_;
 164             if ($timezone) {
 165                 carp "You're using a floating timezone, please see the documentation of"
 166                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
 167                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
 168                       and not $info{floating_tz_ok}
 169                       and not $ENV{DBIC_FLOATING_TZ_OK};
 170                 $value->set_time_zone($timezone);
 171                 $value->set_locale($locale) if $locale;
 172             }
 173             $obj->_deflate_from_datetime( $value, \%info );
 174           },
 175         }
 176     );
 177   }
 178 }
 179
 180 sub _flate_or_fallback
 181 {
 182   my( $self, $value, $info, $method_fmt ) = @_;
 183
 184   my $parser = $self->_datetime_parser;
 185   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 186   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 187   return $parser->$method($value);
 188 }
 189
 190 sub _inflate_to_datetime {
 191   my( $self, $value, $info ) = @_;
 192   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 193 }
 194
 195 sub _deflate_from_datetime {
 196   my( $self, $value, $info ) = @_;
 197   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 198 }
 199
 200 sub _datetime_parser {
 201   my $self = shift;
 202   if (my $parser = $self->__datetime_parser) {
 203     return $parser;
 204   }
 205   my $parser = $self->result_source->storage->datetime_parser(@_);
 206   return $self->__datetime_parser($parser);
 207 }
 208
 209 1;
 210 __END__
 211
 212 =head1 USAGE NOTES
 213
 214 If you have a datetime column with an associated C<timezone>, and subsequently
 215 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 216 timezone, you will get a warning (as there is a very good chance this will not have the
 217 result you expect). For example:
 218
 219   __PACKAGE__->add_columns(
 220     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 221   );
 222
 223   my $event = $schema->resultset('EventTZ')->create({
 224     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 225   });
 226
 227 The warning can be avoided in several ways:
 228
 229 =over
 230
 231 =item Fix your broken code
 232
 233 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 234 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 235 to be supply explicit times to the database:
 236
 237   my $event = $schema->resultset('EventTZ')->create({
 238     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 239   });
 240
 241 =item Suppress the check on per-column basis
 242
 243   __PACKAGE__->add_columns(
 244     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 245   );
 246
 247 =item Suppress the check globally
 248
 249 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 250
 251 =back
 252
 253 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 254 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 255 Instead put it directly into the columns definition like in the examples above. If you still
 256 use the old way you'll see a warning - please fix your code then!
 257
 258 =head1 SEE ALSO
 259
 260 =over 4
 261
 262 =item More information about the add_columns method, and column metadata,
 263       can be found in the documentation for L<DBIx::Class::ResultSource>.
 264
 265 =item Further discussion of problems inherent to the Floating timezone:
 266       L<Floating DateTimes|DateTime/Floating_DateTimes>
 267       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 268
 269 =back
 270
 271 =head1 AUTHOR
 272
 273 Matt S. Trout <mst@shadowcatsystems.co.uk>
 274
 275 =head1 CONTRIBUTORS
 276
 277 Aran Deltac <bluefeet@cpan.org>
 278
 279 =head1 LICENSE
 280
 281 You may distribute this code under the same terms as Perl itself.
 282