lib/DBIx/Class/DB.pm

   1 package DBIx::Class::DB;
   2
   3 use base qw/DBIx::Class/;
   4 use DBIx::Class::Schema;
   5 use DBIx::Class::Storage::DBI;
   6 use DBIx::Class::ClassResolver::PassThrough;
   7 use DBI;
   8
   9 __PACKAGE__->load_components(qw/ResultSetProxy/);
  10
  11 *dbi_commit = \&txn_commit;
  12 *dbi_rollback = \&txn_rollback;
  13
  14 sub storage { shift->schema_instance(@_)->storage; }
  15
  16 sub resultset_instance {
  17   my $class = ref $_[0] || $_[0];
  18   my $source = $class->result_source_instance;
  19   if ($source->result_class ne $class) {
  20     $source = $source->new($source);
  21     $source->result_class($class);
  22   }
  23   return $source->resultset;
  24 }
  25
  26 =head1 NAME
  27
  28 DBIx::Class::DB - Non-recommended classdata schema component
  29
  30 =head1 SYNOPSIS
  31
  32   package MyDB;
  33
  34   use base qw/DBIx::Class/;
  35   __PACKAGE__->load_components('DB');
  36
  37   __PACKAGE__->connection('dbi:...', 'user', 'pass', \%attrs);
  38
  39   package MyDB::MyTable;
  40
  41   use base qw/MyDB/;
  42   __PACKAGE__->load_components('Core'); # just load this in MyDB if it will
  43                                         # always be there
  44
  45   ...
  46
  47 =head1 DESCRIPTION
  48
  49 This class is designed to support the Class::DBI connection-as-classdata style
  50 for DBIx::Class. You are *strongly* recommended to use a DBIx::Class::Schema
  51 instead; DBIx::Class::DB will continue to be supported but new development
  52 will be focused on Schema-based DBIx::Class setups.
  53
  54 =head1 METHODS
  55
  56 =head2 storage
  57
  58 Sets or gets the storage backend. Defaults to L<DBIx::Class::Storage::DBI>.
  59
  60 =head2 class_resolver
  61
  62 ****DEPRECATED****
  63
  64 Sets or gets the class to use for resolving a class. Defaults to
  65 L<DBIx::Class::ClassResolver::Passthrough>, which returns whatever you give
  66 it. See resolve_class below.
  67
  68 =cut
  69
  70 __PACKAGE__->mk_classdata('class_resolver' =>
  71                           'DBIx::Class::ClassResolver::PassThrough');
  72
  73 =head2 connection
  74
  75   __PACKAGE__->connection($dsn, $user, $pass, $attrs);
  76
  77 Specifies the arguments that will be passed to DBI->connect(...) to
  78 instantiate the class dbh when required.
  79
  80 =cut
  81
  82 sub connection {
  83   my ($class, @info) = @_;
  84   $class->setup_schema_instance unless $class->can('schema_instance');
  85   $class->schema_instance->connection(@info);
  86 }
  87
  88 =head2 setup_schema_instance
  89
  90 Creates a class method ->schema_instance which contains a DBIx::Class::Schema;
  91 all class-method operations are proxies through to this object. If you don't
  92 call ->connection in your DBIx::Class::DB subclass at load time you *must*
  93 call ->setup_schema_instance in order for subclasses to find the schema and
  94 register themselves with it.
  95
  96 =cut
  97
  98 sub setup_schema_instance {
  99   my $class = shift;
 100   my $schema = bless({}, 'DBIx::Class::Schema');
 101   $class->mk_classdata('schema_instance' => $schema);
 102 }
 103
 104 =head2 txn_begin
 105
 106 Begins a transaction (does nothing if AutoCommit is off).
 107
 108 =cut
 109
 110 sub txn_begin { shift->schema_instance->txn_begin(@_); }
 111
 112 =head2 txn_commit
 113
 114 Commits the current transaction.
 115
 116 =cut
 117
 118 sub txn_commit { shift->schema_instance->txn_commit(@_); }
 119
 120 =head2 txn_rollback
 121
 122 Rolls back the current transaction.
 123
 124 =cut
 125
 126 sub txn_rollback { shift->schema_instance->txn_rollback(@_); }
 127
 128 =head2 txn_do
 129
 130 Executes a block of code transactionally. If this code reference
 131 throws an exception, the transaction is rolled back and the exception
 132 is rethrown. See L<DBIx::Class::Schema/"txn_do"> for more details.
 133
 134 =cut
 135
 136 sub txn_do { shift->schema_instance->txn_do(@_); }
 137
 138 {
 139   my $warn;
 140
 141   sub resolve_class {
 142     warn "resolve_class deprecated as of 0.04999_02" unless $warn++;
 143     return shift->class_resolver->class(@_);
 144   }
 145 }
 146
 147 1;
 148
 149 =head1 AUTHORS
 150
 151 Matt S. Trout <mst@shadowcatsystems.co.uk>
 152
 153 =head1 LICENSE
 154
 155 You may distribute this code under the same terms as Perl itself.
 156
 157 =cut
 158