lib/DBIx/Class/Admin.pm

   1 package DBIx::Class::Admin;
   2
   3 # check deps
   4 BEGIN {
   5   use Carp::Clan qw/^DBIx::Class/;
   6   use DBIx::Class;
   7   croak('The following modules are required for DBIx::Class::Admin ' . DBIx::Class::Optional::Dependencies->req_missing_for ('admin') )
   8     unless DBIx::Class::Optional::Dependencies->req_ok_for ('admin');
   9 }
  10
  11 use Moose;
  12 use MooseX::Types::Moose qw/Int Str Any Bool/;
  13 use DBIx::Class::Admin::Types qw/DBICConnectInfo DBICHashRef/;
  14 use MooseX::Types::JSON qw(JSON);
  15 use MooseX::Types::Path::Class qw(Dir File);
  16 use Try::Tiny;
  17 use JSON::Any qw(DWIW XS JSON);
  18 use namespace::autoclean;
  19
  20 =head1 NAME
  21
  22 DBIx::Class::Admin - Administration object for schemas
  23
  24 =head1 SYNOPSIS
  25
  26   $ dbicadmin --help
  27
  28   $ dbicadmin --schema=MyApp::Schema \
  29     --connect='["dbi:SQLite:my.db", "", ""]' \
  30     --deploy
  31
  32   $ dbicadmin --schema=MyApp::Schema --class=Employee \
  33     --connect='["dbi:SQLite:my.db", "", ""]' \
  34     --op=update --set='{ "name": "New_Employee" }'
  35
  36   use DBIx::Class::Admin;
  37
  38   # ddl manipulation
  39   my $admin = DBIx::Class::Admin->new(
  40     schema_class=> 'MY::Schema',
  41     sql_dir=> $sql_dir,
  42     connect_info => { dsn => $dsn, user => $user, password => $pass },
  43   );
  44
  45   # create SQLite sql
  46   $admin->create('SQLite');
  47
  48   # create SQL diff for an upgrade
  49   $admin->create('SQLite', {} , "1.0");
  50
  51   # upgrade a database
  52   $admin->upgrade();
  53
  54   # install a version for an unversioned schema
  55   $admin->install("3.0");
  56
  57 =head1 REQUIREMENTS
  58
  59 The Admin interface has additional requirements not currently part of
  60 L<DBIx::Class>. See L<DBIx::Class::Optional::Dependencies> for more details.
  61
  62 =head1 ATTRIBUTES
  63
  64 =head2 schema_class
  65
  66 the class of the schema to load
  67
  68 =cut
  69
  70 has 'schema_class' => (
  71   is  => 'ro',
  72   isa => Str,
  73 );
  74
  75
  76 =head2 schema
  77
  78 A pre-connected schema object can be provided for manipulation
  79
  80 =cut
  81
  82 has 'schema' => (
  83   is          => 'ro',
  84   isa         => 'DBIx::Class::Schema',
  85   lazy_build  => 1,
  86 );
  87
  88 sub _build_schema {
  89   my ($self)  = @_;
  90
  91   require Class::MOP;
  92   Class::MOP::load_class($self->schema_class);
  93   $self->connect_info->[3]{ignore_version} = 1;
  94   return $self->schema_class->connect(@{$self->connect_info});
  95 }
  96
  97 =head2 resultset
  98
  99 a resultset from the schema to operate on
 100
 101 =cut
 102
 103 has 'resultset' => (
 104   is  => 'rw',
 105   isa => Str,
 106 );
 107
 108
 109 =head2 where
 110
 111 a hash ref or json string to be used for identifying data to manipulate
 112
 113 =cut
 114
 115 has 'where' => (
 116   is      => 'rw',
 117   isa     => DBICHashRef,
 118   coerce  => 1,
 119 );
 120
 121
 122 =head2 set
 123
 124 a hash ref or json string to be used for inserting or updating data
 125
 126 =cut
 127
 128 has 'set' => (
 129   is      => 'rw',
 130   isa     => DBICHashRef,
 131   coerce  => 1,
 132 );
 133
 134
 135 =head2 attrs
 136
 137 a hash ref or json string to be used for passing additonal info to the ->search call
 138
 139 =cut
 140
 141 has 'attrs' => (
 142   is      => 'rw',
 143   isa     => DBICHashRef,
 144   coerce  => 1,
 145 );
 146
 147
 148 =head2 connect_info
 149
 150 connect_info the arguments to provide to the connect call of the schema_class
 151
 152 =cut
 153
 154 has 'connect_info' => (
 155   is          => 'ro',
 156   isa         => DBICConnectInfo,
 157   lazy_build  => 1,
 158   coerce      => 1,
 159 );
 160
 161 sub _build_connect_info {
 162   my ($self) = @_;
 163   return $self->_find_stanza($self->config, $self->config_stanza);
 164 }
 165
 166
 167 =head2 config_file
 168
 169 config_file provide a config_file to read connect_info from, if this is provided
 170 config_stanze should also be provided to locate where the connect_info is in the config
 171 The config file should be in a format readable by Config::General
 172
 173 =cut
 174
 175 has config_file => (
 176   is      => 'ro',
 177   isa     => File,
 178   coerce  => 1,
 179 );
 180
 181
 182 =head2 config_stanza
 183
 184 config_stanza for use with config_file should be a '::' deliminated 'path' to the connection information
 185 designed for use with catalyst config files
 186
 187 =cut
 188
 189 has 'config_stanza' => (
 190   is  => 'ro',
 191   isa => Str,
 192 );
 193
 194
 195 =head2 config
 196
 197 Instead of loading from a file the configuration can be provided directly as a hash ref.  Please note
 198 config_stanza will still be required.
 199
 200 =cut
 201
 202 has config => (
 203   is          => 'ro',
 204   isa         => DBICHashRef,
 205   lazy_build  => 1,
 206 );
 207
 208 sub _build_config {
 209   my ($self) = @_;
 210
 211   try { require Config::Any }
 212     catch { die ("Config::Any is required to parse the config file.\n") };
 213
 214   my $cfg = Config::Any->load_files ( {files => [$self->config_file], use_ext =>1, flatten_to_hash=>1});
 215
 216   # just grab the config from the config file
 217   $cfg = $cfg->{$self->config_file};
 218   return $cfg;
 219 }
 220
 221
 222 =head2 sql_dir
 223
 224 The location where sql ddl files should be created or found for an upgrade.
 225
 226 =cut
 227
 228 has 'sql_dir' => (
 229   is      => 'ro',
 230   isa     => Dir,
 231   coerce  => 1,
 232 );
 233
 234
 235 =head2 sql_type
 236
 237 The type of sql dialect to use for creating sql files from schema
 238
 239 =cut
 240
 241 has 'sql_type' => (
 242   is     => 'ro',
 243   isa    => Str,
 244 );
 245
 246 =head2 version
 247
 248 Used for install, the version which will be 'installed' in the schema
 249
 250 =cut
 251
 252 has version => (
 253   is  => 'rw',
 254   isa => Str,
 255 );
 256
 257
 258 =head2 preversion
 259
 260 Previouse version of the schema to create an upgrade diff for, the full sql for that version of the sql must be in the sql_dir
 261
 262 =cut
 263
 264 has preversion => (
 265   is  => 'rw',
 266   isa => Str,
 267 );
 268
 269
 270 =head2 force
 271
 272 Try and force certain operations.
 273
 274 =cut
 275
 276 has force => (
 277   is  => 'rw',
 278   isa => Bool,
 279 );
 280
 281
 282 =head2 quiet
 283
 284 Be less verbose about actions
 285
 286 =cut
 287
 288 has quiet => (
 289   is  => 'rw',
 290   isa => Bool,
 291 );
 292
 293 has '_confirm' => (
 294   is  => 'bare',
 295   isa => Bool,
 296 );
 297
 298
 299 =head2 trace
 300
 301 Toggle DBIx::Class debug output
 302
 303 =cut
 304
 305 has trace => (
 306     is => 'rw',
 307     isa => Bool,
 308     trigger => \&_trigger_trace,
 309 );
 310
 311 sub _trigger_trace {
 312     my ($self, $new, $old) = @_;
 313     $self->schema->storage->debug($new);
 314 }
 315
 316
 317 =head1 METHODS
 318
 319 =head2 create
 320
 321 =over 4
 322
 323 =item Arguments: $sqlt_type, \%sqlt_args, $preversion
 324
 325 =back
 326
 327 L<create> will generate sql for the supplied schema_class in sql_dir. The
 328 flavour of sql to generate can be controlled by supplying a sqlt_type which
 329 should be a L<SQL::Translator> name.
 330
 331 Arguments for L<SQL::Translator> can be supplied in the sqlt_args hashref.
 332
 333 Optional preversion can be supplied to generate a diff to be used by upgrade.
 334
 335 =cut
 336
 337 sub create {
 338   my ($self, $sqlt_type, $sqlt_args, $preversion) = @_;
 339
 340   $preversion ||= $self->preversion();
 341   $sqlt_type ||= $self->sql_type();
 342
 343   my $schema = $self->schema();
 344   # create the dir if does not exist
 345   $self->sql_dir->mkpath() if ( ! -d $self->sql_dir);
 346
 347   $schema->create_ddl_dir( $sqlt_type, (defined $schema->schema_version ? $schema->schema_version : ""), $self->sql_dir->stringify, $preversion, $sqlt_args );
 348 }
 349
 350
 351 =head2 upgrade
 352
 353 =over 4
 354
 355 =item Arguments: <none>
 356
 357 =back
 358
 359 upgrade will attempt to upgrade the connected database to the same version as the schema_class.
 360 B<MAKE SURE YOU BACKUP YOUR DB FIRST>
 361
 362 =cut
 363
 364 sub upgrade {
 365   my ($self) = @_;
 366   my $schema = $self->schema();
 367
 368   if (!$schema->get_db_version()) {
 369     # schema is unversioned
 370     $schema->throw_exception ("Could not determin current schema version, please either install() or deploy().\n");
 371   } else {
 372     $schema->upgrade_directory ($self->sql_dir) if $self->sql_dir;  # this will override whatever default the schema has
 373     my $ret = $schema->upgrade();
 374     return $ret;
 375   }
 376 }
 377
 378
 379 =head2 install
 380
 381 =over 4
 382
 383 =item Arguments: $version
 384
 385 =back
 386
 387 install is here to help when you want to move to L<DBIx::Class::Schema::Versioned> and have an existing
 388 database.  install will take a version and add the version tracking tables and 'install' the version.  No
 389 further ddl modification takes place.  Setting the force attribute to a true value will allow overriding of
 390 already versioned databases.
 391
 392 =cut
 393
 394 sub install {
 395   my ($self, $version) = @_;
 396
 397   my $schema = $self->schema();
 398   $version ||= $self->version();
 399   if (!$schema->get_db_version() ) {
 400     # schema is unversioned
 401     print "Going to install schema version\n" if (!$self->quiet);
 402     my $ret = $schema->install($version);
 403     print "return is $ret\n" if (!$self->quiet);
 404   }
 405   elsif ($schema->get_db_version() and $self->force ) {
 406     carp "Forcing install may not be a good idea";
 407     if($self->_confirm() ) {
 408       $self->schema->_set_db_version({ version => $version});
 409     }
 410   }
 411   else {
 412     $schema->throw_exception ("Schema already has a version. Try upgrade instead.\n");
 413   }
 414
 415 }
 416
 417
 418 =head2 deploy
 419
 420 =over 4
 421
 422 =item Arguments: $args
 423
 424 =back
 425
 426 deploy will create the schema at the connected database.  C<$args> are passed straight to
 427 L<DBIx::Class::Schema/deploy>.
 428
 429 =cut
 430
 431 sub deploy {
 432   my ($self, $args) = @_;
 433   my $schema = $self->schema();
 434   $schema->deploy( $args, $self->sql_dir );
 435 }
 436
 437 =head2 insert
 438
 439 =over 4
 440
 441 =item Arguments: $rs, $set
 442
 443 =back
 444
 445 insert takes the name of a resultset from the schema_class and a hashref of data to insert
 446 into that resultset
 447
 448 =cut
 449
 450 sub insert {
 451   my ($self, $rs, $set) = @_;
 452
 453   $rs ||= $self->resultset();
 454   $set ||= $self->set();
 455   my $resultset = $self->schema->resultset($rs);
 456   my $obj = $resultset->create( $set );
 457   print ''.ref($resultset).' ID: '.join(',',$obj->id())."\n" if (!$self->quiet);
 458 }
 459
 460
 461 =head2 update
 462
 463 =over 4
 464
 465 =item Arguments: $rs, $set, $where
 466
 467 =back
 468
 469 update takes the name of a resultset from the schema_class, a hashref of data to update and
 470 a where hash used to form the search for the rows to update.
 471
 472 =cut
 473
 474 sub update {
 475   my ($self, $rs, $set, $where) = @_;
 476
 477   $rs ||= $self->resultset();
 478   $where ||= $self->where();
 479   $set ||= $self->set();
 480   my $resultset = $self->schema->resultset($rs);
 481   $resultset = $resultset->search( ($where||{}) );
 482
 483   my $count = $resultset->count();
 484   print "This action will modify $count ".ref($resultset)." records.\n" if (!$self->quiet);
 485
 486   if ( $self->force || $self->_confirm() ) {
 487     $resultset->update_all( $set );
 488   }
 489 }
 490
 491
 492 =head2 delete
 493
 494 =over 4
 495
 496 =item Arguments: $rs, $where, $attrs
 497
 498 =back
 499
 500 delete takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 501 The found data is deleted and cannot be recovered.
 502
 503 =cut
 504
 505 sub delete {
 506   my ($self, $rs, $where, $attrs) = @_;
 507
 508   $rs ||= $self->resultset();
 509   $where ||= $self->where();
 510   $attrs ||= $self->attrs();
 511   my $resultset = $self->schema->resultset($rs);
 512   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 513
 514   my $count = $resultset->count();
 515   print "This action will delete $count ".ref($resultset)." records.\n" if (!$self->quiet);
 516
 517   if ( $self->force || $self->_confirm() ) {
 518     $resultset->delete_all();
 519   }
 520 }
 521
 522
 523 =head2 select
 524
 525 =over 4
 526
 527 =item Arguments: $rs, $where, $attrs
 528
 529 =back
 530
 531 select takes the name of a resultset from the schema_class, a where hashref and a attrs to pass to ->search.
 532 The found data is returned in a array ref where the first row will be the columns list.
 533
 534 =cut
 535
 536 sub select {
 537   my ($self, $rs, $where, $attrs) = @_;
 538
 539   $rs ||= $self->resultset();
 540   $where ||= $self->where();
 541   $attrs ||= $self->attrs();
 542   my $resultset = $self->schema->resultset($rs);
 543   $resultset = $resultset->search( ($where||{}), ($attrs||()) );
 544
 545   my @data;
 546   my @columns = $resultset->result_source->columns();
 547   push @data, [@columns];#
 548
 549   while (my $row = $resultset->next()) {
 550     my @fields;
 551     foreach my $column (@columns) {
 552       push( @fields, $row->get_column($column) );
 553     }
 554     push @data, [@fields];
 555   }
 556
 557   return \@data;
 558 }
 559
 560 sub _confirm {
 561   my ($self) = @_;
 562
 563   # mainly here for testing
 564   return 1 if ($self->meta->get_attribute('_confirm')->get_value($self));
 565
 566   print "Are you sure you want to do this? (type YES to confirm) \n";
 567   my $response = <STDIN>;
 568
 569   return ($response=~/^YES/);
 570 }
 571
 572 sub _find_stanza {
 573   my ($self, $cfg, $stanza) = @_;
 574   my @path = split /::/, $stanza;
 575   while (my $path = shift @path) {
 576     if (exists $cfg->{$path}) {
 577       $cfg = $cfg->{$path};
 578     }
 579     else {
 580       die ("Could not find $stanza in config, $path does not seem to exist.\n");
 581     }
 582   }
 583   return $cfg;
 584 }
 585
 586 =head1 AUTHOR
 587
 588 See L<DBIx::Class/CONTRIBUTORS>.
 589
 590 =head1 LICENSE
 591
 592 You may distribute this code under the same terms as Perl itself
 593
 594 =cut
 595
 596 1;