lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6 use Carp::Clan qw/^DBIx::Class/;
   7
   8 =head1 NAME
   9
  10 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  11
  12 =head1 SYNOPSIS
  13
  14 Load this component and then declare one or more
  15 columns to be of the datetime, timestamp or date datatype.
  16
  17   package Event;
  18   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
  19   __PACKAGE__->add_columns(
  20     starts_when => { data_type => 'datetime' }
  21   );
  22
  23 NOTE: You B<must> load C<InflateColumn::DateTime> B<before> C<Core>. See
  24 L<DBIx::Class::Manual::Component> for details.
  25
  26 Then you can treat the specified column as a L<DateTime> object.
  27
  28   print "This event starts the month of ".
  29     $event->starts_when->month_name();
  30
  31 If you want to set a specific timezone and locale for that field, use:
  32
  33   __PACKAGE__->add_columns(
  34     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  35   );
  36
  37 If you want to inflate no matter what data_type your column is,
  38 use inflate_datetime or inflate_date:
  39
  40   __PACKAGE__->add_columns(
  41     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  42   );
  43
  44   __PACKAGE__->add_columns(
  45     starts_when => { data_type => 'varchar', inflate_date => 1 }
  46   );
  47
  48 It's also possible to explicitly skip inflation:
  49
  50   __PACKAGE__->add_columns(
  51     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  52   );
  53
  54 NOTE: Don't rely on C<InflateColumn::DateTime> to validate user input, this
  55 may have unexpected security implications. Instead, use an input parser to
  56 create a DateTime object. For instance, if your user input comes as a
  57 'YYYY-MM-DD' string, you can use C<DateTime::Format::ISO8601> thusly:
  58
  59   use DateTime::Format::ISO8601;
  60   my $dt = DateTime::Format::ISO8601->parse_datetime('YYYY-MM-DD');
  61
  62 =head1 DESCRIPTION
  63
  64 This module figures out the type of DateTime::Format::* class to
  65 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  66 that you are using.  If you switch from one database to a different
  67 one your code should continue to work without modification (though note
  68 that this feature is new as of 0.07, so it may not be perfect yet - bug
  69 reports to the list very much welcome).
  70
  71 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  72
  73 =cut
  74
  75 __PACKAGE__->load_components(qw/InflateColumn/);
  76
  77 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  78
  79 =head2 register_column
  80
  81 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  82 up datetime columns appropriately.  This would not normally be
  83 directly called by end users.
  84
  85 In the case of an invalid date, L<DateTime> will throw an exception.  To
  86 bypass these exceptions and just have the inflation return undef, use
  87 the C<datetime_undef_if_invalid> option in the column info:
  88
  89     "broken_date",
  90     {
  91         data_type => "datetime",
  92         default_value => '0000-00-00',
  93         is_nullable => 1,
  94         datetime_undef_if_invalid => 1
  95     }
  96
  97 =cut
  98
  99 sub register_column {
 100   my ($self, $column, $info, @rest) = @_;
 101   $self->next::method($column, $info, @rest);
 102   return unless defined($info->{data_type});
 103
 104   my $type;
 105
 106   for (qw/date datetime timestamp/) {
 107     my $key = "inflate_${_}";
 108
 109     next unless exists $info->{$key};
 110     return unless $info->{$key};
 111
 112     $type = $_;
 113     last;
 114   }
 115
 116   unless ($type) {
 117     $type = lc($info->{data_type});
 118     if ($type eq "timestamp with time zone" || $type eq "timestamptz") {
 119       $type = "timestamp";
 120       $info->{_ic_dt_method} ||= "timestamp_with_timezone";
 121     }
 122   }
 123
 124   my $timezone;
 125   if ( defined $info->{extra}{timezone} ) {
 126     carp "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 127          "please put it directly into the '$column' column definition.";
 128     $timezone = $info->{extra}{timezone};
 129   }
 130
 131   my $locale;
 132   if ( defined $info->{extra}{locale} ) {
 133     carp "Putting locale into extra => { locale => '...' } has been deprecated, ".
 134          "please put it directly into the '$column' column definition.";
 135     $locale = $info->{extra}{locale};
 136   }
 137
 138   $locale   = $info->{locale}   if defined $info->{locale};
 139   $timezone = $info->{timezone} if defined $info->{timezone};
 140
 141   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 142
 143   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 144     # This shallow copy of %info avoids t/52_cycle.t treating
 145     # the resulting deflator as a circular reference.
 146     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 147
 148     if (defined $info->{extra}{floating_tz_ok}) {
 149       carp "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 150            "please put it directly into the '$column' column definition.";
 151       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 152     }
 153
 154     $self->inflate_column(
 155       $column =>
 156         {
 157           inflate => sub {
 158             my ($value, $obj) = @_;
 159
 160             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 161             if (my $err = $@ ) {
 162               return undef if ($undef_if_invalid);
 163               $self->throw_exception ("Error while inflating ${value} for ${column} on ${self}: $err");
 164             }
 165
 166             $dt->set_time_zone($timezone) if $timezone;
 167             $dt->set_locale($locale) if $locale;
 168             return $dt;
 169           },
 170           deflate => sub {
 171             my ($value, $obj) = @_;
 172             if ($timezone) {
 173                 carp "You're using a floating timezone, please see the documentation of"
 174                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
 175                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
 176                       and not $info{floating_tz_ok}
 177                       and not $ENV{DBIC_FLOATING_TZ_OK};
 178                 $value->set_time_zone($timezone);
 179                 $value->set_locale($locale) if $locale;
 180             }
 181             $obj->_deflate_from_datetime( $value, \%info );
 182           },
 183         }
 184     );
 185   }
 186 }
 187
 188 sub _flate_or_fallback
 189 {
 190   my( $self, $value, $info, $method_fmt ) = @_;
 191
 192   my $parser = $self->_datetime_parser;
 193   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 194   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 195   return $parser->$method($value);
 196 }
 197
 198 sub _inflate_to_datetime {
 199   my( $self, $value, $info ) = @_;
 200   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 201 }
 202
 203 sub _deflate_from_datetime {
 204   my( $self, $value, $info ) = @_;
 205   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 206 }
 207
 208 sub _datetime_parser {
 209   my $self = shift;
 210   if (my $parser = $self->__datetime_parser) {
 211     return $parser;
 212   }
 213   my $parser = $self->result_source->storage->datetime_parser(@_);
 214   return $self->__datetime_parser($parser);
 215 }
 216
 217 1;
 218 __END__
 219
 220 =head1 USAGE NOTES
 221
 222 If you have a datetime column with an associated C<timezone>, and subsequently
 223 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 224 timezone, you will get a warning (as there is a very good chance this will not have the
 225 result you expect). For example:
 226
 227   __PACKAGE__->add_columns(
 228     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 229   );
 230
 231   my $event = $schema->resultset('EventTZ')->create({
 232     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 233   });
 234
 235 The warning can be avoided in several ways:
 236
 237 =over
 238
 239 =item Fix your broken code
 240
 241 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 242 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 243 to be supply explicit times to the database:
 244
 245   my $event = $schema->resultset('EventTZ')->create({
 246     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 247   });
 248
 249 =item Suppress the check on per-column basis
 250
 251   __PACKAGE__->add_columns(
 252     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 253   );
 254
 255 =item Suppress the check globally
 256
 257 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 258
 259 =back
 260
 261 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 262 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 263 Instead put it directly into the columns definition like in the examples above. If you still
 264 use the old way you'll see a warning - please fix your code then!
 265
 266 =head1 SEE ALSO
 267
 268 =over 4
 269
 270 =item More information about the add_columns method, and column metadata,
 271       can be found in the documentation for L<DBIx::Class::ResultSource>.
 272
 273 =item Further discussion of problems inherent to the Floating timezone:
 274       L<Floating DateTimes|DateTime/Floating_DateTimes>
 275       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 276
 277 =back
 278
 279 =head1 AUTHOR
 280
 281 Matt S. Trout <mst@shadowcatsystems.co.uk>
 282
 283 =head1 CONTRIBUTORS
 284
 285 Aran Deltac <bluefeet@cpan.org>
 286
 287 =head1 LICENSE
 288
 289 You may distribute this code under the same terms as Perl itself.
 290