lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 # check deps
   4 BEGIN {
   5     my @_deps = qw(
   6         Moose MooseX::Types MooseX::Types::JSON MooseX::Types::Path::Class
   7         Try::Tiny parent JSON::Any Class::C3::Componentised
   8         namespace::autoclean
   9     );
  10
  11     my @_missing_deps;
  12     foreach my $dep (@_deps) {
  13       eval "require $dep";
  14       if ($@) {
  15         push @_missing_deps, $dep;
  16       }
  17     }
  18
  19     if (@_missing_deps > 0) {
  20       die "The following dependecies are missing " . join ",", @_missing_deps;
  21     }
  22 }
  23
  24 use Moose;
  25 use parent 'DBIx::Class::Schema';
  26 use Carp::Clan qw/^DBIx::Class/;
  27
  28 use MooseX::Types::Moose qw/Int HashRef ArrayRef Str Any Bool/;
  29 use DBIx::Class::Admin::Types qw/DBICConnectInfo/;
  30 use MooseX::Types::JSON qw(JSON);
  31 use MooseX::Types::Path::Class qw(Dir File);
  32 use Try::Tiny;
  33 use JSON::Any;
  34 use namespace::autoclean;
  35
  36
  37 =head1 NAME
  38
  39 DBIx::Class::Admin - Administration object for schemas
  40
  41 =head1 SYNOPSIS
  42
  43   use DBIx::Class::Admin;
  44
  45   # ddl manipulation
  46   my $admin = DBIx::Class::Admin->new(
  47     schema_class=> 'MY::Schema',
  48     sql_dir=> $sql_dir,
  49     connect_info => { dsn => $dsn, user => $user, password => $pass },
  50   );
  51
  52   # create SQLite sql
  53   $admin->create('SQLite');
  54
  55   # create SQL diff for an upgrade
  56   $admin->create('SQLite', {} , "1.0");
  57
  58   # upgrade a database
  59   $admin->upgrade();
  60
  61   # install a version for an unversioned schema
  62   $admin->install("3.0");
  63
  64 =head1 Attributes
  65
  66 =head2 schema_class
  67
  68 the class of the schema to load
  69
  70 =cut
  71
  72 has 'schema_class' => (
  73   is    => 'ro',
  74   isa    => Str,
  75   coerce  => 1,
  76 );
  77
  78
  79 =head2 schema
  80
  81 A pre-connected schema object can be provided for manipulation
  82
  83 =cut
  84
  85 has 'schema' => (
  86   is      => 'ro',
  87   isa      => 'DBIx::Class::Schema',
  88   lazy_build  => 1,
  89 );
  90
  91 sub _build_schema {
  92   my ($self)  = @_;
  93   $self->ensure_class_loaded($self->schema_class);
  94
  95   $self->connect_info->[3]->{ignore_version} =1;
  96   return $self->schema_class->connect(@{$self->connect_info()} ); # ,  $self->connect_info->[3], { ignore_version => 1} );
  97 }
  98
  99
 100 =head2 resultset
 101
 102 a resultset from the schema to operate on
 103
 104 =cut
 105
 106 has 'resultset' => (
 107   is      => 'rw',
 108   isa      => Str,
 109 );
 110
 111
 112 =head2 where
 113
 114 a hash ref or json string to be used for identifying data to manipulate
 115
 116 =cut
 117
 118 has 'where' => (
 119   is      => 'rw',
 120   isa      => HashRef,
 121   coerce    => 1,
 122 );
 123
 124
 125 =head2 set
 126
 127 a hash ref or json string to be used for inserting or updating data
 128
 129 =cut
 130
 131 has 'set' => (
 132   is      => 'rw',
 133   isa      => HashRef,
 134   coerce    => 1,
 135 );
 136
 137
 138 =head2 attrs
 139
 140 a hash ref or json string to be used for passing additonal info to the ->search call
 141
 142 =cut
 143
 144 has 'attrs' => (
 145   is       => 'rw',
 146   isa      => HashRef,
 147   coerce    => 1,
 148 );
 149
 150
 151 =head2 connect_info
 152
 153 connect_info the arguments to provide to the connect call of the schema_class
 154
 155 =cut
 156
 157 has 'connect_info' => (
 158   is      => 'ro',
 159   isa      => DBICConnectInfo,
 160   lazy_build  => 1,
 161   coerce    => 1,
 162 );
 163
 164 sub _build_connect_info {
 165   my ($self) = @_;
 166   return $self->_find_stanza($self->config, $self->config_stanza);
 167 }
 168
 169
 170 =head2 config_file
 171
 172 config_file provide a config_file to read connect_info from, if this is provided
 173 config_stanze should also be provided to locate where the connect_info is in the config
 174 The config file should be in a format readable by Config::General
 175
 176 =cut
 177
 178 has config_file => (
 179   is      => 'ro',
 180   isa      => File,
 181   coerce    => 1,
 182 );
 183
 184
 185 =head2 config_stanza
 186
 187 config_stanza for use with config_file should be a '::' deliminated 'path' to the connection information
 188 designed for use with catalyst config files
 189
 190 =cut
 191
 192 has 'config_stanza' => (
 193   is      => 'ro',
 194   isa      => Str,
 195 );
 196
 197
 198 =head2 config
 199
 200 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 201 config_stanza will still be required.
 202
 203 =cut
 204
 205 has config => (
 206   is      => 'ro',
 207   isa      => HashRef,
 208   lazy_build  => 1,
 209 );
 210
 211 sub _build_config {
 212   my ($self) = @_;
 213   try { require Config::Any } catch { $self->throw_exception( "Config::Any is required to parse the config file"); };
 214
 215   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 216
 217   # just grab the config from the config file
 218   $cfg = $cfg->{$self->config_file};
 219   return $cfg;
 220 }
 221
 222
 223 =head2 sql_dir
 224
 225 The location where sql ddl files should be created or found for an upgrade.
 226
 227 =cut
 228
 229 has 'sql_dir' => (
 230   is      => 'ro',
 231   isa      => Dir,
 232   coerce    => 1,
 233 );
 234
 235
 236 =head2 version
 237
 238 Used for install, the version which will be 'installed' in the schema
 239
 240 =cut
 241
 242 has version => (
 243   is      => 'rw',
 244   isa      => Str,
 245 );
 246
 247
 248 =head2 preversion
 249
 250 Previouse version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 251
 252 =cut
 253
 254 has preversion => (
 255   is      => 'rw',
 256   isa      => Str,
 257 );
 258
 259
 260 =head2 force
 261
 262 Try and force certain operations.
 263
 264 =cut
 265
 266 has force => (
 267   is      => 'rw',
 268   isa      => Bool,
 269 );
 270
 271
 272 =head2 quiet
 273
 274 Be less verbose about actions
 275
 276 =cut
 277
 278 has quiet => (
 279   is      => 'rw',
 280   isa      => Bool,
 281 );
 282
 283 has '_confirm' => (
 284   is    => 'bare',
 285   isa    => Bool,
 286 );
 287
 288
 289 =head1 METHODS
 290
 291 =head2 create
 292
 293 =over 4
 294
 295 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 296
 297 =back
 298
 299 L<create> will generate sql for the supplied schema_class in sql_dir.  The flavour of sql to
 300 generate can be controlled by suppling a sqlt_type which should be a L<SQL::Translator> name.
 301
 302 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 303
 304 Optional preversion can be supplied to generate a diff to be used by upgrade.
 305
 306 =cut
 307
 308 sub create {
 309   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 310
 311   $preversion ||= $self->preversion();
 312
 313   my $schema = $self->schema();
 314   # create the dir if does not exist
 315   $self->sql_dir->mkpath() if ( ! -d $self->sql_dir);
 316
 317   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 318 }
 319
 320
 321 =head2 upgrade
 322
 323 =over 4
 324
 325 =item Arguments: <none>
 326
 327 =back
 328
 329 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 330 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 331
 332 =cut
 333
 334 sub upgrade {
 335   my ($self) = @_;
 336   my $schema = $self->schema();
 337   if (!$schema->get_db_version()) {
 338     # schema is unversioned
 339     $self->throw_exception ("could not determin current schema version, please either install or deploy");
 340   } else {
 341     my $ret = $schema->upgrade();
 342     return $ret;
 343   }
 344 }
 345
 346
 347 =head2 install
 348
 349 =over 4
 350
 351 =item Arguments: $version
 352
 353 =back
 354
 355 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 356 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 357 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 358 already versioned databases.
 359
 360 =cut
 361
 362 sub install {
 363   my ($self, $version) = @_;
 364
 365   my $schema = $self->schema();
 366   $version ||= $self->version();
 367   if (!$schema->get_db_version() ) {
 368     # schema is unversioned
 369     print "Going to install schema version\n";
 370     my $ret = $schema->install($version);
 371     print "retun is $ret\n";
 372   }
 373   elsif ($schema->get_db_version() and $self->force ) {
 374     carp "Forcing install may not be a good idea";
 375     if($self->_confirm() ) {
 376       $self->schema->_set_db_version({ version => $version});
 377     }
 378   }
 379   else {
 380     $self->throw_exception ("schema already has a version not installing, try upgrade instead");
 381   }
 382
 383 }
 384
 385
 386 =head2 deploy
 387
 388 =over 4
 389
 390 =item Arguments: $args
 391
 392 =back
 393
 394 deploy will create the schema at the connected database.  C<$args> are passed straight to
 395 L<DBIx::Class::Schema/deploy>.
 396
 397 =cut
 398
 399 sub deploy {
 400   my ($self, $args) = @_;
 401   my $schema = $self->schema();
 402   if (!$schema->get_db_version() ) {
 403     # schema is unversioned
 404     $schema->deploy( $args, $self->sql_dir)
 405       or $self->throw_exception ("could not deploy schema");
 406   } else {
 407     $self->throw_exception("there already is a database with a version here, try upgrade instead");
 408   }
 409 }
 410
 411 =head2 insert
 412
 413 =over 4
 414
 415 =item Arguments: $rs, $set
 416
 417 =back
 418
 419 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 420 into that resultset
 421
 422 =cut
 423
 424 sub insert {
 425   my ($self, $rs, $set) = @_;
 426
 427   $rs ||= $self->resultset();
 428   $set ||= $self->set();
 429   my $resultset = $self->schema->resultset($rs);
 430   my $obj = $resultset->create( $set );
 431   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 432 }
 433
 434
 435 =head2 update
 436
 437 =over 4
 438
 439 =item Arguments: $rs, $set, $where
 440
 441 =back
 442
 443 update takes the name of a resultset from the schema_class, a hashref of data to update and
 444 a where hash used to form the search for the rows to update.
 445
 446 =cut
 447
 448 sub update {
 449   my ($self, $rs, $set, $where) = @_;
 450
 451   $rs ||= $self->resultset();
 452   $where ||= $self->where();
 453   $set ||= $self->set();
 454   my $resultset = $self->schema->resultset($rs);
 455   $resultset = $resultset->search( ($where||{}) );
 456
 457   my $count = $resultset->count();
 458   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 459
 460   if ( $self->force || $self->_confirm() ) {
 461     $resultset->update_all( $set );
 462   }
 463 }
 464
 465
 466 =head2 delete
 467
 468 =over 4
 469
 470 =item Arguments: $rs, $where, $attrs
 471
 472 =back
 473
 474 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 475 The found data is deleted and cannot be recovered.
 476
 477 =cut
 478
 479 sub delete {
 480   my ($self, $rs, $where, $attrs) = @_;
 481
 482   $rs ||= $self->resultset();
 483   $where ||= $self->where();
 484   $attrs ||= $self->attrs();
 485   my $resultset = $self->schema->resultset($rs);
 486   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 487
 488   my $count = $resultset->count();
 489   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 490
 491   if ( $self->force || $self->_confirm() ) {
 492     $resultset->delete_all();
 493   }
 494 }
 495
 496
 497 =head2 select
 498
 499 =over 4
 500
 501 =item Arguments: $rs, $where, $attrs
 502
 503 =back
 504
 505 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 506 The found data is returned in a array ref where the first row will be the columns list.
 507
 508 =cut
 509
 510 sub select {
 511   my ($self, $rs, $where, $attrs) = @_;
 512
 513   $rs ||= $self->resultset();
 514   $where ||= $self->where();
 515   $attrs ||= $self->attrs();
 516   my $resultset = $self->schema->resultset($rs);
 517   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 518
 519   my @data;
 520   my @columns = $resultset->result_source->columns();
 521   push @data, [@columns];#
 522
 523   while (my $row = $resultset->next()) {
 524     my @fields;
 525     foreach my $column (@columns) {
 526       push( @fields, $row->get_column($column) );
 527     }
 528     push @data, [@fields];
 529   }
 530
 531   return \@data;
 532 }
 533
 534 sub _confirm {
 535   my ($self) = @_;
 536   print "Are you sure you want to do this? (type YES to confirm) \n";
 537   # mainly here for testing
 538   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 539   my $response = <STDIN>;
 540   return 1 if ($response=~/^YES/);
 541   return;
 542 }
 543
 544 sub _find_stanza {
 545   my ($self, $cfg, $stanza) = @_;
 546   my @path = split /::/, $stanza;
 547   while (my $path = shift @path) {
 548     if (exists $cfg->{$path}) {
 549       $cfg = $cfg->{$path};
 550     }
 551     else {
 552       $self->throw_exception("could not find $stanza in config, $path did not seem to exist");
 553     }
 554   }
 555   return $cfg;
 556 }
 557
 558 =head1 AUTHORS
 559
 560 See L<DBIx::Class/CONTRIBUTORS>.
 561
 562 =head1 LICENSE
 563
 564 You may distribute this code under the same terms as Perl itself
 565
 566 =cut
 567
 568 1;