lib/DBIx/Class/InflateColumn/DateTime.pm

   1 package DBIx::Class::InflateColumn::DateTime;
   2
   3 use strict;
   4 use warnings;
   5 use base qw/DBIx::Class/;
   6
   7 =head1 NAME
   8
   9 DBIx::Class::InflateColumn::DateTime - Auto-create DateTime objects from date and datetime columns.
  10
  11 =head1 SYNOPSIS
  12
  13 Load this component and then declare one or more
  14 columns to be of the datetime, timestamp or date datatype.
  15
  16   package Event;
  17   __PACKAGE__->load_components(qw/InflateColumn::DateTime Core/);
  18   __PACKAGE__->add_columns(
  19     starts_when => { data_type => 'datetime' }
  20   );
  21
  22 NOTE: You B<must> load C<InflateColumn::DateTime> B<before> C<Core>. See
  23 L<DBIx::Class::Manual::Component> for details.
  24
  25 Then you can treat the specified column as a L<DateTime> object.
  26
  27   print "This event starts the month of ".
  28     $event->starts_when->month_name();
  29
  30 If you want to set a specific timezone and locale for that field, use:
  31
  32   __PACKAGE__->add_columns(
  33     starts_when => { data_type => 'datetime', timezone => "America/Chicago", locale => "de_DE" }
  34   );
  35
  36 If you want to inflate no matter what data_type your column is,
  37 use inflate_datetime or inflate_date:
  38
  39   __PACKAGE__->add_columns(
  40     starts_when => { data_type => 'varchar', inflate_datetime => 1 }
  41   );
  42
  43   __PACKAGE__->add_columns(
  44     starts_when => { data_type => 'varchar', inflate_date => 1 }
  45   );
  46
  47 It's also possible to explicitly skip inflation:
  48
  49   __PACKAGE__->add_columns(
  50     starts_when => { data_type => 'datetime', inflate_datetime => 0 }
  51   );
  52
  53 =head1 DESCRIPTION
  54
  55 This module figures out the type of DateTime::Format::* class to
  56 inflate/deflate with based on the type of DBIx::Class::Storage::DBI::*
  57 that you are using.  If you switch from one database to a different
  58 one your code should continue to work without modification (though note
  59 that this feature is new as of 0.07, so it may not be perfect yet - bug
  60 reports to the list very much welcome).
  61
  62 For more help with using components, see L<DBIx::Class::Manual::Component/USING>.
  63
  64 =cut
  65
  66 __PACKAGE__->load_components(qw/InflateColumn/);
  67
  68 __PACKAGE__->mk_group_accessors('simple' => '__datetime_parser');
  69
  70 =head2 register_column
  71
  72 Chains with the L<DBIx::Class::Row/register_column> method, and sets
  73 up datetime columns appropriately.  This would not normally be
  74 directly called by end users.
  75
  76 In the case of an invalid date, L<DateTime> will throw an exception.  To
  77 bypass these exceptions and just have the inflation return undef, use
  78 the C<datetime_undef_if_invalid> option in the column info:
  79
  80     "broken_date",
  81     {
  82         data_type => "datetime",
  83         default_value => '0000-00-00',
  84         is_nullable => 1,
  85         datetime_undef_if_invalid => 1
  86     }
  87
  88 =cut
  89
  90 sub register_column {
  91   my ($self, $column, $info, @rest) = @_;
  92   $self->next::method($column, $info, @rest);
  93   return unless defined($info->{data_type});
  94
  95   my $type;
  96
  97   for (qw/date datetime timestamp/) {
  98     my $key = "inflate_${_}";
  99
 100     next unless exists $info->{$key};
 101     return unless $info->{$key};
 102
 103     $type = $_;
 104     last;
 105   }
 106
 107   unless ($type) {
 108     $type = lc($info->{data_type});
 109   }
 110
 111   my $timezone;
 112   if ( defined $info->{extra}{timezone} ) {
 113     warn "Putting timezone into extra => { timezone => '...' } has been deprecated, ".
 114          "please put it directly into the columns definition.";
 115     $timezone = $info->{extra}{timezone};
 116   }
 117
 118   my $locale;
 119   if ( defined $info->{extra}{locale} ) {
 120     warn "Putting locale into extra => { locale => '...' } has been deprecated, ".
 121          "please put it directly into the columns definition.";
 122     $locale = $info->{extra}{locale};
 123   }
 124
 125   $locale   = $info->{locale}   if defined $info->{locale};
 126   $timezone = $info->{timezone} if defined $info->{timezone};
 127
 128   my $undef_if_invalid = $info->{datetime_undef_if_invalid};
 129
 130   if ($type eq 'datetime' || $type eq 'date' || $type eq 'timestamp') {
 131     # This shallow copy of %info avoids t/52_cycle.t treating
 132     # the resulting deflator as a circular reference.
 133     my %info = ( '_ic_dt_method' => $type , %{ $info } );
 134
 135     if (defined $info->{extra}{floating_tz_ok}) {
 136       warn "Putting floating_tz_ok into extra => { floating_tz_ok => 1 } has been deprecated, ".
 137            "please put it directly into the columns definition.";
 138       $info{floating_tz_ok} = $info->{extra}{floating_tz_ok};
 139     }
 140
 141     $self->inflate_column(
 142       $column =>
 143         {
 144           inflate => sub {
 145             my ($value, $obj) = @_;
 146             my $dt = eval { $obj->_inflate_to_datetime( $value, \%info ) };
 147             die "Error while inflating ${value} for ${column} on ${self}: $@"
 148               if $@ and not $undef_if_invalid;
 149             $dt->set_time_zone($timezone) if $timezone;
 150             $dt->set_locale($locale) if $locale;
 151             return $dt;
 152           },
 153           deflate => sub {
 154             my ($value, $obj) = @_;
 155             if ($timezone) {
 156                 warn "You're using a floating timezone, please see the documentation of"
 157                   . " DBIx::Class::InflateColumn::DateTime for an explanation"
 158                   if ref( $value->time_zone ) eq 'DateTime::TimeZone::Floating'
 159                       and not $info{floating_tz_ok}
 160                       and not $ENV{DBIC_FLOATING_TZ_OK};
 161                 $value->set_time_zone($timezone);
 162                 $value->set_locale($locale) if $locale;
 163             }
 164             $obj->_deflate_from_datetime( $value, \%info );
 165           },
 166         }
 167     );
 168   }
 169 }
 170
 171 sub _flate_or_fallback
 172 {
 173   my( $self, $value, $info, $method_fmt ) = @_;
 174
 175   my $parser = $self->_datetime_parser;
 176   my $preferred_method = sprintf($method_fmt, $info->{ _ic_dt_method });
 177   my $method = $parser->can($preferred_method) ? $preferred_method : sprintf($method_fmt, 'datetime');
 178   return $parser->$method($value);
 179 }
 180
 181 sub _inflate_to_datetime {
 182   my( $self, $value, $info ) = @_;
 183   return $self->_flate_or_fallback( $value, $info, 'parse_%s' );
 184 }
 185
 186 sub _deflate_from_datetime {
 187   my( $self, $value, $info ) = @_;
 188   return $self->_flate_or_fallback( $value, $info, 'format_%s' );
 189 }
 190
 191 sub _datetime_parser {
 192   my $self = shift;
 193   if (my $parser = $self->__datetime_parser) {
 194     return $parser;
 195   }
 196   my $parser = $self->result_source->storage->datetime_parser(@_);
 197   return $self->__datetime_parser($parser);
 198 }
 199
 200 1;
 201 __END__
 202
 203 =head1 USAGE NOTES
 204
 205 If you have a datetime column with the C<timezone> extra setting, and subsenquently
 206 create/update this column with a DateTime object in the L<DateTime::TimeZone::Floating>
 207 timezone, you will get a warning (as there is a very good chance this will not have the
 208 result you expect). For example:
 209
 210   __PACKAGE__->add_columns(
 211     starts_when => { data_type => 'datetime', timezone => "America/Chicago" }
 212   );
 213
 214   my $event = $schema->resultset('EventTZ')->create({
 215     starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
 216   });
 217
 218 The warning can be avoided in several ways:
 219
 220 =over
 221
 222 =item Fix your broken code
 223
 224 When calling C<set_time_zone> on a Floating DateTime object, the timezone is simply
 225 set to the requested value, and B<no time conversion takes place>. It is always a good idea
 226 to be supply explicit times to the database:
 227
 228   my $event = $schema->resultset('EventTZ')->create({
 229     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
 230   });
 231
 232 =item Suppress the check on per-column basis
 233
 234   __PACKAGE__->add_columns(
 235     starts_when => { data_type => 'datetime', timezone => "America/Chicago", floating_tz_ok => 1 }
 236   );
 237
 238 =item Suppress the check globally
 239
 240 Set the environment variable DBIC_FLOATING_TZ_OK to some true value.
 241
 242 =back
 243
 244 Putting extra attributes like timezone, locale or floating_tz_ok into extra => {} has been
 245 B<DEPRECATED> because this gets you into trouble using L<DBIx::Class::Schema::Versioned>.
 246 Instead put it directly into the columns definition like in the examples above. If you still
 247 use the old way you'll see a warning - please fix your code then!
 248
 249 =head1 SEE ALSO
 250
 251 =over 4
 252
 253 =item More information about the add_columns method, and column metadata,
 254       can be found in the documentation for L<DBIx::Class::ResultSource>.
 255
 256 =item Further discussion of problems inherent to the Floating timezone:
 257       L<Floating DateTimes|DateTime/Floating_DateTimes>
 258       and L<< $dt->set_time_zone|DateTime/"Set" Methods >>
 259
 260 =back
 261
 262 =head1 AUTHOR
 263
 264 Matt S. Trout <mst@shadowcatsystems.co.uk>
 265
 266 =head1 CONTRIBUTORS
 267
 268 Aran Deltac <bluefeet@cpan.org>
 269
 270 =head1 LICENSE
 271
 272 You may distribute this code under the same terms as Perl itself.
 273