Backout sybase changes
[dbsrgits/DBIx-Class.git] / lib / DBIx / Class / InflateColumn / DateTime.pm
1 package DBIx::Class::InflateColumn::DateTime;
2
3 use strict;
4 use warnings;
5 use base qw/DBIx::Class/;
6 use Carp::Clan qw/^DBIx::Class/;
7
8 =head1 NAME
9
10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
11
12 =head1 SYNOPSIS
13
14 Load this component and then declare one or more 
15 columns to be of the datetime, timestamp or date datatype.
16
17   package Event;
18   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
19   __PACKAGE__->add_columns(
20     starts_when => { data_type => 'datetime' }
21     create_date => { data_type => 'date' }
22   );
23
24 NOTE: You B<must> load C<InflateColumn::DateTime> B<before> C<Core>. See
25 L<DBIx::Class::Manual::Component> for details.
26
27 Then you can treat the specified column as a L<DateTime> object.
28
29   print "This event starts the month of ".
30     $event->starts_when->month_name();
31
32 If you want to set a specific timezone and locale for that field, use:
33
34   __PACKAGE__->add_columns(
35     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
36   );
37
38 If you want to inflate no matter what data_type your column is,
39 use inflate_datetime or inflate_date:
40
41   __PACKAGE__->add_columns(
42     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
43   );
44
45   __PACKAGE__->add_columns(
46     starts_when => { data_type => 'varchar', inflate_date => 1 }
47   );
48
49 It's also possible to explicitly skip inflation:
50
51   __PACKAGE__->add_columns(
52     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
53   );
54
55 NOTE: Don't rely on C<InflateColumn::DateTime> to parse date strings for you.
56 The column is set directly for any non-references and C<InflateColumn::DateTime>
57 is completely bypassed.  Instead, use an input parser to create a DateTime
58 object. For instance, if your user input comes as a 'YYYY-MM-DD' string, you can
59 use C<DateTime::Format::ISO8601> thusly:
60
61   use DateTime::Format::ISO8601;
62   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
63
64 =head1 DESCRIPTION
65
66 This module figures out the type of DateTime::Format::* class to 
67 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::* 
68 that you are using.  If you switch from one database to a different 
69 one your code should continue to work without modification (though note
70 that this feature is new as of 0.07, so it may not be perfect yet - bug
71 reports to the list very much welcome).
72
73 If the data_type of a field is C<date>, C<datetime> or C<timestamp> (or
74 a derivative of these datatypes, e.g. C<timestamp with timezone>), this
75 module will automatically call the appropriate parse/format method for
76 deflation/inflation as defined in the storage class. For instance, for
77 a C<datetime> field the methods C<parse_datetime> and C<format_datetime>
78 would be called on deflation/inflation. If the storage class does not
79 provide a specialized inflator/deflator, C<[parse|format]_datetime> will
80 be used as a fallback. See L<DateTime::Format> for more information on
81 date formatting.
82
83 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
84
85 =cut
86
87 __PACKAGE__->load_components(qw/InflateColumn/);
88
89 =head2 register_column
90
91 Chains with the L<DBIx::Class::Row/register_column> method, and sets
92 up datetime columns appropriately.  This would not normally be
93 directly called by end users.
94
95 In the case of an invalid date, L<DateTime> will throw an exception.  To
96 bypass these exceptions and just have the inflation return undef, use
97 the C<datetime_undef_if_invalid> option in the column info:
98
99     "broken_date",
100     {
101         data_type => "datetime",
102         default_value => '0000-00-00',
103         is_nullable => 1,
104         datetime_undef_if_invalid => 1
105     }
106
107 =cut
108
109 sub register_column {
110   my ($self, $column, $info, @rest) = @_;
111   $self->next::method($column, $info, @rest);
112   return unless defined($info->{data_type});
113
114   my $type;
115
116   for (qw/date datetime timestamp/) {
117     my $key = "inflate_${_}";
118
119     next unless exists $info->{$key};
120     return unless $info->{$key};
121
122     $type = $_;
123     last;
124   }
125
126   unless ($type) {
127     $type = lc($info->{data_type});
128     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
129       $type = "timestamp";
130       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
131     } elsif ($type eq "timestamp without time zone") {
132       $type = "timestamp";
133       $info->{_ic_dt_method} ||= "timestamp_without_timezone";
134     } elsif ($type eq "smalldatetime") {
135       $type = "datetime";
136       $info->{_ic_dt_method} ||= "datetime";
137     }
138   }
139
140   my $timezone;
141   if ( defined $info->{extra}{timezone} ) {
142     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
143          "please put it directly into the '$column' column definition.";
144     $timezone = $info->{extra}{timezone};
145   }
146
147   my $locale;
148   if ( defined $info->{extra}{locale} ) {
149     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
150          "please put it directly into the '$column' column definition.";
151     $locale = $info->{extra}{locale};
152   }
153
154   $locale   = $info->{locale}   if defined $info->{locale};
155   $timezone = $info->{timezone} if defined $info->{timezone};
156
157   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
158
159   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
160     # This shallow copy of %info avoids t/52_cycle.t treating
161     # the resulting deflator as a circular reference.
162     my %info = ( '_ic_dt_method' => $type , %{ $info } );
163
164     if (defined $info->{extra}{floating_tz_ok}) {
165       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
166            "please put it directly into the '$column' column definition.";
167       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
168     }
169
170     $self->inflate_column(
171       $column =>
172         {
173           inflate => sub {
174             my ($value, $obj) = @_;
175
176             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
177             if (my $err = $@ ) {
178               return undef if ($undef_if_invalid);
179               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $err");
180             }
181
182             $dt->set_time_zone($timezone) if $timezone;
183             $dt->set_locale($locale) if $locale;
184             return $dt;
185           },
186           deflate => sub {
187             my ($value, $obj) = @_;
188             if ($timezone) {
189                 carp "You're using a floating timezone, please see the documentation of"
190                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
191                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
192                       and not $info{floating_tz_ok}
193                       and not $ENV{DBIC_FLOATING_TZ_OK};
194                 $value->set_time_zone($timezone);
195                 $value->set_locale($locale) if $locale;
196             }
197             $obj->_deflate_from_datetime( $value, \%info );
198           },
199         }
200     );
201   }
202 }
203
204 sub _flate_or_fallback
205 {
206   my( $self, $value, $info, $method_fmt ) = @_;
207
208   my $parser = $self->_datetime_parser;
209   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
210   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
211   return $parser->$method($value);
212 }
213
214 sub _inflate_to_datetime {
215   my( $self, $value, $info ) = @_;
216   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
217 }
218
219 sub _deflate_from_datetime {
220   my( $self, $value, $info ) = @_;
221   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
222 }
223
224 sub _datetime_parser {
225   shift->result_source->storage->datetime_parser (@_);
226 }
227
228 1;
229 __END__
230
231 =head1 USAGE NOTES
232
233 If you have a datetime column with an associated C<timezone>, and subsequently
234 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
235 timezone, you will get a warning (as there is a very good chance this will not have the
236 result you expect). For example:
237
238   __PACKAGE__->add_columns(
239     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
240   );
241
242   my $event = $schema->resultset('EventTZ')->create({
243     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
244   });
245
246 The warning can be avoided in several ways:
247
248 =over
249
250 =item Fix your broken code
251
252 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
253 set to the requested value, and B<no time conversion takes place>. It is always a good idea
254 to be supply explicit times to the database:
255
256   my $event = $schema->resultset('EventTZ')->create({
257     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
258   });
259
260 =item Suppress the check on per-column basis
261
262   __PACKAGE__->add_columns(
263     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
264   );
265
266 =item Suppress the check globally
267
268 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
269
270 =back
271
272 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
273 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
274 Instead put it directly into the columns definition like in the examples above. If you still
275 use the old way you'll see a warning - please fix your code then!
276
277 =head1 SEE ALSO
278
279 =over 4
280
281 =item More information about the add_columns method, and column metadata, 
282       can be found in the documentation for L<DBIx::Class::ResultSource>.
283
284 =item Further discussion of problems inherent to the Floating timezone:
285       L<Floating DateTimes|DateTime/Floating_DateTimes> 
286       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
287
288 =back
289
290 =head1 AUTHOR
291
292 Matt S. Trout <mst@shadowcatsystems.co.uk>
293
294 =head1 CONTRIBUTORS
295
296 Aran Deltac <bluefeet@cpan.org>
297
298 =head1 LICENSE
299
300 You may distribute this code under the same terms as Perl itself.
301