lib/DBIx/Class/CDBICompat/ImaDBI.pm

   1 package DBIx::Class::CDBICompat::ImaDBI;
   2
   3 use strict;
   4 use warnings;
   5 use DBIx::ContextualFetch;
   6
   7 use base qw/DBIx::Class/;
   8
   9 __PACKAGE__->mk_classdata('_transform_sql_handler_order'
  10                             => [ qw/TABLE ESSENTIAL JOIN/ ] );
  11
  12 __PACKAGE__->mk_classdata('_transform_sql_handlers' =>
  13   {
  14     'TABLE' =>
  15       sub {
  16         my ($self, $class, $data) = @_;
  17         return $class->_table_name unless $data;
  18         my ($f_class, $alias) = split(/=/, $data);
  19         $f_class ||= $class;
  20         $self->{_classes}{$alias} = $f_class;
  21         return $f_class->_table_name." ${alias}";
  22       },
  23     'ESSENTIAL' =>
  24       sub {
  25         my ($self, $class, $data) = @_;
  26         return join(' ', $class->columns('Essential')) unless $data;
  27         return join(' ', $self->{_classes}{$data}->columns('Essential'));
  28       },
  29     'JOIN' =>
  30       sub {
  31         my ($self, $class, $data) = @_;
  32         my ($from, $to) = split(/ /, $data);
  33         my ($from_class, $to_class) = @{$self->{_classes}}{$from, $to};
  34         my ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  35                           map { $from_class->relationship_info($_) }
  36                             $from_class->relationships;
  37         unless ($rel_obj) {
  38           ($from, $to) = ($to, $from);
  39           ($from_class, $to_class) = ($to_class, $from_class);
  40           ($rel_obj) = grep { $_->{class} && $_->{class} eq $to_class }
  41                           map { $from_class->relationship_info($_) }
  42                             $from_class->relationships;
  43         }
  44         $self->throw( "No relationship to JOIN from ${from_class} to ${to_class}" )
  45           unless $rel_obj;
  46         my $attrs = {
  47           %$self,
  48           _aliases => { self => $from, foreign => $to },
  49           _action => 'join',
  50         };
  51         my $join = $from_class->storage->sql_maker->_join_condition(
  52           $from_class->resolve_condition($rel_obj->{cond}, $attrs) );
  53         return $join;
  54       }
  55
  56   } );
  57
  58 sub db_Main {
  59   return $_[0]->storage->dbh;
  60 }
  61
  62 sub connection {
  63   my ($class, @info) = @_;
  64   $info[3] = { %{ $info[3] || {}} };
  65   $info[3]->{RootClass} = 'DBIx::ContextualFetch';
  66   return $class->next::method(@info);
  67 }
  68
  69 sub __driver {
  70   return $_[0]->storage->dbh->{Driver}->{Name};
  71 }
  72
  73 sub set_sql {
  74   my ($class, $name, $sql) = @_;
  75   no strict 'refs';
  76   *{"${class}::sql_${name}"} =
  77     sub {
  78       my $sql = $sql;
  79       my $class = shift;
  80       return $class->storage->sth($class->transform_sql($sql, @_));
  81     };
  82   if ($sql =~ /select/i) {
  83     my $meth = "sql_${name}";
  84     *{"${class}::search_${name}"} =
  85       sub {
  86         my ($class, @args) = @_;
  87         my $sth = $class->$meth;
  88         $sth->execute(@args);
  89         return $class->sth_to_objects($sth);
  90       };
  91   }
  92 }
  93
  94 sub sth_to_objects {
  95   my ($class, $sth) = @_;
  96   my @ret;
  97   while (my $row = $sth->fetchrow_hashref) {
  98     push(@ret, $class->inflate_result($row));
  99   }
 100   return @ret;
 101 }
 102
 103 sub transform_sql {
 104   my ($class, $sql, @args) = @_;
 105   my $attrs = { };
 106   foreach my $key (@{$class->_transform_sql_handler_order}) {
 107     my $h = $class->_transform_sql_handlers->{$key};
 108     $sql =~ s/__$key(?:\(([^\)]+)\))?__/$h->($attrs, $class, $1)/eg;
 109   }
 110   #warn $sql;
 111   return sprintf($sql, @args);
 112 }
 113
 114 package DBIx::ContextualFetch::st;
 115
 116 no warnings 'redefine';
 117
 118 sub _untaint_execute {
 119   my $sth = shift;
 120   my $old_value = $sth->{Taint};
 121   $sth->{Taint} = 0;
 122   my $ret;
 123   {
 124     no warnings 'uninitialized';
 125     $ret = $sth->SUPER::execute(@_);
 126   }
 127   $sth->{Taint} = $old_value;
 128   return $ret;
 129 }
 130
 131 1;